gdb/configure.in

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003
   3 dnl Free Software Foundation, Inc.
   4 dnl
   5 dnl This file is part of GDB.
   6 dnl
   7 dnl This program is free software; you can redistribute it and/or modify
   8 dnl it under the terms of the GNU General Public License as published by
   9 dnl the Free Software Foundation; either version 2 of the License, or
  10 dnl (at your option) any later version.
  11 dnl
  12 dnl This program is distributed in the hope that it will be useful,
  13 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 dnl GNU General Public License for more details.
  16 dnl
  17 dnl You should have received a copy of the GNU General Public License
  18 dnl along with this program; if not, write to the Free Software
  19 dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  20
  21 dnl Process this file with autoconf to produce a configure script.
  22
  23 AC_PREREQ(2.13)dnl
  24 AC_INIT(main.c)
  25 AC_CONFIG_HEADER(config.h:config.in)
  26 AM_MAINTAINER_MODE
  27
  28 AC_PROG_CC
  29 AC_GNU_SOURCE
  30 AC_AIX
  31 AC_ISC_POSIX
  32 AM_PROG_CC_STDC
  33
  34 AC_CONFIG_AUX_DIR(`cd $srcdir;pwd`/..)
  35 AC_CANONICAL_SYSTEM
  36
  37 # FIXME: kettenis/20030102: The AC_PROG_RANLIB from Autoconf 2.13
  38 # doesn't support cross-compilation, but the one from Autoconf 2.5x
  39 # does.  Override RANLIB here (i.e. before running AC_PROG_RANLIB) to
  40 # deal with the lossage.  Note that CY_GNU_GETTEXT currently calls
  41 # AC_PROG_RANLIB.  This can be removed when we switch to Autoconf
  42 # 2.5x.
  43 AC_CHECK_TOOL(RANLIB, ranlib, :)
  44
  45 dnl Set up for gettext.  PACKAGE is used when we call bindtextdomain.
  46 ALL_LINGUAS=
  47 CY_GNU_GETTEXT
  48 AC_DEFINE(PACKAGE, "gdb", [Name of this package. ])
  49
  50 debugdir=${libdir}/debug
  51
  52 AC_ARG_WITH(separate-debug-dir,
  53 [  --with-separate-debug-dir=path   Look for global separate debug info in this path [LIBDIR/debug]],
  54 [debugdir="${withval}"])
  55
  56 AC_DEFINE_DIR(DEBUGDIR, debugdir,
  57               [Global directory for separate debug files. ])
  58 #AC_DEFINE_UNQUOTED(DEBUGDIR, "$debugdir"),
  59
  60 dnl List of object files added by configure.
  61
  62 CONFIG_OBS=
  63 CONFIG_LIB_OBS=
  64 CONFIG_DEPS=
  65 CONFIG_SRCS=
  66 CONFIG_INITS=
  67 ENABLE_CFLAGS=
  68 CONFIG_ALL=
  69 CONFIG_CLEAN=
  70 CONFIG_INSTALL=
  71 CONFIG_UNINSTALL=
  72
  73 AC_CONFIG_SUBDIRS(doc testsuite)
  74 configdirs=
  75
  76 . $srcdir/configure.host
  77
  78 . $srcdir/configure.tgt
  79
  80 # Fetch the default architecture and default target vector from BFD.
  81 targ=$target; . $srcdir/../bfd/config.bfd
  82
  83 # We only want the first architecture, so strip off the others if
  84 # there is more than one.
  85 targ_archs=`echo $targ_archs | sed 's/ .*//'`
  86
  87 if test "x$targ_archs" != x; then
  88   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
  89     [Define to BFD's default architecture. ])
  90 fi
  91 if test "x$targ_defvec" != x; then
  92   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
  93     [Define to BFD's default target vector. ])
  94 fi
  95
  96 AC_ARG_PROGRAM
  97
  98 # The CLI cannot be disabled yet, but may be in the future.
  99
 100 # Enable CLI.
 101 AC_ARG_ENABLE(gdbcli,
 102 [  --disable-gdbcli        disable command-line interface (CLI)],
 103   [case $enableval in
 104     yes)
 105       ;;
 106     no)
 107       AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;;
 108     *)
 109       AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;;
 110   esac],
 111   [enable_gdbcli=yes])
 112 if test x"$enable_gdbcli" = xyes; then
 113   if test -d $srcdir/cli; then
 114     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)"
 115     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)"
 116     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)"
 117     CONFIG_INITS="$CONFIG_INITS \$(SUBDIR_CLI_INITS)"
 118     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)"
 119     CONFIG_ALL="$CONFIG_ALL \$(SUBDIR_CLI_ALL)"
 120     CONFIG_CLEAN="$CONFIG_CLEAN \$(SUBDIR_CLI_CLEAN)"
 121     CONFIG_INSTALL="$CONFIG_INSTALL \$(SUBDIR_CLI_INSTALL)"
 122     CONFIG_UNINSTALL="$CONFIG_UNINSTALL \$(SUBDIR_CLI_UNINSTALL)"
 123   fi
 124 fi
 125
 126 # Enable MI.
 127 AC_ARG_ENABLE(gdbmi,
 128 [  --disable-gdbmi         disable machine-interface (MI)],
 129   [case $enableval in
 130     yes | no)
 131       ;;
 132     *)
 133       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 134   esac],
 135   [enable_gdbmi=yes])
 136 if test x"$enable_gdbmi" = xyes; then
 137   if test -d $srcdir/mi; then
 138     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 139     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 140     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 141     CONFIG_INITS="$CONFIG_INITS \$(SUBDIR_MI_INITS)"
 142     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 143     CONFIG_ALL="$CONFIG_ALL \$(SUBDIR_MI_ALL)"
 144     CONFIG_CLEAN="$CONFIG_CLEAN \$(SUBDIR_MI_CLEAN)"
 145     CONFIG_INSTALL="$CONFIG_INSTALL \$(SUBDIR_MI_INSTALL)"
 146     CONFIG_UNINSTALL="$CONFIG_UNINSTALL \$(SUBDIR_MI_UNINSTALL)"
 147   fi
 148 fi
 149
 150 # Enable TUI.
 151 AC_ARG_ENABLE(tui,
 152 [  --enable-tui            enable full-screen terminal user interface (TUI)],
 153   [case $enableval in
 154     yes | no)
 155       ;;
 156     *)
 157       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 158   esac])
 159 if test x"$enable_tui" = xyes; then
 160   if test -d $srcdir/tui; then
 161     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
 162     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
 163     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
 164     CONFIG_INITS="$CONFIG_INITS \$(SUBDIR_TUI_INITS)"
 165     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
 166     CONFIG_ALL="$CONFIG_ALL \$(SUBDIR_TUI_ALL)"
 167     CONFIG_CLEAN="$CONFIG_CLEAN \$(SUBDIR_TUI_CLEAN)"
 168     CONFIG_INSTALL="$CONFIG_INSTALL \$(SUBDIR_TUI_INSTALL)"
 169     CONFIG_UNINSTALL="$CONFIG_UNINSTALL \$(SUBDIR_TUI_UNINSTALL)"
 170     need_curses=yes
 171   fi
 172 fi
 173
 174 # Enable gdbtk.
 175 AC_ARG_ENABLE(gdbtk,
 176 [  --enable-gdbtk          enable gdbtk graphical user interface (GUI)],
 177   [case $enableval in
 178     yes | no)
 179       ;;
 180     *)
 181       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 182   esac],
 183   [if test -d $srcdir/gdbtk; then
 184     enable_gdbtk=yes
 185   else
 186     enable_gdbtk=no
 187   fi])
 188 # We unconditionally disable gdbtk tests on selected platforms.
 189 case $host_os in
 190   go32* | windows*)
 191     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 192     enable_gdbtk=no ;;
 193 esac
 194
 195 # Libunwind support.
 196 AC_ARG_WITH(libunwind,
 197 [  --with-libunwind            Use libunwind frame unwinding support],
 198 [case "${withval}" in
 199   yes)  enable_libunwind=yes ;;
 200   no)   enable_libunwind=no ;;
 201   *)    AC_MSG_ERROR(bad value ${withval} for GDB with-libunwind option) ;;
 202 esac],[
 203   AC_CHECK_HEADERS(libunwind.h)
 204   AC_CHECK_HEADERS(libunwind-ia64.h)
 205   if test x"$ac_cv_header_libunwind_h" = xyes -a x"$ac_cv_header_libunwind_ia64_h" = xyes; then
 206     enable_libunwind=yes;
 207   fi
 208 ])
 209
 210 if test x"$enable_libunwind" = xyes; then
 211   AC_CHECK_HEADERS(libunwind.h)
 212   AC_CHECK_HEADERS(libunwind-ia64.h)
 213   AC_DEFINE(HAVE_LIBUNWIND, 1)
 214   CONFIG_OBS="$CONFIG_OBS libunwind-frame.o"
 215   CONFIG_DEPS="$CONFIG_DEPS libunwind-frame.o"
 216   CONFIG_SRCS="$CONFIG_SRCS libunwind-frame.c"
 217 fi
 218
 219 # Profiling support.
 220 AC_ARG_ENABLE(profiling,
 221 [  --enable-profiling      enable profiling of GDB],
 222   [case $enableval in
 223     yes | no)
 224       ;;
 225     *)
 226       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 227   esac],
 228  [enable_profiling=no])
 229
 230 AC_CHECK_FUNCS(monstartup _mcleanup)
 231 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 232 [AC_TRY_LINK(
 233 [#include <stdlib.h>
 234 extern char _etext;
 235 ],
 236 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 237 if test $ac_cv_var__etext = yes; then
 238   AC_DEFINE(HAVE__ETEXT, 1,
 239             [Define to 1 if your system has the _etext variable. ])
 240 fi
 241 if test "$enable_profiling" = yes ; then
 242   if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
 243     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 244   fi
 245   PROFILE_CFLAGS=-pg
 246   OLD_CFLAGS="$CFLAGS"
 247   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 248
 249   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 250     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 251      ac_cv_cc_supports_pg=no)])
 252
 253   if test $ac_cv_cc_supports_pg = no; then
 254     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 255   fi
 256
 257   CFLAGS="$OLD_CFLAGS"
 258 fi
 259
 260 # --------------------- #
 261 # Checks for programs.  #
 262 # --------------------- #
 263
 264 AC_PROG_AWK
 265 AC_PROG_INSTALL
 266 AC_PROG_LN_S
 267 AC_PROG_RANLIB
 268 AC_PROG_YACC
 269
 270 AC_CHECK_TOOL(AR, ar)
 271 AC_CHECK_TOOL(DLLTOOL, dlltool)
 272 AC_CHECK_TOOL(WINDRES, windres)
 273
 274 # Needed for GNU/Hurd.
 275 AC_CHECK_TOOL(MIG, mig)
 276
 277 # ---------------------- #
 278 # Checks for libraries.  #
 279 # ---------------------- #
 280
 281 # We might need to link with -lm; most simulators need it.
 282 AC_CHECK_LIB(m, main)
 283
 284 # We need to link with -lw to get `wctype' on Solaris before Solaris
 285 # 2.6.  Solaris 2.6 and beyond have this function in libc, and have a
 286 # libw that some versions of the GNU linker cannot hanle (GNU ld 2.9.1
 287 # is known to have this problem).  Therefore we avoid libw if we can.
 288 AC_CHECK_FUNC(wctype, [],
 289   [AC_CHECK_LIB(w, wctype)])
 290
 291 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 292 AC_SEARCH_LIBS(gethostbyname, nsl)
 293
 294 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 295 AC_SEARCH_LIBS(socketpair, socket)
 296
 297 # Since GDB uses Readline, we need termcap functionality, so we need
 298 # to find a library that provides that.  When GDB is configured with
 299 # --enable-tui, we need full curses functionality.
 300 #
 301 # FIXME: kettenis/20030102: We seem to prefer HP curses (Hcurses) over
 302 # Xcurses on HP-UX; see the `-D__HP_CURSES' in the relevant host
 303 # Makefile fragments.  That's why we need to have `Hcurses' before
 304 # `curses'.  I don't see why we should use HP curses if a more
 305 # standard curses is available, except that according to HP's
 306 # documentation one needs to compile `-D_XOPEN_SOURCE_EXTENDED' on
 307 # HP-UX 10.10 and 10.20.
 308
 309 if test "$need_curses" = yes; then
 310   AC_SEARCH_LIBS(initscr, [ncurses Hcurses curses], [],
 311     [AC_MSG_ERROR([no curses library found])])
 312 fi
 313
 314 case $host_os in
 315   cygwin*)
 316     if test -d $srcdir/libtermcap; then
 317       LIBS="../libtermcap/libtermcap.a $LIBS"
 318       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 319     fi ;;
 320   go32* | *djgpp*)
 321     ac_cv_search_tgetent="none required"
 322     ;;
 323   aix*)
 324     # Readline prefers curses over termcap on AIX.
 325     # ??? Why?
 326     AC_SEARCH_LIBS(tgetent, [tinfo ncurses curses termcap])
 327     ;;
 328 esac
 329
 330 # Note: We used to check for libtermlib and libterminfo too, but
 331 # Readline doesn't, so I think we're safe with leaving them out.
 332 AC_SEARCH_LIBS(tgetent, [termcap tinfo ncurses Hcurses curses])
 333
 334 if test "$ac_cv_search_tgetent" = no; then
 335   AC_MSG_ERROR([no termcap library found])
 336 fi
 337
 338 # ------------------------- #
 339 # Checks for header files.  #
 340 # ------------------------- #
 341
 342 AC_HEADER_DIRENT
 343 AC_HEADER_STAT
 344 AC_HEADER_STDC
 345 AC_CHECK_HEADERS(link.h)
 346 AC_CHECK_HEADERS(nlist.h)
 347 AC_CHECK_HEADERS(poll.h sys/poll.h)
 348 AC_CHECK_HEADERS(proc_service.h thread_db.h)
 349 AC_CHECK_HEADERS(stddef.h)
 350 AC_CHECK_HEADERS(stdlib.h)
 351 AC_CHECK_HEADERS(stdint.h)
 352 AC_CHECK_HEADERS(string.h memory.h strings.h)
 353 AC_CHECK_HEADERS(sys/fault.h)
 354 AC_CHECK_HEADERS(sys/file.h)
 355 AC_CHECK_HEADERS(sys/filio.h)
 356 AC_CHECK_HEADERS(sys/ioctl.h)
 357 AC_CHECK_HEADERS(sys/param.h)
 358 AC_CHECK_HEADERS(sys/proc.h)
 359 AC_CHECK_HEADERS(sys/procfs.h)
 360 AC_CHECK_HEADERS(sys/ptrace.h ptrace.h)
 361 AC_CHECK_HEADERS(sys/reg.h sys/debugreg.h)
 362 AC_CHECK_HEADERS(sys/select.h)
 363 AC_CHECK_HEADERS(sys/syscall.h)
 364 AC_CHECK_HEADERS(sys/user.h)
 365 AC_CHECK_HEADERS(sys/wait.h wait.h)
 366 AC_CHECK_HEADERS(termios.h termio.h sgtty.h)
 367 AC_CHECK_HEADERS(unistd.h)
 368
 369 # On Solaris 2.[78], we need to define _MSE_INT_H to avoid a clash
 370 # between <widec.h> and <wchar.h> that would cause AC_CHECK_HEADERS to
 371 # think that we don't have <curses.h> if we're using GCC.
 372 case $host_os in
 373   solaris2.[[78]])
 374     if test "$GCC" = yes; then
 375       AC_DEFINE(_MSE_INT_H, 1,
 376         [[Define to 1 to avoid a clash between <widec.h> and <wchar.h> on
 377    Solaris 2.[78] when using GCC. ]])
 378     fi ;;
 379 esac
 380 AC_CHECK_HEADERS(curses.h ncurses.h term.h)
 381
 382 # FIXME: kettenis/20030102: In most cases we include these
 383 # unconditionally, so what's the point in checking these?
 384 AC_CHECK_HEADERS(ctype.h time.h)
 385
 386 # ------------------------- #
 387 # Checks for declarations.  #
 388 # ------------------------- #
 389
 390 gcc_AC_CHECK_DECLS(getopt)
 391
 392 # ------------------ #
 393 # Checks for types.  #
 394 # ------------------ #
 395
 396 AC_TYPE_SIGNAL
 397
 398 # ------------------------------------- #
 399 # Checks for compiler characteristics.  #
 400 # ------------------------------------- #
 401
 402 AC_C_CONST
 403 AC_C_INLINE
 404
 405 # ------------------------------ #
 406 # Checks for library functions.  #
 407 # ------------------------------ #
 408
 409 AC_FUNC_ALLOCA
 410 AC_FUNC_MMAP
 411 AC_FUNC_VFORK
 412 AC_CHECK_FUNCS(canonicalize_file_name realpath)
 413 AC_CHECK_FUNCS(poll)
 414 AC_CHECK_FUNCS(pread64)
 415 AC_CHECK_FUNCS(sbrk)
 416 AC_CHECK_FUNCS(setpgid setpgrp)
 417 AC_CHECK_FUNCS(sigaction sigprocmask sigsetmask)
 418 AC_CHECK_FUNCS(socketpair)
 419 AC_CHECK_FUNCS(syscall)
 420
 421 dnl AC_FUNC_SETPGRP does not work when cross compiling
 422 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
 423 if test "$cross_compiling" = no; then
 424   AC_FUNC_SETPGRP
 425 else
 426   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
 427     [AC_TRY_COMPILE([
 428 #include <unistd.h>
 429 ], [
 430   if (setpgrp(1,1) == -1)
 431     exit (0);
 432   else
 433     exit (1);
 434 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
 435 if test $ac_cv_func_setpgrp_void = yes; then
 436   AC_DEFINE(SETPGRP_VOID, 1)
 437 fi
 438 fi
 439
 440 # Check if sigsetjmp is available.  Using AC_CHECK_FUNCS won't do
 441 # since sigsetjmp might only be defined as a macro.
 442 AC_CACHE_CHECK([for sigsetjmp], gdb_cv_func_sigsetjmp,
 443 [AC_TRY_COMPILE([
 444 #include <setjmp.h>
 445 ], [sigjmp_buf env; while (! sigsetjmp (env, 1)) siglongjmp (env, 1);],
 446 gdb_cv_func_sigsetjmp=yes, gdb_cv_func_sigsetjmp=no)])
 447 if test $gdb_cv_func_sigsetjmp = yes; then
 448   AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available. ])
 449 fi
 450
 451 # Assume we'll default to using the included libiberty regex.
 452 gdb_use_included_regex=yes
 453
 454 # However, if the system regex is GNU regex, then default to *not*
 455 # using the included regex.
 456 AC_CACHE_CHECK(
 457   [for GNU regex],
 458   [gdb_cv_have_gnu_regex],
 459   [AC_TRY_COMPILE(
 460     [#include <gnu-versions.h>],
 461     [#define REGEX_INTERFACE_VERSION 1
 462 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
 463 # error "Version mismatch"
 464 #endif],
 465     gdb_cv_have_gnu_regex=yes,
 466     gdb_cv_have_gnu_regex=no)])
 467 if test $gdb_cv_have_gnu_regex = yes; then
 468   gdb_use_included_regex=no
 469 fi
 470
 471 AC_ARG_WITH(included-regex,
 472   [  --without-included-regex don't use included regex; this is the default
 473                           on systems with version 2 of the GNU C library
 474                           (use with caution on other system)],
 475   gdb_with_regex=$withval,
 476   gdb_with_regex=$gdb_use_included_regex)
 477 if test "$gdb_with_regex" = yes; then
 478   AC_DEFINE(USE_INCLUDED_REGEX, 1,
 479     [Define to 1 if the regex included in libiberty should be used.])
 480 fi
 481
 482 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
 483 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
 484 AC_CACHE_CHECK([for r_fs in struct reg], gdb_cv_struct_reg_r_fs,
 485 [AC_TRY_COMPILE([#include <machine/reg.h>], [struct reg r; r.r_fs;],
 486 gdb_cv_struct_reg_r_fs=yes, gdb_cv_struct_reg_r_fs=no)])
 487 if test $gdb_cv_struct_reg_r_fs = yes; then
 488   AC_DEFINE(HAVE_STRUCT_REG_R_FS)
 489 fi
 490 AC_CACHE_CHECK([for r_gs in struct reg], gdb_cv_struct_reg_r_gs,
 491 [AC_TRY_COMPILE([#include <machine/reg.h>], [struct reg r; r.r_gs;],
 492 gdb_cv_struct_reg_r_gs=yes, gdb_cv_struct_reg_r_gs=no)])
 493 if test $gdb_cv_struct_reg_r_gs = yes; then
 494   AC_DEFINE(HAVE_STRUCT_REG_R_GS)
 495 fi
 496
 497 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
 498 AC_MSG_CHECKING(for PTRACE_GETREGS)
 499 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
 500 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 501                 [PTRACE_GETREGS;],
 502                 [gdb_cv_have_ptrace_getregs=yes],
 503                 [gdb_cv_have_ptrace_getregs=no])])
 504 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
 505 if test $gdb_cv_have_ptrace_getregs = yes; then
 506   AC_DEFINE(HAVE_PTRACE_GETREGS)
 507 fi
 508
 509 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
 510 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
 511 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
 512 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 513                 [PTRACE_GETFPXREGS;],
 514                 [gdb_cv_have_ptrace_getfpxregs=yes],
 515                 [gdb_cv_have_ptrace_getfpxregs=no])])
 516 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
 517 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
 518   AC_DEFINE(HAVE_PTRACE_GETFPXREGS)
 519 fi
 520
 521 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
 522 AC_MSG_CHECKING(for PT_GETDBREGS)
 523 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
 524 [AC_TRY_COMPILE([#include <sys/types.h>
 525 #include <sys/ptrace.h>],
 526                 [PT_GETDBREGS;],
 527                 [gdb_cv_have_pt_getdbregs=yes],
 528                 [gdb_cv_have_pt_getdbregs=no])])
 529 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
 530 if test $gdb_cv_have_pt_getdbregs = yes; then
 531   AC_DEFINE(HAVE_PT_GETDBREGS)
 532 fi
 533
 534 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
 535 AC_MSG_CHECKING(for PT_GETXMMREGS)
 536 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
 537 [AC_TRY_COMPILE([#include <sys/types.h>
 538 #include <sys/ptrace.h>],
 539                 [PT_GETXMMREGS;],
 540                 [gdb_cv_have_pt_getxmmregs=yes],
 541                 [gdb_cv_have_pt_getxmmregs=no])])
 542 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
 543 if test $gdb_cv_have_pt_getxmmregs = yes; then
 544   AC_DEFINE(HAVE_PT_GETXMMREGS)
 545 fi
 546
 547 # See if stdint.h provides the uintptr_t type.
 548 # Autoconf 2.5X has an improved AC_CHECK_TYPE which will simplify this.
 549 AC_CACHE_CHECK([for uintptr_t in stdint.h], gdb_cv_have_uintptr_t,
 550   [AC_TRY_COMPILE(
 551     [#include <stdint.h>],
 552     [uintptr_t foo = 0;],
 553     gdb_cv_have_uintptr_t=yes,
 554     gdb_cv_have_uintptr_t=no)])
 555 if test $gdb_cv_have_uintptr_t = yes; then
 556   AC_DEFINE(HAVE_UINTPTR_T, 1, [Define if <stdint.h> provides the uintptr_t type.])
 557 fi
 558
 559 BFD_NEED_DECLARATION(malloc)
 560 BFD_NEED_DECLARATION(realloc)
 561 BFD_NEED_DECLARATION(free)
 562 BFD_NEED_DECLARATION(strerror)
 563 BFD_NEED_DECLARATION(strdup)
 564 BFD_NEED_DECLARATION(strstr)
 565 BFD_NEED_DECLARATION(canonicalize_file_name)
 566
 567 # The following save_state_t checkery is only necessary for HPUX
 568 # versions earlier than 10.20.  When those fade from memory, this
 569 # could be expunged. --jsm 1999-03-22
 570
 571 AC_MSG_CHECKING(for HPUX save_state structure)
 572 AC_EGREP_HEADER(save_state_t, machine/save_state.h,
 573                 gdb_cv_hpux_savestate=yes, gdb_cv_hpux_savestate=no)
 574 AC_EGREP_HEADER(ss_wide, machine/save_state.h, gdb_cv_hpux_sswide=yes,
 575                 gdb_cv_hpux_sswide=no)
 576 if test $gdb_cv_hpux_savestate = yes
 577 then
 578   AC_DEFINE(HAVE_STRUCT_SAVE_STATE_T, 1)
 579 fi
 580 if test $gdb_cv_hpux_sswide = yes
 581 then
 582   AC_DEFINE(HAVE_STRUCT_MEMBER_SS_WIDE, 1)
 583 fi
 584 AC_MSG_RESULT($gdb_cv_hpux_sswide)
 585
 586
 587 # If we are configured native on GNU/Linux, work around problems with
 588 # sys/procfs.h
 589 # Also detect which type of /proc is in use, such as for Unixware or Solaris.
 590
 591 if test "${target}" = "${host}"; then
 592   case "${host}" in
 593   i[[3456]]86-*-linux*)
 594         AC_DEFINE(START_INFERIOR_TRAPS_EXPECTED,2)
 595         AC_DEFINE(sys_quotactl)
 596         ;;
 597   ia64-*-aix*)
 598       AC_DEFINE(NEW_PROC_API)
 599       ;;
 600   *-*-unixware* | *-*-sysv4.2* | *-*-sysv5* | *-*-interix* )
 601       AC_DEFINE(NEW_PROC_API)
 602       ;;
 603   *-*-solaris2.[[678]])
 604       AC_DEFINE(NEW_PROC_API)
 605       ;;
 606   esac
 607 fi
 608
 609 if test "$ac_cv_header_sys_procfs_h" = yes; then
 610   BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
 611   BFD_HAVE_SYS_PROCFS_TYPE(prrun_t)
 612   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
 613   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
 614   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
 615   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
 616   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
 617   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset32_t)
 618   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
 619   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
 620   BFD_HAVE_SYS_PROCFS_TYPE(prsysent_t)
 621   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigset_t)
 622   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigaction64_t)
 623   BFD_HAVE_SYS_PROCFS_TYPE(pr_siginfo64_t)
 624
 625
 626   dnl Check for broken prfpregset_t type
 627
 628   dnl For Linux/i386, glibc 2.1.3 was released with a bogus
 629   dnl prfpregset_t type (it's a typedef for the pointer to a struct
 630   dnl instead of the struct itself).  We detect this here, and work
 631   dnl around it in gdb_proc_service.h.
 632
 633   if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
 634     AC_MSG_CHECKING(whether prfpregset_t type is broken)
 635     AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
 636       [AC_TRY_RUN([#include <sys/procfs.h>
 637        int main ()
 638        {
 639          if (sizeof (prfpregset_t) == sizeof (void *))
 640            return 1;
 641          return 0;
 642        }],
 643        gdb_cv_prfpregset_t_broken=no,
 644        gdb_cv_prfpregset_t_broken=yes,
 645        gdb_cv_prfpregset_t_broken=yes)])
 646     AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
 647     if test $gdb_cv_prfpregset_t_broken = yes; then
 648       AC_DEFINE(PRFPREGSET_T_BROKEN)
 649     fi
 650   fi
 651
 652   dnl Check for PIOCSET ioctl entry
 653
 654   AC_MSG_CHECKING(for PIOCSET ioctl entry in sys/procfs.h)
 655   AC_CACHE_VAL(gdb_cv_have_procfs_piocset,
 656   [AC_TRY_COMPILE([#include <unistd.h>
 657 #include <sys/types.h>
 658 #include <sys/procfs.h>
 659 ], [
 660     int dummy;;
 661     dummy = ioctl(0, PIOCSET, &dummy);
 662   ],
 663   gdb_cv_have_procfs_piocset=yes, gdb_cv_have_procfs_piocset=no)])
 664   AC_MSG_RESULT($gdb_cv_have_procfs_piocset)
 665   if test $gdb_cv_have_procfs_piocset = yes; then
 666     AC_DEFINE(HAVE_PROCFS_PIOCSET)
 667   fi
 668 fi
 669
 670 dnl For native ports (host == target), check to see what kind of
 671 dnl legacy link.h support is needed.  (See solib-legacy.c.)
 672 if test ${host} = ${target} ; then
 673   dnl Check for struct link_map with l_ members which are indicative
 674   dnl of SVR4-like shared libraries
 675
 676   AC_MSG_CHECKING(for member l_addr in struct link_map)
 677   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_l_members,
 678     [AC_TRY_COMPILE([#include <link.h>],
 679                     [struct link_map lm; (void) lm.l_addr;],
 680                     gdb_cv_have_struct_link_map_with_l_members=yes,
 681                     gdb_cv_have_struct_link_map_with_l_members=no)])
 682   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_l_members)
 683   if test $gdb_cv_have_struct_link_map_with_l_members = yes; then
 684     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_L_MEMBERS)
 685   fi
 686
 687   dnl Check for struct link_map with lm_ members which are indicative
 688   dnl of SunOS-like shared libraries
 689
 690   AC_MSG_CHECKING(for member lm_addr in struct link_map)
 691   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_lm_members,
 692     [AC_TRY_COMPILE([#include <sys/types.h>
 693 #include <link.h>],
 694                     [struct link_map lm; (void) lm.lm_addr;],
 695                     gdb_cv_have_struct_link_map_with_lm_members=yes,
 696                     gdb_cv_have_struct_link_map_with_lm_members=no)])
 697   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_lm_members)
 698   if test $gdb_cv_have_struct_link_map_with_lm_members = yes; then
 699     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_LM_MEMBERS)
 700   fi
 701
 702   dnl Check for struct so_map with som_ members which are found on
 703   dnl some *BSD systems.
 704
 705   AC_MSG_CHECKING(for member som_addr in struct so_map)
 706   AC_CACHE_VAL(gdb_cv_have_struct_so_map_with_som_members,
 707     [AC_TRY_COMPILE([#include <sys/types.h>
 708 #ifdef HAVE_NLIST_H
 709 #include <nlist.h>
 710 #endif
 711 #include <link.h>],
 712                     [struct so_map lm; (void) lm.som_addr;],
 713                     gdb_cv_have_struct_so_map_with_som_members=yes,
 714                     gdb_cv_have_struct_so_map_with_som_members=no)])
 715   AC_MSG_RESULT($gdb_cv_have_struct_so_map_with_som_members)
 716   if test $gdb_cv_have_struct_so_map_with_som_members = yes; then
 717     AC_DEFINE(HAVE_STRUCT_SO_MAP_WITH_SOM_MEMBERS)
 718   fi
 719
 720   dnl Check for struct link_map32 type, which allows a 64-bit Solaris
 721   dnl debugger to debug a 32-bit Solaris app with 32-bit shared libraries.
 722
 723   AC_MSG_CHECKING(for struct link_map32 in sys/link.h)
 724   AC_CACHE_VAL(gdb_cv_have_struct_link_map32,
 725     [AC_TRY_COMPILE([#define _SYSCALL32
 726 #include <sys/link.h>], [struct link_map32 l;],
 727      gdb_cv_have_struct_link_map32=yes,
 728      gdb_cv_have_struct_link_map32=no)])
 729   AC_MSG_RESULT($gdb_cv_have_struct_link_map32)
 730   if test $gdb_cv_have_struct_link_map32 = yes; then
 731     AC_DEFINE(HAVE_STRUCT_LINK_MAP32)
 732     AC_DEFINE(_SYSCALL32)
 733   fi
 734 fi
 735
 736 dnl See if compiler supports "long long" type.
 737
 738 AC_MSG_CHECKING(for long long support in compiler)
 739 AC_CACHE_VAL(gdb_cv_c_long_long,
 740 [AC_TRY_COMPILE(, [
 741   extern long long foo;
 742   switch (foo & 2) { case 0: return 1; }
 743 ],
 744 gdb_cv_c_long_long=yes, gdb_cv_c_long_long=no)])
 745 AC_MSG_RESULT($gdb_cv_c_long_long)
 746 if test $gdb_cv_c_long_long = yes; then
 747   AC_DEFINE(CC_HAS_LONG_LONG)
 748 fi
 749
 750 dnl See if the compiler and runtime support printing long long
 751
 752 AC_MSG_CHECKING(for long long support in printf)
 753 AC_CACHE_VAL(gdb_cv_printf_has_long_long,
 754 [AC_TRY_RUN([
 755 int main () {
 756   char buf[32];
 757   long long l = 0;
 758   l = (l << 16) + 0x0123;
 759   l = (l << 16) + 0x4567;
 760   l = (l << 16) + 0x89ab;
 761   l = (l << 16) + 0xcdef;
 762   sprintf (buf, "0x%016llx", l);
 763   return (strcmp ("0x0123456789abcdef", buf));
 764 }],
 765 gdb_cv_printf_has_long_long=yes,
 766 gdb_cv_printf_has_long_long=no,
 767 gdb_cv_printf_has_long_long=no)])
 768 if test $gdb_cv_printf_has_long_long = yes; then
 769   AC_DEFINE(PRINTF_HAS_LONG_LONG)
 770 fi
 771 AC_MSG_RESULT($gdb_cv_printf_has_long_long)
 772
 773 dnl See if compiler supports "long double" type.  Can't use AC_C_LONG_DOUBLE
 774 dnl because autoconf complains about cross-compilation issues.  However, this
 775 dnl code uses the same variables as the macro for compatibility.
 776
 777 AC_MSG_CHECKING(for long double support in compiler)
 778 AC_CACHE_VAL(ac_cv_c_long_double,
 779 [AC_TRY_COMPILE(, [long double foo;],
 780 ac_cv_c_long_double=yes, ac_cv_c_long_double=no)])
 781 AC_MSG_RESULT($ac_cv_c_long_double)
 782 if test $ac_cv_c_long_double = yes; then
 783   AC_DEFINE(HAVE_LONG_DOUBLE)
 784 fi
 785
 786 dnl See if the compiler and runtime support printing long doubles
 787
 788 AC_MSG_CHECKING(for long double support in printf)
 789 AC_CACHE_VAL(gdb_cv_printf_has_long_double,
 790 [AC_TRY_RUN([
 791 int main () {
 792   char buf[16];
 793   long double f = 3.141592653;
 794   sprintf (buf, "%Lg", f);
 795   return (strncmp ("3.14159", buf, 7));
 796 }],
 797 gdb_cv_printf_has_long_double=yes,
 798 gdb_cv_printf_has_long_double=no,
 799 gdb_cv_printf_has_long_double=no)])
 800 if test $gdb_cv_printf_has_long_double = yes; then
 801   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE)
 802 fi
 803 AC_MSG_RESULT($gdb_cv_printf_has_long_double)
 804
 805 dnl See if the compiler and runtime support scanning long doubles
 806
 807 AC_MSG_CHECKING(for long double support in scanf)
 808 AC_CACHE_VAL(gdb_cv_scanf_has_long_double,
 809 [AC_TRY_RUN([
 810 int main () {
 811   char *buf = "3.141592653";
 812   long double f = 0;
 813   sscanf (buf, "%Lg", &f);
 814   return !(f > 3.14159 && f < 3.14160);
 815 }],
 816 gdb_cv_scanf_has_long_double=yes,
 817 gdb_cv_scanf_has_long_double=no,
 818 gdb_cv_scanf_has_long_double=no)])
 819 if test $gdb_cv_scanf_has_long_double = yes; then
 820   AC_DEFINE(SCANF_HAS_LONG_DOUBLE)
 821 fi
 822 AC_MSG_RESULT($gdb_cv_scanf_has_long_double)
 823
 824 case ${host_os} in
 825 aix*)
 826   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
 827     SAVE_LDFLAGS=$LDFLAGS
 828
 829     case $GCC in
 830     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
 831     *) gdb_cv_bigtoc=-bbigtoc ;;
 832     esac
 833
 834     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
 835     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
 836   ])
 837   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
 838   ;;
 839 esac
 840
 841
 842 dnl For certain native configurations, we need to check whether thread
 843 dnl support can be built in or not.
 844 dnl
 845 dnl Note that we only want this if we are both native (host == target),
 846 dnl and not doing a canadian cross build (build == host).
 847
 848 if test ${build} = ${host} -a ${host} = ${target} ; then
 849    case ${host_os} in
 850    hpux*)
 851       AC_MSG_CHECKING(for HPUX/OSF thread support)
 852       if test -f /usr/include/dce/cma_config.h ; then
 853          if test "$GCC" = "yes" ; then
 854             AC_MSG_RESULT(yes)
 855             AC_DEFINE(HAVE_HPUX_THREAD_SUPPORT)
 856             CONFIG_LIB_OBS="${CONFIG_LIB_OBS} hpux-thread.o"
 857             CONFIG_SRCS="${CONFIG_SRCS} hpux-thread.c"
 858          else
 859             AC_MSG_RESULT(no (suppressed because you are not using GCC))
 860          fi
 861       else
 862          AC_MSG_RESULT(no)
 863       fi
 864       ;;
 865    solaris*)
 866       # See if thread_db library is around for Solaris thread debugging.
 867       # Note that we must explicitly test for version 1 of the library
 868       # because version 0 (present on Solaris 2.4 or earlier) doesn't have
 869       # the same API.
 870       AC_MSG_CHECKING(for Solaris thread debugging library)
 871       if test -f /usr/lib/libthread_db.so.1 ; then
 872          AC_MSG_RESULT(yes)
 873          AC_DEFINE(HAVE_THREAD_DB_LIB)
 874          CONFIG_LIB_OBS="${CONFIG_LIB_OBS} sol-thread.o"
 875          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
 876          AC_CHECK_LIB(dl, dlopen)
 877          if test "$GCC" = "yes" ; then
 878             # The GNU linker requires the -export-dynamic option to make
 879             # all symbols visible in the dynamic symbol table.
 880             hold_ldflags=$LDFLAGS
 881             AC_MSG_CHECKING(for the ld -export-dynamic flag)
 882             LDFLAGS="${LDFLAGS} -Wl,-export-dynamic"
 883             AC_TRY_LINK(, [int i;], found=yes, found=no)
 884             LDFLAGS=$hold_ldflags
 885             AC_MSG_RESULT($found)
 886             if test $found = yes; then
 887                CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -Wl,-export-dynamic"
 888             fi
 889          fi
 890          # Sun randomly tweaked the prototypes in <proc_service.h>
 891          # at one point.
 892          AC_MSG_CHECKING(if <proc_service.h> is old)
 893          AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
 894             AC_TRY_COMPILE([
 895                 #include <proc_service.h>
 896                 ps_err_e ps_pdwrite
 897                     (struct ps_prochandle*, psaddr_t, const void*, size_t);
 898             ],, gdb_cv_proc_service_is_old=no,
 899                 gdb_cv_proc_service_is_old=yes)
 900          ])
 901          AC_MSG_RESULT($gdb_cv_proc_service_is_old)
 902          if test $gdb_cv_proc_service_is_old = yes; then
 903             AC_DEFINE(PROC_SERVICE_IS_OLD)
 904          fi
 905       else
 906          AC_MSG_RESULT(no)
 907       fi
 908       ;;
 909    aix*)
 910       AC_MSG_CHECKING(for AiX thread debugging library)
 911       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
 912                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
 913                                    [#ifndef PTHDB_VERSION_3
 914                                     #error
 915                                     #endif],
 916                                    gdb_cv_have_aix_thread_debug=yes,
 917                                    gdb_cv_have_aix_thread_debug=no)])
 918       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
 919       if test $gdb_cv_have_aix_thread_debug = yes; then
 920          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
 921          CONFIG_LIB_OBS="${CONFIG_LIB_OBS} aix-thread.o"
 922          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -lpthdebug"
 923       fi
 924       ;;
 925    esac
 926    AC_SUBST(CONFIG_LDFLAGS)
 927 fi
 928
 929 dnl See if we have a thread_db header file that has TD_NOTALLOC.
 930 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
 931    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
 932                   gdb_cv_thread_db_h_has_td_notalloc,
 933      AC_TRY_COMPILE(
 934        [#include <thread_db.h>],
 935        [int i = TD_NOTALLOC;],
 936        gdb_cv_thread_db_h_has_td_notalloc=yes,
 937        gdb_cv_thread_db_h_has_td_notalloc=no
 938      )
 939    )
 940 fi
 941 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
 942   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
 943             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
 944 fi
 945
 946 dnl See if we have a sys/syscall header file that has __NR_tkill.
 947 if test "x$ac_cv_header_sys_syscall_h" = "xyes"; then
 948    AC_CACHE_CHECK([whether <sys/syscall.h> has __NR_tkill],
 949                   gdb_cv_sys_syscall_h_has_tkill,
 950      AC_TRY_COMPILE(
 951        [#include <sys/syscall.h>],
 952        [int i = __NR_tkill;],
 953        gdb_cv_sys_syscall_h_has_tkill=yes,
 954        gdb_cv_sys_syscall_h_has_tkill=no
 955      )
 956    )
 957 fi
 958 dnl See if we can issue tkill syscall.
 959 if test "x$gdb_cv_sys_syscall_h_has_tkill" = "xyes" && test "x$ac_cv_func_syscall" = "xyes"; then
 960   AC_DEFINE(HAVE_TKILL_SYSCALL, 1,
 961             [Define if we can use the tkill syscall.])
 962 fi
 963
 964 dnl Handle optional features that can be enabled.
 965
 966 AC_ARG_WITH(sysroot,
 967 [  --with-sysroot[=DIR] Search for usr/lib et al within DIR.],
 968 [
 969  case ${with_sysroot} in
 970  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
 971  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
 972  esac
 973
 974  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
 975
 976  if test "x$exec_prefix" = xNONE; then
 977   if test "x$prefix" = xNONE; then
 978    test_prefix=/usr/local
 979   else
 980    test_prefix=$prefix
 981   fi
 982  else
 983   test_prefix=$exec_prefix
 984  fi
 985  case ${TARGET_SYSTEM_ROOT} in
 986  "${test_prefix}"|"${test_prefix}/"*|\
 987  '${exec_prefix}'|'${exec_prefix}/'*)
 988    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
 989    TARGET_SYSTEM_ROOT_DEFINE="$t"
 990    ;;
 991  esac
 992 ], [
 993  TARGET_SYSTEM_ROOT=
 994  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"'
 995 ])
 996 AC_SUBST(TARGET_SYSTEM_ROOT)
 997 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
 998
 999 # NOTE: Don't add -Wall or -Wunused, they both include
