gdb/gdbserver/configure.ac

   1 dnl Autoconf configure script for GDB server.
   2 dnl Copyright (C) 2000, 2002, 2003, 2004, 2005, 2006
   3 dnl Free Software Foundation, Inc.
   4 dnl
   5 dnl This file is part of GDB.
   6 dnl
   7 dnl This program is free software; you can redistribute it and/or modify
   8 dnl it under the terms of the GNU General Public License as published by
   9 dnl the Free Software Foundation; either version 2 of the License, or
  10 dnl (at your option) any later version.
  11 dnl
  12 dnl This program is distributed in the hope that it will be useful,
  13 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 dnl GNU General Public License for more details.
  16 dnl
  17 dnl You should have received a copy of the GNU General Public License
  18 dnl along with this program; if not, write to the Free Software
  19 dnl Foundation, Inc., 51 Franklin Street, Fifth Floor,
  20 dnl Boston, MA 02110-1301, USA.
  21
  22 dnl Process this file with autoconf to produce a configure script.
  23
  24 AC_PREREQ(2.59)dnl
  25
  26 AC_INIT(server.c)
  27 AC_CONFIG_HEADER(config.h:config.in)
  28
  29 AC_PROG_CC
  30
  31 AC_CANONICAL_SYSTEM
  32
  33 AC_PROG_INSTALL
  34
  35 AC_ARG_PROGRAM
  36
  37 AC_HEADER_STDC
  38
  39 AC_CHECK_HEADERS(sgtty.h termio.h termios.h sys/reg.h string.h dnl
  40                  proc_service.h sys/procfs.h thread_db.h linux/elf.h dnl
  41                  stdlib.h unistd.h)
  42
  43 AC_CHECK_DECLS(strerror)
  44
  45 AC_CHECK_TYPES(socklen_t, [], [],
  46 [#include <sys/types.h>
  47 #include <sys/socket.h>
  48 ])
  49 . ${srcdir}/configure.srv
  50
  51 if test "${srv_linux_usrregs}" = "yes"; then
  52   AC_DEFINE(HAVE_LINUX_USRREGS, 1,
  53             [Define if the target supports PTRACE_PEEKUSR for register ]
  54             [access.])
  55 fi
  56
  57 if test "${srv_linux_regsets}" = "yes"; then
  58   AC_DEFINE(HAVE_LINUX_REGSETS, 1,
  59             [Define if the target supports register sets.])
  60
  61   AC_MSG_CHECKING(for PTRACE_GETREGS)
  62   AC_CACHE_VAL(gdbsrv_cv_have_ptrace_getregs,
  63   [AC_TRY_COMPILE([#include <sys/ptrace.h>],
  64                   [PTRACE_GETREGS;],
  65                   [gdbsrv_cv_have_ptrace_getregs=yes],
  66                   [gdbsrv_cv_have_ptrace_getregs=no])])
  67   AC_MSG_RESULT($gdbsrv_cv_have_ptrace_getregs)
  68   if test "${gdbsrv_cv_have_ptrace_getregs}" = "yes"; then
  69     AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
  70               [Define if the target supports PTRACE_GETREGS for register ]
  71               [access.])
  72   fi
  73
  74   AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
  75   AC_CACHE_VAL(gdbsrv_cv_have_ptrace_getfpxregs,
  76   [AC_TRY_COMPILE([#include <sys/ptrace.h>],
  77                   [PTRACE_GETFPXREGS;],
  78                   [gdbsrv_cv_have_ptrace_getfpxregs=yes],
  79                   [gdbsrv_cv_have_ptrace_getfpxregs=no])])
  80   AC_MSG_RESULT($gdbsrv_cv_have_ptrace_getfpxregs)
  81   if test "${gdbsrv_cv_have_ptrace_getfpxregs}" = "yes"; then
  82     AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
  83               [Define if the target supports PTRACE_GETFPXREGS for extended ]
  84               [register access.])
  85   fi
  86 fi
  87
  88 if test "$ac_cv_header_sys_procfs_h" = yes; then
  89   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
  90   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
  91   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
  92   BFD_HAVE_SYS_PROCFS_TYPE(elf_fpregset_t)
  93 fi
  94
  95 srv_thread_depfiles=
  96 srv_libs=
  97 USE_THREAD_DB=
  98
  99 if test "$srv_linux_thread_db" = "yes"; then
 100   SRV_CHECK_THREAD_DB
 101   if test "$srv_cv_thread_db" = no; then
 102     AC_WARN([Could not find libthread_db.])
 103     AC_WARN([Disabling thread support in gdbserver.])
 104     srv_linux_thread_db=no
 105   else
 106     srv_libs="$srv_cv_thread_db"
 107   fi
 108   old_LDFLAGS="$LDFLAGS"
 109   LDFLAGS="$LDFLAGS -rdynamic"
 110   AC_TRY_LINK([], [], [RDYNAMIC=-rdynamic], [RDYNAMIC=])
 111   AC_SUBST(RDYNAMIC)
 112   LDFLAGS="$old_LDFLAGS"
 113 fi
 114
 115 if test "$srv_linux_thread_db" = "yes"; then
 116   srv_thread_depfiles="thread-db.o proc-service.o"
 117   USE_THREAD_DB="-DUSE_THREAD_DB"
 118   AC_CACHE_CHECK([for TD_VERSION], gdbsrv_cv_have_td_version,
 119   [AC_TRY_COMPILE([#include <thread_db.h>], [TD_VERSION;],
 120                   [gdbsrv_cv_have_td_version=yes],
 121                   [gdbsrv_cv_have_td_version=no])])
 122   if test $gdbsrv_cv_have_td_version = yes; then
 123     AC_DEFINE(HAVE_TD_VERSION, 1, [Define if TD_VERSION is available.])
 124   fi
 125 fi
 126
 127 GDBSERVER_DEPFILES="$srv_regobj $srv_tgtobj $srv_thread_depfiles"
 128 GDBSERVER_LIBS="$srv_libs"
 129
 130 AC_SUBST(GDBSERVER_DEPFILES)
 131 AC_SUBST(GDBSERVER_LIBS)
 132 AC_SUBST(USE_THREAD_DB)
 133
 134 AC_OUTPUT(Makefile,
 135 [case x$CONFIG_HEADERS in
 136 xconfig.h:config.in)
 137 echo > stamp-h ;;
 138 esac
 139 ])