gdb/configure.ac

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003,
   3 dnl 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011
   4 dnl Free Software Foundation, Inc.
   5 dnl
   6 dnl This file is part of GDB.
   7 dnl
   8 dnl This program is free software; you can redistribute it and/or modify
   9 dnl it under the terms of the GNU General Public License as published by
  10 dnl the Free Software Foundation; either version 3 of the License, or
  11 dnl (at your option) any later version.
  12 dnl
  13 dnl This program is distributed in the hope that it will be useful,
  14 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 dnl GNU General Public License for more details.
  17 dnl
  18 dnl You should have received a copy of the GNU General Public License
  19 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 dnl Process this file with autoconf to produce a configure script.
  22
  23 AC_PREREQ(2.59)dnl
  24 AC_INIT(main.c)
  25 AC_CONFIG_HEADER(config.h:config.in)
  26 AM_MAINTAINER_MODE
  27
  28 AC_PROG_CC
  29 AC_USE_SYSTEM_EXTENSIONS
  30 gl_EARLY
  31 ACX_LARGEFILE
  32 AM_PROG_CC_STDC
  33
  34 AC_CONFIG_AUX_DIR(..)
  35 AC_CANONICAL_SYSTEM
  36
  37 # Dependency checking.
  38 ZW_CREATE_DEPDIR
  39 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  40
  41 # Check for the 'make' the user wants to use.
  42 AC_CHECK_PROGS(MAKE, make)
  43 MAKE_IS_GNU=
  44 case "`$MAKE --version 2>&1 | sed 1q`" in
  45   *GNU*)
  46     MAKE_IS_GNU=yes
  47     ;;
  48 esac
  49 AM_CONDITIONAL(GMAKE, test "$MAKE_IS_GNU" = yes)
  50 AC_PROG_MAKE_SET
  51
  52 dnl List of object files and targets accumulated by configure.
  53
  54 CONFIG_OBS=
  55 CONFIG_DEPS=
  56 CONFIG_SRCS=
  57 ENABLE_CFLAGS=
  58
  59 CONFIG_ALL=
  60 CONFIG_CLEAN=
  61 CONFIG_INSTALL=
  62 CONFIG_UNINSTALL=
  63
  64 dnl Set up for gettext.
  65 ZW_GNU_GETTEXT_SISTER_DIR
  66
  67 localedir='${datadir}/locale'
  68 AC_SUBST(localedir)
  69
  70 if test x"$USE_NLS" = xyes; then
  71    CONFIG_ALL="$CONFIG_ALL all-po"
  72    CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
  73    CONFIG_INSTALL="$CONFIG_INSTALL install-po"
  74    CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
  75 fi
  76
  77 gl_INIT
  78
  79 # For Makefile dependencies.
  80 GNULIB_STDINT_H=
  81 if test x"$STDINT_H" != x; then
  82   GNULIB_STDINT_H=gnulib/$STDINT_H
  83 fi
  84 AC_SUBST(GNULIB_STDINT_H)
  85
  86 PACKAGE=gdb
  87 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
  88 AC_SUBST(PACKAGE)
  89
  90 # Do we have a single-tree copy of texinfo?  Even if we do, we can't
  91 # rely on it - libiberty is built before texinfo.
  92 AC_CHECK_PROG(MAKEINFO, makeinfo, makeinfo, )
  93 if test "x$MAKEINFO" = "x"; then
  94   AC_ERROR([makeinfo is required for compilation])
  95 else
  96   case "$MAKEINFO" in
  97     */missing\ makeinfo*)
  98       AC_ERROR([makeinfo is required for compilation])
  99       ;;
 100   esac
 101 fi
 102 AC_SUBST(MAKEINFO)
 103
 104 # --split-size=5000000 may be already in $MAKEINFO from parent configure.
 105 # Re-running configure in gdb/ would lose it so ensure it stays present.
 106 MAKEINFOFLAGS=${MAKEINFOFLAGS---split-size=5000000}
 107 AC_SUBST(MAKEINFOFLAGS)
 108
 109 MAKEINFO_EXTRA_FLAGS=""
 110 AC_CACHE_CHECK([whether $MAKEINFO supports @click], gdb_cv_have_makeinfo_click,
 111   [echo '@clicksequence{a @click{} b}' >conftest.texinfo
 112   if eval "$MAKEINFO conftest.texinfo >&5 2>&5"; then
 113     gdb_cv_have_makeinfo_click=yes
 114   else
 115     gdb_cv_have_makeinfo_click=no
 116   fi])
 117 if test x"$gdb_cv_have_makeinfo_click" = xyes; then
 118   MAKEINFO_EXTRA_FLAGS="$MAKEINFO_EXTRA_FLAGS -DHAVE_MAKEINFO_CLICK"
 119 fi
 120 AC_SUBST(MAKEINFO_EXTRA_FLAGS)
 121
 122 # GDB does not use automake, but gnulib does.  This line lets us
 123 # generate its Makefile.in.
 124 AM_INIT_AUTOMAKE(gdb, UNUSED-VERSION, [no-define])
 125
 126 GDB_AC_WITH_DIR(DEBUGDIR, separate-debug-dir,
 127     [look for global separate debug info in this path @<:@LIBDIR/debug@:>@],
 128     [${libdir}/debug])
 129
 130 # GDB's datadir relocation
 131
 132 GDB_AC_WITH_DIR(GDB_DATADIR, gdb-datadir,
 133     [look for global separate data files in this path @<:@DATADIR/gdb@:>@],
 134     [${datadir}/gdb])
 135
 136 AC_ARG_WITH(relocated-sources,
 137 AS_HELP_STRING([--with-relocated-sources=PATH], [automatically relocate this path for source files]),
 138 [reloc_srcdir="${withval}"
 139  AC_DEFINE_DIR(RELOC_SRCDIR, reloc_srcdir,
 140               [Relocated directory for source files. ])
 141 ])
 142
 143 AC_CONFIG_SUBDIRS(testsuite)
 144
 145 # Check whether to support alternative target configurations
 146 AC_ARG_ENABLE(targets,
 147 AS_HELP_STRING([--enable-targets=TARGETS], [alternative target configurations]),
 148 [case "${enableval}" in
 149   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
 150             ;;
 151   no)       enable_targets= ;;
 152   *)        enable_targets=$enableval ;;
 153 esac])
 154
 155 # Check whether to enable 64-bit support on 32-bit hosts
 156 AC_ARG_ENABLE(64-bit-bfd,
 157 AS_HELP_STRING([--enable-64-bit-bfd], [64-bit support (on hosts with narrower word sizes)]),
 158 [case "${enableval}" in
 159   yes)  want64=true  ;;
 160   no)   want64=false ;;
 161   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
 162 esac],[want64=false])dnl
 163
 164 # Provide defaults for some variables set by the per-host and per-target
 165 # configuration.
 166 gdb_host_obs=posix-hdep.o
 167
 168 if test "${target}" = "${host}"; then
 169   gdb_native=yes
 170 else
 171   gdb_native=no
 172 fi
 173
 174 . $srcdir/configure.host
 175
 176 # Accumulate some settings from configure.tgt over all enabled targets
 177
 178 TARGET_OBS=
 179 all_targets=
 180
 181 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 182 do
 183   if test "$targ_alias" = "all"; then
 184     all_targets=true
 185   else
 186     # Canonicalize the secondary target names.
 187     result=`$ac_config_sub $targ_alias 2>/dev/null`
 188     if test -n "$result"; then
 189         targ=$result
 190     else
 191         targ=$targ_alias
 192     fi
 193
 194     . ${srcdir}/configure.tgt
 195
 196     AS_IF([test -z "${gdb_target_obs}"],
 197       [AC_MSG_ERROR([configuration ${targ} is unsupported.])])
 198
 199     # Target-specific object files
 200     for i in ${gdb_target_obs}; do
 201         case " $TARGET_OBS " in
 202         *" ${i} "*) ;;
 203         *)
 204           TARGET_OBS="$TARGET_OBS ${i}"
 205           ;;
 206         esac
 207     done
 208
 209     # Check whether this target needs 64-bit CORE_ADDR
 210     if test x${want64} = xfalse; then
 211       . ${srcdir}/../bfd/config.bfd
 212     fi
 213   fi
 214 done
 215
 216 if test x${all_targets} = xtrue; then
 217
 218   # We want all 64-bit targets if we either:
 219   #  - run on a 64-bit host  or
 220   #  - already require 64-bit support for some other target  or
 221   #  - the --enable-64-bit-bfd option was supplied
 222   # Otherwise we only support all 32-bit targets.
 223   #
 224   # NOTE: This test must be in sync with the corresponding
 225   #       tests in BFD!
 226
 227   if test x${want64} = xfalse; then
 228     AC_CHECK_SIZEOF(long)
 229     if test "x${ac_cv_sizeof_long}" = "x8"; then
 230       want64=true
 231     fi
 232   fi
 233   if test x${want64} = xtrue; then
 234     TARGET_OBS='$(ALL_TARGET_OBS) $(ALL_64_TARGET_OBS)'
 235   else
 236     TARGET_OBS='$(ALL_TARGET_OBS)'
 237   fi
 238 fi
 239
 240 AC_SUBST(TARGET_OBS)
 241
 242 # For other settings, only the main target counts.
 243 gdb_sim=
 244 gdb_osabi=
 245 build_gdbserver=
 246 targ=$target; . ${srcdir}/configure.tgt
 247
 248 # Fetch the default architecture and default target vector from BFD.
 249 targ=$target; . $srcdir/../bfd/config.bfd
 250
 251 # We only want the first architecture, so strip off the others if
 252 # there is more than one.
 253 targ_archs=`echo $targ_archs | sed 's/ .*//'`
 254
 255 if test "x$targ_archs" != x; then
 256   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
 257     [Define to BFD's default architecture. ])
 258 fi
 259 if test "x$targ_defvec" != x; then
 260   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
 261     [Define to BFD's default target vector. ])
 262 fi
 263
 264 # The CLI cannot be disabled yet, but may be in the future.
 265
 266 # Enable CLI.
 267 AC_ARG_ENABLE(gdbcli,
 268 AS_HELP_STRING([--disable-gdbcli], [disable command-line interface (CLI)]),
 269   [case $enableval in
 270     yes)
 271       ;;
 272     no)
 273       AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;;
 274     *)
 275       AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;;
 276   esac],
 277   [enable_gdbcli=yes])
 278 if test x"$enable_gdbcli" = xyes; then
 279   if test -d $srcdir/cli; then
 280     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)"
 281     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)"
 282     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)"
 283     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)"
 284   fi
 285 fi
 286
 287 # Enable MI.
 288 AC_ARG_ENABLE(gdbmi,
 289 AS_HELP_STRING([--disable-gdbmi], [disable machine-interface (MI)]),
 290   [case $enableval in
 291     yes | no)
 292       ;;
 293     *)
 294       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 295   esac],
 296   [enable_gdbmi=yes])
 297 if test x"$enable_gdbmi" = xyes; then
 298   if test -d $srcdir/mi; then
 299     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 300     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 301     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 302     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 303   fi
 304 fi
 305
 306 # Enable TUI.
 307 AC_ARG_ENABLE(tui,
 308 AS_HELP_STRING([--enable-tui], [enable full-screen terminal user interface (TUI)]),
 309   [case $enableval in
 310     yes | no | auto)
 311       ;;
 312     *)
 313       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 314   esac],enable_tui=auto)
 315
 316 # Enable gdbtk.
 317 AC_ARG_ENABLE(gdbtk,
 318 AS_HELP_STRING([--enable-gdbtk], [enable gdbtk graphical user interface (GUI)]),
 319   [case $enableval in
 320     yes | no)
 321       ;;
 322     *)
 323       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 324   esac],
 325   [if test -d $srcdir/gdbtk; then
 326     enable_gdbtk=yes
 327   else
 328     enable_gdbtk=no
 329   fi])
 330 # We unconditionally disable gdbtk tests on selected platforms.
 331 case $host_os in
 332   go32* | windows*)
 333     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 334     enable_gdbtk=no ;;
 335 esac
 336
 337 # Libunwind support.
 338 AC_ARG_WITH(libunwind,
 339 AS_HELP_STRING([--with-libunwind], [use libunwind frame unwinding support]),
 340 [case "${withval}" in
 341   yes)  enable_libunwind=yes ;;
 342   no)   enable_libunwind=no ;;
 343   *)    AC_MSG_ERROR(bad value ${withval} for GDB with-libunwind option) ;;
 344 esac],[
 345   AC_CHECK_HEADERS(libunwind.h libunwind-ia64.h)
 346   if test x"$ac_cv_header_libunwind_h" = xyes -a x"$ac_cv_header_libunwind_ia64_h" = xyes; then
 347     enable_libunwind=yes;
 348   fi
 349 ])
 350
 351 if test x"$enable_libunwind" = xyes; then
 352   AC_CHECK_HEADERS(libunwind.h libunwind-ia64.h)
 353   AC_DEFINE(HAVE_LIBUNWIND, 1, [Define if libunwind library is being used.])
 354   CONFIG_OBS="$CONFIG_OBS libunwind-frame.o"
 355   CONFIG_DEPS="$CONFIG_DEPS libunwind-frame.o"
 356   CONFIG_SRCS="$CONFIG_SRCS libunwind-frame.c"
 357 fi
 358
 359 opt_curses=no
 360 AC_ARG_WITH(curses, AS_HELP_STRING([--with-curses], [use the curses library instead of the termcap library]), opt_curses=$withval)
 361
 362 prefer_curses=no
 363 if test "$opt_curses" = "yes"; then
 364   prefer_curses=yes
 365 fi
 366
 367 # Profiling support.
 368 AC_ARG_ENABLE(profiling,
 369 AS_HELP_STRING([--enable-profiling], [enable profiling of GDB]),
 370   [case $enableval in
 371     yes | no)
 372       ;;
 373     *)
 374       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 375   esac],
 376  [enable_profiling=no])
 377
 378 AC_CHECK_FUNCS(monstartup _mcleanup)
 379 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 380 [AC_TRY_LINK(
 381 [#include <stdlib.h>
 382 extern char _etext;
 383 ],
 384 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 385 if test $ac_cv_var__etext = yes; then
 386   AC_DEFINE(HAVE__ETEXT, 1,
 387             [Define to 1 if your system has the _etext variable. ])
 388 fi
 389 AC_CACHE_CHECK([for etext], ac_cv_var_etext,
 390 [AC_TRY_LINK(
 391 [#include <stdlib.h>
 392 extern char etext;
 393 ],
 394 [free (&etext);], ac_cv_var_etext=yes, ac_cv_var_etext=no)])
 395 if test $ac_cv_var_etext = yes; then
 396   AC_DEFINE(HAVE_ETEXT, 1,
 397             [Define to 1 if your system has the etext variable. ])
 398 fi
 399 if test "$enable_profiling" = yes ; then
 400   if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
 401     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 402   fi
 403   PROFILE_CFLAGS=-pg
 404   OLD_CFLAGS="$CFLAGS"
 405   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 406
 407   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 408     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 409      ac_cv_cc_supports_pg=no)])
 410
 411   if test $ac_cv_cc_supports_pg = no; then
 412     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 413   fi
 414
 415   CFLAGS="$OLD_CFLAGS"
 416 fi
 417
 418 ACX_PKGVERSION([GDB])
 419 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 420 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 421 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 422
 423 # --------------------- #
 424 # Checks for programs.  #
 425 # --------------------- #
 426
 427 AC_PROG_AWK
 428 AC_PROG_INSTALL
 429 AC_PROG_LN_S
 430 AC_PROG_RANLIB
 431 AC_PROG_YACC
 432
 433 AC_CHECK_TOOL(AR, ar)
 434 AC_CHECK_TOOL(DLLTOOL, dlltool)
 435 AC_CHECK_TOOL(WINDRES, windres)
 436
 437 # Needed for GNU/Hurd.
 438 AC_CHECK_TOOL(MIG, mig)
 439
 440 # ---------------------- #
 441 # Checks for libraries.  #
 442 # ---------------------- #
 443
 444 # We might need to link with -lm; most simulators need it.
 445 AC_CHECK_LIB(m, main)
 446
 447 # We need to link with -lw to get `wctype' on Solaris before Solaris
 448 # 2.6.  Solaris 2.6 and beyond have this function in libc, and have a
 449 # libw that some versions of the GNU linker cannot hanle (GNU ld 2.9.1
 450 # is known to have this problem).  Therefore we avoid libw if we can.
 451 AC_CHECK_FUNC(wctype, [],
 452   [AC_CHECK_LIB(w, wctype)])
 453
 454 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 455 AC_SEARCH_LIBS(gethostbyname, nsl)
 456
 457 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 458 AC_SEARCH_LIBS(socketpair, socket)
 459
 460 # Link in zlib if we can.  This allows us to read compressed debug sections.
 461 AM_ZLIB
 462
 463 # On HP/UX we may need libxpdl for dlgetmodinfo (used by solib-pa64.c).
 464 AC_SEARCH_LIBS(dlgetmodinfo, [dl xpdl])
 465
 466 AM_ICONV
 467
 468 # GDB may fork/exec the iconv program to get the list of supported character
 469 # sets.  Allow the user to specify where to find it.
 470 # There are several factors affecting the choice of option name:
 471 # - There is already --with-libiconv-prefix but we can't use it, it specifies
 472 #   the build-time location of libiconv files.
 473 # - The program we need to find is iconv, which comes with glibc.  The user
 474 #   doesn't necessarily have libiconv installed.  Therefore naming this
 475 #   --with-libiconv-foo feels wrong.
 476 # - We want the path to be relocatable, but GDB_AC_DEFINE_RELOCATABLE is
 477 #   defined to work on directories not files (though it really doesn't know
 478 #   the difference).
 479 # - Calling this --with-iconv-prefix is perceived to cause too much confusion
 480 #   with --with-libiconv-prefix.
 481 # Putting these together is why the option name is --with-iconv-bin.
 482
 483 AC_ARG_WITH(iconv-bin,
 484 AS_HELP_STRING([--with-iconv-bin=PATH], [specify where to find the iconv program]),
 485 [iconv_bin="${withval}"
 486  AC_DEFINE_UNQUOTED([ICONV_BIN], ["${iconv_bin}"],
 487                     [Path of directory of iconv program.])
 488  GDB_AC_DEFINE_RELOCATABLE(ICONV_BIN, iconv, ${iconv_bin})
 489 ])
 490
 491 # On alpha-osf, it appears that libtermcap and libcurses are not compatible.
 492 # There is a very specific comment in /usr/include/curses.h explaining that
 493 # termcap routines built into libcurses must not be used.
 494 #
 495 # The symptoms we observed so far is GDB unexpectedly changing
 496 # the terminal settings when tgetent is called - this is particularly
 497 # visible as the output is missing carriage returns, and so rapidly
 498 # becomes very hard to read.
 499 #
 500 # The readline configure script has already decided that libtermcap
 501 # was enough for its purposes, and so decided to build readline using
 502 # libtermcap.  Since the TUI mode requires curses, building GDB with
 503 # TUI enabled results in both libraries to be used at the same time,
 504 # which is not allowed.  This basically means that GDB with TUI is
 505 # broken on alpha-osf.
 506
 507 case $host_os in
 508   osf* )
 509     if test x"$enable_tui" = xyes; then
 510       AC_MSG_ERROR([Building GDB with TUI mode is not supported on this host])
 511     fi
 512     if test x"$enable_tui" = xauto; then
 513       enable_tui=no
 514     fi
 515     ;;
 516 esac
 517
 518 # For the TUI, we need enhanced curses functionality.
 519 if test x"$enable_tui" != xno; then
 520   prefer_curses=yes
 521 fi
 522
 523 curses_found=no
 524 if test x"$prefer_curses" = xyes; then
 525   # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
 526   # curses library because the latter might not provide all the
 527   # functionality we need.  However, this leads to problems on systems
 528   # where the linker searches /usr/local/lib, but the compiler doesn't
 529   # search /usr/local/include, if ncurses is installed in /usr/local.  A
 530   # default installation of ncurses on alpha*-dec-osf* will lead to such
 531   # a situation.
 532   AC_SEARCH_LIBS(waddstr, [ncurses cursesX curses])
 533
 534   if test "$ac_cv_search_waddstr" != no; then
 535     curses_found=yes
 536   fi
 537 fi
 538
 539 # Check whether we should enable the TUI, but only do so if we really
 540 # can.
 541 if test x"$enable_tui" != xno; then
 542   if test -d $srcdir/tui; then
 543     if test "$curses_found" != no; then
 544       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
 545       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
 546       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
 547       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
 548       CONFIG_ALL="${CONFIG_ALL} all-tui"
 549       CONFIG_CLEAN="${CONFIG_CLEAN} clean-tui"
 550       CONFIG_INSTALL="${CONFIG_INSTALL} install-tui"
 551       CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-tui"
 552     else
 553       if test x"$enable_tui" = xyes; then
 554         AC_MSG_ERROR([no enhanced curses library found; disable TUI])
 555       else
 556         AC_MSG_WARN([no enhanced curses library found; disabling TUI])
 557       fi
 558     fi
 559   fi
 560 fi
 561
 562 # Since GDB uses Readline, we need termcap functionality.  In many
 563 # cases this will be provided by the curses library, but some systems
 564 # have a seperate termcap library, or no curses library at all.
 565
 566 case $host_os in
 567   cygwin*)
 568     if test -d $srcdir/libtermcap; then
 569       LIBS="../libtermcap/libtermcap.a $LIBS"
 570       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 571     fi ;;
 572   go32* | *djgpp*)
 573     ac_cv_search_tgetent="none required"
 574     ;;
 575   *mingw32*)
 576     ac_cv_search_tgetent="none required"
 577     CONFIG_OBS="$CONFIG_OBS windows-termcap.o"
 578     ;;
 579 esac
 580
 581 # These are the libraries checked by Readline.
 582 AC_SEARCH_LIBS(tgetent, [termcap tinfo curses ncurses])
 583
 584 if test "$ac_cv_search_tgetent" = no; then
 585   AC_MSG_ERROR([no termcap library found])
 586 fi
 587
 588 AC_ARG_WITH([system-readline],
 589   [AS_HELP_STRING([--with-system-readline],
 590                   [use installed readline library])])
 591
 592 if test "$with_system_readline" = yes; then
 593   READLINE=-lreadline
 594   READLINE_DEPS=
 595   READLINE_CFLAGS=
 596   READLINE_TEXI_INCFLAG=
 597 else
 598   READLINE='$(READLINE_DIR)/libreadline.a'
 599   READLINE_DEPS='$(READLINE)'
 600   READLINE_CFLAGS='-I$(READLINE_SRC)/..'
 601   READLINE_TEXI_INCFLAG='-I $(READLINE_DIR)'
 602 fi
 603 AC_SUBST(READLINE)
 604 AC_SUBST(READLINE_DEPS)
 605 AC_SUBST(READLINE_CFLAGS)
 606 AC_SUBST(READLINE_TEXI_INCFLAG)
 607
 608 AC_ARG_WITH(expat,
 609   AS_HELP_STRING([--with-expat], [include expat support (auto/yes/no)]),
 610   [], [with_expat=auto])
 611 AC_MSG_CHECKING([whether to use expat])
 612 AC_MSG_RESULT([$with_expat])
 613
 614 if test "${with_expat}" = no; then
 615   AC_MSG_WARN([expat support disabled; some features may be unavailable.])
 616   HAVE_LIBEXPAT=no
 617 else
 618   AC_LIB_HAVE_LINKFLAGS([expat], [], [#include "expat.h"],
 619                         [XML_Parser p = XML_ParserCreate (0);])
 620   if test "$HAVE_LIBEXPAT" != yes; then
 621     if test "$with_expat" = yes; then
 622       AC_MSG_ERROR([expat is missing or unusable])
 623     else
 624       AC_MSG_WARN([expat is missing or unusable; some features may be unavailable.])
 625     fi
 626   else
 627     save_LIBS=$LIBS
 628     LIBS="$LIBS $LIBEXPAT"
 629     AC_CHECK_FUNCS(XML_StopParser)
 630     LIBS=$save_LIBS
 631   fi
 632 fi
 633
 634 dnl Utility to simplify finding libpython.
 635 dnl $1 = pythonX.Y
 636 dnl $2 = the shell variable to assign the result to
 637 dnl      If libpython is found we store $version here.
 638 dnl $3 = additional flags to add to CPPFLAGS
 639 dnl $4 = additional flags to add to LIBS
 640
 641 AC_DEFUN([AC_TRY_LIBPYTHON],
 642 [
 643   version=$1
 644   define([have_libpython_var],$2)
 645   new_CPPFLAGS=$3
 646   new_LIBS=$4
 647   AC_MSG_CHECKING([for ${version}])
 648   save_CPPFLAGS=$CPPFLAGS
 649   save_LIBS=$LIBS
 650   CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
 651   LIBS="$LIBS $new_LIBS"
 652   found_usable_python=no
 653   AC_LINK_IFELSE(AC_LANG_PROGRAM([[#include "Python.h"]],
 654                                  [[Py_Initialize ();]]),
 655                  [have_libpython_var=${version}
 656                   found_usable_python=yes
 657                   PYTHON_CPPFLAGS=$new_CPPFLAGS
 658                   PYTHON_LIBS=$new_LIBS])
 659   CPPFLAGS=$save_CPPFLAGS
 660   LIBS=$save_LIBS
 661   AC_MSG_RESULT([${found_usable_python}])
 662 ])
 663
 664 dnl There are several different values for --with-python:
 665 dnl
 666 dnl no -   Don't include python support.
 667 dnl yes -  Include python support, error if it's missing.
 668 dnl        If we find python in $PATH, use it to fetch configure options,
 669 dnl        otherwise assume the compiler can find it with no help from us.
 670 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 671 dnl auto - Same as "yes", but if python is missing from the system,
 672 dnl        fall back to "no".
 673 dnl /path/to/python/exec-prefix -
 674 dnl        Use the python located in this directory.
 675 dnl        If /path/to/python/exec-prefix/bin/python exists, use it to find
 676 dnl        the compilation parameters.  Otherwise use
 677 dnl        -I/path/to/python/exec-prefix/include,
 678 dnl        -L/path/to/python/exec-prefix/lib.
 679 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 680 dnl        NOTE: This case is historical.  It is what was done for 7.0/7.1
 681 dnl        but is deprecated.
 682 dnl /path/to/python/executable -
 683 dnl        Run python-config.py with this version of python to fetch the
 684 dnl        compilation parameters.
 685 dnl        NOTE: This needn't be the real python executable.
 686 dnl        In a cross-compilation scenario (build != host), this could be
 687 dnl        a shell script that provides what python-config.py provides for
 688 dnl        --ldflags, --includes, --exec-prefix.
 689 dnl python-executable -
 690 dnl        Find python-executable in $PATH, and then handle the same as
 691 dnl        /path/to/python/executable.
 692 dnl
 693 dnl If a python program is specified, it is used to run python-config.py and
 694 dnl is passed --ldflags, --includes, --exec-prefix.
 695
 696 AC_ARG_WITH(python,
 697   AS_HELP_STRING([--with-python@<:@=PYTHON@:>@], [include python support (auto/yes/no/<python-program>)]),
 698   [], [with_python=auto])
 699 AC_MSG_CHECKING([whether to use python])
 700 AC_MSG_RESULT([$with_python])
 701
 702 if test "${with_python}" = no; then
 703   AC_MSG_WARN([python support disabled; some features may be unavailable.])
 704   have_libpython=no
 705 else
 706   case "${with_python}" in
 707   /*)
 708     if test -d ${with_python}; then
 709       # Assume the python binary is ${with_python}/bin/python.
 710       python_prog="${with_python}/bin/python"
 711       python_prefix=
 712       # If python does not exit ${with_python}/bin, then try in
 713       # ${with_python}.  On Windows/MinGW, this is where the Python
 714       # executable is.
 715       if test ! -x "${python_prog}"; then
 716         python_prog="${with_python}/python"
 717         python_prefix=
 718       fi
 719       if test ! -x "${python_prog}"; then
 720         # Fall back to gdb 7.0/7.1 behaviour.
 721         python_prog=missing
 722         python_prefix=${with_python}
 723       fi
 724     elif test -x "${with_python}"; then
 725       # While we can't run python compiled for $host (unless host == build),
 726       # the user could write a script that provides the needed information,
 727       # so we support that.
 728       python_prog=${with_python}
 729       python_prefix=
 730     else
 731       AC_ERROR(invalid value for --with-python)
 732     fi
 733     ;;
 734   */*)
 735     # Disallow --with-python=foo/bar.
 736     AC_ERROR(invalid value for --with-python)
 737     ;;
 738   *)
 739     # The user has either specified auto, yes, or the name of the python
 740     # program assumed to be in $PATH.
 741     python_prefix=
 742     case "${with_python}" in
 743     yes | auto)
 744       if test ${build} = ${host}; then
 745         AC_PATH_PROG(python_prog_path, python, missing)
 746         if test "${python_prog_path}" = missing; then
 747           python_prog=missing
 748         else
 749           python_prog=${python_prog_path}
 750         fi
 751       else
 752         # Not much we can do except assume the cross-compiler will find the
 753         # right files.
 754         python_prog=missing
 755       fi
 756       ;;
 757     *)
 758       # While we can't run python compiled for $host (unless host == build),
 759       # the user could write a script that provides the needed information,
 760       # so we support that.
 761       python_prog="${with_python}"
 762       AC_PATH_PROG(python_prog_path, ${python_prog}, missing)
 763       if test "${python_prog_path}" = missing; then
 764         AC_ERROR(unable to find python program ${python_prog})
 765       fi
 766       ;;
 767     esac
 768   esac
 769
 770   if test "${python_prog}" != missing; then
 771     # We have a python program to use, but it may be too old.
 772     # Don't flag an error for --with-python=auto (the default).
 773     have_python_config=yes
 774     python_includes=`${python_prog} ${srcdir}/python/python-config.py --includes`
 775     if test $? != 0; then
 776       have_python_config=failed
 777       if test "${with_python}" != auto; then
 778         AC_ERROR(failure running python-config --includes)
 779       fi
 780     fi
 781     python_libs=`${python_prog} ${srcdir}/python/python-config.py --ldflags`
 782     if test $? != 0; then
 783       have_python_config=failed
 784       if test "${with_python}" != auto; then
 785         AC_ERROR(failure running python-config --ldflags)
 786       fi
 787     fi
 788     python_prefix=`${python_prog} ${srcdir}/python/python-config.py --exec-prefix`
 789     if test $? != 0; then
 790       have_python_config=failed
 791       if test "${with_python}" != auto; then
 792         AC_ERROR(failure running python-config --exec-prefix)
 793       fi
 794     fi
 795   else
 796     # We do not have a python executable we can use to determine where
 797     # to find the Python headers and libs.  We cannot guess the include
 798     # path from the python_prefix either, because that include path
 799     # depends on the Python version.  So, there is nothing much we can
 800     # do except assume that the compiler will be able to find those files.
 801     python_includes=
 802     python_libs=
 803     have_python_config=no
 804   fi
 805
 806   # If we have python-config, only try the configuration it provides.
 807   # Otherwise fallback on the old way of trying different versions of
 808   # python in turn.
 809
 810   have_libpython=no
 811   if test "${have_python_config}" = yes; then
 812     # Determine the Python version by extracting "-lpython<version>"
 813     # part of the python_libs. <version> is usually X.Y with X and Y
 814     # being decimal numbers, but can also be XY (seen on Windows).
 815     #
 816     # The extraction is performed using sed with a regular expression.
 817     # Initially, the regexp used was using the '?' quantifier to make
 818     # the dot in the version number optional.  Unfortunately, this
 819     # does not work with non-GNU versions of sed because, because of
 820     # what looks like a limitation (the '?' quantifier does not work
 821     # with back-references).  We work around this limitation by using
 822     # the '*' quantifier instead.  It means that, in theory, we might
 823     # match unexpected version strings such as "-lpython2..7", but
 824     # this seems unlikely in practice.  And even if that happens,
 825     # an error will be triggered later on, when checking that version
 826     # number.
 827     python_version=`echo " ${python_libs} " \
 828                          | sed -e 's,^.* -l\(python[[0-9]]*[[.]]*[[0-9]]*\).*$,\1,'`
 829     case "${python_version}" in
 830     python*)
 831       AC_TRY_LIBPYTHON(${python_version}, have_libpython,
 832                        ${python_includes}, ${python_libs})
 833       ;;
 834     *)
 835       AC_MSG_ERROR([unable to determine python version from ${python_libs}])
 836       ;;
 837     esac
 838   elif test "${have_python_config}" != failed; then
 839     if test "${have_libpython}" = no; then
 840       AC_TRY_LIBPYTHON(python2.7, have_libpython,
 841                        ${python_includes}, "${python_libs} -lpython2.7")
 842     fi
 843     if test "${have_libpython}" = no; then
 844       AC_TRY_LIBPYTHON(python2.6, have_libpython,
 845                        ${python_includes}, "${python_libs} -lpython2.6")
 846     fi
 847     if test ${have_libpython} = no; then
 848       AC_TRY_LIBPYTHON(python2.5, have_libpython,
 849                        ${python_includes}, "${python_libs} -lpython2.5")
 850     fi
 851     if test ${have_libpython} = no; then
 852       AC_TRY_LIBPYTHON(python2.4, have_libpython,
 853                        ${python_includes}, "${python_libs} -lpython2.4")
 854     fi
 855   fi
 856   if test "${have_libpython}" = python2.7 -o "${have_libpython}" = python27; then
 857     AC_DEFINE(HAVE_LIBPYTHON2_7, 1, [Define if Python 2.7 is being used.])
 858   elif test "${have_libpython}" = python2.6 -o "${have_libpython}" = python26; then
 859     AC_DEFINE(HAVE_LIBPYTHON2_6, 1, [Define if Python 2.6 is being used.])
 860   elif test "${have_libpython}" = python2.5 -o "${have_libpython}" = python25; then
 861     AC_DEFINE(HAVE_LIBPYTHON2_5, 1, [Define if Python 2.5 is being used.])
 862   elif test "${have_libpython}" = python2.4 -o "${have_libpython}" = python24; then
 863     AC_DEFINE(HAVE_LIBPYTHON2_4, 1, [Define if Python 2.4 is being used.])
 864   fi
 865
 866   if test "${have_libpython}" = no; then
 867     case "${with_python}" in
 868     yes)
 869       AC_MSG_ERROR([python is missing or unusable])
 870       ;;
 871     auto)
 872       AC_MSG_WARN([python is missing or unusable; some features may be unavailable.])
 873       ;;
 874     *)
 875       AC_MSG_ERROR([no usable python found at ${with_python}])
 876       ;;
 877     esac
 878   else
 879     if test -n "${python_prefix}"; then
 880       AC_DEFINE_UNQUOTED(WITH_PYTHON_PATH, "${python_prefix}",
 881                          [Define if --with-python provides a path, either directly or via python-config.py --exec-prefix.])
 882       GDB_AC_DEFINE_RELOCATABLE(PYTHON_PATH, python, ${python_prefix})
 883     fi
 884   fi
 885 fi
 886
 887 if test "${have_libpython}" != no; then
 888   AC_DEFINE(HAVE_PYTHON, 1, [Define if Python interpreter is being linked in.])
 889   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_PYTHON_OBS)"
 890   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_PYTHON_DEPS)"
 891   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_PYTHON_SRCS)"
 892   CONFIG_INSTALL="$CONFIG_INSTALL install-python"
 893   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_PYTHON_CFLAGS)"
 894
 895   # Flags needed to compile Python code (taken from python-config --cflags).
 896   # We cannot call python-config directly because it will output whatever was
 897   # used when compiling the Python interpreter itself, including flags which
 898   # would make the python-related objects be compiled differently from the
 899   # rest of GDB (e.g., -O2 and -fPIC).
 900   if test "${GCC}" = yes; then
 901     tentative_python_cflags="-fno-strict-aliasing -DNDEBUG -fwrapv"
 902   fi
 903
 904   if test "x${tentative_python_cflags}" != x; then
 905     AC_MSG_CHECKING(compiler flags for python code)
 906     for flag in ${tentative_python_cflags}; do
 907       # Check that the compiler accepts it
 908       saved_CFLAGS="$CFLAGS"
 909       CFLAGS="$CFLAGS $flag"
 910       AC_TRY_COMPILE([],[],PYTHON_CFLAGS="${PYTHON_CFLAGS} $flag",)
 911       CFLAGS="$saved_CFLAGS"
 912     done
 913     AC_MSG_RESULT(${PYTHON_CFLAGS})
 914   fi
 915
 916   # On IRIX, type siginfo is not defined.  Instead, sys/siginfo.h provides:
 917   #    #if _SGIAPI
 918   #    #define siginfo __siginfo
 919   #    #endif
 920   # The problem is that including Python causes some XOPEN macros to be
 921   # unilaterally defined, and that in turn causes _SGIAPI to evaluate
 922   # to false.  So, we work around this issue by defining siginfo ourself
 923   # though the command-line.
 924   case "$gdb_host" in
 925     irix*) if test "${GCC}" = yes; then
 926              CPPFLAGS="$CPPFLAGS -Dsiginfo=__siginfo"
 927            fi
 928            ;;
 929   esac
 930 else
 931   # Even if Python support is not compiled in, we need to have these files
 932   # included.
 933   CONFIG_OBS="$CONFIG_OBS python.o py-value.o py-prettyprint.o py-auto-load.o"
 934   CONFIG_SRCS="$CONFIG_SRCS python/python.c python/py-value.c \
 935         python/py-prettyprint.c python/py-auto-load.c"
 936 fi
 937 AC_SUBST(PYTHON_CFLAGS)
 938 AC_SUBST(PYTHON_CPPFLAGS)
 939 AC_SUBST(PYTHON_LIBS)
 940
 941 # ------------------------- #
 942 # Checks for header files.  #
 943 # ------------------------- #
 944
 945 AC_HEADER_DIRENT
 946 AC_HEADER_STAT
 947 AC_HEADER_STDC
 948 # elf_hp.h is for HP/UX 64-bit shared library support.
 949 # FIXME: kettenis/20030102: In most cases we include these (ctype.h, time.h)
 950 # unconditionally, so what's the point in checking these?
 951 AC_CHECK_HEADERS([nlist.h machine/reg.h poll.h sys/poll.h proc_service.h \
 952                   thread_db.h gnu/libc-version.h signal.h stddef.h \
 953                   stdlib.h string.h memory.h strings.h sys/fault.h \
 954                   sys/file.h sys/filio.h sys/ioctl.h sys/param.h \
 955                   sys/resource.h sys/procfs.h sys/ptrace.h ptrace.h \
 956                   sys/reg.h sys/debugreg.h sys/select.h sys/syscall.h \
 957                   sys/types.h sys/wait.h wait.h termios.h termio.h \
 958                   sgtty.h unistd.h elf_hp.h ctype.h time.h locale.h])
 959 AC_CHECK_HEADERS(link.h, [], [],
 960 [#if HAVE_SYS_TYPES_H
 961 # include <sys/types.h>
 962 #endif
 963 #if HAVE_NLIST_H
 964 # include <nlist.h>
 965 #endif
 966 ])
 967 AC_CHECK_HEADERS(sys/proc.h, [], [],
 968 [#if HAVE_SYS_PARAM_H
 969 # include <sys/param.h>
 970 #endif
 971 ])
 972 AC_CHECK_HEADERS(sys/user.h, [], [],
 973 [#if HAVE_SYS_PARAM_H
 974 # include <sys/param.h>
 975 #endif
 976 ])
 977
 978 # On Solaris 2.[789], we need to define _MSE_INT_H to avoid a clash
 979 # between <widec.h> and <wchar.h> that would cause AC_CHECK_HEADERS to
 980 # think that we don't have <curses.h> if we're using GCC.
 981 case $host_os in
 982   solaris2.[[789]])
 983     if test "$GCC" = yes; then
 984       AC_DEFINE(_MSE_INT_H, 1,
 985         [Define to 1 to avoid a clash between <widec.h> and <wchar.h> on
 986    Solaris 2.[789] when using GCC. ])
 987     fi ;;
 988 esac
 989 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncurses/ncurses.h ncurses/term.h)
 990 AC_CHECK_HEADERS(term.h, [], [],
 991 [#if HAVE_CURSES_H
 992 # include <curses.h>
 993 #endif
 994 ])
 995
 996 # ------------------------- #
 997 # Checks for declarations.  #
 998 # ------------------------- #
 999
