gdb/configure.in

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004
   3 dnl Free Software Foundation, Inc.
   4 dnl
   5 dnl This file is part of GDB.
   6 dnl
   7 dnl This program is free software; you can redistribute it and/or modify
   8 dnl it under the terms of the GNU General Public License as published by
   9 dnl the Free Software Foundation; either version 2 of the License, or
  10 dnl (at your option) any later version.
  11 dnl
  12 dnl This program is distributed in the hope that it will be useful,
  13 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 dnl GNU General Public License for more details.
  16 dnl
  17 dnl You should have received a copy of the GNU General Public License
  18 dnl along with this program; if not, write to the Free Software
  19 dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  20
  21 dnl Process this file with autoconf to produce a configure script.
  22
  23 AC_PREREQ(2.13)dnl
  24 AC_INIT(main.c)
  25 AC_CONFIG_HEADER(config.h:config.in)
  26 AM_MAINTAINER_MODE
  27
  28 AC_PROG_CC
  29 AC_GNU_SOURCE
  30 AC_AIX
  31 AC_ISC_POSIX
  32 AM_PROG_CC_STDC
  33
  34 AC_CONFIG_AUX_DIR(`cd $srcdir;pwd`/..)
  35 AC_CANONICAL_SYSTEM
  36
  37 # FIXME: kettenis/20030102: The AC_PROG_RANLIB from Autoconf 2.13
  38 # doesn't support cross-compilation, but the one from Autoconf 2.5x
  39 # does.  Override RANLIB here (i.e. before running AC_PROG_RANLIB) to
  40 # deal with the lossage.  Note that CY_GNU_GETTEXT currently calls
  41 # AC_PROG_RANLIB.  This can be removed when we switch to Autoconf
  42 # 2.5x.
  43 AC_CHECK_TOOL(RANLIB, ranlib, :)
  44
  45 dnl List of object files and targets accumulated by configure.
  46
  47 CONFIG_OBS=
  48 CONFIG_DEPS=
  49 CONFIG_SRCS=
  50 ENABLE_CFLAGS=
  51
  52 CONFIG_ALL=
  53 CONFIG_CLEAN=
  54 CONFIG_INSTALL=
  55 CONFIG_UNINSTALL=
  56
  57 dnl Set up for gettext.  PACKAGE is used when we call bindtextdomain.
  58
  59 CY_GNU_GETTEXT
  60
  61 localedir='${datadir}/locale'
  62 AC_SUBST(localedir)
  63
  64 if test "x$POSUB" != x; then
  65
  66   dnl Lifted from GCC's config/gettext.m4.
  67   AC_MSG_CHECKING(for catalogs to be installed)
  68   # Look for .po and .gmo files in the source directory.
  69   CATALOGS=  AC_SUBST(CATALOGS)
  70   XLINGUAS=
  71   for cat in $srcdir/po/*.gmo $srcdir/po/*.po; do
  72     # If there aren't any .gmo files the shell will give us the
  73     # literal string "../path/to/srcdir/po/*.gmo" which has to be
  74     # weeded out.
  75     case "$cat" in *\**)
  76       continue;;
  77     esac
  78     # The quadruple backslash is collapsed to a double backslash
  79     # by the backticks, then collapsed again by the double quotes,
  80     # leaving us with one backslash in the sed expression (right
  81     # before the dot that mustn't act as a wildcard).
  82     cat=`echo $cat | sed -e "s!$srcdir/!!" -e "s!\\\\.po!.gmo!"`
  83     lang=`echo $cat | sed -e 's!po/!!' -e "s!\\\\.gmo!!"`
  84     # The user is allowed to set LINGUAS to a list of languages to
  85     # install catalogs for.  If it's empty that means "all of them."
  86     if test "x$LINGUAS" = x; then
  87       CATALOGS="$CATALOGS $cat"
  88       XLINGUAS="$XLINGUAS $lang"
  89     else
  90       case "$LINGUAS" in *$lang*)
  91         CATALOGS="$CATALOGS $cat"
  92         XLINGUAS="$XLINGUAS $lang"
  93         ;;
  94       esac
  95     fi
  96   done
  97   LINGUAS="$XLINGUAS"
  98   AC_MSG_RESULT($LINGUAS)
  99
 100    CONFIG_ALL="$CONFIG_ALL all-po"
 101    CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
 102    CONFIG_INSTALL="$CONFIG_INSTALL install-po"
 103    CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
 104 fi
 105
 106 PACKAGE=gdb
 107 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
 108 AC_SUBST(PACKAGE)
 109
 110 debugdir=${libdir}/debug
 111
 112 AC_ARG_WITH(separate-debug-dir,
 113 [  --with-separate-debug-dir=path   Look for global separate debug info in this path [LIBDIR/debug]],
 114 [debugdir="${withval}"])
 115
 116 AC_DEFINE_DIR(DEBUGDIR, debugdir,
 117               [Global directory for separate debug files. ])
 118 #AC_DEFINE_UNQUOTED(DEBUGDIR, "$debugdir"),
 119
 120 AC_CONFIG_SUBDIRS(doc testsuite)
 121 configdirs=
 122
 123 . $srcdir/configure.host
 124
 125 . $srcdir/configure.tgt
 126
 127 # Fetch the default architecture and default target vector from BFD.
 128 targ=$target; . $srcdir/../bfd/config.bfd
 129
 130 # We only want the first architecture, so strip off the others if
 131 # there is more than one.
 132 targ_archs=`echo $targ_archs | sed 's/ .*//'`
 133
 134 if test "x$targ_archs" != x; then
 135   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
 136     [Define to BFD's default architecture. ])
 137 fi
 138 if test "x$targ_defvec" != x; then
 139   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
 140     [Define to BFD's default target vector. ])
 141 fi
 142
 143 AC_ARG_PROGRAM
 144
 145 # The CLI cannot be disabled yet, but may be in the future.
 146
 147 # Enable CLI.
 148 AC_ARG_ENABLE(gdbcli,
 149 [  --disable-gdbcli        disable command-line interface (CLI)],
 150   [case $enableval in
 151     yes)
 152       ;;
 153     no)
 154       AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;;
 155     *)
 156       AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;;
 157   esac],
 158   [enable_gdbcli=yes])
 159 if test x"$enable_gdbcli" = xyes; then
 160   if test -d $srcdir/cli; then
 161     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)"
 162     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)"
 163     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)"
 164     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)"
 165   fi
 166 fi
 167
 168 # Enable MI.
 169 AC_ARG_ENABLE(gdbmi,
 170 [  --disable-gdbmi         disable machine-interface (MI)],
 171   [case $enableval in
 172     yes | no)
 173       ;;
 174     *)
 175       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 176   esac],
 177   [enable_gdbmi=yes])
 178 if test x"$enable_gdbmi" = xyes; then
 179   if test -d $srcdir/mi; then
 180     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 181     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 182     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 183     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 184   fi
 185 fi
 186
 187 # Enable TUI.
 188 AC_ARG_ENABLE(tui,
 189 [  --enable-tui            enable full-screen terminal user interface (TUI)],
 190   [case $enableval in
 191     yes | no)
 192       ;;
 193     *)
 194       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 195   esac],enable_tui=yes)
 196 if test x"$enable_tui" = xyes; then
 197   if test -d $srcdir/tui; then
 198     if test "$ac_cv_search_initscr" != no -a "$ac_cv_search_wborder" != no; then
 199       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
 200       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
 201       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
 202       CONFIG_INITS="$CONFIG_INITS \$(SUBDIR_TUI_INITS)"
 203       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
 204       CONFIG_ALL="${CONFIG_ALL} all-tui"
 205       CONFIG_CLEAN="${CONFIG_CLEAN} clean-tui"
 206       CONFIG_INSTALL="${CONFIG_INSTALL} install-tui"
 207       CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-tui"
 208     fi
 209   fi
 210 fi
 211
 212 # Enable gdbtk.
 213 AC_ARG_ENABLE(gdbtk,
 214 [  --enable-gdbtk          enable gdbtk graphical user interface (GUI)],
 215   [case $enableval in
 216     yes | no)
 217       ;;
 218     *)
 219       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 220   esac],
 221   [if test -d $srcdir/gdbtk; then
 222     enable_gdbtk=yes
 223   else
 224     enable_gdbtk=no
 225   fi])
 226 # We unconditionally disable gdbtk tests on selected platforms.
 227 case $host_os in
 228   go32* | windows*)
 229     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 230     enable_gdbtk=no ;;
 231 esac
 232
 233 # Libunwind support.
 234 AC_ARG_WITH(libunwind,
 235 [  --with-libunwind            Use libunwind frame unwinding support],
 236 [case "${withval}" in
 237   yes)  enable_libunwind=yes ;;
 238   no)   enable_libunwind=no ;;
 239   *)    AC_MSG_ERROR(bad value ${withval} for GDB with-libunwind option) ;;
 240 esac],[
 241   AC_CHECK_HEADERS(libunwind.h)
 242   AC_CHECK_HEADERS(libunwind-ia64.h)
 243   if test x"$ac_cv_header_libunwind_h" = xyes -a x"$ac_cv_header_libunwind_ia64_h" = xyes; then
 244     enable_libunwind=yes;
 245   fi
 246 ])
 247
 248 if test x"$enable_libunwind" = xyes; then
 249   AC_CHECK_HEADERS(libunwind.h)
 250   AC_CHECK_HEADERS(libunwind-ia64.h)
 251   AC_DEFINE(HAVE_LIBUNWIND, 1)
 252   CONFIG_OBS="$CONFIG_OBS libunwind-frame.o"
 253   CONFIG_DEPS="$CONFIG_DEPS libunwind-frame.o"
 254   CONFIG_SRCS="$CONFIG_SRCS libunwind-frame.c"
 255 fi
 256
 257 # Profiling support.
 258 AC_ARG_ENABLE(profiling,
 259 [  --enable-profiling      enable profiling of GDB],
 260   [case $enableval in
 261     yes | no)
 262       ;;
 263     *)
 264       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 265   esac],
 266  [enable_profiling=no])
 267
 268 AC_CHECK_FUNCS(monstartup _mcleanup)
 269 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 270 [AC_TRY_LINK(
 271 [#include <stdlib.h>
 272 extern char _etext;
 273 ],
 274 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 275 if test $ac_cv_var__etext = yes; then
 276   AC_DEFINE(HAVE__ETEXT, 1,
 277             [Define to 1 if your system has the _etext variable. ])
 278 fi
 279 if test "$enable_profiling" = yes ; then
 280   if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
 281     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 282   fi
 283   PROFILE_CFLAGS=-pg
 284   OLD_CFLAGS="$CFLAGS"
 285   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 286
 287   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 288     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 289      ac_cv_cc_supports_pg=no)])
 290
 291   if test $ac_cv_cc_supports_pg = no; then
 292     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 293   fi
 294
 295   CFLAGS="$OLD_CFLAGS"
 296 fi
 297
 298 # --------------------- #
 299 # Checks for programs.  #
 300 # --------------------- #
 301
 302 AC_PROG_AWK
 303 AC_PROG_INSTALL
 304 AC_PROG_LN_S
 305 AC_PROG_RANLIB
 306 AC_PROG_YACC
 307
 308 AC_CHECK_TOOL(AR, ar)
 309 AC_CHECK_TOOL(DLLTOOL, dlltool)
 310 AC_CHECK_TOOL(WINDRES, windres)
 311
 312 # Needed for GNU/Hurd.
 313 AC_CHECK_TOOL(MIG, mig)
 314
 315 # ---------------------- #
 316 # Checks for libraries.  #
 317 # ---------------------- #
 318
 319 # We might need to link with -lm; most simulators need it.
 320 AC_CHECK_LIB(m, main)
 321
 322 # We need to link with -lw to get `wctype' on Solaris before Solaris
 323 # 2.6.  Solaris 2.6 and beyond have this function in libc, and have a
 324 # libw that some versions of the GNU linker cannot hanle (GNU ld 2.9.1
 325 # is known to have this problem).  Therefore we avoid libw if we can.
 326 AC_CHECK_FUNC(wctype, [],
 327   [AC_CHECK_LIB(w, wctype)])
 328
 329 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 330 AC_SEARCH_LIBS(gethostbyname, nsl)
 331
 332 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 333 AC_SEARCH_LIBS(socketpair, socket)
 334
 335 # Since GDB uses Readline, we need termcap functionality, so we need
 336 # to find a library that provides that.  When GDB is configured with
 337 # the TUI, we need full curses functionality.
 338
 339 case $host_os in
 340   cygwin*)
 341     if test -d $srcdir/libtermcap; then
 342       LIBS="../libtermcap/libtermcap.a $LIBS"
 343       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 344     fi ;;
 345   go32* | *djgpp*)
 346     ac_cv_search_tgetent="none required"
 347     ;;
 348   aix*)
 349     # Readline prefers curses over termcap on AIX.
 350     # ??? Why?
 351     AC_SEARCH_LIBS(tgetent, [tinfo ncurses curses termcap])
 352     ;;
 353 esac
 354
 355 # Note: We used to check for libtermlib and libterminfo too, but
 356 # Readline doesn't, so I think we're safe with leaving them out.
 357 AC_SEARCH_LIBS(tgetent, [termcap tinfo ncurses Hcurses curses])
 358
 359 if test "$ac_cv_search_tgetent" = no; then
 360   AC_MSG_ERROR([no termcap library found])
 361 fi
 362
 363 # FIXME: kettenis/20030102: We seem to prefer HP curses (Hcurses) over
 364 # Xcurses on HP-UX; see the `-D__HP_CURSES' in the relevant host
 365 # Makefile fragments.  That's why we need to have `Hcurses' before
 366 # `curses'.  I don't see why we should use HP curses if a more
 367 # standard curses is available, except that according to HP's
 368 # documentation one needs to compile `-D_XOPEN_SOURCE_EXTENDED' on
 369 # HP-UX 10.10 and 10.20.
 370
 371 # FIXME: ncurses does not work on native alphaev68-dec-osf5.1,
 372 # and probably other platforms.  AC_SEARCH_LIBS finds the library
 373 # in a place such as /usr/local/lib/libncurses.a, but does not
 374 # do anything to look for the matching include files.
 375 # -- chastain 2004-05-01
 376
 377 AC_SEARCH_LIBS(initscr, [ncurses Hcurses cursesX curses pdcurses], [],
 378   [AC_MSG_WARN([no curses library found])])
 379
 380 # Check whether the wborder function is provided by the curses
 381 # library detected above.  In certain implementations such as
 382 # the HP/UX Hcurses for instance, this function is provided by an
 383 # additional library.  So if we did not find this function inside
 384 # the curses library, try some alternate libraries we know might
 385 # provide it.
 386 AC_SEARCH_LIBS(wborder, [cur_colr], [],
 387     [AC_MSG_WARN([wborder function not found, tui will be disabled])])
 388
 389 # ------------------------- #
 390 # Checks for header files.  #
 391 # ------------------------- #
 392
 393 AC_HEADER_DIRENT
 394 AC_HEADER_STAT
 395 AC_HEADER_STDC
 396 AC_CHECK_HEADERS(link.h)
 397 AC_CHECK_HEADERS(machine/reg.h)
 398 AC_CHECK_HEADERS(nlist.h)
 399 AC_CHECK_HEADERS(poll.h sys/poll.h)
 400 AC_CHECK_HEADERS(proc_service.h thread_db.h gnu/libc-version.h)
 401 AC_CHECK_HEADERS(stddef.h)
 402 AC_CHECK_HEADERS(stdlib.h)
 403 AC_CHECK_HEADERS(stdint.h)
 404 AC_CHECK_HEADERS(string.h memory.h strings.h)
 405 AC_CHECK_HEADERS(sys/fault.h)
 406 AC_CHECK_HEADERS(sys/file.h)
 407 AC_CHECK_HEADERS(sys/filio.h)
 408 AC_CHECK_HEADERS(sys/ioctl.h)
 409 AC_CHECK_HEADERS(sys/param.h)
 410 AC_CHECK_HEADERS(sys/proc.h)
 411 AC_CHECK_HEADERS(sys/procfs.h)
 412 AC_CHECK_HEADERS(sys/ptrace.h ptrace.h)
 413 AC_CHECK_HEADERS(sys/reg.h sys/debugreg.h)
 414 AC_CHECK_HEADERS(sys/select.h)
 415 AC_CHECK_HEADERS(sys/syscall.h)
 416 AC_CHECK_HEADERS(sys/types.h)
 417 AC_CHECK_HEADERS(sys/user.h)
 418 AC_CHECK_HEADERS(sys/wait.h wait.h)
 419 AC_CHECK_HEADERS(termios.h termio.h sgtty.h)
 420 AC_CHECK_HEADERS(unistd.h)
 421
 422 # On Solaris 2.[789], we need to define _MSE_INT_H to avoid a clash
 423 # between <widec.h> and <wchar.h> that would cause AC_CHECK_HEADERS to
 424 # think that we don't have <curses.h> if we're using GCC.
 425 case $host_os in
 426   solaris2.[[789]])
 427     if test "$GCC" = yes; then
 428       AC_DEFINE(_MSE_INT_H, 1,
 429         [[Define to 1 to avoid a clash between <widec.h> and <wchar.h> on
 430    Solaris 2.[789] when using GCC. ]])
 431     fi ;;
 432 esac
 433 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h term.h)
 434
 435 # FIXME: kettenis/20030102: In most cases we include these
 436 # unconditionally, so what's the point in checking these?
 437 AC_CHECK_HEADERS(ctype.h time.h)
 438
 439 dnl Check for struct stat with an st_blocks member
 440 AC_MSG_CHECKING(for member st_blocks in struct stat)
 441 AC_CACHE_VAL(gdb_cv_have_struct_stat_with_st_blocks_member,
 442   [AC_TRY_COMPILE([#include <sys/types.h>
 443 #include <sys/stat.h>],
 444                   [struct stat st; (void) st.st_blocks;],
 445                   gdb_cv_have_struct_stat_with_st_blocks_member=yes,
 446                   gdb_cv_have_struct_stat_with_st_blocks_member=no)])
 447 AC_MSG_RESULT($gdb_cv_have_struct_stat_with_st_blocks_member)
 448 if test $gdb_cv_have_struct_stat_with_st_blocks_member = yes; then
 449   AC_DEFINE(HAVE_STRUCT_STAT_ST_BLOCKS)
 450 fi
 451
 452 # ------------------------- #
 453 # Checks for declarations.  #
 454 # ------------------------- #
 455
 456 gcc_AC_CHECK_DECLS(getopt)
 457
 458 # ------------------ #
 459 # Checks for types.  #
 460 # ------------------ #
 461
 462 AC_TYPE_SIGNAL
 463
 464 # ------------------------------------- #
 465 # Checks for compiler characteristics.  #
 466 # ------------------------------------- #
 467
 468 AC_C_CONST
 469 AC_C_INLINE
 470
 471 # ------------------------------ #
 472 # Checks for library functions.  #
 473 # ------------------------------ #
 474
 475 AC_FUNC_ALLOCA
 476 AC_FUNC_MMAP
 477 AC_FUNC_VFORK
 478 AC_CHECK_FUNCS(canonicalize_file_name realpath)
 479 AC_CHECK_FUNCS(poll)
 480 AC_CHECK_FUNCS(pread64)
 481 AC_CHECK_FUNCS(sbrk)
 482 AC_CHECK_FUNCS(setpgid setpgrp)
 483 AC_CHECK_FUNCS(sigaction sigprocmask sigsetmask)
 484 AC_CHECK_FUNCS(socketpair)
 485 AC_CHECK_FUNCS(syscall)
 486
 487 # Check the return and argument types of ptrace.  No canned test for
 488 # this, so roll our own.
 489 gdb_ptrace_headers='
 490 #if HAVE_SYS_TYPES_H
 491 # include <sys/types.h>
 492 #endif
 493 #if HAVE_SYS_PTRACE_H
 494 # include <sys/ptrace.h>
 495 #endif
 496 #if HAVE_UNISTD_H
 497 # include <unistd.h>
 498 #endif
 499 '
 500 # There is no point in checking if we don't have a prototype.
 501 gcc_AC_CHECK_DECLS(ptrace, , [
 502   : ${gdb_cv_func_ptrace_ret='int'}
 503   : ${gdb_cv_func_ptrace_args='int,int,long,long'}
 504 ], $gdb_ptrace_headers)
 505 # Check return type.
 506 AC_CACHE_CHECK([return type of ptrace], gdb_cv_func_ptrace_ret,
 507   AC_TRY_COMPILE($gdb_ptrace_headers,
 508     [extern long ptrace ();],
 509     gdb_cv_func_ptrace_ret='long',
 510     gdb_cv_func_ptrace_ret='int'))
 511 AC_DEFINE_UNQUOTED(PTRACE_TYPE_RET, $gdb_cv_func_ptrace_ret,
 512   [Define as the return type of ptrace.])
 513 # Check argument types.
 514 AC_CACHE_CHECK([types of arguments for ptrace], gdb_cv_func_ptrace_args, [
 515 for gdb_arg1 in 'int' 'long'; do
 516  for gdb_arg2 in 'pid_t' 'int' 'long'; do
 517   for gdb_arg3 in 'int *' 'caddr_t' 'int' 'long'; do
 518    for gdb_arg4 in 'int' 'long'; do
 519      AC_TRY_COMPILE($gdb_ptrace_headers, [
 520 extern $gdb_cv_func_ptrace_ret
 521   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4);
 522 ], [gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4";
 523     break 4;])
 524     for gdb_arg5 in 'int *' 'int' 'long'; do
 525      AC_TRY_COMPILE($gdb_ptrace_headers, [
 526 extern $gdb_cv_func_ptrace_ret
 527   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4, $gdb_arg5);
 528 ], [
 529 gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4,$gdb_arg5";
 530     break 5;])
 531     done
 532    done
 533   done
 534  done
 535 done
 536 # Provide a safe default value.
 537 : ${gdb_cv_func_ptrace_args='int,int,long,long'}
 538 ])
 539 ac_save_IFS=$IFS; IFS=','
 540 set dummy `echo "$gdb_cv_func_ptrace_args" | sed 's/\*/\*/g'`
 541 IFS=$ac_save_IFS
 542 shift
 543 AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG3, ($[3]),
 544   [Define to the type of arg 3 for ptrace.])
 545 if test -n "$[5]"; then
 546   AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG5, ($[5]),
 547     [Define to the type of arg 5 for ptrace.])
 548 fi
 549
 550 dnl AC_FUNC_SETPGRP does not work when cross compiling
 551 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
 552 if test "$cross_compiling" = no; then
 553   AC_FUNC_SETPGRP
 554 else
 555   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
 556     [AC_TRY_COMPILE([
 557 #include <unistd.h>
 558 ], [
 559   if (setpgrp(1,1) == -1)
 560     exit (0);
 561   else
 562     exit (1);
 563 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
 564 if test $ac_cv_func_setpgrp_void = yes; then
 565   AC_DEFINE(SETPGRP_VOID, 1)
 566 fi
 567 fi
 568
 569 # Check if sigsetjmp is available.  Using AC_CHECK_FUNCS won't do
 570 # since sigsetjmp might only be defined as a macro.
 571 AC_CACHE_CHECK([for sigsetjmp], gdb_cv_func_sigsetjmp,
 572 [AC_TRY_COMPILE([
 573 #include <setjmp.h>
 574 ], [sigjmp_buf env; while (! sigsetjmp (env, 1)) siglongjmp (env, 1);],
 575 gdb_cv_func_sigsetjmp=yes, gdb_cv_func_sigsetjmp=no)])
 576 if test $gdb_cv_func_sigsetjmp = yes; then
 577   AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available. ])
 578 fi
 579
 580 # Assume we'll default to using the included libiberty regex.
 581 gdb_use_included_regex=yes
 582
 583 # However, if the system regex is GNU regex, then default to *not*
 584 # using the included regex.
 585 AC_CACHE_CHECK(
 586   [for GNU regex],
 587   [gdb_cv_have_gnu_regex],
 588   [AC_TRY_COMPILE(
 589     [#include <gnu-versions.h>],
 590     [#define REGEX_INTERFACE_VERSION 1
 591 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
 592 # error "Version mismatch"
 593 #endif],
 594     gdb_cv_have_gnu_regex=yes,
 595     gdb_cv_have_gnu_regex=no)])
 596 if test $gdb_cv_have_gnu_regex = yes; then
 597   gdb_use_included_regex=no
 598 fi
 599
 600 AC_ARG_WITH(included-regex,
 601   [  --without-included-regex don't use included regex; this is the default
 602                           on systems with version 2 of the GNU C library
 603                           (use with caution on other system)],
 604   gdb_with_regex=$withval,
 605   gdb_with_regex=$gdb_use_included_regex)
 606 if test "$gdb_with_regex" = yes; then
 607   AC_DEFINE(USE_INCLUDED_REGEX, 1,
 608     [Define to 1 if the regex included in libiberty should be used.])
 609 fi
 610
 611 # See if <sys/proc.h> defines `struct thread' with a td_pcb member.
 612 AC_CACHE_CHECK([for td_pcb in struct thread], gdb_cv_struct_thread_td_pcb,
 613 [AC_TRY_COMPILE([#include <sys/param.h>
 614 #include <sys/proc.h>], [struct thread td; td.td_pcb;],
 615 gdb_cv_struct_thread_td_pcb=yes, gdb_cv_struct_thread_td_pcb=no)])
 616 if test $gdb_cv_struct_thread_td_pcb = yes; then
 617   AC_DEFINE(HAVE_STRUCT_THREAD_TD_PCB, 1,
 618             [Define to 1 if your system has td_pcb in struct thread.])
 619 fi
 620
 621 # See if <sys/lwp.h> defines `struct lwp`.
 622 AC_CACHE_CHECK([for struct lwp], gdb_cv_struct_lwp,
 623 [AC_TRY_COMPILE([#include <sys/param.h>
 624 #include <sys/lwp.h>], [struct lwp l;],
 625 gdb_cv_struct_lwp=yes, gdb_cv_struct_lwp=no)])
 626 if test $gdb_cv_struct_lwp = yes; then
 627   AC_DEFINE(HAVE_STRUCT_LWP, 1,
 628             [Define to 1 if your system has struct lwp.])
 629 fi
 630
 631 # See if <machine/reg.h> degines `struct reg'.
 632 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
 633 [AC_TRY_COMPILE([#include <sys/types.h>
 634 #include <machine/reg.h>], [struct reg r;],
 635 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
 636 if test $gdb_cv_struct_reg = yes; then
 637   AC_DEFINE(HAVE_STRUCT_REG, 1,
 638             [Define to 1 if your system has struct reg in <machine/reg.h>.])
 639 fi
 640
 641 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
 642 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
 643 AC_CACHE_CHECK([for r_fs in struct reg], gdb_cv_struct_reg_r_fs,
 644 [AC_TRY_COMPILE([#include <machine/reg.h>], [struct reg r; r.r_fs;],
 645 gdb_cv_struct_reg_r_fs=yes, gdb_cv_struct_reg_r_fs=no)])
 646 if test $gdb_cv_struct_reg_r_fs = yes; then
 647   AC_DEFINE(HAVE_STRUCT_REG_R_FS)
 648 fi
 649 AC_CACHE_CHECK([for r_gs in struct reg], gdb_cv_struct_reg_r_gs,
 650 [AC_TRY_COMPILE([#include <machine/reg.h>], [struct reg r; r.r_gs;],
 651 gdb_cv_struct_reg_r_gs=yes, gdb_cv_struct_reg_r_gs=no)])
 652 if test $gdb_cv_struct_reg_r_gs = yes; then
 653   AC_DEFINE(HAVE_STRUCT_REG_R_GS)
 654 fi
 655
 656 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
 657 AC_MSG_CHECKING(for PTRACE_GETREGS)
 658 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
 659 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 660                 [PTRACE_GETREGS;],
 661                 [gdb_cv_have_ptrace_getregs=yes],
 662                 [gdb_cv_have_ptrace_getregs=no])])
 663 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
 664 if test $gdb_cv_have_ptrace_getregs = yes; then
 665   AC_DEFINE(HAVE_PTRACE_GETREGS)
 666 fi
 667
 668 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
 669 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
 670 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
 671 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 672                 [PTRACE_GETFPXREGS;],
 673                 [gdb_cv_have_ptrace_getfpxregs=yes],
 674                 [gdb_cv_have_ptrace_getfpxregs=no])])
 675 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
 676 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
 677   AC_DEFINE(HAVE_PTRACE_GETFPXREGS)
 678 fi
 679
 680 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
 681 AC_MSG_CHECKING(for PT_GETDBREGS)
 682 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
 683 [AC_TRY_COMPILE([#include <sys/types.h>
 684 #include <sys/ptrace.h>],
 685                 [PT_GETDBREGS;],
 686                 [gdb_cv_have_pt_getdbregs=yes],
 687                 [gdb_cv_have_pt_getdbregs=no])])
 688 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
 689 if test $gdb_cv_have_pt_getdbregs = yes; then
 690   AC_DEFINE(HAVE_PT_GETDBREGS)
 691 fi
 692
 693 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
 694 AC_MSG_CHECKING(for PT_GETXMMREGS)
 695 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
 696 [AC_TRY_COMPILE([#include <sys/types.h>
 697 #include <sys/ptrace.h>],
 698                 [PT_GETXMMREGS;],
 699                 [gdb_cv_have_pt_getxmmregs=yes],
 700                 [gdb_cv_have_pt_getxmmregs=no])])
 701 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
 702 if test $gdb_cv_have_pt_getxmmregs = yes; then
 703   AC_DEFINE(HAVE_PT_GETXMMREGS)
 704 fi
 705
 706 # See if stdint.h provides the uintptr_t type.
 707 # Autoconf 2.5X has an improved AC_CHECK_TYPE which will simplify this.
 708 AC_CACHE_CHECK([for uintptr_t in stdint.h], gdb_cv_have_uintptr_t,
 709   [AC_TRY_COMPILE(
 710     [#include <stdint.h>],
 711     [uintptr_t foo = 0;],
 712     gdb_cv_have_uintptr_t=yes,
 713     gdb_cv_have_uintptr_t=no)])
 714 if test $gdb_cv_have_uintptr_t = yes; then
 715   AC_DEFINE(HAVE_UINTPTR_T, 1, [Define if <stdint.h> provides the uintptr_t type.])
 716 fi
 717
 718 BFD_NEED_DECLARATION(malloc)
 719 BFD_NEED_DECLARATION(realloc)
 720 BFD_NEED_DECLARATION(free)
 721 BFD_NEED_DECLARATION(strerror)
 722 BFD_NEED_DECLARATION(strdup)
 723 BFD_NEED_DECLARATION(strstr)
 724 BFD_NEED_DECLARATION(canonicalize_file_name)
 725
 726 # The following save_state_t checkery is only necessary for HPUX
 727 # versions earlier than 10.20.  When those fade from memory, this
 728 # could be expunged. --jsm 1999-03-22
 729
 730 AC_MSG_CHECKING(for HPUX save_state structure)
 731 AC_EGREP_HEADER(save_state_t, machine/save_state.h,
 732                 gdb_cv_hpux_savestate=yes, gdb_cv_hpux_savestate=no)
 733 AC_EGREP_HEADER(ss_wide, machine/save_state.h, gdb_cv_hpux_sswide=yes,
 734                 gdb_cv_hpux_sswide=no)
 735 if test $gdb_cv_hpux_savestate = yes
 736 then
 737   AC_DEFINE(HAVE_STRUCT_SAVE_STATE_T, 1)
 738 fi
 739 if test $gdb_cv_hpux_sswide = yes
 740 then
 741   AC_DEFINE(HAVE_STRUCT_MEMBER_SS_WIDE, 1)
 742 fi
 743 AC_MSG_RESULT($gdb_cv_hpux_sswide)
 744
 745
 746 # If we are configured native on GNU/Linux, work around problems with
 747 # sys/procfs.h
 748 # Also detect which type of /proc is in use, such as for Unixware or Solaris.
 749
 750 if test "${target}" = "${host}"; then
 751   case "${host}" in
 752   i[[3456]]86-*-linux*)
 753         AC_DEFINE(START_INFERIOR_TRAPS_EXPECTED,2)
 754         AC_DEFINE(sys_quotactl)
 755         ;;
 756   ia64-*-aix*)
 757       AC_DEFINE(NEW_PROC_API)
 758       ;;
 759   *-*-unixware* | *-*-sysv4.2* | *-*-sysv5* | *-*-interix* )
 760       AC_DEFINE(NEW_PROC_API)
 761       ;;
 762   *-*-solaris2.[[6789]])
 763       AC_DEFINE(NEW_PROC_API)
 764       ;;
 765   mips-sgi-irix5*)
 766       # Work around <sys/proc.h> needing _KMEMUSER problem on IRIX 5.
 767       AC_DEFINE([_KMEMUSER], 1)
 768       ;;
 769   esac
 770 fi
 771
 772 if test "$ac_cv_header_sys_procfs_h" = yes; then
 773   BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
 774   BFD_HAVE_SYS_PROCFS_TYPE(prrun_t)
 775   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
 776   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
 777   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
 778   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
 779   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
 780   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset32_t)
 781   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
 782   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
 783   BFD_HAVE_SYS_PROCFS_TYPE(prsysent_t)
 784   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigset_t)
 785   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigaction64_t)
 786   BFD_HAVE_SYS_PROCFS_TYPE(pr_siginfo64_t)
 787
 788
 789   dnl Check for broken prfpregset_t type
 790
 791   dnl For Linux/i386, glibc 2.1.3 was released with a bogus
 792   dnl prfpregset_t type (it's a typedef for the pointer to a struct
 793   dnl instead of the struct itself).  We detect this here, and work
 794   dnl around it in gdb_proc_service.h.
 795
 796   if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
 797     AC_MSG_CHECKING(whether prfpregset_t type is broken)
 798     AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
 799       [AC_TRY_RUN([#include <sys/procfs.h>
 800        int main ()
 801        {
 802          if (sizeof (prfpregset_t) == sizeof (void *))
 803            return 1;
 804          return 0;
 805        }],
 806        gdb_cv_prfpregset_t_broken=no,
 807        gdb_cv_prfpregset_t_broken=yes,
 808        gdb_cv_prfpregset_t_broken=yes)])
 809     AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
 810     if test $gdb_cv_prfpregset_t_broken = yes; then
 811       AC_DEFINE(PRFPREGSET_T_BROKEN)
 812     fi
 813   fi
 814
 815   dnl Check for PIOCSET ioctl entry
 816
 817   AC_MSG_CHECKING(for PIOCSET ioctl entry in sys/procfs.h)
 818   AC_CACHE_VAL(gdb_cv_have_procfs_piocset,
 819   [AC_TRY_COMPILE([#include <unistd.h>
 820 #include <sys/types.h>
 821 #include <sys/procfs.h>
 822 ], [
 823     int dummy;;
 824     dummy = ioctl(0, PIOCSET, &dummy);
 825   ],
 826   gdb_cv_have_procfs_piocset=yes, gdb_cv_have_procfs_piocset=no)])
 827   AC_MSG_RESULT($gdb_cv_have_procfs_piocset)
 828   if test $gdb_cv_have_procfs_piocset = yes; then
 829     AC_DEFINE(HAVE_PROCFS_PIOCSET)
 830   fi
 831 fi
 832
 833 dnl For native ports (host == target), check to see what kind of
 834 dnl legacy link.h support is needed.  (See solib-legacy.c.)
 835 if test ${host} = ${target} ; then
 836   dnl Check for struct link_map with l_ members which are indicative
 837   dnl of SVR4-like shared libraries
 838
 839   AC_MSG_CHECKING(for member l_addr in struct link_map)
 840   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_l_members,
 841     [AC_TRY_COMPILE([#include <link.h>],
 842                     [struct link_map lm; (void) lm.l_addr;],
 843                     gdb_cv_have_struct_link_map_with_l_members=yes,
 844                     gdb_cv_have_struct_link_map_with_l_members=no)])
 845   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_l_members)
 846   if test $gdb_cv_have_struct_link_map_with_l_members = yes; then
 847     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_L_MEMBERS)
 848   fi
 849
 850   dnl Check for struct link_map with lm_ members which are indicative
 851   dnl of SunOS-like shared libraries
 852
 853   AC_MSG_CHECKING(for member lm_addr in struct link_map)
 854   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_lm_members,
 855     [AC_TRY_COMPILE([#include <sys/types.h>
 856 #include <link.h>],
 857                     [struct link_map lm; (void) lm.lm_addr;],
 858                     gdb_cv_have_struct_link_map_with_lm_members=yes,
 859                     gdb_cv_have_struct_link_map_with_lm_members=no)])
 860   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_lm_members)
 861   if test $gdb_cv_have_struct_link_map_with_lm_members = yes; then
 862     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_LM_MEMBERS)
 863   fi
 864
 865   dnl Check for struct so_map with som_ members which are found on
 866   dnl some *BSD systems.
 867
 868   AC_MSG_CHECKING(for member som_addr in struct so_map)
 869   AC_CACHE_VAL(gdb_cv_have_struct_so_map_with_som_members,
 870     [AC_TRY_COMPILE([#include <sys/types.h>
 871 #ifdef HAVE_NLIST_H
 872 #include <nlist.h>
 873 #endif
 874 #include <link.h>],
 875                     [struct so_map lm; (void) lm.som_addr;],
 876                     gdb_cv_have_struct_so_map_with_som_members=yes,
 877                     gdb_cv_have_struct_so_map_with_som_members=no)])
 878   AC_MSG_RESULT($gdb_cv_have_struct_so_map_with_som_members)
 879   if test $gdb_cv_have_struct_so_map_with_som_members = yes; then
 880     AC_DEFINE(HAVE_STRUCT_SO_MAP_WITH_SOM_MEMBERS)
 881   fi
 882
 883   dnl Check for struct link_map32 type, which allows a 64-bit Solaris
 884   dnl debugger to debug a 32-bit Solaris app with 32-bit shared libraries.
 885
 886   AC_MSG_CHECKING(for struct link_map32 in sys/link.h)
 887   AC_CACHE_VAL(gdb_cv_have_struct_link_map32,
 888     [AC_TRY_COMPILE([#define _SYSCALL32
 889 #include <sys/link.h>], [struct link_map32 l;],
 890      gdb_cv_have_struct_link_map32=yes,
 891      gdb_cv_have_struct_link_map32=no)])
 892   AC_MSG_RESULT($gdb_cv_have_struct_link_map32)
 893   if test $gdb_cv_have_struct_link_map32 = yes; then
 894     AC_DEFINE(HAVE_STRUCT_LINK_MAP32)
 895     AC_DEFINE(_SYSCALL32)
 896   fi
 897 fi
 898
 899 dnl See if compiler supports "long long" type.
 900
 901 AC_MSG_CHECKING(for long long support in compiler)
 902 AC_CACHE_VAL(gdb_cv_c_long_long,
 903 [AC_TRY_COMPILE(, [
 904   extern long long foo;
 905   switch (foo & 2) { case 0: return 1; }
 906 ],
 907 gdb_cv_c_long_long=yes, gdb_cv_c_long_long=no)])
 908 AC_MSG_RESULT($gdb_cv_c_long_long)
 909 if test $gdb_cv_c_long_long = yes; then
 910   AC_DEFINE(CC_HAS_LONG_LONG)
 911 fi
 912
 913 dnl See if the compiler and runtime support printing long long
 914
 915 AC_MSG_CHECKING(for long long support in printf)
 916 AC_CACHE_VAL(gdb_cv_printf_has_long_long,
 917 [AC_TRY_RUN([
 918 int main () {
 919   char buf[32];
 920   long long l = 0;
 921   l = (l << 16) + 0x0123;
 922   l = (l << 16) + 0x4567;
 923   l = (l << 16) + 0x89ab;
 924   l = (l << 16) + 0xcdef;
 925   sprintf (buf, "0x%016llx", l);
 926   return (strcmp ("0x0123456789abcdef", buf));
 927 }],
 928 gdb_cv_printf_has_long_long=yes,
 929 gdb_cv_printf_has_long_long=no,
 930 gdb_cv_printf_has_long_long=no)])
 931 if test $gdb_cv_printf_has_long_long = yes; then
 932   AC_DEFINE(PRINTF_HAS_LONG_LONG)
 933 fi
 934 AC_MSG_RESULT($gdb_cv_printf_has_long_long)
 935
 936 dnl See if compiler supports "long double" type.  Can't use AC_C_LONG_DOUBLE
 937 dnl because autoconf complains about cross-compilation issues.  However, this
 938 dnl code uses the same variables as the macro for compatibility.
 939
 940 AC_MSG_CHECKING(for long double support in compiler)
 941 AC_CACHE_VAL(ac_cv_c_long_double,
 942 [AC_TRY_COMPILE(, [long double foo;],
 943 ac_cv_c_long_double=yes, ac_cv_c_long_double=no)])
 944 AC_MSG_RESULT($ac_cv_c_long_double)
 945 if test $ac_cv_c_long_double = yes; then
 946   AC_DEFINE(HAVE_LONG_DOUBLE)
 947 fi
 948
 949 dnl See if the compiler and runtime support printing long doubles
 950
 951 AC_MSG_CHECKING(for long double support in printf)
 952 AC_CACHE_VAL(gdb_cv_printf_has_long_double,
 953 [AC_TRY_RUN([
 954 int main () {
 955   char buf[16];
 956   long double f = 3.141592653;
 957   sprintf (buf, "%Lg", f);
 958   return (strncmp ("3.14159", buf, 7));
 959 }],
 960 gdb_cv_printf_has_long_double=yes,
 961 gdb_cv_printf_has_long_double=no,
 962 gdb_cv_printf_has_long_double=no)])
 963 if test $gdb_cv_printf_has_long_double = yes; then
 964   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE)
 965 fi
 966 AC_MSG_RESULT($gdb_cv_printf_has_long_double)
 967
 968 dnl See if the compiler and runtime support scanning long doubles
 969
 970 AC_MSG_CHECKING(for long double support in scanf)
 971 AC_CACHE_VAL(gdb_cv_scanf_has_long_double,
 972 [AC_TRY_RUN([
 973 int main () {
 974   char *buf = "3.141592653";
 975   long double f = 0;
 976   sscanf (buf, "%Lg", &f);
 977   return !(f > 3.14159 && f < 3.14160);
 978 }],
 979 gdb_cv_scanf_has_long_double=yes,
 980 gdb_cv_scanf_has_long_double=no,
 981 gdb_cv_scanf_has_long_double=no)])
 982 if test $gdb_cv_scanf_has_long_double = yes; then
 983   AC_DEFINE(SCANF_HAS_LONG_DOUBLE)
 984 fi
 985 AC_MSG_RESULT($gdb_cv_scanf_has_long_double)
 986
 987 case ${host_os} in
 988 aix*)
 989   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
 990     SAVE_LDFLAGS=$LDFLAGS
 991
 992     case $GCC in
 993     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
 994     *) gdb_cv_bigtoc=-bbigtoc ;;
 995     esac
 996
 997     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
 998     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
 999     LDFLAGS="${SAVE_LDFLAGS}"
