gdb/gdbserver/configure.ac

   1 dnl Autoconf configure script for GDB server.
   2 dnl Copyright (C) 2000-2018 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Process this file with autoconf to produce a configure script.
  20
  21 AC_INIT(server.c)
  22 AC_CONFIG_HEADER(config.h:config.in)
  23
  24 AM_MAINTAINER_MODE
  25
  26 AC_PROG_CC
  27 AC_PROG_CXX
  28 AC_GNU_SOURCE
  29 AC_SYS_LARGEFILE
  30
  31 AC_CANONICAL_SYSTEM
  32
  33 AC_PROG_INSTALL
  34 AC_CHECK_TOOL(AR, ar)
  35 AC_PROG_RANLIB
  36
  37 AC_ARG_PROGRAM
  38
  39 # We require a C++11 compiler.  Check if one is available, and if
  40 # necessary, set CXX_DIALECT to some -std=xxx switch.
  41 AX_CXX_COMPILE_STDCXX(11, , mandatory)
  42
  43 AC_HEADER_STDC
  44
  45 # Set the 'development' global.
  46 . $srcdir/../../bfd/development.sh
  47
  48 # Enable -lmcheck by default (it provides cheap-enough memory
  49 # mangling), but turn it off for releases.
  50 if $development; then
  51   libmcheck_default=yes
  52 else
  53   libmcheck_default=no
  54 fi
  55 GDB_AC_LIBMCHECK(${libmcheck_default})
  56
  57 if $development; then
  58   srv_selftest_objs="common/selftest.o"
  59   AC_DEFINE(GDB_SELF_TEST, 1,
  60             [Define if self-testing features should be enabled])
  61 fi
  62
  63 ACX_NONCANONICAL_TARGET
  64 ACX_NONCANONICAL_HOST
  65
  66 # Dependency checking.
  67 ZW_CREATE_DEPDIR
  68
  69 # Create sub-directories for objects and dependencies.
  70 CONFIG_SRC_SUBDIR="arch common"
  71 AC_SUBST(CONFIG_SRC_SUBDIR)
  72
  73 AC_CONFIG_COMMANDS([gdbdepdir],[
  74   for subdir in ${CONFIG_SRC_SUBDIR}
  75   do
  76       $SHELL $ac_aux_dir/mkinstalldirs $subdir/$DEPDIR
  77   done],
  78   [ac_aux_dir=$ac_aux_dir DEPDIR=$DEPDIR CONFIG_SRC_SUBDIR="$CONFIG_SRC_SUBDIR"])
  79
  80 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  81
  82 gnulib_extra_configure_args=
  83 # If large-file support is disabled, make sure gnulib does the same.
  84 if test "$enable_largefile" = no; then
  85 gnulib_extra_configure_args="$gnulib_extra_configure_args --disable-largefile"
  86 fi
  87
  88 # Configure gnulib.  We can't use AC_CONFIG_SUBDIRS as that'd expect
  89 # to find the the source subdir to be configured directly under
  90 # gdbserver/.  We need to build gnulib under some other directory not
  91 # "gnulib", to avoid the problem of both GDB and GDBserver wanting to
  92 # build it in the same directory, when building in the source dir.
  93 ACX_CONFIGURE_DIR(["../gnulib"], ["build-gnulib-gdbserver"],
  94                   ["$gnulib_extra_configure_args"])
  95
  96 ACX_CONFIGURE_DIR(["../../libiberty"], ["build-libiberty-gdbserver"])
  97
  98 AC_CHECK_HEADERS(termios.h sys/reg.h string.h dnl
  99                  proc_service.h sys/procfs.h linux/elf.h dnl
 100                  fcntl.h signal.h sys/file.h dnl
 101                  sys/ioctl.h netinet/in.h sys/socket.h netdb.h dnl
 102                  netinet/tcp.h arpa/inet.h)
 103 AC_FUNC_FORK
 104 AC_CHECK_FUNCS(getauxval pread pwrite pread64 setns)
 105
 106 GDB_AC_COMMON
 107
 108 # Check the return and argument types of ptrace.
 109 GDB_AC_PTRACE
 110
 111 # Check for UST
 112 ustlibs=""
 113 ustinc=""
 114
 115 AC_ARG_WITH(ust, [  --with-ust=PATH       Specify prefix directory for the installed UST package
 116                           Equivalent to --with-ust-include=PATH/include
 117                           plus --with-ust-lib=PATH/lib])
 118 AC_ARG_WITH(ust_include, [  --with-ust-include=PATH Specify directory for installed UST include files])
 119 AC_ARG_WITH(ust_lib, [  --with-ust-lib=PATH   Specify the directory for the installed UST library])
 120
 121 case $with_ust in
 122   no)
 123     ustlibs=
 124     ustinc=
 125     ;;
 126   "" | yes)
 127     ustlibs=" -lust "
 128     ustinc=""
 129     ;;
 130   *)
 131     ustlibs="-L$with_ust/lib -lust"
 132     ustinc="-I$with_ust/include "
 133     ;;
 134 esac
 135 if test "x$with_ust_include" != x; then
 136   ustinc="-I$with_ust_include "
 137 fi
 138 if test "x$with_ust_lib" != x; then
 139   ustlibs="-L$with_ust_lib -lust"
 140 fi
 141
 142 if test "x$with_ust" != "xno"; then
 143   saved_CFLAGS="$CFLAGS"
 144   CFLAGS="$CFLAGS $ustinc"
 145   AC_MSG_CHECKING([for ust])
 146   AC_TRY_COMPILE([
 147 #define CONFIG_UST_GDB_INTEGRATION
 148 #include <ust/ust.h>
 149   ],[],
 150   [AC_MSG_RESULT([yes]); AC_DEFINE(HAVE_UST, 1, [Define if UST is available])],
 151   [AC_MSG_RESULT([no]); ustlibs= ; ustinc= ])
 152   CFLAGS="$saved_CFLAGS"
 153 fi
 154
 155 # Flags needed for UST
 156 AC_SUBST(ustlibs)
 157 AC_SUBST(ustinc)
 158
 159 AM_GDB_WARNINGS
 160 dnl The codebase isn't clean yet with this flag.
 161 case " $WARN_CFLAGS " in
 162 *" -Wmissing-prototypes "*)
 163   WARN_CFLAGS="$WARN_CFLAGS -Wno-missing-prototypes"
 164   ;;
 165 esac
 166
 167 dnl dladdr is glibc-specific.  It is used by thread-db.c but only for
 168 dnl debugging messages.  It lives in -ldl which is handled below so we don't
 169 dnl use AC_CHECK_LIB (or AC_SEARCH_LIBS) here.  Instead we just temporarily
 170 dnl augment LIBS.
 171 old_LIBS="$LIBS"
 172 LIBS="$LIBS -ldl"
 173 AC_CHECK_FUNCS(dladdr)
 174 LIBS="$old_LIBS"
 175
 176 libiberty_INIT
 177
 178 AC_CHECK_DECLS([strerror, perror, vasprintf, vsnprintf])
 179
 180 AC_CHECK_MEMBERS([struct stat.st_blocks, struct stat.st_blksize])
 181
 182 # See if <sys/user.h> supports the %fs_base and %gs_bas amd64 segment registers.
 183 # Older amd64 Linux's don't have the fs_base and gs_base members of
 184 # `struct user_regs_struct'.
 185 AC_CHECK_MEMBERS([struct user_regs_struct.fs_base, struct user_regs_struct.gs_base],
 186      [], [], [#include <sys/types.h>
 187 #include <sys/user.h>])
 188
 189
 190 AC_CHECK_TYPES(socklen_t, [], [],
 191 [#include <sys/types.h>
 192 #include <sys/socket.h>
 193 ])
 194
 195 case "${target}" in
 196   *-android*)
 197     # Starting with NDK version 9, <elf.h> actually includes definitions
 198     # of Elf32_auxv_t and Elf64_auxv_t. But sadly, <elf.h> includes
 199     # <sys/exec_elf.h> which defines some of the ELF types incorrectly,
 200     # leading to conflicts with the defintions from <linux/elf.h>.
 201     # This makes it impossible for us to include both <elf.h> and
 202     # <linux/elf.h>, which means that, in practice, we do not have
 203     # access to Elf32_auxv_t and Elf64_auxv_t on this platform.
 204     # Therefore, do not try to auto-detect availability, as it would
 205     # get it wrong on this platform.
 206     ;;
 207   *)
 208     AC_CHECK_TYPES([Elf32_auxv_t, Elf64_auxv_t], [], [],
 209     #include <elf.h>
 210     )
 211 esac
 212
 213 ACX_PKGVERSION([GDB])
 214 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 215 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 216 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 217
 218 # Check for various supplementary target information (beyond the
 219 # triplet) which might affect the choices in configure.srv.
 220 case "${target}" in
 221 changequote(,)dnl
 222   i[34567]86-*-linux*)
 223 changequote([,])dnl
 224     AC_CACHE_CHECK([if building for x86-64], [gdb_cv_i386_is_x86_64],
 225                    [save_CPPFLAGS="$CPPFLAGS"
 226                     CPPFLAGS="$CPPFLAGS $CFLAGS"
 227                     AC_EGREP_CPP([got it], [
 228 #if __x86_64__
 229 got it
 230 #endif
 231                  ], [gdb_cv_i386_is_x86_64=yes],
 232                     [gdb_cv_i386_is_x86_64=no])
 233                     CPPFLAGS="$save_CPPFLAGS"])
 234     ;;
 235
 236   x86_64-*-linux*)
 237     AC_CACHE_CHECK([if building for x32], [gdb_cv_x86_is_x32],
 238                    [save_CPPFLAGS="$CPPFLAGS"
 239                     CPPFLAGS="$CPPFLAGS $CFLAGS"
 240                     AC_EGREP_CPP([got it], [
 241 #if __x86_64__ && __ILP32__
 242 got it
 243 #endif
 244                  ], [gdb_cv_x86_is_x32=yes],
 245                     [gdb_cv_x86_is_x32=no])
 246                     CPPFLAGS="$save_CPPFLAGS"])
 247     ;;
 248
 249   m68k-*-*)
 250     AC_CACHE_CHECK([if building for Coldfire], [gdb_cv_m68k_is_coldfire],
 251                    [save_CPPFLAGS="$CPPFLAGS"
 252                     CPPFLAGS="$CPPFLAGS $CFLAGS"
 253                     AC_EGREP_CPP([got it], [
 254 #ifdef __mcoldfire__
 255 got it
 256 #endif
 257                  ], [gdb_cv_m68k_is_coldfire=yes],
 258                     [gdb_cv_m68k_is_coldfire=no])
 259                     CPPFLAGS="$save_CPPFLAGS"])
 260     ;;
 261 esac
 262
 263 . ${srcdir}/configure.srv
 264
 265 # Add in the common host objects.
 266 . ${srcdir}/../common/common.host
 267 srv_host_obs="$common_host_obs"
 268
 269 if test "${srv_mingwce}" = "yes"; then
 270   LIBS="$LIBS -lws2"
 271 elif test "${srv_mingw}" = "yes"; then
 272   LIBS="$LIBS -lws2_32"
 273 elif test "${srv_qnx}" = "yes"; then
 274   LIBS="$LIBS -lsocket"
 275 elif test "${srv_lynxos}" = "yes"; then
 276   LIBS="$LIBS -lnetinet"
 277 fi
 278
 279 if test "${srv_mingw}" = "yes"; then
 280   AC_DEFINE(USE_WIN32API, 1,
 281             [Define if we should use the Windows API, instead of the
 282              POSIX API.  On Windows, we use the Windows API when
 283              building for MinGW, but the POSIX API when building
 284              for Cygwin.])
 285 fi
 286
 287 if test "${srv_linux_usrregs}" = "yes"; then
 288   AC_DEFINE(HAVE_LINUX_USRREGS, 1,
 289             [Define if the target supports PTRACE_PEEKUSR for register ]
 290             [access.])
 291 fi
 292
 293 if test "${srv_linux_regsets}" = "yes"; then
 294   AC_DEFINE(HAVE_LINUX_REGSETS, 1,
 295             [Define if the target supports register sets.])
 296
 297   AC_MSG_CHECKING(for PTRACE_GETREGS)
 298   AC_CACHE_VAL(gdbsrv_cv_have_ptrace_getregs,
 299   [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 300                   [PTRACE_GETREGS;],
 301                   [gdbsrv_cv_have_ptrace_getregs=yes],
 302                   [gdbsrv_cv_have_ptrace_getregs=no])])
 303   AC_MSG_RESULT($gdbsrv_cv_have_ptrace_getregs)
 304   if test "${gdbsrv_cv_have_ptrace_getregs}" = "yes"; then
 305     AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
 306               [Define if the target supports PTRACE_GETREGS for register ]
 307               [access.])
 308   fi
 309
 310   AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
 311   AC_CACHE_VAL(gdbsrv_cv_have_ptrace_getfpxregs,
 312   [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 313                   [PTRACE_GETFPXREGS;],
 314                   [gdbsrv_cv_have_ptrace_getfpxregs=yes],
 315                   [gdbsrv_cv_have_ptrace_getfpxregs=no])])
 316   AC_MSG_RESULT($gdbsrv_cv_have_ptrace_getfpxregs)
 317   if test "${gdbsrv_cv_have_ptrace_getfpxregs}" = "yes"; then
 318     AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
 319               [Define if the target supports PTRACE_GETFPXREGS for extended ]
 320               [register access.])
 321   fi
 322 fi
 323
 324 if test "${srv_linux_btrace}" = "yes"; then
 325   AC_DEFINE(HAVE_LINUX_BTRACE, 1,
 326             [Define if the target supports branch tracing.])
 327 fi
 328
 329 if test "$ac_cv_header_sys_procfs_h" = yes; then
 330   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
 331   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
 332   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
 333   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
 334   BFD_HAVE_SYS_PROCFS_TYPE(elf_fpregset_t)
 335 fi
 336
 337 dnl Some systems (e.g., Android) have lwpid_t defined in libthread_db.h.
 338 if test "$bfd_cv_have_sys_procfs_type_lwpid_t" != yes; then
 339   GDBSERVER_HAVE_THREAD_DB_TYPE(lwpid_t)
 340 fi
 341
 342 dnl Some systems (e.g., Android) have psaddr_t defined in libthread_db.h.
 343 if test "$bfd_cv_have_sys_procfs_type_psaddr_t" != yes; then
 344   GDBSERVER_HAVE_THREAD_DB_TYPE(psaddr_t)
 345 fi
 346
 347 dnl Check for libdl, but do not add it to LIBS as only gdbserver
 348 dnl needs it (and gdbreplay doesn't).
 349 old_LIBS="$LIBS"
 350 AC_CHECK_LIB(dl, dlopen)
 351 LIBS="$old_LIBS"
 352
 353 srv_thread_depfiles=
 354 srv_libs=
 355
 356 if test "$srv_linux_thread_db" = "yes"; then
 357   if test "$ac_cv_lib_dl_dlopen" = "yes"; then
 358     srv_libs="-ldl"
 359     AC_MSG_CHECKING(for the dynamic export flag)
 360     old_LDFLAGS="$LDFLAGS"
 361     # Older GNU ld supports --export-dynamic but --dynamic-list may not be
 362     # supported there.
 363     RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
 364     LDFLAGS="$LDFLAGS $RDYNAMIC"
 365     AC_TRY_LINK([], [],
 366                 [found="-Wl,--dynamic-list"
 367                  RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'],
 368                 [RDYNAMIC="-rdynamic"
 369                  LDFLAGS="$old_LDFLAGS $RDYNAMIC"
 370                  AC_TRY_LINK([], [],
 371                              [found="-rdynamic"],
 372                              [found="no"
 373                               RDYNAMIC=""])])
 374     AC_SUBST(RDYNAMIC)
 375     LDFLAGS="$old_LDFLAGS"
 376     AC_MSG_RESULT($found)
 377   else
 378     srv_libs="-lthread_db"
 379   fi
 380
 381   srv_thread_depfiles="thread-db.o proc-service.o"
 382   AC_DEFINE(USE_THREAD_DB, 1, [Define if we should use libthread_db.])
 383   AC_CACHE_CHECK([for TD_VERSION], gdbsrv_cv_have_td_version,
 384   [AC_TRY_COMPILE([#include <thread_db.h>], [TD_VERSION;],
 385                   [gdbsrv_cv_have_td_version=yes],
 386                   [gdbsrv_cv_have_td_version=no])])
 387   if test $gdbsrv_cv_have_td_version = yes; then
 388     AC_DEFINE(HAVE_TD_VERSION, 1, [Define if TD_VERSION is available.])
 389   fi
 390 fi
 391
 392 AC_ARG_WITH(libthread-db,
 393 AS_HELP_STRING([--with-libthread-db=PATH], [use given libthread_db directly]),
 394 [srv_libthread_db_path="${withval}"
 395   srv_libs="$srv_libthread_db_path"
 396 ])
 397
 398 if test "$srv_libs" != "" -a "$srv_libs" != "-ldl"; then
 399   AC_DEFINE(USE_LIBTHREAD_DB_DIRECTLY, 1, [Define if we should use libthread_db directly.])
 400 fi
 401
 402 if test "$srv_xmlfiles" != ""; then
 403   srv_xmlbuiltin="xml-builtin.o"
 404   AC_DEFINE(USE_XML, 1, [Define if an XML target description is available.])
 405
 406   tmp_xmlfiles=$srv_xmlfiles
 407   srv_xmlfiles=""
 408   for f in $tmp_xmlfiles; do
 409     srv_xmlfiles="$srv_xmlfiles \$(XML_DIR)/$f"
 410   done
 411 fi
 412
 413 GDBSERVER_DEPFILES="$srv_regobj $srv_tgtobj $srv_hostio_err_objs $srv_thread_depfiles $srv_host_obs $srv_selftest_objs"
 414 GDBSERVER_LIBS="$srv_libs"
 415
 416 dnl Check whether the target supports __sync_*_compare_and_swap.
 417 AC_CACHE_CHECK([whether the target supports __sync_*_compare_and_swap],
 418                 gdbsrv_cv_have_sync_builtins, [
 419 AC_TRY_LINK([], [int foo, bar; bar = __sync_val_compare_and_swap(&foo, 0, 1);],
 420                 gdbsrv_cv_have_sync_builtins=yes,
 421                 gdbsrv_cv_have_sync_builtins=no)])
 422 if test $gdbsrv_cv_have_sync_builtins = yes; then
 423   AC_DEFINE(HAVE_SYNC_BUILTINS, 1,
 424     [Define to 1 if the target supports __sync_*_compare_and_swap])
 425 fi
 426
 427 dnl Check for -fvisibility=hidden support in the compiler.
 428 saved_cflags="$CFLAGS"
 429 CFLAGS="$CFLAGS -fvisibility=hidden"
 430 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])],
 431                         [gdbsrv_cv_have_visibility_hidden=yes],
 432                         [gdbsrv_cv_have_visibility_hidden=no])
 433 CFLAGS="$saved_cflags"
 434
 435 dnl Check if we can disable the virtual address space randomization.
 436 dnl The functionality of setarch -R.
 437 AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>])
 438 define([PERSONALITY_TEST], [AC_LANG_PROGRAM([#include <sys/personality.h>], [
 439 #      if !HAVE_DECL_ADDR_NO_RANDOMIZE
 440 #       define ADDR_NO_RANDOMIZE 0x0040000
 441 #      endif
 442        /* Test the flag could be set and stays set.  */
 443        personality (personality (0xffffffff) | ADDR_NO_RANDOMIZE);
 444        if (!(personality (personality (0xffffffff)) & ADDR_NO_RANDOMIZE))
 445            return 1])])
 446 AC_RUN_IFELSE([PERSONALITY_TEST],
 447               [gdbsrv_cv_have_personality=true],
 448               [gdbsrv_cv_have_personality=false],
 449               [AC_LINK_IFELSE([PERSONALITY_TEST],
 450                               [gdbsrv_cv_have_personality=true],
 451                               [gdbsrv_cv_have_personality=false])])
 452 if $gdbsrv_cv_have_personality
 453 then
 454     AC_DEFINE([HAVE_PERSONALITY], 1,
 455               [Define if you support the personality syscall.])
 456 fi
 457
 458
 459 IPA_DEPFILES=""
 460 extra_libraries=""
 461
 462 # check whether to enable the inprocess agent
 463 if test "$ipa_obj" != "" \
 464    -a "$gdbsrv_cv_have_sync_builtins" = yes \
 465    -a "$gdbsrv_cv_have_visibility_hidden" = yes; then
 466    have_ipa=true
 467 else
 468    have_ipa=false
 469 fi
 470
 471 AC_ARG_ENABLE(inprocess-agent,
 472 AS_HELP_STRING([--enable-inprocess-agent], [inprocess agent]),
 473 [case "$enableval" in
 474   yes) want_ipa=true ;;
 475   no) want_ipa=false ;;
 476   *) AC_MSG_ERROR([bad value $enableval for inprocess-agent]) ;;
 477 esac],
 478 [want_ipa=$have_ipa])
 479
 480 if $want_ipa ; then
 481    if $have_ipa ; then
 482      IPA_DEPFILES="$ipa_obj"
 483      extra_libraries="$extra_libraries libinproctrace.so"
 484    else
 485      AC_MSG_ERROR([inprocess agent not supported for this target])
 486    fi
 487 fi
 488
 489 AC_SUBST(GDBSERVER_DEPFILES)
 490 AC_SUBST(GDBSERVER_LIBS)
 491 AC_SUBST(srv_xmlbuiltin)
 492 AC_SUBST(srv_xmlfiles)
 493 AC_SUBST(IPA_DEPFILES)
 494 AC_SUBST(extra_libraries)
 495
 496 GNULIB=build-gnulib-gdbserver/import
 497
 498 GNULIB_STDINT_H=
 499 if test x"$STDINT_H" != x; then
 500   GNULIB_STDINT_H=$GNULIB/$STDINT_H
 501 fi
 502 AC_SUBST(GNULIB_STDINT_H)
 503
 504 AC_CONFIG_FILES([Makefile],
 505 [case x$CONFIG_HEADERS in
 506 xconfig.h:config.in)
 507 echo > stamp-h ;;
 508 esac
 509 ])
 510
 511 AC_OUTPUT