gdb/configure.in

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004
   3 dnl Free Software Foundation, Inc.
   4 dnl
   5 dnl This file is part of GDB.
   6 dnl
   7 dnl This program is free software; you can redistribute it and/or modify
   8 dnl it under the terms of the GNU General Public License as published by
   9 dnl the Free Software Foundation; either version 2 of the License, or
  10 dnl (at your option) any later version.
  11 dnl
  12 dnl This program is distributed in the hope that it will be useful,
  13 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 dnl GNU General Public License for more details.
  16 dnl
  17 dnl You should have received a copy of the GNU General Public License
  18 dnl along with this program; if not, write to the Free Software
  19 dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  20
  21 dnl Process this file with autoconf to produce a configure script.
  22
  23 AC_PREREQ(2.13)dnl
  24 AC_INIT(main.c)
  25 AC_CONFIG_HEADER(config.h:config.in)
  26 AM_MAINTAINER_MODE
  27
  28 AC_PROG_CC
  29 AC_GNU_SOURCE
  30 AC_AIX
  31 AC_ISC_POSIX
  32 AM_PROG_CC_STDC
  33
  34 AC_CONFIG_AUX_DIR(`cd $srcdir;pwd`/..)
  35 AC_CANONICAL_SYSTEM
  36
  37 # FIXME: kettenis/20030102: The AC_PROG_RANLIB from Autoconf 2.13
  38 # doesn't support cross-compilation, but the one from Autoconf 2.5x
  39 # does.  Override RANLIB here (i.e. before running AC_PROG_RANLIB) to
  40 # deal with the lossage.  Note that CY_GNU_GETTEXT currently calls
  41 # AC_PROG_RANLIB.  This can be removed when we switch to Autoconf
  42 # 2.5x.
  43 AC_CHECK_TOOL(RANLIB, ranlib, :)
  44
  45 dnl Set up for gettext.  PACKAGE is used when we call bindtextdomain.
  46 ALL_LINGUAS=
  47 CY_GNU_GETTEXT
  48 AC_DEFINE(PACKAGE, "gdb", [Name of this package. ])
  49
  50 debugdir=${libdir}/debug
  51
  52 AC_ARG_WITH(separate-debug-dir,
  53 [  --with-separate-debug-dir=path   Look for global separate debug info in this path [LIBDIR/debug]],
  54 [debugdir="${withval}"])
  55
  56 AC_DEFINE_DIR(DEBUGDIR, debugdir,
  57               [Global directory for separate debug files. ])
  58 #AC_DEFINE_UNQUOTED(DEBUGDIR, "$debugdir"),
  59
  60 dnl List of object files added by configure.
  61
  62 CONFIG_OBS=
  63 CONFIG_DEPS=
  64 CONFIG_SRCS=
  65 ENABLE_CFLAGS=
  66 CONFIG_ALL=
  67 CONFIG_CLEAN=
  68 CONFIG_INSTALL=
  69 CONFIG_UNINSTALL=
  70
  71 AC_CONFIG_SUBDIRS(doc testsuite)
  72 configdirs=
  73
  74 . $srcdir/configure.host
  75
  76 . $srcdir/configure.tgt
  77
  78 # Fetch the default architecture and default target vector from BFD.
  79 targ=$target; . $srcdir/../bfd/config.bfd
  80
  81 # We only want the first architecture, so strip off the others if
  82 # there is more than one.
  83 targ_archs=`echo $targ_archs | sed 's/ .*//'`
  84
  85 if test "x$targ_archs" != x; then
  86   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
  87     [Define to BFD's default architecture. ])
  88 fi
  89 if test "x$targ_defvec" != x; then
  90   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
  91     [Define to BFD's default target vector. ])
  92 fi
  93
  94 AC_ARG_PROGRAM
  95
  96 # The CLI cannot be disabled yet, but may be in the future.
  97
  98 # Enable CLI.
  99 AC_ARG_ENABLE(gdbcli,
 100 [  --disable-gdbcli        disable command-line interface (CLI)],
 101   [case $enableval in
 102     yes)
 103       ;;
 104     no)
 105       AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;;
 106     *)
 107       AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;;
 108   esac],
 109   [enable_gdbcli=yes])
 110 if test x"$enable_gdbcli" = xyes; then
 111   if test -d $srcdir/cli; then
 112     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)"
 113     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)"
 114     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)"
 115     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)"
 116   fi
 117 fi
 118
 119 # Enable MI.
 120 AC_ARG_ENABLE(gdbmi,
 121 [  --disable-gdbmi         disable machine-interface (MI)],
 122   [case $enableval in
 123     yes | no)
 124       ;;
 125     *)
 126       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 127   esac],
 128   [enable_gdbmi=yes])
 129 if test x"$enable_gdbmi" = xyes; then
 130   if test -d $srcdir/mi; then
 131     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 132     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 133     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 134     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 135   fi
 136 fi
 137
 138 # Enable TUI.
 139 AC_ARG_ENABLE(tui,
 140 [  --enable-tui            enable full-screen terminal user interface (TUI)],
 141   [case $enableval in
 142     yes | no)
 143       ;;
 144     *)
 145       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 146   esac],enable_tui=yes)
 147 if test x"$enable_tui" = xyes; then
 148   if test -d $srcdir/tui; then
 149     if test "$ac_cv_search_initscr" != no -a "$ac_cv_search_wborder" != no; then
 150       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
 151       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
 152       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
 153       CONFIG_INITS="$CONFIG_INITS \$(SUBDIR_TUI_INITS)"
 154       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
 155       CONFIG_ALL="${CONFIG_ALL} all-tui"
 156       CONFIG_CLEAN="${CONFIG_CLEAN} clean-tui"
 157       CONFIG_INSTALL="${CONFIG_INSTALL} install-tui"
 158       CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-tui"
 159     fi
 160   fi
 161 fi
 162
 163 # Enable gdbtk.
 164 AC_ARG_ENABLE(gdbtk,
 165 [  --enable-gdbtk          enable gdbtk graphical user interface (GUI)],
 166   [case $enableval in
 167     yes | no)
 168       ;;
 169     *)
 170       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 171   esac],
 172   [if test -d $srcdir/gdbtk; then
 173     enable_gdbtk=yes
 174   else
 175     enable_gdbtk=no
 176   fi])
 177 # We unconditionally disable gdbtk tests on selected platforms.
 178 case $host_os in
 179   go32* | windows*)
 180     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 181     enable_gdbtk=no ;;
 182 esac
 183
 184 # Libunwind support.
 185 AC_ARG_WITH(libunwind,
 186 [  --with-libunwind            Use libunwind frame unwinding support],
 187 [case "${withval}" in
 188   yes)  enable_libunwind=yes ;;
 189   no)   enable_libunwind=no ;;
 190   *)    AC_MSG_ERROR(bad value ${withval} for GDB with-libunwind option) ;;
 191 esac],[
 192   AC_CHECK_HEADERS(libunwind.h)
 193   AC_CHECK_HEADERS(libunwind-ia64.h)
 194   if test x"$ac_cv_header_libunwind_h" = xyes -a x"$ac_cv_header_libunwind_ia64_h" = xyes; then
 195     enable_libunwind=yes;
 196   fi
 197 ])
 198
 199 if test x"$enable_libunwind" = xyes; then
 200   AC_CHECK_HEADERS(libunwind.h)
 201   AC_CHECK_HEADERS(libunwind-ia64.h)
 202   AC_DEFINE(HAVE_LIBUNWIND, 1)
 203   CONFIG_OBS="$CONFIG_OBS libunwind-frame.o"
 204   CONFIG_DEPS="$CONFIG_DEPS libunwind-frame.o"
 205   CONFIG_SRCS="$CONFIG_SRCS libunwind-frame.c"
 206 fi
 207
 208 # Profiling support.
 209 AC_ARG_ENABLE(profiling,
 210 [  --enable-profiling      enable profiling of GDB],
 211   [case $enableval in
 212     yes | no)
 213       ;;
 214     *)
 215       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 216   esac],
 217  [enable_profiling=no])
 218
 219 AC_CHECK_FUNCS(monstartup _mcleanup)
 220 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 221 [AC_TRY_LINK(
 222 [#include <stdlib.h>
 223 extern char _etext;
 224 ],
 225 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 226 if test $ac_cv_var__etext = yes; then
 227   AC_DEFINE(HAVE__ETEXT, 1,
 228             [Define to 1 if your system has the _etext variable. ])
 229 fi
 230 if test "$enable_profiling" = yes ; then
 231   if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
 232     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 233   fi
 234   PROFILE_CFLAGS=-pg
 235   OLD_CFLAGS="$CFLAGS"
 236   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 237
 238   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 239     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 240      ac_cv_cc_supports_pg=no)])
 241
 242   if test $ac_cv_cc_supports_pg = no; then
 243     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 244   fi
 245
 246   CFLAGS="$OLD_CFLAGS"
 247 fi
 248
 249 # --------------------- #
 250 # Checks for programs.  #
 251 # --------------------- #
 252
 253 AC_PROG_AWK
 254 AC_PROG_INSTALL
 255 AC_PROG_LN_S
 256 AC_PROG_RANLIB
 257 AC_PROG_YACC
 258
 259 AC_CHECK_TOOL(AR, ar)
 260 AC_CHECK_TOOL(DLLTOOL, dlltool)
 261 AC_CHECK_TOOL(WINDRES, windres)
 262
 263 # Needed for GNU/Hurd.
 264 AC_CHECK_TOOL(MIG, mig)
 265
 266 # ---------------------- #
 267 # Checks for libraries.  #
 268 # ---------------------- #
 269
 270 # We might need to link with -lm; most simulators need it.
 271 AC_CHECK_LIB(m, main)
 272
 273 # We need to link with -lw to get `wctype' on Solaris before Solaris
 274 # 2.6.  Solaris 2.6 and beyond have this function in libc, and have a
 275 # libw that some versions of the GNU linker cannot hanle (GNU ld 2.9.1
 276 # is known to have this problem).  Therefore we avoid libw if we can.
 277 AC_CHECK_FUNC(wctype, [],
 278   [AC_CHECK_LIB(w, wctype)])
 279
 280 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 281 AC_SEARCH_LIBS(gethostbyname, nsl)
 282
 283 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 284 AC_SEARCH_LIBS(socketpair, socket)
 285
 286 # Since GDB uses Readline, we need termcap functionality, so we need
 287 # to find a library that provides that.  When GDB is configured with
 288 # the TUI, we need full curses functionality.
 289
 290 case $host_os in
 291   cygwin*)
 292     if test -d $srcdir/libtermcap; then
 293       LIBS="../libtermcap/libtermcap.a $LIBS"
 294       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 295     fi ;;
 296   go32* | *djgpp*)
 297     ac_cv_search_tgetent="none required"
 298     ;;
 299   aix*)
 300     # Readline prefers curses over termcap on AIX.
 301     # ??? Why?
 302     AC_SEARCH_LIBS(tgetent, [tinfo ncurses curses termcap])
 303     ;;
 304 esac
 305
 306 # Note: We used to check for libtermlib and libterminfo too, but
 307 # Readline doesn't, so I think we're safe with leaving them out.
 308 AC_SEARCH_LIBS(tgetent, [termcap tinfo ncurses Hcurses curses])
 309
 310 if test "$ac_cv_search_tgetent" = no; then
 311   AC_MSG_ERROR([no termcap library found])
 312 fi
 313
 314 # FIXME: kettenis/20030102: We seem to prefer HP curses (Hcurses) over
 315 # Xcurses on HP-UX; see the `-D__HP_CURSES' in the relevant host
 316 # Makefile fragments.  That's why we need to have `Hcurses' before
 317 # `curses'.  I don't see why we should use HP curses if a more
 318 # standard curses is available, except that according to HP's
 319 # documentation one needs to compile `-D_XOPEN_SOURCE_EXTENDED' on
 320 # HP-UX 10.10 and 10.20.
 321
 322 case $host_os in
 323   osf5.*)
 324     # ncurses does not work on native alphaev68-dec-osf5.1
 325     # -- chastain 2004-04-24
 326     AC_SEARCH_LIBS(initscr, [curses], [],
 327       [AC_MSG_WARN([no curses library found])])
 328     ;;
 329   *)
 330     AC_SEARCH_LIBS(initscr, [ncurses Hcurses curses pdcurses], [],
 331       [AC_MSG_WARN([no curses library found])])
 332     ;;
 333 esac
 334
 335 # Check whether the wborder function is provided by the curses
 336 # library detected above.  In certain implementations such as
 337 # the HP/UX Hcurses for instance, this function is provided by an
 338 # additional library.  So if we did not find this function inside
 339 # the curses library, try some alternate libraries we know might
 340 # provide it.
 341 AC_SEARCH_LIBS(wborder, [cur_colr], [],
 342     [AC_MSG_WARN([wborder function not found, tui will be disabled])])
 343
 344 # ------------------------- #
 345 # Checks for header files.  #
 346 # ------------------------- #
 347
 348 AC_HEADER_DIRENT
 349 AC_HEADER_STAT
 350 AC_HEADER_STDC
 351 AC_CHECK_HEADERS(link.h)
 352 AC_CHECK_HEADERS(machine/reg.h)
 353 AC_CHECK_HEADERS(nlist.h)
 354 AC_CHECK_HEADERS(poll.h sys/poll.h)
 355 AC_CHECK_HEADERS(proc_service.h thread_db.h gnu/libc-version.h)
 356 AC_CHECK_HEADERS(stddef.h)
 357 AC_CHECK_HEADERS(stdlib.h)
 358 AC_CHECK_HEADERS(stdint.h)
 359 AC_CHECK_HEADERS(string.h memory.h strings.h)
 360 AC_CHECK_HEADERS(sys/fault.h)
 361 AC_CHECK_HEADERS(sys/file.h)
 362 AC_CHECK_HEADERS(sys/filio.h)
 363 AC_CHECK_HEADERS(sys/ioctl.h)
 364 AC_CHECK_HEADERS(sys/param.h)
 365 AC_CHECK_HEADERS(sys/proc.h)
 366 AC_CHECK_HEADERS(sys/procfs.h)
 367 AC_CHECK_HEADERS(sys/ptrace.h ptrace.h)
 368 AC_CHECK_HEADERS(sys/reg.h sys/debugreg.h)
 369 AC_CHECK_HEADERS(sys/select.h)
 370 AC_CHECK_HEADERS(sys/syscall.h)
 371 AC_CHECK_HEADERS(sys/user.h)
 372 AC_CHECK_HEADERS(sys/wait.h wait.h)
 373 AC_CHECK_HEADERS(termios.h termio.h sgtty.h)
 374 AC_CHECK_HEADERS(unistd.h)
 375
 376 # On Solaris 2.[78], we need to define _MSE_INT_H to avoid a clash
 377 # between <widec.h> and <wchar.h> that would cause AC_CHECK_HEADERS to
 378 # think that we don't have <curses.h> if we're using GCC.
 379 case $host_os in
 380   solaris2.[[78]])
 381     if test "$GCC" = yes; then
 382       AC_DEFINE(_MSE_INT_H, 1,
 383         [[Define to 1 to avoid a clash between <widec.h> and <wchar.h> on
 384    Solaris 2.[78] when using GCC. ]])
 385     fi ;;
 386 esac
 387 AC_CHECK_HEADERS(curses.h ncurses.h term.h)
 388
 389 # FIXME: kettenis/20030102: In most cases we include these
 390 # unconditionally, so what's the point in checking these?
 391 AC_CHECK_HEADERS(ctype.h time.h)
 392
 393 dnl Check for struct stat with an st_blocks member
 394 AC_MSG_CHECKING(for member st_blocks in struct stat)
 395 AC_CACHE_VAL(gdb_cv_have_struct_stat_with_st_blocks_member,
 396   [AC_TRY_COMPILE([#include <sys/types.h>
 397 #include <sys/stat.h>],
 398                   [struct stat st; (void) st.st_blocks;],
 399                   gdb_cv_have_struct_stat_with_st_blocks_member=yes,
 400                   gdb_cv_have_struct_stat_with_st_blocks_member=no)])
 401 AC_MSG_RESULT($gdb_cv_have_struct_stat_with_st_blocks_member)
 402 if test $gdb_cv_have_struct_stat_with_st_blocks_member = yes; then
 403   AC_DEFINE(HAVE_STRUCT_STAT_ST_BLOCKS)
 404 fi
 405 # ------------------------- #
 406 # Checks for declarations.  #
 407 # ------------------------- #
 408
 409 gcc_AC_CHECK_DECLS(getopt)
 410
 411 # ------------------ #
 412 # Checks for types.  #
 413 # ------------------ #
 414
 415 AC_TYPE_SIGNAL
 416
 417 # ------------------------------------- #
 418 # Checks for compiler characteristics.  #
 419 # ------------------------------------- #
 420
 421 AC_C_CONST
 422 AC_C_INLINE
 423
 424 # ------------------------------ #
 425 # Checks for library functions.  #
 426 # ------------------------------ #
 427
 428 AC_FUNC_ALLOCA
 429 AC_FUNC_MMAP
 430 AC_FUNC_VFORK
 431 AC_CHECK_FUNCS(canonicalize_file_name realpath)
 432 AC_CHECK_FUNCS(poll)
 433 AC_CHECK_FUNCS(pread64)
 434 AC_CHECK_FUNCS(sbrk)
 435 AC_CHECK_FUNCS(setpgid setpgrp)
 436 AC_CHECK_FUNCS(sigaction sigprocmask sigsetmask)
 437 AC_CHECK_FUNCS(socketpair)
 438 AC_CHECK_FUNCS(syscall)
 439
 440 dnl AC_FUNC_SETPGRP does not work when cross compiling
 441 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
 442 if test "$cross_compiling" = no; then
 443   AC_FUNC_SETPGRP
 444 else
 445   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
 446     [AC_TRY_COMPILE([
 447 #include <unistd.h>
 448 ], [
 449   if (setpgrp(1,1) == -1)
 450     exit (0);
 451   else
 452     exit (1);
 453 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
 454 if test $ac_cv_func_setpgrp_void = yes; then
 455   AC_DEFINE(SETPGRP_VOID, 1)
 456 fi
 457 fi
 458
 459 # Check if sigsetjmp is available.  Using AC_CHECK_FUNCS won't do
 460 # since sigsetjmp might only be defined as a macro.
 461 AC_CACHE_CHECK([for sigsetjmp], gdb_cv_func_sigsetjmp,
 462 [AC_TRY_COMPILE([
 463 #include <setjmp.h>
 464 ], [sigjmp_buf env; while (! sigsetjmp (env, 1)) siglongjmp (env, 1);],
 465 gdb_cv_func_sigsetjmp=yes, gdb_cv_func_sigsetjmp=no)])
 466 if test $gdb_cv_func_sigsetjmp = yes; then
 467   AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available. ])
 468 fi
 469
 470 # Assume we'll default to using the included libiberty regex.
 471 gdb_use_included_regex=yes
 472
 473 # However, if the system regex is GNU regex, then default to *not*
 474 # using the included regex.
 475 AC_CACHE_CHECK(
 476   [for GNU regex],
 477   [gdb_cv_have_gnu_regex],
 478   [AC_TRY_COMPILE(
 479     [#include <gnu-versions.h>],
 480     [#define REGEX_INTERFACE_VERSION 1
 481 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
 482 # error "Version mismatch"
 483 #endif],
 484     gdb_cv_have_gnu_regex=yes,
 485     gdb_cv_have_gnu_regex=no)])
 486 if test $gdb_cv_have_gnu_regex = yes; then
 487   gdb_use_included_regex=no
 488 fi
 489
 490 AC_ARG_WITH(included-regex,
 491   [  --without-included-regex don't use included regex; this is the default
 492                           on systems with version 2 of the GNU C library
 493                           (use with caution on other system)],
 494   gdb_with_regex=$withval,
 495   gdb_with_regex=$gdb_use_included_regex)
 496 if test "$gdb_with_regex" = yes; then
 497   AC_DEFINE(USE_INCLUDED_REGEX, 1,
 498     [Define to 1 if the regex included in libiberty should be used.])
 499 fi
 500
 501 # See if <machine/reg.h> degines `struct reg'.
 502 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
 503 [AC_TRY_COMPILE([#include <sys/types.h>
 504 #include <machine/reg.h>], [struct reg r;],
 505 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
 506 if test $gdb_cv_struct_reg = yes; then
 507   AC_DEFINE(HAVE_STRUCT_REG, 1,
 508             [Define to 1 if your system has struct reg in <machine/reg.h>.])
 509 fi
 510
 511 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
 512 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
 513 AC_CACHE_CHECK([for r_fs in struct reg], gdb_cv_struct_reg_r_fs,
 514 [AC_TRY_COMPILE([#include <machine/reg.h>], [struct reg r; r.r_fs;],
 515 gdb_cv_struct_reg_r_fs=yes, gdb_cv_struct_reg_r_fs=no)])
 516 if test $gdb_cv_struct_reg_r_fs = yes; then
 517   AC_DEFINE(HAVE_STRUCT_REG_R_FS)
 518 fi
 519 AC_CACHE_CHECK([for r_gs in struct reg], gdb_cv_struct_reg_r_gs,
 520 [AC_TRY_COMPILE([#include <machine/reg.h>], [struct reg r; r.r_gs;],
 521 gdb_cv_struct_reg_r_gs=yes, gdb_cv_struct_reg_r_gs=no)])
 522 if test $gdb_cv_struct_reg_r_gs = yes; then
 523   AC_DEFINE(HAVE_STRUCT_REG_R_GS)
 524 fi
 525
 526 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
 527 AC_MSG_CHECKING(for PTRACE_GETREGS)
 528 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
 529 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 530                 [PTRACE_GETREGS;],
 531                 [gdb_cv_have_ptrace_getregs=yes],
 532                 [gdb_cv_have_ptrace_getregs=no])])
 533 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
 534 if test $gdb_cv_have_ptrace_getregs = yes; then
 535   AC_DEFINE(HAVE_PTRACE_GETREGS)
 536 fi
 537
 538 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
 539 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
 540 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
 541 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 542                 [PTRACE_GETFPXREGS;],
 543                 [gdb_cv_have_ptrace_getfpxregs=yes],
 544                 [gdb_cv_have_ptrace_getfpxregs=no])])
 545 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
 546 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
 547   AC_DEFINE(HAVE_PTRACE_GETFPXREGS)
 548 fi
 549
 550 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
 551 AC_MSG_CHECKING(for PT_GETDBREGS)
 552 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
 553 [AC_TRY_COMPILE([#include <sys/types.h>
 554 #include <sys/ptrace.h>],
 555                 [PT_GETDBREGS;],
 556                 [gdb_cv_have_pt_getdbregs=yes],
 557                 [gdb_cv_have_pt_getdbregs=no])])
 558 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
 559 if test $gdb_cv_have_pt_getdbregs = yes; then
 560   AC_DEFINE(HAVE_PT_GETDBREGS)
 561 fi
 562
 563 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
 564 AC_MSG_CHECKING(for PT_GETXMMREGS)
 565 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
 566 [AC_TRY_COMPILE([#include <sys/types.h>
 567 #include <sys/ptrace.h>],
 568                 [PT_GETXMMREGS;],
 569                 [gdb_cv_have_pt_getxmmregs=yes],
 570                 [gdb_cv_have_pt_getxmmregs=no])])
 571 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
 572 if test $gdb_cv_have_pt_getxmmregs = yes; then
 573   AC_DEFINE(HAVE_PT_GETXMMREGS)
 574 fi
 575
 576 # See if stdint.h provides the uintptr_t type.
 577 # Autoconf 2.5X has an improved AC_CHECK_TYPE which will simplify this.
 578 AC_CACHE_CHECK([for uintptr_t in stdint.h], gdb_cv_have_uintptr_t,
 579   [AC_TRY_COMPILE(
 580     [#include <stdint.h>],
 581     [uintptr_t foo = 0;],
 582     gdb_cv_have_uintptr_t=yes,
 583     gdb_cv_have_uintptr_t=no)])
 584 if test $gdb_cv_have_uintptr_t = yes; then
 585   AC_DEFINE(HAVE_UINTPTR_T, 1, [Define if <stdint.h> provides the uintptr_t type.])
 586 fi
 587
 588 BFD_NEED_DECLARATION(malloc)
 589 BFD_NEED_DECLARATION(realloc)
 590 BFD_NEED_DECLARATION(free)
 591 BFD_NEED_DECLARATION(strerror)
 592 BFD_NEED_DECLARATION(strdup)
 593 BFD_NEED_DECLARATION(strstr)
 594 BFD_NEED_DECLARATION(canonicalize_file_name)
 595
 596 # The following save_state_t checkery is only necessary for HPUX
 597 # versions earlier than 10.20.  When those fade from memory, this
 598 # could be expunged. --jsm 1999-03-22
 599
 600 AC_MSG_CHECKING(for HPUX save_state structure)
 601 AC_EGREP_HEADER(save_state_t, machine/save_state.h,
 602                 gdb_cv_hpux_savestate=yes, gdb_cv_hpux_savestate=no)
 603 AC_EGREP_HEADER(ss_wide, machine/save_state.h, gdb_cv_hpux_sswide=yes,
 604                 gdb_cv_hpux_sswide=no)
 605 if test $gdb_cv_hpux_savestate = yes
 606 then
 607   AC_DEFINE(HAVE_STRUCT_SAVE_STATE_T, 1)
 608 fi
 609 if test $gdb_cv_hpux_sswide = yes
 610 then
 611   AC_DEFINE(HAVE_STRUCT_MEMBER_SS_WIDE, 1)
 612 fi
 613 AC_MSG_RESULT($gdb_cv_hpux_sswide)
 614
 615
 616 # If we are configured native on GNU/Linux, work around problems with
 617 # sys/procfs.h
 618 # Also detect which type of /proc is in use, such as for Unixware or Solaris.
 619
 620 if test "${target}" = "${host}"; then
 621   case "${host}" in
 622   i[[3456]]86-*-linux*)
 623         AC_DEFINE(START_INFERIOR_TRAPS_EXPECTED,2)
 624         AC_DEFINE(sys_quotactl)
 625         ;;
 626   ia64-*-aix*)
 627       AC_DEFINE(NEW_PROC_API)
 628       ;;
 629   *-*-unixware* | *-*-sysv4.2* | *-*-sysv5* | *-*-interix* )
 630       AC_DEFINE(NEW_PROC_API)
 631       ;;
 632   *-*-solaris2.[[6789]])
 633       AC_DEFINE(NEW_PROC_API)
 634       ;;
 635   esac
 636 fi
 637
 638 if test "$ac_cv_header_sys_procfs_h" = yes; then
 639   BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
 640   BFD_HAVE_SYS_PROCFS_TYPE(prrun_t)
 641   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
 642   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
 643   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
 644   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
 645   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
 646   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset32_t)
 647   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
 648   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
 649   BFD_HAVE_SYS_PROCFS_TYPE(prsysent_t)
 650   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigset_t)
 651   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigaction64_t)
 652   BFD_HAVE_SYS_PROCFS_TYPE(pr_siginfo64_t)
 653
 654
 655   dnl Check for broken prfpregset_t type
 656
 657   dnl For Linux/i386, glibc 2.1.3 was released with a bogus
 658   dnl prfpregset_t type (it's a typedef for the pointer to a struct
 659   dnl instead of the struct itself).  We detect this here, and work
 660   dnl around it in gdb_proc_service.h.
 661
 662   if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
 663     AC_MSG_CHECKING(whether prfpregset_t type is broken)
 664     AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
 665       [AC_TRY_RUN([#include <sys/procfs.h>
 666        int main ()
 667        {
 668          if (sizeof (prfpregset_t) == sizeof (void *))
 669            return 1;
 670          return 0;
 671        }],
 672        gdb_cv_prfpregset_t_broken=no,
 673        gdb_cv_prfpregset_t_broken=yes,
 674        gdb_cv_prfpregset_t_broken=yes)])
 675     AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
 676     if test $gdb_cv_prfpregset_t_broken = yes; then
 677       AC_DEFINE(PRFPREGSET_T_BROKEN)
 678     fi
 679   fi
 680
 681   dnl Check for PIOCSET ioctl entry
 682
 683   AC_MSG_CHECKING(for PIOCSET ioctl entry in sys/procfs.h)
 684   AC_CACHE_VAL(gdb_cv_have_procfs_piocset,
 685   [AC_TRY_COMPILE([#include <unistd.h>
 686 #include <sys/types.h>
 687 #include <sys/procfs.h>
 688 ], [
 689     int dummy;;
 690     dummy = ioctl(0, PIOCSET, &dummy);
 691   ],
 692   gdb_cv_have_procfs_piocset=yes, gdb_cv_have_procfs_piocset=no)])
 693   AC_MSG_RESULT($gdb_cv_have_procfs_piocset)
 694   if test $gdb_cv_have_procfs_piocset = yes; then
 695     AC_DEFINE(HAVE_PROCFS_PIOCSET)
 696   fi
 697 fi
 698
 699 dnl For native ports (host == target), check to see what kind of
 700 dnl legacy link.h support is needed.  (See solib-legacy.c.)
 701 if test ${host} = ${target} ; then
 702   dnl Check for struct link_map with l_ members which are indicative
 703   dnl of SVR4-like shared libraries
 704
 705   AC_MSG_CHECKING(for member l_addr in struct link_map)
 706   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_l_members,
 707     [AC_TRY_COMPILE([#include <link.h>],
 708                     [struct link_map lm; (void) lm.l_addr;],
 709                     gdb_cv_have_struct_link_map_with_l_members=yes,
 710                     gdb_cv_have_struct_link_map_with_l_members=no)])
 711   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_l_members)
 712   if test $gdb_cv_have_struct_link_map_with_l_members = yes; then
 713     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_L_MEMBERS)
 714   fi
 715
 716   dnl Check for struct link_map with lm_ members which are indicative
 717   dnl of SunOS-like shared libraries
 718
 719   AC_MSG_CHECKING(for member lm_addr in struct link_map)
 720   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_lm_members,
 721     [AC_TRY_COMPILE([#include <sys/types.h>
 722 #include <link.h>],
 723                     [struct link_map lm; (void) lm.lm_addr;],
 724                     gdb_cv_have_struct_link_map_with_lm_members=yes,
 725                     gdb_cv_have_struct_link_map_with_lm_members=no)])
 726   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_lm_members)
 727   if test $gdb_cv_have_struct_link_map_with_lm_members = yes; then
 728     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_LM_MEMBERS)
 729   fi
 730
 731   dnl Check for struct so_map with som_ members which are found on
 732   dnl some *BSD systems.
 733
 734   AC_MSG_CHECKING(for member som_addr in struct so_map)
 735   AC_CACHE_VAL(gdb_cv_have_struct_so_map_with_som_members,
 736     [AC_TRY_COMPILE([#include <sys/types.h>
 737 #ifdef HAVE_NLIST_H
 738 #include <nlist.h>
 739 #endif
 740 #include <link.h>],
 741                     [struct so_map lm; (void) lm.som_addr;],
 742                     gdb_cv_have_struct_so_map_with_som_members=yes,
 743                     gdb_cv_have_struct_so_map_with_som_members=no)])
 744   AC_MSG_RESULT($gdb_cv_have_struct_so_map_with_som_members)
 745   if test $gdb_cv_have_struct_so_map_with_som_members = yes; then
 746     AC_DEFINE(HAVE_STRUCT_SO_MAP_WITH_SOM_MEMBERS)
 747   fi
 748
 749   dnl Check for struct link_map32 type, which allows a 64-bit Solaris
 750   dnl debugger to debug a 32-bit Solaris app with 32-bit shared libraries.
 751
 752   AC_MSG_CHECKING(for struct link_map32 in sys/link.h)
 753   AC_CACHE_VAL(gdb_cv_have_struct_link_map32,
 754     [AC_TRY_COMPILE([#define _SYSCALL32
 755 #include <sys/link.h>], [struct link_map32 l;],
 756      gdb_cv_have_struct_link_map32=yes,
 757      gdb_cv_have_struct_link_map32=no)])
 758   AC_MSG_RESULT($gdb_cv_have_struct_link_map32)
 759   if test $gdb_cv_have_struct_link_map32 = yes; then
 760     AC_DEFINE(HAVE_STRUCT_LINK_MAP32)
 761     AC_DEFINE(_SYSCALL32)
 762   fi
 763 fi
 764
 765 dnl See if compiler supports "long long" type.
 766
 767 AC_MSG_CHECKING(for long long support in compiler)
 768 AC_CACHE_VAL(gdb_cv_c_long_long,
 769 [AC_TRY_COMPILE(, [
 770   extern long long foo;
 771   switch (foo & 2) { case 0: return 1; }
 772 ],
 773 gdb_cv_c_long_long=yes, gdb_cv_c_long_long=no)])
 774 AC_MSG_RESULT($gdb_cv_c_long_long)
 775 if test $gdb_cv_c_long_long = yes; then
 776   AC_DEFINE(CC_HAS_LONG_LONG)
 777 fi
 778
 779 dnl See if the compiler and runtime support printing long long
 780
 781 AC_MSG_CHECKING(for long long support in printf)
 782 AC_CACHE_VAL(gdb_cv_printf_has_long_long,
 783 [AC_TRY_RUN([
 784 int main () {
 785   char buf[32];
 786   long long l = 0;
 787   l = (l << 16) + 0x0123;
 788   l = (l << 16) + 0x4567;
 789   l = (l << 16) + 0x89ab;
 790   l = (l << 16) + 0xcdef;
 791   sprintf (buf, "0x%016llx", l);
 792   return (strcmp ("0x0123456789abcdef", buf));
 793 }],
 794 gdb_cv_printf_has_long_long=yes,
 795 gdb_cv_printf_has_long_long=no,
 796 gdb_cv_printf_has_long_long=no)])
 797 if test $gdb_cv_printf_has_long_long = yes; then
 798   AC_DEFINE(PRINTF_HAS_LONG_LONG)
 799 fi
 800 AC_MSG_RESULT($gdb_cv_printf_has_long_long)
 801
 802 dnl See if compiler supports "long double" type.  Can't use AC_C_LONG_DOUBLE
 803 dnl because autoconf complains about cross-compilation issues.  However, this
 804 dnl code uses the same variables as the macro for compatibility.
 805
 806 AC_MSG_CHECKING(for long double support in compiler)
 807 AC_CACHE_VAL(ac_cv_c_long_double,
 808 [AC_TRY_COMPILE(, [long double foo;],
 809 ac_cv_c_long_double=yes, ac_cv_c_long_double=no)])
 810 AC_MSG_RESULT($ac_cv_c_long_double)
 811 if test $ac_cv_c_long_double = yes; then
 812   AC_DEFINE(HAVE_LONG_DOUBLE)
 813 fi
 814
 815 dnl See if the compiler and runtime support printing long doubles
 816
 817 AC_MSG_CHECKING(for long double support in printf)
 818 AC_CACHE_VAL(gdb_cv_printf_has_long_double,
 819 [AC_TRY_RUN([
 820 int main () {
 821   char buf[16];
 822   long double f = 3.141592653;
 823   sprintf (buf, "%Lg", f);
 824   return (strncmp ("3.14159", buf, 7));
 825 }],
 826 gdb_cv_printf_has_long_double=yes,
 827 gdb_cv_printf_has_long_double=no,
 828 gdb_cv_printf_has_long_double=no)])
 829 if test $gdb_cv_printf_has_long_double = yes; then
 830   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE)
 831 fi
 832 AC_MSG_RESULT($gdb_cv_printf_has_long_double)
 833
 834 dnl See if the compiler and runtime support scanning long doubles
 835
 836 AC_MSG_CHECKING(for long double support in scanf)
 837 AC_CACHE_VAL(gdb_cv_scanf_has_long_double,
 838 [AC_TRY_RUN([
 839 int main () {
 840   char *buf = "3.141592653";
 841   long double f = 0;
 842   sscanf (buf, "%Lg", &f);
 843   return !(f > 3.14159 && f < 3.14160);
 844 }],
 845 gdb_cv_scanf_has_long_double=yes,
 846 gdb_cv_scanf_has_long_double=no,
 847 gdb_cv_scanf_has_long_double=no)])
 848 if test $gdb_cv_scanf_has_long_double = yes; then
 849   AC_DEFINE(SCANF_HAS_LONG_DOUBLE)
 850 fi
 851 AC_MSG_RESULT($gdb_cv_scanf_has_long_double)
 852
 853 case ${host_os} in
 854 aix*)
 855   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
 856     SAVE_LDFLAGS=$LDFLAGS
 857
 858     case $GCC in
 859     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
 860     *) gdb_cv_bigtoc=-bbigtoc ;;
 861     esac
 862
 863     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
 864     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
 865   ])
 866   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
 867   ;;
 868 esac
 869
 870
 871 dnl For certain native configurations, we need to check whether thread
 872 dnl support can be built in or not.
 873 dnl
 874 dnl Note that we only want this if we are both native (host == target),
 875 dnl and not doing a canadian cross build (build == host).
 876
 877 if test ${build} = ${host} -a ${host} = ${target} ; then
 878    case ${host_os} in
 879    hpux*)
 880       AC_MSG_CHECKING(for HPUX/OSF thread support)
 881       if test -f /usr/include/dce/cma_config.h ; then
 882          if test "$GCC" = "yes" ; then
 883             AC_MSG_RESULT(yes)
 884             AC_DEFINE(HAVE_HPUX_THREAD_SUPPORT)
 885             CONFIG_OBS="${CONFIG_OBS} hpux-thread.o"
 886             CONFIG_SRCS="${CONFIG_SRCS} hpux-thread.c"
 887          else
 888             AC_MSG_RESULT(no (suppressed because you are not using GCC))
 889          fi
 890       else
 891          AC_MSG_RESULT(no)
 892       fi
 893       ;;
 894    solaris*)
 895       # See if thread_db library is around for Solaris thread debugging.
 896       # Note that we must explicitly test for version 1 of the library
 897       # because version 0 (present on Solaris 2.4 or earlier) doesn't have
 898       # the same API.
 899       AC_MSG_CHECKING(for Solaris thread debugging library)
 900       if test -f /usr/lib/libthread_db.so.1 ; then
 901          AC_MSG_RESULT(yes)
 902          AC_DEFINE(HAVE_THREAD_DB_LIB)
 903          CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
 904          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
 905          AC_CHECK_LIB(dl, dlopen)
 906          if test "$GCC" = "yes" ; then
 907             # The GNU linker requires the -export-dynamic option to make
 908             # all symbols visible in the dynamic symbol table.
 909             hold_ldflags=$LDFLAGS
 910             AC_MSG_CHECKING(for the ld -export-dynamic flag)
 911             LDFLAGS="${LDFLAGS} -Wl,-export-dynamic"
 912             AC_TRY_LINK(, [int i;], found=yes, found=no)
 913             LDFLAGS=$hold_ldflags
 914             AC_MSG_RESULT($found)
 915             if test $found = yes; then
 916                CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -Wl,-export-dynamic"
 917             fi
 918          fi
 919          # Sun randomly tweaked the prototypes in <proc_service.h>
 920          # at one point.
 921          AC_MSG_CHECKING(if <proc_service.h> is old)
 922          AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
 923             AC_TRY_COMPILE([
 924                 #include <proc_service.h>
 925                 ps_err_e ps_pdwrite
 926                     (struct ps_prochandle*, psaddr_t, const void*, size_t);
 927             ],, gdb_cv_proc_service_is_old=no,
 928                 gdb_cv_proc_service_is_old=yes)
 929          ])
 930          AC_MSG_RESULT($gdb_cv_proc_service_is_old)
 931          if test $gdb_cv_proc_service_is_old = yes; then
 932             AC_DEFINE(PROC_SERVICE_IS_OLD)
 933          fi
 934       else
 935          AC_MSG_RESULT(no)
 936       fi
 937       ;;
 938    aix*)
 939       AC_MSG_CHECKING(for AiX thread debugging library)
 940       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
 941                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
 942                                    [#ifndef PTHDB_VERSION_3
 943                                     #error
 944                                     #endif],
 945                                    gdb_cv_have_aix_thread_debug=yes,
 946                                    gdb_cv_have_aix_thread_debug=no)])
 947       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
 948       if test $gdb_cv_have_aix_thread_debug = yes; then
 949          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
 950          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
 951          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -lpthdebug"
 952       fi
 953       ;;
 954    esac
 955    AC_SUBST(CONFIG_LDFLAGS)
 956 fi
 957
 958 dnl See if we have a thread_db header file that has TD_NOTALLOC.
 959 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
 960    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
 961                   gdb_cv_thread_db_h_has_td_notalloc,
 962      AC_TRY_COMPILE(
 963        [#include <thread_db.h>],
 964        [int i = TD_NOTALLOC;],
 965        gdb_cv_thread_db_h_has_td_notalloc=yes,
 966        gdb_cv_thread_db_h_has_td_notalloc=no
 967      )
 968    )
 969 fi
 970 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
 971   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
 972             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
 973 fi
 974
 975 dnl See if we have a sys/syscall header file that has __NR_tkill.
 976 if test "x$ac_cv_header_sys_syscall_h" = "xyes"; then
 977    AC_CACHE_CHECK([whether <sys/syscall.h> has __NR_tkill],
 978                   gdb_cv_sys_syscall_h_has_tkill,
 979      AC_TRY_COMPILE(
 980        [#include <sys/syscall.h>],
 981        [int i = __NR_tkill;],
 982        gdb_cv_sys_syscall_h_has_tkill=yes,
 983        gdb_cv_sys_syscall_h_has_tkill=no
 984      )
 985    )
 986 fi
 987 dnl See if we can issue tkill syscall.
 988 if test "x$gdb_cv_sys_syscall_h_has_tkill" = "xyes" && test "x$ac_cv_func_syscall" = "xyes"; then
 989   AC_DEFINE(HAVE_TKILL_SYSCALL, 1,
 990             [Define if we can use the tkill syscall.])
 991 fi
 992
 993 dnl Handle optional features that can be enabled.
 994
 995 AC_ARG_WITH(sysroot,
 996 [  --with-sysroot[=DIR] Search for usr/lib et al within DIR.],
 997 [
 998  case ${with_sysroot} in
 999  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
1000  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
1001  esac
1002
1003  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
1004
1005  if test "x$exec_prefix" = xNONE; then
1006   if test "x$prefix" = xNONE; then
1007    test_prefix=/usr/local
1008   else
1009    test_prefix=$prefix
1010   fi
1011  else
1012   test_prefix=$exec_prefix
1013  fi
1014  case ${TARGET_SYSTEM_ROOT} in
1015  "${test_prefix}"|"${test_prefix}/"*|\
1016  '${exec_prefix}'|'${exec_prefix}/'*)
1017    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
1018    TARGET_SYSTEM_ROOT_DEFINE="$t"
1019    ;;
1020  esac
1021 ], [
1022  TARGET_SYSTEM_ROOT=
1023  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"'
1024 ])
1025 AC_SUBST(TARGET_SYSTEM_ROOT)
1026 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
1027
1028 # NOTE: Don't add -Wall or -Wunused, they both include
1029 # -Wunused-parameter which reports bogus warnings.
1030 # NOTE: If you add to this list, remember to update
1031 # gdb/doc/gdbint.texinfo.
1032 build_warnings="-Wimplicit -Wreturn-type -Wcomment -Wtrigraphs \
1033 -Wformat -Wparentheses -Wpointer-arith -Wuninitialized -Wformat-nonliteral \
1034 -Wunused-label -Wunused-function"
1035 # Up for debate: -Wswitch -Wcomment -trigraphs -Wtrigraphs
1036 # -Wunused-function -Wunused-variable -Wunused-value
1037 # -Wchar-subscripts -Wtraditional -Wshadow -Wcast-qual
1038 # -Wcast-align -Wwrite-strings -Wconversion -Wstrict-prototypes
1039 # -Wmissing-prototypes -Wmissing-declarations -Wredundant-decls
1040 # -Woverloaded-virtual -Winline -Werror"
1041 AC_ARG_ENABLE(build-warnings,
1042 [  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
1043 [case "${enableval}" in
1044   yes)  ;;
1045   no)   build_warnings="-w";;
1046   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1047         build_warnings="${build_warnings} ${t}";;
1048   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1049         build_warnings="${t} ${build_warnings}";;
1050   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1051 esac
1052 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1053   echo "Setting compiler warning flags = $build_warnings" 6>&1
1054 fi])dnl
1055 AC_ARG_ENABLE(gdb-build-warnings,
1056 [  --enable-gdb-build-warnings Enable GDB specific build-time compiler warnings if gcc is used],
1057 [case "${enableval}" in
1058   yes)  ;;
1059   no)   build_warnings="-w";;
1060   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1061         build_warnings="${build_warnings} ${t}";;
1062   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1063         build_warnings="${t} ${build_warnings}";;
1064   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1065 esac
1066 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1067   echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1
1068 fi])dnl
1069 WARN_CFLAGS=""
1070 WERROR_CFLAGS=""
1071 if test "x${build_warnings}" != x -a "x$GCC" = xyes
1072 then
1073     AC_MSG_CHECKING(compiler warning flags)
1074     # Separate out the -Werror flag as some files just cannot be
1075     # compiled with it enabled.
1076     for w in ${build_warnings}; do
1077         case $w in
1078         -Werr*) WERROR_CFLAGS=-Werror ;;
1079         *) # Check that GCC accepts it
1080             saved_CFLAGS="$CFLAGS"
1081             CFLAGS="$CFLAGS $w"
1082             AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
1083             CFLAGS="$saved_CFLAGS"
1084         esac
1085     done
1086     AC_MSG_RESULT(${WARN_CFLAGS}${WERROR_CFLAGS})
1087 fi
1088 AC_SUBST(WARN_CFLAGS)
1089 AC_SUBST(WERROR_CFLAGS)
1090
1091 # In the Cygwin environment, we need some additional flags.
1092 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1093 [AC_EGREP_CPP(lose, [
1094 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1095 lose
1096 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1097
1098
1099 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1100 SER_HARDWIRE="ser-unix.o ser-pipe.o ser-tcp.o"
1101 case ${host} in
1102   *go32* ) SER_HARDWIRE=ser-go32.o ;;
1103   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
1104 esac
1105 AC_SUBST(SER_HARDWIRE)
1106
1107 # libreadline needs libuser32.a in a cygwin environment
1108 WIN32LIBS=
1109 if test x$gdb_cv_os_cygwin = xyes; then
1110     WIN32LIBS="-luser32"
1111     case "${target}" in
1112         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
1113         ;;
1114     esac
1115 fi
1116 AC_SUBST(WIN32LIBS)
1117
1118 LIBGUI="../libgui/src/libgui.a"
1119 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
1120 AC_SUBST(LIBGUI)
1121 AC_SUBST(GUI_CFLAGS_X)
1122
1123 WIN32LDAPP=
1124 AC_SUBST(WIN32LIBS)
1125 AC_SUBST(WIN32LDAPP)
1126
1127 configdir="unix"
1128
1129 GDBTKLIBS=
1130 if test "${enable_gdbtk}" = "yes"; then
1131
1132     # Gdbtk must have an absolute path to srcdir in order to run
1133     # properly when not installed.
1134     here=`pwd`
1135     cd ${srcdir}
1136     GDBTK_SRC_DIR=`pwd`
1137     cd $here
1138
1139     CY_AC_PATH_TCLCONFIG
1140     if test -z "${no_tcl}"; then
1141         CY_AC_LOAD_TCLCONFIG
1142         CY_AC_PATH_TKCONFIG
1143
1144         # now look for Tcl library stuff
1145
1146         case "${host}" in
1147         *-*-cygwin*)
1148             tcldir=../tcl/win/
1149             ;;
1150         *)
1151             tcldir=../tcl/unix/
1152             ;;
1153         esac
1154
1155         TCL_DEPS="${tcldir}${TCL_LIB_FILE}"
1156
1157         # If $no_tk is nonempty, then we can't do Tk, and there is no
1158         # point to doing Tcl.
1159         if test -z "${no_tk}"; then
1160            CY_AC_LOAD_TKCONFIG
1161            CY_AC_PATH_TCLH
1162            CY_AC_PATH_TKH
1163            CY_AC_PATH_ITCLH
1164            CY_AC_PATH_ITKH
1165
1166
1167            # now look for Tk library stuff
1168
1169            case "${host}" in
1170            *-*-cygwin*)
1171                tkdir=../tk/win/
1172                ;;
1173            *)
1174                tkdir=../tk/unix/
1175                ;;
1176            esac
1177
1178            TK_DEPS="${tkdir}${TK_LIB_FILE}"
1179
1180            # now look for Itcl library stuff
1181
1182            CY_AC_PATH_ITCLCONFIG
1183            if test -z "${no_itcl}"; then
1184              CY_AC_LOAD_ITCLCONFIG
1185
1186              ITCLLIB="${ITCL_BUILD_LIB_SPEC}"
1187              ITCL_DEPS="${ITCL_LIB_FULL_PATH}"
1188            fi
1189
1190
1191            # now look for Itk library stuff
1192            CY_AC_PATH_ITKCONFIG
1193            if test -z "${no_itcl}"; then
1194              CY_AC_LOAD_ITKCONFIG
1195
1196              ITKLIB="${ITK_BUILD_LIB_SPEC}"
1197              ITK_DEPS="${ITK_LIB_FULL_PATH}"
1198            fi
1199
1200            ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
1201            # Tcl/Tk 8.1 require -fwritable strings.  I don't
1202            # know whether 8.2 will or not, but I bet it will.
1203            # I don't have to worry about 7.x since we don't support it.
1204            GDBTK_CFLAGS=""
1205            if test "$GCC" = "yes"; then
1206                if test "$TCL_VERSION" != "8.0" ; then
1207                    GDBTK_CFLAGS="-fwritable-strings"
1208                fi
1209            fi
1210
1211            # Include some libraries that Tcl and Tk want.
1212            TCL_LIBS='$(LIBGUI) $(ITCL) $(ITK) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
1213            # Yes, the ordering seems wrong here.  But it isn't.
1214            # TK_LIBS is the list of libraries that need to be linked
1215            # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
1216            # were in LIBS then any link tests after this point would
1217            # try to include things like `$(LIBGUI)', which wouldn't work.
1218            GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
1219
1220            CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
1221            CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
1222            CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
1223            CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
1224            CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
1225            CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
1226            CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
1227
1228            if test x$gdb_cv_os_cygwin = xyes; then
1229               WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
1230               WIN32LDAPP="-Wl,--subsystem,console"
1231               CONFIG_OBS="${CONFIG_OBS} gdbres.o"
1232            fi
1233         fi
1234     fi
1235
1236     configdirs="${configdirs} gdbtk"
1237 fi
1238
1239 AC_SUBST(X_CFLAGS)
1240 AC_SUBST(X_LDFLAGS)
1241 AC_SUBST(X_LIBS)
1242 AC_SUBST(TCL_DEPS)
1243 AC_SUBST(TK_DEPS)
1244 AC_SUBST(ITCLLIB)
1245 AC_SUBST(ITCL_DEPS)
1246 AC_SUBST(ITKLIB)
1247 AC_SUBST(ITK_DEPS)
1248 AC_SUBST(GDBTKLIBS)
1249 AC_SUBST(GDBTK_CFLAGS)
1250 AC_SUBST(GDBTK_SRC_DIR)
1251
1252 AC_PATH_X
1253
1254
1255 # Unlike the sim directory, whether a simulator is linked is controlled by
1256 # presence of a SIM= and a SIM_OBS= definition in the target '.mt' file.
1257 # This code just checks for a few cases where we'd like to ignore those
1258 # definitions, even when they're present in the '.mt' file.  These cases
1259 # are when --disable-sim is specified, or if the simulator directory is
1260 # not part of the source tree.
1261 #
1262 AC_ARG_ENABLE(sim,
1263 [  --enable-sim            Link gdb with simulator],
1264 [echo "enable_sim = $enable_sim";
1265  echo "enableval = ${enableval}";
1266  case "${enableval}" in
1267   yes) ignore_sim=false ;;
1268   no)  ignore_sim=true ;;
1269   *)   ignore_sim=false ;;
1270  esac],
1271 [ignore_sim=false])
1272
1273 if test ! -d "${srcdir}/../sim"; then
1274   ignore_sim=true
1275 fi
1276
1277 if test "${ignore_sim}" = "true"; then
1278     IGNORE_SIM="SIM="
1279     IGNORE_SIM_OBS="SIM_OBS="
1280 else
1281     IGNORE_SIM=""
1282     IGNORE_SIM_OBS=""
1283     AC_DEFINE(WITH_SIM)
1284 fi
1285 AC_SUBST(IGNORE_SIM)
1286 AC_SUBST(IGNORE_SIM_OBS)
1287
1288 AC_SUBST(ENABLE_CFLAGS)
1289 AC_SUBST(PROFILE_CFLAGS)
1290
1291 AC_SUBST(CONFIG_OBS)
1292 AC_SUBST(CONFIG_DEPS)
1293 AC_SUBST(CONFIG_SRCS)
1294 AC_SUBST(CONFIG_ALL)
1295 AC_SUBST(CONFIG_CLEAN)
1296 AC_SUBST(CONFIG_INSTALL)
1297 AC_SUBST(CONFIG_UNINSTALL)
1298
1299 # target_subdir is used by the testsuite to find the target libraries.
1300 target_subdir=
1301 if test "${host}" != "${target}"; then
1302     target_subdir="${target_alias}/"
1303 fi
1304 AC_SUBST(target_subdir)
1305
1306 frags=
1307 host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
1308 if test ! -f ${host_makefile_frag}; then
1309     # When building a native debuger the .mh file containing things
1310     # like NATDEPFILES is needed.  Cross debuggers don't need .mh
1311     # since it no longer contains anything useful.
1312     if test "${target}" = "${host}"; then
1313         AC_MSG_ERROR("*** Gdb does not support native target ${host}")
1314     else
1315         host_makefile_frag=/dev/null
1316     fi
1317 fi
1318 frags="$frags $host_makefile_frag"
1319
1320 target_makefile_frag=${srcdir}/config/${gdb_target_cpu}/${gdb_target}.mt
1321 if test ! -f ${target_makefile_frag}; then
1322 AC_MSG_ERROR("*** Gdb does not support target ${target}")
1323 fi
1324 frags="$frags $target_makefile_frag"
1325
1326 AC_SUBST_FILE(host_makefile_frag)
1327 AC_SUBST_FILE(target_makefile_frag)
1328 AC_SUBST(frags)
1329
1330 changequote(,)dnl
1331 hostfile=`sed -n '
1332 s/XM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
1333 ' ${host_makefile_frag}`
1334
1335 targetfile=`sed -n '
1336 s/TM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
1337 ' ${target_makefile_frag}`
1338
1339 if test "${target}" = "${host}"; then
1340 # We pick this up from the host configuration file (.mh) because we
1341 # do not have a native configuration Makefile fragment.
1342 nativefile=`sed -n '
1343 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
1344 ' ${host_makefile_frag}`
1345 fi
1346 changequote([,])
1347
1348 if test x"${gdb_osabi}" != x ; then
1349     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
1350                        [Define to the default OS ABI for this configuration.])
1351 fi
1352
1353 # Enable multi-ice-gdb-server.
1354 AC_ARG_ENABLE(multi-ice,
1355 [  --enable-multi-ice      build the multi-ice-gdb-server],
1356   [case $enableval in
1357     yes | no)
1358       ;;
1359     *) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;;
1360   esac])
1361 if test "x$enable_multi_ice" = xyes; then
1362   configdirs="$configdirs multi-ice"
1363 fi
1364
1365 # We only build gdbserver automatically if host and target are the same.
1366 if test "x$target" = "x$host"; then
1367   AC_MSG_CHECKING(whether gdbserver is supported on this host)
1368   if test "x$build_gdbserver" = xyes; then
1369     configdirs="$configdirs gdbserver"
1370     AC_MSG_RESULT(yes)
1371   else
1372     AC_MSG_RESULT(no)
1373   fi
1374 fi
1375
1376 AC_CONFIG_SUBDIRS($configdirs)
1377
1378 # If hostfile (XM_FILE) and/or targetfile (TM_FILE) and/or nativefile
1379 # (NAT_FILE) is not set in config/*/*.m[ht] files, we link to an empty
1380 # version.
1381
1382 files=
1383 links=
1384
1385 rm -f xm.h
1386 xm_h=""
1387 if test "${hostfile}" != ""; then
1388     xm_h=xm.h
1389     GDB_XM_FILE="config/${gdb_host_cpu}/${hostfile}"
1390     files="${files} ${GDB_XM_FILE}"
1391     links="${links} xm.h"
1392     AC_DEFINE_UNQUOTED(GDB_XM_FILE, ${GDB_XM_FILE})
1393 fi
1394 AC_SUBST(xm_h)
1395
1396 rm -f tm.h
1397 tm_h=""
1398 if test "${targetfile}" != ""; then
1399     tm_h=tm.h
1400     GDB_TM_FILE="config/${gdb_target_cpu}/${targetfile}"
1401     files="${files} ${GDB_TM_FILE}"
1402     links="${links} tm.h"
1403     AC_DEFINE_UNQUOTED(GDB_TM_FILE, ${GDB_TM_FILE})
1404 fi
1405 AC_SUBST(tm_h)
1406
1407 rm -f nm.h
1408 nm_h=""
1409 if test "${nativefile}" != ""; then
1410     nm_h=nm.h
1411     GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}"
1412     files="${files} ${GDB_NM_FILE}"
1413     links="${links} nm.h"
1414     AC_DEFINE_UNQUOTED(GDB_NM_FILE, ${GDB_NM_FILE})
1415 fi
1416 AC_SUBST(nm_h)
1417
1418 AC_LINK_FILES($files, $links)
1419
1420 dnl Check for exe extension set on certain hosts (e.g. Win32)
1421 AC_EXEEXT
1422
1423 dnl  Detect the character set used by this host.
1424
1425 dnl  At the moment, we just assume it's ISO-8859-1 (which is a
1426 dnl  superset of ASCII containing the characters needed for French,
1427 dnl  German, Spanish, Italian, and possibly others), but if were
1428 dnl  *were* to support any host character sets other than ISO-8859-1,
1429 dnl  here's where we'd detect it.
1430 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "ISO-8859-1",
1431           [Define to be a string naming the default host character set.])
1432
1433 AM_ICONV
1434
1435 AC_OUTPUT(Makefile .gdbinit:gdbinit.in,
1436 [
1437 dnl Autoconf doesn't provide a mechanism for modifying definitions
1438 dnl provided by makefile fragments.
1439 dnl
1440 if test "${nativefile}" = ""; then
1441         < Makefile \
1442         sed -e '/^NATDEPFILES[[         ]]*=.*\\$/,/[[^\\]]$/s/^/# /' \
1443             -e '/^NATDEPFILES[[         ]]*=/s/^/# /' \
1444         | sed -e '/^\(NATDEPFILES[[     ]]*[[+]]=[[     ]]*\)/s//# \1/' \
1445         > Makefile.tem
1446 mv -f Makefile.tem Makefile
1447 fi
1448
1449 changequote(,)dnl
1450 sed -e '/^TM_FILE[      ]*=/s,^TM_FILE[         ]*=[    ]*,&config/'"${gdb_target_cpu}"'/,
1451 /^XM_FILE[      ]*=/s,^XM_FILE[         ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,
1452 /^NAT_FILE[     ]*=/s,^NAT_FILE[        ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,' <Makefile >Makefile.tmp
1453 mv -f Makefile.tmp Makefile
1454 changequote([,])dnl
1455
1456
1457 case x$CONFIG_HEADERS in
1458 xconfig.h:config.in)
1459 echo > stamp-h ;;
1460 esac
1461 ],
1462 [
1463 gdb_host_cpu=$gdb_host_cpu
1464 gdb_target_cpu=$gdb_target_cpu
1465 nativefile=$nativefile
1466 ])
1467
1468 exit 0