gdb/configure.in

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004
   3 dnl Free Software Foundation, Inc.
   4 dnl
   5 dnl This file is part of GDB.
   6 dnl
   7 dnl This program is free software; you can redistribute it and/or modify
   8 dnl it under the terms of the GNU General Public License as published by
   9 dnl the Free Software Foundation; either version 2 of the License, or
  10 dnl (at your option) any later version.
  11 dnl
  12 dnl This program is distributed in the hope that it will be useful,
  13 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 dnl GNU General Public License for more details.
  16 dnl
  17 dnl You should have received a copy of the GNU General Public License
  18 dnl along with this program; if not, write to the Free Software
  19 dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  20
  21 dnl Process this file with autoconf to produce a configure script.
  22
  23 AC_PREREQ(2.13)dnl
  24 AC_INIT(main.c)
  25 AC_CONFIG_HEADER(config.h:config.in)
  26 AM_MAINTAINER_MODE
  27
  28 AC_PROG_CC
  29 AC_GNU_SOURCE
  30 AC_AIX
  31 AC_ISC_POSIX
  32 AM_PROG_CC_STDC
  33
  34 AC_CONFIG_AUX_DIR(`cd $srcdir;pwd`/..)
  35 AC_CANONICAL_SYSTEM
  36
  37 # FIXME: kettenis/20030102: The AC_PROG_RANLIB from Autoconf 2.13
  38 # doesn't support cross-compilation, but the one from Autoconf 2.5x
  39 # does.  Override RANLIB here (i.e. before running AC_PROG_RANLIB) to
  40 # deal with the lossage.  Note that CY_GNU_GETTEXT currently calls
  41 # AC_PROG_RANLIB.  This can be removed when we switch to Autoconf
  42 # 2.5x.
  43 AC_CHECK_TOOL(RANLIB, ranlib, :)
  44
  45 dnl Set up for gettext.  PACKAGE is used when we call bindtextdomain.
  46 ALL_LINGUAS=
  47 CY_GNU_GETTEXT
  48 AC_DEFINE(PACKAGE, "gdb", [Name of this package. ])
  49
  50 debugdir=${libdir}/debug
  51
  52 AC_ARG_WITH(separate-debug-dir,
  53 [  --with-separate-debug-dir=path   Look for global separate debug info in this path [LIBDIR/debug]],
  54 [debugdir="${withval}"])
  55
  56 AC_DEFINE_DIR(DEBUGDIR, debugdir,
  57               [Global directory for separate debug files. ])
  58 #AC_DEFINE_UNQUOTED(DEBUGDIR, "$debugdir"),
  59
  60 dnl List of object files added by configure.
  61
  62 CONFIG_OBS=
  63 CONFIG_DEPS=
  64 CONFIG_SRCS=
  65 ENABLE_CFLAGS=
  66 CONFIG_ALL=
  67 CONFIG_CLEAN=
  68 CONFIG_INSTALL=
  69 CONFIG_UNINSTALL=
  70
  71 AC_CONFIG_SUBDIRS(doc testsuite)
  72 configdirs=
  73
  74 . $srcdir/configure.host
  75
  76 . $srcdir/configure.tgt
  77
  78 # Fetch the default architecture and default target vector from BFD.
  79 targ=$target; . $srcdir/../bfd/config.bfd
  80
  81 # We only want the first architecture, so strip off the others if
  82 # there is more than one.
  83 targ_archs=`echo $targ_archs | sed 's/ .*//'`
  84
  85 if test "x$targ_archs" != x; then
  86   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
  87     [Define to BFD's default architecture. ])
  88 fi
  89 if test "x$targ_defvec" != x; then
  90   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
  91     [Define to BFD's default target vector. ])
  92 fi
  93
  94 AC_ARG_PROGRAM
  95
  96 # The CLI cannot be disabled yet, but may be in the future.
  97
  98 # Enable CLI.
  99 AC_ARG_ENABLE(gdbcli,
 100 [  --disable-gdbcli        disable command-line interface (CLI)],
 101   [case $enableval in
 102     yes)
 103       ;;
 104     no)
 105       AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;;
 106     *)
 107       AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;;
 108   esac],
 109   [enable_gdbcli=yes])
 110 if test x"$enable_gdbcli" = xyes; then
 111   if test -d $srcdir/cli; then
 112     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)"
 113     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)"
 114     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)"
 115     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)"
 116   fi
 117 fi
 118
 119 # Enable MI.
 120 AC_ARG_ENABLE(gdbmi,
 121 [  --disable-gdbmi         disable machine-interface (MI)],
 122   [case $enableval in
 123     yes | no)
 124       ;;
 125     *)
 126       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 127   esac],
 128   [enable_gdbmi=yes])
 129 if test x"$enable_gdbmi" = xyes; then
 130   if test -d $srcdir/mi; then
 131     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 132     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 133     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 134     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 135   fi
 136 fi
 137
 138 # Enable TUI.
 139 AC_ARG_ENABLE(tui,
 140 [  --enable-tui            enable full-screen terminal user interface (TUI)],
 141   [case $enableval in
 142     yes | no)
 143       ;;
 144     *)
 145       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 146   esac],enable_tui=yes)
 147 if test x"$enable_tui" = xyes; then
 148   if test -d $srcdir/tui; then
 149     if test "$ac_cv_search_initscr" != no -a "$ac_cv_search_wborder" != no; then
 150       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
 151       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
 152       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
 153       CONFIG_INITS="$CONFIG_INITS \$(SUBDIR_TUI_INITS)"
 154       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
 155       CONFIG_ALL="${CONFIG_ALL} all-tui"
 156       CONFIG_CLEAN="${CONFIG_CLEAN} clean-tui"
 157       CONFIG_INSTALL="${CONFIG_INSTALL} install-tui"
 158       CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-tui"
 159     fi
 160   fi
 161 fi
 162
 163 # Enable gdbtk.
 164 AC_ARG_ENABLE(gdbtk,
 165 [  --enable-gdbtk          enable gdbtk graphical user interface (GUI)],
 166   [case $enableval in
 167     yes | no)
 168       ;;
 169     *)
 170       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 171   esac],
 172   [if test -d $srcdir/gdbtk; then
 173     enable_gdbtk=yes
 174   else
 175     enable_gdbtk=no
 176   fi])
 177 # We unconditionally disable gdbtk tests on selected platforms.
 178 case $host_os in
 179   go32* | windows*)
 180     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 181     enable_gdbtk=no ;;
 182 esac
 183
 184 # Libunwind support.
 185 AC_ARG_WITH(libunwind,
 186 [  --with-libunwind            Use libunwind frame unwinding support],
 187 [case "${withval}" in
 188   yes)  enable_libunwind=yes ;;
 189   no)   enable_libunwind=no ;;
 190   *)    AC_MSG_ERROR(bad value ${withval} for GDB with-libunwind option) ;;
 191 esac],[
 192   AC_CHECK_HEADERS(libunwind.h)
 193   AC_CHECK_HEADERS(libunwind-ia64.h)
 194   if test x"$ac_cv_header_libunwind_h" = xyes -a x"$ac_cv_header_libunwind_ia64_h" = xyes; then
 195     enable_libunwind=yes;
 196   fi
 197 ])
 198
 199 if test x"$enable_libunwind" = xyes; then
 200   AC_CHECK_HEADERS(libunwind.h)
 201   AC_CHECK_HEADERS(libunwind-ia64.h)
 202   AC_DEFINE(HAVE_LIBUNWIND, 1)
 203   CONFIG_OBS="$CONFIG_OBS libunwind-frame.o"
 204   CONFIG_DEPS="$CONFIG_DEPS libunwind-frame.o"
 205   CONFIG_SRCS="$CONFIG_SRCS libunwind-frame.c"
 206 fi
 207
 208 # Profiling support.
 209 AC_ARG_ENABLE(profiling,
 210 [  --enable-profiling      enable profiling of GDB],
 211   [case $enableval in
 212     yes | no)
 213       ;;
 214     *)
 215       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 216   esac],
 217  [enable_profiling=no])
 218
 219 AC_CHECK_FUNCS(monstartup _mcleanup)
 220 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 221 [AC_TRY_LINK(
 222 [#include <stdlib.h>
 223 extern char _etext;
 224 ],
 225 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 226 if test $ac_cv_var__etext = yes; then
 227   AC_DEFINE(HAVE__ETEXT, 1,
 228             [Define to 1 if your system has the _etext variable. ])
 229 fi
 230 if test "$enable_profiling" = yes ; then
 231   if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
 232     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 233   fi
 234   PROFILE_CFLAGS=-pg
 235   OLD_CFLAGS="$CFLAGS"
 236   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 237
 238   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 239     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 240      ac_cv_cc_supports_pg=no)])
 241
 242   if test $ac_cv_cc_supports_pg = no; then
 243     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 244   fi
 245
 246   CFLAGS="$OLD_CFLAGS"
 247 fi
 248
 249 # --------------------- #
 250 # Checks for programs.  #
 251 # --------------------- #
 252
 253 AC_PROG_AWK
 254 AC_PROG_INSTALL
 255 AC_PROG_LN_S
 256 AC_PROG_RANLIB
 257 AC_PROG_YACC
 258
 259 AC_CHECK_TOOL(AR, ar)
 260 AC_CHECK_TOOL(DLLTOOL, dlltool)
 261 AC_CHECK_TOOL(WINDRES, windres)
 262
 263 # Needed for GNU/Hurd.
 264 AC_CHECK_TOOL(MIG, mig)
 265
 266 # ---------------------- #
 267 # Checks for libraries.  #
 268 # ---------------------- #
 269
 270 # We might need to link with -lm; most simulators need it.
 271 AC_CHECK_LIB(m, main)
 272
 273 # We need to link with -lw to get `wctype' on Solaris before Solaris
 274 # 2.6.  Solaris 2.6 and beyond have this function in libc, and have a
 275 # libw that some versions of the GNU linker cannot hanle (GNU ld 2.9.1
 276 # is known to have this problem).  Therefore we avoid libw if we can.
 277 AC_CHECK_FUNC(wctype, [],
 278   [AC_CHECK_LIB(w, wctype)])
 279
 280 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 281 AC_SEARCH_LIBS(gethostbyname, nsl)
 282
 283 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 284 AC_SEARCH_LIBS(socketpair, socket)
 285
 286 # Since GDB uses Readline, we need termcap functionality, so we need
 287 # to find a library that provides that.  When GDB is configured with
 288 # the TUI, we need full curses functionality.
 289
 290 case $host_os in
 291   cygwin*)
 292     if test -d $srcdir/libtermcap; then
 293       LIBS="../libtermcap/libtermcap.a $LIBS"
 294       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 295     fi ;;
 296   go32* | *djgpp*)
 297     ac_cv_search_tgetent="none required"
 298     ;;
 299   aix*)
 300     # Readline prefers curses over termcap on AIX.
 301     # ??? Why?
 302     AC_SEARCH_LIBS(tgetent, [tinfo ncurses curses termcap])
 303     ;;
 304 esac
 305
 306 # Note: We used to check for libtermlib and libterminfo too, but
 307 # Readline doesn't, so I think we're safe with leaving them out.
 308 AC_SEARCH_LIBS(tgetent, [termcap tinfo ncurses Hcurses curses])
 309
 310 if test "$ac_cv_search_tgetent" = no; then
 311   AC_MSG_ERROR([no termcap library found])
 312 fi
 313
 314 # FIXME: kettenis/20030102: We seem to prefer HP curses (Hcurses) over
 315 # Xcurses on HP-UX; see the `-D__HP_CURSES' in the relevant host
 316 # Makefile fragments.  That's why we need to have `Hcurses' before
 317 # `curses'.  I don't see why we should use HP curses if a more
 318 # standard curses is available, except that according to HP's
 319 # documentation one needs to compile `-D_XOPEN_SOURCE_EXTENDED' on
 320 # HP-UX 10.10 and 10.20.
 321
 322 # FIXME: ncurses does not work on native alphaev68-dec-osf5.1,
 323 # and probably other platforms.  AC_SEARCH_LIBS finds the library
 324 # in a place such as /usr/local/lib/libncurses.a, but does not
 325 # do anything to look for the matching include files.
 326 # -- chastain 2004-05-01
 327
 328 AC_SEARCH_LIBS(initscr, [ncurses Hcurses curses pdcurses], [],
 329   [AC_MSG_WARN([no curses library found])])
 330
 331 # Check whether the wborder function is provided by the curses
 332 # library detected above.  In certain implementations such as
 333 # the HP/UX Hcurses for instance, this function is provided by an
 334 # additional library.  So if we did not find this function inside
 335 # the curses library, try some alternate libraries we know might
 336 # provide it.
 337 AC_SEARCH_LIBS(wborder, [cur_colr], [],
 338     [AC_MSG_WARN([wborder function not found, tui will be disabled])])
 339
 340 # ------------------------- #
 341 # Checks for header files.  #
 342 # ------------------------- #
 343
 344 AC_HEADER_DIRENT
 345 AC_HEADER_STAT
 346 AC_HEADER_STDC
 347 AC_CHECK_HEADERS(link.h)
 348 AC_CHECK_HEADERS(machine/reg.h)
 349 AC_CHECK_HEADERS(nlist.h)
 350 AC_CHECK_HEADERS(poll.h sys/poll.h)
 351 AC_CHECK_HEADERS(proc_service.h thread_db.h gnu/libc-version.h)
 352 AC_CHECK_HEADERS(stddef.h)
 353 AC_CHECK_HEADERS(stdlib.h)
 354 AC_CHECK_HEADERS(stdint.h)
 355 AC_CHECK_HEADERS(string.h memory.h strings.h)
 356 AC_CHECK_HEADERS(sys/fault.h)
 357 AC_CHECK_HEADERS(sys/file.h)
 358 AC_CHECK_HEADERS(sys/filio.h)
 359 AC_CHECK_HEADERS(sys/ioctl.h)
 360 AC_CHECK_HEADERS(sys/param.h)
 361 AC_CHECK_HEADERS(sys/proc.h)
 362 AC_CHECK_HEADERS(sys/procfs.h)
 363 AC_CHECK_HEADERS(sys/ptrace.h ptrace.h)
 364 AC_CHECK_HEADERS(sys/reg.h sys/debugreg.h)
 365 AC_CHECK_HEADERS(sys/select.h)
 366 AC_CHECK_HEADERS(sys/syscall.h)
 367 AC_CHECK_HEADERS(sys/user.h)
 368 AC_CHECK_HEADERS(sys/wait.h wait.h)
 369 AC_CHECK_HEADERS(termios.h termio.h sgtty.h)
 370 AC_CHECK_HEADERS(unistd.h)
 371
 372 # On Solaris 2.[78], we need to define _MSE_INT_H to avoid a clash
 373 # between <widec.h> and <wchar.h> that would cause AC_CHECK_HEADERS to
 374 # think that we don't have <curses.h> if we're using GCC.
 375 case $host_os in
 376   solaris2.[[78]])
 377     if test "$GCC" = yes; then
 378       AC_DEFINE(_MSE_INT_H, 1,
 379         [[Define to 1 to avoid a clash between <widec.h> and <wchar.h> on
 380    Solaris 2.[78] when using GCC. ]])
 381     fi ;;
 382 esac
 383 AC_CHECK_HEADERS(curses.h ncurses.h term.h)
 384
 385 # FIXME: kettenis/20030102: In most cases we include these
 386 # unconditionally, so what's the point in checking these?
 387 AC_CHECK_HEADERS(ctype.h time.h)
 388
 389 dnl Check for struct stat with an st_blocks member
 390 AC_MSG_CHECKING(for member st_blocks in struct stat)
 391 AC_CACHE_VAL(gdb_cv_have_struct_stat_with_st_blocks_member,
 392   [AC_TRY_COMPILE([#include <sys/types.h>
 393 #include <sys/stat.h>],
 394                   [struct stat st; (void) st.st_blocks;],
 395                   gdb_cv_have_struct_stat_with_st_blocks_member=yes,
 396                   gdb_cv_have_struct_stat_with_st_blocks_member=no)])
 397 AC_MSG_RESULT($gdb_cv_have_struct_stat_with_st_blocks_member)
 398 if test $gdb_cv_have_struct_stat_with_st_blocks_member = yes; then
 399   AC_DEFINE(HAVE_STRUCT_STAT_ST_BLOCKS)
 400 fi
 401 # ------------------------- #
 402 # Checks for declarations.  #
 403 # ------------------------- #
 404
 405 gcc_AC_CHECK_DECLS(getopt)
 406
 407 # ------------------ #
 408 # Checks for types.  #
 409 # ------------------ #
 410
 411 AC_TYPE_SIGNAL
 412
 413 # ------------------------------------- #
 414 # Checks for compiler characteristics.  #
 415 # ------------------------------------- #
 416
 417 AC_C_CONST
 418 AC_C_INLINE
 419
 420 # ------------------------------ #
 421 # Checks for library functions.  #
 422 # ------------------------------ #
 423
 424 AC_FUNC_ALLOCA
 425 AC_FUNC_MMAP
 426 AC_FUNC_VFORK
 427 AC_CHECK_FUNCS(canonicalize_file_name realpath)
 428 AC_CHECK_FUNCS(poll)
 429 AC_CHECK_FUNCS(pread64)
 430 AC_CHECK_FUNCS(sbrk)
 431 AC_CHECK_FUNCS(setpgid setpgrp)
 432 AC_CHECK_FUNCS(sigaction sigprocmask sigsetmask)
 433 AC_CHECK_FUNCS(socketpair)
 434 AC_CHECK_FUNCS(syscall)
 435
 436 dnl AC_FUNC_SETPGRP does not work when cross compiling
 437 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
 438 if test "$cross_compiling" = no; then
 439   AC_FUNC_SETPGRP
 440 else
 441   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
 442     [AC_TRY_COMPILE([
 443 #include <unistd.h>
 444 ], [
 445   if (setpgrp(1,1) == -1)
 446     exit (0);
 447   else
 448     exit (1);
 449 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
 450 if test $ac_cv_func_setpgrp_void = yes; then
 451   AC_DEFINE(SETPGRP_VOID, 1)
 452 fi
 453 fi
 454
 455 # Check if sigsetjmp is available.  Using AC_CHECK_FUNCS won't do
 456 # since sigsetjmp might only be defined as a macro.
 457 AC_CACHE_CHECK([for sigsetjmp], gdb_cv_func_sigsetjmp,
 458 [AC_TRY_COMPILE([
 459 #include <setjmp.h>
 460 ], [sigjmp_buf env; while (! sigsetjmp (env, 1)) siglongjmp (env, 1);],
 461 gdb_cv_func_sigsetjmp=yes, gdb_cv_func_sigsetjmp=no)])
 462 if test $gdb_cv_func_sigsetjmp = yes; then
 463   AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available. ])
 464 fi
 465
 466 # Assume we'll default to using the included libiberty regex.
 467 gdb_use_included_regex=yes
 468
 469 # However, if the system regex is GNU regex, then default to *not*
 470 # using the included regex.
 471 AC_CACHE_CHECK(
 472   [for GNU regex],
 473   [gdb_cv_have_gnu_regex],
 474   [AC_TRY_COMPILE(
 475     [#include <gnu-versions.h>],
 476     [#define REGEX_INTERFACE_VERSION 1
 477 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
 478 # error "Version mismatch"
 479 #endif],
 480     gdb_cv_have_gnu_regex=yes,
 481     gdb_cv_have_gnu_regex=no)])
 482 if test $gdb_cv_have_gnu_regex = yes; then
 483   gdb_use_included_regex=no
 484 fi
 485
 486 AC_ARG_WITH(included-regex,
 487   [  --without-included-regex don't use included regex; this is the default
 488                           on systems with version 2 of the GNU C library
 489                           (use with caution on other system)],
 490   gdb_with_regex=$withval,
 491   gdb_with_regex=$gdb_use_included_regex)
 492 if test "$gdb_with_regex" = yes; then
 493   AC_DEFINE(USE_INCLUDED_REGEX, 1,
 494     [Define to 1 if the regex included in libiberty should be used.])
 495 fi
 496
 497 # See if <sys/proc.h> defines `struct thread' with a td_pcb member.
 498 AC_CACHE_CHECK([for td_pcb in struct thread], gdb_cv_struct_thread_td_pcb,
 499 [AC_TRY_COMPILE([#include <sys/proc.h>], [struct thread td; td.td_pcb;],
 500 gdb_cv_struct_thread_td_pcb=yes, gdb_cv_struct_thread_td_pcb=no)])
 501 if test $gdb_cv_struct_thread_td_pcb = yes; then
 502   AC_DEFINE(HAVE_STRUCT_THREAD_TD_PCB, 1,
 503             [Define to 1 if your system has td_pcb in struct thread.])
 504 fi
 505
 506 # See if <machine/reg.h> degines `struct reg'.
 507 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
 508 [AC_TRY_COMPILE([#include <sys/types.h>
 509 #include <machine/reg.h>], [struct reg r;],
 510 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
 511 if test $gdb_cv_struct_reg = yes; then
 512   AC_DEFINE(HAVE_STRUCT_REG, 1,
 513             [Define to 1 if your system has struct reg in <machine/reg.h>.])
 514 fi
 515
 516 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
 517 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
 518 AC_CACHE_CHECK([for r_fs in struct reg], gdb_cv_struct_reg_r_fs,
 519 [AC_TRY_COMPILE([#include <machine/reg.h>], [struct reg r; r.r_fs;],
 520 gdb_cv_struct_reg_r_fs=yes, gdb_cv_struct_reg_r_fs=no)])
 521 if test $gdb_cv_struct_reg_r_fs = yes; then
 522   AC_DEFINE(HAVE_STRUCT_REG_R_FS)
 523 fi
 524 AC_CACHE_CHECK([for r_gs in struct reg], gdb_cv_struct_reg_r_gs,
 525 [AC_TRY_COMPILE([#include <machine/reg.h>], [struct reg r; r.r_gs;],
 526 gdb_cv_struct_reg_r_gs=yes, gdb_cv_struct_reg_r_gs=no)])
 527 if test $gdb_cv_struct_reg_r_gs = yes; then
 528   AC_DEFINE(HAVE_STRUCT_REG_R_GS)
 529 fi
 530
 531 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
 532 AC_MSG_CHECKING(for PTRACE_GETREGS)
 533 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
 534 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 535                 [PTRACE_GETREGS;],
 536                 [gdb_cv_have_ptrace_getregs=yes],
 537                 [gdb_cv_have_ptrace_getregs=no])])
 538 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
 539 if test $gdb_cv_have_ptrace_getregs = yes; then
 540   AC_DEFINE(HAVE_PTRACE_GETREGS)
 541 fi
 542
 543 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
 544 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
 545 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
 546 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 547                 [PTRACE_GETFPXREGS;],
 548                 [gdb_cv_have_ptrace_getfpxregs=yes],
 549                 [gdb_cv_have_ptrace_getfpxregs=no])])
 550 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
 551 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
 552   AC_DEFINE(HAVE_PTRACE_GETFPXREGS)
 553 fi
 554
 555 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
 556 AC_MSG_CHECKING(for PT_GETDBREGS)
 557 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
 558 [AC_TRY_COMPILE([#include <sys/types.h>
 559 #include <sys/ptrace.h>],
 560                 [PT_GETDBREGS;],
 561                 [gdb_cv_have_pt_getdbregs=yes],
 562                 [gdb_cv_have_pt_getdbregs=no])])
 563 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
 564 if test $gdb_cv_have_pt_getdbregs = yes; then
 565   AC_DEFINE(HAVE_PT_GETDBREGS)
 566 fi
 567
 568 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
 569 AC_MSG_CHECKING(for PT_GETXMMREGS)
 570 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
 571 [AC_TRY_COMPILE([#include <sys/types.h>
 572 #include <sys/ptrace.h>],
 573                 [PT_GETXMMREGS;],
 574                 [gdb_cv_have_pt_getxmmregs=yes],
 575                 [gdb_cv_have_pt_getxmmregs=no])])
 576 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
 577 if test $gdb_cv_have_pt_getxmmregs = yes; then
 578   AC_DEFINE(HAVE_PT_GETXMMREGS)
 579 fi
 580
 581 # See if stdint.h provides the uintptr_t type.
 582 # Autoconf 2.5X has an improved AC_CHECK_TYPE which will simplify this.
 583 AC_CACHE_CHECK([for uintptr_t in stdint.h], gdb_cv_have_uintptr_t,
 584   [AC_TRY_COMPILE(
 585     [#include <stdint.h>],
 586     [uintptr_t foo = 0;],
 587     gdb_cv_have_uintptr_t=yes,
 588     gdb_cv_have_uintptr_t=no)])
 589 if test $gdb_cv_have_uintptr_t = yes; then
 590   AC_DEFINE(HAVE_UINTPTR_T, 1, [Define if <stdint.h> provides the uintptr_t type.])
 591 fi
 592
 593 BFD_NEED_DECLARATION(malloc)
 594 BFD_NEED_DECLARATION(realloc)
 595 BFD_NEED_DECLARATION(free)
 596 BFD_NEED_DECLARATION(strerror)
 597 BFD_NEED_DECLARATION(strdup)
 598 BFD_NEED_DECLARATION(strstr)
 599 BFD_NEED_DECLARATION(canonicalize_file_name)
 600
 601 # The following save_state_t checkery is only necessary for HPUX
 602 # versions earlier than 10.20.  When those fade from memory, this
 603 # could be expunged. --jsm 1999-03-22
 604
 605 AC_MSG_CHECKING(for HPUX save_state structure)
 606 AC_EGREP_HEADER(save_state_t, machine/save_state.h,
 607                 gdb_cv_hpux_savestate=yes, gdb_cv_hpux_savestate=no)
 608 AC_EGREP_HEADER(ss_wide, machine/save_state.h, gdb_cv_hpux_sswide=yes,
 609                 gdb_cv_hpux_sswide=no)
 610 if test $gdb_cv_hpux_savestate = yes
 611 then
 612   AC_DEFINE(HAVE_STRUCT_SAVE_STATE_T, 1)
 613 fi
 614 if test $gdb_cv_hpux_sswide = yes
 615 then
 616   AC_DEFINE(HAVE_STRUCT_MEMBER_SS_WIDE, 1)
 617 fi
 618 AC_MSG_RESULT($gdb_cv_hpux_sswide)
 619
 620
 621 # If we are configured native on GNU/Linux, work around problems with
 622 # sys/procfs.h
 623 # Also detect which type of /proc is in use, such as for Unixware or Solaris.
 624
 625 if test "${target}" = "${host}"; then
 626   case "${host}" in
 627   i[[3456]]86-*-linux*)
 628         AC_DEFINE(START_INFERIOR_TRAPS_EXPECTED,2)
 629         AC_DEFINE(sys_quotactl)
 630         ;;
 631   ia64-*-aix*)
 632       AC_DEFINE(NEW_PROC_API)
 633       ;;
 634   *-*-unixware* | *-*-sysv4.2* | *-*-sysv5* | *-*-interix* )
 635       AC_DEFINE(NEW_PROC_API)
 636       ;;
 637   *-*-solaris2.[[6789]])
 638       AC_DEFINE(NEW_PROC_API)
 639       ;;
 640   mips-sgi-irix5*)
 641       # Work around <sys/proc.h> needing _KMEMUSER problem on IRIX 5.
 642       AC_DEFINE([_KMEMUSER], 1)
 643       ;;
 644   esac
 645 fi
 646
 647 if test "$ac_cv_header_sys_procfs_h" = yes; then
 648   BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
 649   BFD_HAVE_SYS_PROCFS_TYPE(prrun_t)
 650   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
 651   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
 652   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
 653   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
 654   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
 655   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset32_t)
 656   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
 657   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
 658   BFD_HAVE_SYS_PROCFS_TYPE(prsysent_t)
 659   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigset_t)
 660   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigaction64_t)
 661   BFD_HAVE_SYS_PROCFS_TYPE(pr_siginfo64_t)
 662
 663
 664   dnl Check for broken prfpregset_t type
 665
 666   dnl For Linux/i386, glibc 2.1.3 was released with a bogus
 667   dnl prfpregset_t type (it's a typedef for the pointer to a struct
 668   dnl instead of the struct itself).  We detect this here, and work
 669   dnl around it in gdb_proc_service.h.
 670
 671   if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
 672     AC_MSG_CHECKING(whether prfpregset_t type is broken)
 673     AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
 674       [AC_TRY_RUN([#include <sys/procfs.h>
 675        int main ()
 676        {
 677          if (sizeof (prfpregset_t) == sizeof (void *))
 678            return 1;
 679          return 0;
 680        }],
 681        gdb_cv_prfpregset_t_broken=no,
 682        gdb_cv_prfpregset_t_broken=yes,
 683        gdb_cv_prfpregset_t_broken=yes)])
 684     AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
 685     if test $gdb_cv_prfpregset_t_broken = yes; then
 686       AC_DEFINE(PRFPREGSET_T_BROKEN)
 687     fi
 688   fi
 689
 690   dnl Check for PIOCSET ioctl entry
 691
 692   AC_MSG_CHECKING(for PIOCSET ioctl entry in sys/procfs.h)
 693   AC_CACHE_VAL(gdb_cv_have_procfs_piocset,
 694   [AC_TRY_COMPILE([#include <unistd.h>
 695 #include <sys/types.h>
 696 #include <sys/procfs.h>
 697 ], [
 698     int dummy;;
 699     dummy = ioctl(0, PIOCSET, &dummy);
 700   ],
 701   gdb_cv_have_procfs_piocset=yes, gdb_cv_have_procfs_piocset=no)])
 702   AC_MSG_RESULT($gdb_cv_have_procfs_piocset)
 703   if test $gdb_cv_have_procfs_piocset = yes; then
 704     AC_DEFINE(HAVE_PROCFS_PIOCSET)
 705   fi
 706 fi
 707
 708 dnl For native ports (host == target), check to see what kind of
 709 dnl legacy link.h support is needed.  (See solib-legacy.c.)
 710 if test ${host} = ${target} ; then
 711   dnl Check for struct link_map with l_ members which are indicative
 712   dnl of SVR4-like shared libraries
 713
 714   AC_MSG_CHECKING(for member l_addr in struct link_map)
 715   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_l_members,
 716     [AC_TRY_COMPILE([#include <link.h>],
 717                     [struct link_map lm; (void) lm.l_addr;],
 718                     gdb_cv_have_struct_link_map_with_l_members=yes,
 719                     gdb_cv_have_struct_link_map_with_l_members=no)])
 720   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_l_members)
 721   if test $gdb_cv_have_struct_link_map_with_l_members = yes; then
 722     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_L_MEMBERS)
 723   fi
 724
 725   dnl Check for struct link_map with lm_ members which are indicative
 726   dnl of SunOS-like shared libraries
 727
 728   AC_MSG_CHECKING(for member lm_addr in struct link_map)
 729   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_lm_members,
 730     [AC_TRY_COMPILE([#include <sys/types.h>
 731 #include <link.h>],
 732                     [struct link_map lm; (void) lm.lm_addr;],
 733                     gdb_cv_have_struct_link_map_with_lm_members=yes,
 734                     gdb_cv_have_struct_link_map_with_lm_members=no)])
 735   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_lm_members)
 736   if test $gdb_cv_have_struct_link_map_with_lm_members = yes; then
 737     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_LM_MEMBERS)
 738   fi
 739
 740   dnl Check for struct so_map with som_ members which are found on
 741   dnl some *BSD systems.
 742
 743   AC_MSG_CHECKING(for member som_addr in struct so_map)
 744   AC_CACHE_VAL(gdb_cv_have_struct_so_map_with_som_members,
 745     [AC_TRY_COMPILE([#include <sys/types.h>
 746 #ifdef HAVE_NLIST_H
 747 #include <nlist.h>
 748 #endif
 749 #include <link.h>],
 750                     [struct so_map lm; (void) lm.som_addr;],
 751                     gdb_cv_have_struct_so_map_with_som_members=yes,
 752                     gdb_cv_have_struct_so_map_with_som_members=no)])
 753   AC_MSG_RESULT($gdb_cv_have_struct_so_map_with_som_members)
 754   if test $gdb_cv_have_struct_so_map_with_som_members = yes; then
 755     AC_DEFINE(HAVE_STRUCT_SO_MAP_WITH_SOM_MEMBERS)
 756   fi
 757
 758   dnl Check for struct link_map32 type, which allows a 64-bit Solaris
 759   dnl debugger to debug a 32-bit Solaris app with 32-bit shared libraries.
 760
 761   AC_MSG_CHECKING(for struct link_map32 in sys/link.h)
 762   AC_CACHE_VAL(gdb_cv_have_struct_link_map32,
 763     [AC_TRY_COMPILE([#define _SYSCALL32
 764 #include <sys/link.h>], [struct link_map32 l;],
 765      gdb_cv_have_struct_link_map32=yes,
 766      gdb_cv_have_struct_link_map32=no)])
 767   AC_MSG_RESULT($gdb_cv_have_struct_link_map32)
 768   if test $gdb_cv_have_struct_link_map32 = yes; then
 769     AC_DEFINE(HAVE_STRUCT_LINK_MAP32)
 770     AC_DEFINE(_SYSCALL32)
 771   fi
 772 fi
 773
 774 dnl See if compiler supports "long long" type.
 775
 776 AC_MSG_CHECKING(for long long support in compiler)
 777 AC_CACHE_VAL(gdb_cv_c_long_long,
 778 [AC_TRY_COMPILE(, [
 779   extern long long foo;
 780   switch (foo & 2) { case 0: return 1; }
 781 ],
 782 gdb_cv_c_long_long=yes, gdb_cv_c_long_long=no)])
 783 AC_MSG_RESULT($gdb_cv_c_long_long)
 784 if test $gdb_cv_c_long_long = yes; then
 785   AC_DEFINE(CC_HAS_LONG_LONG)
 786 fi
 787
 788 dnl See if the compiler and runtime support printing long long
 789
 790 AC_MSG_CHECKING(for long long support in printf)
 791 AC_CACHE_VAL(gdb_cv_printf_has_long_long,
 792 [AC_TRY_RUN([
 793 int main () {
 794   char buf[32];
 795   long long l = 0;
 796   l = (l << 16) + 0x0123;
 797   l = (l << 16) + 0x4567;
 798   l = (l << 16) + 0x89ab;
 799   l = (l << 16) + 0xcdef;
 800   sprintf (buf, "0x%016llx", l);
 801   return (strcmp ("0x0123456789abcdef", buf));
 802 }],
 803 gdb_cv_printf_has_long_long=yes,
 804 gdb_cv_printf_has_long_long=no,
 805 gdb_cv_printf_has_long_long=no)])
 806 if test $gdb_cv_printf_has_long_long = yes; then
 807   AC_DEFINE(PRINTF_HAS_LONG_LONG)
 808 fi
 809 AC_MSG_RESULT($gdb_cv_printf_has_long_long)
 810
 811 dnl See if compiler supports "long double" type.  Can't use AC_C_LONG_DOUBLE
 812 dnl because autoconf complains about cross-compilation issues.  However, this
 813 dnl code uses the same variables as the macro for compatibility.
 814
 815 AC_MSG_CHECKING(for long double support in compiler)
 816 AC_CACHE_VAL(ac_cv_c_long_double,
 817 [AC_TRY_COMPILE(, [long double foo;],
 818 ac_cv_c_long_double=yes, ac_cv_c_long_double=no)])
 819 AC_MSG_RESULT($ac_cv_c_long_double)
 820 if test $ac_cv_c_long_double = yes; then
 821   AC_DEFINE(HAVE_LONG_DOUBLE)
 822 fi
 823
 824 dnl See if the compiler and runtime support printing long doubles
 825
 826 AC_MSG_CHECKING(for long double support in printf)
 827 AC_CACHE_VAL(gdb_cv_printf_has_long_double,
 828 [AC_TRY_RUN([
 829 int main () {
 830   char buf[16];
 831   long double f = 3.141592653;
 832   sprintf (buf, "%Lg", f);
 833   return (strncmp ("3.14159", buf, 7));
 834 }],
 835 gdb_cv_printf_has_long_double=yes,
 836 gdb_cv_printf_has_long_double=no,
 837 gdb_cv_printf_has_long_double=no)])
 838 if test $gdb_cv_printf_has_long_double = yes; then
 839   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE)
 840 fi
 841 AC_MSG_RESULT($gdb_cv_printf_has_long_double)
 842
 843 dnl See if the compiler and runtime support scanning long doubles
 844
 845 AC_MSG_CHECKING(for long double support in scanf)
 846 AC_CACHE_VAL(gdb_cv_scanf_has_long_double,
 847 [AC_TRY_RUN([
 848 int main () {
 849   char *buf = "3.141592653";
 850   long double f = 0;
 851   sscanf (buf, "%Lg", &f);
 852   return !(f > 3.14159 && f < 3.14160);
 853 }],
 854 gdb_cv_scanf_has_long_double=yes,
 855 gdb_cv_scanf_has_long_double=no,
 856 gdb_cv_scanf_has_long_double=no)])
 857 if test $gdb_cv_scanf_has_long_double = yes; then
 858   AC_DEFINE(SCANF_HAS_LONG_DOUBLE)
 859 fi
 860 AC_MSG_RESULT($gdb_cv_scanf_has_long_double)
 861
 862 case ${host_os} in
 863 aix*)
 864   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
 865     SAVE_LDFLAGS=$LDFLAGS
 866
 867     case $GCC in
 868     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
 869     *) gdb_cv_bigtoc=-bbigtoc ;;
 870     esac
 871
 872     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
 873     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
 874     LDFLAGS="${SAVE_LDFLAGS}"
 875   ])
 876   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
 877   ;;
 878 esac
 879
 880
 881 dnl For certain native configurations, we need to check whether thread
 882 dnl support can be built in or not.
 883 dnl
 884 dnl Note that we only want this if we are both native (host == target),
 885 dnl and not doing a canadian cross build (build == host).
 886
 887 if test ${build} = ${host} -a ${host} = ${target} ; then
 888    case ${host_os} in
 889    hpux*)
 890       AC_MSG_CHECKING(for HPUX/OSF thread support)
 891       if test -f /usr/include/dce/cma_config.h ; then
 892          if test "$GCC" = "yes" ; then
 893             AC_MSG_RESULT(yes)
 894             AC_DEFINE(HAVE_HPUX_THREAD_SUPPORT)
 895             CONFIG_OBS="${CONFIG_OBS} hpux-thread.o"
 896             CONFIG_SRCS="${CONFIG_SRCS} hpux-thread.c"
 897          else
 898             AC_MSG_RESULT(no (suppressed because you are not using GCC))
 899          fi
 900       else
 901          AC_MSG_RESULT(no)
 902       fi
 903       ;;
 904    solaris*)
 905       # See if thread_db library is around for Solaris thread debugging.
 906       # Note that we must explicitly test for version 1 of the library
 907       # because version 0 (present on Solaris 2.4 or earlier) doesn't have
 908       # the same API.
 909       AC_MSG_CHECKING(for Solaris thread debugging library)
 910       if test -f /usr/lib/libthread_db.so.1 ; then
 911          AC_MSG_RESULT(yes)
 912          AC_DEFINE(HAVE_THREAD_DB_LIB)
 913          CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
 914          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
 915          AC_CHECK_LIB(dl, dlopen)
 916          if test "$GCC" = "yes" ; then
 917             # The GNU linker requires the -export-dynamic option to make
 918             # all symbols visible in the dynamic symbol table.
 919             hold_ldflags=$LDFLAGS
 920             AC_MSG_CHECKING(for the ld -export-dynamic flag)
 921             LDFLAGS="${LDFLAGS} -Wl,-export-dynamic"
 922             AC_TRY_LINK(, [int i;], found=yes, found=no)
 923             LDFLAGS=$hold_ldflags
 924             AC_MSG_RESULT($found)
 925             if test $found = yes; then
 926                CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -Wl,-export-dynamic"
 927             fi
 928          fi
 929          # Sun randomly tweaked the prototypes in <proc_service.h>
 930          # at one point.
 931          AC_MSG_CHECKING(if <proc_service.h> is old)
 932          AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
 933             AC_TRY_COMPILE([
 934                 #include <proc_service.h>
 935                 ps_err_e ps_pdwrite
 936                     (struct ps_prochandle*, psaddr_t, const void*, size_t);
 937             ],, gdb_cv_proc_service_is_old=no,
 938                 gdb_cv_proc_service_is_old=yes)
 939          ])
 940          AC_MSG_RESULT($gdb_cv_proc_service_is_old)
 941          if test $gdb_cv_proc_service_is_old = yes; then
 942             AC_DEFINE(PROC_SERVICE_IS_OLD)
 943          fi
 944       else
 945          AC_MSG_RESULT(no)
 946       fi
 947       ;;
 948    aix*)
 949       AC_MSG_CHECKING(for AiX thread debugging library)
 950       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
 951                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
 952                                    [#ifndef PTHDB_VERSION_3
 953                                     #error
 954                                     #endif],
 955                                    gdb_cv_have_aix_thread_debug=yes,
 956                                    gdb_cv_have_aix_thread_debug=no)])
 957       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
 958       if test $gdb_cv_have_aix_thread_debug = yes; then
 959          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
 960          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
 961          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -lpthdebug"
 962       fi
 963       ;;
 964    esac
 965    AC_SUBST(CONFIG_LDFLAGS)
 966 fi
 967
 968 dnl See if we have a thread_db header file that has TD_NOTALLOC.
 969 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
 970    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
 971                   gdb_cv_thread_db_h_has_td_notalloc,
 972      AC_TRY_COMPILE(
 973        [#include <thread_db.h>],
 974        [int i = TD_NOTALLOC;],
 975        gdb_cv_thread_db_h_has_td_notalloc=yes,
 976        gdb_cv_thread_db_h_has_td_notalloc=no
 977      )
 978    )
 979 fi
 980 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
 981   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
 982             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
 983 fi
 984
 985 dnl See if we have a sys/syscall header file that has __NR_tkill.
 986 if test "x$ac_cv_header_sys_syscall_h" = "xyes"; then
 987    AC_CACHE_CHECK([whether <sys/syscall.h> has __NR_tkill],
 988                   gdb_cv_sys_syscall_h_has_tkill,
 989      AC_TRY_COMPILE(
 990        [#include <sys/syscall.h>],
 991        [int i = __NR_tkill;],
 992        gdb_cv_sys_syscall_h_has_tkill=yes,
 993        gdb_cv_sys_syscall_h_has_tkill=no
 994      )
 995    )
 996 fi
 997 dnl See if we can issue tkill syscall.
 998 if test "x$gdb_cv_sys_syscall_h_has_tkill" = "xyes" && test "x$ac_cv_func_syscall" = "xyes"; then
 999   AC_DEFINE(HAVE_TKILL_SYSCALL, 1,
1000             [Define if we can use the tkill syscall.])
1001 fi
1002
1003 dnl Handle optional features that can be enabled.
1004
1005 AC_ARG_WITH(sysroot,
1006 [  --with-sysroot[=DIR] Search for usr/lib et al within DIR.],
1007 [
1008  case ${with_sysroot} in
1009  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
1010  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
1011  esac
1012
1013  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
1014
1015  if test "x$exec_prefix" = xNONE; then
1016   if test "x$prefix" = xNONE; then
1017    test_prefix=/usr/local
1018   else
1019    test_prefix=$prefix
1020   fi
1021  else
1022   test_prefix=$exec_prefix
1023  fi
1024  case ${TARGET_SYSTEM_ROOT} in
1025  "${test_prefix}"|"${test_prefix}/"*|\
1026  '${exec_prefix}'|'${exec_prefix}/'*)
1027    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
1028    TARGET_SYSTEM_ROOT_DEFINE="$t"
1029    ;;
1030  esac
1031 ], [
1032  TARGET_SYSTEM_ROOT=
1033  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"'
1034 ])
1035 AC_SUBST(TARGET_SYSTEM_ROOT)
1036 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
1037
1038 # NOTE: Don't add -Wall or -Wunused, they both include
1039 # -Wunused-parameter which reports bogus warnings.
1040 # NOTE: If you add to this list, remember to update
1041 # gdb/doc/gdbint.texinfo.
1042 build_warnings="-Wimplicit -Wreturn-type -Wcomment -Wtrigraphs \
1043 -Wformat -Wparentheses -Wpointer-arith -Wuninitialized -Wformat-nonliteral \
1044 -Wunused-label -Wunused-function"
1045 # Up for debate: -Wswitch -Wcomment -trigraphs -Wtrigraphs
1046 # -Wunused-function -Wunused-variable -Wunused-value
1047 # -Wchar-subscripts -Wtraditional -Wshadow -Wcast-qual
1048 # -Wcast-align -Wwrite-strings -Wconversion -Wstrict-prototypes
1049 # -Wmissing-prototypes -Wmissing-declarations -Wredundant-decls
1050 # -Woverloaded-virtual -Winline -Werror"
1051 AC_ARG_ENABLE(build-warnings,
1052 [  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
1053 [case "${enableval}" in
1054   yes)  ;;
1055   no)   build_warnings="-w";;
1056   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1057         build_warnings="${build_warnings} ${t}";;
1058   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1059         build_warnings="${t} ${build_warnings}";;
1060   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1061 esac
1062 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1063   echo "Setting compiler warning flags = $build_warnings" 6>&1
1064 fi])dnl
1065 AC_ARG_ENABLE(gdb-build-warnings,
1066 [  --enable-gdb-build-warnings Enable GDB specific build-time compiler warnings if gcc is used],
1067 [case "${enableval}" in
1068   yes)  ;;
1069   no)   build_warnings="-w";;
1070   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1071         build_warnings="${build_warnings} ${t}";;
1072   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1073         build_warnings="${t} ${build_warnings}";;
1074   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1075 esac
1076 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1077   echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1
1078 fi])dnl
1079 WARN_CFLAGS=""
1080 WERROR_CFLAGS=""
1081 if test "x${build_warnings}" != x -a "x$GCC" = xyes
1082 then
1083     AC_MSG_CHECKING(compiler warning flags)
1084     # Separate out the -Werror flag as some files just cannot be
1085     # compiled with it enabled.
1086     for w in ${build_warnings}; do
1087         case $w in
1088         -Werr*) WERROR_CFLAGS=-Werror ;;
1089         *) # Check that GCC accepts it
1090             saved_CFLAGS="$CFLAGS"
1091             CFLAGS="$CFLAGS $w"
1092             AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
1093             CFLAGS="$saved_CFLAGS"
1094         esac
1095     done
1096     AC_MSG_RESULT(${WARN_CFLAGS}${WERROR_CFLAGS})
1097 fi
1098 AC_SUBST(WARN_CFLAGS)
1099 AC_SUBST(WERROR_CFLAGS)
1100
1101 # In the Cygwin environment, we need some additional flags.
1102 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1103 [AC_EGREP_CPP(lose, [
1104 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1105 lose
1106 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1107
1108
1109 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1110 SER_HARDWIRE="ser-unix.o ser-pipe.o ser-tcp.o"
1111 case ${host} in
1112   *go32* ) SER_HARDWIRE=ser-go32.o ;;
1113   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
1114 esac
1115 AC_SUBST(SER_HARDWIRE)
1116
1117 # libreadline needs libuser32.a in a cygwin environment
1118 WIN32LIBS=
1119 if test x$gdb_cv_os_cygwin = xyes; then
1120     WIN32LIBS="-luser32"
1121     case "${target}" in
1122         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
1123         ;;
1124     esac
1125 fi
1126 AC_SUBST(WIN32LIBS)
1127
1128 LIBGUI="../libgui/src/libgui.a"
1129 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
1130 AC_SUBST(LIBGUI)
1131 AC_SUBST(GUI_CFLAGS_X)
1132
1133 WIN32LDAPP=
1134 AC_SUBST(WIN32LIBS)
1135 AC_SUBST(WIN32LDAPP)
1136
1137 configdir="unix"
1138
1139 GDBTKLIBS=
1140 if test "${enable_gdbtk}" = "yes"; then
1141
1142     # Gdbtk must have an absolute path to srcdir in order to run
1143     # properly when not installed.
1144     here=`pwd`
1145     cd ${srcdir}
1146     GDBTK_SRC_DIR=`pwd`
1147     cd $here
1148
1149     CY_AC_PATH_TCLCONFIG
1150     if test -z "${no_tcl}"; then
1151         CY_AC_LOAD_TCLCONFIG
1152         CY_AC_PATH_TKCONFIG
1153
1154         # now look for Tcl library stuff
1155
1156         case "${host}" in
1157         *-*-cygwin*)
1158             tcldir=../tcl/win/
1159             ;;
1160         *)
1161             tcldir=../tcl/unix/
1162             ;;
1163         esac
1164
1165         TCL_DEPS="${tcldir}${TCL_LIB_FILE}"
1166
1167         # If $no_tk is nonempty, then we can't do Tk, and there is no
1168         # point to doing Tcl.
1169         if test -z "${no_tk}"; then
1170            CY_AC_LOAD_TKCONFIG
1171            CY_AC_PATH_TCLH
1172            CY_AC_PATH_TKH
1173            CY_AC_PATH_ITCLH
1174            CY_AC_PATH_ITKH
1175
1176
1177            # now look for Tk library stuff
1178
1179            case "${host}" in
1180            *-*-cygwin*)
1181                tkdir=../tk/win/
1182                ;;
1183            *)
1184                tkdir=../tk/unix/
1185                ;;
1186            esac
1187
1188            TK_DEPS="${tkdir}${TK_LIB_FILE}"
1189
1190            # now look for Itcl library stuff
1191
1192            CY_AC_PATH_ITCLCONFIG
1193            if test -z "${no_itcl}"; then
1194              CY_AC_LOAD_ITCLCONFIG
1195
1196              ITCLLIB="${ITCL_BUILD_LIB_SPEC}"
1197              ITCL_DEPS="${ITCL_LIB_FULL_PATH}"
1198            fi
1199
1200
1201            # now look for Itk library stuff
1202            CY_AC_PATH_ITKCONFIG
1203            if test -z "${no_itcl}"; then
1204              CY_AC_LOAD_ITKCONFIG
1205
1206              ITKLIB="${ITK_BUILD_LIB_SPEC}"
1207              ITK_DEPS="${ITK_LIB_FULL_PATH}"
1208            fi
1209
1210            ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
1211            # Tcl/Tk 8.1 require -fwritable strings.  I don't
1212            # know whether 8.2 will or not, but I bet it will.
1213            # I don't have to worry about 7.x since we don't support it.
1214            GDBTK_CFLAGS=""
1215            if test "$GCC" = "yes"; then
1216                if test "$TCL_VERSION" != "8.0" ; then
1217                    GDBTK_CFLAGS="-fwritable-strings"
1218                fi
1219            fi
1220
1221            # Include some libraries that Tcl and Tk want.
1222            TCL_LIBS='$(LIBGUI) $(ITCL) $(ITK) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
1223            # Yes, the ordering seems wrong here.  But it isn't.
1224            # TK_LIBS is the list of libraries that need to be linked
1225            # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
1226            # were in LIBS then any link tests after this point would
1227            # try to include things like `$(LIBGUI)', which wouldn't work.
1228            GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
1229
1230            CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
1231            CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
1232            CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
1233            CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
1234            CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
1235            CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
1236            CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
1237
1238            if test x$gdb_cv_os_cygwin = xyes; then
1239               WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
1240               WIN32LDAPP="-Wl,--subsystem,console"
1241               CONFIG_OBS="${CONFIG_OBS} gdbres.o"
1242            fi
1243         fi
1244     fi
1245
1246     configdirs="${configdirs} gdbtk"
1247 fi
1248
1249 AC_SUBST(X_CFLAGS)
1250 AC_SUBST(X_LDFLAGS)
1251 AC_SUBST(X_LIBS)
1252 AC_SUBST(TCL_DEPS)
1253 AC_SUBST(TK_DEPS)
1254 AC_SUBST(ITCLLIB)
1255 AC_SUBST(ITCL_DEPS)
1256 AC_SUBST(ITKLIB)
1257 AC_SUBST(ITK_DEPS)
1258 AC_SUBST(GDBTKLIBS)
1259 AC_SUBST(GDBTK_CFLAGS)
1260 AC_SUBST(GDBTK_SRC_DIR)
1261
1262 AC_PATH_X
1263
1264
1265 # Unlike the sim directory, whether a simulator is linked is controlled by
1266 # presence of a SIM= and a SIM_OBS= definition in the target '.mt' file.
1267 # This code just checks for a few cases where we'd like to ignore those
1268 # definitions, even when they're present in the '.mt' file.  These cases
1269 # are when --disable-sim is specified, or if the simulator directory is
1270 # not part of the source tree.
1271 #
1272 AC_ARG_ENABLE(sim,
1273 [  --enable-sim            Link gdb with simulator],
1274 [echo "enable_sim = $enable_sim";
1275  echo "enableval = ${enableval}";
1276  case "${enableval}" in
1277   yes) ignore_sim=false ;;
1278   no)  ignore_sim=true ;;
1279   *)   ignore_sim=false ;;
1280  esac],
1281 [ignore_sim=false])
1282
1283 if test ! -d "${srcdir}/../sim"; then
1284   ignore_sim=true
1285 fi
1286
1287 if test "${ignore_sim}" = "true"; then
1288     IGNORE_SIM="SIM="
1289     IGNORE_SIM_OBS="SIM_OBS="
1290 else
1291     IGNORE_SIM=""
1292     IGNORE_SIM_OBS=""
1293     AC_DEFINE(WITH_SIM)
1294 fi
1295 AC_SUBST(IGNORE_SIM)
1296 AC_SUBST(IGNORE_SIM_OBS)
1297
1298 AC_SUBST(ENABLE_CFLAGS)
1299 AC_SUBST(PROFILE_CFLAGS)
1300
1301 AC_SUBST(CONFIG_OBS)
1302 AC_SUBST(CONFIG_DEPS)
1303 AC_SUBST(CONFIG_SRCS)
1304 AC_SUBST(CONFIG_ALL)
1305 AC_SUBST(CONFIG_CLEAN)
1306 AC_SUBST(CONFIG_INSTALL)
1307 AC_SUBST(CONFIG_UNINSTALL)
1308
1309 # target_subdir is used by the testsuite to find the target libraries.
1310 target_subdir=
1311 if test "${host}" != "${target}"; then
1312     target_subdir="${target_alias}/"
1313 fi
1314 AC_SUBST(target_subdir)
1315
1316 frags=
1317 host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
1318 if test ! -f ${host_makefile_frag}; then
1319     # When building a native debuger the .mh file containing things
1320     # like NATDEPFILES is needed.  Cross debuggers don't need .mh
1321     # since it no longer contains anything useful.
1322     if test "${target}" = "${host}"; then
1323         AC_MSG_ERROR("*** Gdb does not support native target ${host}")
1324     else
1325         host_makefile_frag=/dev/null
1326     fi
1327 fi
1328 frags="$frags $host_makefile_frag"
1329
1330 target_makefile_frag=${srcdir}/config/${gdb_target_cpu}/${gdb_target}.mt
1331 if test ! -f ${target_makefile_frag}; then
1332 AC_MSG_ERROR("*** Gdb does not support target ${target}")
1333 fi
1334 frags="$frags $target_makefile_frag"
1335
1336 AC_SUBST_FILE(host_makefile_frag)
1337 AC_SUBST_FILE(target_makefile_frag)
1338 AC_SUBST(frags)
1339
1340 changequote(,)dnl
1341 hostfile=`sed -n '
1342 s/XM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
1343 ' ${host_makefile_frag}`
1344
1345 targetfile=`sed -n '
1346 s/TM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
1347 ' ${target_makefile_frag}`
1348
1349 if test "${target}" = "${host}"; then
1350 # We pick this up from the host configuration file (.mh) because we
1351 # do not have a native configuration Makefile fragment.
1352 nativefile=`sed -n '
1353 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
1354 ' ${host_makefile_frag}`
1355 fi
1356 changequote([,])
1357
1358 if test x"${gdb_osabi}" != x ; then
1359     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
1360                        [Define to the default OS ABI for this configuration.])
1361 fi
1362
1363 # Enable multi-ice-gdb-server.
1364 AC_ARG_ENABLE(multi-ice,
1365 [  --enable-multi-ice      build the multi-ice-gdb-server],
1366   [case $enableval in
1367     yes | no)
1368       ;;
1369     *) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;;
1370   esac])
1371 if test "x$enable_multi_ice" = xyes; then
1372   configdirs="$configdirs multi-ice"
1373 fi
1374
1375 # We only build gdbserver automatically if host and target are the same.
1376 if test "x$target" = "x$host"; then
1377   AC_MSG_CHECKING(whether gdbserver is supported on this host)
1378   if test "x$build_gdbserver" = xyes; then
1379     configdirs="$configdirs gdbserver"
1380     AC_MSG_RESULT(yes)
1381   else
1382     AC_MSG_RESULT(no)
1383   fi
1384 fi
1385
1386 AC_CONFIG_SUBDIRS($configdirs)
1387
1388 # If hostfile (XM_FILE) and/or targetfile (TM_FILE) and/or nativefile
1389 # (NAT_FILE) is not set in config/*/*.m[ht] files, we link to an empty
1390 # version.
1391
1392 files=
1393 links=
1394
1395 rm -f xm.h
1396 xm_h=""
1397 if test "${hostfile}" != ""; then
1398     xm_h=xm.h
1399     GDB_XM_FILE="config/${gdb_host_cpu}/${hostfile}"
1400     files="${files} ${GDB_XM_FILE}"
1401     links="${links} xm.h"
1402     AC_DEFINE_UNQUOTED(GDB_XM_FILE, ${GDB_XM_FILE})
1403 fi
1404 AC_SUBST(xm_h)
1405
1406 rm -f tm.h
1407 tm_h=""
1408 if test "${targetfile}" != ""; then
1409     tm_h=tm.h
1410     GDB_TM_FILE="config/${gdb_target_cpu}/${targetfile}"
1411     files="${files} ${GDB_TM_FILE}"
1412     links="${links} tm.h"
1413     AC_DEFINE_UNQUOTED(GDB_TM_FILE, ${GDB_TM_FILE})
1414 fi
1415 AC_SUBST(tm_h)
1416
1417 rm -f nm.h
1418 nm_h=""
1419 if test "${nativefile}" != ""; then
1420     nm_h=nm.h
1421     GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}"
1422     files="${files} ${GDB_NM_FILE}"
1423     links="${links} nm.h"
1424     AC_DEFINE_UNQUOTED(GDB_NM_FILE, ${GDB_NM_FILE})
1425 fi
1426 AC_SUBST(nm_h)
1427
1428 AC_LINK_FILES($files, $links)
1429
1430 dnl Check for exe extension set on certain hosts (e.g. Win32)
1431 AC_EXEEXT
1432
1433 dnl  Detect the character set used by this host.
1434
1435 dnl  At the moment, we just assume it's ISO-8859-1 (which is a
1436 dnl  superset of ASCII containing the characters needed for French,
1437 dnl  German, Spanish, Italian, and possibly others), but if were
1438 dnl  *were* to support any host character sets other than ISO-8859-1,
1439 dnl  here's where we'd detect it.
1440 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "ISO-8859-1",
1441           [Define to be a string naming the default host character set.])
1442
1443 AM_ICONV
1444
1445 AC_OUTPUT(Makefile .gdbinit:gdbinit.in,
1446 [
1447 dnl Autoconf doesn't provide a mechanism for modifying definitions
1448 dnl provided by makefile fragments.
1449 dnl
1450 if test "${nativefile}" = ""; then
1451         < Makefile \
1452         sed -e '/^NATDEPFILES[[         ]]*=.*\\$/,/[[^\\]]$/s/^/# /' \
1453             -e '/^NATDEPFILES[[         ]]*=/s/^/# /' \
1454         | sed -e '/^\(NATDEPFILES[[     ]]*[[+]]=[[     ]]*\)/s//# \1/' \
1455         > Makefile.tem
1456 mv -f Makefile.tem Makefile
1457 fi
1458
1459 changequote(,)dnl
1460 sed -e '/^TM_FILE[      ]*=/s,^TM_FILE[         ]*=[    ]*,&config/'"${gdb_target_cpu}"'/,
1461 /^XM_FILE[      ]*=/s,^XM_FILE[         ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,
1462 /^NAT_FILE[     ]*=/s,^NAT_FILE[        ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,' <Makefile >Makefile.tmp
1463 mv -f Makefile.tmp Makefile
1464 changequote([,])dnl
1465
1466
1467 case x$CONFIG_HEADERS in
1468 xconfig.h:config.in)
1469 echo > stamp-h ;;
1470 esac
1471 ],
1472 [
1473 gdb_host_cpu=$gdb_host_cpu
1474 gdb_target_cpu=$gdb_target_cpu
1475 nativefile=$nativefile
1476 ])
1477
1478 exit 0