gdb/configure.in

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003
   3 dnl Free Software Foundation, Inc.
   4 dnl
   5 dnl This file is part of GDB.
   6 dnl
   7 dnl This program is free software; you can redistribute it and/or modify
   8 dnl it under the terms of the GNU General Public License as published by
   9 dnl the Free Software Foundation; either version 2 of the License, or
  10 dnl (at your option) any later version.
  11 dnl
  12 dnl This program is distributed in the hope that it will be useful,
  13 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 dnl GNU General Public License for more details.
  16 dnl
  17 dnl You should have received a copy of the GNU General Public License
  18 dnl along with this program; if not, write to the Free Software
  19 dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  20
  21 dnl Process this file with autoconf to produce a configure script.
  22
  23 AC_PREREQ(2.13)dnl
  24 AC_INIT(main.c)
  25 AC_CONFIG_HEADER(config.h:config.in)
  26 AM_MAINTAINER_MODE
  27
  28 AC_PROG_CC
  29 AC_AIX
  30 AC_ISC_POSIX
  31 AM_PROG_CC_STDC
  32
  33 AC_CONFIG_AUX_DIR(`cd $srcdir;pwd`/..)
  34 AC_CANONICAL_SYSTEM
  35
  36 # FIXME: kettenis/20030102: The AC_PROG_RANLIB from Autoconf 2.13
  37 # doesn't support cross-compilation, but the one from Autoconf 2.5x
  38 # does.  Override RANLIB here (i.e. before running AC_PROG_RANLIB) to
  39 # deal with the lossage.  Note that CY_GNU_GETTEXT currently calls
  40 # AC_PROG_RANLIB.  This can be removed when we switch to # Autoconf
  41 # 2.5x.
  42 AC_CHECK_TOOL(RANLIB, ranlib, :)
  43
  44 dnl Set up for gettext.  PACKAGE is used when we call bindtextdomain.
  45 ALL_LINGUAS=
  46 CY_GNU_GETTEXT
  47 AC_DEFINE(PACKAGE, "gdb", [Name of this package. ])
  48
  49
  50 dnl List of object files added by configure.
  51
  52 CONFIG_OBS=
  53 CONFIG_LIB_OBS=
  54 CONFIG_DEPS=
  55 CONFIG_SRCS=
  56 CONFIG_INITS=
  57 ENABLE_CFLAGS=
  58 CONFIG_ALL=
  59 CONFIG_CLEAN=
  60 CONFIG_INSTALL=
  61 CONFIG_UNINSTALL=
  62
  63 SUBDIRS="doc testsuite nlm"
  64 configdirs="doc testsuite"
  65
  66 AC_ARG_ENABLE(multi-ice,
  67 [  --enable-multi-ice            Build the multi-ice-gdb-server],
  68 [case "${enableval}" in
  69     yes ) enable_multi_ice="yes" ;;
  70     no)  enable_multi_ice="no" ;;
  71     *) AC_MSG_ERROR(Bad value for --enable-multi-ice: ${enableval}) ;;
  72   esac
  73 ])
  74
  75 if test "${enable_multi_ice}" = "yes"; then
  76   configdirs="${configdirs} multi-ice"
  77 fi
  78
  79 dnl
  80 changequote(,)dnl
  81
  82 . ${srcdir}/configure.host
  83
  84 . ${srcdir}/configure.tgt
  85
  86 targ=${target} ; . ${srcdir}/../bfd/config.bfd
  87
  88 dnl
  89 changequote([,])dnl
  90
  91 dnl use BFD to determine the default architecture and byte order
  92 dnl (bfd_vec->byteorder provides the latter).
  93 targ=${target}
  94 . ${srcdir}/../bfd/config.bfd
  95
  96 dnl We only want the first arch, if there is more than one.
  97 targ_archs=`echo ${targ_archs} | sed -e 's/ .*//;'`
  98
  99 if test x"${targ_archs}" != x ; then
 100     AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, ${targ_archs})
 101 fi
 102 if test x"${targ_defvec}" != x ; then
 103     AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, ${targ_defvec})
 104 fi
 105
 106 AC_ARG_PROGRAM
 107
 108 # The CLI cannot be disabled yet, but may be in the future.
 109
 110 # Enable CLI.
 111 AC_ARG_ENABLE(gdbcli,
 112 [  --disable-gdbcli        disable command-line interface (CLI)],
 113   [case $enableval in
 114     yes)
 115       ;;
 116     no)
 117       AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;;
 118     *)
 119       AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;;
 120   esac],
 121   [enable_gdbcli=yes])
 122 if test x"$enable_gdbcli" = xyes; then
 123   if test -d $srcdir/cli; then
 124     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)"
 125     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)"
 126     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)"
 127     CONFIG_INITS="$CONFIG_INITS \$(SUBDIR_CLI_INITS)"
 128     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)"
 129     CONFIG_ALL="$CONFIG_ALL \$(SUBDIR_CLI_ALL)"
 130     CONFIG_CLEAN="$CONFIG_CLEAN \$(SUBDIR_CLI_CLEAN)"
 131     CONFIG_INSTALL="$CONFIG_INSTALL \$(SUBDIR_CLI_INSTALL)"
 132     CONFIG_UNINSTALL="$CONFIG_UNINSTALL \$(SUBDIR_CLI_UNINSTALL)"
 133   fi
 134 fi
 135
 136 # Enable MI.
 137 AC_ARG_ENABLE(gdbmi,
 138 [  --disable-gdbmi         disable machine-interface (MI)],
 139   [case $enableval in
 140     yes | no)
 141       ;;
 142     *)
 143       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 144   esac],
 145   [enable_gdbmi=yes])
 146 if test x"$enable_gdbmi" = xyes; then
 147   if test -d $srcdir/mi; then
 148     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 149     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 150     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 151     CONFIG_INITS="$CONFIG_INITS \$(SUBDIR_MI_INITS)"
 152     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 153     CONFIG_ALL="$CONFIG_ALL \$(SUBDIR_MI_ALL)"
 154     CONFIG_CLEAN="$CONFIG_CLEAN \$(SUBDIR_MI_CLEAN)"
 155     CONFIG_INSTALL="$CONFIG_INSTALL \$(SUBDIR_MI_INSTALL)"
 156     CONFIG_UNINSTALL="$CONFIG_UNINSTALL \$(SUBDIR_MI_UNINSTALL)"
 157   fi
 158 fi
 159
 160 # Enable TUI.
 161 AC_ARG_ENABLE(tui,
 162 [  --enable-tui            enable full-screen terminal user interface (TUI)],
 163   [case $enableval in
 164     yes | no)
 165       ;;
 166     *)
 167       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 168   esac])
 169 if test x"$enable_tui" = xyes; then
 170   if test -d $srcdir/tui; then
 171     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
 172     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
 173     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
 174     CONFIG_INITS="$CONFIG_INITS \$(SUBDIR_TUI_INITS)"
 175     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
 176     CONFIG_ALL="$CONFIG_ALL \$(SUBDIR_TUI_ALL)"
 177     CONFIG_CLEAN="$CONFIG_CLEAN \$(SUBDIR_TUI_CLEAN)"
 178     CONFIG_INSTALL="$CONFIG_INSTALL \$(SUBDIR_TUI_INSTALL)"
 179     CONFIG_UNINSTALL="$CONFIG_UNINSTALL \$(SUBDIR_TUI_UNINSTALL)"
 180     need_curses=yes
 181   fi
 182 fi
 183
 184 # --------------------- #
 185 # Checks for programs.  #
 186 # --------------------- #
 187
 188 AC_PROG_AWK
 189 AC_PROG_INSTALL
 190 AC_PROG_LN_S
 191 AC_PROG_RANLIB
 192 AC_PROG_YACC
 193
 194 AC_CHECK_TOOL(AR, ar)
 195 AC_CHECK_TOOL(DLLTOOL, dlltool)
 196 AC_CHECK_TOOL(WINDRES, windres)
 197
 198 # Needed for GNU/Hurd.
 199 AC_CHECK_TOOL(MIG, mig)
 200
 201 # ---------------------- #
 202 # Checks for libraries.  #
 203 # ---------------------- #
 204
 205 # We might need to link with -lm; most simulators need it.
 206 AC_CHECK_LIB(m, main)
 207
 208 # We need to link with -lw to get `wctype' on Solaris before Solaris
 209 # 2.6.  Solaris 2.6 and beyond have this function in libc, and have a
 210 # libw that some versions of the GNU linker cannot hanle (GNU ld 2.9.1
 211 # is known to have this problem).  Therefore we avoid libw if we can.
 212 AC_CHECK_FUNC(wctype, [],
 213   [AC_CHECK_LIB(w, wctype)])
 214
 215 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 216 AC_SEARCH_LIBS(socketpair, socket)
 217
 218 # Since GDB uses Readline, we need termcap functionality, so we need
 219 # to find a library that provides that.  When GDB is configured with
 220 # --enable-tui, we need full curses functionality.
 221 #
 222 # FIXME: kettenis/20030102: We seem to prefer HP curses (Hcurses) over
 223 # Xcurses on HP-UX; see the `-D__HP_CURSES' in the relevant host
 224 # Makefile fragments.  That's why we need to have `Hcurses' before
 225 # `curses'.  I don't see why we should use HP curses if a more
 226 # standard curses is available, except that according to HP's
 227 # documentation one needs to compile `-D_XOPEN_SOURCE_EXTENDED' on
 228 # HP-UX 10.10 and 10.20.
 229
 230 if test "$need_curses" = yes; then
 231   AC_SEARCH_LIBS(initscr, [ncurses Hcurses curses], [],
 232     [AC_MSG_ERROR([no curses library found])])
 233 fi
 234
 235 case $host_os in
 236   cygwin*)
 237     if test -d $srcdir/libtermcap; then
 238       LIBS="../libtermcap/libtermcap.a $LIBS"
 239       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 240     fi ;;
 241   go32*)
 242     # ??? Is this really true?
 243     ac_cv_search_tgetent="none required"
 244     ;;
 245   aix*)
 246     # Readline prefers curses over termcap on AIX.
 247     # ??? Why?
 248     AC_SEARCH_LIBS(tgetent, [tinfo ncurses curses termcap])
 249     ;;
 250 esac
 251
 252 # Note: We used to check for libtermlib and libterminfo too, but
 253 # Readline doesn't, so I think we're safe with leaving them out.
 254 AC_SEARCH_LIBS(tgetent, [termcap tinfo ncurses Hcurses curses])
 255
 256 if test "$ac_cv_search_tgetent" = no; then
 257   AC_MSG_ERROR([no termcap library found])
 258 fi
 259
 260 # ------------------------- #
 261 # Checks for header files.  #
 262 # ------------------------- #
 263
 264 AC_HEADER_DIRENT
 265 AC_HEADER_STAT
 266 AC_HEADER_STDC
 267 AC_CHECK_HEADERS(link.h)
 268 AC_CHECK_HEADERS(nlist.h)
 269 AC_CHECK_HEADERS(poll.h sys/poll.h)
 270 AC_CHECK_HEADERS(proc_service.h thread_db.h)
 271 AC_CHECK_HEADERS(stddef.h)
 272 AC_CHECK_HEADERS(stdlib.h)
 273 AC_CHECK_HEADERS(stdint.h)
 274 AC_CHECK_HEADERS(string.h memory.h strings.h)
 275 AC_CHECK_HEADERS(sys/fault.h)
 276 AC_CHECK_HEADERS(sys/file.h)
 277 AC_CHECK_HEADERS(sys/filio.h)
 278 AC_CHECK_HEADERS(sys/ioctl.h)
 279 AC_CHECK_HEADERS(sys/param.h)
 280 AC_CHECK_HEADERS(sys/proc.h)
 281 AC_CHECK_HEADERS(sys/procfs.h)
 282 AC_CHECK_HEADERS(sys/ptrace.h ptrace.h)
 283 AC_CHECK_HEADERS(sys/reg.h sys/debugreg.h)
 284 AC_CHECK_HEADERS(sys/select.h)
 285 AC_CHECK_HEADERS(sys/syscall.h)
 286 AC_CHECK_HEADERS(sys/user.h)
 287 AC_CHECK_HEADERS(sys/wait.h wait.h)
 288 AC_CHECK_HEADERS(termios.h termio.h sgtty.h)
 289 AC_CHECK_HEADERS(unistd.h)
 290
 291 # On Solaris 2.[78], we need to define _MSE_INT_H to avoid a clash
 292 # between <widec.h> and <wchar.h> that would cause AC_CHECK_HEADERS to
 293 # think that we don't have <curses.h> if we're using GCC.
 294 case $host_os in
 295   solaris2.[[78]])
 296     if test "$GCC" = yes; then
 297       AC_DEFINE(_MSE_INT_H, 1,
 298         [[Define to 1 to avoid a clash between <widec.h> and <wchar.h> on
 299    Solaris 2.[78] when using GCC. ]])
 300     fi ;;
 301 esac
 302 AC_CHECK_HEADERS(curses.h ncurses.h term.h)
 303
 304 # FIXME: kettenis/20030102: In most cases we include these
 305 # unconditionally, so what's the point in checking these?
 306 AC_CHECK_HEADERS(ctype.h time.h)
 307
 308 # ------------------ #
 309 # Checks for types.  #
 310 # ------------------ #
 311
 312 AC_TYPE_SIGNAL
 313
 314 # ------------------------------------- #
 315 # Checks for compiler characteristics.  #
 316 # ------------------------------------- #
 317
 318 AC_C_CONST
 319 AC_C_INLINE
 320
 321 # ------------------------------ #
 322 # Checks for library functions.  #
 323 # ------------------------------ #
 324
 325 AC_FUNC_ALLOCA
 326 AC_FUNC_MMAP
 327 AC_FUNC_VFORK
 328 AC_CHECK_FUNCS(canonicalize_file_name realpath)
 329 AC_CHECK_FUNCS(poll)
 330 AC_CHECK_FUNCS(sbrk)
 331 AC_CHECK_FUNCS(setpgid setpgrp)
 332 AC_CHECK_FUNCS(sigaction sigprocmask sigsetmask)
 333 AC_CHECK_FUNCS(socketpair)
 334
 335 dnl AC_FUNC_SETPGRP does not work when cross compiling
 336 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
 337 if test "$cross_compiling" = no; then
 338   AC_FUNC_SETPGRP
 339 else
 340   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
 341     [AC_TRY_COMPILE([
 342 #include <unistd.h>
 343 ], [
 344   if (setpgrp(1,1) == -1)
 345     exit (0);
 346   else
 347     exit (1);
 348 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
 349 if test $ac_cv_func_setpgrp_void = yes; then
 350   AC_DEFINE(SETPGRP_VOID, 1)
 351 fi
 352 fi
 353
 354 # Check if sigsetjmp is available.  Using AC_CHECK_FUNCS won't do
 355 # since sigsetjmp might only be defined as a macro.
 356 AC_CACHE_CHECK([for sigsetjmp], gdb_cv_func_sigsetjmp,
 357 [AC_TRY_COMPILE([
 358 #include <setjmp.h>
 359 ], [sigjmp_buf env; while (! sigsetjmp (env, 1)) siglongjmp (env, 1);],
 360 gdb_cv_func_sigsetjmp=yes, gdb_cv_func_sigsetjmp=no)])
 361 if test $gdb_cv_func_sigsetjmp = yes; then
 362   AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available. ])
 363 fi
 364
 365 # Assume we'll default to using the included libiberty regex.
 366 gdb_use_included_regex=yes
 367
 368 # However, if the system regex is GNU regex, then default to *not*
 369 # using the included regex.
 370 AC_CACHE_CHECK(
 371   [for GNU regex],
 372   [gdb_cv_have_gnu_regex],
 373   [AC_TRY_COMPILE(
 374     [#include <gnu-versions.h>],
 375     [#define REGEX_INTERFACE_VERSION 1
 376 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
 377 # error "Version mismatch"
 378 #endif],
 379     gdb_cv_have_gnu_regex=yes,
 380     gdb_cv_have_gnu_regex=no)])
 381 if test $gdb_cv_have_gnu_regex = yes; then
 382   gdb_use_included_regex=no
 383 fi
 384
 385 AC_ARG_WITH(included-regex,
 386   [  --without-included-regex don't use included regex; this is the default
 387                           on systems with version 2 of the GNU C library
 388                           (use with caution on other system)],
 389   gdb_with_regex=$withval,
 390   gdb_with_regex=$gdb_use_included_regex)
 391 if test "$gdb_with_regex" = yes; then
 392   AC_DEFINE(USE_INCLUDED_REGEX, 1,
 393     [Define to 1 if the regex included in libiberty should be used.])
 394 fi
 395
 396 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
 397 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
 398 AC_CACHE_CHECK([for r_fs in struct reg], gdb_cv_struct_reg_r_fs,
 399 [AC_TRY_COMPILE([#include <machine/reg.h>], [struct reg r; r.r_fs;],
 400 gdb_cv_struct_reg_r_fs=yes, gdb_cv_struct_reg_r_fs=no)])
 401 if test $gdb_cv_struct_reg_r_fs = yes; then
 402   AC_DEFINE(HAVE_STRUCT_REG_R_FS)
 403 fi
 404 AC_CACHE_CHECK([for r_gs in struct reg], gdb_cv_struct_reg_r_gs,
 405 [AC_TRY_COMPILE([#include <machine/reg.h>], [struct reg r; r.r_gs;],
 406 gdb_cv_struct_reg_r_gs=yes, gdb_cv_struct_reg_r_gs=no)])
 407 if test $gdb_cv_struct_reg_r_gs = yes; then
 408   AC_DEFINE(HAVE_STRUCT_REG_R_GS)
 409 fi
 410
 411 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
 412 AC_MSG_CHECKING(for PTRACE_GETREGS)
 413 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
 414 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 415                 [PTRACE_GETREGS;],
 416                 [gdb_cv_have_ptrace_getregs=yes],
 417                 [gdb_cv_have_ptrace_getregs=no])])
 418 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
 419 if test $gdb_cv_have_ptrace_getregs = yes; then
 420   AC_DEFINE(HAVE_PTRACE_GETREGS)
 421 fi
 422
 423 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
 424 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
 425 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
 426 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 427                 [PTRACE_GETFPXREGS;],
 428                 [gdb_cv_have_ptrace_getfpxregs=yes],
 429                 [gdb_cv_have_ptrace_getfpxregs=no])])
 430 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
 431 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
 432   AC_DEFINE(HAVE_PTRACE_GETFPXREGS)
 433 fi
 434
 435 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
 436 AC_MSG_CHECKING(for PT_GETDBREGS)
 437 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
 438 [AC_TRY_COMPILE([#include <sys/types.h>
 439 #include <sys/ptrace.h>],
 440                 [PT_GETDBREGS;],
 441                 [gdb_cv_have_pt_getdbregs=yes],
 442                 [gdb_cv_have_pt_getdbregs=no])])
 443 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
 444 if test $gdb_cv_have_pt_getdbregs = yes; then
 445   AC_DEFINE(HAVE_PT_GETDBREGS)
 446 fi
 447
 448 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
 449 AC_MSG_CHECKING(for PT_GETXMMREGS)
 450 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
 451 [AC_TRY_COMPILE([#include <sys/types.h>
 452 #include <sys/ptrace.h>],
 453                 [PT_GETXMMREGS;],
 454                 [gdb_cv_have_pt_getxmmregs=yes],
 455                 [gdb_cv_have_pt_getxmmregs=no])])
 456 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
 457 if test $gdb_cv_have_pt_getxmmregs = yes; then
 458   AC_DEFINE(HAVE_PT_GETXMMREGS)
 459 fi
 460
 461
 462 BFD_NEED_DECLARATION(malloc)
 463 BFD_NEED_DECLARATION(realloc)
 464 BFD_NEED_DECLARATION(free)
 465 BFD_NEED_DECLARATION(strerror)
 466 BFD_NEED_DECLARATION(strdup)
 467 BFD_NEED_DECLARATION(strstr)
 468 BFD_NEED_DECLARATION(canonicalize_file_name)
 469
 470 # The following save_state_t checkery is only necessary for HPUX
 471 # versions earlier than 10.20.  When those fade from memory, this
 472 # could be expunged. --jsm 1999-03-22
 473
 474 AC_MSG_CHECKING(for HPUX save_state structure)
 475 AC_EGREP_HEADER(save_state_t, machine/save_state.h,
 476                 gdb_cv_hpux_savestate=yes, gdb_cv_hpux_savestate=no)
 477 AC_EGREP_HEADER(ss_wide, machine/save_state.h, gdb_cv_hpux_sswide=yes,
 478                 gdb_cv_hpux_sswide=no)
 479 if test $gdb_cv_hpux_savestate = yes
 480 then
 481   AC_DEFINE(HAVE_STRUCT_SAVE_STATE_T, 1)
 482 fi
 483 if test $gdb_cv_hpux_sswide = yes
 484 then
 485   AC_DEFINE(HAVE_STRUCT_MEMBER_SS_WIDE, 1)
 486 fi
 487 AC_MSG_RESULT($gdb_cv_hpux_sswide)
 488
 489
 490 # If we are configured native on GNU/Linux, work around problems with
 491 # sys/procfs.h
 492 # Also detect which type of /proc is in use, such as for Unixware or Solaris.
 493
 494 if test "${target}" = "${host}"; then
 495   case "${host}" in
 496   i[[3456]]86-*-linux*)
 497         AC_DEFINE(START_INFERIOR_TRAPS_EXPECTED,2)
 498         AC_DEFINE(sys_quotactl)
 499         ;;
 500   ia64-*-aix*)
 501       AC_DEFINE(NEW_PROC_API)
 502       ;;
 503   *-*-unixware* | *-*-sysv4.2* | *-*-sysv5* | *-*-interix* )
 504       AC_DEFINE(NEW_PROC_API)
 505       ;;
 506   *-*-solaris2.[[678]])
 507       AC_DEFINE(NEW_PROC_API)
 508       ;;
 509   esac
 510 fi
 511
 512 if test "$ac_cv_header_sys_procfs_h" = yes; then
 513   BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
 514   BFD_HAVE_SYS_PROCFS_TYPE(prrun_t)
 515   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
 516   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
 517   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
 518   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
 519   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
 520   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset32_t)
 521   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
 522   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
 523   BFD_HAVE_SYS_PROCFS_TYPE(prsysent_t)
 524   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigset_t)
 525   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigaction64_t)
 526   BFD_HAVE_SYS_PROCFS_TYPE(pr_siginfo64_t)
 527
 528
 529   dnl Check for broken prfpregset_t type
 530
 531   dnl For Linux/i386, glibc 2.1.3 was released with a bogus
 532   dnl prfpregset_t type (it's a typedef for the pointer to a struct
 533   dnl instead of the struct itself).  We detect this here, and work
 534   dnl around it in gdb_proc_service.h.
 535
 536   if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
 537     AC_MSG_CHECKING(whether prfpregset_t type is broken)
 538     AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
 539       [AC_TRY_RUN([#include <sys/procfs.h>
 540        int main ()
 541        {
 542          if (sizeof (prfpregset_t) == sizeof (void *))
 543            return 1;
 544          return 0;
 545        }],
 546        gdb_cv_prfpregset_t_broken=no,
 547        gdb_cv_prfpregset_t_broken=yes,
 548        gdb_cv_prfpregset_t_broken=yes)])
 549     AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
 550     if test $gdb_cv_prfpregset_t_broken = yes; then
 551       AC_DEFINE(PRFPREGSET_T_BROKEN)
 552     fi
 553   fi
 554
 555   dnl Check for PIOCSET ioctl entry
 556
 557   AC_MSG_CHECKING(for PIOCSET ioctl entry in sys/procfs.h)
 558   AC_CACHE_VAL(gdb_cv_have_procfs_piocset,
 559   [AC_TRY_COMPILE([#include <unistd.h>
 560 #include <sys/types.h>
 561 #include <sys/procfs.h>
 562 ], [
 563     int dummy;;
 564     dummy = ioctl(0, PIOCSET, &dummy);
 565   ],
 566   gdb_cv_have_procfs_piocset=yes, gdb_cv_have_procfs_piocset=no)])
 567   AC_MSG_RESULT($gdb_cv_have_procfs_piocset)
 568   if test $gdb_cv_have_procfs_piocset = yes; then
 569     AC_DEFINE(HAVE_PROCFS_PIOCSET)
 570   fi
 571 fi
 572
 573 dnl For native ports (host == target), check to see what kind of
 574 dnl legacy link.h support is needed.  (See solib-legacy.c.)
 575 if test ${host} = ${target} ; then
 576   dnl Check for struct link_map with l_ members which are indicative
 577   dnl of SVR4-like shared libraries
 578
 579   AC_MSG_CHECKING(for member l_addr in struct link_map)
 580   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_l_members,
 581     [AC_TRY_COMPILE([#include <link.h>],
 582                     [struct link_map lm; (void) lm.l_addr;],
 583                     gdb_cv_have_struct_link_map_with_l_members=yes,
 584                     gdb_cv_have_struct_link_map_with_l_members=no)])
 585   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_l_members)
 586   if test $gdb_cv_have_struct_link_map_with_l_members = yes; then
 587     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_L_MEMBERS)
 588   fi
 589
 590   dnl Check for struct link_map with lm_ members which are indicative
 591   dnl of SunOS-like shared libraries
 592
 593   AC_MSG_CHECKING(for member lm_addr in struct link_map)
 594   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_lm_members,
 595     [AC_TRY_COMPILE([#include <sys/types.h>
 596 #include <link.h>],
 597                     [struct link_map lm; (void) lm.lm_addr;],
 598                     gdb_cv_have_struct_link_map_with_lm_members=yes,
 599                     gdb_cv_have_struct_link_map_with_lm_members=no)])
 600   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_lm_members)
 601   if test $gdb_cv_have_struct_link_map_with_lm_members = yes; then
 602     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_LM_MEMBERS)
 603   fi
 604
 605   dnl Check for struct so_map with som_ members which are found on
 606   dnl some *BSD systems.
 607
 608   AC_MSG_CHECKING(for member som_addr in struct so_map)
 609   AC_CACHE_VAL(gdb_cv_have_struct_so_map_with_som_members,
 610     [AC_TRY_COMPILE([#include <sys/types.h>
 611 #ifdef HAVE_NLIST_H
 612 #include <nlist.h>
 613 #endif
 614 #include <link.h>],
 615                     [struct so_map lm; (void) lm.som_addr;],
 616                     gdb_cv_have_struct_so_map_with_som_members=yes,
 617                     gdb_cv_have_struct_so_map_with_som_members=no)])
 618   AC_MSG_RESULT($gdb_cv_have_struct_so_map_with_som_members)
 619   if test $gdb_cv_have_struct_so_map_with_som_members = yes; then
 620     AC_DEFINE(HAVE_STRUCT_SO_MAP_WITH_SOM_MEMBERS)
 621   fi
 622
 623   dnl Check for struct link_map32 type, which allows a 64-bit Solaris
 624   dnl debugger to debug a 32-bit Solaris app with 32-bit shared libraries.
 625
 626   AC_MSG_CHECKING(for struct link_map32 in sys/link.h)
 627   AC_CACHE_VAL(gdb_cv_have_struct_link_map32,
 628     [AC_TRY_COMPILE([#define _SYSCALL32
 629 #include <sys/link.h>], [struct link_map32 l;],
 630      gdb_cv_have_struct_link_map32=yes,
 631      gdb_cv_have_struct_link_map32=no)])
 632   AC_MSG_RESULT($gdb_cv_have_struct_link_map32)
 633   if test $gdb_cv_have_struct_link_map32 = yes; then
 634     AC_DEFINE(HAVE_STRUCT_LINK_MAP32)
 635     AC_DEFINE(_SYSCALL32)
 636   fi
 637 fi
 638
 639 dnl See if compiler supports "long long" type.
 640
 641 AC_MSG_CHECKING(for long long support in compiler)
 642 AC_CACHE_VAL(gdb_cv_c_long_long,
 643 [AC_TRY_COMPILE(, [
 644   extern long long foo;
 645   switch (foo & 2) { case 0: return 1; }
 646 ],
 647 gdb_cv_c_long_long=yes, gdb_cv_c_long_long=no)])
 648 AC_MSG_RESULT($gdb_cv_c_long_long)
 649 if test $gdb_cv_c_long_long = yes; then
 650   AC_DEFINE(CC_HAS_LONG_LONG)
 651 fi
 652
 653 dnl See if the compiler and runtime support printing long long
 654
 655 AC_MSG_CHECKING(for long long support in printf)
 656 AC_CACHE_VAL(gdb_cv_printf_has_long_long,
 657 [AC_TRY_RUN([
 658 int main () {
 659   char buf[32];
 660   long long l = 0;
 661   l = (l << 16) + 0x0123;
 662   l = (l << 16) + 0x4567;
 663   l = (l << 16) + 0x89ab;
 664   l = (l << 16) + 0xcdef;
 665   sprintf (buf, "0x%016llx", l);
 666   return (strcmp ("0x0123456789abcdef", buf));
 667 }],
 668 gdb_cv_printf_has_long_long=yes,
 669 gdb_cv_printf_has_long_long=no,
 670 gdb_cv_printf_has_long_long=no)])
 671 if test $gdb_cv_printf_has_long_long = yes; then
 672   AC_DEFINE(PRINTF_HAS_LONG_LONG)
 673 fi
 674 AC_MSG_RESULT($gdb_cv_printf_has_long_long)
 675
 676 dnl See if compiler supports "long double" type.  Can't use AC_C_LONG_DOUBLE
 677 dnl because autoconf complains about cross-compilation issues.  However, this
 678 dnl code uses the same variables as the macro for compatibility.
 679
 680 AC_MSG_CHECKING(for long double support in compiler)
 681 AC_CACHE_VAL(ac_cv_c_long_double,
 682 [AC_TRY_COMPILE(, [long double foo;],
 683 ac_cv_c_long_double=yes, ac_cv_c_long_double=no)])
 684 AC_MSG_RESULT($ac_cv_c_long_double)
 685 if test $ac_cv_c_long_double = yes; then
 686   AC_DEFINE(HAVE_LONG_DOUBLE)
 687 fi
 688
 689 dnl See if the compiler and runtime support printing long doubles
 690
 691 AC_MSG_CHECKING(for long double support in printf)
 692 AC_CACHE_VAL(gdb_cv_printf_has_long_double,
 693 [AC_TRY_RUN([
 694 int main () {
 695   char buf[16];
 696   long double f = 3.141592653;
 697   sprintf (buf, "%Lg", f);
 698   return (strncmp ("3.14159", buf, 7));
 699 }],
 700 gdb_cv_printf_has_long_double=yes,
 701 gdb_cv_printf_has_long_double=no,
 702 gdb_cv_printf_has_long_double=no)])
 703 if test $gdb_cv_printf_has_long_double = yes; then
 704   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE)
 705 fi
 706 AC_MSG_RESULT($gdb_cv_printf_has_long_double)
 707
 708 dnl See if the compiler and runtime support scanning long doubles
 709
 710 AC_MSG_CHECKING(for long double support in scanf)
 711 AC_CACHE_VAL(gdb_cv_scanf_has_long_double,
 712 [AC_TRY_RUN([
 713 int main () {
 714   char *buf = "3.141592653";
 715   long double f = 0;
 716   sscanf (buf, "%Lg", &f);
 717   return !(f > 3.14159 && f < 3.14160);
 718 }],
 719 gdb_cv_scanf_has_long_double=yes,
 720 gdb_cv_scanf_has_long_double=no,
 721 gdb_cv_scanf_has_long_double=no)])
 722 if test $gdb_cv_scanf_has_long_double = yes; then
 723   AC_DEFINE(SCANF_HAS_LONG_DOUBLE)
 724 fi
 725 AC_MSG_RESULT($gdb_cv_scanf_has_long_double)
 726
 727 case ${host_os} in
 728 aix*)
 729   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
 730     SAVE_LDFLAGS=$LDFLAGS
 731
 732     case $GCC in
 733     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
 734     *) gdb_cv_bigtoc=-bbigtoc ;;
 735     esac
 736
 737     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
 738     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
 739   ])
 740   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
 741   ;;
 742 esac
 743
 744
 745 dnl For certain native configurations, we need to check whether thread
 746 dnl support can be built in or not.
 747 dnl
 748 dnl Note that we only want this if we are both native (host == target),
 749 dnl and not doing a canadian cross build (build == host).
 750
 751 if test ${build} = ${host} -a ${host} = ${target} ; then
 752    case ${host_os} in
 753    hpux*)
 754       AC_MSG_CHECKING(for HPUX/OSF thread support)
 755       if test -f /usr/include/dce/cma_config.h ; then
 756          if test "$GCC" = "yes" ; then
 757             AC_MSG_RESULT(yes)
 758             AC_DEFINE(HAVE_HPUX_THREAD_SUPPORT)
 759             CONFIG_LIB_OBS="${CONFIG_LIB_OBS} hpux-thread.o"
 760             CONFIG_SRCS="${CONFIG_SRCS} hpux-thread.c"
 761          else
 762             AC_MSG_RESULT(no (suppressed because you are not using GCC))
 763          fi
 764       else
 765          AC_MSG_RESULT(no)
 766       fi
 767       ;;
 768    solaris*)
 769       # See if thread_db library is around for Solaris thread debugging.
 770       # Note that we must explicitly test for version 1 of the library
 771       # because version 0 (present on Solaris 2.4 or earlier) doesn't have
 772       # the same API.
 773       AC_MSG_CHECKING(for Solaris thread debugging library)
 774       if test -f /usr/lib/libthread_db.so.1 ; then
 775          AC_MSG_RESULT(yes)
 776          AC_DEFINE(HAVE_THREAD_DB_LIB)
 777          CONFIG_LIB_OBS="${CONFIG_LIB_OBS} sol-thread.o"
 778          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
 779          AC_CHECK_LIB(dl, dlopen)
 780          if test "$GCC" = "yes" ; then
 781             # The GNU linker requires the -export-dynamic option to make
 782             # all symbols visible in the dynamic symbol table.
 783             hold_ldflags=$LDFLAGS
 784             AC_MSG_CHECKING(for the ld -export-dynamic flag)
 785             LDFLAGS="${LDFLAGS} -Wl,-export-dynamic"
 786             AC_TRY_LINK(, [int i;], found=yes, found=no)
 787             LDFLAGS=$hold_ldflags
 788             AC_MSG_RESULT($found)
 789             if test $found = yes; then
 790                CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -Wl,-export-dynamic"
 791             fi
 792          fi
 793          # Sun randomly tweaked the prototypes in <proc_service.h>
 794          # at one point.
 795          AC_MSG_CHECKING(if <proc_service.h> is old)
 796          AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
 797             AC_TRY_COMPILE([
 798                 #include <proc_service.h>
 799                 ps_err_e ps_pdwrite
 800                     (struct ps_prochandle*, psaddr_t, const void*, size_t);
 801             ],, gdb_cv_proc_service_is_old=no,
 802                 gdb_cv_proc_service_is_old=yes)
 803          ])
 804          AC_MSG_RESULT($gdb_cv_proc_service_is_old)
 805          if test $gdb_cv_proc_service_is_old = yes; then
 806             AC_DEFINE(PROC_SERVICE_IS_OLD)
 807          fi
 808       else
 809          AC_MSG_RESULT(no)
 810       fi
 811       ;;
 812    aix*)
 813       AC_MSG_CHECKING(for AiX thread debugging library)
 814       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
 815                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
 816                                    [#ifndef PTHDB_VERSION_3
 817                                     #error
 818                                     #endif],
 819                                    gdb_cv_have_aix_thread_debug=yes,
 820                                    gdb_cv_have_aix_thread_debug=no)])
 821       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
 822       if test $gdb_cv_have_aix_thread_debug = yes; then
 823          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
 824          CONFIG_LIB_OBS="${CONFIG_LIB_OBS} aix-thread.o"
 825          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -lpthdebug"
 826       fi
 827       ;;
 828    esac
 829    AC_SUBST(CONFIG_LDFLAGS)
 830 fi
 831
 832 dnl See if we have a thread_db header file that has TD_NOTALLOC.
 833 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
 834    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
 835                   gdb_cv_thread_db_h_has_td_notalloc,
 836      AC_TRY_COMPILE(
 837        [#include <thread_db.h>],
 838        [int i = TD_NOTALLOC;],
 839        gdb_cv_thread_db_h_has_td_notalloc=yes,
 840        gdb_cv_thread_db_h_has_td_notalloc=no
 841      )
 842    )
 843 fi
 844 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
 845   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
 846             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
 847 fi
 848
 849 dnl linux-proc.c wants to use pread64, which may require special CFLAGS
 850 dnl -D_BSD_SOURCE is normally assumed but we have to specify it because of
 851 dnl -D_XOPEN_SOURCE=500.
 852 if test $host = $target; then
 853   case $target in
 854     *-linux*)
 855       save_CFLAGS=$CFLAGS
 856       CFLAGS="$CFLAGS -D_BSD_SOURCE -D_XOPEN_SOURCE=500 -D_LARGEFILE64_SOURCE"
 857       AC_TRY_LINK([#include <unistd.h>],
 858                   [pread64 (0, NULL, 0, 0);],
 859                   [ENABLE_CFLAGS="$ENABLE_CFLAGS -D_BSD_SOURCE -D_XOPEN_SOURCE=500 -D_LARGEFILE64_SOURCE"
 860                    AC_DEFINE(HAVE_PREAD64)], [])
 861       CFLAGS=$save_CFLAGS
 862       ;;
 863   esac
 864 fi
 865
 866 dnl Handle optional features that can be enabled.
 867
 868 AC_ARG_ENABLE(netrom,
 869 [  --enable-netrom         Enable NetROM support],
 870 [case "${enableval}" in
 871 yes)    enable_netrom=yes ;;
 872 no)     enable_netrom=no ;;
 873 *)      AC_MSG_ERROR(bad value ${enableval} given for netrom option) ;;
 874 esac])
 875
 876 if test "${enable_netrom}" = "yes"; then
 877         CONFIG_LIB_OBS="${CONFIG_LIB_OBS} remote-nrom.o"
 878         CONFIG_SRCS="${CONFIG_SRCS} remote-nrom.c"
 879 fi
 880
 881
 882 # NOTE: Don't add -Wall or -Wunused, they both include
 883 # -Wunused-parameter which reports bogus warnings.
 884 # NOTE: If you add to this list, remember to update
 885 # gdb/doc/gdbint.texinfo.
 886 build_warnings="-Wimplicit -Wreturn-type -Wcomment -Wtrigraphs \
 887 -Wformat -Wparentheses -Wpointer-arith -Wuninitialized"
 888 # Up for debate: -Wswitch -Wcomment -trigraphs -Wtrigraphs
 889 # -Wunused-function -Wunused-label -Wunused-variable -Wunused-value
 890 # -Wchar-subscripts -Wtraditional -Wshadow -Wcast-qual
 891 # -Wcast-align -Wwrite-strings -Wconversion -Wstrict-prototypes
 892 # -Wmissing-prototypes -Wmissing-declarations -Wredundant-decls
 893 # -Woverloaded-virtual -Winline -Werror"
 894 AC_ARG_ENABLE(build-warnings,
 895 [  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
 896 [case "${enableval}" in
 897   yes)  ;;
 898   no)   build_warnings="-w";;
 899   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
 900         build_warnings="${build_warnings} ${t}";;
 901   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
 902         build_warnings="${t} ${build_warnings}";;
 903   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
 904 esac
 905 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
 906   echo "Setting compiler warning flags = $build_warnings" 6>&1
 907 fi])dnl
 908 AC_ARG_ENABLE(gdb-build-warnings,
 909 [  --enable-gdb-build-warnings Enable GDB specific build-time compiler warnings if gcc is used],
 910 [case "${enableval}" in
 911   yes)  ;;
 912   no)   build_warnings="-w";;
 913   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
 914         build_warnings="${build_warnings} ${t}";;
 915   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
 916         build_warnings="${t} ${build_warnings}";;
 917   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
 918 esac
 919 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
 920   echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1
 921 fi])dnl
 922 WARN_CFLAGS=""
 923 WERROR_CFLAGS=""
 924 if test "x${build_warnings}" != x -a "x$GCC" = xyes
 925 then
 926     AC_MSG_CHECKING(compiler warning flags)
 927     # Separate out the -Werror flag as some files just cannot be
 928     # compiled with it enabled.
 929     for w in ${build_warnings}; do
 930         case $w in
 931         -Werr*) WERROR_CFLAGS=-Werror ;;
 932         *) # Check that GCC accepts it
 933             saved_CFLAGS="$CFLAGS"
 934             CFLAGS="$CFLAGS $w"
 935             AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
 936             CFLAGS="$saved_CFLAGS"
 937         esac
 938     done
 939     AC_MSG_RESULT(${WARN_CFLAGS}${WERROR_CFLAGS})
 940 fi
 941 AC_SUBST(WARN_CFLAGS)
 942 AC_SUBST(WERROR_CFLAGS)
 943
 944 MMALLOC_CFLAGS=
 945 MMALLOC=
 946 AC_SUBST(MMALLOC_CFLAGS)
 947 AC_SUBST(MMALLOC)
 948
 949 AC_ARG_WITH(mmalloc,
 950 [  --with-mmalloc          Use memory mapped malloc package],
 951 [case "${withval}" in
 952   yes)  want_mmalloc=true ;;
 953   no)   want_mmalloc=false;;
 954   *)    AC_MSG_ERROR(bad value ${withval} for GDB with-mmalloc option) ;;
 955 esac],[want_mmalloc=false])dnl
 956
 957 if test x$want_mmalloc = xtrue; then
 958    AC_DEFINE(USE_MMALLOC)
 959    AC_DEFINE(MMCHECK_FORCE)
 960    MMALLOC_CFLAGS="-I$srcdir/../mmalloc"
 961    MMALLOC='../mmalloc/libmmalloc.a'
 962 fi
 963
 964 # In the Cygwin environment, we need some additional flags.
 965 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
 966 [AC_EGREP_CPP(lose, [
 967 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
 968 lose
 969 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
 970
 971
 972 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
 973 SER_HARDWIRE="ser-unix.o ser-pipe.o ser-tcp.o"
 974 case ${host} in
 975   *go32* ) SER_HARDWIRE=ser-go32.o ;;
 976   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
 977 esac
 978 AC_SUBST(SER_HARDWIRE)
 979
 980 # libreadline needs libuser32.a in a cygwin environment
 981 WIN32LIBS=
 982 if test x$gdb_cv_os_cygwin = xyes; then
 983     WIN32LIBS="-luser32"
 984     case "${target}" in
 985         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
 986         ;;
 987     esac
 988 fi
 989 AC_SUBST(WIN32LIBS)
 990
 991 LIBGUI="../libgui/src/libgui.a"
 992 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
 993 AC_SUBST(LIBGUI)
 994 AC_SUBST(GUI_CFLAGS_X)
 995
 996 AC_ARG_WITH(cpu,
 997 [  --with-cpu=CPU          Set the default CPU variant to debug],
 998 [case "${target}" in
 999   powerpc-* | powerpcle-* )
1000     ## It would be nice to keep this table in sync with the one in
1001     ## gcc/configure.
1002     case "${with_cpu}" in
1003       ppc-uisa | rs6000 | 403 | 403GC | 505 | 860 | 601 | 602 | 603 \
1004       | 604 | 750 )
1005         ## Those are all handled in variants in rs6000-tdep.c, so they're fine.
1006       ;;
1007       common | power | power2 | rios | rios1 | rios2 | rsc | rsc1 )
1008         ## These are all RS6000 variants, as far as GDB is concerned.
1009         with_cpu=rs6000
1010       ;;
1011       603e | ec603e )
1012         with_cpu=603
1013       ;;
1014       604e )
1015         with_cpu=604
1016       ;;
1017       * )
1018         AC_MSG_WARN(GDB: unknown --with-cpu value: \`${with_cpu}'; using \`ppc-uisa'.)
1019         with_cpu=ppc-uisa
1020       ;;
1021     esac
1022   ;;
1023   * )
1024     AC_MSG_WARN(GDB may ignore the --with-cpu flag for ${target} targets)
1025   ;;
1026 esac
1027 AC_DEFINE_UNQUOTED(TARGET_CPU_DEFAULT, "${with_cpu}")
1028 ],)
1029
1030
1031 AC_ARG_ENABLE(gdbtk,
1032 [  --enable-gdbtk          Enable GDBTK GUI front end],
1033 [case "${enableval}" in
1034     yes)
1035         case "$host" in
1036         *go32*)
1037             AC_MSG_WARN([GDB does not support GDBtk on host ${host}.  GDBtk will be disabled.])
1038             enable_gdbtk=no ;;
1039         *windows*)
1040             AC_MSG_WARN([GDB does not support GDBtk on host ${host}.  GDBtk will be disabled.])
1041             enable_gdbtk=no ;;
1042         *)
1043             enable_gdbtk=yes ;;
1044         esac ;;
1045     no)
1046         enable_gdbtk=no  ;;
1047     *)
1048         AC_MSG_ERROR(bad value ${enableval} given for gdbtk option) ;;
1049 esac],
1050 [
1051 # Default is on for everything but go32 and Cygwin
1052 case "$host" in
1053     *go32* | *windows*)
1054         ;;
1055     *)
1056         if test -d "${srcdir}/gdbtk" ; then
1057             enable_gdbtk=yes
1058         fi
1059         ;;
1060 esac
1061 ])
1062
1063 WIN32LDAPP=
1064 AC_SUBST(WIN32LIBS)
1065 AC_SUBST(WIN32LDAPP)
1066
1067 configdir="unix"
1068
1069 GDBTKLIBS=
1070 if test "${enable_gdbtk}" = "yes"; then
1071
1072     # Gdbtk must have an absolute path to srcdir in order to run
1073     # properly when not installed.
1074     here=`pwd`
1075     cd ${srcdir}
1076     GDBTK_SRC_DIR=`pwd`
1077     cd $here
1078
1079     CY_AC_PATH_TCLCONFIG
1080     if test -z "${no_tcl}"; then
1081         CY_AC_LOAD_TCLCONFIG
1082         CY_AC_PATH_TKCONFIG
1083
1084         # now look for Tcl library stuff
1085
1086         case "${host}" in
1087         *-*-cygwin*)
1088             tcldir=../tcl/win/
1089             ;;
1090         *)
1091             tcldir=../tcl/unix/
1092             ;;
1093         esac
1094
1095         TCL_DEPS="${tcldir}${TCL_LIB_FILE}"
1096
1097         # If $no_tk is nonempty, then we can't do Tk, and there is no
1098         # point to doing Tcl.
1099         if test -z "${no_tk}"; then
1100            CY_AC_LOAD_TKCONFIG
1101            CY_AC_PATH_TCLH
1102            CY_AC_PATH_TKH
1103            CY_AC_PATH_ITCLH
1104            CY_AC_PATH_ITKH
1105
1106
1107            # now look for Tk library stuff
1108
1109            case "${host}" in
1110            *-*-cygwin*)
1111                tkdir=../tk/win/
1112                ;;
1113            *)
1114                tkdir=../tk/unix/
1115                ;;
1116            esac
1117
1118            TK_DEPS="${tkdir}${TK_LIB_FILE}"
1119
1120            # now look for Itcl library stuff
1121
1122            CY_AC_PATH_ITCLCONFIG
1123            if test -z "${no_itcl}"; then
1124              CY_AC_LOAD_ITCLCONFIG
1125
1126              ITCLLIB="${ITCL_BUILD_LIB_SPEC}"
1127              ITCL_DEPS="${ITCL_LIB_FULL_PATH}"
1128            fi
1129
1130
1131            # now look for Itk library stuff
1132            CY_AC_PATH_ITKCONFIG
1133            if test -z "${no_itcl}"; then
1134              CY_AC_LOAD_ITKCONFIG
1135
1136              ITKLIB="${ITK_BUILD_LIB_SPEC}"
1137              ITK_DEPS="${ITK_LIB_FULL_PATH}"
1138            fi
1139
1140            ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
1141            # Tcl/Tk 8.1 require -fwritable strings.  I don't
1142            # know whether 8.2 will or not, but I bet it will.
1143            # I don't have to worry about 7.x since we don't support it.
1144            GDBTK_CFLAGS=""
1145            if test "$GCC" = "yes"; then
1146                if test "$TCL_VERSION" != "8.0" ; then
1147                    GDBTK_CFLAGS="-fwritable-strings"
1148                fi
1149            fi
1150
1151            # Include some libraries that Tcl and Tk want.
1152            TCL_LIBS='$(LIBGUI) $(ITCL) $(ITK) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
1153            # Yes, the ordering seems wrong here.  But it isn't.
1154            # TK_LIBS is the list of libraries that need to be linked
1155            # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
1156            # were in LIBS then any link tests after this point would
1157            # try to include things like `$(LIBGUI)', which wouldn't work.
1158            GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
1159
1160            CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
1161            CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
1162            CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
1163            CONFIG_INITS="${CONFIG_INITS} \$(SUBDIR_GDBTK_INITS)"
1164            CONFIG_ALL="${CONFIG_ALL} \$(SUBDIR_GDBTK_ALL)"
1165            CONFIG_CLEAN="${CONFIG_CLEAN} \$(SUBDIR_GDBTK_CLEAN)"
1166            CONFIG_INSTALL="${CONFIG_INSTALL} \$(SUBDIR_GDBTK_INSTALL)"
1167            CONFIG_UNINSTALL="${CONFIG_UNINSTALL} \$(SUBDIR_GDBTK_UNINSTALL)"
1168
1169            if test x$gdb_cv_os_cygwin = xyes; then
1170               WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
1171               WIN32LDAPP="-Wl,--subsystem,console"
1172               CONFIG_OBS="${CONFIG_OBS} gdbres.o"
1173            fi
1174         fi
1175     fi
1176
1177     SUBDIRS="${SUBDIRS} gdbtk"
1178     configdirs="${configdirs} gdbtk"
1179 fi
1180
1181 AC_SUBST(X_CFLAGS)
1182 AC_SUBST(X_LDFLAGS)
1183 AC_SUBST(X_LIBS)
1184 AC_SUBST(TCL_DEPS)
1185 AC_SUBST(TK_DEPS)
1186 AC_SUBST(ITCLLIB)
1187 AC_SUBST(ITCL_DEPS)
1188 AC_SUBST(ITKLIB)
1189 AC_SUBST(ITK_DEPS)
1190 AC_SUBST(GDBTKLIBS)
1191 AC_SUBST(GDBTK_CFLAGS)
1192 AC_SUBST(GDBTK_SRC_DIR)
1193
1194 AC_PATH_X
1195
1196
1197 # Unlike the sim directory, whether a simulator is linked is controlled by
1198 # presence of a SIM= and a SIM_OBS= definition in the target '.mt' file.
1199 # This code just checks for a few cases where we'd like to ignore those
1200 # definitions, even when they're present in the '.mt' file.  These cases
1201 # are when --disable-sim is specified, or if the simulator directory is
1202 # not part of the source tree.
1203 #
1204 AC_ARG_ENABLE(sim,
1205 [  --enable-sim            Link gdb with simulator],
1206 [echo "enable_sim = $enable_sim";
1207  echo "enableval = ${enableval}";
1208  case "${enableval}" in
1209   yes) ignore_sim=false ;;
1210   no)  ignore_sim=true ;;
1211   *)   ignore_sim=false ;;
1212  esac],
1213 [ignore_sim=false])
1214
1215 if test ! -d "${srcdir}/../sim"; then
1216   ignore_sim=true
1217 fi
1218
1219 if test "${ignore_sim}" = "true"; then
1220     IGNORE_SIM="SIM="
1221     IGNORE_SIM_OBS="SIM_OBS="
1222 else
1223     IGNORE_SIM=""
1224     IGNORE_SIM_OBS=""
1225     AC_DEFINE(WITH_SIM)
1226 fi
1227 AC_SUBST(IGNORE_SIM)
1228 AC_SUBST(IGNORE_SIM_OBS)
1229
1230 AC_SUBST(ENABLE_CFLAGS)
1231
1232 AC_SUBST(CONFIG_OBS)
1233 AC_SUBST(CONFIG_LIB_OBS)
1234 AC_SUBST(CONFIG_DEPS)
1235 AC_SUBST(CONFIG_SRCS)
1236 AC_SUBST(CONFIG_INITS)
1237 AC_SUBST(CONFIG_ALL)
1238 AC_SUBST(CONFIG_CLEAN)
1239 AC_SUBST(CONFIG_INSTALL)
1240 AC_SUBST(CONFIG_UNINSTALL)
1241
1242 # Begin stuff to support --enable-shared
1243 AC_ARG_ENABLE(shared,
1244 [  --enable-shared         Use shared libraries],
1245 [case "${enableval}" in
1246   yes) shared=true ;;
1247   no)  shared=false ;;
1248   *) shared=true ;;
1249 esac])dnl
1250
1251 HLDFLAGS=
1252 HLDENV=
1253 # If we have shared libraries, try to set rpath reasonably.
1254 if test "${shared}" = "true"; then
1255   case "${host}" in
1256   *-*-hpux*)
1257     HLDFLAGS='-Wl,+s,+b,$(libdir)'
1258     ;;
1259   *-*-irix5* | *-*-irix6*)
1260     HLDFLAGS='-Wl,-rpath,$(libdir)'
1261     ;;
1262   *-*-linux*aout*)
1263     ;;
1264   *-*-linux* | *-pc-linux-gnu*)
1265     HLDFLAGS='-Wl,-rpath,$(libdir)'
1266     ;;
1267   *-*-solaris*)
1268     HLDFLAGS='-R $(libdir)'
1269     ;;
1270   *-*-sysv4*)
1271     HLDENV='if test -z "$${LD_RUN_PATH}"; then LD_RUN_PATH=$(libdir); else LD_RUN_PATH=$${LD_RUN_PATH}:$(libdir); fi; export LD_RUN_PATH;'
1272     ;;
1273   esac
1274 fi
1275
1276 # On SunOS, if the linker supports the -rpath option, use it to
1277 # prevent ../bfd and ../opcodes from being included in the run time
1278 # search path.
1279 case "${host}" in
1280   *-*-sunos*)
1281     echo 'main () { }' > conftest.c
1282     ${CC} -o conftest -Wl,-rpath= conftest.c >/dev/null 2>conftest.t
1283     if grep 'unrecognized' conftest.t >/dev/null 2>&1; then
1284       :
1285     elif grep 'No such file' conftest.t >/dev/null 2>&1; then
1286       :
1287     elif grep 'do not mix' conftest.t >/dev/null 2>&1; then
1288       :
1289     elif grep 'some text already loaded' conftest.t >/dev/null 2>&1; then
1290       :
1291     elif test "${shared}" = "true"; then
1292       HLDFLAGS='-Wl,-rpath=$(libdir)'
1293     else
1294       HLDFLAGS='-Wl,-rpath='
1295     fi
1296     rm -f conftest.t conftest.c conftest
1297     ;;
1298 esac
1299 AC_SUBST(HLDFLAGS)
1300 AC_SUBST(HLDENV)
1301 # End stuff to support --enable-shared
1302
1303 # target_subdir is used by the testsuite to find the target libraries.
1304 target_subdir=
1305 if test "${host}" != "${target}"; then
1306     target_subdir="${target_alias}/"
1307 fi
1308 AC_SUBST(target_subdir)
1309
1310 frags=
1311 host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
1312 if test ! -f ${host_makefile_frag}; then
1313     # When building a native debuger the .mh file containing things
1314     # like NATDEPFILES is needed.  Cross debuggers don't need .mh
1315     # since it no longer contains anything useful.
1316     if test "${target}" = "${host}"; then
1317         AC_MSG_ERROR("*** Gdb does not support native target ${host}")
1318     else
1319         host_makefile_frag=/dev/null
1320     fi
1321 fi
1322 frags="$frags $host_makefile_frag"
1323
1324 target_makefile_frag=${srcdir}/config/${gdb_target_cpu}/${gdb_target}.mt
1325 if test ! -f ${target_makefile_frag}; then
1326 AC_MSG_ERROR("*** Gdb does not support target ${target}")
1327 fi
1328 frags="$frags $target_makefile_frag"
1329
1330 AC_SUBST_FILE(host_makefile_frag)
1331 AC_SUBST_FILE(target_makefile_frag)
1332 AC_SUBST(frags)
1333
1334 changequote(,)dnl
1335 hostfile=`sed -n '
1336 s/XM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
1337 ' ${host_makefile_frag}`
1338
1339 targetfile=`sed -n '
1340 s/TM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
1341 ' ${target_makefile_frag}`
1342
1343 GDB_MULTI_ARCH=`sed -n '
1344 s/GDB_MULTI_ARCH[       ]*=[    ]*\([^  ]*\)[   ]*/\1/p
1345 ' ${target_makefile_frag}`
1346
1347 if test "${target}" = "${host}"; then
1348 # We pick this up from the host configuration file (.mh) because we
1349 # do not have a native configuration Makefile fragment.
1350 nativefile=`sed -n '
1351 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
1352 ' ${host_makefile_frag}`
1353 fi
1354 changequote([,])
1355
1356 # New targets should just set gdb_multi_arch=yes in configure.tgt.
1357 # Old targets being converted can either do that or set GDB_MULTI_ARCH
1358 # in the target specific makefile frag.  Eventually gdb_multi_arch=yes
1359 # will be the default.
1360 if test x"${GDB_MULTI_ARCH}" = x ; then
1361     case "${gdb_multi_arch}" in
1362     yes ) GDB_MULTI_ARCH=GDB_MULTI_ARCH_PURE ;;
1363     no ) GDB_MULTI_ARCH=0 ;;
1364     0|1|2 ) GDB_MULTI_ARCH=${gdb_multi_arch} ;;
1365     esac
1366 fi
1367 if test x"${GDB_MULTI_ARCH}" != x ; then
1368     AC_DEFINE_UNQUOTED(GDB_MULTI_ARCH, ${GDB_MULTI_ARCH})
1369 fi
1370 # Warn the user when they use an old practice
1371 case "${GDB_MULTI_ARCH}" in
1372     "" ) ;;
1373     0 | GDB_MULTI_ARCH_PARTIAL | 1 | GDB_MULTI_ARCH_TM | 2 )
1374         AC_MSG_WARN("GDB: Target is not pure multi-arch") ;;
1375     GDB_MULTI_ARCH_PURE )
1376         if test x"${targetfile}" != x ; then
1377             AC_MSG_WARN("GDB: Ignoring TM_FILE in ${target_makefile_frag}")
1378             targetfile=""
1379         fi ;;
1380     *)  AC_MSG_ERROR("GDB: Unknown GDB_MULTI_ARCH value ${GDB_MULTI_ARCH}");;
1381 esac
1382
1383 if test "${enable_multi_ice}" = "yes"; then
1384   SUBDIRS="${SUBDIRS} multi-ice"
1385 fi
1386
1387 # ``gdbserver'' can only be built in a native configuration.
1388 if test x"${target}" = x"${host}"; then
1389     AC_MSG_CHECKING(whether gdbserver is supported on this host)
1390     if test x"${build_gdbserver}" = xyes ; then
1391         configdirs="${configdirs} gdbserver"
1392         SUBDIRS="${SUBDIRS} gdbserver"
1393         AC_MSG_RESULT(yes)
1394     else
1395         AC_MSG_RESULT(no)
1396     fi
1397 fi
1398
1399 AC_SUBST(SUBDIRS)
1400
1401 # If hostfile (XM_FILE) and/or targetfile (TM_FILE) and/or nativefile
1402 # (NAT_FILE) is not set in config/*/*.m[ht] files, we link to an empty
1403 # version.
1404
1405 files=
1406 links=
1407
1408 rm -f xm.h
1409 xm_h=""
1410 if test "${hostfile}" != ""; then
1411     xm_h=xm.h
1412     GDB_XM_FILE="config/${gdb_host_cpu}/${hostfile}"
1413     files="${files} ${GDB_XM_FILE}"
1414     links="${links} xm.h"
1415     AC_DEFINE_UNQUOTED(GDB_XM_FILE, ${GDB_XM_FILE})
1416 fi
1417 AC_SUBST(xm_h)
1418
1419 rm -f tm.h
1420 tm_h=""
1421 if test "${targetfile}" != ""; then
1422     tm_h=tm.h
1423     GDB_TM_FILE="config/${gdb_target_cpu}/${targetfile}"
1424     files="${files} ${GDB_TM_FILE}"
1425     links="${links} tm.h"
1426     AC_DEFINE_UNQUOTED(GDB_TM_FILE, ${GDB_TM_FILE})
1427 fi
1428 AC_SUBST(tm_h)
1429
1430 rm -f nm.h
1431 nm_h=""
1432 if test "${nativefile}" != ""; then
1433     nm_h=nm.h
1434     GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}"
1435     files="${files} ${GDB_NM_FILE}"
1436     links="${links} nm.h"
1437     AC_DEFINE_UNQUOTED(GDB_NM_FILE, ${GDB_NM_FILE})
1438 fi
1439 AC_SUBST(nm_h)
1440
1441 AC_LINK_FILES($files, $links)
1442
1443 dnl Check for exe extension set on certain hosts (e.g. Win32)
1444 AC_EXEEXT
1445
1446 dnl  Detect the character set used by this host.
1447
1448 dnl  At the moment, we just assume it's ISO-8859-1 (which is a
1449 dnl  superset of ASCII containing the characters needed for French,
1450 dnl  German, Spanish, Italian, and possibly others), but if were
1451 dnl  *were* to support any host character sets other than ISO-8859-1,
1452 dnl  here's where we'd detect it.
1453 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "ISO-8859-1",
1454           [Define to be a string naming the default host character set.])
1455
1456 AM_ICONV
1457
1458 AC_CONFIG_SUBDIRS($configdirs)
1459 AC_OUTPUT(Makefile .gdbinit:gdbinit.in,
1460 [
1461 dnl Autoconf doesn't provide a mechanism for modifying definitions
1462 dnl provided by makefile fragments.
1463 dnl
1464 if test "${nativefile}" = ""; then
1465         < Makefile \
1466         sed -e '/^NATDEPFILES[[         ]]*=.*\\$/,/[[^\\]]$/s/^/# /' \
1467             -e '/^NATDEPFILES[[         ]]*=/s/^/# /' \
1468         | sed -e '/^\(NATDEPFILES[[     ]]*[[+]]=[[     ]]*\)/s//# \1/' \
1469         > Makefile.tem
1470 mv -f Makefile.tem Makefile
1471 fi
1472
1473 changequote(,)dnl
1474 sed -e '/^TM_FILE[      ]*=/s,^TM_FILE[         ]*=[    ]*,&config/'"${gdb_target_cpu}"'/,
1475 /^XM_FILE[      ]*=/s,^XM_FILE[         ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,
1476 /^NAT_FILE[     ]*=/s,^NAT_FILE[        ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,' <Makefile >Makefile.tmp
1477 mv -f Makefile.tmp Makefile
1478 changequote([,])dnl
1479
1480
1481 case x$CONFIG_HEADERS in
1482 xconfig.h:config.in)
1483 echo > stamp-h ;;
1484 esac
1485 ],
1486 [
1487 gdb_host_cpu=$gdb_host_cpu
1488 gdb_target_cpu=$gdb_target_cpu
1489 nativefile=$nativefile
1490 ])
1491
1492 exit 0