gdb/configure.in

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004
   3 dnl Free Software Foundation, Inc.
   4 dnl
   5 dnl This file is part of GDB.
   6 dnl
   7 dnl This program is free software; you can redistribute it and/or modify
   8 dnl it under the terms of the GNU General Public License as published by
   9 dnl the Free Software Foundation; either version 2 of the License, or
  10 dnl (at your option) any later version.
  11 dnl
  12 dnl This program is distributed in the hope that it will be useful,
  13 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 dnl GNU General Public License for more details.
  16 dnl
  17 dnl You should have received a copy of the GNU General Public License
  18 dnl along with this program; if not, write to the Free Software
  19 dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  20
  21 dnl Process this file with autoconf to produce a configure script.
  22
  23 AC_PREREQ(2.13)dnl
  24 AC_INIT(main.c)
  25 AC_CONFIG_HEADER(config.h:config.in)
  26 AM_MAINTAINER_MODE
  27
  28 AC_PROG_CC
  29 AC_GNU_SOURCE
  30 AC_AIX
  31 AC_ISC_POSIX
  32 AM_PROG_CC_STDC
  33
  34 AC_CONFIG_AUX_DIR(`cd $srcdir;pwd`/..)
  35 AC_CANONICAL_SYSTEM
  36
  37 # FIXME: kettenis/20030102: The AC_PROG_RANLIB from Autoconf 2.13
  38 # doesn't support cross-compilation, but the one from Autoconf 2.5x
  39 # does.  Override RANLIB here (i.e. before running AC_PROG_RANLIB) to
  40 # deal with the lossage.  Note that CY_GNU_GETTEXT currently calls
  41 # AC_PROG_RANLIB.  This can be removed when we switch to Autoconf
  42 # 2.5x.
  43 AC_CHECK_TOOL(RANLIB, ranlib, :)
  44
  45 dnl Set up for gettext.  PACKAGE is used when we call bindtextdomain.
  46 ALL_LINGUAS=
  47 CY_GNU_GETTEXT
  48 AC_DEFINE(PACKAGE, "gdb", [Name of this package. ])
  49
  50 debugdir=${libdir}/debug
  51
  52 AC_ARG_WITH(separate-debug-dir,
  53 [  --with-separate-debug-dir=path   Look for global separate debug info in this path [LIBDIR/debug]],
  54 [debugdir="${withval}"])
  55
  56 AC_DEFINE_DIR(DEBUGDIR, debugdir,
  57               [Global directory for separate debug files. ])
  58 #AC_DEFINE_UNQUOTED(DEBUGDIR, "$debugdir"),
  59
  60 dnl List of object files added by configure.
  61
  62 CONFIG_OBS=
  63 CONFIG_DEPS=
  64 CONFIG_SRCS=
  65 ENABLE_CFLAGS=
  66 CONFIG_ALL=
  67 CONFIG_CLEAN=
  68 CONFIG_INSTALL=
  69 CONFIG_UNINSTALL=
  70
  71 AC_CONFIG_SUBDIRS(doc testsuite)
  72 configdirs=
  73
  74 . $srcdir/configure.host
  75
  76 . $srcdir/configure.tgt
  77
  78 # Fetch the default architecture and default target vector from BFD.
  79 targ=$target; . $srcdir/../bfd/config.bfd
  80
  81 # We only want the first architecture, so strip off the others if
  82 # there is more than one.
  83 targ_archs=`echo $targ_archs | sed 's/ .*//'`
  84
  85 if test "x$targ_archs" != x; then
  86   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
  87     [Define to BFD's default architecture. ])
  88 fi
  89 if test "x$targ_defvec" != x; then
  90   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
  91     [Define to BFD's default target vector. ])
  92 fi
  93
  94 AC_ARG_PROGRAM
  95
  96 # The CLI cannot be disabled yet, but may be in the future.
  97
  98 # Enable CLI.
  99 AC_ARG_ENABLE(gdbcli,
 100 [  --disable-gdbcli        disable command-line interface (CLI)],
 101   [case $enableval in
 102     yes)
 103       ;;
 104     no)
 105       AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;;
 106     *)
 107       AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;;
 108   esac],
 109   [enable_gdbcli=yes])
 110 if test x"$enable_gdbcli" = xyes; then
 111   if test -d $srcdir/cli; then
 112     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)"
 113     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)"
 114     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)"
 115     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)"
 116   fi
 117 fi
 118
 119 # Enable MI.
 120 AC_ARG_ENABLE(gdbmi,
 121 [  --disable-gdbmi         disable machine-interface (MI)],
 122   [case $enableval in
 123     yes | no)
 124       ;;
 125     *)
 126       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 127   esac],
 128   [enable_gdbmi=yes])
 129 if test x"$enable_gdbmi" = xyes; then
 130   if test -d $srcdir/mi; then
 131     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 132     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 133     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 134     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 135   fi
 136 fi
 137
 138 # Enable TUI.
 139 AC_ARG_ENABLE(tui,
 140 [  --enable-tui            enable full-screen terminal user interface (TUI)],
 141   [case $enableval in
 142     yes | no)
 143       ;;
 144     *)
 145       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 146   esac])
 147 if test x"$enable_tui" = xyes; then
 148   if test -d $srcdir/tui; then
 149     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
 150     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
 151     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
 152     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
 153     need_curses=yes
 154   fi
 155 fi
 156
 157 # Enable gdbtk.
 158 AC_ARG_ENABLE(gdbtk,
 159 [  --enable-gdbtk          enable gdbtk graphical user interface (GUI)],
 160   [case $enableval in
 161     yes | no)
 162       ;;
 163     *)
 164       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 165   esac],
 166   [if test -d $srcdir/gdbtk; then
 167     enable_gdbtk=yes
 168   else
 169     enable_gdbtk=no
 170   fi])
 171 # We unconditionally disable gdbtk tests on selected platforms.
 172 case $host_os in
 173   go32* | windows*)
 174     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 175     enable_gdbtk=no ;;
 176 esac
 177
 178 # Libunwind support.
 179 AC_ARG_WITH(libunwind,
 180 [  --with-libunwind            Use libunwind frame unwinding support],
 181 [case "${withval}" in
 182   yes)  enable_libunwind=yes ;;
 183   no)   enable_libunwind=no ;;
 184   *)    AC_MSG_ERROR(bad value ${withval} for GDB with-libunwind option) ;;
 185 esac],[
 186   AC_CHECK_HEADERS(libunwind.h)
 187   AC_CHECK_HEADERS(libunwind-ia64.h)
 188   if test x"$ac_cv_header_libunwind_h" = xyes -a x"$ac_cv_header_libunwind_ia64_h" = xyes; then
 189     enable_libunwind=yes;
 190   fi
 191 ])
 192
 193 if test x"$enable_libunwind" = xyes; then
 194   AC_CHECK_HEADERS(libunwind.h)
 195   AC_CHECK_HEADERS(libunwind-ia64.h)
 196   AC_DEFINE(HAVE_LIBUNWIND, 1)
 197   CONFIG_OBS="$CONFIG_OBS libunwind-frame.o"
 198   CONFIG_DEPS="$CONFIG_DEPS libunwind-frame.o"
 199   CONFIG_SRCS="$CONFIG_SRCS libunwind-frame.c"
 200 fi
 201
 202 # Profiling support.
 203 AC_ARG_ENABLE(profiling,
 204 [  --enable-profiling      enable profiling of GDB],
 205   [case $enableval in
 206     yes | no)
 207       ;;
 208     *)
 209       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 210   esac],
 211  [enable_profiling=no])
 212
 213 AC_CHECK_FUNCS(monstartup _mcleanup)
 214 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 215 [AC_TRY_LINK(
 216 [#include <stdlib.h>
 217 extern char _etext;
 218 ],
 219 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 220 if test $ac_cv_var__etext = yes; then
 221   AC_DEFINE(HAVE__ETEXT, 1,
 222             [Define to 1 if your system has the _etext variable. ])
 223 fi
 224 if test "$enable_profiling" = yes ; then
 225   if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
 226     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 227   fi
 228   PROFILE_CFLAGS=-pg
 229   OLD_CFLAGS="$CFLAGS"
 230   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 231
 232   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 233     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 234      ac_cv_cc_supports_pg=no)])
 235
 236   if test $ac_cv_cc_supports_pg = no; then
 237     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 238   fi
 239
 240   CFLAGS="$OLD_CFLAGS"
 241 fi
 242
 243 # --------------------- #
 244 # Checks for programs.  #
 245 # --------------------- #
 246
 247 AC_PROG_AWK
 248 AC_PROG_INSTALL
 249 AC_PROG_LN_S
 250 AC_PROG_RANLIB
 251 AC_PROG_YACC
 252
 253 AC_CHECK_TOOL(AR, ar)
 254 AC_CHECK_TOOL(DLLTOOL, dlltool)
 255 AC_CHECK_TOOL(WINDRES, windres)
 256
 257 # Needed for GNU/Hurd.
 258 AC_CHECK_TOOL(MIG, mig)
 259
 260 # ---------------------- #
 261 # Checks for libraries.  #
 262 # ---------------------- #
 263
 264 # We might need to link with -lm; most simulators need it.
 265 AC_CHECK_LIB(m, main)
 266
 267 # We need to link with -lw to get `wctype' on Solaris before Solaris
 268 # 2.6.  Solaris 2.6 and beyond have this function in libc, and have a
 269 # libw that some versions of the GNU linker cannot hanle (GNU ld 2.9.1
 270 # is known to have this problem).  Therefore we avoid libw if we can.
 271 AC_CHECK_FUNC(wctype, [],
 272   [AC_CHECK_LIB(w, wctype)])
 273
 274 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 275 AC_SEARCH_LIBS(gethostbyname, nsl)
 276
 277 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 278 AC_SEARCH_LIBS(socketpair, socket)
 279
 280 # Since GDB uses Readline, we need termcap functionality, so we need
 281 # to find a library that provides that.  When GDB is configured with
 282 # --enable-tui, we need full curses functionality.
 283 #
 284 # FIXME: kettenis/20030102: We seem to prefer HP curses (Hcurses) over
 285 # Xcurses on HP-UX; see the `-D__HP_CURSES' in the relevant host
 286 # Makefile fragments.  That's why we need to have `Hcurses' before
 287 # `curses'.  I don't see why we should use HP curses if a more
 288 # standard curses is available, except that according to HP's
 289 # documentation one needs to compile `-D_XOPEN_SOURCE_EXTENDED' on
 290 # HP-UX 10.10 and 10.20.
 291
 292 if test "$need_curses" = yes; then
 293   AC_SEARCH_LIBS(initscr, [ncurses Hcurses curses], [],
 294     [AC_MSG_ERROR([no curses library found])])
 295 fi
 296
 297 case $host_os in
 298   cygwin*)
 299     if test -d $srcdir/libtermcap; then
 300       LIBS="../libtermcap/libtermcap.a $LIBS"
 301       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 302     fi ;;
 303   go32* | *djgpp*)
 304     ac_cv_search_tgetent="none required"
 305     ;;
 306   aix*)
 307     # Readline prefers curses over termcap on AIX.
 308     # ??? Why?
 309     AC_SEARCH_LIBS(tgetent, [tinfo ncurses curses termcap])
 310     ;;
 311 esac
 312
 313 # Note: We used to check for libtermlib and libterminfo too, but
 314 # Readline doesn't, so I think we're safe with leaving them out.
 315 AC_SEARCH_LIBS(tgetent, [termcap tinfo ncurses Hcurses curses])
 316
 317 if test "$ac_cv_search_tgetent" = no; then
 318   AC_MSG_ERROR([no termcap library found])
 319 fi
 320
 321 # ------------------------- #
 322 # Checks for header files.  #
 323 # ------------------------- #
 324
 325 AC_HEADER_DIRENT
 326 AC_HEADER_STAT
 327 AC_HEADER_STDC
 328 AC_CHECK_HEADERS(link.h)
 329 AC_CHECK_HEADERS(machine/reg.h)
 330 AC_CHECK_HEADERS(nlist.h)
 331 AC_CHECK_HEADERS(poll.h sys/poll.h)
 332 AC_CHECK_HEADERS(proc_service.h thread_db.h)
 333 AC_CHECK_HEADERS(stddef.h)
 334 AC_CHECK_HEADERS(stdlib.h)
 335 AC_CHECK_HEADERS(stdint.h)
 336 AC_CHECK_HEADERS(string.h memory.h strings.h)
 337 AC_CHECK_HEADERS(sys/fault.h)
 338 AC_CHECK_HEADERS(sys/file.h)
 339 AC_CHECK_HEADERS(sys/filio.h)
 340 AC_CHECK_HEADERS(sys/ioctl.h)
 341 AC_CHECK_HEADERS(sys/param.h)
 342 AC_CHECK_HEADERS(sys/proc.h)
 343 AC_CHECK_HEADERS(sys/procfs.h)
 344 AC_CHECK_HEADERS(sys/ptrace.h ptrace.h)
 345 AC_CHECK_HEADERS(sys/reg.h sys/debugreg.h)
 346 AC_CHECK_HEADERS(sys/select.h)
 347 AC_CHECK_HEADERS(sys/syscall.h)
 348 AC_CHECK_HEADERS(sys/user.h)
 349 AC_CHECK_HEADERS(sys/wait.h wait.h)
 350 AC_CHECK_HEADERS(termios.h termio.h sgtty.h)
 351 AC_CHECK_HEADERS(unistd.h)
 352
 353 # On Solaris 2.[78], we need to define _MSE_INT_H to avoid a clash
 354 # between <widec.h> and <wchar.h> that would cause AC_CHECK_HEADERS to
 355 # think that we don't have <curses.h> if we're using GCC.
 356 case $host_os in
 357   solaris2.[[78]])
 358     if test "$GCC" = yes; then
 359       AC_DEFINE(_MSE_INT_H, 1,
 360         [[Define to 1 to avoid a clash between <widec.h> and <wchar.h> on
 361    Solaris 2.[78] when using GCC. ]])
 362     fi ;;
 363 esac
 364 AC_CHECK_HEADERS(curses.h ncurses.h term.h)
 365
 366 # FIXME: kettenis/20030102: In most cases we include these
 367 # unconditionally, so what's the point in checking these?
 368 AC_CHECK_HEADERS(ctype.h time.h)
 369
 370 dnl Check for struct stat with an st_blocks member
 371 AC_MSG_CHECKING(for member st_blocks in struct stat)
 372 AC_CACHE_VAL(gdb_cv_have_struct_stat_with_st_blocks_member,
 373   [AC_TRY_COMPILE([#include <sys/types.h>
 374 #include <sys/stat.h>],
 375                   [struct stat st; (void) st.st_blocks;],
 376                   gdb_cv_have_struct_stat_with_st_blocks_member=yes,
 377                   gdb_cv_have_struct_stat_with_st_blocks_member=no)])
 378 AC_MSG_RESULT($gdb_cv_have_struct_stat_with_st_blocks_member)
 379 if test $gdb_cv_have_struct_stat_with_st_blocks_member = yes; then
 380   AC_DEFINE(HAVE_STRUCT_STAT_ST_BLOCKS)
 381 fi
 382 # ------------------------- #
 383 # Checks for declarations.  #
 384 # ------------------------- #
 385
 386 gcc_AC_CHECK_DECLS(getopt)
 387
 388 # ------------------ #
 389 # Checks for types.  #
 390 # ------------------ #
 391
 392 AC_TYPE_SIGNAL
 393
 394 # ------------------------------------- #
 395 # Checks for compiler characteristics.  #
 396 # ------------------------------------- #
 397
 398 AC_C_CONST
 399 AC_C_INLINE
 400
 401 # ------------------------------ #
 402 # Checks for library functions.  #
 403 # ------------------------------ #
 404
 405 AC_FUNC_ALLOCA
 406 AC_FUNC_MMAP
 407 AC_FUNC_VFORK
 408 AC_CHECK_FUNCS(canonicalize_file_name realpath)
 409 AC_CHECK_FUNCS(poll)
 410 AC_CHECK_FUNCS(pread64)
 411 AC_CHECK_FUNCS(sbrk)
 412 AC_CHECK_FUNCS(setpgid setpgrp)
 413 AC_CHECK_FUNCS(sigaction sigprocmask sigsetmask)
 414 AC_CHECK_FUNCS(socketpair)
 415 AC_CHECK_FUNCS(syscall)
 416
 417 dnl AC_FUNC_SETPGRP does not work when cross compiling
 418 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
 419 if test "$cross_compiling" = no; then
 420   AC_FUNC_SETPGRP
 421 else
 422   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
 423     [AC_TRY_COMPILE([
 424 #include <unistd.h>
 425 ], [
 426   if (setpgrp(1,1) == -1)
 427     exit (0);
 428   else
 429     exit (1);
 430 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
 431 if test $ac_cv_func_setpgrp_void = yes; then
 432   AC_DEFINE(SETPGRP_VOID, 1)
 433 fi
 434 fi
 435
 436 # Check if sigsetjmp is available.  Using AC_CHECK_FUNCS won't do
 437 # since sigsetjmp might only be defined as a macro.
 438 AC_CACHE_CHECK([for sigsetjmp], gdb_cv_func_sigsetjmp,
 439 [AC_TRY_COMPILE([
 440 #include <setjmp.h>
 441 ], [sigjmp_buf env; while (! sigsetjmp (env, 1)) siglongjmp (env, 1);],
 442 gdb_cv_func_sigsetjmp=yes, gdb_cv_func_sigsetjmp=no)])
 443 if test $gdb_cv_func_sigsetjmp = yes; then
 444   AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available. ])
 445 fi
 446
 447 # Assume we'll default to using the included libiberty regex.
 448 gdb_use_included_regex=yes
 449
 450 # However, if the system regex is GNU regex, then default to *not*
 451 # using the included regex.
 452 AC_CACHE_CHECK(
 453   [for GNU regex],
 454   [gdb_cv_have_gnu_regex],
 455   [AC_TRY_COMPILE(
 456     [#include <gnu-versions.h>],
 457     [#define REGEX_INTERFACE_VERSION 1
 458 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
 459 # error "Version mismatch"
 460 #endif],
 461     gdb_cv_have_gnu_regex=yes,
 462     gdb_cv_have_gnu_regex=no)])
 463 if test $gdb_cv_have_gnu_regex = yes; then
 464   gdb_use_included_regex=no
 465 fi
 466
 467 AC_ARG_WITH(included-regex,
 468   [  --without-included-regex don't use included regex; this is the default
 469                           on systems with version 2 of the GNU C library
 470                           (use with caution on other system)],
 471   gdb_with_regex=$withval,
 472   gdb_with_regex=$gdb_use_included_regex)
 473 if test "$gdb_with_regex" = yes; then
 474   AC_DEFINE(USE_INCLUDED_REGEX, 1,
 475     [Define to 1 if the regex included in libiberty should be used.])
 476 fi
 477
 478 # See if <machine/reg.h> degines `struct reg'.
 479 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
 480 [AC_TRY_COMPILE([#include <sys/types.h>
 481 #include <machine/reg.h>], [struct reg r;],
 482 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
 483 if test $gdb_cv_struct_reg = yes; then
 484   AC_DEFINE(HAVE_STRUCT_REG, 1,
 485             [Define to 1 if your system has struct reg in <machine/reg.h>.])
 486 fi
 487
 488 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
 489 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
 490 AC_CACHE_CHECK([for r_fs in struct reg], gdb_cv_struct_reg_r_fs,
 491 [AC_TRY_COMPILE([#include <machine/reg.h>], [struct reg r; r.r_fs;],
 492 gdb_cv_struct_reg_r_fs=yes, gdb_cv_struct_reg_r_fs=no)])
 493 if test $gdb_cv_struct_reg_r_fs = yes; then
 494   AC_DEFINE(HAVE_STRUCT_REG_R_FS)
 495 fi
 496 AC_CACHE_CHECK([for r_gs in struct reg], gdb_cv_struct_reg_r_gs,
 497 [AC_TRY_COMPILE([#include <machine/reg.h>], [struct reg r; r.r_gs;],
 498 gdb_cv_struct_reg_r_gs=yes, gdb_cv_struct_reg_r_gs=no)])
 499 if test $gdb_cv_struct_reg_r_gs = yes; then
 500   AC_DEFINE(HAVE_STRUCT_REG_R_GS)
 501 fi
 502
 503 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
 504 AC_MSG_CHECKING(for PTRACE_GETREGS)
 505 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
 506 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 507                 [PTRACE_GETREGS;],
 508                 [gdb_cv_have_ptrace_getregs=yes],
 509                 [gdb_cv_have_ptrace_getregs=no])])
 510 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
 511 if test $gdb_cv_have_ptrace_getregs = yes; then
 512   AC_DEFINE(HAVE_PTRACE_GETREGS)
 513 fi
 514
 515 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
 516 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
 517 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
 518 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 519                 [PTRACE_GETFPXREGS;],
 520                 [gdb_cv_have_ptrace_getfpxregs=yes],
 521                 [gdb_cv_have_ptrace_getfpxregs=no])])
 522 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
 523 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
 524   AC_DEFINE(HAVE_PTRACE_GETFPXREGS)
 525 fi
 526
 527 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
 528 AC_MSG_CHECKING(for PT_GETDBREGS)
 529 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
 530 [AC_TRY_COMPILE([#include <sys/types.h>
 531 #include <sys/ptrace.h>],
 532                 [PT_GETDBREGS;],
 533                 [gdb_cv_have_pt_getdbregs=yes],
 534                 [gdb_cv_have_pt_getdbregs=no])])
 535 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
 536 if test $gdb_cv_have_pt_getdbregs = yes; then
 537   AC_DEFINE(HAVE_PT_GETDBREGS)
 538 fi
 539
 540 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
 541 AC_MSG_CHECKING(for PT_GETXMMREGS)
 542 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
 543 [AC_TRY_COMPILE([#include <sys/types.h>
 544 #include <sys/ptrace.h>],
 545                 [PT_GETXMMREGS;],
 546                 [gdb_cv_have_pt_getxmmregs=yes],
 547                 [gdb_cv_have_pt_getxmmregs=no])])
 548 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
 549 if test $gdb_cv_have_pt_getxmmregs = yes; then
 550   AC_DEFINE(HAVE_PT_GETXMMREGS)
 551 fi
 552
 553 # See if stdint.h provides the uintptr_t type.
 554 # Autoconf 2.5X has an improved AC_CHECK_TYPE which will simplify this.
 555 AC_CACHE_CHECK([for uintptr_t in stdint.h], gdb_cv_have_uintptr_t,
 556   [AC_TRY_COMPILE(
 557     [#include <stdint.h>],
 558     [uintptr_t foo = 0;],
 559     gdb_cv_have_uintptr_t=yes,
 560     gdb_cv_have_uintptr_t=no)])
 561 if test $gdb_cv_have_uintptr_t = yes; then
 562   AC_DEFINE(HAVE_UINTPTR_T, 1, [Define if <stdint.h> provides the uintptr_t type.])
 563 fi
 564
 565 BFD_NEED_DECLARATION(malloc)
 566 BFD_NEED_DECLARATION(realloc)
 567 BFD_NEED_DECLARATION(free)
 568 BFD_NEED_DECLARATION(strerror)
 569 BFD_NEED_DECLARATION(strdup)
 570 BFD_NEED_DECLARATION(strstr)
 571 BFD_NEED_DECLARATION(canonicalize_file_name)
 572
 573 # The following save_state_t checkery is only necessary for HPUX
 574 # versions earlier than 10.20.  When those fade from memory, this
 575 # could be expunged. --jsm 1999-03-22
 576
 577 AC_MSG_CHECKING(for HPUX save_state structure)
 578 AC_EGREP_HEADER(save_state_t, machine/save_state.h,
 579                 gdb_cv_hpux_savestate=yes, gdb_cv_hpux_savestate=no)
 580 AC_EGREP_HEADER(ss_wide, machine/save_state.h, gdb_cv_hpux_sswide=yes,
 581                 gdb_cv_hpux_sswide=no)
 582 if test $gdb_cv_hpux_savestate = yes
 583 then
 584   AC_DEFINE(HAVE_STRUCT_SAVE_STATE_T, 1)
 585 fi
 586 if test $gdb_cv_hpux_sswide = yes
 587 then
 588   AC_DEFINE(HAVE_STRUCT_MEMBER_SS_WIDE, 1)
 589 fi
 590 AC_MSG_RESULT($gdb_cv_hpux_sswide)
 591
 592
 593 # If we are configured native on GNU/Linux, work around problems with
 594 # sys/procfs.h
 595 # Also detect which type of /proc is in use, such as for Unixware or Solaris.
 596
 597 if test "${target}" = "${host}"; then
 598   case "${host}" in
 599   i[[3456]]86-*-linux*)
 600         AC_DEFINE(START_INFERIOR_TRAPS_EXPECTED,2)
 601         AC_DEFINE(sys_quotactl)
 602         ;;
 603   ia64-*-aix*)
 604       AC_DEFINE(NEW_PROC_API)
 605       ;;
 606   *-*-unixware* | *-*-sysv4.2* | *-*-sysv5* | *-*-interix* )
 607       AC_DEFINE(NEW_PROC_API)
 608       ;;
 609   *-*-solaris2.[[6789]])
 610       AC_DEFINE(NEW_PROC_API)
 611       ;;
 612   esac
 613 fi
 614
 615 if test "$ac_cv_header_sys_procfs_h" = yes; then
 616   BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
 617   BFD_HAVE_SYS_PROCFS_TYPE(prrun_t)
 618   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
 619   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
 620   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
 621   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
 622   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
 623   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset32_t)
 624   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
 625   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
 626   BFD_HAVE_SYS_PROCFS_TYPE(prsysent_t)
 627   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigset_t)
 628   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigaction64_t)
 629   BFD_HAVE_SYS_PROCFS_TYPE(pr_siginfo64_t)
 630
 631
 632   dnl Check for broken prfpregset_t type
 633
 634   dnl For Linux/i386, glibc 2.1.3 was released with a bogus
 635   dnl prfpregset_t type (it's a typedef for the pointer to a struct
 636   dnl instead of the struct itself).  We detect this here, and work
 637   dnl around it in gdb_proc_service.h.
 638
 639   if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
 640     AC_MSG_CHECKING(whether prfpregset_t type is broken)
 641     AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
 642       [AC_TRY_RUN([#include <sys/procfs.h>
 643        int main ()
 644        {
 645          if (sizeof (prfpregset_t) == sizeof (void *))
 646            return 1;
 647          return 0;
 648        }],
 649        gdb_cv_prfpregset_t_broken=no,
 650        gdb_cv_prfpregset_t_broken=yes,
 651        gdb_cv_prfpregset_t_broken=yes)])
 652     AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
 653     if test $gdb_cv_prfpregset_t_broken = yes; then
 654       AC_DEFINE(PRFPREGSET_T_BROKEN)
 655     fi
 656   fi
 657
 658   dnl Check for PIOCSET ioctl entry
 659
 660   AC_MSG_CHECKING(for PIOCSET ioctl entry in sys/procfs.h)
 661   AC_CACHE_VAL(gdb_cv_have_procfs_piocset,
 662   [AC_TRY_COMPILE([#include <unistd.h>
 663 #include <sys/types.h>
 664 #include <sys/procfs.h>
 665 ], [
 666     int dummy;;
 667     dummy = ioctl(0, PIOCSET, &dummy);
 668   ],
 669   gdb_cv_have_procfs_piocset=yes, gdb_cv_have_procfs_piocset=no)])
 670   AC_MSG_RESULT($gdb_cv_have_procfs_piocset)
 671   if test $gdb_cv_have_procfs_piocset = yes; then
 672     AC_DEFINE(HAVE_PROCFS_PIOCSET)
 673   fi
 674 fi
 675
 676 dnl For native ports (host == target), check to see what kind of
 677 dnl legacy link.h support is needed.  (See solib-legacy.c.)
 678 if test ${host} = ${target} ; then
 679   dnl Check for struct link_map with l_ members which are indicative
 680   dnl of SVR4-like shared libraries
 681
 682   AC_MSG_CHECKING(for member l_addr in struct link_map)
 683   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_l_members,
 684     [AC_TRY_COMPILE([#include <link.h>],
 685                     [struct link_map lm; (void) lm.l_addr;],
 686                     gdb_cv_have_struct_link_map_with_l_members=yes,
 687                     gdb_cv_have_struct_link_map_with_l_members=no)])
 688   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_l_members)
 689   if test $gdb_cv_have_struct_link_map_with_l_members = yes; then
 690     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_L_MEMBERS)
 691   fi
 692
 693   dnl Check for struct link_map with lm_ members which are indicative
 694   dnl of SunOS-like shared libraries
 695
 696   AC_MSG_CHECKING(for member lm_addr in struct link_map)
 697   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_lm_members,
 698     [AC_TRY_COMPILE([#include <sys/types.h>
 699 #include <link.h>],
 700                     [struct link_map lm; (void) lm.lm_addr;],
 701                     gdb_cv_have_struct_link_map_with_lm_members=yes,
 702                     gdb_cv_have_struct_link_map_with_lm_members=no)])
 703   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_lm_members)
 704   if test $gdb_cv_have_struct_link_map_with_lm_members = yes; then
 705     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_LM_MEMBERS)
 706   fi
 707
 708   dnl Check for struct so_map with som_ members which are found on
 709   dnl some *BSD systems.
 710
 711   AC_MSG_CHECKING(for member som_addr in struct so_map)
 712   AC_CACHE_VAL(gdb_cv_have_struct_so_map_with_som_members,
 713     [AC_TRY_COMPILE([#include <sys/types.h>
 714 #ifdef HAVE_NLIST_H
 715 #include <nlist.h>
 716 #endif
 717 #include <link.h>],
 718                     [struct so_map lm; (void) lm.som_addr;],
 719                     gdb_cv_have_struct_so_map_with_som_members=yes,
 720                     gdb_cv_have_struct_so_map_with_som_members=no)])
 721   AC_MSG_RESULT($gdb_cv_have_struct_so_map_with_som_members)
 722   if test $gdb_cv_have_struct_so_map_with_som_members = yes; then
 723     AC_DEFINE(HAVE_STRUCT_SO_MAP_WITH_SOM_MEMBERS)
 724   fi
 725
 726   dnl Check for struct link_map32 type, which allows a 64-bit Solaris
 727   dnl debugger to debug a 32-bit Solaris app with 32-bit shared libraries.
 728
 729   AC_MSG_CHECKING(for struct link_map32 in sys/link.h)
 730   AC_CACHE_VAL(gdb_cv_have_struct_link_map32,
 731     [AC_TRY_COMPILE([#define _SYSCALL32
 732 #include <sys/link.h>], [struct link_map32 l;],
 733      gdb_cv_have_struct_link_map32=yes,
 734      gdb_cv_have_struct_link_map32=no)])
 735   AC_MSG_RESULT($gdb_cv_have_struct_link_map32)
 736   if test $gdb_cv_have_struct_link_map32 = yes; then
 737     AC_DEFINE(HAVE_STRUCT_LINK_MAP32)
 738     AC_DEFINE(_SYSCALL32)
 739   fi
 740 fi
 741
 742 dnl See if compiler supports "long long" type.
 743
 744 AC_MSG_CHECKING(for long long support in compiler)
 745 AC_CACHE_VAL(gdb_cv_c_long_long,
 746 [AC_TRY_COMPILE(, [
 747   extern long long foo;
 748   switch (foo & 2) { case 0: return 1; }
 749 ],
 750 gdb_cv_c_long_long=yes, gdb_cv_c_long_long=no)])
 751 AC_MSG_RESULT($gdb_cv_c_long_long)
 752 if test $gdb_cv_c_long_long = yes; then
 753   AC_DEFINE(CC_HAS_LONG_LONG)
 754 fi
 755
 756 dnl See if the compiler and runtime support printing long long
 757
 758 AC_MSG_CHECKING(for long long support in printf)
 759 AC_CACHE_VAL(gdb_cv_printf_has_long_long,
 760 [AC_TRY_RUN([
 761 int main () {
 762   char buf[32];
 763   long long l = 0;
 764   l = (l << 16) + 0x0123;
 765   l = (l << 16) + 0x4567;
 766   l = (l << 16) + 0x89ab;
 767   l = (l << 16) + 0xcdef;
 768   sprintf (buf, "0x%016llx", l);
 769   return (strcmp ("0x0123456789abcdef", buf));
 770 }],
 771 gdb_cv_printf_has_long_long=yes,
 772 gdb_cv_printf_has_long_long=no,
 773 gdb_cv_printf_has_long_long=no)])
 774 if test $gdb_cv_printf_has_long_long = yes; then
 775   AC_DEFINE(PRINTF_HAS_LONG_LONG)
 776 fi
 777 AC_MSG_RESULT($gdb_cv_printf_has_long_long)
 778
 779 dnl See if compiler supports "long double" type.  Can't use AC_C_LONG_DOUBLE
 780 dnl because autoconf complains about cross-compilation issues.  However, this
 781 dnl code uses the same variables as the macro for compatibility.
 782
 783 AC_MSG_CHECKING(for long double support in compiler)
 784 AC_CACHE_VAL(ac_cv_c_long_double,
 785 [AC_TRY_COMPILE(, [long double foo;],
 786 ac_cv_c_long_double=yes, ac_cv_c_long_double=no)])
 787 AC_MSG_RESULT($ac_cv_c_long_double)
 788 if test $ac_cv_c_long_double = yes; then
 789   AC_DEFINE(HAVE_LONG_DOUBLE)
 790 fi
 791
 792 dnl See if the compiler and runtime support printing long doubles
 793
 794 AC_MSG_CHECKING(for long double support in printf)
 795 AC_CACHE_VAL(gdb_cv_printf_has_long_double,
 796 [AC_TRY_RUN([
 797 int main () {
 798   char buf[16];
 799   long double f = 3.141592653;
 800   sprintf (buf, "%Lg", f);
 801   return (strncmp ("3.14159", buf, 7));
 802 }],
 803 gdb_cv_printf_has_long_double=yes,
 804 gdb_cv_printf_has_long_double=no,
 805 gdb_cv_printf_has_long_double=no)])
 806 if test $gdb_cv_printf_has_long_double = yes; then
 807   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE)
 808 fi
 809 AC_MSG_RESULT($gdb_cv_printf_has_long_double)
 810
 811 dnl See if the compiler and runtime support scanning long doubles
 812
 813 AC_MSG_CHECKING(for long double support in scanf)
 814 AC_CACHE_VAL(gdb_cv_scanf_has_long_double,
 815 [AC_TRY_RUN([
 816 int main () {
 817   char *buf = "3.141592653";
 818   long double f = 0;
 819   sscanf (buf, "%Lg", &f);
 820   return !(f > 3.14159 && f < 3.14160);
 821 }],
 822 gdb_cv_scanf_has_long_double=yes,
 823 gdb_cv_scanf_has_long_double=no,
 824 gdb_cv_scanf_has_long_double=no)])
 825 if test $gdb_cv_scanf_has_long_double = yes; then
 826   AC_DEFINE(SCANF_HAS_LONG_DOUBLE)
 827 fi
 828 AC_MSG_RESULT($gdb_cv_scanf_has_long_double)
 829
 830 case ${host_os} in
 831 aix*)
 832   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
 833     SAVE_LDFLAGS=$LDFLAGS
 834
 835     case $GCC in
 836     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
 837     *) gdb_cv_bigtoc=-bbigtoc ;;
 838     esac
 839
 840     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
 841     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
 842   ])
 843   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
 844   ;;
 845 esac
 846
 847
 848 dnl For certain native configurations, we need to check whether thread
 849 dnl support can be built in or not.
 850 dnl
 851 dnl Note that we only want this if we are both native (host == target),
 852 dnl and not doing a canadian cross build (build == host).
 853
 854 if test ${build} = ${host} -a ${host} = ${target} ; then
 855    case ${host_os} in
 856    hpux*)
 857       AC_MSG_CHECKING(for HPUX/OSF thread support)
 858       if test -f /usr/include/dce/cma_config.h ; then
 859          if test "$GCC" = "yes" ; then
 860             AC_MSG_RESULT(yes)
 861             AC_DEFINE(HAVE_HPUX_THREAD_SUPPORT)
 862             CONFIG_LIB_OBS="${CONFIG_LIB_OBS} hpux-thread.o"
 863             CONFIG_SRCS="${CONFIG_SRCS} hpux-thread.c"
 864          else
 865             AC_MSG_RESULT(no (suppressed because you are not using GCC))
 866          fi
 867       else
 868          AC_MSG_RESULT(no)
 869       fi
 870       ;;
 871    solaris*)
 872       # See if thread_db library is around for Solaris thread debugging.
 873       # Note that we must explicitly test for version 1 of the library
 874       # because version 0 (present on Solaris 2.4 or earlier) doesn't have
 875       # the same API.
 876       AC_MSG_CHECKING(for Solaris thread debugging library)
 877       if test -f /usr/lib/libthread_db.so.1 ; then
 878          AC_MSG_RESULT(yes)
 879          AC_DEFINE(HAVE_THREAD_DB_LIB)
 880          CONFIG_LIB_OBS="${CONFIG_LIB_OBS} sol-thread.o"
 881          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
 882          AC_CHECK_LIB(dl, dlopen)
 883          if test "$GCC" = "yes" ; then
 884             # The GNU linker requires the -export-dynamic option to make
 885             # all symbols visible in the dynamic symbol table.
 886             hold_ldflags=$LDFLAGS
 887             AC_MSG_CHECKING(for the ld -export-dynamic flag)
 888             LDFLAGS="${LDFLAGS} -Wl,-export-dynamic"
 889             AC_TRY_LINK(, [int i;], found=yes, found=no)
 890             LDFLAGS=$hold_ldflags
 891             AC_MSG_RESULT($found)
 892             if test $found = yes; then
 893                CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -Wl,-export-dynamic"
 894             fi
 895          fi
 896          # Sun randomly tweaked the prototypes in <proc_service.h>
 897          # at one point.
 898          AC_MSG_CHECKING(if <proc_service.h> is old)
 899          AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
 900             AC_TRY_COMPILE([
 901                 #include <proc_service.h>
 902                 ps_err_e ps_pdwrite
 903                     (struct ps_prochandle*, psaddr_t, const void*, size_t);
 904             ],, gdb_cv_proc_service_is_old=no,
 905                 gdb_cv_proc_service_is_old=yes)
 906          ])
 907          AC_MSG_RESULT($gdb_cv_proc_service_is_old)
 908          if test $gdb_cv_proc_service_is_old = yes; then
 909             AC_DEFINE(PROC_SERVICE_IS_OLD)
 910          fi
 911       else
 912          AC_MSG_RESULT(no)
 913       fi
 914       ;;
 915    aix*)
 916       AC_MSG_CHECKING(for AiX thread debugging library)
 917       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
 918                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
 919                                    [#ifndef PTHDB_VERSION_3
 920                                     #error
 921                                     #endif],
 922                                    gdb_cv_have_aix_thread_debug=yes,
 923                                    gdb_cv_have_aix_thread_debug=no)])
 924       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
 925       if test $gdb_cv_have_aix_thread_debug = yes; then
 926          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
 927          CONFIG_LIB_OBS="${CONFIG_LIB_OBS} aix-thread.o"
 928          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -lpthdebug"
 929       fi
 930       ;;
 931    esac
 932    AC_SUBST(CONFIG_LDFLAGS)
 933 fi
 934
 935 dnl See if we have a thread_db header file that has TD_NOTALLOC.
 936 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
 937    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
 938                   gdb_cv_thread_db_h_has_td_notalloc,
 939      AC_TRY_COMPILE(
 940        [#include <thread_db.h>],
 941        [int i = TD_NOTALLOC;],
 942        gdb_cv_thread_db_h_has_td_notalloc=yes,
 943        gdb_cv_thread_db_h_has_td_notalloc=no
 944      )
 945    )
 946 fi
 947 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
 948   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
 949             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
 950 fi
 951
 952 dnl See if we have a sys/syscall header file that has __NR_tkill.
 953 if test "x$ac_cv_header_sys_syscall_h" = "xyes"; then
 954    AC_CACHE_CHECK([whether <sys/syscall.h> has __NR_tkill],
 955                   gdb_cv_sys_syscall_h_has_tkill,
 956      AC_TRY_COMPILE(
 957        [#include <sys/syscall.h>],
 958        [int i = __NR_tkill;],
 959        gdb_cv_sys_syscall_h_has_tkill=yes,
 960        gdb_cv_sys_syscall_h_has_tkill=no
 961      )
 962    )
 963 fi
 964 dnl See if we can issue tkill syscall.
 965 if test "x$gdb_cv_sys_syscall_h_has_tkill" = "xyes" && test "x$ac_cv_func_syscall" = "xyes"; then
 966   AC_DEFINE(HAVE_TKILL_SYSCALL, 1,
 967             [Define if we can use the tkill syscall.])
 968 fi
 969
 970 dnl Handle optional features that can be enabled.
 971
 972 AC_ARG_WITH(sysroot,
 973 [  --with-sysroot[=DIR] Search for usr/lib et al within DIR.],
 974 [
 975  case ${with_sysroot} in
 976  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
 977  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
 978  esac
 979
 980  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
 981
 982  if test "x$exec_prefix" = xNONE; then
 983   if test "x$prefix" = xNONE; then
 984    test_prefix=/usr/local
 985   else
 986    test_prefix=$prefix
 987   fi
 988  else
 989   test_prefix=$exec_prefix
 990  fi
 991  case ${TARGET_SYSTEM_ROOT} in
 992  "${test_prefix}"|"${test_prefix}/"*|\
 993  '${exec_prefix}'|'${exec_prefix}/'*)
 994    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
 995    TARGET_SYSTEM_ROOT_DEFINE="$t"
 996    ;;
 997  esac
 998 ], [
 999  TARGET_SYSTEM_ROOT=
1000  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"'
1001 ])
1002 AC_SUBST(TARGET_SYSTEM_ROOT)
1003 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
1004
1005 # NOTE: Don't add -Wall or -Wunused, they both include
1006 # -Wunused-parameter which reports bogus warnings.
1007 # NOTE: If you add to this list, remember to update
1008 # gdb/doc/gdbint.texinfo.
1009 build_warnings="-Wimplicit -Wreturn-type -Wcomment -Wtrigraphs \
1010 -Wformat -Wparentheses -Wpointer-arith -Wuninitialized -Wformat-nonliteral \
1011 -Wunused-label"
1012 # Up for debate: -Wswitch -Wcomment -trigraphs -Wtrigraphs
1013 # -Wunused-function -Wunused-variable -Wunused-value
1014 # -Wchar-subscripts -Wtraditional -Wshadow -Wcast-qual
1015 # -Wcast-align -Wwrite-strings -Wconversion -Wstrict-prototypes
1016 # -Wmissing-prototypes -Wmissing-declarations -Wredundant-decls
1017 # -Woverloaded-virtual -Winline -Werror"
1018 AC_ARG_ENABLE(build-warnings,
1019 [  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
1020 [case "${enableval}" in
1021   yes)  ;;
1022   no)   build_warnings="-w";;
1023   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1024         build_warnings="${build_warnings} ${t}";;
1025   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1026         build_warnings="${t} ${build_warnings}";;
1027   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1028 esac
1029 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1030   echo "Setting compiler warning flags = $build_warnings" 6>&1
1031 fi])dnl
1032 AC_ARG_ENABLE(gdb-build-warnings,
1033 [  --enable-gdb-build-warnings Enable GDB specific build-time compiler warnings if gcc is used],
1034 [case "${enableval}" in
1035   yes)  ;;
1036   no)   build_warnings="-w";;
1037   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1038         build_warnings="${build_warnings} ${t}";;
1039   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1040         build_warnings="${t} ${build_warnings}";;
1041   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1042 esac
1043 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1044   echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1
1045 fi])dnl
1046 WARN_CFLAGS=""
1047 WERROR_CFLAGS=""
1048 if test "x${build_warnings}" != x -a "x$GCC" = xyes
1049 then
1050     AC_MSG_CHECKING(compiler warning flags)
1051     # Separate out the -Werror flag as some files just cannot be
1052     # compiled with it enabled.
1053     for w in ${build_warnings}; do
1054         case $w in
1055         -Werr*) WERROR_CFLAGS=-Werror ;;
1056         *) # Check that GCC accepts it
1057             saved_CFLAGS="$CFLAGS"
1058             CFLAGS="$CFLAGS $w"
1059             AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
1060             CFLAGS="$saved_CFLAGS"
1061         esac
1062     done
1063     AC_MSG_RESULT(${WARN_CFLAGS}${WERROR_CFLAGS})
1064 fi
1065 AC_SUBST(WARN_CFLAGS)
1066 AC_SUBST(WERROR_CFLAGS)
1067
1068 # In the Cygwin environment, we need some additional flags.
1069 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1070 [AC_EGREP_CPP(lose, [
1071 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1072 lose
1073 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1074
1075
1076 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1077 SER_HARDWIRE="ser-unix.o ser-pipe.o ser-tcp.o"
1078 case ${host} in
1079   *go32* ) SER_HARDWIRE=ser-go32.o ;;
1080   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
1081 esac
1082 AC_SUBST(SER_HARDWIRE)
1083
1084 # libreadline needs libuser32.a in a cygwin environment
1085 WIN32LIBS=
1086 if test x$gdb_cv_os_cygwin = xyes; then
1087     WIN32LIBS="-luser32"
1088     case "${target}" in
1089         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
1090         ;;
1091     esac
1092 fi
1093 AC_SUBST(WIN32LIBS)
1094
1095 LIBGUI="../libgui/src/libgui.a"
1096 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
1097 AC_SUBST(LIBGUI)
1098 AC_SUBST(GUI_CFLAGS_X)
1099
1100 WIN32LDAPP=
1101 AC_SUBST(WIN32LIBS)
1102 AC_SUBST(WIN32LDAPP)
1103
1104 configdir="unix"
1105
1106 GDBTKLIBS=
1107 if test "${enable_gdbtk}" = "yes"; then
1108
1109     # Gdbtk must have an absolute path to srcdir in order to run
1110     # properly when not installed.
1111     here=`pwd`
1112     cd ${srcdir}
1113     GDBTK_SRC_DIR=`pwd`
1114     cd $here
1115
1116     CY_AC_PATH_TCLCONFIG
1117     if test -z "${no_tcl}"; then
1118         CY_AC_LOAD_TCLCONFIG
1119         CY_AC_PATH_TKCONFIG
1120
1121         # now look for Tcl library stuff
1122
1123         case "${host}" in
1124         *-*-cygwin*)
1125             tcldir=../tcl/win/
1126             ;;
1127         *)
1128             tcldir=../tcl/unix/
1129             ;;
1130         esac
1131
1132         TCL_DEPS="${tcldir}${TCL_LIB_FILE}"
1133
1134         # If $no_tk is nonempty, then we can't do Tk, and there is no
1135         # point to doing Tcl.
1136         if test -z "${no_tk}"; then
1137            CY_AC_LOAD_TKCONFIG
1138            CY_AC_PATH_TCLH
1139            CY_AC_PATH_TKH
1140            CY_AC_PATH_ITCLH
1141            CY_AC_PATH_ITKH
1142
1143
1144            # now look for Tk library stuff
1145
1146            case "${host}" in
1147            *-*-cygwin*)
1148                tkdir=../tk/win/
1149                ;;
1150            *)
1151                tkdir=../tk/unix/
1152                ;;
1153            esac
1154
1155            TK_DEPS="${tkdir}${TK_LIB_FILE}"
1156
1157            # now look for Itcl library stuff
1158
1159            CY_AC_PATH_ITCLCONFIG
1160            if test -z "${no_itcl}"; then
1161              CY_AC_LOAD_ITCLCONFIG
1162
1163              ITCLLIB="${ITCL_BUILD_LIB_SPEC}"
1164              ITCL_DEPS="${ITCL_LIB_FULL_PATH}"
1165            fi
1166
1167
1168            # now look for Itk library stuff
1169            CY_AC_PATH_ITKCONFIG
1170            if test -z "${no_itcl}"; then
1171              CY_AC_LOAD_ITKCONFIG
1172
1173              ITKLIB="${ITK_BUILD_LIB_SPEC}"
1174              ITK_DEPS="${ITK_LIB_FULL_PATH}"
1175            fi
1176
1177            ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
1178            # Tcl/Tk 8.1 require -fwritable strings.  I don't
1179            # know whether 8.2 will or not, but I bet it will.
1180            # I don't have to worry about 7.x since we don't support it.
1181            GDBTK_CFLAGS=""
1182            if test "$GCC" = "yes"; then
1183                if test "$TCL_VERSION" != "8.0" ; then
1184                    GDBTK_CFLAGS="-fwritable-strings"
1185                fi
1186            fi
1187
1188            # Include some libraries that Tcl and Tk want.
1189            TCL_LIBS='$(LIBGUI) $(ITCL) $(ITK) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
1190            # Yes, the ordering seems wrong here.  But it isn't.
1191            # TK_LIBS is the list of libraries that need to be linked
1192            # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
1193            # were in LIBS then any link tests after this point would
1194            # try to include things like `$(LIBGUI)', which wouldn't work.
1195            GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
1196
1197            CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
1198            CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
1199            CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
1200            CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
1201            CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
1202            CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
1203            CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
1204
1205            if test x$gdb_cv_os_cygwin = xyes; then
1206               WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
1207               WIN32LDAPP="-Wl,--subsystem,console"
1208               CONFIG_OBS="${CONFIG_OBS} gdbres.o"
1209            fi
1210         fi
1211     fi
1212
1213     configdirs="${configdirs} gdbtk"
1214 fi
1215
1216 AC_SUBST(X_CFLAGS)
1217 AC_SUBST(X_LDFLAGS)
1218 AC_SUBST(X_LIBS)
1219 AC_SUBST(TCL_DEPS)
1220 AC_SUBST(TK_DEPS)
1221 AC_SUBST(ITCLLIB)
1222 AC_SUBST(ITCL_DEPS)
1223 AC_SUBST(ITKLIB)
1224 AC_SUBST(ITK_DEPS)
1225 AC_SUBST(GDBTKLIBS)
1226 AC_SUBST(GDBTK_CFLAGS)
1227 AC_SUBST(GDBTK_SRC_DIR)
1228
1229 AC_PATH_X
1230
1231
1232 # Unlike the sim directory, whether a simulator is linked is controlled by
1233 # presence of a SIM= and a SIM_OBS= definition in the target '.mt' file.
1234 # This code just checks for a few cases where we'd like to ignore those
1235 # definitions, even when they're present in the '.mt' file.  These cases
1236 # are when --disable-sim is specified, or if the simulator directory is
1237 # not part of the source tree.
1238 #
1239 AC_ARG_ENABLE(sim,
1240 [  --enable-sim            Link gdb with simulator],
1241 [echo "enable_sim = $enable_sim";
1242  echo "enableval = ${enableval}";
1243  case "${enableval}" in
1244   yes) ignore_sim=false ;;
1245   no)  ignore_sim=true ;;
1246   *)   ignore_sim=false ;;
1247  esac],
1248 [ignore_sim=false])
1249
1250 if test ! -d "${srcdir}/../sim"; then
1251   ignore_sim=true
1252 fi
1253
1254 if test "${ignore_sim}" = "true"; then
1255     IGNORE_SIM="SIM="
1256     IGNORE_SIM_OBS="SIM_OBS="
1257 else
1258     IGNORE_SIM=""
1259     IGNORE_SIM_OBS=""
1260     AC_DEFINE(WITH_SIM)
1261 fi
1262 AC_SUBST(IGNORE_SIM)
1263 AC_SUBST(IGNORE_SIM_OBS)
1264
1265 AC_SUBST(ENABLE_CFLAGS)
1266 AC_SUBST(PROFILE_CFLAGS)
1267
1268 AC_SUBST(CONFIG_OBS)
1269 AC_SUBST(CONFIG_DEPS)
1270 AC_SUBST(CONFIG_SRCS)
1271 AC_SUBST(CONFIG_ALL)
1272 AC_SUBST(CONFIG_CLEAN)
1273 AC_SUBST(CONFIG_INSTALL)
1274 AC_SUBST(CONFIG_UNINSTALL)
1275
1276 # target_subdir is used by the testsuite to find the target libraries.
1277 target_subdir=
1278 if test "${host}" != "${target}"; then
1279     target_subdir="${target_alias}/"
1280 fi
1281 AC_SUBST(target_subdir)
1282
1283 frags=
1284 host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
1285 if test ! -f ${host_makefile_frag}; then
1286     # When building a native debuger the .mh file containing things
1287     # like NATDEPFILES is needed.  Cross debuggers don't need .mh
1288     # since it no longer contains anything useful.
1289     if test "${target}" = "${host}"; then
1290         AC_MSG_ERROR("*** Gdb does not support native target ${host}")
1291     else
1292         host_makefile_frag=/dev/null
1293     fi
1294 fi
1295 frags="$frags $host_makefile_frag"
1296
1297 target_makefile_frag=${srcdir}/config/${gdb_target_cpu}/${gdb_target}.mt
1298 if test ! -f ${target_makefile_frag}; then
1299 AC_MSG_ERROR("*** Gdb does not support target ${target}")
1300 fi
1301 frags="$frags $target_makefile_frag"
1302
1303 AC_SUBST_FILE(host_makefile_frag)
1304 AC_SUBST_FILE(target_makefile_frag)
1305 AC_SUBST(frags)
1306
1307 changequote(,)dnl
1308 hostfile=`sed -n '
1309 s/XM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
1310 ' ${host_makefile_frag}`
1311
1312 targetfile=`sed -n '
1313 s/TM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
1314 ' ${target_makefile_frag}`
1315
1316 if test "${target}" = "${host}"; then
1317 # We pick this up from the host configuration file (.mh) because we
1318 # do not have a native configuration Makefile fragment.
1319 nativefile=`sed -n '
1320 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
1321 ' ${host_makefile_frag}`
1322 fi
1323 changequote([,])
1324
1325 if test x"${gdb_osabi}" != x ; then
1326     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
1327                        [Define to the default OS ABI for this configuration.])
1328 fi
1329
1330 # Enable multi-ice-gdb-server.
1331 AC_ARG_ENABLE(multi-ice,
1332 [  --enable-multi-ice      build the multi-ice-gdb-server],
1333   [case $enableval in
1334     yes | no)
1335       ;;
1336     *) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;;
1337   esac])
1338 if test "x$enable_multi_ice" = xyes; then
1339   configdirs="$configdirs multi-ice"
1340 fi
1341
1342 # We only build gdbserver automatically if host and target are the same.
1343 if test "x$target" = "x$host"; then
1344   AC_MSG_CHECKING(whether gdbserver is supported on this host)
1345   if test "x$build_gdbserver" = xyes; then
1346     configdirs="$configdirs gdbserver"
1347     AC_MSG_RESULT(yes)
1348   else
1349     AC_MSG_RESULT(no)
1350   fi
1351 fi
1352
1353 AC_CONFIG_SUBDIRS($configdirs)
1354
1355 # If hostfile (XM_FILE) and/or targetfile (TM_FILE) and/or nativefile
1356 # (NAT_FILE) is not set in config/*/*.m[ht] files, we link to an empty
1357 # version.
1358
1359 files=
1360 links=
1361
1362 rm -f xm.h
1363 xm_h=""
1364 if test "${hostfile}" != ""; then
1365     xm_h=xm.h
1366     GDB_XM_FILE="config/${gdb_host_cpu}/${hostfile}"
1367     files="${files} ${GDB_XM_FILE}"
1368     links="${links} xm.h"
1369     AC_DEFINE_UNQUOTED(GDB_XM_FILE, ${GDB_XM_FILE})
1370 fi
1371 AC_SUBST(xm_h)
1372
1373 rm -f tm.h
1374 tm_h=""
1375 if test "${targetfile}" != ""; then
1376     tm_h=tm.h
1377     GDB_TM_FILE="config/${gdb_target_cpu}/${targetfile}"
1378     files="${files} ${GDB_TM_FILE}"
1379     links="${links} tm.h"
1380     AC_DEFINE_UNQUOTED(GDB_TM_FILE, ${GDB_TM_FILE})
1381 fi
1382 AC_SUBST(tm_h)
1383
1384 rm -f nm.h
1385 nm_h=""
1386 if test "${nativefile}" != ""; then
1387     nm_h=nm.h
1388     GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}"
1389     files="${files} ${GDB_NM_FILE}"
1390     links="${links} nm.h"
1391     AC_DEFINE_UNQUOTED(GDB_NM_FILE, ${GDB_NM_FILE})
1392 fi
1393 AC_SUBST(nm_h)
1394
1395 AC_LINK_FILES($files, $links)
1396
1397 dnl Check for exe extension set on certain hosts (e.g. Win32)
1398 AC_EXEEXT
1399
1400 dnl  Detect the character set used by this host.
1401
1402 dnl  At the moment, we just assume it's ISO-8859-1 (which is a
1403 dnl  superset of ASCII containing the characters needed for French,
1404 dnl  German, Spanish, Italian, and possibly others), but if were
1405 dnl  *were* to support any host character sets other than ISO-8859-1,
1406 dnl  here's where we'd detect it.
1407 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "ISO-8859-1",
1408           [Define to be a string naming the default host character set.])
1409
1410 AM_ICONV
1411
1412 AC_OUTPUT(Makefile .gdbinit:gdbinit.in,
1413 [
1414 dnl Autoconf doesn't provide a mechanism for modifying definitions
1415 dnl provided by makefile fragments.
1416 dnl
1417 if test "${nativefile}" = ""; then
1418         < Makefile \
1419         sed -e '/^NATDEPFILES[[         ]]*=.*\\$/,/[[^\\]]$/s/^/# /' \
1420             -e '/^NATDEPFILES[[         ]]*=/s/^/# /' \
1421         | sed -e '/^\(NATDEPFILES[[     ]]*[[+]]=[[     ]]*\)/s//# \1/' \
1422         > Makefile.tem
1423 mv -f Makefile.tem Makefile
1424 fi
1425
1426 changequote(,)dnl
1427 sed -e '/^TM_FILE[      ]*=/s,^TM_FILE[         ]*=[    ]*,&config/'"${gdb_target_cpu}"'/,
1428 /^XM_FILE[      ]*=/s,^XM_FILE[         ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,
1429 /^NAT_FILE[     ]*=/s,^NAT_FILE[        ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,' <Makefile >Makefile.tmp
1430 mv -f Makefile.tmp Makefile
1431 changequote([,])dnl
1432
1433
1434 case x$CONFIG_HEADERS in
1435 xconfig.h:config.in)
1436 echo > stamp-h ;;
1437 esac
1438 ],
1439 [
1440 gdb_host_cpu=$gdb_host_cpu
1441 gdb_target_cpu=$gdb_target_cpu
1442 nativefile=$nativefile
1443 ])
1444
1445 exit 0