gdb/configure.ac

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995-2017 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Process this file with autoconf to produce a configure script.
  20
  21 AC_PREREQ(2.59)dnl
  22 AC_INIT(main.c)
  23 AC_CONFIG_HEADER(config.h:config.in)
  24 AM_MAINTAINER_MODE
  25
  26 # Set the 'development' global.
  27 . $srcdir/../bfd/development.sh
  28
  29 AC_PROG_CC
  30 AC_PROG_CXX
  31
  32 AC_USE_SYSTEM_EXTENSIONS
  33 ACX_LARGEFILE
  34 AM_PROG_CC_STDC
  35 AM_PROG_INSTALL_STRIP
  36
  37 AC_CONFIG_AUX_DIR(..)
  38 AC_CANONICAL_SYSTEM
  39 AC_ARG_PROGRAM
  40
  41 # We require a C++11 compiler.  Check if one is available, and if
  42 # necessary, set CXX_DIALECT to some -std=xxx switch.
  43 AX_CXX_COMPILE_STDCXX(11, , mandatory)
  44
  45 # Dependency checking.
  46 ZW_CREATE_DEPDIR
  47 # Create sub-directories for objects and dependencies.
  48 CONFIG_SRC_SUBDIR="arch"
  49 AC_SUBST(CONFIG_SRC_SUBDIR)
  50
  51 AC_CONFIG_COMMANDS([gdbdepdir],[
  52   for subdir in ${CONFIG_SRC_SUBDIR}
  53   do
  54       $SHELL $ac_aux_dir/mkinstalldirs $subdir/$DEPDIR
  55   done],
  56   [ac_aux_dir=$ac_aux_dir DEPDIR=$DEPDIR CONFIG_SRC_SUBDIR="$CONFIG_SRC_SUBDIR"])
  57
  58 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  59
  60 gnulib_extra_configure_args=
  61 # If large-file support is disabled, make sure gnulib does the same.
  62 if test "$enable_largefile" = no; then
  63 gnulib_extra_configure_args="$gnulib_extra_configure_args --disable-largefile"
  64 fi
  65
  66 # Configure gnulib.  We need to build gnulib under some other
  67 # directory not "gnulib", to avoid the problem of both GDB and
  68 # GDBserver wanting to build it in the same directory, when building
  69 # in the source dir.
  70 ACX_CONFIGURE_DIR(["gnulib"], ["build-gnulib"],
  71                   ["$gnulib_extra_configure_args"])
  72
  73 dnl List of object files and targets accumulated by configure.
  74
  75 CONFIG_OBS=
  76 CONFIG_DEPS=
  77 CONFIG_SRCS=
  78 ENABLE_CFLAGS=
  79
  80 CONFIG_ALL=
  81 CONFIG_CLEAN=
  82 CONFIG_INSTALL=
  83 CONFIG_UNINSTALL=
  84
  85 dnl Set up for gettext.
  86 ZW_GNU_GETTEXT_SISTER_DIR
  87
  88 localedir='${datadir}/locale'
  89 AC_SUBST(localedir)
  90
  91 if test x"$USE_NLS" = xyes; then
  92    CONFIG_ALL="$CONFIG_ALL all-po"
  93    CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
  94    CONFIG_INSTALL="$CONFIG_INSTALL install-po"
  95    CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
  96 fi
  97
  98 GNULIB=build-gnulib/import
  99
 100 # For Makefile dependencies.
 101 GNULIB_STDINT_H=
 102 if test x"$STDINT_H" != x; then
 103   GNULIB_STDINT_H=$GNULIB/$STDINT_H
 104 fi
 105 AC_SUBST(GNULIB_STDINT_H)
 106
 107 PACKAGE=gdb
 108 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
 109 AC_SUBST(PACKAGE)
 110
 111 # We never need to detect it in this sub-configure.
 112 # But preserve it for config.status --recheck.
 113 AC_ARG_VAR(MAKEINFO,
 114   [Parent configure detects if it is of sufficient version.])
 115 AC_ARG_VAR(MAKEINFOFLAGS,
 116   [Parameters for MAKEINFO.])
 117
 118 MAKEINFO_EXTRA_FLAGS=""
 119 AC_CACHE_CHECK([whether $MAKEINFO supports @click], gdb_cv_have_makeinfo_click,
 120   [echo '@clicksequence{a @click{} b}' >conftest.texinfo
 121   if eval "$MAKEINFO conftest.texinfo >&5 2>&5"; then
 122     gdb_cv_have_makeinfo_click=yes
 123   else
 124     gdb_cv_have_makeinfo_click=no
 125   fi])
 126 if test x"$gdb_cv_have_makeinfo_click" = xyes; then
 127   MAKEINFO_EXTRA_FLAGS="$MAKEINFO_EXTRA_FLAGS -DHAVE_MAKEINFO_CLICK"
 128 fi
 129 AC_SUBST(MAKEINFO_EXTRA_FLAGS)
 130
 131 GDB_AC_WITH_DIR(DEBUGDIR, separate-debug-dir,
 132     [look for global separate debug info in this path @<:@LIBDIR/debug@:>@],
 133     [${libdir}/debug])
 134
 135 # We can't pass paths as command line arguments.
 136 # Mingw32 tries to be clever and will convert the paths for us.
 137 # For example -DBINDIR="/usr/local/bin" passed on the command line may get
 138 # converted to -DBINDIR="E:/msys/mingw32/msys/1.0/local/bin".
 139 # This breaks GDB's relocatable path conversions since paths passed in
 140 # config.h would not get so translated, the path prefixes no longer match.
 141 AC_DEFINE_DIR(BINDIR, bindir, [Directory of programs.])
 142
 143 # GDB's datadir relocation
 144
 145 GDB_AC_WITH_DIR(GDB_DATADIR, gdb-datadir,
 146     [look for global separate data files in this path @<:@DATADIR/gdb@:>@],
 147     [${datadir}/gdb])
 148
 149 AC_ARG_WITH(relocated-sources,
 150 AS_HELP_STRING([--with-relocated-sources=PATH], [automatically relocate this path for source files]),
 151 [reloc_srcdir="${withval}"
 152  AC_DEFINE_DIR(RELOC_SRCDIR, reloc_srcdir,
 153               [Relocated directory for source files. ])
 154 ])
 155
 156 AC_MSG_CHECKING([for default auto-load directory])
 157 AC_ARG_WITH(auto-load-dir,
 158 AS_HELP_STRING([--with-auto-load-dir=PATH],
 159   [directories from which to load auto-loaded scripts @<:@$debugdir:$datadir/auto-load@:>@]),,
 160   [with_auto_load_dir='$debugdir:$datadir/auto-load'])
 161 escape_dir=`echo $with_auto_load_dir | sed 's/[[$]]\(datadir\|debugdir\)\>/\\\\\\\\\\\\&/g'`
 162 AC_DEFINE_DIR(AUTO_LOAD_DIR, escape_dir,
 163               [Directories from which to load auto-loaded scripts.])
 164 AC_MSG_RESULT([$with_auto_load_dir])
 165
 166 AC_MSG_CHECKING([for default auto-load safe-path])
 167 AC_ARG_WITH(auto-load-safe-path,
 168 AS_HELP_STRING([--with-auto-load-safe-path=PATH],
 169   [directories safe to hold auto-loaded files @<:@--with-auto-load-dir@:>@])
 170 AS_HELP_STRING([--without-auto-load-safe-path],
 171                [do not restrict auto-loaded files locations]),
 172     [if test "$with_auto_load_safe_path" = "no"; then
 173      with_auto_load_safe_path="/"
 174      fi],
 175 [with_auto_load_safe_path="$with_auto_load_dir"])
 176 escape_dir=`echo $with_auto_load_safe_path | sed 's/[[$]]\(datadir\|debugdir\)\>/\\\\\\\\\\\\&/g'`
 177 AC_DEFINE_DIR(AUTO_LOAD_SAFE_PATH, escape_dir,
 178               [Directories safe to hold auto-loaded files.])
 179 AC_MSG_RESULT([$with_auto_load_safe_path])
 180
 181 AC_CONFIG_SUBDIRS(testsuite)
 182
 183 # Check whether to support alternative target configurations
 184 AC_ARG_ENABLE(targets,
 185 AS_HELP_STRING([--enable-targets=TARGETS], [alternative target configurations]),
 186 [case "${enableval}" in
 187   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
 188             ;;
 189   no)       enable_targets= ;;
 190   *)        enable_targets=$enableval ;;
 191 esac])
 192
 193 # Check whether to enable 64-bit support on 32-bit hosts
 194 AC_ARG_ENABLE(64-bit-bfd,
 195 AS_HELP_STRING([--enable-64-bit-bfd], [64-bit support (on hosts with narrower word sizes)]),
 196 [case "${enableval}" in
 197   yes)  want64=true  ;;
 198   no)   want64=false ;;
 199   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
 200 esac],[want64=false])dnl
 201
 202 # Provide defaults for some variables set by the per-host and per-target
 203 # configuration.
 204 gdb_host_obs=posix-hdep.o
 205
 206 if test "${target}" = "${host}"; then
 207   gdb_native=yes
 208 else
 209   gdb_native=no
 210 fi
 211
 212 . $srcdir/configure.host
 213
 214 # Add in the common host objects.
 215 . $srcdir/common/common.host
 216 gdb_host_obs="$gdb_host_obs $common_host_obs"
 217
 218 # Accumulate some settings from configure.tgt over all enabled targets
 219
 220 TARGET_OBS=
 221 all_targets=
 222 HAVE_NATIVE_GCORE_TARGET=
 223
 224 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 225 do
 226   if test "$targ_alias" = "all"; then
 227     all_targets=true
 228   else
 229     # Canonicalize the secondary target names.
 230     result=`$ac_config_sub $targ_alias 2>/dev/null`
 231     if test -n "$result"; then
 232         targ=$result
 233     else
 234         targ=$targ_alias
 235     fi
 236
 237     . ${srcdir}/configure.tgt
 238
 239     AS_IF([test -z "${gdb_target_obs}"],
 240       [AC_MSG_ERROR([configuration ${targ} is unsupported.])])
 241
 242     # Target-specific object files
 243     for i in ${gdb_target_obs}; do
 244         case " $TARGET_OBS " in
 245         *" ${i} "*) ;;
 246         *)
 247           TARGET_OBS="$TARGET_OBS ${i}"
 248           ;;
 249         esac
 250     done
 251
 252     # Check whether this target needs 64-bit CORE_ADDR
 253     if test x${want64} = xfalse; then
 254       . ${srcdir}/../bfd/config.bfd
 255     fi
 256
 257     # Check whether this target is native and supports gcore.
 258     if test $gdb_native = yes -a "$targ_alias" = "$target_alias" \
 259        && $gdb_have_gcore; then
 260       HAVE_NATIVE_GCORE_TARGET=1
 261     fi
 262   fi
 263 done
 264
 265 if test x${all_targets} = xtrue; then
 266
 267   # We want all 64-bit targets if we either:
 268   #  - run on a 64-bit host  or
 269   #  - already require 64-bit support for some other target  or
 270   #  - the --enable-64-bit-bfd option was supplied
 271   # Otherwise we only support all 32-bit targets.
 272   #
 273   # NOTE: This test must be in sync with the corresponding
 274   #       tests in BFD!
 275
 276   if test x${want64} = xfalse; then
 277     AC_CHECK_SIZEOF(long)
 278     if test "x${ac_cv_sizeof_long}" = "x8"; then
 279       want64=true
 280     fi
 281   fi
 282   if test x${want64} = xtrue; then
 283     TARGET_OBS='$(ALL_TARGET_OBS) $(ALL_64_TARGET_OBS)'
 284   else
 285     TARGET_OBS='$(ALL_TARGET_OBS)'
 286   fi
 287 fi
 288
 289 AC_SUBST(TARGET_OBS)
 290 AC_SUBST(HAVE_NATIVE_GCORE_TARGET)
 291
 292 # For other settings, only the main target counts.
 293 gdb_sim=
 294 gdb_osabi=
 295 build_gdbserver=
 296 targ=$target; . ${srcdir}/configure.tgt
 297
 298 # Fetch the default architecture and default target vector from BFD.
 299 targ=$target; . $srcdir/../bfd/config.bfd
 300
 301 # We only want the first architecture, so strip off the others if
 302 # there is more than one.
 303 targ_archs=`echo $targ_archs | sed 's/ .*//'`
 304
 305 if test "x$targ_archs" != x; then
 306   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
 307     [Define to BFD's default architecture. ])
 308 fi
 309 if test "x$targ_defvec" != x; then
 310   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
 311     [Define to BFD's default target vector. ])
 312 fi
 313
 314 # The CLI cannot be disabled yet, but may be in the future.
 315
 316 # Enable CLI.
 317 AC_ARG_ENABLE(gdbcli,
 318 AS_HELP_STRING([--disable-gdbcli], [disable command-line interface (CLI)]),
 319   [case $enableval in
 320     yes)
 321       ;;
 322     no)
 323       AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;;
 324     *)
 325       AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;;
 326   esac],
 327   [enable_gdbcli=yes])
 328 if test x"$enable_gdbcli" = xyes; then
 329   if test -d $srcdir/cli; then
 330     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)"
 331     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)"
 332     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)"
 333     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)"
 334   fi
 335 fi
 336
 337 # Enable MI.
 338 AC_ARG_ENABLE(gdbmi,
 339 AS_HELP_STRING([--disable-gdbmi], [disable machine-interface (MI)]),
 340   [case $enableval in
 341     yes | no)
 342       ;;
 343     *)
 344       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 345   esac],
 346   [enable_gdbmi=yes])
 347 if test x"$enable_gdbmi" = xyes; then
 348   if test -d $srcdir/mi; then
 349     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 350     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 351     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 352     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 353   fi
 354 fi
 355
 356 # Enable TUI.
 357 AC_ARG_ENABLE(tui,
 358 AS_HELP_STRING([--enable-tui], [enable full-screen terminal user interface (TUI)]),
 359   [case $enableval in
 360     yes | no | auto)
 361       ;;
 362     *)
 363       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 364   esac],enable_tui=auto)
 365
 366 # Enable gdbtk.
 367 AC_ARG_ENABLE(gdbtk,
 368 AS_HELP_STRING([--enable-gdbtk], [enable gdbtk graphical user interface (GUI)]),
 369   [case $enableval in
 370     yes | no)
 371       ;;
 372     *)
 373       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 374   esac],
 375   [if test -d $srcdir/gdbtk; then
 376     enable_gdbtk=yes
 377   else
 378     enable_gdbtk=no
 379   fi])
 380 # We unconditionally disable gdbtk tests on selected platforms.
 381 case $host_os in
 382   go32* | windows*)
 383     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 384     enable_gdbtk=no ;;
 385 esac
 386
 387 # Libunwind support for ia64.
 388
 389 AC_ARG_WITH(libunwind-ia64,
 390 AS_HELP_STRING([--with-libunwind-ia64],
 391                [use libunwind frame unwinding for ia64 targets]),,
 392             [with_libunwind_ia64=auto])
 393
 394 # Backward compatibility option.
 395 if test "${with_libunwind+set}" = set; then
 396   if test x"$with_libunwind_ia64" != xauto; then
 397     AC_MSG_ERROR(
 398       [option --with-libunwind is deprecated, use --with-libunwind-ia64])
 399   fi
 400   AC_MSG_WARN([option --with-libunwind is deprecated, use --with-libunwind-ia64])
 401   with_libunwind_ia64="$with_libunwind"
 402 fi
 403
 404 case "$with_libunwind_ia64" in
 405   yes | no)
 406     ;;
 407   auto)
 408     AC_CHECK_HEADERS(libunwind-ia64.h)
 409     with_libunwind_ia64=$ac_cv_header_libunwind_ia64_h
 410     ;;
 411   *)
 412     AC_MSG_ERROR(
 413       [bad value $with_libunwind_ia64 for GDB --with-libunwind-ia64 option])
 414     ;;
 415 esac
 416
 417 if test x"$with_libunwind_ia64" = xyes; then
 418   AC_CHECK_HEADERS(libunwind-ia64.h)
 419   if test x"$ac_cv_header_libunwind_ia64_h" != xyes; then
 420     AC_MSG_ERROR([GDB option --with-libunwind-ia64 requires libunwind-ia64.h])
 421   fi
 422   CONFIG_OBS="$CONFIG_OBS ia64-libunwind-tdep.o"
 423   CONFIG_DEPS="$CONFIG_DEPS ia64-libunwind-tdep.o"
 424   CONFIG_SRCS="$CONFIG_SRCS ia64-libunwind-tdep.c"
 425 fi
 426
 427 opt_curses=no
 428 AC_ARG_WITH(curses, AS_HELP_STRING([--with-curses], [use the curses library instead of the termcap library]), opt_curses=$withval)
 429
 430 prefer_curses=no
 431 if test "$opt_curses" = "yes"; then
 432   prefer_curses=yes
 433 fi
 434
 435 # Profiling support.
 436 AC_ARG_ENABLE(profiling,
 437 AS_HELP_STRING([--enable-profiling], [enable profiling of GDB]),
 438   [case $enableval in
 439     yes | no)
 440       ;;
 441     *)
 442       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 443   esac],
 444  [enable_profiling=no])
 445
 446 AC_CHECK_FUNCS(monstartup _mcleanup)
 447 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 448 [AC_TRY_LINK(
 449 [#include <stdlib.h>
 450 extern char _etext;
 451 ],
 452 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 453 if test $ac_cv_var__etext = yes; then
 454   AC_DEFINE(HAVE__ETEXT, 1,
 455             [Define to 1 if your system has the _etext variable. ])
 456 fi
 457 AC_CACHE_CHECK([for etext], ac_cv_var_etext,
 458 [AC_TRY_LINK(
 459 [#include <stdlib.h>
 460 extern char etext;
 461 ],
 462 [free (&etext);], ac_cv_var_etext=yes, ac_cv_var_etext=no)])
 463 if test $ac_cv_var_etext = yes; then
 464   AC_DEFINE(HAVE_ETEXT, 1,
 465             [Define to 1 if your system has the etext variable. ])
 466 fi
 467 if test "$enable_profiling" = yes ; then
 468   if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
 469     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 470   fi
 471   PROFILE_CFLAGS=-pg
 472   OLD_CFLAGS="$CFLAGS"
 473   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 474
 475   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 476     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 477      ac_cv_cc_supports_pg=no)])
 478
 479   if test $ac_cv_cc_supports_pg = no; then
 480     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 481   fi
 482
 483   CFLAGS="$OLD_CFLAGS"
 484 fi
 485
 486 ACX_PKGVERSION([GDB])
 487 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 488 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 489 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 490
 491 # --------------------- #
 492 # Checks for programs.  #
 493 # --------------------- #
 494
 495 AC_PROG_AWK
 496 AC_PROG_INSTALL
 497 AC_PROG_LN_S
 498 AC_PROG_RANLIB
 499 AC_PROG_YACC
 500
 501 AC_CHECK_TOOL(AR, ar)
 502 AC_CHECK_TOOL(DLLTOOL, dlltool)
 503 AC_CHECK_TOOL(WINDRES, windres)
 504
 505 case $host_os in
 506   gnu*)
 507     # Needed for GNU Hurd hosts.
 508     AC_CHECK_TOOL(MIG, mig)
 509     if test x"$MIG" = x; then
 510       AC_MSG_ERROR([MIG not found but required for $host hosts])
 511     fi
 512     ;;
 513 esac
 514
 515 # ---------------------- #
 516 # Checks for libraries.  #
 517 # ---------------------- #
 518
 519 # We might need to link with -lm; most simulators need it.
 520 AC_CHECK_LIB(m, main)
 521
 522 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 523 AC_SEARCH_LIBS(gethostbyname, nsl)
 524
 525 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 526 AC_SEARCH_LIBS(socketpair, socket)
 527
 528 # Link in zlib if we can.  This allows us to read compressed debug sections.
 529 AM_ZLIB
 530
 531 # On FreeBSD we may need libutil for kinfo_getvmmap (used by fbsd-nat.c).
 532 # On GNU/kFreeBSD systems, FreeBSD libutil is renamed to libutil-freebsd.
 533 AC_SEARCH_LIBS(kinfo_getvmmap, util util-freebsd,
 534   [AC_DEFINE(HAVE_KINFO_GETVMMAP, 1,
 535             [Define to 1 if your system has the kinfo_getvmmap function. ])])
 536
 537 AM_ICONV
 538
 539 # GDB may fork/exec the iconv program to get the list of supported character
 540 # sets.  Allow the user to specify where to find it.
 541 # There are several factors affecting the choice of option name:
 542 # - There is already --with-libiconv-prefix but we can't use it, it specifies
 543 #   the build-time location of libiconv files.
 544 # - The program we need to find is iconv, which comes with glibc.  The user
 545 #   doesn't necessarily have libiconv installed.  Therefore naming this
 546 #   --with-libiconv-foo feels wrong.
 547 # - We want the path to be relocatable, but GDB_AC_DEFINE_RELOCATABLE is
 548 #   defined to work on directories not files (though it really doesn't know
 549 #   the difference).
 550 # - Calling this --with-iconv-prefix is perceived to cause too much confusion
 551 #   with --with-libiconv-prefix.
 552 # Putting these together is why the option name is --with-iconv-bin.
 553
 554 AC_ARG_WITH(iconv-bin,
 555 AS_HELP_STRING([--with-iconv-bin=PATH], [specify where to find the iconv program]),
 556 [iconv_bin="${withval}"
 557  AC_DEFINE_UNQUOTED([ICONV_BIN], ["${iconv_bin}"],
 558                     [Path of directory of iconv program.])
 559  GDB_AC_DEFINE_RELOCATABLE(ICONV_BIN, iconv, ${iconv_bin})
 560 ])
 561
 562 # For the TUI, we need enhanced curses functionality.
 563 if test x"$enable_tui" != xno; then
 564   prefer_curses=yes
 565 fi
 566
 567 curses_found=no
 568 if test x"$prefer_curses" = xyes; then
 569   # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
 570   # curses library because the latter might not provide all the
 571   # functionality we need.  However, this leads to problems on systems
 572   # where the linker searches /usr/local/lib, but the compiler doesn't
 573   # search /usr/local/include, if ncurses is installed in /usr/local.  A
 574   # default installation of ncurses on alpha*-dec-osf* will lead to such
 575   # a situation.
 576   AC_SEARCH_LIBS(waddstr, [ncursesw ncurses cursesX curses])
 577
 578   if test "$ac_cv_search_waddstr" != no; then
 579     curses_found=yes
 580   fi
 581 fi
 582
 583 # Check whether we should enable the TUI, but only do so if we really
 584 # can.
 585 if test x"$enable_tui" != xno; then
 586   if test -d $srcdir/tui; then
 587     if test "$curses_found" != no; then
 588       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
 589       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
 590       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
 591       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
 592     else
 593       if test x"$enable_tui" = xyes; then
 594         AC_MSG_ERROR([no enhanced curses library found; disable TUI])
 595       else
 596         AC_MSG_WARN([no enhanced curses library found; disabling TUI])
 597       fi
 598     fi
 599   fi
 600 fi
 601
 602 # Since GDB uses Readline, we need termcap functionality.  In many
 603 # cases this will be provided by the curses library, but some systems
 604 # have a separate termcap library, or no curses library at all.
 605
 606 case $host_os in
 607   cygwin*)
 608     if test -d $srcdir/libtermcap; then
 609       LIBS="../libtermcap/libtermcap.a $LIBS"
 610       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 611     fi ;;
 612   go32* | *djgpp*)
 613     ac_cv_search_tgetent="none required"
 614     ;;
 615 esac
 616
 617 # These are the libraries checked by Readline.
 618 AC_SEARCH_LIBS(tgetent, [termcap tinfo curses ncursesw ncurses])
 619
 620 if test "$ac_cv_search_tgetent" = no; then
 621   CONFIG_OBS="$CONFIG_OBS stub-termcap.o"
 622 fi
 623
 624 AC_ARG_WITH([system-readline],
 625   [AS_HELP_STRING([--with-system-readline],
 626                   [use installed readline library])])
 627
 628 if test "$with_system_readline" = yes; then
 629   READLINE=-lreadline
 630   READLINE_DEPS=
 631   READLINE_CFLAGS=
 632   READLINE_TEXI_INCFLAG=
 633 else
 634   READLINE='$(READLINE_DIR)/libreadline.a'
 635   READLINE_DEPS='$(READLINE)'
 636   READLINE_CFLAGS='-I$(READLINE_SRC)/..'
 637   READLINE_TEXI_INCFLAG='-I $(READLINE_DIR)'
 638 fi
 639 AC_SUBST(READLINE)
 640 AC_SUBST(READLINE_DEPS)
 641 AC_SUBST(READLINE_CFLAGS)
 642 AC_SUBST(READLINE_TEXI_INCFLAG)
 643
 644 # Generate jit-reader.h
 645
 646 # This is typedeffed to GDB_CORE_ADDR in jit-reader.h
 647 TARGET_PTR=
 648
 649 AC_CHECK_SIZEOF(unsigned long long)
 650 AC_CHECK_SIZEOF(unsigned long)
 651 AC_CHECK_SIZEOF(unsigned __int128)
 652
 653 if test "x${ac_cv_sizeof_unsigned_long}" = "x8"; then
 654   TARGET_PTR="unsigned long"
 655 elif test "x${ac_cv_sizeof_unsigned_long_long}" = "x8"; then
 656   TARGET_PTR="unsigned long long"
 657 elif test "x${ac_cv_sizeof_unsigned___int128}" = "x16"; then
 658   TARGET_PTR="unsigned __int128"
 659 else
 660   TARGET_PTR="unsigned long"
 661 fi
 662
 663 AC_SUBST(TARGET_PTR)
 664 AC_CONFIG_FILES([jit-reader.h:jit-reader.in])
 665
 666 AC_SEARCH_LIBS(dlopen, dl)
 667
 668 GDB_AC_WITH_DIR([JIT_READER_DIR], [jit-reader-dir],
 669                 [directory to load the JIT readers from],
 670                 [${libdir}/gdb])
 671
 672 AC_ARG_WITH(expat,
 673   AS_HELP_STRING([--with-expat], [include expat support (auto/yes/no)]),
 674   [], [with_expat=auto])
 675 AC_MSG_CHECKING([whether to use expat])
 676 AC_MSG_RESULT([$with_expat])
 677
 678 if test "${with_expat}" = no; then
 679   AC_MSG_WARN([expat support disabled; some features may be unavailable.])
 680   HAVE_LIBEXPAT=no
 681 else
 682   AC_LIB_HAVE_LINKFLAGS([expat], [], [#include "expat.h"],
 683                         [XML_Parser p = XML_ParserCreate (0);])
 684   if test "$HAVE_LIBEXPAT" != yes; then
 685     if test "$with_expat" = yes; then
 686       AC_MSG_ERROR([expat is missing or unusable])
 687     else
 688       AC_MSG_WARN([expat is missing or unusable; some features may be unavailable.])
 689     fi
 690   else
 691     save_LIBS=$LIBS
 692     LIBS="$LIBS $LIBEXPAT"
 693     AC_CHECK_FUNCS(XML_StopParser)
 694     LIBS=$save_LIBS
 695   fi
 696 fi
 697
 698 # --------------------- #
 699 # Check for libpython.  #
 700 # --------------------- #
 701
 702 dnl Utility to simplify finding libpython.
 703 dnl $1 = pythonX.Y
 704 dnl $2 = the shell variable to assign the result to
 705 dnl      If libpython is found we store $version here.
 706 dnl $3 = additional flags to add to CPPFLAGS
 707 dnl $4 = additional flags to add to LIBS
 708
 709 AC_DEFUN([AC_TRY_LIBPYTHON],
 710 [
 711   version=$1
 712   define([have_libpython_var],$2)
 713   new_CPPFLAGS=$3
 714   new_LIBS=$4
 715   AC_MSG_CHECKING([for ${version}])
 716   save_CPPFLAGS=$CPPFLAGS
 717   save_LIBS=$LIBS
 718   CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
 719   LIBS="$LIBS $new_LIBS"
 720   found_usable_python=no
 721   AC_LINK_IFELSE(AC_LANG_PROGRAM([[#include "Python.h"]],
 722                                  [[Py_Initialize ();]]),
 723                  [have_libpython_var=${version}
 724                   found_usable_python=yes
 725                   PYTHON_CPPFLAGS=$new_CPPFLAGS
 726                   PYTHON_LIBS=$new_LIBS])
 727   CPPFLAGS=$save_CPPFLAGS
 728   LIBS=$save_LIBS
 729   AC_MSG_RESULT([${found_usable_python}])
 730 ])
 731
 732 dnl There are several different values for --with-python:
 733 dnl
 734 dnl no -   Don't include python support.
 735 dnl yes -  Include python support, error if it's missing.
 736 dnl        If we find python in $PATH, use it to fetch configure options,
 737 dnl        otherwise assume the compiler can find it with no help from us.
 738 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 739 dnl auto - Same as "yes", but if python is missing from the system,
 740 dnl        fall back to "no".
 741 dnl /path/to/python/exec-prefix -
 742 dnl        Use the python located in this directory.
 743 dnl        If /path/to/python/exec-prefix/bin/python exists, use it to find
 744 dnl        the compilation parameters.  Otherwise use
 745 dnl        -I/path/to/python/exec-prefix/include,
 746 dnl        -L/path/to/python/exec-prefix/lib.
 747 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 748 dnl        NOTE: This case is historical.  It is what was done for 7.0/7.1
 749 dnl        but is deprecated.
 750 dnl /path/to/python/executable -
 751 dnl        Run python-config.py with this version of python to fetch the
 752 dnl        compilation parameters.
 753 dnl        NOTE: This needn't be the real python executable.
 754 dnl        In a cross-compilation scenario (build != host), this could be
 755 dnl        a shell script that provides what python-config.py provides for
 756 dnl        --ldflags, --includes, --exec-prefix.
 757 dnl python-executable -
 758 dnl        Find python-executable in $PATH, and then handle the same as
 759 dnl        /path/to/python/executable.
 760 dnl
 761 dnl If a python program is specified, it is used to run python-config.py and
 762 dnl is passed --ldflags, --includes, --exec-prefix.
 763
 764 AC_ARG_WITH(python,
 765   AS_HELP_STRING([--with-python@<:@=PYTHON@:>@], [include python support (auto/yes/no/<python-program>)]),
 766   [], [with_python=auto])
 767 AC_MSG_CHECKING([whether to use python])
 768 AC_MSG_RESULT([$with_python])
 769
 770 if test "${with_python}" = no; then
 771   AC_MSG_WARN([python support disabled; some features may be unavailable.])
 772   have_libpython=no
 773 else
 774   case "${with_python}" in
 775   [[\\/]]* | ?:[[\\/]]*)
 776     if test -d ${with_python}; then
 777       # Assume the python binary is ${with_python}/bin/python.
 778       python_prog="${with_python}/bin/python"
 779       python_prefix=
 780       # If python does not exit ${with_python}/bin, then try in
 781       # ${with_python}.  On Windows/MinGW, this is where the Python
 782       # executable is.
 783       if test ! -x "${python_prog}"; then
 784         python_prog="${with_python}/python"
 785         python_prefix=
 786       fi
 787       if test ! -x "${python_prog}"; then
 788         # Fall back to gdb 7.0/7.1 behaviour.
 789         python_prog=missing
 790         python_prefix=${with_python}
 791       fi
 792     elif test -x "${with_python}"; then
 793       # While we can't run python compiled for $host (unless host == build),
 794       # the user could write a script that provides the needed information,
 795       # so we support that.
 796       python_prog=${with_python}
 797       python_prefix=
 798     else
 799       AC_ERROR(invalid value for --with-python)
 800     fi
 801     ;;
 802   */*)
 803     # Disallow --with-python=foo/bar.
 804     AC_ERROR(invalid value for --with-python)
 805     ;;
 806   *)
 807     # The user has either specified auto, yes, or the name of the python
 808     # program assumed to be in $PATH.
 809     python_prefix=
 810     case "${with_python}" in
 811     yes | auto)
 812       if test ${build} = ${host}; then
 813         AC_PATH_PROG(python_prog_path, python, missing)
 814         if test "${python_prog_path}" = missing; then
 815           python_prog=missing
 816         else
 817           python_prog=${python_prog_path}
 818         fi
 819       else
 820         # Not much we can do except assume the cross-compiler will find the
 821         # right files.
 822         python_prog=missing
 823       fi
 824       ;;
 825     *)
 826       # While we can't run python compiled for $host (unless host == build),
 827       # the user could write a script that provides the needed information,
 828       # so we support that.
 829       python_prog="${with_python}"
 830       AC_PATH_PROG(python_prog_path, ${python_prog}, missing)
 831       if test "${python_prog_path}" = missing; then
 832         AC_ERROR(unable to find python program ${python_prog})
 833       fi
 834       ;;
 835     esac
 836   esac
 837
 838   if test "${python_prog}" != missing; then
 839     # We have a python program to use, but it may be too old.
 840     # Don't flag an error for --with-python=auto (the default).
 841     have_python_config=yes
 842     python_includes=`${python_prog} ${srcdir}/python/python-config.py --includes`
 843     if test $? != 0; then
 844       have_python_config=failed
 845       if test "${with_python}" != auto; then
 846         AC_ERROR(failure running python-config --includes)
 847       fi
 848     fi
 849     python_libs=`${python_prog} ${srcdir}/python/python-config.py --ldflags`
 850     if test $? != 0; then
 851       have_python_config=failed
 852       if test "${with_python}" != auto; then
 853         AC_ERROR(failure running python-config --ldflags)
 854       fi
 855     fi
 856     python_prefix=`${python_prog} ${srcdir}/python/python-config.py --exec-prefix`
 857     if test $? != 0; then
 858       have_python_config=failed
 859       if test "${with_python}" != auto; then
 860         AC_ERROR(failure running python-config --exec-prefix)
 861       fi
 862     fi
 863   else
 864     # We do not have a python executable we can use to determine where
 865     # to find the Python headers and libs.  We cannot guess the include
 866     # path from the python_prefix either, because that include path
 867     # depends on the Python version.  So, there is nothing much we can
 868     # do except assume that the compiler will be able to find those files.
 869     python_includes=
 870     python_libs=
 871     have_python_config=no
 872   fi
 873
 874   # If we have python-config, only try the configuration it provides.
 875   # Otherwise fallback on the old way of trying different versions of
 876   # python in turn.
 877
 878   have_libpython=no
 879   if test "${have_python_config}" = yes; then
 880     # Determine the Python version by extracting "-lpython<version>"
 881     # part of the python_libs. <version> is usually X.Y with X and Y
 882     # being decimal numbers, but can also be XY (seen on Windows).
 883     #
 884     # The extraction is performed using sed with a regular expression.
 885     # Initially, the regexp used was using the '?' quantifier to make
 886     # the dot in the version number optional.  Unfortunately, this
 887     # does not work with non-GNU versions of sed because, because of
 888     # what looks like a limitation (the '?' quantifier does not work
 889     # with back-references).  We work around this limitation by using
 890     # the '*' quantifier instead.  It means that, in theory, we might
 891     # match unexpected version strings such as "-lpython2..7", but
 892     # this seems unlikely in practice.  And even if that happens,
 893     # an error will be triggered later on, when checking that version
 894     # number.
 895     python_version=`echo " ${python_libs} " \
 896                          | sed -e 's,^.* -l\(python[[0-9]]*[[.]]*[[0-9]]*\).*$,\1,'`
 897     case "${python_version}" in
 898     python*)
 899       AC_TRY_LIBPYTHON(${python_version}, have_libpython,
 900                        ${python_includes}, ${python_libs})
 901       ;;
 902     *)
 903       AC_MSG_ERROR([unable to determine python version from ${python_libs}])
 904       ;;
 905     esac
 906   elif test "${have_python_config}" != failed; then
 907     if test "${have_libpython}" = no; then
 908       AC_TRY_LIBPYTHON(python2.7, have_libpython,
 909                        ${python_includes}, "${python_libs} -lpython2.7")
 910     fi
 911     if test "${have_libpython}" = no; then
 912       AC_TRY_LIBPYTHON(python2.6, have_libpython,
 913                        ${python_includes}, "${python_libs} -lpython2.6")
 914     fi
 915     if test ${have_libpython} = no; then
 916       AC_TRY_LIBPYTHON(python2.5, have_libpython,
 917                        ${python_includes}, "${python_libs} -lpython2.5")
 918     fi
 919     if test ${have_libpython} = no; then
 920       AC_TRY_LIBPYTHON(python2.4, have_libpython,
 921                        ${python_includes}, "${python_libs} -lpython2.4")
 922     fi
 923   fi
 924   if test "${have_libpython}" = python2.7 -o "${have_libpython}" = python27; then
 925     AC_DEFINE(HAVE_LIBPYTHON2_7, 1, [Define if Python 2.7 is being used.])
 926   elif test "${have_libpython}" = python2.6 -o "${have_libpython}" = python26; then
 927     AC_DEFINE(HAVE_LIBPYTHON2_6, 1, [Define if Python 2.6 is being used.])
 928   elif test "${have_libpython}" = python2.5 -o "${have_libpython}" = python25; then
 929     AC_DEFINE(HAVE_LIBPYTHON2_5, 1, [Define if Python 2.5 is being used.])
 930   elif test "${have_libpython}" = python2.4 -o "${have_libpython}" = python24; then
 931     AC_DEFINE(HAVE_LIBPYTHON2_4, 1, [Define if Python 2.4 is being used.])
 932   fi
 933
 934   if test "${have_libpython}" = no; then
 935     case "${with_python}" in
 936     yes)
 937       AC_MSG_ERROR([python is missing or unusable])
 938       ;;
 939     auto)
 940       AC_MSG_WARN([python is missing or unusable; some features may be unavailable.])
 941       ;;
 942     *)
 943       AC_MSG_ERROR([no usable python found at ${with_python}])
 944       ;;
 945     esac
 946   else
 947     if test -n "${python_prefix}"; then
 948       AC_DEFINE_UNQUOTED(WITH_PYTHON_PATH, "${python_prefix}",
 949                          [Define if --with-python provides a path, either directly or via python-config.py --exec-prefix.])
 950       GDB_AC_DEFINE_RELOCATABLE(PYTHON_PATH, python, ${python_prefix})
 951     fi
 952   fi
 953 fi
 954
 955 if test "${have_libpython}" != no; then
 956   AC_DEFINE(HAVE_PYTHON, 1, [Define if Python interpreter is being linked in.])
 957   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_PYTHON_OBS)"
 958   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_PYTHON_DEPS)"
 959   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_PYTHON_SRCS)"
 960   CONFIG_INSTALL="$CONFIG_INSTALL install-python"
 961   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_PYTHON_CFLAGS)"
 962
 963   # Flags needed to compile Python code (taken from python-config --cflags).
 964   # We cannot call python-config directly because it will output whatever was
 965   # used when compiling the Python interpreter itself, including flags which
 966   # would make the python-related objects be compiled differently from the
 967   # rest of GDB (e.g., -O2 and -fPIC).
 968   if test "${GCC}" = yes; then
 969     tentative_python_cflags="-fno-strict-aliasing -DNDEBUG -fwrapv"
 970   fi
 971
 972   if test "x${tentative_python_cflags}" != x; then
 973     AC_MSG_CHECKING(compiler flags for python code)
 974     for flag in ${tentative_python_cflags}; do
 975       # Check that the compiler accepts it
 976       saved_CFLAGS="$CFLAGS"
 977       CFLAGS="$CFLAGS $flag"
 978       AC_TRY_COMPILE([],[],PYTHON_CFLAGS="${PYTHON_CFLAGS} $flag",)
 979       CFLAGS="$saved_CFLAGS"
 980     done
 981     AC_MSG_RESULT(${PYTHON_CFLAGS})
 982   fi
 983
 984   # On x64 Windows, Python's include headers, and pyconfig.h in
 985   # particular, rely on MS_WIN64 macro to detect that it's a 64bit
 986   # version of Windows.  Unfortunately, MS_WIN64 is only defined if
 987   # _MSC_VER, a Microsoft-specific macro, is defined.  So, when
 988   # building on x64 Windows with GCC, we define MS_WIN64 ourselves.
 989   # The issue was reported to the Python community, but still isn't
 990   # solved as of 2012-10-02 (http://bugs.python.org/issue4709).
 991
 992   case "$gdb_host" in
 993     mingw64)
 994            if test "${GCC}" = yes; then
 995              CPPFLAGS="$CPPFLAGS -DMS_WIN64"
 996            fi
 997            ;;
 998   esac
 999
1000   # Note that "python -m threading" cannot be used to check for
1001   # threading support due to a bug in Python 2.7.3
1002   # (http://bugs.python.org/issue15567).
1003   AC_MSG_CHECKING(whether python supports threads)
1004   saved_CPPFLAGS="${CPPFLAGS}"
1005   CPPFLAGS="${PYTHON_CPPFLAGS}"
1006   # Note that the test is reversed so that python_has_threads=yes on
1007   # unexpected failures.
1008   AC_PREPROC_IFELSE(AC_LANG_SOURCE([[
1009 #include <Python.h>
1010 #ifdef WITH_THREAD
1011 # error
1012 #endif
1013   ]]), [python_has_threads=no], [python_has_threads=yes])
1014   AC_MSG_RESULT(${python_has_threads})
1015   CPPFLAGS="${saved_CPPFLAGS}"
1016 else
1017   # Even if Python support is not compiled in, we need to have this file
1018   # included so that the "python" command, et.al., still exists.
1019   CONFIG_OBS="$CONFIG_OBS python.o"
1020   CONFIG_SRCS="$CONFIG_SRCS python/python.c"
1021 fi
1022
1023 # Work around Python http://bugs.python.org/issue10112.  See also
1024 # http://bugs.python.org/issue11410, otherwise -Wl,--dynamic-list has
1025 # no effect.  Note that the only test after this that uses Python is
1026 # the -rdynamic/-Wl,--dynamic-list test, and we do want that one to be
1027 # run without -export-dynamic too.
1028 PYTHON_LIBS=`echo $PYTHON_LIBS | sed -e 's/-Xlinker -export-dynamic//'`
1029
1030 AC_SUBST(PYTHON_CFLAGS)
1031 AC_SUBST(PYTHON_CPPFLAGS)
1032 AC_SUBST(PYTHON_LIBS)
1033 AM_CONDITIONAL(HAVE_PYTHON, test "${have_libpython}" != no)
1034
1035 # -------------------- #
1036 # Check for libguile.  #
1037 # -------------------- #
1038
1039 dnl Utility to simplify finding libguile.
1040 dnl $1 = pkg-config-program
1041 dnl $2 = space-separate list of guile versions to try
1042 dnl $3 = yes|no, indicating whether to flag errors or ignore them
1043 dnl $4 = the shell variable to assign the result to
1044 dnl      If libguile is found we store "yes" here.
1045
1046 AC_DEFUN([AC_TRY_LIBGUILE],
1047 [
1048   pkg_config=$1
1049   guile_version_list=$2
1050   flag_errors=$3
1051   define([have_libguile_var],$4)
1052   found_usable_guile=checking
1053   AC_MSG_CHECKING([for usable guile from ${pkg_config}])
1054   for guile_version in ${guile_version_list}; do
1055     ${pkg_config} --exists ${guile_version} 2>/dev/null
1056     if test $? != 0; then
1057       continue
1058     fi
1059     dnl pkg-config says the package exists, so if we get an error now,
1060     dnl that's bad.
1061     new_CPPFLAGS=`${pkg_config} --cflags ${guile_version}`
1062     if test $? != 0; then
1063       AC_MSG_ERROR([failure running pkg-config --cflags ${guile_version}])
1064     fi
1065     new_LIBS=`${pkg_config} --libs ${guile_version}`
1066     if test $? != 0; then
1067       AC_MSG_ERROR([failure running pkg-config --libs ${guile_version}])
1068     fi
1069     dnl If we get this far, great.
1070     found_usable_guile=${guile_version}
1071     break
1072   done
1073   if test "${found_usable_guile}" = "checking"; then
1074     if test "${flag_errors}" = "yes"; then
1075       AC_MSG_ERROR([unable to find usable guile version from "${guile_version_list}"])
1076     else
1077       found_usable_guile=no
1078     fi
1079   fi
1080   dnl One final sanity check.
1081   dnl The user could have said --with-guile=python-2.7.
1082   if test "${found_usable_guile}" != no; then
1083     save_CPPFLAGS=$CPPFLAGS
1084     save_LIBS=$LIBS
1085     CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
1086     LIBS="$LIBS $new_LIBS"
1087     AC_LINK_IFELSE(AC_LANG_PROGRAM([[#include "libguile.h"]],
1088                                    [[scm_init_guile ();]]),
1089                    [have_libguile_var=yes
1090                     GUILE_CPPFLAGS=$new_CPPFLAGS
1091                     GUILE_LIBS=$new_LIBS],
1092                    [found_usable_guile=no])
1093     dnl scm_set_automatic_finalization_enabled added in Guile 2.2.
1094     AC_CHECK_FUNC(scm_set_automatic_finalization_enabled,
1095       AC_DEFINE(HAVE_GUILE_MANUAL_FINALIZATION, 1,
1096                 [Define if Guile supports manual finalization.])
1097     )
1098     CPPFLAGS=$save_CPPFLAGS
1099     LIBS=$save_LIBS
1100     if test "${found_usable_guile}" = no; then
1101       if test "${flag_errors}" = yes; then
1102         AC_MSG_FAILURE([linking guile version ${guile_version} test program failed])
1103       fi
1104     fi
1105   fi
1106   AC_MSG_RESULT([${found_usable_guile}])
1107 ])
1108
1109 dnl There are several different values for --with-guile:
1110 dnl
1111 dnl no -   Don't include guile support.
1112 dnl yes -  Include guile support, error if it's missing.
1113 dnl        The pkg-config program must be in $PATH.
1114 dnl auto - Same as "yes", but if guile is missing from the system,
1115 dnl        fall back to "no".
1116 dnl guile-version [guile-version-choice-2 ...] -
1117 dnl        A space-separated list of guile package versions to try.
1118 dnl        These are passed to pkg-config as-is.
1119 dnl        E.g., guile-2.0 or guile-2.2-uninstalled
1120 dnl        This requires making sure PKG_CONFIG_PATH is set appropriately.
1121 dnl /path/to/pkg-config -
1122 dnl        Use this pkg-config program.
1123 dnl        NOTE: This needn't be the "real" pkg-config program.
1124 dnl        It could be a shell script.  It is invoked as:
1125 dnl        pkg-config --exists $version
1126 dnl        pkg-config --cflags $version
1127 dnl        pkg-config --libs $version
1128 dnl        pkg-config --variable guild $version
1129 dnl        The script will be called with $version having each value in
1130 dnl        $try_guile_versions until --exists indicates success.
1131
1132 AC_ARG_WITH(guile,
1133   AS_HELP_STRING([--with-guile@<:@=GUILE@:>@], [include guile support (auto/yes/no/<guile-version>/<pkg-config-program>)]),
1134   [], [with_guile=auto])
1135 AC_MSG_CHECKING([whether to use guile])
1136 AC_MSG_RESULT([$with_guile])
1137
1138 dnl We check guile with pkg-config.
1139 AC_PATH_PROG(pkg_config_prog_path, pkg-config, missing)
1140
1141 try_guile_versions="guile-2.0"
1142 have_libguile=no
1143 case "${with_guile}" in
1144 no)
1145   AC_MSG_WARN([guile support disabled; some features will be unavailable.])
1146   ;;
1147 auto)
1148   if test "${pkg_config_prog_path}" = "missing"; then
1149     AC_MSG_WARN([pkg-config not found, guile support disabled])
1150   else
1151     AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${try_guile_versions}, no, have_libguile)
1152   fi
1153   ;;
1154 yes)
1155   if test "${pkg_config_prog_path}" = "missing"; then
1156     AC_MSG_ERROR([pkg-config not found])
1157   fi
1158   AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${try_guile_versions}, yes, have_libguile)
1159   ;;
1160 [[\\/]]* | ?:[[\\/]]*)
1161   if test -x "${with_guile}"; then
1162     AC_TRY_LIBGUILE(${with_guile}, ${try_guile_versions}, yes, have_libguile)
1163   else
1164     AC_MSG_ERROR([Guile config program not executable: ${with_guile}])
1165   fi
1166   ;;
1167 "" | */*)
1168   # Disallow --with=guile="" and --with-guile=foo/bar.
1169   AC_MSG_ERROR([invalid value for --with-guile])
1170   ;;
1171 *)
1172   # A space separate list of guile versions to try, in order.
1173   if test "${pkg_config_prog_path}" = "missing"; then
1174     AC_MSG_ERROR([pkg-config not found])
1175   fi
1176   AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${with_guile}, yes, have_libguile)
1177   ;;
1178 esac
1179
1180 if test "${have_libguile}" != no; then
1181   dnl Get the name of the 'guild' program.
1182   case "${with_guile}" in
1183   [[\\/]]* | ?:[[\\/]]*)
1184     GDB_GUILE_PROGRAM_NAMES(["${with_guile}"], ["${guile_version}"])
1185     ;;
1186   *)
1187     GDB_GUILE_PROGRAM_NAMES(["${pkg_config_prog_path}"], ["${guile_version}"])
1188     ;;
1189   esac
1190
1191   dnl Make sure guild can handle this host.
1192   GDB_TRY_GUILD([$srcdir/guile/lib/gdb/support.scm])
1193   dnl If not, disable guile support.
1194   if test "$ac_cv_guild_ok" = no; then
1195     have_libguile=no
1196     AC_MSG_WARN(disabling guile support, $GUILD fails compiling for $host)
1197   fi
1198 fi
1199
1200 if test "${have_libguile}" != no; then
1201   AC_DEFINE(HAVE_GUILE, 1, [Define if Guile interpreter is being linked in.])
1202   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_GUILE_OBS)"
1203   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_GUILE_DEPS)"
1204   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_GUILE_SRCS)"
1205   CONFIG_INSTALL="$CONFIG_INSTALL install-guile"
1206   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_GUILE_CFLAGS)"
1207
1208   dnl The 'scm_new_smob' function appeared in Guile 2.0.6.
1209   save_LIBS="$LIBS"
1210   save_CPPFLAGS="$CPPFLAGS"
1211   LIBS="$GUILE_LIBS"
1212   CPPFLAGS="$GUILE_CPPFLAGS"
1213   AC_CHECK_FUNCS([scm_new_smob])
1214   LIBS="$save_LIBS"
1215   CPPFLAGS="$save_CPPFLAGS"
1216 else
1217   # Even if Guile support is not compiled in, we need to have these files
1218   # included.
1219   CONFIG_OBS="$CONFIG_OBS guile.o"
1220   CONFIG_SRCS="$CONFIG_SRCS guile/guile.c"
1221 fi
1222 AC_SUBST(GUILE_CPPFLAGS)
1223 AC_SUBST(GUILE_LIBS)
1224 AM_CONDITIONAL(HAVE_GUILE, test "${have_libguile}" != no)
1225
1226 # --------------------- #
1227 # Check for libmcheck.  #
1228 # --------------------- #
1229
1230 # Enable -lmcheck by default (it provides cheap-enough memory mangling),
1231 # but turn it off if Python is enabled with threads, since -lmcheck is
1232 # not thread safe (http://sourceware.org/bugzilla/show_bug.cgi?id=9939),
1233 # and for releases.
1234 if test \( "${have_libpython}" = "no" -o "${python_has_threads}" = "no" \) \
1235    && $development; then
1236   libmcheck_default=yes
1237 else
1238   libmcheck_default=no
1239 fi
1240 GDB_AC_LIBMCHECK(${libmcheck_default})
1241
1242 if test "$ENABLE_LIBMCHECK" = "yes" \
1243         -a "${have_libpython}" != "no" \
1244         -a "${python_has_threads}" = "yes" ; then
1245   AC_MSG_WARN(--enable-libmcheck may lead to spurious crashes if threads are used in python)
1246 fi
1247
1248 AC_ARG_WITH(intel_pt,
1249   AS_HELP_STRING([--with-intel-pt], [include Intel Processor Trace support (auto/yes/no)]),
1250   [], [with_intel_pt=auto])
1251 AC_MSG_CHECKING([whether to use intel pt])
1252 AC_MSG_RESULT([$with_intel_pt])
1253
1254 if test "${with_intel_pt}" = no; then
1255   AC_MSG_WARN([Intel Processor Trace support disabled; some features may be unavailable.])
1256   HAVE_LIBIPT=no
1257 else
1258   AC_PREPROC_IFELSE(AC_LANG_SOURCE([[
1259 #include <linux/perf_event.h>
1260 #ifndef PERF_ATTR_SIZE_VER5
1261 # error
1262 #endif
1263   ]]), [perf_event=yes], [perf_event=no])
1264   if test "$perf_event" != yes; then
1265     if test "$with_intel_pt" = yes; then
1266       AC_MSG_ERROR([linux/perf_event.h missing or too old])
1267     else
1268       AC_MSG_WARN([linux/perf_event.h missing or too old; some features may be unavailable.])
1269     fi
1270   fi
1271
1272   AC_LIB_HAVE_LINKFLAGS([ipt], [], [#include "intel-pt.h"], [pt_insn_alloc_decoder (0);])
1273   if test "$HAVE_LIBIPT" != yes; then
1274     if test "$with_intel_pt" = yes; then
1275       AC_MSG_ERROR([libipt is missing or unusable])
1276     else
1277       AC_MSG_WARN([libipt is missing or unusable; some features may be unavailable.])
1278     fi
1279   else
1280     save_LIBS=$LIBS
1281     LIBS="$LIBS $LIBIPT"
1282     AC_CHECK_FUNCS(pt_insn_event)
1283     AC_CHECK_MEMBERS([struct pt_insn.enabled, struct pt_insn.resynced], [], [],
1284                      [#include <intel-pt.h>])
1285     LIBS=$save_LIBS
1286   fi
1287 fi
1288
1289 # ------------------------- #
1290 # Checks for header files.  #
1291 # ------------------------- #
1292
1293 AC_HEADER_STDC
1294 # elf_hp.h is for HP/UX 64-bit shared library support.
1295 AC_CHECK_HEADERS([nlist.h machine/reg.h poll.h sys/poll.h proc_service.h \
1296                   thread_db.h \
1297                   sys/fault.h \
1298                   sys/file.h sys/filio.h sys/ioctl.h sys/param.h \
1299                   sys/resource.h sys/procfs.h sys/ptrace.h ptrace.h \
1300                   sys/reg.h sys/debugreg.h sys/select.h sys/syscall.h \
1301                   termios.h elf_hp.h \
1302                   dlfcn.h])
1303 AC_CHECK_HEADERS(sys/proc.h, [], [],
1304 [#if HAVE_SYS_PARAM_H
1305 # include <sys/param.h>
1306 #endif
1307 ])
1308 AC_CHECK_HEADERS(sys/user.h, [], [],
1309 [#if HAVE_SYS_PARAM_H
1310 # include <sys/param.h>
1311 #endif
1312 ])
1313
1314 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncursesw/ncurses.h ncurses/ncurses.h ncurses/term.h)
1315 AC_CHECK_HEADERS(term.h, [], [],
1316 [#if HAVE_CURSES_H
1317 # include <curses.h>
1318 #endif
1319 ])
1320
1321 # ------------------------- #
1322 # Checks for declarations.  #
1323 # ------------------------- #
1324
1325 libiberty_INIT
1326
1327 AC_CHECK_DECLS([free, malloc, realloc, snprintf])
1328 AM_LC_MESSAGES
1329
1330 # ----------------------- #
1331 # Checks for structures.  #
1332 # ----------------------- #
1333
1334 AC_CHECK_MEMBERS([struct stat.st_blocks, struct stat.st_blksize])
1335
1336 # ------------------ #
1337 # Checks for types.  #
1338 # ------------------ #
1339
1340 AC_CHECK_TYPES(socklen_t, [], [],
1341 [#include <sys/types.h>
1342 #include <sys/socket.h>
1343 ])
1344
1345 # ------------------------------------- #
1346 # Checks for compiler characteristics.  #
1347 # ------------------------------------- #
1348
1349 AC_C_CONST
1350 AC_C_INLINE
1351 AC_C_BIGENDIAN
1352
1353 # ------------------------------ #
1354 # Checks for library functions.  #
1355 # ------------------------------ #
1356
1357 AC_FUNC_MMAP
1358 AC_FUNC_VFORK
1359 AC_CHECK_FUNCS([getauxval getrusage getuid getgid \
1360                 pipe poll pread pread64 pwrite resize_term \
1361                 sbrk setpgid setpgrp setsid \
1362                 sigaction sigprocmask sigsetmask socketpair \
1363                 ttrace wborder wresize setlocale iconvlist libiconvlist btowc \
1364                 setrlimit getrlimit posix_madvise waitpid \
1365                 ptrace64 sigaltstack mkdtemp setns])
1366 AM_LANGINFO_CODESET
1367 GDB_AC_COMMON
1368
1369 # Check the return and argument types of ptrace.
1370 GDB_AC_PTRACE
1371
1372 dnl AC_FUNC_SETPGRP does not work when cross compiling
1373 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
1374 if test "$cross_compiling" = no; then
1375   AC_FUNC_SETPGRP
1376 else
1377   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
1378     [AC_TRY_COMPILE([
1379 #include <unistd.h>
1380 ], [
1381   if (setpgrp(1,1) == -1)
1382     exit (0);
1383   else
1384     exit (1);
1385 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
1386 if test $ac_cv_func_setpgrp_void = yes; then
1387   AC_DEFINE(SETPGRP_VOID, 1)
1388 fi
1389 fi
1390
1391 # Assume we'll default to using the included libiberty regex.
1392 gdb_use_included_regex=yes
1393
1394 # However, if the system regex is GNU regex, then default to *not*
1395 # using the included regex.
1396 AC_CACHE_CHECK(
1397   [for GNU regex],
1398   [gdb_cv_have_gnu_regex],
1399   [AC_TRY_COMPILE(
1400     [#include <gnu-versions.h>],
1401     [#define REGEX_INTERFACE_VERSION 1
1402 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
1403 # error "Version mismatch"
1404 #endif],
1405     gdb_cv_have_gnu_regex=yes,
1406     gdb_cv_have_gnu_regex=no)])
1407 if test $gdb_cv_have_gnu_regex = yes; then
1408   gdb_use_included_regex=no
1409 fi
1410
1411 AC_ARG_WITH(included-regex,
1412   AS_HELP_STRING([--without-included-regex], [don't use included regex; this is the default on systems with version 2 of the GNU C library (use with caution on other system)]),
1413   gdb_with_regex=$withval,
1414   gdb_with_regex=$gdb_use_included_regex)
1415 if test "$gdb_with_regex" = yes; then
1416   AC_DEFINE(USE_INCLUDED_REGEX, 1,
1417     [Define to 1 if the regex included in libiberty should be used.])
1418 fi
1419
1420 # Check if <sys/proc.h> defines `struct thread' with a td_pcb member.
1421 AC_CHECK_MEMBERS([struct thread.td_pcb], [], [],
1422 [#include <sys/param.h>
1423 #include <sys/proc.h>
1424 ])
1425
1426 # See if <sys/lwp.h> defines `struct lwp`.
1427 AC_CACHE_CHECK([for struct lwp], gdb_cv_struct_lwp,
1428 [AC_TRY_COMPILE([#include <sys/param.h>
1429 #define _KMEMUSER
1430 #include <sys/lwp.h>], [struct lwp l;],
1431 gdb_cv_struct_lwp=yes, gdb_cv_struct_lwp=no)])
1432 if test $gdb_cv_struct_lwp = yes; then
1433   AC_DEFINE(HAVE_STRUCT_LWP, 1,
1434             [Define to 1 if your system has struct lwp.])
1435 fi
1436
1437 # See if <machine/reg.h> degines `struct reg'.
1438 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
1439 [AC_TRY_COMPILE([#include <sys/types.h>
1440 #include <machine/reg.h>], [struct reg r;],
1441 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
1442 if test $gdb_cv_struct_reg = yes; then
1443   AC_DEFINE(HAVE_STRUCT_REG, 1,
1444             [Define to 1 if your system has struct reg in <machine/reg.h>.])
1445 fi
1446
1447 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
1448 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
1449 AC_CHECK_MEMBERS([struct reg.r_fs, struct reg.r_gs], [], [],
1450                  [#include <sys/types.h>
1451 #include <machine/reg.h>])
1452
1453 # See if <sys/user.h> supports the %fs_base and %gs_bas amd64 segment registers.
1454 # Older amd64 Linux's don't have the fs_base and gs_base members of
1455 # `struct user_regs_struct'.
1456 AC_CHECK_MEMBERS([struct user_regs_struct.fs_base, struct user_regs_struct.gs_base],
1457                  [], [], [#include <sys/user.h>])
1458
1459 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
1460 AC_MSG_CHECKING(for PTRACE_GETREGS)
1461 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
1462 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1463                 [PTRACE_GETREGS;],
1464                 [gdb_cv_have_ptrace_getregs=yes],
1465                 [gdb_cv_have_ptrace_getregs=no])])
1466 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
1467 if test $gdb_cv_have_ptrace_getregs = yes; then
1468   AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
1469   [Define if sys/ptrace.h defines the PTRACE_GETREGS request.])
1470 fi
1471
1472 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
1473 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
1474 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
1475 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1476                 [PTRACE_GETFPXREGS;],
1477                 [gdb_cv_have_ptrace_getfpxregs=yes],
1478                 [gdb_cv_have_ptrace_getfpxregs=no])])
1479 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
1480 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
1481   AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
1482   [Define if sys/ptrace.h defines the PTRACE_GETFPXREGS request.])
1483 fi
1484
1485 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
1486 AC_MSG_CHECKING(for PT_GETDBREGS)
1487 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
1488 [AC_TRY_COMPILE([#include <sys/types.h>
1489 #include <sys/ptrace.h>],
1490                 [PT_GETDBREGS;],
1491                 [gdb_cv_have_pt_getdbregs=yes],
1492                 [gdb_cv_have_pt_getdbregs=no])])
1493 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
1494 if test $gdb_cv_have_pt_getdbregs = yes; then
1495   AC_DEFINE(HAVE_PT_GETDBREGS, 1,
1496   [Define if sys/ptrace.h defines the PT_GETDBREGS request.])
1497 fi
1498
1499 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
1500 AC_MSG_CHECKING(for PT_GETXMMREGS)
1501 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
1502 [AC_TRY_COMPILE([#include <sys/types.h>
1503 #include <sys/ptrace.h>],
1504                 [PT_GETXMMREGS;],
1505                 [gdb_cv_have_pt_getxmmregs=yes],
1506                 [gdb_cv_have_pt_getxmmregs=no])])
1507 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
1508 if test $gdb_cv_have_pt_getxmmregs = yes; then
1509   AC_DEFINE(HAVE_PT_GETXMMREGS, 1,
1510   [Define if sys/ptrace.h defines the PT_GETXMMREGS request.])
1511 fi
1512
1513 # See if <sys/ptrace.h> supports LWP names on FreeBSD
1514 # Older FreeBSD versions don't have the pl_tdname member of
1515 # `struct ptrace_lwpinfo'.
1516 AC_CHECK_MEMBERS([struct ptrace_lwpinfo.pl_tdname], [], [],
1517                  [#include <sys/ptrace.h>])
1518
1519 # See if <sys/ptrace.h> supports syscall fields on FreeBSD.  The
1520 # pl_syscall_code member of `struct ptrace_lwpinfo' was added in
1521 # FreeBSD 10.3.
1522 AC_CHECK_MEMBERS([struct ptrace_lwpinfo.pl_syscall_code], [], [],
1523                  [#include <sys/ptrace.h>])
1524
1525 # Detect which type of /proc is in use, such as for Solaris.
1526
1527 if test "${target}" = "${host}"; then
1528   case "${host}" in
1529   *-*-sysv4.2* | *-*-sysv5* )
1530       AC_DEFINE(NEW_PROC_API, 1,
1531       [Define if you want to use new multi-fd /proc interface.])
1532       ;;
1533   *-*-solaris2.[[6789]] | *-*-solaris2.1[[0-9]]*)
1534       AC_DEFINE(NEW_PROC_API, 1,
1535       [Define if you want to use new multi-fd /proc interface.])
1536       ;;
1537   esac
1538 fi
1539
1540 if test "$ac_cv_header_sys_procfs_h" = yes; then
1541   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
1542   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
1543   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
1544   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
1545   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
1546   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
1547   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
1548   BFD_HAVE_SYS_PROCFS_TYPE(prsysent_t)
1549   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigset_t)
1550   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigaction64_t)
1551   BFD_HAVE_SYS_PROCFS_TYPE(pr_siginfo64_t)
1552
1553
1554   dnl Check for broken prfpregset_t type
1555
1556   dnl For Linux/i386, glibc 2.1.3 was released with a bogus
1557   dnl prfpregset_t type (it's a typedef for the pointer to a struct
1558   dnl instead of the struct itself).  We detect this here, and work
1559   dnl around it in gdb_proc_service.h.
1560
1561   if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
1562     AC_MSG_CHECKING(whether prfpregset_t type is broken)
1563     AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
1564       [AC_TRY_RUN([#include <sys/procfs.h>
1565        int main ()
1566        {
1567          if (sizeof (prfpregset_t) == sizeof (void *))
1568            return 1;
1569          return 0;
1570        }],
1571        gdb_cv_prfpregset_t_broken=no,
1572        gdb_cv_prfpregset_t_broken=yes,
1573        gdb_cv_prfpregset_t_broken=yes)])
1574     AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
1575     if test $gdb_cv_prfpregset_t_broken = yes; then
1576       AC_DEFINE(PRFPREGSET_T_BROKEN, 1,
1577       [Define if the prfpregset_t type is broken.])
1578     fi
1579   fi
1580 fi
1581
1582 # Check if the compiler supports the `long long' type.
1583
1584 AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long,
1585                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1586 [[extern long long foo;]],
1587 [[switch (foo & 2) { case 0: return 1; }]])],
1588                                   gdb_cv_c_long_long=yes,
1589                                   gdb_cv_c_long_long=no)])
1590 if test $gdb_cv_c_long_long != yes; then
1591   # libdecnumber requires long long.
1592   AC_MSG_ERROR([Compiler must support long long for GDB.])
1593 fi
1594
1595 # Check if the compiler and runtime support printing long longs.
1596
1597 AC_CACHE_CHECK([for long long support in printf],
1598                gdb_cv_printf_has_long_long,
1599                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1600 [[char buf[32];
1601   long long l = 0;
1602   l = (l << 16) + 0x0123;
1603   l = (l << 16) + 0x4567;
1604   l = (l << 16) + 0x89ab;
1605   l = (l << 16) + 0xcdef;
1606   sprintf (buf, "0x%016llx", l);
1607   return (strcmp ("0x0123456789abcdef", buf));]])],
1608                               gdb_cv_printf_has_long_long=yes,
1609                               gdb_cv_printf_has_long_long=no,
1610                               gdb_cv_printf_has_long_long=no)])
1611 if test $gdb_cv_printf_has_long_long = yes; then
1612   AC_DEFINE(PRINTF_HAS_LONG_LONG, 1,
1613             [Define to 1 if the "%ll" format works to print long longs.])
1614 fi
1615
1616 # Check if the compiler and runtime support printing decfloats.
1617
1618 AC_CACHE_CHECK([for decfloat support in printf],
1619                gdb_cv_printf_has_decfloat,
1620                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1621 [[char buf[64];
1622   _Decimal32 d32 = 1.2345df;
1623   _Decimal64 d64 = 1.2345dd;
1624   _Decimal128 d128 = 1.2345dl;
1625   sprintf (buf, "Decimal32: %H\nDecimal64: %D\nDecimal128: %DD", d32, d64, d128);
1626   return (strcmp ("Decimal32: 1.2345\nDecimal64: 1.2345\nDecimal128: 1.2345", buf));]])],
1627                               gdb_cv_printf_has_decfloat=yes,
1628                               gdb_cv_printf_has_decfloat=no,
1629                               gdb_cv_printf_has_decfloat=no)])
1630 if test $gdb_cv_printf_has_decfloat = yes; then
1631   AC_DEFINE(PRINTF_HAS_DECFLOAT, 1,
1632             [Define to 1 if the "%H, %D and %DD" formats work to print decfloats.])
1633 fi
1634
1635 # Check if the compiler supports the `long double' type.  We can't use
1636 # AC_C_LONG_DOUBLE because that one does additional checks on the
1637 # constants defined in <float.h> that fail on some systems,
1638 # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6.
1639
1640 AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double,
1641                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])],
1642                                   gdb_cv_c_long_double=yes,
1643                                   gdb_cv_c_long_double=no)])
1644 if test $gdb_cv_c_long_double = yes; then
1645   AC_DEFINE(HAVE_LONG_DOUBLE, 1,
1646            [Define to 1 if the compiler supports long double.])
1647 fi
1648
1649 # Check if the compiler and runtime support printing long doubles.
1650
1651 AC_CACHE_CHECK([for long double support in printf],
1652                gdb_cv_printf_has_long_double,
1653                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1654 [[char buf[16];
1655   long double f = 3.141592653;
1656   sprintf (buf, "%Lg", f);
1657   return (strncmp ("3.14159", buf, 7));]])],
1658                               gdb_cv_printf_has_long_double=yes,
1659                               gdb_cv_printf_has_long_double=no,
1660                               gdb_cv_printf_has_long_double=no)])
1661 if test $gdb_cv_printf_has_long_double = yes; then
1662   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1,
1663             [Define to 1 if the "%Lg" format works to print long doubles.])
1664 fi
1665
1666 # Check if the compiler and runtime support scanning long doubles.
1667
1668 AC_CACHE_CHECK([for long double support in scanf],
1669                gdb_cv_scanf_has_long_double,
1670                [AC_RUN_IFELSE([AC_LANG_PROGRAM(
1671 [[#include <stdio.h>]],
1672 [[char *buf = "3.141592653";
1673   long double f = 0;
1674   sscanf (buf, "%Lg", &f);
1675   return !(f > 3.14159 && f < 3.14160);]])],
1676                               gdb_cv_scanf_has_long_double=yes,
1677                               gdb_cv_scanf_has_long_double=no,
1678                               gdb_cv_scanf_has_long_double=no)])
1679 if test $gdb_cv_scanf_has_long_double = yes; then
1680   AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1,
1681             [Define to 1 if the "%Lg" format works to scan long doubles.])
1682 fi
1683
1684 case ${host_os} in
1685 aix*)
1686   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1687     SAVE_LDFLAGS=$LDFLAGS
1688
1689     case $GCC in
1690     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1691     *) gdb_cv_bigtoc=-bbigtoc ;;
1692     esac
1693
1694     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1695     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1696     LDFLAGS="${SAVE_LDFLAGS}"
1697   ])
1698   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
1699   ;;
1700 esac
1701
1702 AC_MSG_CHECKING(for the dynamic export flag)
1703 dynamic_list=false
1704 if test "${gdb_native}" = yes; then
1705    # The dynamically loaded libthread_db needs access to symbols in the gdb
1706    # executable.  Older GNU ld supports --export-dynamic but --dynamic-list
1707    # may not be supported there.
1708    old_LDFLAGS="$LDFLAGS"
1709    # Older GNU ld supports --export-dynamic but --dynamic-list it does not.
1710    RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
1711    LDFLAGS="$LDFLAGS $RDYNAMIC"
1712    if test "${have_libpython}" = no; then
1713      AC_TRY_LINK([], [], [dynamic_list=true])
1714    else
1715      # Workaround http://bugs.python.org/issue4434 where static
1716      # libpythonX.Y.a would get its symbols required for
1717      # pythonX.Y/lib-dynload/*.so modules hidden by -Wl,--dynamic-list.
1718      # Problem does not happen for the recommended libpythonX.Y.so linkage.
1719
1720      # Note the workaround for Python
1721      # http://bugs.python.org/issue10112 earlier has removed
1722      # -export-dynamic from PYTHON_LIBS.  That's exactly what we want
1723      # here too, as otherwise it'd make this -Wl,--dynamic-list test
1724      # always pass.
1725      old_CFLAGS="$CFLAGS"
1726      CFLAGS="$CFLAGS $PYTHON_CFLAGS"
1727      old_LIBS="$LIBS"
1728      LIBS="$LIBS $PYTHON_LIBS"
1729      old_CPPFLAGS="$CPPFLAGS"
1730      CPPFLAGS="$CPPFLAGS $PYTHON_CPPFLAGS"
1731      AC_RUN_IFELSE(
1732        AC_LANG_PROGRAM(
1733          [#include "Python.h"],
1734          [int err;
1735           Py_Initialize ();
1736           err = PyRun_SimpleString ("import itertools\n");
1737           Py_Finalize ();
1738           return err == 0 ? 0 : 1;]),
1739        [dynamic_list=true], [], [true])
1740      LIBS="$old_LIBS"
1741      CFLAGS="$old_CFLAGS"
1742      CPPFLAGS="$old_CPPFLAGS"
1743    fi
1744    LDFLAGS="$old_LDFLAGS"
1745 fi
1746 if $dynamic_list; then
1747   found="-Wl,--dynamic-list"
1748   RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'
1749 else
1750   found="-rdynamic"
1751   RDYNAMIC="-rdynamic"
1752 fi
1753 AC_SUBST(RDYNAMIC)
1754 AC_MSG_RESULT($found)
1755
1756 dnl For certain native configurations, we need to check whether thread
1757 dnl support can be built in or not.
1758 dnl
1759 dnl Note that we only want this if we are both native (host == target),
1760 dnl and not doing a canadian cross build (build == host).
1761
1762 if test ${build} = ${host} -a ${host} = ${target} ; then
1763    case ${host_os} in
1764    aix*)
1765       AC_MSG_CHECKING(for AiX thread debugging library)
1766       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
1767                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
1768                                    [#ifndef PTHDB_VERSION_3
1769                                     #error
1770                                     #endif],
1771                                    gdb_cv_have_aix_thread_debug=yes,
1772                                    gdb_cv_have_aix_thread_debug=no)])
1773       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1774       if test $gdb_cv_have_aix_thread_debug = yes; then
1775          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1776          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1777          LIBS="$LIBS -lpthdebug"
1778
1779          # Older versions of AIX do not provide the declaration for
1780          # the getthrds function (it appears that it was introduced
1781          # with AIX 6.x).
1782          AC_CHECK_DECLS(getthrds, [], [], [[#include <procinfo.h>]])
1783       fi
1784       ;;
1785    esac
1786    AC_SUBST(CONFIG_LDFLAGS)
1787 fi
1788
1789 dnl See if we have a thread_db header file that has TD_NOTALLOC and
1790 dnl other error codes.
1791 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1792    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
1793                   gdb_cv_thread_db_h_has_td_notalloc,
1794      AC_TRY_COMPILE(
1795        [#include <thread_db.h>],
1796        [int i = TD_NOTALLOC;],
1797        gdb_cv_thread_db_h_has_td_notalloc=yes,
1798        gdb_cv_thread_db_h_has_td_notalloc=no
1799      )
1800    )
1801    AC_CACHE_CHECK([whether <thread_db.h> has TD_VERSION],
1802                   gdb_cv_thread_db_h_has_td_version,
1803      AC_TRY_COMPILE(
1804        [#include <thread_db.h>],
1805        [int i = TD_VERSION;],
1806        gdb_cv_thread_db_h_has_td_version=yes,
1807        gdb_cv_thread_db_h_has_td_version=no
1808      )
1809    )
1810    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTLS],
1811                   gdb_cv_thread_db_h_has_td_notls,
1812      AC_TRY_COMPILE(
1813        [#include <thread_db.h>],
1814        [int i = TD_NOTLS;],
1815        gdb_cv_thread_db_h_has_td_notls=yes,
1816        gdb_cv_thread_db_h_has_td_notls=no
1817      )
1818    )
1819 fi
1820 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1821   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1822             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1823 fi
1824 if test "x$gdb_cv_thread_db_h_has_td_version" = "xyes"; then
1825   AC_DEFINE(THREAD_DB_HAS_TD_VERSION, 1,
1826             [Define if <thread_db.h> has the TD_VERSION error code.])
1827 fi
1828 if test "x$gdb_cv_thread_db_h_has_td_notls" = "xyes"; then
1829   AC_DEFINE(THREAD_DB_HAS_TD_NOTLS, 1,
1830             [Define if <thread_db.h> has the TD_NOTLS error code.])
1831 fi
1832
1833 dnl Check if we can disable the virtual address space randomization.
1834 dnl The functionality of setarch -R.
1835 AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>])
1836 define([PERSONALITY_TEST], [AC_LANG_PROGRAM([#include <sys/personality.h>], [
1837 #      if !HAVE_DECL_ADDR_NO_RANDOMIZE
1838 #       define ADDR_NO_RANDOMIZE 0x0040000
1839 #      endif
1840        /* Test the flag could be set and stays set.  */
1841        personality (personality (0xffffffff) | ADDR_NO_RANDOMIZE);
1842        if (!(personality (personality (0xffffffff)) & ADDR_NO_RANDOMIZE))
1843            return 1])])
1844 AC_RUN_IFELSE([PERSONALITY_TEST],
1845               [have_personality=true],
1846               [have_personality=false],
1847               [AC_LINK_IFELSE([PERSONALITY_TEST],
1848                               [have_personality=true],
1849                               [have_personality=false])])
1850 if $have_personality
1851 then
1852     AC_DEFINE([HAVE_PERSONALITY], 1,
1853               [Define if you support the personality syscall.])
1854 fi
1855
1856 dnl Set the host's .gdbinit filename.
1857 case $host_os in
1858   go32* | *djgpp*)
1859     gdbinit=gdb.ini
1860     ;;
1861   *)
1862     gdbinit=.gdbinit
1863     ;;
1864 esac
1865 AC_DEFINE_UNQUOTED(GDBINIT,"$gdbinit",[The .gdbinit filename.])
1866
1867 dnl Handle optional features that can be enabled.
1868
1869 # Support for --with-sysroot is a copy of GDB_AC_WITH_DIR,
1870 # except that the argument to --with-sysroot is optional.
1871 # --with-sysroot (or --with-sysroot=yes) sets the default sysroot path.
1872 if test "x$with_sysroot" = xyes; then
1873   with_sysroot="${exec_prefix}/${target_alias}/sys-root"
1874 fi
1875 AC_ARG_WITH(sysroot,
1876   AS_HELP_STRING([--with-sysroot@<:@=DIR@:>@],
1877                  [search for usr/lib et al within DIR]),
1878   [TARGET_SYSTEM_ROOT=$withval], [TARGET_SYSTEM_ROOT=])
1879 AC_DEFINE_DIR(TARGET_SYSTEM_ROOT, TARGET_SYSTEM_ROOT,
1880               [search for usr/lib et al within DIR])
1881 AC_SUBST(TARGET_SYSTEM_ROOT)
1882 GDB_AC_DEFINE_RELOCATABLE(TARGET_SYSTEM_ROOT, sysroot, ${ac_define_dir})
1883
1884 GDB_AC_WITH_DIR(SYSTEM_GDBINIT, system-gdbinit,
1885     [automatically load a system-wide gdbinit file],
1886     [])
1887
1888 AM_GDB_WARNINGS
1889
1890 # In the Cygwin environment, we need some additional flags.
1891 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1892 [AC_EGREP_CPP(^lose$, [
1893 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1894 lose
1895 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1896
1897
1898 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1899 SER_HARDWIRE="ser-base.o ser-unix.o ser-pipe.o ser-tcp.o"
1900 case ${host} in
1901   *go32* ) SER_HARDWIRE=ser-go32.o ;;
1902   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
1903   *mingw32*) SER_HARDWIRE="ser-base.o ser-tcp.o ser-mingw.o" ;;
1904 esac
1905 AC_SUBST(SER_HARDWIRE)
1906
1907 # libreadline needs libuser32.a in a cygwin environment
1908 WIN32LIBS=
1909 if test x$gdb_cv_os_cygwin = xyes; then
1910     WIN32LIBS="-luser32"
1911     case "${target}" in
1912         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
1913         ;;
1914     esac
1915 fi
1916
1917 # The ser-tcp.c module requires sockets.
1918 case ${host} in
1919   *mingw32*)
1920     AC_DEFINE(USE_WIN32API, 1,
1921               [Define if we should use the Windows API, instead of the
1922                POSIX API.  On Windows, we use the Windows API when
1923                building for MinGW, but the POSIX API when building
1924                for Cygwin.])
1925     WIN32LIBS="$WIN32LIBS -lws2_32"
1926     ;;
1927 esac
1928 AC_SUBST(WIN32LIBS)
1929
1930 # Add ELF support to GDB, but only if BFD includes ELF support.
1931 GDB_AC_CHECK_BFD([for ELF support in BFD], gdb_cv_var_elf,
1932                  [bfd_get_elf_phdr_upper_bound (NULL)], elf-bfd.h)
1933 if test $gdb_cv_var_elf = yes; then
1934   CONFIG_OBS="$CONFIG_OBS elfread.o stap-probe.o dtrace-probe.o"
1935   AC_DEFINE(HAVE_ELF, 1,
1936             [Define if ELF support should be included.])
1937   # -ldl is provided by bfd/Makfile.am (LIBDL) <PLUGINS>.
1938   if test "$plugins" = "yes"; then
1939     AC_SEARCH_LIBS(dlopen, dl)
1940   fi
1941 fi
1942
1943 # Add macho support to GDB, but only if BFD includes it.
1944 GDB_AC_CHECK_BFD([for Mach-O support in BFD], gdb_cv_var_macho,
1945                  [bfd_mach_o_lookup_command (NULL, 0, NULL)], mach-o.h)
1946 if test $gdb_cv_var_macho = yes; then
1947   CONFIG_OBS="$CONFIG_OBS machoread.o"
1948 fi
1949
1950 # Add any host-specific objects to GDB.
1951 CONFIG_OBS="${CONFIG_OBS} ${gdb_host_obs}"
1952
1953 # If building on ELF, look for lzma support for embedded compressed debug info.
1954 if test $gdb_cv_var_elf = yes; then
1955   AC_ARG_WITH(lzma,
1956     AS_HELP_STRING([--with-lzma], [support lzma compression (auto/yes/no)]),
1957     [], [with_lzma=auto])
1958   AC_MSG_CHECKING([whether to use lzma])
1959   AC_MSG_RESULT([$with_lzma])
1960
1961   if test "${with_lzma}" != no; then
1962     AC_LIB_HAVE_LINKFLAGS([lzma], [], [#include "lzma.h"],
1963                           [lzma_index_iter iter;
1964                            lzma_index_iter_init (&iter, 0);
1965                            lzma_mf_is_supported (LZMA_MF_HC3);])
1966     if test "$HAVE_LIBLZMA" != yes; then
1967       if test "$with_lzma" = yes; then
1968         AC_MSG_ERROR([missing liblzma for --with-lzma])
1969       fi
1970     fi
1971   fi
1972 fi
1973
1974 LIBGUI="../libgui/src/libgui.a"
1975 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
1976 AC_SUBST(LIBGUI)
1977 AC_SUBST(GUI_CFLAGS_X)
1978
1979 WIN32LDAPP=
1980 AC_SUBST(WIN32LIBS)
1981 AC_SUBST(WIN32LDAPP)
1982
1983 case "${host}" in
1984 *-*-cygwin* | *-*-mingw* )
1985     configdir="win"
1986     ;;
1987 *)
1988     configdir="unix"
1989     ;;
1990 esac
1991
1992 GDBTKLIBS=
1993 if test "${enable_gdbtk}" = "yes"; then
1994
1995     # Gdbtk must have an absolute path to srcdir in order to run
1996     # properly when not installed.
1997     here=`pwd`
1998     cd ${srcdir}
1999     GDBTK_SRC_DIR=`pwd`
2000     cd $here
2001
2002     SC_PATH_TCLCONFIG
2003
2004     # If $no_tk is nonempty, then we can't do Tk, and there is no
2005     # point to doing Tcl.
2006     SC_PATH_TKCONFIG
2007
2008     if test -z "${no_tcl}" -a -z "${no_tk}"; then
2009         SC_LOAD_TCLCONFIG
2010
2011         # Check for in-tree tcl
2012         here=`pwd`
2013         cd ${srcdir}/..
2014         topdir=`pwd`
2015         cd ${here}
2016
2017         intree="no"
2018         if test "${TCL_SRC_DIR}" = "${topdir}/tcl"; then
2019           intree="yes"
2020         fi
2021
2022         # Find Tcl private headers
2023         if test x"${intree}" = xno; then
2024           CY_AC_TCL_PRIVATE_HEADERS
2025           TCL_INCLUDE="${TCL_INCLUDE_SPEC} ${TCL_PRIVATE_INCLUDE}"
2026           TCL_LIBRARY="${TCL_LIB_SPEC}"
2027           TCL_DEPS=""
2028         else
2029           # If building tcl in the same src tree, private headers
2030           # are not needed, but we need to be sure to use the right
2031           # headers library
2032           TCL_INCLUDE="-I${TCL_SRC_DIR}/generic"
2033           TCL_LIBRARY="${TCL_BUILD_LIB_SPEC}"
2034           TCL_DEPS="../tcl/${configdir}${TCL_LIB_FILE}"
2035         fi
2036         AC_SUBST(TCL_INCLUDE)
2037         AC_SUBST(TCL_LIBRARY)
2038         AC_SUBST(TCL_DEPS)
2039
2040         SC_LOAD_TKCONFIG
2041
2042         # Check for in-tree Tk
2043         intree="no"
2044         if test "${TK_SRC_DIR}" = "${topdir}/tk"; then
2045           intree="yes"
2046         fi
2047
2048         # Find Tk private headers
2049         if test x"${intree}" = xno; then
2050           CY_AC_TK_PRIVATE_HEADERS
2051           TK_INCLUDE="${TK_INCLUDE_SPEC} ${TK_PRIVATE_INCLUDE}"
2052           TK_LIBRARY=${TK_LIB_SPEC}
2053           TK_DEPS=""
2054         else
2055           TK_INCLUDE="-I${TK_SRC_DIR}/generic"
2056           TK_LIBRARY="${TK_BUILD_LIB_SPEC}"
2057           TK_DEPS="../tk/${configdir}/${TK_LIB_FILE}"
2058         fi
2059         AC_SUBST(TK_INCLUDE)
2060         AC_SUBST(TK_LIBRARY)
2061         AC_SUBST(TK_DEPS)
2062         AC_SUBST(TK_XINCLUDES)
2063
2064         ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
2065
2066         # Include some libraries that Tcl and Tk want.
2067         TCL_LIBS='$(LIBGUI) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
2068         # Yes, the ordering seems wrong here.  But it isn't.
2069         # TK_LIBS is the list of libraries that need to be linked
2070         # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
2071         # were in LIBS then any link tests after this point would
2072         # try to include things like `$(LIBGUI)', which wouldn't work.
2073         GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
2074
2075         CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
2076         CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
2077         CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
2078         CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
2079         CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
2080         CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
2081         CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
2082
2083         if test x$gdb_cv_os_cygwin = xyes; then
2084           WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
2085           WIN32LDAPP="-Wl,--subsystem,console"
2086           CONFIG_OBS="${CONFIG_OBS} gdbres.o"
2087         fi
2088
2089         AC_CONFIG_SUBDIRS(gdbtk)
2090     fi
2091 fi
2092
2093 AC_SUBST(X_CFLAGS)
2094 AC_SUBST(X_LDFLAGS)
2095 AC_SUBST(X_LIBS)
2096 AC_SUBST(GDBTKLIBS)
2097 AC_SUBST(GDBTK_CFLAGS)
2098 AC_SUBST(GDBTK_SRC_DIR)
2099
2100 AC_PATH_X
2101
2102 # Unlike the sim directory, whether a simulator is linked is controlled by
2103 # presence of a gdb_sim definition in the target configure.tgt entry.
2104 # This code just checks for a few cases where we'd like to ignore those
2105 # definitions, even when they're present in the '.mt' file.  These cases
2106 # are when --disable-sim is specified, or if the simulator directory is
2107 # not part of the source tree.
2108 #
2109 AC_ARG_ENABLE(sim,
2110 AS_HELP_STRING([--enable-sim], [link gdb with simulator]),
2111 [echo "enable_sim = $enable_sim";
2112  echo "enableval = ${enableval}";
2113  case "${enableval}" in
2114   yes) ignore_sim=false ;;
2115   no)  ignore_sim=true ;;
2116   *)   ignore_sim=false ;;
2117  esac],
2118 [ignore_sim=false])
2119
2120 if test ! -d "${srcdir}/../sim"; then
2121   ignore_sim=true
2122 fi
2123
2124 SIM=
2125 SIM_OBS=
2126 if test "${ignore_sim}" = "false"; then
2127   if test x"${gdb_sim}" != x ; then
2128     SIM="${gdb_sim}"
2129     SIM_OBS="remote-sim.o"
2130     AC_DEFINE(WITH_SIM, 1, [Define if the simulator is being linked in.])
2131
2132     # Some tdep code should only be compiled in when the ppc sim is
2133     # built.  PR sim/13418.
2134     case $target in
2135       powerpc*-*-*)
2136         AC_DEFINE(WITH_PPC_SIM, 1, [Define if the PPC simulator is being linked in.])
2137         ;;
2138     esac
2139   fi
2140 fi
2141 AC_SUBST(SIM)
2142 AC_SUBST(SIM_OBS)
2143
2144 AC_SUBST(ENABLE_CFLAGS)
2145 AC_SUBST(PROFILE_CFLAGS)
2146
2147 AC_SUBST(CONFIG_OBS)
2148 AC_SUBST(CONFIG_DEPS)
2149 AC_SUBST(CONFIG_SRCS)
2150 AC_SUBST(CONFIG_ALL)
2151 AC_SUBST(CONFIG_CLEAN)
2152 AC_SUBST(CONFIG_INSTALL)
2153 AC_SUBST(CONFIG_UNINSTALL)
2154
2155 # List of host floatformats.
2156 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
2157 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
2158 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
2159
2160 # target_subdir is used by the testsuite to find the target libraries.
2161 target_subdir=
2162 if test "${host}" != "${target}"; then
2163     target_subdir="${target_alias}/"
2164 fi
2165 AC_SUBST(target_subdir)
2166
2167 # Import nat definitions.
2168 nat_makefile_frag=/dev/null
2169 if test "${gdb_native}" = "yes"; then
2170   . ${srcdir}/configure.nat
2171   nativefile=$NAT_FILE
2172 fi
2173
2174 AC_SUBST(NAT_FILE)
2175 AC_SUBST(NATDEPFILES)
2176 AC_SUBST(NAT_CDEPS)
2177 AC_SUBST(LOADLIBES)
2178 AC_SUBST(MH_CFLAGS)
2179 AC_SUBST(XM_CLIBS)
2180 AC_SUBST(NAT_GENERATED_FILES)
2181 AC_SUBST(HAVE_NATIVE_GCORE_HOST)
2182 AC_SUBST_FILE(nat_makefile_frag)
2183
2184 if test x"${gdb_osabi}" != x ; then
2185     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
2186                        [Define to the default OS ABI for this configuration.])
2187 fi
2188
2189 # Enable multi-ice-gdb-server.
2190 AC_ARG_ENABLE(multi-ice,
2191 AS_HELP_STRING([--enable-multi-ice], [build the multi-ice-gdb-server]),
2192   [case $enableval in
2193     yes | no)
2194       ;;
2195     *) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;;
2196   esac])
2197 if test "x$enable_multi_ice" = xyes; then
2198    AC_CONFIG_SUBDIRS(multi-ice)
2199 fi
2200
2201 AC_ARG_ENABLE(gdbserver,
2202 AS_HELP_STRING([--enable-gdbserver],
2203                [automatically build gdbserver (yes/no/auto, default is auto)]),
2204 [case "${enableval}" in
2205   yes| no|auto) ;;
2206   *) AC_MSG_ERROR(bad value ${enableval} for --enable-gdbserver option) ;;
2207 esac],[enable_gdbserver=auto])
2208
2209 # We only build gdbserver automatically in a native configuration, and
2210 # only if the user did not explicitly disable its build.
2211 if test "$gdb_native" = "yes" -a "$enable_gdbserver" != "no"; then
2212   AC_MSG_CHECKING(whether gdbserver is supported on this host)
2213   if test "x$build_gdbserver" = xyes; then
2214     AC_MSG_RESULT(yes)
2215     AC_CONFIG_SUBDIRS(gdbserver)
2216     gdbserver_build_enabled=yes
2217   else
2218     AC_MSG_RESULT(no)
2219   fi
2220 fi
2221
2222 # If the user explicitly request the gdbserver to be built, verify that
2223 # we were in fact able to enable it.
2224 if test "$enable_gdbserver" = "yes" -a "$gdbserver_build_enabled" != "yes"; then
2225   AC_MSG_ERROR(Automatic gdbserver build is not supported for this configuration)
2226 fi
2227
2228 # Check for babeltrace and babeltrace-ctf
2229 AC_ARG_WITH(babeltrace,
2230   AC_HELP_STRING([--with-babeltrace], [include babeltrace support (auto/yes/no)]),
2231   [], [with_babeltrace=auto])
2232 AC_MSG_CHECKING([whether to use babeltrace])
2233 AC_MSG_RESULT([$with_babeltrace])
2234
2235 if test "x$with_babeltrace" = "xno"; then
2236   AC_MSG_WARN([babletrace support disabled; GDB is unable to read CTF data.])
2237 else
2238   # Append -Werror to CFLAGS so that configure can catch the warning
2239   # "assignment from incompatible pointer type", which is related to
2240   # the babeltrace change from 1.0.3 to 1.1.0.  Babeltrace 1.1.0 works
2241   # in GDB, while babeltrace 1.0.3 is broken.
2242   # AC_LIB_HAVE_LINKFLAGS may modify CPPFLAGS in it, so it should be
2243   # safe to save and restore CFLAGS here.
2244   saved_CFLAGS=$CFLAGS
2245   CFLAGS="$CFLAGS -Werror"
2246   AC_LIB_HAVE_LINKFLAGS([babeltrace], [babeltrace-ctf],
2247                         [#include <babeltrace/babeltrace.h>
2248                          #include <babeltrace/ctf/events.h>
2249                          #include <babeltrace/ctf/iterator.h>],
2250                         [struct bt_iter_pos *pos = bt_iter_get_pos (bt_ctf_get_iter (NULL));
2251                         struct bt_ctf_event *event = NULL;
2252                         const struct bt_definition *scope;
2253
2254                         pos->type = BT_SEEK_BEGIN;
2255                         bt_iter_set_pos (bt_ctf_get_iter (NULL), pos);
2256                         scope = bt_ctf_get_top_level_scope (event,
2257                                                            BT_STREAM_EVENT_HEADER);
2258                         bt_ctf_get_uint64 (bt_ctf_get_field (event, scope, "id"));
2259                         ])
2260   CFLAGS=$saved_CFLAGS
2261
2262   if test "$HAVE_LIBBABELTRACE" != yes; then
2263      if test "$with_babeltrace" = yes; then
2264        AC_MSG_ERROR([babeltrace is missing or unusable])
2265      else
2266        AC_MSG_WARN([babeltrace is missing or unusable; GDB is unable to read CTF data.])
2267      fi
2268   fi
2269 fi
2270
2271 # If nativefile (NAT_FILE) is not set in configure.nat, we link to an
2272 # empty version.
2273
2274 files=
2275 links=
2276
2277 rm -f nm.h
2278 if test "${nativefile}" != ""; then
2279     case "${nativefile}" in
2280       nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
2281       * ) GDB_NM_FILE="${nativefile}"
2282     esac
2283     files="${files} ${GDB_NM_FILE}"
2284     links="${links} nm.h"
2285     AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}", [nativefile])
2286 fi
2287 AC_SUBST(GDB_NM_FILE)
2288
2289 dnl Add dependency for xsltproc if building with maintainer-mode enabled.
2290 AC_PATH_PROGS(XSLTPROC, xsltproc, missing)
2291 if test "x$USE_MAINTAINER_MODE" = xyes; then
2292   if test "${XSLTPROC}" = missing; then
2293     AC_ERROR(unable to find xsltproc.  maintainer-mode requires xsltproc.)
2294   fi
2295 fi
2296 AC_SUBST(XSLTPROC)
2297
2298 AC_LINK_FILES($files, $links)
2299
2300 dnl Check for exe extension set on certain hosts (e.g. Win32)
2301 AC_EXEEXT
2302
2303 dnl  Detect the character set used by this host.
2304 dnl  At the moment, we just assume it's UTF-8.
2305 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "UTF-8",
2306           [Define to be a string naming the default host character set.])
2307
2308 if $development; then
2309   AC_DEFINE(GDB_SELF_TEST, 1,
2310             [Define if self-testing features should be enabled])
2311   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_UNITTESTS_OBS)"
2312   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_UNITTESTS_SRCS)"
2313 fi
2314
2315 GDB_AC_TRANSFORM([gdb], [GDB_TRANSFORM_NAME])
2316 GDB_AC_TRANSFORM([gcore], [GCORE_TRANSFORM_NAME])
2317 AC_CONFIG_FILES([gcore], [chmod +x gcore])
2318 AC_CONFIG_FILES([Makefile gdb-gdb.gdb doc/Makefile data-directory/Makefile],
2319 [
2320 case x$CONFIG_HEADERS in
2321 xconfig.h:config.in)
2322 echo > stamp-h ;;
2323 esac
2324 ])
2325
2326 AC_OUTPUT