gdb/testsuite/config/gdbserver.exp

   1 # Test framework for GDB (remote protocol) using a "gdbserver",
   2 # ie. a debug agent running as a native process on the same or
   3 # a different host.
   4
   5 #   Copyright 2000 Free Software Foundation, Inc.
   6
   7 # This program is free software; you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 2 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program; if not, write to the Free Software
  19 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  20
  21 # Please email any bugs, comments, and/or additions to this file to:
  22 # bug-gdb@prep.ai.mit.edu
  23
  24 # This file was written by Michael Snyder. (msnyder@redhat.com)
  25
  26 #
  27 # This module to be used for testing gdb with a "gdbserver"
  28 # built either from libremote or from gdb/gdbserver.
  29 #
  30
  31 # Load the basic testing library, and the remote stuff.
  32 load_lib ../config/monitor.exp
  33
  34 #
  35 # To be addressed or set in your baseboard config file:
  36 #
  37 #   set_board_info gdb_protocol "remote"
  38 #       Unles you have a gdbserver that uses a different protocol...
  39 #
  40 #   set_board_info use_gdb_stub 1
  41 #       This tells the rest of the test suite not to do things
  42 #       like "run" which don't work well on remote targets.
  43 #
  44 #   set_board_info gdb,do_reload_on_run 1
  45 #       Unles you have a gdbserver that can handle multiple sessions.
  46 #
  47 #   set_board_info noargs 1
  48 #       At present there is no provision in the remote protocol
  49 #       for passing arguments.  This test framework does not
  50 #       address the issue, so it's best to set this variable
  51 #       in your baseboard configuration file.
  52 #       FIXME: there's no reason why the test harness couldn't
  53 #       pass commandline args when it spawns gdbserver.
  54 #
  55 #   set_board_info gdb,noinferiorio 1
  56 #       Neither the traditional gdbserver nor the one in libremote
  57 #       can presently capture stdout and relay it to GDB via the
  58 #       'O' packet.  This means that tests involving printf will
  59 #       fail unles you set this varibale in your baseboard
  60 #       configuration file.
  61 #
  62 #   set_board_info gdb,no_hardware_watchpoints 1
  63 #       Unles you have a gdbserver that supports hardware watchpoints.
  64 #       FIXME: gdb should detect if the target doesn't support them,
  65 #       and fall back to using software watchpoints.
  66 #
  67 #   set_board_info gdb_server_prog
  68 #       This will be the path to the gdbserver program you want to test.
  69 #       Defaults to "gdbserver".
  70 #
  71 #   set_board_info sockethost
  72 #       The name of the host computer whose socket is being used.
  73 #       Defaults to "localhost".  Note: old gdbserver requires
  74 #       that you define this, but libremote/gdbserver does not.
  75 #
  76 #   set_board_info socketport
  77 #       Port id to use for socket connection.  If not set explicitly,
  78 #       it will start at "2345" and increment for each use.
  79 #
  80
  81
  82
  83 #
  84 # gdb_load -- load a file into the debugger.
  85 #             return a -1 if anything goes wrong.
  86 #
  87
  88 global server_exec;
  89 global portnum;
  90 set portnum "2345";
  91
  92 proc gdb_load { args } {
  93     global server_exec;
  94     global portnum;
  95     global verbose;
  96     global gdb_prompt;
  97
  98     # Port id -- either specified in baseboard file, or managed here.
  99     if [target_info exists gdb,socketport] {
 100         set portnum [target_info gdb,socketport];
 101     } else {
 102         # Bump the port number to avoid conflicts with hung ports.
 103         incr portnum;
 104     }
 105
 106     # Extract the local and remote host ids from the target board struct.
 107
 108     if [target_info exists sockethost] {
 109         set debughost  [target_info sockethost];
 110     } else {
 111         set debughost "localhost:";
 112     }
 113     # Extract the protocol
 114     if [target_info exists gdb_protocol] {
 115         set protocol [target_info gdb_protocol];
 116     } else {
 117         set protocol "remote";
 118     }
 119
 120     # Extract the name of the gdbserver, if known (default 'gdbserver').
 121     if [target_info exists gdb_server_prog] {
 122         set gdbserver [target_info gdb_server_prog];
 123     } else {
 124         set gdbserver "gdbserver";
 125     }
 126     # Extract the socket hostname
 127     if [target_info exists sockethost] {
 128         set sockethost [target_info sockethost];
 129     } else {
 130         set sockethost ""
 131     }
 132
 133     # Export the host:port pair.
 134     set gdbport $debughost$portnum;
 135
 136     if { $args == "" || $args == "{}" } {
 137         if [info exists server_exec] {
 138             set args $server_exec;
 139         } else {
 140             send_gdb "info files\n";
 141             gdb_expect 30 {
 142                 -re "Symbols from \"(\[^\"\]+)\"" {
 143                     set args $expect_out(1,string);
 144                     exp_continue;
 145                 }
 146                 -re "Local exec file:\[\r\n\]+\[ \t\]*`(\[^'\]+)'," {
 147                     set args $expect_out(1,string);
 148                     exp_continue;
 149                 }
 150                 -re "$gdb_prompt $" { }
 151             }
 152         }
 153     }
 154
 155     # remember new exec file
 156     set server_exec $args;
 157
 158     # Fire off the debug agent
 159     if [target_info exists gdb_server_args] {
 160         # This flavour of gdbserver takes as arguments those specified
 161         # in the board configuration file
 162         set custom_args [target_info gdb_server_args];
 163         remote_spawn host \
 164                "$gdbserver $custom_args >& /dev/null < /dev/null &" \
 165                writeonly
 166     } else {
 167         # This flavour of gdbserver takes as arguments the port information
 168         # and the name of the executable file to be debugged.
 169         remote_spawn host \
 170             "$gdbserver $sockethost$portnum $args >& /dev/null < /dev/null &" \
 171             writeonly
 172     }
 173     # Give it a little time to establish
 174     sleep 2
 175
 176     # tell gdb what file we are debugging
 177     if [gdb_file_cmd $args] {
 178         return -1;
 179     }
 180
 181     # attach to the "serial port"
 182     gdb_target_cmd $protocol $gdbport;
 183
 184     # do the real load if needed
 185     if [target_info exists gdb_server_do_load] {
 186         send_gdb "load\n"
 187         set timeout 2400
 188         verbose "Timeout is now $timeout seconds" 2
 189         gdb_expect {
 190             -re ".*$gdb_prompt $" {
 191                 if $verbose>1 then {
 192                     send_user "Loaded $arg into $GDB\n"
 193                 }
 194                 set timeout 30
 195                 verbose "Timeout is now $timeout seconds" 2
 196                 return 1
 197             }
 198             -re "$gdb_prompt $"     {
 199                 if $verbose>1 then {
 200                     perror "GDB couldn't load."
 201                 }
 202             }
 203             timeout {
 204                 if $verbose>1 then {
 205                     perror "Timed out trying to load $arg."
 206                 }
 207             }
 208         }
 209     }
 210
 211     return 0;
 212 }