gdb/configure.in

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright 1995, 1996 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 2 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program; if not, write to the Free Software
  18 dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  19
  20 dnl Process this file with autoconf to produce a configure script.
  21
  22 AC_PREREQ(2.5)dnl
  23 AC_INIT(main.c)
  24 AC_CONFIG_HEADER(config.h:config.in)
  25
  26 AC_PROG_CC
  27 AC_AIX
  28 AC_MINIX
  29 AC_ISC_POSIX
  30
  31 DLLTOOL=${DLLTOOL-dlltool}
  32 AC_SUBST(DLLTOOL)
  33
  34 AC_CONFIG_AUX_DIR(`cd $srcdir;pwd`/..)
  35 AC_CANONICAL_SYSTEM
  36
  37 dnl List of object files added by configure.
  38
  39 CONFIG_OBS=
  40 CONFIG_DEPS=
  41 CONFIG_SRCS=
  42
  43 configdirs="doc testsuite"
  44
  45 dnl
  46 changequote(,)dnl
  47
  48 . ${srcdir}/configure.host
  49
  50 . ${srcdir}/configure.tgt
  51
  52 dnl
  53 changequote([,])dnl
  54
  55 AC_PROG_INSTALL
  56 AC_CHECK_TOOL(AR, ar)
  57 AC_CHECK_TOOL(RANLIB, ranlib, :)
  58 AC_PROG_YACC
  59 AC_PROG_AWK
  60
  61 AC_ARG_PROGRAM
  62
  63 AC_TYPE_SIGNAL
  64
  65 AC_HEADER_STDC
  66 AC_CHECK_HEADERS(limits.h memory.h string.h strings.h unistd.h termios.h termio.h sgtty.h stddef.h stdlib.h sys/procfs.h link.h endian.h objlist.h)
  67 AC_HEADER_STAT
  68
  69 AC_C_CONST
  70
  71 AC_CHECK_FUNCS(setpgid sbrk select poll sigaction)
  72
  73 # If we are configured native on GNU/Linux, work around problems with sys/procfs.h
  74 if test "${target}" = "${host}"; then
  75   case "${host}" in
  76   i[[3456]]86-*-linux*)
  77         AC_DEFINE(START_INFERIOR_TRAPS_EXPECTED,2)
  78         AC_DEFINE(sys_quotactl)
  79         ;;
  80   esac
  81 fi
  82
  83 AC_MSG_CHECKING([for gregset_t type])
  84 AC_CACHE_VAL(gdb_cv_have_gregset_t,
  85 [AC_TRY_LINK([#include <sys/procfs.h>],[gregset_t *gregsetp = 0],
  86 gdb_cv_have_gregset_t=yes, gdb_cv_have_gregset_t=no)])
  87 AC_MSG_RESULT($gdb_cv_have_gregset_t)
  88 if test $gdb_cv_have_gregset_t = yes; then
  89   AC_DEFINE(HAVE_GREGSET_T)
  90 fi
  91
  92 AC_MSG_CHECKING([for fpregset_t type])
  93 AC_CACHE_VAL(gdb_cv_have_fpregset_t,
  94 [AC_TRY_LINK([#include <sys/procfs.h>],[fpregset_t *fpregsetp = 0],
  95 gdb_cv_have_fpregset_t=yes, gdb_cv_have_fpregset_t=no)])
  96 AC_MSG_RESULT($gdb_cv_have_fpregset_t)
  97 if test $gdb_cv_have_fpregset_t = yes; then
  98   AC_DEFINE(HAVE_FPREGSET_T)
  99 fi
 100
 101 dnl See if host has libm.  This is usually needed by simulators.
 102 AC_CHECK_LIB(m, main)
 103
 104 dnl See if compiler supports "long long" type.
 105
 106 AC_MSG_CHECKING(for long long support in compiler)
 107 AC_CACHE_VAL(gdb_cv_c_long_long,
 108 [AC_TRY_COMPILE(, [
 109   extern long long foo;
 110   switch (foo & 2) { case 0: return 1; }
 111 ],
 112 gdb_cv_c_long_long=yes, gdb_cv_c_long_long=no)])
 113 AC_MSG_RESULT($gdb_cv_c_long_long)
 114 if test $gdb_cv_c_long_long = yes; then
 115   AC_DEFINE(CC_HAS_LONG_LONG)
 116 fi
 117
 118 dnl See if the compiler and runtime support printing long long
 119
 120 AC_MSG_CHECKING(for long long support in printf)
 121 AC_CACHE_VAL(gdb_cv_printf_has_long_long,
 122 [AC_TRY_RUN([
 123 int main () {
 124   char buf[32];
 125   long long l = 0;
 126   l = (l << 16) + 0x0123;
 127   l = (l << 16) + 0x4567;
 128   l = (l << 16) + 0x89ab;
 129   l = (l << 16) + 0xcdef;
 130   sprintf (buf, "0x%016llx", l);
 131   return (strcmp ("0x0123456789abcdef", buf));
 132 }],
 133 gdb_cv_printf_has_long_long=yes,
 134 gdb_cv_printf_has_long_long=no,
 135 gdb_cv_printf_has_long_long=no)])
 136 if test $gdb_cv_printf_has_long_long = yes; then
 137   AC_DEFINE(PRINTF_HAS_LONG_LONG)
 138 fi
 139 AC_MSG_RESULT($gdb_cv_printf_has_long_long)
 140
 141 dnl See if compiler supports "long double" type.  Can't use AC_C_LONG_DOUBLE
 142 dnl because autoconf complains about cross-compilation issues.  However, this
 143 dnl code uses the same variables as the macro for compatibility.
 144
 145 AC_MSG_CHECKING(for long double support in compiler)
 146 AC_CACHE_VAL(ac_cv_c_long_double,
 147 [AC_TRY_COMPILE(, [long double foo;],
 148 ac_cv_c_long_double=yes, ac_cv_c_long_double=no)])
 149 AC_MSG_RESULT($ac_cv_c_long_double)
 150 if test $ac_cv_c_long_double = yes; then
 151   AC_DEFINE(HAVE_LONG_DOUBLE)
 152 fi
 153
 154 dnl See if the compiler and runtime support printing long doubles
 155
 156 AC_MSG_CHECKING(for long double support in printf)
 157 AC_CACHE_VAL(gdb_cv_printf_has_long_double,
 158 [AC_TRY_RUN([
 159 int main () {
 160   char buf[16];
 161   long double f = 3.141592653;
 162   sprintf (buf, "%Lg", f);
 163   return (strncmp ("3.14159", buf, 7));
 164 }],
 165 gdb_cv_printf_has_long_double=yes,
 166 gdb_cv_printf_has_long_double=no,
 167 gdb_cv_printf_has_long_double=no)])
 168 if test $gdb_cv_printf_has_long_double = yes; then
 169   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE)
 170 fi
 171 AC_MSG_RESULT($gdb_cv_printf_has_long_double)
 172
 173 dnl See if the compiler and runtime support scanning long doubles
 174
 175 AC_MSG_CHECKING(for long double support in scanf)
 176 AC_CACHE_VAL(gdb_cv_scanf_has_long_double,
 177 [AC_TRY_RUN([
 178 int main () {
 179   char *buf = "3.141592653";
 180   long double f = 0;
 181   sscanf (buf, "%Lg", &f);
 182   return !(f > 3.14159 && f < 3.14160);
 183 }],
 184 gdb_cv_scanf_has_long_double=yes,
 185 gdb_cv_scanf_has_long_double=no,
 186 gdb_cv_scanf_has_long_double=no)])
 187 if test $gdb_cv_scanf_has_long_double = yes; then
 188   AC_DEFINE(SCANF_HAS_LONG_DOUBLE)
 189 fi
 190 AC_MSG_RESULT($gdb_cv_scanf_has_long_double)
 191
 192 AC_FUNC_MMAP
 193
 194 BFD_NEED_DECLARATION(malloc)
 195 BFD_NEED_DECLARATION(realloc)
 196 BFD_NEED_DECLARATION(free)
 197
 198 dnl See if thread_db library is around for Solaris thread debugging.  Note that
 199 dnl we must explicitly test for version 1 of the library because version 0
 200 dnl (present on Solaris 2.4 or earlier) doesn't have the same API.
 201
 202 dnl Note that we only want this if we are both native (host == target), and
 203 dnl not doing a canadian cross build (build == host).
 204
 205 if test ${build} = ${host} -a ${host} = ${target} ; then
 206    case ${host_os} in
 207    hpux*)
 208       AC_MSG_CHECKING(for HPUX/OSF thread support)
 209       if test -f /usr/include/dce/cma_config.h ; then
 210          if test "$GCC" = "yes" ; then
 211             AC_MSG_RESULT(yes)
 212             AC_DEFINE(HAVE_HPUX_THREAD_SUPPORT)
 213             CONFIG_OBS="${CONFIG_OJS} hpux-thread.o"
 214             CONFIG_SRCS="${CONFIG_SRCS} hpux-thread.c"
 215          else
 216             AC_MSG_RESULT(no (suppressed because you are not using GCC))
 217          fi
 218       else
 219          AC_MSG_RESULT(no)
 220       fi
 221       ;;
 222    solaris*)
 223       AC_MSG_CHECKING(for Solaris thread debugging library)
 224       if test -f /usr/lib/libthread_db.so.1 ; then
 225          AC_MSG_RESULT(yes)
 226          AC_DEFINE(HAVE_THREAD_DB_LIB)
 227          CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
 228          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
 229          AC_CHECK_LIB(dl, dlopen)
 230          if test "$GCC" = "yes" ; then
 231             # The GNU linker requires the -export-dynamic option to make
 232             # all symbols visible in the dynamic symbol table.
 233             hold_ldflags=$LDFLAGS
 234             AC_MSG_CHECKING(for the ld -export-dynamic flag)
 235             LDFLAGS="${LDFLAGS} -Wl,-export-dynamic"
 236             AC_TRY_LINK(, [int i;], found=yes, found=no)
 237             LDFLAGS=$hold_ldflags
 238             AC_MSG_RESULT($found)
 239             if test $found = yes; then
 240                CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -Wl,-export-dynamic"
 241             fi
 242          fi
 243       else
 244          AC_MSG_RESULT(no)
 245       fi
 246       ;;
 247    esac
 248    AC_SUBST(CONFIG_LDFLAGS)
 249 fi
 250
 251 dnl Handle optional features that can be enabled.
 252 ENABLE_CFLAGS=
 253
 254 AC_ARG_ENABLE(netrom,
 255 [  --enable-netrom ],
 256 [case "${enableval}" in
 257 yes)    enable_netrom=yes ;;
 258 no)     enable_netrom=no ;;
 259 *)      AC_MSG_ERROR(bad value ${enableval} given for netrom option) ;;
 260 esac])
 261
 262 if test "${enable_netrom}" = "yes"; then
 263         CONFIG_OBS="${CONFIG_OBS} remote-nrom.o"
 264         CONFIG_SRCS="${CONFIG_SRCS} remote-nrom.c"
 265 fi
 266
 267 MMALLOC_CFLAGS=
 268 MMALLOC=
 269 AC_SUBST(MMALLOC_CFLAGS)
 270 AC_SUBST(MMALLOC)
 271
 272 AC_ARG_WITH(mmalloc,
 273 [  --with-mmalloc             use memory mapped malloc package],
 274 [case "${withval}" in
 275   yes)  want_mmalloc=true ;;
 276   no)   want_mmalloc=false;;
 277   *)    AC_MSG_ERROR(bad value ${withval} for GDB with-mmalloc option) ;;
 278 esac],[want_mmalloc=false])dnl
 279
 280 if test x$want_mmalloc = xtrue; then
 281    AC_DEFINE(USE_MMALLOC)
 282    AC_DEFINE(MMCHECK_FORCE)
 283    MMALLOC_CFLAGS="-I$srcdir/../mmalloc"
 284    MMALLOC='../mmalloc/libmmalloc.a'
 285 fi
 286
 287 # start-sanitize-gdbtk
 288 ENABLE_IDE=
 289 AC_ARG_ENABLE(ide, [  --enable-ide            Enable IDE support])
 290 if test "$enable_ide" = yes; then
 291    enable_ide=yes
 292    ENABLE_IDE=1
 293 else
 294    enable_ide=no
 295 fi
 296 AC_SUBST(ENABLE_IDE)
 297
 298 ENABLE_GDBTK=
 299
 300 AC_ARG_ENABLE(gdbtk,
 301 [  --enable-gdbtk ],
 302 [case "${enableval}" in
 303     yes)
 304         case "$host" in
 305         *go32*)
 306             AC_MSG_WARN([GDB does not support GDBtk on host ${host}.  GDBtk will be disabled.])
 307             enable_gdbtk=no ;;
 308         *windows*)
 309             AC_MSG_WARN([GDB does not support GDBtk on host ${host}.  GDBtk will be disabled.])
 310             enable_gdbtk=no ;;
 311         *)
 312             enable_gdbtk=yes ;;
 313         esac ;;
 314     no)
 315         enable_gdbtk=no  ;;
 316     *)
 317         AC_MSG_ERROR(bad value ${enableval} given for gdbtk option) ;;
 318 esac],
 319 [
 320 # Default is on for everything but go32 and cygwin32
 321 case "$host" in
 322     *go32* | *windows*)
 323         ;;
 324     *)
 325         enable_gdbtk=yes ;;
 326     esac
 327 ])
 328
 329 # In the cygwin32 environment, we need some additional flags.
 330 AC_CACHE_CHECK([for cygwin32], gdb_cv_os_cygwin32,
 331 [AC_EGREP_CPP(lose, [
 332 #ifdef __CYGWIN32__
 333 lose
 334 #endif],[gdb_cv_os_cygwin32=yes],[gdb_cv_os_cygwin32=no])])
 335
 336 WIN32LIBS=
 337 WIN32LDAPP=
 338 AC_SUBST(WIN32LIBS)
 339 AC_SUBST(WIN32LDAPP)
 340
 341 WINDRES=${WINDRES-windres}
 342 AC_SUBST(WINDRES)
 343
 344 if test x$gdb_cv_os_cygwin32 = xyes; then
 345     if test x$enable_ide = xyes; then
 346         WIN32LIBS="-ladvapi32"
 347     fi
 348 fi
 349
 350 configdir="unix"
 351
 352 if test "${enable_gdbtk}" = "yes"; then
 353
 354     CY_AC_PATH_TCLCONFIG
 355     if test -z "${no_tcl}"; then
 356         CY_AC_LOAD_TCLCONFIG
 357         CY_AC_PATH_TKCONFIG
 358
 359         # If $no_tk is nonempty, then we can't do Tk, and there is no
 360         # point to doing Tcl.
 361         if test -z "${no_tk}"; then
 362            CY_AC_LOAD_TKCONFIG
 363            CY_AC_PATH_TCLH
 364            CY_AC_PATH_TKH
 365            CY_AC_PATH_ITCLH
 366            CY_AC_PATH_TIX
 367
 368            # now look for tix library stuff
 369            TIXVERSION=4.1.8.0
 370            . ${ac_cv_c_tclconfig}/tclConfig.sh
 371            case "${host}" in
 372            *-*-cygwin32*)
 373                 tixdir=../tix/win/tcl8.0
 374                 ;;
 375            *)
 376                 tixdir=../tix/unix/tk8.0
 377                 ;;
 378            esac
 379            if test "${TCL_SHARED_BUILD}" = "1"; then
 380                 TIX_LIB_EXT="${TCL_SHLIB_SUFFIX}"
 381
 382                 # Can't win them all: SunOS 4 (others?) appends a version
 383                 # number after the ".so"
 384                 case "${host}" in
 385                 *-*-sunos4*)
 386                     TIX_LIB_EXT="${TIX_LIB_EXT}.1.0" ;;
 387                 esac
 388
 389            else
 390                 TIX_LIB_EXT=".a"
 391            fi
 392
 393            if test "${TCL_LIB_VERSIONS_OK}" = "ok"; then
 394                 TIXLIB="-L${tixdir} -ltix${TIXVERSION}"
 395                 TIX_DEPS="${tixdir}/libtix${TIXVERSION}${TIX_LIB_EXT}"
 396            else
 397                 TIXLIB="-L${tixdir} -ltix`echo ${TIXVERSION} | tr -d .`"
 398                 TIX_DEPS="${tixdir}/libtix`echo ${TIXVERSION} | tr -d .`${TIX_LIB_EXT}"
 399            fi
 400
 401            ENABLE_GDBTK=1
 402
 403            # Include some libraries that Tcl and Tk want.
 404            if test "${enable_ide}" = "yes"; then
 405               TCL_LIBS='$(LIBIDETCL) $(LIBIDE) $(LIBGUI) $(IDE) $(ITCL) $(TIX) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
 406               CONFIG_DEPS='$(LIBIDETCL) $(LIBIDE) $(LIBGUI) $(IDE_DEPS) $(ITCL_DEPS) $(TIX_DEPS) $(TK_DEPS) $(TCL_DEPS)'
 407            else
 408               TCL_LIBS='$(LIBGUI) $(ITCL) $(TIX) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
 409               CONFIG_DEPS='$(LIBGUI) $(ITCL_DEPS) $(TIX_DEPS) $(TK_DEPS) $(TCL_DEPS)'
 410            fi
 411            # Yes, the ordering seems wrong here.  But it isn't.
 412            # TK_LIBS is the list of libraries that need to be linked
 413            # after Tcl/Tk.
 414            LIBS="${LIBS} ${TCL_LIBS} ${TK_LIBS}"
 415            CONFIG_OBS="${CONFIG_OBS} gdbtk.o"
 416
 417            if test x$gdb_cv_os_cygwin32 = xyes; then
 418               WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32 -luser32"
 419               WIN32LDAPP="-Wl,--subsystem,windows"
 420               CONFIG_OBS="${CONFIG_OBS} gdbres.o"
 421            fi
 422         fi
 423     fi
 424 fi
 425
 426 AC_SUBST(ENABLE_GDBTK)
 427 AC_SUBST(X_CFLAGS)
 428 AC_SUBST(X_LDFLAGS)
 429 AC_SUBST(X_LIBS)
 430 AC_SUBST(TIXLIB)
 431 AC_SUBST(TIX_DEPS)
 432 # end-sanitize-gdbtk
 433
 434 AC_PATH_X
 435 # start-sanitize-sky
 436 # Enable GPU2 library for MIPS simulator
 437 AC_ARG_WITH(sim-gpu2,
 438 [  --with-sim-gpu2=path                 Use GPU2 library under given directory],
 439 [case "${target}" in
 440   mips*-sky-*)
 441     if test -d "${withval}"
 442     then
 443       LIBS="${LIBS} -L${withval}/lib -lgpu2 -L${x_libraries} -lX11"
 444     else
 445       AC_MSG_WARN([Directory ${withval} does not exist.])
 446     fi ;;
 447   *)  AC_MSG_WARN([--with-sim-gpu2 option invalid for target ${target}])
 448 esac])dnl
 449
 450 # Enable target accurate FP library
 451 AC_ARG_WITH(sim-funit,
 452 [  --with-sim-funit=path                Use target FP lib under given directory],
 453 [case "${target}" in
 454   mips*-sky-*)
 455     if test -d "${withval}"
 456     then
 457       LIBS="${LIBS} -L${withval}/lib -lfunit"
 458     else
 459       AC_MSG_WARN([Directory ${withval} does not exist.])
 460     fi ;;
 461   *)  AC_MSG_WARN([--with-sim-funit option invalid for target ${target}])
 462 esac])dnl
 463 # end-sanitize-sky
 464
 465 AC_SUBST(ENABLE_CFLAGS)
 466
 467 AC_SUBST(CONFIG_OBS)
 468 AC_SUBST(CONFIG_DEPS)
 469 AC_SUBST(CONFIG_SRCS)
 470
 471 # Begin stuff to support --enable-shared
 472 AC_ARG_ENABLE(shared,
 473 [  --enable-shared         use shared libraries],
 474 [case "${enableval}" in
 475   yes) shared=true ;;
 476   no)  shared=false ;;
 477   *) shared=true ;;
 478 esac])dnl
 479
 480 HLDFLAGS=
 481 HLDENV=
 482 # If we have shared libraries, try to set rpath reasonably.
 483 if test "${shared}" = "true"; then
 484   case "${host}" in
 485   *-*-hpux*)
 486     HLDFLAGS='-Wl,+s,+b,$(libdir)'
 487     ;;
 488   *-*-irix5* | *-*-irix6*)
 489     HLDFLAGS='-Wl,-rpath,$(libdir)'
 490     ;;
 491   *-*-linux*aout*)
 492     ;;
 493   *-*-linux* | *-pc-linux-gnu)
 494     HLDFLAGS='-Wl,-rpath,$(libdir)'
 495     ;;
 496   *-*-solaris*)
 497     HLDFLAGS='-R $(libdir)'
 498     ;;
 499   *-*-sysv4*)
 500     HLDENV='if test -z "$${LD_RUN_PATH}"; then LD_RUN_PATH=$(libdir); else LD_RUN_PATH=$${LD_RUN_PATH}:$(libdir); fi; export LD_RUN_PATH;'
 501     ;;
 502   esac
 503 fi
 504
 505 # On SunOS, if the linker supports the -rpath option, use it to
 506 # prevent ../bfd and ../opcodes from being included in the run time
 507 # search path.
 508 case "${host}" in
 509   *-*-sunos*)
 510     echo 'main () { }' > conftest.c
 511     ${CC} -o conftest -Wl,-rpath= conftest.c >/dev/null 2>conftest.t
 512     if grep 'unrecognized' conftest.t >/dev/null 2>&1; then
 513       :
 514     elif grep 'No such file' conftest.t >/dev/null 2>&1; then
 515       :
 516     elif grep 'do not mix' conftest.t >/dev/null 2>&1; then
 517       :
 518     elif grep 'some text already loaded' conftest.t >/dev/null 2>&1; then
 519       :
 520     elif test "${shared}" = "true"; then
 521       HLDFLAGS='-Wl,-rpath=$(libdir)'
 522     else
 523       HLDFLAGS='-Wl,-rpath='
 524     fi
 525     rm -f conftest.t conftest.c conftest
 526     ;;
 527 esac
 528 AC_SUBST(HLDFLAGS)
 529 AC_SUBST(HLDENV)
 530 # End stuff to support --enable-shared
 531
 532 # target_subdir is used by the testsuite to find the target libraries.
 533 target_subdir=
 534 if test "${host}" != "${target}"; then
 535     target_subdir="${target_alias}/"
 536 fi
 537 AC_SUBST(target_subdir)
 538
 539 frags=
 540 host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
 541 if test ! -f ${host_makefile_frag}; then
 542 AC_MSG_ERROR("*** Gdb does not support host ${host}")
 543 fi
 544 frags="$frags $host_makefile_frag"
 545
 546 target_makefile_frag=${srcdir}/config/${gdb_target_cpu}/${gdb_target}.mt
 547 if test ! -f ${target_makefile_frag}; then
 548 AC_MSG_ERROR("*** Gdb does not support target ${target}")
 549 fi
 550 frags="$frags $target_makefile_frag"
 551
 552 AC_SUBST_FILE(host_makefile_frag)
 553 AC_SUBST_FILE(target_makefile_frag)
 554 AC_SUBST(frags)
 555
 556 changequote(,)dnl
 557 hostfile=`sed -n '
 558 s/XM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
 559 ' ${host_makefile_frag}`
 560
 561 targetfile=`sed -n '
 562 s/TM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
 563 ' ${target_makefile_frag}`
 564
 565 # these really aren't orthogonal true/false values of the same condition,
 566 # but shells are slow enough that I like to reuse the test conditions
 567 # whenever possible
 568 if test "${target}" = "${host}"; then
 569 nativefile=`sed -n '
 570 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
 571 ' ${host_makefile_frag}`
 572 # else
 573 # GDBserver is only useful in a "native" enviroment
 574 # configdirs=`echo $configdirs | sed 's/gdbserver//'`
 575 fi
 576 changequote([,])
 577
 578 # If hostfile (XM_FILE) and/or targetfile (TM_FILE) and/or nativefile
 579 # (NAT_FILE) is not set in config/*/*.m[ht] files, we don't make the
 580 # corresponding links.  But we have to remove the xm.h files and tm.h
 581 # files anyway, e.g. when switching from "configure host" to
 582 # "configure none".
 583
 584 files=
 585 links=
 586 rm -f xm.h
 587 if test "${hostfile}" != ""; then
 588 files="${files} config/${gdb_host_cpu}/${hostfile}"
 589 links="${links} xm.h"
 590 fi
 591 rm -f tm.h
 592 if test "${targetfile}" != ""; then
 593 files="${files} config/${gdb_target_cpu}/${targetfile}"
 594 links="${links} tm.h"
 595 fi
 596 rm -f nm.h
 597 if test "${nativefile}" != ""; then
 598 files="${files} config/${gdb_host_cpu}/${nativefile}"
 599 links="${links} nm.h"
 600 else
 601 # A cross-only configuration.
 602 files="${files} config/nm-empty.h"
 603 links="${links} nm.h"
 604 fi
 605 # start-sanitize-gdbtk
 606 AC_PROG_LN_S
 607 # Make it possible to use the GUI without doing a full install
 608 if test "${enable_gdbtk}" = "yes" -a ! -d gdbtcl ; then
 609   if test "$LN_S" = "ln -s" -a ! -f gdbtcl ; then
 610   echo linking $srcdir/gdbtcl to gdbtcl
 611   $LN_S $srcdir/gdbtcl gdbtcl
 612   else
 613   echo Warning: Unable to link $srcdir/gdbtcl to gdbtcl.  You will need to do a
 614   echo "         " make install before you are able to run the GUI.
 615   fi
 616 fi
 617 # end-sanitize-gdbtk
 618
 619 AC_LINK_FILES($files, $links)
 620
 621 dnl Check for exe extension set on certain hosts (e.g. Win32)
 622 AM_EXEEXT
 623
 624 AC_CONFIG_SUBDIRS($configdirs)
 625 AC_OUTPUT(Makefile .gdbinit:gdbinit.in,
 626 [
 627 dnl Autoconf doesn't provide a mechanism for modifying definitions
 628 dnl provided by makefile fragments.
 629 dnl
 630 if test "${nativefile}" = ""; then
 631 sed -e '/^NATDEPFILES[[         ]]*=[[  ]]*/s//# NATDEPFILES=/' \
 632         < Makefile > Makefile.tem
 633 mv -f Makefile.tem Makefile
 634 fi
 635
 636 changequote(,)dnl
 637 sed -e '/^TM_FILE[      ]*=/s,^TM_FILE[         ]*=[    ]*,&config/'"${gdb_target_cpu}"'/,
 638 /^XM_FILE[      ]*=/s,^XM_FILE[         ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,
 639 /^NAT_FILE[     ]*=/s,^NAT_FILE[        ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,' <Makefile >Makefile.tmp
 640 mv -f Makefile.tmp Makefile
 641 changequote([,])dnl
 642
 643 case x$CONFIG_HEADERS in
 644 xconfig.h:config.in)
 645 echo > stamp-h ;;
 646 esac
 647 ],
 648 [
 649 gdb_host_cpu=$gdb_host_cpu
 650 gdb_target_cpu=$gdb_target_cpu
 651 nativefile=$nativefile
 652 ])
 653
 654 exit 0
 655