gen-testsuite-part

   1 #! /usr/bin/env perl
   2 # Automatically compute some dependencies for the hand-written tests
   3 # of the Automake testsuite.  Also, automatically generate some more
   4 # tests from them (for particular cases/setups only).
   5
   6 # Copyright (C) 2011-2012 Free Software Foundation, Inc.
   7
   8 # This program is free software; you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 2, or (at your option)
  11 # any later version.
  12
  13 # This program is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 #--------------------------------------------------------------------------
  22
  23 use warnings FATAL => "all";
  24 use strict;
  25 use File::Basename ();
  26 use constant TRUE => 1;
  27 use constant FALSE => 0;
  28
  29 my $me = File::Basename::basename $0;
  30
  31 # For use in VPATH builds.
  32 my $srcdir = ".";
  33
  34 #--------------------------------------------------------------------------
  35
  36 sub unindent ($)
  37 {
  38   my $text = shift;
  39   $text =~ /^(\s*)/;
  40   my $indentation = $1;
  41   $text =~ s/^$indentation//gm;
  42   return $text;
  43 }
  44
  45 sub atomic_write ($$;$)
  46 {
  47   my ($outfile, $func) = (shift, shift);
  48   my $perms = @_ > 0 ? shift : 0777;
  49   my $tmpfile = "$outfile-t";
  50   foreach my $f ($outfile, $tmpfile)
  51     {
  52       unlink $f or die "$me: cannot unlink '$f': $!\n"
  53         if -e $f;
  54     }
  55   open (my $fh, ">$tmpfile")
  56     or die "$me: can't write to '$tmpfile': $!\n";
  57   $func->($fh);
  58   close $fh
  59     or die "$me: closing '$tmpfile': $!\n";
  60   chmod ($perms & ~umask, $tmpfile)
  61     or die "$me: cannot change perms for '$tmpfile': $!\n";
  62   rename ($tmpfile, $outfile)
  63     or die "$me: renaming '$tmpfile' -> '$outfile: $!\n'";
  64 }
  65
  66 sub line_match ($$)
  67 {
  68   my ($re, $file) = (shift, shift);
  69   # Try both builddir and srcdir, with builddir first, to play nice
  70   # with VPATH builds.
  71   open (FH, "<$file") or open (FH, "<$srcdir/$file")
  72     or die "$me: cannot open file '$file': $!\n";
  73   my $ret = 0;
  74   while (defined (my $line = <FH>))
  75     {
  76       if ($line =~ $re)
  77         {
  78           $ret = 1;
  79           last;
  80         }
  81     }
  82   close FH or die "$me: cannot close file '$file': $!\n";
  83   return $ret;
  84 }
  85
  86 sub write_wrapper_script ($$$)
  87 {
  88   my ($file_handle, $wrapped_test, $shell_setup_code, $creator_name) = @_;
  89   print $file_handle unindent <<EOF;
  90     #! /bin/sh
  91     # This file has been automatically generated.  DO NOT EDIT BY HAND!
  92     . ./defs-static || exit 1
  93     $shell_setup_code
  94     # In the spirit of VPATH, we prefer a test in the build tree
  95     # over one in the source tree.
  96     for dir in . "\$am_top_srcdir"; do
  97       if test -f "\$dir/$wrapped_test"; then
  98         echo "\$0: will source \$dir/$wrapped_test"
  99         . "\$dir/$wrapped_test"; exit \$?
 100       fi
 101     done
 102     echo "\$0: cannot find wrapped test '$wrapped_test'" >&2
 103     exit 99
 104 EOF
 105 }
 106
 107 sub get_list_of_tests ()
 108 {
 109   my $make = defined $ENV{MAKE} ? $ENV{MAKE} : "make";
 110   # Unset MAKEFLAGS, for when we are called from make itself.
 111   my $cmd = "MAKEFLAGS= && unset MAKEFLAGS && cd '$srcdir' && "
 112             . "$make -s -f t/list-of-tests.mk print-list-of-tests";
 113   my @tests_list = split /\s+/, `$cmd`;
 114   die "$me: cannot get list of tests\n" unless $? == 0 && @tests_list;
 115   my $ok = 1;
 116   foreach my $test (@tests_list)
 117     {
 118       # Respect VPATH builds.
 119       next if -f $test || -f "$srcdir/$test";
 120       warn "$me: test '$test' not found\n";
 121       $ok = 0;
 122     }
 123   die "$me: some test scripts not found\n" if !$ok;
 124   return @tests_list;
 125 }
 126
 127 sub parse_options (@)
 128 {
 129   use Getopt::Long qw/GetOptions/;
 130   local @ARGV = @_;
 131   GetOptions ('srcdir=s' => \$srcdir) or die "$me: usage error\n";
 132   die "$me: too many arguments\n" if @ARGV > 0;
 133   die "$me: srcdir '$srcdir': not a directory\n" unless -d $srcdir;
 134 }
 135
 136 #--------------------------------------------------------------------------
 137
 138 # Where testsuite-related helper scripts, data files and shell libraries
 139 # are placed.  Relative to the 't/' subdirectory.
 140 my $auxdir = "ax";
 141
 142 my %deps_extractor =
 143   (
 144     libtool_macros =>
 145       {
 146         line_matcher => qr/^\s*required=.*\blibtool/,
 147         nodist_prereqs => "t/libtool-macros.log",
 148       },
 149     gettext_macros =>
 150       {
 151         line_matcher => qr/^\s*required=.*\bgettext/,
 152         nodist_prereqs => "t/gettext-macros.log",
 153       },
 154     use_trivial_test_driver =>
 155       {
 156         line_matcher => qr/\btrivial-test-driver\b/,
 157         dist_prereqs => "t/$auxdir/trivial-test-driver",
 158       },
 159     check_testsuite_summary =>
 160       {
 161         line_matcher => qr/\btestsuite-summary-checks\.sh\b/,
 162         dist_prereqs => "t/$auxdir/testsuite-summary-checks.sh",
 163       },
 164     extract_testsuite_summary =>
 165       {
 166         line_matcher => qr/\bextract-testsuite-summary\.pl\b/,
 167         dist_prereqs => "t/$auxdir/extract-testsuite-summary.pl",
 168       },
 169     check_tap_testsuite_summary =>
 170       {
 171         line_matcher => qr/\btap-summary-aux\.sh\b/,
 172         dist_prereqs => "t/$auxdir/tap-summary-aux.sh",
 173       },
 174     on_tap_with_common_setup =>
 175       {
 176         line_matcher => qr/\btap-setup\.sh\b/,
 177         dist_prereqs => "t/$auxdir/tap-setup.sh",
 178         nodist_prereqs => "t/tap-common-setup.log",
 179       },
 180     depcomp =>
 181       {
 182         line_matcher => qr/\bdepcomp\.sh\b/,
 183         dist_prereqs => "t/$auxdir/depcomp.sh",
 184       },
 185   );
 186
 187 #--------------------------------------------------------------------------
 188
 189 my %test_generators =
 190   (
 191     #
 192     # Any test script in the Automake testsuite that checks features of
 193     # the Automake-provided parallel testsuite harness might want to
 194     # define a sibling test that does similar checks, but for the old
 195     # serial testsuite harness instead.
 196     #
 197     # Individual tests can request the creation of such a sibling by
 198     # making the string "try-with-serial-tests" appear any line of the
 199     # test itself.
 200     #
 201     serial_testsuite_harness =>
 202       {
 203         line_matcher     => qr/\btry-with-serial-tests\b/,
 204         shell_setup_code => 'am_serial_tests=yes',
 205       },
 206     #
 207     # For each test script in the Automake testsuite that tests features
 208     # of one or more automake-provided shell script from the 'lib/'
 209     # subdirectory by running those scripts directly (i.e., not thought
 210     # make calls and automake-generated makefiles), define a sibling test
 211     # that does likewise, but running the said script with the configure
 212     # time $SHELL instead of the default system shell /bin/sh.
 213     #
 214     # A test is considered a candidate for sibling-generation if it calls
 215     # the 'get_shell_script' function anywhere.
 216     #
 217     # Individual tests can prevent the creation of such a sibling by
 218     # explicitly setting the '$am_test_prefer_config_shell' variable
 219     # to either "yes" or "no".
 220     # The rationale for this is that if the variable is set to "yes",
 221     # the test already uses $SHELL, so that a sibling would be just a
 222     # duplicate; while if the variable is set to "no", the test doesn't
 223     # support, or is not meant to use, $SHELL to run the script under
 224     # testing, and forcing it to do so in the sibling would likely
 225     # cause a spurious failure.
 226     #
 227     prefer_config_shell =>
 228       {
 229         line_matcher =>
 230           qr/(^|\s)get_shell_script\s/,
 231         line_rejecter =>
 232           qr/\bam_test_prefer_config_shell=/,
 233         shell_setup_code =>
 234           'am_test_prefer_config_shell=yes',
 235       },
 236     #
 237     # Tests on tap support should be run with both the perl and awk
 238     # implementations of the TAP driver (they run with the awk one
 239     # by default).
 240     #
 241     perl_tap_driver =>
 242       {
 243         line_matcher =>
 244           qr<(?:\bfetch_tap_driver\b|[\s/]tap-setup\.sh\b)>,
 245         line_rejecter =>
 246           qr/\bam_tap_implementation=/,
 247         shell_setup_code =>
 248           'am_tap_implementation=perl',
 249       },
 250   );
 251
 252 #--------------------------------------------------------------------------
 253
 254 parse_options @ARGV;
 255
 256 my @all_tests = get_list_of_tests;
 257 my @generated_tests = (); # Will be updated later.
 258
 259 print "## -*- Makefile -*-\n";
 260 print "## Generated by $me.  DO NOT EDIT BY HAND!\n\n";
 261
 262 print <<EOF;
 263
 264 ## --------------------------------------------- ##
 265 ##  Autogenerated tests and their dependencies.  ##
 266 ## --------------------------------------------- ##
 267
 268 EOF
 269
 270 # FIXME: the following is not really right, since cannot compose wrapping
 271 # of tests matching more than one condition.  Still, there should be no
 272 # such test at the moment, so the limitation is (temporarily) acceptable.
 273 while (my ($k, $g) = each %test_generators)
 274   {
 275     my @wrapped_tests = grep {
 276       line_match ($g->{line_matcher}, $_)
 277         && (!$g->{line_rejecter} || !line_match ($g->{line_rejecter}, $_))
 278     } @all_tests;
 279     foreach my $wrapped_test (@wrapped_tests)
 280       {
 281         (my $base = $wrapped_test) =~ s/\.([^.]*)$//;
 282         my $suf = $1 or die "$me: test '$wrapped_test' lacks a suffix\n";
 283         my $wrapper_test =  "$base-w.$suf";
 284         # Register wrapper test as "autogenerated".
 285         push @generated_tests, $wrapper_test;
 286         # Create wrapper test.
 287         atomic_write $wrapper_test,
 288                      sub { write_wrapper_script $_[0], $wrapped_test,
 289                            $g->{shell_setup_code} },
 290                      0555;
 291         # The generated test works by sourcing the original test, so that
 292         # it has to be re-run every time that changes ...
 293         print "$base-w.log: $wrapped_test\n";
 294         # ... but also every time the prerequisites of the wrapped test
 295         # changes.  The simpler (although suboptimal) way to do so is to
 296         # ensure that the wrapped tests runs before the wrappee one (in
 297         # case it needs to be re-run *at all*.
 298         # FIXME: we could maybe refactor the script to find a more
 299         # granular way to express such implicit dependencies.
 300         print "$base-w.log: $base.log\n";
 301       }
 302   }
 303
 304 print <<EOF;
 305
 306 ## ---------------------------------------------------- ##
 307 ##  Ad-hoc autogenerated tests and their dependencies.  ##
 308 ## ---------------------------------------------------- ##
 309
 310 EOF
 311
 312 print "## Tests on automatic dependency tracking (see 'depcomp.sh').\n";
 313
 314 # Key: depmode, value: list of required programs.
 315 my %depmodes =
 316   (
 317     auto         => ["cc"],
 318     disabled     => ["cc"],
 319     makedepend   => ["cc", "makedepend"],
 320     dashmstdout  => ["gcc"],
 321     cpp          => ["gcc"],
 322 # This is for older (pre-3.x) GCC versions.  Newer versions
 323 # have depmode "gcc3".
 324     gcc          => ["gcc"],
 325 # This is for older (pre-7) msvc versions.  Newer versions
 326 # have depmodes "msvc7" and "msvc7msys".
 327     msvisualcpp  => ["cl", "cygpath"],
 328     msvcmsys     => ["cl", "mingw"],
 329   );
 330
 331 foreach my $lt (TRUE, FALSE)
 332   {
 333     foreach my $m (keys %depmodes)
 334       {
 335         my $planned = ($lt && $m eq "auto") ? 84 : 28;
 336         my @required =
 337           (
 338             @{$depmodes{$m}},
 339             $lt ? ("libtoolize",) : (),
 340           );
 341         my @vars_init =
 342           (
 343             "am_create_testdir=empty",
 344             "depmode=$m",
 345             "depcomp_with_libtool=" . ($lt ? "yes" : "no"),
 346           );
 347         my $test = "t/depcomp" . ($lt ? "-lt-" : "-") . $m . ".tap";
 348         # Register wrapper test as "autogenerated" ...
 349         push @generated_tests, $test;
 350         # ... and create it.
 351         atomic_write ($test, sub
 352           {
 353             my $file_handle = shift;
 354             print $file_handle unindent <<EOF;
 355               #! /bin/sh
 356               # Automatically generated test.  DO NOT EDIT BY HAND!
 357               @vars_init
 358               required="@required"
 359               . ./defs || exit 1
 360               plan_ $planned
 361               . "\$am_testauxdir/depcomp.sh"; exit \$?
 362 EOF
 363           },
 364           0555);
 365       }
 366    }
 367
 368 # Update generated makefile fragment to account for all the generated tests.
 369 print "generated_TESTS =\n";
 370 map { print "generated_TESTS += $_\n" } @generated_tests;
 371
 372 # The test scripts are scanned for automatic dependency generation *after*
 373 # the generated tests have been created, so they too can be scanned.  To
 374 # do so correctly, we need to update the list in '@all_tests' to make it
 375 # comprise also the freshly-generated tests.
 376
 377 push @all_tests, @generated_tests;
 378
 379 print <<EOF;
 380
 381 ## ----------------------------- ##
 382 ##  Autogenerated dependencies.  ##
 383 ## ----------------------------- ##
 384
 385 EOF
 386
 387 while (my ($k, $x) = each %deps_extractor)
 388   {
 389     my $dist_prereqs = $x->{dist_prereqs} || "";
 390     my $nodist_prereqs = $x->{nodist_prereqs} || "";
 391     my @tests = grep { line_match $x->{line_matcher}, $_ } @all_tests;
 392     map { s/\.[^.]*$//; s/$/\.log/; } (my @logs = @tests);
 393     print "## Added by deps-extracting key '$k'.\n";
 394     ## The list of all tests which have a dependency detected by the
 395     ## current key.
 396     print join(" \\\n  ", "${k}_TESTS =", @tests) . "\n";
 397     print "EXTRA_DIST += $dist_prereqs\n";
 398     map { print "$_: $dist_prereqs $nodist_prereqs\n" } @logs;
 399     print "\n";
 400   }
 401
 402 __END__