gdb/warning.m4

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995-2017 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 AC_DEFUN([AM_GDB_WARNINGS],[
  20 AC_ARG_ENABLE(werror,
  21   AS_HELP_STRING([--enable-werror], [treat compile warnings as errors]),
  22   [case "${enableval}" in
  23      yes | y) ERROR_ON_WARNING="yes" ;;
  24      no | n)  ERROR_ON_WARNING="no" ;;
  25      *) AC_MSG_ERROR(bad value ${enableval} for --enable-werror) ;;
  26    esac])
  27
  28 # Enable -Werror by default when using gcc.  Turn it off for releases.
  29 if test "${GCC}" = yes -a -z "${ERROR_ON_WARNING}" && $development; then
  30     ERROR_ON_WARNING=yes
  31 fi
  32
  33 WERROR_CFLAGS=""
  34 if test "${ERROR_ON_WARNING}" = yes ; then
  35     WERROR_CFLAGS="-Werror"
  36 fi
  37
  38 # The options we'll try to enable.
  39 build_warnings="-Wall -Wpointer-arith \
  40 -Wno-unused -Wunused-value -Wunused-function \
  41 -Wno-switch -Wno-char-subscripts \
  42 -Wempty-body -Wunused-but-set-parameter -Wunused-but-set-variable \
  43 -Wno-sign-compare -Wno-narrowing -Wno-error=maybe-uninitialized \
  44 -Wno-mismatched-tags"
  45
  46 # Enable -Wno-format by default when using gcc on mingw since many
  47 # GCC versions complain about %I64.
  48 case "${host}" in
  49   *-*-mingw32*) build_warnings="$build_warnings -Wno-format" ;;
  50   *) build_warnings="$build_warnings -Wformat-nonliteral" ;;
  51 esac
  52
  53 AC_ARG_ENABLE(build-warnings,
  54 AS_HELP_STRING([--enable-build-warnings], [enable build-time compiler warnings if gcc is used]),
  55 [case "${enableval}" in
  56   yes)  ;;
  57   no)   build_warnings="-w";;
  58   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  59         build_warnings="${build_warnings} ${t}";;
  60   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  61         build_warnings="${t} ${build_warnings}";;
  62   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
  63 esac
  64 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
  65   echo "Setting compiler warning flags = $build_warnings" 6>&1
  66 fi])dnl
  67 AC_ARG_ENABLE(gdb-build-warnings,
  68 AS_HELP_STRING([--enable-gdb-build-warnings], [enable GDB specific build-time compiler warnings if gcc is used]),
  69 [case "${enableval}" in
  70   yes)  ;;
  71   no)   build_warnings="-w";;
  72   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  73         build_warnings="${build_warnings} ${t}";;
  74   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  75         build_warnings="${t} ${build_warnings}";;
  76   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
  77 esac
  78 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
  79   echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1
  80 fi])dnl
  81
  82 # The set of warnings supported by a C++ compiler is not the same as
  83 # of the C compiler.
  84 AC_LANG_PUSH([C++])
  85
  86 WARN_CFLAGS=""
  87 if test "x${build_warnings}" != x -a "x$GCC" = xyes
  88 then
  89     AC_MSG_CHECKING(compiler warning flags)
  90     # Separate out the -Werror flag as some files just cannot be
  91     # compiled with it enabled.
  92     for w in ${build_warnings}; do
  93         # GCC does not complain about -Wno-unknown-warning.  Invert
  94         # and test -Wunknown-warning instead.
  95         case $w in
  96         -Wno-*)
  97                 wtest=`echo $w | sed 's/-Wno-/-W/g'` ;;
  98         *)
  99                 wtest=$w ;;
 100         esac
 101
 102         case $w in
 103         -Werr*) WERROR_CFLAGS=-Werror ;;
 104         *)
 105             # Check whether GCC accepts it.
 106             saved_CFLAGS="$CFLAGS"
 107             CFLAGS="$CFLAGS -Werror $wtest"
 108             saved_CXXFLAGS="$CXXFLAGS"
 109             CXXFLAGS="$CXXFLAGS -Werror $wtest"
 110             AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
 111             CFLAGS="$saved_CFLAGS"
 112             CXXFLAGS="$saved_CXXFLAGS"
 113         esac
 114     done
 115     AC_MSG_RESULT(${WARN_CFLAGS} ${WERROR_CFLAGS})
 116 fi
 117 AC_SUBST(WARN_CFLAGS)
 118 AC_SUBST(WERROR_CFLAGS)
 119
 120 AC_LANG_POP([C++])
 121 ])