gdb/configure.in

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003
   3 dnl Free Software Foundation, Inc.
   4 dnl
   5 dnl This file is part of GDB.
   6 dnl
   7 dnl This program is free software; you can redistribute it and/or modify
   8 dnl it under the terms of the GNU General Public License as published by
   9 dnl the Free Software Foundation; either version 2 of the License, or
  10 dnl (at your option) any later version.
  11 dnl
  12 dnl This program is distributed in the hope that it will be useful,
  13 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 dnl GNU General Public License for more details.
  16 dnl
  17 dnl You should have received a copy of the GNU General Public License
  18 dnl along with this program; if not, write to the Free Software
  19 dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  20
  21 dnl Process this file with autoconf to produce a configure script.
  22
  23 AC_PREREQ(2.13)dnl
  24 AC_INIT(main.c)
  25 AC_CONFIG_HEADER(config.h:config.in)
  26 AM_MAINTAINER_MODE
  27
  28 AC_PROG_CC
  29 AC_GNU_SOURCE
  30 AC_AIX
  31 AC_ISC_POSIX
  32 AM_PROG_CC_STDC
  33
  34 AC_CONFIG_AUX_DIR(`cd $srcdir;pwd`/..)
  35 AC_CANONICAL_SYSTEM
  36
  37 # FIXME: kettenis/20030102: The AC_PROG_RANLIB from Autoconf 2.13
  38 # doesn't support cross-compilation, but the one from Autoconf 2.5x
  39 # does.  Override RANLIB here (i.e. before running AC_PROG_RANLIB) to
  40 # deal with the lossage.  Note that CY_GNU_GETTEXT currently calls
  41 # AC_PROG_RANLIB.  This can be removed when we switch to Autoconf
  42 # 2.5x.
  43 AC_CHECK_TOOL(RANLIB, ranlib, :)
  44
  45 dnl Set up for gettext.  PACKAGE is used when we call bindtextdomain.
  46 ALL_LINGUAS=
  47 CY_GNU_GETTEXT
  48 AC_DEFINE(PACKAGE, "gdb", [Name of this package. ])
  49
  50 debugdir=${libdir}/debug
  51
  52 AC_ARG_WITH(separate-debug-dir,
  53 [  --with-separate-debug-dir=path   Look for global separate debug info in this path [LIBDIR/debug]],
  54 [debugdir="${withval}"])
  55
  56 AC_DEFINE_DIR(DEBUGDIR, debugdir,
  57               [Global directory for separate debug files. ])
  58 #AC_DEFINE_UNQUOTED(DEBUGDIR, "$debugdir"),
  59
  60 dnl List of object files added by configure.
  61
  62 CONFIG_OBS=
  63 CONFIG_LIB_OBS=
  64 CONFIG_DEPS=
  65 CONFIG_SRCS=
  66 CONFIG_INITS=
  67 ENABLE_CFLAGS=
  68 CONFIG_ALL=
  69 CONFIG_CLEAN=
  70 CONFIG_INSTALL=
  71 CONFIG_UNINSTALL=
  72
  73 AC_CONFIG_SUBDIRS(doc testsuite)
  74 configdirs=
  75
  76 . $srcdir/configure.host
  77
  78 . $srcdir/configure.tgt
  79
  80 # Fetch the default architecture and default target vector from BFD.
  81 targ=$target; . $srcdir/../bfd/config.bfd
  82
  83 # We only want the first architecture, so strip off the others if
  84 # there is more than one.
  85 targ_archs=`echo $targ_archs | sed 's/ .*//'`
  86
  87 if test "x$targ_archs" != x; then
  88   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
  89     [Define to BFD's default architecture. ])
  90 fi
  91 if test "x$targ_defvec" != x; then
  92   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
  93     [Define to BFD's default target vector. ])
  94 fi
  95
  96 AC_ARG_PROGRAM
  97
  98 # The CLI cannot be disabled yet, but may be in the future.
  99
 100 # Enable CLI.
 101 AC_ARG_ENABLE(gdbcli,
 102 [  --disable-gdbcli        disable command-line interface (CLI)],
 103   [case $enableval in
 104     yes)
 105       ;;
 106     no)
 107       AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;;
 108     *)
 109       AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;;
 110   esac],
 111   [enable_gdbcli=yes])
 112 if test x"$enable_gdbcli" = xyes; then
 113   if test -d $srcdir/cli; then
 114     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)"
 115     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)"
 116     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)"
 117     CONFIG_INITS="$CONFIG_INITS \$(SUBDIR_CLI_INITS)"
 118     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)"
 119     CONFIG_ALL="$CONFIG_ALL \$(SUBDIR_CLI_ALL)"
 120     CONFIG_CLEAN="$CONFIG_CLEAN \$(SUBDIR_CLI_CLEAN)"
 121     CONFIG_INSTALL="$CONFIG_INSTALL \$(SUBDIR_CLI_INSTALL)"
 122     CONFIG_UNINSTALL="$CONFIG_UNINSTALL \$(SUBDIR_CLI_UNINSTALL)"
 123   fi
 124 fi
 125
 126 # Enable MI.
 127 AC_ARG_ENABLE(gdbmi,
 128 [  --disable-gdbmi         disable machine-interface (MI)],
 129   [case $enableval in
 130     yes | no)
 131       ;;
 132     *)
 133       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 134   esac],
 135   [enable_gdbmi=yes])
 136 if test x"$enable_gdbmi" = xyes; then
 137   if test -d $srcdir/mi; then
 138     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 139     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 140     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 141     CONFIG_INITS="$CONFIG_INITS \$(SUBDIR_MI_INITS)"
 142     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 143     CONFIG_ALL="$CONFIG_ALL \$(SUBDIR_MI_ALL)"
 144     CONFIG_CLEAN="$CONFIG_CLEAN \$(SUBDIR_MI_CLEAN)"
 145     CONFIG_INSTALL="$CONFIG_INSTALL \$(SUBDIR_MI_INSTALL)"
 146     CONFIG_UNINSTALL="$CONFIG_UNINSTALL \$(SUBDIR_MI_UNINSTALL)"
 147   fi
 148 fi
 149
 150 # Enable TUI.
 151 AC_ARG_ENABLE(tui,
 152 [  --enable-tui            enable full-screen terminal user interface (TUI)],
 153   [case $enableval in
 154     yes | no)
 155       ;;
 156     *)
 157       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 158   esac])
 159 if test x"$enable_tui" = xyes; then
 160   if test -d $srcdir/tui; then
 161     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
 162     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
 163     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
 164     CONFIG_INITS="$CONFIG_INITS \$(SUBDIR_TUI_INITS)"
 165     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
 166     CONFIG_ALL="$CONFIG_ALL \$(SUBDIR_TUI_ALL)"
 167     CONFIG_CLEAN="$CONFIG_CLEAN \$(SUBDIR_TUI_CLEAN)"
 168     CONFIG_INSTALL="$CONFIG_INSTALL \$(SUBDIR_TUI_INSTALL)"
 169     CONFIG_UNINSTALL="$CONFIG_UNINSTALL \$(SUBDIR_TUI_UNINSTALL)"
 170     need_curses=yes
 171   fi
 172 fi
 173
 174 # Enable gdbtk.
 175 AC_ARG_ENABLE(gdbtk,
 176 [  --enable-gdbtk          enable gdbtk graphical user interface (GUI)],
 177   [case $enableval in
 178     yes | no)
 179       ;;
 180     *)
 181       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 182   esac],
 183   [if test -d $srcdir/gdbtk; then
 184     enable_gdbtk=yes
 185   else
 186     enable_gdbtk=no
 187   fi])
 188 # We unconditionally disable gdbtk tests on selected platforms.
 189 case $host_os in
 190   go32* | windows*)
 191     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 192     enable_gdbtk=no ;;
 193 esac
 194
 195 # Profiling support.
 196 AC_ARG_ENABLE(profiling,
 197 [  --enable-profiling      enable profiling of GDB],
 198   [case $enableval in
 199     yes | no)
 200       ;;
 201     *)
 202       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 203   esac],
 204  [enable_profiling=no])
 205
 206 AC_CHECK_FUNCS(monstartup _mcleanup)
 207 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 208 [AC_TRY_LINK(
 209 [#include <stdlib.h>
 210 extern char _etext;
 211 ],
 212 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 213 if test $ac_cv_var__etext = yes; then
 214   AC_DEFINE(HAVE__ETEXT, 1,
 215             [Define to 1 if your system has the _etext variable. ])
 216 fi
 217 if test "$enable_profiling" = yes ; then
 218   if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
 219     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 220   fi
 221   PROFILE_CFLAGS=-pg
 222   OLD_CFLAGS="$CFLAGS"
 223   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 224
 225   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 226     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 227      ac_cv_cc_supports_pg=no)])
 228
 229   if test $ac_cv_cc_supports_pg = no; then
 230     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 231   fi
 232
 233   CFLAGS="$OLD_CFLAGS"
 234 fi
 235
 236 # --------------------- #
 237 # Checks for programs.  #
 238 # --------------------- #
 239
 240 AC_PROG_AWK
 241 AC_PROG_INSTALL
 242 AC_PROG_LN_S
 243 AC_PROG_RANLIB
 244 AC_PROG_YACC
 245
 246 AC_CHECK_TOOL(AR, ar)
 247 AC_CHECK_TOOL(DLLTOOL, dlltool)
 248 AC_CHECK_TOOL(WINDRES, windres)
 249
 250 # Needed for GNU/Hurd.
 251 AC_CHECK_TOOL(MIG, mig)
 252
 253 # ---------------------- #
 254 # Checks for libraries.  #
 255 # ---------------------- #
 256
 257 # We might need to link with -lm; most simulators need it.
 258 AC_CHECK_LIB(m, main)
 259
 260 # We need to link with -lw to get `wctype' on Solaris before Solaris
 261 # 2.6.  Solaris 2.6 and beyond have this function in libc, and have a
 262 # libw that some versions of the GNU linker cannot hanle (GNU ld 2.9.1
 263 # is known to have this problem).  Therefore we avoid libw if we can.
 264 AC_CHECK_FUNC(wctype, [],
 265   [AC_CHECK_LIB(w, wctype)])
 266
 267 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 268 AC_SEARCH_LIBS(socketpair, socket)
 269
 270 # Since GDB uses Readline, we need termcap functionality, so we need
 271 # to find a library that provides that.  When GDB is configured with
 272 # --enable-tui, we need full curses functionality.
 273 #
 274 # FIXME: kettenis/20030102: We seem to prefer HP curses (Hcurses) over
 275 # Xcurses on HP-UX; see the `-D__HP_CURSES' in the relevant host
 276 # Makefile fragments.  That's why we need to have `Hcurses' before
 277 # `curses'.  I don't see why we should use HP curses if a more
 278 # standard curses is available, except that according to HP's
 279 # documentation one needs to compile `-D_XOPEN_SOURCE_EXTENDED' on
 280 # HP-UX 10.10 and 10.20.
 281
 282 if test "$need_curses" = yes; then
 283   AC_SEARCH_LIBS(initscr, [ncurses Hcurses curses], [],
 284     [AC_MSG_ERROR([no curses library found])])
 285 fi
 286
 287 case $host_os in
 288   cygwin*)
 289     if test -d $srcdir/libtermcap; then
 290       LIBS="../libtermcap/libtermcap.a $LIBS"
 291       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 292     fi ;;
 293   go32*)
 294     # ??? Is this really true?
 295     ac_cv_search_tgetent="none required"
 296     ;;
 297   aix*)
 298     # Readline prefers curses over termcap on AIX.
 299     # ??? Why?
 300     AC_SEARCH_LIBS(tgetent, [tinfo ncurses curses termcap])
 301     ;;
 302 esac
 303
 304 # Note: We used to check for libtermlib and libterminfo too, but
 305 # Readline doesn't, so I think we're safe with leaving them out.
 306 AC_SEARCH_LIBS(tgetent, [termcap tinfo ncurses Hcurses curses])
 307
 308 if test "$ac_cv_search_tgetent" = no; then
 309   AC_MSG_ERROR([no termcap library found])
 310 fi
 311
 312 # ------------------------- #
 313 # Checks for header files.  #
 314 # ------------------------- #
 315
 316 AC_HEADER_DIRENT
 317 AC_HEADER_STAT
 318 AC_HEADER_STDC
 319 AC_CHECK_HEADERS(link.h)
 320 AC_CHECK_HEADERS(nlist.h)
 321 AC_CHECK_HEADERS(poll.h sys/poll.h)
 322 AC_CHECK_HEADERS(proc_service.h thread_db.h)
 323 AC_CHECK_HEADERS(stddef.h)
 324 AC_CHECK_HEADERS(stdlib.h)
 325 AC_CHECK_HEADERS(stdint.h)
 326 AC_CHECK_HEADERS(string.h memory.h strings.h)
 327 AC_CHECK_HEADERS(sys/fault.h)
 328 AC_CHECK_HEADERS(sys/file.h)
 329 AC_CHECK_HEADERS(sys/filio.h)
 330 AC_CHECK_HEADERS(sys/ioctl.h)
 331 AC_CHECK_HEADERS(sys/param.h)
 332 AC_CHECK_HEADERS(sys/proc.h)
 333 AC_CHECK_HEADERS(sys/procfs.h)
 334 AC_CHECK_HEADERS(sys/ptrace.h ptrace.h)
 335 AC_CHECK_HEADERS(sys/reg.h sys/debugreg.h)
 336 AC_CHECK_HEADERS(sys/select.h)
 337 AC_CHECK_HEADERS(sys/syscall.h)
 338 AC_CHECK_HEADERS(sys/user.h)
 339 AC_CHECK_HEADERS(sys/wait.h wait.h)
 340 AC_CHECK_HEADERS(termios.h termio.h sgtty.h)
 341 AC_CHECK_HEADERS(unistd.h)
 342
 343 # On Solaris 2.[78], we need to define _MSE_INT_H to avoid a clash
 344 # between <widec.h> and <wchar.h> that would cause AC_CHECK_HEADERS to
 345 # think that we don't have <curses.h> if we're using GCC.
 346 case $host_os in
 347   solaris2.[[78]])
 348     if test "$GCC" = yes; then
 349       AC_DEFINE(_MSE_INT_H, 1,
 350         [[Define to 1 to avoid a clash between <widec.h> and <wchar.h> on
 351    Solaris 2.[78] when using GCC. ]])
 352     fi ;;
 353 esac
 354 AC_CHECK_HEADERS(curses.h ncurses.h term.h)
 355
 356 # FIXME: kettenis/20030102: In most cases we include these
 357 # unconditionally, so what's the point in checking these?
 358 AC_CHECK_HEADERS(ctype.h time.h)
 359
 360 # ------------------------- #
 361 # Checks for declarations.  #
 362 # ------------------------- #
 363
 364 gcc_AC_CHECK_DECLS(getopt)
 365
 366 # ------------------ #
 367 # Checks for types.  #
 368 # ------------------ #
 369
 370 AC_TYPE_SIGNAL
 371
 372 # ------------------------------------- #
 373 # Checks for compiler characteristics.  #
 374 # ------------------------------------- #
 375
 376 AC_C_CONST
 377 AC_C_INLINE
 378
 379 # ------------------------------ #
 380 # Checks for library functions.  #
 381 # ------------------------------ #
 382
 383 AC_FUNC_ALLOCA
 384 AC_FUNC_MMAP
 385 AC_FUNC_VFORK
 386 AC_CHECK_FUNCS(canonicalize_file_name realpath)
 387 AC_CHECK_FUNCS(poll)
 388 AC_CHECK_FUNCS(pread64)
 389 AC_CHECK_FUNCS(sbrk)
 390 AC_CHECK_FUNCS(setpgid setpgrp)
 391 AC_CHECK_FUNCS(sigaction sigprocmask sigsetmask)
 392 AC_CHECK_FUNCS(socketpair)
 393 AC_CHECK_FUNCS(syscall)
 394
 395 dnl AC_FUNC_SETPGRP does not work when cross compiling
 396 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
 397 if test "$cross_compiling" = no; then
 398   AC_FUNC_SETPGRP
 399 else
 400   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
 401     [AC_TRY_COMPILE([
 402 #include <unistd.h>
 403 ], [
 404   if (setpgrp(1,1) == -1)
 405     exit (0);
 406   else
 407     exit (1);
 408 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
 409 if test $ac_cv_func_setpgrp_void = yes; then
 410   AC_DEFINE(SETPGRP_VOID, 1)
 411 fi
 412 fi
 413
 414 # Check if sigsetjmp is available.  Using AC_CHECK_FUNCS won't do
 415 # since sigsetjmp might only be defined as a macro.
 416 AC_CACHE_CHECK([for sigsetjmp], gdb_cv_func_sigsetjmp,
 417 [AC_TRY_COMPILE([
 418 #include <setjmp.h>
 419 ], [sigjmp_buf env; while (! sigsetjmp (env, 1)) siglongjmp (env, 1);],
 420 gdb_cv_func_sigsetjmp=yes, gdb_cv_func_sigsetjmp=no)])
 421 if test $gdb_cv_func_sigsetjmp = yes; then
 422   AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available. ])
 423 fi
 424
 425 # Assume we'll default to using the included libiberty regex.
 426 gdb_use_included_regex=yes
 427
 428 # However, if the system regex is GNU regex, then default to *not*
 429 # using the included regex.
 430 AC_CACHE_CHECK(
 431   [for GNU regex],
 432   [gdb_cv_have_gnu_regex],
 433   [AC_TRY_COMPILE(
 434     [#include <gnu-versions.h>],
 435     [#define REGEX_INTERFACE_VERSION 1
 436 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
 437 # error "Version mismatch"
 438 #endif],
 439     gdb_cv_have_gnu_regex=yes,
 440     gdb_cv_have_gnu_regex=no)])
 441 if test $gdb_cv_have_gnu_regex = yes; then
 442   gdb_use_included_regex=no
 443 fi
 444
 445 AC_ARG_WITH(included-regex,
 446   [  --without-included-regex don't use included regex; this is the default
 447                           on systems with version 2 of the GNU C library
 448                           (use with caution on other system)],
 449   gdb_with_regex=$withval,
 450   gdb_with_regex=$gdb_use_included_regex)
 451 if test "$gdb_with_regex" = yes; then
 452   AC_DEFINE(USE_INCLUDED_REGEX, 1,
 453     [Define to 1 if the regex included in libiberty should be used.])
 454 fi
 455
 456 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
 457 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
 458 AC_CACHE_CHECK([for r_fs in struct reg], gdb_cv_struct_reg_r_fs,
 459 [AC_TRY_COMPILE([#include <machine/reg.h>], [struct reg r; r.r_fs;],
 460 gdb_cv_struct_reg_r_fs=yes, gdb_cv_struct_reg_r_fs=no)])
 461 if test $gdb_cv_struct_reg_r_fs = yes; then
 462   AC_DEFINE(HAVE_STRUCT_REG_R_FS)
 463 fi
 464 AC_CACHE_CHECK([for r_gs in struct reg], gdb_cv_struct_reg_r_gs,
 465 [AC_TRY_COMPILE([#include <machine/reg.h>], [struct reg r; r.r_gs;],
 466 gdb_cv_struct_reg_r_gs=yes, gdb_cv_struct_reg_r_gs=no)])
 467 if test $gdb_cv_struct_reg_r_gs = yes; then
 468   AC_DEFINE(HAVE_STRUCT_REG_R_GS)
 469 fi
 470
 471 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
 472 AC_MSG_CHECKING(for PTRACE_GETREGS)
 473 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
 474 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 475                 [PTRACE_GETREGS;],
 476                 [gdb_cv_have_ptrace_getregs=yes],
 477                 [gdb_cv_have_ptrace_getregs=no])])
 478 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
 479 if test $gdb_cv_have_ptrace_getregs = yes; then
 480   AC_DEFINE(HAVE_PTRACE_GETREGS)
 481 fi
 482
 483 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
 484 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
 485 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
 486 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 487                 [PTRACE_GETFPXREGS;],
 488                 [gdb_cv_have_ptrace_getfpxregs=yes],
 489                 [gdb_cv_have_ptrace_getfpxregs=no])])
 490 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
 491 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
 492   AC_DEFINE(HAVE_PTRACE_GETFPXREGS)
 493 fi
 494
 495 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
 496 AC_MSG_CHECKING(for PT_GETDBREGS)
 497 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
 498 [AC_TRY_COMPILE([#include <sys/types.h>
 499 #include <sys/ptrace.h>],
 500                 [PT_GETDBREGS;],
 501                 [gdb_cv_have_pt_getdbregs=yes],
 502                 [gdb_cv_have_pt_getdbregs=no])])
 503 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
 504 if test $gdb_cv_have_pt_getdbregs = yes; then
 505   AC_DEFINE(HAVE_PT_GETDBREGS)
 506 fi
 507
 508 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
 509 AC_MSG_CHECKING(for PT_GETXMMREGS)
 510 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
 511 [AC_TRY_COMPILE([#include <sys/types.h>
 512 #include <sys/ptrace.h>],
 513                 [PT_GETXMMREGS;],
 514                 [gdb_cv_have_pt_getxmmregs=yes],
 515                 [gdb_cv_have_pt_getxmmregs=no])])
 516 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
 517 if test $gdb_cv_have_pt_getxmmregs = yes; then
 518   AC_DEFINE(HAVE_PT_GETXMMREGS)
 519 fi
 520
 521 # See if stdint.h provides the uintptr_t type.
 522 # Autoconf 2.5X has an improved AC_CHECK_TYPE which will simplify this.
 523 AC_CACHE_CHECK([for uintptr_t in stdint.h], gdb_cv_have_uintptr_t,
 524   [AC_TRY_COMPILE(
 525     [#include <stdint.h>],
 526     [uintptr_t foo = 0;],
 527     gdb_cv_have_uintptr_t=yes,
 528     gdb_cv_have_uintptr_t=no)])
 529 AC_MSG_RESULT($gdb_cv_have_uintptr_t)
 530 if test $gdb_cv_have_uintptr_t = yes; then
 531   AC_DEFINE(HAVE_UINTPTR_T, 1, [Define if <stdint.h> provides the uintptr_t type.])
 532 fi
 533
 534 BFD_NEED_DECLARATION(malloc)
 535 BFD_NEED_DECLARATION(realloc)
 536 BFD_NEED_DECLARATION(free)
 537 BFD_NEED_DECLARATION(strerror)
 538 BFD_NEED_DECLARATION(strdup)
 539 BFD_NEED_DECLARATION(strstr)
 540 BFD_NEED_DECLARATION(canonicalize_file_name)
 541
 542 # The following save_state_t checkery is only necessary for HPUX
 543 # versions earlier than 10.20.  When those fade from memory, this
 544 # could be expunged. --jsm 1999-03-22
 545
 546 AC_MSG_CHECKING(for HPUX save_state structure)
 547 AC_EGREP_HEADER(save_state_t, machine/save_state.h,
 548                 gdb_cv_hpux_savestate=yes, gdb_cv_hpux_savestate=no)
 549 AC_EGREP_HEADER(ss_wide, machine/save_state.h, gdb_cv_hpux_sswide=yes,
 550                 gdb_cv_hpux_sswide=no)
 551 if test $gdb_cv_hpux_savestate = yes
 552 then
 553   AC_DEFINE(HAVE_STRUCT_SAVE_STATE_T, 1)
 554 fi
 555 if test $gdb_cv_hpux_sswide = yes
 556 then
 557   AC_DEFINE(HAVE_STRUCT_MEMBER_SS_WIDE, 1)
 558 fi
 559 AC_MSG_RESULT($gdb_cv_hpux_sswide)
 560
 561
 562 # If we are configured native on GNU/Linux, work around problems with
 563 # sys/procfs.h
 564 # Also detect which type of /proc is in use, such as for Unixware or Solaris.
 565
 566 if test "${target}" = "${host}"; then
 567   case "${host}" in
 568   i[[3456]]86-*-linux*)
 569         AC_DEFINE(START_INFERIOR_TRAPS_EXPECTED,2)
 570         AC_DEFINE(sys_quotactl)
 571         ;;
 572   ia64-*-aix*)
 573       AC_DEFINE(NEW_PROC_API)
 574       ;;
 575   *-*-unixware* | *-*-sysv4.2* | *-*-sysv5* | *-*-interix* )
 576       AC_DEFINE(NEW_PROC_API)
 577       ;;
 578   *-*-solaris2.[[678]])
 579       AC_DEFINE(NEW_PROC_API)
 580       ;;
 581   esac
 582 fi
 583
 584 if test "$ac_cv_header_sys_procfs_h" = yes; then
 585   BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
 586   BFD_HAVE_SYS_PROCFS_TYPE(prrun_t)
 587   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
 588   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
 589   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
 590   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
 591   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
 592   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset32_t)
 593   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
 594   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
 595   BFD_HAVE_SYS_PROCFS_TYPE(prsysent_t)
 596   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigset_t)
 597   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigaction64_t)
 598   BFD_HAVE_SYS_PROCFS_TYPE(pr_siginfo64_t)
 599
 600
 601   dnl Check for broken prfpregset_t type
 602
 603   dnl For Linux/i386, glibc 2.1.3 was released with a bogus
 604   dnl prfpregset_t type (it's a typedef for the pointer to a struct
 605   dnl instead of the struct itself).  We detect this here, and work
 606   dnl around it in gdb_proc_service.h.
 607
 608   if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
 609     AC_MSG_CHECKING(whether prfpregset_t type is broken)
 610     AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
 611       [AC_TRY_RUN([#include <sys/procfs.h>
 612        int main ()
 613        {
 614          if (sizeof (prfpregset_t) == sizeof (void *))
 615            return 1;
 616          return 0;
 617        }],
 618        gdb_cv_prfpregset_t_broken=no,
 619        gdb_cv_prfpregset_t_broken=yes,
 620        gdb_cv_prfpregset_t_broken=yes)])
 621     AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
 622     if test $gdb_cv_prfpregset_t_broken = yes; then
 623       AC_DEFINE(PRFPREGSET_T_BROKEN)
 624     fi
 625   fi
 626
 627   dnl Check for PIOCSET ioctl entry
 628
 629   AC_MSG_CHECKING(for PIOCSET ioctl entry in sys/procfs.h)
 630   AC_CACHE_VAL(gdb_cv_have_procfs_piocset,
 631   [AC_TRY_COMPILE([#include <unistd.h>
 632 #include <sys/types.h>
 633 #include <sys/procfs.h>
 634 ], [
 635     int dummy;;
 636     dummy = ioctl(0, PIOCSET, &dummy);
 637   ],
 638   gdb_cv_have_procfs_piocset=yes, gdb_cv_have_procfs_piocset=no)])
 639   AC_MSG_RESULT($gdb_cv_have_procfs_piocset)
 640   if test $gdb_cv_have_procfs_piocset = yes; then
 641     AC_DEFINE(HAVE_PROCFS_PIOCSET)
 642   fi
 643 fi
 644
 645 dnl For native ports (host == target), check to see what kind of
 646 dnl legacy link.h support is needed.  (See solib-legacy.c.)
 647 if test ${host} = ${target} ; then
 648   dnl Check for struct link_map with l_ members which are indicative
 649   dnl of SVR4-like shared libraries
 650
 651   AC_MSG_CHECKING(for member l_addr in struct link_map)
 652   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_l_members,
 653     [AC_TRY_COMPILE([#include <link.h>],
 654                     [struct link_map lm; (void) lm.l_addr;],
 655                     gdb_cv_have_struct_link_map_with_l_members=yes,
 656                     gdb_cv_have_struct_link_map_with_l_members=no)])
 657   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_l_members)
 658   if test $gdb_cv_have_struct_link_map_with_l_members = yes; then
 659     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_L_MEMBERS)
 660   fi
 661
 662   dnl Check for struct link_map with lm_ members which are indicative
 663   dnl of SunOS-like shared libraries
 664
 665   AC_MSG_CHECKING(for member lm_addr in struct link_map)
 666   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_lm_members,
 667     [AC_TRY_COMPILE([#include <sys/types.h>
 668 #include <link.h>],
 669                     [struct link_map lm; (void) lm.lm_addr;],
 670                     gdb_cv_have_struct_link_map_with_lm_members=yes,
 671                     gdb_cv_have_struct_link_map_with_lm_members=no)])
 672   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_lm_members)
 673   if test $gdb_cv_have_struct_link_map_with_lm_members = yes; then
 674     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_LM_MEMBERS)
 675   fi
 676
 677   dnl Check for struct so_map with som_ members which are found on
 678   dnl some *BSD systems.
 679
 680   AC_MSG_CHECKING(for member som_addr in struct so_map)
 681   AC_CACHE_VAL(gdb_cv_have_struct_so_map_with_som_members,
 682     [AC_TRY_COMPILE([#include <sys/types.h>
 683 #ifdef HAVE_NLIST_H
 684 #include <nlist.h>
 685 #endif
 686 #include <link.h>],
 687                     [struct so_map lm; (void) lm.som_addr;],
 688                     gdb_cv_have_struct_so_map_with_som_members=yes,
 689                     gdb_cv_have_struct_so_map_with_som_members=no)])
 690   AC_MSG_RESULT($gdb_cv_have_struct_so_map_with_som_members)
 691   if test $gdb_cv_have_struct_so_map_with_som_members = yes; then
 692     AC_DEFINE(HAVE_STRUCT_SO_MAP_WITH_SOM_MEMBERS)
 693   fi
 694
 695   dnl Check for struct link_map32 type, which allows a 64-bit Solaris
 696   dnl debugger to debug a 32-bit Solaris app with 32-bit shared libraries.
 697
 698   AC_MSG_CHECKING(for struct link_map32 in sys/link.h)
 699   AC_CACHE_VAL(gdb_cv_have_struct_link_map32,
 700     [AC_TRY_COMPILE([#define _SYSCALL32
 701 #include <sys/link.h>], [struct link_map32 l;],
 702      gdb_cv_have_struct_link_map32=yes,
 703      gdb_cv_have_struct_link_map32=no)])
 704   AC_MSG_RESULT($gdb_cv_have_struct_link_map32)
 705   if test $gdb_cv_have_struct_link_map32 = yes; then
 706     AC_DEFINE(HAVE_STRUCT_LINK_MAP32)
 707     AC_DEFINE(_SYSCALL32)
 708   fi
 709 fi
 710
 711 dnl See if compiler supports "long long" type.
 712
 713 AC_MSG_CHECKING(for long long support in compiler)
 714 AC_CACHE_VAL(gdb_cv_c_long_long,
 715 [AC_TRY_COMPILE(, [
 716   extern long long foo;
 717   switch (foo & 2) { case 0: return 1; }
 718 ],
 719 gdb_cv_c_long_long=yes, gdb_cv_c_long_long=no)])
 720 AC_MSG_RESULT($gdb_cv_c_long_long)
 721 if test $gdb_cv_c_long_long = yes; then
 722   AC_DEFINE(CC_HAS_LONG_LONG)
 723 fi
 724
 725 dnl See if the compiler and runtime support printing long long
 726
 727 AC_MSG_CHECKING(for long long support in printf)
 728 AC_CACHE_VAL(gdb_cv_printf_has_long_long,
 729 [AC_TRY_RUN([
 730 int main () {
 731   char buf[32];
 732   long long l = 0;
 733   l = (l << 16) + 0x0123;
 734   l = (l << 16) + 0x4567;
 735   l = (l << 16) + 0x89ab;
 736   l = (l << 16) + 0xcdef;
 737   sprintf (buf, "0x%016llx", l);
 738   return (strcmp ("0x0123456789abcdef", buf));
 739 }],
 740 gdb_cv_printf_has_long_long=yes,
 741 gdb_cv_printf_has_long_long=no,
 742 gdb_cv_printf_has_long_long=no)])
 743 if test $gdb_cv_printf_has_long_long = yes; then
 744   AC_DEFINE(PRINTF_HAS_LONG_LONG)
 745 fi
 746 AC_MSG_RESULT($gdb_cv_printf_has_long_long)
 747
 748 dnl See if compiler supports "long double" type.  Can't use AC_C_LONG_DOUBLE
 749 dnl because autoconf complains about cross-compilation issues.  However, this
 750 dnl code uses the same variables as the macro for compatibility.
 751
 752 AC_MSG_CHECKING(for long double support in compiler)
 753 AC_CACHE_VAL(ac_cv_c_long_double,
 754 [AC_TRY_COMPILE(, [long double foo;],
 755 ac_cv_c_long_double=yes, ac_cv_c_long_double=no)])
 756 AC_MSG_RESULT($ac_cv_c_long_double)
 757 if test $ac_cv_c_long_double = yes; then
 758   AC_DEFINE(HAVE_LONG_DOUBLE)
 759 fi
 760
 761 dnl See if the compiler and runtime support printing long doubles
 762
 763 AC_MSG_CHECKING(for long double support in printf)
 764 AC_CACHE_VAL(gdb_cv_printf_has_long_double,
 765 [AC_TRY_RUN([
 766 int main () {
 767   char buf[16];
 768   long double f = 3.141592653;
 769   sprintf (buf, "%Lg", f);
 770   return (strncmp ("3.14159", buf, 7));
 771 }],
 772 gdb_cv_printf_has_long_double=yes,
 773 gdb_cv_printf_has_long_double=no,
 774 gdb_cv_printf_has_long_double=no)])
 775 if test $gdb_cv_printf_has_long_double = yes; then
 776   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE)
 777 fi
 778 AC_MSG_RESULT($gdb_cv_printf_has_long_double)
 779
 780 dnl See if the compiler and runtime support scanning long doubles
 781
 782 AC_MSG_CHECKING(for long double support in scanf)
 783 AC_CACHE_VAL(gdb_cv_scanf_has_long_double,
 784 [AC_TRY_RUN([
 785 int main () {
 786   char *buf = "3.141592653";
 787   long double f = 0;
 788   sscanf (buf, "%Lg", &f);
 789   return !(f > 3.14159 && f < 3.14160);
 790 }],
 791 gdb_cv_scanf_has_long_double=yes,
 792 gdb_cv_scanf_has_long_double=no,
 793 gdb_cv_scanf_has_long_double=no)])
 794 if test $gdb_cv_scanf_has_long_double = yes; then
 795   AC_DEFINE(SCANF_HAS_LONG_DOUBLE)
 796 fi
 797 AC_MSG_RESULT($gdb_cv_scanf_has_long_double)
 798
 799 case ${host_os} in
 800 aix*)
 801   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
 802     SAVE_LDFLAGS=$LDFLAGS
 803
 804     case $GCC in
 805     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
 806     *) gdb_cv_bigtoc=-bbigtoc ;;
 807     esac
 808
 809     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
 810     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
 811   ])
 812   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
 813   ;;
 814 esac
 815
 816
 817 dnl For certain native configurations, we need to check whether thread
 818 dnl support can be built in or not.
 819 dnl
 820 dnl Note that we only want this if we are both native (host == target),
 821 dnl and not doing a canadian cross build (build == host).
 822
 823 if test ${build} = ${host} -a ${host} = ${target} ; then
 824    case ${host_os} in
 825    hpux*)
 826       AC_MSG_CHECKING(for HPUX/OSF thread support)
 827       if test -f /usr/include/dce/cma_config.h ; then
 828          if test "$GCC" = "yes" ; then
 829             AC_MSG_RESULT(yes)
 830             AC_DEFINE(HAVE_HPUX_THREAD_SUPPORT)
 831             CONFIG_LIB_OBS="${CONFIG_LIB_OBS} hpux-thread.o"
 832             CONFIG_SRCS="${CONFIG_SRCS} hpux-thread.c"
 833          else
 834             AC_MSG_RESULT(no (suppressed because you are not using GCC))
 835          fi
 836       else
 837          AC_MSG_RESULT(no)
 838       fi
 839       ;;
 840    solaris*)
 841       # See if thread_db library is around for Solaris thread debugging.
 842       # Note that we must explicitly test for version 1 of the library
 843       # because version 0 (present on Solaris 2.4 or earlier) doesn't have
 844       # the same API.
 845       AC_MSG_CHECKING(for Solaris thread debugging library)
 846       if test -f /usr/lib/libthread_db.so.1 ; then
 847          AC_MSG_RESULT(yes)
 848          AC_DEFINE(HAVE_THREAD_DB_LIB)
 849          CONFIG_LIB_OBS="${CONFIG_LIB_OBS} sol-thread.o"
 850          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
 851          AC_CHECK_LIB(dl, dlopen)
 852          if test "$GCC" = "yes" ; then
 853             # The GNU linker requires the -export-dynamic option to make
 854             # all symbols visible in the dynamic symbol table.
 855             hold_ldflags=$LDFLAGS
 856             AC_MSG_CHECKING(for the ld -export-dynamic flag)
 857             LDFLAGS="${LDFLAGS} -Wl,-export-dynamic"
 858             AC_TRY_LINK(, [int i;], found=yes, found=no)
 859             LDFLAGS=$hold_ldflags
 860             AC_MSG_RESULT($found)
 861             if test $found = yes; then
 862                CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -Wl,-export-dynamic"
 863             fi
 864          fi
 865          # Sun randomly tweaked the prototypes in <proc_service.h>
 866          # at one point.
 867          AC_MSG_CHECKING(if <proc_service.h> is old)
 868          AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
 869             AC_TRY_COMPILE([
 870                 #include <proc_service.h>
 871                 ps_err_e ps_pdwrite
 872                     (struct ps_prochandle*, psaddr_t, const void*, size_t);
 873             ],, gdb_cv_proc_service_is_old=no,
 874                 gdb_cv_proc_service_is_old=yes)
 875          ])
 876          AC_MSG_RESULT($gdb_cv_proc_service_is_old)
 877          if test $gdb_cv_proc_service_is_old = yes; then
 878             AC_DEFINE(PROC_SERVICE_IS_OLD)
 879          fi
 880       else
 881          AC_MSG_RESULT(no)
 882       fi
 883       ;;
 884    aix*)
 885       AC_MSG_CHECKING(for AiX thread debugging library)
 886       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
 887                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
 888                                    [#ifndef PTHDB_VERSION_3
 889                                     #error
 890                                     #endif],
 891                                    gdb_cv_have_aix_thread_debug=yes,
 892                                    gdb_cv_have_aix_thread_debug=no)])
 893       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
 894       if test $gdb_cv_have_aix_thread_debug = yes; then
 895          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
 896          CONFIG_LIB_OBS="${CONFIG_LIB_OBS} aix-thread.o"
 897          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -lpthdebug"
 898       fi
 899       ;;
 900    esac
 901    AC_SUBST(CONFIG_LDFLAGS)
 902 fi
 903
 904 dnl See if we have a thread_db header file that has TD_NOTALLOC.
 905 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
 906    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
 907                   gdb_cv_thread_db_h_has_td_notalloc,
 908      AC_TRY_COMPILE(
 909        [#include <thread_db.h>],
 910        [int i = TD_NOTALLOC;],
 911        gdb_cv_thread_db_h_has_td_notalloc=yes,
 912        gdb_cv_thread_db_h_has_td_notalloc=no
 913      )
 914    )
 915 fi
 916 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
 917   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
 918             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
 919 fi
 920
 921 dnl See if we have a sys/syscall header file that has __NR_tkill.
 922 if test "x$ac_cv_header_sys_syscall_h" = "xyes"; then
 923    AC_CACHE_CHECK([whether <sys/syscall.h> has __NR_tkill],
 924                   gdb_cv_sys_syscall_h_has_tkill,
 925      AC_TRY_COMPILE(
 926        [#include <sys/syscall.h>],
 927        [int i = __NR_tkill;],
 928        gdb_cv_sys_syscall_h_has_tkill=yes,
 929        gdb_cv_sys_syscall_h_has_tkill=no
 930      )
 931    )
 932 fi
 933 dnl See if we can issue tkill syscall.
 934 if test "x$gdb_cv_sys_syscall_h_has_tkill" = "xyes" && test "x$ac_cv_func_syscall" = "xyes"; then
 935   AC_DEFINE(HAVE_TKILL_SYSCALL, 1,
 936             [Define if we can use the tkill syscall.])
 937 fi
 938
 939 dnl Handle optional features that can be enabled.
 940
 941 AC_ARG_WITH(sysroot,
 942 [  --with-sysroot[=DIR] Search for usr/lib et al within DIR.],
 943 [
 944  case ${with_sysroot} in
 945  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
 946  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
 947  esac
 948
 949  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
 950
 951  if test "x$exec_prefix" = xNONE; then
 952   if test "x$prefix" = xNONE; then
 953    test_prefix=/usr/local
 954   else
 955    test_prefix=$prefix
 956   fi
 957  else
 958   test_prefix=$exec_prefix
 959  fi
 960  case ${TARGET_SYSTEM_ROOT} in
 961  "${test_prefix}"|"${test_prefix}/"*|\
 962  '${exec_prefix}'|'${exec_prefix}/'*)
 963    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
 964    TARGET_SYSTEM_ROOT_DEFINE="$t"
 965    ;;
 966  esac
 967 ], [
 968  TARGET_SYSTEM_ROOT=
 969  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"'
 970 ])
 971 AC_SUBST(TARGET_SYSTEM_ROOT)
 972 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
 973
 974 # NOTE: Don't add -Wall or -Wunused, they both include
 975 # -Wunused-parameter which reports bogus warnings.
 976 # NOTE: If you add to this list, remember to update
 977 # gdb/doc/gdbint.texinfo.
 978 build_warnings="-Wimplicit -Wreturn-type -Wcomment -Wtrigraphs \
 979 -Wformat -Wparentheses -Wpointer-arith -Wuninitialized"
 980 # Up for debate: -Wswitch -Wcomment -trigraphs -Wtrigraphs
 981 # -Wunused-function -Wunused-label -Wunused-variable -Wunused-value
 982 # -Wchar-subscripts -Wtraditional -Wshadow -Wcast-qual
 983 # -Wcast-align -Wwrite-strings -Wconversion -Wstrict-prototypes
 984 # -Wmissing-prototypes -Wmissing-declarations -Wredundant-decls
 985 # -Woverloaded-virtual -Winline -Werror"
 986 AC_ARG_ENABLE(build-warnings,
 987 [  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
 988 [case "${enableval}" in
 989   yes)  ;;
 990   no)   build_warnings="-w";;
 991   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
 992         build_warnings="${build_warnings} ${t}";;
 993   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
 994         build_warnings="${t} ${build_warnings}";;
 995   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
 996 esac
 997 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
 998   echo "Setting compiler warning flags = $build_warnings" 6>&1
 999 fi])dnl
