gdb/selftest.m4

   1 dnl Copyright (C) 2018-2019 Free Software Foundation, Inc.
   2 dnl
   3 dnl This file is part of GDB.
   4 dnl
   5 dnl This program is free software; you can redistribute it and/or modify
   6 dnl it under the terms of the GNU General Public License as published by
   7 dnl the Free Software Foundation; either version 3 of the License, or
   8 dnl (at your option) any later version.
   9 dnl
  10 dnl This program is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 dnl GNU General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU General Public License
  16 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  17
  18 dnl GDB_AC_SELFTEST(ACTION-IF-ENABLED)
  19 dnl
  20 dnl Enable the unit/self tests if needed.  If they are enabled, AC_DEFINE
  21 dnl the GDB_SELF_TEST macro, and execute ACTION-IF-ENABLED.
  22
  23 AC_DEFUN([GDB_AC_SELFTEST],[
  24 # Check whether we will enable the inclusion of unit tests when
  25 # compiling GDB.
  26 #
  27 # The default value of this option changes depending whether we're on
  28 # development mode (in which case it's "true") or not (in which case
  29 # it's "false").
  30 AC_ARG_ENABLE(unit-tests,
  31 AS_HELP_STRING([--enable-unit-tests],
  32 [Enable the inclusion of unit tests when compiling GDB]),
  33 [case "${enableval}" in
  34   yes)  enable_unittests=true  ;;
  35   no)   enable_unittests=false ;;
  36   *)    AC_MSG_ERROR(
  37 [bad value ${enableval} for --{enable,disable}-unit-tests option]) ;;
  38 esac], [enable_unittests=$development])
  39
  40 if $enable_unittests; then
  41   AC_DEFINE(GDB_SELF_TEST, 1,
  42             [Define if self-testing features should be enabled])
  43   $1
  44 fi
  45 ])