giscanner/scannerlexer.l

   1 /* -*- Mode: C -*-
   2 /* GObject introspection: C lexer
   3  *
   4  * Copyright (c) 1997 Sandro Sigala  <ssigala@globalnet.it>
   5  * Copyright (c) 2007-2008 Jürg Billeter  <j@bitron.ch>
   6  *
   7  * All rights reserved.
   8  *
   9  * Redistribution and use in source and binary forms, with or without
  10  * modification, are permitted provided that the following conditions
  11  * are met:
  12  * 1. Redistributions of source code must retain the above copyright
  13  *    notice, this list of conditions and the following disclaimer.
  14  * 2. Redistributions in binary form must reproduce the above copyright
  15  *    notice, this list of conditions and the following disclaimer in the
  16  *    documentation and/or other materials provided with the distribution.
  17  *
  18  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
  19  * IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
  20  * OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
  21  * IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
  22  * INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
  23  * NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  24  * DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  25  * THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  26  * (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
  27  * THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  28  */
  29
  30 %{
  31 #include <ctype.h>
  32 #include <stdio.h>
  33
  34 #include <glib.h>
  35 #include "sourcescanner.h"
  36 #include "scannerparser.h"
  37 #include "grealpath.h"
  38
  39 int lineno;
  40
  41 extern int yylex (GISourceScanner *scanner);
  42 #define YY_DECL int yylex (GISourceScanner *scanner)
  43 static int yywrap (void);
  44 static void parse_comment (GISourceScanner *scanner);
  45 static void process_directive (GISourceScanner *scanner);
  46 static int check_identifier (GISourceScanner *scanner, const char *);
  47 static int parse_ignored_macro (void);
  48 %}
  49
  50 intsuffix                               ([uU][lL]?[lL]?)|([lL][lL]?[uU]?)
  51 fracconst                               ([0-9]*\.[0-9]+)|([0-9]+\.)
  52 exppart                                 [eE][-+]?[0-9]+
  53 floatsuffix                             [fFlL]
  54 chartext                                ([^\'])|(\\.)
  55 stringtext                              ([^\"])|(\\.)
  56
  57 %%
  58
  59 "\n"                                    { ++lineno; } /* " */
  60 [\t\f\v\r ]+                            { /* Ignore whitespace. */ }
  61
  62 "/*"                                    { parse_comment(scanner); }
  63 "//".*                                  { }
  64
  65 "#define "[a-zA-Z_][a-zA-Z_0-9]*"("     { yyless (yyleng - 1); return FUNCTION_MACRO; }
  66 "#define "[a-zA-Z_][a-zA-Z_0-9]*        { return OBJECT_MACRO; }
  67
  68 "#"                                     { process_directive(scanner); }
  69
  70 "{"                                     { return '{'; }
  71 "<%"                                    { return '{'; }
  72 "}"                                     { return '}'; }
  73 "%>"                                    { return '}'; }
  74 "["                                     { return '['; }
  75 "<:"                                    { return '['; }
  76 "]"                                     { return ']'; }
  77 ":>"                                    { return ']'; }
  78 "("                                     { return '('; }
  79 ")"                                     { return ')'; }
  80 ";"                                     { return ';'; }
  81 ":"                                     { return ':'; }
  82 "..."                                   { return ELLIPSIS; }
  83 "?"                                     { return '?'; }
  84 "."                                     { return '.'; }
  85 "+"                                     { return '+'; }
  86 "-"                                     { return '-'; }
  87 "*"                                     { return '*'; }
  88 "/"                                     { return '/'; }
  89 "%"                                     { return '%'; }
  90 "^"                                     { return '^'; }
  91 "&"                                     { return '&'; }
  92 "|"                                     { return '|'; }
  93 "~"                                     { return '~'; }
  94 "!"                                     { return '!'; }
  95 "="                                     { return '='; }
  96 "<"                                     { return '<'; }
  97 ">"                                     { return '>'; }
  98 "+="                                    { return ADDEQ; }
  99 "-="                                    { return SUBEQ; }
 100 "*="                                    { return MULEQ; }
 101 "/="                                    { return DIVEQ; }
 102 "%="                                    { return MODEQ; }
 103 "^="                                    { return XOREQ; }
 104 "&="                                    { return ANDEQ; }
 105 "|="                                    { return OREQ; }
 106 "<<"                                    { return SL; }
 107 ">>"                                    { return SR; }
 108 "<<="                                   { return SLEQ; }
 109 ">>="                                   { return SREQ; }
 110 "=="                                    { return EQ; }
 111 "!="                                    { return NOTEQ; }
 112 "<="                                    { return LTEQ; }
 113 ">="                                    { return GTEQ; }
 114 "&&"                                    { return ANDAND; }
 115 "||"                                    { return OROR; }
 116 "++"                                    { return PLUSPLUS; }
 117 "--"                                    { return MINUSMINUS; }
 118 ","                                     { return ','; }
 119 "->"                                    { return ARROW; }
 120
 121 "__attribute__"                         { if (!parse_ignored_macro()) REJECT; }
 122 "__const"                               { return CONST; }
 123 "__extension__"                         { return EXTENSION; }
 124 "__inline"                              { return INLINE; }
 125 "__nonnull"                             { if (!parse_ignored_macro()) REJECT; }
 126 "__restrict"                            { return RESTRICT; }
 127
 128 [a-zA-Z_][a-zA-Z_0-9]*                  { if (scanner->macro_scan) return IDENTIFIER; else REJECT; }
 129
 130 "asm"                                   { if (!parse_ignored_macro()) REJECT; }
 131 "__asm__"                               { if (!parse_ignored_macro()) REJECT; }
 132 "auto"                                  { return AUTO; }
 133 "_Bool"                                 { return BOOL; }
 134 "break"                                 { return BREAK; }
 135 "case"                                  { return CASE; }
 136 "char"                                  { return CHAR; }
 137 "const"                                 { return CONST; }
 138 "continue"                              { return CONTINUE; }
 139 "default"                               { return DEFAULT; }
 140 "do"                                    { return DO; }
 141 "double"                                { return DOUBLE; }
 142 "else"                                  { return ELSE; }
 143 "enum"                                  { return ENUM; }
 144 "extern"                                { return EXTERN; }
 145 "float"                                 { return FLOAT; }
 146 "for"                                   { return FOR; }
 147 "goto"                                  { return GOTO; }
 148 "if"                                    { return IF; }
 149 "inline"                                { return INLINE; }
 150 "__inline__"                            { return INLINE; }
 151 "int"                                   { return INT; }
 152 "long"                                  { return LONG; }
 153 "register"                              { return REGISTER; }
 154 "restrict"                              { return RESTRICT; }
 155 "return"                                { return RETURN; }
 156 "short"                                 { return SHORT; }
 157 "signed"                                { return SIGNED; }
 158 "sizeof"                                { return SIZEOF; }
 159 "static"                                { return STATIC; }
 160 "struct"                                { return STRUCT; }
 161 "switch"                                { return SWITCH; }
 162 "typedef"                               { return TYPEDEF; }
 163 "union"                                 { return UNION; }
 164 "unsigned"                              { return UNSIGNED; }
 165 "void"                                  { return VOID; }
 166 "volatile"                              { return VOLATILE; }
 167 "while"                                 { return WHILE; }
 168
 169 [a-zA-Z_][a-zA-Z_0-9]*                  { return check_identifier(scanner, yytext); }
 170
 171 "0"[xX][0-9a-fA-F]+{intsuffix}?         { return INTEGER; }
 172 "0"[0-7]+{intsuffix}?                   { return INTEGER; }
 173 [0-9]+{intsuffix}?                      { return INTEGER; }
 174
 175 {fracconst}{exppart}?{floatsuffix}?     { return FLOATING; }
 176 [0-9]+{exppart}{floatsuffix}?           { return FLOATING; }
 177
 178 "'"{chartext}*"'"                       { return CHARACTER; }
 179 "L'"{chartext}*"'"                      { return CHARACTER; }
 180
 181 "\""{stringtext}*"\""                   { return STRING; }
 182 "L\""{stringtext}*"\""                  { return STRING; }
 183
 184 .                                       { fprintf(stderr, "%s:%d: unexpected character `%c'\n", scanner->current_filename, lineno, yytext[0]); }
 185
 186 %%
 187
 188 static int
 189 yywrap (void)
 190 {
 191   return 1;
 192 }
 193
 194
 195 static void
 196 parse_gtkdoc (GISourceScanner *scanner,
 197               gchar           *symbol,
 198               int             *c1,
 199               int             *c2)
 200 {
 201   gboolean isline = FALSE;
 202   gchar line[256];
 203   int i;
 204   gchar **parts;
 205   GISourceDirective *directive;
 206   char *name,*value;
 207   GSList *directives;
 208   GSList *options = NULL;
 209   char *rname;
 210
 211   i = 0;
 212   do
 213     {
 214       *c1 = *c2;
 215       if (*c1 == '\n')
 216         {
 217           isline = TRUE;
 218           break;
 219         }
 220       if (i >= 256)
 221         break;
 222       line[i++] = *c1;
 223       *c2 = input();
 224     } while (*c2 != EOF && !(*c1 == '*' && *c2 == '/'));
 225
 226   if (!isline)
 227     return;
 228
 229   line[i] = '\0';
 230
 231   parts = g_strsplit (line, ": ", 3);
 232
 233   if (g_strv_length (parts) >= 2)
 234     {
 235       name = parts[0];
 236
 237       if (g_strv_length (parts) == 3)
 238         {
 239           char *ptr = parts[1];
 240           GString *current = NULL;
 241           gint8 pstack = 0;
 242
 243           current = g_string_new ("");
 244           value = parts[2];
 245
 246           do
 247             {
 248               if (*ptr == '(')
 249                 {
 250                   pstack++;
 251                   if (pstack == 1)
 252                     continue;
 253                 }
 254               else if (*ptr == ')')
 255                 pstack--;
 256
 257               if (pstack == 0)
 258                 {
 259                   options = g_slist_prepend (options, current->str);
 260                   break;
 261                 }
 262               g_string_append_c (current, *ptr);
 263             }
 264           while (*ptr++);
 265
 266           g_string_free (current, FALSE);
 267         }
 268       else
 269         value = parts[1];
 270     }
 271   else /* parts == 1 */
 272     {
 273       name = parts[0];
 274       value = NULL;
 275     }
 276
 277   /*
 278    * This is a special case for return values, name will only be
 279    * 'eturn' or a valid name, check the call site.
 280    * Context-sensitive parsing would probably be the right way to go
 281    */
 282   if (g_ascii_strncasecmp ("eturn", name, 5) == 0)
 283     rname = "return";
 284   else
 285     rname = name;
 286
 287   directive = gi_source_directive_new (rname, value, options);
 288   directives = g_hash_table_lookup (scanner->directives_map, symbol);
 289   directives = g_slist_prepend (directives, directive);
 290   g_hash_table_replace (scanner->directives_map,
 291                         g_strdup (symbol), directives);
 292
 293   g_strfreev (parts);
 294
 295 }
 296
 297
 298 static void
 299 parse_comment (GISourceScanner *scanner)
 300 {
 301   GString *symbol = NULL;
 302   gboolean startofline = FALSE, have_symbol = FALSE, start1 = FALSE, start_symbol = FALSE;
 303   int c1, c2;
 304
 305   c1 = input();
 306   c2 = input();
 307
 308   while (c2 != EOF && !(c1 == '*' && c2 == '/'))
 309     {
 310       if (c1 == ':')
 311         have_symbol = TRUE;
 312       else if (c1 == '\n')
 313          start1 = TRUE;
 314       else if (c1 == '*' && start1)
 315          start_symbol = TRUE;
 316       else if (!have_symbol && start_symbol)
 317         {
 318           if (!symbol)
 319             symbol = g_string_new ("");
 320           if (c1 != ' ')
 321             g_string_append_c (symbol, c1);
 322         }
 323
 324       if (c1 == '\n')
 325         {
 326           ++lineno;
 327           startofline = TRUE;
 328         }
 329
 330       c1 = c2;
 331       c2 = input();
 332
 333       if ((c1 != '*' && c1 != ' '))
 334           startofline = FALSE;
 335
 336       if (startofline && (c1 == ' ') && (c2 == '@' || (c2 == 'r') || (c2 == 'R')))
 337         {
 338            c1 = c2;
 339            c2 = input();
 340            if (symbol)
 341              parse_gtkdoc (scanner, symbol->str, &c1, &c2);
 342         }
 343     }
 344
 345   if (symbol)
 346     g_string_free (symbol, TRUE);
 347
 348 }
 349
 350 static int
 351 check_identifier (GISourceScanner *scanner,
 352                   const char  *s)
 353 {
 354         /*
 355          * This function checks if `s' is a type name or an
 356          * identifier.
 357          */
 358
 359         if (gi_source_scanner_is_typedef (scanner, s)) {
 360                 return TYPEDEF_NAME;
 361         } else if (strcmp (s, "__builtin_va_list") == 0) {
 362                 return TYPEDEF_NAME;
 363         }
 364
 365         return IDENTIFIER;
 366 }
 367
 368 static void
 369 process_directive (GISourceScanner *scanner)
 370 {
 371         /* extract current filename from #line directives */
 372         GString *filename_builder;
 373         gboolean in_string, found_filename;
 374
 375         lineno = 0;
 376         found_filename = FALSE;
 377         in_string = FALSE;
 378         filename_builder = g_string_new ("");
 379
 380         int c = input ();
 381         while (c != EOF && c != '\n') {
 382                 if (!in_string) {
 383                         if (c == '\"') {
 384                                 in_string = TRUE;
 385                                 found_filename = TRUE;
 386                         } else if (c >= '0' && c <= '9') {
 387                                 if (!found_filename) {
 388                                         lineno = lineno * 10 + (c - '0');
 389                                 }
 390                         }
 391                 } else {
 392                         if (c == '\"') {
 393                                 in_string = FALSE;
 394                         } else if (c == '\\') {
 395                                 g_string_append_c (filename_builder, c);
 396                                 c = input ();
 397                                 g_string_append_c (filename_builder, c);
 398                         } else {
 399                                 g_string_append_c (filename_builder, c);
 400                         }
 401                 }
 402                 c = input ();
 403         }
 404
 405         if (filename_builder->len > 0) {
 406                 char *filename = g_strcompress (filename_builder->str);
 407                 if (g_realpath (filename))
 408                   {
 409                     g_free (scanner->current_filename);
 410                     scanner->current_filename = g_realpath (filename);
 411                     g_assert (scanner->current_filename);
 412                     g_free(filename);
 413                   }
 414         }
 415
 416         g_string_free (filename_builder, TRUE);
 417 }
 418
 419 /*
 420  * This parses a macro which is ignored, such as
 421  * __attribute__((x)) or __asm__ (x)
 422  */
 423 static int
 424 parse_ignored_macro (void)
 425 {
 426         int c;
 427         int nest;
 428
 429         while ((c = input ()) != EOF && isspace (c))
 430                 ;
 431         if (c != '(')
 432                 return FALSE;
 433
 434         nest = 0;
 435         while ((c = input ()) != EOF && (nest > 0 || c != ')')) {
 436                 if (c == '(')
 437                         nest++;
 438                 else if (c == ')')
 439                         nest--;
 440                 else if (c == '"') {
 441                         while ((c = input ()) != EOF && c != '"') {
 442                                 if (c == '\\')
 443                                         c = input ();
 444                         }
 445                 } else if (c == '\'') {
 446                         c = input ();
 447                         if (c == '\\')
 448                                 c = input ();
 449                         else if (c == '\'')
 450                                 return FALSE;
 451                         c = input ();
 452                         if (c != '\'')
 453                                 return FALSE;
 454                 } else if (c == '\n')
 455                         lineno++;
 456         }
 457
 458         return TRUE;
 459 }