1000 # -Wunused-parameter which reports bogus warnings.
1001 # NOTE: If you add to this list, remember to update
1002 # gdb/doc/gdbint.texinfo.
1003 build_warnings="-Wimplicit -Wreturn-type -Wcomment -Wtrigraphs \
1004 -Wformat -Wparentheses -Wpointer-arith -Wuninitialized -Wformat-nonliteral"
1005 # Up for debate: -Wswitch -Wcomment -trigraphs -Wtrigraphs
1006 # -Wunused-function -Wunused-label -Wunused-variable -Wunused-value
1007 # -Wchar-subscripts -Wtraditional -Wshadow -Wcast-qual
1008 # -Wcast-align -Wwrite-strings -Wconversion -Wstrict-prototypes
1009 # -Wmissing-prototypes -Wmissing-declarations -Wredundant-decls
1010 # -Woverloaded-virtual -Winline -Werror"
1011 AC_ARG_ENABLE(build-warnings,
1012 [  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
1013 [case "${enableval}" in
1014   yes)  ;;
1015   no)   build_warnings="-w";;
1016   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1017         build_warnings="${build_warnings} ${t}";;
1018   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1019         build_warnings="${t} ${build_warnings}";;
1020   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1021 esac
1022 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1023   echo "Setting compiler warning flags = $build_warnings" 6>&1
1024 fi])dnl
1025 AC_ARG_ENABLE(gdb-build-warnings,
1026 [  --enable-gdb-build-warnings Enable GDB specific build-time compiler warnings if gcc is used],
1027 [case "${enableval}" in
1028   yes)  ;;
1029   no)   build_warnings="-w";;
1030   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1031         build_warnings="${build_warnings} ${t}";;
1032   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1033         build_warnings="${t} ${build_warnings}";;
1034   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1035 esac
1036 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1037   echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1
1038 fi])dnl
1039 WARN_CFLAGS=""
1040 WERROR_CFLAGS=""
1041 if test "x${build_warnings}" != x -a "x$GCC" = xyes
1042 then
1043     AC_MSG_CHECKING(compiler warning flags)
1044     # Separate out the -Werror flag as some files just cannot be
1045     # compiled with it enabled.
1046     for w in ${build_warnings}; do
1047         case $w in
1048         -Werr*) WERROR_CFLAGS=-Werror ;;
1049         *) # Check that GCC accepts it
1050             saved_CFLAGS="$CFLAGS"
1051             CFLAGS="$CFLAGS $w"
1052             AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
1053             CFLAGS="$saved_CFLAGS"
1054         esac
1055     done
1056     AC_MSG_RESULT(${WARN_CFLAGS}${WERROR_CFLAGS})
1057 fi
1058 AC_SUBST(WARN_CFLAGS)
1059 AC_SUBST(WERROR_CFLAGS)
1060
1061 MMALLOC_CFLAGS=
1062 MMALLOC=
1063 AC_SUBST(MMALLOC_CFLAGS)
1064 AC_SUBST(MMALLOC)
1065
1066 AC_ARG_WITH(mmalloc,
1067 [  --with-mmalloc          Use memory mapped malloc package],
1068 [case "${withval}" in
1069   yes)  want_mmalloc=true ;;
1070   no)   want_mmalloc=false;;
1071   *)    AC_MSG_ERROR(bad value ${withval} for GDB with-mmalloc option) ;;
1072 esac],[want_mmalloc=false])dnl
1073
1074 if test x$want_mmalloc = xtrue; then
1075    AC_DEFINE(USE_MMALLOC)
1076    AC_DEFINE(MMCHECK_FORCE)
1077    MMALLOC_CFLAGS="-I$srcdir/../mmalloc"
1078    MMALLOC='../mmalloc/libmmalloc.a'
1079 fi
1080
1081 # In the Cygwin environment, we need some additional flags.
1082 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1083 [AC_EGREP_CPP(lose, [
1084 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1085 lose
1086 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1087
1088
1089 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1090 SER_HARDWIRE="ser-unix.o ser-pipe.o ser-tcp.o"
1091 case ${host} in
1092   *go32* ) SER_HARDWIRE=ser-go32.o ;;
1093   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
1094 esac
1095 AC_SUBST(SER_HARDWIRE)
1096
1097 # libreadline needs libuser32.a in a cygwin environment
1098 WIN32LIBS=
1099 if test x$gdb_cv_os_cygwin = xyes; then
1100     WIN32LIBS="-luser32"
1101     case "${target}" in
1102         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
1103         ;;
1104     esac
1105 fi
1106 AC_SUBST(WIN32LIBS)
1107
1108 LIBGUI="../libgui/src/libgui.a"
1109 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
1110 AC_SUBST(LIBGUI)
1111 AC_SUBST(GUI_CFLAGS_X)
1112
1113 WIN32LDAPP=
1114 AC_SUBST(WIN32LIBS)
1115 AC_SUBST(WIN32LDAPP)
1116
1117 configdir="unix"
1118
1119 GDBTKLIBS=
1120 if test "${enable_gdbtk}" = "yes"; then
1121
1122     # Gdbtk must have an absolute path to srcdir in order to run
1123     # properly when not installed.
1124     here=`pwd`
1125     cd ${srcdir}
1126     GDBTK_SRC_DIR=`pwd`
1127     cd $here
1128
1129     CY_AC_PATH_TCLCONFIG
1130     if test -z "${no_tcl}"; then
1131         CY_AC_LOAD_TCLCONFIG
1132         CY_AC_PATH_TKCONFIG
1133
1134         # now look for Tcl library stuff
1135
1136         case "${host}" in
1137         *-*-cygwin*)
1138             tcldir=../tcl/win/
1139             ;;
1140         *)
1141             tcldir=../tcl/unix/
1142             ;;
1143         esac
1144
1145         TCL_DEPS="${tcldir}${TCL_LIB_FILE}"
1146
1147         # If $no_tk is nonempty, then we can't do Tk, and there is no
1148         # point to doing Tcl.
1149         if test -z "${no_tk}"; then
1150            CY_AC_LOAD_TKCONFIG
1151            CY_AC_PATH_TCLH
1152            CY_AC_PATH_TKH
1153            CY_AC_PATH_ITCLH
1154            CY_AC_PATH_ITKH
1155
1156
1157            # now look for Tk library stuff
1158
1159            case "${host}" in
1160            *-*-cygwin*)
1161                tkdir=../tk/win/
1162                ;;
1163            *)
1164                tkdir=../tk/unix/
1165                ;;
1166            esac
1167
1168            TK_DEPS="${tkdir}${TK_LIB_FILE}"
1169
1170            # now look for Itcl library stuff
1171
1172            CY_AC_PATH_ITCLCONFIG
1173            if test -z "${no_itcl}"; then
1174              CY_AC_LOAD_ITCLCONFIG
1175
1176              ITCLLIB="${ITCL_BUILD_LIB_SPEC}"
1177              ITCL_DEPS="${ITCL_LIB_FULL_PATH}"
1178            fi
1179
1180
1181            # now look for Itk library stuff
1182            CY_AC_PATH_ITKCONFIG
1183            if test -z "${no_itcl}"; then
1184              CY_AC_LOAD_ITKCONFIG
1185
1186              ITKLIB="${ITK_BUILD_LIB_SPEC}"
1187              ITK_DEPS="${ITK_LIB_FULL_PATH}"
1188            fi
1189
1190            ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
1191            # Tcl/Tk 8.1 require -fwritable strings.  I don't
1192            # know whether 8.2 will or not, but I bet it will.
1193            # I don't have to worry about 7.x since we don't support it.
1194            GDBTK_CFLAGS=""
1195            if test "$GCC" = "yes"; then
1196                if test "$TCL_VERSION" != "8.0" ; then
1197                    GDBTK_CFLAGS="-fwritable-strings"
1198                fi
1199            fi
1200
1201            # Include some libraries that Tcl and Tk want.
1202            TCL_LIBS='$(LIBGUI) $(ITCL) $(ITK) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
1203            # Yes, the ordering seems wrong here.  But it isn't.
1204            # TK_LIBS is the list of libraries that need to be linked
1205            # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
1206            # were in LIBS then any link tests after this point would
1207            # try to include things like `$(LIBGUI)', which wouldn't work.
1208            GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
1209
1210            CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
1211            CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
1212            CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
1213            CONFIG_INITS="${CONFIG_INITS} \$(SUBDIR_GDBTK_INITS)"
1214            CONFIG_ALL="${CONFIG_ALL} \$(SUBDIR_GDBTK_ALL)"
1215            CONFIG_CLEAN="${CONFIG_CLEAN} \$(SUBDIR_GDBTK_CLEAN)"
1216            CONFIG_INSTALL="${CONFIG_INSTALL} \$(SUBDIR_GDBTK_INSTALL)"
1217            CONFIG_UNINSTALL="${CONFIG_UNINSTALL} \$(SUBDIR_GDBTK_UNINSTALL)"
1218
1219            if test x$gdb_cv_os_cygwin = xyes; then
1220               WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
1221               WIN32LDAPP="-Wl,--subsystem,console"
1222               CONFIG_OBS="${CONFIG_OBS} gdbres.o"
1223            fi
1224         fi
1225     fi
1226
1227     configdirs="${configdirs} gdbtk"
1228 fi
1229
1230 AC_SUBST(X_CFLAGS)
1231 AC_SUBST(X_LDFLAGS)
1232 AC_SUBST(X_LIBS)
1233 AC_SUBST(TCL_DEPS)
1234 AC_SUBST(TK_DEPS)
1235 AC_SUBST(ITCLLIB)
1236 AC_SUBST(ITCL_DEPS)
1237 AC_SUBST(ITKLIB)
1238 AC_SUBST(ITK_DEPS)
1239 AC_SUBST(GDBTKLIBS)
1240 AC_SUBST(GDBTK_CFLAGS)
1241 AC_SUBST(GDBTK_SRC_DIR)
1242
1243 AC_PATH_X
1244
1245
1246 # Unlike the sim directory, whether a simulator is linked is controlled by
1247 # presence of a SIM= and a SIM_OBS= definition in the target '.mt' file.
1248 # This code just checks for a few cases where we'd like to ignore those
1249 # definitions, even when they're present in the '.mt' file.  These cases
1250 # are when --disable-sim is specified, or if the simulator directory is
1251 # not part of the source tree.
1252 #
1253 AC_ARG_ENABLE(sim,
1254 [  --enable-sim            Link gdb with simulator],
1255 [echo "enable_sim = $enable_sim";
1256  echo "enableval = ${enableval}";
1257  case "${enableval}" in
1258   yes) ignore_sim=false ;;
1259   no)  ignore_sim=true ;;
1260   *)   ignore_sim=false ;;
1261  esac],
1262 [ignore_sim=false])
1263
1264 if test ! -d "${srcdir}/../sim"; then
1265   ignore_sim=true
1266 fi
1267
1268 if test "${ignore_sim}" = "true"; then
1269     IGNORE_SIM="SIM="
1270     IGNORE_SIM_OBS="SIM_OBS="
1271 else
1272     IGNORE_SIM=""
1273     IGNORE_SIM_OBS=""
1274     AC_DEFINE(WITH_SIM)
1275 fi
1276 AC_SUBST(IGNORE_SIM)
1277 AC_SUBST(IGNORE_SIM_OBS)
1278
1279 AC_SUBST(ENABLE_CFLAGS)
1280 AC_SUBST(PROFILE_CFLAGS)
1281
1282 AC_SUBST(CONFIG_OBS)
1283 AC_SUBST(CONFIG_LIB_OBS)
1284 AC_SUBST(CONFIG_DEPS)
1285 AC_SUBST(CONFIG_SRCS)
1286 AC_SUBST(CONFIG_INITS)
1287 AC_SUBST(CONFIG_ALL)
1288 AC_SUBST(CONFIG_CLEAN)
1289 AC_SUBST(CONFIG_INSTALL)
1290 AC_SUBST(CONFIG_UNINSTALL)
1291
1292 # target_subdir is used by the testsuite to find the target libraries.
1293 target_subdir=
1294 if test "${host}" != "${target}"; then
1295     target_subdir="${target_alias}/"
1296 fi
1297 AC_SUBST(target_subdir)
1298
1299 frags=
1300 host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
1301 if test ! -f ${host_makefile_frag}; then
1302     # When building a native debuger the .mh file containing things
1303     # like NATDEPFILES is needed.  Cross debuggers don't need .mh
1304     # since it no longer contains anything useful.
1305     if test "${target}" = "${host}"; then
1306         AC_MSG_ERROR("*** Gdb does not support native target ${host}")
1307     else
1308         host_makefile_frag=/dev/null
1309     fi
1310 fi
1311 frags="$frags $host_makefile_frag"
1312
1313 target_makefile_frag=${srcdir}/config/${gdb_target_cpu}/${gdb_target}.mt
1314 if test ! -f ${target_makefile_frag}; then
1315 AC_MSG_ERROR("*** Gdb does not support target ${target}")
1316 fi
1317 frags="$frags $target_makefile_frag"
1318
1319 AC_SUBST_FILE(host_makefile_frag)
1320 AC_SUBST_FILE(target_makefile_frag)
1321 AC_SUBST(frags)
1322
1323 changequote(,)dnl
1324 hostfile=`sed -n '
1325 s/XM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
1326 ' ${host_makefile_frag}`
1327
1328 targetfile=`sed -n '
1329 s/TM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
1330 ' ${target_makefile_frag}`
1331
1332 if test "${target}" = "${host}"; then
1333 # We pick this up from the host configuration file (.mh) because we
1334 # do not have a native configuration Makefile fragment.
1335 nativefile=`sed -n '
1336 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
1337 ' ${host_makefile_frag}`
1338 fi
1339 changequote([,])
1340
1341 if test x"${gdb_osabi}" != x ; then
1342     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
1343                        [Define to the default OS ABI for this configuration.])
1344 fi
1345
1346 # Enable multi-ice-gdb-server.
1347 AC_ARG_ENABLE(multi-ice,
1348 [  --enable-multi-ice      build the multi-ice-gdb-server],
1349   [case $enableval in
1350     yes | no)
1351       ;;
1352     *) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;;
1353   esac])
1354 if test "x$enable_multi_ice" = xyes; then
1355   configdirs="$configdirs multi-ice"
1356 fi
1357
1358 # We only build gdbserver automatically if host and target are the same.
1359 if test "x$target" = "x$host"; then
1360   AC_MSG_CHECKING(whether gdbserver is supported on this host)
1361   if test "x$build_gdbserver" = xyes; then
1362     configdirs="$configdirs gdbserver"
1363     AC_MSG_RESULT(yes)
1364   else
1365     AC_MSG_RESULT(no)
1366   fi
1367 fi
1368
1369 AC_CONFIG_SUBDIRS($configdirs)
1370
1371 # If hostfile (XM_FILE) and/or targetfile (TM_FILE) and/or nativefile
1372 # (NAT_FILE) is not set in config/*/*.m[ht] files, we link to an empty
1373 # version.
1374
1375 files=
1376 links=
1377
1378 rm -f xm.h
1379 xm_h=""
1380 if test "${hostfile}" != ""; then
1381     xm_h=xm.h
1382     GDB_XM_FILE="config/${gdb_host_cpu}/${hostfile}"
1383     files="${files} ${GDB_XM_FILE}"
1384     links="${links} xm.h"
1385     AC_DEFINE_UNQUOTED(GDB_XM_FILE, ${GDB_XM_FILE})
1386 fi
1387 AC_SUBST(xm_h)
1388
1389 rm -f tm.h
1390 tm_h=""
1391 if test "${targetfile}" != ""; then
1392     tm_h=tm.h
1393     GDB_TM_FILE="config/${gdb_target_cpu}/${targetfile}"
1394     files="${files} ${GDB_TM_FILE}"
1395     links="${links} tm.h"
1396     AC_DEFINE_UNQUOTED(GDB_TM_FILE, ${GDB_TM_FILE})
1397 fi
1398 AC_SUBST(tm_h)
1399
1400 rm -f nm.h
1401 nm_h=""
1402 if test "${nativefile}" != ""; then
1403     nm_h=nm.h
1404     GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}"
1405     files="${files} ${GDB_NM_FILE}"
1406     links="${links} nm.h"
1407     AC_DEFINE_UNQUOTED(GDB_NM_FILE, ${GDB_NM_FILE})
1408 fi
1409 AC_SUBST(nm_h)
1410
1411 AC_LINK_FILES($files, $links)
1412
1413 dnl Check for exe extension set on certain hosts (e.g. Win32)
1414 AC_EXEEXT
1415
1416 dnl  Detect the character set used by this host.
1417
1418 dnl  At the moment, we just assume it's ISO-8859-1 (which is a
1419 dnl  superset of ASCII containing the characters needed for French,
1420 dnl  German, Spanish, Italian, and possibly others), but if were
1421 dnl  *were* to support any host character sets other than ISO-8859-1,
1422 dnl  here's where we'd detect it.
1423 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "ISO-8859-1",
1424           [Define to be a string naming the default host character set.])
1425
1426 AM_ICONV
1427
1428 AC_OUTPUT(Makefile .gdbinit:gdbinit.in,
1429 [
1430 dnl Autoconf doesn't provide a mechanism for modifying definitions
1431 dnl provided by makefile fragments.
1432 dnl
1433 if test "${nativefile}" = ""; then
1434         < Makefile \
1435         sed -e '/^NATDEPFILES[[         ]]*=.*\\$/,/[[^\\]]$/s/^/# /' \
1436             -e '/^NATDEPFILES[[         ]]*=/s/^/# /' \
1437         | sed -e '/^\(NATDEPFILES[[     ]]*[[+]]=[[     ]]*\)/s//# \1/' \
1438         > Makefile.tem
1439 mv -f Makefile.tem Makefile
1440 fi
1441
1442 changequote(,)dnl
1443 sed -e '/^TM_FILE[      ]*=/s,^TM_FILE[         ]*=[    ]*,&config/'"${gdb_target_cpu}"'/,
1444 /^XM_FILE[      ]*=/s,^XM_FILE[         ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,
1445 /^NAT_FILE[     ]*=/s,^NAT_FILE[        ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,' <Makefile >Makefile.tmp
1446 mv -f Makefile.tmp Makefile
1447 changequote([,])dnl
1448
1449
1450 case x$CONFIG_HEADERS in
1451 xconfig.h:config.in)
1452 echo > stamp-h ;;
1453 esac
1454 ],
1455 [
1456 gdb_host_cpu=$gdb_host_cpu
1457 gdb_target_cpu=$gdb_target_cpu
1458 nativefile=$nativefile
1459 ])
1460
1461 exit 0