1000 AC_ARG_ENABLE(gdb-build-warnings,
1001 [  --enable-gdb-build-warnings Enable GDB specific build-time compiler warnings if gcc is used],
1002 [case "${enableval}" in
1003   yes)  ;;
1004   no)   build_warnings="-w";;
1005   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1006         build_warnings="${build_warnings} ${t}";;
1007   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1008         build_warnings="${t} ${build_warnings}";;
1009   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1010 esac
1011 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1012   echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1
1013 fi])dnl
1014 WARN_CFLAGS=""
1015 WERROR_CFLAGS=""
1016 if test "x${build_warnings}" != x -a "x$GCC" = xyes
1017 then
1018     AC_MSG_CHECKING(compiler warning flags)
1019     # Separate out the -Werror flag as some files just cannot be
1020     # compiled with it enabled.
1021     for w in ${build_warnings}; do
1022         case $w in
1023         -Werr*) WERROR_CFLAGS=-Werror ;;
1024         *) # Check that GCC accepts it
1025             saved_CFLAGS="$CFLAGS"
1026             CFLAGS="$CFLAGS $w"
1027             AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
1028             CFLAGS="$saved_CFLAGS"
1029         esac
1030     done
1031     AC_MSG_RESULT(${WARN_CFLAGS}${WERROR_CFLAGS})
1032 fi
1033 AC_SUBST(WARN_CFLAGS)
1034 AC_SUBST(WERROR_CFLAGS)
1035
1036 MMALLOC_CFLAGS=
1037 MMALLOC=
1038 AC_SUBST(MMALLOC_CFLAGS)
1039 AC_SUBST(MMALLOC)
1040
1041 AC_ARG_WITH(mmalloc,
1042 [  --with-mmalloc          Use memory mapped malloc package],
1043 [case "${withval}" in
1044   yes)  want_mmalloc=true ;;
1045   no)   want_mmalloc=false;;
1046   *)    AC_MSG_ERROR(bad value ${withval} for GDB with-mmalloc option) ;;
1047 esac],[want_mmalloc=false])dnl
1048
1049 if test x$want_mmalloc = xtrue; then
1050    AC_DEFINE(USE_MMALLOC)
1051    AC_DEFINE(MMCHECK_FORCE)
1052    MMALLOC_CFLAGS="-I$srcdir/../mmalloc"
1053    MMALLOC='../mmalloc/libmmalloc.a'
1054 fi
1055
1056 # In the Cygwin environment, we need some additional flags.
1057 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1058 [AC_EGREP_CPP(lose, [
1059 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1060 lose
1061 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1062
1063
1064 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1065 SER_HARDWIRE="ser-unix.o ser-pipe.o ser-tcp.o"
1066 case ${host} in
1067   *go32* ) SER_HARDWIRE=ser-go32.o ;;
1068   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
1069 esac
1070 AC_SUBST(SER_HARDWIRE)
1071
1072 # libreadline needs libuser32.a in a cygwin environment
1073 WIN32LIBS=
1074 if test x$gdb_cv_os_cygwin = xyes; then
1075     WIN32LIBS="-luser32"
1076     case "${target}" in
1077         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
1078         ;;
1079     esac
1080 fi
1081 AC_SUBST(WIN32LIBS)
1082
1083 LIBGUI="../libgui/src/libgui.a"
1084 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
1085 AC_SUBST(LIBGUI)
1086 AC_SUBST(GUI_CFLAGS_X)
1087
1088 WIN32LDAPP=
1089 AC_SUBST(WIN32LIBS)
1090 AC_SUBST(WIN32LDAPP)
1091
1092 configdir="unix"
1093
1094 GDBTKLIBS=
1095 if test "${enable_gdbtk}" = "yes"; then
1096
1097     # Gdbtk must have an absolute path to srcdir in order to run
1098     # properly when not installed.
1099     here=`pwd`
1100     cd ${srcdir}
1101     GDBTK_SRC_DIR=`pwd`
1102     cd $here
1103
1104     CY_AC_PATH_TCLCONFIG
1105     if test -z "${no_tcl}"; then
1106         CY_AC_LOAD_TCLCONFIG
1107         CY_AC_PATH_TKCONFIG
1108
1109         # now look for Tcl library stuff
1110
1111         case "${host}" in
1112         *-*-cygwin*)
1113             tcldir=../tcl/win/
1114             ;;
1115         *)
1116             tcldir=../tcl/unix/
1117             ;;
1118         esac
1119
1120         TCL_DEPS="${tcldir}${TCL_LIB_FILE}"
1121
1122         # If $no_tk is nonempty, then we can't do Tk, and there is no
1123         # point to doing Tcl.
1124         if test -z "${no_tk}"; then
1125            CY_AC_LOAD_TKCONFIG
1126            CY_AC_PATH_TCLH
1127            CY_AC_PATH_TKH
1128            CY_AC_PATH_ITCLH
1129            CY_AC_PATH_ITKH
1130
1131
1132            # now look for Tk library stuff
1133
1134            case "${host}" in
1135            *-*-cygwin*)
1136                tkdir=../tk/win/
1137                ;;
1138            *)
1139                tkdir=../tk/unix/
1140                ;;
1141            esac
1142
1143            TK_DEPS="${tkdir}${TK_LIB_FILE}"
1144
1145            # now look for Itcl library stuff
1146
1147            CY_AC_PATH_ITCLCONFIG
1148            if test -z "${no_itcl}"; then
1149              CY_AC_LOAD_ITCLCONFIG
1150
1151              ITCLLIB="${ITCL_BUILD_LIB_SPEC}"
1152              ITCL_DEPS="${ITCL_LIB_FULL_PATH}"
1153            fi
1154
1155
1156            # now look for Itk library stuff
1157            CY_AC_PATH_ITKCONFIG
1158            if test -z "${no_itcl}"; then
1159              CY_AC_LOAD_ITKCONFIG
1160
1161              ITKLIB="${ITK_BUILD_LIB_SPEC}"
1162              ITK_DEPS="${ITK_LIB_FULL_PATH}"
1163            fi
1164
1165            ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
1166            # Tcl/Tk 8.1 require -fwritable strings.  I don't
1167            # know whether 8.2 will or not, but I bet it will.
1168            # I don't have to worry about 7.x since we don't support it.
1169            GDBTK_CFLAGS=""
1170            if test "$GCC" = "yes"; then
1171                if test "$TCL_VERSION" != "8.0" ; then
1172                    GDBTK_CFLAGS="-fwritable-strings"
1173                fi
1174            fi
1175
1176            # Include some libraries that Tcl and Tk want.
1177            TCL_LIBS='$(LIBGUI) $(ITCL) $(ITK) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
1178            # Yes, the ordering seems wrong here.  But it isn't.
1179            # TK_LIBS is the list of libraries that need to be linked
1180            # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
1181            # were in LIBS then any link tests after this point would
1182            # try to include things like `$(LIBGUI)', which wouldn't work.
1183            GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
1184
1185            CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
1186            CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
1187            CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
1188            CONFIG_INITS="${CONFIG_INITS} \$(SUBDIR_GDBTK_INITS)"
1189            CONFIG_ALL="${CONFIG_ALL} \$(SUBDIR_GDBTK_ALL)"
1190            CONFIG_CLEAN="${CONFIG_CLEAN} \$(SUBDIR_GDBTK_CLEAN)"
1191            CONFIG_INSTALL="${CONFIG_INSTALL} \$(SUBDIR_GDBTK_INSTALL)"
1192            CONFIG_UNINSTALL="${CONFIG_UNINSTALL} \$(SUBDIR_GDBTK_UNINSTALL)"
1193
1194            if test x$gdb_cv_os_cygwin = xyes; then
1195               WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
1196               WIN32LDAPP="-Wl,--subsystem,console"
1197               CONFIG_OBS="${CONFIG_OBS} gdbres.o"
1198            fi
1199         fi
1200     fi
1201
1202     configdirs="${configdirs} gdbtk"
1203 fi
1204
1205 AC_SUBST(X_CFLAGS)
1206 AC_SUBST(X_LDFLAGS)
1207 AC_SUBST(X_LIBS)
1208 AC_SUBST(TCL_DEPS)
1209 AC_SUBST(TK_DEPS)
1210 AC_SUBST(ITCLLIB)
1211 AC_SUBST(ITCL_DEPS)
1212 AC_SUBST(ITKLIB)
1213 AC_SUBST(ITK_DEPS)
1214 AC_SUBST(GDBTKLIBS)
1215 AC_SUBST(GDBTK_CFLAGS)
1216 AC_SUBST(GDBTK_SRC_DIR)
1217
1218 AC_PATH_X
1219
1220
1221 # Unlike the sim directory, whether a simulator is linked is controlled by
1222 # presence of a SIM= and a SIM_OBS= definition in the target '.mt' file.
1223 # This code just checks for a few cases where we'd like to ignore those
1224 # definitions, even when they're present in the '.mt' file.  These cases
1225 # are when --disable-sim is specified, or if the simulator directory is
1226 # not part of the source tree.
1227 #
1228 AC_ARG_ENABLE(sim,
1229 [  --enable-sim            Link gdb with simulator],
1230 [echo "enable_sim = $enable_sim";
1231  echo "enableval = ${enableval}";
1232  case "${enableval}" in
1233   yes) ignore_sim=false ;;
1234   no)  ignore_sim=true ;;
1235   *)   ignore_sim=false ;;
1236  esac],
1237 [ignore_sim=false])
1238
1239 if test ! -d "${srcdir}/../sim"; then
1240   ignore_sim=true
1241 fi
1242
1243 if test "${ignore_sim}" = "true"; then
1244     IGNORE_SIM="SIM="
1245     IGNORE_SIM_OBS="SIM_OBS="
1246 else
1247     IGNORE_SIM=""
1248     IGNORE_SIM_OBS=""
1249     AC_DEFINE(WITH_SIM)
1250 fi
1251 AC_SUBST(IGNORE_SIM)
1252 AC_SUBST(IGNORE_SIM_OBS)
1253
1254 AC_SUBST(ENABLE_CFLAGS)
1255 AC_SUBST(PROFILE_CFLAGS)
1256
1257 AC_SUBST(CONFIG_OBS)
1258 AC_SUBST(CONFIG_LIB_OBS)
1259 AC_SUBST(CONFIG_DEPS)
1260 AC_SUBST(CONFIG_SRCS)
1261 AC_SUBST(CONFIG_INITS)
1262 AC_SUBST(CONFIG_ALL)
1263 AC_SUBST(CONFIG_CLEAN)
1264 AC_SUBST(CONFIG_INSTALL)
1265 AC_SUBST(CONFIG_UNINSTALL)
1266
1267 # target_subdir is used by the testsuite to find the target libraries.
1268 target_subdir=
1269 if test "${host}" != "${target}"; then
1270     target_subdir="${target_alias}/"
1271 fi
1272 AC_SUBST(target_subdir)
1273
1274 frags=
1275 host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
1276 if test ! -f ${host_makefile_frag}; then
1277     # When building a native debuger the .mh file containing things
1278     # like NATDEPFILES is needed.  Cross debuggers don't need .mh
1279     # since it no longer contains anything useful.
1280     if test "${target}" = "${host}"; then
1281         AC_MSG_ERROR("*** Gdb does not support native target ${host}")
1282     else
1283         host_makefile_frag=/dev/null
1284     fi
1285 fi
1286 frags="$frags $host_makefile_frag"
1287
1288 target_makefile_frag=${srcdir}/config/${gdb_target_cpu}/${gdb_target}.mt
1289 if test ! -f ${target_makefile_frag}; then
1290 AC_MSG_ERROR("*** Gdb does not support target ${target}")
1291 fi
1292 frags="$frags $target_makefile_frag"
1293
1294 AC_SUBST_FILE(host_makefile_frag)
1295 AC_SUBST_FILE(target_makefile_frag)
1296 AC_SUBST(frags)
1297
1298 changequote(,)dnl
1299 hostfile=`sed -n '
1300 s/XM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
1301 ' ${host_makefile_frag}`
1302
1303 targetfile=`sed -n '
1304 s/TM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
1305 ' ${target_makefile_frag}`
1306
1307 GDB_MULTI_ARCH=`sed -n '
1308 s/GDB_MULTI_ARCH[       ]*=[    ]*\([^  ]*\)[   ]*/\1/p
1309 ' ${target_makefile_frag}`
1310
1311 if test "${target}" = "${host}"; then
1312 # We pick this up from the host configuration file (.mh) because we
1313 # do not have a native configuration Makefile fragment.
1314 nativefile=`sed -n '
1315 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
1316 ' ${host_makefile_frag}`
1317 fi
1318 changequote([,])
1319
1320 # New targets should just set gdb_multi_arch=yes in configure.tgt.
1321 # Old targets being converted can either do that or set GDB_MULTI_ARCH
1322 # in the target specific makefile frag.  Eventually gdb_multi_arch=yes
1323 # will be the default.
1324 if test x"${GDB_MULTI_ARCH}" = x ; then
1325     case "${gdb_multi_arch}" in
1326     yes ) GDB_MULTI_ARCH=GDB_MULTI_ARCH_PURE ;;
1327     no ) GDB_MULTI_ARCH=0 ;;
1328     0|1|2 ) GDB_MULTI_ARCH=${gdb_multi_arch} ;;
1329     esac
1330 fi
1331 if test x"${GDB_MULTI_ARCH}" != x ; then
1332     AC_DEFINE_UNQUOTED(GDB_MULTI_ARCH, ${GDB_MULTI_ARCH})
1333 fi
1334 # Warn the user when they use an old practice
1335 case "${GDB_MULTI_ARCH}" in
1336     "" ) ;;
1337     0 | GDB_MULTI_ARCH_PARTIAL | 1 | GDB_MULTI_ARCH_TM | 2 )
1338         AC_MSG_WARN("GDB: Target is not pure multi-arch") ;;
1339     GDB_MULTI_ARCH_PURE )
1340         if test x"${targetfile}" != x ; then
1341             AC_MSG_WARN("GDB: Ignoring TM_FILE in ${target_makefile_frag}")
1342             targetfile=""
1343         fi ;;
1344     *)  AC_MSG_ERROR("GDB: Unknown GDB_MULTI_ARCH value ${GDB_MULTI_ARCH}");;
1345 esac
1346
1347 if test x"${gdb_osabi}" != x ; then
1348     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
1349                        [Define to the default OS ABI for this configuration.])
1350 fi
1351
1352 # Enable multi-ice-gdb-server.
1353 AC_ARG_ENABLE(multi-ice,
1354 [  --enable-multi-ice      build the multi-ice-gdb-server],
1355   [case $enableval in
1356     yes | no)
1357       ;;
1358     *) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;;
1359   esac])
1360 if test "x$enable_multi_ice" = xyes; then
1361   configdirs="$configdirs multi-ice"
1362 fi
1363
1364 # We only build gdbserver automatically if host and target are the same.
1365 if test "x$target" = "x$host"; then
1366   AC_MSG_CHECKING(whether gdbserver is supported on this host)
1367   if test "x$build_gdbserver" = xyes; then
1368     configdirs="$configdirs gdbserver"
1369     AC_MSG_RESULT(yes)
1370   else
1371     AC_MSG_RESULT(no)
1372   fi
1373 fi
1374
1375 AC_CONFIG_SUBDIRS($configdirs)
1376
1377 # If hostfile (XM_FILE) and/or targetfile (TM_FILE) and/or nativefile
1378 # (NAT_FILE) is not set in config/*/*.m[ht] files, we link to an empty
1379 # version.
1380
1381 files=
1382 links=
1383
1384 rm -f xm.h
1385 xm_h=""
1386 if test "${hostfile}" != ""; then
1387     xm_h=xm.h
1388     GDB_XM_FILE="config/${gdb_host_cpu}/${hostfile}"
1389     files="${files} ${GDB_XM_FILE}"
1390     links="${links} xm.h"
1391     AC_DEFINE_UNQUOTED(GDB_XM_FILE, ${GDB_XM_FILE})
1392 fi
1393 AC_SUBST(xm_h)
1394
1395 rm -f tm.h
1396 tm_h=""
1397 if test "${targetfile}" != ""; then
1398     tm_h=tm.h
1399     GDB_TM_FILE="config/${gdb_target_cpu}/${targetfile}"
1400     files="${files} ${GDB_TM_FILE}"
1401     links="${links} tm.h"
1402     AC_DEFINE_UNQUOTED(GDB_TM_FILE, ${GDB_TM_FILE})
1403 fi
1404 AC_SUBST(tm_h)
1405
1406 rm -f nm.h
1407 nm_h=""
1408 if test "${nativefile}" != ""; then
1409     nm_h=nm.h
1410     GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}"
1411     files="${files} ${GDB_NM_FILE}"
1412     links="${links} nm.h"
1413     AC_DEFINE_UNQUOTED(GDB_NM_FILE, ${GDB_NM_FILE})
1414 fi
1415 AC_SUBST(nm_h)
1416
1417 AC_LINK_FILES($files, $links)
1418
1419 dnl Check for exe extension set on certain hosts (e.g. Win32)
1420 AC_EXEEXT
1421
1422 dnl  Detect the character set used by this host.
1423
1424 dnl  At the moment, we just assume it's ISO-8859-1 (which is a
1425 dnl  superset of ASCII containing the characters needed for French,
1426 dnl  German, Spanish, Italian, and possibly others), but if were
1427 dnl  *were* to support any host character sets other than ISO-8859-1,
1428 dnl  here's where we'd detect it.
1429 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "ISO-8859-1",
1430           [Define to be a string naming the default host character set.])
1431
1432 AM_ICONV
1433
1434 AC_OUTPUT(Makefile .gdbinit:gdbinit.in,
1435 [
1436 dnl Autoconf doesn't provide a mechanism for modifying definitions
1437 dnl provided by makefile fragments.
1438 dnl
1439 if test "${nativefile}" = ""; then
1440         < Makefile \
1441         sed -e '/^NATDEPFILES[[         ]]*=.*\\$/,/[[^\\]]$/s/^/# /' \
1442             -e '/^NATDEPFILES[[         ]]*=/s/^/# /' \
1443         | sed -e '/^\(NATDEPFILES[[     ]]*[[+]]=[[     ]]*\)/s//# \1/' \
1444         > Makefile.tem
1445 mv -f Makefile.tem Makefile
1446 fi
1447
1448 changequote(,)dnl
1449 sed -e '/^TM_FILE[      ]*=/s,^TM_FILE[         ]*=[    ]*,&config/'"${gdb_target_cpu}"'/,
1450 /^XM_FILE[      ]*=/s,^XM_FILE[         ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,
1451 /^NAT_FILE[     ]*=/s,^NAT_FILE[        ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,' <Makefile >Makefile.tmp
1452 mv -f Makefile.tmp Makefile
1453 changequote([,])dnl
1454
1455
1456 case x$CONFIG_HEADERS in
1457 xconfig.h:config.in)
1458 echo > stamp-h ;;
1459 esac
1460 ],
1461 [
1462 gdb_host_cpu=$gdb_host_cpu
1463 gdb_target_cpu=$gdb_target_cpu
1464 nativefile=$nativefile
1465 ])
1466
1467 exit 0