1000 AC_CHECK_DECLS([free, malloc, realloc, strerror, strstr, getopt,
1001                 snprintf, vsnprintf])
1002 AM_LC_MESSAGES
1003
1004 # ----------------------- #
1005 # Checks for structures.  #
1006 # ----------------------- #
1007
1008 AC_CHECK_MEMBERS([struct stat.st_blocks, struct stat.st_blksize])
1009
1010 # ------------------ #
1011 # Checks for types.  #
1012 # ------------------ #
1013
1014 AC_TYPE_SIGNAL
1015 AC_CHECK_TYPES(socklen_t, [], [],
1016 [#include <sys/types.h>
1017 #include <sys/socket.h>
1018 ])
1019
1020 # ------------------------------------- #
1021 # Checks for compiler characteristics.  #
1022 # ------------------------------------- #
1023
1024 AC_C_CONST
1025 AC_C_INLINE
1026 AC_C_BIGENDIAN
1027
1028 # ------------------------------ #
1029 # Checks for library functions.  #
1030 # ------------------------------ #
1031
1032 AC_FUNC_ALLOCA
1033 AC_FUNC_MMAP
1034 AC_FUNC_VFORK
1035 AC_CHECK_FUNCS([canonicalize_file_name realpath getrusage getuid \
1036                 getgid pipe poll pread64 resize_term sbrk setpgid setpgrp setsid \
1037                 sigaction sigprocmask sigsetmask socketpair syscall \
1038                 ttrace wborder wresize setlocale iconvlist libiconvlist btowc \
1039                 setrlimit getrlimit posix_madvise waitpid])
1040 AM_LANGINFO_CODESET
1041
1042 # Check the return and argument types of ptrace.  No canned test for
1043 # this, so roll our own.
1044 gdb_ptrace_headers='
1045 #if HAVE_SYS_TYPES_H
1046 # include <sys/types.h>
1047 #endif
1048 #if HAVE_SYS_PTRACE_H
1049 # include <sys/ptrace.h>
1050 #endif
1051 #if HAVE_UNISTD_H
1052 # include <unistd.h>
1053 #endif
1054 '
1055 # There is no point in checking if we don't have a prototype.
1056 AC_CHECK_DECLS(ptrace, [], [
1057   : ${gdb_cv_func_ptrace_ret='int'}
1058   : ${gdb_cv_func_ptrace_args='int,int,long,long'}
1059 ], $gdb_ptrace_headers)
1060 # Check return type.  Varargs (used on GNU/Linux) conflict with the
1061 # empty argument list, so check for that explicitly.
1062 AC_CACHE_CHECK([return type of ptrace], gdb_cv_func_ptrace_ret,
1063   AC_TRY_COMPILE($gdb_ptrace_headers,
1064     [extern long ptrace (enum __ptrace_request, ...);],
1065     gdb_cv_func_ptrace_ret='long',
1066     AC_TRY_COMPILE($gdb_ptrace_headers,
1067       [extern int ptrace ();],
1068       gdb_cv_func_ptrace_ret='int',
1069       gdb_cv_func_ptrace_ret='long')))
1070 AC_DEFINE_UNQUOTED(PTRACE_TYPE_RET, $gdb_cv_func_ptrace_ret,
1071   [Define as the return type of ptrace.])
1072 # Check argument types.
1073 AC_CACHE_CHECK([types of arguments for ptrace], gdb_cv_func_ptrace_args, [
1074   AC_TRY_COMPILE($gdb_ptrace_headers,
1075     [extern long ptrace (enum __ptrace_request, ...);],
1076     [gdb_cv_func_ptrace_args='int,int,long,long'],[
1077 for gdb_arg1 in 'int' 'long'; do
1078  for gdb_arg2 in 'pid_t' 'int' 'long'; do
1079   for gdb_arg3 in 'int *' 'caddr_t' 'int' 'long' 'void *'; do
1080    for gdb_arg4 in 'int' 'long'; do
1081      AC_TRY_COMPILE($gdb_ptrace_headers, [
1082 extern $gdb_cv_func_ptrace_ret
1083   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4);
1084 ], [gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4";
1085     break 4;])
1086     for gdb_arg5 in 'int *' 'int' 'long'; do
1087      AC_TRY_COMPILE($gdb_ptrace_headers, [
1088 extern $gdb_cv_func_ptrace_ret
1089   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4, $gdb_arg5);
1090 ], [
1091 gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4,$gdb_arg5";
1092     break 5;])
1093     done
1094    done
1095   done
1096  done
1097 done
1098 # Provide a safe default value.
1099 : ${gdb_cv_func_ptrace_args='int,int,long,long'}
1100 ])])
1101 ac_save_IFS=$IFS; IFS=','
1102 set dummy `echo "$gdb_cv_func_ptrace_args" | sed 's/\*/\*/g'`
1103 IFS=$ac_save_IFS
1104 shift
1105 AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG3, $[3],
1106   [Define to the type of arg 3 for ptrace.])
1107 if test -n "$[5]"; then
1108   AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG5, $[5],
1109     [Define to the type of arg 5 for ptrace.])
1110 fi
1111
1112 dnl AC_FUNC_SETPGRP does not work when cross compiling
1113 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
1114 if test "$cross_compiling" = no; then
1115   AC_FUNC_SETPGRP
1116 else
1117   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
1118     [AC_TRY_COMPILE([
1119 #include <unistd.h>
1120 ], [
1121   if (setpgrp(1,1) == -1)
1122     exit (0);
1123   else
1124     exit (1);
1125 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
1126 if test $ac_cv_func_setpgrp_void = yes; then
1127   AC_DEFINE(SETPGRP_VOID, 1)
1128 fi
1129 fi
1130
1131 # Check if sigsetjmp is available.  Using AC_CHECK_FUNCS won't do
1132 # since sigsetjmp might only be defined as a macro.
1133 AC_CACHE_CHECK([for sigsetjmp], gdb_cv_func_sigsetjmp,
1134 [AC_TRY_COMPILE([
1135 #include <setjmp.h>
1136 ], [sigjmp_buf env; while (! sigsetjmp (env, 1)) siglongjmp (env, 1);],
1137 gdb_cv_func_sigsetjmp=yes, gdb_cv_func_sigsetjmp=no)])
1138 if test $gdb_cv_func_sigsetjmp = yes; then
1139   AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available. ])
1140 fi
1141
1142 # Assume we'll default to using the included libiberty regex.
1143 gdb_use_included_regex=yes
1144
1145 # However, if the system regex is GNU regex, then default to *not*
1146 # using the included regex.
1147 AC_CACHE_CHECK(
1148   [for GNU regex],
1149   [gdb_cv_have_gnu_regex],
1150   [AC_TRY_COMPILE(
1151     [#include <gnu-versions.h>],
1152     [#define REGEX_INTERFACE_VERSION 1
1153 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
1154 # error "Version mismatch"
1155 #endif],
1156     gdb_cv_have_gnu_regex=yes,
1157     gdb_cv_have_gnu_regex=no)])
1158 if test $gdb_cv_have_gnu_regex = yes; then
1159   gdb_use_included_regex=no
1160 fi
1161
1162 AC_ARG_WITH(included-regex,
1163   AS_HELP_STRING([--without-included-regex], [don't use included regex; this is the default on systems with version 2 of the GNU C library (use with caution on other system)]),
1164   gdb_with_regex=$withval,
1165   gdb_with_regex=$gdb_use_included_regex)
1166 if test "$gdb_with_regex" = yes; then
1167   AC_DEFINE(USE_INCLUDED_REGEX, 1,
1168     [Define to 1 if the regex included in libiberty should be used.])
1169 fi
1170
1171 # Check if <sys/proc.h> defines `struct thread' with a td_pcb member.
1172 AC_CHECK_MEMBERS([struct thread.td_pcb], [], [],
1173 [#include <sys/param.h>
1174 #include <sys/proc.h>
1175 ])
1176
1177 # See if <sys/lwp.h> defines `struct lwp`.
1178 AC_CACHE_CHECK([for struct lwp], gdb_cv_struct_lwp,
1179 [AC_TRY_COMPILE([#include <sys/param.h>
1180 #include <sys/lwp.h>], [struct lwp l;],
1181 gdb_cv_struct_lwp=yes, gdb_cv_struct_lwp=no)])
1182 if test $gdb_cv_struct_lwp = yes; then
1183   AC_DEFINE(HAVE_STRUCT_LWP, 1,
1184             [Define to 1 if your system has struct lwp.])
1185 fi
1186
1187 # See if <machine/reg.h> degines `struct reg'.
1188 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
1189 [AC_TRY_COMPILE([#include <sys/types.h>
1190 #include <machine/reg.h>], [struct reg r;],
1191 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
1192 if test $gdb_cv_struct_reg = yes; then
1193   AC_DEFINE(HAVE_STRUCT_REG, 1,
1194             [Define to 1 if your system has struct reg in <machine/reg.h>.])
1195 fi
1196
1197 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
1198 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
1199 AC_CHECK_MEMBERS([struct reg.r_fs, struct reg.r_gs], [], [],
1200                  [#include <machine/reg.h>])
1201
1202 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
1203 AC_MSG_CHECKING(for PTRACE_GETREGS)
1204 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
1205 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1206                 [PTRACE_GETREGS;],
1207                 [gdb_cv_have_ptrace_getregs=yes],
1208                 [gdb_cv_have_ptrace_getregs=no])])
1209 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
1210 if test $gdb_cv_have_ptrace_getregs = yes; then
1211   AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
1212   [Define if sys/ptrace.h defines the PTRACE_GETREGS request.])
1213 fi
1214
1215 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
1216 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
1217 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
1218 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1219                 [PTRACE_GETFPXREGS;],
1220                 [gdb_cv_have_ptrace_getfpxregs=yes],
1221                 [gdb_cv_have_ptrace_getfpxregs=no])])
1222 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
1223 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
1224   AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
1225   [Define if sys/ptrace.h defines the PTRACE_GETFPXREGS request.])
1226 fi
1227
1228 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
1229 AC_MSG_CHECKING(for PT_GETDBREGS)
1230 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
1231 [AC_TRY_COMPILE([#include <sys/types.h>
1232 #include <sys/ptrace.h>],
1233                 [PT_GETDBREGS;],
1234                 [gdb_cv_have_pt_getdbregs=yes],
1235                 [gdb_cv_have_pt_getdbregs=no])])
1236 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
1237 if test $gdb_cv_have_pt_getdbregs = yes; then
1238   AC_DEFINE(HAVE_PT_GETDBREGS, 1,
1239   [Define if sys/ptrace.h defines the PT_GETDBREGS request.])
1240 fi
1241
1242 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
1243 AC_MSG_CHECKING(for PT_GETXMMREGS)
1244 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
1245 [AC_TRY_COMPILE([#include <sys/types.h>
1246 #include <sys/ptrace.h>],
1247                 [PT_GETXMMREGS;],
1248                 [gdb_cv_have_pt_getxmmregs=yes],
1249                 [gdb_cv_have_pt_getxmmregs=no])])
1250 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
1251 if test $gdb_cv_have_pt_getxmmregs = yes; then
1252   AC_DEFINE(HAVE_PT_GETXMMREGS, 1,
1253   [Define if sys/ptrace.h defines the PT_GETXMMREGS request.])
1254 fi
1255
1256 # Detect which type of /proc is in use, such as for Unixware or Solaris.
1257
1258 if test "${target}" = "${host}"; then
1259   case "${host}" in
1260   *-*-unixware* | *-*-sysv4.2* | *-*-sysv5* | *-*-interix* )
1261       AC_DEFINE(NEW_PROC_API, 1,
1262       [Define if you want to use new multi-fd /proc interface
1263        (replaces HAVE_MULTIPLE_PROC_FDS as well as other macros).])
1264       ;;
1265   *-*-solaris2.[[6789]] | *-*-solaris2.1[[0-9]]*)
1266       AC_DEFINE(NEW_PROC_API, 1,
1267       [Define if you want to use new multi-fd /proc interface
1268        (replaces HAVE_MULTIPLE_PROC_FDS as well as other macros).])
1269       ;;
1270   mips-sgi-irix5*)
1271       # Work around <sys/proc.h> needing _KMEMUSER problem on IRIX 5.
1272       AC_DEFINE([_KMEMUSER], 1,
1273       [Define to 1 so <sys/proc.h> gets a definition of anon_hdl.  Works
1274        around a <sys/proc.h> problem on IRIX 5.])
1275       ;;
1276   esac
1277 fi
1278
1279 if test "$ac_cv_header_sys_procfs_h" = yes; then
1280   BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
1281   BFD_HAVE_SYS_PROCFS_TYPE(prrun_t)
1282   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
1283   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
1284   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
1285   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
1286   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
1287   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset32_t)
1288   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
1289   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
1290   BFD_HAVE_SYS_PROCFS_TYPE(prsysent_t)
1291   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigset_t)
1292   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigaction64_t)
1293   BFD_HAVE_SYS_PROCFS_TYPE(pr_siginfo64_t)
1294
1295
1296   dnl Check for broken prfpregset_t type
1297
1298   dnl For Linux/i386, glibc 2.1.3 was released with a bogus
1299   dnl prfpregset_t type (it's a typedef for the pointer to a struct
1300   dnl instead of the struct itself).  We detect this here, and work
1301   dnl around it in gdb_proc_service.h.
1302
1303   if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
1304     AC_MSG_CHECKING(whether prfpregset_t type is broken)
1305     AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
1306       [AC_TRY_RUN([#include <sys/procfs.h>
1307        int main ()
1308        {
1309          if (sizeof (prfpregset_t) == sizeof (void *))
1310            return 1;
1311          return 0;
1312        }],
1313        gdb_cv_prfpregset_t_broken=no,
1314        gdb_cv_prfpregset_t_broken=yes,
1315        gdb_cv_prfpregset_t_broken=yes)])
1316     AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
1317     if test $gdb_cv_prfpregset_t_broken = yes; then
1318       AC_DEFINE(PRFPREGSET_T_BROKEN, 1,
1319       [Define if the prfpregset_t type is broken.])
1320     fi
1321   fi
1322
1323   dnl Check for PIOCSET ioctl entry
1324
1325   AC_MSG_CHECKING(for PIOCSET ioctl entry in sys/procfs.h)
1326   AC_CACHE_VAL(gdb_cv_have_procfs_piocset,
1327   [AC_TRY_COMPILE([#include <unistd.h>
1328 #include <sys/types.h>
1329 #include <sys/procfs.h>
1330 ], [
1331     int dummy;;
1332     dummy = ioctl(0, PIOCSET, &dummy);
1333   ],
1334   gdb_cv_have_procfs_piocset=yes, gdb_cv_have_procfs_piocset=no)])
1335   AC_MSG_RESULT($gdb_cv_have_procfs_piocset)
1336   if test $gdb_cv_have_procfs_piocset = yes; then
1337     AC_DEFINE(HAVE_PROCFS_PIOCSET, 1,
1338     [Define if ioctl argument PIOCSET is available.])
1339   fi
1340 fi
1341
1342 dnl For native ports (host == target), check to see what kind of
1343 dnl legacy link.h support is needed.  (See solib-legacy.c.)
1344 if test ${host} = ${target} ; then
1345   dnl Check for struct link_map with l_ members which are indicative
1346   dnl of SVR4-like shared libraries
1347
1348   AC_MSG_CHECKING(for member l_addr in struct link_map)
1349   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_l_members,
1350     [AC_TRY_COMPILE([#include <link.h>],
1351                     [struct link_map lm; (void) lm.l_addr;],
1352                     gdb_cv_have_struct_link_map_with_l_members=yes,
1353                     gdb_cv_have_struct_link_map_with_l_members=no)])
1354   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_l_members)
1355   if test $gdb_cv_have_struct_link_map_with_l_members = yes; then
1356     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_L_MEMBERS,1,
1357     [Define if <link.h> exists and defines struct link_map which has
1358      members with an ``l_'' prefix.  (For Solaris, SVR4, and
1359      SVR4-like systems.)])
1360   fi
1361
1362   dnl Check for struct link_map with lm_ members which are indicative
1363   dnl of SunOS-like shared libraries
1364
1365   AC_MSG_CHECKING(for member lm_addr in struct link_map)
1366   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_lm_members,
1367     [AC_TRY_COMPILE([#include <sys/types.h>
1368 #include <link.h>],
1369                     [struct link_map lm; (void) lm.lm_addr;],
1370                     gdb_cv_have_struct_link_map_with_lm_members=yes,
1371                     gdb_cv_have_struct_link_map_with_lm_members=no)])
1372   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_lm_members)
1373   if test $gdb_cv_have_struct_link_map_with_lm_members = yes; then
1374     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_LM_MEMBERS, 1,
1375     [Define if <link.h> exists and defines struct link_map which has
1376      members with an ``lm_'' prefix.  (For SunOS.)])
1377   fi
1378
1379   dnl Check for struct so_map with som_ members which are found on
1380   dnl some *BSD systems.
1381
1382   AC_MSG_CHECKING(for member som_addr in struct so_map)
1383   AC_CACHE_VAL(gdb_cv_have_struct_so_map_with_som_members,
1384     [AC_TRY_COMPILE([#include <sys/types.h>
1385 #ifdef HAVE_NLIST_H
1386 #include <nlist.h>
1387 #endif
1388 #include <link.h>],
1389                     [struct so_map lm; (void) lm.som_addr;],
1390                     gdb_cv_have_struct_so_map_with_som_members=yes,
1391                     gdb_cv_have_struct_so_map_with_som_members=no)])
1392   AC_MSG_RESULT($gdb_cv_have_struct_so_map_with_som_members)
1393   if test $gdb_cv_have_struct_so_map_with_som_members = yes; then
1394     AC_DEFINE(HAVE_STRUCT_SO_MAP_WITH_SOM_MEMBERS, 1,
1395     [Define if <link.h> exists and defines a struct so_map which has
1396      members with an ``som_'' prefix.  (Found on older *BSD systems.)])
1397   fi
1398
1399   dnl Check for struct link_map32 type, which allows a 64-bit Solaris
1400   dnl debugger to debug a 32-bit Solaris app with 32-bit shared libraries.
1401
1402   AC_MSG_CHECKING(for struct link_map32 in sys/link.h)
1403   AC_CACHE_VAL(gdb_cv_have_struct_link_map32,
1404     [AC_TRY_COMPILE([#define _SYSCALL32
1405 #include <sys/link.h>], [struct link_map32 l;],
1406      gdb_cv_have_struct_link_map32=yes,
1407      gdb_cv_have_struct_link_map32=no)])
1408   AC_MSG_RESULT($gdb_cv_have_struct_link_map32)
1409   if test $gdb_cv_have_struct_link_map32 = yes; then
1410     AC_DEFINE(HAVE_STRUCT_LINK_MAP32, 1,
1411     [Define if <sys/link.h> has struct link_map32])
1412     AC_DEFINE(_SYSCALL32, 1,
1413     [Define if <sys/link.h> has link_map32 (solaris sparc-64 target)])
1414   fi
1415 fi
1416
1417 # Check if the compiler supports the `long long' type.
1418
1419 AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long,
1420                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1421 [[extern long long foo;]],
1422 [[switch (foo & 2) { case 0: return 1; }]])],
1423                                   gdb_cv_c_long_long=yes,
1424                                   gdb_cv_c_long_long=no)])
1425 if test $gdb_cv_c_long_long = yes; then
1426   AC_DEFINE(CC_HAS_LONG_LONG, 1,
1427             [Define to 1 if the compiler supports long long.])
1428 fi
1429
1430 # Check if the compiler and runtime support printing long longs.
1431
1432 AC_CACHE_CHECK([for long long support in printf],
1433                gdb_cv_printf_has_long_long,
1434                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1435 [[char buf[32];
1436   long long l = 0;
1437   l = (l << 16) + 0x0123;
1438   l = (l << 16) + 0x4567;
1439   l = (l << 16) + 0x89ab;
1440   l = (l << 16) + 0xcdef;
1441   sprintf (buf, "0x%016llx", l);
1442   return (strcmp ("0x0123456789abcdef", buf));]])],
1443                               gdb_cv_printf_has_long_long=yes,
1444                               gdb_cv_printf_has_long_long=no,
1445                               gdb_cv_printf_has_long_long=no)])
1446 if test $gdb_cv_printf_has_long_long = yes; then
1447   AC_DEFINE(PRINTF_HAS_LONG_LONG, 1,
1448             [Define to 1 if the "%ll" format works to print long longs.])
1449 fi
1450
1451 # Check if the compiler and runtime support printing decfloats.
1452
1453 AC_CACHE_CHECK([for decfloat support in printf],
1454                gdb_cv_printf_has_decfloat,
1455                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1456 [[char buf[64];
1457   _Decimal32 d32 = 1.2345df;
1458   _Decimal64 d64 = 1.2345dd;
1459   _Decimal128 d128 = 1.2345dl;
1460   sprintf (buf, "Decimal32: %H\nDecimal64: %D\nDecimal128: %DD", d32, d64, d128);
1461   return (strcmp ("Decimal32: 1.2345\nDecimal64: 1.2345\nDecimal128: 1.2345", buf));]])],
1462                               gdb_cv_printf_has_decfloat=yes,
1463                               gdb_cv_printf_has_decfloat=no,
1464                               gdb_cv_printf_has_decfloat=no)])
1465 if test $gdb_cv_printf_has_decfloat = yes; then
1466   AC_DEFINE(PRINTF_HAS_DECFLOAT, 1,
1467             [Define to 1 if the "%H, %D and %DD" formats work to print decfloats.])
1468 fi
1469
1470 # Check if the compiler supports the `long double' type.  We can't use
1471 # AC_C_LONG_DOUBLE because that one does additional checks on the
1472 # constants defined in <float.h> that fail on some systems,
1473 # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6.
1474
1475 AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double,
1476                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])],
1477                                   gdb_cv_c_long_double=yes,
1478                                   gdb_cv_c_long_double=no)])
1479 if test $gdb_cv_c_long_double = yes; then
1480   AC_DEFINE(HAVE_LONG_DOUBLE, 1,
1481            [Define to 1 if the compiler supports long double.])
1482 fi
1483
1484 # Check if the compiler and runtime support printing long doubles.
1485
1486 AC_CACHE_CHECK([for long double support in printf],
1487                gdb_cv_printf_has_long_double,
1488                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1489 [[char buf[16];
1490   long double f = 3.141592653;
1491   sprintf (buf, "%Lg", f);
1492   return (strncmp ("3.14159", buf, 7));]])],
1493                               gdb_cv_printf_has_long_double=yes,
1494                               gdb_cv_printf_has_long_double=no,
1495                               gdb_cv_printf_has_long_double=no)])
1496 if test $gdb_cv_printf_has_long_double = yes; then
1497   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1,
1498             [Define to 1 if the "%Lg" format works to print long doubles.])
1499 fi
1500
1501 # Check if the compiler and runtime support scanning long doubles.
1502
1503 AC_CACHE_CHECK([for long double support in scanf],
1504                gdb_cv_scanf_has_long_double,
1505                [AC_RUN_IFELSE([AC_LANG_PROGRAM(
1506 [[#include <stdio.h>]],
1507 [[char *buf = "3.141592653";
1508   long double f = 0;
1509   sscanf (buf, "%Lg", &f);
1510   return !(f > 3.14159 && f < 3.14160);]])],
1511                               gdb_cv_scanf_has_long_double=yes,
1512                               gdb_cv_scanf_has_long_double=no,
1513                               gdb_cv_scanf_has_long_double=no)])
1514 if test $gdb_cv_scanf_has_long_double = yes; then
1515   AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1,
1516             [Define to 1 if the "%Lg" format works to scan long doubles.])
1517 fi
1518
1519 case ${host_os} in
1520 aix*)
1521   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1522     SAVE_LDFLAGS=$LDFLAGS
1523
1524     case $GCC in
1525     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1526     *) gdb_cv_bigtoc=-bbigtoc ;;
1527     esac
1528
1529     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1530     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1531     LDFLAGS="${SAVE_LDFLAGS}"
1532   ])
1533   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
1534   ;;
1535 esac
1536
1537 AC_MSG_CHECKING(for the dynamic export flag)
1538 dynamic_list=false
1539 if test "${gdb_native}" = yes; then
1540    # The dynamically loaded libthread_db needs access to symbols in the gdb
1541    # executable.  Older GNU ld supports --export-dynamic but --dynamic-list
1542    # may not be supported there.
1543    old_LDFLAGS="$LDFLAGS"
1544    # Older GNU ld supports --export-dynamic but --dynamic-list it does not.
1545    RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
1546    LDFLAGS="$LDFLAGS $RDYNAMIC"
1547    if test "${have_libpython}" = no; then
1548      AC_TRY_LINK([], [], [dynamic_list=true])
1549    else
1550      # Workaround http://bugs.python.org/issue4434 where static
1551      # libpythonX.Y.a would get its symbols required for
1552      # pythonX.Y/lib-dynload/*.so modules hidden by -Wl,--dynamic-list.
1553      # Problem does not happen for the recommended libpythonX.Y.so linkage.
1554      old_CFLAGS="$CFLAGS"
1555      CFLAGS="$CFLAGS $PYTHON_CFLAGS"
1556      AC_RUN_IFELSE(
1557        AC_LANG_PROGRAM(
1558          [#include "]${have_libpython}[/Python.h"],
1559          [int err;
1560           Py_Initialize ();
1561           err = PyRun_SimpleString ("import itertools\n");
1562           Py_Finalize ();
1563           return err == 0 ? 0 : 1;]),
1564        [dynamic_list=true], [], [true])
1565      CFLAGS="$old_CFLAGS"
1566    fi
1567    LDFLAGS="$old_LDFLAGS"
1568 fi
1569 if $dynamic_list; then
1570   found="-Wl,--dynamic-list"
1571   RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'
1572 else
1573   found="-rdynamic"
1574   RDYNAMIC="-rdynamic"
1575 fi
1576 AC_SUBST(RDYNAMIC)
1577 AC_MSG_RESULT($found)
1578
1579 dnl For certain native configurations, we need to check whether thread
1580 dnl support can be built in or not.
1581 dnl
1582 dnl Note that we only want this if we are both native (host == target),
1583 dnl and not doing a canadian cross build (build == host).
1584
1585 if test ${build} = ${host} -a ${host} = ${target} ; then
1586    case ${host_os} in
1587    solaris*)
1588       # See if thread_db library is around for Solaris thread debugging.
1589       # Note that we must explicitly test for version 1 of the library
1590       # because version 0 (present on Solaris 2.4 or earlier) doesn't have
1591       # the same API.
1592       AC_MSG_CHECKING(for Solaris thread debugging library)
1593       if test -f /usr/lib/libthread_db.so.1 ; then
1594          AC_MSG_RESULT(yes)
1595          AC_DEFINE(HAVE_THREAD_DB_LIB, 1,
1596          [Define if using Solaris thread debugging.])
1597          CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
1598          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
1599          AC_CHECK_LIB(dl, dlopen)
1600          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} $RDYNAMIC"
1601          # Sun randomly tweaked the prototypes in <proc_service.h>
1602          # at one point.
1603          AC_MSG_CHECKING(if <proc_service.h> is old)
1604          AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
1605             AC_TRY_COMPILE([
1606                 #include <proc_service.h>
1607                 ps_err_e ps_pdwrite
1608                     (struct ps_prochandle*, psaddr_t, const void*, size_t);
1609             ],, gdb_cv_proc_service_is_old=no,
1610                 gdb_cv_proc_service_is_old=yes)
1611          ])
1612          AC_MSG_RESULT($gdb_cv_proc_service_is_old)
1613          if test $gdb_cv_proc_service_is_old = yes; then
1614             AC_DEFINE(PROC_SERVICE_IS_OLD, 1,
1615             [Define if <proc_service.h> on solaris uses int instead of
1616              size_t, and assorted other type changes.])
1617          fi
1618       else
1619          AC_MSG_RESULT(no)
1620       fi
1621       ;;
1622    aix*)
1623       AC_MSG_CHECKING(for AiX thread debugging library)
1624       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
1625                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
1626                                    [#ifndef PTHDB_VERSION_3
1627                                     #error
1628                                     #endif],
1629                                    gdb_cv_have_aix_thread_debug=yes,
1630                                    gdb_cv_have_aix_thread_debug=no)])
1631       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1632       if test $gdb_cv_have_aix_thread_debug = yes; then
1633          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1634          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1635          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -lpthdebug"
1636
1637          # Older versions of AIX do not provide the declaration for
1638          # the getthrds function (it appears that it was introduced
1639          # with AIX 6.x).
1640          AC_CHECK_DECLS(getthrds, [], [], [[#include <procinfo.h>]])
1641       fi
1642       ;;
1643    esac
1644    AC_SUBST(CONFIG_LDFLAGS)
1645 fi
1646
1647 dnl See if we have a thread_db header file that has TD_NOTALLOC and
1648 dnl other error codes.
1649 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1650    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
1651                   gdb_cv_thread_db_h_has_td_notalloc,
1652      AC_TRY_COMPILE(
1653        [#include <thread_db.h>],
1654        [int i = TD_NOTALLOC;],
1655        gdb_cv_thread_db_h_has_td_notalloc=yes,
1656        gdb_cv_thread_db_h_has_td_notalloc=no
1657      )
1658    )
1659    AC_CACHE_CHECK([whether <thread_db.h> has TD_VERSION],
1660                   gdb_cv_thread_db_h_has_td_version,
1661      AC_TRY_COMPILE(
1662        [#include <thread_db.h>],
1663        [int i = TD_VERSION;],
1664        gdb_cv_thread_db_h_has_td_version=yes,
1665        gdb_cv_thread_db_h_has_td_version=no
1666      )
1667    )
1668    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTLS],
1669                   gdb_cv_thread_db_h_has_td_notls,
1670      AC_TRY_COMPILE(
1671        [#include <thread_db.h>],
1672        [int i = TD_NOTLS;],
1673        gdb_cv_thread_db_h_has_td_notls=yes,
1674        gdb_cv_thread_db_h_has_td_notls=no
1675      )
1676    )
1677 fi
1678 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1679   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1680             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1681 fi
1682 if test "x$gdb_cv_thread_db_h_has_td_version" = "xyes"; then
1683   AC_DEFINE(THREAD_DB_HAS_TD_VERSION, 1,
1684             [Define if <thread_db.h> has the TD_VERSION error code.])
1685 fi
1686 if test "x$gdb_cv_thread_db_h_has_td_notls" = "xyes"; then
1687   AC_DEFINE(THREAD_DB_HAS_TD_NOTLS, 1,
1688             [Define if <thread_db.h> has the TD_NOTLS error code.])
1689 fi
1690
1691 dnl See if we have a sys/syscall header file that has __NR_tkill.
1692 if test "x$ac_cv_header_sys_syscall_h" = "xyes"; then
1693    AC_CACHE_CHECK([whether <sys/syscall.h> has __NR_tkill],
1694                   gdb_cv_sys_syscall_h_has_tkill,
1695      AC_TRY_COMPILE(
1696        [#include <sys/syscall.h>],
1697        [int i = __NR_tkill;],
1698        gdb_cv_sys_syscall_h_has_tkill=yes,
1699        gdb_cv_sys_syscall_h_has_tkill=no
1700      )
1701    )
1702 fi
1703 dnl See if we can issue tkill syscall.
1704 if test "x$gdb_cv_sys_syscall_h_has_tkill" = "xyes" && test "x$ac_cv_func_syscall" = "xyes"; then
1705   AC_DEFINE(HAVE_TKILL_SYSCALL, 1, [Define if you support the tkill syscall.])
1706 fi
1707
1708 dnl Check if we can disable the virtual address space randomization.
1709 dnl The functionality of setarch -R.
1710 AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>])
1711 define([PERSONALITY_TEST], [AC_LANG_PROGRAM([#include <sys/personality.h>], [
1712 #      if !HAVE_DECL_ADDR_NO_RANDOMIZE
1713 #       define ADDR_NO_RANDOMIZE 0x0040000
1714 #      endif
1715        /* Test the flag could be set and stays set.  */
1716        personality (personality (0xffffffff) | ADDR_NO_RANDOMIZE);
1717        if (!(personality (personality (0xffffffff)) & ADDR_NO_RANDOMIZE))
1718            return 1])])
1719 AC_RUN_IFELSE([PERSONALITY_TEST],
1720               [have_personality=true],
1721               [have_personality=false],
1722               [AC_LINK_IFELSE([PERSONALITY_TEST],
1723                               [have_personality=true],
1724                               [have_personality=false])])
1725 if $have_personality
1726 then
1727     AC_DEFINE([HAVE_PERSONALITY], 1,
1728               [Define if you support the personality syscall.])
1729 fi
1730
1731 dnl Handle optional features that can be enabled.
1732
1733 target_sysroot_reloc=0
1734 AC_ARG_WITH(sysroot,
1735 AS_HELP_STRING([--with-sysroot@<:@=DIR@:>@], [search for usr/lib et al within DIR]),
1736 [
1737  case ${with_sysroot} in
1738  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
1739  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
1740  esac
1741
1742  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
1743
1744  if test "x$prefix" = xNONE; then
1745   test_prefix=/usr/local
1746  else
1747   test_prefix=$prefix
1748  fi
1749  if test "x$exec_prefix" = xNONE || test "x$exec_prefix" = 'x${prefix}'; then
1750   test_exec_prefix=$test_prefix
1751  else
1752   test_exec_prefix=$exec_prefix
1753  fi
1754  case ${TARGET_SYSTEM_ROOT} in
1755  "${test_prefix}"|"${test_prefix}/"*|\
1756  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
1757  '${prefix}'|'${prefix}/'*|\
1758  '${exec_prefix}'|'${exec_prefix}/'*)
1759    target_sysroot_reloc=1
1760    ;;
1761  esac
1762 ], [
1763  TARGET_SYSTEM_ROOT=
1764  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"'
1765 ])
1766 TARGET_SYSTEM_ROOT_DEFINE="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE=$target_sysroot_reloc"
1767 AC_SUBST(TARGET_SYSTEM_ROOT)
1768 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
1769
1770 GDB_AC_WITH_DIR(SYSTEM_GDBINIT, system-gdbinit,
1771     [automatically load a system-wide gdbinit file],
1772     [])
1773
1774 AC_ARG_ENABLE(werror,
1775   AS_HELP_STRING([--enable-werror], [treat compile warnings as errors]),
1776   [case "${enableval}" in
1777      yes | y) ERROR_ON_WARNING="yes" ;;
1778      no | n)  ERROR_ON_WARNING="no" ;;
1779      *) AC_MSG_ERROR(bad value ${enableval} for --enable-werror) ;;
1780    esac])
1781
1782 # Enable -Werror by default when using gcc
1783 if test "${GCC}" = yes -a -z "${ERROR_ON_WARNING}" ; then
1784     ERROR_ON_WARNING=yes
1785 fi
1786
1787 WERROR_CFLAGS=""
1788 if test "${ERROR_ON_WARNING}" = yes ; then
1789     WERROR_CFLAGS="-Werror"
1790 fi
1791
1792 # The entries after -Wno-pointer-sign are disabled warnings which may
1793 # be enabled in the future, which can not currently be used to build
1794 # GDB.
1795 # NOTE: If you change this list, remember to update
1796 # gdb/doc/gdbint.texinfo.
1797 build_warnings="-Wall -Wdeclaration-after-statement -Wpointer-arith \
1798 -Wformat-nonliteral -Wno-pointer-sign \
1799 -Wno-unused -Wunused-value -Wunused-function \
1800 -Wno-switch -Wno-char-subscripts"
1801
1802 # Enable -Wno-format by default when using gcc on mingw since many
1803 # GCC versions complain about %I64.
1804 case "${host}" in
1805   *-*-mingw32*) build_warnings="$build_warnings -Wno-format" ;;
1806 esac
1807
1808 AC_ARG_ENABLE(build-warnings,
1809 AS_HELP_STRING([--enable-build-warnings], [enable build-time compiler warnings if gcc is used]),
1810 [case "${enableval}" in
1811   yes)  ;;
1812   no)   build_warnings="-w";;
1813   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1814         build_warnings="${build_warnings} ${t}";;
1815   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1816         build_warnings="${t} ${build_warnings}";;
1817   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1818 esac
1819 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1820   echo "Setting compiler warning flags = $build_warnings" 6>&1
1821 fi])dnl
1822 AC_ARG_ENABLE(gdb-build-warnings,
1823 AS_HELP_STRING([--enable-gdb-build-warnings], [enable GDB specific build-time compiler warnings if gcc is used]),
1824 [case "${enableval}" in
1825   yes)  ;;
1826   no)   build_warnings="-w";;
1827   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1828         build_warnings="${build_warnings} ${t}";;
1829   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1830         build_warnings="${t} ${build_warnings}";;
1831   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1832 esac
1833 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1834   echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1
1835 fi])dnl
1836 WARN_CFLAGS=""
1837 if test "x${build_warnings}" != x -a "x$GCC" = xyes
1838 then
1839     AC_MSG_CHECKING(compiler warning flags)
1840     # Separate out the -Werror flag as some files just cannot be
1841     # compiled with it enabled.
1842     for w in ${build_warnings}; do
1843         case $w in
1844         -Werr*) WERROR_CFLAGS=-Werror ;;
1845         *) # Check that GCC accepts it
1846             saved_CFLAGS="$CFLAGS"
1847             CFLAGS="$CFLAGS $w"
1848             AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
1849             CFLAGS="$saved_CFLAGS"
1850         esac
1851     done
1852     AC_MSG_RESULT(${WARN_CFLAGS} ${WERROR_CFLAGS})
1853 fi
1854 AC_SUBST(WARN_CFLAGS)
1855 AC_SUBST(WERROR_CFLAGS)
1856
1857 # In the Cygwin environment, we need some additional flags.
1858 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1859 [AC_EGREP_CPP(lose, [
1860 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1861 lose
1862 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1863
1864
1865 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1866 SER_HARDWIRE="ser-base.o ser-unix.o ser-pipe.o ser-tcp.o"
1867 case ${host} in
1868   *go32* ) SER_HARDWIRE=ser-go32.o ;;
1869   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
1870   *mingw32*) SER_HARDWIRE="ser-base.o ser-tcp.o ser-mingw.o" ;;
1871 esac
1872 AC_SUBST(SER_HARDWIRE)
1873
1874 # libreadline needs libuser32.a in a cygwin environment
1875 WIN32LIBS=
1876 if test x$gdb_cv_os_cygwin = xyes; then
1877     WIN32LIBS="-luser32"
1878     case "${target}" in
1879         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
1880         ;;
1881     esac
1882 fi
1883
1884 # The ser-tcp.c module requires sockets.
1885 case ${host} in
1886   *mingw32*)
1887     AC_DEFINE(USE_WIN32API, 1,
1888               [Define if we should use the Windows API, instead of the
1889                POSIX API.  On Windows, we use the Windows API when
1890                building for MinGW, but the POSIX API when building
1891                for Cygwin.])
1892     WIN32LIBS="$WIN32LIBS -lws2_32"
1893     ;;
1894 esac
1895 AC_SUBST(WIN32LIBS)
1896
1897 # Add ELF support to GDB, but only if BFD includes ELF support.
1898 OLD_CFLAGS=$CFLAGS
1899 OLD_LDFLAGS=$LDFLAGS
1900 OLD_LIBS=$LIBS
1901 CFLAGS="$CFLAGS -I${srcdir}/../include -I../bfd -I${srcdir}/../bfd"
1902 LDFLAGS="$LDFLAGS -L../bfd -L../libiberty"
1903 intl=`echo $LIBINTL | sed 's,${top_builddir}/,,g'`
1904 # -ldl is provided by bfd/Makfile.am (LIBDL) <PLUGINS>.
1905 if test "$plugins" = "yes"; then
1906   LIBS="-ldl $LIBS"
1907 fi
1908 LIBS="-lbfd -liberty $intl $LIBS"
1909 AC_CACHE_CHECK([for ELF support in BFD], gdb_cv_var_elf,
1910 [AC_TRY_LINK(
1911 [#include <stdlib.h>
1912 #include "bfd.h"
1913 #include "elf-bfd.h"
1914 ],
1915 [bfd *abfd = NULL; bfd_get_elf_phdr_upper_bound (abfd); ],
1916 gdb_cv_var_elf=yes, gdb_cv_var_elf=no)])
1917 if test $gdb_cv_var_elf = yes; then
1918   CONFIG_OBS="$CONFIG_OBS elfread.o"
1919   AC_DEFINE(HAVE_ELF, 1,
1920             [Define if ELF support should be included.])
1921   # -ldl is provided by bfd/Makfile.am (LIBDL) <PLUGINS>.
1922   if test "$plugins" = "yes"; then
1923     OLD_LIBS="-ldl $OLD_LIBS"
1924   fi
1925 fi
1926 CFLAGS=$OLD_CFLAGS
1927 LDFLAGS=$OLD_LDFLAGS
1928 LIBS=$OLD_LIBS
1929
1930 # Add any host-specific objects to GDB.
1931 CONFIG_OBS="${CONFIG_OBS} ${gdb_host_obs}"
1932
1933 LIBGUI="../libgui/src/libgui.a"
1934 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
1935 AC_SUBST(LIBGUI)
1936 AC_SUBST(GUI_CFLAGS_X)
1937
1938 WIN32LDAPP=
1939 AC_SUBST(WIN32LIBS)
1940 AC_SUBST(WIN32LDAPP)
1941
1942 case "${host}" in
1943 *-*-cygwin* | *-*-mingw* )
1944     configdir="win"
1945     ;;
1946 *)
1947     configdir="unix"
1948     ;;
1949 esac
1950
1951 GDBTKLIBS=
1952 if test "${enable_gdbtk}" = "yes"; then
1953
1954     # Gdbtk must have an absolute path to srcdir in order to run
1955     # properly when not installed.
1956     here=`pwd`
1957     cd ${srcdir}
1958     GDBTK_SRC_DIR=`pwd`
1959     cd $here
1960
1961     SC_PATH_TCLCONFIG
1962
1963     # If $no_tk is nonempty, then we can't do Tk, and there is no
1964     # point to doing Tcl.
1965     SC_PATH_TKCONFIG
1966
1967     if test -z "${no_tcl}" -a -z "${no_tk}"; then
1968         SC_LOAD_TCLCONFIG
1969
1970         # Check for in-tree tcl
1971         here=`pwd`
1972         cd ${srcdir}/..
1973         topdir=`pwd`
1974         cd ${here}
1975
1976         intree="no"
1977         if test "${TCL_SRC_DIR}" = "${topdir}/tcl"; then
1978           intree="yes"
1979         fi
1980
1981         # Find Tcl private headers
1982         if test x"${intree}" = xno; then
1983           CY_AC_TCL_PRIVATE_HEADERS
1984           TCL_INCLUDE="${TCL_INCLUDE_SPEC} ${TCL_PRIVATE_INCLUDE}"
1985           TCL_LIBRARY="${TCL_LIB_SPEC}"
1986           TCL_DEPS=""
1987         else
1988           # If building tcl in the same src tree, private headers
1989           # are not needed, but we need to be sure to use the right
1990           # headers library
1991           TCL_INCLUDE="-I${TCL_SRC_DIR}/generic"
1992           TCL_LIBRARY="${TCL_BUILD_LIB_SPEC}"
1993           TCL_DEPS="../tcl/${configdir}${TCL_LIB_FILE}"
1994         fi
1995         AC_SUBST(TCL_INCLUDE)
1996         AC_SUBST(TCL_LIBRARY)
1997         AC_SUBST(TCL_DEPS)
1998
1999         SC_LOAD_TKCONFIG
2000
2001         # Check for in-tree Tk
2002         intree="no"
2003         if test "${TK_SRC_DIR}" = "${topdir}/tk"; then
2004           intree="yes"
2005         fi
2006
2007         # Find Tk private headers
2008         if test x"${intree}" = xno; then
2009           CY_AC_TK_PRIVATE_HEADERS
2010           TK_INCLUDE="${TK_INCLUDE_SPEC} ${TK_PRIVATE_INCLUDE}"
2011           TK_LIBRARY=${TK_LIB_SPEC}
2012           TK_DEPS=""
2013         else
2014           TK_INCLUDE="-I${TK_SRC_DIR}/generic"
2015           TK_LIBRARY="${TK_BUILD_LIB_SPEC}"
2016           TK_DEPS="../tk/${configdir}/${TK_LIB_FILE}"
2017         fi
2018         AC_SUBST(TK_INCLUDE)
2019         AC_SUBST(TK_LIBRARY)
2020         AC_SUBST(TK_DEPS)
2021         AC_SUBST(TK_XINCLUDES)
2022
2023         ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
2024
2025         # Include some libraries that Tcl and Tk want.
2026         TCL_LIBS='$(LIBGUI) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
2027         # Yes, the ordering seems wrong here.  But it isn't.
2028         # TK_LIBS is the list of libraries that need to be linked
2029         # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
2030         # were in LIBS then any link tests after this point would
2031         # try to include things like `$(LIBGUI)', which wouldn't work.
2032         GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
2033
2034         CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
2035         CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
2036         CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
2037         CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
2038         CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
2039         CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
2040         CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
2041
2042         if test x$gdb_cv_os_cygwin = xyes; then
2043           WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
2044           WIN32LDAPP="-Wl,--subsystem,console"
2045           CONFIG_OBS="${CONFIG_OBS} gdbres.o"
2046         fi
2047
2048         AC_CONFIG_SUBDIRS(gdbtk)
2049     fi
2050 fi
2051
2052 AC_SUBST(X_CFLAGS)
2053 AC_SUBST(X_LDFLAGS)
2054 AC_SUBST(X_LIBS)
2055 AC_SUBST(GDBTKLIBS)
2056 AC_SUBST(GDBTK_CFLAGS)
2057 AC_SUBST(GDBTK_SRC_DIR)
2058
2059 AC_PATH_X
2060
2061 # Unlike the sim directory, whether a simulator is linked is controlled by
2062 # presence of a gdb_sim definition in the target configure.tgt entry.
2063 # This code just checks for a few cases where we'd like to ignore those
2064 # definitions, even when they're present in the '.mt' file.  These cases
2065 # are when --disable-sim is specified, or if the simulator directory is
2066 # not part of the source tree.
2067 #
2068 AC_ARG_ENABLE(sim,
2069 AS_HELP_STRING([--enable-sim], [link gdb with simulator]),
2070 [echo "enable_sim = $enable_sim";
2071  echo "enableval = ${enableval}";
2072  case "${enableval}" in
2073   yes) ignore_sim=false ;;
2074   no)  ignore_sim=true ;;
2075   *)   ignore_sim=false ;;
2076  esac],
2077 [ignore_sim=false])
2078
2079 if test ! -d "${srcdir}/../sim"; then
2080   ignore_sim=true
2081 fi
2082
2083 SIM=
2084 SIM_OBS=
2085 if test "${ignore_sim}" = "false"; then
2086   if test x"${gdb_sim}" != x ; then
2087     SIM="${gdb_sim}"
2088     SIM_OBS="remote-sim.o"
2089     AC_DEFINE(WITH_SIM, 1, [Define if the simulator is being linked in.])
2090   fi
2091 fi
2092 AC_SUBST(SIM)
2093 AC_SUBST(SIM_OBS)
2094
2095 AC_SUBST(ENABLE_CFLAGS)
2096 AC_SUBST(PROFILE_CFLAGS)
2097
2098 AC_SUBST(CONFIG_OBS)
2099 AC_SUBST(CONFIG_DEPS)
2100 AC_SUBST(CONFIG_SRCS)
2101 AC_SUBST(CONFIG_ALL)
2102 AC_SUBST(CONFIG_CLEAN)
2103 AC_SUBST(CONFIG_INSTALL)
2104 AC_SUBST(CONFIG_UNINSTALL)
2105
2106 # List of host floatformats.
2107 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
2108 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
2109 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
2110
2111 # target_subdir is used by the testsuite to find the target libraries.
2112 target_subdir=
2113 if test "${host}" != "${target}"; then
2114     target_subdir="${target_alias}/"
2115 fi
2116 AC_SUBST(target_subdir)
2117
2118 frags=
2119 if test "${gdb_native}" = "yes"; then
2120   host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
2121   if test ! -f ${host_makefile_frag}; then
2122     AC_MSG_ERROR("*** Gdb does not support native target ${host}")
2123   fi
2124   frags="$frags $host_makefile_frag"
2125 else
2126   host_makefile_frag=/dev/null
2127 fi
2128
2129 AC_SUBST_FILE(host_makefile_frag)
2130 AC_SUBST(frags)
2131
2132 changequote(,)dnl
2133 if test "${gdb_native}" = "yes"; then
2134 # We pick this up from the host configuration file (.mh) because we
2135 # do not have a native configuration Makefile fragment.
2136 nativefile=`sed -n '
2137 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
2138 ' ${host_makefile_frag}`
2139 fi
2140 changequote([,])
2141
2142 if test x"${gdb_osabi}" != x ; then
2143     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
2144                        [Define to the default OS ABI for this configuration.])
2145 fi
2146
2147 # Enable multi-ice-gdb-server.
2148 AC_ARG_ENABLE(multi-ice,
2149 AS_HELP_STRING([--enable-multi-ice], [build the multi-ice-gdb-server]),
2150   [case $enableval in
2151     yes | no)
2152       ;;
2153     *) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;;
2154   esac])
2155 if test "x$enable_multi_ice" = xyes; then
2156    AC_CONFIG_SUBDIRS(multi-ice)
2157 fi
2158
2159 AC_ARG_ENABLE(gdbserver,
2160 AS_HELP_STRING([--enable-gdbserver],
2161                [automatically build gdbserver (yes/no/auto, default is auto)]),
2162 [case "${enableval}" in
2163   yes| no|auto) ;;
2164   *) AC_MSG_ERROR(bad value ${enableval} for --enable-gdbserver option) ;;
2165 esac],[enable_gdbserver=auto])
2166
2167 # We only build gdbserver automatically in a native configuration, and
2168 # only if the user did not explicitly disable its build.
2169 if test "$gdb_native" = "yes" -a "$enable_gdbserver" != "no"; then
2170   AC_MSG_CHECKING(whether gdbserver is supported on this host)
2171   if test "x$build_gdbserver" = xyes; then
2172     AC_MSG_RESULT(yes)
2173     AC_CONFIG_SUBDIRS(gdbserver)
2174     gdbserver_build_enabled=yes
2175   else
2176     AC_MSG_RESULT(no)
2177   fi
2178 fi
2179
2180 # If the user explicitly request the gdbserver to be built, verify that
2181 # we were in fact able to enable it.
2182 if test "$enable_gdbserver" = "yes" -a "$gdbserver_build_enabled" != "yes"; then
2183   AC_MSG_ERROR(Automatic gdbserver build is not supported for this configuration)
2184 fi
2185
2186 # If nativefile (NAT_FILE) is not set in config/*/*.m[ht] files, we link
2187 # to an empty version.
2188
2189 files=
2190 links=
2191
2192 rm -f nm.h
2193 if test "${nativefile}" != ""; then
2194     case "${nativefile}" in
2195       nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
2196       * ) GDB_NM_FILE="${nativefile}"
2197     esac
2198     files="${files} ${GDB_NM_FILE}"
2199     links="${links} nm.h"
2200     AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}", [nativefile])
2201 fi
2202 AC_SUBST(GDB_NM_FILE)
2203
2204 AC_LINK_FILES($files, $links)
2205
2206 dnl Check for exe extension set on certain hosts (e.g. Win32)
2207 AC_EXEEXT
2208
2209 dnl  Detect the character set used by this host.
2210 dnl  At the moment, we just assume it's UTF-8.
2211 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "UTF-8",
2212           [Define to be a string naming the default host character set.])
2213
2214 AC_OUTPUT(Makefile .gdbinit:gdbinit.in doc/Makefile gnulib/Makefile data-directory/Makefile,
2215 [
2216 case x$CONFIG_HEADERS in
2217 xconfig.h:config.in)
2218 echo > stamp-h ;;
2219 esac
2220 ])
2221
2222 exit 0