gdb/gdbserver/configure.ac

   1 dnl Autoconf configure script for GDB server.
   2 dnl Copyright (C) 2000-2017 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Process this file with autoconf to produce a configure script.
  20
  21 AC_PREREQ(2.59)dnl
  22
  23 AC_INIT(server.c)
  24 AC_CONFIG_HEADER(config.h:config.in)
  25
  26 AM_MAINTAINER_MODE
  27
  28 AC_PROG_CC
  29 AC_PROG_CXX
  30 AC_GNU_SOURCE
  31 AC_SYS_LARGEFILE
  32
  33 AC_CANONICAL_SYSTEM
  34
  35 AC_PROG_INSTALL
  36 AC_CHECK_TOOL(AR, ar)
  37 AC_PROG_RANLIB
  38
  39 AC_ARG_PROGRAM
  40
  41 # We require a C++11 compiler.  Check if one is available, and if
  42 # necessary, set CXX_DIALECT to some -std=xxx switch.
  43 AX_CXX_COMPILE_STDCXX(11, , mandatory)
  44
  45 AC_HEADER_STDC
  46
  47 # Set the 'development' global.
  48 . $srcdir/../../bfd/development.sh
  49
  50 # Enable -lmcheck by default (it provides cheap-enough memory
  51 # mangling), but turn it off for releases.
  52 if $development; then
  53   libmcheck_default=yes
  54 else
  55   libmcheck_default=no
  56 fi
  57 GDB_AC_LIBMCHECK(${libmcheck_default})
  58
  59 ACX_NONCANONICAL_TARGET
  60 ACX_NONCANONICAL_HOST
  61
  62 # Dependency checking.
  63 ZW_CREATE_DEPDIR
  64 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  65
  66 gnulib_extra_configure_args=
  67 # If large-file support is disabled, make sure gnulib does the same.
  68 if test "$enable_largefile" = no; then
  69 gnulib_extra_configure_args="$gnulib_extra_configure_args --disable-largefile"
  70 fi
  71
  72 # Configure gnulib.  We can't use AC_CONFIG_SUBDIRS as that'd expect
  73 # to find the the source subdir to be configured directly under
  74 # gdbserver/.  We need to build gnulib under some other directory not
  75 # "gnulib", to avoid the problem of both GDB and GDBserver wanting to
  76 # build it in the same directory, when building in the source dir.
  77 ACX_CONFIGURE_DIR(["../gnulib"], ["build-gnulib-gdbserver"],
  78                   ["$gnulib_extra_configure_args"])
  79
  80 ACX_CONFIGURE_DIR(["../../libiberty"], ["build-libiberty-gdbserver"])
  81
  82 AC_CHECK_HEADERS(sgtty.h termio.h termios.h sys/reg.h string.h dnl
  83                  proc_service.h sys/procfs.h linux/elf.h dnl
  84                  fcntl.h signal.h sys/file.h dnl
  85                  sys/ioctl.h netinet/in.h sys/socket.h netdb.h dnl
  86                  netinet/tcp.h arpa/inet.h)
  87 AC_FUNC_FORK
  88 AC_CHECK_FUNCS(getauxval pread pwrite pread64 setns)
  89
  90 GDB_AC_COMMON
  91
  92 # Check the return and argument types of ptrace.
  93 GDB_AC_PTRACE
  94
  95 # Check for UST
  96 ustlibs=""
  97 ustinc=""
  98
  99 AC_ARG_WITH(ust, [  --with-ust=PATH       Specify prefix directory for the installed UST package
 100                           Equivalent to --with-ust-include=PATH/include
 101                           plus --with-ust-lib=PATH/lib])
 102 AC_ARG_WITH(ust_include, [  --with-ust-include=PATH Specify directory for installed UST include files])
 103 AC_ARG_WITH(ust_lib, [  --with-ust-lib=PATH   Specify the directory for the installed UST library])
 104
 105 case $with_ust in
 106   no)
 107     ustlibs=
 108     ustinc=
 109     ;;
 110   "" | yes)
 111     ustlibs=" -lust "
 112     ustinc=""
 113     ;;
 114   *)
 115     ustlibs="-L$with_ust/lib -lust"
 116     ustinc="-I$with_ust/include "
 117     ;;
 118 esac
 119 if test "x$with_ust_include" != x; then
 120   ustinc="-I$with_ust_include "
 121 fi
 122 if test "x$with_ust_lib" != x; then
 123   ustlibs="-L$with_ust_lib -lust"
 124 fi
 125
 126 if test "x$with_ust" != "xno"; then
 127   saved_CFLAGS="$CFLAGS"
 128   CFLAGS="$CFLAGS $ustinc"
 129   AC_MSG_CHECKING([for ust])
 130   AC_TRY_COMPILE([
 131 #define CONFIG_UST_GDB_INTEGRATION
 132 #include <ust/ust.h>
 133   ],[],
 134   [AC_MSG_RESULT([yes]); AC_DEFINE(HAVE_UST, 1, [Define if UST is available])],
 135   [AC_MSG_RESULT([no]); ustlibs= ; ustinc= ])
 136   CFLAGS="$saved_CFLAGS"
 137 fi
 138
 139 # Flags needed for UST
 140 AC_SUBST(ustlibs)
 141 AC_SUBST(ustinc)
 142
 143 AM_GDB_WARNINGS
 144 dnl The codebase isn't clean yet with this flag.
 145 case " $WARN_CFLAGS " in
 146 *" -Wmissing-prototypes "*)
 147   WARN_CFLAGS="$WARN_CFLAGS -Wno-missing-prototypes"
 148   ;;
 149 esac
 150
 151 dnl dladdr is glibc-specific.  It is used by thread-db.c but only for
 152 dnl debugging messages.  It lives in -ldl which is handled below so we don't
 153 dnl use AC_CHECK_LIB (or AC_SEARCH_LIBS) here.  Instead we just temporarily
 154 dnl augment LIBS.
 155 old_LIBS="$LIBS"
 156 LIBS="$LIBS -ldl"
 157 AC_CHECK_FUNCS(dladdr)
 158 LIBS="$old_LIBS"
 159
 160 libiberty_INIT
 161
 162 AC_CHECK_DECLS([strerror, perror, vasprintf, vsnprintf])
 163
 164 AC_CHECK_MEMBERS([struct stat.st_blocks, struct stat.st_blksize])
 165
 166 # See if <sys/user.h> supports the %fs_base and %gs_bas amd64 segment registers.
 167 # Older amd64 Linux's don't have the fs_base and gs_base members of
 168 # `struct user_regs_struct'.
 169 AC_CHECK_MEMBERS([struct user_regs_struct.fs_base, struct user_regs_struct.gs_base],
 170                  [], [], [#include <sys/user.h>])
 171
 172
 173 AC_CHECK_TYPES(socklen_t, [], [],
 174 [#include <sys/types.h>
 175 #include <sys/socket.h>
 176 ])
 177
 178 case "${target}" in
 179   *-android*)
 180     # Starting with NDK version 9, <elf.h> actually includes definitions
 181     # of Elf32_auxv_t and Elf64_auxv_t. But sadly, <elf.h> includes
 182     # <sys/exec_elf.h> which defines some of the ELF types incorrectly,
 183     # leading to conflicts with the defintions from <linux/elf.h>.
 184     # This makes it impossible for us to include both <elf.h> and
 185     # <linux/elf.h>, which means that, in practice, we do not have
 186     # access to Elf32_auxv_t and Elf64_auxv_t on this platform.
 187     # Therefore, do not try to auto-detect availability, as it would
 188     # get it wrong on this platform.
 189     ;;
 190   *)
 191     AC_CHECK_TYPES([Elf32_auxv_t, Elf64_auxv_t], [], [],
 192     #include <elf.h>
 193     )
 194 esac
 195
 196 ACX_PKGVERSION([GDB])
 197 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 198 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 199 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 200
 201 # Check for various supplementary target information (beyond the
 202 # triplet) which might affect the choices in configure.srv.
 203 case "${target}" in
 204 changequote(,)dnl
 205   i[34567]86-*-linux*)
 206 changequote([,])dnl
 207     AC_CACHE_CHECK([if building for x86-64], [gdb_cv_i386_is_x86_64],
 208                    [save_CPPFLAGS="$CPPFLAGS"
 209                     CPPFLAGS="$CPPFLAGS $CFLAGS"
 210                     AC_EGREP_CPP([got it], [
 211 #if __x86_64__
 212 got it
 213 #endif
 214                  ], [gdb_cv_i386_is_x86_64=yes],
 215                     [gdb_cv_i386_is_x86_64=no])
 216                     CPPFLAGS="$save_CPPFLAGS"])
 217     ;;
 218
 219   x86_64-*-linux*)
 220     AC_CACHE_CHECK([if building for x32], [gdb_cv_x86_is_x32],
 221                    [save_CPPFLAGS="$CPPFLAGS"
 222                     CPPFLAGS="$CPPFLAGS $CFLAGS"
 223                     AC_EGREP_CPP([got it], [
 224 #if __x86_64__ && __ILP32__
 225 got it
 226 #endif
 227                  ], [gdb_cv_x86_is_x32=yes],
 228                     [gdb_cv_x86_is_x32=no])
 229                     CPPFLAGS="$save_CPPFLAGS"])
 230     ;;
 231
 232   m68k-*-*)
 233     AC_CACHE_CHECK([if building for Coldfire], [gdb_cv_m68k_is_coldfire],
 234                    [save_CPPFLAGS="$CPPFLAGS"
 235                     CPPFLAGS="$CPPFLAGS $CFLAGS"
 236                     AC_EGREP_CPP([got it], [
 237 #ifdef __mcoldfire__
 238 got it
 239 #endif
 240                  ], [gdb_cv_m68k_is_coldfire=yes],
 241                     [gdb_cv_m68k_is_coldfire=no])
 242                     CPPFLAGS="$save_CPPFLAGS"])
 243     ;;
 244 esac
 245
 246 . ${srcdir}/configure.srv
 247
 248 # Add in the common host objects.
 249 . ${srcdir}/../common/common.host
 250 srv_host_obs="$common_host_obs"
 251
 252 if test "${srv_mingwce}" = "yes"; then
 253   LIBS="$LIBS -lws2"
 254 elif test "${srv_mingw}" = "yes"; then
 255   LIBS="$LIBS -lws2_32"
 256 elif test "${srv_qnx}" = "yes"; then
 257   LIBS="$LIBS -lsocket"
 258 elif test "${srv_lynxos}" = "yes"; then
 259   LIBS="$LIBS -lnetinet"
 260 fi
 261
 262 if test "${srv_mingw}" = "yes"; then
 263   AC_DEFINE(USE_WIN32API, 1,
 264             [Define if we should use the Windows API, instead of the
 265              POSIX API.  On Windows, we use the Windows API when
 266              building for MinGW, but the POSIX API when building
 267              for Cygwin.])
 268 fi
 269
 270 if test "${srv_linux_usrregs}" = "yes"; then
 271   AC_DEFINE(HAVE_LINUX_USRREGS, 1,
 272             [Define if the target supports PTRACE_PEEKUSR for register ]
 273             [access.])
 274 fi
 275
 276 if test "${srv_linux_regsets}" = "yes"; then
 277   AC_DEFINE(HAVE_LINUX_REGSETS, 1,
 278             [Define if the target supports register sets.])
 279
 280   AC_MSG_CHECKING(for PTRACE_GETREGS)
 281   AC_CACHE_VAL(gdbsrv_cv_have_ptrace_getregs,
 282   [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 283                   [PTRACE_GETREGS;],
 284                   [gdbsrv_cv_have_ptrace_getregs=yes],
 285                   [gdbsrv_cv_have_ptrace_getregs=no])])
 286   AC_MSG_RESULT($gdbsrv_cv_have_ptrace_getregs)
 287   if test "${gdbsrv_cv_have_ptrace_getregs}" = "yes"; then
 288     AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
 289               [Define if the target supports PTRACE_GETREGS for register ]
 290               [access.])
 291   fi
 292
 293   AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
 294   AC_CACHE_VAL(gdbsrv_cv_have_ptrace_getfpxregs,
 295   [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 296                   [PTRACE_GETFPXREGS;],
 297                   [gdbsrv_cv_have_ptrace_getfpxregs=yes],
 298                   [gdbsrv_cv_have_ptrace_getfpxregs=no])])
 299   AC_MSG_RESULT($gdbsrv_cv_have_ptrace_getfpxregs)
 300   if test "${gdbsrv_cv_have_ptrace_getfpxregs}" = "yes"; then
 301     AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
 302               [Define if the target supports PTRACE_GETFPXREGS for extended ]
 303               [register access.])
 304   fi
 305 fi
 306
 307 if test "${srv_linux_btrace}" = "yes"; then
 308   AC_DEFINE(HAVE_LINUX_BTRACE, 1,
 309             [Define if the target supports branch tracing.])
 310 fi
 311
 312 if test "$ac_cv_header_sys_procfs_h" = yes; then
 313   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
 314   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
 315   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
 316   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
 317   BFD_HAVE_SYS_PROCFS_TYPE(elf_fpregset_t)
 318 fi
 319
 320 dnl Some systems (e.g., Android) have lwpid_t defined in libthread_db.h.
 321 if test "$bfd_cv_have_sys_procfs_type_lwpid_t" != yes; then
 322   GDBSERVER_HAVE_THREAD_DB_TYPE(lwpid_t)
 323 fi
 324
 325 dnl Some systems (e.g., Android) have psaddr_t defined in libthread_db.h.
 326 if test "$bfd_cv_have_sys_procfs_type_psaddr_t" != yes; then
 327   GDBSERVER_HAVE_THREAD_DB_TYPE(psaddr_t)
 328 fi
 329
 330 dnl Check for libdl, but do not add it to LIBS as only gdbserver
 331 dnl needs it (and gdbreplay doesn't).
 332 old_LIBS="$LIBS"
 333 AC_CHECK_LIB(dl, dlopen)
 334 LIBS="$old_LIBS"
 335
 336 srv_thread_depfiles=
 337 srv_libs=
 338
 339 if test "$srv_linux_thread_db" = "yes"; then
 340   if test "$ac_cv_lib_dl_dlopen" = "yes"; then
 341     srv_libs="-ldl"
 342     AC_MSG_CHECKING(for the dynamic export flag)
 343     old_LDFLAGS="$LDFLAGS"
 344     # Older GNU ld supports --export-dynamic but --dynamic-list may not be
 345     # supported there.
 346     RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
 347     LDFLAGS="$LDFLAGS $RDYNAMIC"
 348     AC_TRY_LINK([], [],
 349                 [found="-Wl,--dynamic-list"
 350                  RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'],
 351                 [RDYNAMIC="-rdynamic"
 352                  LDFLAGS="$old_LDFLAGS $RDYNAMIC"
 353                  AC_TRY_LINK([], [],
 354                              [found="-rdynamic"],
 355                              [found="no"
 356                               RDYNAMIC=""])])
 357     AC_SUBST(RDYNAMIC)
 358     LDFLAGS="$old_LDFLAGS"
 359     AC_MSG_RESULT($found)
 360   else
 361     srv_libs="-lthread_db"
 362   fi
 363
 364   srv_thread_depfiles="thread-db.o proc-service.o"
 365   AC_DEFINE(USE_THREAD_DB, 1, [Define if we should use libthread_db.])
 366   AC_CACHE_CHECK([for TD_VERSION], gdbsrv_cv_have_td_version,
 367   [AC_TRY_COMPILE([#include <thread_db.h>], [TD_VERSION;],
 368                   [gdbsrv_cv_have_td_version=yes],
 369                   [gdbsrv_cv_have_td_version=no])])
 370   if test $gdbsrv_cv_have_td_version = yes; then
 371     AC_DEFINE(HAVE_TD_VERSION, 1, [Define if TD_VERSION is available.])
 372   fi
 373 fi
 374
 375 AC_ARG_WITH(libthread-db,
 376 AS_HELP_STRING([--with-libthread-db=PATH], [use given libthread_db directly]),
 377 [srv_libthread_db_path="${withval}"
 378   srv_libs="$srv_libthread_db_path"
 379 ])
 380
 381 if test "$srv_libs" != "" -a "$srv_libs" != "-ldl"; then
 382   AC_DEFINE(USE_LIBTHREAD_DB_DIRECTLY, 1, [Define if we should use libthread_db directly.])
 383 fi
 384
 385 if test "$srv_xmlfiles" != ""; then
 386   srv_xmlbuiltin="xml-builtin.o"
 387   AC_DEFINE(USE_XML, 1, [Define if an XML target description is available.])
 388
 389   tmp_xmlfiles=$srv_xmlfiles
 390   srv_xmlfiles=""
 391   for f in $tmp_xmlfiles; do
 392     srv_xmlfiles="$srv_xmlfiles \$(XML_DIR)/$f"
 393   done
 394 fi
 395
 396 GDBSERVER_DEPFILES="$srv_regobj $srv_tgtobj $srv_hostio_err_objs $srv_thread_depfiles $srv_host_obs"
 397 GDBSERVER_LIBS="$srv_libs"
 398
 399 dnl Check whether the target supports __sync_*_compare_and_swap.
 400 AC_CACHE_CHECK([whether the target supports __sync_*_compare_and_swap],
 401                 gdbsrv_cv_have_sync_builtins, [
 402 AC_TRY_LINK([], [int foo, bar; bar = __sync_val_compare_and_swap(&foo, 0, 1);],
 403                 gdbsrv_cv_have_sync_builtins=yes,
 404                 gdbsrv_cv_have_sync_builtins=no)])
 405 if test $gdbsrv_cv_have_sync_builtins = yes; then
 406   AC_DEFINE(HAVE_SYNC_BUILTINS, 1,
 407     [Define to 1 if the target supports __sync_*_compare_and_swap])
 408 fi
 409
 410 dnl Check for -fvisibility=hidden support in the compiler.
 411 saved_cflags="$CFLAGS"
 412 CFLAGS="$CFLAGS -fvisibility=hidden"
 413 AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]),
 414                         [gdbsrv_cv_have_visibility_hidden=yes],
 415                         [gdbsrv_cv_have_visibility_hidden=no])
 416 CFLAGS="$saved_cflags"
 417
 418 dnl Check if we can disable the virtual address space randomization.
 419 dnl The functionality of setarch -R.
 420 AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>])
 421 define([PERSONALITY_TEST], [AC_LANG_PROGRAM([#include <sys/personality.h>], [
 422 #      if !HAVE_DECL_ADDR_NO_RANDOMIZE
 423 #       define ADDR_NO_RANDOMIZE 0x0040000
 424 #      endif
 425        /* Test the flag could be set and stays set.  */
 426        personality (personality (0xffffffff) | ADDR_NO_RANDOMIZE);
 427        if (!(personality (personality (0xffffffff)) & ADDR_NO_RANDOMIZE))
 428            return 1])])
 429 AC_RUN_IFELSE([PERSONALITY_TEST],
 430               [gdbsrv_cv_have_personality=true],
 431               [gdbsrv_cv_have_personality=false],
 432               [AC_LINK_IFELSE([PERSONALITY_TEST],
 433                               [gdbsrv_cv_have_personality=true],
 434                               [gdbsrv_cv_have_personality=false])])
 435 if $gdbsrv_cv_have_personality
 436 then
 437     AC_DEFINE([HAVE_PERSONALITY], 1,
 438               [Define if you support the personality syscall.])
 439 fi
 440
 441
 442 IPA_DEPFILES=""
 443 extra_libraries=""
 444
 445 # check whether to enable the inprocess agent
 446 if test "$ipa_obj" != "" \
 447    -a "$gdbsrv_cv_have_sync_builtins" = yes \
 448    -a "$gdbsrv_cv_have_visibility_hidden" = yes; then
 449    have_ipa=true
 450 else
 451    have_ipa=false
 452 fi
 453
 454 AC_ARG_ENABLE(inprocess-agent,
 455 AS_HELP_STRING([--enable-inprocess-agent], [inprocess agent]),
 456 [case "$enableval" in
 457   yes) want_ipa=true ;;
 458   no) want_ipa=false ;;
 459   *) AC_MSG_ERROR([bad value $enableval for inprocess-agent]) ;;
 460 esac],
 461 [want_ipa=$have_ipa])
 462
 463 if $want_ipa ; then
 464    if $have_ipa ; then
 465      IPA_DEPFILES="$ipa_obj"
 466      extra_libraries="$extra_libraries libinproctrace.so"
 467    else
 468      AC_MSG_ERROR([inprocess agent not supported for this target])
 469    fi
 470 fi
 471
 472 AC_SUBST(GDBSERVER_DEPFILES)
 473 AC_SUBST(GDBSERVER_LIBS)
 474 AC_SUBST(srv_xmlbuiltin)
 475 AC_SUBST(srv_xmlfiles)
 476 AC_SUBST(IPA_DEPFILES)
 477 AC_SUBST(extra_libraries)
 478
 479 GNULIB=build-gnulib-gdbserver/import
 480
 481 GNULIB_STDINT_H=
 482 if test x"$STDINT_H" != x; then
 483   GNULIB_STDINT_H=$GNULIB/$STDINT_H
 484 fi
 485 AC_SUBST(GNULIB_STDINT_H)
 486
 487 AC_CONFIG_FILES([Makefile],
 488 [case x$CONFIG_HEADERS in
 489 xconfig.h:config.in)
 490 echo > stamp-h ;;
 491 esac
 492 ])
 493
 494 AC_OUTPUT