gnulib_m4/wctype_h.m4

   1 # wctype_h.m4 serial 21
   2
   3 dnl A placeholder for ISO C99 <wctype.h>, for platforms that lack it.
   4
   5 dnl Copyright (C) 2006-2018 Free Software Foundation, Inc.
   6 dnl This file is free software; the Free Software Foundation
   7 dnl gives unlimited permission to copy and/or distribute it,
   8 dnl with or without modifications, as long as this notice is preserved.
   9
  10 dnl Written by Paul Eggert.
  11
  12 AC_DEFUN([gl_WCTYPE_H],
  13 [
  14   AC_REQUIRE([gl_WCTYPE_H_DEFAULTS])
  15   AC_REQUIRE([AC_PROG_CC])
  16   AC_REQUIRE([AC_CANONICAL_HOST])
  17   AC_CHECK_FUNCS_ONCE([iswcntrl])
  18   if test $ac_cv_func_iswcntrl = yes; then
  19     HAVE_ISWCNTRL=1
  20   else
  21     HAVE_ISWCNTRL=0
  22   fi
  23   AC_SUBST([HAVE_ISWCNTRL])
  24
  25   AC_REQUIRE([gt_TYPE_WINT_T])
  26   if test $gt_cv_c_wint_t = yes; then
  27     HAVE_WINT_T=1
  28   else
  29     HAVE_WINT_T=0
  30   fi
  31   AC_SUBST([HAVE_WINT_T])
  32
  33   AC_REQUIRE([gl_TYPE_WINT_T_PREREQ])
  34
  35   gl_CHECK_NEXT_HEADERS([wctype.h])
  36   if test $ac_cv_header_wctype_h = yes; then
  37     if test $ac_cv_func_iswcntrl = yes; then
  38       dnl Linux libc5 has an iswprint function that returns 0 for all arguments.
  39       dnl The other functions are likely broken in the same way.
  40       AC_CACHE_CHECK([whether iswcntrl works], [gl_cv_func_iswcntrl_works],
  41         [
  42           AC_RUN_IFELSE(
  43             [AC_LANG_SOURCE([[
  44                /* Tru64 with Desktop Toolkit C has a bug: <stdio.h> must be
  45                   included before <wchar.h>.
  46                   BSD/OS 4.0.1 has a bug: <stddef.h>, <stdio.h> and <time.h>
  47                   must be included before <wchar.h>.  */
  48                #include <stddef.h>
  49                #include <stdio.h>
  50                #include <time.h>
  51                #include <wchar.h>
  52                #include <wctype.h>
  53                int main () { return iswprint ('x') == 0; }
  54             ]])],
  55             [gl_cv_func_iswcntrl_works=yes], [gl_cv_func_iswcntrl_works=no],
  56             [dnl Guess no on Linux libc5, yes otherwise.
  57              AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <stdlib.h>
  58                           #if __GNU_LIBRARY__ == 1
  59                           Linux libc5 i18n is broken.
  60                           #endif]], [])],
  61               [gl_cv_func_iswcntrl_works="guessing yes"],
  62               [gl_cv_func_iswcntrl_works="guessing no"])
  63             ])
  64         ])
  65     fi
  66     HAVE_WCTYPE_H=1
  67   else
  68     HAVE_WCTYPE_H=0
  69   fi
  70   AC_SUBST([HAVE_WCTYPE_H])
  71
  72   case "$gl_cv_func_iswcntrl_works" in
  73     *yes) REPLACE_ISWCNTRL=0 ;;
  74     *)    REPLACE_ISWCNTRL=1 ;;
  75   esac
  76   AC_SUBST([REPLACE_ISWCNTRL])
  77
  78   if test $HAVE_ISWCNTRL = 0 || test $REPLACE_ISWCNTRL = 1; then
  79     dnl Redefine all of iswcntrl, ..., iswxdigit in <wctype.h>.
  80     :
  81   fi
  82
  83   if test $REPLACE_ISWCNTRL = 1; then
  84     REPLACE_TOWLOWER=1
  85   else
  86     AC_CHECK_FUNCS([towlower])
  87     if test $ac_cv_func_towlower = yes; then
  88       REPLACE_TOWLOWER=0
  89     else
  90       AC_CHECK_DECLS([towlower],,,
  91         [[/* Tru64 with Desktop Toolkit C has a bug: <stdio.h> must be
  92              included before <wchar.h>.
  93              BSD/OS 4.0.1 has a bug: <stddef.h>, <stdio.h> and <time.h>
  94              must be included before <wchar.h>.  */
  95           #include <stddef.h>
  96           #include <stdio.h>
  97           #include <time.h>
  98           #include <wchar.h>
  99           #if HAVE_WCTYPE_H
 100           # include <wctype.h>
 101           #endif
 102         ]])
 103       if test $ac_cv_have_decl_towlower = yes; then
 104         dnl On Minix 3.1.8, the system's <wctype.h> declares towlower() and
 105         dnl towupper() although it does not have the functions. Avoid a
 106         dnl collision with gnulib's replacement.
 107         REPLACE_TOWLOWER=1
 108       else
 109         REPLACE_TOWLOWER=0
 110       fi
 111     fi
 112   fi
 113   AC_SUBST([REPLACE_TOWLOWER])
 114
 115   if test $HAVE_ISWCNTRL = 0 || test $REPLACE_TOWLOWER = 1; then
 116     dnl Redefine towlower, towupper in <wctype.h>.
 117     :
 118   fi
 119
 120   dnl We assume that the wctype() and iswctype() functions exist if and only
 121   dnl if the type wctype_t is defined in <wchar.h> or in <wctype.h> if that
 122   dnl exists.
 123   dnl HP-UX 11.00 declares all these in <wchar.h> and lacks <wctype.h>.
 124   AC_CACHE_CHECK([for wctype_t], [gl_cv_type_wctype_t],
 125     [AC_COMPILE_IFELSE(
 126        [AC_LANG_PROGRAM(
 127           [[/* Tru64 with Desktop Toolkit C has a bug: <stdio.h> must be
 128                included before <wchar.h>.
 129                BSD/OS 4.0.1 has a bug: <stddef.h>, <stdio.h> and <time.h>
 130                must be included before <wchar.h>.  */
 131             #include <stddef.h>
 132             #include <stdio.h>
 133             #include <time.h>
 134             #include <wchar.h>
 135             #if HAVE_WCTYPE_H
 136             # include <wctype.h>
 137             #endif
 138             wctype_t a;
 139           ]],
 140           [[]])],
 141        [gl_cv_type_wctype_t=yes],
 142        [gl_cv_type_wctype_t=no])
 143     ])
 144   if test $gl_cv_type_wctype_t = no; then
 145     HAVE_WCTYPE_T=0
 146   fi
 147
 148   dnl We assume that the wctrans() and towctrans() functions exist if and only
 149   dnl if the type wctrans_t is defined in <wctype.h>.
 150   AC_CACHE_CHECK([for wctrans_t], [gl_cv_type_wctrans_t],
 151     [AC_COMPILE_IFELSE(
 152        [AC_LANG_PROGRAM(
 153           [[/* Tru64 with Desktop Toolkit C has a bug: <stdio.h> must be
 154                included before <wchar.h>.
 155                BSD/OS 4.0.1 has a bug: <stddef.h>, <stdio.h> and <time.h>
 156                must be included before <wchar.h>.  */
 157             #include <stddef.h>
 158             #include <stdio.h>
 159             #include <time.h>
 160             #include <wchar.h>
 161             #include <wctype.h>
 162             wctrans_t a;
 163           ]],
 164           [[]])],
 165        [gl_cv_type_wctrans_t=yes],
 166        [gl_cv_type_wctrans_t=no])
 167     ])
 168   if test $gl_cv_type_wctrans_t = no; then
 169     HAVE_WCTRANS_T=0
 170   fi
 171
 172   dnl Check for declarations of anything we want to poison if the
 173   dnl corresponding gnulib module is not in use.
 174   gl_WARN_ON_USE_PREPARE([[
 175 /* Tru64 with Desktop Toolkit C has a bug: <stdio.h> must be included before
 176    <wchar.h>.
 177    BSD/OS 4.0.1 has a bug: <stddef.h>, <stdio.h> and <time.h> must be
 178    included before <wchar.h>.  */
 179 #if !(defined __GLIBC__ && !defined __UCLIBC__)
 180 # include <stddef.h>
 181 # include <stdio.h>
 182 # include <time.h>
 183 # include <wchar.h>
 184 #endif
 185 #include <wctype.h>
 186     ]],
 187     [wctype iswctype wctrans towctrans
 188     ])
 189 ])
 190
 191 AC_DEFUN([gl_WCTYPE_MODULE_INDICATOR],
 192 [
 193   dnl Use AC_REQUIRE here, so that the default settings are expanded once only.
 194   AC_REQUIRE([gl_WCTYPE_H_DEFAULTS])
 195   gl_MODULE_INDICATOR_SET_VARIABLE([$1])
 196   dnl Define it also as a C macro, for the benefit of the unit tests.
 197   gl_MODULE_INDICATOR_FOR_TESTS([$1])
 198 ])
 199
 200 AC_DEFUN([gl_WCTYPE_H_DEFAULTS],
 201 [
 202   GNULIB_ISWBLANK=0;    AC_SUBST([GNULIB_ISWBLANK])
 203   GNULIB_WCTYPE=0;      AC_SUBST([GNULIB_WCTYPE])
 204   GNULIB_ISWCTYPE=0;    AC_SUBST([GNULIB_ISWCTYPE])
 205   GNULIB_WCTRANS=0;     AC_SUBST([GNULIB_WCTRANS])
 206   GNULIB_TOWCTRANS=0;   AC_SUBST([GNULIB_TOWCTRANS])
 207   dnl Assume proper GNU behavior unless another module says otherwise.
 208   HAVE_ISWBLANK=1;      AC_SUBST([HAVE_ISWBLANK])
 209   HAVE_WCTYPE_T=1;      AC_SUBST([HAVE_WCTYPE_T])
 210   HAVE_WCTRANS_T=1;     AC_SUBST([HAVE_WCTRANS_T])
 211   REPLACE_ISWBLANK=0;   AC_SUBST([REPLACE_ISWBLANK])
 212 ])