gdb/testsuite/gdb.base/freebpcmd.exp

   1 #   Copyright 2003, 2007, 2008 Free Software Foundation, Inc.
   2
   3 # This program is free software; you can redistribute it and/or modify
   4 # it under the terms of the GNU General Public License as published by
   5 # the Free Software Foundation; either version 3 of the License, or
   6 # (at your option) any later version.
   7 #
   8 # This program is distributed in the hope that it will be useful,
   9 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  10 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  11 # GNU General Public License for more details.
  12 #
  13 # You should have received a copy of the GNU General Public License
  14 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  15
  16
  17 # This is a regression test for the following bug, as of 2003-12-12:
  18 #
  19 # Set a breakpoint which will be hit many times.  Attach a complex set
  20 # of commands to it, including a "continue" command.  Run the program,
  21 # so that the breakpoint is hit, its commands get executed, and the
  22 # program continues and hits the breakpoint again.  You will see
  23 # messages like "warning: Invalid control type in command structure.",
  24 # or maybe GDB will crash.
  25 #
  26 # When the breakpoint is hit, bpstat_stop_status copies the
  27 # breakpoint's command tree to the bpstat.  bpstat_do_actions then
  28 # calls execute_control_command to run the commands.  The 'continue'
  29 # command invokes the following chain of calls:
  30 #
  31 #   continue_command
  32 #     -> clear_proceed_status
  33 #       -> bpstat_clear
  34 #         -> free_command_lines
  35 #            -> frees the commands we are currently running.
  36 #
  37 # When control does eventually return to execute_control_command, GDB
  38 # continues to walk the tree of freed command nodes, resulting in the
  39 # error messages and / or crashes.
  40 #
  41 # Since this bug depends on storage being reused between the time that
  42 # we continue and the time that we fall back to bpstat_do_actions, the
  43 # reproduction recipe is more delicate than I would like.  I welcome
  44 # suggestions for improving this.
  45
  46 set prms_id 0
  47 set bug_id 0
  48
  49 set testfile "freebpcmd"
  50 set srcfile ${testfile}.c
  51 set srcfile1 ${testfile}1.c
  52 set binfile ${objdir}/${subdir}/${testfile}
  53
  54 if  { [gdb_compile "${srcdir}/${subdir}/${srcfile}" "${binfile}" executable {debug}] != "" } {
  55      untested freebpcmd.exp
  56      return -1
  57 }
  58
  59 gdb_exit
  60 gdb_start
  61 gdb_reinitialize_dir $srcdir/$subdir
  62 gdb_load ${binfile}
  63
  64 gdb_test "break [gdb_get_line_number "euphonium"]" "" "set breakpoint"
  65
  66 # The goal of all this is to make sure that there's plenty of memory
  67 # churn, and different amounts of it each time the inferior stops;
  68 # this seems to make GDB crash more reliably.
  69 set lines {{if (i%2) == 0}
  70            {echo "even "}
  71            {print i}
  72            {else}
  73            {echo "odd "}
  74            {print i}
  75            {end}
  76            {set variable $foo = 0}
  77            {set variable $j = 0}
  78            {while $j < i}
  79            {set variable $foo += $j}
  80            {set variable $j++}
  81            {end}
  82            {print $foo}
  83            {if i != 40}
  84            {c}
  85            {end}
  86            {end}}
  87
  88 send_gdb "commands\n"
  89 for {set i 0} {$i < [llength $lines]} {incr i} {
  90     gdb_expect {
  91         -re ".*>" {
  92             send_gdb "[lindex $lines $i]\n"
  93         }
  94         -re "$gdb_prompt $" {
  95             set reason "got top-level prompt early"
  96             break
  97         }
  98         timeout {
  99             set reason "timeout"
 100             break
 101         }
 102     }
 103 }
 104 if {$i >= [llength $lines]} {
 105     pass "send breakpoint commands"
 106 } else {
 107     fail "send breakpoint commands ($reason)"
 108 }
 109
 110 gdb_run_cmd
 111
 112 set timeout 120
 113
 114 gdb_test_multiple "" "run program with breakpoint commands" {
 115     -re "warning: Invalid control type in command structure" {
 116         kfail "gdb/1489" "run program with breakpoint commands"
 117     }
 118     -re "$gdb_prompt $" {
 119         pass "run program with breakpoint commands"
 120     }
 121     eof {
 122         kfail "gdb/1489" "run program with breakpoint commands (GDB died)"
 123     }
 124 }