gdb/warning.m4

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995-2017 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 AC_DEFUN([AM_GDB_WARNINGS],[
  20 AC_ARG_ENABLE(werror,
  21   AS_HELP_STRING([--enable-werror], [treat compile warnings as errors]),
  22   [case "${enableval}" in
  23      yes | y) ERROR_ON_WARNING="yes" ;;
  24      no | n)  ERROR_ON_WARNING="no" ;;
  25      *) AC_MSG_ERROR(bad value ${enableval} for --enable-werror) ;;
  26    esac])
  27
  28 # Enable -Werror by default when using gcc.  Turn it off for releases.
  29 if test "${GCC}" = yes -a -z "${ERROR_ON_WARNING}" && $development; then
  30     ERROR_ON_WARNING=yes
  31 fi
  32
  33 WERROR_CFLAGS=""
  34 if test "${ERROR_ON_WARNING}" = yes ; then
  35     WERROR_CFLAGS="-Werror"
  36 fi
  37
  38 # The options we'll try to enable.
  39 build_warnings="-Wall -Wpointer-arith \
  40 -Wno-unused -Wunused-value -Wunused-function \
  41 -Wno-switch -Wno-char-subscripts \
  42 -Wempty-body -Wunused-but-set-parameter -Wunused-but-set-variable \
  43 -Wno-sign-compare -Wno-narrowing -Wno-error=maybe-uninitialized"
  44
  45 # Enable -Wno-format by default when using gcc on mingw since many
  46 # GCC versions complain about %I64.
  47 case "${host}" in
  48   *-*-mingw32*) build_warnings="$build_warnings -Wno-format" ;;
  49   *) build_warnings="$build_warnings -Wformat-nonliteral" ;;
  50 esac
  51
  52 AC_ARG_ENABLE(build-warnings,
  53 AS_HELP_STRING([--enable-build-warnings], [enable build-time compiler warnings if gcc is used]),
  54 [case "${enableval}" in
  55   yes)  ;;
  56   no)   build_warnings="-w";;
  57   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  58         build_warnings="${build_warnings} ${t}";;
  59   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  60         build_warnings="${t} ${build_warnings}";;
  61   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
  62 esac
  63 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
  64   echo "Setting compiler warning flags = $build_warnings" 6>&1
  65 fi])dnl
  66 AC_ARG_ENABLE(gdb-build-warnings,
  67 AS_HELP_STRING([--enable-gdb-build-warnings], [enable GDB specific build-time compiler warnings if gcc is used]),
  68 [case "${enableval}" in
  69   yes)  ;;
  70   no)   build_warnings="-w";;
  71   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  72         build_warnings="${build_warnings} ${t}";;
  73   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  74         build_warnings="${t} ${build_warnings}";;
  75   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
  76 esac
  77 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
  78   echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1
  79 fi])dnl
  80
  81 # The set of warnings supported by a C++ compiler is not the same as
  82 # of the C compiler.
  83 AC_LANG_PUSH([C++])
  84
  85 WARN_CFLAGS=""
  86 if test "x${build_warnings}" != x -a "x$GCC" = xyes
  87 then
  88     AC_MSG_CHECKING(compiler warning flags)
  89     # Separate out the -Werror flag as some files just cannot be
  90     # compiled with it enabled.
  91     for w in ${build_warnings}; do
  92         # GCC does not complain about -Wno-unknown-warning.  Invert
  93         # and test -Wunknown-warning instead.
  94         case $w in
  95         -Wno-*)
  96                 wtest=`echo $w | sed 's/-Wno-/-W/g'` ;;
  97         *)
  98                 wtest=$w ;;
  99         esac
 100
 101         case $w in
 102         -Werr*) WERROR_CFLAGS=-Werror ;;
 103         *)
 104             # Check whether GCC accepts it.
 105             saved_CFLAGS="$CFLAGS"
 106             CFLAGS="$CFLAGS $wtest"
 107             saved_CXXFLAGS="$CXXFLAGS"
 108             CXXFLAGS="$CXXFLAGS $wtest"
 109             AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
 110             CFLAGS="$saved_CFLAGS"
 111             CXXFLAGS="$saved_CXXFLAGS"
 112         esac
 113     done
 114     AC_MSG_RESULT(${WARN_CFLAGS} ${WERROR_CFLAGS})
 115 fi
 116 AC_SUBST(WARN_CFLAGS)
 117 AC_SUBST(WERROR_CFLAGS)
 118
 119 AC_LANG_POP([C++])
 120 ])