gold/configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_PREREQ(2.59)
   4
   5 AC_INIT(gold, 0.1)
   6 AC_CONFIG_SRCDIR(gold.cc)
   7
   8 AC_CANONICAL_TARGET
   9
  10 AM_INIT_AUTOMAKE
  11
  12 AM_CONFIG_HEADER(config.h:config.in)
  13
  14 AC_ARG_WITH(sysroot,
  15 [  --with-sysroot[=DIR]    search for usr/lib et al within DIR],
  16 [sysroot=$withval], [sysroot=no])
  17
  18 if test "$sysroot" = "yes"; then
  19   sysroot='${exec_prefix}/${target_alias}/sys-root'
  20 elif test "$sysroot" = "no"; then
  21   sysroot=
  22 fi
  23
  24 sysroot_relocatable=0
  25 if test -n "$sysroot"; then
  26   case "sysroot" in
  27     "${prefix}" | "${prefix}/"* | \
  28     "${exec_prefix}" | "${exec_prefix}/"* | \
  29     '${prefix}' | '${prefix}/'*| \
  30     '${exec_prefix}' | '${exec_prefix}/'*)
  31       sysroot_relocatable=1
  32       ;;
  33   esac
  34 fi
  35
  36 AC_DEFINE_UNQUOTED(TARGET_SYSTEM_ROOT, "$sysroot",
  37   [System root for target files])
  38 AC_DEFINE_UNQUOTED(TARGET_SYSTEM_ROOT_RELOCATABLE, $sysroot_relocatable,
  39   [Whether the system root can be relocated])
  40
  41 dnl For now threads are a configure time option.
  42 AC_ARG_ENABLE([threads],
  43 [  --enable-threads        multi-threaded linking],
  44 [case "${enableval}" in
  45   yes | "") threads=yes ;;
  46   no) threads=no ;;
  47   *) threads=yes ;;
  48  esac],
  49 [threads=no])
  50 if test "$threads" = "yes"; then
  51   AC_DEFINE(ENABLE_THREADS, 1,
  52             [Define to do multi-threaded linking])
  53 fi
  54 AM_CONDITIONAL(THREADS, test "$threads" = "yes")
  55
  56 AC_ARG_ENABLE([targets],
  57 [  --enable-targets        alternative target configurations],
  58 [case "${enableval}" in
  59   yes | "")
  60     AC_MSG_ERROR([--enable-targets option must specify target names or 'all'])
  61     ;;
  62   no)
  63     enable_targets=
  64     ;;
  65   *)
  66     enable_targets=$enableval
  67     ;;
  68 esac],
  69 [# For now, enable all targets by default
  70  enable_targets=all
  71 ])
  72
  73 # Canonicalize the enabled targets.
  74 if test -n "$enable_targets"; then
  75   for targ in `echo $enable_targets | sed -e 's/,/ /g'`; do
  76     result=`$ac_config_sub $targ 2>/dev/null`
  77     if test -n "$result"; then
  78       canon_targets="$canon_targets $result"
  79     else
  80       # Permit unrecognized target names, like "all".
  81       canon_targets="$canon_targets $targ"
  82     fi
  83   done
  84 fi
  85
  86 # See which specific instantiations we need.
  87 targetobjs=
  88 all_targets=
  89 default_machine=
  90 default_size=
  91 default_big_endian=
  92 targ_32_little=
  93 targ_32_big=
  94 targ_64_little=
  95 targ_64_big=
  96 for targ in $target $canon_targets; do
  97   if test "$targ" = "all"; then
  98     targ_32_little=yes
  99     targ_32_big=yes
 100     targ_64_little=yes
 101     targ_64_big=yes
 102     all_targets=yes
 103   else
 104     . ${srcdir}/configure.tgt
 105
 106     if test "$targ_obj" = "UNKNOWN"; then
 107       AC_MSG_ERROR("unsupported target $targ")
 108     else
 109       targetobjs="$targetobjs ${targ_obj}.\$(OBJEXT)"
 110       if test "$targ_size" = "32"; then
 111         if test "$targ_big_endian" = "false"; then
 112           targ_32_little=yes
 113         elif test "$targ_big_endian" = "true"; then
 114           targ_32_big=yes
 115         else
 116           AC_MSG_ERROR("bad configure.tgt endian $targ_big_endian")
 117         fi
 118       elif test "$targ_size" = "64"; then
 119         if test "$targ_big_endian" = "false"; then
 120           targ_64_little=yes
 121         elif test "$targ_big_endian" = "true"; then
 122           targ_64_big=yes
 123         else
 124           AC_MSG_ERROR("bad configure.tgt endian $targ_big_endian")
 125         fi
 126       else
 127         AC_MSG_ERROR("bad configure.tgt size $targ_size")
 128       fi
 129
 130       if test "$target" = "$targ"; then
 131         default_machine=$targ_machine
 132         default_size=$targ_size
 133         default_big_endian=$targ_big_endian
 134       fi
 135     fi
 136   fi
 137 done
 138
 139 if test -n "$targ_32_little"; then
 140   AC_DEFINE(HAVE_TARGET_32_LITTLE, 1,
 141               [Define to support 32-bit little-endian targets])
 142 fi
 143 if test -n "$targ_32_big"; then
 144   AC_DEFINE(HAVE_TARGET_32_BIG, 1,
 145               [Define to support 32-bit big-endian targets])
 146 fi
 147 if test -n "$targ_64_little"; then
 148   AC_DEFINE(HAVE_TARGET_64_LITTLE, 1,
 149               [Define to support 64-bit little-endian targets])
 150 fi
 151 if test -n "$targ_64_big"; then
 152   AC_DEFINE(HAVE_TARGET_64_BIG, 1,
 153               [Define to support 64-bit big-endian targets])
 154 fi
 155
 156 if test -n "$all_targets"; then
 157   TARGETOBJS='$(ALL_TARGETOBJS)'
 158 else
 159   TARGETOBJS="$targetobjs"
 160 fi
 161 AC_SUBST(TARGETOBJS)
 162
 163 AC_DEFINE_UNQUOTED(GOLD_DEFAULT_MACHINE, $default_machine,
 164                    [Default machine code])
 165 AC_DEFINE_UNQUOTED(GOLD_DEFAULT_SIZE, $default_size,
 166                    [Default size (32 or 64)])
 167 AC_DEFINE_UNQUOTED(GOLD_DEFAULT_BIG_ENDIAN, $default_big_endian,
 168                    [Default big endian (true or false)])
 169
 170 AC_PROG_CC
 171 AC_PROG_CXX
 172 AC_PROG_YACC
 173 AC_PROG_RANLIB
 174 AC_PROG_INSTALL
 175 AC_PROG_LN_S
 176
 177 AC_GNU_SOURCE
 178
 179 ZW_GNU_GETTEXT_SISTER_DIR
 180 AM_PO_SUBDIRS
 181
 182 AC_C_BIGENDIAN
 183
 184 AC_EXEEXT
 185
 186 AM_CONDITIONAL(NATIVE_LINKER,
 187   test "x$target_alias" = "x" -o "x$host_alias" = "x$target_alias")
 188 AM_CONDITIONAL(GCC, test "$GCC" = yes)
 189
 190 dnl Some architectures do not support taking pointers of functions
 191 dnl defined in shared libraries except in -fPIC mode.  We need to
 192 dnl tell the unittest framework if we're compiling for one of those
 193 dnl targets, so it doesn't try to run the tests that do that.
 194 AM_CONDITIONAL(FN_PTRS_IN_SO_WITHOUT_PIC, [
 195   case $target_cpu in
 196     i?86) true;;
 197     x86_64) false;;
 198     *) true;;
 199   esac])
 200
 201 dnl Test for __thread support.
 202 AC_CACHE_CHECK([for thread support], [gold_cv_c_thread],
 203 [AC_COMPILE_IFELSE([__thread int i = 1;],
 204 [gold_cv_c_thread=yes], [gold_cv_c_thread=no])])
 205
 206 AM_CONDITIONAL(TLS, test "$gold_cv_c_thread" = "yes")
 207
 208 dnl On GNU/Linux TLS in static programs only works when using glibc
 209 dnl 2.4 or later.
 210 AC_CACHE_CHECK([for glibc >= 2.4], [gold_cv_lib_glibc24],
 211 [AC_COMPILE_IFELSE([
 212 #include <features.h>
 213 #if !defined __GLIBC__
 214 error
 215 #elif __GLIBC__ < 2 || (__GLIBC__ == 2 && __GLIBC_MINOR__ < 4)
 216 error
 217 #endif
 218 ], [gold_cv_lib_glibc24=yes], [gold_cv_lib_glibc24=no])])
 219
 220 AM_CONDITIONAL(STATIC_TLS, test "$gold_cv_lib_glibc24" = "yes")
 221
 222 dnl Test for the -ftls-dialect=gnu2 option.
 223 save_CFLAGS="$CFLAGS"
 224 CFLAGS="$CFLAGS -mtls-dialect=gnu2"
 225 AC_COMPILE_IFELSE([int i;], [have_tls_gnu2=yes], [have_tls_gnu2=no])
 226 CFLAGS="$save_CFLAGS"
 227 AM_CONDITIONAL(TLS_GNU2_DIALECT, test "$have_tls_gnu2" = "yes")
 228
 229 dnl On GNU/Linux TLS descriptors are supported by the dynamic loader
 230 dnl only with glibc 2.5 or later.
 231 AC_CACHE_CHECK([for glibc >= 2.5], [gold_cv_lib_glibc25],
 232 [AC_COMPILE_IFELSE([
 233 #include <features.h>
 234 #if !defined __GLIBC__
 235 error
 236 #elif __GLIBC__ < 2 || (__GLIBC__ == 2 && __GLIBC_MINOR__ < 5)
 237 error
 238 #endif
 239 ], [gold_cv_lib_glibc25=yes], [gold_cv_lib_glibc25=no])])
 240
 241 AM_CONDITIONAL(TLS_DESCRIPTORS, test "$gold_cv_lib_glibc25" = "yes")
 242
 243 dnl Check whether the compiler supports constructor priorities in
 244 dnl attributes, which were added in gcc 4.3.
 245 AC_CACHE_CHECK([for constructor priorities], [gold_cv_c_conprio],
 246 [AC_COMPILE_IFELSE([void f() __attribute__ ((constructor (1)));],
 247 [gold_cv_c_conprio=yes], [gold_cv_c_conprio=no])])
 248
 249 AM_CONDITIONAL(CONSTRUCTOR_PRIORITY, test "$gold_cv_c_conprio" = "yes")
 250
 251 AM_BINUTILS_WARNINGS
 252
 253 WARN_CXXFLAGS=`echo ${WARN_CFLAGS} | sed -e 's/-Wstrict-prototypes//' -e 's/-Wmissing-prototypes//'`
 254 AC_SUBST(WARN_CXXFLAGS)
 255
 256 dnl Force support for large files by default.  This may need to be
 257 dnl host dependent.  If build == host, we can check getconf LFS_CFLAGS.
 258 LFS_CFLAGS="-D_LARGEFILE_SOURCE -D_FILE_OFFSET_BITS=64"
 259 AC_SUBST(LFS_CFLAGS)
 260
 261 AC_REPLACE_FUNCS(pread)
 262
 263 # Link in zlib if we can.  This allows us to write compressed sections.
 264 AC_SEARCH_LIBS(zlibVersion, z, [AC_CHECK_HEADERS(zlib.h)])
 265 AM_CONDITIONAL(HAVE_ZLIB, test "$ac_cv_search_zlibVersion" != "no")
 266
 267 AC_LANG_PUSH(C++)
 268
 269 AC_CHECK_HEADERS(tr1/unordered_set tr1/unordered_map)
 270 AC_CHECK_HEADERS(ext/hash_map ext/hash_set)
 271 AC_CHECK_FUNCS(mallinfo)
 272
 273 # gcc 4.3.0 doesn't recognize the printf attribute on a template
 274 # function.  Check for that.  This is gcc bug 35546.  This test can
 275 # probably be removed after the bug has been fixed for a while.
 276 AC_CACHE_CHECK([whether we can use attributes with template functions],
 277 [gold_cv_template_attribute],
 278 [AC_COMPILE_IFELSE([
 279 template<typename T> extern void foo(const char*, ...)
 280   __attribute__ ((__format__ (__printf__, 1, 2)));
 281 template<typename T> void foo(const char* format, ...) {}
 282 void bar() { foo<int>("%s\n", "foo"); }
 283 ], [gold_cv_template_attribute=yes], [gold_cv_template_attribute=no])])
 284 if test "$gold_cv_template_attribute" = "yes"; then
 285   AC_DEFINE(HAVE_TEMPLATE_ATTRIBUTES, 1,
 286             [Define if attributes work on C++ templates])
 287 fi
 288
 289 AC_LANG_POP(C++)
 290
 291 AM_MAINTAINER_MODE
 292
 293 AC_OUTPUT(Makefile testsuite/Makefile po/Makefile.in:po/Make-in)