gdb/testsuite/configure.ac

   1 #                                                       -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # Copyright 2002-2017 Free Software Foundation, Inc.
   5 #
   6 # This program is free software; you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 3 of the License, or
   9 # (at your option) any later version.
  10 #
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 AC_PREREQ(2.59)
  20 AC_INIT(gdb.base)
  21
  22 AC_CANONICAL_BUILD
  23 AC_CANONICAL_HOST
  24 AC_CANONICAL_TARGET
  25
  26 ACX_NONCANONICAL_TARGET
  27
  28 # Enable gdbtk.
  29 AC_ARG_ENABLE(gdbtk,
  30 [  --enable-gtk            enable gdbtk graphical user interface (GUI)],,
  31   [if test -d $srcdir/../gdbtk && test -d $srcdir/gdb.gdbtk; then
  32     enable_gdbtk=yes
  33   else
  34     enable_gdbtk=no
  35   fi])
  36 # We unconditionally disable gdbtk tests on selected platforms.
  37 case $host_os in
  38   go32* | windows*)
  39     enable_gdbtk=no ;;
  40 esac
  41
  42 # Add gdbtk tests when appropriate.
  43 if test $enable_gdbtk = yes; then
  44    AC_CONFIG_SUBDIRS(gdb.gdbtk)
  45 fi
  46
  47 # Enable shared libraries.
  48 AC_ARG_ENABLE(shared,
  49 [  --enable-shared         build shared libraries [deault=yes]],,
  50   enable_shared=yes)
  51
  52 # If we have shared libraries, try to set RPATH_ENVVAR reasonably,
  53 # such that we can find the shared libraries in the build tree.
  54 if test $enable_shared = no; then
  55   # The variable `RPATH_ENVVAR' itself is not likely to be used on any
  56   # platform.
  57   RPATH_ENVVAR=RPATH_ENVVAR
  58 else
  59   # The variable `LD_LIBRARY_PATH' is used on most platforms.
  60   RPATH_ENVVAR=LD_LIBRARY_PATH
  61   # The following exceptions are taken from Libtool 1.4.3.
  62   case $host_os in
  63     aix*)
  64       if test $host_cpu != ia64; then
  65         RPATH_ENVVAR=LIBPATH
  66       fi ;;
  67     darwin* | rhapsody*)
  68       RPATH_ENVVAR=DYLD_LIBRARY_PATH ;;
  69   esac
  70 fi
  71 AC_SUBST(RPATH_ENVVAR)
  72
  73 AC_CHECK_HEADERS(pthread.h)
  74
  75 AC_EXEEXT
  76
  77 if test "${build}" = "${host}" -a "${host}" = "${target}"; then
  78    case "${host}" in
  79      *gnu*)
  80        EXTRA_RULES=read1
  81        ;;
  82    esac
  83 fi
  84 AC_SUBST(EXTRA_RULES)
  85
  86 # Transform the name of some programs and generate the lib/pdtrace
  87 # test tool.
  88 AC_ARG_PROGRAM
  89 GDB_AC_TRANSFORM(strip, STRIP_TRANSFORM_NAME)
  90 GDB_AC_TRANSFORM(readelf, READELF_TRANSFORM_NAME)
  91 GDB_AC_TRANSFORM(as, GAS_TRANSFORM_NAME)
  92 GDB_AC_TRANSFORM(nm, NM_TRANSFORM_NAME)
  93 AC_CONFIG_FILES([lib/pdtrace], [chmod +x lib/pdtrace])
  94 AC_CONFIG_FILES([Makefile])
  95
  96 AC_OUTPUT