gdb/configure.ac

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995-2017 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Process this file with autoconf to produce a configure script.
  20
  21 AC_PREREQ(2.59)dnl
  22 AC_INIT(main.c)
  23 AC_CONFIG_HEADER(config.h:config.in)
  24 AM_MAINTAINER_MODE
  25
  26 # Set the 'development' global.
  27 . $srcdir/../bfd/development.sh
  28
  29 AC_PROG_CC
  30 AC_PROG_CXX
  31
  32 AC_USE_SYSTEM_EXTENSIONS
  33 ACX_LARGEFILE
  34 AM_PROG_CC_STDC
  35 AM_PROG_INSTALL_STRIP
  36
  37 AC_CONFIG_AUX_DIR(..)
  38 AC_CANONICAL_SYSTEM
  39 AC_ARG_PROGRAM
  40
  41 # We require a C++11 compiler.  Check if one is available, and if
  42 # necessary, set CXX_DIALECT to some -std=xxx switch.
  43 AX_CXX_COMPILE_STDCXX(11, , mandatory)
  44
  45 # Dependency checking.
  46 ZW_CREATE_DEPDIR
  47 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  48
  49 gnulib_extra_configure_args=
  50 # If large-file support is disabled, make sure gnulib does the same.
  51 if test "$enable_largefile" = no; then
  52 gnulib_extra_configure_args="$gnulib_extra_configure_args --disable-largefile"
  53 fi
  54
  55 # Configure gnulib.  We need to build gnulib under some other
  56 # directory not "gnulib", to avoid the problem of both GDB and
  57 # GDBserver wanting to build it in the same directory, when building
  58 # in the source dir.
  59 ACX_CONFIGURE_DIR(["gnulib"], ["build-gnulib"],
  60                   ["$gnulib_extra_configure_args"])
  61
  62 dnl List of object files and targets accumulated by configure.
  63
  64 CONFIG_OBS=
  65 CONFIG_DEPS=
  66 CONFIG_SRCS=
  67 ENABLE_CFLAGS=
  68
  69 CONFIG_ALL=
  70 CONFIG_CLEAN=
  71 CONFIG_INSTALL=
  72 CONFIG_UNINSTALL=
  73
  74 dnl Set up for gettext.
  75 ZW_GNU_GETTEXT_SISTER_DIR
  76
  77 localedir='${datadir}/locale'
  78 AC_SUBST(localedir)
  79
  80 if test x"$USE_NLS" = xyes; then
  81    CONFIG_ALL="$CONFIG_ALL all-po"
  82    CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
  83    CONFIG_INSTALL="$CONFIG_INSTALL install-po"
  84    CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
  85 fi
  86
  87 GNULIB=build-gnulib/import
  88
  89 # For Makefile dependencies.
  90 GNULIB_STDINT_H=
  91 if test x"$STDINT_H" != x; then
  92   GNULIB_STDINT_H=$GNULIB/$STDINT_H
  93 fi
  94 AC_SUBST(GNULIB_STDINT_H)
  95
  96 PACKAGE=gdb
  97 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
  98 AC_SUBST(PACKAGE)
  99
 100 # We never need to detect it in this sub-configure.
 101 # But preserve it for config.status --recheck.
 102 AC_ARG_VAR(MAKEINFO,
 103   [Parent configure detects if it is of sufficient version.])
 104 AC_ARG_VAR(MAKEINFOFLAGS,
 105   [Parameters for MAKEINFO.])
 106
 107 MAKEINFO_EXTRA_FLAGS=""
 108 AC_CACHE_CHECK([whether $MAKEINFO supports @click], gdb_cv_have_makeinfo_click,
 109   [echo '@clicksequence{a @click{} b}' >conftest.texinfo
 110   if eval "$MAKEINFO conftest.texinfo >&5 2>&5"; then
 111     gdb_cv_have_makeinfo_click=yes
 112   else
 113     gdb_cv_have_makeinfo_click=no
 114   fi])
 115 if test x"$gdb_cv_have_makeinfo_click" = xyes; then
 116   MAKEINFO_EXTRA_FLAGS="$MAKEINFO_EXTRA_FLAGS -DHAVE_MAKEINFO_CLICK"
 117 fi
 118 AC_SUBST(MAKEINFO_EXTRA_FLAGS)
 119
 120 GDB_AC_WITH_DIR(DEBUGDIR, separate-debug-dir,
 121     [look for global separate debug info in this path @<:@LIBDIR/debug@:>@],
 122     [${libdir}/debug])
 123
 124 # We can't pass paths as command line arguments.
 125 # Mingw32 tries to be clever and will convert the paths for us.
 126 # For example -DBINDIR="/usr/local/bin" passed on the command line may get
 127 # converted to -DBINDIR="E:/msys/mingw32/msys/1.0/local/bin".
 128 # This breaks GDB's relocatable path conversions since paths passed in
 129 # config.h would not get so translated, the path prefixes no longer match.
 130 AC_DEFINE_DIR(BINDIR, bindir, [Directory of programs.])
 131
 132 # GDB's datadir relocation
 133
 134 GDB_AC_WITH_DIR(GDB_DATADIR, gdb-datadir,
 135     [look for global separate data files in this path @<:@DATADIR/gdb@:>@],
 136     [${datadir}/gdb])
 137
 138 AC_ARG_WITH(relocated-sources,
 139 AS_HELP_STRING([--with-relocated-sources=PATH], [automatically relocate this path for source files]),
 140 [reloc_srcdir="${withval}"
 141  AC_DEFINE_DIR(RELOC_SRCDIR, reloc_srcdir,
 142               [Relocated directory for source files. ])
 143 ])
 144
 145 AC_MSG_CHECKING([for default auto-load directory])
 146 AC_ARG_WITH(auto-load-dir,
 147 AS_HELP_STRING([--with-auto-load-dir=PATH],
 148   [directories from which to load auto-loaded scripts @<:@$debugdir:$datadir/auto-load@:>@]),,
 149   [with_auto_load_dir='$debugdir:$datadir/auto-load'])
 150 escape_dir=`echo $with_auto_load_dir | sed 's/[[$]]\(datadir\|debugdir\)\>/\\\\\\\\\\\\&/g'`
 151 AC_DEFINE_DIR(AUTO_LOAD_DIR, escape_dir,
 152               [Directories from which to load auto-loaded scripts.])
 153 AC_MSG_RESULT([$with_auto_load_dir])
 154
 155 AC_MSG_CHECKING([for default auto-load safe-path])
 156 AC_ARG_WITH(auto-load-safe-path,
 157 AS_HELP_STRING([--with-auto-load-safe-path=PATH],
 158   [directories safe to hold auto-loaded files @<:@--with-auto-load-dir@:>@])
 159 AS_HELP_STRING([--without-auto-load-safe-path],
 160                [do not restrict auto-loaded files locations]),
 161     [if test "$with_auto_load_safe_path" = "no"; then
 162      with_auto_load_safe_path="/"
 163      fi],
 164 [with_auto_load_safe_path="$with_auto_load_dir"])
 165 escape_dir=`echo $with_auto_load_safe_path | sed 's/[[$]]\(datadir\|debugdir\)\>/\\\\\\\\\\\\&/g'`
 166 AC_DEFINE_DIR(AUTO_LOAD_SAFE_PATH, escape_dir,
 167               [Directories safe to hold auto-loaded files.])
 168 AC_MSG_RESULT([$with_auto_load_safe_path])
 169
 170 AC_CONFIG_SUBDIRS(testsuite)
 171
 172 # Check whether to support alternative target configurations
 173 AC_ARG_ENABLE(targets,
 174 AS_HELP_STRING([--enable-targets=TARGETS], [alternative target configurations]),
 175 [case "${enableval}" in
 176   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
 177             ;;
 178   no)       enable_targets= ;;
 179   *)        enable_targets=$enableval ;;
 180 esac])
 181
 182 # Check whether to enable 64-bit support on 32-bit hosts
 183 AC_ARG_ENABLE(64-bit-bfd,
 184 AS_HELP_STRING([--enable-64-bit-bfd], [64-bit support (on hosts with narrower word sizes)]),
 185 [case "${enableval}" in
 186   yes)  want64=true  ;;
 187   no)   want64=false ;;
 188   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
 189 esac],[want64=false])dnl
 190
 191 # Provide defaults for some variables set by the per-host and per-target
 192 # configuration.
 193 gdb_host_obs=posix-hdep.o
 194
 195 if test "${target}" = "${host}"; then
 196   gdb_native=yes
 197 else
 198   gdb_native=no
 199 fi
 200
 201 . $srcdir/configure.host
 202
 203 # Add in the common host objects.
 204 . $srcdir/common/common.host
 205 gdb_host_obs="$gdb_host_obs $common_host_obs"
 206
 207 # Accumulate some settings from configure.tgt over all enabled targets
 208
 209 TARGET_OBS=
 210 all_targets=
 211 HAVE_NATIVE_GCORE_TARGET=
 212
 213 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 214 do
 215   if test "$targ_alias" = "all"; then
 216     all_targets=true
 217   else
 218     # Canonicalize the secondary target names.
 219     result=`$ac_config_sub $targ_alias 2>/dev/null`
 220     if test -n "$result"; then
 221         targ=$result
 222     else
 223         targ=$targ_alias
 224     fi
 225
 226     . ${srcdir}/configure.tgt
 227
 228     AS_IF([test -z "${gdb_target_obs}"],
 229       [AC_MSG_ERROR([configuration ${targ} is unsupported.])])
 230
 231     # Target-specific object files
 232     for i in ${gdb_target_obs}; do
 233         case " $TARGET_OBS " in
 234         *" ${i} "*) ;;
 235         *)
 236           TARGET_OBS="$TARGET_OBS ${i}"
 237           ;;
 238         esac
 239     done
 240
 241     # Check whether this target needs 64-bit CORE_ADDR
 242     if test x${want64} = xfalse; then
 243       . ${srcdir}/../bfd/config.bfd
 244     fi
 245
 246     # Check whether this target is native and supports gcore.
 247     if test $gdb_native = yes -a "$targ_alias" = "$target_alias" \
 248        && $gdb_have_gcore; then
 249       HAVE_NATIVE_GCORE_TARGET=1
 250     fi
 251   fi
 252 done
 253
 254 if test x${all_targets} = xtrue; then
 255
 256   # We want all 64-bit targets if we either:
 257   #  - run on a 64-bit host  or
 258   #  - already require 64-bit support for some other target  or
 259   #  - the --enable-64-bit-bfd option was supplied
 260   # Otherwise we only support all 32-bit targets.
 261   #
 262   # NOTE: This test must be in sync with the corresponding
 263   #       tests in BFD!
 264
 265   if test x${want64} = xfalse; then
 266     AC_CHECK_SIZEOF(long)
 267     if test "x${ac_cv_sizeof_long}" = "x8"; then
 268       want64=true
 269     fi
 270   fi
 271   if test x${want64} = xtrue; then
 272     TARGET_OBS='$(ALL_TARGET_OBS) $(ALL_64_TARGET_OBS)'
 273   else
 274     TARGET_OBS='$(ALL_TARGET_OBS)'
 275   fi
 276 fi
 277
 278 AC_SUBST(TARGET_OBS)
 279 AC_SUBST(HAVE_NATIVE_GCORE_TARGET)
 280
 281 # For other settings, only the main target counts.
 282 gdb_sim=
 283 gdb_osabi=
 284 build_gdbserver=
 285 targ=$target; . ${srcdir}/configure.tgt
 286
 287 # Fetch the default architecture and default target vector from BFD.
 288 targ=$target; . $srcdir/../bfd/config.bfd
 289
 290 # We only want the first architecture, so strip off the others if
 291 # there is more than one.
 292 targ_archs=`echo $targ_archs | sed 's/ .*//'`
 293
 294 if test "x$targ_archs" != x; then
 295   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
 296     [Define to BFD's default architecture. ])
 297 fi
 298 if test "x$targ_defvec" != x; then
 299   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
 300     [Define to BFD's default target vector. ])
 301 fi
 302
 303 # The CLI cannot be disabled yet, but may be in the future.
 304
 305 # Enable CLI.
 306 AC_ARG_ENABLE(gdbcli,
 307 AS_HELP_STRING([--disable-gdbcli], [disable command-line interface (CLI)]),
 308   [case $enableval in
 309     yes)
 310       ;;
 311     no)
 312       AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;;
 313     *)
 314       AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;;
 315   esac],
 316   [enable_gdbcli=yes])
 317 if test x"$enable_gdbcli" = xyes; then
 318   if test -d $srcdir/cli; then
 319     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)"
 320     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)"
 321     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)"
 322     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)"
 323   fi
 324 fi
 325
 326 # Enable MI.
 327 AC_ARG_ENABLE(gdbmi,
 328 AS_HELP_STRING([--disable-gdbmi], [disable machine-interface (MI)]),
 329   [case $enableval in
 330     yes | no)
 331       ;;
 332     *)
 333       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 334   esac],
 335   [enable_gdbmi=yes])
 336 if test x"$enable_gdbmi" = xyes; then
 337   if test -d $srcdir/mi; then
 338     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 339     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 340     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 341     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 342   fi
 343 fi
 344
 345 # Enable TUI.
 346 AC_ARG_ENABLE(tui,
 347 AS_HELP_STRING([--enable-tui], [enable full-screen terminal user interface (TUI)]),
 348   [case $enableval in
 349     yes | no | auto)
 350       ;;
 351     *)
 352       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 353   esac],enable_tui=auto)
 354
 355 # Enable gdbtk.
 356 AC_ARG_ENABLE(gdbtk,
 357 AS_HELP_STRING([--enable-gdbtk], [enable gdbtk graphical user interface (GUI)]),
 358   [case $enableval in
 359     yes | no)
 360       ;;
 361     *)
 362       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 363   esac],
 364   [if test -d $srcdir/gdbtk; then
 365     enable_gdbtk=yes
 366   else
 367     enable_gdbtk=no
 368   fi])
 369 # We unconditionally disable gdbtk tests on selected platforms.
 370 case $host_os in
 371   go32* | windows*)
 372     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 373     enable_gdbtk=no ;;
 374 esac
 375
 376 # Libunwind support for ia64.
 377
 378 AC_ARG_WITH(libunwind-ia64,
 379 AS_HELP_STRING([--with-libunwind-ia64],
 380                [use libunwind frame unwinding for ia64 targets]),,
 381             [with_libunwind_ia64=auto])
 382
 383 # Backward compatibility option.
 384 if test "${with_libunwind+set}" = set; then
 385   if test x"$with_libunwind_ia64" != xauto; then
 386     AC_MSG_ERROR(
 387       [option --with-libunwind is deprecated, use --with-libunwind-ia64])
 388   fi
 389   AC_MSG_WARN([option --with-libunwind is deprecated, use --with-libunwind-ia64])
 390   with_libunwind_ia64="$with_libunwind"
 391 fi
 392
 393 case "$with_libunwind_ia64" in
 394   yes | no)
 395     ;;
 396   auto)
 397     AC_CHECK_HEADERS(libunwind-ia64.h)
 398     with_libunwind_ia64=$ac_cv_header_libunwind_ia64_h
 399     ;;
 400   *)
 401     AC_MSG_ERROR(
 402       [bad value $with_libunwind_ia64 for GDB --with-libunwind-ia64 option])
 403     ;;
 404 esac
 405
 406 if test x"$with_libunwind_ia64" = xyes; then
 407   AC_CHECK_HEADERS(libunwind-ia64.h)
 408   if test x"$ac_cv_header_libunwind_ia64_h" != xyes; then
 409     AC_MSG_ERROR([GDB option --with-libunwind-ia64 requires libunwind-ia64.h])
 410   fi
 411   CONFIG_OBS="$CONFIG_OBS ia64-libunwind-tdep.o"
 412   CONFIG_DEPS="$CONFIG_DEPS ia64-libunwind-tdep.o"
 413   CONFIG_SRCS="$CONFIG_SRCS ia64-libunwind-tdep.c"
 414 fi
 415
 416 opt_curses=no
 417 AC_ARG_WITH(curses, AS_HELP_STRING([--with-curses], [use the curses library instead of the termcap library]), opt_curses=$withval)
 418
 419 prefer_curses=no
 420 if test "$opt_curses" = "yes"; then
 421   prefer_curses=yes
 422 fi
 423
 424 # Profiling support.
 425 AC_ARG_ENABLE(profiling,
 426 AS_HELP_STRING([--enable-profiling], [enable profiling of GDB]),
 427   [case $enableval in
 428     yes | no)
 429       ;;
 430     *)
 431       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 432   esac],
 433  [enable_profiling=no])
 434
 435 AC_CHECK_FUNCS(monstartup _mcleanup)
 436 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 437 [AC_TRY_LINK(
 438 [#include <stdlib.h>
 439 extern char _etext;
 440 ],
 441 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 442 if test $ac_cv_var__etext = yes; then
 443   AC_DEFINE(HAVE__ETEXT, 1,
 444             [Define to 1 if your system has the _etext variable. ])
 445 fi
 446 AC_CACHE_CHECK([for etext], ac_cv_var_etext,
 447 [AC_TRY_LINK(
 448 [#include <stdlib.h>
 449 extern char etext;
 450 ],
 451 [free (&etext);], ac_cv_var_etext=yes, ac_cv_var_etext=no)])
 452 if test $ac_cv_var_etext = yes; then
 453   AC_DEFINE(HAVE_ETEXT, 1,
 454             [Define to 1 if your system has the etext variable. ])
 455 fi
 456 if test "$enable_profiling" = yes ; then
 457   if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
 458     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 459   fi
 460   PROFILE_CFLAGS=-pg
 461   OLD_CFLAGS="$CFLAGS"
 462   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 463
 464   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 465     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 466      ac_cv_cc_supports_pg=no)])
 467
 468   if test $ac_cv_cc_supports_pg = no; then
 469     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 470   fi
 471
 472   CFLAGS="$OLD_CFLAGS"
 473 fi
 474
 475 ACX_PKGVERSION([GDB])
 476 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 477 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 478 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 479
 480 # --------------------- #
 481 # Checks for programs.  #
 482 # --------------------- #
 483
 484 AC_PROG_AWK
 485 AC_PROG_INSTALL
 486 AC_PROG_LN_S
 487 AC_PROG_RANLIB
 488 AC_PROG_YACC
 489
 490 AC_CHECK_TOOL(AR, ar)
 491 AC_CHECK_TOOL(DLLTOOL, dlltool)
 492 AC_CHECK_TOOL(WINDRES, windres)
 493
 494 case $host_os in
 495   gnu*)
 496     # Needed for GNU Hurd hosts.
 497     AC_CHECK_TOOL(MIG, mig)
 498     if test x"$MIG" = x; then
 499       AC_MSG_ERROR([MIG not found but required for $host hosts])
 500     fi
 501     ;;
 502 esac
 503
 504 # ---------------------- #
 505 # Checks for libraries.  #
 506 # ---------------------- #
 507
 508 # We might need to link with -lm; most simulators need it.
 509 AC_CHECK_LIB(m, main)
 510
 511 # We need to link with -lw to get `wctype' on Solaris before Solaris
 512 # 2.6.  Solaris 2.6 and beyond have this function in libc, and have a
 513 # libw that some versions of the GNU linker cannot hanle (GNU ld 2.9.1
 514 # is known to have this problem).  Therefore we avoid libw if we can.
 515 AC_CHECK_FUNC(wctype, [],
 516   [AC_CHECK_LIB(w, wctype)])
 517
 518 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 519 AC_SEARCH_LIBS(gethostbyname, nsl)
 520
 521 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 522 AC_SEARCH_LIBS(socketpair, socket)
 523
 524 # Link in zlib if we can.  This allows us to read compressed debug sections.
 525 AM_ZLIB
 526
 527 # On FreeBSD we may need libutil for kinfo_getvmmap (used by fbsd-nat.c).
 528 # On GNU/kFreeBSD systems, FreeBSD libutil is renamed to libutil-freebsd.
 529 AC_SEARCH_LIBS(kinfo_getvmmap, util util-freebsd,
 530   [AC_DEFINE(HAVE_KINFO_GETVMMAP, 1,
 531             [Define to 1 if your system has the kinfo_getvmmap function. ])])
 532
 533 AM_ICONV
 534
 535 # GDB may fork/exec the iconv program to get the list of supported character
 536 # sets.  Allow the user to specify where to find it.
 537 # There are several factors affecting the choice of option name:
 538 # - There is already --with-libiconv-prefix but we can't use it, it specifies
 539 #   the build-time location of libiconv files.
 540 # - The program we need to find is iconv, which comes with glibc.  The user
 541 #   doesn't necessarily have libiconv installed.  Therefore naming this
 542 #   --with-libiconv-foo feels wrong.
 543 # - We want the path to be relocatable, but GDB_AC_DEFINE_RELOCATABLE is
 544 #   defined to work on directories not files (though it really doesn't know
 545 #   the difference).
 546 # - Calling this --with-iconv-prefix is perceived to cause too much confusion
 547 #   with --with-libiconv-prefix.
 548 # Putting these together is why the option name is --with-iconv-bin.
 549
 550 AC_ARG_WITH(iconv-bin,
 551 AS_HELP_STRING([--with-iconv-bin=PATH], [specify where to find the iconv program]),
 552 [iconv_bin="${withval}"
 553  AC_DEFINE_UNQUOTED([ICONV_BIN], ["${iconv_bin}"],
 554                     [Path of directory of iconv program.])
 555  GDB_AC_DEFINE_RELOCATABLE(ICONV_BIN, iconv, ${iconv_bin})
 556 ])
 557
 558 # For the TUI, we need enhanced curses functionality.
 559 if test x"$enable_tui" != xno; then
 560   prefer_curses=yes
 561 fi
 562
 563 curses_found=no
 564 if test x"$prefer_curses" = xyes; then
 565   # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
 566   # curses library because the latter might not provide all the
 567   # functionality we need.  However, this leads to problems on systems
 568   # where the linker searches /usr/local/lib, but the compiler doesn't
 569   # search /usr/local/include, if ncurses is installed in /usr/local.  A
 570   # default installation of ncurses on alpha*-dec-osf* will lead to such
 571   # a situation.
 572   AC_SEARCH_LIBS(waddstr, [ncurses cursesX curses])
 573
 574   if test "$ac_cv_search_waddstr" != no; then
 575     curses_found=yes
 576   fi
 577 fi
 578
 579 # Check whether we should enable the TUI, but only do so if we really
 580 # can.
 581 if test x"$enable_tui" != xno; then
 582   if test -d $srcdir/tui; then
 583     if test "$curses_found" != no; then
 584       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
 585       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
 586       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
 587       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
 588     else
 589       if test x"$enable_tui" = xyes; then
 590         AC_MSG_ERROR([no enhanced curses library found; disable TUI])
 591       else
 592         AC_MSG_WARN([no enhanced curses library found; disabling TUI])
 593       fi
 594     fi
 595   fi
 596 fi
 597
 598 # Since GDB uses Readline, we need termcap functionality.  In many
 599 # cases this will be provided by the curses library, but some systems
 600 # have a separate termcap library, or no curses library at all.
 601
 602 case $host_os in
 603   cygwin*)
 604     if test -d $srcdir/libtermcap; then
 605       LIBS="../libtermcap/libtermcap.a $LIBS"
 606       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 607     fi ;;
 608   go32* | *djgpp*)
 609     ac_cv_search_tgetent="none required"
 610     ;;
 611 esac
 612
 613 # These are the libraries checked by Readline.
 614 AC_SEARCH_LIBS(tgetent, [termcap tinfo curses ncurses])
 615
 616 if test "$ac_cv_search_tgetent" = no; then
 617   CONFIG_OBS="$CONFIG_OBS stub-termcap.o"
 618 fi
 619
 620 AC_ARG_WITH([system-readline],
 621   [AS_HELP_STRING([--with-system-readline],
 622                   [use installed readline library])])
 623
 624 if test "$with_system_readline" = yes; then
 625   READLINE=-lreadline
 626   READLINE_DEPS=
 627   READLINE_CFLAGS=
 628   READLINE_TEXI_INCFLAG=
 629 else
 630   READLINE='$(READLINE_DIR)/libreadline.a'
 631   READLINE_DEPS='$(READLINE)'
 632   READLINE_CFLAGS='-I$(READLINE_SRC)/..'
 633   READLINE_TEXI_INCFLAG='-I $(READLINE_DIR)'
 634 fi
 635 AC_SUBST(READLINE)
 636 AC_SUBST(READLINE_DEPS)
 637 AC_SUBST(READLINE_CFLAGS)
 638 AC_SUBST(READLINE_TEXI_INCFLAG)
 639
 640 # Generate jit-reader.h
 641
 642 # This is typedeffed to GDB_CORE_ADDR in jit-reader.h
 643 TARGET_PTR=
 644
 645 AC_CHECK_SIZEOF(unsigned long long)
 646 AC_CHECK_SIZEOF(unsigned long)
 647 AC_CHECK_SIZEOF(unsigned __int128)
 648
 649 if test "x${ac_cv_sizeof_unsigned_long}" = "x8"; then
 650   TARGET_PTR="unsigned long"
 651 elif test "x${ac_cv_sizeof_unsigned_long_long}" = "x8"; then
 652   TARGET_PTR="unsigned long long"
 653 elif test "x${ac_cv_sizeof_unsigned___int128}" = "x16"; then
 654   TARGET_PTR="unsigned __int128"
 655 else
 656   TARGET_PTR="unsigned long"
 657 fi
 658
 659 AC_SUBST(TARGET_PTR)
 660 AC_CONFIG_FILES([jit-reader.h:jit-reader.in])
 661
 662 AC_SEARCH_LIBS(dlopen, dl)
 663
 664 GDB_AC_WITH_DIR([JIT_READER_DIR], [jit-reader-dir],
 665                 [directory to load the JIT readers from],
 666                 [${libdir}/gdb])
 667
 668 AC_ARG_WITH(expat,
 669   AS_HELP_STRING([--with-expat], [include expat support (auto/yes/no)]),
 670   [], [with_expat=auto])
 671 AC_MSG_CHECKING([whether to use expat])
 672 AC_MSG_RESULT([$with_expat])
 673
 674 if test "${with_expat}" = no; then
 675   AC_MSG_WARN([expat support disabled; some features may be unavailable.])
 676   HAVE_LIBEXPAT=no
 677 else
 678   AC_LIB_HAVE_LINKFLAGS([expat], [], [#include "expat.h"],
 679                         [XML_Parser p = XML_ParserCreate (0);])
 680   if test "$HAVE_LIBEXPAT" != yes; then
 681     if test "$with_expat" = yes; then
 682       AC_MSG_ERROR([expat is missing or unusable])
 683     else
 684       AC_MSG_WARN([expat is missing or unusable; some features may be unavailable.])
 685     fi
 686   else
 687     save_LIBS=$LIBS
 688     LIBS="$LIBS $LIBEXPAT"
 689     AC_CHECK_FUNCS(XML_StopParser)
 690     LIBS=$save_LIBS
 691   fi
 692 fi
 693
 694 # --------------------- #
 695 # Check for libpython.  #
 696 # --------------------- #
 697
 698 dnl Utility to simplify finding libpython.
 699 dnl $1 = pythonX.Y
 700 dnl $2 = the shell variable to assign the result to
 701 dnl      If libpython is found we store $version here.
 702 dnl $3 = additional flags to add to CPPFLAGS
 703 dnl $4 = additional flags to add to LIBS
 704
 705 AC_DEFUN([AC_TRY_LIBPYTHON],
 706 [
 707   version=$1
 708   define([have_libpython_var],$2)
 709   new_CPPFLAGS=$3
 710   new_LIBS=$4
 711   AC_MSG_CHECKING([for ${version}])
 712   save_CPPFLAGS=$CPPFLAGS
 713   save_LIBS=$LIBS
 714   CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
 715   LIBS="$LIBS $new_LIBS"
 716   found_usable_python=no
 717   AC_LINK_IFELSE(AC_LANG_PROGRAM([[#include "Python.h"]],
 718                                  [[Py_Initialize ();]]),
 719                  [have_libpython_var=${version}
 720                   found_usable_python=yes
 721                   PYTHON_CPPFLAGS=$new_CPPFLAGS
 722                   PYTHON_LIBS=$new_LIBS])
 723   CPPFLAGS=$save_CPPFLAGS
 724   LIBS=$save_LIBS
 725   AC_MSG_RESULT([${found_usable_python}])
 726 ])
 727
 728 dnl There are several different values for --with-python:
 729 dnl
 730 dnl no -   Don't include python support.
 731 dnl yes -  Include python support, error if it's missing.
 732 dnl        If we find python in $PATH, use it to fetch configure options,
 733 dnl        otherwise assume the compiler can find it with no help from us.
 734 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 735 dnl auto - Same as "yes", but if python is missing from the system,
 736 dnl        fall back to "no".
 737 dnl /path/to/python/exec-prefix -
 738 dnl        Use the python located in this directory.
 739 dnl        If /path/to/python/exec-prefix/bin/python exists, use it to find
 740 dnl        the compilation parameters.  Otherwise use
 741 dnl        -I/path/to/python/exec-prefix/include,
 742 dnl        -L/path/to/python/exec-prefix/lib.
 743 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 744 dnl        NOTE: This case is historical.  It is what was done for 7.0/7.1
 745 dnl        but is deprecated.
 746 dnl /path/to/python/executable -
 747 dnl        Run python-config.py with this version of python to fetch the
 748 dnl        compilation parameters.
 749 dnl        NOTE: This needn't be the real python executable.
 750 dnl        In a cross-compilation scenario (build != host), this could be
 751 dnl        a shell script that provides what python-config.py provides for
 752 dnl        --ldflags, --includes, --exec-prefix.
 753 dnl python-executable -
 754 dnl        Find python-executable in $PATH, and then handle the same as
 755 dnl        /path/to/python/executable.
 756 dnl
 757 dnl If a python program is specified, it is used to run python-config.py and
 758 dnl is passed --ldflags, --includes, --exec-prefix.
 759
 760 AC_ARG_WITH(python,
 761   AS_HELP_STRING([--with-python@<:@=PYTHON@:>@], [include python support (auto/yes/no/<python-program>)]),
 762   [], [with_python=auto])
 763 AC_MSG_CHECKING([whether to use python])
 764 AC_MSG_RESULT([$with_python])
 765
 766 if test "${with_python}" = no; then
 767   AC_MSG_WARN([python support disabled; some features may be unavailable.])
 768   have_libpython=no
 769 else
 770   case "${with_python}" in
 771   [[\\/]]* | ?:[[\\/]]*)
 772     if test -d ${with_python}; then
 773       # Assume the python binary is ${with_python}/bin/python.
 774       python_prog="${with_python}/bin/python"
 775       python_prefix=
 776       # If python does not exit ${with_python}/bin, then try in
 777       # ${with_python}.  On Windows/MinGW, this is where the Python
 778       # executable is.
 779       if test ! -x "${python_prog}"; then
 780         python_prog="${with_python}/python"
 781         python_prefix=
 782       fi
 783       if test ! -x "${python_prog}"; then
 784         # Fall back to gdb 7.0/7.1 behaviour.
 785         python_prog=missing
 786         python_prefix=${with_python}
 787       fi
 788     elif test -x "${with_python}"; then
 789       # While we can't run python compiled for $host (unless host == build),
 790       # the user could write a script that provides the needed information,
 791       # so we support that.
 792       python_prog=${with_python}
 793       python_prefix=
 794     else
 795       AC_ERROR(invalid value for --with-python)
 796     fi
 797     ;;
 798   */*)
 799     # Disallow --with-python=foo/bar.
 800     AC_ERROR(invalid value for --with-python)
 801     ;;
 802   *)
 803     # The user has either specified auto, yes, or the name of the python
 804     # program assumed to be in $PATH.
 805     python_prefix=
 806     case "${with_python}" in
 807     yes | auto)
 808       if test ${build} = ${host}; then
 809         AC_PATH_PROG(python_prog_path, python, missing)
 810         if test "${python_prog_path}" = missing; then
 811           python_prog=missing
 812         else
 813           python_prog=${python_prog_path}
 814         fi
 815       else
 816         # Not much we can do except assume the cross-compiler will find the
 817         # right files.
 818         python_prog=missing
 819       fi
 820       ;;
 821     *)
 822       # While we can't run python compiled for $host (unless host == build),
 823       # the user could write a script that provides the needed information,
 824       # so we support that.
 825       python_prog="${with_python}"
 826       AC_PATH_PROG(python_prog_path, ${python_prog}, missing)
 827       if test "${python_prog_path}" = missing; then
 828         AC_ERROR(unable to find python program ${python_prog})
 829       fi
 830       ;;
 831     esac
 832   esac
 833
 834   if test "${python_prog}" != missing; then
 835     # We have a python program to use, but it may be too old.
 836     # Don't flag an error for --with-python=auto (the default).
 837     have_python_config=yes
 838     python_includes=`${python_prog} ${srcdir}/python/python-config.py --includes`
 839     if test $? != 0; then
 840       have_python_config=failed
 841       if test "${with_python}" != auto; then
 842         AC_ERROR(failure running python-config --includes)
 843       fi
 844     fi
 845     python_libs=`${python_prog} ${srcdir}/python/python-config.py --ldflags`
 846     if test $? != 0; then
 847       have_python_config=failed
 848       if test "${with_python}" != auto; then
 849         AC_ERROR(failure running python-config --ldflags)
 850       fi
 851     fi
 852     python_prefix=`${python_prog} ${srcdir}/python/python-config.py --exec-prefix`
 853     if test $? != 0; then
 854       have_python_config=failed
 855       if test "${with_python}" != auto; then
 856         AC_ERROR(failure running python-config --exec-prefix)
 857       fi
 858     fi
 859   else
 860     # We do not have a python executable we can use to determine where
 861     # to find the Python headers and libs.  We cannot guess the include
 862     # path from the python_prefix either, because that include path
 863     # depends on the Python version.  So, there is nothing much we can
 864     # do except assume that the compiler will be able to find those files.
 865     python_includes=
 866     python_libs=
 867     have_python_config=no
 868   fi
 869
 870   # If we have python-config, only try the configuration it provides.
 871   # Otherwise fallback on the old way of trying different versions of
 872   # python in turn.
 873
 874   have_libpython=no
 875   if test "${have_python_config}" = yes; then
 876     # Determine the Python version by extracting "-lpython<version>"
 877     # part of the python_libs. <version> is usually X.Y with X and Y
 878     # being decimal numbers, but can also be XY (seen on Windows).
 879     #
 880     # The extraction is performed using sed with a regular expression.
 881     # Initially, the regexp used was using the '?' quantifier to make
 882     # the dot in the version number optional.  Unfortunately, this
 883     # does not work with non-GNU versions of sed because, because of
 884     # what looks like a limitation (the '?' quantifier does not work
 885     # with back-references).  We work around this limitation by using
 886     # the '*' quantifier instead.  It means that, in theory, we might
 887     # match unexpected version strings such as "-lpython2..7", but
 888     # this seems unlikely in practice.  And even if that happens,
 889     # an error will be triggered later on, when checking that version
 890     # number.
 891     python_version=`echo " ${python_libs} " \
 892                          | sed -e 's,^.* -l\(python[[0-9]]*[[.]]*[[0-9]]*\).*$,\1,'`
 893     case "${python_version}" in
 894     python*)
 895       AC_TRY_LIBPYTHON(${python_version}, have_libpython,
 896                        ${python_includes}, ${python_libs})
 897       ;;
 898     *)
 899       AC_MSG_ERROR([unable to determine python version from ${python_libs}])
 900       ;;
 901     esac
 902   elif test "${have_python_config}" != failed; then
 903     if test "${have_libpython}" = no; then
 904       AC_TRY_LIBPYTHON(python2.7, have_libpython,
 905                        ${python_includes}, "${python_libs} -lpython2.7")
 906     fi
 907     if test "${have_libpython}" = no; then
 908       AC_TRY_LIBPYTHON(python2.6, have_libpython,
 909                        ${python_includes}, "${python_libs} -lpython2.6")
 910     fi
 911     if test ${have_libpython} = no; then
 912       AC_TRY_LIBPYTHON(python2.5, have_libpython,
 913                        ${python_includes}, "${python_libs} -lpython2.5")
 914     fi
 915     if test ${have_libpython} = no; then
 916       AC_TRY_LIBPYTHON(python2.4, have_libpython,
 917                        ${python_includes}, "${python_libs} -lpython2.4")
 918     fi
 919   fi
 920   if test "${have_libpython}" = python2.7 -o "${have_libpython}" = python27; then
 921     AC_DEFINE(HAVE_LIBPYTHON2_7, 1, [Define if Python 2.7 is being used.])
 922   elif test "${have_libpython}" = python2.6 -o "${have_libpython}" = python26; then
 923     AC_DEFINE(HAVE_LIBPYTHON2_6, 1, [Define if Python 2.6 is being used.])
 924   elif test "${have_libpython}" = python2.5 -o "${have_libpython}" = python25; then
 925     AC_DEFINE(HAVE_LIBPYTHON2_5, 1, [Define if Python 2.5 is being used.])
 926   elif test "${have_libpython}" = python2.4 -o "${have_libpython}" = python24; then
 927     AC_DEFINE(HAVE_LIBPYTHON2_4, 1, [Define if Python 2.4 is being used.])
 928   fi
 929
 930   if test "${have_libpython}" = no; then
 931     case "${with_python}" in
 932     yes)
 933       AC_MSG_ERROR([python is missing or unusable])
 934       ;;
 935     auto)
 936       AC_MSG_WARN([python is missing or unusable; some features may be unavailable.])
 937       ;;
 938     *)
 939       AC_MSG_ERROR([no usable python found at ${with_python}])
 940       ;;
 941     esac
 942   else
 943     if test -n "${python_prefix}"; then
 944       AC_DEFINE_UNQUOTED(WITH_PYTHON_PATH, "${python_prefix}",
 945                          [Define if --with-python provides a path, either directly or via python-config.py --exec-prefix.])
 946       GDB_AC_DEFINE_RELOCATABLE(PYTHON_PATH, python, ${python_prefix})
 947     fi
 948   fi
 949 fi
 950
 951 if test "${have_libpython}" != no; then
 952   AC_DEFINE(HAVE_PYTHON, 1, [Define if Python interpreter is being linked in.])
 953   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_PYTHON_OBS)"
 954   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_PYTHON_DEPS)"
 955   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_PYTHON_SRCS)"
 956   CONFIG_INSTALL="$CONFIG_INSTALL install-python"
 957   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_PYTHON_CFLAGS)"
 958
 959   # Flags needed to compile Python code (taken from python-config --cflags).
 960   # We cannot call python-config directly because it will output whatever was
 961   # used when compiling the Python interpreter itself, including flags which
 962   # would make the python-related objects be compiled differently from the
 963   # rest of GDB (e.g., -O2 and -fPIC).
 964   if test "${GCC}" = yes; then
 965     tentative_python_cflags="-fno-strict-aliasing -DNDEBUG -fwrapv"
 966   fi
 967
 968   if test "x${tentative_python_cflags}" != x; then
 969     AC_MSG_CHECKING(compiler flags for python code)
 970     for flag in ${tentative_python_cflags}; do
 971       # Check that the compiler accepts it
 972       saved_CFLAGS="$CFLAGS"
 973       CFLAGS="$CFLAGS $flag"
 974       AC_TRY_COMPILE([],[],PYTHON_CFLAGS="${PYTHON_CFLAGS} $flag",)
 975       CFLAGS="$saved_CFLAGS"
 976     done
 977     AC_MSG_RESULT(${PYTHON_CFLAGS})
 978   fi
 979
 980   # On x64 Windows, Python's include headers, and pyconfig.h in
 981   # particular, rely on MS_WIN64 macro to detect that it's a 64bit
 982   # version of Windows.  Unfortunately, MS_WIN64 is only defined if
 983   # _MSC_VER, a Microsoft-specific macro, is defined.  So, when
 984   # building on x64 Windows with GCC, we define MS_WIN64 ourselves.
 985   # The issue was reported to the Python community, but still isn't
 986   # solved as of 2012-10-02 (http://bugs.python.org/issue4709).
 987
 988   case "$gdb_host" in
 989     mingw64)
 990            if test "${GCC}" = yes; then
 991              CPPFLAGS="$CPPFLAGS -DMS_WIN64"
 992            fi
 993            ;;
 994   esac
 995
 996   # Note that "python -m threading" cannot be used to check for
 997   # threading support due to a bug in Python 2.7.3
 998   # (http://bugs.python.org/issue15567).
 999   AC_MSG_CHECKING(whether python supports threads)
1000   saved_CPPFLAGS="${CPPFLAGS}"
1001   CPPFLAGS="${PYTHON_CPPFLAGS}"
1002   # Note that the test is reversed so that python_has_threads=yes on
1003   # unexpected failures.
1004   AC_PREPROC_IFELSE(AC_LANG_SOURCE([[
1005 #include <Python.h>
1006 #ifdef WITH_THREAD
1007 # error
1008 #endif
1009   ]]), [python_has_threads=no], [python_has_threads=yes])
1010   AC_MSG_RESULT(${python_has_threads})
1011   CPPFLAGS="${saved_CPPFLAGS}"
1012 else
1013   # Even if Python support is not compiled in, we need to have this file
1014   # included so that the "python" command, et.al., still exists.
1015   CONFIG_OBS="$CONFIG_OBS python.o"
1016   CONFIG_SRCS="$CONFIG_SRCS python/python.c"
1017 fi
1018
1019 # Work around Python http://bugs.python.org/issue10112.  See also
1020 # http://bugs.python.org/issue11410, otherwise -Wl,--dynamic-list has
1021 # no effect.  Note that the only test after this that uses Python is
1022 # the -rdynamic/-Wl,--dynamic-list test, and we do want that one to be
1023 # run without -export-dynamic too.
1024 PYTHON_LIBS=`echo $PYTHON_LIBS | sed -e 's/-Xlinker -export-dynamic//'`
1025
1026 AC_SUBST(PYTHON_CFLAGS)
1027 AC_SUBST(PYTHON_CPPFLAGS)
1028 AC_SUBST(PYTHON_LIBS)
1029 AM_CONDITIONAL(HAVE_PYTHON, test "${have_libpython}" != no)
1030
1031 # -------------------- #
1032 # Check for libguile.  #
1033 # -------------------- #
1034
1035 dnl Utility to simplify finding libguile.
1036 dnl $1 = pkg-config-program
1037 dnl $2 = space-separate list of guile versions to try
1038 dnl $3 = yes|no, indicating whether to flag errors or ignore them
1039 dnl $4 = the shell variable to assign the result to
1040 dnl      If libguile is found we store "yes" here.
1041
1042 AC_DEFUN([AC_TRY_LIBGUILE],
1043 [
1044   pkg_config=$1
1045   guile_version_list=$2
1046   flag_errors=$3
1047   define([have_libguile_var],$4)
1048   found_usable_guile=checking
1049   AC_MSG_CHECKING([for usable guile from ${pkg_config}])
1050   for guile_version in ${guile_version_list}; do
1051     ${pkg_config} --exists ${guile_version} 2>/dev/null
1052     if test $? != 0; then
1053       continue
1054     fi
1055     dnl pkg-config says the package exists, so if we get an error now,
1056     dnl that's bad.
1057     new_CPPFLAGS=`${pkg_config} --cflags ${guile_version}`
1058     if test $? != 0; then
1059       AC_MSG_ERROR([failure running pkg-config --cflags ${guile_version}])
1060     fi
1061     new_LIBS=`${pkg_config} --libs ${guile_version}`
1062     if test $? != 0; then
1063       AC_MSG_ERROR([failure running pkg-config --libs ${guile_version}])
1064     fi
1065     dnl If we get this far, great.
1066     found_usable_guile=${guile_version}
1067     break
1068   done
1069   if test "${found_usable_guile}" = "checking"; then
1070     if test "${flag_errors}" = "yes"; then
1071       AC_MSG_ERROR([unable to find usable guile version from "${guile_version_list}"])
1072     else
1073       found_usable_guile=no
1074     fi
1075   fi
1076   dnl One final sanity check.
1077   dnl The user could have said --with-guile=python-2.7.
1078   if test "${found_usable_guile}" != no; then
1079     save_CPPFLAGS=$CPPFLAGS
1080     save_LIBS=$LIBS
1081     CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
1082     LIBS="$LIBS $new_LIBS"
1083     AC_LINK_IFELSE(AC_LANG_PROGRAM([[#include "libguile.h"]],
1084                                    [[scm_init_guile ();]]),
1085                    [have_libguile_var=yes
1086                     GUILE_CPPFLAGS=$new_CPPFLAGS
1087                     GUILE_LIBS=$new_LIBS],
1088                    [found_usable_guile=no])
1089     dnl scm_set_automatic_finalization_enabled added in Guile 2.2.
1090     AC_CHECK_FUNC(scm_set_automatic_finalization_enabled,
1091       AC_DEFINE(HAVE_GUILE_MANUAL_FINALIZATION, 1,
1092                 [Define if Guile supports manual finalization.])
1093     )
1094     CPPFLAGS=$save_CPPFLAGS
1095     LIBS=$save_LIBS
1096     if test "${found_usable_guile}" = no; then
1097       if test "${flag_errors}" = yes; then
1098         AC_MSG_FAILURE([linking guile version ${guile_version} test program failed])
1099       fi
1100     fi
1101   fi
1102   AC_MSG_RESULT([${found_usable_guile}])
1103 ])
1104
1105 dnl There are several different values for --with-guile:
1106 dnl
1107 dnl no -   Don't include guile support.
1108 dnl yes -  Include guile support, error if it's missing.
1109 dnl        The pkg-config program must be in $PATH.
1110 dnl auto - Same as "yes", but if guile is missing from the system,
1111 dnl        fall back to "no".
1112 dnl guile-version [guile-version-choice-2 ...] -
1113 dnl        A space-separated list of guile package versions to try.
1114 dnl        These are passed to pkg-config as-is.
1115 dnl        E.g., guile-2.0 or guile-2.2-uninstalled
1116 dnl        This requires making sure PKG_CONFIG_PATH is set appropriately.
1117 dnl /path/to/pkg-config -
1118 dnl        Use this pkg-config program.
1119 dnl        NOTE: This needn't be the "real" pkg-config program.
1120 dnl        It could be a shell script.  It is invoked as:
1121 dnl        pkg-config --exists $version
1122 dnl        pkg-config --cflags $version
1123 dnl        pkg-config --libs $version
1124 dnl        pkg-config --variable guild $version
1125 dnl        The script will be called with $version having each value in
1126 dnl        $try_guile_versions until --exists indicates success.
1127
1128 AC_ARG_WITH(guile,
1129   AS_HELP_STRING([--with-guile@<:@=GUILE@:>@], [include guile support (auto/yes/no/<guile-version>/<pkg-config-program>)]),
1130   [], [with_guile=auto])
1131 AC_MSG_CHECKING([whether to use guile])
1132 AC_MSG_RESULT([$with_guile])
1133
1134 dnl We check guile with pkg-config.
1135 AC_PATH_PROG(pkg_config_prog_path, pkg-config, missing)
1136
1137 try_guile_versions="guile-2.2 guile-2.0"
1138 have_libguile=no
1139 case "${with_guile}" in
1140 no)
1141   AC_MSG_WARN([guile support disabled; some features will be unavailable.])
1142   ;;
1143 auto)
1144   if test "${pkg_config_prog_path}" = "missing"; then
1145     AC_MSG_WARN([pkg-config not found, guile support disabled])
1146   else
1147     AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${try_guile_versions}, no, have_libguile)
1148   fi
1149   ;;
1150 yes)
1151   if test "${pkg_config_prog_path}" = "missing"; then
1152     AC_MSG_ERROR([pkg-config not found])
1153   fi
1154   AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${try_guile_versions}, yes, have_libguile)
1155   ;;
1156 [[\\/]]* | ?:[[\\/]]*)
1157   if test -x "${with_guile}"; then
1158     AC_TRY_LIBGUILE(${with_guile}, ${try_guile_versions}, yes, have_libguile)
1159   else
1160     AC_MSG_ERROR([Guile config program not executable: ${with_guile}])
1161   fi
1162   ;;
1163 "" | */*)
1164   # Disallow --with=guile="" and --with-guile=foo/bar.
1165   AC_MSG_ERROR([invalid value for --with-guile])
1166   ;;
1167 *)
1168   # A space separate list of guile versions to try, in order.
1169   if test "${pkg_config_prog_path}" = "missing"; then
1170     AC_MSG_ERROR([pkg-config not found])
1171   fi
1172   AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${with_guile}, yes, have_libguile)
1173   ;;
1174 esac
1175
1176 if test "${have_libguile}" != no; then
1177   dnl Get the name of the 'guild' program.
1178   case "${with_guile}" in
1179   [[\\/]]* | ?:[[\\/]]*)
1180     GDB_GUILE_PROGRAM_NAMES(["${with_guile}"], ["${guile_version}"])
1181     ;;
1182   *)
1183     GDB_GUILE_PROGRAM_NAMES(["${pkg_config_prog_path}"], ["${guile_version}"])
1184     ;;
1185   esac
1186
1187   dnl Make sure guild can handle this host.
1188   GDB_TRY_GUILD([$srcdir/guile/lib/gdb/support.scm])
1189   dnl If not, disable guile support.
1190   if test "$ac_cv_guild_ok" = no; then
1191     have_libguile=no
1192     AC_MSG_WARN(disabling guile support, $GUILD fails compiling for $host)
1193   fi
1194 fi
1195
1196 if test "${have_libguile}" != no; then
1197   AC_DEFINE(HAVE_GUILE, 1, [Define if Guile interpreter is being linked in.])
1198   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_GUILE_OBS)"
1199   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_GUILE_DEPS)"
1200   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_GUILE_SRCS)"
1201   CONFIG_INSTALL="$CONFIG_INSTALL install-guile"
1202   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_GUILE_CFLAGS)"
1203
1204   dnl The 'scm_new_smob' function appeared in Guile 2.0.6.
1205   save_LIBS="$LIBS"
1206   save_CPPFLAGS="$CPPFLAGS"
1207   LIBS="$GUILE_LIBS"
1208   CPPFLAGS="$GUILE_CPPFLAGS"
1209   AC_CHECK_FUNCS([scm_new_smob])
1210   LIBS="$save_LIBS"
1211   CPPFLAGS="$save_CPPFLAGS"
1212 else
1213   # Even if Guile support is not compiled in, we need to have these files
1214   # included.
1215   CONFIG_OBS="$CONFIG_OBS guile.o"
1216   CONFIG_SRCS="$CONFIG_SRCS guile/guile.c"
1217 fi
1218 AC_SUBST(GUILE_CPPFLAGS)
1219 AC_SUBST(GUILE_LIBS)
1220 AM_CONDITIONAL(HAVE_GUILE, test "${have_libguile}" != no)
1221
1222 # --------------------- #
1223 # Check for libmcheck.  #
1224 # --------------------- #
1225
1226 # Enable -lmcheck by default (it provides cheap-enough memory mangling),
1227 # but turn it off if Python is enabled with threads, since -lmcheck is
1228 # not thread safe (http://sourceware.org/bugzilla/show_bug.cgi?id=9939),
1229 # and for releases.
1230 if test \( "${have_libpython}" = "no" -o "${python_has_threads}" = "no" \) \
1231    && $development; then
1232   libmcheck_default=yes
1233 else
1234   libmcheck_default=no
1235 fi
1236 GDB_AC_LIBMCHECK(${libmcheck_default})
1237
1238 if test "$ENABLE_LIBMCHECK" = "yes" \
1239         -a "${have_libpython}" != "no" \
1240         -a "${python_has_threads}" = "yes" ; then
1241   AC_MSG_WARN(--enable-libmcheck may lead to spurious crashes if threads are used in python)
1242 fi
1243
1244 AC_ARG_WITH(intel_pt,
1245   AS_HELP_STRING([--with-intel-pt], [include Intel Processor Trace support (auto/yes/no)]),
1246   [], [with_intel_pt=auto])
1247 AC_MSG_CHECKING([whether to use intel pt])
1248 AC_MSG_RESULT([$with_intel_pt])
1249
1250 if test "${with_intel_pt}" = no; then
1251   AC_MSG_WARN([Intel Processor Trace support disabled; some features may be unavailable.])
1252   HAVE_LIBIPT=no
1253 else
1254   AC_PREPROC_IFELSE(AC_LANG_SOURCE([[
1255 #include <linux/perf_event.h>
1256 #ifndef PERF_ATTR_SIZE_VER5
1257 # error
1258 #endif
1259   ]]), [perf_event=yes], [perf_event=no])
1260   if test "$perf_event" != yes; then
1261     if test "$with_intel_pt" = yes; then
1262       AC_MSG_ERROR([linux/perf_event.h missing or too old])
1263     else
1264       AC_MSG_WARN([linux/perf_event.h missing or too old; some features may be unavailable.])
1265     fi
1266   fi
1267
1268   AC_LIB_HAVE_LINKFLAGS([ipt], [], [#include "intel-pt.h"], [pt_insn_alloc_decoder (0);])
1269   if test "$HAVE_LIBIPT" != yes; then
1270     if test "$with_intel_pt" = yes; then
1271       AC_MSG_ERROR([libipt is missing or unusable])
1272     else
1273       AC_MSG_WARN([libipt is missing or unusable; some features may be unavailable.])
1274     fi
1275   else
1276     save_LIBS=$LIBS
1277     LIBS="$LIBS $LIBIPT"
1278     AC_CHECK_FUNCS(pt_insn_event)
1279     AC_CHECK_MEMBERS([struct pt_insn.enabled, struct pt_insn.resynced], [], [],
1280                      [#include <intel-pt.h>])
1281     LIBS=$save_LIBS
1282   fi
1283 fi
1284
1285 # ------------------------- #
1286 # Checks for header files.  #
1287 # ------------------------- #
1288
1289 AC_HEADER_STDC
1290 # elf_hp.h is for HP/UX 64-bit shared library support.
1291 AC_CHECK_HEADERS([nlist.h machine/reg.h poll.h sys/poll.h proc_service.h \
1292                   thread_db.h \
1293                   sys/fault.h \
1294                   sys/file.h sys/filio.h sys/ioctl.h sys/param.h \
1295                   sys/resource.h sys/procfs.h sys/ptrace.h ptrace.h \
1296                   sys/reg.h sys/debugreg.h sys/select.h sys/syscall.h \
1297                   termios.h termio.h \
1298                   sgtty.h elf_hp.h \
1299                   dlfcn.h])
1300 AC_CHECK_HEADERS(sys/proc.h, [], [],
1301 [#if HAVE_SYS_PARAM_H
1302 # include <sys/param.h>
1303 #endif
1304 ])
1305 AC_CHECK_HEADERS(sys/user.h, [], [],
1306 [#if HAVE_SYS_PARAM_H
1307 # include <sys/param.h>
1308 #endif
1309 ])
1310
1311 # On Solaris 2.[789], we need to define _MSE_INT_H to avoid a clash
1312 # between <widec.h> and <wchar.h> that would cause AC_CHECK_HEADERS to
1313 # think that we don't have <curses.h> if we're using GCC.
1314 case $host_os in
1315   solaris2.[[789]])
1316     if test "$GCC" = yes; then
1317       AC_DEFINE(_MSE_INT_H, 1,
1318         [Define to 1 to avoid a clash between <widec.h> and <wchar.h> on
1319    Solaris 2.[789] when using GCC. ])
1320     fi ;;
1321 esac
1322 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncurses/ncurses.h ncurses/term.h)
1323 AC_CHECK_HEADERS(term.h, [], [],
1324 [#if HAVE_CURSES_H
1325 # include <curses.h>
1326 #endif
1327 ])
1328
1329 # ------------------------- #
1330 # Checks for declarations.  #
1331 # ------------------------- #
1332
1333 libiberty_INIT
1334
1335 AC_CHECK_DECLS([free, malloc, realloc, snprintf])
1336 AM_LC_MESSAGES
1337
1338 # ----------------------- #
1339 # Checks for structures.  #
1340 # ----------------------- #
1341
1342 AC_CHECK_MEMBERS([struct stat.st_blocks, struct stat.st_blksize])
1343
1344 # ------------------ #
1345 # Checks for types.  #
1346 # ------------------ #
1347
1348 AC_CHECK_TYPES(socklen_t, [], [],
1349 [#include <sys/types.h>
1350 #include <sys/socket.h>
1351 ])
1352
1353 # ------------------------------------- #
1354 # Checks for compiler characteristics.  #
1355 # ------------------------------------- #
1356
1357 AC_C_CONST
1358 AC_C_INLINE
1359 AC_C_BIGENDIAN
1360
1361 # ------------------------------ #
1362 # Checks for library functions.  #
1363 # ------------------------------ #
1364
1365 AC_FUNC_MMAP
1366 AC_FUNC_VFORK
1367 AC_CHECK_FUNCS([getauxval getrusage getuid getgid \
1368                 pipe poll pread pread64 pwrite resize_term \
1369                 sbrk setpgid setpgrp setsid \
1370                 sigaction sigprocmask sigsetmask socketpair \
1371                 ttrace wborder wresize setlocale iconvlist libiconvlist btowc \
1372                 setrlimit getrlimit posix_madvise waitpid \
1373                 ptrace64 sigaltstack mkdtemp setns])
1374 AM_LANGINFO_CODESET
1375 GDB_AC_COMMON
1376
1377 # Check the return and argument types of ptrace.
1378 GDB_AC_PTRACE
1379
1380 dnl AC_FUNC_SETPGRP does not work when cross compiling
1381 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
1382 if test "$cross_compiling" = no; then
1383   AC_FUNC_SETPGRP
1384 else
1385   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
1386     [AC_TRY_COMPILE([
1387 #include <unistd.h>
1388 ], [
1389   if (setpgrp(1,1) == -1)
1390     exit (0);
1391   else
1392     exit (1);
1393 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
1394 if test $ac_cv_func_setpgrp_void = yes; then
1395   AC_DEFINE(SETPGRP_VOID, 1)
1396 fi
1397 fi
1398
1399 # Assume we'll default to using the included libiberty regex.
1400 gdb_use_included_regex=yes
1401
1402 # However, if the system regex is GNU regex, then default to *not*
1403 # using the included regex.
1404 AC_CACHE_CHECK(
1405   [for GNU regex],
1406   [gdb_cv_have_gnu_regex],
1407   [AC_TRY_COMPILE(
1408     [#include <gnu-versions.h>],
1409     [#define REGEX_INTERFACE_VERSION 1
1410 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
1411 # error "Version mismatch"
1412 #endif],
1413     gdb_cv_have_gnu_regex=yes,
1414     gdb_cv_have_gnu_regex=no)])
1415 if test $gdb_cv_have_gnu_regex = yes; then
1416   gdb_use_included_regex=no
1417 fi
1418
1419 AC_ARG_WITH(included-regex,
1420   AS_HELP_STRING([--without-included-regex], [don't use included regex; this is the default on systems with version 2 of the GNU C library (use with caution on other system)]),
1421   gdb_with_regex=$withval,
1422   gdb_with_regex=$gdb_use_included_regex)
1423 if test "$gdb_with_regex" = yes; then
1424   AC_DEFINE(USE_INCLUDED_REGEX, 1,
1425     [Define to 1 if the regex included in libiberty should be used.])
1426 fi
1427
1428 # Check if <sys/proc.h> defines `struct thread' with a td_pcb member.
1429 AC_CHECK_MEMBERS([struct thread.td_pcb], [], [],
1430 [#include <sys/param.h>
1431 #include <sys/proc.h>
1432 ])
1433
1434 # See if <sys/lwp.h> defines `struct lwp`.
1435 AC_CACHE_CHECK([for struct lwp], gdb_cv_struct_lwp,
1436 [AC_TRY_COMPILE([#include <sys/param.h>
1437 #include <sys/lwp.h>], [struct lwp l;],
1438 gdb_cv_struct_lwp=yes, gdb_cv_struct_lwp=no)])
1439 if test $gdb_cv_struct_lwp = yes; then
1440   AC_DEFINE(HAVE_STRUCT_LWP, 1,
1441             [Define to 1 if your system has struct lwp.])
1442 fi
1443
1444 # See if <machine/reg.h> degines `struct reg'.
1445 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
1446 [AC_TRY_COMPILE([#include <sys/types.h>
1447 #include <machine/reg.h>], [struct reg r;],
1448 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
1449 if test $gdb_cv_struct_reg = yes; then
1450   AC_DEFINE(HAVE_STRUCT_REG, 1,
1451             [Define to 1 if your system has struct reg in <machine/reg.h>.])
1452 fi
1453
1454 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
1455 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
1456 AC_CHECK_MEMBERS([struct reg.r_fs, struct reg.r_gs], [], [],
1457                  [#include <sys/types.h>
1458 #include <machine/reg.h>])
1459
1460 # See if <sys/user.h> supports the %fs_base and %gs_bas amd64 segment registers.
1461 # Older amd64 Linux's don't have the fs_base and gs_base members of
1462 # `struct user_regs_struct'.
1463 AC_CHECK_MEMBERS([struct user_regs_struct.fs_base, struct user_regs_struct.gs_base],
1464                  [], [], [#include <sys/user.h>])
1465
1466 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
1467 AC_MSG_CHECKING(for PTRACE_GETREGS)
1468 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
1469 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1470                 [PTRACE_GETREGS;],
1471                 [gdb_cv_have_ptrace_getregs=yes],
1472                 [gdb_cv_have_ptrace_getregs=no])])
1473 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
1474 if test $gdb_cv_have_ptrace_getregs = yes; then
1475   AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
1476   [Define if sys/ptrace.h defines the PTRACE_GETREGS request.])
1477 fi
1478
1479 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
1480 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
1481 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
1482 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1483                 [PTRACE_GETFPXREGS;],
1484                 [gdb_cv_have_ptrace_getfpxregs=yes],
1485                 [gdb_cv_have_ptrace_getfpxregs=no])])
1486 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
1487 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
1488   AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
1489   [Define if sys/ptrace.h defines the PTRACE_GETFPXREGS request.])
1490 fi
1491
1492 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
1493 AC_MSG_CHECKING(for PT_GETDBREGS)
1494 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
1495 [AC_TRY_COMPILE([#include <sys/types.h>
1496 #include <sys/ptrace.h>],
1497                 [PT_GETDBREGS;],
1498                 [gdb_cv_have_pt_getdbregs=yes],
1499                 [gdb_cv_have_pt_getdbregs=no])])
1500 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
1501 if test $gdb_cv_have_pt_getdbregs = yes; then
1502   AC_DEFINE(HAVE_PT_GETDBREGS, 1,
1503   [Define if sys/ptrace.h defines the PT_GETDBREGS request.])
1504 fi
1505
1506 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
1507 AC_MSG_CHECKING(for PT_GETXMMREGS)
1508 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
1509 [AC_TRY_COMPILE([#include <sys/types.h>
1510 #include <sys/ptrace.h>],
1511                 [PT_GETXMMREGS;],
1512                 [gdb_cv_have_pt_getxmmregs=yes],
1513                 [gdb_cv_have_pt_getxmmregs=no])])
1514 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
1515 if test $gdb_cv_have_pt_getxmmregs = yes; then
1516   AC_DEFINE(HAVE_PT_GETXMMREGS, 1,
1517   [Define if sys/ptrace.h defines the PT_GETXMMREGS request.])
1518 fi
1519
1520 # See if <sys/ptrace.h> supports LWP names on FreeBSD
1521 # Older FreeBSD versions don't have the pl_tdname member of
1522 # `struct ptrace_lwpinfo'.
1523 AC_CHECK_MEMBERS([struct ptrace_lwpinfo.pl_tdname], [], [],
1524                  [#include <sys/ptrace.h>])
1525
1526 # See if <sys/ptrace.h> supports syscall fields on FreeBSD.  The
1527 # pl_syscall_code member of `struct ptrace_lwpinfo' was added in
1528 # FreeBSD 10.3.
1529 AC_CHECK_MEMBERS([struct ptrace_lwpinfo.pl_syscall_code], [], [],
1530                  [#include <sys/ptrace.h>])
1531
1532 # Detect which type of /proc is in use, such as for Solaris.
1533
1534 if test "${target}" = "${host}"; then
1535   case "${host}" in
1536   *-*-sysv4.2* | *-*-sysv5* )
1537       AC_DEFINE(NEW_PROC_API, 1,
1538       [Define if you want to use new multi-fd /proc interface.])
1539       ;;
1540   *-*-solaris2.[[6789]] | *-*-solaris2.1[[0-9]]*)
1541       AC_DEFINE(NEW_PROC_API, 1,
1542       [Define if you want to use new multi-fd /proc interface.])
1543       ;;
1544   esac
1545 fi
1546
1547 if test "$ac_cv_header_sys_procfs_h" = yes; then
1548   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
1549   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
1550   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
1551   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
1552   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
1553   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
1554   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
1555   BFD_HAVE_SYS_PROCFS_TYPE(prsysent_t)
1556   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigset_t)
1557   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigaction64_t)
1558   BFD_HAVE_SYS_PROCFS_TYPE(pr_siginfo64_t)
1559
1560
1561   dnl Check for broken prfpregset_t type
1562
1563   dnl For Linux/i386, glibc 2.1.3 was released with a bogus
1564   dnl prfpregset_t type (it's a typedef for the pointer to a struct
1565   dnl instead of the struct itself).  We detect this here, and work
1566   dnl around it in gdb_proc_service.h.
1567
1568   if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
1569     AC_MSG_CHECKING(whether prfpregset_t type is broken)
1570     AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
1571       [AC_TRY_RUN([#include <sys/procfs.h>
1572        int main ()
1573        {
1574          if (sizeof (prfpregset_t) == sizeof (void *))
1575            return 1;
1576          return 0;
1577        }],
1578        gdb_cv_prfpregset_t_broken=no,
1579        gdb_cv_prfpregset_t_broken=yes,
1580        gdb_cv_prfpregset_t_broken=yes)])
1581     AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
1582     if test $gdb_cv_prfpregset_t_broken = yes; then
1583       AC_DEFINE(PRFPREGSET_T_BROKEN, 1,
1584       [Define if the prfpregset_t type is broken.])
1585     fi
1586   fi
1587 fi
1588
1589 # Check if the compiler supports the `long long' type.
1590
1591 AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long,
1592                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1593 [[extern long long foo;]],
1594 [[switch (foo & 2) { case 0: return 1; }]])],
1595                                   gdb_cv_c_long_long=yes,
1596                                   gdb_cv_c_long_long=no)])
1597 if test $gdb_cv_c_long_long != yes; then
1598   # libdecnumber requires long long.
1599   AC_MSG_ERROR([Compiler must support long long for GDB.])
1600 fi
1601
1602 # Check if the compiler and runtime support printing long longs.
1603
1604 AC_CACHE_CHECK([for long long support in printf],
1605                gdb_cv_printf_has_long_long,
1606                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1607 [[char buf[32];
1608   long long l = 0;
1609   l = (l << 16) + 0x0123;
1610   l = (l << 16) + 0x4567;
1611   l = (l << 16) + 0x89ab;
1612   l = (l << 16) + 0xcdef;
1613   sprintf (buf, "0x%016llx", l);
1614   return (strcmp ("0x0123456789abcdef", buf));]])],
1615                               gdb_cv_printf_has_long_long=yes,
1616                               gdb_cv_printf_has_long_long=no,
1617                               gdb_cv_printf_has_long_long=no)])
1618 if test $gdb_cv_printf_has_long_long = yes; then
1619   AC_DEFINE(PRINTF_HAS_LONG_LONG, 1,
1620             [Define to 1 if the "%ll" format works to print long longs.])
1621 fi
1622
1623 # Check if the compiler and runtime support printing decfloats.
1624
1625 AC_CACHE_CHECK([for decfloat support in printf],
1626                gdb_cv_printf_has_decfloat,
1627                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1628 [[char buf[64];
1629   _Decimal32 d32 = 1.2345df;
1630   _Decimal64 d64 = 1.2345dd;
1631   _Decimal128 d128 = 1.2345dl;
1632   sprintf (buf, "Decimal32: %H\nDecimal64: %D\nDecimal128: %DD", d32, d64, d128);
1633   return (strcmp ("Decimal32: 1.2345\nDecimal64: 1.2345\nDecimal128: 1.2345", buf));]])],
1634                               gdb_cv_printf_has_decfloat=yes,
1635                               gdb_cv_printf_has_decfloat=no,
1636                               gdb_cv_printf_has_decfloat=no)])
1637 if test $gdb_cv_printf_has_decfloat = yes; then
1638   AC_DEFINE(PRINTF_HAS_DECFLOAT, 1,
1639             [Define to 1 if the "%H, %D and %DD" formats work to print decfloats.])
1640 fi
1641
1642 # Check if the compiler supports the `long double' type.  We can't use
1643 # AC_C_LONG_DOUBLE because that one does additional checks on the
1644 # constants defined in <float.h> that fail on some systems,
1645 # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6.
1646
1647 AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double,
1648                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])],
1649                                   gdb_cv_c_long_double=yes,
1650                                   gdb_cv_c_long_double=no)])
1651 if test $gdb_cv_c_long_double = yes; then
1652   AC_DEFINE(HAVE_LONG_DOUBLE, 1,
1653            [Define to 1 if the compiler supports long double.])
1654 fi
1655
1656 # Check if the compiler and runtime support printing long doubles.
1657
1658 AC_CACHE_CHECK([for long double support in printf],
1659                gdb_cv_printf_has_long_double,
1660                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1661 [[char buf[16];
1662   long double f = 3.141592653;
1663   sprintf (buf, "%Lg", f);
1664   return (strncmp ("3.14159", buf, 7));]])],
1665                               gdb_cv_printf_has_long_double=yes,
1666                               gdb_cv_printf_has_long_double=no,
1667                               gdb_cv_printf_has_long_double=no)])
1668 if test $gdb_cv_printf_has_long_double = yes; then
1669   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1,
1670             [Define to 1 if the "%Lg" format works to print long doubles.])
1671 fi
1672
1673 # Check if the compiler and runtime support scanning long doubles.
1674
1675 AC_CACHE_CHECK([for long double support in scanf],
1676                gdb_cv_scanf_has_long_double,
1677                [AC_RUN_IFELSE([AC_LANG_PROGRAM(
1678 [[#include <stdio.h>]],
1679 [[char *buf = "3.141592653";
1680   long double f = 0;
1681   sscanf (buf, "%Lg", &f);
1682   return !(f > 3.14159 && f < 3.14160);]])],
1683                               gdb_cv_scanf_has_long_double=yes,
1684                               gdb_cv_scanf_has_long_double=no,
1685                               gdb_cv_scanf_has_long_double=no)])
1686 if test $gdb_cv_scanf_has_long_double = yes; then
1687   AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1,
1688             [Define to 1 if the "%Lg" format works to scan long doubles.])
1689 fi
1690
1691 case ${host_os} in
1692 aix*)
1693   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1694     SAVE_LDFLAGS=$LDFLAGS
1695
1696     case $GCC in
1697     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1698     *) gdb_cv_bigtoc=-bbigtoc ;;
1699     esac
1700
1701     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1702     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1703     LDFLAGS="${SAVE_LDFLAGS}"
1704   ])
1705   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
1706   ;;
1707 esac
1708
1709 AC_MSG_CHECKING(for the dynamic export flag)
1710 dynamic_list=false
1711 if test "${gdb_native}" = yes; then
1712    # The dynamically loaded libthread_db needs access to symbols in the gdb
1713    # executable.  Older GNU ld supports --export-dynamic but --dynamic-list
1714    # may not be supported there.
1715    old_LDFLAGS="$LDFLAGS"
1716    # Older GNU ld supports --export-dynamic but --dynamic-list it does not.
1717    RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
1718    LDFLAGS="$LDFLAGS $RDYNAMIC"
1719    if test "${have_libpython}" = no; then
1720      AC_TRY_LINK([], [], [dynamic_list=true])
1721    else
1722      # Workaround http://bugs.python.org/issue4434 where static
1723      # libpythonX.Y.a would get its symbols required for
1724      # pythonX.Y/lib-dynload/*.so modules hidden by -Wl,--dynamic-list.
1725      # Problem does not happen for the recommended libpythonX.Y.so linkage.
1726
1727      # Note the workaround for Python
1728      # http://bugs.python.org/issue10112 earlier has removed
1729      # -export-dynamic from PYTHON_LIBS.  That's exactly what we want
1730      # here too, as otherwise it'd make this -Wl,--dynamic-list test
1731      # always pass.
1732      old_CFLAGS="$CFLAGS"
1733      CFLAGS="$CFLAGS $PYTHON_CFLAGS"
1734      old_LIBS="$LIBS"
1735      LIBS="$LIBS $PYTHON_LIBS"
1736      old_CPPFLAGS="$CPPFLAGS"
1737      CPPFLAGS="$CPPFLAGS $PYTHON_CPPFLAGS"
1738      AC_RUN_IFELSE(
1739        AC_LANG_PROGRAM(
1740          [#include "Python.h"],
1741          [int err;
1742           Py_Initialize ();
1743           err = PyRun_SimpleString ("import itertools\n");
1744           Py_Finalize ();
1745           return err == 0 ? 0 : 1;]),
1746        [dynamic_list=true], [], [true])
1747      LIBS="$old_LIBS"
1748      CFLAGS="$old_CFLAGS"
1749      CPPFLAGS="$old_CPPFLAGS"
1750    fi
1751    LDFLAGS="$old_LDFLAGS"
1752 fi
1753 if $dynamic_list; then
1754   found="-Wl,--dynamic-list"
1755   RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'
1756 else
1757   found="-rdynamic"
1758   RDYNAMIC="-rdynamic"
1759 fi
1760 AC_SUBST(RDYNAMIC)
1761 AC_MSG_RESULT($found)
1762
1763 dnl For certain native configurations, we need to check whether thread
1764 dnl support can be built in or not.
1765 dnl
1766 dnl Note that we only want this if we are both native (host == target),
1767 dnl and not doing a canadian cross build (build == host).
1768
1769 if test ${build} = ${host} -a ${host} = ${target} ; then
1770    case ${host_os} in
1771    solaris*)
1772       # See if thread_db library is around for Solaris thread debugging.
1773       # Note that we must explicitly test for version 1 of the library
1774       # because version 0 (present on Solaris 2.4 or earlier) doesn't have
1775       # the same API.
1776       AC_MSG_CHECKING(for Solaris thread debugging library)
1777       if test -f /usr/lib/libthread_db.so.1 ; then
1778          AC_MSG_RESULT(yes)
1779          AC_DEFINE(HAVE_THREAD_DB_LIB, 1,
1780          [Define if using Solaris thread debugging.])
1781          CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
1782          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
1783          AC_CHECK_LIB(dl, dlopen)
1784          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} $RDYNAMIC"
1785          # Sun randomly tweaked the prototypes in <proc_service.h>
1786          # at one point.
1787          AC_MSG_CHECKING(if <proc_service.h> is old)
1788          AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
1789             AC_TRY_COMPILE([
1790                 #include <proc_service.h>
1791                 ps_err_e ps_pdwrite
1792                     (struct ps_prochandle*, psaddr_t, const void*, size_t);
1793             ],, gdb_cv_proc_service_is_old=no,
1794                 gdb_cv_proc_service_is_old=yes)
1795          ])
1796          AC_MSG_RESULT($gdb_cv_proc_service_is_old)
1797          if test $gdb_cv_proc_service_is_old = yes; then
1798             AC_DEFINE(PROC_SERVICE_IS_OLD, 1,
1799             [Define if <proc_service.h> on solaris uses int instead of
1800              size_t, and assorted other type changes.])
1801          fi
1802       else
1803          AC_MSG_RESULT(no)
1804       fi
1805       ;;
1806    aix*)
1807       AC_MSG_CHECKING(for AiX thread debugging library)
1808       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
1809                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
1810                                    [#ifndef PTHDB_VERSION_3
1811                                     #error
1812                                     #endif],
1813                                    gdb_cv_have_aix_thread_debug=yes,
1814                                    gdb_cv_have_aix_thread_debug=no)])
1815       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1816       if test $gdb_cv_have_aix_thread_debug = yes; then
1817          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1818          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1819          LIBS="$LIBS -lpthdebug"
1820
1821          # Older versions of AIX do not provide the declaration for
1822          # the getthrds function (it appears that it was introduced
1823          # with AIX 6.x).
1824          AC_CHECK_DECLS(getthrds, [], [], [[#include <procinfo.h>]])
1825       fi
1826       ;;
1827    esac
1828    AC_SUBST(CONFIG_LDFLAGS)
1829 fi
1830
1831 dnl See if we have a thread_db header file that has TD_NOTALLOC and
1832 dnl other error codes.
1833 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1834    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
1835                   gdb_cv_thread_db_h_has_td_notalloc,
1836      AC_TRY_COMPILE(
1837        [#include <thread_db.h>],
1838        [int i = TD_NOTALLOC;],
1839        gdb_cv_thread_db_h_has_td_notalloc=yes,
1840        gdb_cv_thread_db_h_has_td_notalloc=no
1841      )
1842    )
1843    AC_CACHE_CHECK([whether <thread_db.h> has TD_VERSION],
1844                   gdb_cv_thread_db_h_has_td_version,
1845      AC_TRY_COMPILE(
1846        [#include <thread_db.h>],
1847        [int i = TD_VERSION;],
1848        gdb_cv_thread_db_h_has_td_version=yes,
1849        gdb_cv_thread_db_h_has_td_version=no
1850      )
1851    )
1852    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTLS],
1853                   gdb_cv_thread_db_h_has_td_notls,
1854      AC_TRY_COMPILE(
1855        [#include <thread_db.h>],
1856        [int i = TD_NOTLS;],
1857        gdb_cv_thread_db_h_has_td_notls=yes,
1858        gdb_cv_thread_db_h_has_td_notls=no
1859      )
1860    )
1861 fi
1862 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1863   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1864             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1865 fi
1866 if test "x$gdb_cv_thread_db_h_has_td_version" = "xyes"; then
1867   AC_DEFINE(THREAD_DB_HAS_TD_VERSION, 1,
1868             [Define if <thread_db.h> has the TD_VERSION error code.])
1869 fi
1870 if test "x$gdb_cv_thread_db_h_has_td_notls" = "xyes"; then
1871   AC_DEFINE(THREAD_DB_HAS_TD_NOTLS, 1,
1872             [Define if <thread_db.h> has the TD_NOTLS error code.])
1873 fi
1874
1875 dnl Check if we can disable the virtual address space randomization.
1876 dnl The functionality of setarch -R.
1877 AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>])
1878 define([PERSONALITY_TEST], [AC_LANG_PROGRAM([#include <sys/personality.h>], [
1879 #      if !HAVE_DECL_ADDR_NO_RANDOMIZE
1880 #       define ADDR_NO_RANDOMIZE 0x0040000
1881 #      endif
1882        /* Test the flag could be set and stays set.  */
1883        personality (personality (0xffffffff) | ADDR_NO_RANDOMIZE);
1884        if (!(personality (personality (0xffffffff)) & ADDR_NO_RANDOMIZE))
1885            return 1])])
1886 AC_RUN_IFELSE([PERSONALITY_TEST],
1887               [have_personality=true],
1888               [have_personality=false],
1889               [AC_LINK_IFELSE([PERSONALITY_TEST],
1890                               [have_personality=true],
1891                               [have_personality=false])])
1892 if $have_personality
1893 then
1894     AC_DEFINE([HAVE_PERSONALITY], 1,
1895               [Define if you support the personality syscall.])
1896 fi
1897
1898 dnl Set the host's .gdbinit filename.
1899 case $host_os in
1900   go32* | *djgpp*)
1901     gdbinit=gdb.ini
1902     ;;
1903   *)
1904     gdbinit=.gdbinit
1905     ;;
1906 esac
1907 AC_DEFINE_UNQUOTED(GDBINIT,"$gdbinit",[The .gdbinit filename.])
1908
1909 dnl Handle optional features that can be enabled.
1910
1911 # Support for --with-sysroot is a copy of GDB_AC_WITH_DIR,
1912 # except that the argument to --with-sysroot is optional.
1913 # --with-sysroot (or --with-sysroot=yes) sets the default sysroot path.
1914 if test "x$with_sysroot" = xyes; then
1915   with_sysroot="${exec_prefix}/${target_alias}/sys-root"
1916 fi
1917 AC_ARG_WITH(sysroot,
1918   AS_HELP_STRING([--with-sysroot@<:@=DIR@:>@],
1919                  [search for usr/lib et al within DIR]),
1920   [TARGET_SYSTEM_ROOT=$withval], [TARGET_SYSTEM_ROOT=])
1921 AC_DEFINE_DIR(TARGET_SYSTEM_ROOT, TARGET_SYSTEM_ROOT,
1922               [search for usr/lib et al within DIR])
1923 AC_SUBST(TARGET_SYSTEM_ROOT)
1924 GDB_AC_DEFINE_RELOCATABLE(TARGET_SYSTEM_ROOT, sysroot, ${ac_define_dir})
1925
1926 GDB_AC_WITH_DIR(SYSTEM_GDBINIT, system-gdbinit,
1927     [automatically load a system-wide gdbinit file],
1928     [])
1929
1930 AM_GDB_WARNINGS
1931
1932 # In the Cygwin environment, we need some additional flags.
1933 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1934 [AC_EGREP_CPP(^lose$, [
1935 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1936 lose
1937 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1938
1939
1940 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1941 SER_HARDWIRE="ser-base.o ser-unix.o ser-pipe.o ser-tcp.o"
1942 case ${host} in
1943   *go32* ) SER_HARDWIRE=ser-go32.o ;;
1944   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
1945   *mingw32*) SER_HARDWIRE="ser-base.o ser-tcp.o ser-mingw.o" ;;
1946 esac
1947 AC_SUBST(SER_HARDWIRE)
1948
1949 # libreadline needs libuser32.a in a cygwin environment
1950 WIN32LIBS=
1951 if test x$gdb_cv_os_cygwin = xyes; then
1952     WIN32LIBS="-luser32"
1953     case "${target}" in
1954         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
1955         ;;
1956     esac
1957 fi
1958
1959 # The ser-tcp.c module requires sockets.
1960 case ${host} in
1961   *mingw32*)
1962     AC_DEFINE(USE_WIN32API, 1,
1963               [Define if we should use the Windows API, instead of the
1964                POSIX API.  On Windows, we use the Windows API when
1965                building for MinGW, but the POSIX API when building
1966                for Cygwin.])
1967     WIN32LIBS="$WIN32LIBS -lws2_32"
1968     ;;
1969 esac
1970 AC_SUBST(WIN32LIBS)
1971
1972 # Add ELF support to GDB, but only if BFD includes ELF support.
1973 GDB_AC_CHECK_BFD([for ELF support in BFD], gdb_cv_var_elf,
1974                  [bfd_get_elf_phdr_upper_bound (NULL)], elf-bfd.h)
1975 if test $gdb_cv_var_elf = yes; then
1976   CONFIG_OBS="$CONFIG_OBS elfread.o stap-probe.o dtrace-probe.o"
1977   AC_DEFINE(HAVE_ELF, 1,
1978             [Define if ELF support should be included.])
1979   # -ldl is provided by bfd/Makfile.am (LIBDL) <PLUGINS>.
1980   if test "$plugins" = "yes"; then
1981     AC_SEARCH_LIBS(dlopen, dl)
1982   fi
1983 fi
1984
1985 # Add macho support to GDB, but only if BFD includes it.
1986 GDB_AC_CHECK_BFD([for Mach-O support in BFD], gdb_cv_var_macho,
1987                  [bfd_mach_o_lookup_command (NULL, 0, NULL)], mach-o.h)
1988 if test $gdb_cv_var_macho = yes; then
1989   CONFIG_OBS="$CONFIG_OBS machoread.o"
1990 fi
1991
1992 # Add any host-specific objects to GDB.
1993 CONFIG_OBS="${CONFIG_OBS} ${gdb_host_obs}"
1994
1995 # If building on ELF, look for lzma support for embedded compressed debug info.
1996 if test $gdb_cv_var_elf = yes; then
1997   AC_ARG_WITH(lzma,
1998     AS_HELP_STRING([--with-lzma], [support lzma compression (auto/yes/no)]),
1999     [], [with_lzma=auto])
2000   AC_MSG_CHECKING([whether to use lzma])
2001   AC_MSG_RESULT([$with_lzma])
2002
2003   if test "${with_lzma}" != no; then
2004     AC_LIB_HAVE_LINKFLAGS([lzma], [], [#include "lzma.h"],
2005                           [lzma_index_iter iter;
2006                            lzma_index_iter_init (&iter, 0);
2007                            lzma_mf_is_supported (LZMA_MF_HC3);])
2008     if test "$HAVE_LIBLZMA" != yes; then
2009       if test "$with_lzma" = yes; then
2010         AC_MSG_ERROR([missing liblzma for --with-lzma])
2011       fi
2012     fi
2013   fi
2014 fi
2015
2016 LIBGUI="../libgui/src/libgui.a"
2017 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
2018 AC_SUBST(LIBGUI)
2019 AC_SUBST(GUI_CFLAGS_X)
2020
2021 WIN32LDAPP=
2022 AC_SUBST(WIN32LIBS)
2023 AC_SUBST(WIN32LDAPP)
2024
2025 case "${host}" in
2026 *-*-cygwin* | *-*-mingw* )
2027     configdir="win"
2028     ;;
2029 *)
2030     configdir="unix"
2031     ;;
2032 esac
2033
2034 GDBTKLIBS=
2035 if test "${enable_gdbtk}" = "yes"; then
2036
2037     # Gdbtk must have an absolute path to srcdir in order to run
2038     # properly when not installed.
2039     here=`pwd`
2040     cd ${srcdir}
2041     GDBTK_SRC_DIR=`pwd`
2042     cd $here
2043
2044     SC_PATH_TCLCONFIG
2045
2046     # If $no_tk is nonempty, then we can't do Tk, and there is no
2047     # point to doing Tcl.
2048     SC_PATH_TKCONFIG
2049
2050     if test -z "${no_tcl}" -a -z "${no_tk}"; then
2051         SC_LOAD_TCLCONFIG
2052
2053         # Check for in-tree tcl
2054         here=`pwd`
2055         cd ${srcdir}/..
2056         topdir=`pwd`
2057         cd ${here}
2058
2059         intree="no"
2060         if test "${TCL_SRC_DIR}" = "${topdir}/tcl"; then
2061           intree="yes"
2062         fi
2063
2064         # Find Tcl private headers
2065         if test x"${intree}" = xno; then
2066           CY_AC_TCL_PRIVATE_HEADERS
2067           TCL_INCLUDE="${TCL_INCLUDE_SPEC} ${TCL_PRIVATE_INCLUDE}"
2068           TCL_LIBRARY="${TCL_LIB_SPEC}"
2069           TCL_DEPS=""
2070         else
2071           # If building tcl in the same src tree, private headers
2072           # are not needed, but we need to be sure to use the right
2073           # headers library
2074           TCL_INCLUDE="-I${TCL_SRC_DIR}/generic"
2075           TCL_LIBRARY="${TCL_BUILD_LIB_SPEC}"
2076           TCL_DEPS="../tcl/${configdir}${TCL_LIB_FILE}"
2077         fi
2078         AC_SUBST(TCL_INCLUDE)
2079         AC_SUBST(TCL_LIBRARY)
2080         AC_SUBST(TCL_DEPS)
2081
2082         SC_LOAD_TKCONFIG
2083
2084         # Check for in-tree Tk
2085         intree="no"
2086         if test "${TK_SRC_DIR}" = "${topdir}/tk"; then
2087           intree="yes"
2088         fi
2089
2090         # Find Tk private headers
2091         if test x"${intree}" = xno; then
2092           CY_AC_TK_PRIVATE_HEADERS
2093           TK_INCLUDE="${TK_INCLUDE_SPEC} ${TK_PRIVATE_INCLUDE}"
2094           TK_LIBRARY=${TK_LIB_SPEC}
2095           TK_DEPS=""
2096         else
2097           TK_INCLUDE="-I${TK_SRC_DIR}/generic"
2098           TK_LIBRARY="${TK_BUILD_LIB_SPEC}"
2099           TK_DEPS="../tk/${configdir}/${TK_LIB_FILE}"
2100         fi
2101         AC_SUBST(TK_INCLUDE)
2102         AC_SUBST(TK_LIBRARY)
2103         AC_SUBST(TK_DEPS)
2104         AC_SUBST(TK_XINCLUDES)
2105
2106         ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
2107
2108         # Include some libraries that Tcl and Tk want.
2109         TCL_LIBS='$(LIBGUI) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
2110         # Yes, the ordering seems wrong here.  But it isn't.
2111         # TK_LIBS is the list of libraries that need to be linked
2112         # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
2113         # were in LIBS then any link tests after this point would
2114         # try to include things like `$(LIBGUI)', which wouldn't work.
2115         GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
2116
2117         CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
2118         CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
2119         CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
2120         CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
2121         CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
2122         CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
2123         CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
2124
2125         if test x$gdb_cv_os_cygwin = xyes; then
2126           WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
2127           WIN32LDAPP="-Wl,--subsystem,console"
2128           CONFIG_OBS="${CONFIG_OBS} gdbres.o"
2129         fi
2130
2131         AC_CONFIG_SUBDIRS(gdbtk)
2132     fi
2133 fi
2134
2135 AC_SUBST(X_CFLAGS)
2136 AC_SUBST(X_LDFLAGS)
2137 AC_SUBST(X_LIBS)
2138 AC_SUBST(GDBTKLIBS)
2139 AC_SUBST(GDBTK_CFLAGS)
2140 AC_SUBST(GDBTK_SRC_DIR)
2141
2142 AC_PATH_X
2143
2144 # Unlike the sim directory, whether a simulator is linked is controlled by
2145 # presence of a gdb_sim definition in the target configure.tgt entry.
2146 # This code just checks for a few cases where we'd like to ignore those
2147 # definitions, even when they're present in the '.mt' file.  These cases
2148 # are when --disable-sim is specified, or if the simulator directory is
2149 # not part of the source tree.
2150 #
2151 AC_ARG_ENABLE(sim,
2152 AS_HELP_STRING([--enable-sim], [link gdb with simulator]),
2153 [echo "enable_sim = $enable_sim";
2154  echo "enableval = ${enableval}";
2155  case "${enableval}" in
2156   yes) ignore_sim=false ;;
2157   no)  ignore_sim=true ;;
2158   *)   ignore_sim=false ;;
2159  esac],
2160 [ignore_sim=false])
2161
2162 if test ! -d "${srcdir}/../sim"; then
2163   ignore_sim=true
2164 fi
2165
2166 SIM=
2167 SIM_OBS=
2168 if test "${ignore_sim}" = "false"; then
2169   if test x"${gdb_sim}" != x ; then
2170     SIM="${gdb_sim}"
2171     SIM_OBS="remote-sim.o"
2172     AC_DEFINE(WITH_SIM, 1, [Define if the simulator is being linked in.])
2173
2174     # Some tdep code should only be compiled in when the ppc sim is
2175     # built.  PR sim/13418.
2176     case $target in
2177       powerpc*-*-*)
2178         AC_DEFINE(WITH_PPC_SIM, 1, [Define if the PPC simulator is being linked in.])
2179         ;;
2180     esac
2181   fi
2182 fi
2183 AC_SUBST(SIM)
2184 AC_SUBST(SIM_OBS)
2185
2186 AC_SUBST(ENABLE_CFLAGS)
2187 AC_SUBST(PROFILE_CFLAGS)
2188
2189 AC_SUBST(CONFIG_OBS)
2190 AC_SUBST(CONFIG_DEPS)
2191 AC_SUBST(CONFIG_SRCS)
2192 AC_SUBST(CONFIG_ALL)
2193 AC_SUBST(CONFIG_CLEAN)
2194 AC_SUBST(CONFIG_INSTALL)
2195 AC_SUBST(CONFIG_UNINSTALL)
2196
2197 # List of host floatformats.
2198 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
2199 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
2200 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
2201
2202 # target_subdir is used by the testsuite to find the target libraries.
2203 target_subdir=
2204 if test "${host}" != "${target}"; then
2205     target_subdir="${target_alias}/"
2206 fi
2207 AC_SUBST(target_subdir)
2208
2209 # Import nat definitions.
2210 nat_makefile_frag=/dev/null
2211 if test "${gdb_native}" = "yes"; then
2212   . ${srcdir}/configure.nat
2213   nativefile=$NAT_FILE
2214 fi
2215
2216 AC_SUBST(NAT_FILE)
2217 AC_SUBST(NATDEPFILES)
2218 AC_SUBST(NAT_CDEPS)
2219 AC_SUBST(LOADLIBES)
2220 AC_SUBST(MH_CFLAGS)
2221 AC_SUBST(XM_CLIBS)
2222 AC_SUBST(NAT_GENERATED_FILES)
2223 AC_SUBST(HAVE_NATIVE_GCORE_HOST)
2224 AC_SUBST_FILE(nat_makefile_frag)
2225
2226 if test x"${gdb_osabi}" != x ; then
2227     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
2228                        [Define to the default OS ABI for this configuration.])
2229 fi
2230
2231 # Enable multi-ice-gdb-server.
2232 AC_ARG_ENABLE(multi-ice,
2233 AS_HELP_STRING([--enable-multi-ice], [build the multi-ice-gdb-server]),
2234   [case $enableval in
2235     yes | no)
2236       ;;
2237     *) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;;
2238   esac])
2239 if test "x$enable_multi_ice" = xyes; then
2240    AC_CONFIG_SUBDIRS(multi-ice)
2241 fi
2242
2243 AC_ARG_ENABLE(gdbserver,
2244 AS_HELP_STRING([--enable-gdbserver],
2245                [automatically build gdbserver (yes/no/auto, default is auto)]),
2246 [case "${enableval}" in
2247   yes| no|auto) ;;
2248   *) AC_MSG_ERROR(bad value ${enableval} for --enable-gdbserver option) ;;
2249 esac],[enable_gdbserver=auto])
2250
2251 # We only build gdbserver automatically in a native configuration, and
2252 # only if the user did not explicitly disable its build.
2253 if test "$gdb_native" = "yes" -a "$enable_gdbserver" != "no"; then
2254   AC_MSG_CHECKING(whether gdbserver is supported on this host)
2255   if test "x$build_gdbserver" = xyes; then
2256     AC_MSG_RESULT(yes)
2257     AC_CONFIG_SUBDIRS(gdbserver)
2258     gdbserver_build_enabled=yes
2259   else
2260     AC_MSG_RESULT(no)
2261   fi
2262 fi
2263
2264 # If the user explicitly request the gdbserver to be built, verify that
2265 # we were in fact able to enable it.
2266 if test "$enable_gdbserver" = "yes" -a "$gdbserver_build_enabled" != "yes"; then
2267   AC_MSG_ERROR(Automatic gdbserver build is not supported for this configuration)
2268 fi
2269
2270 # Check for babeltrace and babeltrace-ctf
2271 AC_ARG_WITH(babeltrace,
2272   AC_HELP_STRING([--with-babeltrace], [include babeltrace support (auto/yes/no)]),
2273   [], [with_babeltrace=auto])
2274 AC_MSG_CHECKING([whether to use babeltrace])
2275 AC_MSG_RESULT([$with_babeltrace])
2276
2277 if test "x$with_babeltrace" = "xno"; then
2278   AC_MSG_WARN([babletrace support disabled; GDB is unable to read CTF data.])
2279 else
2280   # Append -Werror to CFLAGS so that configure can catch the warning
2281   # "assignment from incompatible pointer type", which is related to
2282   # the babeltrace change from 1.0.3 to 1.1.0.  Babeltrace 1.1.0 works
2283   # in GDB, while babeltrace 1.0.3 is broken.
2284   # AC_LIB_HAVE_LINKFLAGS may modify CPPFLAGS in it, so it should be
2285   # safe to save and restore CFLAGS here.
2286   saved_CFLAGS=$CFLAGS
2287   CFLAGS="$CFLAGS -Werror"
2288   AC_LIB_HAVE_LINKFLAGS([babeltrace], [babeltrace-ctf],
2289                         [#include <babeltrace/babeltrace.h>
2290                          #include <babeltrace/ctf/events.h>
2291                          #include <babeltrace/ctf/iterator.h>],
2292                         [struct bt_iter_pos *pos = bt_iter_get_pos (bt_ctf_get_iter (NULL));
2293                         struct bt_ctf_event *event = NULL;
2294                         const struct bt_definition *scope;
2295
2296                         pos->type = BT_SEEK_BEGIN;
2297                         bt_iter_set_pos (bt_ctf_get_iter (NULL), pos);
2298                         scope = bt_ctf_get_top_level_scope (event,
2299                                                            BT_STREAM_EVENT_HEADER);
2300                         bt_ctf_get_uint64 (bt_ctf_get_field (event, scope, "id"));
2301                         ])
2302   CFLAGS=$saved_CFLAGS
2303
2304   if test "$HAVE_LIBBABELTRACE" != yes; then
2305      if test "$with_babeltrace" = yes; then
2306        AC_MSG_ERROR([babeltrace is missing or unusable])
2307      else
2308        AC_MSG_WARN([babeltrace is missing or unusable; GDB is unable to read CTF data.])
2309      fi
2310   fi
2311 fi
2312
2313 # If nativefile (NAT_FILE) is not set in configure.nat, we link to an
2314 # empty version.
2315
2316 files=
2317 links=
2318
2319 rm -f nm.h
2320 if test "${nativefile}" != ""; then
2321     case "${nativefile}" in
2322       nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
2323       * ) GDB_NM_FILE="${nativefile}"
2324     esac
2325     files="${files} ${GDB_NM_FILE}"
2326     links="${links} nm.h"
2327     AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}", [nativefile])
2328 fi
2329 AC_SUBST(GDB_NM_FILE)
2330
2331 dnl Add dependency for xsltproc if building with maintainer-mode enabled.
2332 AC_PATH_PROGS(XSLTPROC, xsltproc, missing)
2333 if test "x$USE_MAINTAINER_MODE" = xyes; then
2334   if test "${XSLTPROC}" = missing; then
2335     AC_ERROR(unable to find xsltproc.  maintainer-mode requires xsltproc.)
2336   fi
2337 fi
2338 AC_SUBST(XSLTPROC)
2339
2340 AC_LINK_FILES($files, $links)
2341
2342 dnl Check for exe extension set on certain hosts (e.g. Win32)
2343 AC_EXEEXT
2344
2345 dnl  Detect the character set used by this host.
2346 dnl  At the moment, we just assume it's UTF-8.
2347 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "UTF-8",
2348           [Define to be a string naming the default host character set.])
2349
2350 if $development; then
2351   AC_DEFINE(GDB_SELF_TEST, 1,
2352             [Define if self-testing features should be enabled])
2353   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_UNITTESTS_OBS)"
2354   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_UNITTESTS_SRCS)"
2355 fi
2356
2357 GDB_AC_TRANSFORM([gdb], [GDB_TRANSFORM_NAME])
2358 GDB_AC_TRANSFORM([gcore], [GCORE_TRANSFORM_NAME])
2359 AC_CONFIG_FILES([gcore], [chmod +x gcore])
2360 AC_CONFIG_FILES([Makefile gdb-gdb.gdb doc/Makefile data-directory/Makefile],
2361 [
2362 case x$CONFIG_HEADERS in
2363 xconfig.h:config.in)
2364 echo > stamp-h ;;
2365 esac
2366 ])
2367
2368 AC_OUTPUT