gdb/configure.ac

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995-2012 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Process this file with autoconf to produce a configure script.
  20
  21 AC_PREREQ(2.59)dnl
  22 AC_INIT(main.c)
  23 AC_CONFIG_HEADER(config.h:config.in)
  24 AM_MAINTAINER_MODE
  25
  26 # Provide more thorough testing by -lmcheck.
  27 # Set it to 'true' for development snapshots, 'false' for releases or
  28 # pre-releases.
  29 development=true
  30
  31 AC_PROG_CC
  32 AC_USE_SYSTEM_EXTENSIONS
  33 ACX_LARGEFILE
  34 AM_PROG_CC_STDC
  35
  36 AC_CONFIG_AUX_DIR(..)
  37 AC_CANONICAL_SYSTEM
  38 AC_ARG_PROGRAM
  39
  40 # Dependency checking.
  41 ZW_CREATE_DEPDIR
  42 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  43
  44 # Check for the 'make' the user wants to use.
  45 AC_CHECK_PROGS(MAKE, make)
  46 MAKE_IS_GNU=
  47 case "`$MAKE --version 2>&1 | sed 1q`" in
  48   *GNU*)
  49     MAKE_IS_GNU=yes
  50     ;;
  51 esac
  52 AM_CONDITIONAL(GMAKE, test "$MAKE_IS_GNU" = yes)
  53 AC_PROG_MAKE_SET
  54
  55 # Configure gnulib.  We need to build gnulib under some other
  56 # directory not "gnulib", to avoid the problem of both GDB and
  57 # GDBserver wanting to build it in the same directory, when building
  58 # in the source dir.
  59 ACX_CONFIGURE_DIR(["gnulib"], ["build-gnulib"])
  60
  61 dnl List of object files and targets accumulated by configure.
  62
  63 CONFIG_OBS=
  64 CONFIG_DEPS=
  65 CONFIG_SRCS=
  66 ENABLE_CFLAGS=
  67
  68 CONFIG_ALL=
  69 CONFIG_CLEAN=
  70 CONFIG_INSTALL=
  71 CONFIG_UNINSTALL=
  72
  73 dnl Set up for gettext.
  74 ZW_GNU_GETTEXT_SISTER_DIR
  75
  76 localedir='${datadir}/locale'
  77 AC_SUBST(localedir)
  78
  79 if test x"$USE_NLS" = xyes; then
  80    CONFIG_ALL="$CONFIG_ALL all-po"
  81    CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
  82    CONFIG_INSTALL="$CONFIG_INSTALL install-po"
  83    CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
  84 fi
  85
  86 GNULIB=build-gnulib/import
  87
  88 # For Makefile dependencies.
  89 GNULIB_STDINT_H=
  90 if test x"$STDINT_H" != x; then
  91   GNULIB_STDINT_H=$GNULIB/$STDINT_H
  92 fi
  93 AC_SUBST(GNULIB_STDINT_H)
  94
  95 PACKAGE=gdb
  96 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
  97 AC_SUBST(PACKAGE)
  98
  99 # We never need to detect it in this sub-configure.
 100 # But preserve it for config.status --recheck.
 101 AC_ARG_VAR(MAKEINFO,
 102   [Parent configure detects if it is of sufficient version.])
 103 AC_ARG_VAR(MAKEINFOFLAGS,
 104   [Parameters for MAKEINFO.])
 105
 106 MAKEINFO_EXTRA_FLAGS=""
 107 AC_CACHE_CHECK([whether $MAKEINFO supports @click], gdb_cv_have_makeinfo_click,
 108   [echo '@clicksequence{a @click{} b}' >conftest.texinfo
 109   if eval "$MAKEINFO conftest.texinfo >&5 2>&5"; then
 110     gdb_cv_have_makeinfo_click=yes
 111   else
 112     gdb_cv_have_makeinfo_click=no
 113   fi])
 114 if test x"$gdb_cv_have_makeinfo_click" = xyes; then
 115   MAKEINFO_EXTRA_FLAGS="$MAKEINFO_EXTRA_FLAGS -DHAVE_MAKEINFO_CLICK"
 116 fi
 117 AC_SUBST(MAKEINFO_EXTRA_FLAGS)
 118
 119 GDB_AC_WITH_DIR(DEBUGDIR, separate-debug-dir,
 120     [look for global separate debug info in this path @<:@LIBDIR/debug@:>@],
 121     [${libdir}/debug])
 122
 123 # We can't pass paths as command line arguments.
 124 # Mingw32 tries to be clever and will convert the paths for us.
 125 # For example -DBINDIR="/usr/local/bin" passed on the command line may get
 126 # converted to -DBINDIR="E:/msys/mingw32/msys/1.0/local/bin".
 127 # This breaks GDB's relocatable path conversions since paths passed in
 128 # config.h would not get so translated, the path prefixes no longer match.
 129 AC_DEFINE_DIR(BINDIR, bindir, [Directory of programs.])
 130
 131 # GDB's datadir relocation
 132
 133 GDB_AC_WITH_DIR(GDB_DATADIR, gdb-datadir,
 134     [look for global separate data files in this path @<:@DATADIR/gdb@:>@],
 135     [${datadir}/gdb])
 136
 137 AC_ARG_WITH(relocated-sources,
 138 AS_HELP_STRING([--with-relocated-sources=PATH], [automatically relocate this path for source files]),
 139 [reloc_srcdir="${withval}"
 140  AC_DEFINE_DIR(RELOC_SRCDIR, reloc_srcdir,
 141               [Relocated directory for source files. ])
 142 ])
 143
 144 AC_MSG_CHECKING([for default auto-load directory])
 145 AC_ARG_WITH(auto-load-dir,
 146 AS_HELP_STRING([--with-auto-load-dir=PATH],
 147   [directories from which to load auto-loaded scripts @<:@$debugdir:$datadir/auto-load@:>@]),,
 148   [with_auto_load_dir='$debugdir:$datadir/auto-load'])
 149 escape_dir=`echo $with_auto_load_dir | sed 's/[[$]]\(datadir\|debugdir\)\>/\\\\\\\\\\\\&/g'`
 150 AC_DEFINE_DIR(AUTO_LOAD_DIR, escape_dir,
 151               [Directories from which to load auto-loaded scripts.])
 152 AC_MSG_RESULT([$with_auto_load_dir])
 153
 154 AC_MSG_CHECKING([for default auto-load safe-path])
 155 AC_ARG_WITH(auto-load-safe-path,
 156 AS_HELP_STRING([--with-auto-load-safe-path=PATH],
 157   [directories safe to hold auto-loaded files @<:@--with-auto-load-dir@:>@])
 158 AS_HELP_STRING([--without-auto-load-safe-path],
 159                [do not restrict auto-loaded files locations]),
 160     [if test "$with_auto_load_safe_path" = "no"; then
 161      with_auto_load_safe_path="/"
 162      fi],
 163 [with_auto_load_safe_path="$with_auto_load_dir"])
 164 escape_dir=`echo $with_auto_load_safe_path | sed 's/[[$]]\(datadir\|debugdir\)\>/\\\\\\\\\\\\&/g'`
 165 AC_DEFINE_DIR(AUTO_LOAD_SAFE_PATH, escape_dir,
 166               [Directories safe to hold auto-loaded files.])
 167 AC_MSG_RESULT([$with_auto_load_safe_path])
 168
 169 AC_CONFIG_SUBDIRS(testsuite)
 170
 171 # Check whether to support alternative target configurations
 172 AC_ARG_ENABLE(targets,
 173 AS_HELP_STRING([--enable-targets=TARGETS], [alternative target configurations]),
 174 [case "${enableval}" in
 175   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
 176             ;;
 177   no)       enable_targets= ;;
 178   *)        enable_targets=$enableval ;;
 179 esac])
 180
 181 # Check whether to enable 64-bit support on 32-bit hosts
 182 AC_ARG_ENABLE(64-bit-bfd,
 183 AS_HELP_STRING([--enable-64-bit-bfd], [64-bit support (on hosts with narrower word sizes)]),
 184 [case "${enableval}" in
 185   yes)  want64=true  ;;
 186   no)   want64=false ;;
 187   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
 188 esac],[want64=false])dnl
 189
 190 # Provide defaults for some variables set by the per-host and per-target
 191 # configuration.
 192 gdb_host_obs=posix-hdep.o
 193
 194 if test "${target}" = "${host}"; then
 195   gdb_native=yes
 196 else
 197   gdb_native=no
 198 fi
 199
 200 . $srcdir/configure.host
 201
 202 # Accumulate some settings from configure.tgt over all enabled targets
 203
 204 TARGET_OBS=
 205 all_targets=
 206
 207 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 208 do
 209   if test "$targ_alias" = "all"; then
 210     all_targets=true
 211   else
 212     # Canonicalize the secondary target names.
 213     result=`$ac_config_sub $targ_alias 2>/dev/null`
 214     if test -n "$result"; then
 215         targ=$result
 216     else
 217         targ=$targ_alias
 218     fi
 219
 220     . ${srcdir}/configure.tgt
 221
 222     AS_IF([test -z "${gdb_target_obs}"],
 223       [AC_MSG_ERROR([configuration ${targ} is unsupported.])])
 224
 225     # Target-specific object files
 226     for i in ${gdb_target_obs}; do
 227         case " $TARGET_OBS " in
 228         *" ${i} "*) ;;
 229         *)
 230           TARGET_OBS="$TARGET_OBS ${i}"
 231           ;;
 232         esac
 233     done
 234
 235     # Check whether this target needs 64-bit CORE_ADDR
 236     if test x${want64} = xfalse; then
 237       . ${srcdir}/../bfd/config.bfd
 238     fi
 239   fi
 240 done
 241
 242 if test x${all_targets} = xtrue; then
 243
 244   # We want all 64-bit targets if we either:
 245   #  - run on a 64-bit host  or
 246   #  - already require 64-bit support for some other target  or
 247   #  - the --enable-64-bit-bfd option was supplied
 248   # Otherwise we only support all 32-bit targets.
 249   #
 250   # NOTE: This test must be in sync with the corresponding
 251   #       tests in BFD!
 252
 253   if test x${want64} = xfalse; then
 254     AC_CHECK_SIZEOF(long)
 255     if test "x${ac_cv_sizeof_long}" = "x8"; then
 256       want64=true
 257     fi
 258   fi
 259   if test x${want64} = xtrue; then
 260     TARGET_OBS='$(ALL_TARGET_OBS) $(ALL_64_TARGET_OBS)'
 261   else
 262     TARGET_OBS='$(ALL_TARGET_OBS)'
 263   fi
 264 fi
 265
 266 AC_SUBST(TARGET_OBS)
 267
 268 # For other settings, only the main target counts.
 269 gdb_sim=
 270 gdb_osabi=
 271 build_gdbserver=
 272 targ=$target; . ${srcdir}/configure.tgt
 273
 274 # Fetch the default architecture and default target vector from BFD.
 275 targ=$target; . $srcdir/../bfd/config.bfd
 276
 277 # We only want the first architecture, so strip off the others if
 278 # there is more than one.
 279 targ_archs=`echo $targ_archs | sed 's/ .*//'`
 280
 281 if test "x$targ_archs" != x; then
 282   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
 283     [Define to BFD's default architecture. ])
 284 fi
 285 if test "x$targ_defvec" != x; then
 286   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
 287     [Define to BFD's default target vector. ])
 288 fi
 289
 290 # The CLI cannot be disabled yet, but may be in the future.
 291
 292 # Enable CLI.
 293 AC_ARG_ENABLE(gdbcli,
 294 AS_HELP_STRING([--disable-gdbcli], [disable command-line interface (CLI)]),
 295   [case $enableval in
 296     yes)
 297       ;;
 298     no)
 299       AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;;
 300     *)
 301       AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;;
 302   esac],
 303   [enable_gdbcli=yes])
 304 if test x"$enable_gdbcli" = xyes; then
 305   if test -d $srcdir/cli; then
 306     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)"
 307     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)"
 308     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)"
 309     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)"
 310   fi
 311 fi
 312
 313 # Enable MI.
 314 AC_ARG_ENABLE(gdbmi,
 315 AS_HELP_STRING([--disable-gdbmi], [disable machine-interface (MI)]),
 316   [case $enableval in
 317     yes | no)
 318       ;;
 319     *)
 320       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 321   esac],
 322   [enable_gdbmi=yes])
 323 if test x"$enable_gdbmi" = xyes; then
 324   if test -d $srcdir/mi; then
 325     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 326     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 327     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 328     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 329   fi
 330 fi
 331
 332 # Enable TUI.
 333 AC_ARG_ENABLE(tui,
 334 AS_HELP_STRING([--enable-tui], [enable full-screen terminal user interface (TUI)]),
 335   [case $enableval in
 336     yes | no | auto)
 337       ;;
 338     *)
 339       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 340   esac],enable_tui=auto)
 341
 342 # Enable gdbtk.
 343 AC_ARG_ENABLE(gdbtk,
 344 AS_HELP_STRING([--enable-gdbtk], [enable gdbtk graphical user interface (GUI)]),
 345   [case $enableval in
 346     yes | no)
 347       ;;
 348     *)
 349       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 350   esac],
 351   [if test -d $srcdir/gdbtk; then
 352     enable_gdbtk=yes
 353   else
 354     enable_gdbtk=no
 355   fi])
 356 # We unconditionally disable gdbtk tests on selected platforms.
 357 case $host_os in
 358   go32* | windows*)
 359     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 360     enable_gdbtk=no ;;
 361 esac
 362
 363 # Libunwind support for ia64.
 364
 365 AC_ARG_WITH(libunwind-ia64,
 366 AS_HELP_STRING([--with-libunwind-ia64],
 367                [use libunwind frame unwinding for ia64 targets]),,
 368             [with_libunwind_ia64=auto])
 369
 370 # Backward compatibility option.
 371 if test "${with_libunwind+set}" = set; then
 372   if test x"$with_libunwind_ia64" != xauto; then
 373     AC_MSG_ERROR(
 374       [option --with-libunwind is deprecated, use --with-libunwind-ia64])
 375   fi
 376   AC_MSG_WARN([option --with-libunwind is deprecated, use --with-libunwind-ia64])
 377   with_libunwind_ia64="$with_libunwind"
 378 fi
 379
 380 case "$with_libunwind_ia64" in
 381   yes | no)
 382     ;;
 383   auto)
 384     AC_CHECK_HEADERS(libunwind-ia64.h)
 385     with_libunwind_ia64=$ac_cv_header_libunwind_ia64_h
 386     ;;
 387   *)
 388     AC_MSG_ERROR(
 389       [bad value $with_libunwind_ia64 for GDB --with-libunwind-ia64 option])
 390     ;;
 391 esac
 392
 393 if test x"$with_libunwind_ia64" = xyes; then
 394   AC_CHECK_HEADERS(libunwind-ia64.h)
 395   if test x"$ac_cv_header_libunwind_ia64_h" != xyes; then
 396     AC_MSG_ERROR([GDB option --with-libunwind-ia64 requires libunwind-ia64.h])
 397   fi
 398   CONFIG_OBS="$CONFIG_OBS ia64-libunwind-tdep.o"
 399   CONFIG_DEPS="$CONFIG_DEPS ia64-libunwind-tdep.o"
 400   CONFIG_SRCS="$CONFIG_SRCS ia64-libunwind-tdep.c"
 401 fi
 402
 403 opt_curses=no
 404 AC_ARG_WITH(curses, AS_HELP_STRING([--with-curses], [use the curses library instead of the termcap library]), opt_curses=$withval)
 405
 406 prefer_curses=no
 407 if test "$opt_curses" = "yes"; then
 408   prefer_curses=yes
 409 fi
 410
 411 # Profiling support.
 412 AC_ARG_ENABLE(profiling,
 413 AS_HELP_STRING([--enable-profiling], [enable profiling of GDB]),
 414   [case $enableval in
 415     yes | no)
 416       ;;
 417     *)
 418       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 419   esac],
 420  [enable_profiling=no])
 421
 422 AC_CHECK_FUNCS(monstartup _mcleanup)
 423 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 424 [AC_TRY_LINK(
 425 [#include <stdlib.h>
 426 extern char _etext;
 427 ],
 428 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 429 if test $ac_cv_var__etext = yes; then
 430   AC_DEFINE(HAVE__ETEXT, 1,
 431             [Define to 1 if your system has the _etext variable. ])
 432 fi
 433 AC_CACHE_CHECK([for etext], ac_cv_var_etext,
 434 [AC_TRY_LINK(
 435 [#include <stdlib.h>
 436 extern char etext;
 437 ],
 438 [free (&etext);], ac_cv_var_etext=yes, ac_cv_var_etext=no)])
 439 if test $ac_cv_var_etext = yes; then
 440   AC_DEFINE(HAVE_ETEXT, 1,
 441             [Define to 1 if your system has the etext variable. ])
 442 fi
 443 if test "$enable_profiling" = yes ; then
 444   if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
 445     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 446   fi
 447   PROFILE_CFLAGS=-pg
 448   OLD_CFLAGS="$CFLAGS"
 449   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 450
 451   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 452     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 453      ac_cv_cc_supports_pg=no)])
 454
 455   if test $ac_cv_cc_supports_pg = no; then
 456     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 457   fi
 458
 459   CFLAGS="$OLD_CFLAGS"
 460 fi
 461
 462 ACX_PKGVERSION([GDB])
 463 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 464 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 465 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 466
 467 # --------------------- #
 468 # Checks for programs.  #
 469 # --------------------- #
 470
 471 AC_PROG_AWK
 472 AC_PROG_INSTALL
 473 AC_PROG_LN_S
 474 AC_PROG_RANLIB
 475 AC_PROG_YACC
 476
 477 AC_CHECK_TOOL(AR, ar)
 478 AC_CHECK_TOOL(DLLTOOL, dlltool)
 479 AC_CHECK_TOOL(WINDRES, windres)
 480
 481 # Needed for GNU/Hurd.
 482 AC_CHECK_TOOL(MIG, mig)
 483
 484 # ---------------------- #
 485 # Checks for libraries.  #
 486 # ---------------------- #
 487
 488 # We might need to link with -lm; most simulators need it.
 489 AC_CHECK_LIB(m, main)
 490
 491 # We need to link with -lw to get `wctype' on Solaris before Solaris
 492 # 2.6.  Solaris 2.6 and beyond have this function in libc, and have a
 493 # libw that some versions of the GNU linker cannot hanle (GNU ld 2.9.1
 494 # is known to have this problem).  Therefore we avoid libw if we can.
 495 AC_CHECK_FUNC(wctype, [],
 496   [AC_CHECK_LIB(w, wctype)])
 497
 498 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 499 AC_SEARCH_LIBS(gethostbyname, nsl)
 500
 501 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 502 AC_SEARCH_LIBS(socketpair, socket)
 503
 504 # Link in zlib if we can.  This allows us to read compressed debug sections.
 505 AM_ZLIB
 506
 507 # On HP/UX we may need libxpdl for dlgetmodinfo (used by solib-pa64.c).
 508 AC_SEARCH_LIBS(dlgetmodinfo, [dl xpdl])
 509
 510 AM_ICONV
 511
 512 # GDB may fork/exec the iconv program to get the list of supported character
 513 # sets.  Allow the user to specify where to find it.
 514 # There are several factors affecting the choice of option name:
 515 # - There is already --with-libiconv-prefix but we can't use it, it specifies
 516 #   the build-time location of libiconv files.
 517 # - The program we need to find is iconv, which comes with glibc.  The user
 518 #   doesn't necessarily have libiconv installed.  Therefore naming this
 519 #   --with-libiconv-foo feels wrong.
 520 # - We want the path to be relocatable, but GDB_AC_DEFINE_RELOCATABLE is
 521 #   defined to work on directories not files (though it really doesn't know
 522 #   the difference).
 523 # - Calling this --with-iconv-prefix is perceived to cause too much confusion
 524 #   with --with-libiconv-prefix.
 525 # Putting these together is why the option name is --with-iconv-bin.
 526
 527 AC_ARG_WITH(iconv-bin,
 528 AS_HELP_STRING([--with-iconv-bin=PATH], [specify where to find the iconv program]),
 529 [iconv_bin="${withval}"
 530  AC_DEFINE_UNQUOTED([ICONV_BIN], ["${iconv_bin}"],
 531                     [Path of directory of iconv program.])
 532  GDB_AC_DEFINE_RELOCATABLE(ICONV_BIN, iconv, ${iconv_bin})
 533 ])
 534
 535 # On alpha-osf, it appears that libtermcap and libcurses are not compatible.
 536 # There is a very specific comment in /usr/include/curses.h explaining that
 537 # termcap routines built into libcurses must not be used.
 538 #
 539 # The symptoms we observed so far is GDB unexpectedly changing
 540 # the terminal settings when tgetent is called - this is particularly
 541 # visible as the output is missing carriage returns, and so rapidly
 542 # becomes very hard to read.
 543 #
 544 # The readline configure script has already decided that libtermcap
 545 # was enough for its purposes, and so decided to build readline using
 546 # libtermcap.  Since the TUI mode requires curses, building GDB with
 547 # TUI enabled results in both libraries to be used at the same time,
 548 # which is not allowed.  This basically means that GDB with TUI is
 549 # broken on alpha-osf.
 550
 551 case $host_os in
 552   osf* )
 553     if test x"$enable_tui" = xyes; then
 554       AC_MSG_ERROR([Building GDB with TUI mode is not supported on this host])
 555     fi
 556     if test x"$enable_tui" = xauto; then
 557       enable_tui=no
 558     fi
 559     ;;
 560 esac
 561
 562 # For the TUI, we need enhanced curses functionality.
 563 if test x"$enable_tui" != xno; then
 564   prefer_curses=yes
 565 fi
 566
 567 curses_found=no
 568 if test x"$prefer_curses" = xyes; then
 569   # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
 570   # curses library because the latter might not provide all the
 571   # functionality we need.  However, this leads to problems on systems
 572   # where the linker searches /usr/local/lib, but the compiler doesn't
 573   # search /usr/local/include, if ncurses is installed in /usr/local.  A
 574   # default installation of ncurses on alpha*-dec-osf* will lead to such
 575   # a situation.
 576   AC_SEARCH_LIBS(waddstr, [ncurses cursesX curses])
 577
 578   if test "$ac_cv_search_waddstr" != no; then
 579     curses_found=yes
 580   fi
 581 fi
 582
 583 # Check whether we should enable the TUI, but only do so if we really
 584 # can.
 585 if test x"$enable_tui" != xno; then
 586   if test -d $srcdir/tui; then
 587     if test "$curses_found" != no; then
 588       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
 589       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
 590       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
 591       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
 592     else
 593       if test x"$enable_tui" = xyes; then
 594         AC_MSG_ERROR([no enhanced curses library found; disable TUI])
 595       else
 596         AC_MSG_WARN([no enhanced curses library found; disabling TUI])
 597       fi
 598     fi
 599   fi
 600 fi
 601
 602 # Since GDB uses Readline, we need termcap functionality.  In many
 603 # cases this will be provided by the curses library, but some systems
 604 # have a seperate termcap library, or no curses library at all.
 605
 606 case $host_os in
 607   cygwin*)
 608     if test -d $srcdir/libtermcap; then
 609       LIBS="../libtermcap/libtermcap.a $LIBS"
 610       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 611     fi ;;
 612   go32* | *djgpp*)
 613     ac_cv_search_tgetent="none required"
 614     ;;
 615   *mingw32*)
 616     ac_cv_search_tgetent="none required"
 617     CONFIG_OBS="$CONFIG_OBS windows-termcap.o"
 618     ;;
 619 esac
 620
 621 # These are the libraries checked by Readline.
 622 AC_SEARCH_LIBS(tgetent, [termcap tinfo curses ncurses])
 623
 624 if test "$ac_cv_search_tgetent" = no; then
 625   AC_MSG_ERROR([no termcap library found])
 626 fi
 627
 628 AC_ARG_WITH([system-readline],
 629   [AS_HELP_STRING([--with-system-readline],
 630                   [use installed readline library])])
 631
 632 if test "$with_system_readline" = yes; then
 633   READLINE=-lreadline
 634   READLINE_DEPS=
 635   READLINE_CFLAGS=
 636   READLINE_TEXI_INCFLAG=
 637 else
 638   READLINE='$(READLINE_DIR)/libreadline.a'
 639   READLINE_DEPS='$(READLINE)'
 640   READLINE_CFLAGS='-I$(READLINE_SRC)/..'
 641   READLINE_TEXI_INCFLAG='-I $(READLINE_DIR)'
 642 fi
 643 AC_SUBST(READLINE)
 644 AC_SUBST(READLINE_DEPS)
 645 AC_SUBST(READLINE_CFLAGS)
 646 AC_SUBST(READLINE_TEXI_INCFLAG)
 647
 648 # Generate jit-reader.h
 649
 650 # This is typedeffed to GDB_CORE_ADDR in jit-reader.h
 651 TARGET_PTR=
 652
 653 AC_CHECK_SIZEOF(unsigned long long)
 654 AC_CHECK_SIZEOF(unsigned long)
 655 AC_CHECK_SIZEOF(unsigned __int128)
 656
 657 if test "x${ac_cv_sizeof_unsigned_long}" = "x8"; then
 658   TARGET_PTR="unsigned long"
 659 elif test "x${ac_cv_sizeof_unsigned_long_long}" = "x8"; then
 660   TARGET_PTR="unsigned long long"
 661 elif test "x${ac_cv_sizeof_unsigned___int128}" = "x16"; then
 662   TARGET_PTR="unsigned __int128"
 663 else
 664   TARGET_PTR="unsigned long"
 665 fi
 666
 667 AC_SUBST(TARGET_PTR)
 668 AC_CONFIG_FILES([jit-reader.h:jit-reader.in])
 669
 670 AC_SEARCH_LIBS(dlopen, dl)
 671
 672 GDB_AC_WITH_DIR([JIT_READER_DIR], [jit-reader-dir],
 673                 [directory to load the JIT readers from],
 674                 [${libdir}/gdb])
 675
 676 AC_ARG_WITH(expat,
 677   AS_HELP_STRING([--with-expat], [include expat support (auto/yes/no)]),
 678   [], [with_expat=auto])
 679 AC_MSG_CHECKING([whether to use expat])
 680 AC_MSG_RESULT([$with_expat])
 681
 682 if test "${with_expat}" = no; then
 683   AC_MSG_WARN([expat support disabled; some features may be unavailable.])
 684   HAVE_LIBEXPAT=no
 685 else
 686   AC_LIB_HAVE_LINKFLAGS([expat], [], [#include "expat.h"],
 687                         [XML_Parser p = XML_ParserCreate (0);])
 688   if test "$HAVE_LIBEXPAT" != yes; then
 689     if test "$with_expat" = yes; then
 690       AC_MSG_ERROR([expat is missing or unusable])
 691     else
 692       AC_MSG_WARN([expat is missing or unusable; some features may be unavailable.])
 693     fi
 694   else
 695     save_LIBS=$LIBS
 696     LIBS="$LIBS $LIBEXPAT"
 697     AC_CHECK_FUNCS(XML_StopParser)
 698     LIBS=$save_LIBS
 699   fi
 700 fi
 701
 702 dnl Utility to simplify finding libpython.
 703 dnl $1 = pythonX.Y
 704 dnl $2 = the shell variable to assign the result to
 705 dnl      If libpython is found we store $version here.
 706 dnl $3 = additional flags to add to CPPFLAGS
 707 dnl $4 = additional flags to add to LIBS
 708
 709 AC_DEFUN([AC_TRY_LIBPYTHON],
 710 [
 711   version=$1
 712   define([have_libpython_var],$2)
 713   new_CPPFLAGS=$3
 714   new_LIBS=$4
 715   AC_MSG_CHECKING([for ${version}])
 716   save_CPPFLAGS=$CPPFLAGS
 717   save_LIBS=$LIBS
 718   CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
 719   LIBS="$LIBS $new_LIBS"
 720   found_usable_python=no
 721   AC_LINK_IFELSE(AC_LANG_PROGRAM([[#include "Python.h"]],
 722                                  [[Py_Initialize ();]]),
 723                  [have_libpython_var=${version}
 724                   found_usable_python=yes
 725                   PYTHON_CPPFLAGS=$new_CPPFLAGS
 726                   PYTHON_LIBS=$new_LIBS])
 727   CPPFLAGS=$save_CPPFLAGS
 728   LIBS=$save_LIBS
 729   AC_MSG_RESULT([${found_usable_python}])
 730 ])
 731
 732 dnl There are several different values for --with-python:
 733 dnl
 734 dnl no -   Don't include python support.
 735 dnl yes -  Include python support, error if it's missing.
 736 dnl        If we find python in $PATH, use it to fetch configure options,
 737 dnl        otherwise assume the compiler can find it with no help from us.
 738 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 739 dnl auto - Same as "yes", but if python is missing from the system,
 740 dnl        fall back to "no".
 741 dnl /path/to/python/exec-prefix -
 742 dnl        Use the python located in this directory.
 743 dnl        If /path/to/python/exec-prefix/bin/python exists, use it to find
 744 dnl        the compilation parameters.  Otherwise use
 745 dnl        -I/path/to/python/exec-prefix/include,
 746 dnl        -L/path/to/python/exec-prefix/lib.
 747 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 748 dnl        NOTE: This case is historical.  It is what was done for 7.0/7.1
 749 dnl        but is deprecated.
 750 dnl /path/to/python/executable -
 751 dnl        Run python-config.py with this version of python to fetch the
 752 dnl        compilation parameters.
 753 dnl        NOTE: This needn't be the real python executable.
 754 dnl        In a cross-compilation scenario (build != host), this could be
 755 dnl        a shell script that provides what python-config.py provides for
 756 dnl        --ldflags, --includes, --exec-prefix.
 757 dnl python-executable -
 758 dnl        Find python-executable in $PATH, and then handle the same as
 759 dnl        /path/to/python/executable.
 760 dnl
 761 dnl If a python program is specified, it is used to run python-config.py and
 762 dnl is passed --ldflags, --includes, --exec-prefix.
 763
 764 AC_ARG_WITH(python,
 765   AS_HELP_STRING([--with-python@<:@=PYTHON@:>@], [include python support (auto/yes/no/<python-program>)]),
 766   [], [with_python=auto])
 767 AC_MSG_CHECKING([whether to use python])
 768 AC_MSG_RESULT([$with_python])
 769
 770 if test "${with_python}" = no; then
 771   AC_MSG_WARN([python support disabled; some features may be unavailable.])
 772   have_libpython=no
 773 else
 774   case "${with_python}" in
 775   [[\\/]]* | ?:[[\\/]]*)
 776     if test -d ${with_python}; then
 777       # Assume the python binary is ${with_python}/bin/python.
 778       python_prog="${with_python}/bin/python"
 779       python_prefix=
 780       # If python does not exit ${with_python}/bin, then try in
 781       # ${with_python}.  On Windows/MinGW, this is where the Python
 782       # executable is.
 783       if test ! -x "${python_prog}"; then
 784         python_prog="${with_python}/python"
 785         python_prefix=
 786       fi
 787       if test ! -x "${python_prog}"; then
 788         # Fall back to gdb 7.0/7.1 behaviour.
 789         python_prog=missing
 790         python_prefix=${with_python}
 791       fi
 792     elif test -x "${with_python}"; then
 793       # While we can't run python compiled for $host (unless host == build),
 794       # the user could write a script that provides the needed information,
 795       # so we support that.
 796       python_prog=${with_python}
 797       python_prefix=
 798     else
 799       AC_ERROR(invalid value for --with-python)
 800     fi
 801     ;;
 802   */*)
 803     # Disallow --with-python=foo/bar.
 804     AC_ERROR(invalid value for --with-python)
 805     ;;
 806   *)
 807     # The user has either specified auto, yes, or the name of the python
 808     # program assumed to be in $PATH.
 809     python_prefix=
 810     case "${with_python}" in
 811     yes | auto)
 812       if test ${build} = ${host}; then
 813         AC_PATH_PROG(python_prog_path, python, missing)
 814         if test "${python_prog_path}" = missing; then
 815           python_prog=missing
 816         else
 817           python_prog=${python_prog_path}
 818         fi
 819       else
 820         # Not much we can do except assume the cross-compiler will find the
 821         # right files.
 822         python_prog=missing
 823       fi
 824       ;;
 825     *)
 826       # While we can't run python compiled for $host (unless host == build),
 827       # the user could write a script that provides the needed information,
 828       # so we support that.
 829       python_prog="${with_python}"
 830       AC_PATH_PROG(python_prog_path, ${python_prog}, missing)
 831       if test "${python_prog_path}" = missing; then
 832         AC_ERROR(unable to find python program ${python_prog})
 833       fi
 834       ;;
 835     esac
 836   esac
 837
 838   if test "${python_prog}" != missing; then
 839     # We have a python program to use, but it may be too old.
 840     # Don't flag an error for --with-python=auto (the default).
 841     have_python_config=yes
 842     python_includes=`${python_prog} ${srcdir}/python/python-config.py --includes`
 843     if test $? != 0; then
 844       have_python_config=failed
 845       if test "${with_python}" != auto; then
 846         AC_ERROR(failure running python-config --includes)
 847       fi
 848     fi
 849     python_libs=`${python_prog} ${srcdir}/python/python-config.py --ldflags`
 850     if test $? != 0; then
 851       have_python_config=failed
 852       if test "${with_python}" != auto; then
 853         AC_ERROR(failure running python-config --ldflags)
 854       fi
 855     fi
 856     python_prefix=`${python_prog} ${srcdir}/python/python-config.py --exec-prefix`
 857     if test $? != 0; then
 858       have_python_config=failed
 859       if test "${with_python}" != auto; then
 860         AC_ERROR(failure running python-config --exec-prefix)
 861       fi
 862     fi
 863   else
 864     # We do not have a python executable we can use to determine where
 865     # to find the Python headers and libs.  We cannot guess the include
 866     # path from the python_prefix either, because that include path
 867     # depends on the Python version.  So, there is nothing much we can
 868     # do except assume that the compiler will be able to find those files.
 869     python_includes=
 870     python_libs=
 871     have_python_config=no
 872   fi
 873
 874   # If we have python-config, only try the configuration it provides.
 875   # Otherwise fallback on the old way of trying different versions of
 876   # python in turn.
 877
 878   have_libpython=no
 879   if test "${have_python_config}" = yes; then
 880     # Determine the Python version by extracting "-lpython<version>"
 881     # part of the python_libs. <version> is usually X.Y with X and Y
 882     # being decimal numbers, but can also be XY (seen on Windows).
 883     #
 884     # The extraction is performed using sed with a regular expression.
 885     # Initially, the regexp used was using the '?' quantifier to make
 886     # the dot in the version number optional.  Unfortunately, this
 887     # does not work with non-GNU versions of sed because, because of
 888     # what looks like a limitation (the '?' quantifier does not work
 889     # with back-references).  We work around this limitation by using
 890     # the '*' quantifier instead.  It means that, in theory, we might
 891     # match unexpected version strings such as "-lpython2..7", but
 892     # this seems unlikely in practice.  And even if that happens,
 893     # an error will be triggered later on, when checking that version
 894     # number.
 895     python_version=`echo " ${python_libs} " \
 896                          | sed -e 's,^.* -l\(python[[0-9]]*[[.]]*[[0-9]]*\).*$,\1,'`
 897     case "${python_version}" in
 898     python*)
 899       AC_TRY_LIBPYTHON(${python_version}, have_libpython,
 900                        ${python_includes}, ${python_libs})
 901       ;;
 902     *)
 903       AC_MSG_ERROR([unable to determine python version from ${python_libs}])
 904       ;;
 905     esac
 906   elif test "${have_python_config}" != failed; then
 907     if test "${have_libpython}" = no; then
 908       AC_TRY_LIBPYTHON(python2.7, have_libpython,
 909                        ${python_includes}, "${python_libs} -lpython2.7")
 910     fi
 911     if test "${have_libpython}" = no; then
 912       AC_TRY_LIBPYTHON(python2.6, have_libpython,
 913                        ${python_includes}, "${python_libs} -lpython2.6")
 914     fi
 915     if test ${have_libpython} = no; then
 916       AC_TRY_LIBPYTHON(python2.5, have_libpython,
 917                        ${python_includes}, "${python_libs} -lpython2.5")
 918     fi
 919     if test ${have_libpython} = no; then
 920       AC_TRY_LIBPYTHON(python2.4, have_libpython,
 921                        ${python_includes}, "${python_libs} -lpython2.4")
 922     fi
 923   fi
 924   if test "${have_libpython}" = python2.7 -o "${have_libpython}" = python27; then
 925     AC_DEFINE(HAVE_LIBPYTHON2_7, 1, [Define if Python 2.7 is being used.])
 926   elif test "${have_libpython}" = python2.6 -o "${have_libpython}" = python26; then
 927     AC_DEFINE(HAVE_LIBPYTHON2_6, 1, [Define if Python 2.6 is being used.])
 928   elif test "${have_libpython}" = python2.5 -o "${have_libpython}" = python25; then
 929     AC_DEFINE(HAVE_LIBPYTHON2_5, 1, [Define if Python 2.5 is being used.])
 930   elif test "${have_libpython}" = python2.4 -o "${have_libpython}" = python24; then
 931     AC_DEFINE(HAVE_LIBPYTHON2_4, 1, [Define if Python 2.4 is being used.])
 932   fi
 933
 934   if test "${have_libpython}" = no; then
 935     case "${with_python}" in
 936     yes)
 937       AC_MSG_ERROR([python is missing or unusable])
 938       ;;
 939     auto)
 940       AC_MSG_WARN([python is missing or unusable; some features may be unavailable.])
 941       ;;
 942     *)
 943       AC_MSG_ERROR([no usable python found at ${with_python}])
 944       ;;
 945     esac
 946   else
 947     if test -n "${python_prefix}"; then
 948       AC_DEFINE_UNQUOTED(WITH_PYTHON_PATH, "${python_prefix}",
 949                          [Define if --with-python provides a path, either directly or via python-config.py --exec-prefix.])
 950       GDB_AC_DEFINE_RELOCATABLE(PYTHON_PATH, python, ${python_prefix})
 951     fi
 952   fi
 953 fi
 954
 955 if test "${have_libpython}" != no; then
 956   AC_DEFINE(HAVE_PYTHON, 1, [Define if Python interpreter is being linked in.])
 957   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_PYTHON_OBS)"
 958   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_PYTHON_DEPS)"
 959   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_PYTHON_SRCS)"
 960   CONFIG_INSTALL="$CONFIG_INSTALL install-python"
 961   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_PYTHON_CFLAGS)"
 962
 963   # Flags needed to compile Python code (taken from python-config --cflags).
 964   # We cannot call python-config directly because it will output whatever was
 965   # used when compiling the Python interpreter itself, including flags which
 966   # would make the python-related objects be compiled differently from the
 967   # rest of GDB (e.g., -O2 and -fPIC).
 968   if test "${GCC}" = yes; then
 969     tentative_python_cflags="-fno-strict-aliasing -DNDEBUG -fwrapv"
 970   fi
 971
 972   if test "x${tentative_python_cflags}" != x; then
 973     AC_MSG_CHECKING(compiler flags for python code)
 974     for flag in ${tentative_python_cflags}; do
 975       # Check that the compiler accepts it
 976       saved_CFLAGS="$CFLAGS"
 977       CFLAGS="$CFLAGS $flag"
 978       AC_TRY_COMPILE([],[],PYTHON_CFLAGS="${PYTHON_CFLAGS} $flag",)
 979       CFLAGS="$saved_CFLAGS"
 980     done
 981     AC_MSG_RESULT(${PYTHON_CFLAGS})
 982   fi
 983
 984   # On IRIX, type siginfo is not defined.  Instead, sys/siginfo.h provides:
 985   #    #if _SGIAPI
 986   #    #define siginfo __siginfo
 987   #    #endif
 988   # The problem is that including Python causes some XOPEN macros to be
 989   # unilaterally defined, and that in turn causes _SGIAPI to evaluate
 990   # to false.  So, we work around this issue by defining siginfo ourself
 991   # though the command-line.
 992   case "$gdb_host" in
 993     irix*) if test "${GCC}" = yes; then
 994              CPPFLAGS="$CPPFLAGS -Dsiginfo=__siginfo"
 995            fi
 996            ;;
 997   esac
 998
 999   # Note that "python -m threading" cannot be used to check for
1000   # threading support due to a bug in Python 2.7.3
1001   # (http://bugs.python.org/issue15567).
1002   AC_MSG_CHECKING(whether python supports threads)
1003   saved_CPPFLAGS="${CPPFLAGS}"
1004   CPPFLAGS="${PYTHON_CPPFLAGS}"
1005   # Note that the test is reversed so that python_has_threads=yes on
1006   # unexpected failures.
1007   AC_PREPROC_IFELSE(AC_LANG_SOURCE([[
1008 #include <Python.h>
1009 #ifdef WITH_THREAD
1010 # error
1011 #endif
1012   ]]), [python_has_threads=no], [python_has_threads=yes])
1013   AC_MSG_RESULT(${python_has_threads})
1014   CPPFLAGS="${saved_CPPFLAGS}"
1015 else
1016   # Even if Python support is not compiled in, we need to have these files
1017   # included.
1018   CONFIG_OBS="$CONFIG_OBS python.o py-value.o py-prettyprint.o py-auto-load.o"
1019   CONFIG_SRCS="$CONFIG_SRCS python/python.c python/py-value.c \
1020         python/py-prettyprint.c python/py-auto-load.c"
1021 fi
1022 AC_SUBST(PYTHON_CFLAGS)
1023 AC_SUBST(PYTHON_CPPFLAGS)
1024 AC_SUBST(PYTHON_LIBS)
1025
1026 # Provide a --enable-libmcheck/--disable-libmcheck set of options
1027 # allowing a user to enable this option even when building releases,
1028 # or to disable it when building a snapshot.
1029 AC_ARG_ENABLE(libmcheck,
1030   AS_HELP_STRING([--enable-libmcheck],
1031                  [Try building GDB with -lmcheck if available]),
1032   [case "${enableval}" in
1033      yes | y) ENABLE_LIBMCHECK="yes" ;;
1034      no | n)  ENABLE_LIBMCHECK="no" ;;
1035      *) AC_MSG_ERROR(bad value ${enableval} for --enable-libmcheck) ;;
1036    esac])
1037
1038 # Enable -lmcheck by default (it provides cheap-enough memory mangling),
1039 # but turn it off if Python is enabled with threads, since -lmcheck is
1040 # not thread safe (http://sourceware.org/bugzilla/show_bug.cgi?id=9939),
1041 # and for releases.
1042 if test -z "${ENABLE_LIBMCHECK}" \
1043         -a \( "${have_libpython}" = "no" \
1044              -o "${python_has_threads}" = "no" \) \
1045     && $development; then
1046   ENABLE_LIBMCHECK=yes
1047 fi
1048
1049 if test "$ENABLE_LIBMCHECK" = "yes" ; then
1050   if test "${have_libpython}" != "no" -a "${python_has_threads}" = "yes" ; then
1051     AC_MSG_WARN(--enable-libmcheck may lead to spurious crashes if threads are used in python)
1052   fi
1053   AC_CHECK_LIB(mcheck, main)
1054 fi
1055
1056 # ------------------------- #
1057 # Checks for header files.  #
1058 # ------------------------- #
1059
1060 AC_HEADER_DIRENT
1061 AC_HEADER_STAT
1062 AC_HEADER_STDC
1063 # elf_hp.h is for HP/UX 64-bit shared library support.
1064 # FIXME: kettenis/20030102: In most cases we include these (ctype.h, time.h)
1065 # unconditionally, so what's the point in checking these?
1066 AC_CHECK_HEADERS([nlist.h machine/reg.h poll.h sys/poll.h proc_service.h \
1067                   thread_db.h signal.h stddef.h \
1068                   stdlib.h string.h memory.h strings.h sys/fault.h \
1069                   sys/file.h sys/filio.h sys/ioctl.h sys/param.h \
1070                   sys/resource.h sys/procfs.h sys/ptrace.h ptrace.h \
1071                   sys/reg.h sys/debugreg.h sys/select.h sys/syscall.h \
1072                   sys/types.h sys/wait.h wait.h termios.h termio.h \
1073                   sgtty.h unistd.h elf_hp.h ctype.h time.h locale.h \
1074                   dlfcn.h sys/socket.h sys/un.h])
1075 AC_CHECK_HEADERS(link.h, [], [],
1076 [#if HAVE_SYS_TYPES_H
1077 # include <sys/types.h>
1078 #endif
1079 #if HAVE_NLIST_H
1080 # include <nlist.h>
1081 #endif
1082 ])
1083 AC_CHECK_HEADERS(sys/proc.h, [], [],
1084 [#if HAVE_SYS_PARAM_H
1085 # include <sys/param.h>
1086 #endif
1087 ])
1088 AC_CHECK_HEADERS(sys/user.h, [], [],
1089 [#if HAVE_SYS_PARAM_H
1090 # include <sys/param.h>
1091 #endif
1092 ])
1093
1094 # On Solaris 2.[789], we need to define _MSE_INT_H to avoid a clash
1095 # between <widec.h> and <wchar.h> that would cause AC_CHECK_HEADERS to
1096 # think that we don't have <curses.h> if we're using GCC.
1097 case $host_os in
1098   solaris2.[[789]])
1099     if test "$GCC" = yes; then
1100       AC_DEFINE(_MSE_INT_H, 1,
1101         [Define to 1 to avoid a clash between <widec.h> and <wchar.h> on
1102    Solaris 2.[789] when using GCC. ])
1103     fi ;;
1104 esac
1105 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncurses/ncurses.h ncurses/term.h)
1106 AC_CHECK_HEADERS(term.h, [], [],
1107 [#if HAVE_CURSES_H
1108 # include <curses.h>
1109 #endif
1110 ])
1111
1112 # ------------------------- #
1113 # Checks for declarations.  #
1114 # ------------------------- #
1115
1116 AC_CHECK_DECLS([free, malloc, realloc, strerror, strstr, getopt,
1117                 snprintf, vsnprintf])
1118 AM_LC_MESSAGES
1119
1120 # ----------------------- #
1121 # Checks for structures.  #
1122 # ----------------------- #
1123
1124 AC_CHECK_MEMBERS([struct stat.st_blocks, struct stat.st_blksize])
1125
1126 # ------------------ #
1127 # Checks for types.  #
1128 # ------------------ #
1129
1130 AC_TYPE_SIGNAL
1131 AC_CHECK_TYPES(socklen_t, [], [],
1132 [#include <sys/types.h>
1133 #include <sys/socket.h>
1134 ])
1135
1136 # ------------------------------------- #
1137 # Checks for compiler characteristics.  #
1138 # ------------------------------------- #
1139
1140 AC_C_CONST
1141 AC_C_INLINE
1142 AC_C_BIGENDIAN
1143
1144 # ------------------------------ #
1145 # Checks for library functions.  #
1146 # ------------------------------ #
1147
1148 AC_FUNC_ALLOCA
1149 AC_FUNC_MMAP
1150 AC_FUNC_VFORK
1151 AC_CHECK_FUNCS([canonicalize_file_name realpath getrusage getuid getgid \
1152                 pipe poll pread pread64 pwrite readlink resize_term \
1153                 sbrk setpgid setpgrp setsid \
1154                 sigaction sigprocmask sigsetmask socketpair syscall \
1155                 ttrace wborder wresize setlocale iconvlist libiconvlist btowc \
1156                 setrlimit getrlimit posix_madvise waitpid lstat])
1157 AM_LANGINFO_CODESET
1158
1159 # Check the return and argument types of ptrace.  No canned test for
1160 # this, so roll our own.
1161 gdb_ptrace_headers='
1162 #if HAVE_SYS_TYPES_H
1163 # include <sys/types.h>
1164 #endif
1165 #if HAVE_SYS_PTRACE_H
1166 # include <sys/ptrace.h>
1167 #endif
1168 #if HAVE_UNISTD_H
1169 # include <unistd.h>
1170 #endif
1171 '
1172 # There is no point in checking if we don't have a prototype.
1173 AC_CHECK_DECLS(ptrace, [], [
1174   : ${gdb_cv_func_ptrace_ret='int'}
1175   : ${gdb_cv_func_ptrace_args='int,int,long,long'}
1176 ], $gdb_ptrace_headers)
1177 # Check return type.  Varargs (used on GNU/Linux) conflict with the
1178 # empty argument list, so check for that explicitly.
1179 AC_CACHE_CHECK([return type of ptrace], gdb_cv_func_ptrace_ret,
1180   AC_TRY_COMPILE($gdb_ptrace_headers,
1181     [extern long ptrace (enum __ptrace_request, ...);],
1182     gdb_cv_func_ptrace_ret='long',
1183     AC_TRY_COMPILE($gdb_ptrace_headers,
1184       [extern int ptrace ();],
1185       gdb_cv_func_ptrace_ret='int',
1186       gdb_cv_func_ptrace_ret='long')))
1187 AC_DEFINE_UNQUOTED(PTRACE_TYPE_RET, $gdb_cv_func_ptrace_ret,
1188   [Define as the return type of ptrace.])
1189 # Check argument types.
1190 AC_CACHE_CHECK([types of arguments for ptrace], gdb_cv_func_ptrace_args, [
1191   AC_TRY_COMPILE($gdb_ptrace_headers,
1192     [extern long ptrace (enum __ptrace_request, ...);],
1193     [gdb_cv_func_ptrace_args='int,int,long,long'],[
1194 for gdb_arg1 in 'int' 'long'; do
1195  for gdb_arg2 in 'pid_t' 'int' 'long'; do
1196   for gdb_arg3 in 'int *' 'caddr_t' 'int' 'long' 'void *'; do
1197    for gdb_arg4 in 'int' 'long'; do
1198      AC_TRY_COMPILE($gdb_ptrace_headers, [
1199 extern $gdb_cv_func_ptrace_ret
1200   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4);
1201 ], [gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4";
1202     break 4;])
1203     for gdb_arg5 in 'int *' 'int' 'long'; do
1204      AC_TRY_COMPILE($gdb_ptrace_headers, [
1205 extern $gdb_cv_func_ptrace_ret
1206   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4, $gdb_arg5);
1207 ], [
1208 gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4,$gdb_arg5";
1209     break 5;])
1210     done
1211    done
1212   done
1213  done
1214 done
1215 # Provide a safe default value.
1216 : ${gdb_cv_func_ptrace_args='int,int,long,long'}
1217 ])])
1218 ac_save_IFS=$IFS; IFS=','
1219 set dummy `echo "$gdb_cv_func_ptrace_args" | sed 's/\*/\*/g'`
1220 IFS=$ac_save_IFS
1221 shift
1222 AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG3, $[3],
1223   [Define to the type of arg 3 for ptrace.])
1224 if test -n "$[5]"; then
1225   AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG5, $[5],
1226     [Define to the type of arg 5 for ptrace.])
1227 fi
1228
1229 dnl AC_FUNC_SETPGRP does not work when cross compiling
1230 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
1231 if test "$cross_compiling" = no; then
1232   AC_FUNC_SETPGRP
1233 else
1234   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
1235     [AC_TRY_COMPILE([
1236 #include <unistd.h>
1237 ], [
1238   if (setpgrp(1,1) == -1)
1239     exit (0);
1240   else
1241     exit (1);
1242 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
1243 if test $ac_cv_func_setpgrp_void = yes; then
1244   AC_DEFINE(SETPGRP_VOID, 1)
1245 fi
1246 fi
1247
1248 # Check if sigsetjmp is available.  Using AC_CHECK_FUNCS won't do
1249 # since sigsetjmp might only be defined as a macro.
1250 AC_CACHE_CHECK([for sigsetjmp], gdb_cv_func_sigsetjmp,
1251 [AC_TRY_COMPILE([
1252 #include <setjmp.h>
1253 ], [sigjmp_buf env; while (! sigsetjmp (env, 1)) siglongjmp (env, 1);],
1254 gdb_cv_func_sigsetjmp=yes, gdb_cv_func_sigsetjmp=no)])
1255 if test $gdb_cv_func_sigsetjmp = yes; then
1256   AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available. ])
1257 fi
1258
1259 # Assume we'll default to using the included libiberty regex.
1260 gdb_use_included_regex=yes
1261
1262 # However, if the system regex is GNU regex, then default to *not*
1263 # using the included regex.
1264 AC_CACHE_CHECK(
1265   [for GNU regex],
1266   [gdb_cv_have_gnu_regex],
1267   [AC_TRY_COMPILE(
1268     [#include <gnu-versions.h>],
1269     [#define REGEX_INTERFACE_VERSION 1
1270 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
1271 # error "Version mismatch"
1272 #endif],
1273     gdb_cv_have_gnu_regex=yes,
1274     gdb_cv_have_gnu_regex=no)])
1275 if test $gdb_cv_have_gnu_regex = yes; then
1276   gdb_use_included_regex=no
1277 fi
1278
1279 AC_ARG_WITH(included-regex,
1280   AS_HELP_STRING([--without-included-regex], [don't use included regex; this is the default on systems with version 2 of the GNU C library (use with caution on other system)]),
1281   gdb_with_regex=$withval,
1282   gdb_with_regex=$gdb_use_included_regex)
1283 if test "$gdb_with_regex" = yes; then
1284   AC_DEFINE(USE_INCLUDED_REGEX, 1,
1285     [Define to 1 if the regex included in libiberty should be used.])
1286 fi
1287
1288 # Check if <sys/proc.h> defines `struct thread' with a td_pcb member.
1289 AC_CHECK_MEMBERS([struct thread.td_pcb], [], [],
1290 [#include <sys/param.h>
1291 #include <sys/proc.h>
1292 ])
1293
1294 # See if <sys/lwp.h> defines `struct lwp`.
1295 AC_CACHE_CHECK([for struct lwp], gdb_cv_struct_lwp,
1296 [AC_TRY_COMPILE([#include <sys/param.h>
1297 #include <sys/lwp.h>], [struct lwp l;],
1298 gdb_cv_struct_lwp=yes, gdb_cv_struct_lwp=no)])
1299 if test $gdb_cv_struct_lwp = yes; then
1300   AC_DEFINE(HAVE_STRUCT_LWP, 1,
1301             [Define to 1 if your system has struct lwp.])
1302 fi
1303
1304 # See if <machine/reg.h> degines `struct reg'.
1305 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
1306 [AC_TRY_COMPILE([#include <sys/types.h>
1307 #include <machine/reg.h>], [struct reg r;],
1308 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
1309 if test $gdb_cv_struct_reg = yes; then
1310   AC_DEFINE(HAVE_STRUCT_REG, 1,
1311             [Define to 1 if your system has struct reg in <machine/reg.h>.])
1312 fi
1313
1314 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
1315 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
1316 AC_CHECK_MEMBERS([struct reg.r_fs, struct reg.r_gs], [], [],
1317                  [#include <machine/reg.h>])
1318
1319 # See if <sys/user.h> supports the %fs_base and %gs_bas amd64 segment registers.
1320 # Older amd64 Linux's don't have the fs_base and gs_base members of
1321 # `struct user_regs_struct'.
1322 AC_CHECK_MEMBERS([struct user_regs_struct.fs_base, struct user_regs_struct.gs_base],
1323                  [], [], [#include <sys/user.h>])
1324
1325 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
1326 AC_MSG_CHECKING(for PTRACE_GETREGS)
1327 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
1328 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1329                 [PTRACE_GETREGS;],
1330                 [gdb_cv_have_ptrace_getregs=yes],
1331                 [gdb_cv_have_ptrace_getregs=no])])
1332 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
1333 if test $gdb_cv_have_ptrace_getregs = yes; then
1334   AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
1335   [Define if sys/ptrace.h defines the PTRACE_GETREGS request.])
1336 fi
1337
1338 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
1339 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
1340 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
1341 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1342                 [PTRACE_GETFPXREGS;],
1343                 [gdb_cv_have_ptrace_getfpxregs=yes],
1344                 [gdb_cv_have_ptrace_getfpxregs=no])])
1345 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
1346 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
1347   AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
1348   [Define if sys/ptrace.h defines the PTRACE_GETFPXREGS request.])
1349 fi
1350
1351 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
1352 AC_MSG_CHECKING(for PT_GETDBREGS)
1353 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
1354 [AC_TRY_COMPILE([#include <sys/types.h>
1355 #include <sys/ptrace.h>],
1356                 [PT_GETDBREGS;],
1357                 [gdb_cv_have_pt_getdbregs=yes],
1358                 [gdb_cv_have_pt_getdbregs=no])])
1359 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
1360 if test $gdb_cv_have_pt_getdbregs = yes; then
1361   AC_DEFINE(HAVE_PT_GETDBREGS, 1,
1362   [Define if sys/ptrace.h defines the PT_GETDBREGS request.])
1363 fi
1364
1365 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
1366 AC_MSG_CHECKING(for PT_GETXMMREGS)
1367 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
1368 [AC_TRY_COMPILE([#include <sys/types.h>
1369 #include <sys/ptrace.h>],
1370                 [PT_GETXMMREGS;],
1371                 [gdb_cv_have_pt_getxmmregs=yes],
1372                 [gdb_cv_have_pt_getxmmregs=no])])
1373 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
1374 if test $gdb_cv_have_pt_getxmmregs = yes; then
1375   AC_DEFINE(HAVE_PT_GETXMMREGS, 1,
1376   [Define if sys/ptrace.h defines the PT_GETXMMREGS request.])
1377 fi
1378
1379 # Detect which type of /proc is in use, such as for Unixware or Solaris.
1380
1381 if test "${target}" = "${host}"; then
1382   case "${host}" in
1383   *-*-unixware* | *-*-sysv4.2* | *-*-sysv5* | *-*-interix* )
1384       AC_DEFINE(NEW_PROC_API, 1,
1385       [Define if you want to use new multi-fd /proc interface
1386        (replaces HAVE_MULTIPLE_PROC_FDS as well as other macros).])
1387       ;;
1388   *-*-solaris2.[[6789]] | *-*-solaris2.1[[0-9]]*)
1389       AC_DEFINE(NEW_PROC_API, 1,
1390       [Define if you want to use new multi-fd /proc interface
1391        (replaces HAVE_MULTIPLE_PROC_FDS as well as other macros).])
1392       ;;
1393   mips-sgi-irix5*)
1394       # Work around <sys/proc.h> needing _KMEMUSER problem on IRIX 5.
1395       AC_DEFINE([_KMEMUSER], 1,
1396       [Define to 1 so <sys/proc.h> gets a definition of anon_hdl.  Works
1397        around a <sys/proc.h> problem on IRIX 5.])
1398       ;;
1399   esac
1400 fi
1401
1402 if test "$ac_cv_header_sys_procfs_h" = yes; then
1403   BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
1404   BFD_HAVE_SYS_PROCFS_TYPE(prrun_t)
1405   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
1406   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
1407   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
1408   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
1409   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
1410   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset32_t)
1411   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
1412   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
1413   BFD_HAVE_SYS_PROCFS_TYPE(prsysent_t)
1414   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigset_t)
1415   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigaction64_t)
1416   BFD_HAVE_SYS_PROCFS_TYPE(pr_siginfo64_t)
1417
1418
1419   dnl Check for broken prfpregset_t type
1420
1421   dnl For Linux/i386, glibc 2.1.3 was released with a bogus
1422   dnl prfpregset_t type (it's a typedef for the pointer to a struct
1423   dnl instead of the struct itself).  We detect this here, and work
1424   dnl around it in gdb_proc_service.h.
1425
1426   if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
1427     AC_MSG_CHECKING(whether prfpregset_t type is broken)
1428     AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
1429       [AC_TRY_RUN([#include <sys/procfs.h>
1430        int main ()
1431        {
1432          if (sizeof (prfpregset_t) == sizeof (void *))
1433            return 1;
1434          return 0;
1435        }],
1436        gdb_cv_prfpregset_t_broken=no,
1437        gdb_cv_prfpregset_t_broken=yes,
1438        gdb_cv_prfpregset_t_broken=yes)])
1439     AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
1440     if test $gdb_cv_prfpregset_t_broken = yes; then
1441       AC_DEFINE(PRFPREGSET_T_BROKEN, 1,
1442       [Define if the prfpregset_t type is broken.])
1443     fi
1444   fi
1445
1446   dnl Check for PIOCSET ioctl entry
1447
1448   AC_MSG_CHECKING(for PIOCSET ioctl entry in sys/procfs.h)
1449   AC_CACHE_VAL(gdb_cv_have_procfs_piocset,
1450   [AC_TRY_COMPILE([#include <unistd.h>
1451 #include <sys/types.h>
1452 #include <sys/procfs.h>
1453 ], [
1454     int dummy;;
1455     dummy = ioctl(0, PIOCSET, &dummy);
1456   ],
1457   gdb_cv_have_procfs_piocset=yes, gdb_cv_have_procfs_piocset=no)])
1458   AC_MSG_RESULT($gdb_cv_have_procfs_piocset)
1459   if test $gdb_cv_have_procfs_piocset = yes; then
1460     AC_DEFINE(HAVE_PROCFS_PIOCSET, 1,
1461     [Define if ioctl argument PIOCSET is available.])
1462   fi
1463 fi
1464
1465 dnl For native ports (host == target), check to see what kind of
1466 dnl legacy link.h support is needed.  (See solib-legacy.c.)
1467 if test ${host} = ${target} ; then
1468   dnl Check for struct link_map with l_ members which are indicative
1469   dnl of SVR4-like shared libraries
1470
1471   AC_MSG_CHECKING(for member l_addr in struct link_map)
1472   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_l_members,
1473     [AC_TRY_COMPILE([#include <link.h>],
1474                     [struct link_map lm; (void) lm.l_addr;],
1475                     gdb_cv_have_struct_link_map_with_l_members=yes,
1476                     gdb_cv_have_struct_link_map_with_l_members=no)])
1477   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_l_members)
1478   if test $gdb_cv_have_struct_link_map_with_l_members = yes; then
1479     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_L_MEMBERS,1,
1480     [Define if <link.h> exists and defines struct link_map which has
1481      members with an ``l_'' prefix.  (For Solaris, SVR4, and
1482      SVR4-like systems.)])
1483   fi
1484
1485   dnl Check for struct link_map with lm_ members which are indicative
1486   dnl of SunOS-like shared libraries
1487
1488   AC_MSG_CHECKING(for member lm_addr in struct link_map)
1489   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_lm_members,
1490     [AC_TRY_COMPILE([#include <sys/types.h>
1491 #include <link.h>],
1492                     [struct link_map lm; (void) lm.lm_addr;],
1493                     gdb_cv_have_struct_link_map_with_lm_members=yes,
1494                     gdb_cv_have_struct_link_map_with_lm_members=no)])
1495   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_lm_members)
1496   if test $gdb_cv_have_struct_link_map_with_lm_members = yes; then
1497     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_LM_MEMBERS, 1,
1498     [Define if <link.h> exists and defines struct link_map which has
1499      members with an ``lm_'' prefix.  (For SunOS.)])
1500   fi
1501
1502   dnl Check for struct so_map with som_ members which are found on
1503   dnl some *BSD systems.
1504
1505   AC_MSG_CHECKING(for member som_addr in struct so_map)
1506   AC_CACHE_VAL(gdb_cv_have_struct_so_map_with_som_members,
1507     [AC_TRY_COMPILE([#include <sys/types.h>
1508 #ifdef HAVE_NLIST_H
1509 #include <nlist.h>
1510 #endif
1511 #include <link.h>],
1512                     [struct so_map lm; (void) lm.som_addr;],
1513                     gdb_cv_have_struct_so_map_with_som_members=yes,
1514                     gdb_cv_have_struct_so_map_with_som_members=no)])
1515   AC_MSG_RESULT($gdb_cv_have_struct_so_map_with_som_members)
1516   if test $gdb_cv_have_struct_so_map_with_som_members = yes; then
1517     AC_DEFINE(HAVE_STRUCT_SO_MAP_WITH_SOM_MEMBERS, 1,
1518     [Define if <link.h> exists and defines a struct so_map which has
1519      members with an ``som_'' prefix.  (Found on older *BSD systems.)])
1520   fi
1521
1522   dnl Check for struct link_map32 type, which allows a 64-bit Solaris
1523   dnl debugger to debug a 32-bit Solaris app with 32-bit shared libraries.
1524
1525   AC_MSG_CHECKING(for struct link_map32 in sys/link.h)
1526   AC_CACHE_VAL(gdb_cv_have_struct_link_map32,
1527     [AC_TRY_COMPILE([#define _SYSCALL32
1528 #include <sys/link.h>], [struct link_map32 l;],
1529      gdb_cv_have_struct_link_map32=yes,
1530      gdb_cv_have_struct_link_map32=no)])
1531   AC_MSG_RESULT($gdb_cv_have_struct_link_map32)
1532   if test $gdb_cv_have_struct_link_map32 = yes; then
1533     AC_DEFINE(HAVE_STRUCT_LINK_MAP32, 1,
1534     [Define if <sys/link.h> has struct link_map32])
1535     AC_DEFINE(_SYSCALL32, 1,
1536     [Define if <sys/link.h> has link_map32 (solaris sparc-64 target)])
1537   fi
1538 fi
1539
1540 # Check if the compiler supports the `long long' type.
1541
1542 AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long,
1543                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1544 [[extern long long foo;]],
1545 [[switch (foo & 2) { case 0: return 1; }]])],
1546                                   gdb_cv_c_long_long=yes,
1547                                   gdb_cv_c_long_long=no)])
1548 if test $gdb_cv_c_long_long = yes; then
1549   AC_DEFINE(CC_HAS_LONG_LONG, 1,
1550             [Define to 1 if the compiler supports long long.])
1551 fi
1552
1553 # Check if the compiler and runtime support printing long longs.
1554
1555 AC_CACHE_CHECK([for long long support in printf],
1556                gdb_cv_printf_has_long_long,
1557                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1558 [[char buf[32];
1559   long long l = 0;
1560   l = (l << 16) + 0x0123;
1561   l = (l << 16) + 0x4567;
1562   l = (l << 16) + 0x89ab;
1563   l = (l << 16) + 0xcdef;
1564   sprintf (buf, "0x%016llx", l);
1565   return (strcmp ("0x0123456789abcdef", buf));]])],
1566                               gdb_cv_printf_has_long_long=yes,
1567                               gdb_cv_printf_has_long_long=no,
1568                               gdb_cv_printf_has_long_long=no)])
1569 if test $gdb_cv_printf_has_long_long = yes; then
1570   AC_DEFINE(PRINTF_HAS_LONG_LONG, 1,
1571             [Define to 1 if the "%ll" format works to print long longs.])
1572 fi
1573
1574 # Check if the compiler and runtime support printing decfloats.
1575
1576 AC_CACHE_CHECK([for decfloat support in printf],
1577                gdb_cv_printf_has_decfloat,
1578                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1579 [[char buf[64];
1580   _Decimal32 d32 = 1.2345df;
1581   _Decimal64 d64 = 1.2345dd;
1582   _Decimal128 d128 = 1.2345dl;
1583   sprintf (buf, "Decimal32: %H\nDecimal64: %D\nDecimal128: %DD", d32, d64, d128);
1584   return (strcmp ("Decimal32: 1.2345\nDecimal64: 1.2345\nDecimal128: 1.2345", buf));]])],
1585                               gdb_cv_printf_has_decfloat=yes,
1586                               gdb_cv_printf_has_decfloat=no,
1587                               gdb_cv_printf_has_decfloat=no)])
1588 if test $gdb_cv_printf_has_decfloat = yes; then
1589   AC_DEFINE(PRINTF_HAS_DECFLOAT, 1,
1590             [Define to 1 if the "%H, %D and %DD" formats work to print decfloats.])
1591 fi
1592
1593 # Check if the compiler supports the `long double' type.  We can't use
1594 # AC_C_LONG_DOUBLE because that one does additional checks on the
1595 # constants defined in <float.h> that fail on some systems,
1596 # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6.
1597
1598 AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double,
1599                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])],
1600                                   gdb_cv_c_long_double=yes,
1601                                   gdb_cv_c_long_double=no)])
1602 if test $gdb_cv_c_long_double = yes; then
1603   AC_DEFINE(HAVE_LONG_DOUBLE, 1,
1604            [Define to 1 if the compiler supports long double.])
1605 fi
1606
1607 # Check if the compiler and runtime support printing long doubles.
1608
1609 AC_CACHE_CHECK([for long double support in printf],
1610                gdb_cv_printf_has_long_double,
1611                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1612 [[char buf[16];
1613   long double f = 3.141592653;
1614   sprintf (buf, "%Lg", f);
1615   return (strncmp ("3.14159", buf, 7));]])],
1616                               gdb_cv_printf_has_long_double=yes,
1617                               gdb_cv_printf_has_long_double=no,
1618                               gdb_cv_printf_has_long_double=no)])
1619 if test $gdb_cv_printf_has_long_double = yes; then
1620   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1,
1621             [Define to 1 if the "%Lg" format works to print long doubles.])
1622 fi
1623
1624 # Check if the compiler and runtime support scanning long doubles.
1625
1626 AC_CACHE_CHECK([for long double support in scanf],
1627                gdb_cv_scanf_has_long_double,
1628                [AC_RUN_IFELSE([AC_LANG_PROGRAM(
1629 [[#include <stdio.h>]],
1630 [[char *buf = "3.141592653";
1631   long double f = 0;
1632   sscanf (buf, "%Lg", &f);
1633   return !(f > 3.14159 && f < 3.14160);]])],
1634                               gdb_cv_scanf_has_long_double=yes,
1635                               gdb_cv_scanf_has_long_double=no,
1636                               gdb_cv_scanf_has_long_double=no)])
1637 if test $gdb_cv_scanf_has_long_double = yes; then
1638   AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1,
1639             [Define to 1 if the "%Lg" format works to scan long doubles.])
1640 fi
1641
1642 case ${host_os} in
1643 aix*)
1644   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1645     SAVE_LDFLAGS=$LDFLAGS
1646
1647     case $GCC in
1648     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1649     *) gdb_cv_bigtoc=-bbigtoc ;;
1650     esac
1651
1652     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1653     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1654     LDFLAGS="${SAVE_LDFLAGS}"
1655   ])
1656   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
1657   ;;
1658 esac
1659
1660 AC_MSG_CHECKING(for the dynamic export flag)
1661 dynamic_list=false
1662 if test "${gdb_native}" = yes; then
1663    # The dynamically loaded libthread_db needs access to symbols in the gdb
1664    # executable.  Older GNU ld supports --export-dynamic but --dynamic-list
1665    # may not be supported there.
1666    old_LDFLAGS="$LDFLAGS"
1667    # Older GNU ld supports --export-dynamic but --dynamic-list it does not.
1668    RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
1669    LDFLAGS="$LDFLAGS $RDYNAMIC"
1670    if test "${have_libpython}" = no; then
1671      AC_TRY_LINK([], [], [dynamic_list=true])
1672    else
1673      # Workaround http://bugs.python.org/issue4434 where static
1674      # libpythonX.Y.a would get its symbols required for
1675      # pythonX.Y/lib-dynload/*.so modules hidden by -Wl,--dynamic-list.
1676      # Problem does not happen for the recommended libpythonX.Y.so linkage.
1677      old_CFLAGS="$CFLAGS"
1678      CFLAGS="$CFLAGS $PYTHON_CFLAGS"
1679      AC_RUN_IFELSE(
1680        AC_LANG_PROGRAM(
1681          [#include "]${have_libpython}[/Python.h"],
1682          [int err;
1683           Py_Initialize ();
1684           err = PyRun_SimpleString ("import itertools\n");
1685           Py_Finalize ();
1686           return err == 0 ? 0 : 1;]),
1687        [dynamic_list=true], [], [true])
1688      CFLAGS="$old_CFLAGS"
1689    fi
1690    LDFLAGS="$old_LDFLAGS"
1691 fi
1692 if $dynamic_list; then
1693   found="-Wl,--dynamic-list"
1694   RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'
1695 else
1696   found="-rdynamic"
1697   RDYNAMIC="-rdynamic"
1698 fi
1699 AC_SUBST(RDYNAMIC)
1700 AC_MSG_RESULT($found)
1701
1702 dnl For certain native configurations, we need to check whether thread
1703 dnl support can be built in or not.
1704 dnl
1705 dnl Note that we only want this if we are both native (host == target),
1706 dnl and not doing a canadian cross build (build == host).
1707
1708 if test ${build} = ${host} -a ${host} = ${target} ; then
1709    case ${host_os} in
1710    solaris*)
1711       # See if thread_db library is around for Solaris thread debugging.
1712       # Note that we must explicitly test for version 1 of the library
1713       # because version 0 (present on Solaris 2.4 or earlier) doesn't have
1714       # the same API.
1715       AC_MSG_CHECKING(for Solaris thread debugging library)
1716       if test -f /usr/lib/libthread_db.so.1 ; then
1717          AC_MSG_RESULT(yes)
1718          AC_DEFINE(HAVE_THREAD_DB_LIB, 1,
1719          [Define if using Solaris thread debugging.])
1720          CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
1721          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
1722          AC_CHECK_LIB(dl, dlopen)
1723          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} $RDYNAMIC"
1724          # Sun randomly tweaked the prototypes in <proc_service.h>
1725          # at one point.
1726          AC_MSG_CHECKING(if <proc_service.h> is old)
1727          AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
1728             AC_TRY_COMPILE([
1729                 #include <proc_service.h>
1730                 ps_err_e ps_pdwrite
1731                     (struct ps_prochandle*, psaddr_t, const void*, size_t);
1732             ],, gdb_cv_proc_service_is_old=no,
1733                 gdb_cv_proc_service_is_old=yes)
1734          ])
1735          AC_MSG_RESULT($gdb_cv_proc_service_is_old)
1736          if test $gdb_cv_proc_service_is_old = yes; then
1737             AC_DEFINE(PROC_SERVICE_IS_OLD, 1,
1738             [Define if <proc_service.h> on solaris uses int instead of
1739              size_t, and assorted other type changes.])
1740          fi
1741       else
1742          AC_MSG_RESULT(no)
1743       fi
1744       ;;
1745    aix*)
1746       AC_MSG_CHECKING(for AiX thread debugging library)
1747       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
1748                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
1749                                    [#ifndef PTHDB_VERSION_3
1750                                     #error
1751                                     #endif],
1752                                    gdb_cv_have_aix_thread_debug=yes,
1753                                    gdb_cv_have_aix_thread_debug=no)])
1754       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1755       if test $gdb_cv_have_aix_thread_debug = yes; then
1756          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1757          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1758          LIBS="$LIBS -lpthdebug"
1759
1760          # Older versions of AIX do not provide the declaration for
1761          # the getthrds function (it appears that it was introduced
1762          # with AIX 6.x).
1763          AC_CHECK_DECLS(getthrds, [], [], [[#include <procinfo.h>]])
1764       fi
1765       ;;
1766    esac
1767    AC_SUBST(CONFIG_LDFLAGS)
1768 fi
1769
1770 dnl See if we have a thread_db header file that has TD_NOTALLOC and
1771 dnl other error codes.
1772 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1773    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
1774                   gdb_cv_thread_db_h_has_td_notalloc,
1775      AC_TRY_COMPILE(
1776        [#include <thread_db.h>],
1777        [int i = TD_NOTALLOC;],
1778        gdb_cv_thread_db_h_has_td_notalloc=yes,
1779        gdb_cv_thread_db_h_has_td_notalloc=no
1780      )
1781    )
1782    AC_CACHE_CHECK([whether <thread_db.h> has TD_VERSION],
1783                   gdb_cv_thread_db_h_has_td_version,
1784      AC_TRY_COMPILE(
1785        [#include <thread_db.h>],
1786        [int i = TD_VERSION;],
1787        gdb_cv_thread_db_h_has_td_version=yes,
1788        gdb_cv_thread_db_h_has_td_version=no
1789      )
1790    )
1791    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTLS],
1792                   gdb_cv_thread_db_h_has_td_notls,
1793      AC_TRY_COMPILE(
1794        [#include <thread_db.h>],
1795        [int i = TD_NOTLS;],
1796        gdb_cv_thread_db_h_has_td_notls=yes,
1797        gdb_cv_thread_db_h_has_td_notls=no
1798      )
1799    )
1800 fi
1801 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1802   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1803             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1804 fi
1805 if test "x$gdb_cv_thread_db_h_has_td_version" = "xyes"; then
1806   AC_DEFINE(THREAD_DB_HAS_TD_VERSION, 1,
1807             [Define if <thread_db.h> has the TD_VERSION error code.])
1808 fi
1809 if test "x$gdb_cv_thread_db_h_has_td_notls" = "xyes"; then
1810   AC_DEFINE(THREAD_DB_HAS_TD_NOTLS, 1,
1811             [Define if <thread_db.h> has the TD_NOTLS error code.])
1812 fi
1813
1814 dnl See if we have a sys/syscall header file that has __NR_tkill.
1815 if test "x$ac_cv_header_sys_syscall_h" = "xyes"; then
1816    AC_CACHE_CHECK([whether <sys/syscall.h> has __NR_tkill],
1817                   gdb_cv_sys_syscall_h_has_tkill,
1818      AC_TRY_COMPILE(
1819        [#include <sys/syscall.h>],
1820        [int i = __NR_tkill;],
1821        gdb_cv_sys_syscall_h_has_tkill=yes,
1822        gdb_cv_sys_syscall_h_has_tkill=no
1823      )
1824    )
1825 fi
1826 dnl See if we can issue tkill syscall.
1827 if test "x$gdb_cv_sys_syscall_h_has_tkill" = "xyes" && test "x$ac_cv_func_syscall" = "xyes"; then
1828   AC_DEFINE(HAVE_TKILL_SYSCALL, 1, [Define if you support the tkill syscall.])
1829 fi
1830
1831 dnl Check if we can disable the virtual address space randomization.
1832 dnl The functionality of setarch -R.
1833 AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>])
1834 define([PERSONALITY_TEST], [AC_LANG_PROGRAM([#include <sys/personality.h>], [
1835 #      if !HAVE_DECL_ADDR_NO_RANDOMIZE
1836 #       define ADDR_NO_RANDOMIZE 0x0040000
1837 #      endif
1838        /* Test the flag could be set and stays set.  */
1839        personality (personality (0xffffffff) | ADDR_NO_RANDOMIZE);
1840        if (!(personality (personality (0xffffffff)) & ADDR_NO_RANDOMIZE))
1841            return 1])])
1842 AC_RUN_IFELSE([PERSONALITY_TEST],
1843               [have_personality=true],
1844               [have_personality=false],
1845               [AC_LINK_IFELSE([PERSONALITY_TEST],
1846                               [have_personality=true],
1847                               [have_personality=false])])
1848 if $have_personality
1849 then
1850     AC_DEFINE([HAVE_PERSONALITY], 1,
1851               [Define if you support the personality syscall.])
1852 fi
1853
1854 dnl Handle optional features that can be enabled.
1855
1856 # Support for --with-sysroot is a copy of GDB_AC_WITH_DIR,
1857 # except that the argument to --with-sysroot is optional.
1858 # --with-sysroot (or --with-sysroot=yes) sets the default sysroot path.
1859 if test "x$with_sysroot" = xyes; then
1860   with_sysroot="${exec_prefix}/${target_alias}/sys-root"
1861 fi
1862 AC_ARG_WITH(sysroot,
1863   AS_HELP_STRING([--with-sysroot@<:@=DIR@:>@],
1864                  [search for usr/lib et al within DIR]),
1865   [TARGET_SYSTEM_ROOT=$withval], [TARGET_SYSTEM_ROOT=])
1866 AC_DEFINE_DIR(TARGET_SYSTEM_ROOT, TARGET_SYSTEM_ROOT,
1867               [search for usr/lib et al within DIR])
1868 AC_SUBST(TARGET_SYSTEM_ROOT)
1869 GDB_AC_DEFINE_RELOCATABLE(TARGET_SYSTEM_ROOT, sysroot, ${ac_define_dir})
1870
1871 GDB_AC_WITH_DIR(SYSTEM_GDBINIT, system-gdbinit,
1872     [automatically load a system-wide gdbinit file],
1873     [])
1874
1875 AC_ARG_ENABLE(werror,
1876   AS_HELP_STRING([--enable-werror], [treat compile warnings as errors]),
1877   [case "${enableval}" in
1878      yes | y) ERROR_ON_WARNING="yes" ;;
1879      no | n)  ERROR_ON_WARNING="no" ;;
1880      *) AC_MSG_ERROR(bad value ${enableval} for --enable-werror) ;;
1881    esac])
1882
1883 # Enable -Werror by default when using gcc.  Turn it off for releases.
1884 if test "${GCC}" = yes -a -z "${ERROR_ON_WARNING}" && $development; then
1885     ERROR_ON_WARNING=yes
1886 fi
1887
1888 WERROR_CFLAGS=""
1889 if test "${ERROR_ON_WARNING}" = yes ; then
1890     WERROR_CFLAGS="-Werror"
1891 fi
1892
1893 # The entries after -Wno-pointer-sign are disabled warnings which may
1894 # be enabled in the future, which can not currently be used to build
1895 # GDB.
1896 # NOTE: If you change this list, remember to update
1897 # gdb/doc/gdbint.texinfo.
1898 build_warnings="-Wall -Wdeclaration-after-statement -Wpointer-arith \
1899 -Wformat-nonliteral -Wno-pointer-sign \
1900 -Wno-unused -Wunused-value -Wunused-function \
1901 -Wno-switch -Wno-char-subscripts -Wmissing-prototypes \
1902 -Wdeclaration-after-statement"
1903
1904 # Enable -Wno-format by default when using gcc on mingw since many
1905 # GCC versions complain about %I64.
1906 case "${host}" in
1907   *-*-mingw32*) build_warnings="$build_warnings -Wno-format" ;;
1908 esac
1909
1910 AC_ARG_ENABLE(build-warnings,
1911 AS_HELP_STRING([--enable-build-warnings], [enable build-time compiler warnings if gcc is used]),
1912 [case "${enableval}" in
1913   yes)  ;;
1914   no)   build_warnings="-w";;
1915   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1916         build_warnings="${build_warnings} ${t}";;
1917   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1918         build_warnings="${t} ${build_warnings}";;
1919   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1920 esac
1921 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1922   echo "Setting compiler warning flags = $build_warnings" 6>&1
1923 fi])dnl
1924 AC_ARG_ENABLE(gdb-build-warnings,
1925 AS_HELP_STRING([--enable-gdb-build-warnings], [enable GDB specific build-time compiler warnings if gcc is used]),
1926 [case "${enableval}" in
1927   yes)  ;;
1928   no)   build_warnings="-w";;
1929   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1930         build_warnings="${build_warnings} ${t}";;
1931   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1932         build_warnings="${t} ${build_warnings}";;
1933   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1934 esac
1935 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1936   echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1
1937 fi])dnl
1938 WARN_CFLAGS=""
1939 if test "x${build_warnings}" != x -a "x$GCC" = xyes
1940 then
1941     AC_MSG_CHECKING(compiler warning flags)
1942     # Separate out the -Werror flag as some files just cannot be
1943     # compiled with it enabled.
1944     for w in ${build_warnings}; do
1945         case $w in
1946         -Werr*) WERROR_CFLAGS=-Werror ;;
1947         *) # Check that GCC accepts it
1948             saved_CFLAGS="$CFLAGS"
1949             CFLAGS="$CFLAGS $w"
1950             AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
1951             CFLAGS="$saved_CFLAGS"
1952         esac
1953     done
1954     AC_MSG_RESULT(${WARN_CFLAGS} ${WERROR_CFLAGS})
1955 fi
1956 AC_SUBST(WARN_CFLAGS)
1957 AC_SUBST(WERROR_CFLAGS)
1958
1959 # In the Cygwin environment, we need some additional flags.
1960 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1961 [AC_EGREP_CPP(lose, [
1962 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1963 lose
1964 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1965
1966
1967 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1968 SER_HARDWIRE="ser-base.o ser-unix.o ser-pipe.o ser-tcp.o"
1969 case ${host} in
1970   *go32* ) SER_HARDWIRE=ser-go32.o ;;
1971   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
1972   *mingw32*) SER_HARDWIRE="ser-base.o ser-tcp.o ser-mingw.o" ;;
1973 esac
1974 AC_SUBST(SER_HARDWIRE)
1975
1976 # libreadline needs libuser32.a in a cygwin environment
1977 WIN32LIBS=
1978 if test x$gdb_cv_os_cygwin = xyes; then
1979     WIN32LIBS="-luser32"
1980     case "${target}" in
1981         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
1982         ;;
1983     esac
1984 fi
1985
1986 # The ser-tcp.c module requires sockets.
1987 case ${host} in
1988   *mingw32*)
1989     AC_DEFINE(USE_WIN32API, 1,
1990               [Define if we should use the Windows API, instead of the
1991                POSIX API.  On Windows, we use the Windows API when
1992                building for MinGW, but the POSIX API when building
1993                for Cygwin.])
1994     WIN32LIBS="$WIN32LIBS -lws2_32"
1995     ;;
1996 esac
1997 AC_SUBST(WIN32LIBS)
1998
1999 # Add ELF support to GDB, but only if BFD includes ELF support.
2000 OLD_CFLAGS=$CFLAGS
2001 OLD_LDFLAGS=$LDFLAGS
2002 OLD_LIBS=$LIBS
2003 # Put the old CFLAGS/LDFLAGS last, in case the user's (C|LD)FLAGS
2004 # points somewhere with bfd, with -I/foo/lib and -L/foo/lib.  We
2005 # always want our bfd.
2006 CFLAGS="-I${srcdir}/../include -I../bfd -I${srcdir}/../bfd $CFLAGS"
2007 LDFLAGS="-L../bfd -L../libiberty $LDFLAGS"
2008 intl=`echo $LIBINTL | sed 's,${top_builddir}/,,g'`
2009 # -ldl is provided by bfd/Makfile.am (LIBDL) <PLUGINS>.
2010 if test "$plugins" = "yes"; then
2011   LIBS="-ldl $LIBS"
2012 fi
2013 LIBS="-lbfd -liberty $intl $LIBS"
2014 AC_CACHE_CHECK([for ELF support in BFD], gdb_cv_var_elf,
2015 [AC_TRY_LINK(
2016 [#include <stdlib.h>
2017 #include "bfd.h"
2018 #include "elf-bfd.h"
2019 ],
2020 [bfd *abfd = NULL; bfd_get_elf_phdr_upper_bound (abfd); ],
2021 gdb_cv_var_elf=yes, gdb_cv_var_elf=no)])
2022 if test $gdb_cv_var_elf = yes; then
2023   CONFIG_OBS="$CONFIG_OBS elfread.o stap-probe.o"
2024   AC_DEFINE(HAVE_ELF, 1,
2025             [Define if ELF support should be included.])
2026   # -ldl is provided by bfd/Makfile.am (LIBDL) <PLUGINS>.
2027   if test "$plugins" = "yes"; then
2028     OLD_LIBS="-ldl $OLD_LIBS"
2029   fi
2030 fi
2031 CFLAGS=$OLD_CFLAGS
2032 LDFLAGS=$OLD_LDFLAGS
2033 LIBS=$OLD_LIBS
2034
2035 # Add any host-specific objects to GDB.
2036 CONFIG_OBS="${CONFIG_OBS} ${gdb_host_obs}"
2037
2038 LIBGUI="../libgui/src/libgui.a"
2039 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
2040 AC_SUBST(LIBGUI)
2041 AC_SUBST(GUI_CFLAGS_X)
2042
2043 WIN32LDAPP=
2044 AC_SUBST(WIN32LIBS)
2045 AC_SUBST(WIN32LDAPP)
2046
2047 case "${host}" in
2048 *-*-cygwin* | *-*-mingw* )
2049     configdir="win"
2050     ;;
2051 *)
2052     configdir="unix"
2053     ;;
2054 esac
2055
2056 GDBTKLIBS=
2057 if test "${enable_gdbtk}" = "yes"; then
2058
2059     # Gdbtk must have an absolute path to srcdir in order to run
2060     # properly when not installed.
2061     here=`pwd`
2062     cd ${srcdir}
2063     GDBTK_SRC_DIR=`pwd`
2064     cd $here
2065
2066     SC_PATH_TCLCONFIG
2067
2068     # If $no_tk is nonempty, then we can't do Tk, and there is no
2069     # point to doing Tcl.
2070     SC_PATH_TKCONFIG
2071
2072     if test -z "${no_tcl}" -a -z "${no_tk}"; then
2073         SC_LOAD_TCLCONFIG
2074
2075         # Check for in-tree tcl
2076         here=`pwd`
2077         cd ${srcdir}/..
2078         topdir=`pwd`
2079         cd ${here}
2080
2081         intree="no"
2082         if test "${TCL_SRC_DIR}" = "${topdir}/tcl"; then
2083           intree="yes"
2084         fi
2085
2086         # Find Tcl private headers
2087         if test x"${intree}" = xno; then
2088           CY_AC_TCL_PRIVATE_HEADERS
2089           TCL_INCLUDE="${TCL_INCLUDE_SPEC} ${TCL_PRIVATE_INCLUDE}"
2090           TCL_LIBRARY="${TCL_LIB_SPEC}"
2091           TCL_DEPS=""
2092         else
2093           # If building tcl in the same src tree, private headers
2094           # are not needed, but we need to be sure to use the right
2095           # headers library
2096           TCL_INCLUDE="-I${TCL_SRC_DIR}/generic"
2097           TCL_LIBRARY="${TCL_BUILD_LIB_SPEC}"
2098           TCL_DEPS="../tcl/${configdir}${TCL_LIB_FILE}"
2099         fi
2100         AC_SUBST(TCL_INCLUDE)
2101         AC_SUBST(TCL_LIBRARY)
2102         AC_SUBST(TCL_DEPS)
2103
2104         SC_LOAD_TKCONFIG
2105
2106         # Check for in-tree Tk
2107         intree="no"
2108         if test "${TK_SRC_DIR}" = "${topdir}/tk"; then
2109           intree="yes"
2110         fi
2111
2112         # Find Tk private headers
2113         if test x"${intree}" = xno; then
2114           CY_AC_TK_PRIVATE_HEADERS
2115           TK_INCLUDE="${TK_INCLUDE_SPEC} ${TK_PRIVATE_INCLUDE}"
2116           TK_LIBRARY=${TK_LIB_SPEC}
2117           TK_DEPS=""
2118         else
2119           TK_INCLUDE="-I${TK_SRC_DIR}/generic"
2120           TK_LIBRARY="${TK_BUILD_LIB_SPEC}"
2121           TK_DEPS="../tk/${configdir}/${TK_LIB_FILE}"
2122         fi
2123         AC_SUBST(TK_INCLUDE)
2124         AC_SUBST(TK_LIBRARY)
2125         AC_SUBST(TK_DEPS)
2126         AC_SUBST(TK_XINCLUDES)
2127
2128         ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
2129
2130         # Include some libraries that Tcl and Tk want.
2131         TCL_LIBS='$(LIBGUI) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
2132         # Yes, the ordering seems wrong here.  But it isn't.
2133         # TK_LIBS is the list of libraries that need to be linked
2134         # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
2135         # were in LIBS then any link tests after this point would
2136         # try to include things like `$(LIBGUI)', which wouldn't work.
2137         GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
2138
2139         CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
2140         CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
2141         CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
2142         CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
2143         CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
2144         CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
2145         CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
2146
2147         if test x$gdb_cv_os_cygwin = xyes; then
2148           WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
2149           WIN32LDAPP="-Wl,--subsystem,console"
2150           CONFIG_OBS="${CONFIG_OBS} gdbres.o"
2151         fi
2152
2153         AC_CONFIG_SUBDIRS(gdbtk)
2154     fi
2155 fi
2156
2157 AC_SUBST(X_CFLAGS)
2158 AC_SUBST(X_LDFLAGS)
2159 AC_SUBST(X_LIBS)
2160 AC_SUBST(GDBTKLIBS)
2161 AC_SUBST(GDBTK_CFLAGS)
2162 AC_SUBST(GDBTK_SRC_DIR)
2163
2164 AC_PATH_X
2165
2166 # Unlike the sim directory, whether a simulator is linked is controlled by
2167 # presence of a gdb_sim definition in the target configure.tgt entry.
2168 # This code just checks for a few cases where we'd like to ignore those
2169 # definitions, even when they're present in the '.mt' file.  These cases
2170 # are when --disable-sim is specified, or if the simulator directory is
2171 # not part of the source tree.
2172 #
2173 AC_ARG_ENABLE(sim,
2174 AS_HELP_STRING([--enable-sim], [link gdb with simulator]),
2175 [echo "enable_sim = $enable_sim";
2176  echo "enableval = ${enableval}";
2177  case "${enableval}" in
2178   yes) ignore_sim=false ;;
2179   no)  ignore_sim=true ;;
2180   *)   ignore_sim=false ;;
2181  esac],
2182 [ignore_sim=false])
2183
2184 if test ! -d "${srcdir}/../sim"; then
2185   ignore_sim=true
2186 fi
2187
2188 SIM=
2189 SIM_OBS=
2190 if test "${ignore_sim}" = "false"; then
2191   if test x"${gdb_sim}" != x ; then
2192     SIM="${gdb_sim}"
2193     SIM_OBS="remote-sim.o"
2194     AC_DEFINE(WITH_SIM, 1, [Define if the simulator is being linked in.])
2195   fi
2196 fi
2197 AC_SUBST(SIM)
2198 AC_SUBST(SIM_OBS)
2199
2200 AC_SUBST(ENABLE_CFLAGS)
2201 AC_SUBST(PROFILE_CFLAGS)
2202
2203 AC_SUBST(CONFIG_OBS)
2204 AC_SUBST(CONFIG_DEPS)
2205 AC_SUBST(CONFIG_SRCS)
2206 AC_SUBST(CONFIG_ALL)
2207 AC_SUBST(CONFIG_CLEAN)
2208 AC_SUBST(CONFIG_INSTALL)
2209 AC_SUBST(CONFIG_UNINSTALL)
2210
2211 # List of host floatformats.
2212 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
2213 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
2214 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
2215
2216 # target_subdir is used by the testsuite to find the target libraries.
2217 target_subdir=
2218 if test "${host}" != "${target}"; then
2219     target_subdir="${target_alias}/"
2220 fi
2221 AC_SUBST(target_subdir)
2222
2223 frags=
2224 if test "${gdb_native}" = "yes"; then
2225   host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
2226   if test ! -f ${host_makefile_frag}; then
2227     AC_MSG_ERROR("*** Gdb does not support native target ${host}")
2228   fi
2229   frags="$frags $host_makefile_frag"
2230 else
2231   host_makefile_frag=/dev/null
2232 fi
2233
2234 AC_SUBST_FILE(host_makefile_frag)
2235 AC_SUBST(frags)
2236
2237 changequote(,)dnl
2238 if test "${gdb_native}" = "yes"; then
2239 # We pick this up from the host configuration file (.mh) because we
2240 # do not have a native configuration Makefile fragment.
2241 nativefile=`sed -n '
2242 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
2243 ' ${host_makefile_frag}`
2244 fi
2245 changequote([,])
2246
2247 if test x"${gdb_osabi}" != x ; then
2248     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
2249                        [Define to the default OS ABI for this configuration.])
2250 fi
2251
2252 # Enable multi-ice-gdb-server.
2253 AC_ARG_ENABLE(multi-ice,
2254 AS_HELP_STRING([--enable-multi-ice], [build the multi-ice-gdb-server]),
2255   [case $enableval in
2256     yes | no)
2257       ;;
2258     *) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;;
2259   esac])
2260 if test "x$enable_multi_ice" = xyes; then
2261    AC_CONFIG_SUBDIRS(multi-ice)
2262 fi
2263
2264 AC_ARG_ENABLE(gdbserver,
2265 AS_HELP_STRING([--enable-gdbserver],
2266                [automatically build gdbserver (yes/no/auto, default is auto)]),
2267 [case "${enableval}" in
2268   yes| no|auto) ;;
2269   *) AC_MSG_ERROR(bad value ${enableval} for --enable-gdbserver option) ;;
2270 esac],[enable_gdbserver=auto])
2271
2272 # We only build gdbserver automatically in a native configuration, and
2273 # only if the user did not explicitly disable its build.
2274 if test "$gdb_native" = "yes" -a "$enable_gdbserver" != "no"; then
2275   AC_MSG_CHECKING(whether gdbserver is supported on this host)
2276   if test "x$build_gdbserver" = xyes; then
2277     AC_MSG_RESULT(yes)
2278     AC_CONFIG_SUBDIRS(gdbserver)
2279     gdbserver_build_enabled=yes
2280   else
2281     AC_MSG_RESULT(no)
2282   fi
2283 fi
2284
2285 # If the user explicitly request the gdbserver to be built, verify that
2286 # we were in fact able to enable it.
2287 if test "$enable_gdbserver" = "yes" -a "$gdbserver_build_enabled" != "yes"; then
2288   AC_MSG_ERROR(Automatic gdbserver build is not supported for this configuration)
2289 fi
2290
2291 # If nativefile (NAT_FILE) is not set in config/*/*.m[ht] files, we link
2292 # to an empty version.
2293
2294 files=
2295 links=
2296
2297 rm -f nm.h
2298 if test "${nativefile}" != ""; then
2299     case "${nativefile}" in
2300       nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
2301       * ) GDB_NM_FILE="${nativefile}"
2302     esac
2303     files="${files} ${GDB_NM_FILE}"
2304     links="${links} nm.h"
2305     AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}", [nativefile])
2306 fi
2307 AC_SUBST(GDB_NM_FILE)
2308
2309 AC_LINK_FILES($files, $links)
2310
2311 dnl Check for exe extension set on certain hosts (e.g. Win32)
2312 AC_EXEEXT
2313
2314 dnl  Detect the character set used by this host.
2315 dnl  At the moment, we just assume it's UTF-8.
2316 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "UTF-8",
2317           [Define to be a string naming the default host character set.])
2318
2319 AC_OUTPUT(Makefile gdb-gdb.gdb doc/Makefile data-directory/Makefile,
2320 [
2321 case x$CONFIG_HEADERS in
2322 xconfig.h:config.in)
2323 echo > stamp-h ;;
2324 esac
2325 ])
2326
2327 exit 0