gdb/configure.ac

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995-2015 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Process this file with autoconf to produce a configure script.
  20
  21 AC_PREREQ(2.59)dnl
  22 AC_INIT(main.c)
  23 AC_CONFIG_HEADER(config.h:config.in)
  24 AM_MAINTAINER_MODE
  25
  26 # Set the 'development' global.
  27 . $srcdir/../bfd/development.sh
  28
  29 AC_PROG_CC
  30 AC_USE_SYSTEM_EXTENSIONS
  31 ACX_LARGEFILE
  32 AM_PROG_CC_STDC
  33 AM_PROG_INSTALL_STRIP
  34
  35 AC_CONFIG_AUX_DIR(..)
  36 AC_CANONICAL_SYSTEM
  37 AC_ARG_PROGRAM
  38
  39 # Dependency checking.
  40 ZW_CREATE_DEPDIR
  41 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  42
  43 # Check for the 'make' the user wants to use.
  44 AC_CHECK_PROGS(MAKE, make)
  45 MAKE_IS_GNU=
  46 case "`$MAKE --version 2>&1 | sed 1q`" in
  47   *GNU*)
  48     MAKE_IS_GNU=yes
  49     ;;
  50 esac
  51 AM_CONDITIONAL(GMAKE, test "$MAKE_IS_GNU" = yes)
  52 AC_PROG_MAKE_SET
  53
  54 gnulib_extra_configure_args=
  55 # If large-file support is disabled, make sure gnulib does the same.
  56 if test "$enable_largefile" = no; then
  57 gnulib_extra_configure_args="$gnulib_extra_configure_args --disable-largefile"
  58 fi
  59
  60 # Configure gnulib.  We need to build gnulib under some other
  61 # directory not "gnulib", to avoid the problem of both GDB and
  62 # GDBserver wanting to build it in the same directory, when building
  63 # in the source dir.
  64 ACX_CONFIGURE_DIR(["gnulib"], ["build-gnulib"],
  65                   ["$gnulib_extra_configure_args"])
  66
  67 dnl List of object files and targets accumulated by configure.
  68
  69 CONFIG_OBS=
  70 CONFIG_DEPS=
  71 CONFIG_SRCS=
  72 ENABLE_CFLAGS=
  73
  74 CONFIG_ALL=
  75 CONFIG_CLEAN=
  76 CONFIG_INSTALL=
  77 CONFIG_UNINSTALL=
  78
  79 dnl Set up for gettext.
  80 ZW_GNU_GETTEXT_SISTER_DIR
  81
  82 localedir='${datadir}/locale'
  83 AC_SUBST(localedir)
  84
  85 if test x"$USE_NLS" = xyes; then
  86    CONFIG_ALL="$CONFIG_ALL all-po"
  87    CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
  88    CONFIG_INSTALL="$CONFIG_INSTALL install-po"
  89    CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
  90 fi
  91
  92 GNULIB=build-gnulib/import
  93
  94 # For Makefile dependencies.
  95 GNULIB_STDINT_H=
  96 if test x"$STDINT_H" != x; then
  97   GNULIB_STDINT_H=$GNULIB/$STDINT_H
  98 fi
  99 AC_SUBST(GNULIB_STDINT_H)
 100
 101 PACKAGE=gdb
 102 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
 103 AC_SUBST(PACKAGE)
 104
 105 # We never need to detect it in this sub-configure.
 106 # But preserve it for config.status --recheck.
 107 AC_ARG_VAR(MAKEINFO,
 108   [Parent configure detects if it is of sufficient version.])
 109 AC_ARG_VAR(MAKEINFOFLAGS,
 110   [Parameters for MAKEINFO.])
 111
 112 MAKEINFO_EXTRA_FLAGS=""
 113 AC_CACHE_CHECK([whether $MAKEINFO supports @click], gdb_cv_have_makeinfo_click,
 114   [echo '@clicksequence{a @click{} b}' >conftest.texinfo
 115   if eval "$MAKEINFO conftest.texinfo >&5 2>&5"; then
 116     gdb_cv_have_makeinfo_click=yes
 117   else
 118     gdb_cv_have_makeinfo_click=no
 119   fi])
 120 if test x"$gdb_cv_have_makeinfo_click" = xyes; then
 121   MAKEINFO_EXTRA_FLAGS="$MAKEINFO_EXTRA_FLAGS -DHAVE_MAKEINFO_CLICK"
 122 fi
 123 AC_SUBST(MAKEINFO_EXTRA_FLAGS)
 124
 125 GDB_AC_WITH_DIR(DEBUGDIR, separate-debug-dir,
 126     [look for global separate debug info in this path @<:@LIBDIR/debug@:>@],
 127     [${libdir}/debug])
 128
 129 # We can't pass paths as command line arguments.
 130 # Mingw32 tries to be clever and will convert the paths for us.
 131 # For example -DBINDIR="/usr/local/bin" passed on the command line may get
 132 # converted to -DBINDIR="E:/msys/mingw32/msys/1.0/local/bin".
 133 # This breaks GDB's relocatable path conversions since paths passed in
 134 # config.h would not get so translated, the path prefixes no longer match.
 135 AC_DEFINE_DIR(BINDIR, bindir, [Directory of programs.])
 136
 137 # GDB's datadir relocation
 138
 139 GDB_AC_WITH_DIR(GDB_DATADIR, gdb-datadir,
 140     [look for global separate data files in this path @<:@DATADIR/gdb@:>@],
 141     [${datadir}/gdb])
 142
 143 AC_ARG_WITH(relocated-sources,
 144 AS_HELP_STRING([--with-relocated-sources=PATH], [automatically relocate this path for source files]),
 145 [reloc_srcdir="${withval}"
 146  AC_DEFINE_DIR(RELOC_SRCDIR, reloc_srcdir,
 147               [Relocated directory for source files. ])
 148 ])
 149
 150 AC_MSG_CHECKING([for default auto-load directory])
 151 AC_ARG_WITH(auto-load-dir,
 152 AS_HELP_STRING([--with-auto-load-dir=PATH],
 153   [directories from which to load auto-loaded scripts @<:@$debugdir:$datadir/auto-load@:>@]),,
 154   [with_auto_load_dir='$debugdir:$datadir/auto-load'])
 155 escape_dir=`echo $with_auto_load_dir | sed 's/[[$]]\(datadir\|debugdir\)\>/\\\\\\\\\\\\&/g'`
 156 AC_DEFINE_DIR(AUTO_LOAD_DIR, escape_dir,
 157               [Directories from which to load auto-loaded scripts.])
 158 AC_MSG_RESULT([$with_auto_load_dir])
 159
 160 AC_MSG_CHECKING([for default auto-load safe-path])
 161 AC_ARG_WITH(auto-load-safe-path,
 162 AS_HELP_STRING([--with-auto-load-safe-path=PATH],
 163   [directories safe to hold auto-loaded files @<:@--with-auto-load-dir@:>@])
 164 AS_HELP_STRING([--without-auto-load-safe-path],
 165                [do not restrict auto-loaded files locations]),
 166     [if test "$with_auto_load_safe_path" = "no"; then
 167      with_auto_load_safe_path="/"
 168      fi],
 169 [with_auto_load_safe_path="$with_auto_load_dir"])
 170 escape_dir=`echo $with_auto_load_safe_path | sed 's/[[$]]\(datadir\|debugdir\)\>/\\\\\\\\\\\\&/g'`
 171 AC_DEFINE_DIR(AUTO_LOAD_SAFE_PATH, escape_dir,
 172               [Directories safe to hold auto-loaded files.])
 173 AC_MSG_RESULT([$with_auto_load_safe_path])
 174
 175 AC_CONFIG_SUBDIRS(testsuite)
 176
 177 # Check whether to support alternative target configurations
 178 AC_ARG_ENABLE(targets,
 179 AS_HELP_STRING([--enable-targets=TARGETS], [alternative target configurations]),
 180 [case "${enableval}" in
 181   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
 182             ;;
 183   no)       enable_targets= ;;
 184   *)        enable_targets=$enableval ;;
 185 esac])
 186
 187 # Check whether to enable 64-bit support on 32-bit hosts
 188 AC_ARG_ENABLE(64-bit-bfd,
 189 AS_HELP_STRING([--enable-64-bit-bfd], [64-bit support (on hosts with narrower word sizes)]),
 190 [case "${enableval}" in
 191   yes)  want64=true  ;;
 192   no)   want64=false ;;
 193   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
 194 esac],[want64=false])dnl
 195
 196 # Provide defaults for some variables set by the per-host and per-target
 197 # configuration.
 198 gdb_host_obs=posix-hdep.o
 199
 200 if test "${target}" = "${host}"; then
 201   gdb_native=yes
 202 else
 203   gdb_native=no
 204 fi
 205
 206 . $srcdir/configure.host
 207
 208 # Add in the common host objects.
 209 . $srcdir/common/common.host
 210 gdb_host_obs="$gdb_host_obs $common_host_obs"
 211
 212 # Accumulate some settings from configure.tgt over all enabled targets
 213
 214 TARGET_OBS=
 215 all_targets=
 216 HAVE_NATIVE_GCORE_TARGET=
 217
 218 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 219 do
 220   if test "$targ_alias" = "all"; then
 221     all_targets=true
 222   else
 223     # Canonicalize the secondary target names.
 224     result=`$ac_config_sub $targ_alias 2>/dev/null`
 225     if test -n "$result"; then
 226         targ=$result
 227     else
 228         targ=$targ_alias
 229     fi
 230
 231     . ${srcdir}/configure.tgt
 232
 233     AS_IF([test -z "${gdb_target_obs}"],
 234       [AC_MSG_ERROR([configuration ${targ} is unsupported.])])
 235
 236     # Target-specific object files
 237     for i in ${gdb_target_obs}; do
 238         case " $TARGET_OBS " in
 239         *" ${i} "*) ;;
 240         *)
 241           TARGET_OBS="$TARGET_OBS ${i}"
 242           ;;
 243         esac
 244     done
 245
 246     # Check whether this target needs 64-bit CORE_ADDR
 247     if test x${want64} = xfalse; then
 248       . ${srcdir}/../bfd/config.bfd
 249     fi
 250
 251     # Check whether this target is native and supports gcore.
 252     if test $gdb_native = yes -a "$targ_alias" = "$target_alias" \
 253        && $gdb_have_gcore; then
 254       HAVE_NATIVE_GCORE_TARGET=1
 255     fi
 256   fi
 257 done
 258
 259 if test x${all_targets} = xtrue; then
 260
 261   # We want all 64-bit targets if we either:
 262   #  - run on a 64-bit host  or
 263   #  - already require 64-bit support for some other target  or
 264   #  - the --enable-64-bit-bfd option was supplied
 265   # Otherwise we only support all 32-bit targets.
 266   #
 267   # NOTE: This test must be in sync with the corresponding
 268   #       tests in BFD!
 269
 270   if test x${want64} = xfalse; then
 271     AC_CHECK_SIZEOF(long)
 272     if test "x${ac_cv_sizeof_long}" = "x8"; then
 273       want64=true
 274     fi
 275   fi
 276   if test x${want64} = xtrue; then
 277     TARGET_OBS='$(ALL_TARGET_OBS) $(ALL_64_TARGET_OBS)'
 278   else
 279     TARGET_OBS='$(ALL_TARGET_OBS)'
 280   fi
 281 fi
 282
 283 AC_SUBST(TARGET_OBS)
 284 AC_SUBST(HAVE_NATIVE_GCORE_TARGET)
 285
 286 # For other settings, only the main target counts.
 287 gdb_sim=
 288 gdb_osabi=
 289 build_gdbserver=
 290 targ=$target; . ${srcdir}/configure.tgt
 291
 292 # Fetch the default architecture and default target vector from BFD.
 293 targ=$target; . $srcdir/../bfd/config.bfd
 294
 295 # We only want the first architecture, so strip off the others if
 296 # there is more than one.
 297 targ_archs=`echo $targ_archs | sed 's/ .*//'`
 298
 299 if test "x$targ_archs" != x; then
 300   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
 301     [Define to BFD's default architecture. ])
 302 fi
 303 if test "x$targ_defvec" != x; then
 304   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
 305     [Define to BFD's default target vector. ])
 306 fi
 307
 308 # The CLI cannot be disabled yet, but may be in the future.
 309
 310 # Enable CLI.
 311 AC_ARG_ENABLE(gdbcli,
 312 AS_HELP_STRING([--disable-gdbcli], [disable command-line interface (CLI)]),
 313   [case $enableval in
 314     yes)
 315       ;;
 316     no)
 317       AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;;
 318     *)
 319       AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;;
 320   esac],
 321   [enable_gdbcli=yes])
 322 if test x"$enable_gdbcli" = xyes; then
 323   if test -d $srcdir/cli; then
 324     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)"
 325     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)"
 326     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)"
 327     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)"
 328   fi
 329 fi
 330
 331 # Enable MI.
 332 AC_ARG_ENABLE(gdbmi,
 333 AS_HELP_STRING([--disable-gdbmi], [disable machine-interface (MI)]),
 334   [case $enableval in
 335     yes | no)
 336       ;;
 337     *)
 338       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 339   esac],
 340   [enable_gdbmi=yes])
 341 if test x"$enable_gdbmi" = xyes; then
 342   if test -d $srcdir/mi; then
 343     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 344     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 345     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 346     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 347   fi
 348 fi
 349
 350 # Enable TUI.
 351 AC_ARG_ENABLE(tui,
 352 AS_HELP_STRING([--enable-tui], [enable full-screen terminal user interface (TUI)]),
 353   [case $enableval in
 354     yes | no | auto)
 355       ;;
 356     *)
 357       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 358   esac],enable_tui=auto)
 359
 360 # Enable gdbtk.
 361 AC_ARG_ENABLE(gdbtk,
 362 AS_HELP_STRING([--enable-gdbtk], [enable gdbtk graphical user interface (GUI)]),
 363   [case $enableval in
 364     yes | no)
 365       ;;
 366     *)
 367       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 368   esac],
 369   [if test -d $srcdir/gdbtk; then
 370     enable_gdbtk=yes
 371   else
 372     enable_gdbtk=no
 373   fi])
 374 # We unconditionally disable gdbtk tests on selected platforms.
 375 case $host_os in
 376   go32* | windows*)
 377     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 378     enable_gdbtk=no ;;
 379 esac
 380
 381 # Libunwind support for ia64.
 382
 383 AC_ARG_WITH(libunwind-ia64,
 384 AS_HELP_STRING([--with-libunwind-ia64],
 385                [use libunwind frame unwinding for ia64 targets]),,
 386             [with_libunwind_ia64=auto])
 387
 388 # Backward compatibility option.
 389 if test "${with_libunwind+set}" = set; then
 390   if test x"$with_libunwind_ia64" != xauto; then
 391     AC_MSG_ERROR(
 392       [option --with-libunwind is deprecated, use --with-libunwind-ia64])
 393   fi
 394   AC_MSG_WARN([option --with-libunwind is deprecated, use --with-libunwind-ia64])
 395   with_libunwind_ia64="$with_libunwind"
 396 fi
 397
 398 case "$with_libunwind_ia64" in
 399   yes | no)
 400     ;;
 401   auto)
 402     AC_CHECK_HEADERS(libunwind-ia64.h)
 403     with_libunwind_ia64=$ac_cv_header_libunwind_ia64_h
 404     ;;
 405   *)
 406     AC_MSG_ERROR(
 407       [bad value $with_libunwind_ia64 for GDB --with-libunwind-ia64 option])
 408     ;;
 409 esac
 410
 411 if test x"$with_libunwind_ia64" = xyes; then
 412   AC_CHECK_HEADERS(libunwind-ia64.h)
 413   if test x"$ac_cv_header_libunwind_ia64_h" != xyes; then
 414     AC_MSG_ERROR([GDB option --with-libunwind-ia64 requires libunwind-ia64.h])
 415   fi
 416   CONFIG_OBS="$CONFIG_OBS ia64-libunwind-tdep.o"
 417   CONFIG_DEPS="$CONFIG_DEPS ia64-libunwind-tdep.o"
 418   CONFIG_SRCS="$CONFIG_SRCS ia64-libunwind-tdep.c"
 419 fi
 420
 421 opt_curses=no
 422 AC_ARG_WITH(curses, AS_HELP_STRING([--with-curses], [use the curses library instead of the termcap library]), opt_curses=$withval)
 423
 424 prefer_curses=no
 425 if test "$opt_curses" = "yes"; then
 426   prefer_curses=yes
 427 fi
 428
 429 # Profiling support.
 430 AC_ARG_ENABLE(profiling,
 431 AS_HELP_STRING([--enable-profiling], [enable profiling of GDB]),
 432   [case $enableval in
 433     yes | no)
 434       ;;
 435     *)
 436       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 437   esac],
 438  [enable_profiling=no])
 439
 440 AC_CHECK_FUNCS(monstartup _mcleanup)
 441 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 442 [AC_TRY_LINK(
 443 [#include <stdlib.h>
 444 extern char _etext;
 445 ],
 446 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 447 if test $ac_cv_var__etext = yes; then
 448   AC_DEFINE(HAVE__ETEXT, 1,
 449             [Define to 1 if your system has the _etext variable. ])
 450 fi
 451 AC_CACHE_CHECK([for etext], ac_cv_var_etext,
 452 [AC_TRY_LINK(
 453 [#include <stdlib.h>
 454 extern char etext;
 455 ],
 456 [free (&etext);], ac_cv_var_etext=yes, ac_cv_var_etext=no)])
 457 if test $ac_cv_var_etext = yes; then
 458   AC_DEFINE(HAVE_ETEXT, 1,
 459             [Define to 1 if your system has the etext variable. ])
 460 fi
 461 if test "$enable_profiling" = yes ; then
 462   if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
 463     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 464   fi
 465   PROFILE_CFLAGS=-pg
 466   OLD_CFLAGS="$CFLAGS"
 467   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 468
 469   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 470     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 471      ac_cv_cc_supports_pg=no)])
 472
 473   if test $ac_cv_cc_supports_pg = no; then
 474     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 475   fi
 476
 477   CFLAGS="$OLD_CFLAGS"
 478 fi
 479
 480 ACX_PKGVERSION([GDB])
 481 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 482 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 483 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 484
 485 # --------------------- #
 486 # Checks for programs.  #
 487 # --------------------- #
 488
 489 AC_PROG_AWK
 490 AC_PROG_INSTALL
 491 AC_PROG_LN_S
 492 AC_PROG_RANLIB
 493 AC_PROG_YACC
 494
 495 AC_CHECK_TOOL(AR, ar)
 496 AC_CHECK_TOOL(DLLTOOL, dlltool)
 497 AC_CHECK_TOOL(WINDRES, windres)
 498
 499 case $host_os in
 500   gnu*)
 501     # Needed for GNU Hurd hosts.
 502     AC_CHECK_TOOL(MIG, mig)
 503     if test x"$MIG" = x; then
 504       AC_MSG_ERROR([MIG not found but required for $host hosts])
 505     fi
 506     ;;
 507 esac
 508
 509 # ---------------------- #
 510 # Checks for libraries.  #
 511 # ---------------------- #
 512
 513 # We might need to link with -lm; most simulators need it.
 514 AC_CHECK_LIB(m, main)
 515
 516 # We need to link with -lw to get `wctype' on Solaris before Solaris
 517 # 2.6.  Solaris 2.6 and beyond have this function in libc, and have a
 518 # libw that some versions of the GNU linker cannot hanle (GNU ld 2.9.1
 519 # is known to have this problem).  Therefore we avoid libw if we can.
 520 AC_CHECK_FUNC(wctype, [],
 521   [AC_CHECK_LIB(w, wctype)])
 522
 523 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 524 AC_SEARCH_LIBS(gethostbyname, nsl)
 525
 526 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 527 AC_SEARCH_LIBS(socketpair, socket)
 528
 529 # Link in zlib if we can.  This allows us to read compressed debug sections.
 530 AM_ZLIB
 531
 532 # On HP/UX we may need libxpdl for dlgetmodinfo (used by solib-pa64.c).
 533 AC_SEARCH_LIBS(dlgetmodinfo, [dl xpdl])
 534
 535 AM_ICONV
 536
 537 # GDB may fork/exec the iconv program to get the list of supported character
 538 # sets.  Allow the user to specify where to find it.
 539 # There are several factors affecting the choice of option name:
 540 # - There is already --with-libiconv-prefix but we can't use it, it specifies
 541 #   the build-time location of libiconv files.
 542 # - The program we need to find is iconv, which comes with glibc.  The user
 543 #   doesn't necessarily have libiconv installed.  Therefore naming this
 544 #   --with-libiconv-foo feels wrong.
 545 # - We want the path to be relocatable, but GDB_AC_DEFINE_RELOCATABLE is
 546 #   defined to work on directories not files (though it really doesn't know
 547 #   the difference).
 548 # - Calling this --with-iconv-prefix is perceived to cause too much confusion
 549 #   with --with-libiconv-prefix.
 550 # Putting these together is why the option name is --with-iconv-bin.
 551
 552 AC_ARG_WITH(iconv-bin,
 553 AS_HELP_STRING([--with-iconv-bin=PATH], [specify where to find the iconv program]),
 554 [iconv_bin="${withval}"
 555  AC_DEFINE_UNQUOTED([ICONV_BIN], ["${iconv_bin}"],
 556                     [Path of directory of iconv program.])
 557  GDB_AC_DEFINE_RELOCATABLE(ICONV_BIN, iconv, ${iconv_bin})
 558 ])
 559
 560 # For the TUI, we need enhanced curses functionality.
 561 if test x"$enable_tui" != xno; then
 562   prefer_curses=yes
 563 fi
 564
 565 curses_found=no
 566 if test x"$prefer_curses" = xyes; then
 567   # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
 568   # curses library because the latter might not provide all the
 569   # functionality we need.  However, this leads to problems on systems
 570   # where the linker searches /usr/local/lib, but the compiler doesn't
 571   # search /usr/local/include, if ncurses is installed in /usr/local.  A
 572   # default installation of ncurses on alpha*-dec-osf* will lead to such
 573   # a situation.
 574   AC_SEARCH_LIBS(waddstr, [ncurses cursesX curses])
 575
 576   if test "$ac_cv_search_waddstr" != no; then
 577     curses_found=yes
 578   fi
 579 fi
 580
 581 # Check whether we should enable the TUI, but only do so if we really
 582 # can.
 583 if test x"$enable_tui" != xno; then
 584   if test -d $srcdir/tui; then
 585     if test "$curses_found" != no; then
 586       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
 587       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
 588       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
 589       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
 590     else
 591       if test x"$enable_tui" = xyes; then
 592         AC_MSG_ERROR([no enhanced curses library found; disable TUI])
 593       else
 594         AC_MSG_WARN([no enhanced curses library found; disabling TUI])
 595       fi
 596     fi
 597   fi
 598 fi
 599
 600 # Since GDB uses Readline, we need termcap functionality.  In many
 601 # cases this will be provided by the curses library, but some systems
 602 # have a seperate termcap library, or no curses library at all.
 603
 604 case $host_os in
 605   cygwin*)
 606     if test -d $srcdir/libtermcap; then
 607       LIBS="../libtermcap/libtermcap.a $LIBS"
 608       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 609     fi ;;
 610   go32* | *djgpp*)
 611     ac_cv_search_tgetent="none required"
 612     ;;
 613   *mingw32*)
 614     if test x"$curses_found" != xyes; then
 615       ac_cv_search_tgetent="none required"
 616       CONFIG_OBS="$CONFIG_OBS windows-termcap.o"
 617     fi ;;
 618 esac
 619
 620 # These are the libraries checked by Readline.
 621 AC_SEARCH_LIBS(tgetent, [termcap tinfo curses ncurses])
 622
 623 if test "$ac_cv_search_tgetent" = no; then
 624   AC_MSG_ERROR([no termcap library found])
 625 fi
 626
 627 AC_ARG_WITH([system-readline],
 628   [AS_HELP_STRING([--with-system-readline],
 629                   [use installed readline library])])
 630
 631 if test "$with_system_readline" = yes; then
 632   READLINE=-lreadline
 633   READLINE_DEPS=
 634   READLINE_CFLAGS=
 635   READLINE_TEXI_INCFLAG=
 636 else
 637   READLINE='$(READLINE_DIR)/libreadline.a'
 638   READLINE_DEPS='$(READLINE)'
 639   READLINE_CFLAGS='-I$(READLINE_SRC)/..'
 640   READLINE_TEXI_INCFLAG='-I $(READLINE_DIR)'
 641 fi
 642 AC_SUBST(READLINE)
 643 AC_SUBST(READLINE_DEPS)
 644 AC_SUBST(READLINE_CFLAGS)
 645 AC_SUBST(READLINE_TEXI_INCFLAG)
 646
 647 # Generate jit-reader.h
 648
 649 # This is typedeffed to GDB_CORE_ADDR in jit-reader.h
 650 TARGET_PTR=
 651
 652 AC_CHECK_SIZEOF(unsigned long long)
 653 AC_CHECK_SIZEOF(unsigned long)
 654 AC_CHECK_SIZEOF(unsigned __int128)
 655
 656 if test "x${ac_cv_sizeof_unsigned_long}" = "x8"; then
 657   TARGET_PTR="unsigned long"
 658 elif test "x${ac_cv_sizeof_unsigned_long_long}" = "x8"; then
 659   TARGET_PTR="unsigned long long"
 660 elif test "x${ac_cv_sizeof_unsigned___int128}" = "x16"; then
 661   TARGET_PTR="unsigned __int128"
 662 else
 663   TARGET_PTR="unsigned long"
 664 fi
 665
 666 AC_SUBST(TARGET_PTR)
 667 AC_CONFIG_FILES([jit-reader.h:jit-reader.in])
 668
 669 AC_SEARCH_LIBS(dlopen, dl)
 670
 671 GDB_AC_WITH_DIR([JIT_READER_DIR], [jit-reader-dir],
 672                 [directory to load the JIT readers from],
 673                 [${libdir}/gdb])
 674
 675 AC_ARG_WITH(expat,
 676   AS_HELP_STRING([--with-expat], [include expat support (auto/yes/no)]),
 677   [], [with_expat=auto])
 678 AC_MSG_CHECKING([whether to use expat])
 679 AC_MSG_RESULT([$with_expat])
 680
 681 if test "${with_expat}" = no; then
 682   AC_MSG_WARN([expat support disabled; some features may be unavailable.])
 683   HAVE_LIBEXPAT=no
 684 else
 685   AC_LIB_HAVE_LINKFLAGS([expat], [], [#include "expat.h"],
 686                         [XML_Parser p = XML_ParserCreate (0);])
 687   if test "$HAVE_LIBEXPAT" != yes; then
 688     if test "$with_expat" = yes; then
 689       AC_MSG_ERROR([expat is missing or unusable])
 690     else
 691       AC_MSG_WARN([expat is missing or unusable; some features may be unavailable.])
 692     fi
 693   else
 694     save_LIBS=$LIBS
 695     LIBS="$LIBS $LIBEXPAT"
 696     AC_CHECK_FUNCS(XML_StopParser)
 697     LIBS=$save_LIBS
 698   fi
 699 fi
 700
 701 # --------------------- #
 702 # Check for libpython.  #
 703 # --------------------- #
 704
 705 dnl Utility to simplify finding libpython.
 706 dnl $1 = pythonX.Y
 707 dnl $2 = the shell variable to assign the result to
 708 dnl      If libpython is found we store $version here.
 709 dnl $3 = additional flags to add to CPPFLAGS
 710 dnl $4 = additional flags to add to LIBS
 711
 712 AC_DEFUN([AC_TRY_LIBPYTHON],
 713 [
 714   version=$1
 715   define([have_libpython_var],$2)
 716   new_CPPFLAGS=$3
 717   new_LIBS=$4
 718   AC_MSG_CHECKING([for ${version}])
 719   save_CPPFLAGS=$CPPFLAGS
 720   save_LIBS=$LIBS
 721   CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
 722   LIBS="$LIBS $new_LIBS"
 723   found_usable_python=no
 724   AC_LINK_IFELSE(AC_LANG_PROGRAM([[#include "Python.h"]],
 725                                  [[Py_Initialize ();]]),
 726                  [have_libpython_var=${version}
 727                   found_usable_python=yes
 728                   PYTHON_CPPFLAGS=$new_CPPFLAGS
 729                   PYTHON_LIBS=$new_LIBS])
 730   CPPFLAGS=$save_CPPFLAGS
 731   LIBS=$save_LIBS
 732   AC_MSG_RESULT([${found_usable_python}])
 733 ])
 734
 735 dnl There are several different values for --with-python:
 736 dnl
 737 dnl no -   Don't include python support.
 738 dnl yes -  Include python support, error if it's missing.
 739 dnl        If we find python in $PATH, use it to fetch configure options,
 740 dnl        otherwise assume the compiler can find it with no help from us.
 741 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 742 dnl auto - Same as "yes", but if python is missing from the system,
 743 dnl        fall back to "no".
 744 dnl /path/to/python/exec-prefix -
 745 dnl        Use the python located in this directory.
 746 dnl        If /path/to/python/exec-prefix/bin/python exists, use it to find
 747 dnl        the compilation parameters.  Otherwise use
 748 dnl        -I/path/to/python/exec-prefix/include,
 749 dnl        -L/path/to/python/exec-prefix/lib.
 750 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 751 dnl        NOTE: This case is historical.  It is what was done for 7.0/7.1
 752 dnl        but is deprecated.
 753 dnl /path/to/python/executable -
 754 dnl        Run python-config.py with this version of python to fetch the
 755 dnl        compilation parameters.
 756 dnl        NOTE: This needn't be the real python executable.
 757 dnl        In a cross-compilation scenario (build != host), this could be
 758 dnl        a shell script that provides what python-config.py provides for
 759 dnl        --ldflags, --includes, --exec-prefix.
 760 dnl python-executable -
 761 dnl        Find python-executable in $PATH, and then handle the same as
 762 dnl        /path/to/python/executable.
 763 dnl
 764 dnl If a python program is specified, it is used to run python-config.py and
 765 dnl is passed --ldflags, --includes, --exec-prefix.
 766
 767 AC_ARG_WITH(python,
 768   AS_HELP_STRING([--with-python@<:@=PYTHON@:>@], [include python support (auto/yes/no/<python-program>)]),
 769   [], [with_python=auto])
 770 AC_MSG_CHECKING([whether to use python])
 771 AC_MSG_RESULT([$with_python])
 772
 773 if test "${with_python}" = no; then
 774   AC_MSG_WARN([python support disabled; some features may be unavailable.])
 775   have_libpython=no
 776 else
 777   case "${with_python}" in
 778   [[\\/]]* | ?:[[\\/]]*)
 779     if test -d ${with_python}; then
 780       # Assume the python binary is ${with_python}/bin/python.
 781       python_prog="${with_python}/bin/python"
 782       python_prefix=
 783       # If python does not exit ${with_python}/bin, then try in
 784       # ${with_python}.  On Windows/MinGW, this is where the Python
 785       # executable is.
 786       if test ! -x "${python_prog}"; then
 787         python_prog="${with_python}/python"
 788         python_prefix=
 789       fi
 790       if test ! -x "${python_prog}"; then
 791         # Fall back to gdb 7.0/7.1 behaviour.
 792         python_prog=missing
 793         python_prefix=${with_python}
 794       fi
 795     elif test -x "${with_python}"; then
 796       # While we can't run python compiled for $host (unless host == build),
 797       # the user could write a script that provides the needed information,
 798       # so we support that.
 799       python_prog=${with_python}
 800       python_prefix=
 801     else
 802       AC_ERROR(invalid value for --with-python)
 803     fi
 804     ;;
 805   */*)
 806     # Disallow --with-python=foo/bar.
 807     AC_ERROR(invalid value for --with-python)
 808     ;;
 809   *)
 810     # The user has either specified auto, yes, or the name of the python
 811     # program assumed to be in $PATH.
 812     python_prefix=
 813     case "${with_python}" in
 814     yes | auto)
 815       if test ${build} = ${host}; then
 816         AC_PATH_PROG(python_prog_path, python, missing)
 817         if test "${python_prog_path}" = missing; then
 818           python_prog=missing
 819         else
 820           python_prog=${python_prog_path}
 821         fi
 822       else
 823         # Not much we can do except assume the cross-compiler will find the
 824         # right files.
 825         python_prog=missing
 826       fi
 827       ;;
 828     *)
 829       # While we can't run python compiled for $host (unless host == build),
 830       # the user could write a script that provides the needed information,
 831       # so we support that.
 832       python_prog="${with_python}"
 833       AC_PATH_PROG(python_prog_path, ${python_prog}, missing)
 834       if test "${python_prog_path}" = missing; then
 835         AC_ERROR(unable to find python program ${python_prog})
 836       fi
 837       ;;
 838     esac
 839   esac
 840
 841   if test "${python_prog}" != missing; then
 842     # We have a python program to use, but it may be too old.
 843     # Don't flag an error for --with-python=auto (the default).
 844     have_python_config=yes
 845     python_includes=`${python_prog} ${srcdir}/python/python-config.py --includes`
 846     if test $? != 0; then
 847       have_python_config=failed
 848       if test "${with_python}" != auto; then
 849         AC_ERROR(failure running python-config --includes)
 850       fi
 851     fi
 852     python_libs=`${python_prog} ${srcdir}/python/python-config.py --ldflags`
 853     if test $? != 0; then
 854       have_python_config=failed
 855       if test "${with_python}" != auto; then
 856         AC_ERROR(failure running python-config --ldflags)
 857       fi
 858     fi
 859     python_prefix=`${python_prog} ${srcdir}/python/python-config.py --exec-prefix`
 860     if test $? != 0; then
 861       have_python_config=failed
 862       if test "${with_python}" != auto; then
 863         AC_ERROR(failure running python-config --exec-prefix)
 864       fi
 865     fi
 866   else
 867     # We do not have a python executable we can use to determine where
 868     # to find the Python headers and libs.  We cannot guess the include
 869     # path from the python_prefix either, because that include path
 870     # depends on the Python version.  So, there is nothing much we can
 871     # do except assume that the compiler will be able to find those files.
 872     python_includes=
 873     python_libs=
 874     have_python_config=no
 875   fi
 876
 877   # If we have python-config, only try the configuration it provides.
 878   # Otherwise fallback on the old way of trying different versions of
 879   # python in turn.
 880
 881   have_libpython=no
 882   if test "${have_python_config}" = yes; then
 883     # Determine the Python version by extracting "-lpython<version>"
 884     # part of the python_libs. <version> is usually X.Y with X and Y
 885     # being decimal numbers, but can also be XY (seen on Windows).
 886     #
 887     # The extraction is performed using sed with a regular expression.
 888     # Initially, the regexp used was using the '?' quantifier to make
 889     # the dot in the version number optional.  Unfortunately, this
 890     # does not work with non-GNU versions of sed because, because of
 891     # what looks like a limitation (the '?' quantifier does not work
 892     # with back-references).  We work around this limitation by using
 893     # the '*' quantifier instead.  It means that, in theory, we might
 894     # match unexpected version strings such as "-lpython2..7", but
 895     # this seems unlikely in practice.  And even if that happens,
 896     # an error will be triggered later on, when checking that version
 897     # number.
 898     python_version=`echo " ${python_libs} " \
 899                          | sed -e 's,^.* -l\(python[[0-9]]*[[.]]*[[0-9]]*\).*$,\1,'`
 900     case "${python_version}" in
 901     python*)
 902       AC_TRY_LIBPYTHON(${python_version}, have_libpython,
 903                        ${python_includes}, ${python_libs})
 904       ;;
 905     *)
 906       AC_MSG_ERROR([unable to determine python version from ${python_libs}])
 907       ;;
 908     esac
 909   elif test "${have_python_config}" != failed; then
 910     if test "${have_libpython}" = no; then
 911       AC_TRY_LIBPYTHON(python2.7, have_libpython,
 912                        ${python_includes}, "${python_libs} -lpython2.7")
 913     fi
 914     if test "${have_libpython}" = no; then
 915       AC_TRY_LIBPYTHON(python2.6, have_libpython,
 916                        ${python_includes}, "${python_libs} -lpython2.6")
 917     fi
 918     if test ${have_libpython} = no; then
 919       AC_TRY_LIBPYTHON(python2.5, have_libpython,
 920                        ${python_includes}, "${python_libs} -lpython2.5")
 921     fi
 922     if test ${have_libpython} = no; then
 923       AC_TRY_LIBPYTHON(python2.4, have_libpython,
 924                        ${python_includes}, "${python_libs} -lpython2.4")
 925     fi
 926   fi
 927   if test "${have_libpython}" = python2.7 -o "${have_libpython}" = python27; then
 928     AC_DEFINE(HAVE_LIBPYTHON2_7, 1, [Define if Python 2.7 is being used.])
 929   elif test "${have_libpython}" = python2.6 -o "${have_libpython}" = python26; then
 930     AC_DEFINE(HAVE_LIBPYTHON2_6, 1, [Define if Python 2.6 is being used.])
 931   elif test "${have_libpython}" = python2.5 -o "${have_libpython}" = python25; then
 932     AC_DEFINE(HAVE_LIBPYTHON2_5, 1, [Define if Python 2.5 is being used.])
 933   elif test "${have_libpython}" = python2.4 -o "${have_libpython}" = python24; then
 934     AC_DEFINE(HAVE_LIBPYTHON2_4, 1, [Define if Python 2.4 is being used.])
 935   fi
 936
 937   if test "${have_libpython}" = no; then
 938     case "${with_python}" in
 939     yes)
 940       AC_MSG_ERROR([python is missing or unusable])
 941       ;;
 942     auto)
 943       AC_MSG_WARN([python is missing or unusable; some features may be unavailable.])
 944       ;;
 945     *)
 946       AC_MSG_ERROR([no usable python found at ${with_python}])
 947       ;;
 948     esac
 949   else
 950     if test -n "${python_prefix}"; then
 951       AC_DEFINE_UNQUOTED(WITH_PYTHON_PATH, "${python_prefix}",
 952                          [Define if --with-python provides a path, either directly or via python-config.py --exec-prefix.])
 953       GDB_AC_DEFINE_RELOCATABLE(PYTHON_PATH, python, ${python_prefix})
 954     fi
 955   fi
 956 fi
 957
 958 if test "${have_libpython}" != no; then
 959   AC_DEFINE(HAVE_PYTHON, 1, [Define if Python interpreter is being linked in.])
 960   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_PYTHON_OBS)"
 961   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_PYTHON_DEPS)"
 962   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_PYTHON_SRCS)"
 963   CONFIG_INSTALL="$CONFIG_INSTALL install-python"
 964   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_PYTHON_CFLAGS)"
 965
 966   # Flags needed to compile Python code (taken from python-config --cflags).
 967   # We cannot call python-config directly because it will output whatever was
 968   # used when compiling the Python interpreter itself, including flags which
 969   # would make the python-related objects be compiled differently from the
 970   # rest of GDB (e.g., -O2 and -fPIC).
 971   if test "${GCC}" = yes; then
 972     tentative_python_cflags="-fno-strict-aliasing -DNDEBUG -fwrapv"
 973   fi
 974
 975   if test "x${tentative_python_cflags}" != x; then
 976     AC_MSG_CHECKING(compiler flags for python code)
 977     for flag in ${tentative_python_cflags}; do
 978       # Check that the compiler accepts it
 979       saved_CFLAGS="$CFLAGS"
 980       CFLAGS="$CFLAGS $flag"
 981       AC_TRY_COMPILE([],[],PYTHON_CFLAGS="${PYTHON_CFLAGS} $flag",)
 982       CFLAGS="$saved_CFLAGS"
 983     done
 984     AC_MSG_RESULT(${PYTHON_CFLAGS})
 985   fi
 986
 987   # On x64 Windows, Python's include headers, and pyconfig.h in
 988   # particular, rely on MS_WIN64 macro to detect that it's a 64bit
 989   # version of Windows.  Unfortunately, MS_WIN64 is only defined if
 990   # _MSC_VER, a Microsoft-specific macro, is defined.  So, when
 991   # building on x64 Windows with GCC, we define MS_WIN64 ourselves.
 992   # The issue was reported to the Python community, but still isn't
 993   # solved as of 2012-10-02 (http://bugs.python.org/issue4709).
 994
 995   case "$gdb_host" in
 996     mingw64)
 997            if test "${GCC}" = yes; then
 998              CPPFLAGS="$CPPFLAGS -DMS_WIN64"
 999            fi
1000            ;;
1001   esac
1002
1003   # Note that "python -m threading" cannot be used to check for
1004   # threading support due to a bug in Python 2.7.3
1005   # (http://bugs.python.org/issue15567).
1006   AC_MSG_CHECKING(whether python supports threads)
1007   saved_CPPFLAGS="${CPPFLAGS}"
1008   CPPFLAGS="${PYTHON_CPPFLAGS}"
1009   # Note that the test is reversed so that python_has_threads=yes on
1010   # unexpected failures.
1011   AC_PREPROC_IFELSE(AC_LANG_SOURCE([[
1012 #include <Python.h>
1013 #ifdef WITH_THREAD
1014 # error
1015 #endif
1016   ]]), [python_has_threads=no], [python_has_threads=yes])
1017   AC_MSG_RESULT(${python_has_threads})
1018   CPPFLAGS="${saved_CPPFLAGS}"
1019 else
1020   # Even if Python support is not compiled in, we need to have this file
1021   # included so that the "python" command, et.al., still exists.
1022   CONFIG_OBS="$CONFIG_OBS python.o"
1023   CONFIG_SRCS="$CONFIG_SRCS python/python.c"
1024 fi
1025 AC_SUBST(PYTHON_CFLAGS)
1026 AC_SUBST(PYTHON_CPPFLAGS)
1027 AC_SUBST(PYTHON_LIBS)
1028 AM_CONDITIONAL(HAVE_PYTHON, test "${have_libpython}" != no)
1029
1030 # -------------------- #
1031 # Check for libguile.  #
1032 # -------------------- #
1033
1034 dnl Utility to simplify finding libguile.
1035 dnl $1 = pkg-config-program
1036 dnl $2 = space-separate list of guile versions to try
1037 dnl $3 = yes|no, indicating whether to flag errors or ignore them
1038 dnl $4 = the shell variable to assign the result to
1039 dnl      If libguile is found we store "yes" here.
1040
1041 AC_DEFUN([AC_TRY_LIBGUILE],
1042 [
1043   pkg_config=$1
1044   guile_version_list=$2
1045   flag_errors=$3
1046   define([have_libguile_var],$4)
1047   found_usable_guile=checking
1048   AC_MSG_CHECKING([for usable guile from ${pkg_config}])
1049   for guile_version in ${guile_version_list}; do
1050     ${pkg_config} --exists ${guile_version} 2>/dev/null
1051     if test $? != 0; then
1052       continue
1053     fi
1054     dnl pkg-config says the package exists, so if we get an error now,
1055     dnl that's bad.
1056     new_CPPFLAGS=`${pkg_config} --cflags ${guile_version}`
1057     if test $? != 0; then
1058       AC_MSG_ERROR([failure running pkg-config --cflags ${guile_version}])
1059     fi
1060     new_LIBS=`${pkg_config} --libs ${guile_version}`
1061     if test $? != 0; then
1062       AC_MSG_ERROR([failure running pkg-config --libs ${guile_version}])
1063     fi
1064     dnl If we get this far, great.
1065     found_usable_guile=${guile_version}
1066     break
1067   done
1068   if test "${found_usable_guile}" = "checking"; then
1069     if test "${flag_errors}" = "yes"; then
1070       AC_MSG_ERROR([unable to find usable guile version from "${guile_version_list}"])
1071     else
1072       found_usable_guile=no
1073     fi
1074   fi
1075   dnl One final sanity check.
1076   dnl The user could have said --with-guile=python-2.7.
1077   if test "${found_usable_guile}" != no; then
1078     save_CPPFLAGS=$CPPFLAGS
1079     save_LIBS=$LIBS
1080     CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
1081     LIBS="$LIBS $new_LIBS"
1082     AC_LINK_IFELSE(AC_LANG_PROGRAM([[#include "libguile.h"]],
1083                                    [[scm_init_guile ();]]),
1084                    [have_libguile_var=yes
1085                     GUILE_CPPFLAGS=$new_CPPFLAGS
1086                     GUILE_LIBS=$new_LIBS],
1087                    [found_usable_guile=no])
1088     CPPFLAGS=$save_CPPFLAGS
1089     LIBS=$save_LIBS
1090     if test "${found_usable_guile}" = no; then
1091       if test "${flag_errors}" = yes; then
1092         AC_MSG_FAILURE([linking guile version ${guile_version} test program failed])
1093       fi
1094     fi
1095   fi
1096   AC_MSG_RESULT([${found_usable_guile}])
1097 ])
1098
1099 dnl There are several different values for --with-guile:
1100 dnl
1101 dnl no -   Don't include guile support.
1102 dnl yes -  Include guile support, error if it's missing.
1103 dnl        The pkg-config program must be in $PATH.
1104 dnl auto - Same as "yes", but if guile is missing from the system,
1105 dnl        fall back to "no".
1106 dnl guile-version [guile-version-choice-2 ...] -
1107 dnl        A space-separated list of guile package versions to try.
1108 dnl        These are passed to pkg-config as-is.
1109 dnl        E.g., guile-2.0 or guile-2.2-uninstalled
1110 dnl        This requires making sure PKG_CONFIG_PATH is set appropriately.
1111 dnl /path/to/pkg-config -
1112 dnl        Use this pkg-config program.
1113 dnl        NOTE: This needn't be the "real" pkg-config program.
1114 dnl        It could be a shell script.  It is invoked as:
1115 dnl        pkg-config --exists $version
1116 dnl        pkg-config --cflags $version
1117 dnl        pkg-config --libs $version
1118 dnl        pkg-config --variable guild $version
1119 dnl        The script will be called with $version having each value in
1120 dnl        $try_guile_versions until --exists indicates success.
1121
1122 AC_ARG_WITH(guile,
1123   AS_HELP_STRING([--with-guile@<:@=GUILE@:>@], [include guile support (auto/yes/no/<guile-version>/<pkg-config-program>)]),
1124   [], [with_guile=auto])
1125 AC_MSG_CHECKING([whether to use guile])
1126 AC_MSG_RESULT([$with_guile])
1127
1128 dnl We check guile with pkg-config.
1129 AC_PATH_PROG(pkg_config_prog_path, pkg-config, missing)
1130
1131 try_guile_versions="guile-2.2 guile-2.0"
1132 have_libguile=no
1133 case "${with_guile}" in
1134 no)
1135   AC_MSG_WARN([guile support disabled; some features will be unavailable.])
1136   ;;
1137 auto)
1138   if test "${pkg_config_prog_path}" = "missing"; then
1139     AC_MSG_WARN([pkg-config not found, guile support disabled])
1140   else
1141     AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${try_guile_versions}, no, have_libguile)
1142   fi
1143   ;;
1144 yes)
1145   if test "${pkg_config_prog_path}" = "missing"; then
1146     AC_MSG_ERROR([pkg-config not found])
1147   fi
1148   AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${try_guile_versions}, yes, have_libguile)
1149   ;;
1150 [[\\/]]* | ?:[[\\/]]*)
1151   if test -x "${with_guile}"; then
1152     AC_TRY_LIBGUILE(${with_guile}, ${try_guile_versions}, yes, have_libguile)
1153   else
1154     AC_MSG_ERROR([Guile config program not executable: ${with_guile}])
1155   fi
1156   ;;
1157 "" | */*)
1158   # Disallow --with=guile="" and --with-guile=foo/bar.
1159   AC_MSG_ERROR([invalid value for --with-guile])
1160   ;;
1161 *)
1162   # A space separate list of guile versions to try, in order.
1163   if test "${pkg_config_prog_path}" = "missing"; then
1164     AC_MSG_ERROR([pkg-config not found])
1165   fi
1166   AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${with_guile}, yes, have_libguile)
1167   ;;
1168 esac
1169
1170 if test "${have_libguile}" != no; then
1171   dnl Get the name of the 'guild' program.
1172   case "${with_guile}" in
1173   [[\\/]]* | ?:[[\\/]]*)
1174     GDB_GUILE_PROGRAM_NAMES(["${with_guile}"], ["${guile_version}"])
1175     ;;
1176   *)
1177     GDB_GUILE_PROGRAM_NAMES(["${pkg_config_prog_path}"], ["${guile_version}"])
1178     ;;
1179   esac
1180
1181   dnl Make sure guild can handle this host.
1182   GDB_TRY_GUILD([$srcdir/guile/lib/gdb/support.scm])
1183   dnl If not, disable guile support.
1184   if test "$ac_cv_guild_ok" = no; then
1185     have_libguile=no
1186     AC_MSG_WARN(disabling guile support, $GUILD fails compiling for $host)
1187   fi
1188 fi
1189
1190 if test "${have_libguile}" != no; then
1191   AC_DEFINE(HAVE_GUILE, 1, [Define if Guile interpreter is being linked in.])
1192   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_GUILE_OBS)"
1193   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_GUILE_DEPS)"
1194   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_GUILE_SRCS)"
1195   CONFIG_INSTALL="$CONFIG_INSTALL install-guile"
1196   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_GUILE_CFLAGS)"
1197
1198   dnl The 'scm_new_smob' function appeared in Guile 2.0.6.
1199   save_LIBS="$LIBS"
1200   save_CPPFLAGS="$CPPFLAGS"
1201   LIBS="$GUILE_LIBS"
1202   CPPFLAGS="$GUILE_CPPFLAGS"
1203   AC_CHECK_FUNCS([scm_new_smob])
1204   LIBS="$save_LIBS"
1205   CPPFLAGS="$save_CPPFLAGS"
1206 else
1207   # Even if Guile support is not compiled in, we need to have these files
1208   # included.
1209   CONFIG_OBS="$CONFIG_OBS guile.o"
1210   CONFIG_SRCS="$CONFIG_SRCS guile/guile.c"
1211 fi
1212 AC_SUBST(GUILE_CPPFLAGS)
1213 AC_SUBST(GUILE_LIBS)
1214 AM_CONDITIONAL(HAVE_GUILE, test "${have_libguile}" != no)
1215
1216 # --------------------- #
1217 # Check for libmcheck.  #
1218 # --------------------- #
1219
1220 # Enable -lmcheck by default (it provides cheap-enough memory mangling),
1221 # but turn it off if Python is enabled with threads, since -lmcheck is
1222 # not thread safe (http://sourceware.org/bugzilla/show_bug.cgi?id=9939),
1223 # and for releases.
1224 if test \( "${have_libpython}" = "no" -o "${python_has_threads}" = "no" \) \
1225    && $development; then
1226   libmcheck_default=yes
1227 else
1228   libmcheck_default=no
1229 fi
1230 GDB_AC_LIBMCHECK(${libmcheck_default})
1231
1232 if test "$ENABLE_LIBMCHECK" = "yes" \
1233         -a "${have_libpython}" != "no" \
1234         -a "${python_has_threads}" = "yes" ; then
1235   AC_MSG_WARN(--enable-libmcheck may lead to spurious crashes if threads are used in python)
1236 fi
1237
1238 # ------------------------- #
1239 # Checks for header files.  #
1240 # ------------------------- #
1241
1242 AC_HEADER_STDC
1243 # elf_hp.h is for HP/UX 64-bit shared library support.
1244 AC_CHECK_HEADERS([nlist.h machine/reg.h poll.h sys/poll.h proc_service.h \
1245                   thread_db.h \
1246                   sys/fault.h \
1247                   sys/file.h sys/filio.h sys/ioctl.h sys/param.h \
1248                   sys/resource.h sys/procfs.h sys/ptrace.h ptrace.h \
1249                   sys/reg.h sys/debugreg.h sys/select.h sys/syscall.h \
1250                   termios.h termio.h \
1251                   sgtty.h elf_hp.h \
1252                   dlfcn.h])
1253 AC_CHECK_HEADERS(sys/proc.h, [], [],
1254 [#if HAVE_SYS_PARAM_H
1255 # include <sys/param.h>
1256 #endif
1257 ])
1258 AC_CHECK_HEADERS(sys/user.h, [], [],
1259 [#if HAVE_SYS_PARAM_H
1260 # include <sys/param.h>
1261 #endif
1262 ])
1263
1264 # On Solaris 2.[789], we need to define _MSE_INT_H to avoid a clash
1265 # between <widec.h> and <wchar.h> that would cause AC_CHECK_HEADERS to
1266 # think that we don't have <curses.h> if we're using GCC.
1267 case $host_os in
1268   solaris2.[[789]])
1269     if test "$GCC" = yes; then
1270       AC_DEFINE(_MSE_INT_H, 1,
1271         [Define to 1 to avoid a clash between <widec.h> and <wchar.h> on
1272    Solaris 2.[789] when using GCC. ])
1273     fi ;;
1274 esac
1275 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncurses/ncurses.h ncurses/term.h)
1276 AC_CHECK_HEADERS(term.h, [], [],
1277 [#if HAVE_CURSES_H
1278 # include <curses.h>
1279 #endif
1280 ])
1281
1282 # ------------------------- #
1283 # Checks for declarations.  #
1284 # ------------------------- #
1285
1286 AC_CHECK_DECLS([free, malloc, realloc, snprintf])
1287 AM_LC_MESSAGES
1288
1289 # ----------------------- #
1290 # Checks for structures.  #
1291 # ----------------------- #
1292
1293 AC_CHECK_MEMBERS([struct stat.st_blocks, struct stat.st_blksize])
1294
1295 # ------------------ #
1296 # Checks for types.  #
1297 # ------------------ #
1298
1299 AC_TYPE_SIGNAL
1300 AC_CHECK_TYPES(socklen_t, [], [],
1301 [#include <sys/types.h>
1302 #include <sys/socket.h>
1303 ])
1304
1305 # ------------------------------------- #
1306 # Checks for compiler characteristics.  #
1307 # ------------------------------------- #
1308
1309 AC_C_CONST
1310 AC_C_INLINE
1311 AC_C_BIGENDIAN
1312
1313 # ------------------------------ #
1314 # Checks for library functions.  #
1315 # ------------------------------ #
1316
1317 AC_FUNC_MMAP
1318 AC_FUNC_VFORK
1319 AC_CHECK_FUNCS([getauxval getrusage getuid getgid \
1320                 pipe poll pread pread64 pwrite resize_term \
1321                 sbrk setpgid setpgrp setsid \
1322                 sigaction sigprocmask sigsetmask socketpair \
1323                 ttrace wborder wresize setlocale iconvlist libiconvlist btowc \
1324                 setrlimit getrlimit posix_madvise waitpid \
1325                 ptrace64 sigaltstack mkdtemp])
1326 AM_LANGINFO_CODESET
1327 GDB_AC_COMMON
1328
1329 # Check the return and argument types of ptrace.  No canned test for
1330 # this, so roll our own.
1331 gdb_ptrace_headers='
1332 #include <sys/types.h>
1333 #if HAVE_SYS_PTRACE_H
1334 # include <sys/ptrace.h>
1335 #endif
1336 #if HAVE_UNISTD_H
1337 # include <unistd.h>
1338 #endif
1339 '
1340 # There is no point in checking if we don't have a prototype.
1341 AC_CHECK_DECLS(ptrace, [], [
1342   : ${gdb_cv_func_ptrace_ret='int'}
1343   : ${gdb_cv_func_ptrace_args='int,int,long,long'}
1344 ], $gdb_ptrace_headers)
1345 # Check return type.  Varargs (used on GNU/Linux) conflict with the
1346 # empty argument list, so check for that explicitly.
1347 AC_CACHE_CHECK([return type of ptrace], gdb_cv_func_ptrace_ret,
1348   AC_TRY_COMPILE($gdb_ptrace_headers,
1349     [extern long ptrace (enum __ptrace_request, ...);],
1350     gdb_cv_func_ptrace_ret='long',
1351     AC_TRY_COMPILE($gdb_ptrace_headers,
1352       [extern int ptrace ();],
1353       gdb_cv_func_ptrace_ret='int',
1354       gdb_cv_func_ptrace_ret='long')))
1355 AC_DEFINE_UNQUOTED(PTRACE_TYPE_RET, $gdb_cv_func_ptrace_ret,
1356   [Define as the return type of ptrace.])
1357 # Check argument types.
1358 AC_CACHE_CHECK([types of arguments for ptrace], gdb_cv_func_ptrace_args, [
1359   AC_TRY_COMPILE($gdb_ptrace_headers,
1360     [extern long ptrace (enum __ptrace_request, ...);],
1361     [gdb_cv_func_ptrace_args='int,int,long,long'],[
1362 for gdb_arg1 in 'int' 'long'; do
1363  for gdb_arg2 in 'pid_t' 'int' 'long'; do
1364   for gdb_arg3 in 'int *' 'caddr_t' 'int' 'long' 'void *'; do
1365    for gdb_arg4 in 'int' 'long' 'void *'; do
1366      AC_TRY_COMPILE($gdb_ptrace_headers, [
1367 extern $gdb_cv_func_ptrace_ret
1368   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4);
1369 ], [gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4";
1370     break 4;])
1371     for gdb_arg5 in 'int *' 'int' 'long'; do
1372      AC_TRY_COMPILE($gdb_ptrace_headers, [
1373 extern $gdb_cv_func_ptrace_ret
1374   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4, $gdb_arg5);
1375 ], [
1376 gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4,$gdb_arg5";
1377     break 5;])
1378     done
1379    done
1380   done
1381  done
1382 done
1383 # Provide a safe default value.
1384 : ${gdb_cv_func_ptrace_args='int,int,long,long'}
1385 ])])
1386 ac_save_IFS=$IFS; IFS=','
1387 set dummy `echo "$gdb_cv_func_ptrace_args" | sed 's/\*/\*/g'`
1388 IFS=$ac_save_IFS
1389 shift
1390 AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG3, $[3],
1391   [Define to the type of arg 3 for ptrace.])
1392 AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG4, $[4],
1393   [Define to the type of arg 4 for ptrace.])
1394 if test -n "$[5]"; then
1395   AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG5, $[5],
1396     [Define to the type of arg 5 for ptrace.])
1397 fi
1398
1399 dnl AC_FUNC_SETPGRP does not work when cross compiling
1400 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
1401 if test "$cross_compiling" = no; then
1402   AC_FUNC_SETPGRP
1403 else
1404   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
1405     [AC_TRY_COMPILE([
1406 #include <unistd.h>
1407 ], [
1408   if (setpgrp(1,1) == -1)
1409     exit (0);
1410   else
1411     exit (1);
1412 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
1413 if test $ac_cv_func_setpgrp_void = yes; then
1414   AC_DEFINE(SETPGRP_VOID, 1)
1415 fi
1416 fi
1417
1418 # Assume we'll default to using the included libiberty regex.
1419 gdb_use_included_regex=yes
1420
1421 # However, if the system regex is GNU regex, then default to *not*
1422 # using the included regex.
1423 AC_CACHE_CHECK(
1424   [for GNU regex],
1425   [gdb_cv_have_gnu_regex],
1426   [AC_TRY_COMPILE(
1427     [#include <gnu-versions.h>],
1428     [#define REGEX_INTERFACE_VERSION 1
1429 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
1430 # error "Version mismatch"
1431 #endif],
1432     gdb_cv_have_gnu_regex=yes,
1433     gdb_cv_have_gnu_regex=no)])
1434 if test $gdb_cv_have_gnu_regex = yes; then
1435   gdb_use_included_regex=no
1436 fi
1437
1438 AC_ARG_WITH(included-regex,
1439   AS_HELP_STRING([--without-included-regex], [don't use included regex; this is the default on systems with version 2 of the GNU C library (use with caution on other system)]),
1440   gdb_with_regex=$withval,
1441   gdb_with_regex=$gdb_use_included_regex)
1442 if test "$gdb_with_regex" = yes; then
1443   AC_DEFINE(USE_INCLUDED_REGEX, 1,
1444     [Define to 1 if the regex included in libiberty should be used.])
1445 fi
1446
1447 # Check if <sys/proc.h> defines `struct thread' with a td_pcb member.
1448 AC_CHECK_MEMBERS([struct thread.td_pcb], [], [],
1449 [#include <sys/param.h>
1450 #include <sys/proc.h>
1451 ])
1452
1453 # See if <sys/lwp.h> defines `struct lwp`.
1454 AC_CACHE_CHECK([for struct lwp], gdb_cv_struct_lwp,
1455 [AC_TRY_COMPILE([#include <sys/param.h>
1456 #include <sys/lwp.h>], [struct lwp l;],
1457 gdb_cv_struct_lwp=yes, gdb_cv_struct_lwp=no)])
1458 if test $gdb_cv_struct_lwp = yes; then
1459   AC_DEFINE(HAVE_STRUCT_LWP, 1,
1460             [Define to 1 if your system has struct lwp.])
1461 fi
1462
1463 # See if <machine/reg.h> degines `struct reg'.
1464 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
1465 [AC_TRY_COMPILE([#include <sys/types.h>
1466 #include <machine/reg.h>], [struct reg r;],
1467 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
1468 if test $gdb_cv_struct_reg = yes; then
1469   AC_DEFINE(HAVE_STRUCT_REG, 1,
1470             [Define to 1 if your system has struct reg in <machine/reg.h>.])
1471 fi
1472
1473 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
1474 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
1475 AC_CHECK_MEMBERS([struct reg.r_fs, struct reg.r_gs], [], [],
1476                  [#include <machine/reg.h>])
1477
1478 # See if <sys/user.h> supports the %fs_base and %gs_bas amd64 segment registers.
1479 # Older amd64 Linux's don't have the fs_base and gs_base members of
1480 # `struct user_regs_struct'.
1481 AC_CHECK_MEMBERS([struct user_regs_struct.fs_base, struct user_regs_struct.gs_base],
1482                  [], [], [#include <sys/user.h>])
1483
1484 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
1485 AC_MSG_CHECKING(for PTRACE_GETREGS)
1486 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
1487 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1488                 [PTRACE_GETREGS;],
1489                 [gdb_cv_have_ptrace_getregs=yes],
1490                 [gdb_cv_have_ptrace_getregs=no])])
1491 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
1492 if test $gdb_cv_have_ptrace_getregs = yes; then
1493   AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
1494   [Define if sys/ptrace.h defines the PTRACE_GETREGS request.])
1495 fi
1496
1497 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
1498 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
1499 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
1500 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1501                 [PTRACE_GETFPXREGS;],
1502                 [gdb_cv_have_ptrace_getfpxregs=yes],
1503                 [gdb_cv_have_ptrace_getfpxregs=no])])
1504 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
1505 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
1506   AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
1507   [Define if sys/ptrace.h defines the PTRACE_GETFPXREGS request.])
1508 fi
1509
1510 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
1511 AC_MSG_CHECKING(for PT_GETDBREGS)
1512 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
1513 [AC_TRY_COMPILE([#include <sys/types.h>
1514 #include <sys/ptrace.h>],
1515                 [PT_GETDBREGS;],
1516                 [gdb_cv_have_pt_getdbregs=yes],
1517                 [gdb_cv_have_pt_getdbregs=no])])
1518 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
1519 if test $gdb_cv_have_pt_getdbregs = yes; then
1520   AC_DEFINE(HAVE_PT_GETDBREGS, 1,
1521   [Define if sys/ptrace.h defines the PT_GETDBREGS request.])
1522 fi
1523
1524 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
1525 AC_MSG_CHECKING(for PT_GETXMMREGS)
1526 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
1527 [AC_TRY_COMPILE([#include <sys/types.h>
1528 #include <sys/ptrace.h>],
1529                 [PT_GETXMMREGS;],
1530                 [gdb_cv_have_pt_getxmmregs=yes],
1531                 [gdb_cv_have_pt_getxmmregs=no])])
1532 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
1533 if test $gdb_cv_have_pt_getxmmregs = yes; then
1534   AC_DEFINE(HAVE_PT_GETXMMREGS, 1,
1535   [Define if sys/ptrace.h defines the PT_GETXMMREGS request.])
1536 fi
1537
1538 # Detect which type of /proc is in use, such as for Solaris.
1539
1540 if test "${target}" = "${host}"; then
1541   case "${host}" in
1542   *-*-sysv4.2* | *-*-sysv5* )
1543       AC_DEFINE(NEW_PROC_API, 1,
1544       [Define if you want to use new multi-fd /proc interface.])
1545       ;;
1546   *-*-solaris2.[[6789]] | *-*-solaris2.1[[0-9]]*)
1547       AC_DEFINE(NEW_PROC_API, 1,
1548       [Define if you want to use new multi-fd /proc interface.])
1549       ;;
1550   mips-sgi-irix5*)
1551       # Work around <sys/proc.h> needing _KMEMUSER problem on IRIX 5.
1552       AC_DEFINE([_KMEMUSER], 1,
1553       [Define to 1 so <sys/proc.h> gets a definition of anon_hdl.  Works
1554        around a <sys/proc.h> problem on IRIX 5.])
1555       ;;
1556   esac
1557 fi
1558
1559 if test "$ac_cv_header_sys_procfs_h" = yes; then
1560   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
1561   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
1562   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
1563   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
1564   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
1565   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
1566   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
1567   BFD_HAVE_SYS_PROCFS_TYPE(prsysent_t)
1568   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigset_t)
1569   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigaction64_t)
1570   BFD_HAVE_SYS_PROCFS_TYPE(pr_siginfo64_t)
1571
1572
1573   dnl Check for broken prfpregset_t type
1574
1575   dnl For Linux/i386, glibc 2.1.3 was released with a bogus
1576   dnl prfpregset_t type (it's a typedef for the pointer to a struct
1577   dnl instead of the struct itself).  We detect this here, and work
1578   dnl around it in gdb_proc_service.h.
1579
1580   if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
1581     AC_MSG_CHECKING(whether prfpregset_t type is broken)
1582     AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
1583       [AC_TRY_RUN([#include <sys/procfs.h>
1584        int main ()
1585        {
1586          if (sizeof (prfpregset_t) == sizeof (void *))
1587            return 1;
1588          return 0;
1589        }],
1590        gdb_cv_prfpregset_t_broken=no,
1591        gdb_cv_prfpregset_t_broken=yes,
1592        gdb_cv_prfpregset_t_broken=yes)])
1593     AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
1594     if test $gdb_cv_prfpregset_t_broken = yes; then
1595       AC_DEFINE(PRFPREGSET_T_BROKEN, 1,
1596       [Define if the prfpregset_t type is broken.])
1597     fi
1598   fi
1599 fi
1600
1601 # Check if the compiler supports the `long long' type.
1602
1603 AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long,
1604                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1605 [[extern long long foo;]],
1606 [[switch (foo & 2) { case 0: return 1; }]])],
1607                                   gdb_cv_c_long_long=yes,
1608                                   gdb_cv_c_long_long=no)])
1609 if test $gdb_cv_c_long_long != yes; then
1610   # libdecnumber requires long long.
1611   AC_MSG_ERROR([Compiler must support long long for GDB.])
1612 fi
1613
1614 # Check if the compiler and runtime support printing long longs.
1615
1616 AC_CACHE_CHECK([for long long support in printf],
1617                gdb_cv_printf_has_long_long,
1618                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1619 [[char buf[32];
1620   long long l = 0;
1621   l = (l << 16) + 0x0123;
1622   l = (l << 16) + 0x4567;
1623   l = (l << 16) + 0x89ab;
1624   l = (l << 16) + 0xcdef;
1625   sprintf (buf, "0x%016llx", l);
1626   return (strcmp ("0x0123456789abcdef", buf));]])],
1627                               gdb_cv_printf_has_long_long=yes,
1628                               gdb_cv_printf_has_long_long=no,
1629                               gdb_cv_printf_has_long_long=no)])
1630 if test $gdb_cv_printf_has_long_long = yes; then
1631   AC_DEFINE(PRINTF_HAS_LONG_LONG, 1,
1632             [Define to 1 if the "%ll" format works to print long longs.])
1633 fi
1634
1635 # Check if the compiler and runtime support printing decfloats.
1636
1637 AC_CACHE_CHECK([for decfloat support in printf],
1638                gdb_cv_printf_has_decfloat,
1639                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1640 [[char buf[64];
1641   _Decimal32 d32 = 1.2345df;
1642   _Decimal64 d64 = 1.2345dd;
1643   _Decimal128 d128 = 1.2345dl;
1644   sprintf (buf, "Decimal32: %H\nDecimal64: %D\nDecimal128: %DD", d32, d64, d128);
1645   return (strcmp ("Decimal32: 1.2345\nDecimal64: 1.2345\nDecimal128: 1.2345", buf));]])],
1646                               gdb_cv_printf_has_decfloat=yes,
1647                               gdb_cv_printf_has_decfloat=no,
1648                               gdb_cv_printf_has_decfloat=no)])
1649 if test $gdb_cv_printf_has_decfloat = yes; then
1650   AC_DEFINE(PRINTF_HAS_DECFLOAT, 1,
1651             [Define to 1 if the "%H, %D and %DD" formats work to print decfloats.])
1652 fi
1653
1654 # Check if the compiler supports the `long double' type.  We can't use
1655 # AC_C_LONG_DOUBLE because that one does additional checks on the
1656 # constants defined in <float.h> that fail on some systems,
1657 # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6.
1658
1659 AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double,
1660                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])],
1661                                   gdb_cv_c_long_double=yes,
1662                                   gdb_cv_c_long_double=no)])
1663 if test $gdb_cv_c_long_double = yes; then
1664   AC_DEFINE(HAVE_LONG_DOUBLE, 1,
1665            [Define to 1 if the compiler supports long double.])
1666 fi
1667
1668 # Check if the compiler and runtime support printing long doubles.
1669
1670 AC_CACHE_CHECK([for long double support in printf],
1671                gdb_cv_printf_has_long_double,
1672                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1673 [[char buf[16];
1674   long double f = 3.141592653;
1675   sprintf (buf, "%Lg", f);
1676   return (strncmp ("3.14159", buf, 7));]])],
1677                               gdb_cv_printf_has_long_double=yes,
1678                               gdb_cv_printf_has_long_double=no,
1679                               gdb_cv_printf_has_long_double=no)])
1680 if test $gdb_cv_printf_has_long_double = yes; then
1681   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1,
1682             [Define to 1 if the "%Lg" format works to print long doubles.])
1683 fi
1684
1685 # Check if the compiler and runtime support scanning long doubles.
1686
1687 AC_CACHE_CHECK([for long double support in scanf],
1688                gdb_cv_scanf_has_long_double,
1689                [AC_RUN_IFELSE([AC_LANG_PROGRAM(
1690 [[#include <stdio.h>]],
1691 [[char *buf = "3.141592653";
1692   long double f = 0;
1693   sscanf (buf, "%Lg", &f);
1694   return !(f > 3.14159 && f < 3.14160);]])],
1695                               gdb_cv_scanf_has_long_double=yes,
1696                               gdb_cv_scanf_has_long_double=no,
1697                               gdb_cv_scanf_has_long_double=no)])
1698 if test $gdb_cv_scanf_has_long_double = yes; then
1699   AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1,
1700             [Define to 1 if the "%Lg" format works to scan long doubles.])
1701 fi
1702
1703 case ${host_os} in
1704 aix*)
1705   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1706     SAVE_LDFLAGS=$LDFLAGS
1707
1708     case $GCC in
1709     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1710     *) gdb_cv_bigtoc=-bbigtoc ;;
1711     esac
1712
1713     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1714     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1715     LDFLAGS="${SAVE_LDFLAGS}"
1716   ])
1717   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
1718   ;;
1719 esac
1720
1721 AC_MSG_CHECKING(for the dynamic export flag)
1722 dynamic_list=false
1723 if test "${gdb_native}" = yes; then
1724    # The dynamically loaded libthread_db needs access to symbols in the gdb
1725    # executable.  Older GNU ld supports --export-dynamic but --dynamic-list
1726    # may not be supported there.
1727    old_LDFLAGS="$LDFLAGS"
1728    # Older GNU ld supports --export-dynamic but --dynamic-list it does not.
1729    RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
1730    LDFLAGS="$LDFLAGS $RDYNAMIC"
1731    if test "${have_libpython}" = no; then
1732      AC_TRY_LINK([], [], [dynamic_list=true])
1733    else
1734      # Workaround http://bugs.python.org/issue4434 where static
1735      # libpythonX.Y.a would get its symbols required for
1736      # pythonX.Y/lib-dynload/*.so modules hidden by -Wl,--dynamic-list.
1737      # Problem does not happen for the recommended libpythonX.Y.so linkage.
1738      old_CFLAGS="$CFLAGS"
1739      CFLAGS="$CFLAGS $PYTHON_CFLAGS"
1740      old_LIBS="$LIBS"
1741      LIBS="$LIBS $PYTHON_LIBS"
1742      AC_RUN_IFELSE(
1743        AC_LANG_PROGRAM(
1744          [#include "]${have_libpython}[/Python.h"],
1745          [int err;
1746           Py_Initialize ();
1747           err = PyRun_SimpleString ("import itertools\n");
1748           Py_Finalize ();
1749           return err == 0 ? 0 : 1;]),
1750        [dynamic_list=true], [], [true])
1751      LIBS="$old_LIBS"
1752      CFLAGS="$old_CFLAGS"
1753    fi
1754    LDFLAGS="$old_LDFLAGS"
1755 fi
1756 if $dynamic_list; then
1757   found="-Wl,--dynamic-list"
1758   RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'
1759 else
1760   found="-rdynamic"
1761   RDYNAMIC="-rdynamic"
1762 fi
1763 AC_SUBST(RDYNAMIC)
1764 AC_MSG_RESULT($found)
1765
1766 dnl For certain native configurations, we need to check whether thread
1767 dnl support can be built in or not.
1768 dnl
1769 dnl Note that we only want this if we are both native (host == target),
1770 dnl and not doing a canadian cross build (build == host).
1771
1772 if test ${build} = ${host} -a ${host} = ${target} ; then
1773    case ${host_os} in
1774    solaris*)
1775       # See if thread_db library is around for Solaris thread debugging.
1776       # Note that we must explicitly test for version 1 of the library
1777       # because version 0 (present on Solaris 2.4 or earlier) doesn't have
1778       # the same API.
1779       AC_MSG_CHECKING(for Solaris thread debugging library)
1780       if test -f /usr/lib/libthread_db.so.1 ; then
1781          AC_MSG_RESULT(yes)
1782          AC_DEFINE(HAVE_THREAD_DB_LIB, 1,
1783          [Define if using Solaris thread debugging.])
1784          CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
1785          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
1786          AC_CHECK_LIB(dl, dlopen)
1787          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} $RDYNAMIC"
1788          # Sun randomly tweaked the prototypes in <proc_service.h>
1789          # at one point.
1790          AC_MSG_CHECKING(if <proc_service.h> is old)
1791          AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
1792             AC_TRY_COMPILE([
1793                 #include <proc_service.h>
1794                 ps_err_e ps_pdwrite
1795                     (struct ps_prochandle*, psaddr_t, const void*, size_t);
1796             ],, gdb_cv_proc_service_is_old=no,
1797                 gdb_cv_proc_service_is_old=yes)
1798          ])
1799          AC_MSG_RESULT($gdb_cv_proc_service_is_old)
1800          if test $gdb_cv_proc_service_is_old = yes; then
1801             AC_DEFINE(PROC_SERVICE_IS_OLD, 1,
1802             [Define if <proc_service.h> on solaris uses int instead of
1803              size_t, and assorted other type changes.])
1804          fi
1805       else
1806          AC_MSG_RESULT(no)
1807       fi
1808       ;;
1809    aix*)
1810       AC_MSG_CHECKING(for AiX thread debugging library)
1811       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
1812                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
1813                                    [#ifndef PTHDB_VERSION_3
1814                                     #error
1815                                     #endif],
1816                                    gdb_cv_have_aix_thread_debug=yes,
1817                                    gdb_cv_have_aix_thread_debug=no)])
1818       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1819       if test $gdb_cv_have_aix_thread_debug = yes; then
1820          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1821          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1822          LIBS="$LIBS -lpthdebug"
1823
1824          # Older versions of AIX do not provide the declaration for
1825          # the getthrds function (it appears that it was introduced
1826          # with AIX 6.x).
1827          AC_CHECK_DECLS(getthrds, [], [], [[#include <procinfo.h>]])
1828       fi
1829       ;;
1830    esac
1831    AC_SUBST(CONFIG_LDFLAGS)
1832 fi
1833
1834 dnl See if we have a thread_db header file that has TD_NOTALLOC and
1835 dnl other error codes.
1836 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1837    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
1838                   gdb_cv_thread_db_h_has_td_notalloc,
1839      AC_TRY_COMPILE(
1840        [#include <thread_db.h>],
1841        [int i = TD_NOTALLOC;],
1842        gdb_cv_thread_db_h_has_td_notalloc=yes,
1843        gdb_cv_thread_db_h_has_td_notalloc=no
1844      )
1845    )
1846    AC_CACHE_CHECK([whether <thread_db.h> has TD_VERSION],
1847                   gdb_cv_thread_db_h_has_td_version,
1848      AC_TRY_COMPILE(
1849        [#include <thread_db.h>],
1850        [int i = TD_VERSION;],
1851        gdb_cv_thread_db_h_has_td_version=yes,
1852        gdb_cv_thread_db_h_has_td_version=no
1853      )
1854    )
1855    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTLS],
1856                   gdb_cv_thread_db_h_has_td_notls,
1857      AC_TRY_COMPILE(
1858        [#include <thread_db.h>],
1859        [int i = TD_NOTLS;],
1860        gdb_cv_thread_db_h_has_td_notls=yes,
1861        gdb_cv_thread_db_h_has_td_notls=no
1862      )
1863    )
1864 fi
1865 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1866   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1867             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1868 fi
1869 if test "x$gdb_cv_thread_db_h_has_td_version" = "xyes"; then
1870   AC_DEFINE(THREAD_DB_HAS_TD_VERSION, 1,
1871             [Define if <thread_db.h> has the TD_VERSION error code.])
1872 fi
1873 if test "x$gdb_cv_thread_db_h_has_td_notls" = "xyes"; then
1874   AC_DEFINE(THREAD_DB_HAS_TD_NOTLS, 1,
1875             [Define if <thread_db.h> has the TD_NOTLS error code.])
1876 fi
1877
1878 dnl See if we have a sys/syscall header file that has __NR_tkill.
1879 if test "x$ac_cv_header_sys_syscall_h" = "xyes"; then
1880    AC_CACHE_CHECK([whether <sys/syscall.h> has __NR_tkill],
1881                   gdb_cv_sys_syscall_h_has_tkill,
1882      AC_TRY_COMPILE(
1883        [#include <sys/syscall.h>],
1884        [int i = __NR_tkill;],
1885        gdb_cv_sys_syscall_h_has_tkill=yes,
1886        gdb_cv_sys_syscall_h_has_tkill=no
1887      )
1888    )
1889 fi
1890 dnl See if we can issue tkill syscall.
1891 if test "x$gdb_cv_sys_syscall_h_has_tkill" = "xyes"; then
1892   AC_CHECK_FUNC(syscall,
1893     AC_DEFINE(HAVE_TKILL_SYSCALL, 1, [Define if you support the tkill syscall.])
1894   )
1895 fi
1896
1897 dnl Check if we can disable the virtual address space randomization.
1898 dnl The functionality of setarch -R.
1899 AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>])
1900 define([PERSONALITY_TEST], [AC_LANG_PROGRAM([#include <sys/personality.h>], [
1901 #      if !HAVE_DECL_ADDR_NO_RANDOMIZE
1902 #       define ADDR_NO_RANDOMIZE 0x0040000
1903 #      endif
1904        /* Test the flag could be set and stays set.  */
1905        personality (personality (0xffffffff) | ADDR_NO_RANDOMIZE);
1906        if (!(personality (personality (0xffffffff)) & ADDR_NO_RANDOMIZE))
1907            return 1])])
1908 AC_RUN_IFELSE([PERSONALITY_TEST],
1909               [have_personality=true],
1910               [have_personality=false],
1911               [AC_LINK_IFELSE([PERSONALITY_TEST],
1912                               [have_personality=true],
1913                               [have_personality=false])])
1914 if $have_personality
1915 then
1916     AC_DEFINE([HAVE_PERSONALITY], 1,
1917               [Define if you support the personality syscall.])
1918 fi
1919
1920 dnl Set the host's .gdbinit filename.
1921 case $host_os in
1922   go32* | *djgpp*)
1923     gdbinit=gdb.ini
1924     ;;
1925   *)
1926     gdbinit=.gdbinit
1927     ;;
1928 esac
1929 AC_DEFINE_UNQUOTED(GDBINIT,"$gdbinit",[The .gdbinit filename.])
1930
1931 dnl Handle optional features that can be enabled.
1932
1933 # Support for --with-sysroot is a copy of GDB_AC_WITH_DIR,
1934 # except that the argument to --with-sysroot is optional.
1935 # --with-sysroot (or --with-sysroot=yes) sets the default sysroot path.
1936 if test "x$with_sysroot" = xyes; then
1937   with_sysroot="${exec_prefix}/${target_alias}/sys-root"
1938 fi
1939 AC_ARG_WITH(sysroot,
1940   AS_HELP_STRING([--with-sysroot@<:@=DIR@:>@],
1941                  [search for usr/lib et al within DIR]),
1942   [TARGET_SYSTEM_ROOT=$withval], [TARGET_SYSTEM_ROOT=])
1943 AC_DEFINE_DIR(TARGET_SYSTEM_ROOT, TARGET_SYSTEM_ROOT,
1944               [search for usr/lib et al within DIR])
1945 AC_SUBST(TARGET_SYSTEM_ROOT)
1946 GDB_AC_DEFINE_RELOCATABLE(TARGET_SYSTEM_ROOT, sysroot, ${ac_define_dir})
1947
1948 GDB_AC_WITH_DIR(SYSTEM_GDBINIT, system-gdbinit,
1949     [automatically load a system-wide gdbinit file],
1950     [])
1951
1952 AC_ARG_ENABLE(werror,
1953   AS_HELP_STRING([--enable-werror], [treat compile warnings as errors]),
1954   [case "${enableval}" in
1955      yes | y) ERROR_ON_WARNING="yes" ;;
1956      no | n)  ERROR_ON_WARNING="no" ;;
1957      *) AC_MSG_ERROR(bad value ${enableval} for --enable-werror) ;;
1958    esac])
1959
1960 # Enable -Werror by default when using gcc.  Turn it off for releases.
1961 if test "${GCC}" = yes -a -z "${ERROR_ON_WARNING}" && $development; then
1962     ERROR_ON_WARNING=yes
1963 fi
1964
1965 WERROR_CFLAGS=""
1966 if test "${ERROR_ON_WARNING}" = yes ; then
1967     WERROR_CFLAGS="-Werror"
1968 fi
1969
1970 build_warnings="-Wall -Wdeclaration-after-statement -Wpointer-arith \
1971 -Wpointer-sign \
1972 -Wno-unused -Wunused-value -Wunused-function \
1973 -Wno-switch -Wno-char-subscripts -Wmissing-prototypes \
1974 -Wdeclaration-after-statement -Wempty-body -Wmissing-parameter-type \
1975 -Wold-style-declaration -Wold-style-definition"
1976
1977 # Enable -Wno-format by default when using gcc on mingw since many
1978 # GCC versions complain about %I64.
1979 case "${host}" in
1980   *-*-mingw32*) build_warnings="$build_warnings -Wno-format" ;;
1981   *) build_warnings="$build_warnings -Wformat-nonliteral" ;;
1982 esac
1983
1984 AC_ARG_ENABLE(build-warnings,
1985 AS_HELP_STRING([--enable-build-warnings], [enable build-time compiler warnings if gcc is used]),
1986 [case "${enableval}" in
1987   yes)  ;;
1988   no)   build_warnings="-w";;
1989   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1990         build_warnings="${build_warnings} ${t}";;
1991   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1992         build_warnings="${t} ${build_warnings}";;
1993   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1994 esac
1995 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1996   echo "Setting compiler warning flags = $build_warnings" 6>&1
1997 fi])dnl
1998 AC_ARG_ENABLE(gdb-build-warnings,
1999 AS_HELP_STRING([--enable-gdb-build-warnings], [enable GDB specific build-time compiler warnings if gcc is used]),
2000 [case "${enableval}" in
2001   yes)  ;;
2002   no)   build_warnings="-w";;
2003   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
2004         build_warnings="${build_warnings} ${t}";;
2005   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
2006         build_warnings="${t} ${build_warnings}";;
2007   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
2008 esac
2009 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
2010   echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1
2011 fi])dnl
2012 WARN_CFLAGS=""
2013 if test "x${build_warnings}" != x -a "x$GCC" = xyes
2014 then
2015     AC_MSG_CHECKING(compiler warning flags)
2016     # Separate out the -Werror flag as some files just cannot be
2017     # compiled with it enabled.
2018     for w in ${build_warnings}; do
2019         case $w in
2020         -Werr*) WERROR_CFLAGS=-Werror ;;
2021         *) # Check that GCC accepts it
2022             saved_CFLAGS="$CFLAGS"
2023             CFLAGS="$CFLAGS $w"
2024             AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
2025             CFLAGS="$saved_CFLAGS"
2026         esac
2027     done
2028     AC_MSG_RESULT(${WARN_CFLAGS} ${WERROR_CFLAGS})
2029 fi
2030 AC_SUBST(WARN_CFLAGS)
2031 AC_SUBST(WERROR_CFLAGS)
2032
2033 # In the Cygwin environment, we need some additional flags.
2034 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
2035 [AC_EGREP_CPP(^lose$, [
2036 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
2037 lose
2038 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
2039
2040
2041 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
2042 SER_HARDWIRE="ser-base.o ser-unix.o ser-pipe.o ser-tcp.o"
2043 case ${host} in
2044   *go32* ) SER_HARDWIRE=ser-go32.o ;;
2045   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
2046   *mingw32*) SER_HARDWIRE="ser-base.o ser-tcp.o ser-mingw.o" ;;
2047 esac
2048 AC_SUBST(SER_HARDWIRE)
2049
2050 # libreadline needs libuser32.a in a cygwin environment
2051 WIN32LIBS=
2052 if test x$gdb_cv_os_cygwin = xyes; then
2053     WIN32LIBS="-luser32"
2054     case "${target}" in
2055         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
2056         ;;
2057     esac
2058 fi
2059
2060 # The ser-tcp.c module requires sockets.
2061 case ${host} in
2062   *mingw32*)
2063     AC_DEFINE(USE_WIN32API, 1,
2064               [Define if we should use the Windows API, instead of the
2065                POSIX API.  On Windows, we use the Windows API when
2066                building for MinGW, but the POSIX API when building
2067                for Cygwin.])
2068     WIN32LIBS="$WIN32LIBS -lws2_32"
2069     ;;
2070 esac
2071 AC_SUBST(WIN32LIBS)
2072
2073 # Add ELF support to GDB, but only if BFD includes ELF support.
2074 GDB_AC_CHECK_BFD([for ELF support in BFD], gdb_cv_var_elf,
2075                  [bfd_get_elf_phdr_upper_bound (NULL)], elf-bfd.h)
2076 if test $gdb_cv_var_elf = yes; then
2077   CONFIG_OBS="$CONFIG_OBS elfread.o stap-probe.o dtrace-probe.o"
2078   AC_DEFINE(HAVE_ELF, 1,
2079             [Define if ELF support should be included.])
2080   # -ldl is provided by bfd/Makfile.am (LIBDL) <PLUGINS>.
2081   if test "$plugins" = "yes"; then
2082     AC_SEARCH_LIBS(dlopen, dl)
2083   fi
2084 fi
2085
2086 # Add macho support to GDB, but only if BFD includes it.
2087 GDB_AC_CHECK_BFD([for Mach-O support in BFD], gdb_cv_var_macho,
2088                  [bfd_mach_o_lookup_command (NULL, 0, NULL)], mach-o.h)
2089 if test $gdb_cv_var_macho = yes; then
2090   CONFIG_OBS="$CONFIG_OBS machoread.o"
2091 fi
2092
2093 # Add SOM support to GDB, but only if BFD includes it.
2094 GDB_AC_CHECK_BFD([for SOM support in BFD], gdb_cv_var_som,
2095                  [bfd_som_attach_aux_hdr (NULL, 0, NULL)], som.h)
2096 if test $gdb_cv_var_som = yes; then
2097   CONFIG_OBS="$CONFIG_OBS somread.o"
2098 fi
2099
2100 # Add any host-specific objects to GDB.
2101 CONFIG_OBS="${CONFIG_OBS} ${gdb_host_obs}"
2102
2103 # If building on ELF, look for lzma support for embedded compressed debug info.
2104 if test $gdb_cv_var_elf = yes; then
2105   AC_ARG_WITH(lzma,
2106     AS_HELP_STRING([--with-lzma], [support lzma compression (auto/yes/no)]),
2107     [], [with_lzma=auto])
2108   AC_MSG_CHECKING([whether to use lzma])
2109   AC_MSG_RESULT([$with_lzma])
2110
2111   if test "${with_lzma}" != no; then
2112     AC_LIB_HAVE_LINKFLAGS([lzma], [], [#include "lzma.h"],
2113                           [lzma_index_iter iter;
2114                            lzma_index_iter_init (&iter, 0);
2115                            lzma_mf_is_supported (LZMA_MF_HC3);])
2116     if test "$HAVE_LIBLZMA" != yes; then
2117       if test "$with_lzma" = yes; then
2118         AC_MSG_ERROR([missing liblzma for --with-lzma])
2119       fi
2120     fi
2121   fi
2122 fi
2123
2124 LIBGUI="../libgui/src/libgui.a"
2125 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
2126 AC_SUBST(LIBGUI)
2127 AC_SUBST(GUI_CFLAGS_X)
2128
2129 WIN32LDAPP=
2130 AC_SUBST(WIN32LIBS)
2131 AC_SUBST(WIN32LDAPP)
2132
2133 case "${host}" in
2134 *-*-cygwin* | *-*-mingw* )
2135     configdir="win"
2136     ;;
2137 *)
2138     configdir="unix"
2139     ;;
2140 esac
2141
2142 GDBTKLIBS=
2143 if test "${enable_gdbtk}" = "yes"; then
2144
2145     # Gdbtk must have an absolute path to srcdir in order to run
2146     # properly when not installed.
2147     here=`pwd`
2148     cd ${srcdir}
2149     GDBTK_SRC_DIR=`pwd`
2150     cd $here
2151
2152     SC_PATH_TCLCONFIG
2153
2154     # If $no_tk is nonempty, then we can't do Tk, and there is no
2155     # point to doing Tcl.
2156     SC_PATH_TKCONFIG
2157
2158     if test -z "${no_tcl}" -a -z "${no_tk}"; then
2159         SC_LOAD_TCLCONFIG
2160
2161         # Check for in-tree tcl
2162         here=`pwd`
2163         cd ${srcdir}/..
2164         topdir=`pwd`
2165         cd ${here}
2166
2167         intree="no"
2168         if test "${TCL_SRC_DIR}" = "${topdir}/tcl"; then
2169           intree="yes"
2170         fi
2171
2172         # Find Tcl private headers
2173         if test x"${intree}" = xno; then
2174           CY_AC_TCL_PRIVATE_HEADERS
2175           TCL_INCLUDE="${TCL_INCLUDE_SPEC} ${TCL_PRIVATE_INCLUDE}"
2176           TCL_LIBRARY="${TCL_LIB_SPEC}"
2177           TCL_DEPS=""
2178         else
2179           # If building tcl in the same src tree, private headers
2180           # are not needed, but we need to be sure to use the right
2181           # headers library
2182           TCL_INCLUDE="-I${TCL_SRC_DIR}/generic"
2183           TCL_LIBRARY="${TCL_BUILD_LIB_SPEC}"
2184           TCL_DEPS="../tcl/${configdir}${TCL_LIB_FILE}"
2185         fi
2186         AC_SUBST(TCL_INCLUDE)
2187         AC_SUBST(TCL_LIBRARY)
2188         AC_SUBST(TCL_DEPS)
2189
2190         SC_LOAD_TKCONFIG
2191
2192         # Check for in-tree Tk
2193         intree="no"
2194         if test "${TK_SRC_DIR}" = "${topdir}/tk"; then
2195           intree="yes"
2196         fi
2197
2198         # Find Tk private headers
2199         if test x"${intree}" = xno; then
2200           CY_AC_TK_PRIVATE_HEADERS
2201           TK_INCLUDE="${TK_INCLUDE_SPEC} ${TK_PRIVATE_INCLUDE}"
2202           TK_LIBRARY=${TK_LIB_SPEC}
2203           TK_DEPS=""
2204         else
2205           TK_INCLUDE="-I${TK_SRC_DIR}/generic"
2206           TK_LIBRARY="${TK_BUILD_LIB_SPEC}"
2207           TK_DEPS="../tk/${configdir}/${TK_LIB_FILE}"
2208         fi
2209         AC_SUBST(TK_INCLUDE)
2210         AC_SUBST(TK_LIBRARY)
2211         AC_SUBST(TK_DEPS)
2212         AC_SUBST(TK_XINCLUDES)
2213
2214         ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
2215
2216         # Include some libraries that Tcl and Tk want.
2217         TCL_LIBS='$(LIBGUI) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
2218         # Yes, the ordering seems wrong here.  But it isn't.
2219         # TK_LIBS is the list of libraries that need to be linked
2220         # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
2221         # were in LIBS then any link tests after this point would
2222         # try to include things like `$(LIBGUI)', which wouldn't work.
2223         GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
2224
2225         CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
2226         CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
2227         CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
2228         CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
2229         CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
2230         CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
2231         CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
2232
2233         if test x$gdb_cv_os_cygwin = xyes; then
2234           WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
2235           WIN32LDAPP="-Wl,--subsystem,console"
2236           CONFIG_OBS="${CONFIG_OBS} gdbres.o"
2237         fi
2238
2239         AC_CONFIG_SUBDIRS(gdbtk)
2240     fi
2241 fi
2242
2243 AC_SUBST(X_CFLAGS)
2244 AC_SUBST(X_LDFLAGS)
2245 AC_SUBST(X_LIBS)
2246 AC_SUBST(GDBTKLIBS)
2247 AC_SUBST(GDBTK_CFLAGS)
2248 AC_SUBST(GDBTK_SRC_DIR)
2249
2250 AC_PATH_X
2251
2252 # Unlike the sim directory, whether a simulator is linked is controlled by
2253 # presence of a gdb_sim definition in the target configure.tgt entry.
2254 # This code just checks for a few cases where we'd like to ignore those
2255 # definitions, even when they're present in the '.mt' file.  These cases
2256 # are when --disable-sim is specified, or if the simulator directory is
2257 # not part of the source tree.
2258 #
2259 AC_ARG_ENABLE(sim,
2260 AS_HELP_STRING([--enable-sim], [link gdb with simulator]),
2261 [echo "enable_sim = $enable_sim";
2262  echo "enableval = ${enableval}";
2263  case "${enableval}" in
2264   yes) ignore_sim=false ;;
2265   no)  ignore_sim=true ;;
2266   *)   ignore_sim=false ;;
2267  esac],
2268 [ignore_sim=false])
2269
2270 if test ! -d "${srcdir}/../sim"; then
2271   ignore_sim=true
2272 fi
2273
2274 SIM=
2275 SIM_OBS=
2276 if test "${ignore_sim}" = "false"; then
2277   if test x"${gdb_sim}" != x ; then
2278     SIM="${gdb_sim}"
2279     SIM_OBS="remote-sim.o"
2280     AC_DEFINE(WITH_SIM, 1, [Define if the simulator is being linked in.])
2281   fi
2282 fi
2283 AC_SUBST(SIM)
2284 AC_SUBST(SIM_OBS)
2285
2286 AC_SUBST(ENABLE_CFLAGS)
2287 AC_SUBST(PROFILE_CFLAGS)
2288
2289 AC_SUBST(CONFIG_OBS)
2290 AC_SUBST(CONFIG_DEPS)
2291 AC_SUBST(CONFIG_SRCS)
2292 AC_SUBST(CONFIG_ALL)
2293 AC_SUBST(CONFIG_CLEAN)
2294 AC_SUBST(CONFIG_INSTALL)
2295 AC_SUBST(CONFIG_UNINSTALL)
2296
2297 # List of host floatformats.
2298 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
2299 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
2300 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
2301
2302 # target_subdir is used by the testsuite to find the target libraries.
2303 target_subdir=
2304 if test "${host}" != "${target}"; then
2305     target_subdir="${target_alias}/"
2306 fi
2307 AC_SUBST(target_subdir)
2308
2309 frags=
2310 if test "${gdb_native}" = "yes"; then
2311   host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
2312   if test ! -f ${host_makefile_frag}; then
2313     AC_MSG_ERROR("*** Gdb does not support native target ${host}")
2314   fi
2315   frags="$frags $host_makefile_frag"
2316 else
2317   host_makefile_frag=/dev/null
2318 fi
2319
2320 AC_SUBST_FILE(host_makefile_frag)
2321 AC_SUBST(frags)
2322
2323 changequote(,)dnl
2324 if test "${gdb_native}" = "yes"; then
2325 # We pick this up from the host configuration file (.mh) because we
2326 # do not have a native configuration Makefile fragment.
2327 nativefile=`sed -n '
2328 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
2329 ' ${host_makefile_frag}`
2330 fi
2331 changequote([,])
2332
2333 if test x"${gdb_osabi}" != x ; then
2334     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
2335                        [Define to the default OS ABI for this configuration.])
2336 fi
2337
2338 # Enable multi-ice-gdb-server.
2339 AC_ARG_ENABLE(multi-ice,
2340 AS_HELP_STRING([--enable-multi-ice], [build the multi-ice-gdb-server]),
2341   [case $enableval in
2342     yes | no)
2343       ;;
2344     *) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;;
2345   esac])
2346 if test "x$enable_multi_ice" = xyes; then
2347    AC_CONFIG_SUBDIRS(multi-ice)
2348 fi
2349
2350 AC_ARG_ENABLE(gdbserver,
2351 AS_HELP_STRING([--enable-gdbserver],
2352                [automatically build gdbserver (yes/no/auto, default is auto)]),
2353 [case "${enableval}" in
2354   yes| no|auto) ;;
2355   *) AC_MSG_ERROR(bad value ${enableval} for --enable-gdbserver option) ;;
2356 esac],[enable_gdbserver=auto])
2357
2358 # We only build gdbserver automatically in a native configuration, and
2359 # only if the user did not explicitly disable its build.
2360 if test "$gdb_native" = "yes" -a "$enable_gdbserver" != "no"; then
2361   AC_MSG_CHECKING(whether gdbserver is supported on this host)
2362   if test "x$build_gdbserver" = xyes; then
2363     AC_MSG_RESULT(yes)
2364     AC_CONFIG_SUBDIRS(gdbserver)
2365     gdbserver_build_enabled=yes
2366   else
2367     AC_MSG_RESULT(no)
2368   fi
2369 fi
2370
2371 # If the user explicitly request the gdbserver to be built, verify that
2372 # we were in fact able to enable it.
2373 if test "$enable_gdbserver" = "yes" -a "$gdbserver_build_enabled" != "yes"; then
2374   AC_MSG_ERROR(Automatic gdbserver build is not supported for this configuration)
2375 fi
2376
2377 # Check for babeltrace and babeltrace-ctf
2378 AC_ARG_WITH(babeltrace,
2379   AC_HELP_STRING([--with-babeltrace], [include babeltrace support (auto/yes/no)]),
2380   [], [with_babeltrace=auto])
2381 AC_MSG_CHECKING([whether to use babeltrace])
2382 AC_MSG_RESULT([$with_babeltrace])
2383
2384 if test "x$with_babeltrace" = "xno"; then
2385   AC_MSG_WARN([babletrace support disabled; GDB is unable to read CTF data.])
2386 else
2387   # Append -Werror to CFLAGS so that configure can catch the warning
2388   # "assignment from incompatible pointer type", which is related to
2389   # the babeltrace change from 1.0.3 to 1.1.0.  Babeltrace 1.1.0 works
2390   # in GDB, while babeltrace 1.0.3 is broken.
2391   # AC_LIB_HAVE_LINKFLAGS may modify CPPFLAGS in it, so it should be
2392   # safe to save and restore CFLAGS here.
2393   saved_CFLAGS=$CFLAGS
2394   CFLAGS="$CFLAGS -Werror"
2395   AC_LIB_HAVE_LINKFLAGS([babeltrace], [babeltrace-ctf],
2396                         [#include <babeltrace/babeltrace.h>
2397                          #include <babeltrace/ctf/events.h>
2398                          #include <babeltrace/ctf/iterator.h>],
2399                         [struct bt_iter_pos *pos = bt_iter_get_pos (bt_ctf_get_iter (NULL));
2400                         struct bt_ctf_event *event = NULL;
2401                         const struct bt_definition *scope;
2402
2403                         bt_iter_set_pos (bt_ctf_get_iter (NULL), pos);
2404                         scope = bt_ctf_get_top_level_scope (event,
2405                                                            BT_STREAM_EVENT_HEADER);
2406                         bt_ctf_get_uint64 (bt_ctf_get_field (event, scope, "id"));
2407                         ])
2408   CFLAGS=$saved_CFLAGS
2409
2410   if test "$HAVE_LIBBABELTRACE" != yes; then
2411      if test "$with_babeltrace" = yes; then
2412        AC_MSG_ERROR([babeltrace is missing or unusable])
2413      else
2414        AC_MSG_WARN([babeltrace is missing or unusable; GDB is unable to read CTF data.])
2415      fi
2416   fi
2417 fi
2418
2419 # If nativefile (NAT_FILE) is not set in config/*/*.m[ht] files, we link
2420 # to an empty version.
2421
2422 files=
2423 links=
2424
2425 rm -f nm.h
2426 if test "${nativefile}" != ""; then
2427     case "${nativefile}" in
2428       nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
2429       * ) GDB_NM_FILE="${nativefile}"
2430     esac
2431     files="${files} ${GDB_NM_FILE}"
2432     links="${links} nm.h"
2433     AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}", [nativefile])
2434 fi
2435 AC_SUBST(GDB_NM_FILE)
2436
2437 AC_LINK_FILES($files, $links)
2438
2439 dnl Check for exe extension set on certain hosts (e.g. Win32)
2440 AC_EXEEXT
2441
2442 dnl  Detect the character set used by this host.
2443 dnl  At the moment, we just assume it's UTF-8.
2444 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "UTF-8",
2445           [Define to be a string naming the default host character set.])
2446
2447 GDB_AC_TRANSFORM([gdb], [GDB_TRANSFORM_NAME])
2448 GDB_AC_TRANSFORM([gcore], [GCORE_TRANSFORM_NAME])
2449 AC_CONFIG_FILES([gcore], [chmod +x gcore])
2450
2451 AC_OUTPUT(Makefile gdb-gdb.gdb doc/Makefile data-directory/Makefile,
2452 [
2453 case x$CONFIG_HEADERS in
2454 xconfig.h:config.in)
2455 echo > stamp-h ;;
2456 esac
2457 ])
2458
2459 exit 0