gdb/configure.ac

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995-2012 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Process this file with autoconf to produce a configure script.
  20
  21 AC_PREREQ(2.59)dnl
  22 AC_INIT(main.c)
  23 AC_CONFIG_HEADER(config.h:config.in)
  24 AM_MAINTAINER_MODE
  25
  26 AC_PROG_CC
  27 AC_USE_SYSTEM_EXTENSIONS
  28 gl_EARLY
  29 ACX_LARGEFILE
  30 AM_PROG_CC_STDC
  31
  32 AC_CONFIG_AUX_DIR(..)
  33 AC_CANONICAL_SYSTEM
  34
  35 # Dependency checking.
  36 ZW_CREATE_DEPDIR
  37 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  38
  39 # Check for the 'make' the user wants to use.
  40 AC_CHECK_PROGS(MAKE, make)
  41 MAKE_IS_GNU=
  42 case "`$MAKE --version 2>&1 | sed 1q`" in
  43   *GNU*)
  44     MAKE_IS_GNU=yes
  45     ;;
  46 esac
  47 AM_CONDITIONAL(GMAKE, test "$MAKE_IS_GNU" = yes)
  48 AC_PROG_MAKE_SET
  49
  50 dnl List of object files and targets accumulated by configure.
  51
  52 CONFIG_OBS=
  53 CONFIG_DEPS=
  54 CONFIG_SRCS=
  55 ENABLE_CFLAGS=
  56
  57 CONFIG_ALL=
  58 CONFIG_CLEAN=
  59 CONFIG_INSTALL=
  60 CONFIG_UNINSTALL=
  61
  62 dnl Set up for gettext.
  63 ZW_GNU_GETTEXT_SISTER_DIR
  64
  65 localedir='${datadir}/locale'
  66 AC_SUBST(localedir)
  67
  68 if test x"$USE_NLS" = xyes; then
  69    CONFIG_ALL="$CONFIG_ALL all-po"
  70    CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
  71    CONFIG_INSTALL="$CONFIG_INSTALL install-po"
  72    CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
  73 fi
  74
  75 gl_INIT
  76
  77 # For Makefile dependencies.
  78 GNULIB_STDINT_H=
  79 if test x"$STDINT_H" != x; then
  80   GNULIB_STDINT_H=gnulib/$STDINT_H
  81 fi
  82 AC_SUBST(GNULIB_STDINT_H)
  83
  84 PACKAGE=gdb
  85 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
  86 AC_SUBST(PACKAGE)
  87
  88 # We never need to detect it in this sub-configure.
  89 # But preserve it for config.status --recheck.
  90 AC_ARG_VAR(MAKEINFO,
  91   [Parent configure detects if it is of sufficient version.])
  92 AC_ARG_VAR(MAKEINFOFLAGS,
  93   [Parameters for MAKEINFO.])
  94
  95 MAKEINFO_EXTRA_FLAGS=""
  96 AC_CACHE_CHECK([whether $MAKEINFO supports @click], gdb_cv_have_makeinfo_click,
  97   [echo '@clicksequence{a @click{} b}' >conftest.texinfo
  98   if eval "$MAKEINFO conftest.texinfo >&5 2>&5"; then
  99     gdb_cv_have_makeinfo_click=yes
 100   else
 101     gdb_cv_have_makeinfo_click=no
 102   fi])
 103 if test x"$gdb_cv_have_makeinfo_click" = xyes; then
 104   MAKEINFO_EXTRA_FLAGS="$MAKEINFO_EXTRA_FLAGS -DHAVE_MAKEINFO_CLICK"
 105 fi
 106 AC_SUBST(MAKEINFO_EXTRA_FLAGS)
 107
 108 # GDB does not use automake, but gnulib does.  This line lets us
 109 # generate its Makefile.in.
 110 AM_INIT_AUTOMAKE(gdb, UNUSED-VERSION, [no-define])
 111
 112 GDB_AC_WITH_DIR(DEBUGDIR, separate-debug-dir,
 113     [look for global separate debug info in this path @<:@LIBDIR/debug@:>@],
 114     [${libdir}/debug])
 115
 116 # We can't pass paths as command line arguments.
 117 # Mingw32 tries to be clever and will convert the paths for us.
 118 # For example -DBINDIR="/usr/local/bin" passed on the command line may get
 119 # converted to -DBINDIR="E:/msys/mingw32/msys/1.0/local/bin".
 120 # This breaks GDB's relocatable path conversions since paths passed in
 121 # config.h would not get so translated, the path prefixes no longer match.
 122 AC_DEFINE_DIR(BINDIR, bindir, [Directory of programs.])
 123
 124 # GDB's datadir relocation
 125
 126 GDB_AC_WITH_DIR(GDB_DATADIR, gdb-datadir,
 127     [look for global separate data files in this path @<:@DATADIR/gdb@:>@],
 128     [${datadir}/gdb])
 129
 130 AC_ARG_WITH(relocated-sources,
 131 AS_HELP_STRING([--with-relocated-sources=PATH], [automatically relocate this path for source files]),
 132 [reloc_srcdir="${withval}"
 133  AC_DEFINE_DIR(RELOC_SRCDIR, reloc_srcdir,
 134               [Relocated directory for source files. ])
 135 ])
 136
 137 AC_MSG_CHECKING([for default auto-load safe-path])
 138 AC_ARG_WITH(auto-load-safe-path,
 139 AS_HELP_STRING([--with-auto-load-safe-path=PATH], [directories safe to hold auto-loaded files])
 140 AS_HELP_STRING([--without-auto-load-safe-path], [do not restrict auto-loaded files locations]),
 141 [if test "$with_auto_load_safe_path" = "no"; then
 142    with_auto_load_safe_path=""
 143  fi],
 144 [with_auto_load_safe_path="$prefix"])
 145 AC_DEFINE_DIR(DEFAULT_AUTO_LOAD_SAFE_PATH, with_auto_load_safe_path,
 146               [Directories safe to hold auto-loaded files.])
 147 AC_MSG_RESULT([$with_auto_load_safe_path])
 148
 149 AC_CONFIG_SUBDIRS(testsuite)
 150
 151 # Check whether to support alternative target configurations
 152 AC_ARG_ENABLE(targets,
 153 AS_HELP_STRING([--enable-targets=TARGETS], [alternative target configurations]),
 154 [case "${enableval}" in
 155   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
 156             ;;
 157   no)       enable_targets= ;;
 158   *)        enable_targets=$enableval ;;
 159 esac])
 160
 161 # Check whether to enable 64-bit support on 32-bit hosts
 162 AC_ARG_ENABLE(64-bit-bfd,
 163 AS_HELP_STRING([--enable-64-bit-bfd], [64-bit support (on hosts with narrower word sizes)]),
 164 [case "${enableval}" in
 165   yes)  want64=true  ;;
 166   no)   want64=false ;;
 167   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
 168 esac],[want64=false])dnl
 169
 170 # Provide defaults for some variables set by the per-host and per-target
 171 # configuration.
 172 gdb_host_obs=posix-hdep.o
 173
 174 if test "${target}" = "${host}"; then
 175   gdb_native=yes
 176 else
 177   gdb_native=no
 178 fi
 179
 180 . $srcdir/configure.host
 181
 182 # Accumulate some settings from configure.tgt over all enabled targets
 183
 184 TARGET_OBS=
 185 all_targets=
 186
 187 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 188 do
 189   if test "$targ_alias" = "all"; then
 190     all_targets=true
 191   else
 192     # Canonicalize the secondary target names.
 193     result=`$ac_config_sub $targ_alias 2>/dev/null`
 194     if test -n "$result"; then
 195         targ=$result
 196     else
 197         targ=$targ_alias
 198     fi
 199
 200     . ${srcdir}/configure.tgt
 201
 202     AS_IF([test -z "${gdb_target_obs}"],
 203       [AC_MSG_ERROR([configuration ${targ} is unsupported.])])
 204
 205     # Target-specific object files
 206     for i in ${gdb_target_obs}; do
 207         case " $TARGET_OBS " in
 208         *" ${i} "*) ;;
 209         *)
 210           TARGET_OBS="$TARGET_OBS ${i}"
 211           ;;
 212         esac
 213     done
 214
 215     # Check whether this target needs 64-bit CORE_ADDR
 216     if test x${want64} = xfalse; then
 217       . ${srcdir}/../bfd/config.bfd
 218     fi
 219   fi
 220 done
 221
 222 if test x${all_targets} = xtrue; then
 223
 224   # We want all 64-bit targets if we either:
 225   #  - run on a 64-bit host  or
 226   #  - already require 64-bit support for some other target  or
 227   #  - the --enable-64-bit-bfd option was supplied
 228   # Otherwise we only support all 32-bit targets.
 229   #
 230   # NOTE: This test must be in sync with the corresponding
 231   #       tests in BFD!
 232
 233   if test x${want64} = xfalse; then
 234     AC_CHECK_SIZEOF(long)
 235     if test "x${ac_cv_sizeof_long}" = "x8"; then
 236       want64=true
 237     fi
 238   fi
 239   if test x${want64} = xtrue; then
 240     TARGET_OBS='$(ALL_TARGET_OBS) $(ALL_64_TARGET_OBS)'
 241   else
 242     TARGET_OBS='$(ALL_TARGET_OBS)'
 243   fi
 244 fi
 245
 246 AC_SUBST(TARGET_OBS)
 247
 248 # For other settings, only the main target counts.
 249 gdb_sim=
 250 gdb_osabi=
 251 build_gdbserver=
 252 targ=$target; . ${srcdir}/configure.tgt
 253
 254 # Fetch the default architecture and default target vector from BFD.
 255 targ=$target; . $srcdir/../bfd/config.bfd
 256
 257 # We only want the first architecture, so strip off the others if
 258 # there is more than one.
 259 targ_archs=`echo $targ_archs | sed 's/ .*//'`
 260
 261 if test "x$targ_archs" != x; then
 262   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
 263     [Define to BFD's default architecture. ])
 264 fi
 265 if test "x$targ_defvec" != x; then
 266   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
 267     [Define to BFD's default target vector. ])
 268 fi
 269
 270 # The CLI cannot be disabled yet, but may be in the future.
 271
 272 # Enable CLI.
 273 AC_ARG_ENABLE(gdbcli,
 274 AS_HELP_STRING([--disable-gdbcli], [disable command-line interface (CLI)]),
 275   [case $enableval in
 276     yes)
 277       ;;
 278     no)
 279       AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;;
 280     *)
 281       AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;;
 282   esac],
 283   [enable_gdbcli=yes])
 284 if test x"$enable_gdbcli" = xyes; then
 285   if test -d $srcdir/cli; then
 286     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)"
 287     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)"
 288     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)"
 289     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)"
 290   fi
 291 fi
 292
 293 # Enable MI.
 294 AC_ARG_ENABLE(gdbmi,
 295 AS_HELP_STRING([--disable-gdbmi], [disable machine-interface (MI)]),
 296   [case $enableval in
 297     yes | no)
 298       ;;
 299     *)
 300       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 301   esac],
 302   [enable_gdbmi=yes])
 303 if test x"$enable_gdbmi" = xyes; then
 304   if test -d $srcdir/mi; then
 305     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 306     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 307     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 308     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 309   fi
 310 fi
 311
 312 # Enable TUI.
 313 AC_ARG_ENABLE(tui,
 314 AS_HELP_STRING([--enable-tui], [enable full-screen terminal user interface (TUI)]),
 315   [case $enableval in
 316     yes | no | auto)
 317       ;;
 318     *)
 319       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 320   esac],enable_tui=auto)
 321
 322 # Enable gdbtk.
 323 AC_ARG_ENABLE(gdbtk,
 324 AS_HELP_STRING([--enable-gdbtk], [enable gdbtk graphical user interface (GUI)]),
 325   [case $enableval in
 326     yes | no)
 327       ;;
 328     *)
 329       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 330   esac],
 331   [if test -d $srcdir/gdbtk; then
 332     enable_gdbtk=yes
 333   else
 334     enable_gdbtk=no
 335   fi])
 336 # We unconditionally disable gdbtk tests on selected platforms.
 337 case $host_os in
 338   go32* | windows*)
 339     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 340     enable_gdbtk=no ;;
 341 esac
 342
 343 # Libunwind support for ia64.
 344
 345 AC_ARG_WITH(libunwind-ia64,
 346 AS_HELP_STRING([--with-libunwind-ia64],
 347                [use libunwind frame unwinding for ia64 targets]),,
 348             [with_libunwind_ia64=auto])
 349
 350 # Backward compatibility option.
 351 if test "${with_libunwind+set}" = set; then
 352   if test x"$with_libunwind_ia64" != xauto; then
 353     AC_MSG_ERROR(
 354       [option --with-libunwind is deprecated, use --with-libunwind-ia64])
 355   fi
 356   AC_MSG_WARN([option --with-libunwind is deprecated, use --with-libunwind-ia64])
 357   with_libunwind_ia64="$with_libunwind"
 358 fi
 359
 360 case "$with_libunwind_ia64" in
 361   yes | no)
 362     ;;
 363   auto)
 364     AC_CHECK_HEADERS(libunwind-ia64.h)
 365     with_libunwind_ia64=$ac_cv_header_libunwind_ia64_h
 366     ;;
 367   *)
 368     AC_MSG_ERROR(
 369       [bad value $with_libunwind_ia64 for GDB --with-libunwind-ia64 option])
 370     ;;
 371 esac
 372
 373 if test x"$with_libunwind_ia64" = xyes; then
 374   AC_CHECK_HEADERS(libunwind-ia64.h)
 375   if test x"$ac_cv_header_libunwind_ia64_h" != xyes; then
 376     AC_MSG_ERROR([GDB option --with-libunwind-ia64 requires libunwind-ia64.h])
 377   fi
 378   CONFIG_OBS="$CONFIG_OBS ia64-libunwind-tdep.o"
 379   CONFIG_DEPS="$CONFIG_DEPS ia64-libunwind-tdep.o"
 380   CONFIG_SRCS="$CONFIG_SRCS ia64-libunwind-tdep.c"
 381 fi
 382
 383 opt_curses=no
 384 AC_ARG_WITH(curses, AS_HELP_STRING([--with-curses], [use the curses library instead of the termcap library]), opt_curses=$withval)
 385
 386 prefer_curses=no
 387 if test "$opt_curses" = "yes"; then
 388   prefer_curses=yes
 389 fi
 390
 391 # Profiling support.
 392 AC_ARG_ENABLE(profiling,
 393 AS_HELP_STRING([--enable-profiling], [enable profiling of GDB]),
 394   [case $enableval in
 395     yes | no)
 396       ;;
 397     *)
 398       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 399   esac],
 400  [enable_profiling=no])
 401
 402 AC_CHECK_FUNCS(monstartup _mcleanup)
 403 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 404 [AC_TRY_LINK(
 405 [#include <stdlib.h>
 406 extern char _etext;
 407 ],
 408 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 409 if test $ac_cv_var__etext = yes; then
 410   AC_DEFINE(HAVE__ETEXT, 1,
 411             [Define to 1 if your system has the _etext variable. ])
 412 fi
 413 AC_CACHE_CHECK([for etext], ac_cv_var_etext,
 414 [AC_TRY_LINK(
 415 [#include <stdlib.h>
 416 extern char etext;
 417 ],
 418 [free (&etext);], ac_cv_var_etext=yes, ac_cv_var_etext=no)])
 419 if test $ac_cv_var_etext = yes; then
 420   AC_DEFINE(HAVE_ETEXT, 1,
 421             [Define to 1 if your system has the etext variable. ])
 422 fi
 423 if test "$enable_profiling" = yes ; then
 424   if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
 425     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 426   fi
 427   PROFILE_CFLAGS=-pg
 428   OLD_CFLAGS="$CFLAGS"
 429   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 430
 431   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 432     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 433      ac_cv_cc_supports_pg=no)])
 434
 435   if test $ac_cv_cc_supports_pg = no; then
 436     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 437   fi
 438
 439   CFLAGS="$OLD_CFLAGS"
 440 fi
 441
 442 ACX_PKGVERSION([GDB])
 443 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 444 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 445 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 446
 447 # --------------------- #
 448 # Checks for programs.  #
 449 # --------------------- #
 450
 451 AC_PROG_AWK
 452 AC_PROG_INSTALL
 453 AC_PROG_LN_S
 454 AC_PROG_RANLIB
 455 AC_PROG_YACC
 456
 457 AC_CHECK_TOOL(AR, ar)
 458 AC_CHECK_TOOL(DLLTOOL, dlltool)
 459 AC_CHECK_TOOL(WINDRES, windres)
 460
 461 # Needed for GNU/Hurd.
 462 AC_CHECK_TOOL(MIG, mig)
 463
 464 # ---------------------- #
 465 # Checks for libraries.  #
 466 # ---------------------- #
 467
 468 # We might need to link with -lm; most simulators need it.
 469 AC_CHECK_LIB(m, main)
 470
 471 # We need to link with -lw to get `wctype' on Solaris before Solaris
 472 # 2.6.  Solaris 2.6 and beyond have this function in libc, and have a
 473 # libw that some versions of the GNU linker cannot hanle (GNU ld 2.9.1
 474 # is known to have this problem).  Therefore we avoid libw if we can.
 475 AC_CHECK_FUNC(wctype, [],
 476   [AC_CHECK_LIB(w, wctype)])
 477
 478 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 479 AC_SEARCH_LIBS(gethostbyname, nsl)
 480
 481 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 482 AC_SEARCH_LIBS(socketpair, socket)
 483
 484 # Link in zlib if we can.  This allows us to read compressed debug sections.
 485 AM_ZLIB
 486
 487 # On HP/UX we may need libxpdl for dlgetmodinfo (used by solib-pa64.c).
 488 AC_SEARCH_LIBS(dlgetmodinfo, [dl xpdl])
 489
 490 AM_ICONV
 491
 492 # GDB may fork/exec the iconv program to get the list of supported character
 493 # sets.  Allow the user to specify where to find it.
 494 # There are several factors affecting the choice of option name:
 495 # - There is already --with-libiconv-prefix but we can't use it, it specifies
 496 #   the build-time location of libiconv files.
 497 # - The program we need to find is iconv, which comes with glibc.  The user
 498 #   doesn't necessarily have libiconv installed.  Therefore naming this
 499 #   --with-libiconv-foo feels wrong.
 500 # - We want the path to be relocatable, but GDB_AC_DEFINE_RELOCATABLE is
 501 #   defined to work on directories not files (though it really doesn't know
 502 #   the difference).
 503 # - Calling this --with-iconv-prefix is perceived to cause too much confusion
 504 #   with --with-libiconv-prefix.
 505 # Putting these together is why the option name is --with-iconv-bin.
 506
 507 AC_ARG_WITH(iconv-bin,
 508 AS_HELP_STRING([--with-iconv-bin=PATH], [specify where to find the iconv program]),
 509 [iconv_bin="${withval}"
 510  AC_DEFINE_UNQUOTED([ICONV_BIN], ["${iconv_bin}"],
 511                     [Path of directory of iconv program.])
 512  GDB_AC_DEFINE_RELOCATABLE(ICONV_BIN, iconv, ${iconv_bin})
 513 ])
 514
 515 # On alpha-osf, it appears that libtermcap and libcurses are not compatible.
 516 # There is a very specific comment in /usr/include/curses.h explaining that
 517 # termcap routines built into libcurses must not be used.
 518 #
 519 # The symptoms we observed so far is GDB unexpectedly changing
 520 # the terminal settings when tgetent is called - this is particularly
 521 # visible as the output is missing carriage returns, and so rapidly
 522 # becomes very hard to read.
 523 #
 524 # The readline configure script has already decided that libtermcap
 525 # was enough for its purposes, and so decided to build readline using
 526 # libtermcap.  Since the TUI mode requires curses, building GDB with
 527 # TUI enabled results in both libraries to be used at the same time,
 528 # which is not allowed.  This basically means that GDB with TUI is
 529 # broken on alpha-osf.
 530
 531 case $host_os in
 532   osf* )
 533     if test x"$enable_tui" = xyes; then
 534       AC_MSG_ERROR([Building GDB with TUI mode is not supported on this host])
 535     fi
 536     if test x"$enable_tui" = xauto; then
 537       enable_tui=no
 538     fi
 539     ;;
 540 esac
 541
 542 # For the TUI, we need enhanced curses functionality.
 543 if test x"$enable_tui" != xno; then
 544   prefer_curses=yes
 545 fi
 546
 547 curses_found=no
 548 if test x"$prefer_curses" = xyes; then
 549   # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
 550   # curses library because the latter might not provide all the
 551   # functionality we need.  However, this leads to problems on systems
 552   # where the linker searches /usr/local/lib, but the compiler doesn't
 553   # search /usr/local/include, if ncurses is installed in /usr/local.  A
 554   # default installation of ncurses on alpha*-dec-osf* will lead to such
 555   # a situation.
 556   AC_SEARCH_LIBS(waddstr, [ncurses cursesX curses])
 557
 558   if test "$ac_cv_search_waddstr" != no; then
 559     curses_found=yes
 560   fi
 561 fi
 562
 563 # Check whether we should enable the TUI, but only do so if we really
 564 # can.
 565 if test x"$enable_tui" != xno; then
 566   if test -d $srcdir/tui; then
 567     if test "$curses_found" != no; then
 568       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
 569       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
 570       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
 571       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
 572     else
 573       if test x"$enable_tui" = xyes; then
 574         AC_MSG_ERROR([no enhanced curses library found; disable TUI])
 575       else
 576         AC_MSG_WARN([no enhanced curses library found; disabling TUI])
 577       fi
 578     fi
 579   fi
 580 fi
 581
 582 # Since GDB uses Readline, we need termcap functionality.  In many
 583 # cases this will be provided by the curses library, but some systems
 584 # have a seperate termcap library, or no curses library at all.
 585
 586 case $host_os in
 587   cygwin*)
 588     if test -d $srcdir/libtermcap; then
 589       LIBS="../libtermcap/libtermcap.a $LIBS"
 590       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 591     fi ;;
 592   go32* | *djgpp*)
 593     ac_cv_search_tgetent="none required"
 594     ;;
 595   *mingw32*)
 596     ac_cv_search_tgetent="none required"
 597     CONFIG_OBS="$CONFIG_OBS windows-termcap.o"
 598     ;;
 599 esac
 600
 601 # These are the libraries checked by Readline.
 602 AC_SEARCH_LIBS(tgetent, [termcap tinfo curses ncurses])
 603
 604 if test "$ac_cv_search_tgetent" = no; then
 605   AC_MSG_ERROR([no termcap library found])
 606 fi
 607
 608 AC_ARG_WITH([system-readline],
 609   [AS_HELP_STRING([--with-system-readline],
 610                   [use installed readline library])])
 611
 612 if test "$with_system_readline" = yes; then
 613   READLINE=-lreadline
 614   READLINE_DEPS=
 615   READLINE_CFLAGS=
 616   READLINE_TEXI_INCFLAG=
 617 else
 618   READLINE='$(READLINE_DIR)/libreadline.a'
 619   READLINE_DEPS='$(READLINE)'
 620   READLINE_CFLAGS='-I$(READLINE_SRC)/..'
 621   READLINE_TEXI_INCFLAG='-I $(READLINE_DIR)'
 622 fi
 623 AC_SUBST(READLINE)
 624 AC_SUBST(READLINE_DEPS)
 625 AC_SUBST(READLINE_CFLAGS)
 626 AC_SUBST(READLINE_TEXI_INCFLAG)
 627
 628 # Generate jit-reader.h
 629
 630 # This is typedeffed to GDB_CORE_ADDR in jit-reader.h
 631 TARGET_PTR=
 632
 633 AC_CHECK_SIZEOF(unsigned long long)
 634 AC_CHECK_SIZEOF(unsigned long)
 635 AC_CHECK_SIZEOF(unsigned __int128)
 636
 637 if test "x${ac_cv_sizeof_unsigned_long}" = "x8"; then
 638   TARGET_PTR="unsigned long"
 639 elif test "x${ac_cv_sizeof_unsigned_long_long}" = "x8"; then
 640   TARGET_PTR="unsigned long long"
 641 elif test "x${ac_cv_sizeof_unsigned___int128}" = "x16"; then
 642   TARGET_PTR="unsigned __int128"
 643 else
 644   TARGET_PTR="unsigned long"
 645 fi
 646
 647 AC_SUBST(TARGET_PTR)
 648 AC_CONFIG_FILES([jit-reader.h:jit-reader.in])
 649
 650 AC_SEARCH_LIBS(dlopen, dl)
 651
 652 GDB_AC_WITH_DIR([JIT_READER_DIR], [jit-reader-dir],
 653                 [directory to load the JIT readers from],
 654                 [${libdir}/gdb])
 655
 656 AC_ARG_WITH(expat,
 657   AS_HELP_STRING([--with-expat], [include expat support (auto/yes/no)]),
 658   [], [with_expat=auto])
 659 AC_MSG_CHECKING([whether to use expat])
 660 AC_MSG_RESULT([$with_expat])
 661
 662 if test "${with_expat}" = no; then
 663   AC_MSG_WARN([expat support disabled; some features may be unavailable.])
 664   HAVE_LIBEXPAT=no
 665 else
 666   AC_LIB_HAVE_LINKFLAGS([expat], [], [#include "expat.h"],
 667                         [XML_Parser p = XML_ParserCreate (0);])
 668   if test "$HAVE_LIBEXPAT" != yes; then
 669     if test "$with_expat" = yes; then
 670       AC_MSG_ERROR([expat is missing or unusable])
 671     else
 672       AC_MSG_WARN([expat is missing or unusable; some features may be unavailable.])
 673     fi
 674   else
 675     save_LIBS=$LIBS
 676     LIBS="$LIBS $LIBEXPAT"
 677     AC_CHECK_FUNCS(XML_StopParser)
 678     LIBS=$save_LIBS
 679   fi
 680 fi
 681
 682 dnl Utility to simplify finding libpython.
 683 dnl $1 = pythonX.Y
 684 dnl $2 = the shell variable to assign the result to
 685 dnl      If libpython is found we store $version here.
 686 dnl $3 = additional flags to add to CPPFLAGS
 687 dnl $4 = additional flags to add to LIBS
 688
 689 AC_DEFUN([AC_TRY_LIBPYTHON],
 690 [
 691   version=$1
 692   define([have_libpython_var],$2)
 693   new_CPPFLAGS=$3
 694   new_LIBS=$4
 695   AC_MSG_CHECKING([for ${version}])
 696   save_CPPFLAGS=$CPPFLAGS
 697   save_LIBS=$LIBS
 698   CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
 699   LIBS="$LIBS $new_LIBS"
 700   found_usable_python=no
 701   AC_LINK_IFELSE(AC_LANG_PROGRAM([[#include "Python.h"]],
 702                                  [[Py_Initialize ();]]),
 703                  [have_libpython_var=${version}
 704                   found_usable_python=yes
 705                   PYTHON_CPPFLAGS=$new_CPPFLAGS
 706                   PYTHON_LIBS=$new_LIBS])
 707   CPPFLAGS=$save_CPPFLAGS
 708   LIBS=$save_LIBS
 709   AC_MSG_RESULT([${found_usable_python}])
 710 ])
 711
 712 dnl There are several different values for --with-python:
 713 dnl
 714 dnl no -   Don't include python support.
 715 dnl yes -  Include python support, error if it's missing.
 716 dnl        If we find python in $PATH, use it to fetch configure options,
 717 dnl        otherwise assume the compiler can find it with no help from us.
 718 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 719 dnl auto - Same as "yes", but if python is missing from the system,
 720 dnl        fall back to "no".
 721 dnl /path/to/python/exec-prefix -
 722 dnl        Use the python located in this directory.
 723 dnl        If /path/to/python/exec-prefix/bin/python exists, use it to find
 724 dnl        the compilation parameters.  Otherwise use
 725 dnl        -I/path/to/python/exec-prefix/include,
 726 dnl        -L/path/to/python/exec-prefix/lib.
 727 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 728 dnl        NOTE: This case is historical.  It is what was done for 7.0/7.1
 729 dnl        but is deprecated.
 730 dnl /path/to/python/executable -
 731 dnl        Run python-config.py with this version of python to fetch the
 732 dnl        compilation parameters.
 733 dnl        NOTE: This needn't be the real python executable.
 734 dnl        In a cross-compilation scenario (build != host), this could be
 735 dnl        a shell script that provides what python-config.py provides for
 736 dnl        --ldflags, --includes, --exec-prefix.
 737 dnl python-executable -
 738 dnl        Find python-executable in $PATH, and then handle the same as
 739 dnl        /path/to/python/executable.
 740 dnl
 741 dnl If a python program is specified, it is used to run python-config.py and
 742 dnl is passed --ldflags, --includes, --exec-prefix.
 743
 744 AC_ARG_WITH(python,
 745   AS_HELP_STRING([--with-python@<:@=PYTHON@:>@], [include python support (auto/yes/no/<python-program>)]),
 746   [], [with_python=auto])
 747 AC_MSG_CHECKING([whether to use python])
 748 AC_MSG_RESULT([$with_python])
 749
 750 if test "${with_python}" = no; then
 751   AC_MSG_WARN([python support disabled; some features may be unavailable.])
 752   have_libpython=no
 753 else
 754   case "${with_python}" in
 755   [[\\/]]* | ?:[[\\/]]*)
 756     if test -d ${with_python}; then
 757       # Assume the python binary is ${with_python}/bin/python.
 758       python_prog="${with_python}/bin/python"
 759       python_prefix=
 760       # If python does not exit ${with_python}/bin, then try in
 761       # ${with_python}.  On Windows/MinGW, this is where the Python
 762       # executable is.
 763       if test ! -x "${python_prog}"; then
 764         python_prog="${with_python}/python"
 765         python_prefix=
 766       fi
 767       if test ! -x "${python_prog}"; then
 768         # Fall back to gdb 7.0/7.1 behaviour.
 769         python_prog=missing
 770         python_prefix=${with_python}
 771       fi
 772     elif test -x "${with_python}"; then
 773       # While we can't run python compiled for $host (unless host == build),
 774       # the user could write a script that provides the needed information,
 775       # so we support that.
 776       python_prog=${with_python}
 777       python_prefix=
 778     else
 779       AC_ERROR(invalid value for --with-python)
 780     fi
 781     ;;
 782   */*)
 783     # Disallow --with-python=foo/bar.
 784     AC_ERROR(invalid value for --with-python)
 785     ;;
 786   *)
 787     # The user has either specified auto, yes, or the name of the python
 788     # program assumed to be in $PATH.
 789     python_prefix=
 790     case "${with_python}" in
 791     yes | auto)
 792       if test ${build} = ${host}; then
 793         AC_PATH_PROG(python_prog_path, python, missing)
 794         if test "${python_prog_path}" = missing; then
 795           python_prog=missing
 796         else
 797           python_prog=${python_prog_path}
 798         fi
 799       else
 800         # Not much we can do except assume the cross-compiler will find the
 801         # right files.
 802         python_prog=missing
 803       fi
 804       ;;
 805     *)
 806       # While we can't run python compiled for $host (unless host == build),
 807       # the user could write a script that provides the needed information,
 808       # so we support that.
 809       python_prog="${with_python}"
 810       AC_PATH_PROG(python_prog_path, ${python_prog}, missing)
 811       if test "${python_prog_path}" = missing; then
 812         AC_ERROR(unable to find python program ${python_prog})
 813       fi
 814       ;;
 815     esac
 816   esac
 817
 818   if test "${python_prog}" != missing; then
 819     # We have a python program to use, but it may be too old.
 820     # Don't flag an error for --with-python=auto (the default).
 821     have_python_config=yes
 822     python_includes=`${python_prog} ${srcdir}/python/python-config.py --includes`
 823     if test $? != 0; then
 824       have_python_config=failed
 825       if test "${with_python}" != auto; then
 826         AC_ERROR(failure running python-config --includes)
 827       fi
 828     fi
 829     python_libs=`${python_prog} ${srcdir}/python/python-config.py --ldflags`
 830     if test $? != 0; then
 831       have_python_config=failed
 832       if test "${with_python}" != auto; then
 833         AC_ERROR(failure running python-config --ldflags)
 834       fi
 835     fi
 836     python_prefix=`${python_prog} ${srcdir}/python/python-config.py --exec-prefix`
 837     if test $? != 0; then
 838       have_python_config=failed
 839       if test "${with_python}" != auto; then
 840         AC_ERROR(failure running python-config --exec-prefix)
 841       fi
 842     fi
 843   else
 844     # We do not have a python executable we can use to determine where
 845     # to find the Python headers and libs.  We cannot guess the include
 846     # path from the python_prefix either, because that include path
 847     # depends on the Python version.  So, there is nothing much we can
 848     # do except assume that the compiler will be able to find those files.
 849     python_includes=
 850     python_libs=
 851     have_python_config=no
 852   fi
 853
 854   # If we have python-config, only try the configuration it provides.
 855   # Otherwise fallback on the old way of trying different versions of
 856   # python in turn.
 857
 858   have_libpython=no
 859   if test "${have_python_config}" = yes; then
 860     # Determine the Python version by extracting "-lpython<version>"
 861     # part of the python_libs. <version> is usually X.Y with X and Y
 862     # being decimal numbers, but can also be XY (seen on Windows).
 863     #
 864     # The extraction is performed using sed with a regular expression.
 865     # Initially, the regexp used was using the '?' quantifier to make
 866     # the dot in the version number optional.  Unfortunately, this
 867     # does not work with non-GNU versions of sed because, because of
 868     # what looks like a limitation (the '?' quantifier does not work
 869     # with back-references).  We work around this limitation by using
 870     # the '*' quantifier instead.  It means that, in theory, we might
 871     # match unexpected version strings such as "-lpython2..7", but
 872     # this seems unlikely in practice.  And even if that happens,
 873     # an error will be triggered later on, when checking that version
 874     # number.
 875     python_version=`echo " ${python_libs} " \
 876                          | sed -e 's,^.* -l\(python[[0-9]]*[[.]]*[[0-9]]*\).*$,\1,'`
 877     case "${python_version}" in
 878     python*)
 879       AC_TRY_LIBPYTHON(${python_version}, have_libpython,
 880                        ${python_includes}, ${python_libs})
 881       ;;
 882     *)
 883       AC_MSG_ERROR([unable to determine python version from ${python_libs}])
 884       ;;
 885     esac
 886   elif test "${have_python_config}" != failed; then
 887     if test "${have_libpython}" = no; then
 888       AC_TRY_LIBPYTHON(python2.7, have_libpython,
 889                        ${python_includes}, "${python_libs} -lpython2.7")
 890     fi
 891     if test "${have_libpython}" = no; then
 892       AC_TRY_LIBPYTHON(python2.6, have_libpython,
 893                        ${python_includes}, "${python_libs} -lpython2.6")
 894     fi
 895     if test ${have_libpython} = no; then
 896       AC_TRY_LIBPYTHON(python2.5, have_libpython,
 897                        ${python_includes}, "${python_libs} -lpython2.5")
 898     fi
 899     if test ${have_libpython} = no; then
 900       AC_TRY_LIBPYTHON(python2.4, have_libpython,
 901                        ${python_includes}, "${python_libs} -lpython2.4")
 902     fi
 903   fi
 904   if test "${have_libpython}" = python2.7 -o "${have_libpython}" = python27; then
 905     AC_DEFINE(HAVE_LIBPYTHON2_7, 1, [Define if Python 2.7 is being used.])
 906   elif test "${have_libpython}" = python2.6 -o "${have_libpython}" = python26; then
 907     AC_DEFINE(HAVE_LIBPYTHON2_6, 1, [Define if Python 2.6 is being used.])
 908   elif test "${have_libpython}" = python2.5 -o "${have_libpython}" = python25; then
 909     AC_DEFINE(HAVE_LIBPYTHON2_5, 1, [Define if Python 2.5 is being used.])
 910   elif test "${have_libpython}" = python2.4 -o "${have_libpython}" = python24; then
 911     AC_DEFINE(HAVE_LIBPYTHON2_4, 1, [Define if Python 2.4 is being used.])
 912   fi
 913
 914   if test "${have_libpython}" = no; then
 915     case "${with_python}" in
 916     yes)
 917       AC_MSG_ERROR([python is missing or unusable])
 918       ;;
 919     auto)
 920       AC_MSG_WARN([python is missing or unusable; some features may be unavailable.])
 921       ;;
 922     *)
 923       AC_MSG_ERROR([no usable python found at ${with_python}])
 924       ;;
 925     esac
 926   else
 927     if test -n "${python_prefix}"; then
 928       AC_DEFINE_UNQUOTED(WITH_PYTHON_PATH, "${python_prefix}",
 929                          [Define if --with-python provides a path, either directly or via python-config.py --exec-prefix.])
 930       GDB_AC_DEFINE_RELOCATABLE(PYTHON_PATH, python, ${python_prefix})
 931     fi
 932   fi
 933 fi
 934
 935 if test "${have_libpython}" != no; then
 936   AC_DEFINE(HAVE_PYTHON, 1, [Define if Python interpreter is being linked in.])
 937   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_PYTHON_OBS)"
 938   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_PYTHON_DEPS)"
 939   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_PYTHON_SRCS)"
 940   CONFIG_INSTALL="$CONFIG_INSTALL install-python"
 941   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_PYTHON_CFLAGS)"
 942
 943   # Flags needed to compile Python code (taken from python-config --cflags).
 944   # We cannot call python-config directly because it will output whatever was
 945   # used when compiling the Python interpreter itself, including flags which
 946   # would make the python-related objects be compiled differently from the
 947   # rest of GDB (e.g., -O2 and -fPIC).
 948   if test "${GCC}" = yes; then
 949     tentative_python_cflags="-fno-strict-aliasing -DNDEBUG -fwrapv"
 950   fi
 951
 952   if test "x${tentative_python_cflags}" != x; then
 953     AC_MSG_CHECKING(compiler flags for python code)
 954     for flag in ${tentative_python_cflags}; do
 955       # Check that the compiler accepts it
 956       saved_CFLAGS="$CFLAGS"
 957       CFLAGS="$CFLAGS $flag"
 958       AC_TRY_COMPILE([],[],PYTHON_CFLAGS="${PYTHON_CFLAGS} $flag",)
 959       CFLAGS="$saved_CFLAGS"
 960     done
 961     AC_MSG_RESULT(${PYTHON_CFLAGS})
 962   fi
 963
 964   # On IRIX, type siginfo is not defined.  Instead, sys/siginfo.h provides:
 965   #    #if _SGIAPI
 966   #    #define siginfo __siginfo
 967   #    #endif
 968   # The problem is that including Python causes some XOPEN macros to be
 969   # unilaterally defined, and that in turn causes _SGIAPI to evaluate
 970   # to false.  So, we work around this issue by defining siginfo ourself
 971   # though the command-line.
 972   case "$gdb_host" in
 973     irix*) if test "${GCC}" = yes; then
 974              CPPFLAGS="$CPPFLAGS -Dsiginfo=__siginfo"
 975            fi
 976            ;;
 977   esac
 978 else
 979   # Even if Python support is not compiled in, we need to have these files
 980   # included.
 981   CONFIG_OBS="$CONFIG_OBS python.o py-value.o py-prettyprint.o py-auto-load.o"
 982   CONFIG_SRCS="$CONFIG_SRCS python/python.c python/py-value.c \
 983         python/py-prettyprint.c python/py-auto-load.c"
 984 fi
 985 AC_SUBST(PYTHON_CFLAGS)
 986 AC_SUBST(PYTHON_CPPFLAGS)
 987 AC_SUBST(PYTHON_LIBS)
 988
 989 # ------------------------- #
 990 # Checks for header files.  #
 991 # ------------------------- #
 992
 993 AC_HEADER_DIRENT
 994 AC_HEADER_STAT
 995 AC_HEADER_STDC
 996 # elf_hp.h is for HP/UX 64-bit shared library support.
 997 # FIXME: kettenis/20030102: In most cases we include these (ctype.h, time.h)
 998 # unconditionally, so what's the point in checking these?
 999 AC_CHECK_HEADERS([nlist.h machine/reg.h poll.h sys/poll.h proc_service.h \
1000                   thread_db.h gnu/libc-version.h signal.h stddef.h \
1001                   stdlib.h string.h memory.h strings.h sys/fault.h \
1002                   sys/file.h sys/filio.h sys/ioctl.h sys/param.h \
1003                   sys/resource.h sys/procfs.h sys/ptrace.h ptrace.h \
1004                   sys/reg.h sys/debugreg.h sys/select.h sys/syscall.h \
1005                   sys/types.h sys/wait.h wait.h termios.h termio.h \
1006                   sgtty.h unistd.h elf_hp.h ctype.h time.h locale.h \
1007                   dlfcn.h sys/socket.h sys/un.h])
1008 AC_CHECK_HEADERS(link.h, [], [],
1009 [#if HAVE_SYS_TYPES_H
1010 # include <sys/types.h>
1011 #endif
1012 #if HAVE_NLIST_H
1013 # include <nlist.h>
1014 #endif
1015 ])
1016 AC_CHECK_HEADERS(sys/proc.h, [], [],
1017 [#if HAVE_SYS_PARAM_H
1018 # include <sys/param.h>
1019 #endif
1020 ])
1021 AC_CHECK_HEADERS(sys/user.h, [], [],
1022 [#if HAVE_SYS_PARAM_H
1023 # include <sys/param.h>
1024 #endif
1025 ])
1026
1027 # On Solaris 2.[789], we need to define _MSE_INT_H to avoid a clash
1028 # between <widec.h> and <wchar.h> that would cause AC_CHECK_HEADERS to
1029 # think that we don't have <curses.h> if we're using GCC.
1030 case $host_os in
1031   solaris2.[[789]])
1032     if test "$GCC" = yes; then
1033       AC_DEFINE(_MSE_INT_H, 1,
1034         [Define to 1 to avoid a clash between <widec.h> and <wchar.h> on
1035    Solaris 2.[789] when using GCC. ])
1036     fi ;;
1037 esac
1038 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncurses/ncurses.h ncurses/term.h)
1039 AC_CHECK_HEADERS(term.h, [], [],
1040 [#if HAVE_CURSES_H
1041 # include <curses.h>
1042 #endif
1043 ])
1044
1045 # ------------------------- #
1046 # Checks for declarations.  #
1047 # ------------------------- #
1048
1049 AC_CHECK_DECLS([free, malloc, realloc, strerror, strstr, getopt,
1050                 snprintf, vsnprintf])
1051 AM_LC_MESSAGES
1052
1053 # ----------------------- #
1054 # Checks for structures.  #
1055 # ----------------------- #
1056
1057 AC_CHECK_MEMBERS([struct stat.st_blocks, struct stat.st_blksize])
1058
1059 # ------------------ #
1060 # Checks for types.  #
1061 # ------------------ #
1062
1063 AC_TYPE_SIGNAL
1064 AC_CHECK_TYPES(socklen_t, [], [],
1065 [#include <sys/types.h>
1066 #include <sys/socket.h>
1067 ])
1068
1069 # ------------------------------------- #
1070 # Checks for compiler characteristics.  #
1071 # ------------------------------------- #
1072
1073 AC_C_CONST
1074 AC_C_INLINE
1075 AC_C_BIGENDIAN
1076
1077 # ------------------------------ #
1078 # Checks for library functions.  #
1079 # ------------------------------ #
1080
1081 AC_FUNC_ALLOCA
1082 AC_FUNC_MMAP
1083 AC_FUNC_VFORK
1084 AC_CHECK_FUNCS([canonicalize_file_name realpath getrusage getuid getgid \
1085                 pipe poll pread pread64 pwrite readlink resize_term \
1086                 sbrk setpgid setpgrp setsid \
1087                 sigaction sigprocmask sigsetmask socketpair syscall \
1088                 ttrace wborder wresize setlocale iconvlist libiconvlist btowc \
1089                 setrlimit getrlimit posix_madvise waitpid lstat])
1090 AM_LANGINFO_CODESET
1091
1092 # Check the return and argument types of ptrace.  No canned test for
1093 # this, so roll our own.
1094 gdb_ptrace_headers='
1095 #if HAVE_SYS_TYPES_H
1096 # include <sys/types.h>
1097 #endif
1098 #if HAVE_SYS_PTRACE_H
1099 # include <sys/ptrace.h>
1100 #endif
1101 #if HAVE_UNISTD_H
1102 # include <unistd.h>
1103 #endif
1104 '
1105 # There is no point in checking if we don't have a prototype.
1106 AC_CHECK_DECLS(ptrace, [], [
1107   : ${gdb_cv_func_ptrace_ret='int'}
1108   : ${gdb_cv_func_ptrace_args='int,int,long,long'}
1109 ], $gdb_ptrace_headers)
1110 # Check return type.  Varargs (used on GNU/Linux) conflict with the
1111 # empty argument list, so check for that explicitly.
1112 AC_CACHE_CHECK([return type of ptrace], gdb_cv_func_ptrace_ret,
1113   AC_TRY_COMPILE($gdb_ptrace_headers,
1114     [extern long ptrace (enum __ptrace_request, ...);],
1115     gdb_cv_func_ptrace_ret='long',
1116     AC_TRY_COMPILE($gdb_ptrace_headers,
1117       [extern int ptrace ();],
1118       gdb_cv_func_ptrace_ret='int',
1119       gdb_cv_func_ptrace_ret='long')))
1120 AC_DEFINE_UNQUOTED(PTRACE_TYPE_RET, $gdb_cv_func_ptrace_ret,
1121   [Define as the return type of ptrace.])
1122 # Check argument types.
1123 AC_CACHE_CHECK([types of arguments for ptrace], gdb_cv_func_ptrace_args, [
1124   AC_TRY_COMPILE($gdb_ptrace_headers,
1125     [extern long ptrace (enum __ptrace_request, ...);],
1126     [gdb_cv_func_ptrace_args='int,int,long,long'],[
1127 for gdb_arg1 in 'int' 'long'; do
1128  for gdb_arg2 in 'pid_t' 'int' 'long'; do
1129   for gdb_arg3 in 'int *' 'caddr_t' 'int' 'long' 'void *'; do
1130    for gdb_arg4 in 'int' 'long'; do
1131      AC_TRY_COMPILE($gdb_ptrace_headers, [
1132 extern $gdb_cv_func_ptrace_ret
1133   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4);
1134 ], [gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4";
1135     break 4;])
1136     for gdb_arg5 in 'int *' 'int' 'long'; do
1137      AC_TRY_COMPILE($gdb_ptrace_headers, [
1138 extern $gdb_cv_func_ptrace_ret
1139   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4, $gdb_arg5);
1140 ], [
1141 gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4,$gdb_arg5";
1142     break 5;])
1143     done
1144    done
1145   done
1146  done
1147 done
1148 # Provide a safe default value.
1149 : ${gdb_cv_func_ptrace_args='int,int,long,long'}
1150 ])])
1151 ac_save_IFS=$IFS; IFS=','
1152 set dummy `echo "$gdb_cv_func_ptrace_args" | sed 's/\*/\*/g'`
1153 IFS=$ac_save_IFS
1154 shift
1155 AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG3, $[3],
1156   [Define to the type of arg 3 for ptrace.])
1157 if test -n "$[5]"; then
1158   AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG5, $[5],
1159     [Define to the type of arg 5 for ptrace.])
1160 fi
1161
1162 dnl AC_FUNC_SETPGRP does not work when cross compiling
1163 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
1164 if test "$cross_compiling" = no; then
1165   AC_FUNC_SETPGRP
1166 else
1167   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
1168     [AC_TRY_COMPILE([
1169 #include <unistd.h>
1170 ], [
1171   if (setpgrp(1,1) == -1)
1172     exit (0);
1173   else
1174     exit (1);
1175 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
1176 if test $ac_cv_func_setpgrp_void = yes; then
1177   AC_DEFINE(SETPGRP_VOID, 1)
1178 fi
1179 fi
1180
1181 # Check if sigsetjmp is available.  Using AC_CHECK_FUNCS won't do
1182 # since sigsetjmp might only be defined as a macro.
1183 AC_CACHE_CHECK([for sigsetjmp], gdb_cv_func_sigsetjmp,
1184 [AC_TRY_COMPILE([
1185 #include <setjmp.h>
1186 ], [sigjmp_buf env; while (! sigsetjmp (env, 1)) siglongjmp (env, 1);],
1187 gdb_cv_func_sigsetjmp=yes, gdb_cv_func_sigsetjmp=no)])
1188 if test $gdb_cv_func_sigsetjmp = yes; then
1189   AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available. ])
1190 fi
1191
1192 # Assume we'll default to using the included libiberty regex.
1193 gdb_use_included_regex=yes
1194
1195 # However, if the system regex is GNU regex, then default to *not*
1196 # using the included regex.
1197 AC_CACHE_CHECK(
1198   [for GNU regex],
1199   [gdb_cv_have_gnu_regex],
1200   [AC_TRY_COMPILE(
1201     [#include <gnu-versions.h>],
1202     [#define REGEX_INTERFACE_VERSION 1
1203 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
1204 # error "Version mismatch"
1205 #endif],
1206     gdb_cv_have_gnu_regex=yes,
1207     gdb_cv_have_gnu_regex=no)])
1208 if test $gdb_cv_have_gnu_regex = yes; then
1209   gdb_use_included_regex=no
1210 fi
1211
1212 AC_ARG_WITH(included-regex,
1213   AS_HELP_STRING([--without-included-regex], [don't use included regex; this is the default on systems with version 2 of the GNU C library (use with caution on other system)]),
1214   gdb_with_regex=$withval,
1215   gdb_with_regex=$gdb_use_included_regex)
1216 if test "$gdb_with_regex" = yes; then
1217   AC_DEFINE(USE_INCLUDED_REGEX, 1,
1218     [Define to 1 if the regex included in libiberty should be used.])
1219 fi
1220
1221 # Check if <sys/proc.h> defines `struct thread' with a td_pcb member.
1222 AC_CHECK_MEMBERS([struct thread.td_pcb], [], [],
1223 [#include <sys/param.h>
1224 #include <sys/proc.h>
1225 ])
1226
1227 # See if <sys/lwp.h> defines `struct lwp`.
1228 AC_CACHE_CHECK([for struct lwp], gdb_cv_struct_lwp,
1229 [AC_TRY_COMPILE([#include <sys/param.h>
1230 #include <sys/lwp.h>], [struct lwp l;],
1231 gdb_cv_struct_lwp=yes, gdb_cv_struct_lwp=no)])
1232 if test $gdb_cv_struct_lwp = yes; then
1233   AC_DEFINE(HAVE_STRUCT_LWP, 1,
1234             [Define to 1 if your system has struct lwp.])
1235 fi
1236
1237 # See if <machine/reg.h> degines `struct reg'.
1238 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
1239 [AC_TRY_COMPILE([#include <sys/types.h>
1240 #include <machine/reg.h>], [struct reg r;],
1241 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
1242 if test $gdb_cv_struct_reg = yes; then
1243   AC_DEFINE(HAVE_STRUCT_REG, 1,
1244             [Define to 1 if your system has struct reg in <machine/reg.h>.])
1245 fi
1246
1247 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
1248 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
1249 AC_CHECK_MEMBERS([struct reg.r_fs, struct reg.r_gs], [], [],
1250                  [#include <machine/reg.h>])
1251
1252 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
1253 AC_MSG_CHECKING(for PTRACE_GETREGS)
1254 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
1255 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1256                 [PTRACE_GETREGS;],
1257                 [gdb_cv_have_ptrace_getregs=yes],
1258                 [gdb_cv_have_ptrace_getregs=no])])
1259 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
1260 if test $gdb_cv_have_ptrace_getregs = yes; then
1261   AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
1262   [Define if sys/ptrace.h defines the PTRACE_GETREGS request.])
1263 fi
1264
1265 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
1266 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
1267 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
1268 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1269                 [PTRACE_GETFPXREGS;],
1270                 [gdb_cv_have_ptrace_getfpxregs=yes],
1271                 [gdb_cv_have_ptrace_getfpxregs=no])])
1272 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
1273 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
1274   AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
1275   [Define if sys/ptrace.h defines the PTRACE_GETFPXREGS request.])
1276 fi
1277
1278 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
1279 AC_MSG_CHECKING(for PT_GETDBREGS)
1280 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
1281 [AC_TRY_COMPILE([#include <sys/types.h>
1282 #include <sys/ptrace.h>],
1283                 [PT_GETDBREGS;],
1284                 [gdb_cv_have_pt_getdbregs=yes],
1285                 [gdb_cv_have_pt_getdbregs=no])])
1286 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
1287 if test $gdb_cv_have_pt_getdbregs = yes; then
1288   AC_DEFINE(HAVE_PT_GETDBREGS, 1,
1289   [Define if sys/ptrace.h defines the PT_GETDBREGS request.])
1290 fi
1291
1292 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
1293 AC_MSG_CHECKING(for PT_GETXMMREGS)
1294 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
1295 [AC_TRY_COMPILE([#include <sys/types.h>
1296 #include <sys/ptrace.h>],
1297                 [PT_GETXMMREGS;],
1298                 [gdb_cv_have_pt_getxmmregs=yes],
1299                 [gdb_cv_have_pt_getxmmregs=no])])
1300 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
1301 if test $gdb_cv_have_pt_getxmmregs = yes; then
1302   AC_DEFINE(HAVE_PT_GETXMMREGS, 1,
1303   [Define if sys/ptrace.h defines the PT_GETXMMREGS request.])
1304 fi
1305
1306 # Detect which type of /proc is in use, such as for Unixware or Solaris.
1307
1308 if test "${target}" = "${host}"; then
1309   case "${host}" in
1310   *-*-unixware* | *-*-sysv4.2* | *-*-sysv5* | *-*-interix* )
1311       AC_DEFINE(NEW_PROC_API, 1,
1312       [Define if you want to use new multi-fd /proc interface
1313        (replaces HAVE_MULTIPLE_PROC_FDS as well as other macros).])
1314       ;;
1315   *-*-solaris2.[[6789]] | *-*-solaris2.1[[0-9]]*)
1316       AC_DEFINE(NEW_PROC_API, 1,
1317       [Define if you want to use new multi-fd /proc interface
1318        (replaces HAVE_MULTIPLE_PROC_FDS as well as other macros).])
1319       ;;
1320   mips-sgi-irix5*)
1321       # Work around <sys/proc.h> needing _KMEMUSER problem on IRIX 5.
1322       AC_DEFINE([_KMEMUSER], 1,
1323       [Define to 1 so <sys/proc.h> gets a definition of anon_hdl.  Works
1324        around a <sys/proc.h> problem on IRIX 5.])
1325       ;;
1326   esac
1327 fi
1328
1329 if test "$ac_cv_header_sys_procfs_h" = yes; then
1330   BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
1331   BFD_HAVE_SYS_PROCFS_TYPE(prrun_t)
1332   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
1333   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
1334   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
1335   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
1336   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
1337   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset32_t)
1338   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
1339   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
1340   BFD_HAVE_SYS_PROCFS_TYPE(prsysent_t)
1341   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigset_t)
1342   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigaction64_t)
1343   BFD_HAVE_SYS_PROCFS_TYPE(pr_siginfo64_t)
1344
1345
1346   dnl Check for broken prfpregset_t type
1347
1348   dnl For Linux/i386, glibc 2.1.3 was released with a bogus
1349   dnl prfpregset_t type (it's a typedef for the pointer to a struct
1350   dnl instead of the struct itself).  We detect this here, and work
1351   dnl around it in gdb_proc_service.h.
1352
1353   if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
1354     AC_MSG_CHECKING(whether prfpregset_t type is broken)
1355     AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
1356       [AC_TRY_RUN([#include <sys/procfs.h>
1357        int main ()
1358        {
1359          if (sizeof (prfpregset_t) == sizeof (void *))
1360            return 1;
1361          return 0;
1362        }],
1363        gdb_cv_prfpregset_t_broken=no,
1364        gdb_cv_prfpregset_t_broken=yes,
1365        gdb_cv_prfpregset_t_broken=yes)])
1366     AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
1367     if test $gdb_cv_prfpregset_t_broken = yes; then
1368       AC_DEFINE(PRFPREGSET_T_BROKEN, 1,
1369       [Define if the prfpregset_t type is broken.])
1370     fi
1371   fi
1372
1373   dnl Check for PIOCSET ioctl entry
1374
1375   AC_MSG_CHECKING(for PIOCSET ioctl entry in sys/procfs.h)
1376   AC_CACHE_VAL(gdb_cv_have_procfs_piocset,
1377   [AC_TRY_COMPILE([#include <unistd.h>
1378 #include <sys/types.h>
1379 #include <sys/procfs.h>
1380 ], [
1381     int dummy;;
1382     dummy = ioctl(0, PIOCSET, &dummy);
1383   ],
1384   gdb_cv_have_procfs_piocset=yes, gdb_cv_have_procfs_piocset=no)])
1385   AC_MSG_RESULT($gdb_cv_have_procfs_piocset)
1386   if test $gdb_cv_have_procfs_piocset = yes; then
1387     AC_DEFINE(HAVE_PROCFS_PIOCSET, 1,
1388     [Define if ioctl argument PIOCSET is available.])
1389   fi
1390 fi
1391
1392 dnl For native ports (host == target), check to see what kind of
1393 dnl legacy link.h support is needed.  (See solib-legacy.c.)
1394 if test ${host} = ${target} ; then
1395   dnl Check for struct link_map with l_ members which are indicative
1396   dnl of SVR4-like shared libraries
1397
1398   AC_MSG_CHECKING(for member l_addr in struct link_map)
1399   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_l_members,
1400     [AC_TRY_COMPILE([#include <link.h>],
1401                     [struct link_map lm; (void) lm.l_addr;],
1402                     gdb_cv_have_struct_link_map_with_l_members=yes,
1403                     gdb_cv_have_struct_link_map_with_l_members=no)])
1404   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_l_members)
1405   if test $gdb_cv_have_struct_link_map_with_l_members = yes; then
1406     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_L_MEMBERS,1,
1407     [Define if <link.h> exists and defines struct link_map which has
1408      members with an ``l_'' prefix.  (For Solaris, SVR4, and
1409      SVR4-like systems.)])
1410   fi
1411
1412   dnl Check for struct link_map with lm_ members which are indicative
1413   dnl of SunOS-like shared libraries
1414
1415   AC_MSG_CHECKING(for member lm_addr in struct link_map)
1416   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_lm_members,
1417     [AC_TRY_COMPILE([#include <sys/types.h>
1418 #include <link.h>],
1419                     [struct link_map lm; (void) lm.lm_addr;],
1420                     gdb_cv_have_struct_link_map_with_lm_members=yes,
1421                     gdb_cv_have_struct_link_map_with_lm_members=no)])
1422   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_lm_members)
1423   if test $gdb_cv_have_struct_link_map_with_lm_members = yes; then
1424     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_LM_MEMBERS, 1,
1425     [Define if <link.h> exists and defines struct link_map which has
1426      members with an ``lm_'' prefix.  (For SunOS.)])
1427   fi
1428
1429   dnl Check for struct so_map with som_ members which are found on
1430   dnl some *BSD systems.
1431
1432   AC_MSG_CHECKING(for member som_addr in struct so_map)
1433   AC_CACHE_VAL(gdb_cv_have_struct_so_map_with_som_members,
1434     [AC_TRY_COMPILE([#include <sys/types.h>
1435 #ifdef HAVE_NLIST_H
1436 #include <nlist.h>
1437 #endif
1438 #include <link.h>],
1439                     [struct so_map lm; (void) lm.som_addr;],
1440                     gdb_cv_have_struct_so_map_with_som_members=yes,
1441                     gdb_cv_have_struct_so_map_with_som_members=no)])
1442   AC_MSG_RESULT($gdb_cv_have_struct_so_map_with_som_members)
1443   if test $gdb_cv_have_struct_so_map_with_som_members = yes; then
1444     AC_DEFINE(HAVE_STRUCT_SO_MAP_WITH_SOM_MEMBERS, 1,
1445     [Define if <link.h> exists and defines a struct so_map which has
1446      members with an ``som_'' prefix.  (Found on older *BSD systems.)])
1447   fi
1448
1449   dnl Check for struct link_map32 type, which allows a 64-bit Solaris
1450   dnl debugger to debug a 32-bit Solaris app with 32-bit shared libraries.
1451
1452   AC_MSG_CHECKING(for struct link_map32 in sys/link.h)
1453   AC_CACHE_VAL(gdb_cv_have_struct_link_map32,
1454     [AC_TRY_COMPILE([#define _SYSCALL32
1455 #include <sys/link.h>], [struct link_map32 l;],
1456      gdb_cv_have_struct_link_map32=yes,
1457      gdb_cv_have_struct_link_map32=no)])
1458   AC_MSG_RESULT($gdb_cv_have_struct_link_map32)
1459   if test $gdb_cv_have_struct_link_map32 = yes; then
1460     AC_DEFINE(HAVE_STRUCT_LINK_MAP32, 1,
1461     [Define if <sys/link.h> has struct link_map32])
1462     AC_DEFINE(_SYSCALL32, 1,
1463     [Define if <sys/link.h> has link_map32 (solaris sparc-64 target)])
1464   fi
1465 fi
1466
1467 # Check if the compiler supports the `long long' type.
1468
1469 AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long,
1470                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1471 [[extern long long foo;]],
1472 [[switch (foo & 2) { case 0: return 1; }]])],
1473                                   gdb_cv_c_long_long=yes,
1474                                   gdb_cv_c_long_long=no)])
1475 if test $gdb_cv_c_long_long = yes; then
1476   AC_DEFINE(CC_HAS_LONG_LONG, 1,
1477             [Define to 1 if the compiler supports long long.])
1478 fi
1479
1480 # Check if the compiler and runtime support printing long longs.
1481
1482 AC_CACHE_CHECK([for long long support in printf],
1483                gdb_cv_printf_has_long_long,
1484                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1485 [[char buf[32];
1486   long long l = 0;
1487   l = (l << 16) + 0x0123;
1488   l = (l << 16) + 0x4567;
1489   l = (l << 16) + 0x89ab;
1490   l = (l << 16) + 0xcdef;
1491   sprintf (buf, "0x%016llx", l);
1492   return (strcmp ("0x0123456789abcdef", buf));]])],
1493                               gdb_cv_printf_has_long_long=yes,
1494                               gdb_cv_printf_has_long_long=no,
1495                               gdb_cv_printf_has_long_long=no)])
1496 if test $gdb_cv_printf_has_long_long = yes; then
1497   AC_DEFINE(PRINTF_HAS_LONG_LONG, 1,
1498             [Define to 1 if the "%ll" format works to print long longs.])
1499 fi
1500
1501 # Check if the compiler and runtime support printing decfloats.
1502
1503 AC_CACHE_CHECK([for decfloat support in printf],
1504                gdb_cv_printf_has_decfloat,
1505                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1506 [[char buf[64];
1507   _Decimal32 d32 = 1.2345df;
1508   _Decimal64 d64 = 1.2345dd;
1509   _Decimal128 d128 = 1.2345dl;
1510   sprintf (buf, "Decimal32: %H\nDecimal64: %D\nDecimal128: %DD", d32, d64, d128);
1511   return (strcmp ("Decimal32: 1.2345\nDecimal64: 1.2345\nDecimal128: 1.2345", buf));]])],
1512                               gdb_cv_printf_has_decfloat=yes,
1513                               gdb_cv_printf_has_decfloat=no,
1514                               gdb_cv_printf_has_decfloat=no)])
1515 if test $gdb_cv_printf_has_decfloat = yes; then
1516   AC_DEFINE(PRINTF_HAS_DECFLOAT, 1,
1517             [Define to 1 if the "%H, %D and %DD" formats work to print decfloats.])
1518 fi
1519
1520 # Check if the compiler supports the `long double' type.  We can't use
1521 # AC_C_LONG_DOUBLE because that one does additional checks on the
1522 # constants defined in <float.h> that fail on some systems,
1523 # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6.
1524
1525 AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double,
1526                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])],
1527                                   gdb_cv_c_long_double=yes,
1528                                   gdb_cv_c_long_double=no)])
1529 if test $gdb_cv_c_long_double = yes; then
1530   AC_DEFINE(HAVE_LONG_DOUBLE, 1,
1531            [Define to 1 if the compiler supports long double.])
1532 fi
1533
1534 # Check if the compiler and runtime support printing long doubles.
1535
1536 AC_CACHE_CHECK([for long double support in printf],
1537                gdb_cv_printf_has_long_double,
1538                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1539 [[char buf[16];
1540   long double f = 3.141592653;
1541   sprintf (buf, "%Lg", f);
1542   return (strncmp ("3.14159", buf, 7));]])],
1543                               gdb_cv_printf_has_long_double=yes,
1544                               gdb_cv_printf_has_long_double=no,
1545                               gdb_cv_printf_has_long_double=no)])
1546 if test $gdb_cv_printf_has_long_double = yes; then
1547   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1,
1548             [Define to 1 if the "%Lg" format works to print long doubles.])
1549 fi
1550
1551 # Check if the compiler and runtime support scanning long doubles.
1552
1553 AC_CACHE_CHECK([for long double support in scanf],
1554                gdb_cv_scanf_has_long_double,
1555                [AC_RUN_IFELSE([AC_LANG_PROGRAM(
1556 [[#include <stdio.h>]],
1557 [[char *buf = "3.141592653";
1558   long double f = 0;
1559   sscanf (buf, "%Lg", &f);
1560   return !(f > 3.14159 && f < 3.14160);]])],
1561                               gdb_cv_scanf_has_long_double=yes,
1562                               gdb_cv_scanf_has_long_double=no,
1563                               gdb_cv_scanf_has_long_double=no)])
1564 if test $gdb_cv_scanf_has_long_double = yes; then
1565   AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1,
1566             [Define to 1 if the "%Lg" format works to scan long doubles.])
1567 fi
1568
1569 case ${host_os} in
1570 aix*)
1571   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1572     SAVE_LDFLAGS=$LDFLAGS
1573
1574     case $GCC in
1575     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1576     *) gdb_cv_bigtoc=-bbigtoc ;;
1577     esac
1578
1579     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1580     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1581     LDFLAGS="${SAVE_LDFLAGS}"
1582   ])
1583   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
1584   ;;
1585 esac
1586
1587 AC_MSG_CHECKING(for the dynamic export flag)
1588 dynamic_list=false
1589 if test "${gdb_native}" = yes; then
1590    # The dynamically loaded libthread_db needs access to symbols in the gdb
1591    # executable.  Older GNU ld supports --export-dynamic but --dynamic-list
1592    # may not be supported there.
1593    old_LDFLAGS="$LDFLAGS"
1594    # Older GNU ld supports --export-dynamic but --dynamic-list it does not.
1595    RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
1596    LDFLAGS="$LDFLAGS $RDYNAMIC"
1597    if test "${have_libpython}" = no; then
1598      AC_TRY_LINK([], [], [dynamic_list=true])
1599    else
1600      # Workaround http://bugs.python.org/issue4434 where static
1601      # libpythonX.Y.a would get its symbols required for
1602      # pythonX.Y/lib-dynload/*.so modules hidden by -Wl,--dynamic-list.
1603      # Problem does not happen for the recommended libpythonX.Y.so linkage.
1604      old_CFLAGS="$CFLAGS"
1605      CFLAGS="$CFLAGS $PYTHON_CFLAGS"
1606      AC_RUN_IFELSE(
1607        AC_LANG_PROGRAM(
1608          [#include "]${have_libpython}[/Python.h"],
1609          [int err;
1610           Py_Initialize ();
1611           err = PyRun_SimpleString ("import itertools\n");
1612           Py_Finalize ();
1613           return err == 0 ? 0 : 1;]),
1614        [dynamic_list=true], [], [true])
1615      CFLAGS="$old_CFLAGS"
1616    fi
1617    LDFLAGS="$old_LDFLAGS"
1618 fi
1619 if $dynamic_list; then
1620   found="-Wl,--dynamic-list"
1621   RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'
1622 else
1623   found="-rdynamic"
1624   RDYNAMIC="-rdynamic"
1625 fi
1626 AC_SUBST(RDYNAMIC)
1627 AC_MSG_RESULT($found)
1628
1629 dnl For certain native configurations, we need to check whether thread
1630 dnl support can be built in or not.
1631 dnl
1632 dnl Note that we only want this if we are both native (host == target),
1633 dnl and not doing a canadian cross build (build == host).
1634
1635 if test ${build} = ${host} -a ${host} = ${target} ; then
1636    case ${host_os} in
1637    solaris*)
1638       # See if thread_db library is around for Solaris thread debugging.
1639       # Note that we must explicitly test for version 1 of the library
1640       # because version 0 (present on Solaris 2.4 or earlier) doesn't have
1641       # the same API.
1642       AC_MSG_CHECKING(for Solaris thread debugging library)
1643       if test -f /usr/lib/libthread_db.so.1 ; then
1644          AC_MSG_RESULT(yes)
1645          AC_DEFINE(HAVE_THREAD_DB_LIB, 1,
1646          [Define if using Solaris thread debugging.])
1647          CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
1648          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
1649          AC_CHECK_LIB(dl, dlopen)
1650          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} $RDYNAMIC"
1651          # Sun randomly tweaked the prototypes in <proc_service.h>
1652          # at one point.
1653          AC_MSG_CHECKING(if <proc_service.h> is old)
1654          AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
1655             AC_TRY_COMPILE([
1656                 #include <proc_service.h>
1657                 ps_err_e ps_pdwrite
1658                     (struct ps_prochandle*, psaddr_t, const void*, size_t);
1659             ],, gdb_cv_proc_service_is_old=no,
1660                 gdb_cv_proc_service_is_old=yes)
1661          ])
1662          AC_MSG_RESULT($gdb_cv_proc_service_is_old)
1663          if test $gdb_cv_proc_service_is_old = yes; then
1664             AC_DEFINE(PROC_SERVICE_IS_OLD, 1,
1665             [Define if <proc_service.h> on solaris uses int instead of
1666              size_t, and assorted other type changes.])
1667          fi
1668       else
1669          AC_MSG_RESULT(no)
1670       fi
1671       ;;
1672    aix*)
1673       AC_MSG_CHECKING(for AiX thread debugging library)
1674       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
1675                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
1676                                    [#ifndef PTHDB_VERSION_3
1677                                     #error
1678                                     #endif],
1679                                    gdb_cv_have_aix_thread_debug=yes,
1680                                    gdb_cv_have_aix_thread_debug=no)])
1681       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1682       if test $gdb_cv_have_aix_thread_debug = yes; then
1683          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1684          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1685          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -lpthdebug"
1686
1687          # Older versions of AIX do not provide the declaration for
1688          # the getthrds function (it appears that it was introduced
1689          # with AIX 6.x).
1690          AC_CHECK_DECLS(getthrds, [], [], [[#include <procinfo.h>]])
1691       fi
1692       ;;
1693    esac
1694    AC_SUBST(CONFIG_LDFLAGS)
1695 fi
1696
1697 dnl See if we have a thread_db header file that has TD_NOTALLOC and
1698 dnl other error codes.
1699 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1700    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
1701                   gdb_cv_thread_db_h_has_td_notalloc,
1702      AC_TRY_COMPILE(
1703        [#include <thread_db.h>],
1704        [int i = TD_NOTALLOC;],
1705        gdb_cv_thread_db_h_has_td_notalloc=yes,
1706        gdb_cv_thread_db_h_has_td_notalloc=no
1707      )
1708    )
1709    AC_CACHE_CHECK([whether <thread_db.h> has TD_VERSION],
1710                   gdb_cv_thread_db_h_has_td_version,
1711      AC_TRY_COMPILE(
1712        [#include <thread_db.h>],
1713        [int i = TD_VERSION;],
1714        gdb_cv_thread_db_h_has_td_version=yes,
1715        gdb_cv_thread_db_h_has_td_version=no
1716      )
1717    )
1718    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTLS],
1719                   gdb_cv_thread_db_h_has_td_notls,
1720      AC_TRY_COMPILE(
1721        [#include <thread_db.h>],
1722        [int i = TD_NOTLS;],
1723        gdb_cv_thread_db_h_has_td_notls=yes,
1724        gdb_cv_thread_db_h_has_td_notls=no
1725      )
1726    )
1727 fi
1728 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1729   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1730             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1731 fi
1732 if test "x$gdb_cv_thread_db_h_has_td_version" = "xyes"; then
1733   AC_DEFINE(THREAD_DB_HAS_TD_VERSION, 1,
1734             [Define if <thread_db.h> has the TD_VERSION error code.])
1735 fi
1736 if test "x$gdb_cv_thread_db_h_has_td_notls" = "xyes"; then
1737   AC_DEFINE(THREAD_DB_HAS_TD_NOTLS, 1,
1738             [Define if <thread_db.h> has the TD_NOTLS error code.])
1739 fi
1740
1741 dnl See if we have a sys/syscall header file that has __NR_tkill.
1742 if test "x$ac_cv_header_sys_syscall_h" = "xyes"; then
1743    AC_CACHE_CHECK([whether <sys/syscall.h> has __NR_tkill],
1744                   gdb_cv_sys_syscall_h_has_tkill,
1745      AC_TRY_COMPILE(
1746        [#include <sys/syscall.h>],
1747        [int i = __NR_tkill;],
1748        gdb_cv_sys_syscall_h_has_tkill=yes,
1749        gdb_cv_sys_syscall_h_has_tkill=no
1750      )
1751    )
1752 fi
1753 dnl See if we can issue tkill syscall.
1754 if test "x$gdb_cv_sys_syscall_h_has_tkill" = "xyes" && test "x$ac_cv_func_syscall" = "xyes"; then
1755   AC_DEFINE(HAVE_TKILL_SYSCALL, 1, [Define if you support the tkill syscall.])
1756 fi
1757
1758 dnl Check if we can disable the virtual address space randomization.
1759 dnl The functionality of setarch -R.
1760 AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>])
1761 define([PERSONALITY_TEST], [AC_LANG_PROGRAM([#include <sys/personality.h>], [
1762 #      if !HAVE_DECL_ADDR_NO_RANDOMIZE
1763 #       define ADDR_NO_RANDOMIZE 0x0040000
1764 #      endif
1765        /* Test the flag could be set and stays set.  */
1766        personality (personality (0xffffffff) | ADDR_NO_RANDOMIZE);
1767        if (!(personality (personality (0xffffffff)) & ADDR_NO_RANDOMIZE))
1768            return 1])])
1769 AC_RUN_IFELSE([PERSONALITY_TEST],
1770               [have_personality=true],
1771               [have_personality=false],
1772               [AC_LINK_IFELSE([PERSONALITY_TEST],
1773                               [have_personality=true],
1774                               [have_personality=false])])
1775 if $have_personality
1776 then
1777     AC_DEFINE([HAVE_PERSONALITY], 1,
1778               [Define if you support the personality syscall.])
1779 fi
1780
1781 dnl Handle optional features that can be enabled.
1782
1783 # Support for --with-sysroot is a copy of GDB_AC_WITH_DIR,
1784 # except that the argument to --with-sysroot is optional.
1785 # --with-sysroot (or --with-sysroot=yes) sets the default sysroot path.
1786 if test "x$with_sysroot" = xyes; then
1787   with_sysroot="${exec_prefix}/${target_alias}/sys-root"
1788 fi
1789 AC_ARG_WITH(sysroot,
1790   AS_HELP_STRING([--with-sysroot@<:@=DIR@:>@],
1791                  [search for usr/lib et al within DIR]),
1792   [TARGET_SYSTEM_ROOT=$withval], [TARGET_SYSTEM_ROOT=])
1793 AC_DEFINE_DIR(TARGET_SYSTEM_ROOT, TARGET_SYSTEM_ROOT,
1794               [search for usr/lib et al within DIR])
1795 AC_SUBST(TARGET_SYSTEM_ROOT)
1796 GDB_AC_DEFINE_RELOCATABLE(TARGET_SYSTEM_ROOT, sysroot, ${ac_define_dir})
1797
1798 GDB_AC_WITH_DIR(SYSTEM_GDBINIT, system-gdbinit,
1799     [automatically load a system-wide gdbinit file],
1800     [])
1801
1802 AC_ARG_ENABLE(werror,
1803   AS_HELP_STRING([--enable-werror], [treat compile warnings as errors]),
1804   [case "${enableval}" in
1805      yes | y) ERROR_ON_WARNING="yes" ;;
1806      no | n)  ERROR_ON_WARNING="no" ;;
1807      *) AC_MSG_ERROR(bad value ${enableval} for --enable-werror) ;;
1808    esac])
1809
1810 # Enable -Werror by default when using gcc
1811 if test "${GCC}" = yes -a -z "${ERROR_ON_WARNING}" ; then
1812     ERROR_ON_WARNING=yes
1813 fi
1814
1815 WERROR_CFLAGS=""
1816 if test "${ERROR_ON_WARNING}" = yes ; then
1817     WERROR_CFLAGS="-Werror"
1818 fi
1819
1820 # The entries after -Wno-pointer-sign are disabled warnings which may
1821 # be enabled in the future, which can not currently be used to build
1822 # GDB.
1823 # NOTE: If you change this list, remember to update
1824 # gdb/doc/gdbint.texinfo.
1825 build_warnings="-Wall -Wdeclaration-after-statement -Wpointer-arith \
1826 -Wformat-nonliteral -Wno-pointer-sign \
1827 -Wno-unused -Wunused-value -Wunused-function \
1828 -Wno-switch -Wno-char-subscripts -Wmissing-prototypes"
1829
1830 # Enable -Wno-format by default when using gcc on mingw since many
1831 # GCC versions complain about %I64.
1832 case "${host}" in
1833   *-*-mingw32*) build_warnings="$build_warnings -Wno-format" ;;
1834 esac
1835
1836 AC_ARG_ENABLE(build-warnings,
1837 AS_HELP_STRING([--enable-build-warnings], [enable build-time compiler warnings if gcc is used]),
1838 [case "${enableval}" in
1839   yes)  ;;
1840   no)   build_warnings="-w";;
1841   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1842         build_warnings="${build_warnings} ${t}";;
1843   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1844         build_warnings="${t} ${build_warnings}";;
1845   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1846 esac
1847 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1848   echo "Setting compiler warning flags = $build_warnings" 6>&1
1849 fi])dnl
1850 AC_ARG_ENABLE(gdb-build-warnings,
1851 AS_HELP_STRING([--enable-gdb-build-warnings], [enable GDB specific build-time compiler warnings if gcc is used]),
1852 [case "${enableval}" in
1853   yes)  ;;
1854   no)   build_warnings="-w";;
1855   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1856         build_warnings="${build_warnings} ${t}";;
1857   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1858         build_warnings="${t} ${build_warnings}";;
1859   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1860 esac
1861 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1862   echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1
1863 fi])dnl
1864 WARN_CFLAGS=""
1865 if test "x${build_warnings}" != x -a "x$GCC" = xyes
1866 then
1867     AC_MSG_CHECKING(compiler warning flags)
1868     # Separate out the -Werror flag as some files just cannot be
1869     # compiled with it enabled.
1870     for w in ${build_warnings}; do
1871         case $w in
1872         -Werr*) WERROR_CFLAGS=-Werror ;;
1873         *) # Check that GCC accepts it
1874             saved_CFLAGS="$CFLAGS"
1875             CFLAGS="$CFLAGS $w"
1876             AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
1877             CFLAGS="$saved_CFLAGS"
1878         esac
1879     done
1880     AC_MSG_RESULT(${WARN_CFLAGS} ${WERROR_CFLAGS})
1881 fi
1882 AC_SUBST(WARN_CFLAGS)
1883 AC_SUBST(WERROR_CFLAGS)
1884
1885 # In the Cygwin environment, we need some additional flags.
1886 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1887 [AC_EGREP_CPP(lose, [
1888 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1889 lose
1890 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1891
1892
1893 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1894 SER_HARDWIRE="ser-base.o ser-unix.o ser-pipe.o ser-tcp.o"
1895 case ${host} in
1896   *go32* ) SER_HARDWIRE=ser-go32.o ;;
1897   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
1898   *mingw32*) SER_HARDWIRE="ser-base.o ser-tcp.o ser-mingw.o" ;;
1899 esac
1900 AC_SUBST(SER_HARDWIRE)
1901
1902 # libreadline needs libuser32.a in a cygwin environment
1903 WIN32LIBS=
1904 if test x$gdb_cv_os_cygwin = xyes; then
1905     WIN32LIBS="-luser32"
1906     case "${target}" in
1907         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
1908         ;;
1909     esac
1910 fi
1911
1912 # The ser-tcp.c module requires sockets.
1913 case ${host} in
1914   *mingw32*)
1915     AC_DEFINE(USE_WIN32API, 1,
1916               [Define if we should use the Windows API, instead of the
1917                POSIX API.  On Windows, we use the Windows API when
1918                building for MinGW, but the POSIX API when building
1919                for Cygwin.])
1920     WIN32LIBS="$WIN32LIBS -lws2_32"
1921     ;;
1922 esac
1923 AC_SUBST(WIN32LIBS)
1924
1925 # Add ELF support to GDB, but only if BFD includes ELF support.
1926 OLD_CFLAGS=$CFLAGS
1927 OLD_LDFLAGS=$LDFLAGS
1928 OLD_LIBS=$LIBS
1929 # Put the old CFLAGS/LDFLAGS last, in case the user's (C|LD)FLAGS
1930 # points somewhere with bfd, with -I/foo/lib and -L/foo/lib.  We
1931 # always want our bfd.
1932 CFLAGS="-I${srcdir}/../include -I../bfd -I${srcdir}/../bfd $CFLAGS"
1933 LDFLAGS="-L../bfd -L../libiberty $LDFLAGS"
1934 intl=`echo $LIBINTL | sed 's,${top_builddir}/,,g'`
1935 # -ldl is provided by bfd/Makfile.am (LIBDL) <PLUGINS>.
1936 if test "$plugins" = "yes"; then
1937   LIBS="-ldl $LIBS"
1938 fi
1939 LIBS="-lbfd -liberty $intl $LIBS"
1940 AC_CACHE_CHECK([for ELF support in BFD], gdb_cv_var_elf,
1941 [AC_TRY_LINK(
1942 [#include <stdlib.h>
1943 #include "bfd.h"
1944 #include "elf-bfd.h"
1945 ],
1946 [bfd *abfd = NULL; bfd_get_elf_phdr_upper_bound (abfd); ],
1947 gdb_cv_var_elf=yes, gdb_cv_var_elf=no)])
1948 if test $gdb_cv_var_elf = yes; then
1949   CONFIG_OBS="$CONFIG_OBS elfread.o"
1950   AC_DEFINE(HAVE_ELF, 1,
1951             [Define if ELF support should be included.])
1952   # -ldl is provided by bfd/Makfile.am (LIBDL) <PLUGINS>.
1953   if test "$plugins" = "yes"; then
1954     OLD_LIBS="-ldl $OLD_LIBS"
1955   fi
1956 fi
1957 CFLAGS=$OLD_CFLAGS
1958 LDFLAGS=$OLD_LDFLAGS
1959 LIBS=$OLD_LIBS
1960
1961 # Add any host-specific objects to GDB.
1962 CONFIG_OBS="${CONFIG_OBS} ${gdb_host_obs}"
1963
1964 LIBGUI="../libgui/src/libgui.a"
1965 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
1966 AC_SUBST(LIBGUI)
1967 AC_SUBST(GUI_CFLAGS_X)
1968
1969 WIN32LDAPP=
1970 AC_SUBST(WIN32LIBS)
1971 AC_SUBST(WIN32LDAPP)
1972
1973 case "${host}" in
1974 *-*-cygwin* | *-*-mingw* )
1975     configdir="win"
1976     ;;
1977 *)
1978     configdir="unix"
1979     ;;
1980 esac
1981
1982 GDBTKLIBS=
1983 if test "${enable_gdbtk}" = "yes"; then
1984
1985     # Gdbtk must have an absolute path to srcdir in order to run
1986     # properly when not installed.
1987     here=`pwd`
1988     cd ${srcdir}
1989     GDBTK_SRC_DIR=`pwd`
1990     cd $here
1991
1992     SC_PATH_TCLCONFIG
1993
1994     # If $no_tk is nonempty, then we can't do Tk, and there is no
1995     # point to doing Tcl.
1996     SC_PATH_TKCONFIG
1997
1998     if test -z "${no_tcl}" -a -z "${no_tk}"; then
1999         SC_LOAD_TCLCONFIG
2000
2001         # Check for in-tree tcl
2002         here=`pwd`
2003         cd ${srcdir}/..
2004         topdir=`pwd`
2005         cd ${here}
2006
2007         intree="no"
2008         if test "${TCL_SRC_DIR}" = "${topdir}/tcl"; then
2009           intree="yes"
2010         fi
2011
2012         # Find Tcl private headers
2013         if test x"${intree}" = xno; then
2014           CY_AC_TCL_PRIVATE_HEADERS
2015           TCL_INCLUDE="${TCL_INCLUDE_SPEC} ${TCL_PRIVATE_INCLUDE}"
2016           TCL_LIBRARY="${TCL_LIB_SPEC}"
2017           TCL_DEPS=""
2018         else
2019           # If building tcl in the same src tree, private headers
2020           # are not needed, but we need to be sure to use the right
2021           # headers library
2022           TCL_INCLUDE="-I${TCL_SRC_DIR}/generic"
2023           TCL_LIBRARY="${TCL_BUILD_LIB_SPEC}"
2024           TCL_DEPS="../tcl/${configdir}${TCL_LIB_FILE}"
2025         fi
2026         AC_SUBST(TCL_INCLUDE)
2027         AC_SUBST(TCL_LIBRARY)
2028         AC_SUBST(TCL_DEPS)
2029
2030         SC_LOAD_TKCONFIG
2031
2032         # Check for in-tree Tk
2033         intree="no"
2034         if test "${TK_SRC_DIR}" = "${topdir}/tk"; then
2035           intree="yes"
2036         fi
2037
2038         # Find Tk private headers
2039         if test x"${intree}" = xno; then
2040           CY_AC_TK_PRIVATE_HEADERS
2041           TK_INCLUDE="${TK_INCLUDE_SPEC} ${TK_PRIVATE_INCLUDE}"
2042           TK_LIBRARY=${TK_LIB_SPEC}
2043           TK_DEPS=""
2044         else
2045           TK_INCLUDE="-I${TK_SRC_DIR}/generic"
2046           TK_LIBRARY="${TK_BUILD_LIB_SPEC}"
2047           TK_DEPS="../tk/${configdir}/${TK_LIB_FILE}"
2048         fi
2049         AC_SUBST(TK_INCLUDE)
2050         AC_SUBST(TK_LIBRARY)
2051         AC_SUBST(TK_DEPS)
2052         AC_SUBST(TK_XINCLUDES)
2053
2054         ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
2055
2056         # Include some libraries that Tcl and Tk want.
2057         TCL_LIBS='$(LIBGUI) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
2058         # Yes, the ordering seems wrong here.  But it isn't.
2059         # TK_LIBS is the list of libraries that need to be linked
2060         # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
2061         # were in LIBS then any link tests after this point would
2062         # try to include things like `$(LIBGUI)', which wouldn't work.
2063         GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
2064
2065         CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
2066         CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
2067         CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
2068         CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
2069         CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
2070         CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
2071         CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
2072
2073         if test x$gdb_cv_os_cygwin = xyes; then
2074           WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
2075           WIN32LDAPP="-Wl,--subsystem,console"
2076           CONFIG_OBS="${CONFIG_OBS} gdbres.o"
2077         fi
2078
2079         AC_CONFIG_SUBDIRS(gdbtk)
2080     fi
2081 fi
2082
2083 AC_SUBST(X_CFLAGS)
2084 AC_SUBST(X_LDFLAGS)
2085 AC_SUBST(X_LIBS)
2086 AC_SUBST(GDBTKLIBS)
2087 AC_SUBST(GDBTK_CFLAGS)
2088 AC_SUBST(GDBTK_SRC_DIR)
2089
2090 AC_PATH_X
2091
2092 # Unlike the sim directory, whether a simulator is linked is controlled by
2093 # presence of a gdb_sim definition in the target configure.tgt entry.
2094 # This code just checks for a few cases where we'd like to ignore those
2095 # definitions, even when they're present in the '.mt' file.  These cases
2096 # are when --disable-sim is specified, or if the simulator directory is
2097 # not part of the source tree.
2098 #
2099 AC_ARG_ENABLE(sim,
2100 AS_HELP_STRING([--enable-sim], [link gdb with simulator]),
2101 [echo "enable_sim = $enable_sim";
2102  echo "enableval = ${enableval}";
2103  case "${enableval}" in
2104   yes) ignore_sim=false ;;
2105   no)  ignore_sim=true ;;
2106   *)   ignore_sim=false ;;
2107  esac],
2108 [ignore_sim=false])
2109
2110 if test ! -d "${srcdir}/../sim"; then
2111   ignore_sim=true
2112 fi
2113
2114 SIM=
2115 SIM_OBS=
2116 if test "${ignore_sim}" = "false"; then
2117   if test x"${gdb_sim}" != x ; then
2118     SIM="${gdb_sim}"
2119     SIM_OBS="remote-sim.o"
2120     AC_DEFINE(WITH_SIM, 1, [Define if the simulator is being linked in.])
2121   fi
2122 fi
2123 AC_SUBST(SIM)
2124 AC_SUBST(SIM_OBS)
2125
2126 AC_SUBST(ENABLE_CFLAGS)
2127 AC_SUBST(PROFILE_CFLAGS)
2128
2129 AC_SUBST(CONFIG_OBS)
2130 AC_SUBST(CONFIG_DEPS)
2131 AC_SUBST(CONFIG_SRCS)
2132 AC_SUBST(CONFIG_ALL)
2133 AC_SUBST(CONFIG_CLEAN)
2134 AC_SUBST(CONFIG_INSTALL)
2135 AC_SUBST(CONFIG_UNINSTALL)
2136
2137 # List of host floatformats.
2138 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
2139 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
2140 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
2141
2142 # target_subdir is used by the testsuite to find the target libraries.
2143 target_subdir=
2144 if test "${host}" != "${target}"; then
2145     target_subdir="${target_alias}/"
2146 fi
2147 AC_SUBST(target_subdir)
2148
2149 frags=
2150 if test "${gdb_native}" = "yes"; then
2151   host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
2152   if test ! -f ${host_makefile_frag}; then
2153     AC_MSG_ERROR("*** Gdb does not support native target ${host}")
2154   fi
2155   frags="$frags $host_makefile_frag"
2156 else
2157   host_makefile_frag=/dev/null
2158 fi
2159
2160 AC_SUBST_FILE(host_makefile_frag)
2161 AC_SUBST(frags)
2162
2163 changequote(,)dnl
2164 if test "${gdb_native}" = "yes"; then
2165 # We pick this up from the host configuration file (.mh) because we
2166 # do not have a native configuration Makefile fragment.
2167 nativefile=`sed -n '
2168 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
2169 ' ${host_makefile_frag}`
2170 fi
2171 changequote([,])
2172
2173 if test x"${gdb_osabi}" != x ; then
2174     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
2175                        [Define to the default OS ABI for this configuration.])
2176 fi
2177
2178 # Enable multi-ice-gdb-server.
2179 AC_ARG_ENABLE(multi-ice,
2180 AS_HELP_STRING([--enable-multi-ice], [build the multi-ice-gdb-server]),
2181   [case $enableval in
2182     yes | no)
2183       ;;
2184     *) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;;
2185   esac])
2186 if test "x$enable_multi_ice" = xyes; then
2187    AC_CONFIG_SUBDIRS(multi-ice)
2188 fi
2189
2190 AC_ARG_ENABLE(gdbserver,
2191 AS_HELP_STRING([--enable-gdbserver],
2192                [automatically build gdbserver (yes/no/auto, default is auto)]),
2193 [case "${enableval}" in
2194   yes| no|auto) ;;
2195   *) AC_MSG_ERROR(bad value ${enableval} for --enable-gdbserver option) ;;
2196 esac],[enable_gdbserver=auto])
2197
2198 # We only build gdbserver automatically in a native configuration, and
2199 # only if the user did not explicitly disable its build.
2200 if test "$gdb_native" = "yes" -a "$enable_gdbserver" != "no"; then
2201   AC_MSG_CHECKING(whether gdbserver is supported on this host)
2202   if test "x$build_gdbserver" = xyes; then
2203     AC_MSG_RESULT(yes)
2204     AC_CONFIG_SUBDIRS(gdbserver)
2205     gdbserver_build_enabled=yes
2206   else
2207     AC_MSG_RESULT(no)
2208   fi
2209 fi
2210
2211 # If the user explicitly request the gdbserver to be built, verify that
2212 # we were in fact able to enable it.
2213 if test "$enable_gdbserver" = "yes" -a "$gdbserver_build_enabled" != "yes"; then
2214   AC_MSG_ERROR(Automatic gdbserver build is not supported for this configuration)
2215 fi
2216
2217 # If nativefile (NAT_FILE) is not set in config/*/*.m[ht] files, we link
2218 # to an empty version.
2219
2220 files=
2221 links=
2222
2223 rm -f nm.h
2224 if test "${nativefile}" != ""; then
2225     case "${nativefile}" in
2226       nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
2227       * ) GDB_NM_FILE="${nativefile}"
2228     esac
2229     files="${files} ${GDB_NM_FILE}"
2230     links="${links} nm.h"
2231     AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}", [nativefile])
2232 fi
2233 AC_SUBST(GDB_NM_FILE)
2234
2235 AC_LINK_FILES($files, $links)
2236
2237 dnl Check for exe extension set on certain hosts (e.g. Win32)
2238 AC_EXEEXT
2239
2240 dnl  Detect the character set used by this host.
2241 dnl  At the moment, we just assume it's UTF-8.
2242 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "UTF-8",
2243           [Define to be a string naming the default host character set.])
2244
2245 AC_OUTPUT(Makefile gdb-gdb.gdb doc/Makefile gnulib/Makefile data-directory/Makefile,
2246 [
2247 case x$CONFIG_HEADERS in
2248 xconfig.h:config.in)
2249 echo > stamp-h ;;
2250 esac
2251 ])
2252
2253 exit 0