gold/configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_PREREQ(2.59)
   4
   5 AC_INIT(gold, 0.1)
   6 AC_CONFIG_SRCDIR(gold.cc)
   7
   8 AC_CANONICAL_TARGET
   9
  10 AM_INIT_AUTOMAKE
  11
  12 AM_CONFIG_HEADER(config.h:config.in)
  13
  14 AC_ARG_WITH(sysroot,
  15 [  --with-sysroot[=DIR]    search for usr/lib et al within DIR],
  16 [sysroot=$withval], [sysroot=no])
  17
  18 if test "$sysroot" = "yes"; then
  19   sysroot='${exec_prefix}/${target_alias}/sys-root'
  20 elif test "$sysroot" = "no"; then
  21   sysroot=
  22 fi
  23
  24 sysroot_relocatable=0
  25 if test -n "$sysroot"; then
  26   case "sysroot" in
  27     "${prefix}" | "${prefix}/"* | \
  28     "${exec_prefix}" | "${exec_prefix}/"* | \
  29     '${prefix}' | '${prefix}/'*| \
  30     '${exec_prefix}' | '${exec_prefix}/'*)
  31       sysroot_relocatable=1
  32       ;;
  33   esac
  34 fi
  35
  36 AC_DEFINE_UNQUOTED(TARGET_SYSTEM_ROOT, "$sysroot",
  37   [System root for target files])
  38 AC_DEFINE_UNQUOTED(TARGET_SYSTEM_ROOT_RELOCATABLE, $sysroot_relocatable,
  39   [Whether the system root can be relocated])
  40
  41 dnl For now threads are a configure time option.
  42 AC_ARG_ENABLE([threads],
  43 [  --enable-threads        multi-threaded linking],
  44 [case "${enableval}" in
  45   yes | "") threads=yes ;;
  46   no) threads=no ;;
  47   *) threads=yes ;;
  48  esac],
  49 [threads=no])
  50 if test "$threads" = "yes"; then
  51   AC_DEFINE(ENABLE_THREADS, 1,
  52             [Define to do multi-threaded linking])
  53 fi
  54 AM_CONDITIONAL(THREADS, test "$threads" = "yes")
  55
  56 AC_ARG_ENABLE([targets],
  57 [  --enable-targets        alternative target configurations],
  58 [case "${enableval}" in
  59   yes | "")
  60     AC_MSG_ERROR([--enable-targets option must specify target names or 'all'])
  61     ;;
  62   no)
  63     enable_targets=
  64     ;;
  65   *)
  66     enable_targets=$enableval
  67     ;;
  68 esac],
  69 [# For now, enable all targets by default
  70  enable_targets=all
  71 ])
  72
  73 # Canonicalize the enabled targets.
  74 if test -n "$enable_targets"; then
  75   for targ in `echo $enable_targets | sed -e 's/,/ /g'`; do
  76     result=`$ac_config_sub $targ 2>/dev/null`
  77     if test -n "$result"; then
  78       canon_targets="$canon_targets $result"
  79     else
  80       # Permit unrecognized target names, like "all".
  81       canon_targets="$canon_targets $targ"
  82     fi
  83   done
  84 fi
  85
  86 # See which specific instantiations we need.
  87 targetobjs=
  88 all_targets=
  89 default_machine=
  90 default_size=
  91 default_big_endian=
  92 targ_32_little=
  93 targ_32_big=
  94 targ_64_little=
  95 targ_64_big=
  96 for targ in $target $canon_targets; do
  97   if test "$targ" = "all"; then
  98     targ_32_little=yes
  99     targ_32_big=yes
 100     targ_64_little=yes
 101     targ_64_big=yes
 102     all_targets=yes
 103   else
 104     . ${srcdir}/configure.tgt
 105
 106     if test "$targ_obj" = "UNKNOWN"; then
 107       AC_MSG_ERROR("unsupported target $targ")
 108     else
 109       targetobjs="$targetobjs ${targ_obj}.\$(OBJEXT)"
 110       if test "$targ_size" = "32" -o "$targ_extra_size" = "32"; then
 111           if test "$targ_big_endian" = "true" \
 112               -o "$targ_extra_big_endian" = "true"; then
 113               targ_32_big=yes
 114           fi
 115           if test "$targ_big_endian" = "false" \
 116               -o "$targ_extra_big_endian" = "false"; then
 117               targ_32_little=yes
 118           fi
 119       fi
 120       if test "$targ_size" = "64" -o "$targ_extra_size" = "64"; then
 121           if test "$targ_big_endian" = "true" \
 122               -o "$targ_extra_big_endian" = "true"; then
 123               targ_64_big=yes
 124           fi
 125           if test "$targ_big_endian" = "false" \
 126               -o "$targ_extra_big_endian" = "false"; then
 127               targ_64_little=yes
 128           fi
 129       fi
 130
 131       if test "$target" = "$targ"; then
 132         default_machine=$targ_machine
 133         default_size=$targ_size
 134         default_big_endian=$targ_big_endian
 135       fi
 136     fi
 137   fi
 138 done
 139
 140 if test -n "$targ_32_little"; then
 141   AC_DEFINE(HAVE_TARGET_32_LITTLE, 1,
 142               [Define to support 32-bit little-endian targets])
 143 fi
 144 if test -n "$targ_32_big"; then
 145   AC_DEFINE(HAVE_TARGET_32_BIG, 1,
 146               [Define to support 32-bit big-endian targets])
 147 fi
 148 if test -n "$targ_64_little"; then
 149   AC_DEFINE(HAVE_TARGET_64_LITTLE, 1,
 150               [Define to support 64-bit little-endian targets])
 151 fi
 152 if test -n "$targ_64_big"; then
 153   AC_DEFINE(HAVE_TARGET_64_BIG, 1,
 154               [Define to support 64-bit big-endian targets])
 155 fi
 156
 157 if test -n "$all_targets"; then
 158   TARGETOBJS='$(ALL_TARGETOBJS)'
 159 else
 160   TARGETOBJS="$targetobjs"
 161 fi
 162 AC_SUBST(TARGETOBJS)
 163
 164 AC_DEFINE_UNQUOTED(GOLD_DEFAULT_MACHINE, $default_machine,
 165                    [Default machine code])
 166 AC_DEFINE_UNQUOTED(GOLD_DEFAULT_SIZE, $default_size,
 167                    [Default size (32 or 64)])
 168 AC_DEFINE_UNQUOTED(GOLD_DEFAULT_BIG_ENDIAN, $default_big_endian,
 169                    [Default big endian (true or false)])
 170
 171 AC_PROG_CC
 172 AC_PROG_CXX
 173 AC_PROG_YACC
 174 AC_PROG_RANLIB
 175 AC_PROG_INSTALL
 176 AC_PROG_LN_S
 177
 178 AC_GNU_SOURCE
 179
 180 ZW_GNU_GETTEXT_SISTER_DIR
 181 AM_PO_SUBDIRS
 182
 183 AC_C_BIGENDIAN
 184
 185 AC_EXEEXT
 186
 187 AM_CONDITIONAL(NATIVE_LINKER,
 188   test "x$target_alias" = "x" -o "x$host_alias" = "x$target_alias")
 189 AM_CONDITIONAL(GCC, test "$GCC" = yes)
 190
 191 dnl Some architectures do not support taking pointers of functions
 192 dnl defined in shared libraries except in -fPIC mode.  We need to
 193 dnl tell the unittest framework if we're compiling for one of those
 194 dnl targets, so it doesn't try to run the tests that do that.
 195 AM_CONDITIONAL(FN_PTRS_IN_SO_WITHOUT_PIC, [
 196   case $target_cpu in
 197     i?86) true;;
 198     x86_64) false;;
 199     *) true;;
 200   esac])
 201
 202 dnl Test for __thread support.
 203 AC_CACHE_CHECK([for thread support], [gold_cv_c_thread],
 204 [AC_COMPILE_IFELSE([__thread int i = 1;],
 205 [gold_cv_c_thread=yes], [gold_cv_c_thread=no])])
 206
 207 AM_CONDITIONAL(TLS, test "$gold_cv_c_thread" = "yes")
 208
 209 dnl On GNU/Linux TLS in static programs only works when using glibc
 210 dnl 2.4 or later.
 211 AC_CACHE_CHECK([for glibc >= 2.4], [gold_cv_lib_glibc24],
 212 [AC_COMPILE_IFELSE([
 213 #include <features.h>
 214 #if !defined __GLIBC__
 215 error
 216 #elif __GLIBC__ < 2 || (__GLIBC__ == 2 && __GLIBC_MINOR__ < 4)
 217 error
 218 #endif
 219 ], [gold_cv_lib_glibc24=yes], [gold_cv_lib_glibc24=no])])
 220
 221 AM_CONDITIONAL(STATIC_TLS, test "$gold_cv_lib_glibc24" = "yes")
 222
 223 dnl Test for the -ftls-dialect=gnu2 option.
 224 save_CFLAGS="$CFLAGS"
 225 CFLAGS="$CFLAGS -mtls-dialect=gnu2"
 226 AC_COMPILE_IFELSE([int i;], [have_tls_gnu2=yes], [have_tls_gnu2=no])
 227 CFLAGS="$save_CFLAGS"
 228 AM_CONDITIONAL(TLS_GNU2_DIALECT, test "$have_tls_gnu2" = "yes")
 229
 230 dnl On GNU/Linux TLS descriptors are supported by the dynamic loader
 231 dnl only with glibc 2.5 or later.
 232 AC_CACHE_CHECK([for glibc >= 2.5], [gold_cv_lib_glibc25],
 233 [AC_COMPILE_IFELSE([
 234 #include <features.h>
 235 #if !defined __GLIBC__
 236 error
 237 #elif __GLIBC__ < 2 || (__GLIBC__ == 2 && __GLIBC_MINOR__ < 5)
 238 error
 239 #endif
 240 ], [gold_cv_lib_glibc25=yes], [gold_cv_lib_glibc25=no])])
 241
 242 AM_CONDITIONAL(TLS_DESCRIPTORS, test "$gold_cv_lib_glibc25" = "yes")
 243
 244 dnl Check whether the compiler supports constructor priorities in
 245 dnl attributes, which were added in gcc 4.3.
 246 AC_CACHE_CHECK([for constructor priorities], [gold_cv_c_conprio],
 247 [AC_COMPILE_IFELSE([void f() __attribute__ ((constructor (1)));],
 248 [gold_cv_c_conprio=yes], [gold_cv_c_conprio=no])])
 249
 250 AM_CONDITIONAL(CONSTRUCTOR_PRIORITY, test "$gold_cv_c_conprio" = "yes")
 251
 252 AM_BINUTILS_WARNINGS
 253
 254 WARN_CXXFLAGS=`echo ${WARN_CFLAGS} | sed -e 's/-Wstrict-prototypes//' -e 's/-Wmissing-prototypes//'`
 255 AC_SUBST(WARN_CXXFLAGS)
 256
 257 dnl Force support for large files by default.  This may need to be
 258 dnl host dependent.  If build == host, we can check getconf LFS_CFLAGS.
 259 LFS_CFLAGS="-D_LARGEFILE_SOURCE -D_FILE_OFFSET_BITS=64"
 260 AC_SUBST(LFS_CFLAGS)
 261
 262 AC_REPLACE_FUNCS(pread)
 263
 264 # Link in zlib if we can.  This allows us to write compressed sections.
 265 AC_SEARCH_LIBS(zlibVersion, z, [AC_CHECK_HEADERS(zlib.h)])
 266 AM_CONDITIONAL(HAVE_ZLIB, test "$ac_cv_search_zlibVersion" != "no")
 267
 268 AC_LANG_PUSH(C++)
 269
 270 AC_CHECK_HEADERS(tr1/unordered_set tr1/unordered_map)
 271 AC_CHECK_HEADERS(ext/hash_map ext/hash_set)
 272 AC_CHECK_FUNCS(mallinfo)
 273
 274 # gcc 4.3.0 doesn't recognize the printf attribute on a template
 275 # function.  Check for that.  This is gcc bug 35546.  This test can
 276 # probably be removed after the bug has been fixed for a while.
 277 AC_CACHE_CHECK([whether we can use attributes with template functions],
 278 [gold_cv_template_attribute],
 279 [AC_COMPILE_IFELSE([
 280 template<typename T> extern void foo(const char*, ...)
 281   __attribute__ ((__format__ (__printf__, 1, 2)));
 282 template<typename T> void foo(const char* format, ...) {}
 283 void bar() { foo<int>("%s\n", "foo"); }
 284 ], [gold_cv_template_attribute=yes], [gold_cv_template_attribute=no])])
 285 if test "$gold_cv_template_attribute" = "yes"; then
 286   AC_DEFINE(HAVE_TEMPLATE_ATTRIBUTES, 1,
 287             [Define if attributes work on C++ templates])
 288 fi
 289
 290 AC_LANG_POP(C++)
 291
 292 AM_MAINTAINER_MODE
 293
 294 AC_OUTPUT(Makefile testsuite/Makefile po/Makefile.in:po/Make-in)