gdb/testsuite/gdb.asm/asm-source.exp

   1 # Copyright 1998, 2000, 2001, 2002, 2003, 2004 Free Software Foundation, Inc.
   2 #
   3 # This program is free software; you can redistribute it and/or modify
   4 # it under the terms of the GNU General Public License as published by
   5 # the Free Software Foundation; either version 2 of the License, or
   6 # (at your option) any later version.
   7 #
   8 # This program is distributed in the hope that it will be useful,
   9 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  10 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  11 # GNU General Public License for more details.
  12 #
  13 # You should have received a copy of the GNU General Public License
  14 # along with this program; if not, write to the Free Software
  15 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  16 #
  17 # Please email any bugs, comments, and/or additions to this file to:
  18 # bug-gdb@prep.ai.mit.edu
  19 #
  20 # This file was written by Kendra.
  21
  22 if $tracelevel then {
  23     strace $tracelevel
  24 }
  25
  26 #
  27 # Test debugging assembly level programs.
  28 # This file uses asmsrc[12].s for input.
  29 #
  30
  31 set prms_id 0
  32 set bug_id 0
  33
  34 set asm-arch ""
  35 set asm-note "empty"
  36 set asm-flags ""
  37 set link-flags "--entry _start"
  38 set debug-flags ""
  39
  40 switch -glob -- [istarget] {
  41     "alpha*-*-*" {
  42         set asm-arch alpha
  43         # ??? Won't work with ecoff systems like Tru64, but then we also
  44         # don't have any other -g flag that creates mdebug output.
  45         set asm-flags "-no-mdebug -I${srcdir}/${subdir} -I${objdir}/${subdir}"
  46         set debug-flags "-gdwarf-2"
  47     }
  48     "*arm-*-*" {
  49         set asm-arch arm
  50     }
  51     "xscale-*-*" {
  52         set asm-arch arm
  53     }
  54     "d10v-*-*" {
  55         set asm-arch d10v
  56     }
  57     "frv-*-*" {
  58         set asm-arch frv
  59     }
  60     "s390-*-*" {
  61         set asm-arch s390
  62     }
  63     "s390x-*-*" {
  64         set asm-arch s390x
  65     }
  66     "x86_64-*-*" {
  67         set asm-arch x86_64
  68         set asm-flags "-I${srcdir}/${subdir} -I${objdir}/${subdir}"
  69         set debug-flags "-gdwarf-2"
  70     }
  71     "i\[3456\]86-*-*" {
  72         set asm-arch i386
  73     }
  74     "m32r*-*" {
  75         set asm-arch m32r
  76         append link-flags "--whole-archive -lgloss --no-whole-archive"
  77     }
  78     "m6811-*-*" {
  79         set asm-arch m68hc11
  80         set asm-flags "-mshort-double -m68hc11 -gdwarf-2 --no-warn -I${srcdir}/${subdir} -I${objdir}/${subdir}"
  81     }
  82     "m6812-*-*" {
  83         set asm-arch m68hc11
  84         set asm-flags "-mshort-double -m68hc12 -gdwarf-2 --no-warn -I${srcdir}/${subdir} -I${objdir}/${subdir}"
  85     }
  86     "mips*-*" {
  87         set asm-arch mips
  88     }
  89     "powerpc*-*" {
  90         set asm-arch powerpc
  91     }
  92     "sh*-*-*" {
  93         set asm-arch sh
  94         set asm-flags "-I${srcdir}/${subdir} -I${objdir}/${subdir}"
  95         set debug-flags "-gdwarf-2"
  96     }
  97     "sparc-*-*" {
  98         set asm-arch sparc
  99     }
 100     "sparc64-*-*" {
 101         set asm-arch sparc64
 102         set asm-flags "-xarch=v9 -I${srcdir}/${subdir} -I${objdir}/${subdir}"
 103         set debug-flags "-gdwarf-2"
 104     }
 105     "xstormy16-*-*" {
 106         set asm-arch xstormy16
 107         set asm-flags "-I${srcdir}/${subdir} -I${objdir}/${subdir}"
 108         set debug-flags "-gdwarf-2"
 109     }
 110     "v850-*-*" {
 111         set asm-arch v850
 112         set gdb_wrapper_initialized 1
 113     }
 114     "m68k-*-*" {
 115         set asm-arch m68k
 116     }
 117     "ia64-*-*" {
 118         set asm-arch ia64
 119         set asm-flags "-I${srcdir}/${subdir} -I${objdir}/${subdir}"
 120         set debug-flags "-gdwarf-2"
 121     }
 122     "hppa*-linux-*" {
 123         set asm-arch pa
 124         set asm-flags "-I${srcdir}/${subdir} -I${objdir}/${subdir}"
 125         set debug-flags "-gdwarf-2"
 126     }
 127 }
 128
 129 if { "${asm-arch}" == "" } {
 130     gdb_suppress_entire_file "Assembly source test -- not implemented for this target."
 131 }
 132
 133 # On NetBSD/ELF we need a special NetBSD-identifying note section.
 134 if { [istarget "*-*-netbsdelf*"]
 135      || [istarget "x86_64-*-netbsd*"] } then {
 136     set asm-note "netbsd"
 137 }
 138
 139 # On OpenBSD/ELF we need a similar note section.  We make no attempt
 140 # of handing a.out here since most OpenBSD/a.out systems use a rather
 141 # outdated assembler that doesn't assemble this test's code anyway.
 142 if { [istarget "*-*-openbsd*"] } then {
 143     set asm-note "openbsd"
 144 }
 145
 146 # Watch out, we are invoking the assembler, but the testsuite sets multilib
 147 # switches according to compiler syntax.  If we pass these options straight
 148 # to the assembler, they won't always make sense.  If we don't pass them to
 149 # the assembler, the final link will complain that the object files were
 150 # built with different defaults.  So no matter what we do, we lose.  We may as
 151 # well get out of this test sooner rather than later.
 152 set dest [target_info name]
 153 if [board_info $dest exists multilib_flags] {
 154         set multilib_flags [board_info $dest multilib_flags]
 155         if { "${multilib_flags}" != "" } {
 156            gdb_suppress_entire_file "Assembly source test -- multilibs not supported by this test."
 157            return;
 158          }
 159 }
 160
 161 set testfile "asm-source"
 162 set binfile ${objdir}/${subdir}/${testfile}
 163 set srcfile1 asmsrc1.s
 164 set srcfile2 asmsrc2.s
 165
 166 remote_exec build "rm -f ${subdir}/arch.inc"
 167 remote_download host ${srcdir}/${subdir}/${asm-arch}.inc ${subdir}/arch.inc
 168 remote_exec build "rm -f ${subdir}/note.inc"
 169 remote_download host ${srcdir}/${subdir}/${asm-note}.inc ${subdir}/note.inc
 170
 171 if { "${asm-flags}" == "" } {
 172     set asm-flags "-I${srcdir}/${subdir} -I${objdir}/${subdir}"
 173     set debug-flags "-gstabs"
 174 }
 175
 176 # Allow the target board to override the debug flags.
 177 if { [board_info $dest exists debug_flags] } then {
 178     set debug-flags "[board_info $dest debug_flags]"
 179 }
 180
 181 # The debug flags are in the format that gcc expects:
 182 # "-gdwarf-2", "-gstabs+", or "-gstabs".  To be compatible with the
 183 # other languages in the test suite, we accept this input format.
 184 # So the user can run the test suite with:
 185 #
 186 #   runtest --target_board unix/gdb:debug_flags=-gdwarf-2
 187 #   make check RUNTESTFLAGS="--target_board unix/gdb:debug_flags=-gdwarf-2"
 188 #
 189 # However, the GNU assembler has different spellings than gcc.
 190 # So I adjust the debug flags here.
 191
 192 # The GNU assembler spells "dwarf-2" as "dwarf2".
 193 regsub "--" "-gdwarf-2" "${debug-flags}" "-gdwarf2" debug-flags
 194
 195 # The GNU assembler before 2.15 did not support "stabs+".
 196 regsub "--" "-gstabs\[+\]" "${debug-flags}" "-gstabs" debug-flags
 197
 198 # The GNU assembler does not support level options like "-g2" or "-g3".
 199 regsub "--" "-g\[0-9\]" "${debug-flags}" "" debug-flags
 200
 201 if {[target_assemble ${srcdir}/${subdir}/${srcfile1} asmsrc1.o "${asm-flags} ${debug-flags}"] != ""} then {
 202      gdb_suppress_entire_file "Testcase compile failed, so all tests in this file will automatically fail."
 203 }
 204 if {[target_assemble ${srcdir}/${subdir}/${srcfile2} asmsrc2.o "${asm-flags} ${debug-flags}"] != ""} then {
 205      gdb_suppress_entire_file "Testcase compile failed, so all tests in this file will automatically fail."
 206 }
 207
 208 # We deliberately don't use gdb_compile here to link together the
 209 # assembled object files.  Using gdb_compile, and therefore the C
 210 # compiler, is conceptually wrong, since we're testing raw assembler
 211 # code here that provides its own startup code.  Using target_link
 212 # also avoids a lot of problems on many systems, most notably on
 213 # *-*-*bsd* and *-*-solaris2*.
 214 if {[target_link "asmsrc1.o asmsrc2.o" "${binfile}" ${link-flags}] != "" } then {
 215      gdb_suppress_entire_file "Testcase compile failed, so all tests in this file will automatically fail."
 216 }
 217
 218 remote_exec build "mv asmsrc1.o asmsrc2.o ${objdir}/${subdir}"
 219
 220
 221 gdb_start
 222 gdb_reinitialize_dir $srcdir/$subdir
 223 gdb_load ${binfile}
 224
 225 #
 226 # Run to `main' where we begin our tests.
 227 #
 228
 229 if ![runto_main] then {
 230     gdb_suppress_tests
 231 }
 232
 233 # Execute the `f' command and see if the result includes source info.
 234 gdb_test "f" "asmsrc1\[.\]s:29.*several_nops" "f at main"
 235
 236 # See if we properly `next' over a macro with several insns.
 237 gdb_test "n" "33\[      \]*.*foo2" "next over macro"
 238
 239 # See if we can properly `step' into a subroutine call.
 240 gdb_test "s" "8\[       \]*.*" "step into foo2"
 241
 242 # Test 'info target', and incidentally capture the entry point address.
 243 set entry_point 0
 244 send_gdb "info target\n"
 245 gdb_expect {
 246     -re "Symbols from .*asm-source.*Entry point: 0x(\[01232456789abcdefABCDEF\]+).*$gdb_prompt $" {
 247         set entry_point $expect_out(1,string)
 248         pass "info target"
 249     }
 250     -re ".*$gdb_prompt $" {
 251         fail "info target"
 252     }
 253     timeout {
 254         fail "info target (timeout)"
 255     }
 256 }
 257
 258 # Capture the start symbol (may be '_start' or 'start')
 259 set entry_symbol ""
 260 send_gdb "info symbol 0x$entry_point\n"
 261 gdb_expect {
 262     -re "info symbol 0x$entry_point\[\r\n\]+(\[^\r\n\]*) in section .*$gdb_prompt $" {
 263         # We match the echoed `info symbol' command here, to help us
 264         # reliably identify the beginning of the start symbol in the
 265         # command's output.  You might think we could just use '^' to
 266         # start matching at the beginning of the line, but
 267         # unfortunately, in Expect, '^' matches the beginning of the
 268         # input that hasn't been matched by any expect clause yet.  If
 269         # every expect clause consumes a complete line, along with its
 270         # terminating CR/LF, this is equivalent to the beginning of a
 271         # line.  But expect clauses that end with `.*' will consume as
 272         # much as happened to arrive from the TTY --- exactly where
 273         # they leave you depends on inter-process timing.  :(
 274         set entry_symbol $expect_out(1,string)
 275         pass "info symbol"
 276     }
 277     -re ".*$gdb_prompt $" {
 278         fail "info symbol"
 279     }
 280     timeout {
 281         fail "info symbol (timeout)"
 282     }
 283 }
 284
 285 # Now try a 'list' from the other source file.
 286 gdb_test "list $entry_symbol" ".*gdbasm_startup.*" "list"
 287
 288 # Now try a source file search
 289 gdb_test "search A routine for foo2 to call" \
 290         "40\[ \t\]+comment \"A routine for foo2 to call.\"" "search"
 291
 292 # See if `f' prints the right source file.
 293 gdb_test "f" ".*asmsrc2\[.\]s:8.*" "f in foo2"
 294
 295 # `next' one insn (or macro) to set up our stackframe (for the following bt).
 296 gdb_test "n" "12\[      \]*.*foo3" "n in foo2"
 297
 298 # See if a simple `bt' prints the right source files and
 299 # doesn't fall off the stack.
 300
 301 gdb_test "bt 10" \
 302         "\#0.*foo2.*asmsrc2\[.\]s:12.*\#1.*main.*asmsrc1\[.\]s:33" \
 303         "bt ALL in foo2"
 304
 305 # See if a capped `bt' prints the right source files.
 306 gdb_test "bt 2" "\#0.*foo2.*asmsrc2\[.\]s:12.*\#1.*main.*asmsrc1\[.\]s:33.*" "bt 2 in foo2"
 307
 308 # Step into another subroutine which lives back in the first source file.
 309 gdb_test "s" "" "s 2"
 310
 311 # Next over insns to set up the stack frame.
 312 gdb_test "n" "" "n 2"
 313
 314 # Now see if a capped `bt' is correct.
 315 gdb_test "bt 3" "\#0.*foo3.*asmsrc1\[.\]s:45.*\#1.*foo2.*asmsrc2\[.\]s:12.*\#2.*main.*asmsrc1\[.\]s:33.*" "bt 3 in foo3"
 316
 317 # Try 'info source' from asmsrc1.s
 318 gdb_test "info source" \
 319         "Current source file is .*asmsrc1.s.*Source language is asm.*" \
 320         "info source asmsrc1.s"
 321
 322 # Try 'finishing' from foo3
 323 gdb_test "finish" "Run till exit from.*\[\r\n\]13\[ \t\]+gdbasm_call foo3" \
 324         "finish from foo3"
 325
 326 # Try 'info source' from asmsrc2.s
 327 gdb_test "info source" \
 328         "Current source file is .*asmsrc2.s.*Source language is asm.*" \
 329         "info source asmsrc2.s"
 330
 331 # Try 'info sources'.  This can produce a lot of output on systems
 332 # with dynamic linking, where the system's shared libc was compiled
 333 # with debugging info; for example, on Linux, this produces 47kb of
 334 # output.  So we consume it as we go.
 335 send_gdb "info sources\n"
 336 set seen_asmsrc_1 0
 337 set seen_asmsrc_2 0
 338 gdb_expect {
 339     -re "^\[^,\]*asmsrc1.s(, |\[\r\n\]+)" {
 340         set seen_asmsrc_1 1
 341         exp_continue
 342     }
 343     -re "^\[^,\]*asmsrc2.s(, |\[\r\n\]+)" {
 344         set seen_asmsrc_2 1
 345         exp_continue
 346     }
 347     -re ", " {
 348         exp_continue
 349     }
 350     -re "$gdb_prompt $" {
 351         if {$seen_asmsrc_1 && $seen_asmsrc_2} {
 352             pass "info sources"
 353         } else {
 354             fail "info sources"
 355         }
 356     }
 357     timeout {
 358             fail "info sources (timeout)"
 359     }
 360 }
 361
 362
 363 # Try 'info line'
 364 gdb_test "info line" \
 365         "Line 13 of.*asmsrc2.s.*starts at.*<foo2+.*> and ends at.*<foo2+.*>." \
 366         "info line"
 367
 368 # Try 'nexting' over next call to foo3
 369 gdb_test "next" "17\[ \t\]+gdbasm_leave" "next over foo3"
 370
 371 # Try 'return' from foo2
 372 gdb_test "return" "\#0  main .*37\[ \t\]+gdbasm_exit0" "return from foo2" \
 373         "Make (foo2|selected stack frame) return now\?.*" "y"
 374
 375 # Disassemble something, check the output
 376 proc test_dis { command var } {
 377     global gdb_prompt
 378     send_gdb "${command}\n"
 379     gdb_expect {
 380         -re "${var}.*:.*(Cannot access|Bad address)" {
 381             # The "disassembler" was only accessing the local
 382             # executable and that would cause attempts to disassemble
 383             # variables to fail (memory not valid).
 384             fail "${command} (memory read error)"
 385         }
 386         -re "${var}.*:.*${gdb_prompt}" {
 387             pass "${command}"
 388         }
 389         timeout {
 390             fail "${command} (timeout)"
 391         }
 392     }
 393 }
 394
 395 # See if we can look at a global variable, three ways
 396 gdb_test "print globalvar" ".* = 11" "look at global variable"
 397 test_dis "x/i &globalvar" "globalvar"
 398 test_dis "disassem &globalvar &globalvar+1" "globalvar"
 399
 400 # See if we can look at a static variable, three ways
 401 gdb_test "print staticvar" ".* = 5" "look at static variable"
 402 test_dis "x/i &staticvar" "staticvar"
 403 test_dis "disassem &staticvar &staticvar+1" "staticvar"
 404
 405 # See if we can look at a static function
 406 gdb_test "disassem foostatic" ".*<foostatic\\+0>:.*End of assembler dump." \
 407         "look at static function"
 408
 409 remote_exec build "rm -f ${subdir}/arch.inc"
 410 remote_exec build "rm -f ${subdir}/note.inc"