gdb/configure.ac

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004,
   3 dnl 2005, 2006
   4 dnl Free Software Foundation, Inc.
   5 dnl
   6 dnl This file is part of GDB.
   7 dnl
   8 dnl This program is free software; you can redistribute it and/or modify
   9 dnl it under the terms of the GNU General Public License as published by
  10 dnl the Free Software Foundation; either version 3 of the License, or
  11 dnl (at your option) any later version.
  12 dnl
  13 dnl This program is distributed in the hope that it will be useful,
  14 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 dnl GNU General Public License for more details.
  17 dnl
  18 dnl You should have received a copy of the GNU General Public License
  19 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 dnl Process this file with autoconf to produce a configure script.
  22
  23 AC_PREREQ(2.59)dnl
  24 AC_INIT(main.c)
  25 AC_CONFIG_HEADER(config.h:config.in)
  26 AM_MAINTAINER_MODE
  27
  28 AC_PROG_CC
  29 AC_GNU_SOURCE
  30 AC_AIX
  31 AC_ISC_POSIX
  32 AM_PROG_CC_STDC
  33
  34 AC_CONFIG_AUX_DIR(`cd $srcdir;pwd`/..)
  35 AC_CANONICAL_SYSTEM
  36
  37 dnl List of object files and targets accumulated by configure.
  38
  39 CONFIG_OBS=
  40 CONFIG_DEPS=
  41 CONFIG_SRCS=
  42 ENABLE_CFLAGS=
  43
  44 CONFIG_ALL=
  45 CONFIG_CLEAN=
  46 CONFIG_INSTALL=
  47 CONFIG_UNINSTALL=
  48
  49 dnl Set up for gettext.
  50 ZW_GNU_GETTEXT_SISTER_DIR
  51
  52 localedir='${datadir}/locale'
  53 AC_SUBST(localedir)
  54
  55 if test x"$USE_NLS" = xyes; then
  56    CONFIG_ALL="$CONFIG_ALL all-po"
  57    CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
  58    CONFIG_INSTALL="$CONFIG_INSTALL install-po"
  59    CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
  60 fi
  61
  62 PACKAGE=gdb
  63 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
  64 AC_SUBST(PACKAGE)
  65
  66 debugdir=${libdir}/debug
  67
  68 AC_ARG_WITH(separate-debug-dir,
  69 [  --with-separate-debug-dir=path   Look for global separate debug info in this path [LIBDIR/debug]],
  70 [debugdir="${withval}"])
  71
  72 AC_DEFINE_DIR(DEBUGDIR, debugdir,
  73               [Global directory for separate debug files. ])
  74 #AC_DEFINE_UNQUOTED(DEBUGDIR, "$debugdir"),
  75
  76 if test "x$exec_prefix" = xNONE || test "x$exec_prefix" = 'x${prefix}'; then
  77   if test "x$prefix" = xNONE; then
  78     test_prefix=/usr/local
  79   else
  80     test_prefix=$prefix
  81   fi
  82 else
  83   test_prefix=$exec_prefix
  84 fi
  85 case ${debugdir} in
  86 "${test_prefix}"|"${test_prefix}/"*|\
  87 '${exec_prefix}'|'${exec_prefix}/'*)
  88   AC_DEFINE(DEBUGDIR_RELOCATABLE, 1, [Define if the debug directory should be relocated when GDB is moved.])
  89   ;;
  90 esac
  91
  92 AC_CONFIG_SUBDIRS(doc testsuite)
  93
  94 # Provide defaults for some variables set by the per-host and per-target
  95 # configuration.
  96 gdb_host_obs=posix-hdep.o
  97
  98 if test "${target}" = "${host}"; then
  99   gdb_native=yes
 100 else
 101   gdb_native=no
 102 fi
 103
 104 . $srcdir/configure.host
 105
 106 . $srcdir/configure.tgt
 107
 108 # Fetch the default architecture and default target vector from BFD.
 109 targ=$target; . $srcdir/../bfd/config.bfd
 110
 111 # We only want the first architecture, so strip off the others if
 112 # there is more than one.
 113 targ_archs=`echo $targ_archs | sed 's/ .*//'`
 114
 115 if test "x$targ_archs" != x; then
 116   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
 117     [Define to BFD's default architecture. ])
 118 fi
 119 if test "x$targ_defvec" != x; then
 120   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
 121     [Define to BFD's default target vector. ])
 122 fi
 123
 124 AC_ARG_PROGRAM
 125
 126 # The CLI cannot be disabled yet, but may be in the future.
 127
 128 # Enable CLI.
 129 AC_ARG_ENABLE(gdbcli,
 130 [  --disable-gdbcli        disable command-line interface (CLI)],
 131   [case $enableval in
 132     yes)
 133       ;;
 134     no)
 135       AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;;
 136     *)
 137       AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;;
 138   esac],
 139   [enable_gdbcli=yes])
 140 if test x"$enable_gdbcli" = xyes; then
 141   if test -d $srcdir/cli; then
 142     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)"
 143     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)"
 144     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)"
 145     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)"
 146   fi
 147 fi
 148
 149 # Enable MI.
 150 AC_ARG_ENABLE(gdbmi,
 151 [  --disable-gdbmi         disable machine-interface (MI)],
 152   [case $enableval in
 153     yes | no)
 154       ;;
 155     *)
 156       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 157   esac],
 158   [enable_gdbmi=yes])
 159 if test x"$enable_gdbmi" = xyes; then
 160   if test -d $srcdir/mi; then
 161     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 162     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 163     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 164     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 165   fi
 166 fi
 167
 168 # Enable TUI.
 169 AC_ARG_ENABLE(tui,
 170 [  --enable-tui            enable full-screen terminal user interface (TUI)],
 171   [case $enableval in
 172     yes | no)
 173       ;;
 174     *)
 175       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 176   esac],enable_tui=yes)
 177
 178 # Enable gdbtk.
 179 AC_ARG_ENABLE(gdbtk,
 180 [  --enable-gdbtk          enable gdbtk graphical user interface (GUI)],
 181   [case $enableval in
 182     yes | no)
 183       ;;
 184     *)
 185       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 186   esac],
 187   [if test -d $srcdir/gdbtk -a -d $srcdir/../itcl; then
 188     enable_gdbtk=yes
 189   else
 190     enable_gdbtk=no
 191   fi])
 192 # We unconditionally disable gdbtk tests on selected platforms.
 193 case $host_os in
 194   go32* | windows*)
 195     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 196     enable_gdbtk=no ;;
 197 esac
 198
 199 # Libunwind support.
 200 AC_ARG_WITH(libunwind,
 201 [  --with-libunwind            Use libunwind frame unwinding support],
 202 [case "${withval}" in
 203   yes)  enable_libunwind=yes ;;
 204   no)   enable_libunwind=no ;;
 205   *)    AC_MSG_ERROR(bad value ${withval} for GDB with-libunwind option) ;;
 206 esac],[
 207   AC_CHECK_HEADERS(libunwind.h)
 208   AC_CHECK_HEADERS(libunwind-ia64.h)
 209   if test x"$ac_cv_header_libunwind_h" = xyes -a x"$ac_cv_header_libunwind_ia64_h" = xyes; then
 210     enable_libunwind=yes;
 211   fi
 212 ])
 213
 214 if test x"$enable_libunwind" = xyes; then
 215   AC_CHECK_HEADERS(libunwind.h)
 216   AC_CHECK_HEADERS(libunwind-ia64.h)
 217   AC_DEFINE(HAVE_LIBUNWIND, 1, [Define if libunwind library is being used.])
 218   CONFIG_OBS="$CONFIG_OBS libunwind-frame.o"
 219   CONFIG_DEPS="$CONFIG_DEPS libunwind-frame.o"
 220   CONFIG_SRCS="$CONFIG_SRCS libunwind-frame.c"
 221 fi
 222
 223 # Profiling support.
 224 AC_ARG_ENABLE(profiling,
 225 [  --enable-profiling      enable profiling of GDB],
 226   [case $enableval in
 227     yes | no)
 228       ;;
 229     *)
 230       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 231   esac],
 232  [enable_profiling=no])
 233
 234 AC_CHECK_FUNCS(monstartup _mcleanup)
 235 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 236 [AC_TRY_LINK(
 237 [#include <stdlib.h>
 238 extern char _etext;
 239 ],
 240 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 241 if test $ac_cv_var__etext = yes; then
 242   AC_DEFINE(HAVE__ETEXT, 1,
 243             [Define to 1 if your system has the _etext variable. ])
 244 fi
 245 AC_CACHE_CHECK([for etext], ac_cv_var_etext,
 246 [AC_TRY_LINK(
 247 [#include <stdlib.h>
 248 extern char etext;
 249 ],
 250 [free (&etext);], ac_cv_var_etext=yes, ac_cv_var_etext=no)])
 251 if test $ac_cv_var_etext = yes; then
 252   AC_DEFINE(HAVE_ETEXT, 1,
 253             [Define to 1 if your system has the etext variable. ])
 254 fi
 255 if test "$enable_profiling" = yes ; then
 256   if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
 257     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 258   fi
 259   PROFILE_CFLAGS=-pg
 260   OLD_CFLAGS="$CFLAGS"
 261   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 262
 263   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 264     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 265      ac_cv_cc_supports_pg=no)])
 266
 267   if test $ac_cv_cc_supports_pg = no; then
 268     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 269   fi
 270
 271   CFLAGS="$OLD_CFLAGS"
 272 fi
 273
 274 # --------------------- #
 275 # Checks for programs.  #
 276 # --------------------- #
 277
 278 AC_PROG_AWK
 279 AC_PROG_INSTALL
 280 AC_PROG_LN_S
 281 AC_PROG_RANLIB
 282 AC_PROG_YACC
 283
 284 AC_CHECK_TOOL(AR, ar)
 285 AC_CHECK_TOOL(DLLTOOL, dlltool)
 286 AC_CHECK_TOOL(WINDRES, windres)
 287
 288 # Needed for GNU/Hurd.
 289 AC_CHECK_TOOL(MIG, mig)
 290
 291 # ---------------------- #
 292 # Checks for libraries.  #
 293 # ---------------------- #
 294
 295 # We might need to link with -lm; most simulators need it.
 296 AC_CHECK_LIB(m, main)
 297
 298 # We need to link with -lw to get `wctype' on Solaris before Solaris
 299 # 2.6.  Solaris 2.6 and beyond have this function in libc, and have a
 300 # libw that some versions of the GNU linker cannot hanle (GNU ld 2.9.1
 301 # is known to have this problem).  Therefore we avoid libw if we can.
 302 AC_CHECK_FUNC(wctype, [],
 303   [AC_CHECK_LIB(w, wctype)])
 304
 305 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 306 AC_SEARCH_LIBS(gethostbyname, nsl)
 307
 308 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 309 AC_SEARCH_LIBS(socketpair, socket)
 310
 311 # For the TUI, we need enhanced curses functionality.
 312 #
 313 # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
 314 # curses library because the latter might not provide all the
 315 # functionality we need.  However, this leads to problems on systems
 316 # where the linker searches /usr/local/lib, but the compiler doesn't
 317 # search /usr/local/include, if ncurses is installed in /usr/local.  A
 318 # default installation of ncurses on alpha*-dec-osf* will lead to such
 319 # a situation.
 320 AC_SEARCH_LIBS(waddstr, [ncurses cursesX curses])
 321
 322 # On HP/UX we may need libxpdl for dlgetmodinfo (used by solib-pa64.c).
 323 AC_SEARCH_LIBS(dlgetmodinfo, [dl xpdl])
 324
 325 # Since GDB uses Readline, we need termcap functionality.  In many
 326 # cases this will be provided by the curses library, but some systems
 327 # have a seperate termcap library, or no curses library at all.
 328
 329 case $host_os in
 330   cygwin*)
 331     if test -d $srcdir/libtermcap; then
 332       LIBS="../libtermcap/libtermcap.a $LIBS"
 333       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 334     fi ;;
 335   go32* | *djgpp*)
 336     ac_cv_search_tgetent="none required"
 337     ;;
 338   *mingw32*)
 339     ac_cv_search_tgetent="none required"
 340     CONFIG_OBS="$CONFIG_OBS win32-termcap.o"
 341     ;;
 342 esac
 343
 344 # These are the libraries checked by Readline.
 345 AC_SEARCH_LIBS(tgetent, [termcap tinfo curses ncurses])
 346
 347 if test "$ac_cv_search_tgetent" = no; then
 348   AC_MSG_ERROR([no termcap library found])
 349 fi
 350
 351 AC_ARG_WITH([system-readline],
 352   [AS_HELP_STRING([--with-system-readline],
 353                   [use installed readline library])])
 354
 355 if test "$with_system_readline" = yes; then
 356   READLINE=-lreadline
 357   READLINE_DEPS=
 358   READLINE_CFLAGS=
 359 else
 360   READLINE='$(READLINE_DIR)/libreadline.a'
 361   READLINE_DEPS='$(READLINE)'
 362   READLINE_CFLAGS='-I$(READLINE_SRC)/..'
 363 fi
 364 AC_SUBST(READLINE)
 365 AC_SUBST(READLINE_DEPS)
 366 AC_SUBST(READLINE_CFLAGS)
 367
 368 AC_ARG_WITH(expat,
 369   AS_HELP_STRING([--with-expat], [include expat support (auto/yes/no)]),
 370   [], [with_expat=auto])
 371 AC_MSG_CHECKING([whether to use expat])
 372 AC_MSG_RESULT([$with_expat])
 373
 374 if test "${with_expat}" = no; then
 375   AC_MSG_WARN([expat support disabled; some features may be unavailable.])
 376   HAVE_LIBEXPAT=no
 377 else
 378   AC_LIB_HAVE_LINKFLAGS([expat], [], [#include "expat.h"],
 379                         [XML_Parser p = XML_ParserCreate (0);])
 380   if test "$HAVE_LIBEXPAT" != yes; then
 381     if test "$with_expat" = yes; then
 382       AC_MSG_ERROR([expat is missing or unusable])
 383     else
 384       AC_MSG_WARN([expat is missing or unusable; some features may be unavailable.])
 385     fi
 386   else
 387     save_LIBS=$LIBS
 388     LIBS="$LIBS $LIBEXPAT"
 389     AC_CHECK_FUNCS(XML_StopParser)
 390     LIBS=$save_LIBS
 391   fi
 392 fi
 393
 394 # ------------------------- #
 395 # Checks for header files.  #
 396 # ------------------------- #
 397
 398 AC_HEADER_DIRENT
 399 AC_HEADER_STAT
 400 AC_HEADER_STDC
 401 AC_CHECK_HEADERS(nlist.h)
 402 AC_CHECK_HEADERS(link.h, [], [],
 403 [#if HAVE_SYS_TYPES_H
 404 # include <sys/types.h>
 405 #endif
 406 #if HAVE_NLIST_H
 407 # include <nlist.h>
 408 #endif
 409 ])
 410 AC_CHECK_HEADERS(machine/reg.h)
 411 AC_CHECK_HEADERS(poll.h sys/poll.h)
 412 AC_CHECK_HEADERS(proc_service.h thread_db.h gnu/libc-version.h)
 413 AC_CHECK_HEADERS(signal.h)
 414 AC_CHECK_HEADERS(stddef.h)
 415 AC_CHECK_HEADERS(stdlib.h)
 416 AC_CHECK_HEADERS(stdint.h)
 417 AC_CHECK_HEADERS(string.h memory.h strings.h)
 418 AC_CHECK_HEADERS(sys/fault.h)
 419 AC_CHECK_HEADERS(sys/file.h)
 420 AC_CHECK_HEADERS(sys/filio.h)
 421 AC_CHECK_HEADERS(sys/ioctl.h)
 422 AC_CHECK_HEADERS(sys/param.h)
 423 AC_CHECK_HEADERS(sys/resource.h)
 424 AC_CHECK_HEADERS(sys/proc.h, [], [],
 425 [#if HAVE_SYS_PARAM_H
 426 # include <sys/param.h>
 427 #endif
 428 ])
 429 AC_CHECK_HEADERS(sys/procfs.h)
 430 AC_CHECK_HEADERS(sys/ptrace.h ptrace.h)
 431 AC_CHECK_HEADERS(sys/reg.h sys/debugreg.h)
 432 AC_CHECK_HEADERS(sys/select.h)
 433 AC_CHECK_HEADERS(sys/syscall.h)
 434 AC_CHECK_HEADERS(sys/types.h)
 435 AC_CHECK_HEADERS(sys/user.h, [], [],
 436 [#if HAVE_SYS_PARAM_H
 437 # include <sys/param.h>
 438 #endif
 439 ])
 440 AC_CHECK_HEADERS(sys/wait.h wait.h)
 441 AC_CHECK_HEADERS(termios.h termio.h sgtty.h)
 442 AC_CHECK_HEADERS(unistd.h)
 443
 444 # On Solaris 2.[789], we need to define _MSE_INT_H to avoid a clash
 445 # between <widec.h> and <wchar.h> that would cause AC_CHECK_HEADERS to
 446 # think that we don't have <curses.h> if we're using GCC.
 447 case $host_os in
 448   solaris2.[[789]])
 449     if test "$GCC" = yes; then
 450       AC_DEFINE(_MSE_INT_H, 1,
 451         [Define to 1 to avoid a clash between <widec.h> and <wchar.h> on
 452    Solaris 2.[789] when using GCC. ])
 453     fi ;;
 454 esac
 455 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncurses/ncurses.h)
 456 AC_CHECK_HEADERS(ncurses/term.h)
 457 AC_CHECK_HEADERS(term.h, [], [],
 458 [#if HAVE_CURSES_H
 459 # include <curses.h>
 460 #endif
 461 ])
 462
 463 # Check for HP/UX 64-bit shared library support
 464 AC_CHECK_HEADERS(elf_hp.h)
 465
 466 # FIXME: kettenis/20030102: In most cases we include these
 467 # unconditionally, so what's the point in checking these?
 468 AC_CHECK_HEADERS(ctype.h time.h)
 469
 470 # Create a header we can use portably to get the standard integer types.
 471 GCC_HEADER_STDINT(gdb_stdint.h)
 472
 473 # ------------------------- #
 474 # Checks for declarations.  #
 475 # ------------------------- #
 476
 477 AC_CHECK_DECLS([free, malloc, realloc])
 478 AC_CHECK_DECLS([strerror, strstr])
 479 AC_CHECK_DECLS([getopt, snprintf, vsnprintf])
 480
 481 # ----------------------- #
 482 # Checks for structures.  #
 483 # ----------------------- #
 484
 485 AC_CHECK_MEMBERS([struct stat.st_blocks])
 486 AC_CHECK_MEMBERS([struct stat.st_blksize])
 487
 488 # ------------------ #
 489 # Checks for types.  #
 490 # ------------------ #
 491
 492 AC_TYPE_SIGNAL
 493 AC_CHECK_TYPES(socklen_t, [], [],
 494 [#include <sys/types.h>
 495 #include <sys/socket.h>
 496 ])
 497 AC_CHECK_TYPES(uintptr_t, [], [], [#include <stdint.h>])
 498
 499 # ------------------------------------- #
 500 # Checks for compiler characteristics.  #
 501 # ------------------------------------- #
 502
 503 AC_C_CONST
 504 AC_C_INLINE
 505 AC_C_BIGENDIAN
 506
 507 # ------------------------------ #
 508 # Checks for library functions.  #
 509 # ------------------------------ #
 510
 511 AC_FUNC_ALLOCA
 512 AC_FUNC_MMAP
 513 AC_FUNC_VFORK
 514 AC_CHECK_FUNCS(canonicalize_file_name realpath)
 515 AC_CHECK_FUNCS(getrusage)
 516 AC_CHECK_FUNCS(getuid getgid)
 517 AC_CHECK_FUNCS(poll)
 518 AC_CHECK_FUNCS(pread64)
 519 AC_CHECK_FUNCS(sbrk)
 520 AC_CHECK_FUNCS(setpgid setpgrp)
 521 AC_CHECK_FUNCS(sigaction sigprocmask sigsetmask)
 522 AC_CHECK_FUNCS(socketpair)
 523 AC_CHECK_FUNCS(syscall)
 524 AC_CHECK_FUNCS(ttrace)
 525 AC_CHECK_FUNCS(wborder)
 526
 527 # Check the return and argument types of ptrace.  No canned test for
 528 # this, so roll our own.
 529 gdb_ptrace_headers='
 530 #if HAVE_SYS_TYPES_H
 531 # include <sys/types.h>
 532 #endif
 533 #if HAVE_SYS_PTRACE_H
 534 # include <sys/ptrace.h>
 535 #endif
 536 #if HAVE_UNISTD_H
 537 # include <unistd.h>
 538 #endif
 539 '
 540 # There is no point in checking if we don't have a prototype.
 541 AC_CHECK_DECLS(ptrace, [], [
 542   : ${gdb_cv_func_ptrace_ret='int'}
 543   : ${gdb_cv_func_ptrace_args='int,int,long,long'}
 544 ], $gdb_ptrace_headers)
 545 # Check return type.
 546 AC_CACHE_CHECK([return type of ptrace], gdb_cv_func_ptrace_ret,
 547   AC_TRY_COMPILE($gdb_ptrace_headers,
 548     [extern int ptrace ();],
 549     gdb_cv_func_ptrace_ret='int',
 550     gdb_cv_func_ptrace_ret='long'))
 551 AC_DEFINE_UNQUOTED(PTRACE_TYPE_RET, $gdb_cv_func_ptrace_ret,
 552   [Define as the return type of ptrace.])
 553 # Check argument types.
 554 AC_CACHE_CHECK([types of arguments for ptrace], gdb_cv_func_ptrace_args, [
 555 for gdb_arg1 in 'int' 'long'; do
 556  for gdb_arg2 in 'pid_t' 'int' 'long'; do
 557   for gdb_arg3 in 'int *' 'caddr_t' 'int' 'long'; do
 558    for gdb_arg4 in 'int' 'long'; do
 559      AC_TRY_COMPILE($gdb_ptrace_headers, [
 560 extern $gdb_cv_func_ptrace_ret
 561   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4);
 562 ], [gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4";
 563     break 4;])
 564     for gdb_arg5 in 'int *' 'int' 'long'; do
 565      AC_TRY_COMPILE($gdb_ptrace_headers, [
 566 extern $gdb_cv_func_ptrace_ret
 567   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4, $gdb_arg5);
 568 ], [
 569 gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4,$gdb_arg5";
 570     break 5;])
 571     done
 572    done
 573   done
 574  done
 575 done
 576 # Provide a safe default value.
 577 : ${gdb_cv_func_ptrace_args='int,int,long,long'}
 578 ])
 579 ac_save_IFS=$IFS; IFS=','
 580 set dummy `echo "$gdb_cv_func_ptrace_args" | sed 's/\*/\*/g'`
 581 IFS=$ac_save_IFS
 582 shift
 583 AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG3, $[3],
 584   [Define to the type of arg 3 for ptrace.])
 585 if test -n "$[5]"; then
 586   AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG5, $[5],
 587     [Define to the type of arg 5 for ptrace.])
 588 fi
 589
 590 dnl AC_FUNC_SETPGRP does not work when cross compiling
 591 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
 592 if test "$cross_compiling" = no; then
 593   AC_FUNC_SETPGRP
 594 else
 595   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
 596     [AC_TRY_COMPILE([
 597 #include <unistd.h>
 598 ], [
 599   if (setpgrp(1,1) == -1)
 600     exit (0);
 601   else
 602     exit (1);
 603 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
 604 if test $ac_cv_func_setpgrp_void = yes; then
 605   AC_DEFINE(SETPGRP_VOID, 1)
 606 fi
 607 fi
 608
 609 # Check if sigsetjmp is available.  Using AC_CHECK_FUNCS won't do
 610 # since sigsetjmp might only be defined as a macro.
 611 AC_CACHE_CHECK([for sigsetjmp], gdb_cv_func_sigsetjmp,
 612 [AC_TRY_COMPILE([
 613 #include <setjmp.h>
 614 ], [sigjmp_buf env; while (! sigsetjmp (env, 1)) siglongjmp (env, 1);],
 615 gdb_cv_func_sigsetjmp=yes, gdb_cv_func_sigsetjmp=no)])
 616 if test $gdb_cv_func_sigsetjmp = yes; then
 617   AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available. ])
 618 fi
 619
 620 # Assume we'll default to using the included libiberty regex.
 621 gdb_use_included_regex=yes
 622
 623 # However, if the system regex is GNU regex, then default to *not*
 624 # using the included regex.
 625 AC_CACHE_CHECK(
 626   [for GNU regex],
 627   [gdb_cv_have_gnu_regex],
 628   [AC_TRY_COMPILE(
 629     [#include <gnu-versions.h>],
 630     [#define REGEX_INTERFACE_VERSION 1
 631 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
 632 # error "Version mismatch"
 633 #endif],
 634     gdb_cv_have_gnu_regex=yes,
 635     gdb_cv_have_gnu_regex=no)])
 636 if test $gdb_cv_have_gnu_regex = yes; then
 637   gdb_use_included_regex=no
 638 fi
 639
 640 AC_ARG_WITH(included-regex,
 641   [  --without-included-regex don't use included regex; this is the default
 642                           on systems with version 2 of the GNU C library
 643                           (use with caution on other system)],
 644   gdb_with_regex=$withval,
 645   gdb_with_regex=$gdb_use_included_regex)
 646 if test "$gdb_with_regex" = yes; then
 647   AC_DEFINE(USE_INCLUDED_REGEX, 1,
 648     [Define to 1 if the regex included in libiberty should be used.])
 649 fi
 650
 651 # Check if <sys/proc.h> defines `struct thread' with a td_pcb member.
 652 AC_CHECK_MEMBERS([struct thread.td_pcb], [], [],
 653 [#include <sys/param.h>
 654 #include <sys/proc.h>
 655 ])
 656
 657 # See if <sys/lwp.h> defines `struct lwp`.
 658 AC_CACHE_CHECK([for struct lwp], gdb_cv_struct_lwp,
 659 [AC_TRY_COMPILE([#include <sys/param.h>
 660 #include <sys/lwp.h>], [struct lwp l;],
 661 gdb_cv_struct_lwp=yes, gdb_cv_struct_lwp=no)])
 662 if test $gdb_cv_struct_lwp = yes; then
 663   AC_DEFINE(HAVE_STRUCT_LWP, 1,
 664             [Define to 1 if your system has struct lwp.])
 665 fi
 666
 667 # See if <machine/reg.h> degines `struct reg'.
 668 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
 669 [AC_TRY_COMPILE([#include <sys/types.h>
 670 #include <machine/reg.h>], [struct reg r;],
 671 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
 672 if test $gdb_cv_struct_reg = yes; then
 673   AC_DEFINE(HAVE_STRUCT_REG, 1,
 674             [Define to 1 if your system has struct reg in <machine/reg.h>.])
 675 fi
 676
 677 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
 678 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
 679 AC_CHECK_MEMBERS([struct reg.r_fs, struct reg.r_gs], [], [],
 680                  [#include <machine/reg.h>])
 681
 682 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
 683 AC_MSG_CHECKING(for PTRACE_GETREGS)
 684 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
 685 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 686                 [PTRACE_GETREGS;],
 687                 [gdb_cv_have_ptrace_getregs=yes],
 688                 [gdb_cv_have_ptrace_getregs=no])])
 689 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
 690 if test $gdb_cv_have_ptrace_getregs = yes; then
 691   AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
 692   [Define if sys/ptrace.h defines the PTRACE_GETREGS request.])
 693 fi
 694
 695 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
 696 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
 697 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
 698 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 699                 [PTRACE_GETFPXREGS;],
 700                 [gdb_cv_have_ptrace_getfpxregs=yes],
 701                 [gdb_cv_have_ptrace_getfpxregs=no])])
 702 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
 703 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
 704   AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
 705   [Define if sys/ptrace.h defines the PTRACE_GETFPXREGS request.])
 706 fi
 707
 708 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
 709 AC_MSG_CHECKING(for PT_GETDBREGS)
 710 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
 711 [AC_TRY_COMPILE([#include <sys/types.h>
 712 #include <sys/ptrace.h>],
 713                 [PT_GETDBREGS;],
 714                 [gdb_cv_have_pt_getdbregs=yes],
 715                 [gdb_cv_have_pt_getdbregs=no])])
 716 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
 717 if test $gdb_cv_have_pt_getdbregs = yes; then
 718   AC_DEFINE(HAVE_PT_GETDBREGS, 1,
 719   [Define if sys/ptrace.h defines the PT_GETDBREGS request.])
 720 fi
 721
 722 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
 723 AC_MSG_CHECKING(for PT_GETXMMREGS)
 724 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
 725 [AC_TRY_COMPILE([#include <sys/types.h>
 726 #include <sys/ptrace.h>],
 727                 [PT_GETXMMREGS;],
 728                 [gdb_cv_have_pt_getxmmregs=yes],
 729                 [gdb_cv_have_pt_getxmmregs=no])])
 730 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
 731 if test $gdb_cv_have_pt_getxmmregs = yes; then
 732   AC_DEFINE(HAVE_PT_GETXMMREGS, 1,
 733   [Define if sys/ptrace.h defines the PT_GETXMMREGS request.])
 734 fi
 735
 736 # Detect which type of /proc is in use, such as for Unixware or Solaris.
 737
 738 if test "${target}" = "${host}"; then
 739   case "${host}" in
 740   *-*-unixware* | *-*-sysv4.2* | *-*-sysv5* | *-*-interix* )
 741       AC_DEFINE(NEW_PROC_API, 1,
 742       [Define if you want to use new multi-fd /proc interface
 743        (replaces HAVE_MULTIPLE_PROC_FDS as well as other macros).])
 744       ;;
 745   *-*-solaris2.[[6789]] | *-*-solaris2.1[[0-9]])
 746       AC_DEFINE(NEW_PROC_API, 1,
 747       [Define if you want to use new multi-fd /proc interface
 748        (replaces HAVE_MULTIPLE_PROC_FDS as well as other macros).])
 749       ;;
 750   mips-sgi-irix5*)
 751       # Work around <sys/proc.h> needing _KMEMUSER problem on IRIX 5.
 752       AC_DEFINE([_KMEMUSER], 1,
 753       [Define to 1 so <sys/proc.h> gets a definition of anon_hdl.  Works
 754        around a <sys/proc.h> problem on IRIX 5.])
 755       ;;
 756   esac
 757 fi
 758
 759 if test "$ac_cv_header_sys_procfs_h" = yes; then
 760   BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
 761   BFD_HAVE_SYS_PROCFS_TYPE(prrun_t)
 762   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
 763   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
 764   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
 765   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
 766   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
 767   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset32_t)
 768   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
 769   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
 770   BFD_HAVE_SYS_PROCFS_TYPE(prsysent_t)
 771   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigset_t)
 772   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigaction64_t)
 773   BFD_HAVE_SYS_PROCFS_TYPE(pr_siginfo64_t)
 774
 775
 776   dnl Check for broken prfpregset_t type
 777
 778   dnl For Linux/i386, glibc 2.1.3 was released with a bogus
 779   dnl prfpregset_t type (it's a typedef for the pointer to a struct
 780   dnl instead of the struct itself).  We detect this here, and work
 781   dnl around it in gdb_proc_service.h.
 782
 783   if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
 784     AC_MSG_CHECKING(whether prfpregset_t type is broken)
 785     AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
 786       [AC_TRY_RUN([#include <sys/procfs.h>
 787        int main ()
 788        {
 789          if (sizeof (prfpregset_t) == sizeof (void *))
 790            return 1;
 791          return 0;
 792        }],
 793        gdb_cv_prfpregset_t_broken=no,
 794        gdb_cv_prfpregset_t_broken=yes,
 795        gdb_cv_prfpregset_t_broken=yes)])
 796     AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
 797     if test $gdb_cv_prfpregset_t_broken = yes; then
 798       AC_DEFINE(PRFPREGSET_T_BROKEN, 1,
 799       [Define if the prfpregset_t type is broken.])
 800     fi
 801   fi
 802
 803   dnl Check for PIOCSET ioctl entry
 804
 805   AC_MSG_CHECKING(for PIOCSET ioctl entry in sys/procfs.h)
 806   AC_CACHE_VAL(gdb_cv_have_procfs_piocset,
 807   [AC_TRY_COMPILE([#include <unistd.h>
 808 #include <sys/types.h>
 809 #include <sys/procfs.h>
 810 ], [
 811     int dummy;;
 812     dummy = ioctl(0, PIOCSET, &dummy);
 813   ],
 814   gdb_cv_have_procfs_piocset=yes, gdb_cv_have_procfs_piocset=no)])
 815   AC_MSG_RESULT($gdb_cv_have_procfs_piocset)
 816   if test $gdb_cv_have_procfs_piocset = yes; then
 817     AC_DEFINE(HAVE_PROCFS_PIOCSET, 1,
 818     [Define if ioctl argument PIOCSET is available.])
 819   fi
 820 fi
 821
 822 dnl For native ports (host == target), check to see what kind of
 823 dnl legacy link.h support is needed.  (See solib-legacy.c.)
 824 if test ${host} = ${target} ; then
 825   dnl Check for struct link_map with l_ members which are indicative
 826   dnl of SVR4-like shared libraries
 827
 828   AC_MSG_CHECKING(for member l_addr in struct link_map)
 829   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_l_members,
 830     [AC_TRY_COMPILE([#include <link.h>],
 831                     [struct link_map lm; (void) lm.l_addr;],
 832                     gdb_cv_have_struct_link_map_with_l_members=yes,
 833                     gdb_cv_have_struct_link_map_with_l_members=no)])
 834   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_l_members)
 835   if test $gdb_cv_have_struct_link_map_with_l_members = yes; then
 836     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_L_MEMBERS,1,
 837     [Define if <link.h> exists and defines struct link_map which has
 838      members with an ``l_'' prefix.  (For Solaris, SVR4, and
 839      SVR4-like systems.)])
 840   fi
 841
 842   dnl Check for struct link_map with lm_ members which are indicative
 843   dnl of SunOS-like shared libraries
 844
 845   AC_MSG_CHECKING(for member lm_addr in struct link_map)
 846   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_lm_members,
 847     [AC_TRY_COMPILE([#include <sys/types.h>
 848 #include <link.h>],
 849                     [struct link_map lm; (void) lm.lm_addr;],
 850                     gdb_cv_have_struct_link_map_with_lm_members=yes,
 851                     gdb_cv_have_struct_link_map_with_lm_members=no)])
 852   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_lm_members)
 853   if test $gdb_cv_have_struct_link_map_with_lm_members = yes; then
 854     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_LM_MEMBERS, 1,
 855     [Define if <link.h> exists and defines struct link_map which has
 856      members with an ``lm_'' prefix.  (For SunOS.)])
 857   fi
 858
 859   dnl Check for struct so_map with som_ members which are found on
 860   dnl some *BSD systems.
 861
 862   AC_MSG_CHECKING(for member som_addr in struct so_map)
 863   AC_CACHE_VAL(gdb_cv_have_struct_so_map_with_som_members,
 864     [AC_TRY_COMPILE([#include <sys/types.h>
 865 #ifdef HAVE_NLIST_H
 866 #include <nlist.h>
 867 #endif
 868 #include <link.h>],
 869                     [struct so_map lm; (void) lm.som_addr;],
 870                     gdb_cv_have_struct_so_map_with_som_members=yes,
 871                     gdb_cv_have_struct_so_map_with_som_members=no)])
 872   AC_MSG_RESULT($gdb_cv_have_struct_so_map_with_som_members)
 873   if test $gdb_cv_have_struct_so_map_with_som_members = yes; then
 874     AC_DEFINE(HAVE_STRUCT_SO_MAP_WITH_SOM_MEMBERS, 1,
 875     [Define if <link.h> exists and defines a struct so_map which has
 876      members with an ``som_'' prefix.  (Found on older *BSD systems.)])
 877   fi
 878
 879   dnl Check for struct link_map32 type, which allows a 64-bit Solaris
 880   dnl debugger to debug a 32-bit Solaris app with 32-bit shared libraries.
 881
 882   AC_MSG_CHECKING(for struct link_map32 in sys/link.h)
 883   AC_CACHE_VAL(gdb_cv_have_struct_link_map32,
 884     [AC_TRY_COMPILE([#define _SYSCALL32
 885 #include <sys/link.h>], [struct link_map32 l;],
 886      gdb_cv_have_struct_link_map32=yes,
 887      gdb_cv_have_struct_link_map32=no)])
 888   AC_MSG_RESULT($gdb_cv_have_struct_link_map32)
 889   if test $gdb_cv_have_struct_link_map32 = yes; then
 890     AC_DEFINE(HAVE_STRUCT_LINK_MAP32, 1,
 891     [Define if <sys/link.h> has struct link_map32])
 892     AC_DEFINE(_SYSCALL32, 1,
 893     [Define if <sys/link.h> has link_map32 (solaris sparc-64 target)])
 894   fi
 895 fi
 896
 897 # Check if the compiler supports the `long long' type.
 898
 899 AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long,
 900                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 901 [[extern long long foo;]],
 902 [[switch (foo & 2) { case 0: return 1; }]])],
 903                                   gdb_cv_c_long_long=yes,
 904                                   gdb_cv_c_long_long=no)])
 905 if test $gdb_cv_c_long_long = yes; then
 906   AC_DEFINE(CC_HAS_LONG_LONG, 1,
 907             [Define to 1 if the compiler supports long long.])
 908 fi
 909
 910 # Check if the compiler and runtime support printing long longs.
 911
 912 AC_CACHE_CHECK([for long long support in printf],
 913                gdb_cv_printf_has_long_long,
 914                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
 915 [[char buf[32];
 916   long long l = 0;
 917   l = (l << 16) + 0x0123;
 918   l = (l << 16) + 0x4567;
 919   l = (l << 16) + 0x89ab;
 920   l = (l << 16) + 0xcdef;
 921   sprintf (buf, "0x%016llx", l);
 922   return (strcmp ("0x0123456789abcdef", buf));]])],
 923                               gdb_cv_printf_has_long_long=yes,
 924                               gdb_cv_printf_has_long_long=no,
 925                               gdb_cv_printf_has_long_long=no)])
 926 if test $gdb_cv_printf_has_long_long = yes; then
 927   AC_DEFINE(PRINTF_HAS_LONG_LONG, 1,
 928             [Define to 1 if the "%ll" format works to print long longs.])
 929 fi
 930
 931 # Check if the compiler and runtime support printing decfloats.
 932
 933 AC_CACHE_CHECK([for decfloat support in printf],
 934                gdb_cv_printf_has_decfloat,
 935                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
 936 [[char buf[64];
 937   _Decimal32 d32 = 1.2345df;
 938   _Decimal64 d64 = 1.2345dd;
 939   _Decimal128 d128 = 1.2345dl;
 940   sprintf (buf, "Decimal32: %H\nDecimal64: %D\nDecimal128: %DD", d32, d64, d128);
 941   return (strcmp ("Decimal32: 1.2345\nDecimal64: 1.2345\nDecimal128: 1.2345", buf));]])],
 942                               gdb_cv_printf_has_decfloat=yes,
 943                               gdb_cv_printf_has_decfloat=no,
 944                               gdb_cv_printf_has_decfloat=no)])
 945 if test $gdb_cv_printf_has_decfloat = yes; then
 946   AC_DEFINE(PRINTF_HAS_DECFLOAT, 1,
 947             [Define to 1 if the "%H, %D and %DD" formats work to print decfloats.])
 948 fi
 949
 950 # Check if the compiler supports the `long double' type.  We can't use
 951 # AC_C_LONG_DOUBLE because that one does additional checks on the
 952 # constants defined in <float.h> that fail on some systems,
 953 # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6.
 954
 955 AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double,
 956                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])],
 957                                   gdb_cv_c_long_double=yes,
 958                                   gdb_cv_c_long_double=no)])
 959 if test $gdb_cv_c_long_double = yes; then
 960   AC_DEFINE(HAVE_LONG_DOUBLE, 1,
 961            [Define to 1 if the compiler supports long double.])
 962 fi
 963
 964 # Check if the compiler and runtime support printing long doubles.
 965
 966 AC_CACHE_CHECK([for long double support in printf],
 967                gdb_cv_printf_has_long_double,
 968                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
 969 [[char buf[16];
 970   long double f = 3.141592653;
 971   sprintf (buf, "%Lg", f);
 972   return (strncmp ("3.14159", buf, 7));]])],
 973                               gdb_cv_printf_has_long_double=yes,
 974                               gdb_cv_printf_has_long_double=no,
 975                               gdb_cv_printf_has_long_double=no)])
 976 if test $gdb_cv_printf_has_long_double = yes; then
 977   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1,
 978             [Define to 1 if the "%Lg" format works to print long doubles.])
 979 fi
 980
 981 # Check if the compiler and runtime support scanning long doubles.
 982
 983 AC_CACHE_CHECK([for long double support in scanf],
 984                gdb_cv_scanf_has_long_double,
 985                [AC_RUN_IFELSE([AC_LANG_PROGRAM(
 986 [[#include <stdio.h>]],
 987 [[char *buf = "3.141592653";
 988   long double f = 0;
 989   sscanf (buf, "%Lg", &f);
 990   return !(f > 3.14159 && f < 3.14160);]])],
 991                               gdb_cv_scanf_has_long_double=yes,
 992                               gdb_cv_scanf_has_long_double=no,
 993                               gdb_cv_scanf_has_long_double=no)])
 994 if test $gdb_cv_scanf_has_long_double = yes; then
 995   AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1,
 996             [Define to 1 if the "%Lg" format works to scan long doubles.])
 997 fi
 998
 999 case ${host_os} in
1000 aix*)
1001   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1002     SAVE_LDFLAGS=$LDFLAGS
1003
1004     case $GCC in
1005     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1006     *) gdb_cv_bigtoc=-bbigtoc ;;
1007     esac
1008
1009     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1010     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1011     LDFLAGS="${SAVE_LDFLAGS}"
1012   ])
1013   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
1014   ;;
1015 esac
1016
1017
1018 dnl For certain native configurations, we need to check whether thread
1019 dnl support can be built in or not.
1020 dnl
1021 dnl Note that we only want this if we are both native (host == target),
1022 dnl and not doing a canadian cross build (build == host).
1023
1024 if test ${build} = ${host} -a ${host} = ${target} ; then
1025    case ${host_os} in
1026    hpux*)
1027       AC_MSG_CHECKING(for HPUX/OSF thread support)
1028       if test -f /usr/include/dce/cma_config.h ; then
1029          if test "$GCC" = "yes" ; then
1030             AC_MSG_RESULT(yes)
1031             AC_DEFINE(HAVE_HPUX_THREAD_SUPPORT, 1,
1032             [Define if you have HPUX threads])
1033             CONFIG_OBS="${CONFIG_OBS} hpux-thread.o"
1034             CONFIG_SRCS="${CONFIG_SRCS} hpux-thread.c"
1035          else
1036             AC_MSG_RESULT(no (suppressed because you are not using GCC))
1037          fi
1038       else
1039          AC_MSG_RESULT(no)
1040       fi
1041       ;;
1042    solaris*)
1043       # See if thread_db library is around for Solaris thread debugging.
1044       # Note that we must explicitly test for version 1 of the library
1045       # because version 0 (present on Solaris 2.4 or earlier) doesn't have
1046       # the same API.
1047       AC_MSG_CHECKING(for Solaris thread debugging library)
1048       if test -f /usr/lib/libthread_db.so.1 ; then
1049          AC_MSG_RESULT(yes)
1050          AC_DEFINE(HAVE_THREAD_DB_LIB, 1,
1051          [Define if using Solaris thread debugging.])
1052          CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
1053          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
1054          AC_CHECK_LIB(dl, dlopen)
1055          if test "$GCC" = "yes" ; then
1056             # The GNU linker requires the -export-dynamic option to make
1057             # all symbols visible in the dynamic symbol table.
1058             hold_ldflags=$LDFLAGS
1059             AC_MSG_CHECKING(for the ld -export-dynamic flag)
1060             LDFLAGS="${LDFLAGS} -Wl,-export-dynamic"
1061             AC_TRY_LINK(, [int i;], found=yes, found=no)
1062             LDFLAGS=$hold_ldflags
1063             AC_MSG_RESULT($found)
1064             if test $found = yes; then
1065                CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -Wl,-export-dynamic"
1066             fi
1067          fi
1068          # Sun randomly tweaked the prototypes in <proc_service.h>
1069          # at one point.
1070          AC_MSG_CHECKING(if <proc_service.h> is old)
1071          AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
1072             AC_TRY_COMPILE([
1073                 #include <proc_service.h>
1074                 ps_err_e ps_pdwrite
1075                     (struct ps_prochandle*, psaddr_t, const void*, size_t);
1076             ],, gdb_cv_proc_service_is_old=no,
1077                 gdb_cv_proc_service_is_old=yes)
1078          ])
1079          AC_MSG_RESULT($gdb_cv_proc_service_is_old)
1080          if test $gdb_cv_proc_service_is_old = yes; then
1081             AC_DEFINE(PROC_SERVICE_IS_OLD, 1,
1082             [Define if <proc_service.h> on solaris uses int instead of
1083              size_t, and assorted other type changes.])
1084          fi
1085       else
1086          AC_MSG_RESULT(no)
1087       fi
1088       ;;
1089    aix*)
1090       AC_MSG_CHECKING(for AiX thread debugging library)
1091       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
1092                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
1093                                    [#ifndef PTHDB_VERSION_3
1094                                     #error
1095                                     #endif],
1096                                    gdb_cv_have_aix_thread_debug=yes,
1097                                    gdb_cv_have_aix_thread_debug=no)])
1098       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1099       if test $gdb_cv_have_aix_thread_debug = yes; then
1100          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1101          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1102          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -lpthdebug"
1103       fi
1104       ;;
1105    esac
1106    AC_SUBST(CONFIG_LDFLAGS)
1107 fi
1108
1109 dnl See if we have a thread_db header file that has TD_NOTALLOC and
1110 dnl other error codes.
1111 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1112    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
1113                   gdb_cv_thread_db_h_has_td_notalloc,
1114      AC_TRY_COMPILE(
1115        [#include <thread_db.h>],
1116        [int i = TD_NOTALLOC;],
1117        gdb_cv_thread_db_h_has_td_notalloc=yes,
1118        gdb_cv_thread_db_h_has_td_notalloc=no
1119      )
1120    )
1121    AC_CACHE_CHECK([whether <thread_db.h> has TD_VERSION],
1122                   gdb_cv_thread_db_h_has_td_version,
1123      AC_TRY_COMPILE(
1124        [#include <thread_db.h>],
1125        [int i = TD_VERSION;],
1126        gdb_cv_thread_db_h_has_td_version=yes,
1127        gdb_cv_thread_db_h_has_td_version=no
1128      )
1129    )
1130    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTLS],
1131                   gdb_cv_thread_db_h_has_td_notls,
1132      AC_TRY_COMPILE(
1133        [#include <thread_db.h>],
1134        [int i = TD_NOTLS;],
1135        gdb_cv_thread_db_h_has_td_notls=yes,
1136        gdb_cv_thread_db_h_has_td_notls=no
1137      )
1138    )
1139 fi
1140 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1141   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1142             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1143 fi
1144 if test "x$gdb_cv_thread_db_h_has_td_version" = "xyes"; then
1145   AC_DEFINE(THREAD_DB_HAS_TD_VERSION, 1,
1146             [Define if <thread_db.h> has the TD_VERSION error code.])
1147 fi
1148 if test "x$gdb_cv_thread_db_h_has_td_notls" = "xyes"; then
1149   AC_DEFINE(THREAD_DB_HAS_TD_NOTLS, 1,
1150             [Define if <thread_db.h> has the TD_NOTLS error code.])
1151 fi
1152
1153 dnl See if we have a sys/syscall header file that has __NR_tkill.
1154 if test "x$ac_cv_header_sys_syscall_h" = "xyes"; then
1155    AC_CACHE_CHECK([whether <sys/syscall.h> has __NR_tkill],
1156                   gdb_cv_sys_syscall_h_has_tkill,
1157      AC_TRY_COMPILE(
1158        [#include <sys/syscall.h>],
1159        [int i = __NR_tkill;],
1160        gdb_cv_sys_syscall_h_has_tkill=yes,
1161        gdb_cv_sys_syscall_h_has_tkill=no
1162      )
1163    )
1164 fi
1165 dnl See if we can issue tkill syscall.
1166 if test "x$gdb_cv_sys_syscall_h_has_tkill" = "xyes" && test "x$ac_cv_func_syscall" = "xyes"; then
1167   AC_DEFINE(HAVE_TKILL_SYSCALL, 1, [Define if you support the tkill syscall.])
1168 fi
1169
1170 dnl Handle optional features that can be enabled.
1171
1172 AC_ARG_WITH(sysroot,
1173 [  --with-sysroot[=DIR] Search for usr/lib et al within DIR.],
1174 [
1175  case ${with_sysroot} in
1176  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
1177  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
1178  esac
1179
1180  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
1181
1182  if test "x$prefix" = xNONE; then
1183   test_prefix=/usr/local
1184  else
1185   test_prefix=$prefix
1186  fi
1187  if test "x$exec_prefix" = xNONE || test "x$exec_prefix" = 'x${prefix}'; then
1188   test_exec_prefix=$test_prefix
1189  else
1190   test_exec_prefix=$exec_prefix
1191  fi
1192  case ${TARGET_SYSTEM_ROOT} in
1193  "${test_prefix}"|"${test_prefix}/"*|\
1194  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
1195  '${prefix}'|'${prefix}/'*|\
1196  '${exec_prefix}'|'${exec_prefix}/'*)
1197    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
1198    TARGET_SYSTEM_ROOT_DEFINE="$t"
1199    ;;
1200  esac
1201 ], [
1202  TARGET_SYSTEM_ROOT=
1203  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"'
1204 ])
1205 AC_SUBST(TARGET_SYSTEM_ROOT)
1206 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
1207
1208 AC_ARG_ENABLE(werror,
1209   [  --enable-werror    treat compile warnings as errors],
1210   [case "${enableval}" in
1211      yes | y) ERROR_ON_WARNING="yes" ;;
1212      no | n)  ERROR_ON_WARNING="no" ;;
1213      *) AC_MSG_ERROR(bad value ${enableval} for --enable-werror) ;;
1214    esac])
1215
1216 # Enable -Werror by default when using gcc
1217 if test "${GCC}" = yes -a -z "${ERROR_ON_WARNING}" ; then
1218     ERROR_ON_WARNING=yes
1219 fi
1220
1221 WERROR_CFLAGS=""
1222 if test "${ERROR_ON_WARNING}" = yes ; then
1223     WERROR_CFLAGS="-Werror"
1224 fi
1225
1226 # The entries after -Wno-pointer-sign are disabled warnings which may
1227 # be enabled in the future, which can not currently be used to build
1228 # GDB.
1229 # NOTE: If you change this list, remember to update
1230 # gdb/doc/gdbint.texinfo.
1231 build_warnings="-Wall -Wdeclaration-after-statement -Wpointer-arith \
1232 -Wformat-nonliteral -Wno-pointer-sign \
1233 -Wno-unused -Wno-switch -Wno-char-subscripts"
1234
1235 AC_ARG_ENABLE(build-warnings,
1236 [  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
1237 [case "${enableval}" in
1238   yes)  ;;
1239   no)   build_warnings="-w";;
1240   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1241         build_warnings="${build_warnings} ${t}";;
1242   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1243         build_warnings="${t} ${build_warnings}";;
1244   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1245 esac
1246 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1247   echo "Setting compiler warning flags = $build_warnings" 6>&1
1248 fi])dnl
1249 AC_ARG_ENABLE(gdb-build-warnings,
1250 [  --enable-gdb-build-warnings Enable GDB specific build-time compiler warnings if gcc is used],
1251 [case "${enableval}" in
1252   yes)  ;;
1253   no)   build_warnings="-w";;
1254   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1255         build_warnings="${build_warnings} ${t}";;
1256   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1257         build_warnings="${t} ${build_warnings}";;
1258   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1259 esac
1260 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1261   echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1
1262 fi])dnl
1263 WARN_CFLAGS=""
1264 if test "x${build_warnings}" != x -a "x$GCC" = xyes
1265 then
1266     AC_MSG_CHECKING(compiler warning flags)
1267     # Separate out the -Werror flag as some files just cannot be
1268     # compiled with it enabled.
1269     for w in ${build_warnings}; do
1270         case $w in
1271         -Werr*) WERROR_CFLAGS=-Werror ;;
1272         *) # Check that GCC accepts it
1273             saved_CFLAGS="$CFLAGS"
1274             CFLAGS="$CFLAGS $w"
1275             AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
1276             CFLAGS="$saved_CFLAGS"
1277         esac
1278     done
1279     AC_MSG_RESULT(${WARN_CFLAGS} ${WERROR_CFLAGS})
1280 fi
1281 AC_SUBST(WARN_CFLAGS)
1282 AC_SUBST(WERROR_CFLAGS)
1283
1284 # In the Cygwin environment, we need some additional flags.
1285 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1286 [AC_EGREP_CPP(lose, [
1287 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1288 lose
1289 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1290
1291
1292 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1293 SER_HARDWIRE="ser-base.o ser-unix.o ser-pipe.o ser-tcp.o"
1294 case ${host} in
1295   *go32* ) SER_HARDWIRE=ser-go32.o ;;
1296   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
1297   *mingw32*) SER_HARDWIRE="ser-base.o ser-tcp.o ser-mingw.o" ;;
1298 esac
1299 AC_SUBST(SER_HARDWIRE)
1300
1301 # libreadline needs libuser32.a in a cygwin environment
1302 WIN32LIBS=
1303 if test x$gdb_cv_os_cygwin = xyes; then
1304     WIN32LIBS="-luser32"
1305     case "${target}" in
1306         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
1307         ;;
1308     esac
1309 fi
1310
1311 # The ser-tcp.c module requires sockets.
1312 case ${host} in
1313   *mingw32*)
1314     AC_DEFINE(USE_WIN32API, 1,
1315               [Define if we should use the Windows API, instead of the
1316                POSIX API.  On Windows, we use the Windows API when
1317                building for MinGW, but the POSIX API when building
1318                for Cygwin.])
1319     WIN32LIBS="$WIN32LIBS -lws2_32"
1320     ;;
1321 esac
1322 AC_SUBST(WIN32LIBS)
1323
1324 # Add ELF support to GDB, but only if BFD includes ELF support.
1325 OLD_CFLAGS=$CFLAGS
1326 OLD_LDFLAGS=$LDFLAGS
1327 OLD_LIBS=$LIBS
1328 CFLAGS="$CFLAGS -I${srcdir}/../include -I../bfd -I${srcdir}/../bfd"
1329 LDFLAGS="$LDFLAGS -L../bfd -L../libiberty"
1330 intl=`echo $LIBINTL | sed 's,${top_builddir}/,,g'`
1331 LIBS="$LIBS -lbfd -liberty $intl"
1332 AC_CACHE_CHECK([for ELF support in BFD], gdb_cv_var_elf,
1333 [AC_TRY_LINK(
1334 [#include <stdlib.h>
1335 #include "bfd.h"
1336 #include "elf-bfd.h"
1337 ],
1338 [bfd *abfd = NULL; bfd_get_elf_phdr_upper_bound (abfd); ],
1339 gdb_cv_var_elf=yes, gdb_cv_var_elf=no)])
1340 if test $gdb_cv_var_elf = yes; then
1341   CONFIG_OBS="$CONFIG_OBS elfread.o"
1342   AC_DEFINE(HAVE_ELF, 1,
1343             [Define if ELF support should be included.])
1344 fi
1345 CFLAGS=$OLD_CFLAGS
1346 LDFLAGS=$OLD_LDFLAGS
1347 LIBS=$OLD_LIBS
1348
1349 # Add any host-specific objects to GDB.
1350 CONFIG_OBS="${CONFIG_OBS} ${gdb_host_obs}"
1351
1352 LIBGUI="../libgui/src/libgui.a"
1353 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
1354 AC_SUBST(LIBGUI)
1355 AC_SUBST(GUI_CFLAGS_X)
1356
1357 WIN32LDAPP=
1358 AC_SUBST(WIN32LIBS)
1359 AC_SUBST(WIN32LDAPP)
1360
1361 case "${host}" in
1362 *-*-cygwin*)
1363     configdir="win"
1364     ;;
1365 *)
1366     configdir="unix"
1367     ;;
1368 esac
1369
1370 GDBTKLIBS=
1371 if test "${enable_gdbtk}" = "yes"; then
1372
1373     # Gdbtk must have an absolute path to srcdir in order to run
1374     # properly when not installed.
1375     here=`pwd`
1376     cd ${srcdir}
1377     GDBTK_SRC_DIR=`pwd`
1378     cd $here
1379
1380     CY_AC_PATH_TCLCONFIG
1381     if test -z "${no_tcl}"; then
1382         CY_AC_LOAD_TCLCONFIG
1383         CY_AC_PATH_TKCONFIG
1384
1385         # now look for Tcl library stuff
1386
1387         tcldir="../tcl/${configdir}/"
1388
1389         TCL_DEPS="${tcldir}${TCL_LIB_FILE}"
1390
1391         # If $no_tk is nonempty, then we can't do Tk, and there is no
1392         # point to doing Tcl.
1393         if test -z "${no_tk}"; then
1394            CY_AC_LOAD_TKCONFIG
1395            CY_AC_PATH_TCLH
1396            CY_AC_PATH_TKH
1397            CY_AC_PATH_ITCLH
1398            CY_AC_PATH_ITKH
1399
1400
1401            # now look for Tk library stuff
1402
1403            tkdir="../tk/${configdir}/"
1404
1405            TK_DEPS="${tkdir}${TK_LIB_FILE}"
1406
1407            # now look for Itcl library stuff
1408
1409            CY_AC_PATH_ITCLCONFIG
1410            if test -z "${no_itcl}"; then
1411              CY_AC_LOAD_ITCLCONFIG
1412
1413              ITCLLIB="${ITCL_BUILD_LIB_SPEC}"
1414              ITCL_DEPS="${ITCL_LIB_FULL_PATH}"
1415            fi
1416
1417
1418            # now look for Itk library stuff
1419            CY_AC_PATH_ITKCONFIG
1420            if test -z "${no_itcl}"; then
1421              CY_AC_LOAD_ITKCONFIG
1422
1423              ITKLIB="${ITK_BUILD_LIB_SPEC}"
1424              ITK_DEPS="${ITK_LIB_FULL_PATH}"
1425            fi
1426
1427            ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
1428
1429            # Include some libraries that Tcl and Tk want.
1430            TCL_LIBS='$(LIBGUI) $(ITCL) $(ITK) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
1431            # Yes, the ordering seems wrong here.  But it isn't.
1432            # TK_LIBS is the list of libraries that need to be linked
1433            # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
1434            # were in LIBS then any link tests after this point would
1435            # try to include things like `$(LIBGUI)', which wouldn't work.
1436            GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
1437
1438            CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
1439            CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
1440            CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
1441            CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
1442            CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
1443            CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
1444            CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
1445
1446            if test x$gdb_cv_os_cygwin = xyes; then
1447               WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
1448               WIN32LDAPP="-Wl,--subsystem,console"
1449               CONFIG_OBS="${CONFIG_OBS} gdbres.o"
1450            fi
1451         fi
1452     fi
1453
1454     AC_CONFIG_SUBDIRS(gdbtk)
1455 fi
1456
1457 AC_SUBST(X_CFLAGS)
1458 AC_SUBST(X_LDFLAGS)
1459 AC_SUBST(X_LIBS)
1460 AC_SUBST(TCL_DEPS)
1461 AC_SUBST(TK_DEPS)
1462 AC_SUBST(ITCLLIB)
1463 AC_SUBST(ITCL_DEPS)
1464 AC_SUBST(ITKLIB)
1465 AC_SUBST(ITK_DEPS)
1466 AC_SUBST(GDBTKLIBS)
1467 AC_SUBST(GDBTK_CFLAGS)
1468 AC_SUBST(GDBTK_SRC_DIR)
1469
1470 AC_PATH_X
1471
1472 # Check whether we should enable the TUI, but only do so if we really
1473 # can.
1474 if test x"$enable_tui" = xyes; then
1475   if test -d $srcdir/tui; then
1476     if test "$ac_cv_search_waddstr" != no; then
1477       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
1478       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
1479       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
1480       CONFIG_INITS="$CONFIG_INITS \$(SUBDIR_TUI_INITS)"
1481       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
1482       CONFIG_ALL="${CONFIG_ALL} all-tui"
1483       CONFIG_CLEAN="${CONFIG_CLEAN} clean-tui"
1484       CONFIG_INSTALL="${CONFIG_INSTALL} install-tui"
1485       CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-tui"
1486     else
1487       AC_MSG_WARN([no enhanced curses library found; disabling TUI])
1488     fi
1489   fi
1490 fi
1491
1492 # Unlike the sim directory, whether a simulator is linked is controlled by
1493 # presence of a SIM= and a SIM_OBS= definition in the target '.mt' file.
1494 # This code just checks for a few cases where we'd like to ignore those
1495 # definitions, even when they're present in the '.mt' file.  These cases
1496 # are when --disable-sim is specified, or if the simulator directory is
1497 # not part of the source tree.
1498 #
1499 AC_ARG_ENABLE(sim,
1500 [  --enable-sim            Link gdb with simulator],
1501 [echo "enable_sim = $enable_sim";
1502  echo "enableval = ${enableval}";
1503  case "${enableval}" in
1504   yes) ignore_sim=false ;;
1505   no)  ignore_sim=true ;;
1506   *)   ignore_sim=false ;;
1507  esac],
1508 [ignore_sim=false])
1509
1510 if test ! -d "${srcdir}/../sim"; then
1511   ignore_sim=true
1512 fi
1513
1514 if test "${ignore_sim}" = "true"; then
1515     IGNORE_SIM="SIM="
1516     IGNORE_SIM_OBS="SIM_OBS="
1517 else
1518     IGNORE_SIM=""
1519     IGNORE_SIM_OBS=""
1520     AC_DEFINE(WITH_SIM, 1, [Define if the simulator is being linked in.])
1521 fi
1522 AC_SUBST(IGNORE_SIM)
1523 AC_SUBST(IGNORE_SIM_OBS)
1524
1525 AC_SUBST(ENABLE_CFLAGS)
1526 AC_SUBST(PROFILE_CFLAGS)
1527
1528 AC_SUBST(CONFIG_OBS)
1529 AC_SUBST(CONFIG_DEPS)
1530 AC_SUBST(CONFIG_SRCS)
1531 AC_SUBST(CONFIG_ALL)
1532 AC_SUBST(CONFIG_CLEAN)
1533 AC_SUBST(CONFIG_INSTALL)
1534 AC_SUBST(CONFIG_UNINSTALL)
1535
1536 # List of host floatformats.
1537 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
1538 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
1539 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
1540
1541 # target_subdir is used by the testsuite to find the target libraries.
1542 target_subdir=
1543 if test "${host}" != "${target}"; then
1544     target_subdir="${target_alias}/"
1545 fi
1546 AC_SUBST(target_subdir)
1547
1548 frags=
1549 if test "${gdb_native}" = "yes"; then
1550   host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
1551   if test ! -f ${host_makefile_frag}; then
1552     AC_MSG_ERROR("*** Gdb does not support native target ${host}")
1553   fi
1554   frags="$frags $host_makefile_frag"
1555 else
1556   host_makefile_frag=/dev/null
1557 fi
1558
1559 target_makefile_frag=${srcdir}/config/${gdb_target_cpu}/${gdb_target}.mt
1560 if test ! -f ${target_makefile_frag}; then
1561   AC_MSG_ERROR("*** Gdb does not support target ${target}")
1562 fi
1563 frags="$frags $target_makefile_frag"
1564
1565 AC_SUBST_FILE(host_makefile_frag)
1566 AC_SUBST_FILE(target_makefile_frag)
1567 AC_SUBST(frags)
1568
1569 changequote(,)dnl
1570 if test "${gdb_native}" = "yes"; then
1571 # We pick this up from the host configuration file (.mh) because we
1572 # do not have a native configuration Makefile fragment.
1573 nativefile=`sed -n '
1574 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
1575 ' ${host_makefile_frag}`
1576 fi
1577 changequote([,])
1578
1579 if test x"${gdb_osabi}" != x ; then
1580     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
1581                        [Define to the default OS ABI for this configuration.])
1582 fi
1583
1584 # Enable multi-ice-gdb-server.
1585 AC_ARG_ENABLE(multi-ice,
1586 [  --enable-multi-ice      build the multi-ice-gdb-server],
1587   [case $enableval in
1588     yes | no)
1589       ;;
1590     *) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;;
1591   esac])
1592 if test "x$enable_multi_ice" = xyes; then
1593    AC_CONFIG_SUBDIRS(multi-ice)
1594 fi
1595
1596 # We only build gdbserver automatically in a native configuration.
1597 if test "$gdb_native" = "yes"; then
1598   AC_MSG_CHECKING(whether gdbserver is supported on this host)
1599   if test "x$build_gdbserver" = xyes; then
1600     AC_MSG_RESULT(yes)
1601     AC_CONFIG_SUBDIRS(gdbserver)
1602   else
1603     AC_MSG_RESULT(no)
1604   fi
1605 fi
1606
1607 # If nativefile (NAT_FILE) is not set in config/*/*.m[ht] files, we link
1608 # to an empty version.
1609
1610 files=
1611 links=
1612
1613 rm -f nm.h
1614 nm_h=""
1615 if test "${nativefile}" != ""; then
1616     nm_h=nm.h
1617     case "${nativefile}" in
1618       nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
1619       * ) GDB_NM_FILE="${nativefile}"
1620     esac
1621     files="${files} ${GDB_NM_FILE}"
1622     links="${links} nm.h"
1623     AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}", [nativefile])
1624 fi
1625 AC_SUBST(nm_h)
1626
1627 AC_LINK_FILES($files, $links)
1628
1629 dnl Check for exe extension set on certain hosts (e.g. Win32)
1630 AC_EXEEXT
1631
1632 dnl  Detect the character set used by this host.
1633
1634 dnl  At the moment, we just assume it's ISO-8859-1 (which is a
1635 dnl  superset of ASCII containing the characters needed for French,
1636 dnl  German, Spanish, Italian, and possibly others), but if were
1637 dnl  *were* to support any host character sets other than ISO-8859-1,
1638 dnl  here's where we'd detect it.
1639 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "ISO-8859-1",
1640           [Define to be a string naming the default host character set.])
1641
1642 AM_ICONV
1643
1644 AC_OUTPUT(Makefile .gdbinit:gdbinit.in,
1645 [
1646 dnl Autoconf doesn't provide a mechanism for modifying definitions
1647 dnl provided by makefile fragments.
1648 dnl
1649
1650 changequote(,)dnl
1651 sed -e '/^NAT_FILE[     ]*=/s,^NAT_FILE[        ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,' <Makefile >Makefile.tmp
1652 mv -f Makefile.tmp Makefile
1653 changequote([,])dnl
1654
1655
1656 case x$CONFIG_HEADERS in
1657 xconfig.h:config.in)
1658 echo > stamp-h ;;
1659 esac
1660 ],
1661 [
1662 gdb_host_cpu=$gdb_host_cpu
1663 gdb_target_cpu=$gdb_target_cpu
1664 nativefile=$nativefile
1665 ])
1666
1667 exit 0