1000   ])
1001   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
1002   ;;
1003 esac
1004
1005
1006 dnl For certain native configurations, we need to check whether thread
1007 dnl support can be built in or not.
1008 dnl
1009 dnl Note that we only want this if we are both native (host == target),
1010 dnl and not doing a canadian cross build (build == host).
1011
1012 if test ${build} = ${host} -a ${host} = ${target} ; then
1013    case ${host_os} in
1014    hpux*)
1015       AC_MSG_CHECKING(for HPUX/OSF thread support)
1016       if test -f /usr/include/dce/cma_config.h ; then
1017          if test "$GCC" = "yes" ; then
1018             AC_MSG_RESULT(yes)
1019             AC_DEFINE(HAVE_HPUX_THREAD_SUPPORT)
1020             CONFIG_OBS="${CONFIG_OBS} hpux-thread.o"
1021             CONFIG_SRCS="${CONFIG_SRCS} hpux-thread.c"
1022          else
1023             AC_MSG_RESULT(no (suppressed because you are not using GCC))
1024          fi
1025       else
1026          AC_MSG_RESULT(no)
1027       fi
1028       ;;
1029    solaris*)
1030       # See if thread_db library is around for Solaris thread debugging.
1031       # Note that we must explicitly test for version 1 of the library
1032       # because version 0 (present on Solaris 2.4 or earlier) doesn't have
1033       # the same API.
1034       AC_MSG_CHECKING(for Solaris thread debugging library)
1035       if test -f /usr/lib/libthread_db.so.1 ; then
1036          AC_MSG_RESULT(yes)
1037          AC_DEFINE(HAVE_THREAD_DB_LIB)
1038          CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
1039          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
1040          AC_CHECK_LIB(dl, dlopen)
1041          if test "$GCC" = "yes" ; then
1042             # The GNU linker requires the -export-dynamic option to make
1043             # all symbols visible in the dynamic symbol table.
1044             hold_ldflags=$LDFLAGS
1045             AC_MSG_CHECKING(for the ld -export-dynamic flag)
1046             LDFLAGS="${LDFLAGS} -Wl,-export-dynamic"
1047             AC_TRY_LINK(, [int i;], found=yes, found=no)
1048             LDFLAGS=$hold_ldflags
1049             AC_MSG_RESULT($found)
1050             if test $found = yes; then
1051                CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -Wl,-export-dynamic"
1052             fi
1053          fi
1054          # Sun randomly tweaked the prototypes in <proc_service.h>
1055          # at one point.
1056          AC_MSG_CHECKING(if <proc_service.h> is old)
1057          AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
1058             AC_TRY_COMPILE([
1059                 #include <proc_service.h>
1060                 ps_err_e ps_pdwrite
1061                     (struct ps_prochandle*, psaddr_t, const void*, size_t);
1062             ],, gdb_cv_proc_service_is_old=no,
1063                 gdb_cv_proc_service_is_old=yes)
1064          ])
1065          AC_MSG_RESULT($gdb_cv_proc_service_is_old)
1066          if test $gdb_cv_proc_service_is_old = yes; then
1067             AC_DEFINE(PROC_SERVICE_IS_OLD)
1068          fi
1069       else
1070          AC_MSG_RESULT(no)
1071       fi
1072       ;;
1073    aix*)
1074       AC_MSG_CHECKING(for AiX thread debugging library)
1075       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
1076                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
1077                                    [#ifndef PTHDB_VERSION_3
1078                                     #error
1079                                     #endif],
1080                                    gdb_cv_have_aix_thread_debug=yes,
1081                                    gdb_cv_have_aix_thread_debug=no)])
1082       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1083       if test $gdb_cv_have_aix_thread_debug = yes; then
1084          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1085          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1086          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -lpthdebug"
1087       fi
1088       ;;
1089    esac
1090    AC_SUBST(CONFIG_LDFLAGS)
1091 fi
1092
1093 dnl See if we have a thread_db header file that has TD_NOTALLOC.
1094 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1095    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
1096                   gdb_cv_thread_db_h_has_td_notalloc,
1097      AC_TRY_COMPILE(
1098        [#include <thread_db.h>],
1099        [int i = TD_NOTALLOC;],
1100        gdb_cv_thread_db_h_has_td_notalloc=yes,
1101        gdb_cv_thread_db_h_has_td_notalloc=no
1102      )
1103    )
1104 fi
1105 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1106   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1107             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1108 fi
1109
1110 dnl See if we have a sys/syscall header file that has __NR_tkill.
1111 if test "x$ac_cv_header_sys_syscall_h" = "xyes"; then
1112    AC_CACHE_CHECK([whether <sys/syscall.h> has __NR_tkill],
1113                   gdb_cv_sys_syscall_h_has_tkill,
1114      AC_TRY_COMPILE(
1115        [#include <sys/syscall.h>],
1116        [int i = __NR_tkill;],
1117        gdb_cv_sys_syscall_h_has_tkill=yes,
1118        gdb_cv_sys_syscall_h_has_tkill=no
1119      )
1120    )
1121 fi
1122 dnl See if we can issue tkill syscall.
1123 if test "x$gdb_cv_sys_syscall_h_has_tkill" = "xyes" && test "x$ac_cv_func_syscall" = "xyes"; then
1124   AC_DEFINE(HAVE_TKILL_SYSCALL, 1,
1125             [Define if we can use the tkill syscall.])
1126 fi
1127
1128 dnl Handle optional features that can be enabled.
1129
1130 AC_ARG_WITH(sysroot,
1131 [  --with-sysroot[=DIR] Search for usr/lib et al within DIR.],
1132 [
1133  case ${with_sysroot} in
1134  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
1135  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
1136  esac
1137
1138  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
1139
1140  if test "x$exec_prefix" = xNONE; then
1141   if test "x$prefix" = xNONE; then
1142    test_prefix=/usr/local
1143   else
1144    test_prefix=$prefix
1145   fi
1146  else
1147   test_prefix=$exec_prefix
1148  fi
1149  case ${TARGET_SYSTEM_ROOT} in
1150  "${test_prefix}"|"${test_prefix}/"*|\
1151  '${exec_prefix}'|'${exec_prefix}/'*)
1152    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
1153    TARGET_SYSTEM_ROOT_DEFINE="$t"
1154    ;;
1155  esac
1156 ], [
1157  TARGET_SYSTEM_ROOT=
1158  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"'
1159 ])
1160 AC_SUBST(TARGET_SYSTEM_ROOT)
1161 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
1162
1163 # NOTE: Don't add -Wall or -Wunused, they both include
1164 # -Wunused-parameter which reports bogus warnings.
1165 # NOTE: If you add to this list, remember to update
1166 # gdb/doc/gdbint.texinfo.
1167 build_warnings="-Wimplicit -Wreturn-type -Wcomment -Wtrigraphs \
1168 -Wformat -Wparentheses -Wpointer-arith -Wuninitialized -Wformat-nonliteral \
1169 -Wunused-label -Wunused-function"
1170 # Up for debate: -Wswitch -Wcomment -trigraphs -Wtrigraphs
1171 # -Wunused-function -Wunused-variable -Wunused-value
1172 # -Wchar-subscripts -Wtraditional -Wshadow -Wcast-qual
1173 # -Wcast-align -Wwrite-strings -Wconversion -Wstrict-prototypes
1174 # -Wmissing-prototypes -Wmissing-declarations -Wredundant-decls
1175 # -Woverloaded-virtual -Winline -Werror"
1176 AC_ARG_ENABLE(build-warnings,
1177 [  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
1178 [case "${enableval}" in
1179   yes)  ;;
1180   no)   build_warnings="-w";;
1181   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1182         build_warnings="${build_warnings} ${t}";;
1183   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1184         build_warnings="${t} ${build_warnings}";;
1185   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1186 esac
1187 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1188   echo "Setting compiler warning flags = $build_warnings" 6>&1
1189 fi])dnl
1190 AC_ARG_ENABLE(gdb-build-warnings,
1191 [  --enable-gdb-build-warnings Enable GDB specific build-time compiler warnings if gcc is used],
1192 [case "${enableval}" in
1193   yes)  ;;
1194   no)   build_warnings="-w";;
1195   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1196         build_warnings="${build_warnings} ${t}";;
1197   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1198         build_warnings="${t} ${build_warnings}";;
1199   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1200 esac
1201 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1202   echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1
1203 fi])dnl
1204 WARN_CFLAGS=""
1205 WERROR_CFLAGS=""
1206 if test "x${build_warnings}" != x -a "x$GCC" = xyes
1207 then
1208     AC_MSG_CHECKING(compiler warning flags)
1209     # Separate out the -Werror flag as some files just cannot be
1210     # compiled with it enabled.
1211     for w in ${build_warnings}; do
1212         case $w in
1213         -Werr*) WERROR_CFLAGS=-Werror ;;
1214         *) # Check that GCC accepts it
1215             saved_CFLAGS="$CFLAGS"
1216             CFLAGS="$CFLAGS $w"
1217             AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
1218             CFLAGS="$saved_CFLAGS"
1219         esac
1220     done
1221     AC_MSG_RESULT(${WARN_CFLAGS}${WERROR_CFLAGS})
1222 fi
1223 AC_SUBST(WARN_CFLAGS)
1224 AC_SUBST(WERROR_CFLAGS)
1225
1226 # In the Cygwin environment, we need some additional flags.
1227 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1228 [AC_EGREP_CPP(lose, [
1229 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1230 lose
1231 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1232
1233
1234 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1235 SER_HARDWIRE="ser-unix.o ser-pipe.o ser-tcp.o"
1236 case ${host} in
1237   *go32* ) SER_HARDWIRE=ser-go32.o ;;
1238   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
1239 esac
1240 AC_SUBST(SER_HARDWIRE)
1241
1242 # libreadline needs libuser32.a in a cygwin environment
1243 WIN32LIBS=
1244 if test x$gdb_cv_os_cygwin = xyes; then
1245     WIN32LIBS="-luser32"
1246     case "${target}" in
1247         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
1248         ;;
1249     esac
1250 fi
1251 AC_SUBST(WIN32LIBS)
1252
1253 LIBGUI="../libgui/src/libgui.a"
1254 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
1255 AC_SUBST(LIBGUI)
1256 AC_SUBST(GUI_CFLAGS_X)
1257
1258 WIN32LDAPP=
1259 AC_SUBST(WIN32LIBS)
1260 AC_SUBST(WIN32LDAPP)
1261
1262 case "${host}" in
1263 *-*-cygwin*)
1264     configdir="win"
1265     ;;
1266 *)
1267     configdir="unix"
1268     ;;
1269 esac
1270
1271 GDBTKLIBS=
1272 if test "${enable_gdbtk}" = "yes"; then
1273
1274     # Gdbtk must have an absolute path to srcdir in order to run
1275     # properly when not installed.
1276     here=`pwd`
1277     cd ${srcdir}
1278     GDBTK_SRC_DIR=`pwd`
1279     cd $here
1280
1281     CY_AC_PATH_TCLCONFIG
1282     if test -z "${no_tcl}"; then
1283         CY_AC_LOAD_TCLCONFIG
1284         CY_AC_PATH_TKCONFIG
1285
1286         # now look for Tcl library stuff
1287
1288         tcldir="../tcl/${configdir}/"
1289
1290         TCL_DEPS="${tcldir}${TCL_LIB_FILE}"
1291
1292         # If $no_tk is nonempty, then we can't do Tk, and there is no
1293         # point to doing Tcl.
1294         if test -z "${no_tk}"; then
1295            CY_AC_LOAD_TKCONFIG
1296            CY_AC_PATH_TCLH
1297            CY_AC_PATH_TKH
1298            CY_AC_PATH_ITCLH
1299            CY_AC_PATH_ITKH
1300
1301
1302            # now look for Tk library stuff
1303
1304            tkdir="../tk/${configdir}/"
1305
1306            TK_DEPS="${tkdir}${TK_LIB_FILE}"
1307
1308            # now look for Itcl library stuff
1309
1310            CY_AC_PATH_ITCLCONFIG
1311            if test -z "${no_itcl}"; then
1312              CY_AC_LOAD_ITCLCONFIG
1313
1314              ITCLLIB="${ITCL_BUILD_LIB_SPEC}"
1315              ITCL_DEPS="${ITCL_LIB_FULL_PATH}"
1316            fi
1317
1318
1319            # now look for Itk library stuff
1320            CY_AC_PATH_ITKCONFIG
1321            if test -z "${no_itcl}"; then
1322              CY_AC_LOAD_ITKCONFIG
1323
1324              ITKLIB="${ITK_BUILD_LIB_SPEC}"
1325              ITK_DEPS="${ITK_LIB_FULL_PATH}"
1326            fi
1327
1328            ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
1329            # Tcl/Tk 8.1 require -fwritable strings.  I don't
1330            # know whether 8.2 will or not, but I bet it will.
1331            # I don't have to worry about 7.x since we don't support it.
1332            GDBTK_CFLAGS=""
1333            if test "$GCC" = "yes"; then
1334                if test "$TCL_VERSION" != "8.0" ; then
1335                    GDBTK_CFLAGS="-fwritable-strings"
1336                fi
1337            fi
1338
1339            # Include some libraries that Tcl and Tk want.
1340            TCL_LIBS='$(LIBGUI) $(ITCL) $(ITK) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
1341            # Yes, the ordering seems wrong here.  But it isn't.
1342            # TK_LIBS is the list of libraries that need to be linked
1343            # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
1344            # were in LIBS then any link tests after this point would
1345            # try to include things like `$(LIBGUI)', which wouldn't work.
1346            GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
1347
1348            CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
1349            CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
1350            CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
1351            CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
1352            CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
1353            CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
1354            CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
1355
1356            if test x$gdb_cv_os_cygwin = xyes; then
1357               WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
1358               WIN32LDAPP="-Wl,--subsystem,console"
1359               CONFIG_OBS="${CONFIG_OBS} gdbres.o"
1360            fi
1361         fi
1362     fi
1363
1364     configdirs="${configdirs} gdbtk"
1365 fi
1366
1367 AC_SUBST(X_CFLAGS)
1368 AC_SUBST(X_LDFLAGS)
1369 AC_SUBST(X_LIBS)
1370 AC_SUBST(TCL_DEPS)
1371 AC_SUBST(TK_DEPS)
1372 AC_SUBST(ITCLLIB)
1373 AC_SUBST(ITCL_DEPS)
1374 AC_SUBST(ITKLIB)
1375 AC_SUBST(ITK_DEPS)
1376 AC_SUBST(GDBTKLIBS)
1377 AC_SUBST(GDBTK_CFLAGS)
1378 AC_SUBST(GDBTK_SRC_DIR)
1379
1380 AC_PATH_X
1381
1382
1383 # Unlike the sim directory, whether a simulator is linked is controlled by
1384 # presence of a SIM= and a SIM_OBS= definition in the target '.mt' file.
1385 # This code just checks for a few cases where we'd like to ignore those
1386 # definitions, even when they're present in the '.mt' file.  These cases
1387 # are when --disable-sim is specified, or if the simulator directory is
1388 # not part of the source tree.
1389 #
1390 AC_ARG_ENABLE(sim,
1391 [  --enable-sim            Link gdb with simulator],
1392 [echo "enable_sim = $enable_sim";
1393  echo "enableval = ${enableval}";
1394  case "${enableval}" in
1395   yes) ignore_sim=false ;;
1396   no)  ignore_sim=true ;;
1397   *)   ignore_sim=false ;;
1398  esac],
1399 [ignore_sim=false])
1400
1401 if test ! -d "${srcdir}/../sim"; then
1402   ignore_sim=true
1403 fi
1404
1405 if test "${ignore_sim}" = "true"; then
1406     IGNORE_SIM="SIM="
1407     IGNORE_SIM_OBS="SIM_OBS="
1408 else
1409     IGNORE_SIM=""
1410     IGNORE_SIM_OBS=""
1411     AC_DEFINE(WITH_SIM)
1412 fi
1413 AC_SUBST(IGNORE_SIM)
1414 AC_SUBST(IGNORE_SIM_OBS)
1415
1416 AC_SUBST(ENABLE_CFLAGS)
1417 AC_SUBST(PROFILE_CFLAGS)
1418
1419 AC_SUBST(CONFIG_OBS)
1420 AC_SUBST(CONFIG_DEPS)
1421 AC_SUBST(CONFIG_SRCS)
1422 AC_SUBST(CONFIG_ALL)
1423 AC_SUBST(CONFIG_CLEAN)
1424 AC_SUBST(CONFIG_INSTALL)
1425 AC_SUBST(CONFIG_UNINSTALL)
1426
1427 # List of host floatformats.
1428 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
1429 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
1430 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
1431
1432 # target_subdir is used by the testsuite to find the target libraries.
1433 target_subdir=
1434 if test "${host}" != "${target}"; then
1435     target_subdir="${target_alias}/"
1436 fi
1437 AC_SUBST(target_subdir)
1438
1439 frags=
1440 host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
1441 if test ! -f ${host_makefile_frag}; then
1442     # When building a native debuger the .mh file containing things
1443     # like NATDEPFILES is needed.  Cross debuggers don't need .mh
1444     # since it no longer contains anything useful.
1445     if test "${target}" = "${host}"; then
1446         AC_MSG_ERROR("*** Gdb does not support native target ${host}")
1447     else
1448         host_makefile_frag=/dev/null
1449     fi
1450 fi
1451 frags="$frags $host_makefile_frag"
1452
1453 target_makefile_frag=${srcdir}/config/${gdb_target_cpu}/${gdb_target}.mt
1454 if test ! -f ${target_makefile_frag}; then
1455 AC_MSG_ERROR("*** Gdb does not support target ${target}")
1456 fi
1457 frags="$frags $target_makefile_frag"
1458
1459 AC_SUBST_FILE(host_makefile_frag)
1460 AC_SUBST_FILE(target_makefile_frag)
1461 AC_SUBST(frags)
1462
1463 changequote(,)dnl
1464 hostfile=`sed -n '
1465 s/XM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
1466 ' ${host_makefile_frag}`
1467
1468 targetfile=`sed -n '
1469 s/TM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
1470 ' ${target_makefile_frag}`
1471
1472 if test "${target}" = "${host}"; then
1473 # We pick this up from the host configuration file (.mh) because we
1474 # do not have a native configuration Makefile fragment.
1475 nativefile=`sed -n '
1476 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
1477 ' ${host_makefile_frag}`
1478 fi
1479 changequote([,])
1480
1481 if test x"${gdb_osabi}" != x ; then
1482     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
1483                        [Define to the default OS ABI for this configuration.])
1484 fi
1485
1486 # Enable multi-ice-gdb-server.
1487 AC_ARG_ENABLE(multi-ice,
1488 [  --enable-multi-ice      build the multi-ice-gdb-server],
1489   [case $enableval in
1490     yes | no)
1491       ;;
1492     *) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;;
1493   esac])
1494 if test "x$enable_multi_ice" = xyes; then
1495   configdirs="$configdirs multi-ice"
1496 fi
1497
1498 # We only build gdbserver automatically if host and target are the same.
1499 if test "x$target" = "x$host"; then
1500   AC_MSG_CHECKING(whether gdbserver is supported on this host)
1501   if test "x$build_gdbserver" = xyes; then
1502     configdirs="$configdirs gdbserver"
1503     AC_MSG_RESULT(yes)
1504   else
1505     AC_MSG_RESULT(no)
1506   fi
1507 fi
1508
1509 AC_CONFIG_SUBDIRS($configdirs)
1510
1511 # If hostfile (XM_FILE) and/or targetfile (TM_FILE) and/or nativefile
1512 # (NAT_FILE) is not set in config/*/*.m[ht] files, we link to an empty
1513 # version.
1514
1515 files=
1516 links=
1517
1518 rm -f xm.h
1519 xm_h=""
1520 if test "${hostfile}" != ""; then
1521     xm_h=xm.h
1522     GDB_XM_FILE="config/${gdb_host_cpu}/${hostfile}"
1523     files="${files} ${GDB_XM_FILE}"
1524     links="${links} xm.h"
1525     AC_DEFINE_UNQUOTED(GDB_XM_FILE, ${GDB_XM_FILE})
1526 fi
1527 AC_SUBST(xm_h)
1528
1529 rm -f tm.h
1530 tm_h=""
1531 if test "${targetfile}" != ""; then
1532     tm_h=tm.h
1533     GDB_TM_FILE="config/${gdb_target_cpu}/${targetfile}"
1534     files="${files} ${GDB_TM_FILE}"
1535     links="${links} tm.h"
1536     AC_DEFINE_UNQUOTED(GDB_TM_FILE, ${GDB_TM_FILE})
1537 fi
1538 AC_SUBST(tm_h)
1539
1540 rm -f nm.h
1541 nm_h=""
1542 if test "${nativefile}" != ""; then
1543     nm_h=nm.h
1544     GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}"
1545     files="${files} ${GDB_NM_FILE}"
1546     links="${links} nm.h"
1547     AC_DEFINE_UNQUOTED(GDB_NM_FILE, ${GDB_NM_FILE})
1548 fi
1549 AC_SUBST(nm_h)
1550
1551 AC_LINK_FILES($files, $links)
1552
1553 dnl Check for exe extension set on certain hosts (e.g. Win32)
1554 AC_EXEEXT
1555
1556 dnl  Detect the character set used by this host.
1557
1558 dnl  At the moment, we just assume it's ISO-8859-1 (which is a
1559 dnl  superset of ASCII containing the characters needed for French,
1560 dnl  German, Spanish, Italian, and possibly others), but if were
1561 dnl  *were* to support any host character sets other than ISO-8859-1,
1562 dnl  here's where we'd detect it.
1563 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "ISO-8859-1",
1564           [Define to be a string naming the default host character set.])
1565
1566 AM_ICONV
1567
1568 AC_OUTPUT(Makefile .gdbinit:gdbinit.in,
1569 [
1570 dnl Autoconf doesn't provide a mechanism for modifying definitions
1571 dnl provided by makefile fragments.
1572 dnl
1573 if test "${nativefile}" = ""; then
1574         < Makefile \
1575         sed -e '/^NATDEPFILES[[         ]]*=.*\\$/,/[[^\\]]$/s/^/# /' \
1576             -e '/^NATDEPFILES[[         ]]*=/s/^/# /' \
1577         | sed -e '/^\(NATDEPFILES[[     ]]*[[+]]=[[     ]]*\)/s//# \1/' \
1578         > Makefile.tem
1579 mv -f Makefile.tem Makefile
1580 fi
1581
1582 changequote(,)dnl
1583 sed -e '/^TM_FILE[      ]*=/s,^TM_FILE[         ]*=[    ]*,&config/'"${gdb_target_cpu}"'/,
1584 /^XM_FILE[      ]*=/s,^XM_FILE[         ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,
1585 /^NAT_FILE[     ]*=/s,^NAT_FILE[        ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,' <Makefile >Makefile.tmp
1586 mv -f Makefile.tmp Makefile
1587 changequote([,])dnl
1588
1589
1590 case x$CONFIG_HEADERS in
1591 xconfig.h:config.in)
1592 echo > stamp-h ;;
1593 esac
1594 ],
1595 [
1596 gdb_host_cpu=$gdb_host_cpu
1597 gdb_target_cpu=$gdb_target_cpu
1598 nativefile=$nativefile
1599 ])
1600
1601 exit 0