gdb/configure.ac

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995-2014 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Process this file with autoconf to produce a configure script.
  20
  21 AC_PREREQ(2.59)dnl
  22 AC_INIT(main.c)
  23 AC_CONFIG_HEADER(config.h:config.in)
  24 AM_MAINTAINER_MODE
  25
  26 # Set the 'development' global.
  27 . $srcdir/development.sh
  28
  29 AC_PROG_CC
  30 AC_USE_SYSTEM_EXTENSIONS
  31 ACX_LARGEFILE
  32 AM_PROG_CC_STDC
  33 AM_PROG_INSTALL_STRIP
  34
  35 AC_CONFIG_AUX_DIR(..)
  36 AC_CANONICAL_SYSTEM
  37 AC_ARG_PROGRAM
  38
  39 # Dependency checking.
  40 ZW_CREATE_DEPDIR
  41 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  42
  43 # Check for the 'make' the user wants to use.
  44 AC_CHECK_PROGS(MAKE, make)
  45 MAKE_IS_GNU=
  46 case "`$MAKE --version 2>&1 | sed 1q`" in
  47   *GNU*)
  48     MAKE_IS_GNU=yes
  49     ;;
  50 esac
  51 AM_CONDITIONAL(GMAKE, test "$MAKE_IS_GNU" = yes)
  52 AC_PROG_MAKE_SET
  53
  54 # Configure gnulib.  We need to build gnulib under some other
  55 # directory not "gnulib", to avoid the problem of both GDB and
  56 # GDBserver wanting to build it in the same directory, when building
  57 # in the source dir.
  58 ACX_CONFIGURE_DIR(["gnulib"], ["build-gnulib"])
  59
  60 dnl List of object files and targets accumulated by configure.
  61
  62 CONFIG_OBS=
  63 CONFIG_DEPS=
  64 CONFIG_SRCS=
  65 ENABLE_CFLAGS=
  66
  67 CONFIG_ALL=
  68 CONFIG_CLEAN=
  69 CONFIG_INSTALL=
  70 CONFIG_UNINSTALL=
  71
  72 dnl Set up for gettext.
  73 ZW_GNU_GETTEXT_SISTER_DIR
  74
  75 localedir='${datadir}/locale'
  76 AC_SUBST(localedir)
  77
  78 if test x"$USE_NLS" = xyes; then
  79    CONFIG_ALL="$CONFIG_ALL all-po"
  80    CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
  81    CONFIG_INSTALL="$CONFIG_INSTALL install-po"
  82    CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
  83 fi
  84
  85 GNULIB=build-gnulib/import
  86
  87 # For Makefile dependencies.
  88 GNULIB_STDINT_H=
  89 if test x"$STDINT_H" != x; then
  90   GNULIB_STDINT_H=$GNULIB/$STDINT_H
  91 fi
  92 AC_SUBST(GNULIB_STDINT_H)
  93
  94 PACKAGE=gdb
  95 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
  96 AC_SUBST(PACKAGE)
  97
  98 # We never need to detect it in this sub-configure.
  99 # But preserve it for config.status --recheck.
 100 AC_ARG_VAR(MAKEINFO,
 101   [Parent configure detects if it is of sufficient version.])
 102 AC_ARG_VAR(MAKEINFOFLAGS,
 103   [Parameters for MAKEINFO.])
 104
 105 MAKEINFO_EXTRA_FLAGS=""
 106 AC_CACHE_CHECK([whether $MAKEINFO supports @click], gdb_cv_have_makeinfo_click,
 107   [echo '@clicksequence{a @click{} b}' >conftest.texinfo
 108   if eval "$MAKEINFO conftest.texinfo >&5 2>&5"; then
 109     gdb_cv_have_makeinfo_click=yes
 110   else
 111     gdb_cv_have_makeinfo_click=no
 112   fi])
 113 if test x"$gdb_cv_have_makeinfo_click" = xyes; then
 114   MAKEINFO_EXTRA_FLAGS="$MAKEINFO_EXTRA_FLAGS -DHAVE_MAKEINFO_CLICK"
 115 fi
 116 AC_SUBST(MAKEINFO_EXTRA_FLAGS)
 117
 118 GDB_AC_WITH_DIR(DEBUGDIR, separate-debug-dir,
 119     [look for global separate debug info in this path @<:@LIBDIR/debug@:>@],
 120     [${libdir}/debug])
 121
 122 # We can't pass paths as command line arguments.
 123 # Mingw32 tries to be clever and will convert the paths for us.
 124 # For example -DBINDIR="/usr/local/bin" passed on the command line may get
 125 # converted to -DBINDIR="E:/msys/mingw32/msys/1.0/local/bin".
 126 # This breaks GDB's relocatable path conversions since paths passed in
 127 # config.h would not get so translated, the path prefixes no longer match.
 128 AC_DEFINE_DIR(BINDIR, bindir, [Directory of programs.])
 129
 130 # GDB's datadir relocation
 131
 132 GDB_AC_WITH_DIR(GDB_DATADIR, gdb-datadir,
 133     [look for global separate data files in this path @<:@DATADIR/gdb@:>@],
 134     [${datadir}/gdb])
 135
 136 AC_ARG_WITH(relocated-sources,
 137 AS_HELP_STRING([--with-relocated-sources=PATH], [automatically relocate this path for source files]),
 138 [reloc_srcdir="${withval}"
 139  AC_DEFINE_DIR(RELOC_SRCDIR, reloc_srcdir,
 140               [Relocated directory for source files. ])
 141 ])
 142
 143 AC_MSG_CHECKING([for default auto-load directory])
 144 AC_ARG_WITH(auto-load-dir,
 145 AS_HELP_STRING([--with-auto-load-dir=PATH],
 146   [directories from which to load auto-loaded scripts @<:@$debugdir:$datadir/auto-load@:>@]),,
 147   [with_auto_load_dir='$debugdir:$datadir/auto-load'])
 148 escape_dir=`echo $with_auto_load_dir | sed 's/[[$]]\(datadir\|debugdir\)\>/\\\\\\\\\\\\&/g'`
 149 AC_DEFINE_DIR(AUTO_LOAD_DIR, escape_dir,
 150               [Directories from which to load auto-loaded scripts.])
 151 AC_MSG_RESULT([$with_auto_load_dir])
 152
 153 AC_MSG_CHECKING([for default auto-load safe-path])
 154 AC_ARG_WITH(auto-load-safe-path,
 155 AS_HELP_STRING([--with-auto-load-safe-path=PATH],
 156   [directories safe to hold auto-loaded files @<:@--with-auto-load-dir@:>@])
 157 AS_HELP_STRING([--without-auto-load-safe-path],
 158                [do not restrict auto-loaded files locations]),
 159     [if test "$with_auto_load_safe_path" = "no"; then
 160      with_auto_load_safe_path="/"
 161      fi],
 162 [with_auto_load_safe_path="$with_auto_load_dir"])
 163 escape_dir=`echo $with_auto_load_safe_path | sed 's/[[$]]\(datadir\|debugdir\)\>/\\\\\\\\\\\\&/g'`
 164 AC_DEFINE_DIR(AUTO_LOAD_SAFE_PATH, escape_dir,
 165               [Directories safe to hold auto-loaded files.])
 166 AC_MSG_RESULT([$with_auto_load_safe_path])
 167
 168 AC_CONFIG_SUBDIRS(testsuite)
 169
 170 # Check whether to support alternative target configurations
 171 AC_ARG_ENABLE(targets,
 172 AS_HELP_STRING([--enable-targets=TARGETS], [alternative target configurations]),
 173 [case "${enableval}" in
 174   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
 175             ;;
 176   no)       enable_targets= ;;
 177   *)        enable_targets=$enableval ;;
 178 esac])
 179
 180 # Check whether to enable 64-bit support on 32-bit hosts
 181 AC_ARG_ENABLE(64-bit-bfd,
 182 AS_HELP_STRING([--enable-64-bit-bfd], [64-bit support (on hosts with narrower word sizes)]),
 183 [case "${enableval}" in
 184   yes)  want64=true  ;;
 185   no)   want64=false ;;
 186   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
 187 esac],[want64=false])dnl
 188
 189 # Provide defaults for some variables set by the per-host and per-target
 190 # configuration.
 191 gdb_host_obs=posix-hdep.o
 192
 193 if test "${target}" = "${host}"; then
 194   gdb_native=yes
 195 else
 196   gdb_native=no
 197 fi
 198
 199 . $srcdir/configure.host
 200
 201 # Accumulate some settings from configure.tgt over all enabled targets
 202
 203 TARGET_OBS=
 204 all_targets=
 205 HAVE_NATIVE_GCORE_TARGET=
 206
 207 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 208 do
 209   if test "$targ_alias" = "all"; then
 210     all_targets=true
 211   else
 212     # Canonicalize the secondary target names.
 213     result=`$ac_config_sub $targ_alias 2>/dev/null`
 214     if test -n "$result"; then
 215         targ=$result
 216     else
 217         targ=$targ_alias
 218     fi
 219
 220     . ${srcdir}/configure.tgt
 221
 222     AS_IF([test -z "${gdb_target_obs}"],
 223       [AC_MSG_ERROR([configuration ${targ} is unsupported.])])
 224
 225     # Target-specific object files
 226     for i in ${gdb_target_obs}; do
 227         case " $TARGET_OBS " in
 228         *" ${i} "*) ;;
 229         *)
 230           TARGET_OBS="$TARGET_OBS ${i}"
 231           ;;
 232         esac
 233     done
 234
 235     # Check whether this target needs 64-bit CORE_ADDR
 236     if test x${want64} = xfalse; then
 237       . ${srcdir}/../bfd/config.bfd
 238     fi
 239
 240     # Check whether this target is native and supports gcore.
 241     if test $gdb_native = yes -a "$targ_alias" = "$target_alias" \
 242        && $gdb_have_gcore; then
 243       HAVE_NATIVE_GCORE_TARGET=1
 244     fi
 245   fi
 246 done
 247
 248 if test x${all_targets} = xtrue; then
 249
 250   # We want all 64-bit targets if we either:
 251   #  - run on a 64-bit host  or
 252   #  - already require 64-bit support for some other target  or
 253   #  - the --enable-64-bit-bfd option was supplied
 254   # Otherwise we only support all 32-bit targets.
 255   #
 256   # NOTE: This test must be in sync with the corresponding
 257   #       tests in BFD!
 258
 259   if test x${want64} = xfalse; then
 260     AC_CHECK_SIZEOF(long)
 261     if test "x${ac_cv_sizeof_long}" = "x8"; then
 262       want64=true
 263     fi
 264   fi
 265   if test x${want64} = xtrue; then
 266     TARGET_OBS='$(ALL_TARGET_OBS) $(ALL_64_TARGET_OBS)'
 267   else
 268     TARGET_OBS='$(ALL_TARGET_OBS)'
 269   fi
 270 fi
 271
 272 AC_SUBST(TARGET_OBS)
 273 AC_SUBST(HAVE_NATIVE_GCORE_TARGET)
 274
 275 # For other settings, only the main target counts.
 276 gdb_sim=
 277 gdb_osabi=
 278 build_gdbserver=
 279 targ=$target; . ${srcdir}/configure.tgt
 280
 281 # Fetch the default architecture and default target vector from BFD.
 282 targ=$target; . $srcdir/../bfd/config.bfd
 283
 284 # We only want the first architecture, so strip off the others if
 285 # there is more than one.
 286 targ_archs=`echo $targ_archs | sed 's/ .*//'`
 287
 288 if test "x$targ_archs" != x; then
 289   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
 290     [Define to BFD's default architecture. ])
 291 fi
 292 if test "x$targ_defvec" != x; then
 293   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
 294     [Define to BFD's default target vector. ])
 295 fi
 296
 297 # The CLI cannot be disabled yet, but may be in the future.
 298
 299 # Enable CLI.
 300 AC_ARG_ENABLE(gdbcli,
 301 AS_HELP_STRING([--disable-gdbcli], [disable command-line interface (CLI)]),
 302   [case $enableval in
 303     yes)
 304       ;;
 305     no)
 306       AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;;
 307     *)
 308       AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;;
 309   esac],
 310   [enable_gdbcli=yes])
 311 if test x"$enable_gdbcli" = xyes; then
 312   if test -d $srcdir/cli; then
 313     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)"
 314     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)"
 315     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)"
 316     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)"
 317   fi
 318 fi
 319
 320 # Enable MI.
 321 AC_ARG_ENABLE(gdbmi,
 322 AS_HELP_STRING([--disable-gdbmi], [disable machine-interface (MI)]),
 323   [case $enableval in
 324     yes | no)
 325       ;;
 326     *)
 327       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 328   esac],
 329   [enable_gdbmi=yes])
 330 if test x"$enable_gdbmi" = xyes; then
 331   if test -d $srcdir/mi; then
 332     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 333     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 334     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 335     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 336   fi
 337 fi
 338
 339 # Enable TUI.
 340 AC_ARG_ENABLE(tui,
 341 AS_HELP_STRING([--enable-tui], [enable full-screen terminal user interface (TUI)]),
 342   [case $enableval in
 343     yes | no | auto)
 344       ;;
 345     *)
 346       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 347   esac],enable_tui=auto)
 348
 349 # Enable gdbtk.
 350 AC_ARG_ENABLE(gdbtk,
 351 AS_HELP_STRING([--enable-gdbtk], [enable gdbtk graphical user interface (GUI)]),
 352   [case $enableval in
 353     yes | no)
 354       ;;
 355     *)
 356       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 357   esac],
 358   [if test -d $srcdir/gdbtk; then
 359     enable_gdbtk=yes
 360   else
 361     enable_gdbtk=no
 362   fi])
 363 # We unconditionally disable gdbtk tests on selected platforms.
 364 case $host_os in
 365   go32* | windows*)
 366     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 367     enable_gdbtk=no ;;
 368 esac
 369
 370 # Libunwind support for ia64.
 371
 372 AC_ARG_WITH(libunwind-ia64,
 373 AS_HELP_STRING([--with-libunwind-ia64],
 374                [use libunwind frame unwinding for ia64 targets]),,
 375             [with_libunwind_ia64=auto])
 376
 377 # Backward compatibility option.
 378 if test "${with_libunwind+set}" = set; then
 379   if test x"$with_libunwind_ia64" != xauto; then
 380     AC_MSG_ERROR(
 381       [option --with-libunwind is deprecated, use --with-libunwind-ia64])
 382   fi
 383   AC_MSG_WARN([option --with-libunwind is deprecated, use --with-libunwind-ia64])
 384   with_libunwind_ia64="$with_libunwind"
 385 fi
 386
 387 case "$with_libunwind_ia64" in
 388   yes | no)
 389     ;;
 390   auto)
 391     AC_CHECK_HEADERS(libunwind-ia64.h)
 392     with_libunwind_ia64=$ac_cv_header_libunwind_ia64_h
 393     ;;
 394   *)
 395     AC_MSG_ERROR(
 396       [bad value $with_libunwind_ia64 for GDB --with-libunwind-ia64 option])
 397     ;;
 398 esac
 399
 400 if test x"$with_libunwind_ia64" = xyes; then
 401   AC_CHECK_HEADERS(libunwind-ia64.h)
 402   if test x"$ac_cv_header_libunwind_ia64_h" != xyes; then
 403     AC_MSG_ERROR([GDB option --with-libunwind-ia64 requires libunwind-ia64.h])
 404   fi
 405   CONFIG_OBS="$CONFIG_OBS ia64-libunwind-tdep.o"
 406   CONFIG_DEPS="$CONFIG_DEPS ia64-libunwind-tdep.o"
 407   CONFIG_SRCS="$CONFIG_SRCS ia64-libunwind-tdep.c"
 408 fi
 409
 410 opt_curses=no
 411 AC_ARG_WITH(curses, AS_HELP_STRING([--with-curses], [use the curses library instead of the termcap library]), opt_curses=$withval)
 412
 413 prefer_curses=no
 414 if test "$opt_curses" = "yes"; then
 415   prefer_curses=yes
 416 fi
 417
 418 # Profiling support.
 419 AC_ARG_ENABLE(profiling,
 420 AS_HELP_STRING([--enable-profiling], [enable profiling of GDB]),
 421   [case $enableval in
 422     yes | no)
 423       ;;
 424     *)
 425       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 426   esac],
 427  [enable_profiling=no])
 428
 429 AC_CHECK_FUNCS(monstartup _mcleanup)
 430 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 431 [AC_TRY_LINK(
 432 [#include <stdlib.h>
 433 extern char _etext;
 434 ],
 435 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 436 if test $ac_cv_var__etext = yes; then
 437   AC_DEFINE(HAVE__ETEXT, 1,
 438             [Define to 1 if your system has the _etext variable. ])
 439 fi
 440 AC_CACHE_CHECK([for etext], ac_cv_var_etext,
 441 [AC_TRY_LINK(
 442 [#include <stdlib.h>
 443 extern char etext;
 444 ],
 445 [free (&etext);], ac_cv_var_etext=yes, ac_cv_var_etext=no)])
 446 if test $ac_cv_var_etext = yes; then
 447   AC_DEFINE(HAVE_ETEXT, 1,
 448             [Define to 1 if your system has the etext variable. ])
 449 fi
 450 if test "$enable_profiling" = yes ; then
 451   if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
 452     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 453   fi
 454   PROFILE_CFLAGS=-pg
 455   OLD_CFLAGS="$CFLAGS"
 456   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 457
 458   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 459     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 460      ac_cv_cc_supports_pg=no)])
 461
 462   if test $ac_cv_cc_supports_pg = no; then
 463     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 464   fi
 465
 466   CFLAGS="$OLD_CFLAGS"
 467 fi
 468
 469 ACX_PKGVERSION([GDB])
 470 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 471 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 472 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 473
 474 # --------------------- #
 475 # Checks for programs.  #
 476 # --------------------- #
 477
 478 AC_PROG_AWK
 479 AC_PROG_INSTALL
 480 AC_PROG_LN_S
 481 AC_PROG_RANLIB
 482 AC_PROG_YACC
 483
 484 AC_CHECK_TOOL(AR, ar)
 485 AC_CHECK_TOOL(DLLTOOL, dlltool)
 486 AC_CHECK_TOOL(WINDRES, windres)
 487
 488 case $host_os in
 489   gnu*)
 490     # Needed for GNU Hurd hosts.
 491     AC_CHECK_TOOL(MIG, mig)
 492     if test x"$MIG" = x; then
 493       AC_MSG_ERROR([MIG not found but required for $host hosts])
 494     fi
 495     ;;
 496 esac
 497
 498 # ---------------------- #
 499 # Checks for libraries.  #
 500 # ---------------------- #
 501
 502 # We might need to link with -lm; most simulators need it.
 503 AC_CHECK_LIB(m, main)
 504
 505 # We need to link with -lw to get `wctype' on Solaris before Solaris
 506 # 2.6.  Solaris 2.6 and beyond have this function in libc, and have a
 507 # libw that some versions of the GNU linker cannot hanle (GNU ld 2.9.1
 508 # is known to have this problem).  Therefore we avoid libw if we can.
 509 AC_CHECK_FUNC(wctype, [],
 510   [AC_CHECK_LIB(w, wctype)])
 511
 512 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 513 AC_SEARCH_LIBS(gethostbyname, nsl)
 514
 515 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 516 AC_SEARCH_LIBS(socketpair, socket)
 517
 518 # Link in zlib if we can.  This allows us to read compressed debug sections.
 519 AM_ZLIB
 520
 521 # On HP/UX we may need libxpdl for dlgetmodinfo (used by solib-pa64.c).
 522 AC_SEARCH_LIBS(dlgetmodinfo, [dl xpdl])
 523
 524 AM_ICONV
 525
 526 # GDB may fork/exec the iconv program to get the list of supported character
 527 # sets.  Allow the user to specify where to find it.
 528 # There are several factors affecting the choice of option name:
 529 # - There is already --with-libiconv-prefix but we can't use it, it specifies
 530 #   the build-time location of libiconv files.
 531 # - The program we need to find is iconv, which comes with glibc.  The user
 532 #   doesn't necessarily have libiconv installed.  Therefore naming this
 533 #   --with-libiconv-foo feels wrong.
 534 # - We want the path to be relocatable, but GDB_AC_DEFINE_RELOCATABLE is
 535 #   defined to work on directories not files (though it really doesn't know
 536 #   the difference).
 537 # - Calling this --with-iconv-prefix is perceived to cause too much confusion
 538 #   with --with-libiconv-prefix.
 539 # Putting these together is why the option name is --with-iconv-bin.
 540
 541 AC_ARG_WITH(iconv-bin,
 542 AS_HELP_STRING([--with-iconv-bin=PATH], [specify where to find the iconv program]),
 543 [iconv_bin="${withval}"
 544  AC_DEFINE_UNQUOTED([ICONV_BIN], ["${iconv_bin}"],
 545                     [Path of directory of iconv program.])
 546  GDB_AC_DEFINE_RELOCATABLE(ICONV_BIN, iconv, ${iconv_bin})
 547 ])
 548
 549 # On alpha-osf, it appears that libtermcap and libcurses are not compatible.
 550 # There is a very specific comment in /usr/include/curses.h explaining that
 551 # termcap routines built into libcurses must not be used.
 552 #
 553 # The symptoms we observed so far is GDB unexpectedly changing
 554 # the terminal settings when tgetent is called - this is particularly
 555 # visible as the output is missing carriage returns, and so rapidly
 556 # becomes very hard to read.
 557 #
 558 # The readline configure script has already decided that libtermcap
 559 # was enough for its purposes, and so decided to build readline using
 560 # libtermcap.  Since the TUI mode requires curses, building GDB with
 561 # TUI enabled results in both libraries to be used at the same time,
 562 # which is not allowed.  This basically means that GDB with TUI is
 563 # broken on alpha-osf.
 564
 565 case $host_os in
 566   osf* )
 567     if test x"$enable_tui" = xyes; then
 568       AC_MSG_ERROR([Building GDB with TUI mode is not supported on this host])
 569     fi
 570     if test x"$enable_tui" = xauto; then
 571       enable_tui=no
 572     fi
 573     ;;
 574 esac
 575
 576 # For the TUI, we need enhanced curses functionality.
 577 if test x"$enable_tui" != xno; then
 578   prefer_curses=yes
 579 fi
 580
 581 curses_found=no
 582 if test x"$prefer_curses" = xyes; then
 583   # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
 584   # curses library because the latter might not provide all the
 585   # functionality we need.  However, this leads to problems on systems
 586   # where the linker searches /usr/local/lib, but the compiler doesn't
 587   # search /usr/local/include, if ncurses is installed in /usr/local.  A
 588   # default installation of ncurses on alpha*-dec-osf* will lead to such
 589   # a situation.
 590   AC_SEARCH_LIBS(waddstr, [ncurses cursesX curses])
 591
 592   if test "$ac_cv_search_waddstr" != no; then
 593     curses_found=yes
 594   fi
 595 fi
 596
 597 # Check whether we should enable the TUI, but only do so if we really
 598 # can.
 599 if test x"$enable_tui" != xno; then
 600   if test -d $srcdir/tui; then
 601     if test "$curses_found" != no; then
 602       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
 603       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
 604       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
 605       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
 606     else
 607       if test x"$enable_tui" = xyes; then
 608         AC_MSG_ERROR([no enhanced curses library found; disable TUI])
 609       else
 610         AC_MSG_WARN([no enhanced curses library found; disabling TUI])
 611       fi
 612     fi
 613   fi
 614 fi
 615
 616 # Since GDB uses Readline, we need termcap functionality.  In many
 617 # cases this will be provided by the curses library, but some systems
 618 # have a seperate termcap library, or no curses library at all.
 619
 620 case $host_os in
 621   cygwin*)
 622     if test -d $srcdir/libtermcap; then
 623       LIBS="../libtermcap/libtermcap.a $LIBS"
 624       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 625     fi ;;
 626   go32* | *djgpp*)
 627     ac_cv_search_tgetent="none required"
 628     ;;
 629   *mingw32*)
 630     ac_cv_search_tgetent="none required"
 631     CONFIG_OBS="$CONFIG_OBS windows-termcap.o"
 632     ;;
 633 esac
 634
 635 # These are the libraries checked by Readline.
 636 AC_SEARCH_LIBS(tgetent, [termcap tinfo curses ncurses])
 637
 638 if test "$ac_cv_search_tgetent" = no; then
 639   AC_MSG_ERROR([no termcap library found])
 640 fi
 641
 642 AC_ARG_WITH([system-readline],
 643   [AS_HELP_STRING([--with-system-readline],
 644                   [use installed readline library])])
 645
 646 if test "$with_system_readline" = yes; then
 647   READLINE=-lreadline
 648   READLINE_DEPS=
 649   READLINE_CFLAGS=
 650   READLINE_TEXI_INCFLAG=
 651 else
 652   READLINE='$(READLINE_DIR)/libreadline.a'
 653   READLINE_DEPS='$(READLINE)'
 654   READLINE_CFLAGS='-I$(READLINE_SRC)/..'
 655   READLINE_TEXI_INCFLAG='-I $(READLINE_DIR)'
 656 fi
 657 AC_SUBST(READLINE)
 658 AC_SUBST(READLINE_DEPS)
 659 AC_SUBST(READLINE_CFLAGS)
 660 AC_SUBST(READLINE_TEXI_INCFLAG)
 661
 662 # Generate jit-reader.h
 663
 664 # This is typedeffed to GDB_CORE_ADDR in jit-reader.h
 665 TARGET_PTR=
 666
 667 AC_CHECK_SIZEOF(unsigned long long)
 668 AC_CHECK_SIZEOF(unsigned long)
 669 AC_CHECK_SIZEOF(unsigned __int128)
 670
 671 if test "x${ac_cv_sizeof_unsigned_long}" = "x8"; then
 672   TARGET_PTR="unsigned long"
 673 elif test "x${ac_cv_sizeof_unsigned_long_long}" = "x8"; then
 674   TARGET_PTR="unsigned long long"
 675 elif test "x${ac_cv_sizeof_unsigned___int128}" = "x16"; then
 676   TARGET_PTR="unsigned __int128"
 677 else
 678   TARGET_PTR="unsigned long"
 679 fi
 680
 681 AC_SUBST(TARGET_PTR)
 682 AC_CONFIG_FILES([jit-reader.h:jit-reader.in])
 683
 684 AC_SEARCH_LIBS(dlopen, dl)
 685
 686 GDB_AC_WITH_DIR([JIT_READER_DIR], [jit-reader-dir],
 687                 [directory to load the JIT readers from],
 688                 [${libdir}/gdb])
 689
 690 AC_ARG_WITH(expat,
 691   AS_HELP_STRING([--with-expat], [include expat support (auto/yes/no)]),
 692   [], [with_expat=auto])
 693 AC_MSG_CHECKING([whether to use expat])
 694 AC_MSG_RESULT([$with_expat])
 695
 696 if test "${with_expat}" = no; then
 697   AC_MSG_WARN([expat support disabled; some features may be unavailable.])
 698   HAVE_LIBEXPAT=no
 699 else
 700   AC_LIB_HAVE_LINKFLAGS([expat], [], [#include "expat.h"],
 701                         [XML_Parser p = XML_ParserCreate (0);])
 702   if test "$HAVE_LIBEXPAT" != yes; then
 703     if test "$with_expat" = yes; then
 704       AC_MSG_ERROR([expat is missing or unusable])
 705     else
 706       AC_MSG_WARN([expat is missing or unusable; some features may be unavailable.])
 707     fi
 708   else
 709     save_LIBS=$LIBS
 710     LIBS="$LIBS $LIBEXPAT"
 711     AC_CHECK_FUNCS(XML_StopParser)
 712     LIBS=$save_LIBS
 713   fi
 714 fi
 715
 716 # --------------------- #
 717 # Check for libpython.  #
 718 # --------------------- #
 719
 720 dnl Utility to simplify finding libpython.
 721 dnl $1 = pythonX.Y
 722 dnl $2 = the shell variable to assign the result to
 723 dnl      If libpython is found we store $version here.
 724 dnl $3 = additional flags to add to CPPFLAGS
 725 dnl $4 = additional flags to add to LIBS
 726
 727 AC_DEFUN([AC_TRY_LIBPYTHON],
 728 [
 729   version=$1
 730   define([have_libpython_var],$2)
 731   new_CPPFLAGS=$3
 732   new_LIBS=$4
 733   AC_MSG_CHECKING([for ${version}])
 734   save_CPPFLAGS=$CPPFLAGS
 735   save_LIBS=$LIBS
 736   CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
 737   LIBS="$LIBS $new_LIBS"
 738   found_usable_python=no
 739   AC_LINK_IFELSE(AC_LANG_PROGRAM([[#include "Python.h"]],
 740                                  [[Py_Initialize ();]]),
 741                  [have_libpython_var=${version}
 742                   found_usable_python=yes
 743                   PYTHON_CPPFLAGS=$new_CPPFLAGS
 744                   PYTHON_LIBS=$new_LIBS])
 745   CPPFLAGS=$save_CPPFLAGS
 746   LIBS=$save_LIBS
 747   AC_MSG_RESULT([${found_usable_python}])
 748 ])
 749
 750 dnl There are several different values for --with-python:
 751 dnl
 752 dnl no -   Don't include python support.
 753 dnl yes -  Include python support, error if it's missing.
 754 dnl        If we find python in $PATH, use it to fetch configure options,
 755 dnl        otherwise assume the compiler can find it with no help from us.
 756 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 757 dnl auto - Same as "yes", but if python is missing from the system,
 758 dnl        fall back to "no".
 759 dnl /path/to/python/exec-prefix -
 760 dnl        Use the python located in this directory.
 761 dnl        If /path/to/python/exec-prefix/bin/python exists, use it to find
 762 dnl        the compilation parameters.  Otherwise use
 763 dnl        -I/path/to/python/exec-prefix/include,
 764 dnl        -L/path/to/python/exec-prefix/lib.
 765 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 766 dnl        NOTE: This case is historical.  It is what was done for 7.0/7.1
 767 dnl        but is deprecated.
 768 dnl /path/to/python/executable -
 769 dnl        Run python-config.py with this version of python to fetch the
 770 dnl        compilation parameters.
 771 dnl        NOTE: This needn't be the real python executable.
 772 dnl        In a cross-compilation scenario (build != host), this could be
 773 dnl        a shell script that provides what python-config.py provides for
 774 dnl        --ldflags, --includes, --exec-prefix.
 775 dnl python-executable -
 776 dnl        Find python-executable in $PATH, and then handle the same as
 777 dnl        /path/to/python/executable.
 778 dnl
 779 dnl If a python program is specified, it is used to run python-config.py and
 780 dnl is passed --ldflags, --includes, --exec-prefix.
 781
 782 AC_ARG_WITH(python,
 783   AS_HELP_STRING([--with-python@<:@=PYTHON@:>@], [include python support (auto/yes/no/<python-program>)]),
 784   [], [with_python=auto])
 785 AC_MSG_CHECKING([whether to use python])
 786 AC_MSG_RESULT([$with_python])
 787
 788 if test "${with_python}" = no; then
 789   AC_MSG_WARN([python support disabled; some features may be unavailable.])
 790   have_libpython=no
 791 else
 792   case "${with_python}" in
 793   [[\\/]]* | ?:[[\\/]]*)
 794     if test -d ${with_python}; then
 795       # Assume the python binary is ${with_python}/bin/python.
 796       python_prog="${with_python}/bin/python"
 797       python_prefix=
 798       # If python does not exit ${with_python}/bin, then try in
 799       # ${with_python}.  On Windows/MinGW, this is where the Python
 800       # executable is.
 801       if test ! -x "${python_prog}"; then
 802         python_prog="${with_python}/python"
 803         python_prefix=
 804       fi
 805       if test ! -x "${python_prog}"; then
 806         # Fall back to gdb 7.0/7.1 behaviour.
 807         python_prog=missing
 808         python_prefix=${with_python}
 809       fi
 810     elif test -x "${with_python}"; then
 811       # While we can't run python compiled for $host (unless host == build),
 812       # the user could write a script that provides the needed information,
 813       # so we support that.
 814       python_prog=${with_python}
 815       python_prefix=
 816     else
 817       AC_ERROR(invalid value for --with-python)
 818     fi
 819     ;;
 820   */*)
 821     # Disallow --with-python=foo/bar.
 822     AC_ERROR(invalid value for --with-python)
 823     ;;
 824   *)
 825     # The user has either specified auto, yes, or the name of the python
 826     # program assumed to be in $PATH.
 827     python_prefix=
 828     case "${with_python}" in
 829     yes | auto)
 830       if test ${build} = ${host}; then
 831         AC_PATH_PROG(python_prog_path, python, missing)
 832         if test "${python_prog_path}" = missing; then
 833           python_prog=missing
 834         else
 835           python_prog=${python_prog_path}
 836         fi
 837       else
 838         # Not much we can do except assume the cross-compiler will find the
 839         # right files.
 840         python_prog=missing
 841       fi
 842       ;;
 843     *)
 844       # While we can't run python compiled for $host (unless host == build),
 845       # the user could write a script that provides the needed information,
 846       # so we support that.
 847       python_prog="${with_python}"
 848       AC_PATH_PROG(python_prog_path, ${python_prog}, missing)
 849       if test "${python_prog_path}" = missing; then
 850         AC_ERROR(unable to find python program ${python_prog})
 851       fi
 852       ;;
 853     esac
 854   esac
 855
 856   if test "${python_prog}" != missing; then
 857     # We have a python program to use, but it may be too old.
 858     # Don't flag an error for --with-python=auto (the default).
 859     have_python_config=yes
 860     python_includes=`${python_prog} ${srcdir}/python/python-config.py --includes`
 861     if test $? != 0; then
 862       have_python_config=failed
 863       if test "${with_python}" != auto; then
 864         AC_ERROR(failure running python-config --includes)
 865       fi
 866     fi
 867     python_libs=`${python_prog} ${srcdir}/python/python-config.py --ldflags`
 868     if test $? != 0; then
 869       have_python_config=failed
 870       if test "${with_python}" != auto; then
 871         AC_ERROR(failure running python-config --ldflags)
 872       fi
 873     fi
 874     python_prefix=`${python_prog} ${srcdir}/python/python-config.py --exec-prefix`
 875     if test $? != 0; then
 876       have_python_config=failed
 877       if test "${with_python}" != auto; then
 878         AC_ERROR(failure running python-config --exec-prefix)
 879       fi
 880     fi
 881   else
 882     # We do not have a python executable we can use to determine where
 883     # to find the Python headers and libs.  We cannot guess the include
 884     # path from the python_prefix either, because that include path
 885     # depends on the Python version.  So, there is nothing much we can
 886     # do except assume that the compiler will be able to find those files.
 887     python_includes=
 888     python_libs=
 889     have_python_config=no
 890   fi
 891
 892   # If we have python-config, only try the configuration it provides.
 893   # Otherwise fallback on the old way of trying different versions of
 894   # python in turn.
 895
 896   have_libpython=no
 897   if test "${have_python_config}" = yes; then
 898     # Determine the Python version by extracting "-lpython<version>"
 899     # part of the python_libs. <version> is usually X.Y with X and Y
 900     # being decimal numbers, but can also be XY (seen on Windows).
 901     #
 902     # The extraction is performed using sed with a regular expression.
 903     # Initially, the regexp used was using the '?' quantifier to make
 904     # the dot in the version number optional.  Unfortunately, this
 905     # does not work with non-GNU versions of sed because, because of
 906     # what looks like a limitation (the '?' quantifier does not work
 907     # with back-references).  We work around this limitation by using
 908     # the '*' quantifier instead.  It means that, in theory, we might
 909     # match unexpected version strings such as "-lpython2..7", but
 910     # this seems unlikely in practice.  And even if that happens,
 911     # an error will be triggered later on, when checking that version
 912     # number.
 913     python_version=`echo " ${python_libs} " \
 914                          | sed -e 's,^.* -l\(python[[0-9]]*[[.]]*[[0-9]]*\).*$,\1,'`
 915     case "${python_version}" in
 916     python*)
 917       AC_TRY_LIBPYTHON(${python_version}, have_libpython,
 918                        ${python_includes}, ${python_libs})
 919       ;;
 920     *)
 921       AC_MSG_ERROR([unable to determine python version from ${python_libs}])
 922       ;;
 923     esac
 924   elif test "${have_python_config}" != failed; then
 925     if test "${have_libpython}" = no; then
 926       AC_TRY_LIBPYTHON(python2.7, have_libpython,
 927                        ${python_includes}, "${python_libs} -lpython2.7")
 928     fi
 929     if test "${have_libpython}" = no; then
 930       AC_TRY_LIBPYTHON(python2.6, have_libpython,
 931                        ${python_includes}, "${python_libs} -lpython2.6")
 932     fi
 933     if test ${have_libpython} = no; then
 934       AC_TRY_LIBPYTHON(python2.5, have_libpython,
 935                        ${python_includes}, "${python_libs} -lpython2.5")
 936     fi
 937     if test ${have_libpython} = no; then
 938       AC_TRY_LIBPYTHON(python2.4, have_libpython,
 939                        ${python_includes}, "${python_libs} -lpython2.4")
 940     fi
 941   fi
 942   if test "${have_libpython}" = python2.7 -o "${have_libpython}" = python27; then
 943     AC_DEFINE(HAVE_LIBPYTHON2_7, 1, [Define if Python 2.7 is being used.])
 944   elif test "${have_libpython}" = python2.6 -o "${have_libpython}" = python26; then
 945     AC_DEFINE(HAVE_LIBPYTHON2_6, 1, [Define if Python 2.6 is being used.])
 946   elif test "${have_libpython}" = python2.5 -o "${have_libpython}" = python25; then
 947     AC_DEFINE(HAVE_LIBPYTHON2_5, 1, [Define if Python 2.5 is being used.])
 948   elif test "${have_libpython}" = python2.4 -o "${have_libpython}" = python24; then
 949     AC_DEFINE(HAVE_LIBPYTHON2_4, 1, [Define if Python 2.4 is being used.])
 950   fi
 951
 952   if test "${have_libpython}" = no; then
 953     case "${with_python}" in
 954     yes)
 955       AC_MSG_ERROR([python is missing or unusable])
 956       ;;
 957     auto)
 958       AC_MSG_WARN([python is missing or unusable; some features may be unavailable.])
 959       ;;
 960     *)
 961       AC_MSG_ERROR([no usable python found at ${with_python}])
 962       ;;
 963     esac
 964   else
 965     if test -n "${python_prefix}"; then
 966       AC_DEFINE_UNQUOTED(WITH_PYTHON_PATH, "${python_prefix}",
 967                          [Define if --with-python provides a path, either directly or via python-config.py --exec-prefix.])
 968       GDB_AC_DEFINE_RELOCATABLE(PYTHON_PATH, python, ${python_prefix})
 969     fi
 970   fi
 971 fi
 972
 973 if test "${have_libpython}" != no; then
 974   AC_DEFINE(HAVE_PYTHON, 1, [Define if Python interpreter is being linked in.])
 975   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_PYTHON_OBS)"
 976   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_PYTHON_DEPS)"
 977   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_PYTHON_SRCS)"
 978   CONFIG_INSTALL="$CONFIG_INSTALL install-python"
 979   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_PYTHON_CFLAGS)"
 980
 981   # Flags needed to compile Python code (taken from python-config --cflags).
 982   # We cannot call python-config directly because it will output whatever was
 983   # used when compiling the Python interpreter itself, including flags which
 984   # would make the python-related objects be compiled differently from the
 985   # rest of GDB (e.g., -O2 and -fPIC).
 986   if test "${GCC}" = yes; then
 987     tentative_python_cflags="-fno-strict-aliasing -DNDEBUG -fwrapv"
 988   fi
 989
 990   if test "x${tentative_python_cflags}" != x; then
 991     AC_MSG_CHECKING(compiler flags for python code)
 992     for flag in ${tentative_python_cflags}; do
 993       # Check that the compiler accepts it
 994       saved_CFLAGS="$CFLAGS"
 995       CFLAGS="$CFLAGS $flag"
 996       AC_TRY_COMPILE([],[],PYTHON_CFLAGS="${PYTHON_CFLAGS} $flag",)
 997       CFLAGS="$saved_CFLAGS"
 998     done
 999     AC_MSG_RESULT(${PYTHON_CFLAGS})
1000   fi
1001
1002   # On IRIX, type siginfo is not defined.  Instead, sys/siginfo.h provides:
1003   #    #if _SGIAPI
1004   #    #define siginfo __siginfo
1005   #    #endif
1006   # The problem is that including Python causes some XOPEN macros to be
1007   # unilaterally defined, and that in turn causes _SGIAPI to evaluate
1008   # to false.  So, we work around this issue by defining siginfo ourself
1009   # though the command-line.
1010   #
1011   # On x64 Windows, Python's include headers, and pyconfig.h in
1012   # particular, rely on MS_WIN64 macro to detect that it's a 64bit
1013   # version of Windows.  Unfortunately, MS_WIN64 is only defined if
1014   # _MSC_VER, a Microsoft-specific macro, is defined.  So, when
1015   # building on x64 Windows with GCC, we define MS_WIN64 ourselves.
1016   # The issue was reported to the Python community, but still isn't
1017   # solved as of 2012-10-02 (http://bugs.python.org/issue4709).
1018
1019   case "$gdb_host" in
1020     irix*) if test "${GCC}" = yes; then
1021              CPPFLAGS="$CPPFLAGS -Dsiginfo=__siginfo"
1022            fi
1023            ;;
1024     mingw64)
1025            if test "${GCC}" = yes; then
1026              CPPFLAGS="$CPPFLAGS -DMS_WIN64"
1027            fi
1028            ;;
1029   esac
1030
1031   # Note that "python -m threading" cannot be used to check for
1032   # threading support due to a bug in Python 2.7.3
1033   # (http://bugs.python.org/issue15567).
1034   AC_MSG_CHECKING(whether python supports threads)
1035   saved_CPPFLAGS="${CPPFLAGS}"
1036   CPPFLAGS="${PYTHON_CPPFLAGS}"
1037   # Note that the test is reversed so that python_has_threads=yes on
1038   # unexpected failures.
1039   AC_PREPROC_IFELSE(AC_LANG_SOURCE([[
1040 #include <Python.h>
1041 #ifdef WITH_THREAD
1042 # error
1043 #endif
1044   ]]), [python_has_threads=no], [python_has_threads=yes])
1045   AC_MSG_RESULT(${python_has_threads})
1046   CPPFLAGS="${saved_CPPFLAGS}"
1047 else
1048   # Even if Python support is not compiled in, we need to have this file
1049   # included so that the "python" command, et.al., still exists.
1050   CONFIG_OBS="$CONFIG_OBS python.o"
1051   CONFIG_SRCS="$CONFIG_SRCS python/python.c"
1052 fi
1053 AC_SUBST(PYTHON_CFLAGS)
1054 AC_SUBST(PYTHON_CPPFLAGS)
1055 AC_SUBST(PYTHON_LIBS)
1056
1057 # -------------------- #
1058 # Check for libguile.  #
1059 # -------------------- #
1060
1061 dnl Utility to simplify finding libguile.
1062 dnl $1 = pkg-config-program
1063 dnl $2 = space-separate list of guile versions to try
1064 dnl $3 = yes|no, indicating whether to flag errors or ignore them
1065 dnl $4 = the shell variable to assign the result to
1066 dnl      If libguile is found we store "yes" here.
1067
1068 AC_DEFUN([AC_TRY_LIBGUILE],
1069 [
1070   pkg_config=$1
1071   guile_version_list=$2
1072   flag_errors=$3
1073   define([have_libguile_var],$4)
1074   found_usable_guile=checking
1075   AC_MSG_CHECKING([for usable guile from ${pkg_config}])
1076   for guile_version in ${guile_version_list}; do
1077     ${pkg_config} --exists ${guile_version} 2>/dev/null
1078     if test $? != 0; then
1079       continue
1080     fi
1081     dnl pkg-config says the package exists, so if we get an error now,
1082     dnl that's bad.
1083     new_CPPFLAGS=`${pkg_config} --cflags ${guile_version}`
1084     if test $? != 0; then
1085       AC_MSG_ERROR([failure running pkg-config --cflags ${guile_version}])
1086     fi
1087     new_LIBS=`${pkg_config} --libs ${guile_version}`
1088     if test $? != 0; then
1089       AC_MSG_ERROR([failure running pkg-config --libs ${guile_version}])
1090     fi
1091     dnl If we get this far, great.
1092     found_usable_guile=${guile_version}
1093     break
1094   done
1095   if test "${found_usable_guile}" = "checking"; then
1096     if test "${flag_errors}" = "yes"; then
1097       AC_MSG_ERROR([unable to find usable guile version from "${guile_version_list}"])
1098     else
1099       found_usable_guile=no
1100     fi
1101   fi
1102   dnl One final sanity check.
1103   dnl The user could have said --with-guile=python-2.7.
1104   if test "${found_usable_guile}" != no; then
1105     save_CPPFLAGS=$CPPFLAGS
1106     save_LIBS=$LIBS
1107     CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
1108     LIBS="$LIBS $new_LIBS"
1109     AC_LINK_IFELSE(AC_LANG_PROGRAM([[#include "libguile.h"]],
1110                                    [[scm_init_guile ();]]),
1111                    [have_libguile_var=yes
1112                     GUILE_CPPFLAGS=$new_CPPFLAGS
1113                     GUILE_LIBS=$new_LIBS],
1114                    [found_usable_guile=no])
1115     CPPFLAGS=$save_CPPFLAGS
1116     LIBS=$save_LIBS
1117     if test "${found_usable_guile}" = no; then
1118       if test "${flag_errors}" = yes; then
1119         AC_MSG_FAILURE([linking guile version ${guile_version} test program failed])
1120       fi
1121     fi
1122   fi
1123   AC_MSG_RESULT([${found_usable_guile}])
1124 ])
1125
1126 dnl There are several different values for --with-guile:
1127 dnl
1128 dnl no -   Don't include guile support.
1129 dnl yes -  Include guile support, error if it's missing.
1130 dnl        The pkg-config program must be in $PATH.
1131 dnl auto - Same as "yes", but if guile is missing from the system,
1132 dnl        fall back to "no".
1133 dnl guile-version [guile-version-choice-2 ...] -
1134 dnl        A space-separated list of guile package versions to try.
1135 dnl        These are passed to pkg-config as-is.
1136 dnl        E.g., guile-2.0 or guile-2.2-uninstalled
1137 dnl        This requires making sure PKG_CONFIG_PATH is set appropriately.
1138 dnl /path/to/pkg-config -
1139 dnl        Use this pkg-config program.
1140 dnl        NOTE: This needn't be the "real" pkg-config program.
1141 dnl        It could be a shell script.  It is invoked as:
1142 dnl        pkg-config --exists $version
1143 dnl        pkg-config --cflags $version
1144 dnl        pkg-config --libs $version
1145 dnl        $version will be the default guile version (currently guile-2.0),
1146 dnl        but the program is free to ignore this.
1147
1148 AC_ARG_WITH(guile,
1149   AS_HELP_STRING([--with-guile@<:@=GUILE@:>@], [include guile support (auto/yes/no/<guile-version>/<pkg-config-program>)]),
1150   [], [with_guile=auto])
1151 AC_MSG_CHECKING([whether to use guile])
1152 AC_MSG_RESULT([$with_guile])
1153
1154 dnl We check guile with pkg-config.
1155 AC_PATH_PROG(pkg_config_prog_path, pkg-config, missing)
1156
1157 try_guile_versions="guile-2.0"
1158 have_libguile=no
1159 case "${with_guile}" in
1160 no)
1161   AC_MSG_WARN([guile support disabled; some features will be unavailable.])
1162   ;;
1163 auto)
1164   if test "${pkg_config_prog_path}" = "missing"; then
1165     AC_MSG_WARN([pkg-config not found, guile support disabled])
1166   else
1167     AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${try_guile_versions}, no, have_libguile)
1168   fi
1169   ;;
1170 yes)
1171   if test "${pkg_config_prog_path}" = "missing"; then
1172     AC_MSG_ERROR([pkg-config not found])
1173   fi
1174   AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${try_guile_versions}, yes, have_libguile)
1175   ;;
1176 [[\\/]]* | ?:[[\\/]]*)
1177   if test -x "${with_guile}"; then
1178     AC_TRY_LIBGUILE(${with_guile}, ${try_guile_versions}, yes, have_libguile)
1179   else
1180     AC_MSG_ERROR([Guile config program not executable: ${with_guile}])
1181   fi
1182   ;;
1183 "" | */*)
1184   # Disallow --with=guile="" and --with-guile=foo/bar.
1185   AC_MSG_ERROR([invalid value for --with-guile])
1186   ;;
1187 *)
1188   # A space separate list of guile versions to try, in order.
1189   if test "${pkg_config_prog_path}" = "missing"; then
1190     AC_MSG_ERROR([pkg-config not found])
1191   fi
1192   AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${with_guile}, yes, have_libguile)
1193   ;;
1194 esac
1195
1196 if test "${have_libguile}" != no; then
1197   AC_DEFINE(HAVE_GUILE, 1, [Define if Guile interpreter is being linked in.])
1198   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_GUILE_OBS)"
1199   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_GUILE_DEPS)"
1200   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_GUILE_SRCS)"
1201   CONFIG_INSTALL="$CONFIG_INSTALL install-guile"
1202   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_GUILE_CFLAGS)"
1203 else
1204   # Even if Guile support is not compiled in, we need to have these files
1205   # included.
1206   CONFIG_OBS="$CONFIG_OBS guile.o"
1207   CONFIG_SRCS="$CONFIG_SRCS guile/guile.c"
1208 fi
1209 AC_SUBST(GUILE_CPPFLAGS)
1210 AC_SUBST(GUILE_LIBS)
1211
1212 # --------------------- #
1213 # Check for libmcheck.  #
1214 # --------------------- #
1215
1216 # Enable -lmcheck by default (it provides cheap-enough memory mangling),
1217 # but turn it off if Python is enabled with threads, since -lmcheck is
1218 # not thread safe (http://sourceware.org/bugzilla/show_bug.cgi?id=9939),
1219 # and for releases.
1220 if test \( "${have_libpython}" = "no" -o "${python_has_threads}" = "no" \) \
1221    && $development; then
1222   libmcheck_default=yes
1223 else
1224   libmcheck_default=no
1225 fi
1226 GDB_AC_LIBMCHECK(${libmcheck_default})
1227
1228 if test "$ENABLE_LIBMCHECK" = "yes" \
1229         -a "${have_libpython}" != "no" \
1230         -a "${python_has_threads}" = "yes" ; then
1231   AC_MSG_WARN(--enable-libmcheck may lead to spurious crashes if threads are used in python)
1232 fi
1233
1234 # ------------------------- #
1235 # Checks for header files.  #
1236 # ------------------------- #
1237
1238 AC_HEADER_STDC
1239 # elf_hp.h is for HP/UX 64-bit shared library support.
1240 AC_CHECK_HEADERS([nlist.h machine/reg.h poll.h sys/poll.h proc_service.h \
1241                   thread_db.h \
1242                   sys/fault.h \
1243                   sys/file.h sys/filio.h sys/ioctl.h sys/param.h \
1244                   sys/resource.h sys/procfs.h sys/ptrace.h ptrace.h \
1245                   sys/reg.h sys/debugreg.h sys/select.h sys/syscall.h \
1246                   termios.h termio.h \
1247                   sgtty.h elf_hp.h \
1248                   dlfcn.h])
1249 AC_CHECK_HEADERS(sys/proc.h, [], [],
1250 [#if HAVE_SYS_PARAM_H
1251 # include <sys/param.h>
1252 #endif
1253 ])
1254 AC_CHECK_HEADERS(sys/user.h, [], [],
1255 [#if HAVE_SYS_PARAM_H
1256 # include <sys/param.h>
1257 #endif
1258 ])
1259
1260 # On Solaris 2.[789], we need to define _MSE_INT_H to avoid a clash
1261 # between <widec.h> and <wchar.h> that would cause AC_CHECK_HEADERS to
1262 # think that we don't have <curses.h> if we're using GCC.
1263 case $host_os in
1264   solaris2.[[789]])
1265     if test "$GCC" = yes; then
1266       AC_DEFINE(_MSE_INT_H, 1,
1267         [Define to 1 to avoid a clash between <widec.h> and <wchar.h> on
1268    Solaris 2.[789] when using GCC. ])
1269     fi ;;
1270 esac
1271 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncurses/ncurses.h ncurses/term.h)
1272 AC_CHECK_HEADERS(term.h, [], [],
1273 [#if HAVE_CURSES_H
1274 # include <curses.h>
1275 #endif
1276 ])
1277
1278 # ------------------------- #
1279 # Checks for declarations.  #
1280 # ------------------------- #
1281
1282 AC_CHECK_DECLS([free, malloc, realloc, snprintf])
1283 AM_LC_MESSAGES
1284
1285 # ----------------------- #
1286 # Checks for structures.  #
1287 # ----------------------- #
1288
1289 AC_CHECK_MEMBERS([struct stat.st_blocks, struct stat.st_blksize])
1290
1291 # ------------------ #
1292 # Checks for types.  #
1293 # ------------------ #
1294
1295 AC_TYPE_SIGNAL
1296 AC_CHECK_TYPES(socklen_t, [], [],
1297 [#include <sys/types.h>
1298 #include <sys/socket.h>
1299 ])
1300
1301 # ------------------------------------- #
1302 # Checks for compiler characteristics.  #
1303 # ------------------------------------- #
1304
1305 AC_C_CONST
1306 AC_C_INLINE
1307 AC_C_BIGENDIAN
1308
1309 # ------------------------------ #
1310 # Checks for library functions.  #
1311 # ------------------------------ #
1312
1313 AC_FUNC_ALLOCA
1314 AC_FUNC_MMAP
1315 AC_FUNC_VFORK
1316 AC_CHECK_FUNCS([canonicalize_file_name realpath getrusage getuid getgid \
1317                 pipe poll pread pread64 pwrite readlink resize_term \
1318                 sbrk setpgid setpgrp setsid \
1319                 sigaction sigprocmask sigsetmask socketpair \
1320                 ttrace wborder wresize setlocale iconvlist libiconvlist btowc \
1321                 setrlimit getrlimit posix_madvise waitpid lstat \
1322                 ptrace64])
1323 AM_LANGINFO_CODESET
1324 GDB_AC_COMMON
1325
1326 # Check the return and argument types of ptrace.  No canned test for
1327 # this, so roll our own.
1328 gdb_ptrace_headers='
1329 #include <sys/types.h>
1330 #if HAVE_SYS_PTRACE_H
1331 # include <sys/ptrace.h>
1332 #endif
1333 #if HAVE_UNISTD_H
1334 # include <unistd.h>
1335 #endif
1336 '
1337 # There is no point in checking if we don't have a prototype.
1338 AC_CHECK_DECLS(ptrace, [], [
1339   : ${gdb_cv_func_ptrace_ret='int'}
1340   : ${gdb_cv_func_ptrace_args='int,int,long,long'}
1341 ], $gdb_ptrace_headers)
1342 # Check return type.  Varargs (used on GNU/Linux) conflict with the
1343 # empty argument list, so check for that explicitly.
1344 AC_CACHE_CHECK([return type of ptrace], gdb_cv_func_ptrace_ret,
1345   AC_TRY_COMPILE($gdb_ptrace_headers,
1346     [extern long ptrace (enum __ptrace_request, ...);],
1347     gdb_cv_func_ptrace_ret='long',
1348     AC_TRY_COMPILE($gdb_ptrace_headers,
1349       [extern int ptrace ();],
1350       gdb_cv_func_ptrace_ret='int',
1351       gdb_cv_func_ptrace_ret='long')))
1352 AC_DEFINE_UNQUOTED(PTRACE_TYPE_RET, $gdb_cv_func_ptrace_ret,
1353   [Define as the return type of ptrace.])
1354 # Check argument types.
1355 AC_CACHE_CHECK([types of arguments for ptrace], gdb_cv_func_ptrace_args, [
1356   AC_TRY_COMPILE($gdb_ptrace_headers,
1357     [extern long ptrace (enum __ptrace_request, ...);],
1358     [gdb_cv_func_ptrace_args='int,int,long,long'],[
1359 for gdb_arg1 in 'int' 'long'; do
1360  for gdb_arg2 in 'pid_t' 'int' 'long'; do
1361   for gdb_arg3 in 'int *' 'caddr_t' 'int' 'long' 'void *'; do
1362    for gdb_arg4 in 'int' 'long' 'void *'; do
1363      AC_TRY_COMPILE($gdb_ptrace_headers, [
1364 extern $gdb_cv_func_ptrace_ret
1365   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4);
1366 ], [gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4";
1367     break 4;])
1368     for gdb_arg5 in 'int *' 'int' 'long'; do
1369      AC_TRY_COMPILE($gdb_ptrace_headers, [
1370 extern $gdb_cv_func_ptrace_ret
1371   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4, $gdb_arg5);
1372 ], [
1373 gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4,$gdb_arg5";
1374     break 5;])
1375     done
1376    done
1377   done
1378  done
1379 done
1380 # Provide a safe default value.
1381 : ${gdb_cv_func_ptrace_args='int,int,long,long'}
1382 ])])
1383 ac_save_IFS=$IFS; IFS=','
1384 set dummy `echo "$gdb_cv_func_ptrace_args" | sed 's/\*/\*/g'`
1385 IFS=$ac_save_IFS
1386 shift
1387 AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG3, $[3],
1388   [Define to the type of arg 3 for ptrace.])
1389 AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG4, $[4],
1390   [Define to the type of arg 4 for ptrace.])
1391 if test -n "$[5]"; then
1392   AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG5, $[5],
1393     [Define to the type of arg 5 for ptrace.])
1394 fi
1395
1396 dnl AC_FUNC_SETPGRP does not work when cross compiling
1397 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
1398 if test "$cross_compiling" = no; then
1399   AC_FUNC_SETPGRP
1400 else
1401   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
1402     [AC_TRY_COMPILE([
1403 #include <unistd.h>
1404 ], [
1405   if (setpgrp(1,1) == -1)
1406     exit (0);
1407   else
1408     exit (1);
1409 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
1410 if test $ac_cv_func_setpgrp_void = yes; then
1411   AC_DEFINE(SETPGRP_VOID, 1)
1412 fi
1413 fi
1414
1415 # Check if sigsetjmp is available.  Using AC_CHECK_FUNCS won't do
1416 # since sigsetjmp might only be defined as a macro.
1417 AC_CACHE_CHECK([for sigsetjmp], gdb_cv_func_sigsetjmp,
1418 [AC_TRY_COMPILE([
1419 #include <setjmp.h>
1420 ], [sigjmp_buf env; while (! sigsetjmp (env, 1)) siglongjmp (env, 1);],
1421 gdb_cv_func_sigsetjmp=yes, gdb_cv_func_sigsetjmp=no)])
1422 if test $gdb_cv_func_sigsetjmp = yes; then
1423   AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available. ])
1424 fi
1425
1426 # Assume we'll default to using the included libiberty regex.
1427 gdb_use_included_regex=yes
1428
1429 # However, if the system regex is GNU regex, then default to *not*
1430 # using the included regex.
1431 AC_CACHE_CHECK(
1432   [for GNU regex],
1433   [gdb_cv_have_gnu_regex],
1434   [AC_TRY_COMPILE(
1435     [#include <gnu-versions.h>],
1436     [#define REGEX_INTERFACE_VERSION 1
1437 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
1438 # error "Version mismatch"
1439 #endif],
1440     gdb_cv_have_gnu_regex=yes,
1441     gdb_cv_have_gnu_regex=no)])
1442 if test $gdb_cv_have_gnu_regex = yes; then
1443   gdb_use_included_regex=no
1444 fi
1445
1446 AC_ARG_WITH(included-regex,
1447   AS_HELP_STRING([--without-included-regex], [don't use included regex; this is the default on systems with version 2 of the GNU C library (use with caution on other system)]),
1448   gdb_with_regex=$withval,
1449   gdb_with_regex=$gdb_use_included_regex)
1450 if test "$gdb_with_regex" = yes; then
1451   AC_DEFINE(USE_INCLUDED_REGEX, 1,
1452     [Define to 1 if the regex included in libiberty should be used.])
1453 fi
1454
1455 # Check if <sys/proc.h> defines `struct thread' with a td_pcb member.
1456 AC_CHECK_MEMBERS([struct thread.td_pcb], [], [],
1457 [#include <sys/param.h>
1458 #include <sys/proc.h>
1459 ])
1460
1461 # See if <sys/lwp.h> defines `struct lwp`.
1462 AC_CACHE_CHECK([for struct lwp], gdb_cv_struct_lwp,
1463 [AC_TRY_COMPILE([#include <sys/param.h>
1464 #include <sys/lwp.h>], [struct lwp l;],
1465 gdb_cv_struct_lwp=yes, gdb_cv_struct_lwp=no)])
1466 if test $gdb_cv_struct_lwp = yes; then
1467   AC_DEFINE(HAVE_STRUCT_LWP, 1,
1468             [Define to 1 if your system has struct lwp.])
1469 fi
1470
1471 # See if <machine/reg.h> degines `struct reg'.
1472 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
1473 [AC_TRY_COMPILE([#include <sys/types.h>
1474 #include <machine/reg.h>], [struct reg r;],
1475 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
1476 if test $gdb_cv_struct_reg = yes; then
1477   AC_DEFINE(HAVE_STRUCT_REG, 1,
1478             [Define to 1 if your system has struct reg in <machine/reg.h>.])
1479 fi
1480
1481 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
1482 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
1483 AC_CHECK_MEMBERS([struct reg.r_fs, struct reg.r_gs], [], [],
1484                  [#include <machine/reg.h>])
1485
1486 # See if <sys/user.h> supports the %fs_base and %gs_bas amd64 segment registers.
1487 # Older amd64 Linux's don't have the fs_base and gs_base members of
1488 # `struct user_regs_struct'.
1489 AC_CHECK_MEMBERS([struct user_regs_struct.fs_base, struct user_regs_struct.gs_base],
1490                  [], [], [#include <sys/user.h>])
1491
1492 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
1493 AC_MSG_CHECKING(for PTRACE_GETREGS)
1494 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
1495 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1496                 [PTRACE_GETREGS;],
1497                 [gdb_cv_have_ptrace_getregs=yes],
1498                 [gdb_cv_have_ptrace_getregs=no])])
1499 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
1500 if test $gdb_cv_have_ptrace_getregs = yes; then
1501   AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
1502   [Define if sys/ptrace.h defines the PTRACE_GETREGS request.])
1503 fi
1504
1505 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
1506 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
1507 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
1508 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1509                 [PTRACE_GETFPXREGS;],
1510                 [gdb_cv_have_ptrace_getfpxregs=yes],
1511                 [gdb_cv_have_ptrace_getfpxregs=no])])
1512 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
1513 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
1514   AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
1515   [Define if sys/ptrace.h defines the PTRACE_GETFPXREGS request.])
1516 fi
1517
1518 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
1519 AC_MSG_CHECKING(for PT_GETDBREGS)
1520 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
1521 [AC_TRY_COMPILE([#include <sys/types.h>
1522 #include <sys/ptrace.h>],
1523                 [PT_GETDBREGS;],
1524                 [gdb_cv_have_pt_getdbregs=yes],
1525                 [gdb_cv_have_pt_getdbregs=no])])
1526 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
1527 if test $gdb_cv_have_pt_getdbregs = yes; then
1528   AC_DEFINE(HAVE_PT_GETDBREGS, 1,
1529   [Define if sys/ptrace.h defines the PT_GETDBREGS request.])
1530 fi
1531
1532 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
1533 AC_MSG_CHECKING(for PT_GETXMMREGS)
1534 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
1535 [AC_TRY_COMPILE([#include <sys/types.h>
1536 #include <sys/ptrace.h>],
1537                 [PT_GETXMMREGS;],
1538                 [gdb_cv_have_pt_getxmmregs=yes],
1539                 [gdb_cv_have_pt_getxmmregs=no])])
1540 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
1541 if test $gdb_cv_have_pt_getxmmregs = yes; then
1542   AC_DEFINE(HAVE_PT_GETXMMREGS, 1,
1543   [Define if sys/ptrace.h defines the PT_GETXMMREGS request.])
1544 fi
1545
1546 # Detect which type of /proc is in use, such as for Solaris.
1547
1548 if test "${target}" = "${host}"; then
1549   case "${host}" in
1550   *-*-sysv4.2* | *-*-sysv5* )
1551       AC_DEFINE(NEW_PROC_API, 1,
1552       [Define if you want to use new multi-fd /proc interface.])
1553       ;;
1554   *-*-solaris2.[[6789]] | *-*-solaris2.1[[0-9]]*)
1555       AC_DEFINE(NEW_PROC_API, 1,
1556       [Define if you want to use new multi-fd /proc interface.])
1557       ;;
1558   mips-sgi-irix5*)
1559       # Work around <sys/proc.h> needing _KMEMUSER problem on IRIX 5.
1560       AC_DEFINE([_KMEMUSER], 1,
1561       [Define to 1 so <sys/proc.h> gets a definition of anon_hdl.  Works
1562        around a <sys/proc.h> problem on IRIX 5.])
1563       ;;
1564   esac
1565 fi
1566
1567 if test "$ac_cv_header_sys_procfs_h" = yes; then
1568   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
1569   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
1570   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
1571   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
1572   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
1573   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
1574   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
1575   BFD_HAVE_SYS_PROCFS_TYPE(prsysent_t)
1576   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigset_t)
1577   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigaction64_t)
1578   BFD_HAVE_SYS_PROCFS_TYPE(pr_siginfo64_t)
1579
1580
1581   dnl Check for broken prfpregset_t type
1582
1583   dnl For Linux/i386, glibc 2.1.3 was released with a bogus
1584   dnl prfpregset_t type (it's a typedef for the pointer to a struct
1585   dnl instead of the struct itself).  We detect this here, and work
1586   dnl around it in gdb_proc_service.h.
1587
1588   if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
1589     AC_MSG_CHECKING(whether prfpregset_t type is broken)
1590     AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
1591       [AC_TRY_RUN([#include <sys/procfs.h>
1592        int main ()
1593        {
1594          if (sizeof (prfpregset_t) == sizeof (void *))
1595            return 1;
1596          return 0;
1597        }],
1598        gdb_cv_prfpregset_t_broken=no,
1599        gdb_cv_prfpregset_t_broken=yes,
1600        gdb_cv_prfpregset_t_broken=yes)])
1601     AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
1602     if test $gdb_cv_prfpregset_t_broken = yes; then
1603       AC_DEFINE(PRFPREGSET_T_BROKEN, 1,
1604       [Define if the prfpregset_t type is broken.])
1605     fi
1606   fi
1607 fi
1608
1609 # Check if the compiler supports the `long long' type.
1610
1611 AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long,
1612                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1613 [[extern long long foo;]],
1614 [[switch (foo & 2) { case 0: return 1; }]])],
1615                                   gdb_cv_c_long_long=yes,
1616                                   gdb_cv_c_long_long=no)])
1617 if test $gdb_cv_c_long_long != yes; then
1618   # libdecnumber requires long long.
1619   AC_MSG_ERROR([Compiler must support long long for GDB.])
1620 fi
1621
1622 # Check if the compiler and runtime support printing long longs.
1623
1624 AC_CACHE_CHECK([for long long support in printf],
1625                gdb_cv_printf_has_long_long,
1626                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1627 [[char buf[32];
1628   long long l = 0;
1629   l = (l << 16) + 0x0123;
1630   l = (l << 16) + 0x4567;
1631   l = (l << 16) + 0x89ab;
1632   l = (l << 16) + 0xcdef;
1633   sprintf (buf, "0x%016llx", l);
1634   return (strcmp ("0x0123456789abcdef", buf));]])],
1635                               gdb_cv_printf_has_long_long=yes,
1636                               gdb_cv_printf_has_long_long=no,
1637                               gdb_cv_printf_has_long_long=no)])
1638 if test $gdb_cv_printf_has_long_long = yes; then
1639   AC_DEFINE(PRINTF_HAS_LONG_LONG, 1,
1640             [Define to 1 if the "%ll" format works to print long longs.])
1641 fi
1642
1643 # Check if the compiler and runtime support printing decfloats.
1644
1645 AC_CACHE_CHECK([for decfloat support in printf],
1646                gdb_cv_printf_has_decfloat,
1647                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1648 [[char buf[64];
1649   _Decimal32 d32 = 1.2345df;
1650   _Decimal64 d64 = 1.2345dd;
1651   _Decimal128 d128 = 1.2345dl;
1652   sprintf (buf, "Decimal32: %H\nDecimal64: %D\nDecimal128: %DD", d32, d64, d128);
1653   return (strcmp ("Decimal32: 1.2345\nDecimal64: 1.2345\nDecimal128: 1.2345", buf));]])],
1654                               gdb_cv_printf_has_decfloat=yes,
1655                               gdb_cv_printf_has_decfloat=no,
1656                               gdb_cv_printf_has_decfloat=no)])
1657 if test $gdb_cv_printf_has_decfloat = yes; then
1658   AC_DEFINE(PRINTF_HAS_DECFLOAT, 1,
1659             [Define to 1 if the "%H, %D and %DD" formats work to print decfloats.])
1660 fi
1661
1662 # Check if the compiler supports the `long double' type.  We can't use
1663 # AC_C_LONG_DOUBLE because that one does additional checks on the
1664 # constants defined in <float.h> that fail on some systems,
1665 # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6.
1666
1667 AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double,
1668                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])],
1669                                   gdb_cv_c_long_double=yes,
1670                                   gdb_cv_c_long_double=no)])
1671 if test $gdb_cv_c_long_double = yes; then
1672   AC_DEFINE(HAVE_LONG_DOUBLE, 1,
1673            [Define to 1 if the compiler supports long double.])
1674 fi
1675
1676 # Check if the compiler and runtime support printing long doubles.
1677
1678 AC_CACHE_CHECK([for long double support in printf],
1679                gdb_cv_printf_has_long_double,
1680                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1681 [[char buf[16];
1682   long double f = 3.141592653;
1683   sprintf (buf, "%Lg", f);
1684   return (strncmp ("3.14159", buf, 7));]])],
1685                               gdb_cv_printf_has_long_double=yes,
1686                               gdb_cv_printf_has_long_double=no,
1687                               gdb_cv_printf_has_long_double=no)])
1688 if test $gdb_cv_printf_has_long_double = yes; then
1689   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1,
1690             [Define to 1 if the "%Lg" format works to print long doubles.])
1691 fi
1692
1693 # Check if the compiler and runtime support scanning long doubles.
1694
1695 AC_CACHE_CHECK([for long double support in scanf],
1696                gdb_cv_scanf_has_long_double,
1697                [AC_RUN_IFELSE([AC_LANG_PROGRAM(
1698 [[#include <stdio.h>]],
1699 [[char *buf = "3.141592653";
1700   long double f = 0;
1701   sscanf (buf, "%Lg", &f);
1702   return !(f > 3.14159 && f < 3.14160);]])],
1703                               gdb_cv_scanf_has_long_double=yes,
1704                               gdb_cv_scanf_has_long_double=no,
1705                               gdb_cv_scanf_has_long_double=no)])
1706 if test $gdb_cv_scanf_has_long_double = yes; then
1707   AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1,
1708             [Define to 1 if the "%Lg" format works to scan long doubles.])
1709 fi
1710
1711 case ${host_os} in
1712 aix*)
1713   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1714     SAVE_LDFLAGS=$LDFLAGS
1715
1716     case $GCC in
1717     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1718     *) gdb_cv_bigtoc=-bbigtoc ;;
1719     esac
1720
1721     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1722     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1723     LDFLAGS="${SAVE_LDFLAGS}"
1724   ])
1725   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
1726   ;;
1727 esac
1728
1729 AC_MSG_CHECKING(for the dynamic export flag)
1730 dynamic_list=false
1731 if test "${gdb_native}" = yes; then
1732    # The dynamically loaded libthread_db needs access to symbols in the gdb
1733    # executable.  Older GNU ld supports --export-dynamic but --dynamic-list
1734    # may not be supported there.
1735    old_LDFLAGS="$LDFLAGS"
1736    # Older GNU ld supports --export-dynamic but --dynamic-list it does not.
1737    RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
1738    LDFLAGS="$LDFLAGS $RDYNAMIC"
1739    if test "${have_libpython}" = no; then
1740      AC_TRY_LINK([], [], [dynamic_list=true])
1741    else
1742      # Workaround http://bugs.python.org/issue4434 where static
1743      # libpythonX.Y.a would get its symbols required for
1744      # pythonX.Y/lib-dynload/*.so modules hidden by -Wl,--dynamic-list.
1745      # Problem does not happen for the recommended libpythonX.Y.so linkage.
1746      old_CFLAGS="$CFLAGS"
1747      CFLAGS="$CFLAGS $PYTHON_CFLAGS"
1748      old_LIBS="$LIBS"
1749      LIBS="$LIBS $PYTHON_LIBS"
1750      AC_RUN_IFELSE(
1751        AC_LANG_PROGRAM(
1752          [#include "]${have_libpython}[/Python.h"],
1753          [int err;
1754           Py_Initialize ();
1755           err = PyRun_SimpleString ("import itertools\n");
1756           Py_Finalize ();
1757           return err == 0 ? 0 : 1;]),
1758        [dynamic_list=true], [], [true])
1759      LIBS="$old_LIBS"
1760      CFLAGS="$old_CFLAGS"
1761    fi
1762    LDFLAGS="$old_LDFLAGS"
1763 fi
1764 if $dynamic_list; then
1765   found="-Wl,--dynamic-list"
1766   RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'
1767 else
1768   found="-rdynamic"
1769   RDYNAMIC="-rdynamic"
1770 fi
1771 AC_SUBST(RDYNAMIC)
1772 AC_MSG_RESULT($found)
1773
1774 dnl For certain native configurations, we need to check whether thread
1775 dnl support can be built in or not.
1776 dnl
1777 dnl Note that we only want this if we are both native (host == target),
1778 dnl and not doing a canadian cross build (build == host).
1779
1780 if test ${build} = ${host} -a ${host} = ${target} ; then
1781    case ${host_os} in
1782    solaris*)
1783       # See if thread_db library is around for Solaris thread debugging.
1784       # Note that we must explicitly test for version 1 of the library
1785       # because version 0 (present on Solaris 2.4 or earlier) doesn't have
1786       # the same API.
1787       AC_MSG_CHECKING(for Solaris thread debugging library)
1788       if test -f /usr/lib/libthread_db.so.1 ; then
1789          AC_MSG_RESULT(yes)
1790          AC_DEFINE(HAVE_THREAD_DB_LIB, 1,
1791          [Define if using Solaris thread debugging.])
1792          CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
1793          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
1794          AC_CHECK_LIB(dl, dlopen)
1795          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} $RDYNAMIC"
1796          # Sun randomly tweaked the prototypes in <proc_service.h>
1797          # at one point.
1798          AC_MSG_CHECKING(if <proc_service.h> is old)
1799          AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
1800             AC_TRY_COMPILE([
1801                 #include <proc_service.h>
1802                 ps_err_e ps_pdwrite
1803                     (struct ps_prochandle*, psaddr_t, const void*, size_t);
1804             ],, gdb_cv_proc_service_is_old=no,
1805                 gdb_cv_proc_service_is_old=yes)
1806          ])
1807          AC_MSG_RESULT($gdb_cv_proc_service_is_old)
1808          if test $gdb_cv_proc_service_is_old = yes; then
1809             AC_DEFINE(PROC_SERVICE_IS_OLD, 1,
1810             [Define if <proc_service.h> on solaris uses int instead of
1811              size_t, and assorted other type changes.])
1812          fi
1813       else
1814          AC_MSG_RESULT(no)
1815       fi
1816       ;;
1817    aix*)
1818       AC_MSG_CHECKING(for AiX thread debugging library)
1819       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
1820                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
1821                                    [#ifndef PTHDB_VERSION_3
1822                                     #error
1823                                     #endif],
1824                                    gdb_cv_have_aix_thread_debug=yes,
1825                                    gdb_cv_have_aix_thread_debug=no)])
1826       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1827       if test $gdb_cv_have_aix_thread_debug = yes; then
1828          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1829          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1830          LIBS="$LIBS -lpthdebug"
1831
1832          # Older versions of AIX do not provide the declaration for
1833          # the getthrds function (it appears that it was introduced
1834          # with AIX 6.x).
1835          AC_CHECK_DECLS(getthrds, [], [], [[#include <procinfo.h>]])
1836       fi
1837       ;;
1838    esac
1839    AC_SUBST(CONFIG_LDFLAGS)
1840 fi
1841
1842 dnl See if we have a thread_db header file that has TD_NOTALLOC and
1843 dnl other error codes.
1844 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1845    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
1846                   gdb_cv_thread_db_h_has_td_notalloc,
1847      AC_TRY_COMPILE(
1848        [#include <thread_db.h>],
1849        [int i = TD_NOTALLOC;],
1850        gdb_cv_thread_db_h_has_td_notalloc=yes,
1851        gdb_cv_thread_db_h_has_td_notalloc=no
1852      )
1853    )
1854    AC_CACHE_CHECK([whether <thread_db.h> has TD_VERSION],
1855                   gdb_cv_thread_db_h_has_td_version,
1856      AC_TRY_COMPILE(
1857        [#include <thread_db.h>],
1858        [int i = TD_VERSION;],
1859        gdb_cv_thread_db_h_has_td_version=yes,
1860        gdb_cv_thread_db_h_has_td_version=no
1861      )
1862    )
1863    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTLS],
1864                   gdb_cv_thread_db_h_has_td_notls,
1865      AC_TRY_COMPILE(
1866        [#include <thread_db.h>],
1867        [int i = TD_NOTLS;],
1868        gdb_cv_thread_db_h_has_td_notls=yes,
1869        gdb_cv_thread_db_h_has_td_notls=no
1870      )
1871    )
1872 fi
1873 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1874   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1875             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1876 fi
1877 if test "x$gdb_cv_thread_db_h_has_td_version" = "xyes"; then
1878   AC_DEFINE(THREAD_DB_HAS_TD_VERSION, 1,
1879             [Define if <thread_db.h> has the TD_VERSION error code.])
1880 fi
1881 if test "x$gdb_cv_thread_db_h_has_td_notls" = "xyes"; then
1882   AC_DEFINE(THREAD_DB_HAS_TD_NOTLS, 1,
1883             [Define if <thread_db.h> has the TD_NOTLS error code.])
1884 fi
1885
1886 dnl See if we have a sys/syscall header file that has __NR_tkill.
1887 if test "x$ac_cv_header_sys_syscall_h" = "xyes"; then
1888    AC_CACHE_CHECK([whether <sys/syscall.h> has __NR_tkill],
1889                   gdb_cv_sys_syscall_h_has_tkill,
1890      AC_TRY_COMPILE(
1891        [#include <sys/syscall.h>],
1892        [int i = __NR_tkill;],
1893        gdb_cv_sys_syscall_h_has_tkill=yes,
1894        gdb_cv_sys_syscall_h_has_tkill=no
1895      )
1896    )
1897 fi
1898 dnl See if we can issue tkill syscall.
1899 if test "x$gdb_cv_sys_syscall_h_has_tkill" = "xyes"; then
1900   AC_CHECK_FUNC(syscall,
1901     AC_DEFINE(HAVE_TKILL_SYSCALL, 1, [Define if you support the tkill syscall.])
1902   )
1903 fi
1904
1905 dnl Check if we can disable the virtual address space randomization.
1906 dnl The functionality of setarch -R.
1907 AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>])
1908 define([PERSONALITY_TEST], [AC_LANG_PROGRAM([#include <sys/personality.h>], [
1909 #      if !HAVE_DECL_ADDR_NO_RANDOMIZE
1910 #       define ADDR_NO_RANDOMIZE 0x0040000
1911 #      endif
1912        /* Test the flag could be set and stays set.  */
1913        personality (personality (0xffffffff) | ADDR_NO_RANDOMIZE);
1914        if (!(personality (personality (0xffffffff)) & ADDR_NO_RANDOMIZE))
1915            return 1])])
1916 AC_RUN_IFELSE([PERSONALITY_TEST],
1917               [have_personality=true],
1918               [have_personality=false],
1919               [AC_LINK_IFELSE([PERSONALITY_TEST],
1920                               [have_personality=true],
1921                               [have_personality=false])])
1922 if $have_personality
1923 then
1924     AC_DEFINE([HAVE_PERSONALITY], 1,
1925               [Define if you support the personality syscall.])
1926 fi
1927
1928 dnl Set the host's .gdbinit filename.
1929 case $host_os in
1930   go32* | *djgpp*)
1931     gdbinit=gdb.ini
1932     ;;
1933   *)
1934     gdbinit=.gdbinit
1935     ;;
1936 esac
1937 AC_DEFINE_UNQUOTED(GDBINIT,"$gdbinit",[The .gdbinit filename.])
1938
1939 dnl Handle optional features that can be enabled.
1940
1941 # Support for --with-sysroot is a copy of GDB_AC_WITH_DIR,
1942 # except that the argument to --with-sysroot is optional.
1943 # --with-sysroot (or --with-sysroot=yes) sets the default sysroot path.
1944 if test "x$with_sysroot" = xyes; then
1945   with_sysroot="${exec_prefix}/${target_alias}/sys-root"
1946 fi
1947 AC_ARG_WITH(sysroot,
1948   AS_HELP_STRING([--with-sysroot@<:@=DIR@:>@],
1949                  [search for usr/lib et al within DIR]),
1950   [TARGET_SYSTEM_ROOT=$withval], [TARGET_SYSTEM_ROOT=])
1951 AC_DEFINE_DIR(TARGET_SYSTEM_ROOT, TARGET_SYSTEM_ROOT,
1952               [search for usr/lib et al within DIR])
1953 AC_SUBST(TARGET_SYSTEM_ROOT)
1954 GDB_AC_DEFINE_RELOCATABLE(TARGET_SYSTEM_ROOT, sysroot, ${ac_define_dir})
1955
1956 GDB_AC_WITH_DIR(SYSTEM_GDBINIT, system-gdbinit,
1957     [automatically load a system-wide gdbinit file],
1958     [])
1959
1960 AC_ARG_ENABLE(werror,
1961   AS_HELP_STRING([--enable-werror], [treat compile warnings as errors]),
1962   [case "${enableval}" in
1963      yes | y) ERROR_ON_WARNING="yes" ;;
1964      no | n)  ERROR_ON_WARNING="no" ;;
1965      *) AC_MSG_ERROR(bad value ${enableval} for --enable-werror) ;;
1966    esac])
1967
1968 # Enable -Werror by default when using gcc.  Turn it off for releases.
1969 if test "${GCC}" = yes -a -z "${ERROR_ON_WARNING}" && $development; then
1970     ERROR_ON_WARNING=yes
1971 fi
1972
1973 WERROR_CFLAGS=""
1974 if test "${ERROR_ON_WARNING}" = yes ; then
1975     WERROR_CFLAGS="-Werror"
1976 fi
1977
1978 build_warnings="-Wall -Wdeclaration-after-statement -Wpointer-arith \
1979 -Wpointer-sign \
1980 -Wno-unused -Wunused-value -Wunused-function \
1981 -Wno-switch -Wno-char-subscripts -Wmissing-prototypes \
1982 -Wdeclaration-after-statement -Wempty-body -Wmissing-parameter-type \
1983 -Wold-style-declaration -Wold-style-definition"
1984
1985 # Enable -Wno-format by default when using gcc on mingw since many
1986 # GCC versions complain about %I64.
1987 case "${host}" in
1988   *-*-mingw32*) build_warnings="$build_warnings -Wno-format" ;;
1989   *) build_warnings="$build_warnings -Wformat-nonliteral" ;;
1990 esac
1991
1992 AC_ARG_ENABLE(build-warnings,
1993 AS_HELP_STRING([--enable-build-warnings], [enable build-time compiler warnings if gcc is used]),
1994 [case "${enableval}" in
1995   yes)  ;;
1996   no)   build_warnings="-w";;
1997   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1998         build_warnings="${build_warnings} ${t}";;
1999   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
2000         build_warnings="${t} ${build_warnings}";;
2001   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
2002 esac
2003 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
2004   echo "Setting compiler warning flags = $build_warnings" 6>&1
2005 fi])dnl
2006 AC_ARG_ENABLE(gdb-build-warnings,
2007 AS_HELP_STRING([--enable-gdb-build-warnings], [enable GDB specific build-time compiler warnings if gcc is used]),
2008 [case "${enableval}" in
2009   yes)  ;;
2010   no)   build_warnings="-w";;
2011   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
2012         build_warnings="${build_warnings} ${t}";;
2013   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
2014         build_warnings="${t} ${build_warnings}";;
2015   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
2016 esac
2017 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
2018   echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1
2019 fi])dnl
2020 WARN_CFLAGS=""
2021 if test "x${build_warnings}" != x -a "x$GCC" = xyes
2022 then
2023     AC_MSG_CHECKING(compiler warning flags)
2024     # Separate out the -Werror flag as some files just cannot be
2025     # compiled with it enabled.
2026     for w in ${build_warnings}; do
2027         case $w in
2028         -Werr*) WERROR_CFLAGS=-Werror ;;
2029         *) # Check that GCC accepts it
2030             saved_CFLAGS="$CFLAGS"
2031             CFLAGS="$CFLAGS $w"
2032             AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
2033             CFLAGS="$saved_CFLAGS"
2034         esac
2035     done
2036     AC_MSG_RESULT(${WARN_CFLAGS} ${WERROR_CFLAGS})
2037 fi
2038 AC_SUBST(WARN_CFLAGS)
2039 AC_SUBST(WERROR_CFLAGS)
2040
2041 # In the Cygwin environment, we need some additional flags.
2042 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
2043 [AC_EGREP_CPP(^lose$, [
2044 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
2045 lose
2046 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
2047
2048
2049 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
2050 SER_HARDWIRE="ser-base.o ser-unix.o ser-pipe.o ser-tcp.o"
2051 case ${host} in
2052   *go32* ) SER_HARDWIRE=ser-go32.o ;;
2053   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
2054   *mingw32*) SER_HARDWIRE="ser-base.o ser-tcp.o ser-mingw.o" ;;
2055 esac
2056 AC_SUBST(SER_HARDWIRE)
2057
2058 # libreadline needs libuser32.a in a cygwin environment
2059 WIN32LIBS=
2060 if test x$gdb_cv_os_cygwin = xyes; then
2061     WIN32LIBS="-luser32"
2062     case "${target}" in
2063         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
2064         ;;
2065     esac
2066 fi
2067
2068 # The ser-tcp.c module requires sockets.
2069 case ${host} in
2070   *mingw32*)
2071     AC_DEFINE(USE_WIN32API, 1,
2072               [Define if we should use the Windows API, instead of the
2073                POSIX API.  On Windows, we use the Windows API when
2074                building for MinGW, but the POSIX API when building
2075                for Cygwin.])
2076     WIN32LIBS="$WIN32LIBS -lws2_32"
2077     ;;
2078 esac
2079 AC_SUBST(WIN32LIBS)
2080
2081 # Add ELF support to GDB, but only if BFD includes ELF support.
2082 GDB_AC_CHECK_BFD([for ELF support in BFD], gdb_cv_var_elf,
2083                  [bfd_get_elf_phdr_upper_bound (NULL)], elf-bfd.h)
2084 if test $gdb_cv_var_elf = yes; then
2085   CONFIG_OBS="$CONFIG_OBS elfread.o stap-probe.o"
2086   AC_DEFINE(HAVE_ELF, 1,
2087             [Define if ELF support should be included.])
2088   # -ldl is provided by bfd/Makfile.am (LIBDL) <PLUGINS>.
2089   if test "$plugins" = "yes"; then
2090     AC_SEARCH_LIBS(dlopen, dl)
2091   fi
2092 fi
2093
2094 # Add macho support to GDB, but only if BFD includes it.
2095 GDB_AC_CHECK_BFD([for Mach-O support in BFD], gdb_cv_var_macho,
2096                  [bfd_mach_o_lookup_command (NULL, 0, NULL)], mach-o.h)
2097 if test $gdb_cv_var_macho = yes; then
2098   CONFIG_OBS="$CONFIG_OBS machoread.o"
2099 fi
2100
2101 # Add SOM support to GDB, but only if BFD includes it.
2102 GDB_AC_CHECK_BFD([for SOM support in BFD], gdb_cv_var_som,
2103                  [bfd_som_attach_aux_hdr (NULL, 0, NULL)], som.h)
2104 if test $gdb_cv_var_som = yes; then
2105   CONFIG_OBS="$CONFIG_OBS somread.o"
2106 fi
2107
2108 # Add any host-specific objects to GDB.
2109 CONFIG_OBS="${CONFIG_OBS} ${gdb_host_obs}"
2110
2111 # If building on ELF, look for lzma support for embedded compressed debug info.
2112 if test $gdb_cv_var_elf = yes; then
2113   AC_ARG_WITH(lzma,
2114     AS_HELP_STRING([--with-lzma], [support lzma compression (auto/yes/no)]),
2115     [], [with_lzma=auto])
2116   AC_MSG_CHECKING([whether to use lzma])
2117   AC_MSG_RESULT([$with_lzma])
2118
2119   if test "${with_lzma}" != no; then
2120     AC_LIB_HAVE_LINKFLAGS([lzma], [], [#include "lzma.h"],
2121                           [lzma_index_iter iter;
2122                            lzma_index_iter_init (&iter, 0);
2123                            lzma_mf_is_supported (LZMA_MF_HC3);])
2124     if test "$HAVE_LIBLZMA" != yes; then
2125       if test "$with_lzma" = yes; then
2126         AC_MSG_ERROR([missing liblzma for --with-lzma])
2127       fi
2128     fi
2129   fi
2130 fi
2131
2132 LIBGUI="../libgui/src/libgui.a"
2133 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
2134 AC_SUBST(LIBGUI)
2135 AC_SUBST(GUI_CFLAGS_X)
2136
2137 WIN32LDAPP=
2138 AC_SUBST(WIN32LIBS)
2139 AC_SUBST(WIN32LDAPP)
2140
2141 case "${host}" in
2142 *-*-cygwin* | *-*-mingw* )
2143     configdir="win"
2144     ;;
2145 *)
2146     configdir="unix"
2147     ;;
2148 esac
2149
2150 GDBTKLIBS=
2151 if test "${enable_gdbtk}" = "yes"; then
2152
2153     # Gdbtk must have an absolute path to srcdir in order to run
2154     # properly when not installed.
2155     here=`pwd`
2156     cd ${srcdir}
2157     GDBTK_SRC_DIR=`pwd`
2158     cd $here
2159
2160     SC_PATH_TCLCONFIG
2161
2162     # If $no_tk is nonempty, then we can't do Tk, and there is no
2163     # point to doing Tcl.
2164     SC_PATH_TKCONFIG
2165
2166     if test -z "${no_tcl}" -a -z "${no_tk}"; then
2167         SC_LOAD_TCLCONFIG
2168
2169         # Check for in-tree tcl
2170         here=`pwd`
2171         cd ${srcdir}/..
2172         topdir=`pwd`
2173         cd ${here}
2174
2175         intree="no"
2176         if test "${TCL_SRC_DIR}" = "${topdir}/tcl"; then
2177           intree="yes"
2178         fi
2179
2180         # Find Tcl private headers
2181         if test x"${intree}" = xno; then
2182           CY_AC_TCL_PRIVATE_HEADERS
2183           TCL_INCLUDE="${TCL_INCLUDE_SPEC} ${TCL_PRIVATE_INCLUDE}"
2184           TCL_LIBRARY="${TCL_LIB_SPEC}"
2185           TCL_DEPS=""
2186         else
2187           # If building tcl in the same src tree, private headers
2188           # are not needed, but we need to be sure to use the right
2189           # headers library
2190           TCL_INCLUDE="-I${TCL_SRC_DIR}/generic"
2191           TCL_LIBRARY="${TCL_BUILD_LIB_SPEC}"
2192           TCL_DEPS="../tcl/${configdir}${TCL_LIB_FILE}"
2193         fi
2194         AC_SUBST(TCL_INCLUDE)
2195         AC_SUBST(TCL_LIBRARY)
2196         AC_SUBST(TCL_DEPS)
2197
2198         SC_LOAD_TKCONFIG
2199
2200         # Check for in-tree Tk
2201         intree="no"
2202         if test "${TK_SRC_DIR}" = "${topdir}/tk"; then
2203           intree="yes"
2204         fi
2205
2206         # Find Tk private headers
2207         if test x"${intree}" = xno; then
2208           CY_AC_TK_PRIVATE_HEADERS
2209           TK_INCLUDE="${TK_INCLUDE_SPEC} ${TK_PRIVATE_INCLUDE}"
2210           TK_LIBRARY=${TK_LIB_SPEC}
2211           TK_DEPS=""
2212         else
2213           TK_INCLUDE="-I${TK_SRC_DIR}/generic"
2214           TK_LIBRARY="${TK_BUILD_LIB_SPEC}"
2215           TK_DEPS="../tk/${configdir}/${TK_LIB_FILE}"
2216         fi
2217         AC_SUBST(TK_INCLUDE)
2218         AC_SUBST(TK_LIBRARY)
2219         AC_SUBST(TK_DEPS)
2220         AC_SUBST(TK_XINCLUDES)
2221
2222         ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
2223
2224         # Include some libraries that Tcl and Tk want.
2225         TCL_LIBS='$(LIBGUI) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
2226         # Yes, the ordering seems wrong here.  But it isn't.
2227         # TK_LIBS is the list of libraries that need to be linked
2228         # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
2229         # were in LIBS then any link tests after this point would
2230         # try to include things like `$(LIBGUI)', which wouldn't work.
2231         GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
2232
2233         CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
2234         CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
2235         CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
2236         CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
2237         CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
2238         CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
2239         CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
2240
2241         if test x$gdb_cv_os_cygwin = xyes; then
2242           WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
2243           WIN32LDAPP="-Wl,--subsystem,console"
2244           CONFIG_OBS="${CONFIG_OBS} gdbres.o"
2245         fi
2246
2247         AC_CONFIG_SUBDIRS(gdbtk)
2248     fi
2249 fi
2250
2251 AC_SUBST(X_CFLAGS)
2252 AC_SUBST(X_LDFLAGS)
2253 AC_SUBST(X_LIBS)
2254 AC_SUBST(GDBTKLIBS)
2255 AC_SUBST(GDBTK_CFLAGS)
2256 AC_SUBST(GDBTK_SRC_DIR)
2257
2258 AC_PATH_X
2259
2260 # Unlike the sim directory, whether a simulator is linked is controlled by
2261 # presence of a gdb_sim definition in the target configure.tgt entry.
2262 # This code just checks for a few cases where we'd like to ignore those
2263 # definitions, even when they're present in the '.mt' file.  These cases
2264 # are when --disable-sim is specified, or if the simulator directory is
2265 # not part of the source tree.
2266 #
2267 AC_ARG_ENABLE(sim,
2268 AS_HELP_STRING([--enable-sim], [link gdb with simulator]),
2269 [echo "enable_sim = $enable_sim";
2270  echo "enableval = ${enableval}";
2271  case "${enableval}" in
2272   yes) ignore_sim=false ;;
2273   no)  ignore_sim=true ;;
2274   *)   ignore_sim=false ;;
2275  esac],
2276 [ignore_sim=false])
2277
2278 if test ! -d "${srcdir}/../sim"; then
2279   ignore_sim=true
2280 fi
2281
2282 SIM=
2283 SIM_OBS=
2284 if test "${ignore_sim}" = "false"; then
2285   if test x"${gdb_sim}" != x ; then
2286     SIM="${gdb_sim}"
2287     SIM_OBS="remote-sim.o"
2288     AC_DEFINE(WITH_SIM, 1, [Define if the simulator is being linked in.])
2289   fi
2290 fi
2291 AC_SUBST(SIM)
2292 AC_SUBST(SIM_OBS)
2293
2294 AC_SUBST(ENABLE_CFLAGS)
2295 AC_SUBST(PROFILE_CFLAGS)
2296
2297 AC_SUBST(CONFIG_OBS)
2298 AC_SUBST(CONFIG_DEPS)
2299 AC_SUBST(CONFIG_SRCS)
2300 AC_SUBST(CONFIG_ALL)
2301 AC_SUBST(CONFIG_CLEAN)
2302 AC_SUBST(CONFIG_INSTALL)
2303 AC_SUBST(CONFIG_UNINSTALL)
2304
2305 # List of host floatformats.
2306 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
2307 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
2308 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
2309
2310 # target_subdir is used by the testsuite to find the target libraries.
2311 target_subdir=
2312 if test "${host}" != "${target}"; then
2313     target_subdir="${target_alias}/"
2314 fi
2315 AC_SUBST(target_subdir)
2316
2317 frags=
2318 if test "${gdb_native}" = "yes"; then
2319   host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
2320   if test ! -f ${host_makefile_frag}; then
2321     AC_MSG_ERROR("*** Gdb does not support native target ${host}")
2322   fi
2323   frags="$frags $host_makefile_frag"
2324 else
2325   host_makefile_frag=/dev/null
2326 fi
2327
2328 AC_SUBST_FILE(host_makefile_frag)
2329 AC_SUBST(frags)
2330
2331 changequote(,)dnl
2332 if test "${gdb_native}" = "yes"; then
2333 # We pick this up from the host configuration file (.mh) because we
2334 # do not have a native configuration Makefile fragment.
2335 nativefile=`sed -n '
2336 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
2337 ' ${host_makefile_frag}`
2338 fi
2339 changequote([,])
2340
2341 if test x"${gdb_osabi}" != x ; then
2342     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
2343                        [Define to the default OS ABI for this configuration.])
2344 fi
2345
2346 # Enable multi-ice-gdb-server.
2347 AC_ARG_ENABLE(multi-ice,
2348 AS_HELP_STRING([--enable-multi-ice], [build the multi-ice-gdb-server]),
2349   [case $enableval in
2350     yes | no)
2351       ;;
2352     *) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;;
2353   esac])
2354 if test "x$enable_multi_ice" = xyes; then
2355    AC_CONFIG_SUBDIRS(multi-ice)
2356 fi
2357
2358 AC_ARG_ENABLE(gdbserver,
2359 AS_HELP_STRING([--enable-gdbserver],
2360                [automatically build gdbserver (yes/no/auto, default is auto)]),
2361 [case "${enableval}" in
2362   yes| no|auto) ;;
2363   *) AC_MSG_ERROR(bad value ${enableval} for --enable-gdbserver option) ;;
2364 esac],[enable_gdbserver=auto])
2365
2366 # We only build gdbserver automatically in a native configuration, and
2367 # only if the user did not explicitly disable its build.
2368 if test "$gdb_native" = "yes" -a "$enable_gdbserver" != "no"; then
2369   AC_MSG_CHECKING(whether gdbserver is supported on this host)
2370   if test "x$build_gdbserver" = xyes; then
2371     AC_MSG_RESULT(yes)
2372     AC_CONFIG_SUBDIRS(gdbserver)
2373     gdbserver_build_enabled=yes
2374   else
2375     AC_MSG_RESULT(no)
2376   fi
2377 fi
2378
2379 # If the user explicitly request the gdbserver to be built, verify that
2380 # we were in fact able to enable it.
2381 if test "$enable_gdbserver" = "yes" -a "$gdbserver_build_enabled" != "yes"; then
2382   AC_MSG_ERROR(Automatic gdbserver build is not supported for this configuration)
2383 fi
2384
2385 # Check for babeltrace and babeltrace-ctf
2386 AC_ARG_WITH(babeltrace,
2387   AC_HELP_STRING([--with-babeltrace], [include babeltrace support (auto/yes/no)]),
2388   [], [with_babeltrace=auto])
2389 AC_MSG_CHECKING([whether to use babeltrace])
2390 AC_MSG_RESULT([$with_babeltrace])
2391
2392 if test "x$with_babeltrace" = "xno"; then
2393   AC_MSG_WARN([babletrace support disabled; GDB is unable to read CTF data.])
2394 else
2395   # Append -Werror to CFLAGS so that configure can catch the warning
2396   # "assignment from incompatible pointer type", which is related to
2397   # the babeltrace change from 1.0.3 to 1.1.0.  Babeltrace 1.1.0 works
2398   # in GDB, while babeltrace 1.0.3 is broken.
2399   # AC_LIB_HAVE_LINKFLAGS may modify CPPFLAGS in it, so it should be
2400   # safe to save and restore CFLAGS here.
2401   saved_CFLAGS=$CFLAGS
2402   CFLAGS="$CFLAGS -Werror"
2403   AC_LIB_HAVE_LINKFLAGS([babeltrace], [babeltrace-ctf],
2404                         [#include <babeltrace/babeltrace.h>
2405                          #include <babeltrace/ctf/events.h>
2406                          #include <babeltrace/ctf/iterator.h>],
2407                         [struct bt_iter_pos *pos = bt_iter_get_pos (bt_ctf_get_iter (NULL));
2408                         struct bt_ctf_event *event = NULL;
2409                         const struct bt_definition *scope;
2410
2411                         scope = bt_ctf_get_top_level_scope (event,
2412                                                            BT_STREAM_EVENT_HEADER);
2413                         bt_ctf_get_uint64 (bt_ctf_get_field (event, scope, "id"));
2414                         ])
2415   CFLAGS=$saved_CFLAGS
2416
2417   if test "$HAVE_LIBBABELTRACE" != yes; then
2418      if test "$with_babeltrace" = yes; then
2419        AC_MSG_ERROR([babeltrace is missing or unusable])
2420      else
2421        AC_MSG_WARN([babeltrace is missing or unusable; GDB is unable to read CTF data.])
2422      fi
2423   fi
2424 fi
2425
2426 # If nativefile (NAT_FILE) is not set in config/*/*.m[ht] files, we link
2427 # to an empty version.
2428
2429 files=
2430 links=
2431
2432 rm -f nm.h
2433 if test "${nativefile}" != ""; then
2434     case "${nativefile}" in
2435       nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
2436       * ) GDB_NM_FILE="${nativefile}"
2437     esac
2438     files="${files} ${GDB_NM_FILE}"
2439     links="${links} nm.h"
2440     AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}", [nativefile])
2441 fi
2442 AC_SUBST(GDB_NM_FILE)
2443
2444 AC_LINK_FILES($files, $links)
2445
2446 dnl Check for exe extension set on certain hosts (e.g. Win32)
2447 AC_EXEEXT
2448
2449 dnl  Detect the character set used by this host.
2450 dnl  At the moment, we just assume it's UTF-8.
2451 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "UTF-8",
2452           [Define to be a string naming the default host character set.])
2453
2454 # Undo the $ec_script escaping suitable for Makefile.
2455 transform=`echo "$program_transform_name" | sed -e 's/[\\$][\\$]/\\$/g'`
2456 GDB_TRANSFORM_NAME=`echo gdb | sed -e "$transform"`
2457 if test "x$GDB_TRANSFORM_NAME" = x; then
2458   GDB_TRANSFORM_NAME=gdb
2459 fi
2460 AC_SUBST(GDB_TRANSFORM_NAME)
2461 GCORE_TRANSFORM_NAME=`echo gcore | sed -e "$transform"`
2462 if test "x$GCORE_TRANSFORM_NAME" = x; then
2463   GCORE_TRANSFORM_NAME=gcore
2464 fi
2465 AC_SUBST(GCORE_TRANSFORM_NAME)
2466 AC_CONFIG_FILES([gcore], [chmod +x gcore])
2467
2468 AC_OUTPUT(Makefile gdb-gdb.gdb doc/Makefile data-directory/Makefile,
2469 [
2470 case x$CONFIG_HEADERS in
2471 xconfig.h:config.in)
2472 echo > stamp-h ;;
2473 esac
2474 ])
2475
2476 exit 0