gdb/warning.m4

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995-2018 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 AC_DEFUN([AM_GDB_WARNINGS],[
  20 AC_ARG_ENABLE(werror,
  21   AS_HELP_STRING([--enable-werror], [treat compile warnings as errors]),
  22   [case "${enableval}" in
  23      yes | y) ERROR_ON_WARNING="yes" ;;
  24      no | n)  ERROR_ON_WARNING="no" ;;
  25      *) AC_MSG_ERROR(bad value ${enableval} for --enable-werror) ;;
  26    esac])
  27
  28 # Enable -Werror by default when using gcc.  Turn it off for releases.
  29 if test "${GCC}" = yes -a -z "${ERROR_ON_WARNING}" && $development; then
  30     ERROR_ON_WARNING=yes
  31 fi
  32
  33 WERROR_CFLAGS=""
  34 if test "${ERROR_ON_WARNING}" = yes ; then
  35     WERROR_CFLAGS="-Werror"
  36 fi
  37
  38 # The options we'll try to enable.
  39 build_warnings="-Wall -Wpointer-arith \
  40 -Wno-unused -Wunused-value -Wunused-function \
  41 -Wno-switch -Wno-char-subscripts \
  42 -Wempty-body -Wunused-but-set-parameter -Wunused-but-set-variable \
  43 -Wno-sign-compare -Wno-narrowing -Wno-error=maybe-uninitialized \
  44 -Wno-mismatched-tags \
  45 -Wno-error=deprecated-register"
  46
  47 case "${host}" in
  48   *-*-mingw32*)
  49     # Enable -Wno-format by default when using gcc on mingw since many
  50     # GCC versions complain about %I64.
  51     build_warnings="$build_warnings -Wno-format" ;;
  52   *-*-solaris*)
  53     # Solaris 11.4 <python2.7/ceval.h> uses #pragma no_inline that GCC
  54     # doesn't understand.
  55     build_warnings="$build_warnings -Wno-unknown-pragmas"
  56     # Solaris 11 <unistd.h> marks vfork deprecated.
  57     build_warnings="$build_warnings -Wno-deprecated-declarations" ;;
  58   *) build_warnings="$build_warnings -Wformat-nonliteral" ;;
  59 esac
  60
  61 AC_ARG_ENABLE(build-warnings,
  62 AS_HELP_STRING([--enable-build-warnings], [enable build-time compiler warnings if gcc is used]),
  63 [case "${enableval}" in
  64   yes)  ;;
  65   no)   build_warnings="-w";;
  66   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  67         build_warnings="${build_warnings} ${t}";;
  68   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  69         build_warnings="${t} ${build_warnings}";;
  70   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
  71 esac
  72 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
  73   echo "Setting compiler warning flags = $build_warnings" 6>&1
  74 fi])dnl
  75 AC_ARG_ENABLE(gdb-build-warnings,
  76 AS_HELP_STRING([--enable-gdb-build-warnings], [enable GDB specific build-time compiler warnings if gcc is used]),
  77 [case "${enableval}" in
  78   yes)  ;;
  79   no)   build_warnings="-w";;
  80   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  81         build_warnings="${build_warnings} ${t}";;
  82   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  83         build_warnings="${t} ${build_warnings}";;
  84   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
  85 esac
  86 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
  87   echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1
  88 fi])dnl
  89
  90 # The set of warnings supported by a C++ compiler is not the same as
  91 # of the C compiler.
  92 AC_LANG_PUSH([C++])
  93
  94 WARN_CFLAGS=""
  95 if test "x${build_warnings}" != x -a "x$GCC" = xyes
  96 then
  97     AC_MSG_CHECKING(compiler warning flags)
  98     # Separate out the -Werror flag as some files just cannot be
  99     # compiled with it enabled.
 100     for w in ${build_warnings}; do
 101         # GCC does not complain about -Wno-unknown-warning.  Invert
 102         # and test -Wunknown-warning instead.
 103         case $w in
 104         -Wno-*)
 105                 wtest=`echo $w | sed 's/-Wno-/-W/g'` ;;
 106         *)
 107                 wtest=$w ;;
 108         esac
 109
 110         case $w in
 111         -Werr*) WERROR_CFLAGS=-Werror ;;
 112         *)
 113             # Check whether GCC accepts it.
 114             saved_CFLAGS="$CFLAGS"
 115             CFLAGS="$CFLAGS -Werror $wtest"
 116             saved_CXXFLAGS="$CXXFLAGS"
 117             CXXFLAGS="$CXXFLAGS -Werror $wtest"
 118             AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
 119             CFLAGS="$saved_CFLAGS"
 120             CXXFLAGS="$saved_CXXFLAGS"
 121         esac
 122     done
 123     AC_MSG_RESULT(${WARN_CFLAGS} ${WERROR_CFLAGS})
 124 fi
 125 AC_SUBST(WARN_CFLAGS)
 126 AC_SUBST(WERROR_CFLAGS)
 127
 128 AC_LANG_POP([C++])
 129 ])