gdb/configure.ac

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995-2014 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Process this file with autoconf to produce a configure script.
  20
  21 AC_PREREQ(2.59)dnl
  22 AC_INIT(main.c)
  23 AC_CONFIG_HEADER(config.h:config.in)
  24 AM_MAINTAINER_MODE
  25
  26 # Set the 'development' global.
  27 . $srcdir/../bfd/development.sh
  28
  29 AC_PROG_CC
  30 AC_USE_SYSTEM_EXTENSIONS
  31 ACX_LARGEFILE
  32 AM_PROG_CC_STDC
  33 AM_PROG_INSTALL_STRIP
  34
  35 AC_CONFIG_AUX_DIR(..)
  36 AC_CANONICAL_SYSTEM
  37 AC_ARG_PROGRAM
  38
  39 # Dependency checking.
  40 ZW_CREATE_DEPDIR
  41 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  42
  43 # Check for the 'make' the user wants to use.
  44 AC_CHECK_PROGS(MAKE, make)
  45 MAKE_IS_GNU=
  46 case "`$MAKE --version 2>&1 | sed 1q`" in
  47   *GNU*)
  48     MAKE_IS_GNU=yes
  49     ;;
  50 esac
  51 AM_CONDITIONAL(GMAKE, test "$MAKE_IS_GNU" = yes)
  52 AC_PROG_MAKE_SET
  53
  54 # Configure gnulib.  We need to build gnulib under some other
  55 # directory not "gnulib", to avoid the problem of both GDB and
  56 # GDBserver wanting to build it in the same directory, when building
  57 # in the source dir.
  58 ACX_CONFIGURE_DIR(["gnulib"], ["build-gnulib"])
  59
  60 dnl List of object files and targets accumulated by configure.
  61
  62 CONFIG_OBS=
  63 CONFIG_DEPS=
  64 CONFIG_SRCS=
  65 ENABLE_CFLAGS=
  66
  67 CONFIG_ALL=
  68 CONFIG_CLEAN=
  69 CONFIG_INSTALL=
  70 CONFIG_UNINSTALL=
  71
  72 dnl Set up for gettext.
  73 ZW_GNU_GETTEXT_SISTER_DIR
  74
  75 localedir='${datadir}/locale'
  76 AC_SUBST(localedir)
  77
  78 if test x"$USE_NLS" = xyes; then
  79    CONFIG_ALL="$CONFIG_ALL all-po"
  80    CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
  81    CONFIG_INSTALL="$CONFIG_INSTALL install-po"
  82    CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
  83 fi
  84
  85 GNULIB=build-gnulib/import
  86
  87 # For Makefile dependencies.
  88 GNULIB_STDINT_H=
  89 if test x"$STDINT_H" != x; then
  90   GNULIB_STDINT_H=$GNULIB/$STDINT_H
  91 fi
  92 AC_SUBST(GNULIB_STDINT_H)
  93
  94 PACKAGE=gdb
  95 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
  96 AC_SUBST(PACKAGE)
  97
  98 # We never need to detect it in this sub-configure.
  99 # But preserve it for config.status --recheck.
 100 AC_ARG_VAR(MAKEINFO,
 101   [Parent configure detects if it is of sufficient version.])
 102 AC_ARG_VAR(MAKEINFOFLAGS,
 103   [Parameters for MAKEINFO.])
 104
 105 MAKEINFO_EXTRA_FLAGS=""
 106 AC_CACHE_CHECK([whether $MAKEINFO supports @click], gdb_cv_have_makeinfo_click,
 107   [echo '@clicksequence{a @click{} b}' >conftest.texinfo
 108   if eval "$MAKEINFO conftest.texinfo >&5 2>&5"; then
 109     gdb_cv_have_makeinfo_click=yes
 110   else
 111     gdb_cv_have_makeinfo_click=no
 112   fi])
 113 if test x"$gdb_cv_have_makeinfo_click" = xyes; then
 114   MAKEINFO_EXTRA_FLAGS="$MAKEINFO_EXTRA_FLAGS -DHAVE_MAKEINFO_CLICK"
 115 fi
 116 AC_SUBST(MAKEINFO_EXTRA_FLAGS)
 117
 118 GDB_AC_WITH_DIR(DEBUGDIR, separate-debug-dir,
 119     [look for global separate debug info in this path @<:@LIBDIR/debug@:>@],
 120     [${libdir}/debug])
 121
 122 # We can't pass paths as command line arguments.
 123 # Mingw32 tries to be clever and will convert the paths for us.
 124 # For example -DBINDIR="/usr/local/bin" passed on the command line may get
 125 # converted to -DBINDIR="E:/msys/mingw32/msys/1.0/local/bin".
 126 # This breaks GDB's relocatable path conversions since paths passed in
 127 # config.h would not get so translated, the path prefixes no longer match.
 128 AC_DEFINE_DIR(BINDIR, bindir, [Directory of programs.])
 129
 130 # GDB's datadir relocation
 131
 132 GDB_AC_WITH_DIR(GDB_DATADIR, gdb-datadir,
 133     [look for global separate data files in this path @<:@DATADIR/gdb@:>@],
 134     [${datadir}/gdb])
 135
 136 AC_ARG_WITH(relocated-sources,
 137 AS_HELP_STRING([--with-relocated-sources=PATH], [automatically relocate this path for source files]),
 138 [reloc_srcdir="${withval}"
 139  AC_DEFINE_DIR(RELOC_SRCDIR, reloc_srcdir,
 140               [Relocated directory for source files. ])
 141 ])
 142
 143 AC_MSG_CHECKING([for default auto-load directory])
 144 AC_ARG_WITH(auto-load-dir,
 145 AS_HELP_STRING([--with-auto-load-dir=PATH],
 146   [directories from which to load auto-loaded scripts @<:@$debugdir:$datadir/auto-load@:>@]),,
 147   [with_auto_load_dir='$debugdir:$datadir/auto-load'])
 148 escape_dir=`echo $with_auto_load_dir | sed 's/[[$]]\(datadir\|debugdir\)\>/\\\\\\\\\\\\&/g'`
 149 AC_DEFINE_DIR(AUTO_LOAD_DIR, escape_dir,
 150               [Directories from which to load auto-loaded scripts.])
 151 AC_MSG_RESULT([$with_auto_load_dir])
 152
 153 AC_MSG_CHECKING([for default auto-load safe-path])
 154 AC_ARG_WITH(auto-load-safe-path,
 155 AS_HELP_STRING([--with-auto-load-safe-path=PATH],
 156   [directories safe to hold auto-loaded files @<:@--with-auto-load-dir@:>@])
 157 AS_HELP_STRING([--without-auto-load-safe-path],
 158                [do not restrict auto-loaded files locations]),
 159     [if test "$with_auto_load_safe_path" = "no"; then
 160      with_auto_load_safe_path="/"
 161      fi],
 162 [with_auto_load_safe_path="$with_auto_load_dir"])
 163 escape_dir=`echo $with_auto_load_safe_path | sed 's/[[$]]\(datadir\|debugdir\)\>/\\\\\\\\\\\\&/g'`
 164 AC_DEFINE_DIR(AUTO_LOAD_SAFE_PATH, escape_dir,
 165               [Directories safe to hold auto-loaded files.])
 166 AC_MSG_RESULT([$with_auto_load_safe_path])
 167
 168 AC_CONFIG_SUBDIRS(testsuite)
 169
 170 # Check whether to support alternative target configurations
 171 AC_ARG_ENABLE(targets,
 172 AS_HELP_STRING([--enable-targets=TARGETS], [alternative target configurations]),
 173 [case "${enableval}" in
 174   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
 175             ;;
 176   no)       enable_targets= ;;
 177   *)        enable_targets=$enableval ;;
 178 esac])
 179
 180 # Check whether to enable 64-bit support on 32-bit hosts
 181 AC_ARG_ENABLE(64-bit-bfd,
 182 AS_HELP_STRING([--enable-64-bit-bfd], [64-bit support (on hosts with narrower word sizes)]),
 183 [case "${enableval}" in
 184   yes)  want64=true  ;;
 185   no)   want64=false ;;
 186   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
 187 esac],[want64=false])dnl
 188
 189 # Provide defaults for some variables set by the per-host and per-target
 190 # configuration.
 191 gdb_host_obs=posix-hdep.o
 192
 193 if test "${target}" = "${host}"; then
 194   gdb_native=yes
 195 else
 196   gdb_native=no
 197 fi
 198
 199 . $srcdir/configure.host
 200
 201 # Accumulate some settings from configure.tgt over all enabled targets
 202
 203 TARGET_OBS=
 204 all_targets=
 205 HAVE_NATIVE_GCORE_TARGET=
 206
 207 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 208 do
 209   if test "$targ_alias" = "all"; then
 210     all_targets=true
 211   else
 212     # Canonicalize the secondary target names.
 213     result=`$ac_config_sub $targ_alias 2>/dev/null`
 214     if test -n "$result"; then
 215         targ=$result
 216     else
 217         targ=$targ_alias
 218     fi
 219
 220     . ${srcdir}/configure.tgt
 221
 222     AS_IF([test -z "${gdb_target_obs}"],
 223       [AC_MSG_ERROR([configuration ${targ} is unsupported.])])
 224
 225     # Target-specific object files
 226     for i in ${gdb_target_obs}; do
 227         case " $TARGET_OBS " in
 228         *" ${i} "*) ;;
 229         *)
 230           TARGET_OBS="$TARGET_OBS ${i}"
 231           ;;
 232         esac
 233     done
 234
 235     # Check whether this target needs 64-bit CORE_ADDR
 236     if test x${want64} = xfalse; then
 237       . ${srcdir}/../bfd/config.bfd
 238     fi
 239
 240     # Check whether this target is native and supports gcore.
 241     if test $gdb_native = yes -a "$targ_alias" = "$target_alias" \
 242        && $gdb_have_gcore; then
 243       HAVE_NATIVE_GCORE_TARGET=1
 244     fi
 245   fi
 246 done
 247
 248 if test x${all_targets} = xtrue; then
 249
 250   # We want all 64-bit targets if we either:
 251   #  - run on a 64-bit host  or
 252   #  - already require 64-bit support for some other target  or
 253   #  - the --enable-64-bit-bfd option was supplied
 254   # Otherwise we only support all 32-bit targets.
 255   #
 256   # NOTE: This test must be in sync with the corresponding
 257   #       tests in BFD!
 258
 259   if test x${want64} = xfalse; then
 260     AC_CHECK_SIZEOF(long)
 261     if test "x${ac_cv_sizeof_long}" = "x8"; then
 262       want64=true
 263     fi
 264   fi
 265   if test x${want64} = xtrue; then
 266     TARGET_OBS='$(ALL_TARGET_OBS) $(ALL_64_TARGET_OBS)'
 267   else
 268     TARGET_OBS='$(ALL_TARGET_OBS)'
 269   fi
 270 fi
 271
 272 AC_SUBST(TARGET_OBS)
 273 AC_SUBST(HAVE_NATIVE_GCORE_TARGET)
 274
 275 # For other settings, only the main target counts.
 276 gdb_sim=
 277 gdb_osabi=
 278 build_gdbserver=
 279 targ=$target; . ${srcdir}/configure.tgt
 280
 281 # Fetch the default architecture and default target vector from BFD.
 282 targ=$target; . $srcdir/../bfd/config.bfd
 283
 284 # We only want the first architecture, so strip off the others if
 285 # there is more than one.
 286 targ_archs=`echo $targ_archs | sed 's/ .*//'`
 287
 288 if test "x$targ_archs" != x; then
 289   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
 290     [Define to BFD's default architecture. ])
 291 fi
 292 if test "x$targ_defvec" != x; then
 293   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
 294     [Define to BFD's default target vector. ])
 295 fi
 296
 297 # The CLI cannot be disabled yet, but may be in the future.
 298
 299 # Enable CLI.
 300 AC_ARG_ENABLE(gdbcli,
 301 AS_HELP_STRING([--disable-gdbcli], [disable command-line interface (CLI)]),
 302   [case $enableval in
 303     yes)
 304       ;;
 305     no)
 306       AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;;
 307     *)
 308       AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;;
 309   esac],
 310   [enable_gdbcli=yes])
 311 if test x"$enable_gdbcli" = xyes; then
 312   if test -d $srcdir/cli; then
 313     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)"
 314     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)"
 315     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)"
 316     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)"
 317   fi
 318 fi
 319
 320 # Enable MI.
 321 AC_ARG_ENABLE(gdbmi,
 322 AS_HELP_STRING([--disable-gdbmi], [disable machine-interface (MI)]),
 323   [case $enableval in
 324     yes | no)
 325       ;;
 326     *)
 327       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 328   esac],
 329   [enable_gdbmi=yes])
 330 if test x"$enable_gdbmi" = xyes; then
 331   if test -d $srcdir/mi; then
 332     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 333     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 334     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 335     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 336   fi
 337 fi
 338
 339 # Enable TUI.
 340 AC_ARG_ENABLE(tui,
 341 AS_HELP_STRING([--enable-tui], [enable full-screen terminal user interface (TUI)]),
 342   [case $enableval in
 343     yes | no | auto)
 344       ;;
 345     *)
 346       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 347   esac],enable_tui=auto)
 348
 349 # Enable gdbtk.
 350 AC_ARG_ENABLE(gdbtk,
 351 AS_HELP_STRING([--enable-gdbtk], [enable gdbtk graphical user interface (GUI)]),
 352   [case $enableval in
 353     yes | no)
 354       ;;
 355     *)
 356       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 357   esac],
 358   [if test -d $srcdir/gdbtk; then
 359     enable_gdbtk=yes
 360   else
 361     enable_gdbtk=no
 362   fi])
 363 # We unconditionally disable gdbtk tests on selected platforms.
 364 case $host_os in
 365   go32* | windows*)
 366     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 367     enable_gdbtk=no ;;
 368 esac
 369
 370 # Libunwind support for ia64.
 371
 372 AC_ARG_WITH(libunwind-ia64,
 373 AS_HELP_STRING([--with-libunwind-ia64],
 374                [use libunwind frame unwinding for ia64 targets]),,
 375             [with_libunwind_ia64=auto])
 376
 377 # Backward compatibility option.
 378 if test "${with_libunwind+set}" = set; then
 379   if test x"$with_libunwind_ia64" != xauto; then
 380     AC_MSG_ERROR(
 381       [option --with-libunwind is deprecated, use --with-libunwind-ia64])
 382   fi
 383   AC_MSG_WARN([option --with-libunwind is deprecated, use --with-libunwind-ia64])
 384   with_libunwind_ia64="$with_libunwind"
 385 fi
 386
 387 case "$with_libunwind_ia64" in
 388   yes | no)
 389     ;;
 390   auto)
 391     AC_CHECK_HEADERS(libunwind-ia64.h)
 392     with_libunwind_ia64=$ac_cv_header_libunwind_ia64_h
 393     ;;
 394   *)
 395     AC_MSG_ERROR(
 396       [bad value $with_libunwind_ia64 for GDB --with-libunwind-ia64 option])
 397     ;;
 398 esac
 399
 400 if test x"$with_libunwind_ia64" = xyes; then
 401   AC_CHECK_HEADERS(libunwind-ia64.h)
 402   if test x"$ac_cv_header_libunwind_ia64_h" != xyes; then
 403     AC_MSG_ERROR([GDB option --with-libunwind-ia64 requires libunwind-ia64.h])
 404   fi
 405   CONFIG_OBS="$CONFIG_OBS ia64-libunwind-tdep.o"
 406   CONFIG_DEPS="$CONFIG_DEPS ia64-libunwind-tdep.o"
 407   CONFIG_SRCS="$CONFIG_SRCS ia64-libunwind-tdep.c"
 408 fi
 409
 410 opt_curses=no
 411 AC_ARG_WITH(curses, AS_HELP_STRING([--with-curses], [use the curses library instead of the termcap library]), opt_curses=$withval)
 412
 413 prefer_curses=no
 414 if test "$opt_curses" = "yes"; then
 415   prefer_curses=yes
 416 fi
 417
 418 # Profiling support.
 419 AC_ARG_ENABLE(profiling,
 420 AS_HELP_STRING([--enable-profiling], [enable profiling of GDB]),
 421   [case $enableval in
 422     yes | no)
 423       ;;
 424     *)
 425       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 426   esac],
 427  [enable_profiling=no])
 428
 429 AC_CHECK_FUNCS(monstartup _mcleanup)
 430 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 431 [AC_TRY_LINK(
 432 [#include <stdlib.h>
 433 extern char _etext;
 434 ],
 435 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 436 if test $ac_cv_var__etext = yes; then
 437   AC_DEFINE(HAVE__ETEXT, 1,
 438             [Define to 1 if your system has the _etext variable. ])
 439 fi
 440 AC_CACHE_CHECK([for etext], ac_cv_var_etext,
 441 [AC_TRY_LINK(
 442 [#include <stdlib.h>
 443 extern char etext;
 444 ],
 445 [free (&etext);], ac_cv_var_etext=yes, ac_cv_var_etext=no)])
 446 if test $ac_cv_var_etext = yes; then
 447   AC_DEFINE(HAVE_ETEXT, 1,
 448             [Define to 1 if your system has the etext variable. ])
 449 fi
 450 if test "$enable_profiling" = yes ; then
 451   if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
 452     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 453   fi
 454   PROFILE_CFLAGS=-pg
 455   OLD_CFLAGS="$CFLAGS"
 456   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 457
 458   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 459     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 460      ac_cv_cc_supports_pg=no)])
 461
 462   if test $ac_cv_cc_supports_pg = no; then
 463     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 464   fi
 465
 466   CFLAGS="$OLD_CFLAGS"
 467 fi
 468
 469 ACX_PKGVERSION([GDB])
 470 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 471 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 472 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 473
 474 # --------------------- #
 475 # Checks for programs.  #
 476 # --------------------- #
 477
 478 AC_PROG_AWK
 479 AC_PROG_INSTALL
 480 AC_PROG_LN_S
 481 AC_PROG_RANLIB
 482 AC_PROG_YACC
 483
 484 AC_CHECK_TOOL(AR, ar)
 485 AC_CHECK_TOOL(DLLTOOL, dlltool)
 486 AC_CHECK_TOOL(WINDRES, windres)
 487
 488 case $host_os in
 489   gnu*)
 490     # Needed for GNU Hurd hosts.
 491     AC_CHECK_TOOL(MIG, mig)
 492     if test x"$MIG" = x; then
 493       AC_MSG_ERROR([MIG not found but required for $host hosts])
 494     fi
 495     ;;
 496 esac
 497
 498 # ---------------------- #
 499 # Checks for libraries.  #
 500 # ---------------------- #
 501
 502 # We might need to link with -lm; most simulators need it.
 503 AC_CHECK_LIB(m, main)
 504
 505 # We need to link with -lw to get `wctype' on Solaris before Solaris
 506 # 2.6.  Solaris 2.6 and beyond have this function in libc, and have a
 507 # libw that some versions of the GNU linker cannot hanle (GNU ld 2.9.1
 508 # is known to have this problem).  Therefore we avoid libw if we can.
 509 AC_CHECK_FUNC(wctype, [],
 510   [AC_CHECK_LIB(w, wctype)])
 511
 512 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 513 AC_SEARCH_LIBS(gethostbyname, nsl)
 514
 515 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 516 AC_SEARCH_LIBS(socketpair, socket)
 517
 518 # Link in zlib if we can.  This allows us to read compressed debug sections.
 519 AM_ZLIB
 520
 521 # On HP/UX we may need libxpdl for dlgetmodinfo (used by solib-pa64.c).
 522 AC_SEARCH_LIBS(dlgetmodinfo, [dl xpdl])
 523
 524 AM_ICONV
 525
 526 # GDB may fork/exec the iconv program to get the list of supported character
 527 # sets.  Allow the user to specify where to find it.
 528 # There are several factors affecting the choice of option name:
 529 # - There is already --with-libiconv-prefix but we can't use it, it specifies
 530 #   the build-time location of libiconv files.
 531 # - The program we need to find is iconv, which comes with glibc.  The user
 532 #   doesn't necessarily have libiconv installed.  Therefore naming this
 533 #   --with-libiconv-foo feels wrong.
 534 # - We want the path to be relocatable, but GDB_AC_DEFINE_RELOCATABLE is
 535 #   defined to work on directories not files (though it really doesn't know
 536 #   the difference).
 537 # - Calling this --with-iconv-prefix is perceived to cause too much confusion
 538 #   with --with-libiconv-prefix.
 539 # Putting these together is why the option name is --with-iconv-bin.
 540
 541 AC_ARG_WITH(iconv-bin,
 542 AS_HELP_STRING([--with-iconv-bin=PATH], [specify where to find the iconv program]),
 543 [iconv_bin="${withval}"
 544  AC_DEFINE_UNQUOTED([ICONV_BIN], ["${iconv_bin}"],
 545                     [Path of directory of iconv program.])
 546  GDB_AC_DEFINE_RELOCATABLE(ICONV_BIN, iconv, ${iconv_bin})
 547 ])
 548
 549 # For the TUI, we need enhanced curses functionality.
 550 if test x"$enable_tui" != xno; then
 551   prefer_curses=yes
 552 fi
 553
 554 curses_found=no
 555 if test x"$prefer_curses" = xyes; then
 556   # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
 557   # curses library because the latter might not provide all the
 558   # functionality we need.  However, this leads to problems on systems
 559   # where the linker searches /usr/local/lib, but the compiler doesn't
 560   # search /usr/local/include, if ncurses is installed in /usr/local.  A
 561   # default installation of ncurses on alpha*-dec-osf* will lead to such
 562   # a situation.
 563   AC_SEARCH_LIBS(waddstr, [ncurses cursesX curses])
 564
 565   if test "$ac_cv_search_waddstr" != no; then
 566     curses_found=yes
 567   fi
 568 fi
 569
 570 # Check whether we should enable the TUI, but only do so if we really
 571 # can.
 572 if test x"$enable_tui" != xno; then
 573   if test -d $srcdir/tui; then
 574     if test "$curses_found" != no; then
 575       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
 576       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
 577       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
 578       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
 579     else
 580       if test x"$enable_tui" = xyes; then
 581         AC_MSG_ERROR([no enhanced curses library found; disable TUI])
 582       else
 583         AC_MSG_WARN([no enhanced curses library found; disabling TUI])
 584       fi
 585     fi
 586   fi
 587 fi
 588
 589 # Since GDB uses Readline, we need termcap functionality.  In many
 590 # cases this will be provided by the curses library, but some systems
 591 # have a seperate termcap library, or no curses library at all.
 592
 593 case $host_os in
 594   cygwin*)
 595     if test -d $srcdir/libtermcap; then
 596       LIBS="../libtermcap/libtermcap.a $LIBS"
 597       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 598     fi ;;
 599   go32* | *djgpp*)
 600     ac_cv_search_tgetent="none required"
 601     ;;
 602   *mingw32*)
 603     ac_cv_search_tgetent="none required"
 604     CONFIG_OBS="$CONFIG_OBS windows-termcap.o"
 605     ;;
 606 esac
 607
 608 # These are the libraries checked by Readline.
 609 AC_SEARCH_LIBS(tgetent, [termcap tinfo curses ncurses])
 610
 611 if test "$ac_cv_search_tgetent" = no; then
 612   AC_MSG_ERROR([no termcap library found])
 613 fi
 614
 615 AC_ARG_WITH([system-readline],
 616   [AS_HELP_STRING([--with-system-readline],
 617                   [use installed readline library])])
 618
 619 if test "$with_system_readline" = yes; then
 620   READLINE=-lreadline
 621   READLINE_DEPS=
 622   READLINE_CFLAGS=
 623   READLINE_TEXI_INCFLAG=
 624 else
 625   READLINE='$(READLINE_DIR)/libreadline.a'
 626   READLINE_DEPS='$(READLINE)'
 627   READLINE_CFLAGS='-I$(READLINE_SRC)/..'
 628   READLINE_TEXI_INCFLAG='-I $(READLINE_DIR)'
 629 fi
 630 AC_SUBST(READLINE)
 631 AC_SUBST(READLINE_DEPS)
 632 AC_SUBST(READLINE_CFLAGS)
 633 AC_SUBST(READLINE_TEXI_INCFLAG)
 634
 635 # Generate jit-reader.h
 636
 637 # This is typedeffed to GDB_CORE_ADDR in jit-reader.h
 638 TARGET_PTR=
 639
 640 AC_CHECK_SIZEOF(unsigned long long)
 641 AC_CHECK_SIZEOF(unsigned long)
 642 AC_CHECK_SIZEOF(unsigned __int128)
 643
 644 if test "x${ac_cv_sizeof_unsigned_long}" = "x8"; then
 645   TARGET_PTR="unsigned long"
 646 elif test "x${ac_cv_sizeof_unsigned_long_long}" = "x8"; then
 647   TARGET_PTR="unsigned long long"
 648 elif test "x${ac_cv_sizeof_unsigned___int128}" = "x16"; then
 649   TARGET_PTR="unsigned __int128"
 650 else
 651   TARGET_PTR="unsigned long"
 652 fi
 653
 654 AC_SUBST(TARGET_PTR)
 655 AC_CONFIG_FILES([jit-reader.h:jit-reader.in])
 656
 657 AC_SEARCH_LIBS(dlopen, dl)
 658
 659 GDB_AC_WITH_DIR([JIT_READER_DIR], [jit-reader-dir],
 660                 [directory to load the JIT readers from],
 661                 [${libdir}/gdb])
 662
 663 AC_ARG_WITH(expat,
 664   AS_HELP_STRING([--with-expat], [include expat support (auto/yes/no)]),
 665   [], [with_expat=auto])
 666 AC_MSG_CHECKING([whether to use expat])
 667 AC_MSG_RESULT([$with_expat])
 668
 669 if test "${with_expat}" = no; then
 670   AC_MSG_WARN([expat support disabled; some features may be unavailable.])
 671   HAVE_LIBEXPAT=no
 672 else
 673   AC_LIB_HAVE_LINKFLAGS([expat], [], [#include "expat.h"],
 674                         [XML_Parser p = XML_ParserCreate (0);])
 675   if test "$HAVE_LIBEXPAT" != yes; then
 676     if test "$with_expat" = yes; then
 677       AC_MSG_ERROR([expat is missing or unusable])
 678     else
 679       AC_MSG_WARN([expat is missing or unusable; some features may be unavailable.])
 680     fi
 681   else
 682     save_LIBS=$LIBS
 683     LIBS="$LIBS $LIBEXPAT"
 684     AC_CHECK_FUNCS(XML_StopParser)
 685     LIBS=$save_LIBS
 686   fi
 687 fi
 688
 689 # --------------------- #
 690 # Check for libpython.  #
 691 # --------------------- #
 692
 693 dnl Utility to simplify finding libpython.
 694 dnl $1 = pythonX.Y
 695 dnl $2 = the shell variable to assign the result to
 696 dnl      If libpython is found we store $version here.
 697 dnl $3 = additional flags to add to CPPFLAGS
 698 dnl $4 = additional flags to add to LIBS
 699
 700 AC_DEFUN([AC_TRY_LIBPYTHON],
 701 [
 702   version=$1
 703   define([have_libpython_var],$2)
 704   new_CPPFLAGS=$3
 705   new_LIBS=$4
 706   AC_MSG_CHECKING([for ${version}])
 707   save_CPPFLAGS=$CPPFLAGS
 708   save_LIBS=$LIBS
 709   CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
 710   LIBS="$LIBS $new_LIBS"
 711   found_usable_python=no
 712   AC_LINK_IFELSE(AC_LANG_PROGRAM([[#include "Python.h"]],
 713                                  [[Py_Initialize ();]]),
 714                  [have_libpython_var=${version}
 715                   found_usable_python=yes
 716                   PYTHON_CPPFLAGS=$new_CPPFLAGS
 717                   PYTHON_LIBS=$new_LIBS])
 718   CPPFLAGS=$save_CPPFLAGS
 719   LIBS=$save_LIBS
 720   AC_MSG_RESULT([${found_usable_python}])
 721 ])
 722
 723 dnl There are several different values for --with-python:
 724 dnl
 725 dnl no -   Don't include python support.
 726 dnl yes -  Include python support, error if it's missing.
 727 dnl        If we find python in $PATH, use it to fetch configure options,
 728 dnl        otherwise assume the compiler can find it with no help from us.
 729 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 730 dnl auto - Same as "yes", but if python is missing from the system,
 731 dnl        fall back to "no".
 732 dnl /path/to/python/exec-prefix -
 733 dnl        Use the python located in this directory.
 734 dnl        If /path/to/python/exec-prefix/bin/python exists, use it to find
 735 dnl        the compilation parameters.  Otherwise use
 736 dnl        -I/path/to/python/exec-prefix/include,
 737 dnl        -L/path/to/python/exec-prefix/lib.
 738 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 739 dnl        NOTE: This case is historical.  It is what was done for 7.0/7.1
 740 dnl        but is deprecated.
 741 dnl /path/to/python/executable -
 742 dnl        Run python-config.py with this version of python to fetch the
 743 dnl        compilation parameters.
 744 dnl        NOTE: This needn't be the real python executable.
 745 dnl        In a cross-compilation scenario (build != host), this could be
 746 dnl        a shell script that provides what python-config.py provides for
 747 dnl        --ldflags, --includes, --exec-prefix.
 748 dnl python-executable -
 749 dnl        Find python-executable in $PATH, and then handle the same as
 750 dnl        /path/to/python/executable.
 751 dnl
 752 dnl If a python program is specified, it is used to run python-config.py and
 753 dnl is passed --ldflags, --includes, --exec-prefix.
 754
 755 AC_ARG_WITH(python,
 756   AS_HELP_STRING([--with-python@<:@=PYTHON@:>@], [include python support (auto/yes/no/<python-program>)]),
 757   [], [with_python=auto])
 758 AC_MSG_CHECKING([whether to use python])
 759 AC_MSG_RESULT([$with_python])
 760
 761 if test "${with_python}" = no; then
 762   AC_MSG_WARN([python support disabled; some features may be unavailable.])
 763   have_libpython=no
 764 else
 765   case "${with_python}" in
 766   [[\\/]]* | ?:[[\\/]]*)
 767     if test -d ${with_python}; then
 768       # Assume the python binary is ${with_python}/bin/python.
 769       python_prog="${with_python}/bin/python"
 770       python_prefix=
 771       # If python does not exit ${with_python}/bin, then try in
 772       # ${with_python}.  On Windows/MinGW, this is where the Python
 773       # executable is.
 774       if test ! -x "${python_prog}"; then
 775         python_prog="${with_python}/python"
 776         python_prefix=
 777       fi
 778       if test ! -x "${python_prog}"; then
 779         # Fall back to gdb 7.0/7.1 behaviour.
 780         python_prog=missing
 781         python_prefix=${with_python}
 782       fi
 783     elif test -x "${with_python}"; then
 784       # While we can't run python compiled for $host (unless host == build),
 785       # the user could write a script that provides the needed information,
 786       # so we support that.
 787       python_prog=${with_python}
 788       python_prefix=
 789     else
 790       AC_ERROR(invalid value for --with-python)
 791     fi
 792     ;;
 793   */*)
 794     # Disallow --with-python=foo/bar.
 795     AC_ERROR(invalid value for --with-python)
 796     ;;
 797   *)
 798     # The user has either specified auto, yes, or the name of the python
 799     # program assumed to be in $PATH.
 800     python_prefix=
 801     case "${with_python}" in
 802     yes | auto)
 803       if test ${build} = ${host}; then
 804         AC_PATH_PROG(python_prog_path, python, missing)
 805         if test "${python_prog_path}" = missing; then
 806           python_prog=missing
 807         else
 808           python_prog=${python_prog_path}
 809         fi
 810       else
 811         # Not much we can do except assume the cross-compiler will find the
 812         # right files.
 813         python_prog=missing
 814       fi
 815       ;;
 816     *)
 817       # While we can't run python compiled for $host (unless host == build),
 818       # the user could write a script that provides the needed information,
 819       # so we support that.
 820       python_prog="${with_python}"
 821       AC_PATH_PROG(python_prog_path, ${python_prog}, missing)
 822       if test "${python_prog_path}" = missing; then
 823         AC_ERROR(unable to find python program ${python_prog})
 824       fi
 825       ;;
 826     esac
 827   esac
 828
 829   if test "${python_prog}" != missing; then
 830     # We have a python program to use, but it may be too old.
 831     # Don't flag an error for --with-python=auto (the default).
 832     have_python_config=yes
 833     python_includes=`${python_prog} ${srcdir}/python/python-config.py --includes`
 834     if test $? != 0; then
 835       have_python_config=failed
 836       if test "${with_python}" != auto; then
 837         AC_ERROR(failure running python-config --includes)
 838       fi
 839     fi
 840     python_libs=`${python_prog} ${srcdir}/python/python-config.py --ldflags`
 841     if test $? != 0; then
 842       have_python_config=failed
 843       if test "${with_python}" != auto; then
 844         AC_ERROR(failure running python-config --ldflags)
 845       fi
 846     fi
 847     python_prefix=`${python_prog} ${srcdir}/python/python-config.py --exec-prefix`
 848     if test $? != 0; then
 849       have_python_config=failed
 850       if test "${with_python}" != auto; then
 851         AC_ERROR(failure running python-config --exec-prefix)
 852       fi
 853     fi
 854   else
 855     # We do not have a python executable we can use to determine where
 856     # to find the Python headers and libs.  We cannot guess the include
 857     # path from the python_prefix either, because that include path
 858     # depends on the Python version.  So, there is nothing much we can
 859     # do except assume that the compiler will be able to find those files.
 860     python_includes=
 861     python_libs=
 862     have_python_config=no
 863   fi
 864
 865   # If we have python-config, only try the configuration it provides.
 866   # Otherwise fallback on the old way of trying different versions of
 867   # python in turn.
 868
 869   have_libpython=no
 870   if test "${have_python_config}" = yes; then
 871     # Determine the Python version by extracting "-lpython<version>"
 872     # part of the python_libs. <version> is usually X.Y with X and Y
 873     # being decimal numbers, but can also be XY (seen on Windows).
 874     #
 875     # The extraction is performed using sed with a regular expression.
 876     # Initially, the regexp used was using the '?' quantifier to make
 877     # the dot in the version number optional.  Unfortunately, this
 878     # does not work with non-GNU versions of sed because, because of
 879     # what looks like a limitation (the '?' quantifier does not work
 880     # with back-references).  We work around this limitation by using
 881     # the '*' quantifier instead.  It means that, in theory, we might
 882     # match unexpected version strings such as "-lpython2..7", but
 883     # this seems unlikely in practice.  And even if that happens,
 884     # an error will be triggered later on, when checking that version
 885     # number.
 886     python_version=`echo " ${python_libs} " \
 887                          | sed -e 's,^.* -l\(python[[0-9]]*[[.]]*[[0-9]]*\).*$,\1,'`
 888     case "${python_version}" in
 889     python*)
 890       AC_TRY_LIBPYTHON(${python_version}, have_libpython,
 891                        ${python_includes}, ${python_libs})
 892       ;;
 893     *)
 894       AC_MSG_ERROR([unable to determine python version from ${python_libs}])
 895       ;;
 896     esac
 897   elif test "${have_python_config}" != failed; then
 898     if test "${have_libpython}" = no; then
 899       AC_TRY_LIBPYTHON(python2.7, have_libpython,
 900                        ${python_includes}, "${python_libs} -lpython2.7")
 901     fi
 902     if test "${have_libpython}" = no; then
 903       AC_TRY_LIBPYTHON(python2.6, have_libpython,
 904                        ${python_includes}, "${python_libs} -lpython2.6")
 905     fi
 906     if test ${have_libpython} = no; then
 907       AC_TRY_LIBPYTHON(python2.5, have_libpython,
 908                        ${python_includes}, "${python_libs} -lpython2.5")
 909     fi
 910     if test ${have_libpython} = no; then
 911       AC_TRY_LIBPYTHON(python2.4, have_libpython,
 912                        ${python_includes}, "${python_libs} -lpython2.4")
 913     fi
 914   fi
 915   if test "${have_libpython}" = python2.7 -o "${have_libpython}" = python27; then
 916     AC_DEFINE(HAVE_LIBPYTHON2_7, 1, [Define if Python 2.7 is being used.])
 917   elif test "${have_libpython}" = python2.6 -o "${have_libpython}" = python26; then
 918     AC_DEFINE(HAVE_LIBPYTHON2_6, 1, [Define if Python 2.6 is being used.])
 919   elif test "${have_libpython}" = python2.5 -o "${have_libpython}" = python25; then
 920     AC_DEFINE(HAVE_LIBPYTHON2_5, 1, [Define if Python 2.5 is being used.])
 921   elif test "${have_libpython}" = python2.4 -o "${have_libpython}" = python24; then
 922     AC_DEFINE(HAVE_LIBPYTHON2_4, 1, [Define if Python 2.4 is being used.])
 923   fi
 924
 925   if test "${have_libpython}" = no; then
 926     case "${with_python}" in
 927     yes)
 928       AC_MSG_ERROR([python is missing or unusable])
 929       ;;
 930     auto)
 931       AC_MSG_WARN([python is missing or unusable; some features may be unavailable.])
 932       ;;
 933     *)
 934       AC_MSG_ERROR([no usable python found at ${with_python}])
 935       ;;
 936     esac
 937   else
 938     if test -n "${python_prefix}"; then
 939       AC_DEFINE_UNQUOTED(WITH_PYTHON_PATH, "${python_prefix}",
 940                          [Define if --with-python provides a path, either directly or via python-config.py --exec-prefix.])
 941       GDB_AC_DEFINE_RELOCATABLE(PYTHON_PATH, python, ${python_prefix})
 942     fi
 943   fi
 944 fi
 945
 946 if test "${have_libpython}" != no; then
 947   AC_DEFINE(HAVE_PYTHON, 1, [Define if Python interpreter is being linked in.])
 948   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_PYTHON_OBS)"
 949   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_PYTHON_DEPS)"
 950   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_PYTHON_SRCS)"
 951   CONFIG_INSTALL="$CONFIG_INSTALL install-python"
 952   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_PYTHON_CFLAGS)"
 953
 954   # Flags needed to compile Python code (taken from python-config --cflags).
 955   # We cannot call python-config directly because it will output whatever was
 956   # used when compiling the Python interpreter itself, including flags which
 957   # would make the python-related objects be compiled differently from the
 958   # rest of GDB (e.g., -O2 and -fPIC).
 959   if test "${GCC}" = yes; then
 960     tentative_python_cflags="-fno-strict-aliasing -DNDEBUG -fwrapv"
 961   fi
 962
 963   if test "x${tentative_python_cflags}" != x; then
 964     AC_MSG_CHECKING(compiler flags for python code)
 965     for flag in ${tentative_python_cflags}; do
 966       # Check that the compiler accepts it
 967       saved_CFLAGS="$CFLAGS"
 968       CFLAGS="$CFLAGS $flag"
 969       AC_TRY_COMPILE([],[],PYTHON_CFLAGS="${PYTHON_CFLAGS} $flag",)
 970       CFLAGS="$saved_CFLAGS"
 971     done
 972     AC_MSG_RESULT(${PYTHON_CFLAGS})
 973   fi
 974
 975   # On x64 Windows, Python's include headers, and pyconfig.h in
 976   # particular, rely on MS_WIN64 macro to detect that it's a 64bit
 977   # version of Windows.  Unfortunately, MS_WIN64 is only defined if
 978   # _MSC_VER, a Microsoft-specific macro, is defined.  So, when
 979   # building on x64 Windows with GCC, we define MS_WIN64 ourselves.
 980   # The issue was reported to the Python community, but still isn't
 981   # solved as of 2012-10-02 (http://bugs.python.org/issue4709).
 982
 983   case "$gdb_host" in
 984     mingw64)
 985            if test "${GCC}" = yes; then
 986              CPPFLAGS="$CPPFLAGS -DMS_WIN64"
 987            fi
 988            ;;
 989   esac
 990
 991   # Note that "python -m threading" cannot be used to check for
 992   # threading support due to a bug in Python 2.7.3
 993   # (http://bugs.python.org/issue15567).
 994   AC_MSG_CHECKING(whether python supports threads)
 995   saved_CPPFLAGS="${CPPFLAGS}"
 996   CPPFLAGS="${PYTHON_CPPFLAGS}"
 997   # Note that the test is reversed so that python_has_threads=yes on
 998   # unexpected failures.
 999   AC_PREPROC_IFELSE(AC_LANG_SOURCE([[
1000 #include <Python.h>
1001 #ifdef WITH_THREAD
1002 # error
1003 #endif
1004   ]]), [python_has_threads=no], [python_has_threads=yes])
1005   AC_MSG_RESULT(${python_has_threads})
1006   CPPFLAGS="${saved_CPPFLAGS}"
1007 else
1008   # Even if Python support is not compiled in, we need to have this file
1009   # included so that the "python" command, et.al., still exists.
1010   CONFIG_OBS="$CONFIG_OBS python.o"
1011   CONFIG_SRCS="$CONFIG_SRCS python/python.c"
1012 fi
1013 AC_SUBST(PYTHON_CFLAGS)
1014 AC_SUBST(PYTHON_CPPFLAGS)
1015 AC_SUBST(PYTHON_LIBS)
1016 AM_CONDITIONAL(HAVE_PYTHON, test "${have_libpython}" != no)
1017
1018 # -------------------- #
1019 # Check for libguile.  #
1020 # -------------------- #
1021
1022 dnl Utility to simplify finding libguile.
1023 dnl $1 = pkg-config-program
1024 dnl $2 = space-separate list of guile versions to try
1025 dnl $3 = yes|no, indicating whether to flag errors or ignore them
1026 dnl $4 = the shell variable to assign the result to
1027 dnl      If libguile is found we store "yes" here.
1028
1029 AC_DEFUN([AC_TRY_LIBGUILE],
1030 [
1031   pkg_config=$1
1032   guile_version_list=$2
1033   flag_errors=$3
1034   define([have_libguile_var],$4)
1035   found_usable_guile=checking
1036   AC_MSG_CHECKING([for usable guile from ${pkg_config}])
1037   for guile_version in ${guile_version_list}; do
1038     ${pkg_config} --exists ${guile_version} 2>/dev/null
1039     if test $? != 0; then
1040       continue
1041     fi
1042     dnl pkg-config says the package exists, so if we get an error now,
1043     dnl that's bad.
1044     new_CPPFLAGS=`${pkg_config} --cflags ${guile_version}`
1045     if test $? != 0; then
1046       AC_MSG_ERROR([failure running pkg-config --cflags ${guile_version}])
1047     fi
1048     new_LIBS=`${pkg_config} --libs ${guile_version}`
1049     if test $? != 0; then
1050       AC_MSG_ERROR([failure running pkg-config --libs ${guile_version}])
1051     fi
1052     dnl If we get this far, great.
1053     found_usable_guile=${guile_version}
1054     break
1055   done
1056   if test "${found_usable_guile}" = "checking"; then
1057     if test "${flag_errors}" = "yes"; then
1058       AC_MSG_ERROR([unable to find usable guile version from "${guile_version_list}"])
1059     else
1060       found_usable_guile=no
1061     fi
1062   fi
1063   dnl One final sanity check.
1064   dnl The user could have said --with-guile=python-2.7.
1065   if test "${found_usable_guile}" != no; then
1066     save_CPPFLAGS=$CPPFLAGS
1067     save_LIBS=$LIBS
1068     CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
1069     LIBS="$LIBS $new_LIBS"
1070     AC_LINK_IFELSE(AC_LANG_PROGRAM([[#include "libguile.h"]],
1071                                    [[scm_init_guile ();]]),
1072                    [have_libguile_var=yes
1073                     GUILE_CPPFLAGS=$new_CPPFLAGS
1074                     GUILE_LIBS=$new_LIBS],
1075                    [found_usable_guile=no])
1076     CPPFLAGS=$save_CPPFLAGS
1077     LIBS=$save_LIBS
1078     if test "${found_usable_guile}" = no; then
1079       if test "${flag_errors}" = yes; then
1080         AC_MSG_FAILURE([linking guile version ${guile_version} test program failed])
1081       fi
1082     fi
1083   fi
1084   AC_MSG_RESULT([${found_usable_guile}])
1085 ])
1086
1087 dnl There are several different values for --with-guile:
1088 dnl
1089 dnl no -   Don't include guile support.
1090 dnl yes -  Include guile support, error if it's missing.
1091 dnl        The pkg-config program must be in $PATH.
1092 dnl auto - Same as "yes", but if guile is missing from the system,
1093 dnl        fall back to "no".
1094 dnl guile-version [guile-version-choice-2 ...] -
1095 dnl        A space-separated list of guile package versions to try.
1096 dnl        These are passed to pkg-config as-is.
1097 dnl        E.g., guile-2.0 or guile-2.2-uninstalled
1098 dnl        This requires making sure PKG_CONFIG_PATH is set appropriately.
1099 dnl /path/to/pkg-config -
1100 dnl        Use this pkg-config program.
1101 dnl        NOTE: This needn't be the "real" pkg-config program.
1102 dnl        It could be a shell script.  It is invoked as:
1103 dnl        pkg-config --exists $version
1104 dnl        pkg-config --cflags $version
1105 dnl        pkg-config --libs $version
1106 dnl        pkg-config --variable guild $version
1107 dnl        The script will be called with $version having each value in
1108 dnl        $try_guile_versions until --exists indicates success.
1109
1110 AC_ARG_WITH(guile,
1111   AS_HELP_STRING([--with-guile@<:@=GUILE@:>@], [include guile support (auto/yes/no/<guile-version>/<pkg-config-program>)]),
1112   [], [with_guile=auto])
1113 AC_MSG_CHECKING([whether to use guile])
1114 AC_MSG_RESULT([$with_guile])
1115
1116 dnl We check guile with pkg-config.
1117 AC_PATH_PROG(pkg_config_prog_path, pkg-config, missing)
1118
1119 try_guile_versions="guile-2.2 guile-2.0"
1120 have_libguile=no
1121 case "${with_guile}" in
1122 no)
1123   AC_MSG_WARN([guile support disabled; some features will be unavailable.])
1124   ;;
1125 auto)
1126   if test "${pkg_config_prog_path}" = "missing"; then
1127     AC_MSG_WARN([pkg-config not found, guile support disabled])
1128   else
1129     AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${try_guile_versions}, no, have_libguile)
1130   fi
1131   ;;
1132 yes)
1133   if test "${pkg_config_prog_path}" = "missing"; then
1134     AC_MSG_ERROR([pkg-config not found])
1135   fi
1136   AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${try_guile_versions}, yes, have_libguile)
1137   ;;
1138 [[\\/]]* | ?:[[\\/]]*)
1139   if test -x "${with_guile}"; then
1140     AC_TRY_LIBGUILE(${with_guile}, ${try_guile_versions}, yes, have_libguile)
1141   else
1142     AC_MSG_ERROR([Guile config program not executable: ${with_guile}])
1143   fi
1144   ;;
1145 "" | */*)
1146   # Disallow --with=guile="" and --with-guile=foo/bar.
1147   AC_MSG_ERROR([invalid value for --with-guile])
1148   ;;
1149 *)
1150   # A space separate list of guile versions to try, in order.
1151   if test "${pkg_config_prog_path}" = "missing"; then
1152     AC_MSG_ERROR([pkg-config not found])
1153   fi
1154   AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${with_guile}, yes, have_libguile)
1155   ;;
1156 esac
1157
1158 if test "${have_libguile}" != no; then
1159   dnl Get the name of the 'guild' program.
1160   case "${with_guile}" in
1161   [[\\/]]* | ?:[[\\/]]*)
1162     GDB_GUILE_PROGRAM_NAMES(["${with_guile}"], ["${guile_version}"])
1163     ;;
1164   *)
1165     GDB_GUILE_PROGRAM_NAMES(["${pkg_config_prog_path}"], ["${guile_version}"])
1166     ;;
1167   esac
1168
1169   dnl Make sure guild can handle this host.
1170   GDB_TRY_GUILD([$srcdir/guile/lib/gdb/support.scm])
1171   dnl If not, disable guile support.
1172   if test "$ac_cv_guild_ok" = no; then
1173     have_libguile=no
1174     AC_MSG_WARN(disabling guile support, $GUILD fails compiling for $host)
1175   fi
1176 fi
1177
1178 if test "${have_libguile}" != no; then
1179   AC_DEFINE(HAVE_GUILE, 1, [Define if Guile interpreter is being linked in.])
1180   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_GUILE_OBS)"
1181   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_GUILE_DEPS)"
1182   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_GUILE_SRCS)"
1183   CONFIG_INSTALL="$CONFIG_INSTALL install-guile"
1184   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_GUILE_CFLAGS)"
1185
1186   dnl The 'scm_new_smob' function appeared in Guile 2.0.6.
1187   save_LIBS="$LIBS"
1188   save_CPPFLAGS="$CPPFLAGS"
1189   LIBS="$GUILE_LIBS"
1190   CPPFLAGS="$GUILE_CPPFLAGS"
1191   AC_CHECK_FUNCS([scm_new_smob])
1192   LIBS="$save_LIBS"
1193   CPPFLAGS="$save_CPPFLAGS"
1194 else
1195   # Even if Guile support is not compiled in, we need to have these files
1196   # included.
1197   CONFIG_OBS="$CONFIG_OBS guile.o"
1198   CONFIG_SRCS="$CONFIG_SRCS guile/guile.c"
1199 fi
1200 AC_SUBST(GUILE_CPPFLAGS)
1201 AC_SUBST(GUILE_LIBS)
1202 AM_CONDITIONAL(HAVE_GUILE, test "${have_libguile}" != no)
1203
1204 # --------------------- #
1205 # Check for libmcheck.  #
1206 # --------------------- #
1207
1208 # Enable -lmcheck by default (it provides cheap-enough memory mangling),
1209 # but turn it off if Python is enabled with threads, since -lmcheck is
1210 # not thread safe (http://sourceware.org/bugzilla/show_bug.cgi?id=9939),
1211 # and for releases.
1212 if test \( "${have_libpython}" = "no" -o "${python_has_threads}" = "no" \) \
1213    && $development; then
1214   libmcheck_default=yes
1215 else
1216   libmcheck_default=no
1217 fi
1218 GDB_AC_LIBMCHECK(${libmcheck_default})
1219
1220 if test "$ENABLE_LIBMCHECK" = "yes" \
1221         -a "${have_libpython}" != "no" \
1222         -a "${python_has_threads}" = "yes" ; then
1223   AC_MSG_WARN(--enable-libmcheck may lead to spurious crashes if threads are used in python)
1224 fi
1225
1226 # ------------------------- #
1227 # Checks for header files.  #
1228 # ------------------------- #
1229
1230 AC_HEADER_STDC
1231 # elf_hp.h is for HP/UX 64-bit shared library support.
1232 AC_CHECK_HEADERS([nlist.h machine/reg.h poll.h sys/poll.h proc_service.h \
1233                   thread_db.h \
1234                   sys/fault.h \
1235                   sys/file.h sys/filio.h sys/ioctl.h sys/param.h \
1236                   sys/resource.h sys/procfs.h sys/ptrace.h ptrace.h \
1237                   sys/reg.h sys/debugreg.h sys/select.h sys/syscall.h \
1238                   termios.h termio.h \
1239                   sgtty.h elf_hp.h \
1240                   dlfcn.h])
1241 AC_CHECK_HEADERS(sys/proc.h, [], [],
1242 [#if HAVE_SYS_PARAM_H
1243 # include <sys/param.h>
1244 #endif
1245 ])
1246 AC_CHECK_HEADERS(sys/user.h, [], [],
1247 [#if HAVE_SYS_PARAM_H
1248 # include <sys/param.h>
1249 #endif
1250 ])
1251
1252 # On Solaris 2.[789], we need to define _MSE_INT_H to avoid a clash
1253 # between <widec.h> and <wchar.h> that would cause AC_CHECK_HEADERS to
1254 # think that we don't have <curses.h> if we're using GCC.
1255 case $host_os in
1256   solaris2.[[789]])
1257     if test "$GCC" = yes; then
1258       AC_DEFINE(_MSE_INT_H, 1,
1259         [Define to 1 to avoid a clash between <widec.h> and <wchar.h> on
1260    Solaris 2.[789] when using GCC. ])
1261     fi ;;
1262 esac
1263 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncurses/ncurses.h ncurses/term.h)
1264 AC_CHECK_HEADERS(term.h, [], [],
1265 [#if HAVE_CURSES_H
1266 # include <curses.h>
1267 #endif
1268 ])
1269
1270 # ------------------------- #
1271 # Checks for declarations.  #
1272 # ------------------------- #
1273
1274 AC_CHECK_DECLS([free, malloc, realloc, snprintf])
1275 AM_LC_MESSAGES
1276
1277 # ----------------------- #
1278 # Checks for structures.  #
1279 # ----------------------- #
1280
1281 AC_CHECK_MEMBERS([struct stat.st_blocks, struct stat.st_blksize])
1282
1283 # ------------------ #
1284 # Checks for types.  #
1285 # ------------------ #
1286
1287 AC_TYPE_SIGNAL
1288 AC_CHECK_TYPES(socklen_t, [], [],
1289 [#include <sys/types.h>
1290 #include <sys/socket.h>
1291 ])
1292
1293 # ------------------------------------- #
1294 # Checks for compiler characteristics.  #
1295 # ------------------------------------- #
1296
1297 AC_C_CONST
1298 AC_C_INLINE
1299 AC_C_BIGENDIAN
1300
1301 # ------------------------------ #
1302 # Checks for library functions.  #
1303 # ------------------------------ #
1304
1305 AC_FUNC_MMAP
1306 AC_FUNC_VFORK
1307 AC_CHECK_FUNCS([getrusage getuid getgid \
1308                 pipe poll pread pread64 pwrite resize_term \
1309                 sbrk setpgid setpgrp setsid \
1310                 sigaction sigprocmask sigsetmask socketpair \
1311                 ttrace wborder wresize setlocale iconvlist libiconvlist btowc \
1312                 setrlimit getrlimit posix_madvise waitpid \
1313                 ptrace64 sigaltstack])
1314 AM_LANGINFO_CODESET
1315 GDB_AC_COMMON
1316
1317 # Check the return and argument types of ptrace.  No canned test for
1318 # this, so roll our own.
1319 gdb_ptrace_headers='
1320 #include <sys/types.h>
1321 #if HAVE_SYS_PTRACE_H
1322 # include <sys/ptrace.h>
1323 #endif
1324 #if HAVE_UNISTD_H
1325 # include <unistd.h>
1326 #endif
1327 '
1328 # There is no point in checking if we don't have a prototype.
1329 AC_CHECK_DECLS(ptrace, [], [
1330   : ${gdb_cv_func_ptrace_ret='int'}
1331   : ${gdb_cv_func_ptrace_args='int,int,long,long'}
1332 ], $gdb_ptrace_headers)
1333 # Check return type.  Varargs (used on GNU/Linux) conflict with the
1334 # empty argument list, so check for that explicitly.
1335 AC_CACHE_CHECK([return type of ptrace], gdb_cv_func_ptrace_ret,
1336   AC_TRY_COMPILE($gdb_ptrace_headers,
1337     [extern long ptrace (enum __ptrace_request, ...);],
1338     gdb_cv_func_ptrace_ret='long',
1339     AC_TRY_COMPILE($gdb_ptrace_headers,
1340       [extern int ptrace ();],
1341       gdb_cv_func_ptrace_ret='int',
1342       gdb_cv_func_ptrace_ret='long')))
1343 AC_DEFINE_UNQUOTED(PTRACE_TYPE_RET, $gdb_cv_func_ptrace_ret,
1344   [Define as the return type of ptrace.])
1345 # Check argument types.
1346 AC_CACHE_CHECK([types of arguments for ptrace], gdb_cv_func_ptrace_args, [
1347   AC_TRY_COMPILE($gdb_ptrace_headers,
1348     [extern long ptrace (enum __ptrace_request, ...);],
1349     [gdb_cv_func_ptrace_args='int,int,long,long'],[
1350 for gdb_arg1 in 'int' 'long'; do
1351  for gdb_arg2 in 'pid_t' 'int' 'long'; do
1352   for gdb_arg3 in 'int *' 'caddr_t' 'int' 'long' 'void *'; do
1353    for gdb_arg4 in 'int' 'long' 'void *'; do
1354      AC_TRY_COMPILE($gdb_ptrace_headers, [
1355 extern $gdb_cv_func_ptrace_ret
1356   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4);
1357 ], [gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4";
1358     break 4;])
1359     for gdb_arg5 in 'int *' 'int' 'long'; do
1360      AC_TRY_COMPILE($gdb_ptrace_headers, [
1361 extern $gdb_cv_func_ptrace_ret
1362   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4, $gdb_arg5);
1363 ], [
1364 gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4,$gdb_arg5";
1365     break 5;])
1366     done
1367    done
1368   done
1369  done
1370 done
1371 # Provide a safe default value.
1372 : ${gdb_cv_func_ptrace_args='int,int,long,long'}
1373 ])])
1374 ac_save_IFS=$IFS; IFS=','
1375 set dummy `echo "$gdb_cv_func_ptrace_args" | sed 's/\*/\*/g'`
1376 IFS=$ac_save_IFS
1377 shift
1378 AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG3, $[3],
1379   [Define to the type of arg 3 for ptrace.])
1380 AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG4, $[4],
1381   [Define to the type of arg 4 for ptrace.])
1382 if test -n "$[5]"; then
1383   AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG5, $[5],
1384     [Define to the type of arg 5 for ptrace.])
1385 fi
1386
1387 dnl AC_FUNC_SETPGRP does not work when cross compiling
1388 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
1389 if test "$cross_compiling" = no; then
1390   AC_FUNC_SETPGRP
1391 else
1392   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
1393     [AC_TRY_COMPILE([
1394 #include <unistd.h>
1395 ], [
1396   if (setpgrp(1,1) == -1)
1397     exit (0);
1398   else
1399     exit (1);
1400 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
1401 if test $ac_cv_func_setpgrp_void = yes; then
1402   AC_DEFINE(SETPGRP_VOID, 1)
1403 fi
1404 fi
1405
1406 # Assume we'll default to using the included libiberty regex.
1407 gdb_use_included_regex=yes
1408
1409 # However, if the system regex is GNU regex, then default to *not*
1410 # using the included regex.
1411 AC_CACHE_CHECK(
1412   [for GNU regex],
1413   [gdb_cv_have_gnu_regex],
1414   [AC_TRY_COMPILE(
1415     [#include <gnu-versions.h>],
1416     [#define REGEX_INTERFACE_VERSION 1
1417 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
1418 # error "Version mismatch"
1419 #endif],
1420     gdb_cv_have_gnu_regex=yes,
1421     gdb_cv_have_gnu_regex=no)])
1422 if test $gdb_cv_have_gnu_regex = yes; then
1423   gdb_use_included_regex=no
1424 fi
1425
1426 AC_ARG_WITH(included-regex,
1427   AS_HELP_STRING([--without-included-regex], [don't use included regex; this is the default on systems with version 2 of the GNU C library (use with caution on other system)]),
1428   gdb_with_regex=$withval,
1429   gdb_with_regex=$gdb_use_included_regex)
1430 if test "$gdb_with_regex" = yes; then
1431   AC_DEFINE(USE_INCLUDED_REGEX, 1,
1432     [Define to 1 if the regex included in libiberty should be used.])
1433 fi
1434
1435 # Check if <sys/proc.h> defines `struct thread' with a td_pcb member.
1436 AC_CHECK_MEMBERS([struct thread.td_pcb], [], [],
1437 [#include <sys/param.h>
1438 #include <sys/proc.h>
1439 ])
1440
1441 # See if <sys/lwp.h> defines `struct lwp`.
1442 AC_CACHE_CHECK([for struct lwp], gdb_cv_struct_lwp,
1443 [AC_TRY_COMPILE([#include <sys/param.h>
1444 #include <sys/lwp.h>], [struct lwp l;],
1445 gdb_cv_struct_lwp=yes, gdb_cv_struct_lwp=no)])
1446 if test $gdb_cv_struct_lwp = yes; then
1447   AC_DEFINE(HAVE_STRUCT_LWP, 1,
1448             [Define to 1 if your system has struct lwp.])
1449 fi
1450
1451 # See if <machine/reg.h> degines `struct reg'.
1452 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
1453 [AC_TRY_COMPILE([#include <sys/types.h>
1454 #include <machine/reg.h>], [struct reg r;],
1455 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
1456 if test $gdb_cv_struct_reg = yes; then
1457   AC_DEFINE(HAVE_STRUCT_REG, 1,
1458             [Define to 1 if your system has struct reg in <machine/reg.h>.])
1459 fi
1460
1461 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
1462 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
1463 AC_CHECK_MEMBERS([struct reg.r_fs, struct reg.r_gs], [], [],
1464                  [#include <machine/reg.h>])
1465
1466 # See if <sys/user.h> supports the %fs_base and %gs_bas amd64 segment registers.
1467 # Older amd64 Linux's don't have the fs_base and gs_base members of
1468 # `struct user_regs_struct'.
1469 AC_CHECK_MEMBERS([struct user_regs_struct.fs_base, struct user_regs_struct.gs_base],
1470                  [], [], [#include <sys/user.h>])
1471
1472 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
1473 AC_MSG_CHECKING(for PTRACE_GETREGS)
1474 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
1475 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1476                 [PTRACE_GETREGS;],
1477                 [gdb_cv_have_ptrace_getregs=yes],
1478                 [gdb_cv_have_ptrace_getregs=no])])
1479 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
1480 if test $gdb_cv_have_ptrace_getregs = yes; then
1481   AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
1482   [Define if sys/ptrace.h defines the PTRACE_GETREGS request.])
1483 fi
1484
1485 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
1486 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
1487 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
1488 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1489                 [PTRACE_GETFPXREGS;],
1490                 [gdb_cv_have_ptrace_getfpxregs=yes],
1491                 [gdb_cv_have_ptrace_getfpxregs=no])])
1492 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
1493 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
1494   AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
1495   [Define if sys/ptrace.h defines the PTRACE_GETFPXREGS request.])
1496 fi
1497
1498 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
1499 AC_MSG_CHECKING(for PT_GETDBREGS)
1500 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
1501 [AC_TRY_COMPILE([#include <sys/types.h>
1502 #include <sys/ptrace.h>],
1503                 [PT_GETDBREGS;],
1504                 [gdb_cv_have_pt_getdbregs=yes],
1505                 [gdb_cv_have_pt_getdbregs=no])])
1506 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
1507 if test $gdb_cv_have_pt_getdbregs = yes; then
1508   AC_DEFINE(HAVE_PT_GETDBREGS, 1,
1509   [Define if sys/ptrace.h defines the PT_GETDBREGS request.])
1510 fi
1511
1512 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
1513 AC_MSG_CHECKING(for PT_GETXMMREGS)
1514 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
1515 [AC_TRY_COMPILE([#include <sys/types.h>
1516 #include <sys/ptrace.h>],
1517                 [PT_GETXMMREGS;],
1518                 [gdb_cv_have_pt_getxmmregs=yes],
1519                 [gdb_cv_have_pt_getxmmregs=no])])
1520 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
1521 if test $gdb_cv_have_pt_getxmmregs = yes; then
1522   AC_DEFINE(HAVE_PT_GETXMMREGS, 1,
1523   [Define if sys/ptrace.h defines the PT_GETXMMREGS request.])
1524 fi
1525
1526 # Detect which type of /proc is in use, such as for Solaris.
1527
1528 if test "${target}" = "${host}"; then
1529   case "${host}" in
1530   *-*-sysv4.2* | *-*-sysv5* )
1531       AC_DEFINE(NEW_PROC_API, 1,
1532       [Define if you want to use new multi-fd /proc interface.])
1533       ;;
1534   *-*-solaris2.[[6789]] | *-*-solaris2.1[[0-9]]*)
1535       AC_DEFINE(NEW_PROC_API, 1,
1536       [Define if you want to use new multi-fd /proc interface.])
1537       ;;
1538   mips-sgi-irix5*)
1539       # Work around <sys/proc.h> needing _KMEMUSER problem on IRIX 5.
1540       AC_DEFINE([_KMEMUSER], 1,
1541       [Define to 1 so <sys/proc.h> gets a definition of anon_hdl.  Works
1542        around a <sys/proc.h> problem on IRIX 5.])
1543       ;;
1544   esac
1545 fi
1546
1547 if test "$ac_cv_header_sys_procfs_h" = yes; then
1548   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
1549   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
1550   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
1551   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
1552   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
1553   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
1554   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
1555   BFD_HAVE_SYS_PROCFS_TYPE(prsysent_t)
1556   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigset_t)
1557   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigaction64_t)
1558   BFD_HAVE_SYS_PROCFS_TYPE(pr_siginfo64_t)
1559
1560
1561   dnl Check for broken prfpregset_t type
1562
1563   dnl For Linux/i386, glibc 2.1.3 was released with a bogus
1564   dnl prfpregset_t type (it's a typedef for the pointer to a struct
1565   dnl instead of the struct itself).  We detect this here, and work
1566   dnl around it in gdb_proc_service.h.
1567
1568   if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
1569     AC_MSG_CHECKING(whether prfpregset_t type is broken)
1570     AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
1571       [AC_TRY_RUN([#include <sys/procfs.h>
1572        int main ()
1573        {
1574          if (sizeof (prfpregset_t) == sizeof (void *))
1575            return 1;
1576          return 0;
1577        }],
1578        gdb_cv_prfpregset_t_broken=no,
1579        gdb_cv_prfpregset_t_broken=yes,
1580        gdb_cv_prfpregset_t_broken=yes)])
1581     AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
1582     if test $gdb_cv_prfpregset_t_broken = yes; then
1583       AC_DEFINE(PRFPREGSET_T_BROKEN, 1,
1584       [Define if the prfpregset_t type is broken.])
1585     fi
1586   fi
1587 fi
1588
1589 # Check if the compiler supports the `long long' type.
1590
1591 AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long,
1592                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1593 [[extern long long foo;]],
1594 [[switch (foo & 2) { case 0: return 1; }]])],
1595                                   gdb_cv_c_long_long=yes,
1596                                   gdb_cv_c_long_long=no)])
1597 if test $gdb_cv_c_long_long != yes; then
1598   # libdecnumber requires long long.
1599   AC_MSG_ERROR([Compiler must support long long for GDB.])
1600 fi
1601
1602 # Check if the compiler and runtime support printing long longs.
1603
1604 AC_CACHE_CHECK([for long long support in printf],
1605                gdb_cv_printf_has_long_long,
1606                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1607 [[char buf[32];
1608   long long l = 0;
1609   l = (l << 16) + 0x0123;
1610   l = (l << 16) + 0x4567;
1611   l = (l << 16) + 0x89ab;
1612   l = (l << 16) + 0xcdef;
1613   sprintf (buf, "0x%016llx", l);
1614   return (strcmp ("0x0123456789abcdef", buf));]])],
1615                               gdb_cv_printf_has_long_long=yes,
1616                               gdb_cv_printf_has_long_long=no,
1617                               gdb_cv_printf_has_long_long=no)])
1618 if test $gdb_cv_printf_has_long_long = yes; then
1619   AC_DEFINE(PRINTF_HAS_LONG_LONG, 1,
1620             [Define to 1 if the "%ll" format works to print long longs.])
1621 fi
1622
1623 # Check if the compiler and runtime support printing decfloats.
1624
1625 AC_CACHE_CHECK([for decfloat support in printf],
1626                gdb_cv_printf_has_decfloat,
1627                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1628 [[char buf[64];
1629   _Decimal32 d32 = 1.2345df;
1630   _Decimal64 d64 = 1.2345dd;
1631   _Decimal128 d128 = 1.2345dl;
1632   sprintf (buf, "Decimal32: %H\nDecimal64: %D\nDecimal128: %DD", d32, d64, d128);
1633   return (strcmp ("Decimal32: 1.2345\nDecimal64: 1.2345\nDecimal128: 1.2345", buf));]])],
1634                               gdb_cv_printf_has_decfloat=yes,
1635                               gdb_cv_printf_has_decfloat=no,
1636                               gdb_cv_printf_has_decfloat=no)])
1637 if test $gdb_cv_printf_has_decfloat = yes; then
1638   AC_DEFINE(PRINTF_HAS_DECFLOAT, 1,
1639             [Define to 1 if the "%H, %D and %DD" formats work to print decfloats.])
1640 fi
1641
1642 # Check if the compiler supports the `long double' type.  We can't use
1643 # AC_C_LONG_DOUBLE because that one does additional checks on the
1644 # constants defined in <float.h> that fail on some systems,
1645 # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6.
1646
1647 AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double,
1648                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])],
1649                                   gdb_cv_c_long_double=yes,
1650                                   gdb_cv_c_long_double=no)])
1651 if test $gdb_cv_c_long_double = yes; then
1652   AC_DEFINE(HAVE_LONG_DOUBLE, 1,
1653            [Define to 1 if the compiler supports long double.])
1654 fi
1655
1656 # Check if the compiler and runtime support printing long doubles.
1657
1658 AC_CACHE_CHECK([for long double support in printf],
1659                gdb_cv_printf_has_long_double,
1660                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1661 [[char buf[16];
1662   long double f = 3.141592653;
1663   sprintf (buf, "%Lg", f);
1664   return (strncmp ("3.14159", buf, 7));]])],
1665                               gdb_cv_printf_has_long_double=yes,
1666                               gdb_cv_printf_has_long_double=no,
1667                               gdb_cv_printf_has_long_double=no)])
1668 if test $gdb_cv_printf_has_long_double = yes; then
1669   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1,
1670             [Define to 1 if the "%Lg" format works to print long doubles.])
1671 fi
1672
1673 # Check if the compiler and runtime support scanning long doubles.
1674
1675 AC_CACHE_CHECK([for long double support in scanf],
1676                gdb_cv_scanf_has_long_double,
1677                [AC_RUN_IFELSE([AC_LANG_PROGRAM(
1678 [[#include <stdio.h>]],
1679 [[char *buf = "3.141592653";
1680   long double f = 0;
1681   sscanf (buf, "%Lg", &f);
1682   return !(f > 3.14159 && f < 3.14160);]])],
1683                               gdb_cv_scanf_has_long_double=yes,
1684                               gdb_cv_scanf_has_long_double=no,
1685                               gdb_cv_scanf_has_long_double=no)])
1686 if test $gdb_cv_scanf_has_long_double = yes; then
1687   AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1,
1688             [Define to 1 if the "%Lg" format works to scan long doubles.])
1689 fi
1690
1691 case ${host_os} in
1692 aix*)
1693   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1694     SAVE_LDFLAGS=$LDFLAGS
1695
1696     case $GCC in
1697     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1698     *) gdb_cv_bigtoc=-bbigtoc ;;
1699     esac
1700
1701     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1702     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1703     LDFLAGS="${SAVE_LDFLAGS}"
1704   ])
1705   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
1706   ;;
1707 esac
1708
1709 AC_MSG_CHECKING(for the dynamic export flag)
1710 dynamic_list=false
1711 if test "${gdb_native}" = yes; then
1712    # The dynamically loaded libthread_db needs access to symbols in the gdb
1713    # executable.  Older GNU ld supports --export-dynamic but --dynamic-list
1714    # may not be supported there.
1715    old_LDFLAGS="$LDFLAGS"
1716    # Older GNU ld supports --export-dynamic but --dynamic-list it does not.
1717    RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
1718    LDFLAGS="$LDFLAGS $RDYNAMIC"
1719    if test "${have_libpython}" = no; then
1720      AC_TRY_LINK([], [], [dynamic_list=true])
1721    else
1722      # Workaround http://bugs.python.org/issue4434 where static
1723      # libpythonX.Y.a would get its symbols required for
1724      # pythonX.Y/lib-dynload/*.so modules hidden by -Wl,--dynamic-list.
1725      # Problem does not happen for the recommended libpythonX.Y.so linkage.
1726      old_CFLAGS="$CFLAGS"
1727      CFLAGS="$CFLAGS $PYTHON_CFLAGS"
1728      old_LIBS="$LIBS"
1729      LIBS="$LIBS $PYTHON_LIBS"
1730      AC_RUN_IFELSE(
1731        AC_LANG_PROGRAM(
1732          [#include "]${have_libpython}[/Python.h"],
1733          [int err;
1734           Py_Initialize ();
1735           err = PyRun_SimpleString ("import itertools\n");
1736           Py_Finalize ();
1737           return err == 0 ? 0 : 1;]),
1738        [dynamic_list=true], [], [true])
1739      LIBS="$old_LIBS"
1740      CFLAGS="$old_CFLAGS"
1741    fi
1742    LDFLAGS="$old_LDFLAGS"
1743 fi
1744 if $dynamic_list; then
1745   found="-Wl,--dynamic-list"
1746   RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'
1747 else
1748   found="-rdynamic"
1749   RDYNAMIC="-rdynamic"
1750 fi
1751 AC_SUBST(RDYNAMIC)
1752 AC_MSG_RESULT($found)
1753
1754 dnl For certain native configurations, we need to check whether thread
1755 dnl support can be built in or not.
1756 dnl
1757 dnl Note that we only want this if we are both native (host == target),
1758 dnl and not doing a canadian cross build (build == host).
1759
1760 if test ${build} = ${host} -a ${host} = ${target} ; then
1761    case ${host_os} in
1762    solaris*)
1763       # See if thread_db library is around for Solaris thread debugging.
1764       # Note that we must explicitly test for version 1 of the library
1765       # because version 0 (present on Solaris 2.4 or earlier) doesn't have
1766       # the same API.
1767       AC_MSG_CHECKING(for Solaris thread debugging library)
1768       if test -f /usr/lib/libthread_db.so.1 ; then
1769          AC_MSG_RESULT(yes)
1770          AC_DEFINE(HAVE_THREAD_DB_LIB, 1,
1771          [Define if using Solaris thread debugging.])
1772          CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
1773          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
1774          AC_CHECK_LIB(dl, dlopen)
1775          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} $RDYNAMIC"
1776          # Sun randomly tweaked the prototypes in <proc_service.h>
1777          # at one point.
1778          AC_MSG_CHECKING(if <proc_service.h> is old)
1779          AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
1780             AC_TRY_COMPILE([
1781                 #include <proc_service.h>
1782                 ps_err_e ps_pdwrite
1783                     (struct ps_prochandle*, psaddr_t, const void*, size_t);
1784             ],, gdb_cv_proc_service_is_old=no,
1785                 gdb_cv_proc_service_is_old=yes)
1786          ])
1787          AC_MSG_RESULT($gdb_cv_proc_service_is_old)
1788          if test $gdb_cv_proc_service_is_old = yes; then
1789             AC_DEFINE(PROC_SERVICE_IS_OLD, 1,
1790             [Define if <proc_service.h> on solaris uses int instead of
1791              size_t, and assorted other type changes.])
1792          fi
1793       else
1794          AC_MSG_RESULT(no)
1795       fi
1796       ;;
1797    aix*)
1798       AC_MSG_CHECKING(for AiX thread debugging library)
1799       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
1800                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
1801                                    [#ifndef PTHDB_VERSION_3
1802                                     #error
1803                                     #endif],
1804                                    gdb_cv_have_aix_thread_debug=yes,
1805                                    gdb_cv_have_aix_thread_debug=no)])
1806       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1807       if test $gdb_cv_have_aix_thread_debug = yes; then
1808          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1809          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1810          LIBS="$LIBS -lpthdebug"
1811
1812          # Older versions of AIX do not provide the declaration for
1813          # the getthrds function (it appears that it was introduced
1814          # with AIX 6.x).
1815          AC_CHECK_DECLS(getthrds, [], [], [[#include <procinfo.h>]])
1816       fi
1817       ;;
1818    esac
1819    AC_SUBST(CONFIG_LDFLAGS)
1820 fi
1821
1822 dnl See if we have a thread_db header file that has TD_NOTALLOC and
1823 dnl other error codes.
1824 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1825    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
1826                   gdb_cv_thread_db_h_has_td_notalloc,
1827      AC_TRY_COMPILE(
1828        [#include <thread_db.h>],
1829        [int i = TD_NOTALLOC;],
1830        gdb_cv_thread_db_h_has_td_notalloc=yes,
1831        gdb_cv_thread_db_h_has_td_notalloc=no
1832      )
1833    )
1834    AC_CACHE_CHECK([whether <thread_db.h> has TD_VERSION],
1835                   gdb_cv_thread_db_h_has_td_version,
1836      AC_TRY_COMPILE(
1837        [#include <thread_db.h>],
1838        [int i = TD_VERSION;],
1839        gdb_cv_thread_db_h_has_td_version=yes,
1840        gdb_cv_thread_db_h_has_td_version=no
1841      )
1842    )
1843    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTLS],
1844                   gdb_cv_thread_db_h_has_td_notls,
1845      AC_TRY_COMPILE(
1846        [#include <thread_db.h>],
1847        [int i = TD_NOTLS;],
1848        gdb_cv_thread_db_h_has_td_notls=yes,
1849        gdb_cv_thread_db_h_has_td_notls=no
1850      )
1851    )
1852 fi
1853 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1854   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1855             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1856 fi
1857 if test "x$gdb_cv_thread_db_h_has_td_version" = "xyes"; then
1858   AC_DEFINE(THREAD_DB_HAS_TD_VERSION, 1,
1859             [Define if <thread_db.h> has the TD_VERSION error code.])
1860 fi
1861 if test "x$gdb_cv_thread_db_h_has_td_notls" = "xyes"; then
1862   AC_DEFINE(THREAD_DB_HAS_TD_NOTLS, 1,
1863             [Define if <thread_db.h> has the TD_NOTLS error code.])
1864 fi
1865
1866 dnl See if we have a sys/syscall header file that has __NR_tkill.
1867 if test "x$ac_cv_header_sys_syscall_h" = "xyes"; then
1868    AC_CACHE_CHECK([whether <sys/syscall.h> has __NR_tkill],
1869                   gdb_cv_sys_syscall_h_has_tkill,
1870      AC_TRY_COMPILE(
1871        [#include <sys/syscall.h>],
1872        [int i = __NR_tkill;],
1873        gdb_cv_sys_syscall_h_has_tkill=yes,
1874        gdb_cv_sys_syscall_h_has_tkill=no
1875      )
1876    )
1877 fi
1878 dnl See if we can issue tkill syscall.
1879 if test "x$gdb_cv_sys_syscall_h_has_tkill" = "xyes"; then
1880   AC_CHECK_FUNC(syscall,
1881     AC_DEFINE(HAVE_TKILL_SYSCALL, 1, [Define if you support the tkill syscall.])
1882   )
1883 fi
1884
1885 dnl Check if we can disable the virtual address space randomization.
1886 dnl The functionality of setarch -R.
1887 AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>])
1888 define([PERSONALITY_TEST], [AC_LANG_PROGRAM([#include <sys/personality.h>], [
1889 #      if !HAVE_DECL_ADDR_NO_RANDOMIZE
1890 #       define ADDR_NO_RANDOMIZE 0x0040000
1891 #      endif
1892        /* Test the flag could be set and stays set.  */
1893        personality (personality (0xffffffff) | ADDR_NO_RANDOMIZE);
1894        if (!(personality (personality (0xffffffff)) & ADDR_NO_RANDOMIZE))
1895            return 1])])
1896 AC_RUN_IFELSE([PERSONALITY_TEST],
1897               [have_personality=true],
1898               [have_personality=false],
1899               [AC_LINK_IFELSE([PERSONALITY_TEST],
1900                               [have_personality=true],
1901                               [have_personality=false])])
1902 if $have_personality
1903 then
1904     AC_DEFINE([HAVE_PERSONALITY], 1,
1905               [Define if you support the personality syscall.])
1906 fi
1907
1908 dnl Set the host's .gdbinit filename.
1909 case $host_os in
1910   go32* | *djgpp*)
1911     gdbinit=gdb.ini
1912     ;;
1913   *)
1914     gdbinit=.gdbinit
1915     ;;
1916 esac
1917 AC_DEFINE_UNQUOTED(GDBINIT,"$gdbinit",[The .gdbinit filename.])
1918
1919 dnl Handle optional features that can be enabled.
1920
1921 # Support for --with-sysroot is a copy of GDB_AC_WITH_DIR,
1922 # except that the argument to --with-sysroot is optional.
1923 # --with-sysroot (or --with-sysroot=yes) sets the default sysroot path.
1924 if test "x$with_sysroot" = xyes; then
1925   with_sysroot="${exec_prefix}/${target_alias}/sys-root"
1926 fi
1927 AC_ARG_WITH(sysroot,
1928   AS_HELP_STRING([--with-sysroot@<:@=DIR@:>@],
1929                  [search for usr/lib et al within DIR]),
1930   [TARGET_SYSTEM_ROOT=$withval], [TARGET_SYSTEM_ROOT=])
1931 AC_DEFINE_DIR(TARGET_SYSTEM_ROOT, TARGET_SYSTEM_ROOT,
1932               [search for usr/lib et al within DIR])
1933 AC_SUBST(TARGET_SYSTEM_ROOT)
1934 GDB_AC_DEFINE_RELOCATABLE(TARGET_SYSTEM_ROOT, sysroot, ${ac_define_dir})
1935
1936 GDB_AC_WITH_DIR(SYSTEM_GDBINIT, system-gdbinit,
1937     [automatically load a system-wide gdbinit file],
1938     [])
1939
1940 AC_ARG_ENABLE(werror,
1941   AS_HELP_STRING([--enable-werror], [treat compile warnings as errors]),
1942   [case "${enableval}" in
1943      yes | y) ERROR_ON_WARNING="yes" ;;
1944      no | n)  ERROR_ON_WARNING="no" ;;
1945      *) AC_MSG_ERROR(bad value ${enableval} for --enable-werror) ;;
1946    esac])
1947
1948 # Enable -Werror by default when using gcc.  Turn it off for releases.
1949 if test "${GCC}" = yes -a -z "${ERROR_ON_WARNING}" && $development; then
1950     ERROR_ON_WARNING=yes
1951 fi
1952
1953 WERROR_CFLAGS=""
1954 if test "${ERROR_ON_WARNING}" = yes ; then
1955     WERROR_CFLAGS="-Werror"
1956 fi
1957
1958 build_warnings="-Wall -Wdeclaration-after-statement -Wpointer-arith \
1959 -Wpointer-sign \
1960 -Wno-unused -Wunused-value -Wunused-function \
1961 -Wno-switch -Wno-char-subscripts -Wmissing-prototypes \
1962 -Wdeclaration-after-statement -Wempty-body -Wmissing-parameter-type \
1963 -Wold-style-declaration -Wold-style-definition"
1964
1965 # Enable -Wno-format by default when using gcc on mingw since many
1966 # GCC versions complain about %I64.
1967 case "${host}" in
1968   *-*-mingw32*) build_warnings="$build_warnings -Wno-format" ;;
1969   *) build_warnings="$build_warnings -Wformat-nonliteral" ;;
1970 esac
1971
1972 AC_ARG_ENABLE(build-warnings,
1973 AS_HELP_STRING([--enable-build-warnings], [enable build-time compiler warnings if gcc is used]),
1974 [case "${enableval}" in
1975   yes)  ;;
1976   no)   build_warnings="-w";;
1977   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1978         build_warnings="${build_warnings} ${t}";;
1979   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1980         build_warnings="${t} ${build_warnings}";;
1981   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1982 esac
1983 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1984   echo "Setting compiler warning flags = $build_warnings" 6>&1
1985 fi])dnl
1986 AC_ARG_ENABLE(gdb-build-warnings,
1987 AS_HELP_STRING([--enable-gdb-build-warnings], [enable GDB specific build-time compiler warnings if gcc is used]),
1988 [case "${enableval}" in
1989   yes)  ;;
1990   no)   build_warnings="-w";;
1991   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1992         build_warnings="${build_warnings} ${t}";;
1993   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1994         build_warnings="${t} ${build_warnings}";;
1995   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1996 esac
1997 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1998   echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1
1999 fi])dnl
2000 WARN_CFLAGS=""
2001 if test "x${build_warnings}" != x -a "x$GCC" = xyes
2002 then
2003     AC_MSG_CHECKING(compiler warning flags)
2004     # Separate out the -Werror flag as some files just cannot be
2005     # compiled with it enabled.
2006     for w in ${build_warnings}; do
2007         case $w in
2008         -Werr*) WERROR_CFLAGS=-Werror ;;
2009         *) # Check that GCC accepts it
2010             saved_CFLAGS="$CFLAGS"
2011             CFLAGS="$CFLAGS $w"
2012             AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
2013             CFLAGS="$saved_CFLAGS"
2014         esac
2015     done
2016     AC_MSG_RESULT(${WARN_CFLAGS} ${WERROR_CFLAGS})
2017 fi
2018 AC_SUBST(WARN_CFLAGS)
2019 AC_SUBST(WERROR_CFLAGS)
2020
2021 # In the Cygwin environment, we need some additional flags.
2022 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
2023 [AC_EGREP_CPP(^lose$, [
2024 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
2025 lose
2026 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
2027
2028
2029 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
2030 SER_HARDWIRE="ser-base.o ser-unix.o ser-pipe.o ser-tcp.o"
2031 case ${host} in
2032   *go32* ) SER_HARDWIRE=ser-go32.o ;;
2033   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
2034   *mingw32*) SER_HARDWIRE="ser-base.o ser-tcp.o ser-mingw.o" ;;
2035 esac
2036 AC_SUBST(SER_HARDWIRE)
2037
2038 # libreadline needs libuser32.a in a cygwin environment
2039 WIN32LIBS=
2040 if test x$gdb_cv_os_cygwin = xyes; then
2041     WIN32LIBS="-luser32"
2042     case "${target}" in
2043         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
2044         ;;
2045     esac
2046 fi
2047
2048 # The ser-tcp.c module requires sockets.
2049 case ${host} in
2050   *mingw32*)
2051     AC_DEFINE(USE_WIN32API, 1,
2052               [Define if we should use the Windows API, instead of the
2053                POSIX API.  On Windows, we use the Windows API when
2054                building for MinGW, but the POSIX API when building
2055                for Cygwin.])
2056     WIN32LIBS="$WIN32LIBS -lws2_32"
2057     ;;
2058 esac
2059 AC_SUBST(WIN32LIBS)
2060
2061 # Add ELF support to GDB, but only if BFD includes ELF support.
2062 GDB_AC_CHECK_BFD([for ELF support in BFD], gdb_cv_var_elf,
2063                  [bfd_get_elf_phdr_upper_bound (NULL)], elf-bfd.h)
2064 if test $gdb_cv_var_elf = yes; then
2065   CONFIG_OBS="$CONFIG_OBS elfread.o stap-probe.o"
2066   AC_DEFINE(HAVE_ELF, 1,
2067             [Define if ELF support should be included.])
2068   # -ldl is provided by bfd/Makfile.am (LIBDL) <PLUGINS>.
2069   if test "$plugins" = "yes"; then
2070     AC_SEARCH_LIBS(dlopen, dl)
2071   fi
2072 fi
2073
2074 # Add macho support to GDB, but only if BFD includes it.
2075 GDB_AC_CHECK_BFD([for Mach-O support in BFD], gdb_cv_var_macho,
2076                  [bfd_mach_o_lookup_command (NULL, 0, NULL)], mach-o.h)
2077 if test $gdb_cv_var_macho = yes; then
2078   CONFIG_OBS="$CONFIG_OBS machoread.o"
2079 fi
2080
2081 # Add SOM support to GDB, but only if BFD includes it.
2082 GDB_AC_CHECK_BFD([for SOM support in BFD], gdb_cv_var_som,
2083                  [bfd_som_attach_aux_hdr (NULL, 0, NULL)], som.h)
2084 if test $gdb_cv_var_som = yes; then
2085   CONFIG_OBS="$CONFIG_OBS somread.o"
2086 fi
2087
2088 # Add any host-specific objects to GDB.
2089 CONFIG_OBS="${CONFIG_OBS} ${gdb_host_obs}"
2090
2091 # If building on ELF, look for lzma support for embedded compressed debug info.
2092 if test $gdb_cv_var_elf = yes; then
2093   AC_ARG_WITH(lzma,
2094     AS_HELP_STRING([--with-lzma], [support lzma compression (auto/yes/no)]),
2095     [], [with_lzma=auto])
2096   AC_MSG_CHECKING([whether to use lzma])
2097   AC_MSG_RESULT([$with_lzma])
2098
2099   if test "${with_lzma}" != no; then
2100     AC_LIB_HAVE_LINKFLAGS([lzma], [], [#include "lzma.h"],
2101                           [lzma_index_iter iter;
2102                            lzma_index_iter_init (&iter, 0);
2103                            lzma_mf_is_supported (LZMA_MF_HC3);])
2104     if test "$HAVE_LIBLZMA" != yes; then
2105       if test "$with_lzma" = yes; then
2106         AC_MSG_ERROR([missing liblzma for --with-lzma])
2107       fi
2108     fi
2109   fi
2110 fi
2111
2112 LIBGUI="../libgui/src/libgui.a"
2113 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
2114 AC_SUBST(LIBGUI)
2115 AC_SUBST(GUI_CFLAGS_X)
2116
2117 WIN32LDAPP=
2118 AC_SUBST(WIN32LIBS)
2119 AC_SUBST(WIN32LDAPP)
2120
2121 case "${host}" in
2122 *-*-cygwin* | *-*-mingw* )
2123     configdir="win"
2124     ;;
2125 *)
2126     configdir="unix"
2127     ;;
2128 esac
2129
2130 GDBTKLIBS=
2131 if test "${enable_gdbtk}" = "yes"; then
2132
2133     # Gdbtk must have an absolute path to srcdir in order to run
2134     # properly when not installed.
2135     here=`pwd`
2136     cd ${srcdir}
2137     GDBTK_SRC_DIR=`pwd`
2138     cd $here
2139
2140     SC_PATH_TCLCONFIG
2141
2142     # If $no_tk is nonempty, then we can't do Tk, and there is no
2143     # point to doing Tcl.
2144     SC_PATH_TKCONFIG
2145
2146     if test -z "${no_tcl}" -a -z "${no_tk}"; then
2147         SC_LOAD_TCLCONFIG
2148
2149         # Check for in-tree tcl
2150         here=`pwd`
2151         cd ${srcdir}/..
2152         topdir=`pwd`
2153         cd ${here}
2154
2155         intree="no"
2156         if test "${TCL_SRC_DIR}" = "${topdir}/tcl"; then
2157           intree="yes"
2158         fi
2159
2160         # Find Tcl private headers
2161         if test x"${intree}" = xno; then
2162           CY_AC_TCL_PRIVATE_HEADERS
2163           TCL_INCLUDE="${TCL_INCLUDE_SPEC} ${TCL_PRIVATE_INCLUDE}"
2164           TCL_LIBRARY="${TCL_LIB_SPEC}"
2165           TCL_DEPS=""
2166         else
2167           # If building tcl in the same src tree, private headers
2168           # are not needed, but we need to be sure to use the right
2169           # headers library
2170           TCL_INCLUDE="-I${TCL_SRC_DIR}/generic"
2171           TCL_LIBRARY="${TCL_BUILD_LIB_SPEC}"
2172           TCL_DEPS="../tcl/${configdir}${TCL_LIB_FILE}"
2173         fi
2174         AC_SUBST(TCL_INCLUDE)
2175         AC_SUBST(TCL_LIBRARY)
2176         AC_SUBST(TCL_DEPS)
2177
2178         SC_LOAD_TKCONFIG
2179
2180         # Check for in-tree Tk
2181         intree="no"
2182         if test "${TK_SRC_DIR}" = "${topdir}/tk"; then
2183           intree="yes"
2184         fi
2185
2186         # Find Tk private headers
2187         if test x"${intree}" = xno; then
2188           CY_AC_TK_PRIVATE_HEADERS
2189           TK_INCLUDE="${TK_INCLUDE_SPEC} ${TK_PRIVATE_INCLUDE}"
2190           TK_LIBRARY=${TK_LIB_SPEC}
2191           TK_DEPS=""
2192         else
2193           TK_INCLUDE="-I${TK_SRC_DIR}/generic"
2194           TK_LIBRARY="${TK_BUILD_LIB_SPEC}"
2195           TK_DEPS="../tk/${configdir}/${TK_LIB_FILE}"
2196         fi
2197         AC_SUBST(TK_INCLUDE)
2198         AC_SUBST(TK_LIBRARY)
2199         AC_SUBST(TK_DEPS)
2200         AC_SUBST(TK_XINCLUDES)
2201
2202         ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
2203
2204         # Include some libraries that Tcl and Tk want.
2205         TCL_LIBS='$(LIBGUI) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
2206         # Yes, the ordering seems wrong here.  But it isn't.
2207         # TK_LIBS is the list of libraries that need to be linked
2208         # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
2209         # were in LIBS then any link tests after this point would
2210         # try to include things like `$(LIBGUI)', which wouldn't work.
2211         GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
2212
2213         CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
2214         CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
2215         CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
2216         CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
2217         CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
2218         CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
2219         CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
2220
2221         if test x$gdb_cv_os_cygwin = xyes; then
2222           WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
2223           WIN32LDAPP="-Wl,--subsystem,console"
2224           CONFIG_OBS="${CONFIG_OBS} gdbres.o"
2225         fi
2226
2227         AC_CONFIG_SUBDIRS(gdbtk)
2228     fi
2229 fi
2230
2231 AC_SUBST(X_CFLAGS)
2232 AC_SUBST(X_LDFLAGS)
2233 AC_SUBST(X_LIBS)
2234 AC_SUBST(GDBTKLIBS)
2235 AC_SUBST(GDBTK_CFLAGS)
2236 AC_SUBST(GDBTK_SRC_DIR)
2237
2238 AC_PATH_X
2239
2240 # Unlike the sim directory, whether a simulator is linked is controlled by
2241 # presence of a gdb_sim definition in the target configure.tgt entry.
2242 # This code just checks for a few cases where we'd like to ignore those
2243 # definitions, even when they're present in the '.mt' file.  These cases
2244 # are when --disable-sim is specified, or if the simulator directory is
2245 # not part of the source tree.
2246 #
2247 AC_ARG_ENABLE(sim,
2248 AS_HELP_STRING([--enable-sim], [link gdb with simulator]),
2249 [echo "enable_sim = $enable_sim";
2250  echo "enableval = ${enableval}";
2251  case "${enableval}" in
2252   yes) ignore_sim=false ;;
2253   no)  ignore_sim=true ;;
2254   *)   ignore_sim=false ;;
2255  esac],
2256 [ignore_sim=false])
2257
2258 if test ! -d "${srcdir}/../sim"; then
2259   ignore_sim=true
2260 fi
2261
2262 SIM=
2263 SIM_OBS=
2264 if test "${ignore_sim}" = "false"; then
2265   if test x"${gdb_sim}" != x ; then
2266     SIM="${gdb_sim}"
2267     SIM_OBS="remote-sim.o"
2268     AC_DEFINE(WITH_SIM, 1, [Define if the simulator is being linked in.])
2269   fi
2270 fi
2271 AC_SUBST(SIM)
2272 AC_SUBST(SIM_OBS)
2273
2274 AC_SUBST(ENABLE_CFLAGS)
2275 AC_SUBST(PROFILE_CFLAGS)
2276
2277 AC_SUBST(CONFIG_OBS)
2278 AC_SUBST(CONFIG_DEPS)
2279 AC_SUBST(CONFIG_SRCS)
2280 AC_SUBST(CONFIG_ALL)
2281 AC_SUBST(CONFIG_CLEAN)
2282 AC_SUBST(CONFIG_INSTALL)
2283 AC_SUBST(CONFIG_UNINSTALL)
2284
2285 # List of host floatformats.
2286 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
2287 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
2288 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
2289
2290 # target_subdir is used by the testsuite to find the target libraries.
2291 target_subdir=
2292 if test "${host}" != "${target}"; then
2293     target_subdir="${target_alias}/"
2294 fi
2295 AC_SUBST(target_subdir)
2296
2297 frags=
2298 if test "${gdb_native}" = "yes"; then
2299   host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
2300   if test ! -f ${host_makefile_frag}; then
2301     AC_MSG_ERROR("*** Gdb does not support native target ${host}")
2302   fi
2303   frags="$frags $host_makefile_frag"
2304 else
2305   host_makefile_frag=/dev/null
2306 fi
2307
2308 AC_SUBST_FILE(host_makefile_frag)
2309 AC_SUBST(frags)
2310
2311 changequote(,)dnl
2312 if test "${gdb_native}" = "yes"; then
2313 # We pick this up from the host configuration file (.mh) because we
2314 # do not have a native configuration Makefile fragment.
2315 nativefile=`sed -n '
2316 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
2317 ' ${host_makefile_frag}`
2318 fi
2319 changequote([,])
2320
2321 if test x"${gdb_osabi}" != x ; then
2322     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
2323                        [Define to the default OS ABI for this configuration.])
2324 fi
2325
2326 # Enable multi-ice-gdb-server.
2327 AC_ARG_ENABLE(multi-ice,
2328 AS_HELP_STRING([--enable-multi-ice], [build the multi-ice-gdb-server]),
2329   [case $enableval in
2330     yes | no)
2331       ;;
2332     *) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;;
2333   esac])
2334 if test "x$enable_multi_ice" = xyes; then
2335    AC_CONFIG_SUBDIRS(multi-ice)
2336 fi
2337
2338 AC_ARG_ENABLE(gdbserver,
2339 AS_HELP_STRING([--enable-gdbserver],
2340                [automatically build gdbserver (yes/no/auto, default is auto)]),
2341 [case "${enableval}" in
2342   yes| no|auto) ;;
2343   *) AC_MSG_ERROR(bad value ${enableval} for --enable-gdbserver option) ;;
2344 esac],[enable_gdbserver=auto])
2345
2346 # We only build gdbserver automatically in a native configuration, and
2347 # only if the user did not explicitly disable its build.
2348 if test "$gdb_native" = "yes" -a "$enable_gdbserver" != "no"; then
2349   AC_MSG_CHECKING(whether gdbserver is supported on this host)
2350   if test "x$build_gdbserver" = xyes; then
2351     AC_MSG_RESULT(yes)
2352     AC_CONFIG_SUBDIRS(gdbserver)
2353     gdbserver_build_enabled=yes
2354   else
2355     AC_MSG_RESULT(no)
2356   fi
2357 fi
2358
2359 # If the user explicitly request the gdbserver to be built, verify that
2360 # we were in fact able to enable it.
2361 if test "$enable_gdbserver" = "yes" -a "$gdbserver_build_enabled" != "yes"; then
2362   AC_MSG_ERROR(Automatic gdbserver build is not supported for this configuration)
2363 fi
2364
2365 # Check for babeltrace and babeltrace-ctf
2366 AC_ARG_WITH(babeltrace,
2367   AC_HELP_STRING([--with-babeltrace], [include babeltrace support (auto/yes/no)]),
2368   [], [with_babeltrace=auto])
2369 AC_MSG_CHECKING([whether to use babeltrace])
2370 AC_MSG_RESULT([$with_babeltrace])
2371
2372 if test "x$with_babeltrace" = "xno"; then
2373   AC_MSG_WARN([babletrace support disabled; GDB is unable to read CTF data.])
2374 else
2375   # Append -Werror to CFLAGS so that configure can catch the warning
2376   # "assignment from incompatible pointer type", which is related to
2377   # the babeltrace change from 1.0.3 to 1.1.0.  Babeltrace 1.1.0 works
2378   # in GDB, while babeltrace 1.0.3 is broken.
2379   # AC_LIB_HAVE_LINKFLAGS may modify CPPFLAGS in it, so it should be
2380   # safe to save and restore CFLAGS here.
2381   saved_CFLAGS=$CFLAGS
2382   CFLAGS="$CFLAGS -Werror"
2383   AC_LIB_HAVE_LINKFLAGS([babeltrace], [babeltrace-ctf],
2384                         [#include <babeltrace/babeltrace.h>
2385                          #include <babeltrace/ctf/events.h>
2386                          #include <babeltrace/ctf/iterator.h>],
2387                         [struct bt_iter_pos *pos = bt_iter_get_pos (bt_ctf_get_iter (NULL));
2388                         struct bt_ctf_event *event = NULL;
2389                         const struct bt_definition *scope;
2390
2391                         bt_iter_set_pos (bt_ctf_get_iter (NULL), pos);
2392                         scope = bt_ctf_get_top_level_scope (event,
2393                                                            BT_STREAM_EVENT_HEADER);
2394                         bt_ctf_get_uint64 (bt_ctf_get_field (event, scope, "id"));
2395                         ])
2396   CFLAGS=$saved_CFLAGS
2397
2398   if test "$HAVE_LIBBABELTRACE" != yes; then
2399      if test "$with_babeltrace" = yes; then
2400        AC_MSG_ERROR([babeltrace is missing or unusable])
2401      else
2402        AC_MSG_WARN([babeltrace is missing or unusable; GDB is unable to read CTF data.])
2403      fi
2404   fi
2405 fi
2406
2407 # If nativefile (NAT_FILE) is not set in config/*/*.m[ht] files, we link
2408 # to an empty version.
2409
2410 files=
2411 links=
2412
2413 rm -f nm.h
2414 if test "${nativefile}" != ""; then
2415     case "${nativefile}" in
2416       nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
2417       * ) GDB_NM_FILE="${nativefile}"
2418     esac
2419     files="${files} ${GDB_NM_FILE}"
2420     links="${links} nm.h"
2421     AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}", [nativefile])
2422 fi
2423 AC_SUBST(GDB_NM_FILE)
2424
2425 AC_LINK_FILES($files, $links)
2426
2427 dnl Check for exe extension set on certain hosts (e.g. Win32)
2428 AC_EXEEXT
2429
2430 dnl  Detect the character set used by this host.
2431 dnl  At the moment, we just assume it's UTF-8.
2432 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "UTF-8",
2433           [Define to be a string naming the default host character set.])
2434
2435 # Undo the $ec_script escaping suitable for Makefile.
2436 transform=`echo "$program_transform_name" | sed -e 's/[\\$][\\$]/\\$/g'`
2437 GDB_TRANSFORM_NAME=`echo gdb | sed -e "$transform"`
2438 if test "x$GDB_TRANSFORM_NAME" = x; then
2439   GDB_TRANSFORM_NAME=gdb
2440 fi
2441 AC_SUBST(GDB_TRANSFORM_NAME)
2442 GCORE_TRANSFORM_NAME=`echo gcore | sed -e "$transform"`
2443 if test "x$GCORE_TRANSFORM_NAME" = x; then
2444   GCORE_TRANSFORM_NAME=gcore
2445 fi
2446 AC_SUBST(GCORE_TRANSFORM_NAME)
2447 AC_CONFIG_FILES([gcore], [chmod +x gcore])
2448
2449 AC_OUTPUT(Makefile gdb-gdb.gdb doc/Makefile data-directory/Makefile,
2450 [
2451 case x$CONFIG_HEADERS in
2452 xconfig.h:config.in)
2453 echo > stamp-h ;;
2454 esac
2455 ])
2456
2457 exit 0