gdb/copying.awk

   1 BEGIN   {
   2           FS="\"";
   3           print "/* ==> Do not modify this file!!  " \
   4                 "-*- buffer-read-only: t -*- vi" \
   5                 ":set ro:";
   6           print "   It is created automatically by copying.awk.";
   7           print "   Modify copying.awk instead.  <== */";
   8           print ""
   9           print "#include \"defs.h\""
  10           print "#include \"command.h\""
  11           print "#include \"gdbcmd.h\""
  12           print ""
  13           print "static void show_copying_command (const char *, int);"
  14           print ""
  15           print "static void show_warranty_command (const char *, int);"
  16           print ""
  17           print "static void";
  18           print "show_copying_command (const char *ignore, int from_tty)";
  19           print "{";
  20         }
  21 NR == 1,/^[     ]*15\. Disclaimer of Warranty\.[        ]*$/    {
  22           if ($0 ~ /\f/)
  23             {
  24               printf "  printf_filtered (\"\\n\");\n";
  25             }
  26           else if ($0 !~ /^[    ]*15\. Disclaimer of Warranty\.[        ]*$/)
  27             {
  28               printf "  printf_filtered (\"";
  29               for (i = 1; i < NF; i++)
  30                 printf "%s\\\"", $i;
  31               printf "%s\\n\");\n", $NF;
  32             }
  33         }
  34 /^[      ]*15\. Disclaimer of Warranty\.[       ]*$/    {
  35           print "}";
  36           print "";
  37           print "static void";
  38           print "show_warranty_command (const char *ignore, int from_tty)";
  39           print "{";
  40         }
  41 /^[     ]*15\. Disclaimer of Warranty\.[        ]*$/, /^[       ]*END OF TERMS AND CONDITIONS[  ]*$/{
  42           if (! ($0 ~ /^[       ]*END OF TERMS AND CONDITIONS[  ]*$/))
  43             {
  44               printf "  printf_filtered (\"";
  45               for (i = 1; i < NF; i++)
  46                 printf "%s\\\"", $i;
  47               printf "%s\\n\");\n", $NF;
  48             }
  49         }
  50 END     {
  51           print "}";
  52           print "";
  53           print "void"
  54           print "_initialize_copying (void)";
  55           print "{";
  56           print "  add_cmd (\"copying\", no_set_class, show_copying_command,";
  57           print "          _(\"Conditions for redistributing copies of GDB.\"),";
  58           print "          &showlist);";
  59           print "  add_cmd (\"warranty\", no_set_class, show_warranty_command,";
  60           print "          _(\"Various kinds of warranty you do not have.\"),";
  61           print "          &showlist);";
  62           print "";
  63           print "  /* For old-timers, allow \"info copying\", etc.  */";
  64           print "  add_info (\"copying\", show_copying_command,";
  65           print "           _(\"Conditions for redistributing copies of GDB.\"));";
  66           print "  add_info (\"warranty\", show_warranty_command,";
  67           print "           _(\"Various kinds of warranty you do not have.\"));";
  68           print "}";
  69         }