* configure.in: Only set host_makefile_frag when building a native
[external/binutils.git] / gdb / configure.in
1 dnl Autoconf configure script for GDB, the GNU debugger.
2 dnl Copyright 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004
3 dnl Free Software Foundation, Inc.
4 dnl
5 dnl This file is part of GDB.
6 dnl 
7 dnl This program is free software; you can redistribute it and/or modify
8 dnl it under the terms of the GNU General Public License as published by
9 dnl the Free Software Foundation; either version 2 of the License, or
10 dnl (at your option) any later version.
11 dnl 
12 dnl This program is distributed in the hope that it will be useful,
13 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
14 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 dnl GNU General Public License for more details.
16 dnl 
17 dnl You should have received a copy of the GNU General Public License
18 dnl along with this program; if not, write to the Free Software
19 dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
20
21 dnl Process this file with autoconf to produce a configure script.
22
23 AC_PREREQ(2.13)dnl
24 AC_INIT(main.c)
25 AC_CONFIG_HEADER(config.h:config.in)
26 AM_MAINTAINER_MODE
27
28 AC_PROG_CC
29 AC_GNU_SOURCE
30 AC_AIX
31 AC_ISC_POSIX
32 AM_PROG_CC_STDC
33
34 AC_CONFIG_AUX_DIR(`cd $srcdir;pwd`/..)
35 AC_CANONICAL_SYSTEM
36
37 # FIXME: kettenis/20030102: The AC_PROG_RANLIB from Autoconf 2.13
38 # doesn't support cross-compilation, but the one from Autoconf 2.5x
39 # does.  Override RANLIB here (i.e. before running AC_PROG_RANLIB) to
40 # deal with the lossage.  Note that CY_GNU_GETTEXT currently calls
41 # AC_PROG_RANLIB.  This can be removed when we switch to Autoconf
42 # 2.5x.
43 AC_CHECK_TOOL(RANLIB, ranlib, :)
44
45 dnl List of object files and targets accumulated by configure.
46
47 CONFIG_OBS=
48 CONFIG_DEPS=
49 CONFIG_SRCS=
50 ENABLE_CFLAGS=
51
52 CONFIG_ALL=
53 CONFIG_CLEAN=
54 CONFIG_INSTALL=
55 CONFIG_UNINSTALL=
56
57 dnl Set up for gettext.  PACKAGE is used when we call bindtextdomain.
58
59 CY_GNU_GETTEXT
60
61 localedir='${datadir}/locale'
62 AC_SUBST(localedir)
63
64 if test "x$POSUB" != x; then
65
66   dnl Lifted from GCC's config/gettext.m4.
67   AC_MSG_CHECKING(for catalogs to be installed)
68   # Look for .po and .gmo files in the source directory.
69   CATALOGS=  AC_SUBST(CATALOGS)
70   XLINGUAS=
71   for cat in $srcdir/po/*.gmo $srcdir/po/*.po; do
72     # If there aren't any .gmo files the shell will give us the
73     # literal string "../path/to/srcdir/po/*.gmo" which has to be
74     # weeded out.
75     case "$cat" in *\**)
76       continue;;
77     esac
78     # The quadruple backslash is collapsed to a double backslash
79     # by the backticks, then collapsed again by the double quotes,
80     # leaving us with one backslash in the sed expression (right
81     # before the dot that mustn't act as a wildcard).
82     cat=`echo $cat | sed -e "s!$srcdir/!!" -e "s!\\\\.po!.gmo!"`
83     lang=`echo $cat | sed -e 's!po/!!' -e "s!\\\\.gmo!!"`
84     # The user is allowed to set LINGUAS to a list of languages to
85     # install catalogs for.  If it's empty that means "all of them."
86     if test "x$LINGUAS" = x; then
87       CATALOGS="$CATALOGS $cat"
88       XLINGUAS="$XLINGUAS $lang"
89     else
90       case "$LINGUAS" in *$lang*)
91         CATALOGS="$CATALOGS $cat"
92         XLINGUAS="$XLINGUAS $lang"
93         ;;
94       esac
95     fi
96   done
97   LINGUAS="$XLINGUAS"
98   AC_MSG_RESULT($LINGUAS)
99
100    CONFIG_ALL="$CONFIG_ALL all-po"
101    CONFIG_CLEAN="$CONFIG_CLEAN clean-po"                   
102    CONFIG_INSTALL="$CONFIG_INSTALL install-po"
103    CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
104 fi
105
106 PACKAGE=gdb
107 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
108 AC_SUBST(PACKAGE)
109
110 debugdir=${libdir}/debug
111          
112 AC_ARG_WITH(separate-debug-dir,
113 [  --with-separate-debug-dir=path   Look for global separate debug info in this path [LIBDIR/debug]],
114 [debugdir="${withval}"])
115         
116 AC_DEFINE_DIR(DEBUGDIR, debugdir,
117               [Global directory for separate debug files. ])
118 #AC_DEFINE_UNQUOTED(DEBUGDIR, "$debugdir"),
119
120 AC_CONFIG_SUBDIRS(doc testsuite)
121 configdirs=
122
123 . $srcdir/configure.host
124
125 . $srcdir/configure.tgt
126
127 # Fetch the default architecture and default target vector from BFD.
128 targ=$target; . $srcdir/../bfd/config.bfd
129
130 # We only want the first architecture, so strip off the others if
131 # there is more than one.
132 targ_archs=`echo $targ_archs | sed 's/ .*//'`
133
134 if test "x$targ_archs" != x; then
135   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
136     [Define to BFD's default architecture. ])
137 fi
138 if test "x$targ_defvec" != x; then
139   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
140     [Define to BFD's default target vector. ])
141 fi
142
143 AC_ARG_PROGRAM
144
145 # The CLI cannot be disabled yet, but may be in the future.
146
147 # Enable CLI.
148 AC_ARG_ENABLE(gdbcli,
149 [  --disable-gdbcli        disable command-line interface (CLI)],
150   [case $enableval in
151     yes)
152       ;;
153     no)
154       AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;;
155     *)
156       AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;;
157   esac],
158   [enable_gdbcli=yes])
159 if test x"$enable_gdbcli" = xyes; then
160   if test -d $srcdir/cli; then
161     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)"
162     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)"
163     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)"
164     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)"
165   fi
166 fi
167
168 # Enable MI.
169 AC_ARG_ENABLE(gdbmi,
170 [  --disable-gdbmi         disable machine-interface (MI)],
171   [case $enableval in
172     yes | no)
173       ;;
174     *)
175       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
176   esac],
177   [enable_gdbmi=yes])
178 if test x"$enable_gdbmi" = xyes; then
179   if test -d $srcdir/mi; then
180     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
181     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
182     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
183     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
184   fi
185 fi
186
187 # Enable TUI.
188 AC_ARG_ENABLE(tui,
189 [  --enable-tui            enable full-screen terminal user interface (TUI)],
190   [case $enableval in
191     yes | no)
192       ;;
193     *)
194       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
195   esac],enable_tui=yes)
196 if test x"$enable_tui" = xyes; then
197   if test -d $srcdir/tui; then
198     if test "$ac_cv_search_waddstr" != no; then
199       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
200       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
201       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
202       CONFIG_INITS="$CONFIG_INITS \$(SUBDIR_TUI_INITS)"
203       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
204       CONFIG_ALL="${CONFIG_ALL} all-tui"
205       CONFIG_CLEAN="${CONFIG_CLEAN} clean-tui"
206       CONFIG_INSTALL="${CONFIG_INSTALL} install-tui"
207       CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-tui"
208     fi
209   fi
210 fi
211
212 # Enable gdbtk.
213 AC_ARG_ENABLE(gdbtk,
214 [  --enable-gdbtk          enable gdbtk graphical user interface (GUI)],
215   [case $enableval in
216     yes | no)
217       ;;
218     *)
219       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
220   esac],
221   [if test -d $srcdir/gdbtk; then
222     enable_gdbtk=yes
223   else
224     enable_gdbtk=no
225   fi])
226 # We unconditionally disable gdbtk tests on selected platforms.
227 case $host_os in
228   go32* | windows*)
229     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
230     enable_gdbtk=no ;;
231 esac
232
233 # Libunwind support.
234 AC_ARG_WITH(libunwind,
235 [  --with-libunwind            Use libunwind frame unwinding support],
236 [case "${withval}" in
237   yes)  enable_libunwind=yes ;;
238   no)   enable_libunwind=no ;;
239   *)    AC_MSG_ERROR(bad value ${withval} for GDB with-libunwind option) ;;
240 esac],[
241   AC_CHECK_HEADERS(libunwind.h)
242   AC_CHECK_HEADERS(libunwind-ia64.h)
243   if test x"$ac_cv_header_libunwind_h" = xyes -a x"$ac_cv_header_libunwind_ia64_h" = xyes; then
244     enable_libunwind=yes;
245   fi
246 ])
247    
248 if test x"$enable_libunwind" = xyes; then
249   AC_CHECK_HEADERS(libunwind.h)
250   AC_CHECK_HEADERS(libunwind-ia64.h)
251   AC_DEFINE(HAVE_LIBUNWIND, 1)
252   CONFIG_OBS="$CONFIG_OBS libunwind-frame.o"
253   CONFIG_DEPS="$CONFIG_DEPS libunwind-frame.o"
254   CONFIG_SRCS="$CONFIG_SRCS libunwind-frame.c"
255 fi
256
257 # Profiling support.
258 AC_ARG_ENABLE(profiling,
259 [  --enable-profiling      enable profiling of GDB],
260   [case $enableval in
261     yes | no)
262       ;;
263     *)
264       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
265   esac],
266  [enable_profiling=no])
267
268 AC_CHECK_FUNCS(monstartup _mcleanup)
269 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
270 [AC_TRY_LINK(
271 [#include <stdlib.h>
272 extern char _etext;
273 ],
274 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
275 if test $ac_cv_var__etext = yes; then
276   AC_DEFINE(HAVE__ETEXT, 1,
277             [Define to 1 if your system has the _etext variable. ])
278 fi
279 if test "$enable_profiling" = yes ; then
280   if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
281     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
282   fi
283   PROFILE_CFLAGS=-pg
284   OLD_CFLAGS="$CFLAGS"
285   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
286
287   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
288     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
289      ac_cv_cc_supports_pg=no)])
290
291   if test $ac_cv_cc_supports_pg = no; then
292     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
293   fi
294
295   CFLAGS="$OLD_CFLAGS"
296 fi
297
298 # --------------------- #
299 # Checks for programs.  #
300 # --------------------- #
301
302 AC_PROG_AWK
303 AC_PROG_INSTALL
304 AC_PROG_LN_S
305 AC_PROG_RANLIB
306 AC_PROG_YACC
307
308 AC_CHECK_TOOL(AR, ar)
309 AC_CHECK_TOOL(DLLTOOL, dlltool)
310 AC_CHECK_TOOL(WINDRES, windres)
311
312 # Needed for GNU/Hurd.
313 AC_CHECK_TOOL(MIG, mig)
314
315 # ---------------------- #
316 # Checks for libraries.  #
317 # ---------------------- #
318
319 # We might need to link with -lm; most simulators need it.
320 AC_CHECK_LIB(m, main)
321
322 # We need to link with -lw to get `wctype' on Solaris before Solaris
323 # 2.6.  Solaris 2.6 and beyond have this function in libc, and have a
324 # libw that some versions of the GNU linker cannot hanle (GNU ld 2.9.1
325 # is known to have this problem).  Therefore we avoid libw if we can.
326 AC_CHECK_FUNC(wctype, [],
327   [AC_CHECK_LIB(w, wctype)])
328
329 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
330 AC_SEARCH_LIBS(gethostbyname, nsl)
331
332 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
333 AC_SEARCH_LIBS(socketpair, socket)
334
335 # For the TUI, we need enhanced curses functionality.
336 #
337 # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
338 # curses library because the latter might not provide all the
339 # functionality we need.  However, this leads to problems on systems
340 # where the linker searches /usr/local/lib, but the compiler doesn't
341 # search /usr/local/include, if ncurses is installed in /usr/local.  A
342 # default installation of ncurses on alpha*-dec-osf* will lead to such
343 # a situation.
344 AC_SEARCH_LIBS(waddstr, [ncurses cursesX curses])
345
346 if test "$ac_cv_search_waddstr" = no; then
347   AC_MSG_WARN([no curses library found])
348 fi
349
350 # Since GDB uses Readline, we need termcap functionality.  In many
351 # cases this will be provided by the curses library, but some systems
352 # have a seperate termcap library, or no curses library at all.
353
354 case $host_os in
355   cygwin*)
356     if test -d $srcdir/libtermcap; then
357       LIBS="../libtermcap/libtermcap.a $LIBS"
358       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
359     fi ;;
360   go32* | *djgpp*)
361     ac_cv_search_tgetent="none required"
362     ;;
363 esac
364
365 # These are the libraries checked by Readline.
366 AC_SEARCH_LIBS(tgetent, [termcap tinfo curses ncurses])
367
368 if test "$ac_cv_search_tgetent" = no; then
369   AC_MSG_ERROR([no termcap library found])
370 fi
371
372 # ------------------------- #
373 # Checks for header files.  #
374 # ------------------------- #
375
376 AC_HEADER_DIRENT
377 AC_HEADER_STAT
378 AC_HEADER_STDC
379 AC_CHECK_HEADERS(link.h)
380 AC_CHECK_HEADERS(machine/reg.h)
381 AC_CHECK_HEADERS(nlist.h)
382 AC_CHECK_HEADERS(poll.h sys/poll.h)
383 AC_CHECK_HEADERS(proc_service.h thread_db.h gnu/libc-version.h)
384 AC_CHECK_HEADERS(stddef.h)
385 AC_CHECK_HEADERS(stdlib.h)
386 AC_CHECK_HEADERS(stdint.h)
387 AC_CHECK_HEADERS(string.h memory.h strings.h)
388 AC_CHECK_HEADERS(sys/fault.h)
389 AC_CHECK_HEADERS(sys/file.h)
390 AC_CHECK_HEADERS(sys/filio.h)
391 AC_CHECK_HEADERS(sys/ioctl.h)
392 AC_CHECK_HEADERS(sys/param.h)
393 AC_CHECK_HEADERS(sys/proc.h)
394 AC_CHECK_HEADERS(sys/procfs.h)
395 AC_CHECK_HEADERS(sys/ptrace.h ptrace.h)
396 AC_CHECK_HEADERS(sys/reg.h sys/debugreg.h)
397 AC_CHECK_HEADERS(sys/select.h)
398 AC_CHECK_HEADERS(sys/syscall.h)
399 AC_CHECK_HEADERS(sys/types.h)
400 AC_CHECK_HEADERS(sys/user.h)
401 AC_CHECK_HEADERS(sys/wait.h wait.h)
402 AC_CHECK_HEADERS(termios.h termio.h sgtty.h)
403 AC_CHECK_HEADERS(unistd.h)
404
405 # On Solaris 2.[789], we need to define _MSE_INT_H to avoid a clash
406 # between <widec.h> and <wchar.h> that would cause AC_CHECK_HEADERS to
407 # think that we don't have <curses.h> if we're using GCC.
408 case $host_os in
409   solaris2.[[789]])
410     if test "$GCC" = yes; then
411       AC_DEFINE(_MSE_INT_H, 1,
412         [[Define to 1 to avoid a clash between <widec.h> and <wchar.h> on
413    Solaris 2.[789] when using GCC. ]])
414     fi ;;
415 esac
416 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncurses/ncurses.h term.h)
417
418 # FIXME: kettenis/20030102: In most cases we include these
419 # unconditionally, so what's the point in checking these?
420 AC_CHECK_HEADERS(ctype.h time.h)
421
422 dnl Check for struct stat with an st_blocks member
423 AC_MSG_CHECKING(for member st_blocks in struct stat)
424 AC_CACHE_VAL(gdb_cv_have_struct_stat_with_st_blocks_member,
425   [AC_TRY_COMPILE([#include <sys/types.h>
426 #include <sys/stat.h>],
427                   [struct stat st; (void) st.st_blocks;],
428                   gdb_cv_have_struct_stat_with_st_blocks_member=yes,
429                   gdb_cv_have_struct_stat_with_st_blocks_member=no)])
430 AC_MSG_RESULT($gdb_cv_have_struct_stat_with_st_blocks_member)
431 if test $gdb_cv_have_struct_stat_with_st_blocks_member = yes; then
432   AC_DEFINE(HAVE_STRUCT_STAT_ST_BLOCKS)
433 fi
434
435 # ------------------------- #
436 # Checks for declarations.  #
437 # ------------------------- #
438
439 gcc_AC_CHECK_DECLS(getopt)
440
441 # ------------------ #
442 # Checks for types.  #
443 # ------------------ #
444
445 AC_TYPE_SIGNAL
446
447 # ------------------------------------- #
448 # Checks for compiler characteristics.  #
449 # ------------------------------------- #
450
451 AC_C_CONST
452 AC_C_INLINE
453
454 # ------------------------------ #
455 # Checks for library functions.  #
456 # ------------------------------ #
457
458 AC_FUNC_ALLOCA
459 AC_FUNC_MMAP
460 AC_FUNC_VFORK
461 AC_CHECK_FUNCS(canonicalize_file_name realpath)
462 AC_CHECK_FUNCS(poll)
463 AC_CHECK_FUNCS(pread64)
464 AC_CHECK_FUNCS(sbrk)
465 AC_CHECK_FUNCS(setpgid setpgrp)
466 AC_CHECK_FUNCS(sigaction sigprocmask sigsetmask)
467 AC_CHECK_FUNCS(socketpair)
468 AC_CHECK_FUNCS(syscall)
469 AC_CHECK_FUNCS(ttrace)
470 AC_CHECK_FUNCS(wborder)
471
472 # Check the return and argument types of ptrace.  No canned test for
473 # this, so roll our own.
474 gdb_ptrace_headers='
475 #if HAVE_SYS_TYPES_H
476 # include <sys/types.h>
477 #endif
478 #if HAVE_SYS_PTRACE_H
479 # include <sys/ptrace.h>
480 #endif
481 #if HAVE_UNISTD_H
482 # include <unistd.h>
483 #endif
484 '
485 # There is no point in checking if we don't have a prototype.
486 gcc_AC_CHECK_DECLS(ptrace, , [
487   : ${gdb_cv_func_ptrace_ret='int'}
488   : ${gdb_cv_func_ptrace_args='int,int,long,long'}
489 ], $gdb_ptrace_headers)
490 # Check return type.
491 AC_CACHE_CHECK([return type of ptrace], gdb_cv_func_ptrace_ret,
492   AC_TRY_COMPILE($gdb_ptrace_headers,
493     [extern int ptrace ();],
494     gdb_cv_func_ptrace_ret='int',
495     gdb_cv_func_ptrace_ret='long'))
496 AC_DEFINE_UNQUOTED(PTRACE_TYPE_RET, $gdb_cv_func_ptrace_ret,
497   [Define as the return type of ptrace.])
498 # Check argument types.
499 AC_CACHE_CHECK([types of arguments for ptrace], gdb_cv_func_ptrace_args, [
500 for gdb_arg1 in 'int' 'long'; do
501  for gdb_arg2 in 'pid_t' 'int' 'long'; do
502   for gdb_arg3 in 'int *' 'caddr_t' 'int' 'long'; do
503    for gdb_arg4 in 'int' 'long'; do
504      AC_TRY_COMPILE($gdb_ptrace_headers, [
505 extern $gdb_cv_func_ptrace_ret
506   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4);
507 ], [gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4";
508     break 4;])
509     for gdb_arg5 in 'int *' 'int' 'long'; do
510      AC_TRY_COMPILE($gdb_ptrace_headers, [
511 extern $gdb_cv_func_ptrace_ret
512   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4, $gdb_arg5);
513 ], [
514 gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4,$gdb_arg5";
515     break 5;])
516     done
517    done
518   done
519  done
520 done
521 # Provide a safe default value.
522 : ${gdb_cv_func_ptrace_args='int,int,long,long'}
523 ])
524 ac_save_IFS=$IFS; IFS=','
525 set dummy `echo "$gdb_cv_func_ptrace_args" | sed 's/\*/\*/g'`
526 IFS=$ac_save_IFS
527 shift
528 AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG3, $[3],
529   [Define to the type of arg 3 for ptrace.])
530 if test -n "$[5]"; then
531   AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG5, $[5],
532     [Define to the type of arg 5 for ptrace.])
533 fi
534
535 dnl AC_FUNC_SETPGRP does not work when cross compiling
536 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
537 if test "$cross_compiling" = no; then
538   AC_FUNC_SETPGRP
539 else
540   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
541     [AC_TRY_COMPILE([
542 #include <unistd.h>
543 ], [
544   if (setpgrp(1,1) == -1)
545     exit (0);
546   else
547     exit (1);
548 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
549 if test $ac_cv_func_setpgrp_void = yes; then
550   AC_DEFINE(SETPGRP_VOID, 1)
551 fi
552 fi
553
554 # Check if sigsetjmp is available.  Using AC_CHECK_FUNCS won't do
555 # since sigsetjmp might only be defined as a macro.
556 AC_CACHE_CHECK([for sigsetjmp], gdb_cv_func_sigsetjmp,
557 [AC_TRY_COMPILE([
558 #include <setjmp.h>
559 ], [sigjmp_buf env; while (! sigsetjmp (env, 1)) siglongjmp (env, 1);],
560 gdb_cv_func_sigsetjmp=yes, gdb_cv_func_sigsetjmp=no)])
561 if test $gdb_cv_func_sigsetjmp = yes; then
562   AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available. ])
563 fi
564
565 # Assume we'll default to using the included libiberty regex.
566 gdb_use_included_regex=yes
567
568 # However, if the system regex is GNU regex, then default to *not*
569 # using the included regex.
570 AC_CACHE_CHECK(
571   [for GNU regex],
572   [gdb_cv_have_gnu_regex],
573   [AC_TRY_COMPILE(
574     [#include <gnu-versions.h>],
575     [#define REGEX_INTERFACE_VERSION 1
576 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
577 # error "Version mismatch"
578 #endif],
579     gdb_cv_have_gnu_regex=yes,
580     gdb_cv_have_gnu_regex=no)])
581 if test $gdb_cv_have_gnu_regex = yes; then
582   gdb_use_included_regex=no
583 fi
584
585 AC_ARG_WITH(included-regex,
586   [  --without-included-regex don't use included regex; this is the default
587                           on systems with version 2 of the GNU C library
588                           (use with caution on other system)],
589   gdb_with_regex=$withval,
590   gdb_with_regex=$gdb_use_included_regex)
591 if test "$gdb_with_regex" = yes; then
592   AC_DEFINE(USE_INCLUDED_REGEX, 1,
593     [Define to 1 if the regex included in libiberty should be used.])
594 fi
595
596 # See if <sys/proc.h> defines `struct thread' with a td_pcb member.
597 AC_CACHE_CHECK([for td_pcb in struct thread], gdb_cv_struct_thread_td_pcb,
598 [AC_TRY_COMPILE([#include <sys/param.h>
599 #include <sys/proc.h>], [struct thread td; td.td_pcb;],
600 gdb_cv_struct_thread_td_pcb=yes, gdb_cv_struct_thread_td_pcb=no)])
601 if test $gdb_cv_struct_thread_td_pcb = yes; then
602   AC_DEFINE(HAVE_STRUCT_THREAD_TD_PCB, 1,
603             [Define to 1 if your system has td_pcb in struct thread.])
604 fi
605
606 # See if <sys/lwp.h> defines `struct lwp`.
607 AC_CACHE_CHECK([for struct lwp], gdb_cv_struct_lwp,
608 [AC_TRY_COMPILE([#include <sys/param.h>
609 #include <sys/lwp.h>], [struct lwp l;],
610 gdb_cv_struct_lwp=yes, gdb_cv_struct_lwp=no)])
611 if test $gdb_cv_struct_lwp = yes; then
612   AC_DEFINE(HAVE_STRUCT_LWP, 1,
613             [Define to 1 if your system has struct lwp.])
614 fi
615
616 # See if <machine/reg.h> degines `struct reg'.
617 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
618 [AC_TRY_COMPILE([#include <sys/types.h>
619 #include <machine/reg.h>], [struct reg r;],
620 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
621 if test $gdb_cv_struct_reg = yes; then
622   AC_DEFINE(HAVE_STRUCT_REG, 1,
623             [Define to 1 if your system has struct reg in <machine/reg.h>.])
624 fi
625
626 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
627 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
628 AC_CACHE_CHECK([for r_fs in struct reg], gdb_cv_struct_reg_r_fs,
629 [AC_TRY_COMPILE([#include <machine/reg.h>], [struct reg r; r.r_fs;],
630 gdb_cv_struct_reg_r_fs=yes, gdb_cv_struct_reg_r_fs=no)])
631 if test $gdb_cv_struct_reg_r_fs = yes; then
632   AC_DEFINE(HAVE_STRUCT_REG_R_FS)
633 fi
634 AC_CACHE_CHECK([for r_gs in struct reg], gdb_cv_struct_reg_r_gs,
635 [AC_TRY_COMPILE([#include <machine/reg.h>], [struct reg r; r.r_gs;],
636 gdb_cv_struct_reg_r_gs=yes, gdb_cv_struct_reg_r_gs=no)])
637 if test $gdb_cv_struct_reg_r_gs = yes; then
638   AC_DEFINE(HAVE_STRUCT_REG_R_GS)
639 fi
640
641 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
642 AC_MSG_CHECKING(for PTRACE_GETREGS)
643 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
644 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
645                 [PTRACE_GETREGS;],
646                 [gdb_cv_have_ptrace_getregs=yes],
647                 [gdb_cv_have_ptrace_getregs=no])])
648 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
649 if test $gdb_cv_have_ptrace_getregs = yes; then
650   AC_DEFINE(HAVE_PTRACE_GETREGS)
651 fi
652
653 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
654 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
655 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
656 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
657                 [PTRACE_GETFPXREGS;],
658                 [gdb_cv_have_ptrace_getfpxregs=yes],
659                 [gdb_cv_have_ptrace_getfpxregs=no])])
660 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
661 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
662   AC_DEFINE(HAVE_PTRACE_GETFPXREGS)
663 fi
664
665 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
666 AC_MSG_CHECKING(for PT_GETDBREGS)
667 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
668 [AC_TRY_COMPILE([#include <sys/types.h>
669 #include <sys/ptrace.h>],
670                 [PT_GETDBREGS;],
671                 [gdb_cv_have_pt_getdbregs=yes],
672                 [gdb_cv_have_pt_getdbregs=no])])
673 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
674 if test $gdb_cv_have_pt_getdbregs = yes; then
675   AC_DEFINE(HAVE_PT_GETDBREGS)
676 fi
677
678 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
679 AC_MSG_CHECKING(for PT_GETXMMREGS)
680 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
681 [AC_TRY_COMPILE([#include <sys/types.h>
682 #include <sys/ptrace.h>],
683                 [PT_GETXMMREGS;],
684                 [gdb_cv_have_pt_getxmmregs=yes],
685                 [gdb_cv_have_pt_getxmmregs=no])])
686 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
687 if test $gdb_cv_have_pt_getxmmregs = yes; then
688   AC_DEFINE(HAVE_PT_GETXMMREGS)
689 fi
690
691 # See if stdint.h provides the uintptr_t type.
692 # Autoconf 2.5X has an improved AC_CHECK_TYPE which will simplify this.
693 AC_CACHE_CHECK([for uintptr_t in stdint.h], gdb_cv_have_uintptr_t,
694   [AC_TRY_COMPILE(
695     [#include <stdint.h>],
696     [uintptr_t foo = 0;],
697     gdb_cv_have_uintptr_t=yes,
698     gdb_cv_have_uintptr_t=no)])
699 if test $gdb_cv_have_uintptr_t = yes; then
700   AC_DEFINE(HAVE_UINTPTR_T, 1, [Define if <stdint.h> provides the uintptr_t type.])
701 fi
702
703 BFD_NEED_DECLARATION(malloc)
704 BFD_NEED_DECLARATION(realloc)
705 BFD_NEED_DECLARATION(free)
706 BFD_NEED_DECLARATION(strerror)
707 BFD_NEED_DECLARATION(strdup)
708 BFD_NEED_DECLARATION(strstr)
709 BFD_NEED_DECLARATION(canonicalize_file_name)
710
711 # The following save_state_t checkery is only necessary for HPUX 
712 # versions earlier than 10.20.  When those fade from memory, this 
713 # could be expunged. --jsm 1999-03-22
714
715 AC_MSG_CHECKING(for HPUX save_state structure)
716 AC_EGREP_HEADER(save_state_t, machine/save_state.h, 
717                 gdb_cv_hpux_savestate=yes, gdb_cv_hpux_savestate=no)
718 AC_EGREP_HEADER(ss_wide, machine/save_state.h, gdb_cv_hpux_sswide=yes,
719                 gdb_cv_hpux_sswide=no)
720 if test $gdb_cv_hpux_savestate = yes
721 then
722   AC_DEFINE(HAVE_STRUCT_SAVE_STATE_T, 1)
723 fi
724 if test $gdb_cv_hpux_sswide = yes
725 then
726   AC_DEFINE(HAVE_STRUCT_MEMBER_SS_WIDE, 1)
727 fi
728 AC_MSG_RESULT($gdb_cv_hpux_sswide)
729
730
731 # If we are configured native on GNU/Linux, work around problems with
732 # sys/procfs.h
733 # Also detect which type of /proc is in use, such as for Unixware or Solaris.
734
735 if test "${target}" = "${host}"; then
736   case "${host}" in
737   i[[3456]]86-*-linux*)
738         AC_DEFINE(START_INFERIOR_TRAPS_EXPECTED,2)
739         AC_DEFINE(sys_quotactl)
740         ;;
741   ia64-*-aix*)
742       AC_DEFINE(NEW_PROC_API)
743       ;;
744   *-*-unixware* | *-*-sysv4.2* | *-*-sysv5* | *-*-interix* )
745       AC_DEFINE(NEW_PROC_API)
746       ;;
747   *-*-solaris2.[[6789]])
748       AC_DEFINE(NEW_PROC_API)
749       ;;
750   mips-sgi-irix5*)
751       # Work around <sys/proc.h> needing _KMEMUSER problem on IRIX 5.
752       AC_DEFINE([_KMEMUSER], 1)
753       ;;
754   esac
755 fi
756
757 if test "$ac_cv_header_sys_procfs_h" = yes; then
758   BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
759   BFD_HAVE_SYS_PROCFS_TYPE(prrun_t)
760   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
761   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
762   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
763   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
764   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
765   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset32_t)
766   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
767   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
768   BFD_HAVE_SYS_PROCFS_TYPE(prsysent_t)
769   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigset_t)
770   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigaction64_t)
771   BFD_HAVE_SYS_PROCFS_TYPE(pr_siginfo64_t)
772
773
774   dnl Check for broken prfpregset_t type
775
776   dnl For Linux/i386, glibc 2.1.3 was released with a bogus
777   dnl prfpregset_t type (it's a typedef for the pointer to a struct
778   dnl instead of the struct itself).  We detect this here, and work
779   dnl around it in gdb_proc_service.h.
780
781   if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
782     AC_MSG_CHECKING(whether prfpregset_t type is broken)
783     AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
784       [AC_TRY_RUN([#include <sys/procfs.h>
785        int main ()
786        {
787          if (sizeof (prfpregset_t) == sizeof (void *))
788            return 1;
789          return 0;
790        }],
791        gdb_cv_prfpregset_t_broken=no,
792        gdb_cv_prfpregset_t_broken=yes,
793        gdb_cv_prfpregset_t_broken=yes)])
794     AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
795     if test $gdb_cv_prfpregset_t_broken = yes; then
796       AC_DEFINE(PRFPREGSET_T_BROKEN)
797     fi
798   fi
799
800   dnl Check for PIOCSET ioctl entry 
801
802   AC_MSG_CHECKING(for PIOCSET ioctl entry in sys/procfs.h)
803   AC_CACHE_VAL(gdb_cv_have_procfs_piocset,
804   [AC_TRY_COMPILE([#include <unistd.h>
805 #include <sys/types.h>
806 #include <sys/procfs.h>
807 ], [
808     int dummy;;
809     dummy = ioctl(0, PIOCSET, &dummy);
810   ],
811   gdb_cv_have_procfs_piocset=yes, gdb_cv_have_procfs_piocset=no)])
812   AC_MSG_RESULT($gdb_cv_have_procfs_piocset)
813   if test $gdb_cv_have_procfs_piocset = yes; then
814     AC_DEFINE(HAVE_PROCFS_PIOCSET)
815   fi
816 fi
817
818 dnl For native ports (host == target), check to see what kind of
819 dnl legacy link.h support is needed.  (See solib-legacy.c.)
820 if test ${host} = ${target} ; then
821   dnl Check for struct link_map with l_ members which are indicative
822   dnl of SVR4-like shared libraries
823
824   AC_MSG_CHECKING(for member l_addr in struct link_map)
825   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_l_members,
826     [AC_TRY_COMPILE([#include <link.h>],
827                     [struct link_map lm; (void) lm.l_addr;],
828                     gdb_cv_have_struct_link_map_with_l_members=yes,
829                     gdb_cv_have_struct_link_map_with_l_members=no)])
830   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_l_members)
831   if test $gdb_cv_have_struct_link_map_with_l_members = yes; then
832     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_L_MEMBERS)
833   fi
834
835   dnl Check for struct link_map with lm_ members which are indicative
836   dnl of SunOS-like shared libraries
837
838   AC_MSG_CHECKING(for member lm_addr in struct link_map)
839   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_lm_members,
840     [AC_TRY_COMPILE([#include <sys/types.h>
841 #include <link.h>],
842                     [struct link_map lm; (void) lm.lm_addr;],
843                     gdb_cv_have_struct_link_map_with_lm_members=yes,
844                     gdb_cv_have_struct_link_map_with_lm_members=no)])
845   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_lm_members)
846   if test $gdb_cv_have_struct_link_map_with_lm_members = yes; then
847     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_LM_MEMBERS)
848   fi
849
850   dnl Check for struct so_map with som_ members which are found on 
851   dnl some *BSD systems.
852
853   AC_MSG_CHECKING(for member som_addr in struct so_map)
854   AC_CACHE_VAL(gdb_cv_have_struct_so_map_with_som_members,
855     [AC_TRY_COMPILE([#include <sys/types.h>
856 #ifdef HAVE_NLIST_H
857 #include <nlist.h>
858 #endif
859 #include <link.h>],
860                     [struct so_map lm; (void) lm.som_addr;],
861                     gdb_cv_have_struct_so_map_with_som_members=yes,
862                     gdb_cv_have_struct_so_map_with_som_members=no)])
863   AC_MSG_RESULT($gdb_cv_have_struct_so_map_with_som_members)
864   if test $gdb_cv_have_struct_so_map_with_som_members = yes; then
865     AC_DEFINE(HAVE_STRUCT_SO_MAP_WITH_SOM_MEMBERS)
866   fi
867
868   dnl Check for struct link_map32 type, which allows a 64-bit Solaris
869   dnl debugger to debug a 32-bit Solaris app with 32-bit shared libraries.
870
871   AC_MSG_CHECKING(for struct link_map32 in sys/link.h)
872   AC_CACHE_VAL(gdb_cv_have_struct_link_map32, 
873     [AC_TRY_COMPILE([#define _SYSCALL32
874 #include <sys/link.h>], [struct link_map32 l;],
875      gdb_cv_have_struct_link_map32=yes,
876      gdb_cv_have_struct_link_map32=no)])
877   AC_MSG_RESULT($gdb_cv_have_struct_link_map32)
878   if test $gdb_cv_have_struct_link_map32 = yes; then
879     AC_DEFINE(HAVE_STRUCT_LINK_MAP32)
880     AC_DEFINE(_SYSCALL32)
881   fi
882 fi
883
884 dnl See if compiler supports "long long" type.
885
886 AC_MSG_CHECKING(for long long support in compiler)
887 AC_CACHE_VAL(gdb_cv_c_long_long,
888 [AC_TRY_COMPILE(, [
889   extern long long foo;
890   switch (foo & 2) { case 0: return 1; }
891 ],
892 gdb_cv_c_long_long=yes, gdb_cv_c_long_long=no)])
893 AC_MSG_RESULT($gdb_cv_c_long_long)
894 if test $gdb_cv_c_long_long = yes; then
895   AC_DEFINE(CC_HAS_LONG_LONG)
896 fi
897
898 dnl See if the compiler and runtime support printing long long
899
900 AC_MSG_CHECKING(for long long support in printf)
901 AC_CACHE_VAL(gdb_cv_printf_has_long_long,
902 [AC_TRY_RUN([
903 int main () {
904   char buf[32];
905   long long l = 0;
906   l = (l << 16) + 0x0123;
907   l = (l << 16) + 0x4567;
908   l = (l << 16) + 0x89ab;
909   l = (l << 16) + 0xcdef;
910   sprintf (buf, "0x%016llx", l);
911   return (strcmp ("0x0123456789abcdef", buf));
912 }],
913 gdb_cv_printf_has_long_long=yes,
914 gdb_cv_printf_has_long_long=no,
915 gdb_cv_printf_has_long_long=no)])
916 if test $gdb_cv_printf_has_long_long = yes; then
917   AC_DEFINE(PRINTF_HAS_LONG_LONG)
918 fi
919 AC_MSG_RESULT($gdb_cv_printf_has_long_long)
920
921 dnl See if compiler supports "long double" type.  Can't use AC_C_LONG_DOUBLE
922 dnl because autoconf complains about cross-compilation issues.  However, this
923 dnl code uses the same variables as the macro for compatibility.
924
925 AC_MSG_CHECKING(for long double support in compiler)
926 AC_CACHE_VAL(ac_cv_c_long_double,
927 [AC_TRY_COMPILE(, [long double foo;],
928 ac_cv_c_long_double=yes, ac_cv_c_long_double=no)])
929 AC_MSG_RESULT($ac_cv_c_long_double)
930 if test $ac_cv_c_long_double = yes; then
931   AC_DEFINE(HAVE_LONG_DOUBLE)
932 fi
933
934 dnl See if the compiler and runtime support printing long doubles
935
936 AC_MSG_CHECKING(for long double support in printf)
937 AC_CACHE_VAL(gdb_cv_printf_has_long_double,
938 [AC_TRY_RUN([
939 int main () {
940   char buf[16];
941   long double f = 3.141592653;
942   sprintf (buf, "%Lg", f);
943   return (strncmp ("3.14159", buf, 7));
944 }],
945 gdb_cv_printf_has_long_double=yes,
946 gdb_cv_printf_has_long_double=no,
947 gdb_cv_printf_has_long_double=no)])
948 if test $gdb_cv_printf_has_long_double = yes; then
949   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE)
950 fi
951 AC_MSG_RESULT($gdb_cv_printf_has_long_double)
952
953 dnl See if the compiler and runtime support scanning long doubles
954
955 AC_MSG_CHECKING(for long double support in scanf)
956 AC_CACHE_VAL(gdb_cv_scanf_has_long_double,
957 [AC_TRY_RUN([
958 int main () {
959   char *buf = "3.141592653";
960   long double f = 0;
961   sscanf (buf, "%Lg", &f);
962   return !(f > 3.14159 && f < 3.14160);
963 }],
964 gdb_cv_scanf_has_long_double=yes,
965 gdb_cv_scanf_has_long_double=no,
966 gdb_cv_scanf_has_long_double=no)])
967 if test $gdb_cv_scanf_has_long_double = yes; then
968   AC_DEFINE(SCANF_HAS_LONG_DOUBLE)
969 fi
970 AC_MSG_RESULT($gdb_cv_scanf_has_long_double)
971
972 case ${host_os} in
973 aix*)
974   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
975     SAVE_LDFLAGS=$LDFLAGS
976
977     case $GCC in
978     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
979     *) gdb_cv_bigtoc=-bbigtoc ;;
980     esac
981
982     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
983     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
984     LDFLAGS="${SAVE_LDFLAGS}"
985   ])
986   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
987   ;;
988 esac
989
990
991 dnl For certain native configurations, we need to check whether thread
992 dnl support can be built in or not.
993 dnl
994 dnl Note that we only want this if we are both native (host == target),
995 dnl and not doing a canadian cross build (build == host).
996
997 if test ${build} = ${host} -a ${host} = ${target} ; then
998    case ${host_os} in
999    hpux*)
1000       AC_MSG_CHECKING(for HPUX/OSF thread support)
1001       if test -f /usr/include/dce/cma_config.h ; then
1002          if test "$GCC" = "yes" ; then
1003             AC_MSG_RESULT(yes)
1004             AC_DEFINE(HAVE_HPUX_THREAD_SUPPORT)
1005             CONFIG_OBS="${CONFIG_OBS} hpux-thread.o"
1006             CONFIG_SRCS="${CONFIG_SRCS} hpux-thread.c"
1007          else
1008             AC_MSG_RESULT(no (suppressed because you are not using GCC))
1009          fi
1010       else
1011          AC_MSG_RESULT(no)
1012       fi
1013       ;;
1014    solaris*)
1015       # See if thread_db library is around for Solaris thread debugging.
1016       # Note that we must explicitly test for version 1 of the library
1017       # because version 0 (present on Solaris 2.4 or earlier) doesn't have
1018       # the same API.
1019       AC_MSG_CHECKING(for Solaris thread debugging library)
1020       if test -f /usr/lib/libthread_db.so.1 ; then
1021          AC_MSG_RESULT(yes)
1022          AC_DEFINE(HAVE_THREAD_DB_LIB)
1023          CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
1024          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
1025          AC_CHECK_LIB(dl, dlopen)
1026          if test "$GCC" = "yes" ; then
1027             # The GNU linker requires the -export-dynamic option to make
1028             # all symbols visible in the dynamic symbol table.
1029             hold_ldflags=$LDFLAGS
1030             AC_MSG_CHECKING(for the ld -export-dynamic flag)
1031             LDFLAGS="${LDFLAGS} -Wl,-export-dynamic"
1032             AC_TRY_LINK(, [int i;], found=yes, found=no)
1033             LDFLAGS=$hold_ldflags
1034             AC_MSG_RESULT($found)
1035             if test $found = yes; then
1036                CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -Wl,-export-dynamic"
1037             fi
1038          fi
1039          # Sun randomly tweaked the prototypes in <proc_service.h>
1040          # at one point.
1041          AC_MSG_CHECKING(if <proc_service.h> is old)
1042          AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
1043             AC_TRY_COMPILE([
1044                 #include <proc_service.h>
1045                 ps_err_e ps_pdwrite
1046                     (struct ps_prochandle*, psaddr_t, const void*, size_t);
1047             ],, gdb_cv_proc_service_is_old=no,
1048                 gdb_cv_proc_service_is_old=yes)
1049          ])
1050          AC_MSG_RESULT($gdb_cv_proc_service_is_old)
1051          if test $gdb_cv_proc_service_is_old = yes; then
1052             AC_DEFINE(PROC_SERVICE_IS_OLD)
1053          fi
1054       else
1055          AC_MSG_RESULT(no)
1056       fi
1057       ;;
1058    aix*)
1059       AC_MSG_CHECKING(for AiX thread debugging library)
1060       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
1061                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
1062                                    [#ifndef PTHDB_VERSION_3
1063                                     #error
1064                                     #endif],
1065                                    gdb_cv_have_aix_thread_debug=yes,
1066                                    gdb_cv_have_aix_thread_debug=no)])
1067       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1068       if test $gdb_cv_have_aix_thread_debug = yes; then
1069          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1070          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1071          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -lpthdebug"
1072       fi
1073       ;;
1074    esac
1075    AC_SUBST(CONFIG_LDFLAGS)
1076 fi
1077
1078 dnl See if we have a thread_db header file that has TD_NOTALLOC.
1079 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1080    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
1081                   gdb_cv_thread_db_h_has_td_notalloc,
1082      AC_TRY_COMPILE(
1083        [#include <thread_db.h>],
1084        [int i = TD_NOTALLOC;],
1085        gdb_cv_thread_db_h_has_td_notalloc=yes,
1086        gdb_cv_thread_db_h_has_td_notalloc=no
1087      )
1088    )
1089 fi
1090 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1091   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1092             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1093 fi
1094
1095 dnl See if we have a sys/syscall header file that has __NR_tkill.
1096 if test "x$ac_cv_header_sys_syscall_h" = "xyes"; then
1097    AC_CACHE_CHECK([whether <sys/syscall.h> has __NR_tkill],
1098                   gdb_cv_sys_syscall_h_has_tkill,
1099      AC_TRY_COMPILE(
1100        [#include <sys/syscall.h>],
1101        [int i = __NR_tkill;],
1102        gdb_cv_sys_syscall_h_has_tkill=yes,
1103        gdb_cv_sys_syscall_h_has_tkill=no
1104      )
1105    )
1106 fi
1107 dnl See if we can issue tkill syscall.
1108 if test "x$gdb_cv_sys_syscall_h_has_tkill" = "xyes" && test "x$ac_cv_func_syscall" = "xyes"; then
1109   AC_DEFINE(HAVE_TKILL_SYSCALL, 1,
1110             [Define if we can use the tkill syscall.])
1111 fi
1112
1113 dnl Handle optional features that can be enabled.
1114
1115 AC_ARG_WITH(sysroot,
1116 [  --with-sysroot[=DIR] Search for usr/lib et al within DIR.],
1117 [
1118  case ${with_sysroot} in
1119  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
1120  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
1121  esac
1122
1123  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
1124
1125  if test "x$exec_prefix" = xNONE; then
1126   if test "x$prefix" = xNONE; then
1127    test_prefix=/usr/local
1128   else
1129    test_prefix=$prefix
1130   fi
1131  else
1132   test_prefix=$exec_prefix
1133  fi
1134  case ${TARGET_SYSTEM_ROOT} in
1135  "${test_prefix}"|"${test_prefix}/"*|\
1136  '${exec_prefix}'|'${exec_prefix}/'*)
1137    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
1138    TARGET_SYSTEM_ROOT_DEFINE="$t"
1139    ;;
1140  esac
1141 ], [
1142  TARGET_SYSTEM_ROOT=
1143  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"'
1144 ])
1145 AC_SUBST(TARGET_SYSTEM_ROOT)
1146 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
1147
1148 # NOTE: Don't add -Wall or -Wunused, they both include
1149 # -Wunused-parameter which reports bogus warnings.
1150 # NOTE: If you add to this list, remember to update
1151 # gdb/doc/gdbint.texinfo.
1152 build_warnings="-Wimplicit -Wreturn-type -Wcomment -Wtrigraphs \
1153 -Wformat -Wparentheses -Wpointer-arith -Wuninitialized -Wformat-nonliteral \
1154 -Wunused-label -Wunused-function"
1155 # Up for debate: -Wswitch -Wcomment -trigraphs -Wtrigraphs
1156 # -Wunused-function -Wunused-variable -Wunused-value
1157 # -Wchar-subscripts -Wtraditional -Wshadow -Wcast-qual
1158 # -Wcast-align -Wwrite-strings -Wconversion -Wstrict-prototypes
1159 # -Wmissing-prototypes -Wmissing-declarations -Wredundant-decls
1160 # -Woverloaded-virtual -Winline -Werror"
1161 AC_ARG_ENABLE(build-warnings,
1162 [  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
1163 [case "${enableval}" in
1164   yes)  ;;
1165   no)   build_warnings="-w";;
1166   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1167         build_warnings="${build_warnings} ${t}";;
1168   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1169         build_warnings="${t} ${build_warnings}";;
1170   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1171 esac
1172 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1173   echo "Setting compiler warning flags = $build_warnings" 6>&1
1174 fi])dnl
1175 AC_ARG_ENABLE(gdb-build-warnings,
1176 [  --enable-gdb-build-warnings Enable GDB specific build-time compiler warnings if gcc is used],
1177 [case "${enableval}" in
1178   yes)  ;;
1179   no)   build_warnings="-w";;
1180   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1181         build_warnings="${build_warnings} ${t}";;
1182   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1183         build_warnings="${t} ${build_warnings}";;
1184   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1185 esac
1186 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1187   echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1
1188 fi])dnl
1189 WARN_CFLAGS=""
1190 WERROR_CFLAGS=""
1191 if test "x${build_warnings}" != x -a "x$GCC" = xyes
1192 then
1193     AC_MSG_CHECKING(compiler warning flags)
1194     # Separate out the -Werror flag as some files just cannot be
1195     # compiled with it enabled.
1196     for w in ${build_warnings}; do
1197         case $w in
1198         -Werr*) WERROR_CFLAGS=-Werror ;;
1199         *) # Check that GCC accepts it
1200             saved_CFLAGS="$CFLAGS"
1201             CFLAGS="$CFLAGS $w"
1202             AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
1203             CFLAGS="$saved_CFLAGS"
1204         esac
1205     done
1206     AC_MSG_RESULT(${WARN_CFLAGS}${WERROR_CFLAGS})
1207 fi
1208 AC_SUBST(WARN_CFLAGS)
1209 AC_SUBST(WERROR_CFLAGS)
1210
1211 # In the Cygwin environment, we need some additional flags.
1212 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1213 [AC_EGREP_CPP(lose, [
1214 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1215 lose
1216 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1217
1218
1219 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1220 SER_HARDWIRE="ser-unix.o ser-pipe.o ser-tcp.o"
1221 case ${host} in
1222   *go32* ) SER_HARDWIRE=ser-go32.o ;;
1223   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
1224 esac
1225 AC_SUBST(SER_HARDWIRE)
1226
1227 # libreadline needs libuser32.a in a cygwin environment
1228 WIN32LIBS=
1229 if test x$gdb_cv_os_cygwin = xyes; then
1230     WIN32LIBS="-luser32"
1231     case "${target}" in
1232         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
1233         ;;
1234     esac
1235 fi
1236 AC_SUBST(WIN32LIBS)
1237
1238 LIBGUI="../libgui/src/libgui.a"
1239 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
1240 AC_SUBST(LIBGUI)
1241 AC_SUBST(GUI_CFLAGS_X)
1242
1243 WIN32LDAPP=
1244 AC_SUBST(WIN32LIBS)
1245 AC_SUBST(WIN32LDAPP)
1246
1247 case "${host}" in
1248 *-*-cygwin*)
1249     configdir="win"
1250     ;;
1251 *)
1252     configdir="unix"
1253     ;;
1254 esac
1255
1256 GDBTKLIBS=
1257 if test "${enable_gdbtk}" = "yes"; then
1258
1259     # Gdbtk must have an absolute path to srcdir in order to run
1260     # properly when not installed.
1261     here=`pwd`
1262     cd ${srcdir}
1263     GDBTK_SRC_DIR=`pwd`
1264     cd $here
1265
1266     CY_AC_PATH_TCLCONFIG
1267     if test -z "${no_tcl}"; then
1268         CY_AC_LOAD_TCLCONFIG
1269         CY_AC_PATH_TKCONFIG
1270
1271         # now look for Tcl library stuff
1272
1273         tcldir="../tcl/${configdir}/"
1274
1275         TCL_DEPS="${tcldir}${TCL_LIB_FILE}"
1276
1277         # If $no_tk is nonempty, then we can't do Tk, and there is no
1278         # point to doing Tcl.
1279         if test -z "${no_tk}"; then
1280            CY_AC_LOAD_TKCONFIG
1281            CY_AC_PATH_TCLH
1282            CY_AC_PATH_TKH
1283            CY_AC_PATH_ITCLH
1284            CY_AC_PATH_ITKH
1285
1286
1287            # now look for Tk library stuff
1288
1289            tkdir="../tk/${configdir}/"
1290
1291            TK_DEPS="${tkdir}${TK_LIB_FILE}"
1292
1293            # now look for Itcl library stuff
1294
1295            CY_AC_PATH_ITCLCONFIG
1296            if test -z "${no_itcl}"; then
1297              CY_AC_LOAD_ITCLCONFIG 
1298
1299              ITCLLIB="${ITCL_BUILD_LIB_SPEC}"
1300              ITCL_DEPS="${ITCL_LIB_FULL_PATH}"
1301            fi
1302
1303            
1304            # now look for Itk library stuff
1305            CY_AC_PATH_ITKCONFIG
1306            if test -z "${no_itcl}"; then
1307              CY_AC_LOAD_ITKCONFIG
1308
1309              ITKLIB="${ITK_BUILD_LIB_SPEC}"
1310              ITK_DEPS="${ITK_LIB_FULL_PATH}"
1311            fi
1312
1313            ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
1314            # Tcl/Tk 8.1 require -fwritable strings.  I don't
1315            # know whether 8.2 will or not, but I bet it will.
1316            # I don't have to worry about 7.x since we don't support it.
1317            GDBTK_CFLAGS=""
1318            if test "$GCC" = "yes"; then
1319                if test "$TCL_VERSION" != "8.0" ; then
1320                    GDBTK_CFLAGS="-fwritable-strings"
1321                fi
1322            fi
1323
1324            # Include some libraries that Tcl and Tk want.
1325            TCL_LIBS='$(LIBGUI) $(ITCL) $(ITK) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
1326            # Yes, the ordering seems wrong here.  But it isn't.
1327            # TK_LIBS is the list of libraries that need to be linked
1328            # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
1329            # were in LIBS then any link tests after this point would
1330            # try to include things like `$(LIBGUI)', which wouldn't work.
1331            GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
1332
1333            CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
1334            CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
1335            CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
1336            CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
1337            CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
1338            CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
1339            CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
1340
1341            if test x$gdb_cv_os_cygwin = xyes; then
1342               WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
1343               WIN32LDAPP="-Wl,--subsystem,console"
1344               CONFIG_OBS="${CONFIG_OBS} gdbres.o"
1345            fi
1346         fi
1347     fi
1348
1349     configdirs="${configdirs} gdbtk"
1350 fi
1351
1352 AC_SUBST(X_CFLAGS)
1353 AC_SUBST(X_LDFLAGS)
1354 AC_SUBST(X_LIBS)
1355 AC_SUBST(TCL_DEPS)
1356 AC_SUBST(TK_DEPS)
1357 AC_SUBST(ITCLLIB)
1358 AC_SUBST(ITCL_DEPS)
1359 AC_SUBST(ITKLIB)
1360 AC_SUBST(ITK_DEPS)
1361 AC_SUBST(GDBTKLIBS)
1362 AC_SUBST(GDBTK_CFLAGS)
1363 AC_SUBST(GDBTK_SRC_DIR)
1364
1365 AC_PATH_X
1366
1367  
1368 # Unlike the sim directory, whether a simulator is linked is controlled by 
1369 # presence of a SIM= and a SIM_OBS= definition in the target '.mt' file.  
1370 # This code just checks for a few cases where we'd like to ignore those
1371 # definitions, even when they're present in the '.mt' file.  These cases
1372 # are when --disable-sim is specified, or if the simulator directory is
1373 # not part of the source tree.
1374 #
1375 AC_ARG_ENABLE(sim,
1376 [  --enable-sim            Link gdb with simulator],
1377 [echo "enable_sim = $enable_sim";
1378  echo "enableval = ${enableval}";
1379  case "${enableval}" in
1380   yes) ignore_sim=false ;;
1381   no)  ignore_sim=true ;;
1382   *)   ignore_sim=false ;;
1383  esac],
1384 [ignore_sim=false])
1385
1386 if test ! -d "${srcdir}/../sim"; then
1387   ignore_sim=true
1388 fi
1389
1390 if test "${ignore_sim}" = "true"; then
1391     IGNORE_SIM="SIM="
1392     IGNORE_SIM_OBS="SIM_OBS="
1393 else
1394     IGNORE_SIM=""
1395     IGNORE_SIM_OBS=""
1396     AC_DEFINE(WITH_SIM)
1397 fi
1398 AC_SUBST(IGNORE_SIM)
1399 AC_SUBST(IGNORE_SIM_OBS)
1400
1401 AC_SUBST(ENABLE_CFLAGS)
1402 AC_SUBST(PROFILE_CFLAGS)
1403
1404 AC_SUBST(CONFIG_OBS)
1405 AC_SUBST(CONFIG_DEPS)
1406 AC_SUBST(CONFIG_SRCS)
1407 AC_SUBST(CONFIG_ALL)
1408 AC_SUBST(CONFIG_CLEAN)
1409 AC_SUBST(CONFIG_INSTALL)
1410 AC_SUBST(CONFIG_UNINSTALL)
1411
1412 # List of host floatformats.
1413 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
1414 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
1415 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
1416
1417 # target_subdir is used by the testsuite to find the target libraries.
1418 target_subdir=
1419 if test "${host}" != "${target}"; then
1420     target_subdir="${target_alias}/"
1421 fi
1422 AC_SUBST(target_subdir)
1423
1424 frags=
1425 if test "${target}" = "${host}"; then
1426   host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
1427   if test ! -f ${host_makefile_frag}; then
1428     AC_MSG_ERROR("*** Gdb does not support native target ${host}")
1429   fi
1430   frags="$frags $host_makefile_frag"
1431 else
1432   host_makefile_frag=/dev/null
1433 fi
1434
1435 target_makefile_frag=${srcdir}/config/${gdb_target_cpu}/${gdb_target}.mt
1436 if test ! -f ${target_makefile_frag}; then
1437   AC_MSG_ERROR("*** Gdb does not support target ${target}")
1438 fi
1439 frags="$frags $target_makefile_frag"
1440
1441 AC_SUBST_FILE(host_makefile_frag)
1442 AC_SUBST_FILE(target_makefile_frag)
1443 AC_SUBST(frags)
1444
1445 changequote(,)dnl
1446 hostfile=`sed -n '
1447 s/XM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
1448 ' ${host_makefile_frag}`
1449
1450 targetfile=`sed -n '
1451 s/DEPRECATED_TM_FILE[   ]*=[    ]*\([^  ]*\)/\1/p
1452 ' ${target_makefile_frag}`
1453
1454 if test "${target}" = "${host}"; then
1455 # We pick this up from the host configuration file (.mh) because we
1456 # do not have a native configuration Makefile fragment.
1457 nativefile=`sed -n '
1458 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
1459 ' ${host_makefile_frag}`
1460 fi
1461 changequote([,])
1462
1463 if test x"${gdb_osabi}" != x ; then
1464     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
1465                        [Define to the default OS ABI for this configuration.])
1466 fi
1467
1468 # Enable multi-ice-gdb-server.
1469 AC_ARG_ENABLE(multi-ice,
1470 [  --enable-multi-ice      build the multi-ice-gdb-server],
1471   [case $enableval in
1472     yes | no)
1473       ;;
1474     *) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;;
1475   esac])
1476 if test "x$enable_multi_ice" = xyes; then
1477   configdirs="$configdirs multi-ice"
1478 fi
1479
1480 # We only build gdbserver automatically if host and target are the same.
1481 if test "x$target" = "x$host"; then
1482   AC_MSG_CHECKING(whether gdbserver is supported on this host)
1483   if test "x$build_gdbserver" = xyes; then
1484     configdirs="$configdirs gdbserver"
1485     AC_MSG_RESULT(yes)
1486   else
1487     AC_MSG_RESULT(no)
1488   fi
1489 fi
1490
1491 AC_CONFIG_SUBDIRS($configdirs)
1492
1493 # If hostfile (XM_FILE) and/or targetfile (DEPRECATED_TM_FILE) and/or
1494 # nativefile (NAT_FILE) is not set in config/*/*.m[ht] files, we link
1495 # to an empty version.
1496
1497 files=
1498 links=
1499
1500 rm -f xm.h
1501 xm_h=""
1502 if test "${hostfile}" != ""; then
1503     xm_h=xm.h
1504     case "${hostfile}" in
1505       xm-*.h ) GDB_XM_FILE="config/${gdb_host_cpu}/${hostfile}" ;;
1506       * ) GDB_XM_FILE="${hostfile}"
1507     esac
1508     files="${files} ${GDB_XM_FILE}"
1509     links="${links} xm.h"
1510     AC_DEFINE_UNQUOTED(GDB_XM_FILE, "${GDB_XM_FILE}")
1511 fi
1512 AC_SUBST(xm_h)
1513
1514 rm -f tm.h
1515 tm_h=""
1516 if test "${targetfile}" != ""; then
1517     tm_h=tm.h
1518     case "${targetfile}" in
1519       tm-*.h ) GDB_TM_FILE="config/${gdb_target_cpu}/${targetfile}" ;;
1520       * ) GDB_TM_FILE="${targetfile}"
1521     esac
1522     files="${files} ${GDB_TM_FILE}"
1523     links="${links} tm.h"
1524     AC_DEFINE_UNQUOTED(GDB_TM_FILE, "${GDB_TM_FILE}")
1525 fi
1526 AC_SUBST(tm_h)
1527
1528 rm -f nm.h
1529 nm_h=""
1530 if test "${nativefile}" != ""; then
1531     nm_h=nm.h
1532     case "${nativefile}" in
1533       nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
1534       * ) GDB_NM_FILE="${nativefile}"
1535     esac
1536     files="${files} ${GDB_NM_FILE}"
1537     links="${links} nm.h"
1538     AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}")
1539 fi
1540 AC_SUBST(nm_h)
1541
1542 AC_LINK_FILES($files, $links)
1543
1544 dnl Check for exe extension set on certain hosts (e.g. Win32)
1545 AC_EXEEXT
1546
1547 dnl  Detect the character set used by this host.
1548
1549 dnl  At the moment, we just assume it's ISO-8859-1 (which is a
1550 dnl  superset of ASCII containing the characters needed for French,
1551 dnl  German, Spanish, Italian, and possibly others), but if were
1552 dnl  *were* to support any host character sets other than ISO-8859-1,
1553 dnl  here's where we'd detect it.
1554 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "ISO-8859-1",
1555           [Define to be a string naming the default host character set.])
1556
1557 AM_ICONV
1558
1559 AC_OUTPUT(Makefile .gdbinit:gdbinit.in,
1560 [
1561 dnl Autoconf doesn't provide a mechanism for modifying definitions 
1562 dnl provided by makefile fragments.
1563 dnl
1564
1565 changequote(,)dnl
1566 sed -e '/^DEPRECATED_TM_FILE[   ]*=/s,^DEPRECATED_TM_FILE[      ]*=[    ]*,&config/'"${gdb_target_cpu}"'/,
1567 /^XM_FILE[      ]*=/s,^XM_FILE[         ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,
1568 /^NAT_FILE[     ]*=/s,^NAT_FILE[        ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,' <Makefile >Makefile.tmp
1569 mv -f Makefile.tmp Makefile
1570 changequote([,])dnl
1571
1572
1573 case x$CONFIG_HEADERS in
1574 xconfig.h:config.in)
1575 echo > stamp-h ;;
1576 esac
1577 ],
1578 [
1579 gdb_host_cpu=$gdb_host_cpu
1580 gdb_target_cpu=$gdb_target_cpu
1581 nativefile=$nativefile
1582 ])
1583
1584 exit 0