gettext-tools/gnulib-m4/extensions.m4

   1 # serial 13  -*- Autoconf -*-
   2 # Enable extensions on systems that normally disable them.
   3
   4 # Copyright (C) 2003, 2006-2013 Free Software Foundation, Inc.
   5 # This file is free software; the Free Software Foundation
   6 # gives unlimited permission to copy and/or distribute it,
   7 # with or without modifications, as long as this notice is preserved.
   8
   9 # This definition of AC_USE_SYSTEM_EXTENSIONS is stolen from git
  10 # Autoconf.  Perhaps we can remove this once we can assume Autoconf
  11 # 2.70 or later everywhere, but since Autoconf mutates rapidly
  12 # enough in this area it's likely we'll need to redefine
  13 # AC_USE_SYSTEM_EXTENSIONS for quite some time.
  14
  15 # If autoconf reports a warning
  16 #     warning: AC_COMPILE_IFELSE was called before AC_USE_SYSTEM_EXTENSIONS
  17 # or  warning: AC_RUN_IFELSE was called before AC_USE_SYSTEM_EXTENSIONS
  18 # the fix is
  19 #   1) to ensure that AC_USE_SYSTEM_EXTENSIONS is never directly invoked
  20 #      but always AC_REQUIREd,
  21 #   2) to ensure that for each occurrence of
  22 #        AC_REQUIRE([AC_USE_SYSTEM_EXTENSIONS])
  23 #      or
  24 #        AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  25 #      the corresponding gnulib module description has 'extensions' among
  26 #      its dependencies. This will ensure that the gl_USE_SYSTEM_EXTENSIONS
  27 #      invocation occurs in gl_EARLY, not in gl_INIT.
  28
  29 # AC_USE_SYSTEM_EXTENSIONS
  30 # ------------------------
  31 # Enable extensions on systems that normally disable them,
  32 # typically due to standards-conformance issues.
  33 #
  34 # Remember that #undef in AH_VERBATIM gets replaced with #define by
  35 # AC_DEFINE.  The goal here is to define all known feature-enabling
  36 # macros, then, if reports of conflicts are made, disable macros that
  37 # cause problems on some platforms (such as __EXTENSIONS__).
  38 AC_DEFUN_ONCE([AC_USE_SYSTEM_EXTENSIONS],
  39 [AC_BEFORE([$0], [AC_COMPILE_IFELSE])dnl
  40 AC_BEFORE([$0], [AC_RUN_IFELSE])dnl
  41
  42   AC_CHECK_HEADER([minix/config.h], [MINIX=yes], [MINIX=])
  43   if test "$MINIX" = yes; then
  44     AC_DEFINE([_POSIX_SOURCE], [1],
  45       [Define to 1 if you need to in order for 'stat' and other
  46        things to work.])
  47     AC_DEFINE([_POSIX_1_SOURCE], [2],
  48       [Define to 2 if the system does not provide POSIX.1 features
  49        except with this defined.])
  50     AC_DEFINE([_MINIX], [1],
  51       [Define to 1 if on MINIX.])
  52     AC_DEFINE([_NETBSD_SOURCE], [1],
  53       [Define to 1 to make NetBSD features available.  MINIX 3 needs this.])
  54   fi
  55
  56 dnl Use a different key than __EXTENSIONS__, as that name broke existing
  57 dnl configure.ac when using autoheader 2.62.
  58   AH_VERBATIM([USE_SYSTEM_EXTENSIONS],
  59 [/* Enable extensions on AIX 3, Interix.  */
  60 #ifndef _ALL_SOURCE
  61 # undef _ALL_SOURCE
  62 #endif
  63 /* Enable general extensions on OS X.  */
  64 #ifndef _DARWIN_C_SOURCE
  65 # undef _DARWIN_C_SOURCE
  66 #endif
  67 /* Enable GNU extensions on systems that have them.  */
  68 #ifndef _GNU_SOURCE
  69 # undef _GNU_SOURCE
  70 #endif
  71 /* Enable threading extensions on Solaris.  */
  72 #ifndef _POSIX_PTHREAD_SEMANTICS
  73 # undef _POSIX_PTHREAD_SEMANTICS
  74 #endif
  75 /* Enable extensions on HP NonStop.  */
  76 #ifndef _TANDEM_SOURCE
  77 # undef _TANDEM_SOURCE
  78 #endif
  79 /* Enable X/Open extensions if necessary.  HP-UX 11.11 defines
  80    mbstate_t only if _XOPEN_SOURCE is defined to 500, regardless of
  81    whether compiling with -Ae or -D_HPUX_SOURCE=1.  */
  82 #ifndef _XOPEN_SOURCE
  83 # undef _XOPEN_SOURCE
  84 #endif
  85 /* Enable general extensions on Solaris.  */
  86 #ifndef __EXTENSIONS__
  87 # undef __EXTENSIONS__
  88 #endif
  89 ])
  90   AC_CACHE_CHECK([whether it is safe to define __EXTENSIONS__],
  91     [ac_cv_safe_to_define___extensions__],
  92     [AC_COMPILE_IFELSE(
  93        [AC_LANG_PROGRAM([[
  94 #         define __EXTENSIONS__ 1
  95           ]AC_INCLUDES_DEFAULT])],
  96        [ac_cv_safe_to_define___extensions__=yes],
  97        [ac_cv_safe_to_define___extensions__=no])])
  98   test $ac_cv_safe_to_define___extensions__ = yes &&
  99     AC_DEFINE([__EXTENSIONS__])
 100   AC_DEFINE([_ALL_SOURCE])
 101   AC_DEFINE([_DARWIN_C_SOURCE])
 102   AC_DEFINE([_GNU_SOURCE])
 103   AC_DEFINE([_POSIX_PTHREAD_SEMANTICS])
 104   AC_DEFINE([_TANDEM_SOURCE])
 105   AC_CACHE_CHECK([whether _XOPEN_SOURCE should be defined],
 106     [ac_cv_should_define__xopen_source],
 107     [ac_cv_should_define__xopen_source=no
 108      AC_COMPILE_IFELSE(
 109        [AC_LANG_PROGRAM([[
 110           #include <wchar.h>
 111           mbstate_t x;]])],
 112        [],
 113        [AC_COMPILE_IFELSE(
 114           [AC_LANG_PROGRAM([[
 115              #define _XOPEN_SOURCE 500
 116              #include <wchar.h>
 117              mbstate_t x;]])],
 118           [ac_cv_should_define__xopen_source=yes])])])
 119   test $ac_cv_should_define__xopen_source = yes &&
 120     AC_DEFINE([_XOPEN_SOURCE], [500])
 121 ])# AC_USE_SYSTEM_EXTENSIONS
 122
 123 # gl_USE_SYSTEM_EXTENSIONS
 124 # ------------------------
 125 # Enable extensions on systems that normally disable them,
 126 # typically due to standards-conformance issues.
 127 AC_DEFUN_ONCE([gl_USE_SYSTEM_EXTENSIONS],
 128 [
 129   dnl Require this macro before AC_USE_SYSTEM_EXTENSIONS.
 130   dnl gnulib does not need it. But if it gets required by third-party macros
 131   dnl after AC_USE_SYSTEM_EXTENSIONS is required, autoconf 2.62..2.63 emit a
 132   dnl warning: "AC_COMPILE_IFELSE was called before AC_USE_SYSTEM_EXTENSIONS".
 133   dnl Note: We can do this only for one of the macros AC_AIX, AC_GNU_SOURCE,
 134   dnl AC_MINIX. If people still use AC_AIX or AC_MINIX, they are out of luck.
 135   AC_REQUIRE([AC_GNU_SOURCE])
 136
 137   AC_REQUIRE([AC_USE_SYSTEM_EXTENSIONS])
 138 ])