gdb/configure.in

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004
   3 dnl Free Software Foundation, Inc.
   4 dnl
   5 dnl This file is part of GDB.
   6 dnl
   7 dnl This program is free software; you can redistribute it and/or modify
   8 dnl it under the terms of the GNU General Public License as published by
   9 dnl the Free Software Foundation; either version 2 of the License, or
  10 dnl (at your option) any later version.
  11 dnl
  12 dnl This program is distributed in the hope that it will be useful,
  13 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 dnl GNU General Public License for more details.
  16 dnl
  17 dnl You should have received a copy of the GNU General Public License
  18 dnl along with this program; if not, write to the Free Software
  19 dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  20
  21 dnl Process this file with autoconf to produce a configure script.
  22
  23 AC_PREREQ(2.13)dnl
  24 AC_INIT(main.c)
  25 AC_CONFIG_HEADER(config.h:config.in)
  26 AM_MAINTAINER_MODE
  27
  28 AC_PROG_CC
  29 AC_GNU_SOURCE
  30 AC_AIX
  31 AC_ISC_POSIX
  32 AM_PROG_CC_STDC
  33
  34 AC_CONFIG_AUX_DIR(`cd $srcdir;pwd`/..)
  35 AC_CANONICAL_SYSTEM
  36
  37 # FIXME: kettenis/20030102: The AC_PROG_RANLIB from Autoconf 2.13
  38 # doesn't support cross-compilation, but the one from Autoconf 2.5x
  39 # does.  Override RANLIB here (i.e. before running AC_PROG_RANLIB) to
  40 # deal with the lossage.  Note that CY_GNU_GETTEXT currently calls
  41 # AC_PROG_RANLIB.  This can be removed when we switch to Autoconf
  42 # 2.5x.
  43 AC_CHECK_TOOL(RANLIB, ranlib, :)
  44
  45 dnl Set up for gettext.  PACKAGE is used when we call bindtextdomain.
  46 ALL_LINGUAS=
  47 CY_GNU_GETTEXT
  48 AC_DEFINE(PACKAGE, "gdb", [Name of this package. ])
  49
  50 debugdir=${libdir}/debug
  51
  52 AC_ARG_WITH(separate-debug-dir,
  53 [  --with-separate-debug-dir=path   Look for global separate debug info in this path [LIBDIR/debug]],
  54 [debugdir="${withval}"])
  55
  56 AC_DEFINE_DIR(DEBUGDIR, debugdir,
  57               [Global directory for separate debug files. ])
  58 #AC_DEFINE_UNQUOTED(DEBUGDIR, "$debugdir"),
  59
  60 dnl List of object files added by configure.
  61
  62 CONFIG_OBS=
  63 CONFIG_DEPS=
  64 CONFIG_SRCS=
  65 ENABLE_CFLAGS=
  66 CONFIG_ALL=
  67 CONFIG_CLEAN=
  68 CONFIG_INSTALL=
  69 CONFIG_UNINSTALL=
  70
  71 AC_CONFIG_SUBDIRS(doc testsuite)
  72 configdirs=
  73
  74 . $srcdir/configure.host
  75
  76 . $srcdir/configure.tgt
  77
  78 # Fetch the default architecture and default target vector from BFD.
  79 targ=$target; . $srcdir/../bfd/config.bfd
  80
  81 # We only want the first architecture, so strip off the others if
  82 # there is more than one.
  83 targ_archs=`echo $targ_archs | sed 's/ .*//'`
  84
  85 if test "x$targ_archs" != x; then
  86   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
  87     [Define to BFD's default architecture. ])
  88 fi
  89 if test "x$targ_defvec" != x; then
  90   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
  91     [Define to BFD's default target vector. ])
  92 fi
  93
  94 AC_ARG_PROGRAM
  95
  96 # The CLI cannot be disabled yet, but may be in the future.
  97
  98 # Enable CLI.
  99 AC_ARG_ENABLE(gdbcli,
 100 [  --disable-gdbcli        disable command-line interface (CLI)],
 101   [case $enableval in
 102     yes)
 103       ;;
 104     no)
 105       AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;;
 106     *)
 107       AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;;
 108   esac],
 109   [enable_gdbcli=yes])
 110 if test x"$enable_gdbcli" = xyes; then
 111   if test -d $srcdir/cli; then
 112     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)"
 113     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)"
 114     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)"
 115     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)"
 116   fi
 117 fi
 118
 119 # Enable MI.
 120 AC_ARG_ENABLE(gdbmi,
 121 [  --disable-gdbmi         disable machine-interface (MI)],
 122   [case $enableval in
 123     yes | no)
 124       ;;
 125     *)
 126       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 127   esac],
 128   [enable_gdbmi=yes])
 129 if test x"$enable_gdbmi" = xyes; then
 130   if test -d $srcdir/mi; then
 131     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 132     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 133     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 134     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 135   fi
 136 fi
 137
 138 # FIXME: kettenis/20030102: We seem to prefer HP curses (Hcurses) over
 139 # Xcurses on HP-UX; see the `-D__HP_CURSES' in the relevant host
 140 # Makefile fragments.  That's why we need to have `Hcurses' before
 141 # `curses'.  I don't see why we should use HP curses if a more
 142 # standard curses is available, except that according to HP's
 143 # documentation one needs to compile `-D_XOPEN_SOURCE_EXTENDED' on
 144 # HP-UX 10.10 and 10.20.
 145
 146 AC_SEARCH_LIBS(initscr, [ncurses Hcurses curses pdcurses], [],
 147     [AC_MSG_WARN([no curses library found])])
 148
 149 # Check whether the wborder function is provided by the curses
 150 # library detected above.  In certain implementations such as
 151 # the HP/UX Hcurses for instance, this function is provided by an
 152 # additional library.  So if we did not find this function inside
 153 # the curses library, try some alternate libraries we know might
 154 # provide it.
 155 AC_SEARCH_LIBS(wborder, [cur_colr], [],
 156     [AC_MSG_WARN([wborder function not found, tui will be disabled])])
 157
 158 # Enable TUI.
 159 AC_ARG_ENABLE(tui,
 160 [  --enable-tui            enable full-screen terminal user interface (TUI)],
 161   [case $enableval in
 162     yes | no)
 163       ;;
 164     *)
 165       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 166   esac],enable_tui=yes)
 167 if test x"$enable_tui" = xyes; then
 168   if test -d $srcdir/tui; then
 169     if test "$ac_cv_search_initscr" != no -a "$ac_cv_search_wborder" != no; then
 170       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
 171       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
 172       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
 173       CONFIG_INITS="$CONFIG_INITS \$(SUBDIR_TUI_INITS)"
 174       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
 175       CONFIG_ALL="${CONFIG_ALL} all-tui"
 176       CONFIG_CLEAN="${CONFIG_CLEAN} clean-tui"
 177       CONFIG_INSTALL="${CONFIG_INSTALL} install-tui"
 178       CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-tui"
 179     fi
 180   fi
 181 fi
 182
 183 # Enable gdbtk.
 184 AC_ARG_ENABLE(gdbtk,
 185 [  --enable-gdbtk          enable gdbtk graphical user interface (GUI)],
 186   [case $enableval in
 187     yes | no)
 188       ;;
 189     *)
 190       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 191   esac],
 192   [if test -d $srcdir/gdbtk; then
 193     enable_gdbtk=yes
 194   else
 195     enable_gdbtk=no
 196   fi])
 197 # We unconditionally disable gdbtk tests on selected platforms.
 198 case $host_os in
 199   go32* | windows*)
 200     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 201     enable_gdbtk=no ;;
 202 esac
 203
 204 # Libunwind support.
 205 AC_ARG_WITH(libunwind,
 206 [  --with-libunwind            Use libunwind frame unwinding support],
 207 [case "${withval}" in
 208   yes)  enable_libunwind=yes ;;
 209   no)   enable_libunwind=no ;;
 210   *)    AC_MSG_ERROR(bad value ${withval} for GDB with-libunwind option) ;;
 211 esac],[
 212   AC_CHECK_HEADERS(libunwind.h)
 213   AC_CHECK_HEADERS(libunwind-ia64.h)
 214   if test x"$ac_cv_header_libunwind_h" = xyes -a x"$ac_cv_header_libunwind_ia64_h" = xyes; then
 215     enable_libunwind=yes;
 216   fi
 217 ])
 218
 219 if test x"$enable_libunwind" = xyes; then
 220   AC_CHECK_HEADERS(libunwind.h)
 221   AC_CHECK_HEADERS(libunwind-ia64.h)
 222   AC_DEFINE(HAVE_LIBUNWIND, 1)
 223   CONFIG_OBS="$CONFIG_OBS libunwind-frame.o"
 224   CONFIG_DEPS="$CONFIG_DEPS libunwind-frame.o"
 225   CONFIG_SRCS="$CONFIG_SRCS libunwind-frame.c"
 226 fi
 227
 228 # Profiling support.
 229 AC_ARG_ENABLE(profiling,
 230 [  --enable-profiling      enable profiling of GDB],
 231   [case $enableval in
 232     yes | no)
 233       ;;
 234     *)
 235       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 236   esac],
 237  [enable_profiling=no])
 238
 239 AC_CHECK_FUNCS(monstartup _mcleanup)
 240 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 241 [AC_TRY_LINK(
 242 [#include <stdlib.h>
 243 extern char _etext;
 244 ],
 245 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 246 if test $ac_cv_var__etext = yes; then
 247   AC_DEFINE(HAVE__ETEXT, 1,
 248             [Define to 1 if your system has the _etext variable. ])
 249 fi
 250 if test "$enable_profiling" = yes ; then
 251   if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
 252     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 253   fi
 254   PROFILE_CFLAGS=-pg
 255   OLD_CFLAGS="$CFLAGS"
 256   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 257
 258   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 259     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 260      ac_cv_cc_supports_pg=no)])
 261
 262   if test $ac_cv_cc_supports_pg = no; then
 263     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 264   fi
 265
 266   CFLAGS="$OLD_CFLAGS"
 267 fi
 268
 269 # --------------------- #
 270 # Checks for programs.  #
 271 # --------------------- #
 272
 273 AC_PROG_AWK
 274 AC_PROG_INSTALL
 275 AC_PROG_LN_S
 276 AC_PROG_RANLIB
 277 AC_PROG_YACC
 278
 279 AC_CHECK_TOOL(AR, ar)
 280 AC_CHECK_TOOL(DLLTOOL, dlltool)
 281 AC_CHECK_TOOL(WINDRES, windres)
 282
 283 # Needed for GNU/Hurd.
 284 AC_CHECK_TOOL(MIG, mig)
 285
 286 # ---------------------- #
 287 # Checks for libraries.  #
 288 # ---------------------- #
 289
 290 # We might need to link with -lm; most simulators need it.
 291 AC_CHECK_LIB(m, main)
 292
 293 # We need to link with -lw to get `wctype' on Solaris before Solaris
 294 # 2.6.  Solaris 2.6 and beyond have this function in libc, and have a
 295 # libw that some versions of the GNU linker cannot hanle (GNU ld 2.9.1
 296 # is known to have this problem).  Therefore we avoid libw if we can.
 297 AC_CHECK_FUNC(wctype, [],
 298   [AC_CHECK_LIB(w, wctype)])
 299
 300 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 301 AC_SEARCH_LIBS(gethostbyname, nsl)
 302
 303 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 304 AC_SEARCH_LIBS(socketpair, socket)
 305
 306 # Since GDB uses Readline, we need termcap functionality, so we need
 307 # to find a library that provides that.  When GDB is configured with
 308 # the TUI, we need full curses functionality.
 309
 310 case $host_os in
 311   cygwin*)
 312     if test -d $srcdir/libtermcap; then
 313       LIBS="../libtermcap/libtermcap.a $LIBS"
 314       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 315     fi ;;
 316   go32* | *djgpp*)
 317     ac_cv_search_tgetent="none required"
 318     ;;
 319   aix*)
 320     # Readline prefers curses over termcap on AIX.
 321     # ??? Why?
 322     AC_SEARCH_LIBS(tgetent, [tinfo ncurses curses termcap])
 323     ;;
 324 esac
 325
 326 # Note: We used to check for libtermlib and libterminfo too, but
 327 # Readline doesn't, so I think we're safe with leaving them out.
 328 AC_SEARCH_LIBS(tgetent, [termcap tinfo ncurses Hcurses curses])
 329
 330 if test "$ac_cv_search_tgetent" = no; then
 331   AC_MSG_ERROR([no termcap library found])
 332 fi
 333
 334 # ------------------------- #
 335 # Checks for header files.  #
 336 # ------------------------- #
 337
 338 AC_HEADER_DIRENT
 339 AC_HEADER_STAT
 340 AC_HEADER_STDC
 341 AC_CHECK_HEADERS(link.h)
 342 AC_CHECK_HEADERS(machine/reg.h)
 343 AC_CHECK_HEADERS(nlist.h)
 344 AC_CHECK_HEADERS(poll.h sys/poll.h)
 345 AC_CHECK_HEADERS(proc_service.h thread_db.h)
 346 AC_CHECK_HEADERS(stddef.h)
 347 AC_CHECK_HEADERS(stdlib.h)
 348 AC_CHECK_HEADERS(stdint.h)
 349 AC_CHECK_HEADERS(string.h memory.h strings.h)
 350 AC_CHECK_HEADERS(sys/fault.h)
 351 AC_CHECK_HEADERS(sys/file.h)
 352 AC_CHECK_HEADERS(sys/filio.h)
 353 AC_CHECK_HEADERS(sys/ioctl.h)
 354 AC_CHECK_HEADERS(sys/param.h)
 355 AC_CHECK_HEADERS(sys/proc.h)
 356 AC_CHECK_HEADERS(sys/procfs.h)
 357 AC_CHECK_HEADERS(sys/ptrace.h ptrace.h)
 358 AC_CHECK_HEADERS(sys/reg.h sys/debugreg.h)
 359 AC_CHECK_HEADERS(sys/select.h)
 360 AC_CHECK_HEADERS(sys/syscall.h)
 361 AC_CHECK_HEADERS(sys/user.h)
 362 AC_CHECK_HEADERS(sys/wait.h wait.h)
 363 AC_CHECK_HEADERS(termios.h termio.h sgtty.h)
 364 AC_CHECK_HEADERS(unistd.h)
 365
 366 # On Solaris 2.[78], we need to define _MSE_INT_H to avoid a clash
 367 # between <widec.h> and <wchar.h> that would cause AC_CHECK_HEADERS to
 368 # think that we don't have <curses.h> if we're using GCC.
 369 case $host_os in
 370   solaris2.[[78]])
 371     if test "$GCC" = yes; then
 372       AC_DEFINE(_MSE_INT_H, 1,
 373         [[Define to 1 to avoid a clash between <widec.h> and <wchar.h> on
 374    Solaris 2.[78] when using GCC. ]])
 375     fi ;;
 376 esac
 377 AC_CHECK_HEADERS(curses.h ncurses.h term.h)
 378
 379 # FIXME: kettenis/20030102: In most cases we include these
 380 # unconditionally, so what's the point in checking these?
 381 AC_CHECK_HEADERS(ctype.h time.h)
 382
 383 dnl Check for struct stat with an st_blocks member
 384 AC_MSG_CHECKING(for member st_blocks in struct stat)
 385 AC_CACHE_VAL(gdb_cv_have_struct_stat_with_st_blocks_member,
 386   [AC_TRY_COMPILE([#include <sys/types.h>
 387 #include <sys/stat.h>],
 388                   [struct stat st; (void) st.st_blocks;],
 389                   gdb_cv_have_struct_stat_with_st_blocks_member=yes,
 390                   gdb_cv_have_struct_stat_with_st_blocks_member=no)])
 391 AC_MSG_RESULT($gdb_cv_have_struct_stat_with_st_blocks_member)
 392 if test $gdb_cv_have_struct_stat_with_st_blocks_member = yes; then
 393   AC_DEFINE(HAVE_STRUCT_STAT_ST_BLOCKS)
 394 fi
 395 # ------------------------- #
 396 # Checks for declarations.  #
 397 # ------------------------- #
 398
 399 gcc_AC_CHECK_DECLS(getopt)
 400
 401 # ------------------ #
 402 # Checks for types.  #
 403 # ------------------ #
 404
 405 AC_TYPE_SIGNAL
 406
 407 # ------------------------------------- #
 408 # Checks for compiler characteristics.  #
 409 # ------------------------------------- #
 410
 411 AC_C_CONST
 412 AC_C_INLINE
 413
 414 # ------------------------------ #
 415 # Checks for library functions.  #
 416 # ------------------------------ #
 417
 418 AC_FUNC_ALLOCA
 419 AC_FUNC_MMAP
 420 AC_FUNC_VFORK
 421 AC_CHECK_FUNCS(canonicalize_file_name realpath)
 422 AC_CHECK_FUNCS(poll)
 423 AC_CHECK_FUNCS(pread64)
 424 AC_CHECK_FUNCS(sbrk)
 425 AC_CHECK_FUNCS(setpgid setpgrp)
 426 AC_CHECK_FUNCS(sigaction sigprocmask sigsetmask)
 427 AC_CHECK_FUNCS(socketpair)
 428 AC_CHECK_FUNCS(syscall)
 429
 430 dnl AC_FUNC_SETPGRP does not work when cross compiling
 431 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
 432 if test "$cross_compiling" = no; then
 433   AC_FUNC_SETPGRP
 434 else
 435   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
 436     [AC_TRY_COMPILE([
 437 #include <unistd.h>
 438 ], [
 439   if (setpgrp(1,1) == -1)
 440     exit (0);
 441   else
 442     exit (1);
 443 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
 444 if test $ac_cv_func_setpgrp_void = yes; then
 445   AC_DEFINE(SETPGRP_VOID, 1)
 446 fi
 447 fi
 448
 449 # Check if sigsetjmp is available.  Using AC_CHECK_FUNCS won't do
 450 # since sigsetjmp might only be defined as a macro.
 451 AC_CACHE_CHECK([for sigsetjmp], gdb_cv_func_sigsetjmp,
 452 [AC_TRY_COMPILE([
 453 #include <setjmp.h>
 454 ], [sigjmp_buf env; while (! sigsetjmp (env, 1)) siglongjmp (env, 1);],
 455 gdb_cv_func_sigsetjmp=yes, gdb_cv_func_sigsetjmp=no)])
 456 if test $gdb_cv_func_sigsetjmp = yes; then
 457   AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available. ])
 458 fi
 459
 460 # Assume we'll default to using the included libiberty regex.
 461 gdb_use_included_regex=yes
 462
 463 # However, if the system regex is GNU regex, then default to *not*
 464 # using the included regex.
 465 AC_CACHE_CHECK(
 466   [for GNU regex],
 467   [gdb_cv_have_gnu_regex],
 468   [AC_TRY_COMPILE(
 469     [#include <gnu-versions.h>],
 470     [#define REGEX_INTERFACE_VERSION 1
 471 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
 472 # error "Version mismatch"
 473 #endif],
 474     gdb_cv_have_gnu_regex=yes,
 475     gdb_cv_have_gnu_regex=no)])
 476 if test $gdb_cv_have_gnu_regex = yes; then
 477   gdb_use_included_regex=no
 478 fi
 479
 480 AC_ARG_WITH(included-regex,
 481   [  --without-included-regex don't use included regex; this is the default
 482                           on systems with version 2 of the GNU C library
 483                           (use with caution on other system)],
 484   gdb_with_regex=$withval,
 485   gdb_with_regex=$gdb_use_included_regex)
 486 if test "$gdb_with_regex" = yes; then
 487   AC_DEFINE(USE_INCLUDED_REGEX, 1,
 488     [Define to 1 if the regex included in libiberty should be used.])
 489 fi
 490
 491 # See if <machine/reg.h> degines `struct reg'.
 492 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
 493 [AC_TRY_COMPILE([#include <sys/types.h>
 494 #include <machine/reg.h>], [struct reg r;],
 495 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
 496 if test $gdb_cv_struct_reg = yes; then
 497   AC_DEFINE(HAVE_STRUCT_REG, 1,
 498             [Define to 1 if your system has struct reg in <machine/reg.h>.])
 499 fi
 500
 501 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
 502 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
 503 AC_CACHE_CHECK([for r_fs in struct reg], gdb_cv_struct_reg_r_fs,
 504 [AC_TRY_COMPILE([#include <machine/reg.h>], [struct reg r; r.r_fs;],
 505 gdb_cv_struct_reg_r_fs=yes, gdb_cv_struct_reg_r_fs=no)])
 506 if test $gdb_cv_struct_reg_r_fs = yes; then
 507   AC_DEFINE(HAVE_STRUCT_REG_R_FS)
 508 fi
 509 AC_CACHE_CHECK([for r_gs in struct reg], gdb_cv_struct_reg_r_gs,
 510 [AC_TRY_COMPILE([#include <machine/reg.h>], [struct reg r; r.r_gs;],
 511 gdb_cv_struct_reg_r_gs=yes, gdb_cv_struct_reg_r_gs=no)])
 512 if test $gdb_cv_struct_reg_r_gs = yes; then
 513   AC_DEFINE(HAVE_STRUCT_REG_R_GS)
 514 fi
 515
 516 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
 517 AC_MSG_CHECKING(for PTRACE_GETREGS)
 518 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
 519 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 520                 [PTRACE_GETREGS;],
 521                 [gdb_cv_have_ptrace_getregs=yes],
 522                 [gdb_cv_have_ptrace_getregs=no])])
 523 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
 524 if test $gdb_cv_have_ptrace_getregs = yes; then
 525   AC_DEFINE(HAVE_PTRACE_GETREGS)
 526 fi
 527
 528 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
 529 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
 530 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
 531 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 532                 [PTRACE_GETFPXREGS;],
 533                 [gdb_cv_have_ptrace_getfpxregs=yes],
 534                 [gdb_cv_have_ptrace_getfpxregs=no])])
 535 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
 536 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
 537   AC_DEFINE(HAVE_PTRACE_GETFPXREGS)
 538 fi
 539
 540 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
 541 AC_MSG_CHECKING(for PT_GETDBREGS)
 542 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
 543 [AC_TRY_COMPILE([#include <sys/types.h>
 544 #include <sys/ptrace.h>],
 545                 [PT_GETDBREGS;],
 546                 [gdb_cv_have_pt_getdbregs=yes],
 547                 [gdb_cv_have_pt_getdbregs=no])])
 548 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
 549 if test $gdb_cv_have_pt_getdbregs = yes; then
 550   AC_DEFINE(HAVE_PT_GETDBREGS)
 551 fi
 552
 553 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
 554 AC_MSG_CHECKING(for PT_GETXMMREGS)
 555 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
 556 [AC_TRY_COMPILE([#include <sys/types.h>
 557 #include <sys/ptrace.h>],
 558                 [PT_GETXMMREGS;],
 559                 [gdb_cv_have_pt_getxmmregs=yes],
 560                 [gdb_cv_have_pt_getxmmregs=no])])
 561 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
 562 if test $gdb_cv_have_pt_getxmmregs = yes; then
 563   AC_DEFINE(HAVE_PT_GETXMMREGS)
 564 fi
 565
 566 # See if stdint.h provides the uintptr_t type.
 567 # Autoconf 2.5X has an improved AC_CHECK_TYPE which will simplify this.
 568 AC_CACHE_CHECK([for uintptr_t in stdint.h], gdb_cv_have_uintptr_t,
 569   [AC_TRY_COMPILE(
 570     [#include <stdint.h>],
 571     [uintptr_t foo = 0;],
 572     gdb_cv_have_uintptr_t=yes,
 573     gdb_cv_have_uintptr_t=no)])
 574 if test $gdb_cv_have_uintptr_t = yes; then
 575   AC_DEFINE(HAVE_UINTPTR_T, 1, [Define if <stdint.h> provides the uintptr_t type.])
 576 fi
 577
 578 BFD_NEED_DECLARATION(malloc)
 579 BFD_NEED_DECLARATION(realloc)
 580 BFD_NEED_DECLARATION(free)
 581 BFD_NEED_DECLARATION(strerror)
 582 BFD_NEED_DECLARATION(strdup)
 583 BFD_NEED_DECLARATION(strstr)
 584 BFD_NEED_DECLARATION(canonicalize_file_name)
 585
 586 # The following save_state_t checkery is only necessary for HPUX
 587 # versions earlier than 10.20.  When those fade from memory, this
 588 # could be expunged. --jsm 1999-03-22
 589
 590 AC_MSG_CHECKING(for HPUX save_state structure)
 591 AC_EGREP_HEADER(save_state_t, machine/save_state.h,
 592                 gdb_cv_hpux_savestate=yes, gdb_cv_hpux_savestate=no)
 593 AC_EGREP_HEADER(ss_wide, machine/save_state.h, gdb_cv_hpux_sswide=yes,
 594                 gdb_cv_hpux_sswide=no)
 595 if test $gdb_cv_hpux_savestate = yes
 596 then
 597   AC_DEFINE(HAVE_STRUCT_SAVE_STATE_T, 1)
 598 fi
 599 if test $gdb_cv_hpux_sswide = yes
 600 then
 601   AC_DEFINE(HAVE_STRUCT_MEMBER_SS_WIDE, 1)
 602 fi
 603 AC_MSG_RESULT($gdb_cv_hpux_sswide)
 604
 605
 606 # If we are configured native on GNU/Linux, work around problems with
 607 # sys/procfs.h
 608 # Also detect which type of /proc is in use, such as for Unixware or Solaris.
 609
 610 if test "${target}" = "${host}"; then
 611   case "${host}" in
 612   i[[3456]]86-*-linux*)
 613         AC_DEFINE(START_INFERIOR_TRAPS_EXPECTED,2)
 614         AC_DEFINE(sys_quotactl)
 615         ;;
 616   ia64-*-aix*)
 617       AC_DEFINE(NEW_PROC_API)
 618       ;;
 619   *-*-unixware* | *-*-sysv4.2* | *-*-sysv5* | *-*-interix* )
 620       AC_DEFINE(NEW_PROC_API)
 621       ;;
 622   *-*-solaris2.[[6789]])
 623       AC_DEFINE(NEW_PROC_API)
 624       ;;
 625   esac
 626 fi
 627
 628 if test "$ac_cv_header_sys_procfs_h" = yes; then
 629   BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
 630   BFD_HAVE_SYS_PROCFS_TYPE(prrun_t)
 631   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
 632   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
 633   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
 634   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
 635   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
 636   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset32_t)
 637   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
 638   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
 639   BFD_HAVE_SYS_PROCFS_TYPE(prsysent_t)
 640   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigset_t)
 641   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigaction64_t)
 642   BFD_HAVE_SYS_PROCFS_TYPE(pr_siginfo64_t)
 643
 644
 645   dnl Check for broken prfpregset_t type
 646
 647   dnl For Linux/i386, glibc 2.1.3 was released with a bogus
 648   dnl prfpregset_t type (it's a typedef for the pointer to a struct
 649   dnl instead of the struct itself).  We detect this here, and work
 650   dnl around it in gdb_proc_service.h.
 651
 652   if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
 653     AC_MSG_CHECKING(whether prfpregset_t type is broken)
 654     AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
 655       [AC_TRY_RUN([#include <sys/procfs.h>
 656        int main ()
 657        {
 658          if (sizeof (prfpregset_t) == sizeof (void *))
 659            return 1;
 660          return 0;
 661        }],
 662        gdb_cv_prfpregset_t_broken=no,
 663        gdb_cv_prfpregset_t_broken=yes,
 664        gdb_cv_prfpregset_t_broken=yes)])
 665     AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
 666     if test $gdb_cv_prfpregset_t_broken = yes; then
 667       AC_DEFINE(PRFPREGSET_T_BROKEN)
 668     fi
 669   fi
 670
 671   dnl Check for PIOCSET ioctl entry
 672
 673   AC_MSG_CHECKING(for PIOCSET ioctl entry in sys/procfs.h)
 674   AC_CACHE_VAL(gdb_cv_have_procfs_piocset,
 675   [AC_TRY_COMPILE([#include <unistd.h>
 676 #include <sys/types.h>
 677 #include <sys/procfs.h>
 678 ], [
 679     int dummy;;
 680     dummy = ioctl(0, PIOCSET, &dummy);
 681   ],
 682   gdb_cv_have_procfs_piocset=yes, gdb_cv_have_procfs_piocset=no)])
 683   AC_MSG_RESULT($gdb_cv_have_procfs_piocset)
 684   if test $gdb_cv_have_procfs_piocset = yes; then
 685     AC_DEFINE(HAVE_PROCFS_PIOCSET)
 686   fi
 687 fi
 688
 689 dnl For native ports (host == target), check to see what kind of
 690 dnl legacy link.h support is needed.  (See solib-legacy.c.)
 691 if test ${host} = ${target} ; then
 692   dnl Check for struct link_map with l_ members which are indicative
 693   dnl of SVR4-like shared libraries
 694
 695   AC_MSG_CHECKING(for member l_addr in struct link_map)
 696   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_l_members,
 697     [AC_TRY_COMPILE([#include <link.h>],
 698                     [struct link_map lm; (void) lm.l_addr;],
 699                     gdb_cv_have_struct_link_map_with_l_members=yes,
 700                     gdb_cv_have_struct_link_map_with_l_members=no)])
 701   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_l_members)
 702   if test $gdb_cv_have_struct_link_map_with_l_members = yes; then
 703     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_L_MEMBERS)
 704   fi
 705
 706   dnl Check for struct link_map with lm_ members which are indicative
 707   dnl of SunOS-like shared libraries
 708
 709   AC_MSG_CHECKING(for member lm_addr in struct link_map)
 710   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_lm_members,
 711     [AC_TRY_COMPILE([#include <sys/types.h>
 712 #include <link.h>],
 713                     [struct link_map lm; (void) lm.lm_addr;],
 714                     gdb_cv_have_struct_link_map_with_lm_members=yes,
 715                     gdb_cv_have_struct_link_map_with_lm_members=no)])
 716   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_lm_members)
 717   if test $gdb_cv_have_struct_link_map_with_lm_members = yes; then
 718     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_LM_MEMBERS)
 719   fi
 720
 721   dnl Check for struct so_map with som_ members which are found on
 722   dnl some *BSD systems.
 723
 724   AC_MSG_CHECKING(for member som_addr in struct so_map)
 725   AC_CACHE_VAL(gdb_cv_have_struct_so_map_with_som_members,
 726     [AC_TRY_COMPILE([#include <sys/types.h>
 727 #ifdef HAVE_NLIST_H
 728 #include <nlist.h>
 729 #endif
 730 #include <link.h>],
 731                     [struct so_map lm; (void) lm.som_addr;],
 732                     gdb_cv_have_struct_so_map_with_som_members=yes,
 733                     gdb_cv_have_struct_so_map_with_som_members=no)])
 734   AC_MSG_RESULT($gdb_cv_have_struct_so_map_with_som_members)
 735   if test $gdb_cv_have_struct_so_map_with_som_members = yes; then
 736     AC_DEFINE(HAVE_STRUCT_SO_MAP_WITH_SOM_MEMBERS)
 737   fi
 738
 739   dnl Check for struct link_map32 type, which allows a 64-bit Solaris
 740   dnl debugger to debug a 32-bit Solaris app with 32-bit shared libraries.
 741
 742   AC_MSG_CHECKING(for struct link_map32 in sys/link.h)
 743   AC_CACHE_VAL(gdb_cv_have_struct_link_map32,
 744     [AC_TRY_COMPILE([#define _SYSCALL32
 745 #include <sys/link.h>], [struct link_map32 l;],
 746      gdb_cv_have_struct_link_map32=yes,
 747      gdb_cv_have_struct_link_map32=no)])
 748   AC_MSG_RESULT($gdb_cv_have_struct_link_map32)
 749   if test $gdb_cv_have_struct_link_map32 = yes; then
 750     AC_DEFINE(HAVE_STRUCT_LINK_MAP32)
 751     AC_DEFINE(_SYSCALL32)
 752   fi
 753 fi
 754
 755 dnl See if compiler supports "long long" type.
 756
 757 AC_MSG_CHECKING(for long long support in compiler)
 758 AC_CACHE_VAL(gdb_cv_c_long_long,
 759 [AC_TRY_COMPILE(, [
 760   extern long long foo;
 761   switch (foo & 2) { case 0: return 1; }
 762 ],
 763 gdb_cv_c_long_long=yes, gdb_cv_c_long_long=no)])
 764 AC_MSG_RESULT($gdb_cv_c_long_long)
 765 if test $gdb_cv_c_long_long = yes; then
 766   AC_DEFINE(CC_HAS_LONG_LONG)
 767 fi
 768
 769 dnl See if the compiler and runtime support printing long long
 770
 771 AC_MSG_CHECKING(for long long support in printf)
 772 AC_CACHE_VAL(gdb_cv_printf_has_long_long,
 773 [AC_TRY_RUN([
 774 int main () {
 775   char buf[32];
 776   long long l = 0;
 777   l = (l << 16) + 0x0123;
 778   l = (l << 16) + 0x4567;
 779   l = (l << 16) + 0x89ab;
 780   l = (l << 16) + 0xcdef;
 781   sprintf (buf, "0x%016llx", l);
 782   return (strcmp ("0x0123456789abcdef", buf));
 783 }],
 784 gdb_cv_printf_has_long_long=yes,
 785 gdb_cv_printf_has_long_long=no,
 786 gdb_cv_printf_has_long_long=no)])
 787 if test $gdb_cv_printf_has_long_long = yes; then
 788   AC_DEFINE(PRINTF_HAS_LONG_LONG)
 789 fi
 790 AC_MSG_RESULT($gdb_cv_printf_has_long_long)
 791
 792 dnl See if compiler supports "long double" type.  Can't use AC_C_LONG_DOUBLE
 793 dnl because autoconf complains about cross-compilation issues.  However, this
 794 dnl code uses the same variables as the macro for compatibility.
 795
 796 AC_MSG_CHECKING(for long double support in compiler)
 797 AC_CACHE_VAL(ac_cv_c_long_double,
 798 [AC_TRY_COMPILE(, [long double foo;],
 799 ac_cv_c_long_double=yes, ac_cv_c_long_double=no)])
 800 AC_MSG_RESULT($ac_cv_c_long_double)
 801 if test $ac_cv_c_long_double = yes; then
 802   AC_DEFINE(HAVE_LONG_DOUBLE)
 803 fi
 804
 805 dnl See if the compiler and runtime support printing long doubles
 806
 807 AC_MSG_CHECKING(for long double support in printf)
 808 AC_CACHE_VAL(gdb_cv_printf_has_long_double,
 809 [AC_TRY_RUN([
 810 int main () {
 811   char buf[16];
 812   long double f = 3.141592653;
 813   sprintf (buf, "%Lg", f);
 814   return (strncmp ("3.14159", buf, 7));
 815 }],
 816 gdb_cv_printf_has_long_double=yes,
 817 gdb_cv_printf_has_long_double=no,
 818 gdb_cv_printf_has_long_double=no)])
 819 if test $gdb_cv_printf_has_long_double = yes; then
 820   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE)
 821 fi
 822 AC_MSG_RESULT($gdb_cv_printf_has_long_double)
 823
 824 dnl See if the compiler and runtime support scanning long doubles
 825
 826 AC_MSG_CHECKING(for long double support in scanf)
 827 AC_CACHE_VAL(gdb_cv_scanf_has_long_double,
 828 [AC_TRY_RUN([
 829 int main () {
 830   char *buf = "3.141592653";
 831   long double f = 0;
 832   sscanf (buf, "%Lg", &f);
 833   return !(f > 3.14159 && f < 3.14160);
 834 }],
 835 gdb_cv_scanf_has_long_double=yes,
 836 gdb_cv_scanf_has_long_double=no,
 837 gdb_cv_scanf_has_long_double=no)])
 838 if test $gdb_cv_scanf_has_long_double = yes; then
 839   AC_DEFINE(SCANF_HAS_LONG_DOUBLE)
 840 fi
 841 AC_MSG_RESULT($gdb_cv_scanf_has_long_double)
 842
 843 case ${host_os} in
 844 aix*)
 845   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
 846     SAVE_LDFLAGS=$LDFLAGS
 847
 848     case $GCC in
 849     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
 850     *) gdb_cv_bigtoc=-bbigtoc ;;
 851     esac
 852
 853     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
 854     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
 855   ])
 856   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
 857   ;;
 858 esac
 859
 860
 861 dnl For certain native configurations, we need to check whether thread
 862 dnl support can be built in or not.
 863 dnl
 864 dnl Note that we only want this if we are both native (host == target),
 865 dnl and not doing a canadian cross build (build == host).
 866
 867 if test ${build} = ${host} -a ${host} = ${target} ; then
 868    case ${host_os} in
 869    hpux*)
 870       AC_MSG_CHECKING(for HPUX/OSF thread support)
 871       if test -f /usr/include/dce/cma_config.h ; then
 872          if test "$GCC" = "yes" ; then
 873             AC_MSG_RESULT(yes)
 874             AC_DEFINE(HAVE_HPUX_THREAD_SUPPORT)
 875             CONFIG_OBS="${CONFIG_OBS} hpux-thread.o"
 876             CONFIG_SRCS="${CONFIG_SRCS} hpux-thread.c"
 877          else
 878             AC_MSG_RESULT(no (suppressed because you are not using GCC))
 879          fi
 880       else
 881          AC_MSG_RESULT(no)
 882       fi
 883       ;;
 884    solaris*)
 885       # See if thread_db library is around for Solaris thread debugging.
 886       # Note that we must explicitly test for version 1 of the library
 887       # because version 0 (present on Solaris 2.4 or earlier) doesn't have
 888       # the same API.
 889       AC_MSG_CHECKING(for Solaris thread debugging library)
 890       if test -f /usr/lib/libthread_db.so.1 ; then
 891          AC_MSG_RESULT(yes)
 892          AC_DEFINE(HAVE_THREAD_DB_LIB)
 893          CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
 894          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
 895          AC_CHECK_LIB(dl, dlopen)
 896          if test "$GCC" = "yes" ; then
 897             # The GNU linker requires the -export-dynamic option to make
 898             # all symbols visible in the dynamic symbol table.
 899             hold_ldflags=$LDFLAGS
 900             AC_MSG_CHECKING(for the ld -export-dynamic flag)
 901             LDFLAGS="${LDFLAGS} -Wl,-export-dynamic"
 902             AC_TRY_LINK(, [int i;], found=yes, found=no)
 903             LDFLAGS=$hold_ldflags
 904             AC_MSG_RESULT($found)
 905             if test $found = yes; then
 906                CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -Wl,-export-dynamic"
 907             fi
 908          fi
 909          # Sun randomly tweaked the prototypes in <proc_service.h>
 910          # at one point.
 911          AC_MSG_CHECKING(if <proc_service.h> is old)
 912          AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
 913             AC_TRY_COMPILE([
 914                 #include <proc_service.h>
 915                 ps_err_e ps_pdwrite
 916                     (struct ps_prochandle*, psaddr_t, const void*, size_t);
 917             ],, gdb_cv_proc_service_is_old=no,
 918                 gdb_cv_proc_service_is_old=yes)
 919          ])
 920          AC_MSG_RESULT($gdb_cv_proc_service_is_old)
 921          if test $gdb_cv_proc_service_is_old = yes; then
 922             AC_DEFINE(PROC_SERVICE_IS_OLD)
 923          fi
 924       else
 925          AC_MSG_RESULT(no)
 926       fi
 927       ;;
 928    aix*)
 929       AC_MSG_CHECKING(for AiX thread debugging library)
 930       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
 931                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
 932                                    [#ifndef PTHDB_VERSION_3
 933                                     #error
 934                                     #endif],
 935                                    gdb_cv_have_aix_thread_debug=yes,
 936                                    gdb_cv_have_aix_thread_debug=no)])
 937       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
 938       if test $gdb_cv_have_aix_thread_debug = yes; then
 939          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
 940          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
 941          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -lpthdebug"
 942       fi
 943       ;;
 944    esac
 945    AC_SUBST(CONFIG_LDFLAGS)
 946 fi
 947
 948 dnl See if we have a thread_db header file that has TD_NOTALLOC.
 949 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
 950    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
 951                   gdb_cv_thread_db_h_has_td_notalloc,
 952      AC_TRY_COMPILE(
 953        [#include <thread_db.h>],
 954        [int i = TD_NOTALLOC;],
 955        gdb_cv_thread_db_h_has_td_notalloc=yes,
 956        gdb_cv_thread_db_h_has_td_notalloc=no
 957      )
 958    )
 959 fi
 960 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
 961   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
 962             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
 963 fi
 964
 965 dnl See if we have a sys/syscall header file that has __NR_tkill.
 966 if test "x$ac_cv_header_sys_syscall_h" = "xyes"; then
 967    AC_CACHE_CHECK([whether <sys/syscall.h> has __NR_tkill],
 968                   gdb_cv_sys_syscall_h_has_tkill,
 969      AC_TRY_COMPILE(
 970        [#include <sys/syscall.h>],
 971        [int i = __NR_tkill;],
 972        gdb_cv_sys_syscall_h_has_tkill=yes,
 973        gdb_cv_sys_syscall_h_has_tkill=no
 974      )
 975    )
 976 fi
 977 dnl See if we can issue tkill syscall.
 978 if test "x$gdb_cv_sys_syscall_h_has_tkill" = "xyes" && test "x$ac_cv_func_syscall" = "xyes"; then
 979   AC_DEFINE(HAVE_TKILL_SYSCALL, 1,
 980             [Define if we can use the tkill syscall.])
 981 fi
 982
 983 dnl Handle optional features that can be enabled.
 984
 985 AC_ARG_WITH(sysroot,
 986 [  --with-sysroot[=DIR] Search for usr/lib et al within DIR.],
 987 [
 988  case ${with_sysroot} in
 989  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
 990  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
 991  esac
 992
 993  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
 994
 995  if test "x$exec_prefix" = xNONE; then
 996   if test "x$prefix" = xNONE; then
 997    test_prefix=/usr/local
 998   else
 999    test_prefix=$prefix
1000   fi
1001  else
1002   test_prefix=$exec_prefix
1003  fi
1004  case ${TARGET_SYSTEM_ROOT} in
1005  "${test_prefix}"|"${test_prefix}/"*|\
1006  '${exec_prefix}'|'${exec_prefix}/'*)
1007    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
1008    TARGET_SYSTEM_ROOT_DEFINE="$t"
1009    ;;
1010  esac
1011 ], [
1012  TARGET_SYSTEM_ROOT=
1013  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"'
1014 ])
1015 AC_SUBST(TARGET_SYSTEM_ROOT)
1016 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
1017
1018 # NOTE: Don't add -Wall or -Wunused, they both include
1019 # -Wunused-parameter which reports bogus warnings.
1020 # NOTE: If you add to this list, remember to update
1021 # gdb/doc/gdbint.texinfo.
1022 build_warnings="-Wimplicit -Wreturn-type -Wcomment -Wtrigraphs \
1023 -Wformat -Wparentheses -Wpointer-arith -Wuninitialized -Wformat-nonliteral \
1024 -Wunused-label -Wunused-function"
1025 # Up for debate: -Wswitch -Wcomment -trigraphs -Wtrigraphs
1026 # -Wunused-function -Wunused-variable -Wunused-value
1027 # -Wchar-subscripts -Wtraditional -Wshadow -Wcast-qual
1028 # -Wcast-align -Wwrite-strings -Wconversion -Wstrict-prototypes
1029 # -Wmissing-prototypes -Wmissing-declarations -Wredundant-decls
1030 # -Woverloaded-virtual -Winline -Werror"
1031 AC_ARG_ENABLE(build-warnings,
1032 [  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
1033 [case "${enableval}" in
1034   yes)  ;;
1035   no)   build_warnings="-w";;
1036   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1037         build_warnings="${build_warnings} ${t}";;
1038   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1039         build_warnings="${t} ${build_warnings}";;
1040   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1041 esac
1042 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1043   echo "Setting compiler warning flags = $build_warnings" 6>&1
1044 fi])dnl
1045 AC_ARG_ENABLE(gdb-build-warnings,
1046 [  --enable-gdb-build-warnings Enable GDB specific build-time compiler warnings if gcc is used],
1047 [case "${enableval}" in
1048   yes)  ;;
1049   no)   build_warnings="-w";;
1050   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1051         build_warnings="${build_warnings} ${t}";;
1052   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1053         build_warnings="${t} ${build_warnings}";;
1054   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1055 esac
1056 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1057   echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1
1058 fi])dnl
1059 WARN_CFLAGS=""
1060 WERROR_CFLAGS=""
1061 if test "x${build_warnings}" != x -a "x$GCC" = xyes
1062 then
1063     AC_MSG_CHECKING(compiler warning flags)
1064     # Separate out the -Werror flag as some files just cannot be
1065     # compiled with it enabled.
1066     for w in ${build_warnings}; do
1067         case $w in
1068         -Werr*) WERROR_CFLAGS=-Werror ;;
1069         *) # Check that GCC accepts it
1070             saved_CFLAGS="$CFLAGS"
1071             CFLAGS="$CFLAGS $w"
1072             AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
1073             CFLAGS="$saved_CFLAGS"
1074         esac
1075     done
1076     AC_MSG_RESULT(${WARN_CFLAGS}${WERROR_CFLAGS})
1077 fi
1078 AC_SUBST(WARN_CFLAGS)
1079 AC_SUBST(WERROR_CFLAGS)
1080
1081 # In the Cygwin environment, we need some additional flags.
1082 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1083 [AC_EGREP_CPP(lose, [
1084 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1085 lose
1086 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1087
1088
1089 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1090 SER_HARDWIRE="ser-unix.o ser-pipe.o ser-tcp.o"
1091 case ${host} in
1092   *go32* ) SER_HARDWIRE=ser-go32.o ;;
1093   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
1094 esac
1095 AC_SUBST(SER_HARDWIRE)
1096
1097 # libreadline needs libuser32.a in a cygwin environment
1098 WIN32LIBS=
1099 if test x$gdb_cv_os_cygwin = xyes; then
1100     WIN32LIBS="-luser32"
1101     case "${target}" in
1102         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
1103         ;;
1104     esac
1105 fi
1106 AC_SUBST(WIN32LIBS)
1107
1108 LIBGUI="../libgui/src/libgui.a"
1109 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
1110 AC_SUBST(LIBGUI)
1111 AC_SUBST(GUI_CFLAGS_X)
1112
1113 WIN32LDAPP=
1114 AC_SUBST(WIN32LIBS)
1115 AC_SUBST(WIN32LDAPP)
1116
1117 configdir="unix"
1118
1119 GDBTKLIBS=
1120 if test "${enable_gdbtk}" = "yes"; then
1121
1122     # Gdbtk must have an absolute path to srcdir in order to run
1123     # properly when not installed.
1124     here=`pwd`
1125     cd ${srcdir}
1126     GDBTK_SRC_DIR=`pwd`
1127     cd $here
1128
1129     CY_AC_PATH_TCLCONFIG
1130     if test -z "${no_tcl}"; then
1131         CY_AC_LOAD_TCLCONFIG
1132         CY_AC_PATH_TKCONFIG
1133
1134         # now look for Tcl library stuff
1135
1136         case "${host}" in
1137         *-*-cygwin*)
1138             tcldir=../tcl/win/
1139             ;;
1140         *)
1141             tcldir=../tcl/unix/
1142             ;;
1143         esac
1144
1145         TCL_DEPS="${tcldir}${TCL_LIB_FILE}"
1146
1147         # If $no_tk is nonempty, then we can't do Tk, and there is no
1148         # point to doing Tcl.
1149         if test -z "${no_tk}"; then
1150            CY_AC_LOAD_TKCONFIG
1151            CY_AC_PATH_TCLH
1152            CY_AC_PATH_TKH
1153            CY_AC_PATH_ITCLH
1154            CY_AC_PATH_ITKH
1155
1156
1157            # now look for Tk library stuff
1158
1159            case "${host}" in
1160            *-*-cygwin*)
1161                tkdir=../tk/win/
1162                ;;
1163            *)
1164                tkdir=../tk/unix/
1165                ;;
1166            esac
1167
1168            TK_DEPS="${tkdir}${TK_LIB_FILE}"
1169
1170            # now look for Itcl library stuff
1171
1172            CY_AC_PATH_ITCLCONFIG
1173            if test -z "${no_itcl}"; then
1174              CY_AC_LOAD_ITCLCONFIG
1175
1176              ITCLLIB="${ITCL_BUILD_LIB_SPEC}"
1177              ITCL_DEPS="${ITCL_LIB_FULL_PATH}"
1178            fi
1179
1180
1181            # now look for Itk library stuff
1182            CY_AC_PATH_ITKCONFIG
1183            if test -z "${no_itcl}"; then
1184              CY_AC_LOAD_ITKCONFIG
1185
1186              ITKLIB="${ITK_BUILD_LIB_SPEC}"
1187              ITK_DEPS="${ITK_LIB_FULL_PATH}"
1188            fi
1189
1190            ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
1191            # Tcl/Tk 8.1 require -fwritable strings.  I don't
1192            # know whether 8.2 will or not, but I bet it will.
1193            # I don't have to worry about 7.x since we don't support it.
1194            GDBTK_CFLAGS=""
1195            if test "$GCC" = "yes"; then
1196                if test "$TCL_VERSION" != "8.0" ; then
1197                    GDBTK_CFLAGS="-fwritable-strings"
1198                fi
1199            fi
1200
1201            # Include some libraries that Tcl and Tk want.
1202            TCL_LIBS='$(LIBGUI) $(ITCL) $(ITK) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
1203            # Yes, the ordering seems wrong here.  But it isn't.
1204            # TK_LIBS is the list of libraries that need to be linked
1205            # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
1206            # were in LIBS then any link tests after this point would
1207            # try to include things like `$(LIBGUI)', which wouldn't work.
1208            GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
1209
1210            CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
1211            CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
1212            CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
1213            CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
1214            CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
1215            CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
1216            CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
1217
1218            if test x$gdb_cv_os_cygwin = xyes; then
1219               WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
1220               WIN32LDAPP="-Wl,--subsystem,console"
1221               CONFIG_OBS="${CONFIG_OBS} gdbres.o"
1222            fi
1223         fi
1224     fi
1225
1226     configdirs="${configdirs} gdbtk"
1227 fi
1228
1229 AC_SUBST(X_CFLAGS)
1230 AC_SUBST(X_LDFLAGS)
1231 AC_SUBST(X_LIBS)
1232 AC_SUBST(TCL_DEPS)
1233 AC_SUBST(TK_DEPS)
1234 AC_SUBST(ITCLLIB)
1235 AC_SUBST(ITCL_DEPS)
1236 AC_SUBST(ITKLIB)
1237 AC_SUBST(ITK_DEPS)
1238 AC_SUBST(GDBTKLIBS)
1239 AC_SUBST(GDBTK_CFLAGS)
1240 AC_SUBST(GDBTK_SRC_DIR)
1241
1242 AC_PATH_X
1243
1244
1245 # Unlike the sim directory, whether a simulator is linked is controlled by
1246 # presence of a SIM= and a SIM_OBS= definition in the target '.mt' file.
1247 # This code just checks for a few cases where we'd like to ignore those
1248 # definitions, even when they're present in the '.mt' file.  These cases
1249 # are when --disable-sim is specified, or if the simulator directory is
1250 # not part of the source tree.
1251 #
1252 AC_ARG_ENABLE(sim,
1253 [  --enable-sim            Link gdb with simulator],
1254 [echo "enable_sim = $enable_sim";
1255  echo "enableval = ${enableval}";
1256  case "${enableval}" in
1257   yes) ignore_sim=false ;;
1258   no)  ignore_sim=true ;;
1259   *)   ignore_sim=false ;;
1260  esac],
1261 [ignore_sim=false])
1262
1263 if test ! -d "${srcdir}/../sim"; then
1264   ignore_sim=true
1265 fi
1266
1267 if test "${ignore_sim}" = "true"; then
1268     IGNORE_SIM="SIM="
1269     IGNORE_SIM_OBS="SIM_OBS="
1270 else
1271     IGNORE_SIM=""
1272     IGNORE_SIM_OBS=""
1273     AC_DEFINE(WITH_SIM)
1274 fi
1275 AC_SUBST(IGNORE_SIM)
1276 AC_SUBST(IGNORE_SIM_OBS)
1277
1278 AC_SUBST(ENABLE_CFLAGS)
1279 AC_SUBST(PROFILE_CFLAGS)
1280
1281 AC_SUBST(CONFIG_OBS)
1282 AC_SUBST(CONFIG_DEPS)
1283 AC_SUBST(CONFIG_SRCS)
1284 AC_SUBST(CONFIG_ALL)
1285 AC_SUBST(CONFIG_CLEAN)
1286 AC_SUBST(CONFIG_INSTALL)
1287 AC_SUBST(CONFIG_UNINSTALL)
1288
1289 # target_subdir is used by the testsuite to find the target libraries.
1290 target_subdir=
1291 if test "${host}" != "${target}"; then
1292     target_subdir="${target_alias}/"
1293 fi
1294 AC_SUBST(target_subdir)
1295
1296 frags=
1297 host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
1298 if test ! -f ${host_makefile_frag}; then
1299     # When building a native debuger the .mh file containing things
1300     # like NATDEPFILES is needed.  Cross debuggers don't need .mh
1301     # since it no longer contains anything useful.
1302     if test "${target}" = "${host}"; then
1303         AC_MSG_ERROR("*** Gdb does not support native target ${host}")
1304     else
1305         host_makefile_frag=/dev/null
1306     fi
1307 fi
1308 frags="$frags $host_makefile_frag"
1309
1310 target_makefile_frag=${srcdir}/config/${gdb_target_cpu}/${gdb_target}.mt
1311 if test ! -f ${target_makefile_frag}; then
1312 AC_MSG_ERROR("*** Gdb does not support target ${target}")
1313 fi
1314 frags="$frags $target_makefile_frag"
1315
1316 AC_SUBST_FILE(host_makefile_frag)
1317 AC_SUBST_FILE(target_makefile_frag)
1318 AC_SUBST(frags)
1319
1320 changequote(,)dnl
1321 hostfile=`sed -n '
1322 s/XM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
1323 ' ${host_makefile_frag}`
1324
1325 targetfile=`sed -n '
1326 s/TM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
1327 ' ${target_makefile_frag}`
1328
1329 if test "${target}" = "${host}"; then
1330 # We pick this up from the host configuration file (.mh) because we
1331 # do not have a native configuration Makefile fragment.
1332 nativefile=`sed -n '
1333 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
1334 ' ${host_makefile_frag}`
1335 fi
1336 changequote([,])
1337
1338 if test x"${gdb_osabi}" != x ; then
1339     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
1340                        [Define to the default OS ABI for this configuration.])
1341 fi
1342
1343 # Enable multi-ice-gdb-server.
1344 AC_ARG_ENABLE(multi-ice,
1345 [  --enable-multi-ice      build the multi-ice-gdb-server],
1346   [case $enableval in
1347     yes | no)
1348       ;;
1349     *) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;;
1350   esac])
1351 if test "x$enable_multi_ice" = xyes; then
1352   configdirs="$configdirs multi-ice"
1353 fi
1354
1355 # We only build gdbserver automatically if host and target are the same.
1356 if test "x$target" = "x$host"; then
1357   AC_MSG_CHECKING(whether gdbserver is supported on this host)
1358   if test "x$build_gdbserver" = xyes; then
1359     configdirs="$configdirs gdbserver"
1360     AC_MSG_RESULT(yes)
1361   else
1362     AC_MSG_RESULT(no)
1363   fi
1364 fi
1365
1366 AC_CONFIG_SUBDIRS($configdirs)
1367
1368 # If hostfile (XM_FILE) and/or targetfile (TM_FILE) and/or nativefile
1369 # (NAT_FILE) is not set in config/*/*.m[ht] files, we link to an empty
1370 # version.
1371
1372 files=
1373 links=
1374
1375 rm -f xm.h
1376 xm_h=""
1377 if test "${hostfile}" != ""; then
1378     xm_h=xm.h
1379     GDB_XM_FILE="config/${gdb_host_cpu}/${hostfile}"
1380     files="${files} ${GDB_XM_FILE}"
1381     links="${links} xm.h"
1382     AC_DEFINE_UNQUOTED(GDB_XM_FILE, ${GDB_XM_FILE})
1383 fi
1384 AC_SUBST(xm_h)
1385
1386 rm -f tm.h
1387 tm_h=""
1388 if test "${targetfile}" != ""; then
1389     tm_h=tm.h
1390     GDB_TM_FILE="config/${gdb_target_cpu}/${targetfile}"
1391     files="${files} ${GDB_TM_FILE}"
1392     links="${links} tm.h"
1393     AC_DEFINE_UNQUOTED(GDB_TM_FILE, ${GDB_TM_FILE})
1394 fi
1395 AC_SUBST(tm_h)
1396
1397 rm -f nm.h
1398 nm_h=""
1399 if test "${nativefile}" != ""; then
1400     nm_h=nm.h
1401     GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}"
1402     files="${files} ${GDB_NM_FILE}"
1403     links="${links} nm.h"
1404     AC_DEFINE_UNQUOTED(GDB_NM_FILE, ${GDB_NM_FILE})
1405 fi
1406 AC_SUBST(nm_h)
1407
1408 AC_LINK_FILES($files, $links)
1409
1410 dnl Check for exe extension set on certain hosts (e.g. Win32)
1411 AC_EXEEXT
1412
1413 dnl  Detect the character set used by this host.
1414
1415 dnl  At the moment, we just assume it's ISO-8859-1 (which is a
1416 dnl  superset of ASCII containing the characters needed for French,
1417 dnl  German, Spanish, Italian, and possibly others), but if were
1418 dnl  *were* to support any host character sets other than ISO-8859-1,
1419 dnl  here's where we'd detect it.
1420 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "ISO-8859-1",
1421           [Define to be a string naming the default host character set.])
1422
1423 AM_ICONV
1424
1425 AC_OUTPUT(Makefile .gdbinit:gdbinit.in,
1426 [
1427 dnl Autoconf doesn't provide a mechanism for modifying definitions
1428 dnl provided by makefile fragments.
1429 dnl
1430 if test "${nativefile}" = ""; then
1431         < Makefile \
1432         sed -e '/^NATDEPFILES[[         ]]*=.*\\$/,/[[^\\]]$/s/^/# /' \
1433             -e '/^NATDEPFILES[[         ]]*=/s/^/# /' \
1434         | sed -e '/^\(NATDEPFILES[[     ]]*[[+]]=[[     ]]*\)/s//# \1/' \
1435         > Makefile.tem
1436 mv -f Makefile.tem Makefile
1437 fi
1438
1439 changequote(,)dnl
1440 sed -e '/^TM_FILE[      ]*=/s,^TM_FILE[         ]*=[    ]*,&config/'"${gdb_target_cpu}"'/,
1441 /^XM_FILE[      ]*=/s,^XM_FILE[         ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,
1442 /^NAT_FILE[     ]*=/s,^NAT_FILE[        ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,' <Makefile >Makefile.tmp
1443 mv -f Makefile.tmp Makefile
1444 changequote([,])dnl
1445
1446
1447 case x$CONFIG_HEADERS in
1448 xconfig.h:config.in)
1449 echo > stamp-h ;;
1450 esac
1451 ],
1452 [
1453 gdb_host_cpu=$gdb_host_cpu
1454 gdb_target_cpu=$gdb_target_cpu
1455 nativefile=$nativefile
1456 ])
1457
1458 exit 0