gdb/configure.ac

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995-2012 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Process this file with autoconf to produce a configure script.
  20
  21 AC_PREREQ(2.59)dnl
  22 AC_INIT(main.c)
  23 AC_CONFIG_HEADER(config.h:config.in)
  24 AM_MAINTAINER_MODE
  25
  26 AC_PROG_CC
  27 AC_USE_SYSTEM_EXTENSIONS
  28 ACX_LARGEFILE
  29 AM_PROG_CC_STDC
  30
  31 AC_CONFIG_AUX_DIR(..)
  32 AC_CANONICAL_SYSTEM
  33
  34 # Dependency checking.
  35 ZW_CREATE_DEPDIR
  36 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  37
  38 # Check for the 'make' the user wants to use.
  39 AC_CHECK_PROGS(MAKE, make)
  40 MAKE_IS_GNU=
  41 case "`$MAKE --version 2>&1 | sed 1q`" in
  42   *GNU*)
  43     MAKE_IS_GNU=yes
  44     ;;
  45 esac
  46 AM_CONDITIONAL(GMAKE, test "$MAKE_IS_GNU" = yes)
  47 AC_PROG_MAKE_SET
  48
  49 # Configure gnulib.  We need to build gnulib under some other
  50 # directory not "gnulib", to avoid the problem of both GDB and
  51 # GDBserver wanting to build it in the same directory, when building
  52 # in the source dir.
  53 ACX_CONFIGURE_DIR(["gnulib"], ["build-gnulib"])
  54
  55 dnl List of object files and targets accumulated by configure.
  56
  57 CONFIG_OBS=
  58 CONFIG_DEPS=
  59 CONFIG_SRCS=
  60 ENABLE_CFLAGS=
  61
  62 CONFIG_ALL=
  63 CONFIG_CLEAN=
  64 CONFIG_INSTALL=
  65 CONFIG_UNINSTALL=
  66
  67 dnl Set up for gettext.
  68 ZW_GNU_GETTEXT_SISTER_DIR
  69
  70 localedir='${datadir}/locale'
  71 AC_SUBST(localedir)
  72
  73 if test x"$USE_NLS" = xyes; then
  74    CONFIG_ALL="$CONFIG_ALL all-po"
  75    CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
  76    CONFIG_INSTALL="$CONFIG_INSTALL install-po"
  77    CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
  78 fi
  79
  80 GNULIB=build-gnulib/import
  81
  82 # For Makefile dependencies.
  83 GNULIB_STDINT_H=
  84 if test x"$STDINT_H" != x; then
  85   GNULIB_STDINT_H=$GNULIB/$STDINT_H
  86 fi
  87 AC_SUBST(GNULIB_STDINT_H)
  88
  89 PACKAGE=gdb
  90 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
  91 AC_SUBST(PACKAGE)
  92
  93 # We never need to detect it in this sub-configure.
  94 # But preserve it for config.status --recheck.
  95 AC_ARG_VAR(MAKEINFO,
  96   [Parent configure detects if it is of sufficient version.])
  97 AC_ARG_VAR(MAKEINFOFLAGS,
  98   [Parameters for MAKEINFO.])
  99
 100 MAKEINFO_EXTRA_FLAGS=""
 101 AC_CACHE_CHECK([whether $MAKEINFO supports @click], gdb_cv_have_makeinfo_click,
 102   [echo '@clicksequence{a @click{} b}' >conftest.texinfo
 103   if eval "$MAKEINFO conftest.texinfo >&5 2>&5"; then
 104     gdb_cv_have_makeinfo_click=yes
 105   else
 106     gdb_cv_have_makeinfo_click=no
 107   fi])
 108 if test x"$gdb_cv_have_makeinfo_click" = xyes; then
 109   MAKEINFO_EXTRA_FLAGS="$MAKEINFO_EXTRA_FLAGS -DHAVE_MAKEINFO_CLICK"
 110 fi
 111 AC_SUBST(MAKEINFO_EXTRA_FLAGS)
 112
 113 GDB_AC_WITH_DIR(DEBUGDIR, separate-debug-dir,
 114     [look for global separate debug info in this path @<:@LIBDIR/debug@:>@],
 115     [${libdir}/debug])
 116
 117 # We can't pass paths as command line arguments.
 118 # Mingw32 tries to be clever and will convert the paths for us.
 119 # For example -DBINDIR="/usr/local/bin" passed on the command line may get
 120 # converted to -DBINDIR="E:/msys/mingw32/msys/1.0/local/bin".
 121 # This breaks GDB's relocatable path conversions since paths passed in
 122 # config.h would not get so translated, the path prefixes no longer match.
 123 AC_DEFINE_DIR(BINDIR, bindir, [Directory of programs.])
 124
 125 # GDB's datadir relocation
 126
 127 GDB_AC_WITH_DIR(GDB_DATADIR, gdb-datadir,
 128     [look for global separate data files in this path @<:@DATADIR/gdb@:>@],
 129     [${datadir}/gdb])
 130
 131 AC_ARG_WITH(relocated-sources,
 132 AS_HELP_STRING([--with-relocated-sources=PATH], [automatically relocate this path for source files]),
 133 [reloc_srcdir="${withval}"
 134  AC_DEFINE_DIR(RELOC_SRCDIR, reloc_srcdir,
 135               [Relocated directory for source files. ])
 136 ])
 137
 138 AC_MSG_CHECKING([for default auto-load safe-path])
 139 AC_ARG_WITH(auto-load-safe-path,
 140 AS_HELP_STRING([--with-auto-load-safe-path=PATH], [directories safe to hold auto-loaded files])
 141 AS_HELP_STRING([--without-auto-load-safe-path], [do not restrict auto-loaded files locations]),
 142 [if test "$with_auto_load_safe_path" = "no"; then
 143    with_auto_load_safe_path=""
 144  fi],
 145 [with_auto_load_safe_path="$prefix"])
 146 AC_DEFINE_DIR(DEFAULT_AUTO_LOAD_SAFE_PATH, with_auto_load_safe_path,
 147               [Directories safe to hold auto-loaded files.])
 148 AC_MSG_RESULT([$with_auto_load_safe_path])
 149
 150 AC_CONFIG_SUBDIRS(testsuite)
 151
 152 # Check whether to support alternative target configurations
 153 AC_ARG_ENABLE(targets,
 154 AS_HELP_STRING([--enable-targets=TARGETS], [alternative target configurations]),
 155 [case "${enableval}" in
 156   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
 157             ;;
 158   no)       enable_targets= ;;
 159   *)        enable_targets=$enableval ;;
 160 esac])
 161
 162 # Check whether to enable 64-bit support on 32-bit hosts
 163 AC_ARG_ENABLE(64-bit-bfd,
 164 AS_HELP_STRING([--enable-64-bit-bfd], [64-bit support (on hosts with narrower word sizes)]),
 165 [case "${enableval}" in
 166   yes)  want64=true  ;;
 167   no)   want64=false ;;
 168   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
 169 esac],[want64=false])dnl
 170
 171 # Provide defaults for some variables set by the per-host and per-target
 172 # configuration.
 173 gdb_host_obs=posix-hdep.o
 174
 175 if test "${target}" = "${host}"; then
 176   gdb_native=yes
 177 else
 178   gdb_native=no
 179 fi
 180
 181 . $srcdir/configure.host
 182
 183 # Accumulate some settings from configure.tgt over all enabled targets
 184
 185 TARGET_OBS=
 186 all_targets=
 187
 188 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 189 do
 190   if test "$targ_alias" = "all"; then
 191     all_targets=true
 192   else
 193     # Canonicalize the secondary target names.
 194     result=`$ac_config_sub $targ_alias 2>/dev/null`
 195     if test -n "$result"; then
 196         targ=$result
 197     else
 198         targ=$targ_alias
 199     fi
 200
 201     . ${srcdir}/configure.tgt
 202
 203     AS_IF([test -z "${gdb_target_obs}"],
 204       [AC_MSG_ERROR([configuration ${targ} is unsupported.])])
 205
 206     # Target-specific object files
 207     for i in ${gdb_target_obs}; do
 208         case " $TARGET_OBS " in
 209         *" ${i} "*) ;;
 210         *)
 211           TARGET_OBS="$TARGET_OBS ${i}"
 212           ;;
 213         esac
 214     done
 215
 216     # Check whether this target needs 64-bit CORE_ADDR
 217     if test x${want64} = xfalse; then
 218       . ${srcdir}/../bfd/config.bfd
 219     fi
 220   fi
 221 done
 222
 223 if test x${all_targets} = xtrue; then
 224
 225   # We want all 64-bit targets if we either:
 226   #  - run on a 64-bit host  or
 227   #  - already require 64-bit support for some other target  or
 228   #  - the --enable-64-bit-bfd option was supplied
 229   # Otherwise we only support all 32-bit targets.
 230   #
 231   # NOTE: This test must be in sync with the corresponding
 232   #       tests in BFD!
 233
 234   if test x${want64} = xfalse; then
 235     AC_CHECK_SIZEOF(long)
 236     if test "x${ac_cv_sizeof_long}" = "x8"; then
 237       want64=true
 238     fi
 239   fi
 240   if test x${want64} = xtrue; then
 241     TARGET_OBS='$(ALL_TARGET_OBS) $(ALL_64_TARGET_OBS)'
 242   else
 243     TARGET_OBS='$(ALL_TARGET_OBS)'
 244   fi
 245 fi
 246
 247 AC_SUBST(TARGET_OBS)
 248
 249 # For other settings, only the main target counts.
 250 gdb_sim=
 251 gdb_osabi=
 252 build_gdbserver=
 253 targ=$target; . ${srcdir}/configure.tgt
 254
 255 # Fetch the default architecture and default target vector from BFD.
 256 targ=$target; . $srcdir/../bfd/config.bfd
 257
 258 # We only want the first architecture, so strip off the others if
 259 # there is more than one.
 260 targ_archs=`echo $targ_archs | sed 's/ .*//'`
 261
 262 if test "x$targ_archs" != x; then
 263   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
 264     [Define to BFD's default architecture. ])
 265 fi
 266 if test "x$targ_defvec" != x; then
 267   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
 268     [Define to BFD's default target vector. ])
 269 fi
 270
 271 # The CLI cannot be disabled yet, but may be in the future.
 272
 273 # Enable CLI.
 274 AC_ARG_ENABLE(gdbcli,
 275 AS_HELP_STRING([--disable-gdbcli], [disable command-line interface (CLI)]),
 276   [case $enableval in
 277     yes)
 278       ;;
 279     no)
 280       AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;;
 281     *)
 282       AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;;
 283   esac],
 284   [enable_gdbcli=yes])
 285 if test x"$enable_gdbcli" = xyes; then
 286   if test -d $srcdir/cli; then
 287     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)"
 288     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)"
 289     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)"
 290     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)"
 291   fi
 292 fi
 293
 294 # Enable MI.
 295 AC_ARG_ENABLE(gdbmi,
 296 AS_HELP_STRING([--disable-gdbmi], [disable machine-interface (MI)]),
 297   [case $enableval in
 298     yes | no)
 299       ;;
 300     *)
 301       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 302   esac],
 303   [enable_gdbmi=yes])
 304 if test x"$enable_gdbmi" = xyes; then
 305   if test -d $srcdir/mi; then
 306     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 307     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 308     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 309     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 310   fi
 311 fi
 312
 313 # Enable TUI.
 314 AC_ARG_ENABLE(tui,
 315 AS_HELP_STRING([--enable-tui], [enable full-screen terminal user interface (TUI)]),
 316   [case $enableval in
 317     yes | no | auto)
 318       ;;
 319     *)
 320       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 321   esac],enable_tui=auto)
 322
 323 # Enable gdbtk.
 324 AC_ARG_ENABLE(gdbtk,
 325 AS_HELP_STRING([--enable-gdbtk], [enable gdbtk graphical user interface (GUI)]),
 326   [case $enableval in
 327     yes | no)
 328       ;;
 329     *)
 330       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 331   esac],
 332   [if test -d $srcdir/gdbtk; then
 333     enable_gdbtk=yes
 334   else
 335     enable_gdbtk=no
 336   fi])
 337 # We unconditionally disable gdbtk tests on selected platforms.
 338 case $host_os in
 339   go32* | windows*)
 340     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 341     enable_gdbtk=no ;;
 342 esac
 343
 344 # Libunwind support for ia64.
 345
 346 AC_ARG_WITH(libunwind-ia64,
 347 AS_HELP_STRING([--with-libunwind-ia64],
 348                [use libunwind frame unwinding for ia64 targets]),,
 349             [with_libunwind_ia64=auto])
 350
 351 # Backward compatibility option.
 352 if test "${with_libunwind+set}" = set; then
 353   if test x"$with_libunwind_ia64" != xauto; then
 354     AC_MSG_ERROR(
 355       [option --with-libunwind is deprecated, use --with-libunwind-ia64])
 356   fi
 357   AC_MSG_WARN([option --with-libunwind is deprecated, use --with-libunwind-ia64])
 358   with_libunwind_ia64="$with_libunwind"
 359 fi
 360
 361 case "$with_libunwind_ia64" in
 362   yes | no)
 363     ;;
 364   auto)
 365     AC_CHECK_HEADERS(libunwind-ia64.h)
 366     with_libunwind_ia64=$ac_cv_header_libunwind_ia64_h
 367     ;;
 368   *)
 369     AC_MSG_ERROR(
 370       [bad value $with_libunwind_ia64 for GDB --with-libunwind-ia64 option])
 371     ;;
 372 esac
 373
 374 if test x"$with_libunwind_ia64" = xyes; then
 375   AC_CHECK_HEADERS(libunwind-ia64.h)
 376   if test x"$ac_cv_header_libunwind_ia64_h" != xyes; then
 377     AC_MSG_ERROR([GDB option --with-libunwind-ia64 requires libunwind-ia64.h])
 378   fi
 379   CONFIG_OBS="$CONFIG_OBS ia64-libunwind-tdep.o"
 380   CONFIG_DEPS="$CONFIG_DEPS ia64-libunwind-tdep.o"
 381   CONFIG_SRCS="$CONFIG_SRCS ia64-libunwind-tdep.c"
 382 fi
 383
 384 opt_curses=no
 385 AC_ARG_WITH(curses, AS_HELP_STRING([--with-curses], [use the curses library instead of the termcap library]), opt_curses=$withval)
 386
 387 prefer_curses=no
 388 if test "$opt_curses" = "yes"; then
 389   prefer_curses=yes
 390 fi
 391
 392 # Profiling support.
 393 AC_ARG_ENABLE(profiling,
 394 AS_HELP_STRING([--enable-profiling], [enable profiling of GDB]),
 395   [case $enableval in
 396     yes | no)
 397       ;;
 398     *)
 399       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 400   esac],
 401  [enable_profiling=no])
 402
 403 AC_CHECK_FUNCS(monstartup _mcleanup)
 404 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 405 [AC_TRY_LINK(
 406 [#include <stdlib.h>
 407 extern char _etext;
 408 ],
 409 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 410 if test $ac_cv_var__etext = yes; then
 411   AC_DEFINE(HAVE__ETEXT, 1,
 412             [Define to 1 if your system has the _etext variable. ])
 413 fi
 414 AC_CACHE_CHECK([for etext], ac_cv_var_etext,
 415 [AC_TRY_LINK(
 416 [#include <stdlib.h>
 417 extern char etext;
 418 ],
 419 [free (&etext);], ac_cv_var_etext=yes, ac_cv_var_etext=no)])
 420 if test $ac_cv_var_etext = yes; then
 421   AC_DEFINE(HAVE_ETEXT, 1,
 422             [Define to 1 if your system has the etext variable. ])
 423 fi
 424 if test "$enable_profiling" = yes ; then
 425   if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
 426     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 427   fi
 428   PROFILE_CFLAGS=-pg
 429   OLD_CFLAGS="$CFLAGS"
 430   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 431
 432   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 433     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 434      ac_cv_cc_supports_pg=no)])
 435
 436   if test $ac_cv_cc_supports_pg = no; then
 437     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 438   fi
 439
 440   CFLAGS="$OLD_CFLAGS"
 441 fi
 442
 443 ACX_PKGVERSION([GDB])
 444 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 445 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 446 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 447
 448 # --------------------- #
 449 # Checks for programs.  #
 450 # --------------------- #
 451
 452 AC_PROG_AWK
 453 AC_PROG_INSTALL
 454 AC_PROG_LN_S
 455 AC_PROG_RANLIB
 456 AC_PROG_YACC
 457
 458 AC_CHECK_TOOL(AR, ar)
 459 AC_CHECK_TOOL(DLLTOOL, dlltool)
 460 AC_CHECK_TOOL(WINDRES, windres)
 461
 462 # Needed for GNU/Hurd.
 463 AC_CHECK_TOOL(MIG, mig)
 464
 465 # ---------------------- #
 466 # Checks for libraries.  #
 467 # ---------------------- #
 468
 469 # We might need to link with -lm; most simulators need it.
 470 AC_CHECK_LIB(m, main)
 471
 472 # We need to link with -lw to get `wctype' on Solaris before Solaris
 473 # 2.6.  Solaris 2.6 and beyond have this function in libc, and have a
 474 # libw that some versions of the GNU linker cannot hanle (GNU ld 2.9.1
 475 # is known to have this problem).  Therefore we avoid libw if we can.
 476 AC_CHECK_FUNC(wctype, [],
 477   [AC_CHECK_LIB(w, wctype)])
 478
 479 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 480 AC_SEARCH_LIBS(gethostbyname, nsl)
 481
 482 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 483 AC_SEARCH_LIBS(socketpair, socket)
 484
 485 # Link in zlib if we can.  This allows us to read compressed debug sections.
 486 AM_ZLIB
 487
 488 # On HP/UX we may need libxpdl for dlgetmodinfo (used by solib-pa64.c).
 489 AC_SEARCH_LIBS(dlgetmodinfo, [dl xpdl])
 490
 491 AM_ICONV
 492
 493 # GDB may fork/exec the iconv program to get the list of supported character
 494 # sets.  Allow the user to specify where to find it.
 495 # There are several factors affecting the choice of option name:
 496 # - There is already --with-libiconv-prefix but we can't use it, it specifies
 497 #   the build-time location of libiconv files.
 498 # - The program we need to find is iconv, which comes with glibc.  The user
 499 #   doesn't necessarily have libiconv installed.  Therefore naming this
 500 #   --with-libiconv-foo feels wrong.
 501 # - We want the path to be relocatable, but GDB_AC_DEFINE_RELOCATABLE is
 502 #   defined to work on directories not files (though it really doesn't know
 503 #   the difference).
 504 # - Calling this --with-iconv-prefix is perceived to cause too much confusion
 505 #   with --with-libiconv-prefix.
 506 # Putting these together is why the option name is --with-iconv-bin.
 507
 508 AC_ARG_WITH(iconv-bin,
 509 AS_HELP_STRING([--with-iconv-bin=PATH], [specify where to find the iconv program]),
 510 [iconv_bin="${withval}"
 511  AC_DEFINE_UNQUOTED([ICONV_BIN], ["${iconv_bin}"],
 512                     [Path of directory of iconv program.])
 513  GDB_AC_DEFINE_RELOCATABLE(ICONV_BIN, iconv, ${iconv_bin})
 514 ])
 515
 516 # On alpha-osf, it appears that libtermcap and libcurses are not compatible.
 517 # There is a very specific comment in /usr/include/curses.h explaining that
 518 # termcap routines built into libcurses must not be used.
 519 #
 520 # The symptoms we observed so far is GDB unexpectedly changing
 521 # the terminal settings when tgetent is called - this is particularly
 522 # visible as the output is missing carriage returns, and so rapidly
 523 # becomes very hard to read.
 524 #
 525 # The readline configure script has already decided that libtermcap
 526 # was enough for its purposes, and so decided to build readline using
 527 # libtermcap.  Since the TUI mode requires curses, building GDB with
 528 # TUI enabled results in both libraries to be used at the same time,
 529 # which is not allowed.  This basically means that GDB with TUI is
 530 # broken on alpha-osf.
 531
 532 case $host_os in
 533   osf* )
 534     if test x"$enable_tui" = xyes; then
 535       AC_MSG_ERROR([Building GDB with TUI mode is not supported on this host])
 536     fi
 537     if test x"$enable_tui" = xauto; then
 538       enable_tui=no
 539     fi
 540     ;;
 541 esac
 542
 543 # For the TUI, we need enhanced curses functionality.
 544 if test x"$enable_tui" != xno; then
 545   prefer_curses=yes
 546 fi
 547
 548 curses_found=no
 549 if test x"$prefer_curses" = xyes; then
 550   # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
 551   # curses library because the latter might not provide all the
 552   # functionality we need.  However, this leads to problems on systems
 553   # where the linker searches /usr/local/lib, but the compiler doesn't
 554   # search /usr/local/include, if ncurses is installed in /usr/local.  A
 555   # default installation of ncurses on alpha*-dec-osf* will lead to such
 556   # a situation.
 557   AC_SEARCH_LIBS(waddstr, [ncurses cursesX curses])
 558
 559   if test "$ac_cv_search_waddstr" != no; then
 560     curses_found=yes
 561   fi
 562 fi
 563
 564 # Check whether we should enable the TUI, but only do so if we really
 565 # can.
 566 if test x"$enable_tui" != xno; then
 567   if test -d $srcdir/tui; then
 568     if test "$curses_found" != no; then
 569       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
 570       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
 571       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
 572       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
 573     else
 574       if test x"$enable_tui" = xyes; then
 575         AC_MSG_ERROR([no enhanced curses library found; disable TUI])
 576       else
 577         AC_MSG_WARN([no enhanced curses library found; disabling TUI])
 578       fi
 579     fi
 580   fi
 581 fi
 582
 583 # Since GDB uses Readline, we need termcap functionality.  In many
 584 # cases this will be provided by the curses library, but some systems
 585 # have a seperate termcap library, or no curses library at all.
 586
 587 case $host_os in
 588   cygwin*)
 589     if test -d $srcdir/libtermcap; then
 590       LIBS="../libtermcap/libtermcap.a $LIBS"
 591       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 592     fi ;;
 593   go32* | *djgpp*)
 594     ac_cv_search_tgetent="none required"
 595     ;;
 596   *mingw32*)
 597     ac_cv_search_tgetent="none required"
 598     CONFIG_OBS="$CONFIG_OBS windows-termcap.o"
 599     ;;
 600 esac
 601
 602 # These are the libraries checked by Readline.
 603 AC_SEARCH_LIBS(tgetent, [termcap tinfo curses ncurses])
 604
 605 if test "$ac_cv_search_tgetent" = no; then
 606   AC_MSG_ERROR([no termcap library found])
 607 fi
 608
 609 AC_ARG_WITH([system-readline],
 610   [AS_HELP_STRING([--with-system-readline],
 611                   [use installed readline library])])
 612
 613 if test "$with_system_readline" = yes; then
 614   READLINE=-lreadline
 615   READLINE_DEPS=
 616   READLINE_CFLAGS=
 617   READLINE_TEXI_INCFLAG=
 618 else
 619   READLINE='$(READLINE_DIR)/libreadline.a'
 620   READLINE_DEPS='$(READLINE)'
 621   READLINE_CFLAGS='-I$(READLINE_SRC)/..'
 622   READLINE_TEXI_INCFLAG='-I $(READLINE_DIR)'
 623 fi
 624 AC_SUBST(READLINE)
 625 AC_SUBST(READLINE_DEPS)
 626 AC_SUBST(READLINE_CFLAGS)
 627 AC_SUBST(READLINE_TEXI_INCFLAG)
 628
 629 # Generate jit-reader.h
 630
 631 # This is typedeffed to GDB_CORE_ADDR in jit-reader.h
 632 TARGET_PTR=
 633
 634 AC_CHECK_SIZEOF(unsigned long long)
 635 AC_CHECK_SIZEOF(unsigned long)
 636 AC_CHECK_SIZEOF(unsigned __int128)
 637
 638 if test "x${ac_cv_sizeof_unsigned_long}" = "x8"; then
 639   TARGET_PTR="unsigned long"
 640 elif test "x${ac_cv_sizeof_unsigned_long_long}" = "x8"; then
 641   TARGET_PTR="unsigned long long"
 642 elif test "x${ac_cv_sizeof_unsigned___int128}" = "x16"; then
 643   TARGET_PTR="unsigned __int128"
 644 else
 645   TARGET_PTR="unsigned long"
 646 fi
 647
 648 AC_SUBST(TARGET_PTR)
 649 AC_CONFIG_FILES([jit-reader.h:jit-reader.in])
 650
 651 AC_SEARCH_LIBS(dlopen, dl)
 652
 653 GDB_AC_WITH_DIR([JIT_READER_DIR], [jit-reader-dir],
 654                 [directory to load the JIT readers from],
 655                 [${libdir}/gdb])
 656
 657 AC_ARG_WITH(expat,
 658   AS_HELP_STRING([--with-expat], [include expat support (auto/yes/no)]),
 659   [], [with_expat=auto])
 660 AC_MSG_CHECKING([whether to use expat])
 661 AC_MSG_RESULT([$with_expat])
 662
 663 if test "${with_expat}" = no; then
 664   AC_MSG_WARN([expat support disabled; some features may be unavailable.])
 665   HAVE_LIBEXPAT=no
 666 else
 667   AC_LIB_HAVE_LINKFLAGS([expat], [], [#include "expat.h"],
 668                         [XML_Parser p = XML_ParserCreate (0);])
 669   if test "$HAVE_LIBEXPAT" != yes; then
 670     if test "$with_expat" = yes; then
 671       AC_MSG_ERROR([expat is missing or unusable])
 672     else
 673       AC_MSG_WARN([expat is missing or unusable; some features may be unavailable.])
 674     fi
 675   else
 676     save_LIBS=$LIBS
 677     LIBS="$LIBS $LIBEXPAT"
 678     AC_CHECK_FUNCS(XML_StopParser)
 679     LIBS=$save_LIBS
 680   fi
 681 fi
 682
 683 dnl Utility to simplify finding libpython.
 684 dnl $1 = pythonX.Y
 685 dnl $2 = the shell variable to assign the result to
 686 dnl      If libpython is found we store $version here.
 687 dnl $3 = additional flags to add to CPPFLAGS
 688 dnl $4 = additional flags to add to LIBS
 689
 690 AC_DEFUN([AC_TRY_LIBPYTHON],
 691 [
 692   version=$1
 693   define([have_libpython_var],$2)
 694   new_CPPFLAGS=$3
 695   new_LIBS=$4
 696   AC_MSG_CHECKING([for ${version}])
 697   save_CPPFLAGS=$CPPFLAGS
 698   save_LIBS=$LIBS
 699   CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
 700   LIBS="$LIBS $new_LIBS"
 701   found_usable_python=no
 702   AC_LINK_IFELSE(AC_LANG_PROGRAM([[#include "Python.h"]],
 703                                  [[Py_Initialize ();]]),
 704                  [have_libpython_var=${version}
 705                   found_usable_python=yes
 706                   PYTHON_CPPFLAGS=$new_CPPFLAGS
 707                   PYTHON_LIBS=$new_LIBS])
 708   CPPFLAGS=$save_CPPFLAGS
 709   LIBS=$save_LIBS
 710   AC_MSG_RESULT([${found_usable_python}])
 711 ])
 712
 713 dnl There are several different values for --with-python:
 714 dnl
 715 dnl no -   Don't include python support.
 716 dnl yes -  Include python support, error if it's missing.
 717 dnl        If we find python in $PATH, use it to fetch configure options,
 718 dnl        otherwise assume the compiler can find it with no help from us.
 719 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 720 dnl auto - Same as "yes", but if python is missing from the system,
 721 dnl        fall back to "no".
 722 dnl /path/to/python/exec-prefix -
 723 dnl        Use the python located in this directory.
 724 dnl        If /path/to/python/exec-prefix/bin/python exists, use it to find
 725 dnl        the compilation parameters.  Otherwise use
 726 dnl        -I/path/to/python/exec-prefix/include,
 727 dnl        -L/path/to/python/exec-prefix/lib.
 728 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 729 dnl        NOTE: This case is historical.  It is what was done for 7.0/7.1
 730 dnl        but is deprecated.
 731 dnl /path/to/python/executable -
 732 dnl        Run python-config.py with this version of python to fetch the
 733 dnl        compilation parameters.
 734 dnl        NOTE: This needn't be the real python executable.
 735 dnl        In a cross-compilation scenario (build != host), this could be
 736 dnl        a shell script that provides what python-config.py provides for
 737 dnl        --ldflags, --includes, --exec-prefix.
 738 dnl python-executable -
 739 dnl        Find python-executable in $PATH, and then handle the same as
 740 dnl        /path/to/python/executable.
 741 dnl
 742 dnl If a python program is specified, it is used to run python-config.py and
 743 dnl is passed --ldflags, --includes, --exec-prefix.
 744
 745 AC_ARG_WITH(python,
 746   AS_HELP_STRING([--with-python@<:@=PYTHON@:>@], [include python support (auto/yes/no/<python-program>)]),
 747   [], [with_python=auto])
 748 AC_MSG_CHECKING([whether to use python])
 749 AC_MSG_RESULT([$with_python])
 750
 751 if test "${with_python}" = no; then
 752   AC_MSG_WARN([python support disabled; some features may be unavailable.])
 753   have_libpython=no
 754 else
 755   case "${with_python}" in
 756   [[\\/]]* | ?:[[\\/]]*)
 757     if test -d ${with_python}; then
 758       # Assume the python binary is ${with_python}/bin/python.
 759       python_prog="${with_python}/bin/python"
 760       python_prefix=
 761       # If python does not exit ${with_python}/bin, then try in
 762       # ${with_python}.  On Windows/MinGW, this is where the Python
 763       # executable is.
 764       if test ! -x "${python_prog}"; then
 765         python_prog="${with_python}/python"
 766         python_prefix=
 767       fi
 768       if test ! -x "${python_prog}"; then
 769         # Fall back to gdb 7.0/7.1 behaviour.
 770         python_prog=missing
 771         python_prefix=${with_python}
 772       fi
 773     elif test -x "${with_python}"; then
 774       # While we can't run python compiled for $host (unless host == build),
 775       # the user could write a script that provides the needed information,
 776       # so we support that.
 777       python_prog=${with_python}
 778       python_prefix=
 779     else
 780       AC_ERROR(invalid value for --with-python)
 781     fi
 782     ;;
 783   */*)
 784     # Disallow --with-python=foo/bar.
 785     AC_ERROR(invalid value for --with-python)
 786     ;;
 787   *)
 788     # The user has either specified auto, yes, or the name of the python
 789     # program assumed to be in $PATH.
 790     python_prefix=
 791     case "${with_python}" in
 792     yes | auto)
 793       if test ${build} = ${host}; then
 794         AC_PATH_PROG(python_prog_path, python, missing)
 795         if test "${python_prog_path}" = missing; then
 796           python_prog=missing
 797         else
 798           python_prog=${python_prog_path}
 799         fi
 800       else
 801         # Not much we can do except assume the cross-compiler will find the
 802         # right files.
 803         python_prog=missing
 804       fi
 805       ;;
 806     *)
 807       # While we can't run python compiled for $host (unless host == build),
 808       # the user could write a script that provides the needed information,
 809       # so we support that.
 810       python_prog="${with_python}"
 811       AC_PATH_PROG(python_prog_path, ${python_prog}, missing)
 812       if test "${python_prog_path}" = missing; then
 813         AC_ERROR(unable to find python program ${python_prog})
 814       fi
 815       ;;
 816     esac
 817   esac
 818
 819   if test "${python_prog}" != missing; then
 820     # We have a python program to use, but it may be too old.
 821     # Don't flag an error for --with-python=auto (the default).
 822     have_python_config=yes
 823     python_includes=`${python_prog} ${srcdir}/python/python-config.py --includes`
 824     if test $? != 0; then
 825       have_python_config=failed
 826       if test "${with_python}" != auto; then
 827         AC_ERROR(failure running python-config --includes)
 828       fi
 829     fi
 830     python_libs=`${python_prog} ${srcdir}/python/python-config.py --ldflags`
 831     if test $? != 0; then
 832       have_python_config=failed
 833       if test "${with_python}" != auto; then
 834         AC_ERROR(failure running python-config --ldflags)
 835       fi
 836     fi
 837     python_prefix=`${python_prog} ${srcdir}/python/python-config.py --exec-prefix`
 838     if test $? != 0; then
 839       have_python_config=failed
 840       if test "${with_python}" != auto; then
 841         AC_ERROR(failure running python-config --exec-prefix)
 842       fi
 843     fi
 844   else
 845     # We do not have a python executable we can use to determine where
 846     # to find the Python headers and libs.  We cannot guess the include
 847     # path from the python_prefix either, because that include path
 848     # depends on the Python version.  So, there is nothing much we can
 849     # do except assume that the compiler will be able to find those files.
 850     python_includes=
 851     python_libs=
 852     have_python_config=no
 853   fi
 854
 855   # If we have python-config, only try the configuration it provides.
 856   # Otherwise fallback on the old way of trying different versions of
 857   # python in turn.
 858
 859   have_libpython=no
 860   if test "${have_python_config}" = yes; then
 861     # Determine the Python version by extracting "-lpython<version>"
 862     # part of the python_libs. <version> is usually X.Y with X and Y
 863     # being decimal numbers, but can also be XY (seen on Windows).
 864     #
 865     # The extraction is performed using sed with a regular expression.
 866     # Initially, the regexp used was using the '?' quantifier to make
 867     # the dot in the version number optional.  Unfortunately, this
 868     # does not work with non-GNU versions of sed because, because of
 869     # what looks like a limitation (the '?' quantifier does not work
 870     # with back-references).  We work around this limitation by using
 871     # the '*' quantifier instead.  It means that, in theory, we might
 872     # match unexpected version strings such as "-lpython2..7", but
 873     # this seems unlikely in practice.  And even if that happens,
 874     # an error will be triggered later on, when checking that version
 875     # number.
 876     python_version=`echo " ${python_libs} " \
 877                          | sed -e 's,^.* -l\(python[[0-9]]*[[.]]*[[0-9]]*\).*$,\1,'`
 878     case "${python_version}" in
 879     python*)
 880       AC_TRY_LIBPYTHON(${python_version}, have_libpython,
 881                        ${python_includes}, ${python_libs})
 882       ;;
 883     *)
 884       AC_MSG_ERROR([unable to determine python version from ${python_libs}])
 885       ;;
 886     esac
 887   elif test "${have_python_config}" != failed; then
 888     if test "${have_libpython}" = no; then
 889       AC_TRY_LIBPYTHON(python2.7, have_libpython,
 890                        ${python_includes}, "${python_libs} -lpython2.7")
 891     fi
 892     if test "${have_libpython}" = no; then
 893       AC_TRY_LIBPYTHON(python2.6, have_libpython,
 894                        ${python_includes}, "${python_libs} -lpython2.6")
 895     fi
 896     if test ${have_libpython} = no; then
 897       AC_TRY_LIBPYTHON(python2.5, have_libpython,
 898                        ${python_includes}, "${python_libs} -lpython2.5")
 899     fi
 900     if test ${have_libpython} = no; then
 901       AC_TRY_LIBPYTHON(python2.4, have_libpython,
 902                        ${python_includes}, "${python_libs} -lpython2.4")
 903     fi
 904   fi
 905   if test "${have_libpython}" = python2.7 -o "${have_libpython}" = python27; then
 906     AC_DEFINE(HAVE_LIBPYTHON2_7, 1, [Define if Python 2.7 is being used.])
 907   elif test "${have_libpython}" = python2.6 -o "${have_libpython}" = python26; then
 908     AC_DEFINE(HAVE_LIBPYTHON2_6, 1, [Define if Python 2.6 is being used.])
 909   elif test "${have_libpython}" = python2.5 -o "${have_libpython}" = python25; then
 910     AC_DEFINE(HAVE_LIBPYTHON2_5, 1, [Define if Python 2.5 is being used.])
 911   elif test "${have_libpython}" = python2.4 -o "${have_libpython}" = python24; then
 912     AC_DEFINE(HAVE_LIBPYTHON2_4, 1, [Define if Python 2.4 is being used.])
 913   fi
 914
 915   if test "${have_libpython}" = no; then
 916     case "${with_python}" in
 917     yes)
 918       AC_MSG_ERROR([python is missing or unusable])
 919       ;;
 920     auto)
 921       AC_MSG_WARN([python is missing or unusable; some features may be unavailable.])
 922       ;;
 923     *)
 924       AC_MSG_ERROR([no usable python found at ${with_python}])
 925       ;;
 926     esac
 927   else
 928     if test -n "${python_prefix}"; then
 929       AC_DEFINE_UNQUOTED(WITH_PYTHON_PATH, "${python_prefix}",
 930                          [Define if --with-python provides a path, either directly or via python-config.py --exec-prefix.])
 931       GDB_AC_DEFINE_RELOCATABLE(PYTHON_PATH, python, ${python_prefix})
 932     fi
 933   fi
 934 fi
 935
 936 if test "${have_libpython}" != no; then
 937   AC_DEFINE(HAVE_PYTHON, 1, [Define if Python interpreter is being linked in.])
 938   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_PYTHON_OBS)"
 939   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_PYTHON_DEPS)"
 940   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_PYTHON_SRCS)"
 941   CONFIG_INSTALL="$CONFIG_INSTALL install-python"
 942   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_PYTHON_CFLAGS)"
 943
 944   # Flags needed to compile Python code (taken from python-config --cflags).
 945   # We cannot call python-config directly because it will output whatever was
 946   # used when compiling the Python interpreter itself, including flags which
 947   # would make the python-related objects be compiled differently from the
 948   # rest of GDB (e.g., -O2 and -fPIC).
 949   if test "${GCC}" = yes; then
 950     tentative_python_cflags="-fno-strict-aliasing -DNDEBUG -fwrapv"
 951   fi
 952
 953   if test "x${tentative_python_cflags}" != x; then
 954     AC_MSG_CHECKING(compiler flags for python code)
 955     for flag in ${tentative_python_cflags}; do
 956       # Check that the compiler accepts it
 957       saved_CFLAGS="$CFLAGS"
 958       CFLAGS="$CFLAGS $flag"
 959       AC_TRY_COMPILE([],[],PYTHON_CFLAGS="${PYTHON_CFLAGS} $flag",)
 960       CFLAGS="$saved_CFLAGS"
 961     done
 962     AC_MSG_RESULT(${PYTHON_CFLAGS})
 963   fi
 964
 965   # On IRIX, type siginfo is not defined.  Instead, sys/siginfo.h provides:
 966   #    #if _SGIAPI
 967   #    #define siginfo __siginfo
 968   #    #endif
 969   # The problem is that including Python causes some XOPEN macros to be
 970   # unilaterally defined, and that in turn causes _SGIAPI to evaluate
 971   # to false.  So, we work around this issue by defining siginfo ourself
 972   # though the command-line.
 973   case "$gdb_host" in
 974     irix*) if test "${GCC}" = yes; then
 975              CPPFLAGS="$CPPFLAGS -Dsiginfo=__siginfo"
 976            fi
 977            ;;
 978   esac
 979 else
 980   # Even if Python support is not compiled in, we need to have these files
 981   # included.
 982   CONFIG_OBS="$CONFIG_OBS python.o py-value.o py-prettyprint.o py-auto-load.o"
 983   CONFIG_SRCS="$CONFIG_SRCS python/python.c python/py-value.c \
 984         python/py-prettyprint.c python/py-auto-load.c"
 985 fi
 986 AC_SUBST(PYTHON_CFLAGS)
 987 AC_SUBST(PYTHON_CPPFLAGS)
 988 AC_SUBST(PYTHON_LIBS)
 989
 990 # ------------------------- #
 991 # Checks for header files.  #
 992 # ------------------------- #
 993
 994 AC_HEADER_DIRENT
 995 AC_HEADER_STAT
 996 AC_HEADER_STDC
 997 # elf_hp.h is for HP/UX 64-bit shared library support.
 998 # FIXME: kettenis/20030102: In most cases we include these (ctype.h, time.h)
 999 # unconditionally, so what's the point in checking these?
1000 AC_CHECK_HEADERS([nlist.h machine/reg.h poll.h sys/poll.h proc_service.h \
1001                   thread_db.h gnu/libc-version.h signal.h stddef.h \
1002                   stdlib.h string.h memory.h strings.h sys/fault.h \
1003                   sys/file.h sys/filio.h sys/ioctl.h sys/param.h \
1004                   sys/resource.h sys/procfs.h sys/ptrace.h ptrace.h \
1005                   sys/reg.h sys/debugreg.h sys/select.h sys/syscall.h \
1006                   sys/types.h sys/wait.h wait.h termios.h termio.h \
1007                   sgtty.h unistd.h elf_hp.h ctype.h time.h locale.h \
1008                   dlfcn.h sys/socket.h sys/un.h])
1009 AC_CHECK_HEADERS(link.h, [], [],
1010 [#if HAVE_SYS_TYPES_H
1011 # include <sys/types.h>
1012 #endif
1013 #if HAVE_NLIST_H
1014 # include <nlist.h>
1015 #endif
1016 ])
1017 AC_CHECK_HEADERS(sys/proc.h, [], [],
1018 [#if HAVE_SYS_PARAM_H
1019 # include <sys/param.h>
1020 #endif
1021 ])
1022 AC_CHECK_HEADERS(sys/user.h, [], [],
1023 [#if HAVE_SYS_PARAM_H
1024 # include <sys/param.h>
1025 #endif
1026 ])
1027
1028 # On Solaris 2.[789], we need to define _MSE_INT_H to avoid a clash
1029 # between <widec.h> and <wchar.h> that would cause AC_CHECK_HEADERS to
1030 # think that we don't have <curses.h> if we're using GCC.
1031 case $host_os in
1032   solaris2.[[789]])
1033     if test "$GCC" = yes; then
1034       AC_DEFINE(_MSE_INT_H, 1,
1035         [Define to 1 to avoid a clash between <widec.h> and <wchar.h> on
1036    Solaris 2.[789] when using GCC. ])
1037     fi ;;
1038 esac
1039 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncurses/ncurses.h ncurses/term.h)
1040 AC_CHECK_HEADERS(term.h, [], [],
1041 [#if HAVE_CURSES_H
1042 # include <curses.h>
1043 #endif
1044 ])
1045
1046 # ------------------------- #
1047 # Checks for declarations.  #
1048 # ------------------------- #
1049
1050 AC_CHECK_DECLS([free, malloc, realloc, strerror, strstr, getopt,
1051                 snprintf, vsnprintf])
1052 AM_LC_MESSAGES
1053
1054 # ----------------------- #
1055 # Checks for structures.  #
1056 # ----------------------- #
1057
1058 AC_CHECK_MEMBERS([struct stat.st_blocks, struct stat.st_blksize])
1059
1060 # ------------------ #
1061 # Checks for types.  #
1062 # ------------------ #
1063
1064 AC_TYPE_SIGNAL
1065 AC_CHECK_TYPES(socklen_t, [], [],
1066 [#include <sys/types.h>
1067 #include <sys/socket.h>
1068 ])
1069
1070 # ------------------------------------- #
1071 # Checks for compiler characteristics.  #
1072 # ------------------------------------- #
1073
1074 AC_C_CONST
1075 AC_C_INLINE
1076 AC_C_BIGENDIAN
1077
1078 # ------------------------------ #
1079 # Checks for library functions.  #
1080 # ------------------------------ #
1081
1082 AC_FUNC_ALLOCA
1083 AC_FUNC_MMAP
1084 AC_FUNC_VFORK
1085 AC_CHECK_FUNCS([canonicalize_file_name realpath getrusage getuid getgid \
1086                 pipe poll pread pread64 pwrite readlink resize_term \
1087                 sbrk setpgid setpgrp setsid \
1088                 sigaction sigprocmask sigsetmask socketpair syscall \
1089                 ttrace wborder wresize setlocale iconvlist libiconvlist btowc \
1090                 setrlimit getrlimit posix_madvise waitpid lstat])
1091 AM_LANGINFO_CODESET
1092
1093 # Check the return and argument types of ptrace.  No canned test for
1094 # this, so roll our own.
1095 gdb_ptrace_headers='
1096 #if HAVE_SYS_TYPES_H
1097 # include <sys/types.h>
1098 #endif
1099 #if HAVE_SYS_PTRACE_H
1100 # include <sys/ptrace.h>
1101 #endif
1102 #if HAVE_UNISTD_H
1103 # include <unistd.h>
1104 #endif
1105 '
1106 # There is no point in checking if we don't have a prototype.
1107 AC_CHECK_DECLS(ptrace, [], [
1108   : ${gdb_cv_func_ptrace_ret='int'}
1109   : ${gdb_cv_func_ptrace_args='int,int,long,long'}
1110 ], $gdb_ptrace_headers)
1111 # Check return type.  Varargs (used on GNU/Linux) conflict with the
1112 # empty argument list, so check for that explicitly.
1113 AC_CACHE_CHECK([return type of ptrace], gdb_cv_func_ptrace_ret,
1114   AC_TRY_COMPILE($gdb_ptrace_headers,
1115     [extern long ptrace (enum __ptrace_request, ...);],
1116     gdb_cv_func_ptrace_ret='long',
1117     AC_TRY_COMPILE($gdb_ptrace_headers,
1118       [extern int ptrace ();],
1119       gdb_cv_func_ptrace_ret='int',
1120       gdb_cv_func_ptrace_ret='long')))
1121 AC_DEFINE_UNQUOTED(PTRACE_TYPE_RET, $gdb_cv_func_ptrace_ret,
1122   [Define as the return type of ptrace.])
1123 # Check argument types.
1124 AC_CACHE_CHECK([types of arguments for ptrace], gdb_cv_func_ptrace_args, [
1125   AC_TRY_COMPILE($gdb_ptrace_headers,
1126     [extern long ptrace (enum __ptrace_request, ...);],
1127     [gdb_cv_func_ptrace_args='int,int,long,long'],[
1128 for gdb_arg1 in 'int' 'long'; do
1129  for gdb_arg2 in 'pid_t' 'int' 'long'; do
1130   for gdb_arg3 in 'int *' 'caddr_t' 'int' 'long' 'void *'; do
1131    for gdb_arg4 in 'int' 'long'; do
1132      AC_TRY_COMPILE($gdb_ptrace_headers, [
1133 extern $gdb_cv_func_ptrace_ret
1134   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4);
1135 ], [gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4";
1136     break 4;])
1137     for gdb_arg5 in 'int *' 'int' 'long'; do
1138      AC_TRY_COMPILE($gdb_ptrace_headers, [
1139 extern $gdb_cv_func_ptrace_ret
1140   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4, $gdb_arg5);
1141 ], [
1142 gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4,$gdb_arg5";
1143     break 5;])
1144     done
1145    done
1146   done
1147  done
1148 done
1149 # Provide a safe default value.
1150 : ${gdb_cv_func_ptrace_args='int,int,long,long'}
1151 ])])
1152 ac_save_IFS=$IFS; IFS=','
1153 set dummy `echo "$gdb_cv_func_ptrace_args" | sed 's/\*/\*/g'`
1154 IFS=$ac_save_IFS
1155 shift
1156 AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG3, $[3],
1157   [Define to the type of arg 3 for ptrace.])
1158 if test -n "$[5]"; then
1159   AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG5, $[5],
1160     [Define to the type of arg 5 for ptrace.])
1161 fi
1162
1163 dnl AC_FUNC_SETPGRP does not work when cross compiling
1164 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
1165 if test "$cross_compiling" = no; then
1166   AC_FUNC_SETPGRP
1167 else
1168   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
1169     [AC_TRY_COMPILE([
1170 #include <unistd.h>
1171 ], [
1172   if (setpgrp(1,1) == -1)
1173     exit (0);
1174   else
1175     exit (1);
1176 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
1177 if test $ac_cv_func_setpgrp_void = yes; then
1178   AC_DEFINE(SETPGRP_VOID, 1)
1179 fi
1180 fi
1181
1182 # Check if sigsetjmp is available.  Using AC_CHECK_FUNCS won't do
1183 # since sigsetjmp might only be defined as a macro.
1184 AC_CACHE_CHECK([for sigsetjmp], gdb_cv_func_sigsetjmp,
1185 [AC_TRY_COMPILE([
1186 #include <setjmp.h>
1187 ], [sigjmp_buf env; while (! sigsetjmp (env, 1)) siglongjmp (env, 1);],
1188 gdb_cv_func_sigsetjmp=yes, gdb_cv_func_sigsetjmp=no)])
1189 if test $gdb_cv_func_sigsetjmp = yes; then
1190   AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available. ])
1191 fi
1192
1193 # Assume we'll default to using the included libiberty regex.
1194 gdb_use_included_regex=yes
1195
1196 # However, if the system regex is GNU regex, then default to *not*
1197 # using the included regex.
1198 AC_CACHE_CHECK(
1199   [for GNU regex],
1200   [gdb_cv_have_gnu_regex],
1201   [AC_TRY_COMPILE(
1202     [#include <gnu-versions.h>],
1203     [#define REGEX_INTERFACE_VERSION 1
1204 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
1205 # error "Version mismatch"
1206 #endif],
1207     gdb_cv_have_gnu_regex=yes,
1208     gdb_cv_have_gnu_regex=no)])
1209 if test $gdb_cv_have_gnu_regex = yes; then
1210   gdb_use_included_regex=no
1211 fi
1212
1213 AC_ARG_WITH(included-regex,
1214   AS_HELP_STRING([--without-included-regex], [don't use included regex; this is the default on systems with version 2 of the GNU C library (use with caution on other system)]),
1215   gdb_with_regex=$withval,
1216   gdb_with_regex=$gdb_use_included_regex)
1217 if test "$gdb_with_regex" = yes; then
1218   AC_DEFINE(USE_INCLUDED_REGEX, 1,
1219     [Define to 1 if the regex included in libiberty should be used.])
1220 fi
1221
1222 # Check if <sys/proc.h> defines `struct thread' with a td_pcb member.
1223 AC_CHECK_MEMBERS([struct thread.td_pcb], [], [],
1224 [#include <sys/param.h>
1225 #include <sys/proc.h>
1226 ])
1227
1228 # See if <sys/lwp.h> defines `struct lwp`.
1229 AC_CACHE_CHECK([for struct lwp], gdb_cv_struct_lwp,
1230 [AC_TRY_COMPILE([#include <sys/param.h>
1231 #include <sys/lwp.h>], [struct lwp l;],
1232 gdb_cv_struct_lwp=yes, gdb_cv_struct_lwp=no)])
1233 if test $gdb_cv_struct_lwp = yes; then
1234   AC_DEFINE(HAVE_STRUCT_LWP, 1,
1235             [Define to 1 if your system has struct lwp.])
1236 fi
1237
1238 # See if <machine/reg.h> degines `struct reg'.
1239 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
1240 [AC_TRY_COMPILE([#include <sys/types.h>
1241 #include <machine/reg.h>], [struct reg r;],
1242 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
1243 if test $gdb_cv_struct_reg = yes; then
1244   AC_DEFINE(HAVE_STRUCT_REG, 1,
1245             [Define to 1 if your system has struct reg in <machine/reg.h>.])
1246 fi
1247
1248 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
1249 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
1250 AC_CHECK_MEMBERS([struct reg.r_fs, struct reg.r_gs], [], [],
1251                  [#include <machine/reg.h>])
1252
1253 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
1254 AC_MSG_CHECKING(for PTRACE_GETREGS)
1255 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
1256 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1257                 [PTRACE_GETREGS;],
1258                 [gdb_cv_have_ptrace_getregs=yes],
1259                 [gdb_cv_have_ptrace_getregs=no])])
1260 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
1261 if test $gdb_cv_have_ptrace_getregs = yes; then
1262   AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
1263   [Define if sys/ptrace.h defines the PTRACE_GETREGS request.])
1264 fi
1265
1266 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
1267 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
1268 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
1269 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1270                 [PTRACE_GETFPXREGS;],
1271                 [gdb_cv_have_ptrace_getfpxregs=yes],
1272                 [gdb_cv_have_ptrace_getfpxregs=no])])
1273 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
1274 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
1275   AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
1276   [Define if sys/ptrace.h defines the PTRACE_GETFPXREGS request.])
1277 fi
1278
1279 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
1280 AC_MSG_CHECKING(for PT_GETDBREGS)
1281 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
1282 [AC_TRY_COMPILE([#include <sys/types.h>
1283 #include <sys/ptrace.h>],
1284                 [PT_GETDBREGS;],
1285                 [gdb_cv_have_pt_getdbregs=yes],
1286                 [gdb_cv_have_pt_getdbregs=no])])
1287 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
1288 if test $gdb_cv_have_pt_getdbregs = yes; then
1289   AC_DEFINE(HAVE_PT_GETDBREGS, 1,
1290   [Define if sys/ptrace.h defines the PT_GETDBREGS request.])
1291 fi
1292
1293 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
1294 AC_MSG_CHECKING(for PT_GETXMMREGS)
1295 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
1296 [AC_TRY_COMPILE([#include <sys/types.h>
1297 #include <sys/ptrace.h>],
1298                 [PT_GETXMMREGS;],
1299                 [gdb_cv_have_pt_getxmmregs=yes],
1300                 [gdb_cv_have_pt_getxmmregs=no])])
1301 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
1302 if test $gdb_cv_have_pt_getxmmregs = yes; then
1303   AC_DEFINE(HAVE_PT_GETXMMREGS, 1,
1304   [Define if sys/ptrace.h defines the PT_GETXMMREGS request.])
1305 fi
1306
1307 # Detect which type of /proc is in use, such as for Unixware or Solaris.
1308
1309 if test "${target}" = "${host}"; then
1310   case "${host}" in
1311   *-*-unixware* | *-*-sysv4.2* | *-*-sysv5* | *-*-interix* )
1312       AC_DEFINE(NEW_PROC_API, 1,
1313       [Define if you want to use new multi-fd /proc interface
1314        (replaces HAVE_MULTIPLE_PROC_FDS as well as other macros).])
1315       ;;
1316   *-*-solaris2.[[6789]] | *-*-solaris2.1[[0-9]]*)
1317       AC_DEFINE(NEW_PROC_API, 1,
1318       [Define if you want to use new multi-fd /proc interface
1319        (replaces HAVE_MULTIPLE_PROC_FDS as well as other macros).])
1320       ;;
1321   mips-sgi-irix5*)
1322       # Work around <sys/proc.h> needing _KMEMUSER problem on IRIX 5.
1323       AC_DEFINE([_KMEMUSER], 1,
1324       [Define to 1 so <sys/proc.h> gets a definition of anon_hdl.  Works
1325        around a <sys/proc.h> problem on IRIX 5.])
1326       ;;
1327   esac
1328 fi
1329
1330 if test "$ac_cv_header_sys_procfs_h" = yes; then
1331   BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
1332   BFD_HAVE_SYS_PROCFS_TYPE(prrun_t)
1333   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
1334   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
1335   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
1336   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
1337   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
1338   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset32_t)
1339   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
1340   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
1341   BFD_HAVE_SYS_PROCFS_TYPE(prsysent_t)
1342   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigset_t)
1343   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigaction64_t)
1344   BFD_HAVE_SYS_PROCFS_TYPE(pr_siginfo64_t)
1345
1346
1347   dnl Check for broken prfpregset_t type
1348
1349   dnl For Linux/i386, glibc 2.1.3 was released with a bogus
1350   dnl prfpregset_t type (it's a typedef for the pointer to a struct
1351   dnl instead of the struct itself).  We detect this here, and work
1352   dnl around it in gdb_proc_service.h.
1353
1354   if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
1355     AC_MSG_CHECKING(whether prfpregset_t type is broken)
1356     AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
1357       [AC_TRY_RUN([#include <sys/procfs.h>
1358        int main ()
1359        {
1360          if (sizeof (prfpregset_t) == sizeof (void *))
1361            return 1;
1362          return 0;
1363        }],
1364        gdb_cv_prfpregset_t_broken=no,
1365        gdb_cv_prfpregset_t_broken=yes,
1366        gdb_cv_prfpregset_t_broken=yes)])
1367     AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
1368     if test $gdb_cv_prfpregset_t_broken = yes; then
1369       AC_DEFINE(PRFPREGSET_T_BROKEN, 1,
1370       [Define if the prfpregset_t type is broken.])
1371     fi
1372   fi
1373
1374   dnl Check for PIOCSET ioctl entry
1375
1376   AC_MSG_CHECKING(for PIOCSET ioctl entry in sys/procfs.h)
1377   AC_CACHE_VAL(gdb_cv_have_procfs_piocset,
1378   [AC_TRY_COMPILE([#include <unistd.h>
1379 #include <sys/types.h>
1380 #include <sys/procfs.h>
1381 ], [
1382     int dummy;;
1383     dummy = ioctl(0, PIOCSET, &dummy);
1384   ],
1385   gdb_cv_have_procfs_piocset=yes, gdb_cv_have_procfs_piocset=no)])
1386   AC_MSG_RESULT($gdb_cv_have_procfs_piocset)
1387   if test $gdb_cv_have_procfs_piocset = yes; then
1388     AC_DEFINE(HAVE_PROCFS_PIOCSET, 1,
1389     [Define if ioctl argument PIOCSET is available.])
1390   fi
1391 fi
1392
1393 dnl For native ports (host == target), check to see what kind of
1394 dnl legacy link.h support is needed.  (See solib-legacy.c.)
1395 if test ${host} = ${target} ; then
1396   dnl Check for struct link_map with l_ members which are indicative
1397   dnl of SVR4-like shared libraries
1398
1399   AC_MSG_CHECKING(for member l_addr in struct link_map)
1400   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_l_members,
1401     [AC_TRY_COMPILE([#include <link.h>],
1402                     [struct link_map lm; (void) lm.l_addr;],
1403                     gdb_cv_have_struct_link_map_with_l_members=yes,
1404                     gdb_cv_have_struct_link_map_with_l_members=no)])
1405   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_l_members)
1406   if test $gdb_cv_have_struct_link_map_with_l_members = yes; then
1407     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_L_MEMBERS,1,
1408     [Define if <link.h> exists and defines struct link_map which has
1409      members with an ``l_'' prefix.  (For Solaris, SVR4, and
1410      SVR4-like systems.)])
1411   fi
1412
1413   dnl Check for struct link_map with lm_ members which are indicative
1414   dnl of SunOS-like shared libraries
1415
1416   AC_MSG_CHECKING(for member lm_addr in struct link_map)
1417   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_lm_members,
1418     [AC_TRY_COMPILE([#include <sys/types.h>
1419 #include <link.h>],
1420                     [struct link_map lm; (void) lm.lm_addr;],
1421                     gdb_cv_have_struct_link_map_with_lm_members=yes,
1422                     gdb_cv_have_struct_link_map_with_lm_members=no)])
1423   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_lm_members)
1424   if test $gdb_cv_have_struct_link_map_with_lm_members = yes; then
1425     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_LM_MEMBERS, 1,
1426     [Define if <link.h> exists and defines struct link_map which has
1427      members with an ``lm_'' prefix.  (For SunOS.)])
1428   fi
1429
1430   dnl Check for struct so_map with som_ members which are found on
1431   dnl some *BSD systems.
1432
1433   AC_MSG_CHECKING(for member som_addr in struct so_map)
1434   AC_CACHE_VAL(gdb_cv_have_struct_so_map_with_som_members,
1435     [AC_TRY_COMPILE([#include <sys/types.h>
1436 #ifdef HAVE_NLIST_H
1437 #include <nlist.h>
1438 #endif
1439 #include <link.h>],
1440                     [struct so_map lm; (void) lm.som_addr;],
1441                     gdb_cv_have_struct_so_map_with_som_members=yes,
1442                     gdb_cv_have_struct_so_map_with_som_members=no)])
1443   AC_MSG_RESULT($gdb_cv_have_struct_so_map_with_som_members)
1444   if test $gdb_cv_have_struct_so_map_with_som_members = yes; then
1445     AC_DEFINE(HAVE_STRUCT_SO_MAP_WITH_SOM_MEMBERS, 1,
1446     [Define if <link.h> exists and defines a struct so_map which has
1447      members with an ``som_'' prefix.  (Found on older *BSD systems.)])
1448   fi
1449
1450   dnl Check for struct link_map32 type, which allows a 64-bit Solaris
1451   dnl debugger to debug a 32-bit Solaris app with 32-bit shared libraries.
1452
1453   AC_MSG_CHECKING(for struct link_map32 in sys/link.h)
1454   AC_CACHE_VAL(gdb_cv_have_struct_link_map32,
1455     [AC_TRY_COMPILE([#define _SYSCALL32
1456 #include <sys/link.h>], [struct link_map32 l;],
1457      gdb_cv_have_struct_link_map32=yes,
1458      gdb_cv_have_struct_link_map32=no)])
1459   AC_MSG_RESULT($gdb_cv_have_struct_link_map32)
1460   if test $gdb_cv_have_struct_link_map32 = yes; then
1461     AC_DEFINE(HAVE_STRUCT_LINK_MAP32, 1,
1462     [Define if <sys/link.h> has struct link_map32])
1463     AC_DEFINE(_SYSCALL32, 1,
1464     [Define if <sys/link.h> has link_map32 (solaris sparc-64 target)])
1465   fi
1466 fi
1467
1468 # Check if the compiler supports the `long long' type.
1469
1470 AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long,
1471                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1472 [[extern long long foo;]],
1473 [[switch (foo & 2) { case 0: return 1; }]])],
1474                                   gdb_cv_c_long_long=yes,
1475                                   gdb_cv_c_long_long=no)])
1476 if test $gdb_cv_c_long_long = yes; then
1477   AC_DEFINE(CC_HAS_LONG_LONG, 1,
1478             [Define to 1 if the compiler supports long long.])
1479 fi
1480
1481 # Check if the compiler and runtime support printing long longs.
1482
1483 AC_CACHE_CHECK([for long long support in printf],
1484                gdb_cv_printf_has_long_long,
1485                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1486 [[char buf[32];
1487   long long l = 0;
1488   l = (l << 16) + 0x0123;
1489   l = (l << 16) + 0x4567;
1490   l = (l << 16) + 0x89ab;
1491   l = (l << 16) + 0xcdef;
1492   sprintf (buf, "0x%016llx", l);
1493   return (strcmp ("0x0123456789abcdef", buf));]])],
1494                               gdb_cv_printf_has_long_long=yes,
1495                               gdb_cv_printf_has_long_long=no,
1496                               gdb_cv_printf_has_long_long=no)])
1497 if test $gdb_cv_printf_has_long_long = yes; then
1498   AC_DEFINE(PRINTF_HAS_LONG_LONG, 1,
1499             [Define to 1 if the "%ll" format works to print long longs.])
1500 fi
1501
1502 # Check if the compiler and runtime support printing decfloats.
1503
1504 AC_CACHE_CHECK([for decfloat support in printf],
1505                gdb_cv_printf_has_decfloat,
1506                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1507 [[char buf[64];
1508   _Decimal32 d32 = 1.2345df;
1509   _Decimal64 d64 = 1.2345dd;
1510   _Decimal128 d128 = 1.2345dl;
1511   sprintf (buf, "Decimal32: %H\nDecimal64: %D\nDecimal128: %DD", d32, d64, d128);
1512   return (strcmp ("Decimal32: 1.2345\nDecimal64: 1.2345\nDecimal128: 1.2345", buf));]])],
1513                               gdb_cv_printf_has_decfloat=yes,
1514                               gdb_cv_printf_has_decfloat=no,
1515                               gdb_cv_printf_has_decfloat=no)])
1516 if test $gdb_cv_printf_has_decfloat = yes; then
1517   AC_DEFINE(PRINTF_HAS_DECFLOAT, 1,
1518             [Define to 1 if the "%H, %D and %DD" formats work to print decfloats.])
1519 fi
1520
1521 # Check if the compiler supports the `long double' type.  We can't use
1522 # AC_C_LONG_DOUBLE because that one does additional checks on the
1523 # constants defined in <float.h> that fail on some systems,
1524 # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6.
1525
1526 AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double,
1527                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])],
1528                                   gdb_cv_c_long_double=yes,
1529                                   gdb_cv_c_long_double=no)])
1530 if test $gdb_cv_c_long_double = yes; then
1531   AC_DEFINE(HAVE_LONG_DOUBLE, 1,
1532            [Define to 1 if the compiler supports long double.])
1533 fi
1534
1535 # Check if the compiler and runtime support printing long doubles.
1536
1537 AC_CACHE_CHECK([for long double support in printf],
1538                gdb_cv_printf_has_long_double,
1539                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1540 [[char buf[16];
1541   long double f = 3.141592653;
1542   sprintf (buf, "%Lg", f);
1543   return (strncmp ("3.14159", buf, 7));]])],
1544                               gdb_cv_printf_has_long_double=yes,
1545                               gdb_cv_printf_has_long_double=no,
1546                               gdb_cv_printf_has_long_double=no)])
1547 if test $gdb_cv_printf_has_long_double = yes; then
1548   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1,
1549             [Define to 1 if the "%Lg" format works to print long doubles.])
1550 fi
1551
1552 # Check if the compiler and runtime support scanning long doubles.
1553
1554 AC_CACHE_CHECK([for long double support in scanf],
1555                gdb_cv_scanf_has_long_double,
1556                [AC_RUN_IFELSE([AC_LANG_PROGRAM(
1557 [[#include <stdio.h>]],
1558 [[char *buf = "3.141592653";
1559   long double f = 0;
1560   sscanf (buf, "%Lg", &f);
1561   return !(f > 3.14159 && f < 3.14160);]])],
1562                               gdb_cv_scanf_has_long_double=yes,
1563                               gdb_cv_scanf_has_long_double=no,
1564                               gdb_cv_scanf_has_long_double=no)])
1565 if test $gdb_cv_scanf_has_long_double = yes; then
1566   AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1,
1567             [Define to 1 if the "%Lg" format works to scan long doubles.])
1568 fi
1569
1570 case ${host_os} in
1571 aix*)
1572   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1573     SAVE_LDFLAGS=$LDFLAGS
1574
1575     case $GCC in
1576     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1577     *) gdb_cv_bigtoc=-bbigtoc ;;
1578     esac
1579
1580     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1581     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1582     LDFLAGS="${SAVE_LDFLAGS}"
1583   ])
1584   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
1585   ;;
1586 esac
1587
1588 AC_MSG_CHECKING(for the dynamic export flag)
1589 dynamic_list=false
1590 if test "${gdb_native}" = yes; then
1591    # The dynamically loaded libthread_db needs access to symbols in the gdb
1592    # executable.  Older GNU ld supports --export-dynamic but --dynamic-list
1593    # may not be supported there.
1594    old_LDFLAGS="$LDFLAGS"
1595    # Older GNU ld supports --export-dynamic but --dynamic-list it does not.
1596    RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
1597    LDFLAGS="$LDFLAGS $RDYNAMIC"
1598    if test "${have_libpython}" = no; then
1599      AC_TRY_LINK([], [], [dynamic_list=true])
1600    else
1601      # Workaround http://bugs.python.org/issue4434 where static
1602      # libpythonX.Y.a would get its symbols required for
1603      # pythonX.Y/lib-dynload/*.so modules hidden by -Wl,--dynamic-list.
1604      # Problem does not happen for the recommended libpythonX.Y.so linkage.
1605      old_CFLAGS="$CFLAGS"
1606      CFLAGS="$CFLAGS $PYTHON_CFLAGS"
1607      AC_RUN_IFELSE(
1608        AC_LANG_PROGRAM(
1609          [#include "]${have_libpython}[/Python.h"],
1610          [int err;
1611           Py_Initialize ();
1612           err = PyRun_SimpleString ("import itertools\n");
1613           Py_Finalize ();
1614           return err == 0 ? 0 : 1;]),
1615        [dynamic_list=true], [], [true])
1616      CFLAGS="$old_CFLAGS"
1617    fi
1618    LDFLAGS="$old_LDFLAGS"
1619 fi
1620 if $dynamic_list; then
1621   found="-Wl,--dynamic-list"
1622   RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'
1623 else
1624   found="-rdynamic"
1625   RDYNAMIC="-rdynamic"
1626 fi
1627 AC_SUBST(RDYNAMIC)
1628 AC_MSG_RESULT($found)
1629
1630 dnl For certain native configurations, we need to check whether thread
1631 dnl support can be built in or not.
1632 dnl
1633 dnl Note that we only want this if we are both native (host == target),
1634 dnl and not doing a canadian cross build (build == host).
1635
1636 if test ${build} = ${host} -a ${host} = ${target} ; then
1637    case ${host_os} in
1638    solaris*)
1639       # See if thread_db library is around for Solaris thread debugging.
1640       # Note that we must explicitly test for version 1 of the library
1641       # because version 0 (present on Solaris 2.4 or earlier) doesn't have
1642       # the same API.
1643       AC_MSG_CHECKING(for Solaris thread debugging library)
1644       if test -f /usr/lib/libthread_db.so.1 ; then
1645          AC_MSG_RESULT(yes)
1646          AC_DEFINE(HAVE_THREAD_DB_LIB, 1,
1647          [Define if using Solaris thread debugging.])
1648          CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
1649          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
1650          AC_CHECK_LIB(dl, dlopen)
1651          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} $RDYNAMIC"
1652          # Sun randomly tweaked the prototypes in <proc_service.h>
1653          # at one point.
1654          AC_MSG_CHECKING(if <proc_service.h> is old)
1655          AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
1656             AC_TRY_COMPILE([
1657                 #include <proc_service.h>
1658                 ps_err_e ps_pdwrite
1659                     (struct ps_prochandle*, psaddr_t, const void*, size_t);
1660             ],, gdb_cv_proc_service_is_old=no,
1661                 gdb_cv_proc_service_is_old=yes)
1662          ])
1663          AC_MSG_RESULT($gdb_cv_proc_service_is_old)
1664          if test $gdb_cv_proc_service_is_old = yes; then
1665             AC_DEFINE(PROC_SERVICE_IS_OLD, 1,
1666             [Define if <proc_service.h> on solaris uses int instead of
1667              size_t, and assorted other type changes.])
1668          fi
1669       else
1670          AC_MSG_RESULT(no)
1671       fi
1672       ;;
1673    aix*)
1674       AC_MSG_CHECKING(for AiX thread debugging library)
1675       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
1676                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
1677                                    [#ifndef PTHDB_VERSION_3
1678                                     #error
1679                                     #endif],
1680                                    gdb_cv_have_aix_thread_debug=yes,
1681                                    gdb_cv_have_aix_thread_debug=no)])
1682       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1683       if test $gdb_cv_have_aix_thread_debug = yes; then
1684          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1685          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1686          LIBS="$LIBS -lpthdebug"
1687
1688          # Older versions of AIX do not provide the declaration for
1689          # the getthrds function (it appears that it was introduced
1690          # with AIX 6.x).
1691          AC_CHECK_DECLS(getthrds, [], [], [[#include <procinfo.h>]])
1692       fi
1693       ;;
1694    esac
1695    AC_SUBST(CONFIG_LDFLAGS)
1696 fi
1697
1698 dnl See if we have a thread_db header file that has TD_NOTALLOC and
1699 dnl other error codes.
1700 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1701    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
1702                   gdb_cv_thread_db_h_has_td_notalloc,
1703      AC_TRY_COMPILE(
1704        [#include <thread_db.h>],
1705        [int i = TD_NOTALLOC;],
1706        gdb_cv_thread_db_h_has_td_notalloc=yes,
1707        gdb_cv_thread_db_h_has_td_notalloc=no
1708      )
1709    )
1710    AC_CACHE_CHECK([whether <thread_db.h> has TD_VERSION],
1711                   gdb_cv_thread_db_h_has_td_version,
1712      AC_TRY_COMPILE(
1713        [#include <thread_db.h>],
1714        [int i = TD_VERSION;],
1715        gdb_cv_thread_db_h_has_td_version=yes,
1716        gdb_cv_thread_db_h_has_td_version=no
1717      )
1718    )
1719    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTLS],
1720                   gdb_cv_thread_db_h_has_td_notls,
1721      AC_TRY_COMPILE(
1722        [#include <thread_db.h>],
1723        [int i = TD_NOTLS;],
1724        gdb_cv_thread_db_h_has_td_notls=yes,
1725        gdb_cv_thread_db_h_has_td_notls=no
1726      )
1727    )
1728 fi
1729 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1730   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1731             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1732 fi
1733 if test "x$gdb_cv_thread_db_h_has_td_version" = "xyes"; then
1734   AC_DEFINE(THREAD_DB_HAS_TD_VERSION, 1,
1735             [Define if <thread_db.h> has the TD_VERSION error code.])
1736 fi
1737 if test "x$gdb_cv_thread_db_h_has_td_notls" = "xyes"; then
1738   AC_DEFINE(THREAD_DB_HAS_TD_NOTLS, 1,
1739             [Define if <thread_db.h> has the TD_NOTLS error code.])
1740 fi
1741
1742 dnl See if we have a sys/syscall header file that has __NR_tkill.
1743 if test "x$ac_cv_header_sys_syscall_h" = "xyes"; then
1744    AC_CACHE_CHECK([whether <sys/syscall.h> has __NR_tkill],
1745                   gdb_cv_sys_syscall_h_has_tkill,
1746      AC_TRY_COMPILE(
1747        [#include <sys/syscall.h>],
1748        [int i = __NR_tkill;],
1749        gdb_cv_sys_syscall_h_has_tkill=yes,
1750        gdb_cv_sys_syscall_h_has_tkill=no
1751      )
1752    )
1753 fi
1754 dnl See if we can issue tkill syscall.
1755 if test "x$gdb_cv_sys_syscall_h_has_tkill" = "xyes" && test "x$ac_cv_func_syscall" = "xyes"; then
1756   AC_DEFINE(HAVE_TKILL_SYSCALL, 1, [Define if you support the tkill syscall.])
1757 fi
1758
1759 dnl Check if we can disable the virtual address space randomization.
1760 dnl The functionality of setarch -R.
1761 AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>])
1762 define([PERSONALITY_TEST], [AC_LANG_PROGRAM([#include <sys/personality.h>], [
1763 #      if !HAVE_DECL_ADDR_NO_RANDOMIZE
1764 #       define ADDR_NO_RANDOMIZE 0x0040000
1765 #      endif
1766        /* Test the flag could be set and stays set.  */
1767        personality (personality (0xffffffff) | ADDR_NO_RANDOMIZE);
1768        if (!(personality (personality (0xffffffff)) & ADDR_NO_RANDOMIZE))
1769            return 1])])
1770 AC_RUN_IFELSE([PERSONALITY_TEST],
1771               [have_personality=true],
1772               [have_personality=false],
1773               [AC_LINK_IFELSE([PERSONALITY_TEST],
1774                               [have_personality=true],
1775                               [have_personality=false])])
1776 if $have_personality
1777 then
1778     AC_DEFINE([HAVE_PERSONALITY], 1,
1779               [Define if you support the personality syscall.])
1780 fi
1781
1782 dnl Handle optional features that can be enabled.
1783
1784 # Support for --with-sysroot is a copy of GDB_AC_WITH_DIR,
1785 # except that the argument to --with-sysroot is optional.
1786 # --with-sysroot (or --with-sysroot=yes) sets the default sysroot path.
1787 if test "x$with_sysroot" = xyes; then
1788   with_sysroot="${exec_prefix}/${target_alias}/sys-root"
1789 fi
1790 AC_ARG_WITH(sysroot,
1791   AS_HELP_STRING([--with-sysroot@<:@=DIR@:>@],
1792                  [search for usr/lib et al within DIR]),
1793   [TARGET_SYSTEM_ROOT=$withval], [TARGET_SYSTEM_ROOT=])
1794 AC_DEFINE_DIR(TARGET_SYSTEM_ROOT, TARGET_SYSTEM_ROOT,
1795               [search for usr/lib et al within DIR])
1796 AC_SUBST(TARGET_SYSTEM_ROOT)
1797 GDB_AC_DEFINE_RELOCATABLE(TARGET_SYSTEM_ROOT, sysroot, ${ac_define_dir})
1798
1799 GDB_AC_WITH_DIR(SYSTEM_GDBINIT, system-gdbinit,
1800     [automatically load a system-wide gdbinit file],
1801     [])
1802
1803 AC_ARG_ENABLE(werror,
1804   AS_HELP_STRING([--enable-werror], [treat compile warnings as errors]),
1805   [case "${enableval}" in
1806      yes | y) ERROR_ON_WARNING="yes" ;;
1807      no | n)  ERROR_ON_WARNING="no" ;;
1808      *) AC_MSG_ERROR(bad value ${enableval} for --enable-werror) ;;
1809    esac])
1810
1811 # Enable -Werror by default when using gcc
1812 if test "${GCC}" = yes -a -z "${ERROR_ON_WARNING}" ; then
1813     ERROR_ON_WARNING=yes
1814 fi
1815
1816 WERROR_CFLAGS=""
1817 if test "${ERROR_ON_WARNING}" = yes ; then
1818     WERROR_CFLAGS="-Werror"
1819 fi
1820
1821 # The entries after -Wno-pointer-sign are disabled warnings which may
1822 # be enabled in the future, which can not currently be used to build
1823 # GDB.
1824 # NOTE: If you change this list, remember to update
1825 # gdb/doc/gdbint.texinfo.
1826 build_warnings="-Wall -Wdeclaration-after-statement -Wpointer-arith \
1827 -Wformat-nonliteral -Wno-pointer-sign \
1828 -Wno-unused -Wunused-value -Wunused-function \
1829 -Wno-switch -Wno-char-subscripts -Wmissing-prototypes"
1830
1831 # Enable -Wno-format by default when using gcc on mingw since many
1832 # GCC versions complain about %I64.
1833 case "${host}" in
1834   *-*-mingw32*) build_warnings="$build_warnings -Wno-format" ;;
1835 esac
1836
1837 AC_ARG_ENABLE(build-warnings,
1838 AS_HELP_STRING([--enable-build-warnings], [enable build-time compiler warnings if gcc is used]),
1839 [case "${enableval}" in
1840   yes)  ;;
1841   no)   build_warnings="-w";;
1842   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1843         build_warnings="${build_warnings} ${t}";;
1844   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1845         build_warnings="${t} ${build_warnings}";;
1846   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1847 esac
1848 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1849   echo "Setting compiler warning flags = $build_warnings" 6>&1
1850 fi])dnl
1851 AC_ARG_ENABLE(gdb-build-warnings,
1852 AS_HELP_STRING([--enable-gdb-build-warnings], [enable GDB specific build-time compiler warnings if gcc is used]),
1853 [case "${enableval}" in
1854   yes)  ;;
1855   no)   build_warnings="-w";;
1856   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1857         build_warnings="${build_warnings} ${t}";;
1858   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1859         build_warnings="${t} ${build_warnings}";;
1860   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1861 esac
1862 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1863   echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1
1864 fi])dnl
1865 WARN_CFLAGS=""
1866 if test "x${build_warnings}" != x -a "x$GCC" = xyes
1867 then
1868     AC_MSG_CHECKING(compiler warning flags)
1869     # Separate out the -Werror flag as some files just cannot be
1870     # compiled with it enabled.
1871     for w in ${build_warnings}; do
1872         case $w in
1873         -Werr*) WERROR_CFLAGS=-Werror ;;
1874         *) # Check that GCC accepts it
1875             saved_CFLAGS="$CFLAGS"
1876             CFLAGS="$CFLAGS $w"
1877             AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
1878             CFLAGS="$saved_CFLAGS"
1879         esac
1880     done
1881     AC_MSG_RESULT(${WARN_CFLAGS} ${WERROR_CFLAGS})
1882 fi
1883 AC_SUBST(WARN_CFLAGS)
1884 AC_SUBST(WERROR_CFLAGS)
1885
1886 # In the Cygwin environment, we need some additional flags.
1887 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1888 [AC_EGREP_CPP(lose, [
1889 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1890 lose
1891 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1892
1893
1894 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1895 SER_HARDWIRE="ser-base.o ser-unix.o ser-pipe.o ser-tcp.o"
1896 case ${host} in
1897   *go32* ) SER_HARDWIRE=ser-go32.o ;;
1898   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
1899   *mingw32*) SER_HARDWIRE="ser-base.o ser-tcp.o ser-mingw.o" ;;
1900 esac
1901 AC_SUBST(SER_HARDWIRE)
1902
1903 # libreadline needs libuser32.a in a cygwin environment
1904 WIN32LIBS=
1905 if test x$gdb_cv_os_cygwin = xyes; then
1906     WIN32LIBS="-luser32"
1907     case "${target}" in
1908         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
1909         ;;
1910     esac
1911 fi
1912
1913 # The ser-tcp.c module requires sockets.
1914 case ${host} in
1915   *mingw32*)
1916     AC_DEFINE(USE_WIN32API, 1,
1917               [Define if we should use the Windows API, instead of the
1918                POSIX API.  On Windows, we use the Windows API when
1919                building for MinGW, but the POSIX API when building
1920                for Cygwin.])
1921     WIN32LIBS="$WIN32LIBS -lws2_32"
1922     ;;
1923 esac
1924 AC_SUBST(WIN32LIBS)
1925
1926 # Add ELF support to GDB, but only if BFD includes ELF support.
1927 OLD_CFLAGS=$CFLAGS
1928 OLD_LDFLAGS=$LDFLAGS
1929 OLD_LIBS=$LIBS
1930 # Put the old CFLAGS/LDFLAGS last, in case the user's (C|LD)FLAGS
1931 # points somewhere with bfd, with -I/foo/lib and -L/foo/lib.  We
1932 # always want our bfd.
1933 CFLAGS="-I${srcdir}/../include -I../bfd -I${srcdir}/../bfd $CFLAGS"
1934 LDFLAGS="-L../bfd -L../libiberty $LDFLAGS"
1935 intl=`echo $LIBINTL | sed 's,${top_builddir}/,,g'`
1936 # -ldl is provided by bfd/Makfile.am (LIBDL) <PLUGINS>.
1937 if test "$plugins" = "yes"; then
1938   LIBS="-ldl $LIBS"
1939 fi
1940 LIBS="-lbfd -liberty $intl $LIBS"
1941 AC_CACHE_CHECK([for ELF support in BFD], gdb_cv_var_elf,
1942 [AC_TRY_LINK(
1943 [#include <stdlib.h>
1944 #include "bfd.h"
1945 #include "elf-bfd.h"
1946 ],
1947 [bfd *abfd = NULL; bfd_get_elf_phdr_upper_bound (abfd); ],
1948 gdb_cv_var_elf=yes, gdb_cv_var_elf=no)])
1949 if test $gdb_cv_var_elf = yes; then
1950   CONFIG_OBS="$CONFIG_OBS elfread.o"
1951   AC_DEFINE(HAVE_ELF, 1,
1952             [Define if ELF support should be included.])
1953   # -ldl is provided by bfd/Makfile.am (LIBDL) <PLUGINS>.
1954   if test "$plugins" = "yes"; then
1955     OLD_LIBS="-ldl $OLD_LIBS"
1956   fi
1957 fi
1958 CFLAGS=$OLD_CFLAGS
1959 LDFLAGS=$OLD_LDFLAGS
1960 LIBS=$OLD_LIBS
1961
1962 # Add any host-specific objects to GDB.
1963 CONFIG_OBS="${CONFIG_OBS} ${gdb_host_obs}"
1964
1965 LIBGUI="../libgui/src/libgui.a"
1966 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
1967 AC_SUBST(LIBGUI)
1968 AC_SUBST(GUI_CFLAGS_X)
1969
1970 WIN32LDAPP=
1971 AC_SUBST(WIN32LIBS)
1972 AC_SUBST(WIN32LDAPP)
1973
1974 case "${host}" in
1975 *-*-cygwin* | *-*-mingw* )
1976     configdir="win"
1977     ;;
1978 *)
1979     configdir="unix"
1980     ;;
1981 esac
1982
1983 GDBTKLIBS=
1984 if test "${enable_gdbtk}" = "yes"; then
1985
1986     # Gdbtk must have an absolute path to srcdir in order to run
1987     # properly when not installed.
1988     here=`pwd`
1989     cd ${srcdir}
1990     GDBTK_SRC_DIR=`pwd`
1991     cd $here
1992
1993     SC_PATH_TCLCONFIG
1994
1995     # If $no_tk is nonempty, then we can't do Tk, and there is no
1996     # point to doing Tcl.
1997     SC_PATH_TKCONFIG
1998
1999     if test -z "${no_tcl}" -a -z "${no_tk}"; then
2000         SC_LOAD_TCLCONFIG
2001
2002         # Check for in-tree tcl
2003         here=`pwd`
2004         cd ${srcdir}/..
2005         topdir=`pwd`
2006         cd ${here}
2007
2008         intree="no"
2009         if test "${TCL_SRC_DIR}" = "${topdir}/tcl"; then
2010           intree="yes"
2011         fi
2012
2013         # Find Tcl private headers
2014         if test x"${intree}" = xno; then
2015           CY_AC_TCL_PRIVATE_HEADERS
2016           TCL_INCLUDE="${TCL_INCLUDE_SPEC} ${TCL_PRIVATE_INCLUDE}"
2017           TCL_LIBRARY="${TCL_LIB_SPEC}"
2018           TCL_DEPS=""
2019         else
2020           # If building tcl in the same src tree, private headers
2021           # are not needed, but we need to be sure to use the right
2022           # headers library
2023           TCL_INCLUDE="-I${TCL_SRC_DIR}/generic"
2024           TCL_LIBRARY="${TCL_BUILD_LIB_SPEC}"
2025           TCL_DEPS="../tcl/${configdir}${TCL_LIB_FILE}"
2026         fi
2027         AC_SUBST(TCL_INCLUDE)
2028         AC_SUBST(TCL_LIBRARY)
2029         AC_SUBST(TCL_DEPS)
2030
2031         SC_LOAD_TKCONFIG
2032
2033         # Check for in-tree Tk
2034         intree="no"
2035         if test "${TK_SRC_DIR}" = "${topdir}/tk"; then
2036           intree="yes"
2037         fi
2038
2039         # Find Tk private headers
2040         if test x"${intree}" = xno; then
2041           CY_AC_TK_PRIVATE_HEADERS
2042           TK_INCLUDE="${TK_INCLUDE_SPEC} ${TK_PRIVATE_INCLUDE}"
2043           TK_LIBRARY=${TK_LIB_SPEC}
2044           TK_DEPS=""
2045         else
2046           TK_INCLUDE="-I${TK_SRC_DIR}/generic"
2047           TK_LIBRARY="${TK_BUILD_LIB_SPEC}"
2048           TK_DEPS="../tk/${configdir}/${TK_LIB_FILE}"
2049         fi
2050         AC_SUBST(TK_INCLUDE)
2051         AC_SUBST(TK_LIBRARY)
2052         AC_SUBST(TK_DEPS)
2053         AC_SUBST(TK_XINCLUDES)
2054
2055         ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
2056
2057         # Include some libraries that Tcl and Tk want.
2058         TCL_LIBS='$(LIBGUI) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
2059         # Yes, the ordering seems wrong here.  But it isn't.
2060         # TK_LIBS is the list of libraries that need to be linked
2061         # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
2062         # were in LIBS then any link tests after this point would
2063         # try to include things like `$(LIBGUI)', which wouldn't work.
2064         GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
2065
2066         CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
2067         CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
2068         CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
2069         CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
2070         CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
2071         CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
2072         CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
2073
2074         if test x$gdb_cv_os_cygwin = xyes; then
2075           WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
2076           WIN32LDAPP="-Wl,--subsystem,console"
2077           CONFIG_OBS="${CONFIG_OBS} gdbres.o"
2078         fi
2079
2080         AC_CONFIG_SUBDIRS(gdbtk)
2081     fi
2082 fi
2083
2084 AC_SUBST(X_CFLAGS)
2085 AC_SUBST(X_LDFLAGS)
2086 AC_SUBST(X_LIBS)
2087 AC_SUBST(GDBTKLIBS)
2088 AC_SUBST(GDBTK_CFLAGS)
2089 AC_SUBST(GDBTK_SRC_DIR)
2090
2091 AC_PATH_X
2092
2093 # Unlike the sim directory, whether a simulator is linked is controlled by
2094 # presence of a gdb_sim definition in the target configure.tgt entry.
2095 # This code just checks for a few cases where we'd like to ignore those
2096 # definitions, even when they're present in the '.mt' file.  These cases
2097 # are when --disable-sim is specified, or if the simulator directory is
2098 # not part of the source tree.
2099 #
2100 AC_ARG_ENABLE(sim,
2101 AS_HELP_STRING([--enable-sim], [link gdb with simulator]),
2102 [echo "enable_sim = $enable_sim";
2103  echo "enableval = ${enableval}";
2104  case "${enableval}" in
2105   yes) ignore_sim=false ;;
2106   no)  ignore_sim=true ;;
2107   *)   ignore_sim=false ;;
2108  esac],
2109 [ignore_sim=false])
2110
2111 if test ! -d "${srcdir}/../sim"; then
2112   ignore_sim=true
2113 fi
2114
2115 SIM=
2116 SIM_OBS=
2117 if test "${ignore_sim}" = "false"; then
2118   if test x"${gdb_sim}" != x ; then
2119     SIM="${gdb_sim}"
2120     SIM_OBS="remote-sim.o"
2121     AC_DEFINE(WITH_SIM, 1, [Define if the simulator is being linked in.])
2122   fi
2123 fi
2124 AC_SUBST(SIM)
2125 AC_SUBST(SIM_OBS)
2126
2127 AC_SUBST(ENABLE_CFLAGS)
2128 AC_SUBST(PROFILE_CFLAGS)
2129
2130 AC_SUBST(CONFIG_OBS)
2131 AC_SUBST(CONFIG_DEPS)
2132 AC_SUBST(CONFIG_SRCS)
2133 AC_SUBST(CONFIG_ALL)
2134 AC_SUBST(CONFIG_CLEAN)
2135 AC_SUBST(CONFIG_INSTALL)
2136 AC_SUBST(CONFIG_UNINSTALL)
2137
2138 # List of host floatformats.
2139 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
2140 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
2141 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
2142
2143 # target_subdir is used by the testsuite to find the target libraries.
2144 target_subdir=
2145 if test "${host}" != "${target}"; then
2146     target_subdir="${target_alias}/"
2147 fi
2148 AC_SUBST(target_subdir)
2149
2150 frags=
2151 if test "${gdb_native}" = "yes"; then
2152   host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
2153   if test ! -f ${host_makefile_frag}; then
2154     AC_MSG_ERROR("*** Gdb does not support native target ${host}")
2155   fi
2156   frags="$frags $host_makefile_frag"
2157 else
2158   host_makefile_frag=/dev/null
2159 fi
2160
2161 AC_SUBST_FILE(host_makefile_frag)
2162 AC_SUBST(frags)
2163
2164 changequote(,)dnl
2165 if test "${gdb_native}" = "yes"; then
2166 # We pick this up from the host configuration file (.mh) because we
2167 # do not have a native configuration Makefile fragment.
2168 nativefile=`sed -n '
2169 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
2170 ' ${host_makefile_frag}`
2171 fi
2172 changequote([,])
2173
2174 if test x"${gdb_osabi}" != x ; then
2175     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
2176                        [Define to the default OS ABI for this configuration.])
2177 fi
2178
2179 # Enable multi-ice-gdb-server.
2180 AC_ARG_ENABLE(multi-ice,
2181 AS_HELP_STRING([--enable-multi-ice], [build the multi-ice-gdb-server]),
2182   [case $enableval in
2183     yes | no)
2184       ;;
2185     *) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;;
2186   esac])
2187 if test "x$enable_multi_ice" = xyes; then
2188    AC_CONFIG_SUBDIRS(multi-ice)
2189 fi
2190
2191 AC_ARG_ENABLE(gdbserver,
2192 AS_HELP_STRING([--enable-gdbserver],
2193                [automatically build gdbserver (yes/no/auto, default is auto)]),
2194 [case "${enableval}" in
2195   yes| no|auto) ;;
2196   *) AC_MSG_ERROR(bad value ${enableval} for --enable-gdbserver option) ;;
2197 esac],[enable_gdbserver=auto])
2198
2199 # We only build gdbserver automatically in a native configuration, and
2200 # only if the user did not explicitly disable its build.
2201 if test "$gdb_native" = "yes" -a "$enable_gdbserver" != "no"; then
2202   AC_MSG_CHECKING(whether gdbserver is supported on this host)
2203   if test "x$build_gdbserver" = xyes; then
2204     AC_MSG_RESULT(yes)
2205     AC_CONFIG_SUBDIRS(gdbserver)
2206     gdbserver_build_enabled=yes
2207   else
2208     AC_MSG_RESULT(no)
2209   fi
2210 fi
2211
2212 # If the user explicitly request the gdbserver to be built, verify that
2213 # we were in fact able to enable it.
2214 if test "$enable_gdbserver" = "yes" -a "$gdbserver_build_enabled" != "yes"; then
2215   AC_MSG_ERROR(Automatic gdbserver build is not supported for this configuration)
2216 fi
2217
2218 # If nativefile (NAT_FILE) is not set in config/*/*.m[ht] files, we link
2219 # to an empty version.
2220
2221 files=
2222 links=
2223
2224 rm -f nm.h
2225 if test "${nativefile}" != ""; then
2226     case "${nativefile}" in
2227       nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
2228       * ) GDB_NM_FILE="${nativefile}"
2229     esac
2230     files="${files} ${GDB_NM_FILE}"
2231     links="${links} nm.h"
2232     AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}", [nativefile])
2233 fi
2234 AC_SUBST(GDB_NM_FILE)
2235
2236 AC_LINK_FILES($files, $links)
2237
2238 dnl Check for exe extension set on certain hosts (e.g. Win32)
2239 AC_EXEEXT
2240
2241 dnl  Detect the character set used by this host.
2242 dnl  At the moment, we just assume it's UTF-8.
2243 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "UTF-8",
2244           [Define to be a string naming the default host character set.])
2245
2246 AC_OUTPUT(Makefile gdb-gdb.gdb doc/Makefile data-directory/Makefile,
2247 [
2248 case x$CONFIG_HEADERS in
2249 xconfig.h:config.in)
2250 echo > stamp-h ;;
2251 esac
2252 ])
2253
2254 exit 0