gdb/configure.ac

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995-2013 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Process this file with autoconf to produce a configure script.
  20
  21 AC_PREREQ(2.59)dnl
  22 AC_INIT(main.c)
  23 AC_CONFIG_HEADER(config.h:config.in)
  24 AM_MAINTAINER_MODE
  25
  26 # Set the 'development' global.
  27 . $srcdir/development.sh
  28
  29 AC_PROG_CC
  30 AC_USE_SYSTEM_EXTENSIONS
  31 ACX_LARGEFILE
  32 AM_PROG_CC_STDC
  33
  34 AC_CONFIG_AUX_DIR(..)
  35 AC_CANONICAL_SYSTEM
  36 AC_ARG_PROGRAM
  37
  38 # Dependency checking.
  39 ZW_CREATE_DEPDIR
  40 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  41
  42 # Check for the 'make' the user wants to use.
  43 AC_CHECK_PROGS(MAKE, make)
  44 MAKE_IS_GNU=
  45 case "`$MAKE --version 2>&1 | sed 1q`" in
  46   *GNU*)
  47     MAKE_IS_GNU=yes
  48     ;;
  49 esac
  50 AM_CONDITIONAL(GMAKE, test "$MAKE_IS_GNU" = yes)
  51 AC_PROG_MAKE_SET
  52
  53 # Configure gnulib.  We need to build gnulib under some other
  54 # directory not "gnulib", to avoid the problem of both GDB and
  55 # GDBserver wanting to build it in the same directory, when building
  56 # in the source dir.
  57 ACX_CONFIGURE_DIR(["gnulib"], ["build-gnulib"])
  58
  59 dnl List of object files and targets accumulated by configure.
  60
  61 CONFIG_OBS=
  62 CONFIG_DEPS=
  63 CONFIG_SRCS=
  64 ENABLE_CFLAGS=
  65
  66 CONFIG_ALL=
  67 CONFIG_CLEAN=
  68 CONFIG_INSTALL=
  69 CONFIG_UNINSTALL=
  70
  71 dnl Set up for gettext.
  72 ZW_GNU_GETTEXT_SISTER_DIR
  73
  74 localedir='${datadir}/locale'
  75 AC_SUBST(localedir)
  76
  77 if test x"$USE_NLS" = xyes; then
  78    CONFIG_ALL="$CONFIG_ALL all-po"
  79    CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
  80    CONFIG_INSTALL="$CONFIG_INSTALL install-po"
  81    CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
  82 fi
  83
  84 GNULIB=build-gnulib/import
  85
  86 # For Makefile dependencies.
  87 GNULIB_STDINT_H=
  88 if test x"$STDINT_H" != x; then
  89   GNULIB_STDINT_H=$GNULIB/$STDINT_H
  90 fi
  91 AC_SUBST(GNULIB_STDINT_H)
  92
  93 PACKAGE=gdb
  94 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
  95 AC_SUBST(PACKAGE)
  96
  97 # We never need to detect it in this sub-configure.
  98 # But preserve it for config.status --recheck.
  99 AC_ARG_VAR(MAKEINFO,
 100   [Parent configure detects if it is of sufficient version.])
 101 AC_ARG_VAR(MAKEINFOFLAGS,
 102   [Parameters for MAKEINFO.])
 103
 104 MAKEINFO_EXTRA_FLAGS=""
 105 AC_CACHE_CHECK([whether $MAKEINFO supports @click], gdb_cv_have_makeinfo_click,
 106   [echo '@clicksequence{a @click{} b}' >conftest.texinfo
 107   if eval "$MAKEINFO conftest.texinfo >&5 2>&5"; then
 108     gdb_cv_have_makeinfo_click=yes
 109   else
 110     gdb_cv_have_makeinfo_click=no
 111   fi])
 112 if test x"$gdb_cv_have_makeinfo_click" = xyes; then
 113   MAKEINFO_EXTRA_FLAGS="$MAKEINFO_EXTRA_FLAGS -DHAVE_MAKEINFO_CLICK"
 114 fi
 115 AC_SUBST(MAKEINFO_EXTRA_FLAGS)
 116
 117 GDB_AC_WITH_DIR(DEBUGDIR, separate-debug-dir,
 118     [look for global separate debug info in this path @<:@LIBDIR/debug@:>@],
 119     [${libdir}/debug])
 120
 121 # We can't pass paths as command line arguments.
 122 # Mingw32 tries to be clever and will convert the paths for us.
 123 # For example -DBINDIR="/usr/local/bin" passed on the command line may get
 124 # converted to -DBINDIR="E:/msys/mingw32/msys/1.0/local/bin".
 125 # This breaks GDB's relocatable path conversions since paths passed in
 126 # config.h would not get so translated, the path prefixes no longer match.
 127 AC_DEFINE_DIR(BINDIR, bindir, [Directory of programs.])
 128
 129 # GDB's datadir relocation
 130
 131 GDB_AC_WITH_DIR(GDB_DATADIR, gdb-datadir,
 132     [look for global separate data files in this path @<:@DATADIR/gdb@:>@],
 133     [${datadir}/gdb])
 134
 135 AC_ARG_WITH(relocated-sources,
 136 AS_HELP_STRING([--with-relocated-sources=PATH], [automatically relocate this path for source files]),
 137 [reloc_srcdir="${withval}"
 138  AC_DEFINE_DIR(RELOC_SRCDIR, reloc_srcdir,
 139               [Relocated directory for source files. ])
 140 ])
 141
 142 AC_MSG_CHECKING([for default auto-load directory])
 143 AC_ARG_WITH(auto-load-dir,
 144 AS_HELP_STRING([--with-auto-load-dir=PATH],
 145   [directories from which to load auto-loaded scripts @<:@$debugdir:$datadir/auto-load@:>@]),,
 146   [with_auto_load_dir='$debugdir:$datadir/auto-load'])
 147 escape_dir=`echo $with_auto_load_dir | sed 's/[[$]]\(datadir\|debugdir\)\>/\\\\\\\\\\\\&/g'`
 148 AC_DEFINE_DIR(AUTO_LOAD_DIR, escape_dir,
 149               [Directories from which to load auto-loaded scripts.])
 150 AC_MSG_RESULT([$with_auto_load_dir])
 151
 152 AC_MSG_CHECKING([for default auto-load safe-path])
 153 AC_ARG_WITH(auto-load-safe-path,
 154 AS_HELP_STRING([--with-auto-load-safe-path=PATH],
 155   [directories safe to hold auto-loaded files @<:@--with-auto-load-dir@:>@])
 156 AS_HELP_STRING([--without-auto-load-safe-path],
 157                [do not restrict auto-loaded files locations]),
 158     [if test "$with_auto_load_safe_path" = "no"; then
 159      with_auto_load_safe_path="/"
 160      fi],
 161 [with_auto_load_safe_path="$with_auto_load_dir"])
 162 escape_dir=`echo $with_auto_load_safe_path | sed 's/[[$]]\(datadir\|debugdir\)\>/\\\\\\\\\\\\&/g'`
 163 AC_DEFINE_DIR(AUTO_LOAD_SAFE_PATH, escape_dir,
 164               [Directories safe to hold auto-loaded files.])
 165 AC_MSG_RESULT([$with_auto_load_safe_path])
 166
 167 AC_CONFIG_SUBDIRS(testsuite)
 168
 169 # Check whether to support alternative target configurations
 170 AC_ARG_ENABLE(targets,
 171 AS_HELP_STRING([--enable-targets=TARGETS], [alternative target configurations]),
 172 [case "${enableval}" in
 173   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
 174             ;;
 175   no)       enable_targets= ;;
 176   *)        enable_targets=$enableval ;;
 177 esac])
 178
 179 # Check whether to enable 64-bit support on 32-bit hosts
 180 AC_ARG_ENABLE(64-bit-bfd,
 181 AS_HELP_STRING([--enable-64-bit-bfd], [64-bit support (on hosts with narrower word sizes)]),
 182 [case "${enableval}" in
 183   yes)  want64=true  ;;
 184   no)   want64=false ;;
 185   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
 186 esac],[want64=false])dnl
 187
 188 # Provide defaults for some variables set by the per-host and per-target
 189 # configuration.
 190 gdb_host_obs=posix-hdep.o
 191
 192 if test "${target}" = "${host}"; then
 193   gdb_native=yes
 194 else
 195   gdb_native=no
 196 fi
 197
 198 . $srcdir/configure.host
 199
 200 # Accumulate some settings from configure.tgt over all enabled targets
 201
 202 TARGET_OBS=
 203 all_targets=
 204 HAVE_NATIVE_GCORE_TARGET=
 205
 206 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 207 do
 208   if test "$targ_alias" = "all"; then
 209     all_targets=true
 210   else
 211     # Canonicalize the secondary target names.
 212     result=`$ac_config_sub $targ_alias 2>/dev/null`
 213     if test -n "$result"; then
 214         targ=$result
 215     else
 216         targ=$targ_alias
 217     fi
 218
 219     . ${srcdir}/configure.tgt
 220
 221     AS_IF([test -z "${gdb_target_obs}"],
 222       [AC_MSG_ERROR([configuration ${targ} is unsupported.])])
 223
 224     # Target-specific object files
 225     for i in ${gdb_target_obs}; do
 226         case " $TARGET_OBS " in
 227         *" ${i} "*) ;;
 228         *)
 229           TARGET_OBS="$TARGET_OBS ${i}"
 230           ;;
 231         esac
 232     done
 233
 234     # Check whether this target needs 64-bit CORE_ADDR
 235     if test x${want64} = xfalse; then
 236       . ${srcdir}/../bfd/config.bfd
 237     fi
 238
 239     # Check whether this target is native and supports gcore.
 240     if test $gdb_native = yes -a "$targ_alias" = "$target_alias" \
 241        && $gdb_have_gcore; then
 242       HAVE_NATIVE_GCORE_TARGET=1
 243     fi
 244   fi
 245 done
 246
 247 if test x${all_targets} = xtrue; then
 248
 249   # We want all 64-bit targets if we either:
 250   #  - run on a 64-bit host  or
 251   #  - already require 64-bit support for some other target  or
 252   #  - the --enable-64-bit-bfd option was supplied
 253   # Otherwise we only support all 32-bit targets.
 254   #
 255   # NOTE: This test must be in sync with the corresponding
 256   #       tests in BFD!
 257
 258   if test x${want64} = xfalse; then
 259     AC_CHECK_SIZEOF(long)
 260     if test "x${ac_cv_sizeof_long}" = "x8"; then
 261       want64=true
 262     fi
 263   fi
 264   if test x${want64} = xtrue; then
 265     TARGET_OBS='$(ALL_TARGET_OBS) $(ALL_64_TARGET_OBS)'
 266   else
 267     TARGET_OBS='$(ALL_TARGET_OBS)'
 268   fi
 269 fi
 270
 271 AC_SUBST(TARGET_OBS)
 272 AC_SUBST(HAVE_NATIVE_GCORE_TARGET)
 273
 274 # For other settings, only the main target counts.
 275 gdb_sim=
 276 gdb_osabi=
 277 build_gdbserver=
 278 targ=$target; . ${srcdir}/configure.tgt
 279
 280 # Fetch the default architecture and default target vector from BFD.
 281 targ=$target; . $srcdir/../bfd/config.bfd
 282
 283 # We only want the first architecture, so strip off the others if
 284 # there is more than one.
 285 targ_archs=`echo $targ_archs | sed 's/ .*//'`
 286
 287 if test "x$targ_archs" != x; then
 288   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
 289     [Define to BFD's default architecture. ])
 290 fi
 291 if test "x$targ_defvec" != x; then
 292   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
 293     [Define to BFD's default target vector. ])
 294 fi
 295
 296 # The CLI cannot be disabled yet, but may be in the future.
 297
 298 # Enable CLI.
 299 AC_ARG_ENABLE(gdbcli,
 300 AS_HELP_STRING([--disable-gdbcli], [disable command-line interface (CLI)]),
 301   [case $enableval in
 302     yes)
 303       ;;
 304     no)
 305       AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;;
 306     *)
 307       AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;;
 308   esac],
 309   [enable_gdbcli=yes])
 310 if test x"$enable_gdbcli" = xyes; then
 311   if test -d $srcdir/cli; then
 312     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)"
 313     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)"
 314     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)"
 315     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)"
 316   fi
 317 fi
 318
 319 # Enable MI.
 320 AC_ARG_ENABLE(gdbmi,
 321 AS_HELP_STRING([--disable-gdbmi], [disable machine-interface (MI)]),
 322   [case $enableval in
 323     yes | no)
 324       ;;
 325     *)
 326       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 327   esac],
 328   [enable_gdbmi=yes])
 329 if test x"$enable_gdbmi" = xyes; then
 330   if test -d $srcdir/mi; then
 331     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 332     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 333     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 334     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 335   fi
 336 fi
 337
 338 # Enable TUI.
 339 AC_ARG_ENABLE(tui,
 340 AS_HELP_STRING([--enable-tui], [enable full-screen terminal user interface (TUI)]),
 341   [case $enableval in
 342     yes | no | auto)
 343       ;;
 344     *)
 345       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 346   esac],enable_tui=auto)
 347
 348 # Enable gdbtk.
 349 AC_ARG_ENABLE(gdbtk,
 350 AS_HELP_STRING([--enable-gdbtk], [enable gdbtk graphical user interface (GUI)]),
 351   [case $enableval in
 352     yes | no)
 353       ;;
 354     *)
 355       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 356   esac],
 357   [if test -d $srcdir/gdbtk; then
 358     enable_gdbtk=yes
 359   else
 360     enable_gdbtk=no
 361   fi])
 362 # We unconditionally disable gdbtk tests on selected platforms.
 363 case $host_os in
 364   go32* | windows*)
 365     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 366     enable_gdbtk=no ;;
 367 esac
 368
 369 # Libunwind support for ia64.
 370
 371 AC_ARG_WITH(libunwind-ia64,
 372 AS_HELP_STRING([--with-libunwind-ia64],
 373                [use libunwind frame unwinding for ia64 targets]),,
 374             [with_libunwind_ia64=auto])
 375
 376 # Backward compatibility option.
 377 if test "${with_libunwind+set}" = set; then
 378   if test x"$with_libunwind_ia64" != xauto; then
 379     AC_MSG_ERROR(
 380       [option --with-libunwind is deprecated, use --with-libunwind-ia64])
 381   fi
 382   AC_MSG_WARN([option --with-libunwind is deprecated, use --with-libunwind-ia64])
 383   with_libunwind_ia64="$with_libunwind"
 384 fi
 385
 386 case "$with_libunwind_ia64" in
 387   yes | no)
 388     ;;
 389   auto)
 390     AC_CHECK_HEADERS(libunwind-ia64.h)
 391     with_libunwind_ia64=$ac_cv_header_libunwind_ia64_h
 392     ;;
 393   *)
 394     AC_MSG_ERROR(
 395       [bad value $with_libunwind_ia64 for GDB --with-libunwind-ia64 option])
 396     ;;
 397 esac
 398
 399 if test x"$with_libunwind_ia64" = xyes; then
 400   AC_CHECK_HEADERS(libunwind-ia64.h)
 401   if test x"$ac_cv_header_libunwind_ia64_h" != xyes; then
 402     AC_MSG_ERROR([GDB option --with-libunwind-ia64 requires libunwind-ia64.h])
 403   fi
 404   CONFIG_OBS="$CONFIG_OBS ia64-libunwind-tdep.o"
 405   CONFIG_DEPS="$CONFIG_DEPS ia64-libunwind-tdep.o"
 406   CONFIG_SRCS="$CONFIG_SRCS ia64-libunwind-tdep.c"
 407 fi
 408
 409 opt_curses=no
 410 AC_ARG_WITH(curses, AS_HELP_STRING([--with-curses], [use the curses library instead of the termcap library]), opt_curses=$withval)
 411
 412 prefer_curses=no
 413 if test "$opt_curses" = "yes"; then
 414   prefer_curses=yes
 415 fi
 416
 417 # Profiling support.
 418 AC_ARG_ENABLE(profiling,
 419 AS_HELP_STRING([--enable-profiling], [enable profiling of GDB]),
 420   [case $enableval in
 421     yes | no)
 422       ;;
 423     *)
 424       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 425   esac],
 426  [enable_profiling=no])
 427
 428 AC_CHECK_FUNCS(monstartup _mcleanup)
 429 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 430 [AC_TRY_LINK(
 431 [#include <stdlib.h>
 432 extern char _etext;
 433 ],
 434 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 435 if test $ac_cv_var__etext = yes; then
 436   AC_DEFINE(HAVE__ETEXT, 1,
 437             [Define to 1 if your system has the _etext variable. ])
 438 fi
 439 AC_CACHE_CHECK([for etext], ac_cv_var_etext,
 440 [AC_TRY_LINK(
 441 [#include <stdlib.h>
 442 extern char etext;
 443 ],
 444 [free (&etext);], ac_cv_var_etext=yes, ac_cv_var_etext=no)])
 445 if test $ac_cv_var_etext = yes; then
 446   AC_DEFINE(HAVE_ETEXT, 1,
 447             [Define to 1 if your system has the etext variable. ])
 448 fi
 449 if test "$enable_profiling" = yes ; then
 450   if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
 451     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 452   fi
 453   PROFILE_CFLAGS=-pg
 454   OLD_CFLAGS="$CFLAGS"
 455   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 456
 457   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 458     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 459      ac_cv_cc_supports_pg=no)])
 460
 461   if test $ac_cv_cc_supports_pg = no; then
 462     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 463   fi
 464
 465   CFLAGS="$OLD_CFLAGS"
 466 fi
 467
 468 ACX_PKGVERSION([GDB])
 469 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 470 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 471 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 472
 473 # --------------------- #
 474 # Checks for programs.  #
 475 # --------------------- #
 476
 477 AC_PROG_AWK
 478 AC_PROG_INSTALL
 479 AC_PROG_LN_S
 480 AC_PROG_RANLIB
 481 AC_PROG_YACC
 482
 483 AC_CHECK_TOOL(AR, ar)
 484 AC_CHECK_TOOL(DLLTOOL, dlltool)
 485 AC_CHECK_TOOL(WINDRES, windres)
 486
 487 case $host_os in
 488   gnu*)
 489     # Needed for GNU Hurd hosts.
 490     AC_CHECK_TOOL(MIG, mig)
 491     if test x"$MIG" = x; then
 492       AC_MSG_ERROR([MIG not found but required for $host hosts])
 493     fi
 494     ;;
 495 esac
 496
 497 # ---------------------- #
 498 # Checks for libraries.  #
 499 # ---------------------- #
 500
 501 # We might need to link with -lm; most simulators need it.
 502 AC_CHECK_LIB(m, main)
 503
 504 # We need to link with -lw to get `wctype' on Solaris before Solaris
 505 # 2.6.  Solaris 2.6 and beyond have this function in libc, and have a
 506 # libw that some versions of the GNU linker cannot hanle (GNU ld 2.9.1
 507 # is known to have this problem).  Therefore we avoid libw if we can.
 508 AC_CHECK_FUNC(wctype, [],
 509   [AC_CHECK_LIB(w, wctype)])
 510
 511 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 512 AC_SEARCH_LIBS(gethostbyname, nsl)
 513
 514 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 515 AC_SEARCH_LIBS(socketpair, socket)
 516
 517 # Link in zlib if we can.  This allows us to read compressed debug sections.
 518 AM_ZLIB
 519
 520 # On HP/UX we may need libxpdl for dlgetmodinfo (used by solib-pa64.c).
 521 AC_SEARCH_LIBS(dlgetmodinfo, [dl xpdl])
 522
 523 AM_ICONV
 524
 525 # GDB may fork/exec the iconv program to get the list of supported character
 526 # sets.  Allow the user to specify where to find it.
 527 # There are several factors affecting the choice of option name:
 528 # - There is already --with-libiconv-prefix but we can't use it, it specifies
 529 #   the build-time location of libiconv files.
 530 # - The program we need to find is iconv, which comes with glibc.  The user
 531 #   doesn't necessarily have libiconv installed.  Therefore naming this
 532 #   --with-libiconv-foo feels wrong.
 533 # - We want the path to be relocatable, but GDB_AC_DEFINE_RELOCATABLE is
 534 #   defined to work on directories not files (though it really doesn't know
 535 #   the difference).
 536 # - Calling this --with-iconv-prefix is perceived to cause too much confusion
 537 #   with --with-libiconv-prefix.
 538 # Putting these together is why the option name is --with-iconv-bin.
 539
 540 AC_ARG_WITH(iconv-bin,
 541 AS_HELP_STRING([--with-iconv-bin=PATH], [specify where to find the iconv program]),
 542 [iconv_bin="${withval}"
 543  AC_DEFINE_UNQUOTED([ICONV_BIN], ["${iconv_bin}"],
 544                     [Path of directory of iconv program.])
 545  GDB_AC_DEFINE_RELOCATABLE(ICONV_BIN, iconv, ${iconv_bin})
 546 ])
 547
 548 # On alpha-osf, it appears that libtermcap and libcurses are not compatible.
 549 # There is a very specific comment in /usr/include/curses.h explaining that
 550 # termcap routines built into libcurses must not be used.
 551 #
 552 # The symptoms we observed so far is GDB unexpectedly changing
 553 # the terminal settings when tgetent is called - this is particularly
 554 # visible as the output is missing carriage returns, and so rapidly
 555 # becomes very hard to read.
 556 #
 557 # The readline configure script has already decided that libtermcap
 558 # was enough for its purposes, and so decided to build readline using
 559 # libtermcap.  Since the TUI mode requires curses, building GDB with
 560 # TUI enabled results in both libraries to be used at the same time,
 561 # which is not allowed.  This basically means that GDB with TUI is
 562 # broken on alpha-osf.
 563
 564 case $host_os in
 565   osf* )
 566     if test x"$enable_tui" = xyes; then
 567       AC_MSG_ERROR([Building GDB with TUI mode is not supported on this host])
 568     fi
 569     if test x"$enable_tui" = xauto; then
 570       enable_tui=no
 571     fi
 572     ;;
 573 esac
 574
 575 # For the TUI, we need enhanced curses functionality.
 576 if test x"$enable_tui" != xno; then
 577   prefer_curses=yes
 578 fi
 579
 580 curses_found=no
 581 if test x"$prefer_curses" = xyes; then
 582   # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
 583   # curses library because the latter might not provide all the
 584   # functionality we need.  However, this leads to problems on systems
 585   # where the linker searches /usr/local/lib, but the compiler doesn't
 586   # search /usr/local/include, if ncurses is installed in /usr/local.  A
 587   # default installation of ncurses on alpha*-dec-osf* will lead to such
 588   # a situation.
 589   AC_SEARCH_LIBS(waddstr, [ncurses cursesX curses])
 590
 591   if test "$ac_cv_search_waddstr" != no; then
 592     curses_found=yes
 593   fi
 594 fi
 595
 596 # Check whether we should enable the TUI, but only do so if we really
 597 # can.
 598 if test x"$enable_tui" != xno; then
 599   if test -d $srcdir/tui; then
 600     if test "$curses_found" != no; then
 601       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
 602       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
 603       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
 604       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
 605     else
 606       if test x"$enable_tui" = xyes; then
 607         AC_MSG_ERROR([no enhanced curses library found; disable TUI])
 608       else
 609         AC_MSG_WARN([no enhanced curses library found; disabling TUI])
 610       fi
 611     fi
 612   fi
 613 fi
 614
 615 # Since GDB uses Readline, we need termcap functionality.  In many
 616 # cases this will be provided by the curses library, but some systems
 617 # have a seperate termcap library, or no curses library at all.
 618
 619 case $host_os in
 620   cygwin*)
 621     if test -d $srcdir/libtermcap; then
 622       LIBS="../libtermcap/libtermcap.a $LIBS"
 623       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 624     fi ;;
 625   go32* | *djgpp*)
 626     ac_cv_search_tgetent="none required"
 627     ;;
 628   *mingw32*)
 629     ac_cv_search_tgetent="none required"
 630     CONFIG_OBS="$CONFIG_OBS windows-termcap.o"
 631     ;;
 632 esac
 633
 634 # These are the libraries checked by Readline.
 635 AC_SEARCH_LIBS(tgetent, [termcap tinfo curses ncurses])
 636
 637 if test "$ac_cv_search_tgetent" = no; then
 638   AC_MSG_ERROR([no termcap library found])
 639 fi
 640
 641 AC_ARG_WITH([system-readline],
 642   [AS_HELP_STRING([--with-system-readline],
 643                   [use installed readline library])])
 644
 645 if test "$with_system_readline" = yes; then
 646   READLINE=-lreadline
 647   READLINE_DEPS=
 648   READLINE_CFLAGS=
 649   READLINE_TEXI_INCFLAG=
 650 else
 651   READLINE='$(READLINE_DIR)/libreadline.a'
 652   READLINE_DEPS='$(READLINE)'
 653   READLINE_CFLAGS='-I$(READLINE_SRC)/..'
 654   READLINE_TEXI_INCFLAG='-I $(READLINE_DIR)'
 655 fi
 656 AC_SUBST(READLINE)
 657 AC_SUBST(READLINE_DEPS)
 658 AC_SUBST(READLINE_CFLAGS)
 659 AC_SUBST(READLINE_TEXI_INCFLAG)
 660
 661 # Generate jit-reader.h
 662
 663 # This is typedeffed to GDB_CORE_ADDR in jit-reader.h
 664 TARGET_PTR=
 665
 666 AC_CHECK_SIZEOF(unsigned long long)
 667 AC_CHECK_SIZEOF(unsigned long)
 668 AC_CHECK_SIZEOF(unsigned __int128)
 669
 670 if test "x${ac_cv_sizeof_unsigned_long}" = "x8"; then
 671   TARGET_PTR="unsigned long"
 672 elif test "x${ac_cv_sizeof_unsigned_long_long}" = "x8"; then
 673   TARGET_PTR="unsigned long long"
 674 elif test "x${ac_cv_sizeof_unsigned___int128}" = "x16"; then
 675   TARGET_PTR="unsigned __int128"
 676 else
 677   TARGET_PTR="unsigned long"
 678 fi
 679
 680 AC_SUBST(TARGET_PTR)
 681 AC_CONFIG_FILES([jit-reader.h:jit-reader.in])
 682
 683 AC_SEARCH_LIBS(dlopen, dl)
 684
 685 GDB_AC_WITH_DIR([JIT_READER_DIR], [jit-reader-dir],
 686                 [directory to load the JIT readers from],
 687                 [${libdir}/gdb])
 688
 689 AC_ARG_WITH(expat,
 690   AS_HELP_STRING([--with-expat], [include expat support (auto/yes/no)]),
 691   [], [with_expat=auto])
 692 AC_MSG_CHECKING([whether to use expat])
 693 AC_MSG_RESULT([$with_expat])
 694
 695 if test "${with_expat}" = no; then
 696   AC_MSG_WARN([expat support disabled; some features may be unavailable.])
 697   HAVE_LIBEXPAT=no
 698 else
 699   AC_LIB_HAVE_LINKFLAGS([expat], [], [#include "expat.h"],
 700                         [XML_Parser p = XML_ParserCreate (0);])
 701   if test "$HAVE_LIBEXPAT" != yes; then
 702     if test "$with_expat" = yes; then
 703       AC_MSG_ERROR([expat is missing or unusable])
 704     else
 705       AC_MSG_WARN([expat is missing or unusable; some features may be unavailable.])
 706     fi
 707   else
 708     save_LIBS=$LIBS
 709     LIBS="$LIBS $LIBEXPAT"
 710     AC_CHECK_FUNCS(XML_StopParser)
 711     LIBS=$save_LIBS
 712   fi
 713 fi
 714
 715 dnl Utility to simplify finding libpython.
 716 dnl $1 = pythonX.Y
 717 dnl $2 = the shell variable to assign the result to
 718 dnl      If libpython is found we store $version here.
 719 dnl $3 = additional flags to add to CPPFLAGS
 720 dnl $4 = additional flags to add to LIBS
 721
 722 AC_DEFUN([AC_TRY_LIBPYTHON],
 723 [
 724   version=$1
 725   define([have_libpython_var],$2)
 726   new_CPPFLAGS=$3
 727   new_LIBS=$4
 728   AC_MSG_CHECKING([for ${version}])
 729   save_CPPFLAGS=$CPPFLAGS
 730   save_LIBS=$LIBS
 731   CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
 732   LIBS="$LIBS $new_LIBS"
 733   found_usable_python=no
 734   AC_LINK_IFELSE(AC_LANG_PROGRAM([[#include "Python.h"]],
 735                                  [[Py_Initialize ();]]),
 736                  [have_libpython_var=${version}
 737                   found_usable_python=yes
 738                   PYTHON_CPPFLAGS=$new_CPPFLAGS
 739                   PYTHON_LIBS=$new_LIBS])
 740   CPPFLAGS=$save_CPPFLAGS
 741   LIBS=$save_LIBS
 742   AC_MSG_RESULT([${found_usable_python}])
 743 ])
 744
 745 dnl There are several different values for --with-python:
 746 dnl
 747 dnl no -   Don't include python support.
 748 dnl yes -  Include python support, error if it's missing.
 749 dnl        If we find python in $PATH, use it to fetch configure options,
 750 dnl        otherwise assume the compiler can find it with no help from us.
 751 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 752 dnl auto - Same as "yes", but if python is missing from the system,
 753 dnl        fall back to "no".
 754 dnl /path/to/python/exec-prefix -
 755 dnl        Use the python located in this directory.
 756 dnl        If /path/to/python/exec-prefix/bin/python exists, use it to find
 757 dnl        the compilation parameters.  Otherwise use
 758 dnl        -I/path/to/python/exec-prefix/include,
 759 dnl        -L/path/to/python/exec-prefix/lib.
 760 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 761 dnl        NOTE: This case is historical.  It is what was done for 7.0/7.1
 762 dnl        but is deprecated.
 763 dnl /path/to/python/executable -
 764 dnl        Run python-config.py with this version of python to fetch the
 765 dnl        compilation parameters.
 766 dnl        NOTE: This needn't be the real python executable.
 767 dnl        In a cross-compilation scenario (build != host), this could be
 768 dnl        a shell script that provides what python-config.py provides for
 769 dnl        --ldflags, --includes, --exec-prefix.
 770 dnl python-executable -
 771 dnl        Find python-executable in $PATH, and then handle the same as
 772 dnl        /path/to/python/executable.
 773 dnl
 774 dnl If a python program is specified, it is used to run python-config.py and
 775 dnl is passed --ldflags, --includes, --exec-prefix.
 776
 777 AC_ARG_WITH(python,
 778   AS_HELP_STRING([--with-python@<:@=PYTHON@:>@], [include python support (auto/yes/no/<python-program>)]),
 779   [], [with_python=auto])
 780 AC_MSG_CHECKING([whether to use python])
 781 AC_MSG_RESULT([$with_python])
 782
 783 if test "${with_python}" = no; then
 784   AC_MSG_WARN([python support disabled; some features may be unavailable.])
 785   have_libpython=no
 786 else
 787   case "${with_python}" in
 788   [[\\/]]* | ?:[[\\/]]*)
 789     if test -d ${with_python}; then
 790       # Assume the python binary is ${with_python}/bin/python.
 791       python_prog="${with_python}/bin/python"
 792       python_prefix=
 793       # If python does not exit ${with_python}/bin, then try in
 794       # ${with_python}.  On Windows/MinGW, this is where the Python
 795       # executable is.
 796       if test ! -x "${python_prog}"; then
 797         python_prog="${with_python}/python"
 798         python_prefix=
 799       fi
 800       if test ! -x "${python_prog}"; then
 801         # Fall back to gdb 7.0/7.1 behaviour.
 802         python_prog=missing
 803         python_prefix=${with_python}
 804       fi
 805     elif test -x "${with_python}"; then
 806       # While we can't run python compiled for $host (unless host == build),
 807       # the user could write a script that provides the needed information,
 808       # so we support that.
 809       python_prog=${with_python}
 810       python_prefix=
 811     else
 812       AC_ERROR(invalid value for --with-python)
 813     fi
 814     ;;
 815   */*)
 816     # Disallow --with-python=foo/bar.
 817     AC_ERROR(invalid value for --with-python)
 818     ;;
 819   *)
 820     # The user has either specified auto, yes, or the name of the python
 821     # program assumed to be in $PATH.
 822     python_prefix=
 823     case "${with_python}" in
 824     yes | auto)
 825       if test ${build} = ${host}; then
 826         AC_PATH_PROG(python_prog_path, python, missing)
 827         if test "${python_prog_path}" = missing; then
 828           python_prog=missing
 829         else
 830           python_prog=${python_prog_path}
 831         fi
 832       else
 833         # Not much we can do except assume the cross-compiler will find the
 834         # right files.
 835         python_prog=missing
 836       fi
 837       ;;
 838     *)
 839       # While we can't run python compiled for $host (unless host == build),
 840       # the user could write a script that provides the needed information,
 841       # so we support that.
 842       python_prog="${with_python}"
 843       AC_PATH_PROG(python_prog_path, ${python_prog}, missing)
 844       if test "${python_prog_path}" = missing; then
 845         AC_ERROR(unable to find python program ${python_prog})
 846       fi
 847       ;;
 848     esac
 849   esac
 850
 851   if test "${python_prog}" != missing; then
 852     # We have a python program to use, but it may be too old.
 853     # Don't flag an error for --with-python=auto (the default).
 854     have_python_config=yes
 855     python_includes=`${python_prog} ${srcdir}/python/python-config.py --includes`
 856     if test $? != 0; then
 857       have_python_config=failed
 858       if test "${with_python}" != auto; then
 859         AC_ERROR(failure running python-config --includes)
 860       fi
 861     fi
 862     python_libs=`${python_prog} ${srcdir}/python/python-config.py --ldflags`
 863     if test $? != 0; then
 864       have_python_config=failed
 865       if test "${with_python}" != auto; then
 866         AC_ERROR(failure running python-config --ldflags)
 867       fi
 868     fi
 869     python_prefix=`${python_prog} ${srcdir}/python/python-config.py --exec-prefix`
 870     if test $? != 0; then
 871       have_python_config=failed
 872       if test "${with_python}" != auto; then
 873         AC_ERROR(failure running python-config --exec-prefix)
 874       fi
 875     fi
 876   else
 877     # We do not have a python executable we can use to determine where
 878     # to find the Python headers and libs.  We cannot guess the include
 879     # path from the python_prefix either, because that include path
 880     # depends on the Python version.  So, there is nothing much we can
 881     # do except assume that the compiler will be able to find those files.
 882     python_includes=
 883     python_libs=
 884     have_python_config=no
 885   fi
 886
 887   # If we have python-config, only try the configuration it provides.
 888   # Otherwise fallback on the old way of trying different versions of
 889   # python in turn.
 890
 891   have_libpython=no
 892   if test "${have_python_config}" = yes; then
 893     # Determine the Python version by extracting "-lpython<version>"
 894     # part of the python_libs. <version> is usually X.Y with X and Y
 895     # being decimal numbers, but can also be XY (seen on Windows).
 896     #
 897     # The extraction is performed using sed with a regular expression.
 898     # Initially, the regexp used was using the '?' quantifier to make
 899     # the dot in the version number optional.  Unfortunately, this
 900     # does not work with non-GNU versions of sed because, because of
 901     # what looks like a limitation (the '?' quantifier does not work
 902     # with back-references).  We work around this limitation by using
 903     # the '*' quantifier instead.  It means that, in theory, we might
 904     # match unexpected version strings such as "-lpython2..7", but
 905     # this seems unlikely in practice.  And even if that happens,
 906     # an error will be triggered later on, when checking that version
 907     # number.
 908     python_version=`echo " ${python_libs} " \
 909                          | sed -e 's,^.* -l\(python[[0-9]]*[[.]]*[[0-9]]*\).*$,\1,'`
 910     case "${python_version}" in
 911     python*)
 912       AC_TRY_LIBPYTHON(${python_version}, have_libpython,
 913                        ${python_includes}, ${python_libs})
 914       ;;
 915     *)
 916       AC_MSG_ERROR([unable to determine python version from ${python_libs}])
 917       ;;
 918     esac
 919   elif test "${have_python_config}" != failed; then
 920     if test "${have_libpython}" = no; then
 921       AC_TRY_LIBPYTHON(python2.7, have_libpython,
 922                        ${python_includes}, "${python_libs} -lpython2.7")
 923     fi
 924     if test "${have_libpython}" = no; then
 925       AC_TRY_LIBPYTHON(python2.6, have_libpython,
 926                        ${python_includes}, "${python_libs} -lpython2.6")
 927     fi
 928     if test ${have_libpython} = no; then
 929       AC_TRY_LIBPYTHON(python2.5, have_libpython,
 930                        ${python_includes}, "${python_libs} -lpython2.5")
 931     fi
 932     if test ${have_libpython} = no; then
 933       AC_TRY_LIBPYTHON(python2.4, have_libpython,
 934                        ${python_includes}, "${python_libs} -lpython2.4")
 935     fi
 936   fi
 937   if test "${have_libpython}" = python2.7 -o "${have_libpython}" = python27; then
 938     AC_DEFINE(HAVE_LIBPYTHON2_7, 1, [Define if Python 2.7 is being used.])
 939   elif test "${have_libpython}" = python2.6 -o "${have_libpython}" = python26; then
 940     AC_DEFINE(HAVE_LIBPYTHON2_6, 1, [Define if Python 2.6 is being used.])
 941   elif test "${have_libpython}" = python2.5 -o "${have_libpython}" = python25; then
 942     AC_DEFINE(HAVE_LIBPYTHON2_5, 1, [Define if Python 2.5 is being used.])
 943   elif test "${have_libpython}" = python2.4 -o "${have_libpython}" = python24; then
 944     AC_DEFINE(HAVE_LIBPYTHON2_4, 1, [Define if Python 2.4 is being used.])
 945   fi
 946
 947   if test "${have_libpython}" = no; then
 948     case "${with_python}" in
 949     yes)
 950       AC_MSG_ERROR([python is missing or unusable])
 951       ;;
 952     auto)
 953       AC_MSG_WARN([python is missing or unusable; some features may be unavailable.])
 954       ;;
 955     *)
 956       AC_MSG_ERROR([no usable python found at ${with_python}])
 957       ;;
 958     esac
 959   else
 960     if test -n "${python_prefix}"; then
 961       AC_DEFINE_UNQUOTED(WITH_PYTHON_PATH, "${python_prefix}",
 962                          [Define if --with-python provides a path, either directly or via python-config.py --exec-prefix.])
 963       GDB_AC_DEFINE_RELOCATABLE(PYTHON_PATH, python, ${python_prefix})
 964     fi
 965   fi
 966 fi
 967
 968 if test "${have_libpython}" != no; then
 969   AC_DEFINE(HAVE_PYTHON, 1, [Define if Python interpreter is being linked in.])
 970   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_PYTHON_OBS)"
 971   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_PYTHON_DEPS)"
 972   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_PYTHON_SRCS)"
 973   CONFIG_INSTALL="$CONFIG_INSTALL install-python"
 974   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_PYTHON_CFLAGS)"
 975
 976   # Flags needed to compile Python code (taken from python-config --cflags).
 977   # We cannot call python-config directly because it will output whatever was
 978   # used when compiling the Python interpreter itself, including flags which
 979   # would make the python-related objects be compiled differently from the
 980   # rest of GDB (e.g., -O2 and -fPIC).
 981   if test "${GCC}" = yes; then
 982     tentative_python_cflags="-fno-strict-aliasing -DNDEBUG -fwrapv"
 983   fi
 984
 985   if test "x${tentative_python_cflags}" != x; then
 986     AC_MSG_CHECKING(compiler flags for python code)
 987     for flag in ${tentative_python_cflags}; do
 988       # Check that the compiler accepts it
 989       saved_CFLAGS="$CFLAGS"
 990       CFLAGS="$CFLAGS $flag"
 991       AC_TRY_COMPILE([],[],PYTHON_CFLAGS="${PYTHON_CFLAGS} $flag",)
 992       CFLAGS="$saved_CFLAGS"
 993     done
 994     AC_MSG_RESULT(${PYTHON_CFLAGS})
 995   fi
 996
 997   # On IRIX, type siginfo is not defined.  Instead, sys/siginfo.h provides:
 998   #    #if _SGIAPI
 999   #    #define siginfo __siginfo
1000   #    #endif
1001   # The problem is that including Python causes some XOPEN macros to be
1002   # unilaterally defined, and that in turn causes _SGIAPI to evaluate
1003   # to false.  So, we work around this issue by defining siginfo ourself
1004   # though the command-line.
1005   #
1006   # On x64 Windows, Python's include headers, and pyconfig.h in
1007   # particular, rely on MS_WIN64 macro to detect that it's a 64bit
1008   # version of Windows.  Unfortunately, MS_WIN64 is only defined if
1009   # _MSC_VER, a Microsoft-specific macro, is defined.  So, when
1010   # building on x64 Windows with GCC, we define MS_WIN64 ourselves.
1011   # The issue was reported to the Python community, but still isn't
1012   # solved as of 2012-10-02 (http://bugs.python.org/issue4709).
1013
1014   case "$gdb_host" in
1015     irix*) if test "${GCC}" = yes; then
1016              CPPFLAGS="$CPPFLAGS -Dsiginfo=__siginfo"
1017            fi
1018            ;;
1019     mingw64)
1020            if test "${GCC}" = yes; then
1021              CPPFLAGS="$CPPFLAGS -DMS_WIN64"
1022            fi
1023            ;;
1024   esac
1025
1026   # Note that "python -m threading" cannot be used to check for
1027   # threading support due to a bug in Python 2.7.3
1028   # (http://bugs.python.org/issue15567).
1029   AC_MSG_CHECKING(whether python supports threads)
1030   saved_CPPFLAGS="${CPPFLAGS}"
1031   CPPFLAGS="${PYTHON_CPPFLAGS}"
1032   # Note that the test is reversed so that python_has_threads=yes on
1033   # unexpected failures.
1034   AC_PREPROC_IFELSE(AC_LANG_SOURCE([[
1035 #include <Python.h>
1036 #ifdef WITH_THREAD
1037 # error
1038 #endif
1039   ]]), [python_has_threads=no], [python_has_threads=yes])
1040   AC_MSG_RESULT(${python_has_threads})
1041   CPPFLAGS="${saved_CPPFLAGS}"
1042 else
1043   # Even if Python support is not compiled in, we need to have these files
1044   # included.
1045   CONFIG_OBS="$CONFIG_OBS python.o py-value.o py-prettyprint.o py-auto-load.o"
1046   CONFIG_SRCS="$CONFIG_SRCS python/python.c python/py-value.c \
1047         python/py-prettyprint.c python/py-auto-load.c"
1048 fi
1049 AC_SUBST(PYTHON_CFLAGS)
1050 AC_SUBST(PYTHON_CPPFLAGS)
1051 AC_SUBST(PYTHON_LIBS)
1052
1053 # Enable -lmcheck by default (it provides cheap-enough memory mangling),
1054 # but turn it off if Python is enabled with threads, since -lmcheck is
1055 # not thread safe (http://sourceware.org/bugzilla/show_bug.cgi?id=9939),
1056 # and for releases.
1057 if test \( "${have_libpython}" = "no" -o "${python_has_threads}" = "no" \) \
1058    && $development; then
1059   libmcheck_default=yes
1060 else
1061   libmcheck_default=no
1062 fi
1063 GDB_AC_LIBMCHECK(${libmcheck_default})
1064
1065 if test "$ENABLE_LIBMCHECK" = "yes" \
1066         -a "${have_libpython}" != "no" \
1067         -a "${python_has_threads}" = "yes" ; then
1068   AC_MSG_WARN(--enable-libmcheck may lead to spurious crashes if threads are used in python)
1069 fi
1070
1071 # ------------------------- #
1072 # Checks for header files.  #
1073 # ------------------------- #
1074
1075 AC_HEADER_DIRENT
1076 AC_HEADER_STDC
1077 # elf_hp.h is for HP/UX 64-bit shared library support.
1078 AC_CHECK_HEADERS([nlist.h machine/reg.h poll.h sys/poll.h sys/socket.h proc_service.h \
1079                   thread_db.h signal.h stddef.h \
1080                   stdlib.h string.h memory.h strings.h sys/fault.h \
1081                   sys/file.h sys/filio.h sys/ioctl.h sys/param.h \
1082                   sys/resource.h sys/procfs.h sys/ptrace.h ptrace.h \
1083                   sys/reg.h sys/debugreg.h sys/select.h sys/syscall.h \
1084                   sys/types.h sys/wait.h wait.h termios.h termio.h \
1085                   sgtty.h unistd.h elf_hp.h locale.h \
1086                   dlfcn.h sys/un.h linux/perf_event.h])
1087 AC_CHECK_HEADERS(link.h, [], [],
1088 [#if HAVE_SYS_TYPES_H
1089 # include <sys/types.h>
1090 #endif
1091 #if HAVE_NLIST_H
1092 # include <nlist.h>
1093 #endif
1094 ])
1095 AC_CHECK_HEADERS(sys/proc.h, [], [],
1096 [#if HAVE_SYS_PARAM_H
1097 # include <sys/param.h>
1098 #endif
1099 ])
1100 AC_CHECK_HEADERS(sys/user.h, [], [],
1101 [#if HAVE_SYS_PARAM_H
1102 # include <sys/param.h>
1103 #endif
1104 ])
1105
1106 # On Solaris 2.[789], we need to define _MSE_INT_H to avoid a clash
1107 # between <widec.h> and <wchar.h> that would cause AC_CHECK_HEADERS to
1108 # think that we don't have <curses.h> if we're using GCC.
1109 case $host_os in
1110   solaris2.[[789]])
1111     if test "$GCC" = yes; then
1112       AC_DEFINE(_MSE_INT_H, 1,
1113         [Define to 1 to avoid a clash between <widec.h> and <wchar.h> on
1114    Solaris 2.[789] when using GCC. ])
1115     fi ;;
1116 esac
1117 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncurses/ncurses.h ncurses/term.h)
1118 AC_CHECK_HEADERS(term.h, [], [],
1119 [#if HAVE_CURSES_H
1120 # include <curses.h>
1121 #endif
1122 ])
1123
1124 # ------------------------- #
1125 # Checks for declarations.  #
1126 # ------------------------- #
1127
1128 AC_CHECK_DECLS([free, malloc, realloc, strerror, strstr, getopt,
1129                 snprintf, vsnprintf])
1130 AM_LC_MESSAGES
1131
1132 # ----------------------- #
1133 # Checks for structures.  #
1134 # ----------------------- #
1135
1136 AC_CHECK_MEMBERS([struct stat.st_blocks, struct stat.st_blksize])
1137
1138 # ------------------ #
1139 # Checks for types.  #
1140 # ------------------ #
1141
1142 AC_TYPE_SIGNAL
1143 AC_CHECK_TYPES(socklen_t, [], [],
1144 [#include <sys/types.h>
1145 #include <sys/socket.h>
1146 ])
1147
1148 # ------------------------------------- #
1149 # Checks for compiler characteristics.  #
1150 # ------------------------------------- #
1151
1152 AC_C_CONST
1153 AC_C_INLINE
1154 AC_C_BIGENDIAN
1155
1156 # ------------------------------ #
1157 # Checks for library functions.  #
1158 # ------------------------------ #
1159
1160 AC_FUNC_ALLOCA
1161 AC_FUNC_MMAP
1162 AC_FUNC_VFORK
1163 AC_CHECK_FUNCS([canonicalize_file_name realpath getrusage getuid getgid \
1164                 pipe poll pread pread64 pwrite readlink resize_term \
1165                 sbrk setpgid setpgrp setsid \
1166                 sigaction sigprocmask sigsetmask socketpair syscall \
1167                 ttrace wborder wresize setlocale iconvlist libiconvlist btowc \
1168                 setrlimit getrlimit posix_madvise waitpid lstat \
1169                 fdwalk pipe2 ptrace64])
1170 AM_LANGINFO_CODESET
1171
1172 # Check the return and argument types of ptrace.  No canned test for
1173 # this, so roll our own.
1174 gdb_ptrace_headers='
1175 #if HAVE_SYS_TYPES_H
1176 # include <sys/types.h>
1177 #endif
1178 #if HAVE_SYS_PTRACE_H
1179 # include <sys/ptrace.h>
1180 #endif
1181 #if HAVE_UNISTD_H
1182 # include <unistd.h>
1183 #endif
1184 '
1185 # There is no point in checking if we don't have a prototype.
1186 AC_CHECK_DECLS(ptrace, [], [
1187   : ${gdb_cv_func_ptrace_ret='int'}
1188   : ${gdb_cv_func_ptrace_args='int,int,long,long'}
1189 ], $gdb_ptrace_headers)
1190 # Check return type.  Varargs (used on GNU/Linux) conflict with the
1191 # empty argument list, so check for that explicitly.
1192 AC_CACHE_CHECK([return type of ptrace], gdb_cv_func_ptrace_ret,
1193   AC_TRY_COMPILE($gdb_ptrace_headers,
1194     [extern long ptrace (enum __ptrace_request, ...);],
1195     gdb_cv_func_ptrace_ret='long',
1196     AC_TRY_COMPILE($gdb_ptrace_headers,
1197       [extern int ptrace ();],
1198       gdb_cv_func_ptrace_ret='int',
1199       gdb_cv_func_ptrace_ret='long')))
1200 AC_DEFINE_UNQUOTED(PTRACE_TYPE_RET, $gdb_cv_func_ptrace_ret,
1201   [Define as the return type of ptrace.])
1202 # Check argument types.
1203 AC_CACHE_CHECK([types of arguments for ptrace], gdb_cv_func_ptrace_args, [
1204   AC_TRY_COMPILE($gdb_ptrace_headers,
1205     [extern long ptrace (enum __ptrace_request, ...);],
1206     [gdb_cv_func_ptrace_args='int,int,long,long'],[
1207 for gdb_arg1 in 'int' 'long'; do
1208  for gdb_arg2 in 'pid_t' 'int' 'long'; do
1209   for gdb_arg3 in 'int *' 'caddr_t' 'int' 'long' 'void *'; do
1210    for gdb_arg4 in 'int' 'long' 'void *'; do
1211      AC_TRY_COMPILE($gdb_ptrace_headers, [
1212 extern $gdb_cv_func_ptrace_ret
1213   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4);
1214 ], [gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4";
1215     break 4;])
1216     for gdb_arg5 in 'int *' 'int' 'long'; do
1217      AC_TRY_COMPILE($gdb_ptrace_headers, [
1218 extern $gdb_cv_func_ptrace_ret
1219   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4, $gdb_arg5);
1220 ], [
1221 gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4,$gdb_arg5";
1222     break 5;])
1223     done
1224    done
1225   done
1226  done
1227 done
1228 # Provide a safe default value.
1229 : ${gdb_cv_func_ptrace_args='int,int,long,long'}
1230 ])])
1231 ac_save_IFS=$IFS; IFS=','
1232 set dummy `echo "$gdb_cv_func_ptrace_args" | sed 's/\*/\*/g'`
1233 IFS=$ac_save_IFS
1234 shift
1235 AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG3, $[3],
1236   [Define to the type of arg 3 for ptrace.])
1237 AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG4, $[4],
1238   [Define to the type of arg 4 for ptrace.])
1239 if test -n "$[5]"; then
1240   AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG5, $[5],
1241     [Define to the type of arg 5 for ptrace.])
1242 fi
1243
1244 dnl AC_FUNC_SETPGRP does not work when cross compiling
1245 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
1246 if test "$cross_compiling" = no; then
1247   AC_FUNC_SETPGRP
1248 else
1249   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
1250     [AC_TRY_COMPILE([
1251 #include <unistd.h>
1252 ], [
1253   if (setpgrp(1,1) == -1)
1254     exit (0);
1255   else
1256     exit (1);
1257 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
1258 if test $ac_cv_func_setpgrp_void = yes; then
1259   AC_DEFINE(SETPGRP_VOID, 1)
1260 fi
1261 fi
1262
1263 # Check if sigsetjmp is available.  Using AC_CHECK_FUNCS won't do
1264 # since sigsetjmp might only be defined as a macro.
1265 AC_CACHE_CHECK([for sigsetjmp], gdb_cv_func_sigsetjmp,
1266 [AC_TRY_COMPILE([
1267 #include <setjmp.h>
1268 ], [sigjmp_buf env; while (! sigsetjmp (env, 1)) siglongjmp (env, 1);],
1269 gdb_cv_func_sigsetjmp=yes, gdb_cv_func_sigsetjmp=no)])
1270 if test $gdb_cv_func_sigsetjmp = yes; then
1271   AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available. ])
1272 fi
1273
1274 # Assume we'll default to using the included libiberty regex.
1275 gdb_use_included_regex=yes
1276
1277 # However, if the system regex is GNU regex, then default to *not*
1278 # using the included regex.
1279 AC_CACHE_CHECK(
1280   [for GNU regex],
1281   [gdb_cv_have_gnu_regex],
1282   [AC_TRY_COMPILE(
1283     [#include <gnu-versions.h>],
1284     [#define REGEX_INTERFACE_VERSION 1
1285 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
1286 # error "Version mismatch"
1287 #endif],
1288     gdb_cv_have_gnu_regex=yes,
1289     gdb_cv_have_gnu_regex=no)])
1290 if test $gdb_cv_have_gnu_regex = yes; then
1291   gdb_use_included_regex=no
1292 fi
1293
1294 AC_ARG_WITH(included-regex,
1295   AS_HELP_STRING([--without-included-regex], [don't use included regex; this is the default on systems with version 2 of the GNU C library (use with caution on other system)]),
1296   gdb_with_regex=$withval,
1297   gdb_with_regex=$gdb_use_included_regex)
1298 if test "$gdb_with_regex" = yes; then
1299   AC_DEFINE(USE_INCLUDED_REGEX, 1,
1300     [Define to 1 if the regex included in libiberty should be used.])
1301 fi
1302
1303 # Check if <sys/proc.h> defines `struct thread' with a td_pcb member.
1304 AC_CHECK_MEMBERS([struct thread.td_pcb], [], [],
1305 [#include <sys/param.h>
1306 #include <sys/proc.h>
1307 ])
1308
1309 # See if <sys/lwp.h> defines `struct lwp`.
1310 AC_CACHE_CHECK([for struct lwp], gdb_cv_struct_lwp,
1311 [AC_TRY_COMPILE([#include <sys/param.h>
1312 #include <sys/lwp.h>], [struct lwp l;],
1313 gdb_cv_struct_lwp=yes, gdb_cv_struct_lwp=no)])
1314 if test $gdb_cv_struct_lwp = yes; then
1315   AC_DEFINE(HAVE_STRUCT_LWP, 1,
1316             [Define to 1 if your system has struct lwp.])
1317 fi
1318
1319 # See if <machine/reg.h> degines `struct reg'.
1320 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
1321 [AC_TRY_COMPILE([#include <sys/types.h>
1322 #include <machine/reg.h>], [struct reg r;],
1323 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
1324 if test $gdb_cv_struct_reg = yes; then
1325   AC_DEFINE(HAVE_STRUCT_REG, 1,
1326             [Define to 1 if your system has struct reg in <machine/reg.h>.])
1327 fi
1328
1329 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
1330 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
1331 AC_CHECK_MEMBERS([struct reg.r_fs, struct reg.r_gs], [], [],
1332                  [#include <machine/reg.h>])
1333
1334 # See if <sys/user.h> supports the %fs_base and %gs_bas amd64 segment registers.
1335 # Older amd64 Linux's don't have the fs_base and gs_base members of
1336 # `struct user_regs_struct'.
1337 AC_CHECK_MEMBERS([struct user_regs_struct.fs_base, struct user_regs_struct.gs_base],
1338                  [], [], [#include <sys/user.h>])
1339
1340 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
1341 AC_MSG_CHECKING(for PTRACE_GETREGS)
1342 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
1343 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1344                 [PTRACE_GETREGS;],
1345                 [gdb_cv_have_ptrace_getregs=yes],
1346                 [gdb_cv_have_ptrace_getregs=no])])
1347 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
1348 if test $gdb_cv_have_ptrace_getregs = yes; then
1349   AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
1350   [Define if sys/ptrace.h defines the PTRACE_GETREGS request.])
1351 fi
1352
1353 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
1354 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
1355 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
1356 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1357                 [PTRACE_GETFPXREGS;],
1358                 [gdb_cv_have_ptrace_getfpxregs=yes],
1359                 [gdb_cv_have_ptrace_getfpxregs=no])])
1360 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
1361 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
1362   AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
1363   [Define if sys/ptrace.h defines the PTRACE_GETFPXREGS request.])
1364 fi
1365
1366 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
1367 AC_MSG_CHECKING(for PT_GETDBREGS)
1368 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
1369 [AC_TRY_COMPILE([#include <sys/types.h>
1370 #include <sys/ptrace.h>],
1371                 [PT_GETDBREGS;],
1372                 [gdb_cv_have_pt_getdbregs=yes],
1373                 [gdb_cv_have_pt_getdbregs=no])])
1374 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
1375 if test $gdb_cv_have_pt_getdbregs = yes; then
1376   AC_DEFINE(HAVE_PT_GETDBREGS, 1,
1377   [Define if sys/ptrace.h defines the PT_GETDBREGS request.])
1378 fi
1379
1380 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
1381 AC_MSG_CHECKING(for PT_GETXMMREGS)
1382 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
1383 [AC_TRY_COMPILE([#include <sys/types.h>
1384 #include <sys/ptrace.h>],
1385                 [PT_GETXMMREGS;],
1386                 [gdb_cv_have_pt_getxmmregs=yes],
1387                 [gdb_cv_have_pt_getxmmregs=no])])
1388 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
1389 if test $gdb_cv_have_pt_getxmmregs = yes; then
1390   AC_DEFINE(HAVE_PT_GETXMMREGS, 1,
1391   [Define if sys/ptrace.h defines the PT_GETXMMREGS request.])
1392 fi
1393
1394 # Detect which type of /proc is in use, such as for Solaris.
1395
1396 if test "${target}" = "${host}"; then
1397   case "${host}" in
1398   *-*-sysv4.2* | *-*-sysv5* | *-*-interix* )
1399       AC_DEFINE(NEW_PROC_API, 1,
1400       [Define if you want to use new multi-fd /proc interface
1401        (replaces HAVE_MULTIPLE_PROC_FDS as well as other macros).])
1402       ;;
1403   *-*-solaris2.[[6789]] | *-*-solaris2.1[[0-9]]*)
1404       AC_DEFINE(NEW_PROC_API, 1,
1405       [Define if you want to use new multi-fd /proc interface
1406        (replaces HAVE_MULTIPLE_PROC_FDS as well as other macros).])
1407       ;;
1408   mips-sgi-irix5*)
1409       # Work around <sys/proc.h> needing _KMEMUSER problem on IRIX 5.
1410       AC_DEFINE([_KMEMUSER], 1,
1411       [Define to 1 so <sys/proc.h> gets a definition of anon_hdl.  Works
1412        around a <sys/proc.h> problem on IRIX 5.])
1413       ;;
1414   esac
1415 fi
1416
1417 if test "$ac_cv_header_sys_procfs_h" = yes; then
1418   BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
1419   BFD_HAVE_SYS_PROCFS_TYPE(prrun_t)
1420   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
1421   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
1422   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
1423   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
1424   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
1425   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset32_t)
1426   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
1427   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
1428   BFD_HAVE_SYS_PROCFS_TYPE(prsysent_t)
1429   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigset_t)
1430   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigaction64_t)
1431   BFD_HAVE_SYS_PROCFS_TYPE(pr_siginfo64_t)
1432
1433
1434   dnl Check for broken prfpregset_t type
1435
1436   dnl For Linux/i386, glibc 2.1.3 was released with a bogus
1437   dnl prfpregset_t type (it's a typedef for the pointer to a struct
1438   dnl instead of the struct itself).  We detect this here, and work
1439   dnl around it in gdb_proc_service.h.
1440
1441   if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
1442     AC_MSG_CHECKING(whether prfpregset_t type is broken)
1443     AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
1444       [AC_TRY_RUN([#include <sys/procfs.h>
1445        int main ()
1446        {
1447          if (sizeof (prfpregset_t) == sizeof (void *))
1448            return 1;
1449          return 0;
1450        }],
1451        gdb_cv_prfpregset_t_broken=no,
1452        gdb_cv_prfpregset_t_broken=yes,
1453        gdb_cv_prfpregset_t_broken=yes)])
1454     AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
1455     if test $gdb_cv_prfpregset_t_broken = yes; then
1456       AC_DEFINE(PRFPREGSET_T_BROKEN, 1,
1457       [Define if the prfpregset_t type is broken.])
1458     fi
1459   fi
1460
1461   dnl Check for PIOCSET ioctl entry
1462
1463   AC_MSG_CHECKING(for PIOCSET ioctl entry in sys/procfs.h)
1464   AC_CACHE_VAL(gdb_cv_have_procfs_piocset,
1465   [AC_TRY_COMPILE([#include <unistd.h>
1466 #include <sys/types.h>
1467 #include <sys/procfs.h>
1468 ], [
1469     int dummy;;
1470     dummy = ioctl(0, PIOCSET, &dummy);
1471   ],
1472   gdb_cv_have_procfs_piocset=yes, gdb_cv_have_procfs_piocset=no)])
1473   AC_MSG_RESULT($gdb_cv_have_procfs_piocset)
1474   if test $gdb_cv_have_procfs_piocset = yes; then
1475     AC_DEFINE(HAVE_PROCFS_PIOCSET, 1,
1476     [Define if ioctl argument PIOCSET is available.])
1477   fi
1478 fi
1479
1480 dnl For native ports (host == target), check to see what kind of
1481 dnl legacy link.h support is needed.  (See solib-legacy.c.)
1482 if test ${host} = ${target} ; then
1483   dnl Check for struct link_map with l_ members which are indicative
1484   dnl of SVR4-like shared libraries
1485
1486   AC_MSG_CHECKING(for member l_addr in struct link_map)
1487   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_l_members,
1488     [AC_TRY_COMPILE([#include <link.h>],
1489                     [struct link_map lm; (void) lm.l_addr;],
1490                     gdb_cv_have_struct_link_map_with_l_members=yes,
1491                     gdb_cv_have_struct_link_map_with_l_members=no)])
1492   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_l_members)
1493   if test $gdb_cv_have_struct_link_map_with_l_members = yes; then
1494     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_L_MEMBERS,1,
1495     [Define if <link.h> exists and defines struct link_map which has
1496      members with an ``l_'' prefix.  (For Solaris, SVR4, and
1497      SVR4-like systems.)])
1498   fi
1499
1500   dnl Check for struct link_map with lm_ members which are indicative
1501   dnl of SunOS-like shared libraries
1502
1503   AC_MSG_CHECKING(for member lm_addr in struct link_map)
1504   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_lm_members,
1505     [AC_TRY_COMPILE([#include <sys/types.h>
1506 #include <link.h>],
1507                     [struct link_map lm; (void) lm.lm_addr;],
1508                     gdb_cv_have_struct_link_map_with_lm_members=yes,
1509                     gdb_cv_have_struct_link_map_with_lm_members=no)])
1510   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_lm_members)
1511   if test $gdb_cv_have_struct_link_map_with_lm_members = yes; then
1512     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_LM_MEMBERS, 1,
1513     [Define if <link.h> exists and defines struct link_map which has
1514      members with an ``lm_'' prefix.  (For SunOS.)])
1515   fi
1516
1517   dnl Check for struct so_map with som_ members which are found on
1518   dnl some *BSD systems.
1519
1520   AC_MSG_CHECKING(for member som_addr in struct so_map)
1521   AC_CACHE_VAL(gdb_cv_have_struct_so_map_with_som_members,
1522     [AC_TRY_COMPILE([#include <sys/types.h>
1523 #ifdef HAVE_NLIST_H
1524 #include <nlist.h>
1525 #endif
1526 #include <link.h>],
1527                     [struct so_map lm; (void) lm.som_addr;],
1528                     gdb_cv_have_struct_so_map_with_som_members=yes,
1529                     gdb_cv_have_struct_so_map_with_som_members=no)])
1530   AC_MSG_RESULT($gdb_cv_have_struct_so_map_with_som_members)
1531   if test $gdb_cv_have_struct_so_map_with_som_members = yes; then
1532     AC_DEFINE(HAVE_STRUCT_SO_MAP_WITH_SOM_MEMBERS, 1,
1533     [Define if <link.h> exists and defines a struct so_map which has
1534      members with an ``som_'' prefix.  (Found on older *BSD systems.)])
1535   fi
1536
1537   dnl Check for struct link_map32 type, which allows a 64-bit Solaris
1538   dnl debugger to debug a 32-bit Solaris app with 32-bit shared libraries.
1539
1540   AC_MSG_CHECKING(for struct link_map32 in sys/link.h)
1541   AC_CACHE_VAL(gdb_cv_have_struct_link_map32,
1542     [AC_TRY_COMPILE([#define _SYSCALL32
1543 #include <sys/link.h>], [struct link_map32 l;],
1544      gdb_cv_have_struct_link_map32=yes,
1545      gdb_cv_have_struct_link_map32=no)])
1546   AC_MSG_RESULT($gdb_cv_have_struct_link_map32)
1547   if test $gdb_cv_have_struct_link_map32 = yes; then
1548     AC_DEFINE(HAVE_STRUCT_LINK_MAP32, 1,
1549     [Define if <sys/link.h> has struct link_map32])
1550     AC_DEFINE(_SYSCALL32, 1,
1551     [Define if <sys/link.h> has link_map32 (solaris sparc-64 target)])
1552   fi
1553 fi
1554
1555 # Check if the compiler supports the `long long' type.
1556
1557 AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long,
1558                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1559 [[extern long long foo;]],
1560 [[switch (foo & 2) { case 0: return 1; }]])],
1561                                   gdb_cv_c_long_long=yes,
1562                                   gdb_cv_c_long_long=no)])
1563 if test $gdb_cv_c_long_long != yes; then
1564   # libdecnumber requires long long.
1565   AC_MSG_ERROR([Compiler must support long long for GDB.])
1566 fi
1567
1568 # Check if the compiler and runtime support printing long longs.
1569
1570 AC_CACHE_CHECK([for long long support in printf],
1571                gdb_cv_printf_has_long_long,
1572                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1573 [[char buf[32];
1574   long long l = 0;
1575   l = (l << 16) + 0x0123;
1576   l = (l << 16) + 0x4567;
1577   l = (l << 16) + 0x89ab;
1578   l = (l << 16) + 0xcdef;
1579   sprintf (buf, "0x%016llx", l);
1580   return (strcmp ("0x0123456789abcdef", buf));]])],
1581                               gdb_cv_printf_has_long_long=yes,
1582                               gdb_cv_printf_has_long_long=no,
1583                               gdb_cv_printf_has_long_long=no)])
1584 if test $gdb_cv_printf_has_long_long = yes; then
1585   AC_DEFINE(PRINTF_HAS_LONG_LONG, 1,
1586             [Define to 1 if the "%ll" format works to print long longs.])
1587 fi
1588
1589 # Check if the compiler and runtime support printing decfloats.
1590
1591 AC_CACHE_CHECK([for decfloat support in printf],
1592                gdb_cv_printf_has_decfloat,
1593                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1594 [[char buf[64];
1595   _Decimal32 d32 = 1.2345df;
1596   _Decimal64 d64 = 1.2345dd;
1597   _Decimal128 d128 = 1.2345dl;
1598   sprintf (buf, "Decimal32: %H\nDecimal64: %D\nDecimal128: %DD", d32, d64, d128);
1599   return (strcmp ("Decimal32: 1.2345\nDecimal64: 1.2345\nDecimal128: 1.2345", buf));]])],
1600                               gdb_cv_printf_has_decfloat=yes,
1601                               gdb_cv_printf_has_decfloat=no,
1602                               gdb_cv_printf_has_decfloat=no)])
1603 if test $gdb_cv_printf_has_decfloat = yes; then
1604   AC_DEFINE(PRINTF_HAS_DECFLOAT, 1,
1605             [Define to 1 if the "%H, %D and %DD" formats work to print decfloats.])
1606 fi
1607
1608 # Check if the compiler supports the `long double' type.  We can't use
1609 # AC_C_LONG_DOUBLE because that one does additional checks on the
1610 # constants defined in <float.h> that fail on some systems,
1611 # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6.
1612
1613 AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double,
1614                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])],
1615                                   gdb_cv_c_long_double=yes,
1616                                   gdb_cv_c_long_double=no)])
1617 if test $gdb_cv_c_long_double = yes; then
1618   AC_DEFINE(HAVE_LONG_DOUBLE, 1,
1619            [Define to 1 if the compiler supports long double.])
1620 fi
1621
1622 # Check if the compiler and runtime support printing long doubles.
1623
1624 AC_CACHE_CHECK([for long double support in printf],
1625                gdb_cv_printf_has_long_double,
1626                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1627 [[char buf[16];
1628   long double f = 3.141592653;
1629   sprintf (buf, "%Lg", f);
1630   return (strncmp ("3.14159", buf, 7));]])],
1631                               gdb_cv_printf_has_long_double=yes,
1632                               gdb_cv_printf_has_long_double=no,
1633                               gdb_cv_printf_has_long_double=no)])
1634 if test $gdb_cv_printf_has_long_double = yes; then
1635   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1,
1636             [Define to 1 if the "%Lg" format works to print long doubles.])
1637 fi
1638
1639 # Check if the compiler and runtime support scanning long doubles.
1640
1641 AC_CACHE_CHECK([for long double support in scanf],
1642                gdb_cv_scanf_has_long_double,
1643                [AC_RUN_IFELSE([AC_LANG_PROGRAM(
1644 [[#include <stdio.h>]],
1645 [[char *buf = "3.141592653";
1646   long double f = 0;
1647   sscanf (buf, "%Lg", &f);
1648   return !(f > 3.14159 && f < 3.14160);]])],
1649                               gdb_cv_scanf_has_long_double=yes,
1650                               gdb_cv_scanf_has_long_double=no,
1651                               gdb_cv_scanf_has_long_double=no)])
1652 if test $gdb_cv_scanf_has_long_double = yes; then
1653   AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1,
1654             [Define to 1 if the "%Lg" format works to scan long doubles.])
1655 fi
1656
1657 case ${host_os} in
1658 aix*)
1659   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1660     SAVE_LDFLAGS=$LDFLAGS
1661
1662     case $GCC in
1663     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1664     *) gdb_cv_bigtoc=-bbigtoc ;;
1665     esac
1666
1667     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1668     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1669     LDFLAGS="${SAVE_LDFLAGS}"
1670   ])
1671   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
1672   ;;
1673 esac
1674
1675 AC_MSG_CHECKING(for the dynamic export flag)
1676 dynamic_list=false
1677 if test "${gdb_native}" = yes; then
1678    # The dynamically loaded libthread_db needs access to symbols in the gdb
1679    # executable.  Older GNU ld supports --export-dynamic but --dynamic-list
1680    # may not be supported there.
1681    old_LDFLAGS="$LDFLAGS"
1682    # Older GNU ld supports --export-dynamic but --dynamic-list it does not.
1683    RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
1684    LDFLAGS="$LDFLAGS $RDYNAMIC"
1685    if test "${have_libpython}" = no; then
1686      AC_TRY_LINK([], [], [dynamic_list=true])
1687    else
1688      # Workaround http://bugs.python.org/issue4434 where static
1689      # libpythonX.Y.a would get its symbols required for
1690      # pythonX.Y/lib-dynload/*.so modules hidden by -Wl,--dynamic-list.
1691      # Problem does not happen for the recommended libpythonX.Y.so linkage.
1692      old_CFLAGS="$CFLAGS"
1693      CFLAGS="$CFLAGS $PYTHON_CFLAGS"
1694      old_LIBS="$LIBS"
1695      LIBS="$LIBS $PYTHON_LIBS"
1696      AC_RUN_IFELSE(
1697        AC_LANG_PROGRAM(
1698          [#include "]${have_libpython}[/Python.h"],
1699          [int err;
1700           Py_Initialize ();
1701           err = PyRun_SimpleString ("import itertools\n");
1702           Py_Finalize ();
1703           return err == 0 ? 0 : 1;]),
1704        [dynamic_list=true], [], [true])
1705      LIBS="$old_LIBS"
1706      CFLAGS="$old_CFLAGS"
1707    fi
1708    LDFLAGS="$old_LDFLAGS"
1709 fi
1710 if $dynamic_list; then
1711   found="-Wl,--dynamic-list"
1712   RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'
1713 else
1714   found="-rdynamic"
1715   RDYNAMIC="-rdynamic"
1716 fi
1717 AC_SUBST(RDYNAMIC)
1718 AC_MSG_RESULT($found)
1719
1720 dnl For certain native configurations, we need to check whether thread
1721 dnl support can be built in or not.
1722 dnl
1723 dnl Note that we only want this if we are both native (host == target),
1724 dnl and not doing a canadian cross build (build == host).
1725
1726 if test ${build} = ${host} -a ${host} = ${target} ; then
1727    case ${host_os} in
1728    solaris*)
1729       # See if thread_db library is around for Solaris thread debugging.
1730       # Note that we must explicitly test for version 1 of the library
1731       # because version 0 (present on Solaris 2.4 or earlier) doesn't have
1732       # the same API.
1733       AC_MSG_CHECKING(for Solaris thread debugging library)
1734       if test -f /usr/lib/libthread_db.so.1 ; then
1735          AC_MSG_RESULT(yes)
1736          AC_DEFINE(HAVE_THREAD_DB_LIB, 1,
1737          [Define if using Solaris thread debugging.])
1738          CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
1739          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
1740          AC_CHECK_LIB(dl, dlopen)
1741          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} $RDYNAMIC"
1742          # Sun randomly tweaked the prototypes in <proc_service.h>
1743          # at one point.
1744          AC_MSG_CHECKING(if <proc_service.h> is old)
1745          AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
1746             AC_TRY_COMPILE([
1747                 #include <proc_service.h>
1748                 ps_err_e ps_pdwrite
1749                     (struct ps_prochandle*, psaddr_t, const void*, size_t);
1750             ],, gdb_cv_proc_service_is_old=no,
1751                 gdb_cv_proc_service_is_old=yes)
1752          ])
1753          AC_MSG_RESULT($gdb_cv_proc_service_is_old)
1754          if test $gdb_cv_proc_service_is_old = yes; then
1755             AC_DEFINE(PROC_SERVICE_IS_OLD, 1,
1756             [Define if <proc_service.h> on solaris uses int instead of
1757              size_t, and assorted other type changes.])
1758          fi
1759       else
1760          AC_MSG_RESULT(no)
1761       fi
1762       ;;
1763    aix*)
1764       AC_MSG_CHECKING(for AiX thread debugging library)
1765       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
1766                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
1767                                    [#ifndef PTHDB_VERSION_3
1768                                     #error
1769                                     #endif],
1770                                    gdb_cv_have_aix_thread_debug=yes,
1771                                    gdb_cv_have_aix_thread_debug=no)])
1772       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1773       if test $gdb_cv_have_aix_thread_debug = yes; then
1774          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1775          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1776          LIBS="$LIBS -lpthdebug"
1777
1778          # Older versions of AIX do not provide the declaration for
1779          # the getthrds function (it appears that it was introduced
1780          # with AIX 6.x).
1781          AC_CHECK_DECLS(getthrds, [], [], [[#include <procinfo.h>]])
1782       fi
1783       ;;
1784    esac
1785    AC_SUBST(CONFIG_LDFLAGS)
1786 fi
1787
1788 dnl See if we have a thread_db header file that has TD_NOTALLOC and
1789 dnl other error codes.
1790 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1791    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
1792                   gdb_cv_thread_db_h_has_td_notalloc,
1793      AC_TRY_COMPILE(
1794        [#include <thread_db.h>],
1795        [int i = TD_NOTALLOC;],
1796        gdb_cv_thread_db_h_has_td_notalloc=yes,
1797        gdb_cv_thread_db_h_has_td_notalloc=no
1798      )
1799    )
1800    AC_CACHE_CHECK([whether <thread_db.h> has TD_VERSION],
1801                   gdb_cv_thread_db_h_has_td_version,
1802      AC_TRY_COMPILE(
1803        [#include <thread_db.h>],
1804        [int i = TD_VERSION;],
1805        gdb_cv_thread_db_h_has_td_version=yes,
1806        gdb_cv_thread_db_h_has_td_version=no
1807      )
1808    )
1809    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTLS],
1810                   gdb_cv_thread_db_h_has_td_notls,
1811      AC_TRY_COMPILE(
1812        [#include <thread_db.h>],
1813        [int i = TD_NOTLS;],
1814        gdb_cv_thread_db_h_has_td_notls=yes,
1815        gdb_cv_thread_db_h_has_td_notls=no
1816      )
1817    )
1818 fi
1819 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1820   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1821             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1822 fi
1823 if test "x$gdb_cv_thread_db_h_has_td_version" = "xyes"; then
1824   AC_DEFINE(THREAD_DB_HAS_TD_VERSION, 1,
1825             [Define if <thread_db.h> has the TD_VERSION error code.])
1826 fi
1827 if test "x$gdb_cv_thread_db_h_has_td_notls" = "xyes"; then
1828   AC_DEFINE(THREAD_DB_HAS_TD_NOTLS, 1,
1829             [Define if <thread_db.h> has the TD_NOTLS error code.])
1830 fi
1831
1832 dnl See if we have a sys/syscall header file that has __NR_tkill.
1833 if test "x$ac_cv_header_sys_syscall_h" = "xyes"; then
1834    AC_CACHE_CHECK([whether <sys/syscall.h> has __NR_tkill],
1835                   gdb_cv_sys_syscall_h_has_tkill,
1836      AC_TRY_COMPILE(
1837        [#include <sys/syscall.h>],
1838        [int i = __NR_tkill;],
1839        gdb_cv_sys_syscall_h_has_tkill=yes,
1840        gdb_cv_sys_syscall_h_has_tkill=no
1841      )
1842    )
1843 fi
1844 dnl See if we can issue tkill syscall.
1845 if test "x$gdb_cv_sys_syscall_h_has_tkill" = "xyes" && test "x$ac_cv_func_syscall" = "xyes"; then
1846   AC_DEFINE(HAVE_TKILL_SYSCALL, 1, [Define if you support the tkill syscall.])
1847 fi
1848
1849 dnl Check if we can disable the virtual address space randomization.
1850 dnl The functionality of setarch -R.
1851 AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>])
1852 define([PERSONALITY_TEST], [AC_LANG_PROGRAM([#include <sys/personality.h>], [
1853 #      if !HAVE_DECL_ADDR_NO_RANDOMIZE
1854 #       define ADDR_NO_RANDOMIZE 0x0040000
1855 #      endif
1856        /* Test the flag could be set and stays set.  */
1857        personality (personality (0xffffffff) | ADDR_NO_RANDOMIZE);
1858        if (!(personality (personality (0xffffffff)) & ADDR_NO_RANDOMIZE))
1859            return 1])])
1860 AC_RUN_IFELSE([PERSONALITY_TEST],
1861               [have_personality=true],
1862               [have_personality=false],
1863               [AC_LINK_IFELSE([PERSONALITY_TEST],
1864                               [have_personality=true],
1865                               [have_personality=false])])
1866 if $have_personality
1867 then
1868     AC_DEFINE([HAVE_PERSONALITY], 1,
1869               [Define if you support the personality syscall.])
1870 fi
1871
1872 dnl Set the host's .gdbinit filename.
1873 case $host_os in
1874   go32* | *djgpp*)
1875     gdbinit=gdb.ini
1876     ;;
1877   *)
1878     gdbinit=.gdbinit
1879     ;;
1880 esac
1881 AC_DEFINE_UNQUOTED(GDBINIT,"$gdbinit",[The .gdbinit filename.])
1882
1883 dnl Handle optional features that can be enabled.
1884
1885 # Support for --with-sysroot is a copy of GDB_AC_WITH_DIR,
1886 # except that the argument to --with-sysroot is optional.
1887 # --with-sysroot (or --with-sysroot=yes) sets the default sysroot path.
1888 if test "x$with_sysroot" = xyes; then
1889   with_sysroot="${exec_prefix}/${target_alias}/sys-root"
1890 fi
1891 AC_ARG_WITH(sysroot,
1892   AS_HELP_STRING([--with-sysroot@<:@=DIR@:>@],
1893                  [search for usr/lib et al within DIR]),
1894   [TARGET_SYSTEM_ROOT=$withval], [TARGET_SYSTEM_ROOT=])
1895 AC_DEFINE_DIR(TARGET_SYSTEM_ROOT, TARGET_SYSTEM_ROOT,
1896               [search for usr/lib et al within DIR])
1897 AC_SUBST(TARGET_SYSTEM_ROOT)
1898 GDB_AC_DEFINE_RELOCATABLE(TARGET_SYSTEM_ROOT, sysroot, ${ac_define_dir})
1899
1900 GDB_AC_WITH_DIR(SYSTEM_GDBINIT, system-gdbinit,
1901     [automatically load a system-wide gdbinit file],
1902     [])
1903
1904 AC_ARG_ENABLE(werror,
1905   AS_HELP_STRING([--enable-werror], [treat compile warnings as errors]),
1906   [case "${enableval}" in
1907      yes | y) ERROR_ON_WARNING="yes" ;;
1908      no | n)  ERROR_ON_WARNING="no" ;;
1909      *) AC_MSG_ERROR(bad value ${enableval} for --enable-werror) ;;
1910    esac])
1911
1912 # Enable -Werror by default when using gcc.  Turn it off for releases.
1913 if test "${GCC}" = yes -a -z "${ERROR_ON_WARNING}" && $development; then
1914     ERROR_ON_WARNING=yes
1915 fi
1916
1917 WERROR_CFLAGS=""
1918 if test "${ERROR_ON_WARNING}" = yes ; then
1919     WERROR_CFLAGS="-Werror"
1920 fi
1921
1922 # The entries after -Wno-pointer-sign are disabled warnings which may
1923 # be enabled in the future, which can not currently be used to build
1924 # GDB.
1925 # NOTE: If you change this list, remember to update
1926 # gdb/doc/gdbint.texinfo.
1927 build_warnings="-Wall -Wdeclaration-after-statement -Wpointer-arith \
1928 -Wpointer-sign \
1929 -Wno-unused -Wunused-value -Wunused-function \
1930 -Wno-switch -Wno-char-subscripts -Wmissing-prototypes \
1931 -Wdeclaration-after-statement -Wempty-body -Wmissing-parameter-type \
1932 -Wold-style-declaration -Wold-style-definition"
1933
1934 # Enable -Wno-format by default when using gcc on mingw since many
1935 # GCC versions complain about %I64.
1936 case "${host}" in
1937   *-*-mingw32*) build_warnings="$build_warnings -Wno-format" ;;
1938   *) build_warnings="$build_warnings -Wformat-nonliteral" ;;
1939 esac
1940
1941 AC_ARG_ENABLE(build-warnings,
1942 AS_HELP_STRING([--enable-build-warnings], [enable build-time compiler warnings if gcc is used]),
1943 [case "${enableval}" in
1944   yes)  ;;
1945   no)   build_warnings="-w";;
1946   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1947         build_warnings="${build_warnings} ${t}";;
1948   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1949         build_warnings="${t} ${build_warnings}";;
1950   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1951 esac
1952 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1953   echo "Setting compiler warning flags = $build_warnings" 6>&1
1954 fi])dnl
1955 AC_ARG_ENABLE(gdb-build-warnings,
1956 AS_HELP_STRING([--enable-gdb-build-warnings], [enable GDB specific build-time compiler warnings if gcc is used]),
1957 [case "${enableval}" in
1958   yes)  ;;
1959   no)   build_warnings="-w";;
1960   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1961         build_warnings="${build_warnings} ${t}";;
1962   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1963         build_warnings="${t} ${build_warnings}";;
1964   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1965 esac
1966 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1967   echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1
1968 fi])dnl
1969 WARN_CFLAGS=""
1970 if test "x${build_warnings}" != x -a "x$GCC" = xyes
1971 then
1972     AC_MSG_CHECKING(compiler warning flags)
1973     # Separate out the -Werror flag as some files just cannot be
1974     # compiled with it enabled.
1975     for w in ${build_warnings}; do
1976         case $w in
1977         -Werr*) WERROR_CFLAGS=-Werror ;;
1978         *) # Check that GCC accepts it
1979             saved_CFLAGS="$CFLAGS"
1980             CFLAGS="$CFLAGS $w"
1981             AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
1982             CFLAGS="$saved_CFLAGS"
1983         esac
1984     done
1985     AC_MSG_RESULT(${WARN_CFLAGS} ${WERROR_CFLAGS})
1986 fi
1987 AC_SUBST(WARN_CFLAGS)
1988 AC_SUBST(WERROR_CFLAGS)
1989
1990 # In the Cygwin environment, we need some additional flags.
1991 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1992 [AC_EGREP_CPP(lose, [
1993 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1994 lose
1995 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1996
1997
1998 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1999 SER_HARDWIRE="ser-base.o ser-unix.o ser-pipe.o ser-tcp.o"
2000 case ${host} in
2001   *go32* ) SER_HARDWIRE=ser-go32.o ;;
2002   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
2003   *mingw32*) SER_HARDWIRE="ser-base.o ser-tcp.o ser-mingw.o" ;;
2004 esac
2005 AC_SUBST(SER_HARDWIRE)
2006
2007 # libreadline needs libuser32.a in a cygwin environment
2008 WIN32LIBS=
2009 if test x$gdb_cv_os_cygwin = xyes; then
2010     WIN32LIBS="-luser32"
2011     case "${target}" in
2012         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
2013         ;;
2014     esac
2015 fi
2016
2017 # The ser-tcp.c module requires sockets.
2018 case ${host} in
2019   *mingw32*)
2020     AC_DEFINE(USE_WIN32API, 1,
2021               [Define if we should use the Windows API, instead of the
2022                POSIX API.  On Windows, we use the Windows API when
2023                building for MinGW, but the POSIX API when building
2024                for Cygwin.])
2025     WIN32LIBS="$WIN32LIBS -lws2_32"
2026     ;;
2027 esac
2028 AC_SUBST(WIN32LIBS)
2029
2030 # Add ELF support to GDB, but only if BFD includes ELF support.
2031 GDB_AC_CHECK_BFD([for ELF support in BFD], gdb_cv_var_elf,
2032                  [bfd_get_elf_phdr_upper_bound (NULL)], elf-bfd.h)
2033 if test $gdb_cv_var_elf = yes; then
2034   CONFIG_OBS="$CONFIG_OBS elfread.o stap-probe.o"
2035   AC_DEFINE(HAVE_ELF, 1,
2036             [Define if ELF support should be included.])
2037   # -ldl is provided by bfd/Makfile.am (LIBDL) <PLUGINS>.
2038   if test "$plugins" = "yes"; then
2039     AC_SEARCH_LIBS(dlopen, dl)
2040   fi
2041 fi
2042
2043 # Add macho support to GDB, but only if BFD includes it.
2044 GDB_AC_CHECK_BFD([for Mach-O support in BFD], gdb_cv_var_macho,
2045                  [bfd_mach_o_lookup_command (NULL, 0, NULL)], mach-o.h)
2046 if test $gdb_cv_var_macho = yes; then
2047   CONFIG_OBS="$CONFIG_OBS machoread.o"
2048 fi
2049
2050 # Add SOM support to GDB, but only if BFD includes it.
2051 GDB_AC_CHECK_BFD([for SOM support in BFD], gdb_cv_var_som,
2052                  [bfd_som_attach_aux_hdr (NULL, 0, NULL)], som.h)
2053 if test $gdb_cv_var_som = yes; then
2054   CONFIG_OBS="$CONFIG_OBS somread.o"
2055 fi
2056
2057 # Add any host-specific objects to GDB.
2058 CONFIG_OBS="${CONFIG_OBS} ${gdb_host_obs}"
2059
2060 # If building on ELF, look for lzma support for embedded compressed debug info.
2061 if test $gdb_cv_var_elf = yes; then
2062   AC_ARG_WITH(lzma,
2063     AS_HELP_STRING([--with-lzma], [support lzma compression (auto/yes/no)]),
2064     [], [with_lzma=auto])
2065   AC_MSG_CHECKING([whether to use lzma])
2066   AC_MSG_RESULT([$with_lzma])
2067
2068   if test "${with_lzma}" != no; then
2069     AC_LIB_HAVE_LINKFLAGS([lzma], [], [#include "lzma.h"],
2070                           [lzma_index_iter iter;
2071                            lzma_index_iter_init (&iter, 0);
2072                            lzma_mf_is_supported (LZMA_MF_HC3);])
2073     if test "$HAVE_LIBLZMA" != yes; then
2074       if test "$with_lzma" = yes; then
2075         AC_MSG_ERROR([missing liblzma for --with-lzma])
2076       fi
2077     fi
2078   fi
2079 fi
2080
2081 LIBGUI="../libgui/src/libgui.a"
2082 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
2083 AC_SUBST(LIBGUI)
2084 AC_SUBST(GUI_CFLAGS_X)
2085
2086 WIN32LDAPP=
2087 AC_SUBST(WIN32LIBS)
2088 AC_SUBST(WIN32LDAPP)
2089
2090 case "${host}" in
2091 *-*-cygwin* | *-*-mingw* )
2092     configdir="win"
2093     ;;
2094 *)
2095     configdir="unix"
2096     ;;
2097 esac
2098
2099 GDBTKLIBS=
2100 if test "${enable_gdbtk}" = "yes"; then
2101
2102     # Gdbtk must have an absolute path to srcdir in order to run
2103     # properly when not installed.
2104     here=`pwd`
2105     cd ${srcdir}
2106     GDBTK_SRC_DIR=`pwd`
2107     cd $here
2108
2109     SC_PATH_TCLCONFIG
2110
2111     # If $no_tk is nonempty, then we can't do Tk, and there is no
2112     # point to doing Tcl.
2113     SC_PATH_TKCONFIG
2114
2115     if test -z "${no_tcl}" -a -z "${no_tk}"; then
2116         SC_LOAD_TCLCONFIG
2117
2118         # Check for in-tree tcl
2119         here=`pwd`
2120         cd ${srcdir}/..
2121         topdir=`pwd`
2122         cd ${here}
2123
2124         intree="no"
2125         if test "${TCL_SRC_DIR}" = "${topdir}/tcl"; then
2126           intree="yes"
2127         fi
2128
2129         # Find Tcl private headers
2130         if test x"${intree}" = xno; then
2131           CY_AC_TCL_PRIVATE_HEADERS
2132           TCL_INCLUDE="${TCL_INCLUDE_SPEC} ${TCL_PRIVATE_INCLUDE}"
2133           TCL_LIBRARY="${TCL_LIB_SPEC}"
2134           TCL_DEPS=""
2135         else
2136           # If building tcl in the same src tree, private headers
2137           # are not needed, but we need to be sure to use the right
2138           # headers library
2139           TCL_INCLUDE="-I${TCL_SRC_DIR}/generic"
2140           TCL_LIBRARY="${TCL_BUILD_LIB_SPEC}"
2141           TCL_DEPS="../tcl/${configdir}${TCL_LIB_FILE}"
2142         fi
2143         AC_SUBST(TCL_INCLUDE)
2144         AC_SUBST(TCL_LIBRARY)
2145         AC_SUBST(TCL_DEPS)
2146
2147         SC_LOAD_TKCONFIG
2148
2149         # Check for in-tree Tk
2150         intree="no"
2151         if test "${TK_SRC_DIR}" = "${topdir}/tk"; then
2152           intree="yes"
2153         fi
2154
2155         # Find Tk private headers
2156         if test x"${intree}" = xno; then
2157           CY_AC_TK_PRIVATE_HEADERS
2158           TK_INCLUDE="${TK_INCLUDE_SPEC} ${TK_PRIVATE_INCLUDE}"
2159           TK_LIBRARY=${TK_LIB_SPEC}
2160           TK_DEPS=""
2161         else
2162           TK_INCLUDE="-I${TK_SRC_DIR}/generic"
2163           TK_LIBRARY="${TK_BUILD_LIB_SPEC}"
2164           TK_DEPS="../tk/${configdir}/${TK_LIB_FILE}"
2165         fi
2166         AC_SUBST(TK_INCLUDE)
2167         AC_SUBST(TK_LIBRARY)
2168         AC_SUBST(TK_DEPS)
2169         AC_SUBST(TK_XINCLUDES)
2170
2171         ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
2172
2173         # Include some libraries that Tcl and Tk want.
2174         TCL_LIBS='$(LIBGUI) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
2175         # Yes, the ordering seems wrong here.  But it isn't.
2176         # TK_LIBS is the list of libraries that need to be linked
2177         # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
2178         # were in LIBS then any link tests after this point would
2179         # try to include things like `$(LIBGUI)', which wouldn't work.
2180         GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
2181
2182         CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
2183         CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
2184         CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
2185         CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
2186         CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
2187         CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
2188         CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
2189
2190         if test x$gdb_cv_os_cygwin = xyes; then
2191           WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
2192           WIN32LDAPP="-Wl,--subsystem,console"
2193           CONFIG_OBS="${CONFIG_OBS} gdbres.o"
2194         fi
2195
2196         AC_CONFIG_SUBDIRS(gdbtk)
2197     fi
2198 fi
2199
2200 AC_SUBST(X_CFLAGS)
2201 AC_SUBST(X_LDFLAGS)
2202 AC_SUBST(X_LIBS)
2203 AC_SUBST(GDBTKLIBS)
2204 AC_SUBST(GDBTK_CFLAGS)
2205 AC_SUBST(GDBTK_SRC_DIR)
2206
2207 AC_PATH_X
2208
2209 # Unlike the sim directory, whether a simulator is linked is controlled by
2210 # presence of a gdb_sim definition in the target configure.tgt entry.
2211 # This code just checks for a few cases where we'd like to ignore those
2212 # definitions, even when they're present in the '.mt' file.  These cases
2213 # are when --disable-sim is specified, or if the simulator directory is
2214 # not part of the source tree.
2215 #
2216 AC_ARG_ENABLE(sim,
2217 AS_HELP_STRING([--enable-sim], [link gdb with simulator]),
2218 [echo "enable_sim = $enable_sim";
2219  echo "enableval = ${enableval}";
2220  case "${enableval}" in
2221   yes) ignore_sim=false ;;
2222   no)  ignore_sim=true ;;
2223   *)   ignore_sim=false ;;
2224  esac],
2225 [ignore_sim=false])
2226
2227 if test ! -d "${srcdir}/../sim"; then
2228   ignore_sim=true
2229 fi
2230
2231 SIM=
2232 SIM_OBS=
2233 if test "${ignore_sim}" = "false"; then
2234   if test x"${gdb_sim}" != x ; then
2235     SIM="${gdb_sim}"
2236     SIM_OBS="remote-sim.o"
2237     AC_DEFINE(WITH_SIM, 1, [Define if the simulator is being linked in.])
2238   fi
2239 fi
2240 AC_SUBST(SIM)
2241 AC_SUBST(SIM_OBS)
2242
2243 AC_SUBST(ENABLE_CFLAGS)
2244 AC_SUBST(PROFILE_CFLAGS)
2245
2246 AC_SUBST(CONFIG_OBS)
2247 AC_SUBST(CONFIG_DEPS)
2248 AC_SUBST(CONFIG_SRCS)
2249 AC_SUBST(CONFIG_ALL)
2250 AC_SUBST(CONFIG_CLEAN)
2251 AC_SUBST(CONFIG_INSTALL)
2252 AC_SUBST(CONFIG_UNINSTALL)
2253
2254 # List of host floatformats.
2255 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
2256 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
2257 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
2258
2259 # target_subdir is used by the testsuite to find the target libraries.
2260 target_subdir=
2261 if test "${host}" != "${target}"; then
2262     target_subdir="${target_alias}/"
2263 fi
2264 AC_SUBST(target_subdir)
2265
2266 frags=
2267 if test "${gdb_native}" = "yes"; then
2268   host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
2269   if test ! -f ${host_makefile_frag}; then
2270     AC_MSG_ERROR("*** Gdb does not support native target ${host}")
2271   fi
2272   frags="$frags $host_makefile_frag"
2273 else
2274   host_makefile_frag=/dev/null
2275 fi
2276
2277 AC_SUBST_FILE(host_makefile_frag)
2278 AC_SUBST(frags)
2279
2280 changequote(,)dnl
2281 if test "${gdb_native}" = "yes"; then
2282 # We pick this up from the host configuration file (.mh) because we
2283 # do not have a native configuration Makefile fragment.
2284 nativefile=`sed -n '
2285 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
2286 ' ${host_makefile_frag}`
2287 fi
2288 changequote([,])
2289
2290 if test x"${gdb_osabi}" != x ; then
2291     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
2292                        [Define to the default OS ABI for this configuration.])
2293 fi
2294
2295 # Enable multi-ice-gdb-server.
2296 AC_ARG_ENABLE(multi-ice,
2297 AS_HELP_STRING([--enable-multi-ice], [build the multi-ice-gdb-server]),
2298   [case $enableval in
2299     yes | no)
2300       ;;
2301     *) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;;
2302   esac])
2303 if test "x$enable_multi_ice" = xyes; then
2304    AC_CONFIG_SUBDIRS(multi-ice)
2305 fi
2306
2307 AC_ARG_ENABLE(gdbserver,
2308 AS_HELP_STRING([--enable-gdbserver],
2309                [automatically build gdbserver (yes/no/auto, default is auto)]),
2310 [case "${enableval}" in
2311   yes| no|auto) ;;
2312   *) AC_MSG_ERROR(bad value ${enableval} for --enable-gdbserver option) ;;
2313 esac],[enable_gdbserver=auto])
2314
2315 # We only build gdbserver automatically in a native configuration, and
2316 # only if the user did not explicitly disable its build.
2317 if test "$gdb_native" = "yes" -a "$enable_gdbserver" != "no"; then
2318   AC_MSG_CHECKING(whether gdbserver is supported on this host)
2319   if test "x$build_gdbserver" = xyes; then
2320     AC_MSG_RESULT(yes)
2321     AC_CONFIG_SUBDIRS(gdbserver)
2322     gdbserver_build_enabled=yes
2323   else
2324     AC_MSG_RESULT(no)
2325   fi
2326 fi
2327
2328 # If the user explicitly request the gdbserver to be built, verify that
2329 # we were in fact able to enable it.
2330 if test "$enable_gdbserver" = "yes" -a "$gdbserver_build_enabled" != "yes"; then
2331   AC_MSG_ERROR(Automatic gdbserver build is not supported for this configuration)
2332 fi
2333
2334 # Check for babeltrace and babeltrace-ctf
2335 AC_ARG_WITH(babeltrace,
2336   AC_HELP_STRING([--with-babeltrace], [include babeltrace support (auto/yes/no)]),
2337   [], [with_babeltrace=auto])
2338 AC_MSG_CHECKING([whether to use babeltrace])
2339 AC_MSG_RESULT([$with_babeltrace])
2340
2341 if test "x$with_babeltrace" = "xno"; then
2342   AC_MSG_WARN([babletrace support disabled; GDB is unable to read CTF data.])
2343 else
2344   # Append -Werror to CFLAGS so that configure can catch the warning
2345   # "assignment from incompatible pointer type", which is related to
2346   # the babeltrace change from 1.0.3 to 1.1.0.  Babeltrace 1.1.0 works
2347   # in GDB, while babeltrace 1.0.3 is broken.
2348   # AC_LIB_HAVE_LINKFLAGS may modify CPPFLAGS in it, so it should be
2349   # safe to save and restore CFLAGS here.
2350   saved_CFLAGS=$CFLAGS
2351   CFLAGS="$CFLAGS -Werror"
2352   AC_LIB_HAVE_LINKFLAGS([babeltrace], [babeltrace-ctf],
2353                         [#include <babeltrace/babeltrace.h>
2354                          #include <babeltrace/ctf/events.h>
2355                          #include <babeltrace/ctf/iterator.h>],
2356                         [struct bt_iter_pos *pos = bt_iter_get_pos (bt_ctf_get_iter (NULL));
2357                         struct bt_ctf_event *event = NULL;
2358                         const struct bt_definition *scope;
2359
2360                         scope = bt_ctf_get_top_level_scope (event,
2361                                                            BT_STREAM_EVENT_HEADER);
2362                         bt_ctf_get_uint64 (bt_ctf_get_field (event, scope, "id"));
2363                         ])
2364   CFLAGS=$saved_CFLAGS
2365
2366   if test "$HAVE_LIBBABELTRACE" != yes; then
2367      if test "$with_babeltrace" = yes; then
2368        AC_MSG_ERROR([babeltrace is missing or unusable])
2369      else
2370        AC_MSG_WARN([babeltrace is missing or unusable; GDB is unable to read CTF data.])
2371      fi
2372   fi
2373 fi
2374
2375 # If nativefile (NAT_FILE) is not set in config/*/*.m[ht] files, we link
2376 # to an empty version.
2377
2378 files=
2379 links=
2380
2381 rm -f nm.h
2382 if test "${nativefile}" != ""; then
2383     case "${nativefile}" in
2384       nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
2385       * ) GDB_NM_FILE="${nativefile}"
2386     esac
2387     files="${files} ${GDB_NM_FILE}"
2388     links="${links} nm.h"
2389     AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}", [nativefile])
2390 fi
2391 AC_SUBST(GDB_NM_FILE)
2392
2393 AC_LINK_FILES($files, $links)
2394
2395 dnl Check for exe extension set on certain hosts (e.g. Win32)
2396 AC_EXEEXT
2397
2398 dnl  Detect the character set used by this host.
2399 dnl  At the moment, we just assume it's UTF-8.
2400 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "UTF-8",
2401           [Define to be a string naming the default host character set.])
2402
2403 # Undo the $ec_script escaping suitable for Makefile.
2404 transform=`echo "$program_transform_name" | sed -e 's/[\\$][\\$]/\\$/g'`
2405 GDB_TRANSFORM_NAME=`echo gdb | sed -e "$transform"`
2406 if test "x$GDB_TRANSFORM_NAME" = x; then
2407   GDB_TRANSFORM_NAME=gdb
2408 fi
2409 AC_SUBST(GDB_TRANSFORM_NAME)
2410 GCORE_TRANSFORM_NAME=`echo gcore | sed -e "$transform"`
2411 if test "x$GCORE_TRANSFORM_NAME" = x; then
2412   GCORE_TRANSFORM_NAME=gcore
2413 fi
2414 AC_SUBST(GCORE_TRANSFORM_NAME)
2415 AC_CONFIG_FILES([gcore], [chmod +x gcore])
2416
2417 AC_OUTPUT(Makefile gdb-gdb.gdb doc/Makefile data-directory/Makefile,
2418 [
2419 case x$CONFIG_HEADERS in
2420 xconfig.h:config.in)
2421 echo > stamp-h ;;
2422 esac
2423 ])
2424
2425 exit 0