gdb/configure.ac

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995-2015 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Process this file with autoconf to produce a configure script.
  20
  21 AC_PREREQ(2.59)dnl
  22 AC_INIT(main.c)
  23 AC_CONFIG_HEADER(config.h:config.in)
  24 AM_MAINTAINER_MODE
  25
  26 # Set the 'development' global.
  27 . $srcdir/../bfd/development.sh
  28
  29 AC_PROG_CC
  30 AC_PROG_CXX
  31
  32 AC_USE_SYSTEM_EXTENSIONS
  33 ACX_LARGEFILE
  34 AM_PROG_CC_STDC
  35 AM_PROG_INSTALL_STRIP
  36
  37 AC_CONFIG_AUX_DIR(..)
  38 AC_CANONICAL_SYSTEM
  39 AC_ARG_PROGRAM
  40
  41 # See if we are building with C++, and substitute COMPILER.
  42 GDB_AC_BUILD_WITH_CXX
  43
  44 # Dependency checking.
  45 ZW_CREATE_DEPDIR
  46 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  47
  48 # Check for the 'make' the user wants to use.
  49 AC_CHECK_PROGS(MAKE, make)
  50 MAKE_IS_GNU=
  51 case "`$MAKE --version 2>&1 | sed 1q`" in
  52   *GNU*)
  53     MAKE_IS_GNU=yes
  54     ;;
  55 esac
  56 AM_CONDITIONAL(GMAKE, test "$MAKE_IS_GNU" = yes)
  57 AC_PROG_MAKE_SET
  58
  59 gnulib_extra_configure_args=
  60 # If large-file support is disabled, make sure gnulib does the same.
  61 if test "$enable_largefile" = no; then
  62 gnulib_extra_configure_args="$gnulib_extra_configure_args --disable-largefile"
  63 fi
  64
  65 # Configure gnulib.  We need to build gnulib under some other
  66 # directory not "gnulib", to avoid the problem of both GDB and
  67 # GDBserver wanting to build it in the same directory, when building
  68 # in the source dir.
  69 ACX_CONFIGURE_DIR(["gnulib"], ["build-gnulib"],
  70                   ["$gnulib_extra_configure_args"])
  71
  72 dnl List of object files and targets accumulated by configure.
  73
  74 CONFIG_OBS=
  75 CONFIG_DEPS=
  76 CONFIG_SRCS=
  77 ENABLE_CFLAGS=
  78
  79 CONFIG_ALL=
  80 CONFIG_CLEAN=
  81 CONFIG_INSTALL=
  82 CONFIG_UNINSTALL=
  83
  84 dnl Set up for gettext.
  85 ZW_GNU_GETTEXT_SISTER_DIR
  86
  87 localedir='${datadir}/locale'
  88 AC_SUBST(localedir)
  89
  90 if test x"$USE_NLS" = xyes; then
  91    CONFIG_ALL="$CONFIG_ALL all-po"
  92    CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
  93    CONFIG_INSTALL="$CONFIG_INSTALL install-po"
  94    CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
  95 fi
  96
  97 GNULIB=build-gnulib/import
  98
  99 # For Makefile dependencies.
 100 GNULIB_STDINT_H=
 101 if test x"$STDINT_H" != x; then
 102   GNULIB_STDINT_H=$GNULIB/$STDINT_H
 103 fi
 104 AC_SUBST(GNULIB_STDINT_H)
 105
 106 PACKAGE=gdb
 107 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
 108 AC_SUBST(PACKAGE)
 109
 110 # We never need to detect it in this sub-configure.
 111 # But preserve it for config.status --recheck.
 112 AC_ARG_VAR(MAKEINFO,
 113   [Parent configure detects if it is of sufficient version.])
 114 AC_ARG_VAR(MAKEINFOFLAGS,
 115   [Parameters for MAKEINFO.])
 116
 117 MAKEINFO_EXTRA_FLAGS=""
 118 AC_CACHE_CHECK([whether $MAKEINFO supports @click], gdb_cv_have_makeinfo_click,
 119   [echo '@clicksequence{a @click{} b}' >conftest.texinfo
 120   if eval "$MAKEINFO conftest.texinfo >&5 2>&5"; then
 121     gdb_cv_have_makeinfo_click=yes
 122   else
 123     gdb_cv_have_makeinfo_click=no
 124   fi])
 125 if test x"$gdb_cv_have_makeinfo_click" = xyes; then
 126   MAKEINFO_EXTRA_FLAGS="$MAKEINFO_EXTRA_FLAGS -DHAVE_MAKEINFO_CLICK"
 127 fi
 128 AC_SUBST(MAKEINFO_EXTRA_FLAGS)
 129
 130 GDB_AC_WITH_DIR(DEBUGDIR, separate-debug-dir,
 131     [look for global separate debug info in this path @<:@LIBDIR/debug@:>@],
 132     [${libdir}/debug])
 133
 134 # We can't pass paths as command line arguments.
 135 # Mingw32 tries to be clever and will convert the paths for us.
 136 # For example -DBINDIR="/usr/local/bin" passed on the command line may get
 137 # converted to -DBINDIR="E:/msys/mingw32/msys/1.0/local/bin".
 138 # This breaks GDB's relocatable path conversions since paths passed in
 139 # config.h would not get so translated, the path prefixes no longer match.
 140 AC_DEFINE_DIR(BINDIR, bindir, [Directory of programs.])
 141
 142 # GDB's datadir relocation
 143
 144 GDB_AC_WITH_DIR(GDB_DATADIR, gdb-datadir,
 145     [look for global separate data files in this path @<:@DATADIR/gdb@:>@],
 146     [${datadir}/gdb])
 147
 148 AC_ARG_WITH(relocated-sources,
 149 AS_HELP_STRING([--with-relocated-sources=PATH], [automatically relocate this path for source files]),
 150 [reloc_srcdir="${withval}"
 151  AC_DEFINE_DIR(RELOC_SRCDIR, reloc_srcdir,
 152               [Relocated directory for source files. ])
 153 ])
 154
 155 AC_MSG_CHECKING([for default auto-load directory])
 156 AC_ARG_WITH(auto-load-dir,
 157 AS_HELP_STRING([--with-auto-load-dir=PATH],
 158   [directories from which to load auto-loaded scripts @<:@$debugdir:$datadir/auto-load@:>@]),,
 159   [with_auto_load_dir='$debugdir:$datadir/auto-load'])
 160 escape_dir=`echo $with_auto_load_dir | sed 's/[[$]]\(datadir\|debugdir\)\>/\\\\\\\\\\\\&/g'`
 161 AC_DEFINE_DIR(AUTO_LOAD_DIR, escape_dir,
 162               [Directories from which to load auto-loaded scripts.])
 163 AC_MSG_RESULT([$with_auto_load_dir])
 164
 165 AC_MSG_CHECKING([for default auto-load safe-path])
 166 AC_ARG_WITH(auto-load-safe-path,
 167 AS_HELP_STRING([--with-auto-load-safe-path=PATH],
 168   [directories safe to hold auto-loaded files @<:@--with-auto-load-dir@:>@])
 169 AS_HELP_STRING([--without-auto-load-safe-path],
 170                [do not restrict auto-loaded files locations]),
 171     [if test "$with_auto_load_safe_path" = "no"; then
 172      with_auto_load_safe_path="/"
 173      fi],
 174 [with_auto_load_safe_path="$with_auto_load_dir"])
 175 escape_dir=`echo $with_auto_load_safe_path | sed 's/[[$]]\(datadir\|debugdir\)\>/\\\\\\\\\\\\&/g'`
 176 AC_DEFINE_DIR(AUTO_LOAD_SAFE_PATH, escape_dir,
 177               [Directories safe to hold auto-loaded files.])
 178 AC_MSG_RESULT([$with_auto_load_safe_path])
 179
 180 AC_CONFIG_SUBDIRS(testsuite)
 181
 182 # Check whether to support alternative target configurations
 183 AC_ARG_ENABLE(targets,
 184 AS_HELP_STRING([--enable-targets=TARGETS], [alternative target configurations]),
 185 [case "${enableval}" in
 186   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
 187             ;;
 188   no)       enable_targets= ;;
 189   *)        enable_targets=$enableval ;;
 190 esac])
 191
 192 # Check whether to enable 64-bit support on 32-bit hosts
 193 AC_ARG_ENABLE(64-bit-bfd,
 194 AS_HELP_STRING([--enable-64-bit-bfd], [64-bit support (on hosts with narrower word sizes)]),
 195 [case "${enableval}" in
 196   yes)  want64=true  ;;
 197   no)   want64=false ;;
 198   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
 199 esac],[want64=false])dnl
 200
 201 # Provide defaults for some variables set by the per-host and per-target
 202 # configuration.
 203 gdb_host_obs=posix-hdep.o
 204
 205 if test "${target}" = "${host}"; then
 206   gdb_native=yes
 207 else
 208   gdb_native=no
 209 fi
 210
 211 . $srcdir/configure.host
 212
 213 # Add in the common host objects.
 214 . $srcdir/common/common.host
 215 gdb_host_obs="$gdb_host_obs $common_host_obs"
 216
 217 # Accumulate some settings from configure.tgt over all enabled targets
 218
 219 TARGET_OBS=
 220 all_targets=
 221 HAVE_NATIVE_GCORE_TARGET=
 222
 223 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 224 do
 225   if test "$targ_alias" = "all"; then
 226     all_targets=true
 227   else
 228     # Canonicalize the secondary target names.
 229     result=`$ac_config_sub $targ_alias 2>/dev/null`
 230     if test -n "$result"; then
 231         targ=$result
 232     else
 233         targ=$targ_alias
 234     fi
 235
 236     . ${srcdir}/configure.tgt
 237
 238     AS_IF([test -z "${gdb_target_obs}"],
 239       [AC_MSG_ERROR([configuration ${targ} is unsupported.])])
 240
 241     # Target-specific object files
 242     for i in ${gdb_target_obs}; do
 243         case " $TARGET_OBS " in
 244         *" ${i} "*) ;;
 245         *)
 246           TARGET_OBS="$TARGET_OBS ${i}"
 247           ;;
 248         esac
 249     done
 250
 251     # Check whether this target needs 64-bit CORE_ADDR
 252     if test x${want64} = xfalse; then
 253       . ${srcdir}/../bfd/config.bfd
 254     fi
 255
 256     # Check whether this target is native and supports gcore.
 257     if test $gdb_native = yes -a "$targ_alias" = "$target_alias" \
 258        && $gdb_have_gcore; then
 259       HAVE_NATIVE_GCORE_TARGET=1
 260     fi
 261   fi
 262 done
 263
 264 if test x${all_targets} = xtrue; then
 265
 266   # We want all 64-bit targets if we either:
 267   #  - run on a 64-bit host  or
 268   #  - already require 64-bit support for some other target  or
 269   #  - the --enable-64-bit-bfd option was supplied
 270   # Otherwise we only support all 32-bit targets.
 271   #
 272   # NOTE: This test must be in sync with the corresponding
 273   #       tests in BFD!
 274
 275   if test x${want64} = xfalse; then
 276     AC_CHECK_SIZEOF(long)
 277     if test "x${ac_cv_sizeof_long}" = "x8"; then
 278       want64=true
 279     fi
 280   fi
 281   if test x${want64} = xtrue; then
 282     TARGET_OBS='$(ALL_TARGET_OBS) $(ALL_64_TARGET_OBS)'
 283   else
 284     TARGET_OBS='$(ALL_TARGET_OBS)'
 285   fi
 286 fi
 287
 288 AC_SUBST(TARGET_OBS)
 289 AC_SUBST(HAVE_NATIVE_GCORE_TARGET)
 290
 291 # For other settings, only the main target counts.
 292 gdb_sim=
 293 gdb_osabi=
 294 build_gdbserver=
 295 targ=$target; . ${srcdir}/configure.tgt
 296
 297 # Fetch the default architecture and default target vector from BFD.
 298 targ=$target; . $srcdir/../bfd/config.bfd
 299
 300 # We only want the first architecture, so strip off the others if
 301 # there is more than one.
 302 targ_archs=`echo $targ_archs | sed 's/ .*//'`
 303
 304 if test "x$targ_archs" != x; then
 305   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
 306     [Define to BFD's default architecture. ])
 307 fi
 308 if test "x$targ_defvec" != x; then
 309   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
 310     [Define to BFD's default target vector. ])
 311 fi
 312
 313 # The CLI cannot be disabled yet, but may be in the future.
 314
 315 # Enable CLI.
 316 AC_ARG_ENABLE(gdbcli,
 317 AS_HELP_STRING([--disable-gdbcli], [disable command-line interface (CLI)]),
 318   [case $enableval in
 319     yes)
 320       ;;
 321     no)
 322       AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;;
 323     *)
 324       AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;;
 325   esac],
 326   [enable_gdbcli=yes])
 327 if test x"$enable_gdbcli" = xyes; then
 328   if test -d $srcdir/cli; then
 329     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)"
 330     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)"
 331     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)"
 332     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)"
 333   fi
 334 fi
 335
 336 # Enable MI.
 337 AC_ARG_ENABLE(gdbmi,
 338 AS_HELP_STRING([--disable-gdbmi], [disable machine-interface (MI)]),
 339   [case $enableval in
 340     yes | no)
 341       ;;
 342     *)
 343       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 344   esac],
 345   [enable_gdbmi=yes])
 346 if test x"$enable_gdbmi" = xyes; then
 347   if test -d $srcdir/mi; then
 348     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 349     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 350     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 351     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 352   fi
 353 fi
 354
 355 # Enable TUI.
 356 AC_ARG_ENABLE(tui,
 357 AS_HELP_STRING([--enable-tui], [enable full-screen terminal user interface (TUI)]),
 358   [case $enableval in
 359     yes | no | auto)
 360       ;;
 361     *)
 362       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 363   esac],enable_tui=auto)
 364
 365 # Enable gdbtk.
 366 AC_ARG_ENABLE(gdbtk,
 367 AS_HELP_STRING([--enable-gdbtk], [enable gdbtk graphical user interface (GUI)]),
 368   [case $enableval in
 369     yes | no)
 370       ;;
 371     *)
 372       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 373   esac],
 374   [if test -d $srcdir/gdbtk; then
 375     enable_gdbtk=yes
 376   else
 377     enable_gdbtk=no
 378   fi])
 379 # We unconditionally disable gdbtk tests on selected platforms.
 380 case $host_os in
 381   go32* | windows*)
 382     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 383     enable_gdbtk=no ;;
 384 esac
 385
 386 # Libunwind support for ia64.
 387
 388 AC_ARG_WITH(libunwind-ia64,
 389 AS_HELP_STRING([--with-libunwind-ia64],
 390                [use libunwind frame unwinding for ia64 targets]),,
 391             [with_libunwind_ia64=auto])
 392
 393 # Backward compatibility option.
 394 if test "${with_libunwind+set}" = set; then
 395   if test x"$with_libunwind_ia64" != xauto; then
 396     AC_MSG_ERROR(
 397       [option --with-libunwind is deprecated, use --with-libunwind-ia64])
 398   fi
 399   AC_MSG_WARN([option --with-libunwind is deprecated, use --with-libunwind-ia64])
 400   with_libunwind_ia64="$with_libunwind"
 401 fi
 402
 403 case "$with_libunwind_ia64" in
 404   yes | no)
 405     ;;
 406   auto)
 407     AC_CHECK_HEADERS(libunwind-ia64.h)
 408     with_libunwind_ia64=$ac_cv_header_libunwind_ia64_h
 409     ;;
 410   *)
 411     AC_MSG_ERROR(
 412       [bad value $with_libunwind_ia64 for GDB --with-libunwind-ia64 option])
 413     ;;
 414 esac
 415
 416 if test x"$with_libunwind_ia64" = xyes; then
 417   AC_CHECK_HEADERS(libunwind-ia64.h)
 418   if test x"$ac_cv_header_libunwind_ia64_h" != xyes; then
 419     AC_MSG_ERROR([GDB option --with-libunwind-ia64 requires libunwind-ia64.h])
 420   fi
 421   CONFIG_OBS="$CONFIG_OBS ia64-libunwind-tdep.o"
 422   CONFIG_DEPS="$CONFIG_DEPS ia64-libunwind-tdep.o"
 423   CONFIG_SRCS="$CONFIG_SRCS ia64-libunwind-tdep.c"
 424 fi
 425
 426 opt_curses=no
 427 AC_ARG_WITH(curses, AS_HELP_STRING([--with-curses], [use the curses library instead of the termcap library]), opt_curses=$withval)
 428
 429 prefer_curses=no
 430 if test "$opt_curses" = "yes"; then
 431   prefer_curses=yes
 432 fi
 433
 434 # Profiling support.
 435 AC_ARG_ENABLE(profiling,
 436 AS_HELP_STRING([--enable-profiling], [enable profiling of GDB]),
 437   [case $enableval in
 438     yes | no)
 439       ;;
 440     *)
 441       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 442   esac],
 443  [enable_profiling=no])
 444
 445 AC_CHECK_FUNCS(monstartup _mcleanup)
 446 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 447 [AC_TRY_LINK(
 448 [#include <stdlib.h>
 449 extern char _etext;
 450 ],
 451 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 452 if test $ac_cv_var__etext = yes; then
 453   AC_DEFINE(HAVE__ETEXT, 1,
 454             [Define to 1 if your system has the _etext variable. ])
 455 fi
 456 AC_CACHE_CHECK([for etext], ac_cv_var_etext,
 457 [AC_TRY_LINK(
 458 [#include <stdlib.h>
 459 extern char etext;
 460 ],
 461 [free (&etext);], ac_cv_var_etext=yes, ac_cv_var_etext=no)])
 462 if test $ac_cv_var_etext = yes; then
 463   AC_DEFINE(HAVE_ETEXT, 1,
 464             [Define to 1 if your system has the etext variable. ])
 465 fi
 466 if test "$enable_profiling" = yes ; then
 467   if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
 468     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 469   fi
 470   PROFILE_CFLAGS=-pg
 471   OLD_CFLAGS="$CFLAGS"
 472   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 473
 474   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 475     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 476      ac_cv_cc_supports_pg=no)])
 477
 478   if test $ac_cv_cc_supports_pg = no; then
 479     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 480   fi
 481
 482   CFLAGS="$OLD_CFLAGS"
 483 fi
 484
 485 ACX_PKGVERSION([GDB])
 486 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 487 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 488 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 489
 490 # --------------------- #
 491 # Checks for programs.  #
 492 # --------------------- #
 493
 494 AC_PROG_AWK
 495 AC_PROG_INSTALL
 496 AC_PROG_LN_S
 497 AC_PROG_RANLIB
 498 AC_PROG_YACC
 499
 500 AC_CHECK_TOOL(AR, ar)
 501 AC_CHECK_TOOL(DLLTOOL, dlltool)
 502 AC_CHECK_TOOL(WINDRES, windres)
 503
 504 case $host_os in
 505   gnu*)
 506     # Needed for GNU Hurd hosts.
 507     AC_CHECK_TOOL(MIG, mig)
 508     if test x"$MIG" = x; then
 509       AC_MSG_ERROR([MIG not found but required for $host hosts])
 510     fi
 511     ;;
 512 esac
 513
 514 # ---------------------- #
 515 # Checks for libraries.  #
 516 # ---------------------- #
 517
 518 # We might need to link with -lm; most simulators need it.
 519 AC_CHECK_LIB(m, main)
 520
 521 # We need to link with -lw to get `wctype' on Solaris before Solaris
 522 # 2.6.  Solaris 2.6 and beyond have this function in libc, and have a
 523 # libw that some versions of the GNU linker cannot hanle (GNU ld 2.9.1
 524 # is known to have this problem).  Therefore we avoid libw if we can.
 525 AC_CHECK_FUNC(wctype, [],
 526   [AC_CHECK_LIB(w, wctype)])
 527
 528 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 529 AC_SEARCH_LIBS(gethostbyname, nsl)
 530
 531 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 532 AC_SEARCH_LIBS(socketpair, socket)
 533
 534 # Link in zlib if we can.  This allows us to read compressed debug sections.
 535 AM_ZLIB
 536
 537 # On FreeBSD we may need libutil for kinfo_getvmmap (used by fbsd-nat.c).
 538 AC_SEARCH_LIBS(kinfo_getvmmap, util,
 539   [AC_DEFINE(HAVE_KINFO_GETVMMAP, 1,
 540             [Define to 1 if your system has the kinfo_getvmmap function. ])])
 541
 542 AM_ICONV
 543
 544 # GDB may fork/exec the iconv program to get the list of supported character
 545 # sets.  Allow the user to specify where to find it.
 546 # There are several factors affecting the choice of option name:
 547 # - There is already --with-libiconv-prefix but we can't use it, it specifies
 548 #   the build-time location of libiconv files.
 549 # - The program we need to find is iconv, which comes with glibc.  The user
 550 #   doesn't necessarily have libiconv installed.  Therefore naming this
 551 #   --with-libiconv-foo feels wrong.
 552 # - We want the path to be relocatable, but GDB_AC_DEFINE_RELOCATABLE is
 553 #   defined to work on directories not files (though it really doesn't know
 554 #   the difference).
 555 # - Calling this --with-iconv-prefix is perceived to cause too much confusion
 556 #   with --with-libiconv-prefix.
 557 # Putting these together is why the option name is --with-iconv-bin.
 558
 559 AC_ARG_WITH(iconv-bin,
 560 AS_HELP_STRING([--with-iconv-bin=PATH], [specify where to find the iconv program]),
 561 [iconv_bin="${withval}"
 562  AC_DEFINE_UNQUOTED([ICONV_BIN], ["${iconv_bin}"],
 563                     [Path of directory of iconv program.])
 564  GDB_AC_DEFINE_RELOCATABLE(ICONV_BIN, iconv, ${iconv_bin})
 565 ])
 566
 567 # For the TUI, we need enhanced curses functionality.
 568 if test x"$enable_tui" != xno; then
 569   prefer_curses=yes
 570 fi
 571
 572 curses_found=no
 573 if test x"$prefer_curses" = xyes; then
 574   # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
 575   # curses library because the latter might not provide all the
 576   # functionality we need.  However, this leads to problems on systems
 577   # where the linker searches /usr/local/lib, but the compiler doesn't
 578   # search /usr/local/include, if ncurses is installed in /usr/local.  A
 579   # default installation of ncurses on alpha*-dec-osf* will lead to such
 580   # a situation.
 581   AC_SEARCH_LIBS(waddstr, [ncurses cursesX curses])
 582
 583   if test "$ac_cv_search_waddstr" != no; then
 584     curses_found=yes
 585   fi
 586 fi
 587
 588 # Check whether we should enable the TUI, but only do so if we really
 589 # can.
 590 if test x"$enable_tui" != xno; then
 591   if test -d $srcdir/tui; then
 592     if test "$curses_found" != no; then
 593       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
 594       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
 595       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
 596       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
 597     else
 598       if test x"$enable_tui" = xyes; then
 599         AC_MSG_ERROR([no enhanced curses library found; disable TUI])
 600       else
 601         AC_MSG_WARN([no enhanced curses library found; disabling TUI])
 602       fi
 603     fi
 604   fi
 605 fi
 606
 607 # Since GDB uses Readline, we need termcap functionality.  In many
 608 # cases this will be provided by the curses library, but some systems
 609 # have a seperate termcap library, or no curses library at all.
 610
 611 case $host_os in
 612   cygwin*)
 613     if test -d $srcdir/libtermcap; then
 614       LIBS="../libtermcap/libtermcap.a $LIBS"
 615       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 616     fi ;;
 617   go32* | *djgpp*)
 618     ac_cv_search_tgetent="none required"
 619     ;;
 620 esac
 621
 622 # These are the libraries checked by Readline.
 623 AC_SEARCH_LIBS(tgetent, [termcap tinfo curses ncurses])
 624
 625 if test "$ac_cv_search_tgetent" = no; then
 626   CONFIG_OBS="$CONFIG_OBS stub-termcap.o"
 627 fi
 628
 629 AC_ARG_WITH([system-readline],
 630   [AS_HELP_STRING([--with-system-readline],
 631                   [use installed readline library])])
 632
 633 if test "$with_system_readline" = yes; then
 634   READLINE=-lreadline
 635   READLINE_DEPS=
 636   READLINE_CFLAGS=
 637   READLINE_TEXI_INCFLAG=
 638 else
 639   READLINE='$(READLINE_DIR)/libreadline.a'
 640   READLINE_DEPS='$(READLINE)'
 641   READLINE_CFLAGS='-I$(READLINE_SRC)/..'
 642   READLINE_TEXI_INCFLAG='-I $(READLINE_DIR)'
 643 fi
 644 AC_SUBST(READLINE)
 645 AC_SUBST(READLINE_DEPS)
 646 AC_SUBST(READLINE_CFLAGS)
 647 AC_SUBST(READLINE_TEXI_INCFLAG)
 648
 649 # Generate jit-reader.h
 650
 651 # This is typedeffed to GDB_CORE_ADDR in jit-reader.h
 652 TARGET_PTR=
 653
 654 AC_CHECK_SIZEOF(unsigned long long)
 655 AC_CHECK_SIZEOF(unsigned long)
 656 AC_CHECK_SIZEOF(unsigned __int128)
 657
 658 if test "x${ac_cv_sizeof_unsigned_long}" = "x8"; then
 659   TARGET_PTR="unsigned long"
 660 elif test "x${ac_cv_sizeof_unsigned_long_long}" = "x8"; then
 661   TARGET_PTR="unsigned long long"
 662 elif test "x${ac_cv_sizeof_unsigned___int128}" = "x16"; then
 663   TARGET_PTR="unsigned __int128"
 664 else
 665   TARGET_PTR="unsigned long"
 666 fi
 667
 668 AC_SUBST(TARGET_PTR)
 669 AC_CONFIG_FILES([jit-reader.h:jit-reader.in])
 670
 671 AC_SEARCH_LIBS(dlopen, dl)
 672
 673 GDB_AC_WITH_DIR([JIT_READER_DIR], [jit-reader-dir],
 674                 [directory to load the JIT readers from],
 675                 [${libdir}/gdb])
 676
 677 AC_ARG_WITH(expat,
 678   AS_HELP_STRING([--with-expat], [include expat support (auto/yes/no)]),
 679   [], [with_expat=auto])
 680 AC_MSG_CHECKING([whether to use expat])
 681 AC_MSG_RESULT([$with_expat])
 682
 683 if test "${with_expat}" = no; then
 684   AC_MSG_WARN([expat support disabled; some features may be unavailable.])
 685   HAVE_LIBEXPAT=no
 686 else
 687   AC_LIB_HAVE_LINKFLAGS([expat], [], [#include "expat.h"],
 688                         [XML_Parser p = XML_ParserCreate (0);])
 689   if test "$HAVE_LIBEXPAT" != yes; then
 690     if test "$with_expat" = yes; then
 691       AC_MSG_ERROR([expat is missing or unusable])
 692     else
 693       AC_MSG_WARN([expat is missing or unusable; some features may be unavailable.])
 694     fi
 695   else
 696     save_LIBS=$LIBS
 697     LIBS="$LIBS $LIBEXPAT"
 698     AC_CHECK_FUNCS(XML_StopParser)
 699     LIBS=$save_LIBS
 700   fi
 701 fi
 702
 703 # --------------------- #
 704 # Check for libpython.  #
 705 # --------------------- #
 706
 707 dnl Utility to simplify finding libpython.
 708 dnl $1 = pythonX.Y
 709 dnl $2 = the shell variable to assign the result to
 710 dnl      If libpython is found we store $version here.
 711 dnl $3 = additional flags to add to CPPFLAGS
 712 dnl $4 = additional flags to add to LIBS
 713
 714 AC_DEFUN([AC_TRY_LIBPYTHON],
 715 [
 716   version=$1
 717   define([have_libpython_var],$2)
 718   new_CPPFLAGS=$3
 719   new_LIBS=$4
 720   AC_MSG_CHECKING([for ${version}])
 721   save_CPPFLAGS=$CPPFLAGS
 722   save_LIBS=$LIBS
 723   CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
 724   LIBS="$LIBS $new_LIBS"
 725   found_usable_python=no
 726   AC_LINK_IFELSE(AC_LANG_PROGRAM([[#include "Python.h"]],
 727                                  [[Py_Initialize ();]]),
 728                  [have_libpython_var=${version}
 729                   found_usable_python=yes
 730                   PYTHON_CPPFLAGS=$new_CPPFLAGS
 731                   PYTHON_LIBS=$new_LIBS])
 732   CPPFLAGS=$save_CPPFLAGS
 733   LIBS=$save_LIBS
 734   AC_MSG_RESULT([${found_usable_python}])
 735 ])
 736
 737 dnl There are several different values for --with-python:
 738 dnl
 739 dnl no -   Don't include python support.
 740 dnl yes -  Include python support, error if it's missing.
 741 dnl        If we find python in $PATH, use it to fetch configure options,
 742 dnl        otherwise assume the compiler can find it with no help from us.
 743 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 744 dnl auto - Same as "yes", but if python is missing from the system,
 745 dnl        fall back to "no".
 746 dnl /path/to/python/exec-prefix -
 747 dnl        Use the python located in this directory.
 748 dnl        If /path/to/python/exec-prefix/bin/python exists, use it to find
 749 dnl        the compilation parameters.  Otherwise use
 750 dnl        -I/path/to/python/exec-prefix/include,
 751 dnl        -L/path/to/python/exec-prefix/lib.
 752 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 753 dnl        NOTE: This case is historical.  It is what was done for 7.0/7.1
 754 dnl        but is deprecated.
 755 dnl /path/to/python/executable -
 756 dnl        Run python-config.py with this version of python to fetch the
 757 dnl        compilation parameters.
 758 dnl        NOTE: This needn't be the real python executable.
 759 dnl        In a cross-compilation scenario (build != host), this could be
 760 dnl        a shell script that provides what python-config.py provides for
 761 dnl        --ldflags, --includes, --exec-prefix.
 762 dnl python-executable -
 763 dnl        Find python-executable in $PATH, and then handle the same as
 764 dnl        /path/to/python/executable.
 765 dnl
 766 dnl If a python program is specified, it is used to run python-config.py and
 767 dnl is passed --ldflags, --includes, --exec-prefix.
 768
 769 AC_ARG_WITH(python,
 770   AS_HELP_STRING([--with-python@<:@=PYTHON@:>@], [include python support (auto/yes/no/<python-program>)]),
 771   [], [with_python=auto])
 772 AC_MSG_CHECKING([whether to use python])
 773 AC_MSG_RESULT([$with_python])
 774
 775 if test "${with_python}" = no; then
 776   AC_MSG_WARN([python support disabled; some features may be unavailable.])
 777   have_libpython=no
 778 else
 779   case "${with_python}" in
 780   [[\\/]]* | ?:[[\\/]]*)
 781     if test -d ${with_python}; then
 782       # Assume the python binary is ${with_python}/bin/python.
 783       python_prog="${with_python}/bin/python"
 784       python_prefix=
 785       # If python does not exit ${with_python}/bin, then try in
 786       # ${with_python}.  On Windows/MinGW, this is where the Python
 787       # executable is.
 788       if test ! -x "${python_prog}"; then
 789         python_prog="${with_python}/python"
 790         python_prefix=
 791       fi
 792       if test ! -x "${python_prog}"; then
 793         # Fall back to gdb 7.0/7.1 behaviour.
 794         python_prog=missing
 795         python_prefix=${with_python}
 796       fi
 797     elif test -x "${with_python}"; then
 798       # While we can't run python compiled for $host (unless host == build),
 799       # the user could write a script that provides the needed information,
 800       # so we support that.
 801       python_prog=${with_python}
 802       python_prefix=
 803     else
 804       AC_ERROR(invalid value for --with-python)
 805     fi
 806     ;;
 807   */*)
 808     # Disallow --with-python=foo/bar.
 809     AC_ERROR(invalid value for --with-python)
 810     ;;
 811   *)
 812     # The user has either specified auto, yes, or the name of the python
 813     # program assumed to be in $PATH.
 814     python_prefix=
 815     case "${with_python}" in
 816     yes | auto)
 817       if test ${build} = ${host}; then
 818         AC_PATH_PROG(python_prog_path, python, missing)
 819         if test "${python_prog_path}" = missing; then
 820           python_prog=missing
 821         else
 822           python_prog=${python_prog_path}
 823         fi
 824       else
 825         # Not much we can do except assume the cross-compiler will find the
 826         # right files.
 827         python_prog=missing
 828       fi
 829       ;;
 830     *)
 831       # While we can't run python compiled for $host (unless host == build),
 832       # the user could write a script that provides the needed information,
 833       # so we support that.
 834       python_prog="${with_python}"
 835       AC_PATH_PROG(python_prog_path, ${python_prog}, missing)
 836       if test "${python_prog_path}" = missing; then
 837         AC_ERROR(unable to find python program ${python_prog})
 838       fi
 839       ;;
 840     esac
 841   esac
 842
 843   if test "${python_prog}" != missing; then
 844     # We have a python program to use, but it may be too old.
 845     # Don't flag an error for --with-python=auto (the default).
 846     have_python_config=yes
 847     python_includes=`${python_prog} ${srcdir}/python/python-config.py --includes`
 848     if test $? != 0; then
 849       have_python_config=failed
 850       if test "${with_python}" != auto; then
 851         AC_ERROR(failure running python-config --includes)
 852       fi
 853     fi
 854     python_libs=`${python_prog} ${srcdir}/python/python-config.py --ldflags`
 855     if test $? != 0; then
 856       have_python_config=failed
 857       if test "${with_python}" != auto; then
 858         AC_ERROR(failure running python-config --ldflags)
 859       fi
 860     fi
 861     python_prefix=`${python_prog} ${srcdir}/python/python-config.py --exec-prefix`
 862     if test $? != 0; then
 863       have_python_config=failed
 864       if test "${with_python}" != auto; then
 865         AC_ERROR(failure running python-config --exec-prefix)
 866       fi
 867     fi
 868   else
 869     # We do not have a python executable we can use to determine where
 870     # to find the Python headers and libs.  We cannot guess the include
 871     # path from the python_prefix either, because that include path
 872     # depends on the Python version.  So, there is nothing much we can
 873     # do except assume that the compiler will be able to find those files.
 874     python_includes=
 875     python_libs=
 876     have_python_config=no
 877   fi
 878
 879   # If we have python-config, only try the configuration it provides.
 880   # Otherwise fallback on the old way of trying different versions of
 881   # python in turn.
 882
 883   have_libpython=no
 884   if test "${have_python_config}" = yes; then
 885     # Determine the Python version by extracting "-lpython<version>"
 886     # part of the python_libs. <version> is usually X.Y with X and Y
 887     # being decimal numbers, but can also be XY (seen on Windows).
 888     #
 889     # The extraction is performed using sed with a regular expression.
 890     # Initially, the regexp used was using the '?' quantifier to make
 891     # the dot in the version number optional.  Unfortunately, this
 892     # does not work with non-GNU versions of sed because, because of
 893     # what looks like a limitation (the '?' quantifier does not work
 894     # with back-references).  We work around this limitation by using
 895     # the '*' quantifier instead.  It means that, in theory, we might
 896     # match unexpected version strings such as "-lpython2..7", but
 897     # this seems unlikely in practice.  And even if that happens,
 898     # an error will be triggered later on, when checking that version
 899     # number.
 900     python_version=`echo " ${python_libs} " \
 901                          | sed -e 's,^.* -l\(python[[0-9]]*[[.]]*[[0-9]]*\).*$,\1,'`
 902     case "${python_version}" in
 903     python*)
 904       AC_TRY_LIBPYTHON(${python_version}, have_libpython,
 905                        ${python_includes}, ${python_libs})
 906       ;;
 907     *)
 908       AC_MSG_ERROR([unable to determine python version from ${python_libs}])
 909       ;;
 910     esac
 911   elif test "${have_python_config}" != failed; then
 912     if test "${have_libpython}" = no; then
 913       AC_TRY_LIBPYTHON(python2.7, have_libpython,
 914                        ${python_includes}, "${python_libs} -lpython2.7")
 915     fi
 916     if test "${have_libpython}" = no; then
 917       AC_TRY_LIBPYTHON(python2.6, have_libpython,
 918                        ${python_includes}, "${python_libs} -lpython2.6")
 919     fi
 920     if test ${have_libpython} = no; then
 921       AC_TRY_LIBPYTHON(python2.5, have_libpython,
 922                        ${python_includes}, "${python_libs} -lpython2.5")
 923     fi
 924     if test ${have_libpython} = no; then
 925       AC_TRY_LIBPYTHON(python2.4, have_libpython,
 926                        ${python_includes}, "${python_libs} -lpython2.4")
 927     fi
 928   fi
 929   if test "${have_libpython}" = python2.7 -o "${have_libpython}" = python27; then
 930     AC_DEFINE(HAVE_LIBPYTHON2_7, 1, [Define if Python 2.7 is being used.])
 931   elif test "${have_libpython}" = python2.6 -o "${have_libpython}" = python26; then
 932     AC_DEFINE(HAVE_LIBPYTHON2_6, 1, [Define if Python 2.6 is being used.])
 933   elif test "${have_libpython}" = python2.5 -o "${have_libpython}" = python25; then
 934     AC_DEFINE(HAVE_LIBPYTHON2_5, 1, [Define if Python 2.5 is being used.])
 935   elif test "${have_libpython}" = python2.4 -o "${have_libpython}" = python24; then
 936     AC_DEFINE(HAVE_LIBPYTHON2_4, 1, [Define if Python 2.4 is being used.])
 937   fi
 938
 939   if test "${have_libpython}" = no; then
 940     case "${with_python}" in
 941     yes)
 942       AC_MSG_ERROR([python is missing or unusable])
 943       ;;
 944     auto)
 945       AC_MSG_WARN([python is missing or unusable; some features may be unavailable.])
 946       ;;
 947     *)
 948       AC_MSG_ERROR([no usable python found at ${with_python}])
 949       ;;
 950     esac
 951   else
 952     if test -n "${python_prefix}"; then
 953       AC_DEFINE_UNQUOTED(WITH_PYTHON_PATH, "${python_prefix}",
 954                          [Define if --with-python provides a path, either directly or via python-config.py --exec-prefix.])
 955       GDB_AC_DEFINE_RELOCATABLE(PYTHON_PATH, python, ${python_prefix})
 956     fi
 957   fi
 958 fi
 959
 960 if test "${have_libpython}" != no; then
 961   AC_DEFINE(HAVE_PYTHON, 1, [Define if Python interpreter is being linked in.])
 962   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_PYTHON_OBS)"
 963   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_PYTHON_DEPS)"
 964   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_PYTHON_SRCS)"
 965   CONFIG_INSTALL="$CONFIG_INSTALL install-python"
 966   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_PYTHON_CFLAGS)"
 967
 968   # Flags needed to compile Python code (taken from python-config --cflags).
 969   # We cannot call python-config directly because it will output whatever was
 970   # used when compiling the Python interpreter itself, including flags which
 971   # would make the python-related objects be compiled differently from the
 972   # rest of GDB (e.g., -O2 and -fPIC).
 973   if test "${GCC}" = yes; then
 974     tentative_python_cflags="-fno-strict-aliasing -DNDEBUG -fwrapv"
 975   fi
 976
 977   if test "x${tentative_python_cflags}" != x; then
 978     AC_MSG_CHECKING(compiler flags for python code)
 979     for flag in ${tentative_python_cflags}; do
 980       # Check that the compiler accepts it
 981       saved_CFLAGS="$CFLAGS"
 982       CFLAGS="$CFLAGS $flag"
 983       AC_TRY_COMPILE([],[],PYTHON_CFLAGS="${PYTHON_CFLAGS} $flag",)
 984       CFLAGS="$saved_CFLAGS"
 985     done
 986     AC_MSG_RESULT(${PYTHON_CFLAGS})
 987   fi
 988
 989   # On x64 Windows, Python's include headers, and pyconfig.h in
 990   # particular, rely on MS_WIN64 macro to detect that it's a 64bit
 991   # version of Windows.  Unfortunately, MS_WIN64 is only defined if
 992   # _MSC_VER, a Microsoft-specific macro, is defined.  So, when
 993   # building on x64 Windows with GCC, we define MS_WIN64 ourselves.
 994   # The issue was reported to the Python community, but still isn't
 995   # solved as of 2012-10-02 (http://bugs.python.org/issue4709).
 996
 997   case "$gdb_host" in
 998     mingw64)
 999            if test "${GCC}" = yes; then
1000              CPPFLAGS="$CPPFLAGS -DMS_WIN64"
1001            fi
1002            ;;
1003   esac
1004
1005   # Note that "python -m threading" cannot be used to check for
1006   # threading support due to a bug in Python 2.7.3
1007   # (http://bugs.python.org/issue15567).
1008   AC_MSG_CHECKING(whether python supports threads)
1009   saved_CPPFLAGS="${CPPFLAGS}"
1010   CPPFLAGS="${PYTHON_CPPFLAGS}"
1011   # Note that the test is reversed so that python_has_threads=yes on
1012   # unexpected failures.
1013   AC_PREPROC_IFELSE(AC_LANG_SOURCE([[
1014 #include <Python.h>
1015 #ifdef WITH_THREAD
1016 # error
1017 #endif
1018   ]]), [python_has_threads=no], [python_has_threads=yes])
1019   AC_MSG_RESULT(${python_has_threads})
1020   CPPFLAGS="${saved_CPPFLAGS}"
1021 else
1022   # Even if Python support is not compiled in, we need to have this file
1023   # included so that the "python" command, et.al., still exists.
1024   CONFIG_OBS="$CONFIG_OBS python.o"
1025   CONFIG_SRCS="$CONFIG_SRCS python/python.c"
1026 fi
1027 AC_SUBST(PYTHON_CFLAGS)
1028 AC_SUBST(PYTHON_CPPFLAGS)
1029 AC_SUBST(PYTHON_LIBS)
1030 AM_CONDITIONAL(HAVE_PYTHON, test "${have_libpython}" != no)
1031
1032 # -------------------- #
1033 # Check for libguile.  #
1034 # -------------------- #
1035
1036 dnl Utility to simplify finding libguile.
1037 dnl $1 = pkg-config-program
1038 dnl $2 = space-separate list of guile versions to try
1039 dnl $3 = yes|no, indicating whether to flag errors or ignore them
1040 dnl $4 = the shell variable to assign the result to
1041 dnl      If libguile is found we store "yes" here.
1042
1043 AC_DEFUN([AC_TRY_LIBGUILE],
1044 [
1045   pkg_config=$1
1046   guile_version_list=$2
1047   flag_errors=$3
1048   define([have_libguile_var],$4)
1049   found_usable_guile=checking
1050   AC_MSG_CHECKING([for usable guile from ${pkg_config}])
1051   for guile_version in ${guile_version_list}; do
1052     ${pkg_config} --exists ${guile_version} 2>/dev/null
1053     if test $? != 0; then
1054       continue
1055     fi
1056     dnl pkg-config says the package exists, so if we get an error now,
1057     dnl that's bad.
1058     new_CPPFLAGS=`${pkg_config} --cflags ${guile_version}`
1059     if test $? != 0; then
1060       AC_MSG_ERROR([failure running pkg-config --cflags ${guile_version}])
1061     fi
1062     new_LIBS=`${pkg_config} --libs ${guile_version}`
1063     if test $? != 0; then
1064       AC_MSG_ERROR([failure running pkg-config --libs ${guile_version}])
1065     fi
1066     dnl If we get this far, great.
1067     found_usable_guile=${guile_version}
1068     break
1069   done
1070   if test "${found_usable_guile}" = "checking"; then
1071     if test "${flag_errors}" = "yes"; then
1072       AC_MSG_ERROR([unable to find usable guile version from "${guile_version_list}"])
1073     else
1074       found_usable_guile=no
1075     fi
1076   fi
1077   dnl One final sanity check.
1078   dnl The user could have said --with-guile=python-2.7.
1079   if test "${found_usable_guile}" != no; then
1080     save_CPPFLAGS=$CPPFLAGS
1081     save_LIBS=$LIBS
1082     CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
1083     LIBS="$LIBS $new_LIBS"
1084     AC_LINK_IFELSE(AC_LANG_PROGRAM([[#include "libguile.h"]],
1085                                    [[scm_init_guile ();]]),
1086                    [have_libguile_var=yes
1087                     GUILE_CPPFLAGS=$new_CPPFLAGS
1088                     GUILE_LIBS=$new_LIBS],
1089                    [found_usable_guile=no])
1090     dnl scm_set_automatic_finalization_enabled added in Guile 2.2.
1091     AC_CHECK_FUNC(scm_set_automatic_finalization_enabled,
1092       AC_DEFINE(HAVE_GUILE_MANUAL_FINALIZATION, 1,
1093                 [Define if Guile supports manual finalization.])
1094     )
1095     CPPFLAGS=$save_CPPFLAGS
1096     LIBS=$save_LIBS
1097     if test "${found_usable_guile}" = no; then
1098       if test "${flag_errors}" = yes; then
1099         AC_MSG_FAILURE([linking guile version ${guile_version} test program failed])
1100       fi
1101     fi
1102   fi
1103   AC_MSG_RESULT([${found_usable_guile}])
1104 ])
1105
1106 dnl There are several different values for --with-guile:
1107 dnl
1108 dnl no -   Don't include guile support.
1109 dnl yes -  Include guile support, error if it's missing.
1110 dnl        The pkg-config program must be in $PATH.
1111 dnl auto - Same as "yes", but if guile is missing from the system,
1112 dnl        fall back to "no".
1113 dnl guile-version [guile-version-choice-2 ...] -
1114 dnl        A space-separated list of guile package versions to try.
1115 dnl        These are passed to pkg-config as-is.
1116 dnl        E.g., guile-2.0 or guile-2.2-uninstalled
1117 dnl        This requires making sure PKG_CONFIG_PATH is set appropriately.
1118 dnl /path/to/pkg-config -
1119 dnl        Use this pkg-config program.
1120 dnl        NOTE: This needn't be the "real" pkg-config program.
1121 dnl        It could be a shell script.  It is invoked as:
1122 dnl        pkg-config --exists $version
1123 dnl        pkg-config --cflags $version
1124 dnl        pkg-config --libs $version
1125 dnl        pkg-config --variable guild $version
1126 dnl        The script will be called with $version having each value in
1127 dnl        $try_guile_versions until --exists indicates success.
1128
1129 AC_ARG_WITH(guile,
1130   AS_HELP_STRING([--with-guile@<:@=GUILE@:>@], [include guile support (auto/yes/no/<guile-version>/<pkg-config-program>)]),
1131   [], [with_guile=auto])
1132 AC_MSG_CHECKING([whether to use guile])
1133 AC_MSG_RESULT([$with_guile])
1134
1135 dnl We check guile with pkg-config.
1136 AC_PATH_PROG(pkg_config_prog_path, pkg-config, missing)
1137
1138 try_guile_versions="guile-2.2 guile-2.0"
1139 have_libguile=no
1140 case "${with_guile}" in
1141 no)
1142   AC_MSG_WARN([guile support disabled; some features will be unavailable.])
1143   ;;
1144 auto)
1145   if test "${pkg_config_prog_path}" = "missing"; then
1146     AC_MSG_WARN([pkg-config not found, guile support disabled])
1147   else
1148     AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${try_guile_versions}, no, have_libguile)
1149   fi
1150   ;;
1151 yes)
1152   if test "${pkg_config_prog_path}" = "missing"; then
1153     AC_MSG_ERROR([pkg-config not found])
1154   fi
1155   AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${try_guile_versions}, yes, have_libguile)
1156   ;;
1157 [[\\/]]* | ?:[[\\/]]*)
1158   if test -x "${with_guile}"; then
1159     AC_TRY_LIBGUILE(${with_guile}, ${try_guile_versions}, yes, have_libguile)
1160   else
1161     AC_MSG_ERROR([Guile config program not executable: ${with_guile}])
1162   fi
1163   ;;
1164 "" | */*)
1165   # Disallow --with=guile="" and --with-guile=foo/bar.
1166   AC_MSG_ERROR([invalid value for --with-guile])
1167   ;;
1168 *)
1169   # A space separate list of guile versions to try, in order.
1170   if test "${pkg_config_prog_path}" = "missing"; then
1171     AC_MSG_ERROR([pkg-config not found])
1172   fi
1173   AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${with_guile}, yes, have_libguile)
1174   ;;
1175 esac
1176
1177 if test "${have_libguile}" != no; then
1178   dnl Get the name of the 'guild' program.
1179   case "${with_guile}" in
1180   [[\\/]]* | ?:[[\\/]]*)
1181     GDB_GUILE_PROGRAM_NAMES(["${with_guile}"], ["${guile_version}"])
1182     ;;
1183   *)
1184     GDB_GUILE_PROGRAM_NAMES(["${pkg_config_prog_path}"], ["${guile_version}"])
1185     ;;
1186   esac
1187
1188   dnl Make sure guild can handle this host.
1189   GDB_TRY_GUILD([$srcdir/guile/lib/gdb/support.scm])
1190   dnl If not, disable guile support.
1191   if test "$ac_cv_guild_ok" = no; then
1192     have_libguile=no
1193     AC_MSG_WARN(disabling guile support, $GUILD fails compiling for $host)
1194   fi
1195 fi
1196
1197 if test "${have_libguile}" != no; then
1198   AC_DEFINE(HAVE_GUILE, 1, [Define if Guile interpreter is being linked in.])
1199   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_GUILE_OBS)"
1200   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_GUILE_DEPS)"
1201   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_GUILE_SRCS)"
1202   CONFIG_INSTALL="$CONFIG_INSTALL install-guile"
1203   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_GUILE_CFLAGS)"
1204
1205   dnl The 'scm_new_smob' function appeared in Guile 2.0.6.
1206   save_LIBS="$LIBS"
1207   save_CPPFLAGS="$CPPFLAGS"
1208   LIBS="$GUILE_LIBS"
1209   CPPFLAGS="$GUILE_CPPFLAGS"
1210   AC_CHECK_FUNCS([scm_new_smob])
1211   LIBS="$save_LIBS"
1212   CPPFLAGS="$save_CPPFLAGS"
1213 else
1214   # Even if Guile support is not compiled in, we need to have these files
1215   # included.
1216   CONFIG_OBS="$CONFIG_OBS guile.o"
1217   CONFIG_SRCS="$CONFIG_SRCS guile/guile.c"
1218 fi
1219 AC_SUBST(GUILE_CPPFLAGS)
1220 AC_SUBST(GUILE_LIBS)
1221 AM_CONDITIONAL(HAVE_GUILE, test "${have_libguile}" != no)
1222
1223 # --------------------- #
1224 # Check for libmcheck.  #
1225 # --------------------- #
1226
1227 # Enable -lmcheck by default (it provides cheap-enough memory mangling),
1228 # but turn it off if Python is enabled with threads, since -lmcheck is
1229 # not thread safe (http://sourceware.org/bugzilla/show_bug.cgi?id=9939),
1230 # and for releases.
1231 if test \( "${have_libpython}" = "no" -o "${python_has_threads}" = "no" \) \
1232    && $development; then
1233   libmcheck_default=yes
1234 else
1235   libmcheck_default=no
1236 fi
1237 GDB_AC_LIBMCHECK(${libmcheck_default})
1238
1239 if test "$ENABLE_LIBMCHECK" = "yes" \
1240         -a "${have_libpython}" != "no" \
1241         -a "${python_has_threads}" = "yes" ; then
1242   AC_MSG_WARN(--enable-libmcheck may lead to spurious crashes if threads are used in python)
1243 fi
1244
1245 # ------------------------- #
1246 # Checks for header files.  #
1247 # ------------------------- #
1248
1249 AC_HEADER_STDC
1250 # elf_hp.h is for HP/UX 64-bit shared library support.
1251 AC_CHECK_HEADERS([nlist.h machine/reg.h poll.h sys/poll.h proc_service.h \
1252                   thread_db.h \
1253                   sys/fault.h \
1254                   sys/file.h sys/filio.h sys/ioctl.h sys/param.h \
1255                   sys/resource.h sys/procfs.h sys/ptrace.h ptrace.h \
1256                   sys/reg.h sys/debugreg.h sys/select.h sys/syscall.h \
1257                   termios.h termio.h \
1258                   sgtty.h elf_hp.h \
1259                   dlfcn.h])
1260 AC_CHECK_HEADERS(sys/proc.h, [], [],
1261 [#if HAVE_SYS_PARAM_H
1262 # include <sys/param.h>
1263 #endif
1264 ])
1265 AC_CHECK_HEADERS(sys/user.h, [], [],
1266 [#if HAVE_SYS_PARAM_H
1267 # include <sys/param.h>
1268 #endif
1269 ])
1270
1271 # On Solaris 2.[789], we need to define _MSE_INT_H to avoid a clash
1272 # between <widec.h> and <wchar.h> that would cause AC_CHECK_HEADERS to
1273 # think that we don't have <curses.h> if we're using GCC.
1274 case $host_os in
1275   solaris2.[[789]])
1276     if test "$GCC" = yes; then
1277       AC_DEFINE(_MSE_INT_H, 1,
1278         [Define to 1 to avoid a clash between <widec.h> and <wchar.h> on
1279    Solaris 2.[789] when using GCC. ])
1280     fi ;;
1281 esac
1282 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncurses/ncurses.h ncurses/term.h)
1283 AC_CHECK_HEADERS(term.h, [], [],
1284 [#if HAVE_CURSES_H
1285 # include <curses.h>
1286 #endif
1287 ])
1288
1289 # ------------------------- #
1290 # Checks for declarations.  #
1291 # ------------------------- #
1292
1293 libiberty_INIT
1294
1295 AC_CHECK_DECLS([free, malloc, realloc, snprintf])
1296 AM_LC_MESSAGES
1297
1298 # ----------------------- #
1299 # Checks for structures.  #
1300 # ----------------------- #
1301
1302 AC_CHECK_MEMBERS([struct stat.st_blocks, struct stat.st_blksize])
1303
1304 # ------------------ #
1305 # Checks for types.  #
1306 # ------------------ #
1307
1308 AC_TYPE_SIGNAL
1309 AC_CHECK_TYPES(socklen_t, [], [],
1310 [#include <sys/types.h>
1311 #include <sys/socket.h>
1312 ])
1313
1314 # ------------------------------------- #
1315 # Checks for compiler characteristics.  #
1316 # ------------------------------------- #
1317
1318 AC_C_CONST
1319 AC_C_INLINE
1320 AC_C_BIGENDIAN
1321
1322 # ------------------------------ #
1323 # Checks for library functions.  #
1324 # ------------------------------ #
1325
1326 AC_FUNC_MMAP
1327 AC_FUNC_VFORK
1328 AC_CHECK_FUNCS([getauxval getrusage getuid getgid \
1329                 pipe poll pread pread64 pwrite resize_term \
1330                 sbrk setpgid setpgrp setsid \
1331                 sigaction sigprocmask sigsetmask socketpair \
1332                 ttrace wborder wresize setlocale iconvlist libiconvlist btowc \
1333                 setrlimit getrlimit posix_madvise waitpid \
1334                 ptrace64 sigaltstack mkdtemp])
1335 AM_LANGINFO_CODESET
1336 GDB_AC_COMMON
1337
1338 # Check the return and argument types of ptrace.  No canned test for
1339 # this, so roll our own.
1340 gdb_ptrace_headers='
1341 #include <sys/types.h>
1342 #if HAVE_SYS_PTRACE_H
1343 # include <sys/ptrace.h>
1344 #endif
1345 #if HAVE_UNISTD_H
1346 # include <unistd.h>
1347 #endif
1348 '
1349 # There is no point in checking if we don't have a prototype.
1350 AC_CHECK_DECLS(ptrace, [], [
1351   : ${gdb_cv_func_ptrace_ret='int'}
1352   : ${gdb_cv_func_ptrace_args='int,int,long,long'}
1353 ], $gdb_ptrace_headers)
1354 # Check return type.  Varargs (used on GNU/Linux) conflict with the
1355 # empty argument list, so check for that explicitly.
1356 AC_CACHE_CHECK([return type of ptrace], gdb_cv_func_ptrace_ret,
1357   AC_TRY_COMPILE($gdb_ptrace_headers,
1358     [extern long ptrace (enum __ptrace_request, ...);],
1359     gdb_cv_func_ptrace_ret='long',
1360     AC_TRY_COMPILE($gdb_ptrace_headers,
1361       [extern int ptrace ();],
1362       gdb_cv_func_ptrace_ret='int',
1363       gdb_cv_func_ptrace_ret='long')))
1364 AC_DEFINE_UNQUOTED(PTRACE_TYPE_RET, $gdb_cv_func_ptrace_ret,
1365   [Define as the return type of ptrace.])
1366 # Check argument types.
1367 AC_CACHE_CHECK([types of arguments for ptrace], gdb_cv_func_ptrace_args, [
1368   AC_TRY_COMPILE($gdb_ptrace_headers,
1369     [extern long ptrace (enum __ptrace_request, ...);],
1370     [gdb_cv_func_ptrace_args='int,int,long,long'],[
1371 for gdb_arg1 in 'int' 'long'; do
1372  for gdb_arg2 in 'pid_t' 'int' 'long'; do
1373   for gdb_arg3 in 'int *' 'caddr_t' 'int' 'long' 'void *'; do
1374    for gdb_arg4 in 'int' 'long' 'void *'; do
1375      AC_TRY_COMPILE($gdb_ptrace_headers, [
1376 extern $gdb_cv_func_ptrace_ret
1377   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4);
1378 ], [gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4";
1379     break 4;])
1380     for gdb_arg5 in 'int *' 'int' 'long'; do
1381      AC_TRY_COMPILE($gdb_ptrace_headers, [
1382 extern $gdb_cv_func_ptrace_ret
1383   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4, $gdb_arg5);
1384 ], [
1385 gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4,$gdb_arg5";
1386     break 5;])
1387     done
1388    done
1389   done
1390  done
1391 done
1392 # Provide a safe default value.
1393 : ${gdb_cv_func_ptrace_args='int,int,long,long'}
1394 ])])
1395 ac_save_IFS=$IFS; IFS=','
1396 set dummy `echo "$gdb_cv_func_ptrace_args" | sed 's/\*/\*/g'`
1397 IFS=$ac_save_IFS
1398 shift
1399 AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG3, $[3],
1400   [Define to the type of arg 3 for ptrace.])
1401 AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG4, $[4],
1402   [Define to the type of arg 4 for ptrace.])
1403 if test -n "$[5]"; then
1404   AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG5, $[5],
1405     [Define to the type of arg 5 for ptrace.])
1406 fi
1407
1408 dnl AC_FUNC_SETPGRP does not work when cross compiling
1409 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
1410 if test "$cross_compiling" = no; then
1411   AC_FUNC_SETPGRP
1412 else
1413   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
1414     [AC_TRY_COMPILE([
1415 #include <unistd.h>
1416 ], [
1417   if (setpgrp(1,1) == -1)
1418     exit (0);
1419   else
1420     exit (1);
1421 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
1422 if test $ac_cv_func_setpgrp_void = yes; then
1423   AC_DEFINE(SETPGRP_VOID, 1)
1424 fi
1425 fi
1426
1427 # Assume we'll default to using the included libiberty regex.
1428 gdb_use_included_regex=yes
1429
1430 # However, if the system regex is GNU regex, then default to *not*
1431 # using the included regex.
1432 AC_CACHE_CHECK(
1433   [for GNU regex],
1434   [gdb_cv_have_gnu_regex],
1435   [AC_TRY_COMPILE(
1436     [#include <gnu-versions.h>],
1437     [#define REGEX_INTERFACE_VERSION 1
1438 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
1439 # error "Version mismatch"
1440 #endif],
1441     gdb_cv_have_gnu_regex=yes,
1442     gdb_cv_have_gnu_regex=no)])
1443 if test $gdb_cv_have_gnu_regex = yes; then
1444   gdb_use_included_regex=no
1445 fi
1446
1447 AC_ARG_WITH(included-regex,
1448   AS_HELP_STRING([--without-included-regex], [don't use included regex; this is the default on systems with version 2 of the GNU C library (use with caution on other system)]),
1449   gdb_with_regex=$withval,
1450   gdb_with_regex=$gdb_use_included_regex)
1451 if test "$gdb_with_regex" = yes; then
1452   AC_DEFINE(USE_INCLUDED_REGEX, 1,
1453     [Define to 1 if the regex included in libiberty should be used.])
1454 fi
1455
1456 # Check if <sys/proc.h> defines `struct thread' with a td_pcb member.
1457 AC_CHECK_MEMBERS([struct thread.td_pcb], [], [],
1458 [#include <sys/param.h>
1459 #include <sys/proc.h>
1460 ])
1461
1462 # See if <sys/lwp.h> defines `struct lwp`.
1463 AC_CACHE_CHECK([for struct lwp], gdb_cv_struct_lwp,
1464 [AC_TRY_COMPILE([#include <sys/param.h>
1465 #include <sys/lwp.h>], [struct lwp l;],
1466 gdb_cv_struct_lwp=yes, gdb_cv_struct_lwp=no)])
1467 if test $gdb_cv_struct_lwp = yes; then
1468   AC_DEFINE(HAVE_STRUCT_LWP, 1,
1469             [Define to 1 if your system has struct lwp.])
1470 fi
1471
1472 # See if <machine/reg.h> degines `struct reg'.
1473 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
1474 [AC_TRY_COMPILE([#include <sys/types.h>
1475 #include <machine/reg.h>], [struct reg r;],
1476 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
1477 if test $gdb_cv_struct_reg = yes; then
1478   AC_DEFINE(HAVE_STRUCT_REG, 1,
1479             [Define to 1 if your system has struct reg in <machine/reg.h>.])
1480 fi
1481
1482 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
1483 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
1484 AC_CHECK_MEMBERS([struct reg.r_fs, struct reg.r_gs], [], [],
1485                  [#include <machine/reg.h>])
1486
1487 # See if <sys/user.h> supports the %fs_base and %gs_bas amd64 segment registers.
1488 # Older amd64 Linux's don't have the fs_base and gs_base members of
1489 # `struct user_regs_struct'.
1490 AC_CHECK_MEMBERS([struct user_regs_struct.fs_base, struct user_regs_struct.gs_base],
1491                  [], [], [#include <sys/user.h>])
1492
1493 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
1494 AC_MSG_CHECKING(for PTRACE_GETREGS)
1495 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
1496 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1497                 [PTRACE_GETREGS;],
1498                 [gdb_cv_have_ptrace_getregs=yes],
1499                 [gdb_cv_have_ptrace_getregs=no])])
1500 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
1501 if test $gdb_cv_have_ptrace_getregs = yes; then
1502   AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
1503   [Define if sys/ptrace.h defines the PTRACE_GETREGS request.])
1504 fi
1505
1506 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
1507 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
1508 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
1509 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1510                 [PTRACE_GETFPXREGS;],
1511                 [gdb_cv_have_ptrace_getfpxregs=yes],
1512                 [gdb_cv_have_ptrace_getfpxregs=no])])
1513 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
1514 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
1515   AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
1516   [Define if sys/ptrace.h defines the PTRACE_GETFPXREGS request.])
1517 fi
1518
1519 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
1520 AC_MSG_CHECKING(for PT_GETDBREGS)
1521 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
1522 [AC_TRY_COMPILE([#include <sys/types.h>
1523 #include <sys/ptrace.h>],
1524                 [PT_GETDBREGS;],
1525                 [gdb_cv_have_pt_getdbregs=yes],
1526                 [gdb_cv_have_pt_getdbregs=no])])
1527 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
1528 if test $gdb_cv_have_pt_getdbregs = yes; then
1529   AC_DEFINE(HAVE_PT_GETDBREGS, 1,
1530   [Define if sys/ptrace.h defines the PT_GETDBREGS request.])
1531 fi
1532
1533 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
1534 AC_MSG_CHECKING(for PT_GETXMMREGS)
1535 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
1536 [AC_TRY_COMPILE([#include <sys/types.h>
1537 #include <sys/ptrace.h>],
1538                 [PT_GETXMMREGS;],
1539                 [gdb_cv_have_pt_getxmmregs=yes],
1540                 [gdb_cv_have_pt_getxmmregs=no])])
1541 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
1542 if test $gdb_cv_have_pt_getxmmregs = yes; then
1543   AC_DEFINE(HAVE_PT_GETXMMREGS, 1,
1544   [Define if sys/ptrace.h defines the PT_GETXMMREGS request.])
1545 fi
1546
1547 # Detect which type of /proc is in use, such as for Solaris.
1548
1549 if test "${target}" = "${host}"; then
1550   case "${host}" in
1551   *-*-sysv4.2* | *-*-sysv5* )
1552       AC_DEFINE(NEW_PROC_API, 1,
1553       [Define if you want to use new multi-fd /proc interface.])
1554       ;;
1555   *-*-solaris2.[[6789]] | *-*-solaris2.1[[0-9]]*)
1556       AC_DEFINE(NEW_PROC_API, 1,
1557       [Define if you want to use new multi-fd /proc interface.])
1558       ;;
1559   mips-sgi-irix5*)
1560       # Work around <sys/proc.h> needing _KMEMUSER problem on IRIX 5.
1561       AC_DEFINE([_KMEMUSER], 1,
1562       [Define to 1 so <sys/proc.h> gets a definition of anon_hdl.  Works
1563        around a <sys/proc.h> problem on IRIX 5.])
1564       ;;
1565   esac
1566 fi
1567
1568 if test "$ac_cv_header_sys_procfs_h" = yes; then
1569   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
1570   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
1571   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
1572   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
1573   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
1574   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
1575   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
1576   BFD_HAVE_SYS_PROCFS_TYPE(prsysent_t)
1577   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigset_t)
1578   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigaction64_t)
1579   BFD_HAVE_SYS_PROCFS_TYPE(pr_siginfo64_t)
1580
1581
1582   dnl Check for broken prfpregset_t type
1583
1584   dnl For Linux/i386, glibc 2.1.3 was released with a bogus
1585   dnl prfpregset_t type (it's a typedef for the pointer to a struct
1586   dnl instead of the struct itself).  We detect this here, and work
1587   dnl around it in gdb_proc_service.h.
1588
1589   if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
1590     AC_MSG_CHECKING(whether prfpregset_t type is broken)
1591     AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
1592       [AC_TRY_RUN([#include <sys/procfs.h>
1593        int main ()
1594        {
1595          if (sizeof (prfpregset_t) == sizeof (void *))
1596            return 1;
1597          return 0;
1598        }],
1599        gdb_cv_prfpregset_t_broken=no,
1600        gdb_cv_prfpregset_t_broken=yes,
1601        gdb_cv_prfpregset_t_broken=yes)])
1602     AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
1603     if test $gdb_cv_prfpregset_t_broken = yes; then
1604       AC_DEFINE(PRFPREGSET_T_BROKEN, 1,
1605       [Define if the prfpregset_t type is broken.])
1606     fi
1607   fi
1608 fi
1609
1610 # Check if the compiler supports the `long long' type.
1611
1612 AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long,
1613                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1614 [[extern long long foo;]],
1615 [[switch (foo & 2) { case 0: return 1; }]])],
1616                                   gdb_cv_c_long_long=yes,
1617                                   gdb_cv_c_long_long=no)])
1618 if test $gdb_cv_c_long_long != yes; then
1619   # libdecnumber requires long long.
1620   AC_MSG_ERROR([Compiler must support long long for GDB.])
1621 fi
1622
1623 # Check if the compiler and runtime support printing long longs.
1624
1625 AC_CACHE_CHECK([for long long support in printf],
1626                gdb_cv_printf_has_long_long,
1627                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1628 [[char buf[32];
1629   long long l = 0;
1630   l = (l << 16) + 0x0123;
1631   l = (l << 16) + 0x4567;
1632   l = (l << 16) + 0x89ab;
1633   l = (l << 16) + 0xcdef;
1634   sprintf (buf, "0x%016llx", l);
1635   return (strcmp ("0x0123456789abcdef", buf));]])],
1636                               gdb_cv_printf_has_long_long=yes,
1637                               gdb_cv_printf_has_long_long=no,
1638                               gdb_cv_printf_has_long_long=no)])
1639 if test $gdb_cv_printf_has_long_long = yes; then
1640   AC_DEFINE(PRINTF_HAS_LONG_LONG, 1,
1641             [Define to 1 if the "%ll" format works to print long longs.])
1642 fi
1643
1644 # Check if the compiler and runtime support printing decfloats.
1645
1646 AC_CACHE_CHECK([for decfloat support in printf],
1647                gdb_cv_printf_has_decfloat,
1648                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1649 [[char buf[64];
1650   _Decimal32 d32 = 1.2345df;
1651   _Decimal64 d64 = 1.2345dd;
1652   _Decimal128 d128 = 1.2345dl;
1653   sprintf (buf, "Decimal32: %H\nDecimal64: %D\nDecimal128: %DD", d32, d64, d128);
1654   return (strcmp ("Decimal32: 1.2345\nDecimal64: 1.2345\nDecimal128: 1.2345", buf));]])],
1655                               gdb_cv_printf_has_decfloat=yes,
1656                               gdb_cv_printf_has_decfloat=no,
1657                               gdb_cv_printf_has_decfloat=no)])
1658 if test $gdb_cv_printf_has_decfloat = yes; then
1659   AC_DEFINE(PRINTF_HAS_DECFLOAT, 1,
1660             [Define to 1 if the "%H, %D and %DD" formats work to print decfloats.])
1661 fi
1662
1663 # Check if the compiler supports the `long double' type.  We can't use
1664 # AC_C_LONG_DOUBLE because that one does additional checks on the
1665 # constants defined in <float.h> that fail on some systems,
1666 # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6.
1667
1668 AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double,
1669                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])],
1670                                   gdb_cv_c_long_double=yes,
1671                                   gdb_cv_c_long_double=no)])
1672 if test $gdb_cv_c_long_double = yes; then
1673   AC_DEFINE(HAVE_LONG_DOUBLE, 1,
1674            [Define to 1 if the compiler supports long double.])
1675 fi
1676
1677 # Check if the compiler and runtime support printing long doubles.
1678
1679 AC_CACHE_CHECK([for long double support in printf],
1680                gdb_cv_printf_has_long_double,
1681                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1682 [[char buf[16];
1683   long double f = 3.141592653;
1684   sprintf (buf, "%Lg", f);
1685   return (strncmp ("3.14159", buf, 7));]])],
1686                               gdb_cv_printf_has_long_double=yes,
1687                               gdb_cv_printf_has_long_double=no,
1688                               gdb_cv_printf_has_long_double=no)])
1689 if test $gdb_cv_printf_has_long_double = yes; then
1690   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1,
1691             [Define to 1 if the "%Lg" format works to print long doubles.])
1692 fi
1693
1694 # Check if the compiler and runtime support scanning long doubles.
1695
1696 AC_CACHE_CHECK([for long double support in scanf],
1697                gdb_cv_scanf_has_long_double,
1698                [AC_RUN_IFELSE([AC_LANG_PROGRAM(
1699 [[#include <stdio.h>]],
1700 [[char *buf = "3.141592653";
1701   long double f = 0;
1702   sscanf (buf, "%Lg", &f);
1703   return !(f > 3.14159 && f < 3.14160);]])],
1704                               gdb_cv_scanf_has_long_double=yes,
1705                               gdb_cv_scanf_has_long_double=no,
1706                               gdb_cv_scanf_has_long_double=no)])
1707 if test $gdb_cv_scanf_has_long_double = yes; then
1708   AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1,
1709             [Define to 1 if the "%Lg" format works to scan long doubles.])
1710 fi
1711
1712 case ${host_os} in
1713 aix*)
1714   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1715     SAVE_LDFLAGS=$LDFLAGS
1716
1717     case $GCC in
1718     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1719     *) gdb_cv_bigtoc=-bbigtoc ;;
1720     esac
1721
1722     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1723     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1724     LDFLAGS="${SAVE_LDFLAGS}"
1725   ])
1726   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
1727   ;;
1728 esac
1729
1730 AC_MSG_CHECKING(for the dynamic export flag)
1731 dynamic_list=false
1732 if test "${gdb_native}" = yes; then
1733    # The dynamically loaded libthread_db needs access to symbols in the gdb
1734    # executable.  Older GNU ld supports --export-dynamic but --dynamic-list
1735    # may not be supported there.
1736    old_LDFLAGS="$LDFLAGS"
1737    # Older GNU ld supports --export-dynamic but --dynamic-list it does not.
1738    RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
1739    LDFLAGS="$LDFLAGS $RDYNAMIC"
1740    if test "${have_libpython}" = no; then
1741      AC_TRY_LINK([], [], [dynamic_list=true])
1742    else
1743      # Workaround http://bugs.python.org/issue4434 where static
1744      # libpythonX.Y.a would get its symbols required for
1745      # pythonX.Y/lib-dynload/*.so modules hidden by -Wl,--dynamic-list.
1746      # Problem does not happen for the recommended libpythonX.Y.so linkage.
1747      old_CFLAGS="$CFLAGS"
1748      CFLAGS="$CFLAGS $PYTHON_CFLAGS"
1749      old_LIBS="$LIBS"
1750      LIBS="$LIBS $PYTHON_LIBS"
1751      AC_RUN_IFELSE(
1752        AC_LANG_PROGRAM(
1753          [#include "]${have_libpython}[/Python.h"],
1754          [int err;
1755           Py_Initialize ();
1756           err = PyRun_SimpleString ("import itertools\n");
1757           Py_Finalize ();
1758           return err == 0 ? 0 : 1;]),
1759        [dynamic_list=true], [], [true])
1760      LIBS="$old_LIBS"
1761      CFLAGS="$old_CFLAGS"
1762    fi
1763    LDFLAGS="$old_LDFLAGS"
1764 fi
1765 if $dynamic_list; then
1766   found="-Wl,--dynamic-list"
1767   RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'
1768 else
1769   found="-rdynamic"
1770   RDYNAMIC="-rdynamic"
1771 fi
1772 AC_SUBST(RDYNAMIC)
1773 AC_MSG_RESULT($found)
1774
1775 dnl For certain native configurations, we need to check whether thread
1776 dnl support can be built in or not.
1777 dnl
1778 dnl Note that we only want this if we are both native (host == target),
1779 dnl and not doing a canadian cross build (build == host).
1780
1781 if test ${build} = ${host} -a ${host} = ${target} ; then
1782    case ${host_os} in
1783    solaris*)
1784       # See if thread_db library is around for Solaris thread debugging.
1785       # Note that we must explicitly test for version 1 of the library
1786       # because version 0 (present on Solaris 2.4 or earlier) doesn't have
1787       # the same API.
1788       AC_MSG_CHECKING(for Solaris thread debugging library)
1789       if test -f /usr/lib/libthread_db.so.1 ; then
1790          AC_MSG_RESULT(yes)
1791          AC_DEFINE(HAVE_THREAD_DB_LIB, 1,
1792          [Define if using Solaris thread debugging.])
1793          CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
1794          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
1795          AC_CHECK_LIB(dl, dlopen)
1796          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} $RDYNAMIC"
1797          # Sun randomly tweaked the prototypes in <proc_service.h>
1798          # at one point.
1799          AC_MSG_CHECKING(if <proc_service.h> is old)
1800          AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
1801             AC_TRY_COMPILE([
1802                 #include <proc_service.h>
1803                 ps_err_e ps_pdwrite
1804                     (struct ps_prochandle*, psaddr_t, const void*, size_t);
1805             ],, gdb_cv_proc_service_is_old=no,
1806                 gdb_cv_proc_service_is_old=yes)
1807          ])
1808          AC_MSG_RESULT($gdb_cv_proc_service_is_old)
1809          if test $gdb_cv_proc_service_is_old = yes; then
1810             AC_DEFINE(PROC_SERVICE_IS_OLD, 1,
1811             [Define if <proc_service.h> on solaris uses int instead of
1812              size_t, and assorted other type changes.])
1813          fi
1814       else
1815          AC_MSG_RESULT(no)
1816       fi
1817       ;;
1818    aix*)
1819       AC_MSG_CHECKING(for AiX thread debugging library)
1820       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
1821                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
1822                                    [#ifndef PTHDB_VERSION_3
1823                                     #error
1824                                     #endif],
1825                                    gdb_cv_have_aix_thread_debug=yes,
1826                                    gdb_cv_have_aix_thread_debug=no)])
1827       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1828       if test $gdb_cv_have_aix_thread_debug = yes; then
1829          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1830          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1831          LIBS="$LIBS -lpthdebug"
1832
1833          # Older versions of AIX do not provide the declaration for
1834          # the getthrds function (it appears that it was introduced
1835          # with AIX 6.x).
1836          AC_CHECK_DECLS(getthrds, [], [], [[#include <procinfo.h>]])
1837       fi
1838       ;;
1839    esac
1840    AC_SUBST(CONFIG_LDFLAGS)
1841 fi
1842
1843 dnl See if we have a thread_db header file that has TD_NOTALLOC and
1844 dnl other error codes.
1845 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1846    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
1847                   gdb_cv_thread_db_h_has_td_notalloc,
1848      AC_TRY_COMPILE(
1849        [#include <thread_db.h>],
1850        [int i = TD_NOTALLOC;],
1851        gdb_cv_thread_db_h_has_td_notalloc=yes,
1852        gdb_cv_thread_db_h_has_td_notalloc=no
1853      )
1854    )
1855    AC_CACHE_CHECK([whether <thread_db.h> has TD_VERSION],
1856                   gdb_cv_thread_db_h_has_td_version,
1857      AC_TRY_COMPILE(
1858        [#include <thread_db.h>],
1859        [int i = TD_VERSION;],
1860        gdb_cv_thread_db_h_has_td_version=yes,
1861        gdb_cv_thread_db_h_has_td_version=no
1862      )
1863    )
1864    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTLS],
1865                   gdb_cv_thread_db_h_has_td_notls,
1866      AC_TRY_COMPILE(
1867        [#include <thread_db.h>],
1868        [int i = TD_NOTLS;],
1869        gdb_cv_thread_db_h_has_td_notls=yes,
1870        gdb_cv_thread_db_h_has_td_notls=no
1871      )
1872    )
1873 fi
1874 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1875   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1876             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1877 fi
1878 if test "x$gdb_cv_thread_db_h_has_td_version" = "xyes"; then
1879   AC_DEFINE(THREAD_DB_HAS_TD_VERSION, 1,
1880             [Define if <thread_db.h> has the TD_VERSION error code.])
1881 fi
1882 if test "x$gdb_cv_thread_db_h_has_td_notls" = "xyes"; then
1883   AC_DEFINE(THREAD_DB_HAS_TD_NOTLS, 1,
1884             [Define if <thread_db.h> has the TD_NOTLS error code.])
1885 fi
1886
1887 dnl See if we have a sys/syscall header file that has __NR_tkill.
1888 if test "x$ac_cv_header_sys_syscall_h" = "xyes"; then
1889    AC_CACHE_CHECK([whether <sys/syscall.h> has __NR_tkill],
1890                   gdb_cv_sys_syscall_h_has_tkill,
1891      AC_TRY_COMPILE(
1892        [#include <sys/syscall.h>],
1893        [int i = __NR_tkill;],
1894        gdb_cv_sys_syscall_h_has_tkill=yes,
1895        gdb_cv_sys_syscall_h_has_tkill=no
1896      )
1897    )
1898 fi
1899 dnl See if we can issue tkill syscall.
1900 if test "x$gdb_cv_sys_syscall_h_has_tkill" = "xyes"; then
1901   AC_CHECK_FUNC(syscall,
1902     AC_DEFINE(HAVE_TKILL_SYSCALL, 1, [Define if you support the tkill syscall.])
1903   )
1904 fi
1905
1906 dnl Check if we can disable the virtual address space randomization.
1907 dnl The functionality of setarch -R.
1908 AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>])
1909 define([PERSONALITY_TEST], [AC_LANG_PROGRAM([#include <sys/personality.h>], [
1910 #      if !HAVE_DECL_ADDR_NO_RANDOMIZE
1911 #       define ADDR_NO_RANDOMIZE 0x0040000
1912 #      endif
1913        /* Test the flag could be set and stays set.  */
1914        personality (personality (0xffffffff) | ADDR_NO_RANDOMIZE);
1915        if (!(personality (personality (0xffffffff)) & ADDR_NO_RANDOMIZE))
1916            return 1])])
1917 AC_RUN_IFELSE([PERSONALITY_TEST],
1918               [have_personality=true],
1919               [have_personality=false],
1920               [AC_LINK_IFELSE([PERSONALITY_TEST],
1921                               [have_personality=true],
1922                               [have_personality=false])])
1923 if $have_personality
1924 then
1925     AC_DEFINE([HAVE_PERSONALITY], 1,
1926               [Define if you support the personality syscall.])
1927 fi
1928
1929 dnl Set the host's .gdbinit filename.
1930 case $host_os in
1931   go32* | *djgpp*)
1932     gdbinit=gdb.ini
1933     ;;
1934   *)
1935     gdbinit=.gdbinit
1936     ;;
1937 esac
1938 AC_DEFINE_UNQUOTED(GDBINIT,"$gdbinit",[The .gdbinit filename.])
1939
1940 dnl Handle optional features that can be enabled.
1941
1942 # Support for --with-sysroot is a copy of GDB_AC_WITH_DIR,
1943 # except that the argument to --with-sysroot is optional.
1944 # --with-sysroot (or --with-sysroot=yes) sets the default sysroot path.
1945 if test "x$with_sysroot" = xyes; then
1946   with_sysroot="${exec_prefix}/${target_alias}/sys-root"
1947 fi
1948 AC_ARG_WITH(sysroot,
1949   AS_HELP_STRING([--with-sysroot@<:@=DIR@:>@],
1950                  [search for usr/lib et al within DIR]),
1951   [TARGET_SYSTEM_ROOT=$withval], [TARGET_SYSTEM_ROOT=])
1952 AC_DEFINE_DIR(TARGET_SYSTEM_ROOT, TARGET_SYSTEM_ROOT,
1953               [search for usr/lib et al within DIR])
1954 AC_SUBST(TARGET_SYSTEM_ROOT)
1955 GDB_AC_DEFINE_RELOCATABLE(TARGET_SYSTEM_ROOT, sysroot, ${ac_define_dir})
1956
1957 GDB_AC_WITH_DIR(SYSTEM_GDBINIT, system-gdbinit,
1958     [automatically load a system-wide gdbinit file],
1959     [])
1960
1961 AC_ARG_ENABLE(werror,
1962   AS_HELP_STRING([--enable-werror], [treat compile warnings as errors]),
1963   [case "${enableval}" in
1964      yes | y) ERROR_ON_WARNING="yes" ;;
1965      no | n)  ERROR_ON_WARNING="no" ;;
1966      *) AC_MSG_ERROR(bad value ${enableval} for --enable-werror) ;;
1967    esac])
1968
1969 # Enable -Werror by default when using gcc in C mode.  Leave it off
1970 # for C++ until we're warning clean.  Turn it off for releases.
1971 if test "${GCC}" = yes -a -z "${ERROR_ON_WARNING}" \
1972    && test x"$enable_build_with_cxx" != x"yes" \
1973    && $development; then
1974     ERROR_ON_WARNING=yes
1975 fi
1976
1977 WERROR_CFLAGS=""
1978 if test "${ERROR_ON_WARNING}" = yes ; then
1979     WERROR_CFLAGS="-Werror"
1980 fi
1981
1982 # These options work in either C or C++ modes.
1983 build_warnings="-Wall -Wpointer-arith \
1984 -Wno-unused -Wunused-value -Wunused-function \
1985 -Wno-switch -Wno-char-subscripts \
1986 -Wempty-body"
1987
1988 # Now add in C and C++ specific options, depending on mode.
1989 if test "$enable_build_with_cxx" = "yes"; then
1990    build_warnings="$build_warnings -Wno-sign-compare -Wno-write-strings \
1991 -Wno-narrowing"
1992 else
1993    build_warnings="$build_warnings -Wpointer-sign -Wmissing-prototypes \
1994 -Wdeclaration-after-statement -Wmissing-parameter-type \
1995 -Wold-style-declaration -Wold-style-definition"
1996 fi
1997
1998 # Enable -Wno-format by default when using gcc on mingw since many
1999 # GCC versions complain about %I64.
2000 case "${host}" in
2001   *-*-mingw32*) build_warnings="$build_warnings -Wno-format" ;;
2002   *) build_warnings="$build_warnings -Wformat-nonliteral" ;;
2003 esac
2004
2005 AC_ARG_ENABLE(build-warnings,
2006 AS_HELP_STRING([--enable-build-warnings], [enable build-time compiler warnings if gcc is used]),
2007 [case "${enableval}" in
2008   yes)  ;;
2009   no)   build_warnings="-w";;
2010   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
2011         build_warnings="${build_warnings} ${t}";;
2012   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
2013         build_warnings="${t} ${build_warnings}";;
2014   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
2015 esac
2016 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
2017   echo "Setting compiler warning flags = $build_warnings" 6>&1
2018 fi])dnl
2019 AC_ARG_ENABLE(gdb-build-warnings,
2020 AS_HELP_STRING([--enable-gdb-build-warnings], [enable GDB specific build-time compiler warnings if gcc is used]),
2021 [case "${enableval}" in
2022   yes)  ;;
2023   no)   build_warnings="-w";;
2024   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
2025         build_warnings="${build_warnings} ${t}";;
2026   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
2027         build_warnings="${t} ${build_warnings}";;
2028   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
2029 esac
2030 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
2031   echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1
2032 fi])dnl
2033
2034 # The set of warnings supported by a C++ compiler is not the same as
2035 # of the C compiler.
2036 if test "$enable_build_with_cxx" = "yes"; then
2037     AC_LANG_PUSH([C++])
2038 fi
2039
2040 WARN_CFLAGS=""
2041 if test "x${build_warnings}" != x -a "x$GCC" = xyes
2042 then
2043     AC_MSG_CHECKING(compiler warning flags)
2044     # Separate out the -Werror flag as some files just cannot be
2045     # compiled with it enabled.
2046     for w in ${build_warnings}; do
2047         case $w in
2048         -Werr*) WERROR_CFLAGS=-Werror ;;
2049         *)
2050             # Check whether GCC accepts it.
2051             saved_CFLAGS="$CFLAGS"
2052             CFLAGS="$CFLAGS $w"
2053             saved_CXXFLAGS="$CXXFLAGS"
2054             CXXFLAGS="$CXXFLAGS $w"
2055             AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
2056             CFLAGS="$saved_CFLAGS"
2057             CXXFLAGS="$saved_CXXFLAGS"
2058         esac
2059     done
2060     AC_MSG_RESULT(${WARN_CFLAGS} ${WERROR_CFLAGS})
2061 fi
2062 AC_SUBST(WARN_CFLAGS)
2063 AC_SUBST(WERROR_CFLAGS)
2064
2065 if test "$enable_build_with_cxx" = "yes"; then
2066    AC_LANG_POP([C++])
2067 fi
2068
2069 # In the Cygwin environment, we need some additional flags.
2070 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
2071 [AC_EGREP_CPP(^lose$, [
2072 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
2073 lose
2074 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
2075
2076
2077 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
2078 SER_HARDWIRE="ser-base.o ser-unix.o ser-pipe.o ser-tcp.o"
2079 case ${host} in
2080   *go32* ) SER_HARDWIRE=ser-go32.o ;;
2081   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
2082   *mingw32*) SER_HARDWIRE="ser-base.o ser-tcp.o ser-mingw.o" ;;
2083 esac
2084 AC_SUBST(SER_HARDWIRE)
2085
2086 # libreadline needs libuser32.a in a cygwin environment
2087 WIN32LIBS=
2088 if test x$gdb_cv_os_cygwin = xyes; then
2089     WIN32LIBS="-luser32"
2090     case "${target}" in
2091         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
2092         ;;
2093     esac
2094 fi
2095
2096 # The ser-tcp.c module requires sockets.
2097 case ${host} in
2098   *mingw32*)
2099     AC_DEFINE(USE_WIN32API, 1,
2100               [Define if we should use the Windows API, instead of the
2101                POSIX API.  On Windows, we use the Windows API when
2102                building for MinGW, but the POSIX API when building
2103                for Cygwin.])
2104     WIN32LIBS="$WIN32LIBS -lws2_32"
2105     ;;
2106 esac
2107 AC_SUBST(WIN32LIBS)
2108
2109 # Add ELF support to GDB, but only if BFD includes ELF support.
2110 GDB_AC_CHECK_BFD([for ELF support in BFD], gdb_cv_var_elf,
2111                  [bfd_get_elf_phdr_upper_bound (NULL)], elf-bfd.h)
2112 if test $gdb_cv_var_elf = yes; then
2113   CONFIG_OBS="$CONFIG_OBS elfread.o stap-probe.o dtrace-probe.o"
2114   AC_DEFINE(HAVE_ELF, 1,
2115             [Define if ELF support should be included.])
2116   # -ldl is provided by bfd/Makfile.am (LIBDL) <PLUGINS>.
2117   if test "$plugins" = "yes"; then
2118     AC_SEARCH_LIBS(dlopen, dl)
2119   fi
2120 fi
2121
2122 # Add macho support to GDB, but only if BFD includes it.
2123 GDB_AC_CHECK_BFD([for Mach-O support in BFD], gdb_cv_var_macho,
2124                  [bfd_mach_o_lookup_command (NULL, 0, NULL)], mach-o.h)
2125 if test $gdb_cv_var_macho = yes; then
2126   CONFIG_OBS="$CONFIG_OBS machoread.o"
2127 fi
2128
2129 # Add any host-specific objects to GDB.
2130 CONFIG_OBS="${CONFIG_OBS} ${gdb_host_obs}"
2131
2132 # If building on ELF, look for lzma support for embedded compressed debug info.
2133 if test $gdb_cv_var_elf = yes; then
2134   AC_ARG_WITH(lzma,
2135     AS_HELP_STRING([--with-lzma], [support lzma compression (auto/yes/no)]),
2136     [], [with_lzma=auto])
2137   AC_MSG_CHECKING([whether to use lzma])
2138   AC_MSG_RESULT([$with_lzma])
2139
2140   if test "${with_lzma}" != no; then
2141     AC_LIB_HAVE_LINKFLAGS([lzma], [], [#include "lzma.h"],
2142                           [lzma_index_iter iter;
2143                            lzma_index_iter_init (&iter, 0);
2144                            lzma_mf_is_supported (LZMA_MF_HC3);])
2145     if test "$HAVE_LIBLZMA" != yes; then
2146       if test "$with_lzma" = yes; then
2147         AC_MSG_ERROR([missing liblzma for --with-lzma])
2148       fi
2149     fi
2150   fi
2151 fi
2152
2153 LIBGUI="../libgui/src/libgui.a"
2154 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
2155 AC_SUBST(LIBGUI)
2156 AC_SUBST(GUI_CFLAGS_X)
2157
2158 WIN32LDAPP=
2159 AC_SUBST(WIN32LIBS)
2160 AC_SUBST(WIN32LDAPP)
2161
2162 case "${host}" in
2163 *-*-cygwin* | *-*-mingw* )
2164     configdir="win"
2165     ;;
2166 *)
2167     configdir="unix"
2168     ;;
2169 esac
2170
2171 GDBTKLIBS=
2172 if test "${enable_gdbtk}" = "yes"; then
2173
2174     # Gdbtk must have an absolute path to srcdir in order to run
2175     # properly when not installed.
2176     here=`pwd`
2177     cd ${srcdir}
2178     GDBTK_SRC_DIR=`pwd`
2179     cd $here
2180
2181     SC_PATH_TCLCONFIG
2182
2183     # If $no_tk is nonempty, then we can't do Tk, and there is no
2184     # point to doing Tcl.
2185     SC_PATH_TKCONFIG
2186
2187     if test -z "${no_tcl}" -a -z "${no_tk}"; then
2188         SC_LOAD_TCLCONFIG
2189
2190         # Check for in-tree tcl
2191         here=`pwd`
2192         cd ${srcdir}/..
2193         topdir=`pwd`
2194         cd ${here}
2195
2196         intree="no"
2197         if test "${TCL_SRC_DIR}" = "${topdir}/tcl"; then
2198           intree="yes"
2199         fi
2200
2201         # Find Tcl private headers
2202         if test x"${intree}" = xno; then
2203           CY_AC_TCL_PRIVATE_HEADERS
2204           TCL_INCLUDE="${TCL_INCLUDE_SPEC} ${TCL_PRIVATE_INCLUDE}"
2205           TCL_LIBRARY="${TCL_LIB_SPEC}"
2206           TCL_DEPS=""
2207         else
2208           # If building tcl in the same src tree, private headers
2209           # are not needed, but we need to be sure to use the right
2210           # headers library
2211           TCL_INCLUDE="-I${TCL_SRC_DIR}/generic"
2212           TCL_LIBRARY="${TCL_BUILD_LIB_SPEC}"
2213           TCL_DEPS="../tcl/${configdir}${TCL_LIB_FILE}"
2214         fi
2215         AC_SUBST(TCL_INCLUDE)
2216         AC_SUBST(TCL_LIBRARY)
2217         AC_SUBST(TCL_DEPS)
2218
2219         SC_LOAD_TKCONFIG
2220
2221         # Check for in-tree Tk
2222         intree="no"
2223         if test "${TK_SRC_DIR}" = "${topdir}/tk"; then
2224           intree="yes"
2225         fi
2226
2227         # Find Tk private headers
2228         if test x"${intree}" = xno; then
2229           CY_AC_TK_PRIVATE_HEADERS
2230           TK_INCLUDE="${TK_INCLUDE_SPEC} ${TK_PRIVATE_INCLUDE}"
2231           TK_LIBRARY=${TK_LIB_SPEC}
2232           TK_DEPS=""
2233         else
2234           TK_INCLUDE="-I${TK_SRC_DIR}/generic"
2235           TK_LIBRARY="${TK_BUILD_LIB_SPEC}"
2236           TK_DEPS="../tk/${configdir}/${TK_LIB_FILE}"
2237         fi
2238         AC_SUBST(TK_INCLUDE)
2239         AC_SUBST(TK_LIBRARY)
2240         AC_SUBST(TK_DEPS)
2241         AC_SUBST(TK_XINCLUDES)
2242
2243         ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
2244
2245         # Include some libraries that Tcl and Tk want.
2246         TCL_LIBS='$(LIBGUI) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
2247         # Yes, the ordering seems wrong here.  But it isn't.
2248         # TK_LIBS is the list of libraries that need to be linked
2249         # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
2250         # were in LIBS then any link tests after this point would
2251         # try to include things like `$(LIBGUI)', which wouldn't work.
2252         GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
2253
2254         CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
2255         CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
2256         CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
2257         CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
2258         CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
2259         CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
2260         CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
2261
2262         if test x$gdb_cv_os_cygwin = xyes; then
2263           WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
2264           WIN32LDAPP="-Wl,--subsystem,console"
2265           CONFIG_OBS="${CONFIG_OBS} gdbres.o"
2266         fi
2267
2268         AC_CONFIG_SUBDIRS(gdbtk)
2269     fi
2270 fi
2271
2272 AC_SUBST(X_CFLAGS)
2273 AC_SUBST(X_LDFLAGS)
2274 AC_SUBST(X_LIBS)
2275 AC_SUBST(GDBTKLIBS)
2276 AC_SUBST(GDBTK_CFLAGS)
2277 AC_SUBST(GDBTK_SRC_DIR)
2278
2279 AC_PATH_X
2280
2281 # Unlike the sim directory, whether a simulator is linked is controlled by
2282 # presence of a gdb_sim definition in the target configure.tgt entry.
2283 # This code just checks for a few cases where we'd like to ignore those
2284 # definitions, even when they're present in the '.mt' file.  These cases
2285 # are when --disable-sim is specified, or if the simulator directory is
2286 # not part of the source tree.
2287 #
2288 AC_ARG_ENABLE(sim,
2289 AS_HELP_STRING([--enable-sim], [link gdb with simulator]),
2290 [echo "enable_sim = $enable_sim";
2291  echo "enableval = ${enableval}";
2292  case "${enableval}" in
2293   yes) ignore_sim=false ;;
2294   no)  ignore_sim=true ;;
2295   *)   ignore_sim=false ;;
2296  esac],
2297 [ignore_sim=false])
2298
2299 if test ! -d "${srcdir}/../sim"; then
2300   ignore_sim=true
2301 fi
2302
2303 SIM=
2304 SIM_OBS=
2305 if test "${ignore_sim}" = "false"; then
2306   if test x"${gdb_sim}" != x ; then
2307     SIM="${gdb_sim}"
2308     SIM_OBS="remote-sim.o"
2309     AC_DEFINE(WITH_SIM, 1, [Define if the simulator is being linked in.])
2310   fi
2311 fi
2312 AC_SUBST(SIM)
2313 AC_SUBST(SIM_OBS)
2314
2315 AC_SUBST(ENABLE_CFLAGS)
2316 AC_SUBST(PROFILE_CFLAGS)
2317
2318 AC_SUBST(CONFIG_OBS)
2319 AC_SUBST(CONFIG_DEPS)
2320 AC_SUBST(CONFIG_SRCS)
2321 AC_SUBST(CONFIG_ALL)
2322 AC_SUBST(CONFIG_CLEAN)
2323 AC_SUBST(CONFIG_INSTALL)
2324 AC_SUBST(CONFIG_UNINSTALL)
2325
2326 # List of host floatformats.
2327 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
2328 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
2329 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
2330
2331 # target_subdir is used by the testsuite to find the target libraries.
2332 target_subdir=
2333 if test "${host}" != "${target}"; then
2334     target_subdir="${target_alias}/"
2335 fi
2336 AC_SUBST(target_subdir)
2337
2338 frags=
2339 if test "${gdb_native}" = "yes"; then
2340   host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
2341   if test ! -f ${host_makefile_frag}; then
2342     AC_MSG_ERROR("*** Gdb does not support native target ${host}")
2343   fi
2344   frags="$frags $host_makefile_frag"
2345 else
2346   host_makefile_frag=/dev/null
2347 fi
2348
2349 AC_SUBST_FILE(host_makefile_frag)
2350 AC_SUBST(frags)
2351
2352 changequote(,)dnl
2353 if test "${gdb_native}" = "yes"; then
2354 # We pick this up from the host configuration file (.mh) because we
2355 # do not have a native configuration Makefile fragment.
2356 nativefile=`sed -n '
2357 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
2358 ' ${host_makefile_frag}`
2359 fi
2360 changequote([,])
2361
2362 if test x"${gdb_osabi}" != x ; then
2363     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
2364                        [Define to the default OS ABI for this configuration.])
2365 fi
2366
2367 # Enable multi-ice-gdb-server.
2368 AC_ARG_ENABLE(multi-ice,
2369 AS_HELP_STRING([--enable-multi-ice], [build the multi-ice-gdb-server]),
2370   [case $enableval in
2371     yes | no)
2372       ;;
2373     *) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;;
2374   esac])
2375 if test "x$enable_multi_ice" = xyes; then
2376    AC_CONFIG_SUBDIRS(multi-ice)
2377 fi
2378
2379 AC_ARG_ENABLE(gdbserver,
2380 AS_HELP_STRING([--enable-gdbserver],
2381                [automatically build gdbserver (yes/no/auto, default is auto)]),
2382 [case "${enableval}" in
2383   yes| no|auto) ;;
2384   *) AC_MSG_ERROR(bad value ${enableval} for --enable-gdbserver option) ;;
2385 esac],[enable_gdbserver=auto])
2386
2387 # We only build gdbserver automatically in a native configuration, and
2388 # only if the user did not explicitly disable its build.
2389 if test "$gdb_native" = "yes" -a "$enable_gdbserver" != "no"; then
2390   AC_MSG_CHECKING(whether gdbserver is supported on this host)
2391   if test "x$build_gdbserver" = xyes; then
2392     AC_MSG_RESULT(yes)
2393     AC_CONFIG_SUBDIRS(gdbserver)
2394     gdbserver_build_enabled=yes
2395   else
2396     AC_MSG_RESULT(no)
2397   fi
2398 fi
2399
2400 # If the user explicitly request the gdbserver to be built, verify that
2401 # we were in fact able to enable it.
2402 if test "$enable_gdbserver" = "yes" -a "$gdbserver_build_enabled" != "yes"; then
2403   AC_MSG_ERROR(Automatic gdbserver build is not supported for this configuration)
2404 fi
2405
2406 # Check for babeltrace and babeltrace-ctf
2407 AC_ARG_WITH(babeltrace,
2408   AC_HELP_STRING([--with-babeltrace], [include babeltrace support (auto/yes/no)]),
2409   [], [with_babeltrace=auto])
2410 AC_MSG_CHECKING([whether to use babeltrace])
2411 AC_MSG_RESULT([$with_babeltrace])
2412
2413 if test "x$with_babeltrace" = "xno"; then
2414   AC_MSG_WARN([babletrace support disabled; GDB is unable to read CTF data.])
2415 else
2416   # Append -Werror to CFLAGS so that configure can catch the warning
2417   # "assignment from incompatible pointer type", which is related to
2418   # the babeltrace change from 1.0.3 to 1.1.0.  Babeltrace 1.1.0 works
2419   # in GDB, while babeltrace 1.0.3 is broken.
2420   # AC_LIB_HAVE_LINKFLAGS may modify CPPFLAGS in it, so it should be
2421   # safe to save and restore CFLAGS here.
2422   saved_CFLAGS=$CFLAGS
2423   CFLAGS="$CFLAGS -Werror"
2424   AC_LIB_HAVE_LINKFLAGS([babeltrace], [babeltrace-ctf],
2425                         [#include <babeltrace/babeltrace.h>
2426                          #include <babeltrace/ctf/events.h>
2427                          #include <babeltrace/ctf/iterator.h>],
2428                         [struct bt_iter_pos *pos = bt_iter_get_pos (bt_ctf_get_iter (NULL));
2429                         struct bt_ctf_event *event = NULL;
2430                         const struct bt_definition *scope;
2431
2432                         bt_iter_set_pos (bt_ctf_get_iter (NULL), pos);
2433                         scope = bt_ctf_get_top_level_scope (event,
2434                                                            BT_STREAM_EVENT_HEADER);
2435                         bt_ctf_get_uint64 (bt_ctf_get_field (event, scope, "id"));
2436                         ])
2437   CFLAGS=$saved_CFLAGS
2438
2439   if test "$HAVE_LIBBABELTRACE" != yes; then
2440      if test "$with_babeltrace" = yes; then
2441        AC_MSG_ERROR([babeltrace is missing or unusable])
2442      else
2443        AC_MSG_WARN([babeltrace is missing or unusable; GDB is unable to read CTF data.])
2444      fi
2445   fi
2446 fi
2447
2448 # If nativefile (NAT_FILE) is not set in config/*/*.m[ht] files, we link
2449 # to an empty version.
2450
2451 files=
2452 links=
2453
2454 rm -f nm.h
2455 if test "${nativefile}" != ""; then
2456     case "${nativefile}" in
2457       nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
2458       * ) GDB_NM_FILE="${nativefile}"
2459     esac
2460     files="${files} ${GDB_NM_FILE}"
2461     links="${links} nm.h"
2462     AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}", [nativefile])
2463 fi
2464 AC_SUBST(GDB_NM_FILE)
2465
2466 AC_LINK_FILES($files, $links)
2467
2468 dnl Check for exe extension set on certain hosts (e.g. Win32)
2469 AC_EXEEXT
2470
2471 dnl  Detect the character set used by this host.
2472 dnl  At the moment, we just assume it's UTF-8.
2473 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "UTF-8",
2474           [Define to be a string naming the default host character set.])
2475
2476 GDB_AC_TRANSFORM([gdb], [GDB_TRANSFORM_NAME])
2477 GDB_AC_TRANSFORM([gcore], [GCORE_TRANSFORM_NAME])
2478 AC_CONFIG_FILES([gcore], [chmod +x gcore])
2479
2480 AC_OUTPUT(Makefile gdb-gdb.gdb doc/Makefile data-directory/Makefile,
2481 [
2482 case x$CONFIG_HEADERS in
2483 xconfig.h:config.in)
2484 echo > stamp-h ;;
2485 esac
2486 ])
2487
2488 exit 0