gdb/testsuite/gdb.threads/watchthreads-reorder.exp

   1 # This testcase is part of GDB, the GNU debugger.
   2
   3 # Copyright 2009 Free Software Foundation, Inc.
   4
   5 # This program is free software; you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  17
  18 # Test GDB can cope with two watchpoints being hit by different threads at the
  19 # same time, GDB reports one of them and after "continue" to report the other
  20 # one GDB should not be confused by differently set watchpoints that time.
  21 # This is the goal of "reorder1".  "reorder0" tests the basic functionality of
  22 # two watchpoints being hit at the same time, without reordering them during the
  23 # stop.  The formerly broken functionality is due to the all-stop mode default
  24 # "show breakpoint always-inserted" being "off".  Formerly the remembered hit
  25 # could be assigned during continuation of a thread with pending SIGTRAP to the
  26 # different/new watchpoint, just based on the watchpoint/debug register number.
  27
  28 if {(![istarget "i?86-*-*"] && ![istarget "x86_64-*-*"]
  29      && ![istarget "ia64-*-*"])
  30     || [target_info exists gdb,no_hardware_watchpoints]
  31     || ![istarget *-*-linux*]} {
  32     return 0
  33 }
  34
  35 set testfile "watchthreads-reorder"
  36 set srcfile ${testfile}.c
  37 set binfile ${objdir}/${subdir}/${testfile}
  38 if {[gdb_compile_pthreads "${srcdir}/${subdir}/${srcfile}" ${binfile} executable [list debug additional_flags=-lrt]] != "" } {
  39     return -1
  40 }
  41
  42 foreach reorder {0 1} {
  43
  44     global pf_prefix
  45     set prefix_test $pf_prefix
  46     lappend pf_prefix "reorder$reorder:"
  47
  48     clean_restart $testfile
  49
  50     gdb_test "set can-use-hw-watchpoints 1"
  51
  52     if ![runto_main] {
  53         return -1
  54     }
  55
  56     # Use "rwatch" as "watch" would report the watchpoint changed just based on its
  57     # read memory value during a stop by unrelated event.  We are interested in not
  58     # losing the hardware watchpoint trigger.
  59
  60     gdb_test "rwatch thread1_rwatch" "Hardware read watchpoint \[0-9\]+: thread1_rwatch"
  61     set test "rwatch thread2_rwatch"
  62     gdb_test_multiple $test $test {
  63         -re "Target does not support this type of hardware watchpoint\\.\r\n$gdb_prompt $" {
  64             # ppc64 supports at most 1 hw watchpoints.
  65             unsupported $test
  66             return
  67         }
  68         -re "Hardware read watchpoint \[0-9\]+: thread2_rwatch\r\n$gdb_prompt $" {
  69             pass $test
  70         }
  71     }
  72     gdb_breakpoint [gdb_get_line_number "break-at-exit"]
  73
  74     # The watchpoints can happen in arbitrary order depending on random:
  75     # SEL: Found 2 SIGTRAP events, selecting #[01]
  76     # As GDB contains no srand() on the specific host/OS it will behave always the
  77     # same.  Such order cannot be guaranteed for GDB in general.
  78
  79     gdb_test "continue" \
  80              "Hardware read watchpoint \[0-9\]+: thread\[12\]_rwatch\r\n\r\nValue = 0\r\n0x\[0-9a-f\]+ in thread\[12\]_func .*" \
  81              "continue a"
  82
  83     if $reorder {
  84         # GDB orders watchpoints by their addresses so inserting new variables
  85         # with lower addresses will shift the former watchpoints to higher
  86         # debug registers.
  87
  88         gdb_test "rwatch unused1_rwatch" "Hardware read watchpoint \[0-9\]+: unused1_rwatch"
  89         gdb_test "rwatch unused2_rwatch" "Hardware read watchpoint \[0-9\]+: unused2_rwatch"
  90     }
  91
  92     gdb_test "continue" \
  93              "Hardware read watchpoint \[0-9\]+: thread\[12\]_rwatch\r\n\r\nValue = 0\r\n0x\[0-9a-f\]+ in thread\[12\]_func .*" \
  94              "continue b"
  95
  96     # While the debug output itself is not checked in this testcase one bug was
  97     # found in the DEBUG_INFRUN code path.
  98     gdb_test "set debug infrun 1"
  99
 100     gdb_continue_to_breakpoint "break-at-exit" ".*break-at-exit.*"
 101
 102     set pf_prefix $prefix_test
 103 }