gdb/testsuite/gdb.base/sss-bp-on-user-bp-2.exp

   1 # Copyright (C) 2014-2023 Free Software Foundation, Inc.
   2
   3 # This program is free software; you can redistribute it and/or modify
   4 # it under the terms of the GNU General Public License as published by
   5 # the Free Software Foundation; either version 3 of the License, or
   6 # (at your option) any later version.
   7 #
   8 # This program is distributed in the hope that it will be useful,
   9 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  10 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  11 # GNU General Public License for more details.
  12 #
  13 # You should have received a copy of the GNU General Public License
  14 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  15
  16 # Test that GDB doesn't get confused in the following scenario
  17 # (PR breakpoints/17000).  Say, we have this program:
  18 #
  19 #  =>  0xff000001  INSN1
  20 #      0xff000002  INSN2
  21 #
  22 # The PC currently points at INSN1.
  23 #
  24 # 1 - User sets a breakpoint at 0xff000002 (INSN2).
  25 #
  26 # 2 - User steps.  On software single-step archs, this sets a software
  27 #     single-step breakpoint at 0xff000002 (INSN2) too.
  28 #
  29 # 3 - User deletes breakpoint (INSN2) before the single-step finishes.
  30 #
  31 # 4 - The single-step finishes, and GDB removes the single-step
  32 #     breakpoint.
  33
  34 # Test relies on checking gdb debug output. Do not run if gdb debug is
  35 # enabled as any debug will be redirected to the log.
  36 if [gdb_debug_enabled] {
  37     untested "debug is enabled"
  38     return 0
  39 }
  40
  41 standard_testfile
  42
  43 if {[prepare_for_testing "failed to prepare" $testfile $srcfile debug]} {
  44     return -1
  45 }
  46
  47 if ![runto_main] {
  48     return 0
  49 }
  50
  51 delete_breakpoints
  52
  53 # With the all-stop RSP, we can't talk to the target while it's
  54 # running, until we get back the stop reply.  If not using single-step
  55 # breakpoints, then the "del" in stepi_del_break below will try to
  56 # delete the user breakpoint from the target, which will fail, with
  57 # "Cannot execute this command while the target is running.".  On
  58 # software single-step targets, that del shouldn't trigger any RSP
  59 # traffic.  Hardware-step targets that can't access memory while the
  60 # target is running, either remote or native, are likewise affected.
  61 # So we just skip the test if not using software single-stepping.  We
  62 # detect that by looking for 'to_resume (..., step)' in "debug
  63 # target" output.
  64
  65 # Probe for software single-step breakpoint use.
  66
  67 gdb_test_no_output "set debug target 1"
  68 set hardware_step 0
  69 set test "probe target hardware step"
  70 gdb_test_multiple "si" $test {
  71     -re "resume \\(\[^\r\n\]+, step, .*$gdb_prompt $" {
  72         set hardware_step 1
  73         pass $test
  74     }
  75     -re "$gdb_prompt $" {
  76         pass $test
  77     }
  78 }
  79
  80 if { $hardware_step } {
  81     unsupported "target doesn't use software single-stepping"
  82     return
  83 }
  84
  85 gdb_test "set debug target 0" "->log_command.*\\)"
  86
  87 set line_re "\[^\r\n\]*"
  88
  89 gdb_test "b test:label" "Breakpoint .*"
  90 gdb_continue_to_breakpoint "run past setup"
  91 delete_breakpoints
  92
  93 # So we can precisely control breakpoint insertion order.
  94 gdb_test_no_output "set breakpoint always-inserted on"
  95
  96 # Capture disassembly output.  PREFIX is used as test prefix.  The
  97 # current instruction indicator (=>) is stripped away.
  98 proc disassemble { prefix } {
  99     with_test_prefix "$prefix" {
 100         set output [capture_command_output "disassemble test" ""]
 101         return [string map {"=>" "  "} $output]
 102     }
 103 }
 104
 105 # Issue a stepi and immediately delete the user breakpoint that is set
 106 # at the same address as the software single-step breakpoint.  Do this
 107 # in a user defined command, so that the stepi's trap doesn't have a
 108 # chance to be handled before further input is processed.  We then
 109 # compare before/after disassembly.  GDB should be able to handle
 110 # deleting the user breakpoint before deleting the single-step
 111 # breakpoint.  E.g., we shouldn't see breakpoint instructions in the
 112 # disassembly.
 113
 114 set disasm_before [disassemble "before"]
 115
 116 gdb_test "b test:label2" ".*" "set breakpoint where si will land"
 117
 118 set test "define stepi_del_break"
 119 gdb_test_multiple $test $test {
 120     -re "Type commands for definition of \"stepi_del_break\".\r\nEnd with a line saying just \"end\".\r\n>$" {
 121         gdb_test "si&\ndel \$bpnum\nend" "" $test
 122     }
 123 }
 124
 125 set command "stepi_del_break"
 126 set test $command
 127 gdb_test_multiple $command $test {
 128     -re "^$command\r\n$gdb_prompt " {
 129         # Note no end anchor, because "si&" finishes and prints the
 130         # current frame/line after the prompt is printed.
 131         pass $test
 132     }
 133 }
 134
 135 # Now consume the output of the finished "si&".
 136 set test "si& finished"
 137 gdb_test_multiple "" $test {
 138     -re "must be a single line \\\*/\r\n" {
 139         pass $test
 140     }
 141 }
 142
 143 set disasm_after [disassemble "after"]
 144
 145 set test "before/after disassembly matches"
 146 if ![string compare $disasm_before $disasm_after]  {
 147     pass $test
 148 } else {
 149     fail $test
 150 }