gdb/configure.ac

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995-2017 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Process this file with autoconf to produce a configure script.
  20
  21 AC_PREREQ(2.59)dnl
  22 AC_INIT(main.c)
  23 AC_CONFIG_HEADER(config.h:config.in)
  24 AM_MAINTAINER_MODE
  25
  26 # Set the 'development' global.
  27 . $srcdir/../bfd/development.sh
  28
  29 AC_PROG_CC
  30 AC_PROG_CXX
  31
  32 AC_USE_SYSTEM_EXTENSIONS
  33 ACX_LARGEFILE
  34 AM_PROG_CC_STDC
  35 AM_PROG_INSTALL_STRIP
  36
  37 AC_CONFIG_AUX_DIR(..)
  38 AC_CANONICAL_SYSTEM
  39 AC_ARG_PROGRAM
  40
  41 # We require a C++11 compiler.  Check if one is available, and if
  42 # necessary, set CXX_DIALECT to some -std=xxx switch.
  43 AX_CXX_COMPILE_STDCXX(11, , mandatory)
  44
  45 # Dependency checking.
  46 ZW_CREATE_DEPDIR
  47 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  48
  49 gnulib_extra_configure_args=
  50 # If large-file support is disabled, make sure gnulib does the same.
  51 if test "$enable_largefile" = no; then
  52 gnulib_extra_configure_args="$gnulib_extra_configure_args --disable-largefile"
  53 fi
  54
  55 # Configure gnulib.  We need to build gnulib under some other
  56 # directory not "gnulib", to avoid the problem of both GDB and
  57 # GDBserver wanting to build it in the same directory, when building
  58 # in the source dir.
  59 ACX_CONFIGURE_DIR(["gnulib"], ["build-gnulib"],
  60                   ["$gnulib_extra_configure_args"])
  61
  62 dnl List of object files and targets accumulated by configure.
  63
  64 CONFIG_OBS=
  65 CONFIG_DEPS=
  66 CONFIG_SRCS=
  67 ENABLE_CFLAGS=
  68
  69 CONFIG_ALL=
  70 CONFIG_CLEAN=
  71 CONFIG_INSTALL=
  72 CONFIG_UNINSTALL=
  73
  74 dnl Set up for gettext.
  75 ZW_GNU_GETTEXT_SISTER_DIR
  76
  77 localedir='${datadir}/locale'
  78 AC_SUBST(localedir)
  79
  80 if test x"$USE_NLS" = xyes; then
  81    CONFIG_ALL="$CONFIG_ALL all-po"
  82    CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
  83    CONFIG_INSTALL="$CONFIG_INSTALL install-po"
  84    CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
  85 fi
  86
  87 GNULIB=build-gnulib/import
  88
  89 # For Makefile dependencies.
  90 GNULIB_STDINT_H=
  91 if test x"$STDINT_H" != x; then
  92   GNULIB_STDINT_H=$GNULIB/$STDINT_H
  93 fi
  94 AC_SUBST(GNULIB_STDINT_H)
  95
  96 PACKAGE=gdb
  97 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
  98 AC_SUBST(PACKAGE)
  99
 100 # We never need to detect it in this sub-configure.
 101 # But preserve it for config.status --recheck.
 102 AC_ARG_VAR(MAKEINFO,
 103   [Parent configure detects if it is of sufficient version.])
 104 AC_ARG_VAR(MAKEINFOFLAGS,
 105   [Parameters for MAKEINFO.])
 106
 107 MAKEINFO_EXTRA_FLAGS=""
 108 AC_CACHE_CHECK([whether $MAKEINFO supports @click], gdb_cv_have_makeinfo_click,
 109   [echo '@clicksequence{a @click{} b}' >conftest.texinfo
 110   if eval "$MAKEINFO conftest.texinfo >&5 2>&5"; then
 111     gdb_cv_have_makeinfo_click=yes
 112   else
 113     gdb_cv_have_makeinfo_click=no
 114   fi])
 115 if test x"$gdb_cv_have_makeinfo_click" = xyes; then
 116   MAKEINFO_EXTRA_FLAGS="$MAKEINFO_EXTRA_FLAGS -DHAVE_MAKEINFO_CLICK"
 117 fi
 118 AC_SUBST(MAKEINFO_EXTRA_FLAGS)
 119
 120 GDB_AC_WITH_DIR(DEBUGDIR, separate-debug-dir,
 121     [look for global separate debug info in this path @<:@LIBDIR/debug@:>@],
 122     [${libdir}/debug])
 123
 124 # We can't pass paths as command line arguments.
 125 # Mingw32 tries to be clever and will convert the paths for us.
 126 # For example -DBINDIR="/usr/local/bin" passed on the command line may get
 127 # converted to -DBINDIR="E:/msys/mingw32/msys/1.0/local/bin".
 128 # This breaks GDB's relocatable path conversions since paths passed in
 129 # config.h would not get so translated, the path prefixes no longer match.
 130 AC_DEFINE_DIR(BINDIR, bindir, [Directory of programs.])
 131
 132 # GDB's datadir relocation
 133
 134 GDB_AC_WITH_DIR(GDB_DATADIR, gdb-datadir,
 135     [look for global separate data files in this path @<:@DATADIR/gdb@:>@],
 136     [${datadir}/gdb])
 137
 138 AC_ARG_WITH(relocated-sources,
 139 AS_HELP_STRING([--with-relocated-sources=PATH], [automatically relocate this path for source files]),
 140 [reloc_srcdir="${withval}"
 141  AC_DEFINE_DIR(RELOC_SRCDIR, reloc_srcdir,
 142               [Relocated directory for source files. ])
 143 ])
 144
 145 AC_MSG_CHECKING([for default auto-load directory])
 146 AC_ARG_WITH(auto-load-dir,
 147 AS_HELP_STRING([--with-auto-load-dir=PATH],
 148   [directories from which to load auto-loaded scripts @<:@$debugdir:$datadir/auto-load@:>@]),,
 149   [with_auto_load_dir='$debugdir:$datadir/auto-load'])
 150 escape_dir=`echo $with_auto_load_dir | sed 's/[[$]]\(datadir\|debugdir\)\>/\\\\\\\\\\\\&/g'`
 151 AC_DEFINE_DIR(AUTO_LOAD_DIR, escape_dir,
 152               [Directories from which to load auto-loaded scripts.])
 153 AC_MSG_RESULT([$with_auto_load_dir])
 154
 155 AC_MSG_CHECKING([for default auto-load safe-path])
 156 AC_ARG_WITH(auto-load-safe-path,
 157 AS_HELP_STRING([--with-auto-load-safe-path=PATH],
 158   [directories safe to hold auto-loaded files @<:@--with-auto-load-dir@:>@])
 159 AS_HELP_STRING([--without-auto-load-safe-path],
 160                [do not restrict auto-loaded files locations]),
 161     [if test "$with_auto_load_safe_path" = "no"; then
 162      with_auto_load_safe_path="/"
 163      fi],
 164 [with_auto_load_safe_path="$with_auto_load_dir"])
 165 escape_dir=`echo $with_auto_load_safe_path | sed 's/[[$]]\(datadir\|debugdir\)\>/\\\\\\\\\\\\&/g'`
 166 AC_DEFINE_DIR(AUTO_LOAD_SAFE_PATH, escape_dir,
 167               [Directories safe to hold auto-loaded files.])
 168 AC_MSG_RESULT([$with_auto_load_safe_path])
 169
 170 AC_CONFIG_SUBDIRS(testsuite)
 171
 172 # Check whether to support alternative target configurations
 173 AC_ARG_ENABLE(targets,
 174 AS_HELP_STRING([--enable-targets=TARGETS], [alternative target configurations]),
 175 [case "${enableval}" in
 176   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
 177             ;;
 178   no)       enable_targets= ;;
 179   *)        enable_targets=$enableval ;;
 180 esac])
 181
 182 # Check whether to enable 64-bit support on 32-bit hosts
 183 AC_ARG_ENABLE(64-bit-bfd,
 184 AS_HELP_STRING([--enable-64-bit-bfd], [64-bit support (on hosts with narrower word sizes)]),
 185 [case "${enableval}" in
 186   yes)  want64=true  ;;
 187   no)   want64=false ;;
 188   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
 189 esac],[want64=false])dnl
 190
 191 # Provide defaults for some variables set by the per-host and per-target
 192 # configuration.
 193 gdb_host_obs=posix-hdep.o
 194
 195 if test "${target}" = "${host}"; then
 196   gdb_native=yes
 197 else
 198   gdb_native=no
 199 fi
 200
 201 . $srcdir/configure.host
 202
 203 # Add in the common host objects.
 204 . $srcdir/common/common.host
 205 gdb_host_obs="$gdb_host_obs $common_host_obs"
 206
 207 # Accumulate some settings from configure.tgt over all enabled targets
 208
 209 TARGET_OBS=
 210 all_targets=
 211 HAVE_NATIVE_GCORE_TARGET=
 212
 213 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 214 do
 215   if test "$targ_alias" = "all"; then
 216     all_targets=true
 217   else
 218     # Canonicalize the secondary target names.
 219     result=`$ac_config_sub $targ_alias 2>/dev/null`
 220     if test -n "$result"; then
 221         targ=$result
 222     else
 223         targ=$targ_alias
 224     fi
 225
 226     . ${srcdir}/configure.tgt
 227
 228     AS_IF([test -z "${gdb_target_obs}"],
 229       [AC_MSG_ERROR([configuration ${targ} is unsupported.])])
 230
 231     # Target-specific object files
 232     for i in ${gdb_target_obs}; do
 233         case " $TARGET_OBS " in
 234         *" ${i} "*) ;;
 235         *)
 236           TARGET_OBS="$TARGET_OBS ${i}"
 237           ;;
 238         esac
 239     done
 240
 241     # Check whether this target needs 64-bit CORE_ADDR
 242     if test x${want64} = xfalse; then
 243       . ${srcdir}/../bfd/config.bfd
 244     fi
 245
 246     # Check whether this target is native and supports gcore.
 247     if test $gdb_native = yes -a "$targ_alias" = "$target_alias" \
 248        && $gdb_have_gcore; then
 249       HAVE_NATIVE_GCORE_TARGET=1
 250     fi
 251   fi
 252 done
 253
 254 if test x${all_targets} = xtrue; then
 255
 256   # We want all 64-bit targets if we either:
 257   #  - run on a 64-bit host  or
 258   #  - already require 64-bit support for some other target  or
 259   #  - the --enable-64-bit-bfd option was supplied
 260   # Otherwise we only support all 32-bit targets.
 261   #
 262   # NOTE: This test must be in sync with the corresponding
 263   #       tests in BFD!
 264
 265   if test x${want64} = xfalse; then
 266     AC_CHECK_SIZEOF(long)
 267     if test "x${ac_cv_sizeof_long}" = "x8"; then
 268       want64=true
 269     fi
 270   fi
 271   if test x${want64} = xtrue; then
 272     TARGET_OBS='$(ALL_TARGET_OBS) $(ALL_64_TARGET_OBS)'
 273   else
 274     TARGET_OBS='$(ALL_TARGET_OBS)'
 275   fi
 276 fi
 277
 278 AC_SUBST(TARGET_OBS)
 279 AC_SUBST(HAVE_NATIVE_GCORE_TARGET)
 280
 281 # For other settings, only the main target counts.
 282 gdb_sim=
 283 gdb_osabi=
 284 build_gdbserver=
 285 targ=$target; . ${srcdir}/configure.tgt
 286
 287 # Fetch the default architecture and default target vector from BFD.
 288 targ=$target; . $srcdir/../bfd/config.bfd
 289
 290 # We only want the first architecture, so strip off the others if
 291 # there is more than one.
 292 targ_archs=`echo $targ_archs | sed 's/ .*//'`
 293
 294 if test "x$targ_archs" != x; then
 295   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
 296     [Define to BFD's default architecture. ])
 297 fi
 298 if test "x$targ_defvec" != x; then
 299   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
 300     [Define to BFD's default target vector. ])
 301 fi
 302
 303 # The CLI cannot be disabled yet, but may be in the future.
 304
 305 # Enable CLI.
 306 AC_ARG_ENABLE(gdbcli,
 307 AS_HELP_STRING([--disable-gdbcli], [disable command-line interface (CLI)]),
 308   [case $enableval in
 309     yes)
 310       ;;
 311     no)
 312       AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;;
 313     *)
 314       AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;;
 315   esac],
 316   [enable_gdbcli=yes])
 317 if test x"$enable_gdbcli" = xyes; then
 318   if test -d $srcdir/cli; then
 319     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)"
 320     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)"
 321     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)"
 322     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)"
 323   fi
 324 fi
 325
 326 # Enable MI.
 327 AC_ARG_ENABLE(gdbmi,
 328 AS_HELP_STRING([--disable-gdbmi], [disable machine-interface (MI)]),
 329   [case $enableval in
 330     yes | no)
 331       ;;
 332     *)
 333       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 334   esac],
 335   [enable_gdbmi=yes])
 336 if test x"$enable_gdbmi" = xyes; then
 337   if test -d $srcdir/mi; then
 338     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 339     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 340     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 341     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 342   fi
 343 fi
 344
 345 # Enable TUI.
 346 AC_ARG_ENABLE(tui,
 347 AS_HELP_STRING([--enable-tui], [enable full-screen terminal user interface (TUI)]),
 348   [case $enableval in
 349     yes | no | auto)
 350       ;;
 351     *)
 352       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 353   esac],enable_tui=auto)
 354
 355 # Enable gdbtk.
 356 AC_ARG_ENABLE(gdbtk,
 357 AS_HELP_STRING([--enable-gdbtk], [enable gdbtk graphical user interface (GUI)]),
 358   [case $enableval in
 359     yes | no)
 360       ;;
 361     *)
 362       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 363   esac],
 364   [if test -d $srcdir/gdbtk; then
 365     enable_gdbtk=yes
 366   else
 367     enable_gdbtk=no
 368   fi])
 369 # We unconditionally disable gdbtk tests on selected platforms.
 370 case $host_os in
 371   go32* | windows*)
 372     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 373     enable_gdbtk=no ;;
 374 esac
 375
 376 # Libunwind support for ia64.
 377
 378 AC_ARG_WITH(libunwind-ia64,
 379 AS_HELP_STRING([--with-libunwind-ia64],
 380                [use libunwind frame unwinding for ia64 targets]),,
 381             [with_libunwind_ia64=auto])
 382
 383 # Backward compatibility option.
 384 if test "${with_libunwind+set}" = set; then
 385   if test x"$with_libunwind_ia64" != xauto; then
 386     AC_MSG_ERROR(
 387       [option --with-libunwind is deprecated, use --with-libunwind-ia64])
 388   fi
 389   AC_MSG_WARN([option --with-libunwind is deprecated, use --with-libunwind-ia64])
 390   with_libunwind_ia64="$with_libunwind"
 391 fi
 392
 393 case "$with_libunwind_ia64" in
 394   yes | no)
 395     ;;
 396   auto)
 397     AC_CHECK_HEADERS(libunwind-ia64.h)
 398     with_libunwind_ia64=$ac_cv_header_libunwind_ia64_h
 399     ;;
 400   *)
 401     AC_MSG_ERROR(
 402       [bad value $with_libunwind_ia64 for GDB --with-libunwind-ia64 option])
 403     ;;
 404 esac
 405
 406 if test x"$with_libunwind_ia64" = xyes; then
 407   AC_CHECK_HEADERS(libunwind-ia64.h)
 408   if test x"$ac_cv_header_libunwind_ia64_h" != xyes; then
 409     AC_MSG_ERROR([GDB option --with-libunwind-ia64 requires libunwind-ia64.h])
 410   fi
 411   CONFIG_OBS="$CONFIG_OBS ia64-libunwind-tdep.o"
 412   CONFIG_DEPS="$CONFIG_DEPS ia64-libunwind-tdep.o"
 413   CONFIG_SRCS="$CONFIG_SRCS ia64-libunwind-tdep.c"
 414 fi
 415
 416 opt_curses=no
 417 AC_ARG_WITH(curses, AS_HELP_STRING([--with-curses], [use the curses library instead of the termcap library]), opt_curses=$withval)
 418
 419 prefer_curses=no
 420 if test "$opt_curses" = "yes"; then
 421   prefer_curses=yes
 422 fi
 423
 424 # Profiling support.
 425 AC_ARG_ENABLE(profiling,
 426 AS_HELP_STRING([--enable-profiling], [enable profiling of GDB]),
 427   [case $enableval in
 428     yes | no)
 429       ;;
 430     *)
 431       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 432   esac],
 433  [enable_profiling=no])
 434
 435 AC_CHECK_FUNCS(monstartup _mcleanup)
 436 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 437 [AC_TRY_LINK(
 438 [#include <stdlib.h>
 439 extern char _etext;
 440 ],
 441 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 442 if test $ac_cv_var__etext = yes; then
 443   AC_DEFINE(HAVE__ETEXT, 1,
 444             [Define to 1 if your system has the _etext variable. ])
 445 fi
 446 AC_CACHE_CHECK([for etext], ac_cv_var_etext,
 447 [AC_TRY_LINK(
 448 [#include <stdlib.h>
 449 extern char etext;
 450 ],
 451 [free (&etext);], ac_cv_var_etext=yes, ac_cv_var_etext=no)])
 452 if test $ac_cv_var_etext = yes; then
 453   AC_DEFINE(HAVE_ETEXT, 1,
 454             [Define to 1 if your system has the etext variable. ])
 455 fi
 456 if test "$enable_profiling" = yes ; then
 457   if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
 458     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 459   fi
 460   PROFILE_CFLAGS=-pg
 461   OLD_CFLAGS="$CFLAGS"
 462   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 463
 464   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 465     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 466      ac_cv_cc_supports_pg=no)])
 467
 468   if test $ac_cv_cc_supports_pg = no; then
 469     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 470   fi
 471
 472   CFLAGS="$OLD_CFLAGS"
 473 fi
 474
 475 ACX_PKGVERSION([GDB])
 476 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 477 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 478 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 479
 480 # --------------------- #
 481 # Checks for programs.  #
 482 # --------------------- #
 483
 484 AC_PROG_AWK
 485 AC_PROG_INSTALL
 486 AC_PROG_LN_S
 487 AC_PROG_RANLIB
 488 AC_PROG_YACC
 489
 490 AC_CHECK_TOOL(AR, ar)
 491 AC_CHECK_TOOL(DLLTOOL, dlltool)
 492 AC_CHECK_TOOL(WINDRES, windres)
 493
 494 case $host_os in
 495   gnu*)
 496     # Needed for GNU Hurd hosts.
 497     AC_CHECK_TOOL(MIG, mig)
 498     if test x"$MIG" = x; then
 499       AC_MSG_ERROR([MIG not found but required for $host hosts])
 500     fi
 501     ;;
 502 esac
 503
 504 # ---------------------- #
 505 # Checks for libraries.  #
 506 # ---------------------- #
 507
 508 # We might need to link with -lm; most simulators need it.
 509 AC_CHECK_LIB(m, main)
 510
 511 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 512 AC_SEARCH_LIBS(gethostbyname, nsl)
 513
 514 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 515 AC_SEARCH_LIBS(socketpair, socket)
 516
 517 # Link in zlib if we can.  This allows us to read compressed debug sections.
 518 AM_ZLIB
 519
 520 # On FreeBSD we may need libutil for kinfo_getvmmap (used by fbsd-nat.c).
 521 # On GNU/kFreeBSD systems, FreeBSD libutil is renamed to libutil-freebsd.
 522 AC_SEARCH_LIBS(kinfo_getvmmap, util util-freebsd,
 523   [AC_DEFINE(HAVE_KINFO_GETVMMAP, 1,
 524             [Define to 1 if your system has the kinfo_getvmmap function. ])])
 525
 526 AM_ICONV
 527
 528 # GDB may fork/exec the iconv program to get the list of supported character
 529 # sets.  Allow the user to specify where to find it.
 530 # There are several factors affecting the choice of option name:
 531 # - There is already --with-libiconv-prefix but we can't use it, it specifies
 532 #   the build-time location of libiconv files.
 533 # - The program we need to find is iconv, which comes with glibc.  The user
 534 #   doesn't necessarily have libiconv installed.  Therefore naming this
 535 #   --with-libiconv-foo feels wrong.
 536 # - We want the path to be relocatable, but GDB_AC_DEFINE_RELOCATABLE is
 537 #   defined to work on directories not files (though it really doesn't know
 538 #   the difference).
 539 # - Calling this --with-iconv-prefix is perceived to cause too much confusion
 540 #   with --with-libiconv-prefix.
 541 # Putting these together is why the option name is --with-iconv-bin.
 542
 543 AC_ARG_WITH(iconv-bin,
 544 AS_HELP_STRING([--with-iconv-bin=PATH], [specify where to find the iconv program]),
 545 [iconv_bin="${withval}"
 546  AC_DEFINE_UNQUOTED([ICONV_BIN], ["${iconv_bin}"],
 547                     [Path of directory of iconv program.])
 548  GDB_AC_DEFINE_RELOCATABLE(ICONV_BIN, iconv, ${iconv_bin})
 549 ])
 550
 551 # For the TUI, we need enhanced curses functionality.
 552 if test x"$enable_tui" != xno; then
 553   prefer_curses=yes
 554 fi
 555
 556 curses_found=no
 557 if test x"$prefer_curses" = xyes; then
 558   # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
 559   # curses library because the latter might not provide all the
 560   # functionality we need.  However, this leads to problems on systems
 561   # where the linker searches /usr/local/lib, but the compiler doesn't
 562   # search /usr/local/include, if ncurses is installed in /usr/local.  A
 563   # default installation of ncurses on alpha*-dec-osf* will lead to such
 564   # a situation.
 565   AC_SEARCH_LIBS(waddstr, [ncurses cursesX curses])
 566
 567   if test "$ac_cv_search_waddstr" != no; then
 568     curses_found=yes
 569   fi
 570 fi
 571
 572 # Check whether we should enable the TUI, but only do so if we really
 573 # can.
 574 if test x"$enable_tui" != xno; then
 575   if test -d $srcdir/tui; then
 576     if test "$curses_found" != no; then
 577       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
 578       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
 579       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
 580       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
 581     else
 582       if test x"$enable_tui" = xyes; then
 583         AC_MSG_ERROR([no enhanced curses library found; disable TUI])
 584       else
 585         AC_MSG_WARN([no enhanced curses library found; disabling TUI])
 586       fi
 587     fi
 588   fi
 589 fi
 590
 591 # Since GDB uses Readline, we need termcap functionality.  In many
 592 # cases this will be provided by the curses library, but some systems
 593 # have a separate termcap library, or no curses library at all.
 594
 595 case $host_os in
 596   cygwin*)
 597     if test -d $srcdir/libtermcap; then
 598       LIBS="../libtermcap/libtermcap.a $LIBS"
 599       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 600     fi ;;
 601   go32* | *djgpp*)
 602     ac_cv_search_tgetent="none required"
 603     ;;
 604 esac
 605
 606 # These are the libraries checked by Readline.
 607 AC_SEARCH_LIBS(tgetent, [termcap tinfo curses ncurses])
 608
 609 if test "$ac_cv_search_tgetent" = no; then
 610   CONFIG_OBS="$CONFIG_OBS stub-termcap.o"
 611 fi
 612
 613 AC_ARG_WITH([system-readline],
 614   [AS_HELP_STRING([--with-system-readline],
 615                   [use installed readline library])])
 616
 617 if test "$with_system_readline" = yes; then
 618   READLINE=-lreadline
 619   READLINE_DEPS=
 620   READLINE_CFLAGS=
 621   READLINE_TEXI_INCFLAG=
 622 else
 623   READLINE='$(READLINE_DIR)/libreadline.a'
 624   READLINE_DEPS='$(READLINE)'
 625   READLINE_CFLAGS='-I$(READLINE_SRC)/..'
 626   READLINE_TEXI_INCFLAG='-I $(READLINE_DIR)'
 627 fi
 628 AC_SUBST(READLINE)
 629 AC_SUBST(READLINE_DEPS)
 630 AC_SUBST(READLINE_CFLAGS)
 631 AC_SUBST(READLINE_TEXI_INCFLAG)
 632
 633 # Generate jit-reader.h
 634
 635 # This is typedeffed to GDB_CORE_ADDR in jit-reader.h
 636 TARGET_PTR=
 637
 638 AC_CHECK_SIZEOF(unsigned long long)
 639 AC_CHECK_SIZEOF(unsigned long)
 640 AC_CHECK_SIZEOF(unsigned __int128)
 641
 642 if test "x${ac_cv_sizeof_unsigned_long}" = "x8"; then
 643   TARGET_PTR="unsigned long"
 644 elif test "x${ac_cv_sizeof_unsigned_long_long}" = "x8"; then
 645   TARGET_PTR="unsigned long long"
 646 elif test "x${ac_cv_sizeof_unsigned___int128}" = "x16"; then
 647   TARGET_PTR="unsigned __int128"
 648 else
 649   TARGET_PTR="unsigned long"
 650 fi
 651
 652 AC_SUBST(TARGET_PTR)
 653 AC_CONFIG_FILES([jit-reader.h:jit-reader.in])
 654
 655 AC_SEARCH_LIBS(dlopen, dl)
 656
 657 GDB_AC_WITH_DIR([JIT_READER_DIR], [jit-reader-dir],
 658                 [directory to load the JIT readers from],
 659                 [${libdir}/gdb])
 660
 661 AC_ARG_WITH(expat,
 662   AS_HELP_STRING([--with-expat], [include expat support (auto/yes/no)]),
 663   [], [with_expat=auto])
 664 AC_MSG_CHECKING([whether to use expat])
 665 AC_MSG_RESULT([$with_expat])
 666
 667 if test "${with_expat}" = no; then
 668   AC_MSG_WARN([expat support disabled; some features may be unavailable.])
 669   HAVE_LIBEXPAT=no
 670 else
 671   AC_LIB_HAVE_LINKFLAGS([expat], [], [#include "expat.h"],
 672                         [XML_Parser p = XML_ParserCreate (0);])
 673   if test "$HAVE_LIBEXPAT" != yes; then
 674     if test "$with_expat" = yes; then
 675       AC_MSG_ERROR([expat is missing or unusable])
 676     else
 677       AC_MSG_WARN([expat is missing or unusable; some features may be unavailable.])
 678     fi
 679   else
 680     save_LIBS=$LIBS
 681     LIBS="$LIBS $LIBEXPAT"
 682     AC_CHECK_FUNCS(XML_StopParser)
 683     LIBS=$save_LIBS
 684   fi
 685 fi
 686
 687 # --------------------- #
 688 # Check for libpython.  #
 689 # --------------------- #
 690
 691 dnl Utility to simplify finding libpython.
 692 dnl $1 = pythonX.Y
 693 dnl $2 = the shell variable to assign the result to
 694 dnl      If libpython is found we store $version here.
 695 dnl $3 = additional flags to add to CPPFLAGS
 696 dnl $4 = additional flags to add to LIBS
 697
 698 AC_DEFUN([AC_TRY_LIBPYTHON],
 699 [
 700   version=$1
 701   define([have_libpython_var],$2)
 702   new_CPPFLAGS=$3
 703   new_LIBS=$4
 704   AC_MSG_CHECKING([for ${version}])
 705   save_CPPFLAGS=$CPPFLAGS
 706   save_LIBS=$LIBS
 707   CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
 708   LIBS="$LIBS $new_LIBS"
 709   found_usable_python=no
 710   AC_LINK_IFELSE(AC_LANG_PROGRAM([[#include "Python.h"]],
 711                                  [[Py_Initialize ();]]),
 712                  [have_libpython_var=${version}
 713                   found_usable_python=yes
 714                   PYTHON_CPPFLAGS=$new_CPPFLAGS
 715                   PYTHON_LIBS=$new_LIBS])
 716   CPPFLAGS=$save_CPPFLAGS
 717   LIBS=$save_LIBS
 718   AC_MSG_RESULT([${found_usable_python}])
 719 ])
 720
 721 dnl There are several different values for --with-python:
 722 dnl
 723 dnl no -   Don't include python support.
 724 dnl yes -  Include python support, error if it's missing.
 725 dnl        If we find python in $PATH, use it to fetch configure options,
 726 dnl        otherwise assume the compiler can find it with no help from us.
 727 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 728 dnl auto - Same as "yes", but if python is missing from the system,
 729 dnl        fall back to "no".
 730 dnl /path/to/python/exec-prefix -
 731 dnl        Use the python located in this directory.
 732 dnl        If /path/to/python/exec-prefix/bin/python exists, use it to find
 733 dnl        the compilation parameters.  Otherwise use
 734 dnl        -I/path/to/python/exec-prefix/include,
 735 dnl        -L/path/to/python/exec-prefix/lib.
 736 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 737 dnl        NOTE: This case is historical.  It is what was done for 7.0/7.1
 738 dnl        but is deprecated.
 739 dnl /path/to/python/executable -
 740 dnl        Run python-config.py with this version of python to fetch the
 741 dnl        compilation parameters.
 742 dnl        NOTE: This needn't be the real python executable.
 743 dnl        In a cross-compilation scenario (build != host), this could be
 744 dnl        a shell script that provides what python-config.py provides for
 745 dnl        --ldflags, --includes, --exec-prefix.
 746 dnl python-executable -
 747 dnl        Find python-executable in $PATH, and then handle the same as
 748 dnl        /path/to/python/executable.
 749 dnl
 750 dnl If a python program is specified, it is used to run python-config.py and
 751 dnl is passed --ldflags, --includes, --exec-prefix.
 752
 753 AC_ARG_WITH(python,
 754   AS_HELP_STRING([--with-python@<:@=PYTHON@:>@], [include python support (auto/yes/no/<python-program>)]),
 755   [], [with_python=auto])
 756 AC_MSG_CHECKING([whether to use python])
 757 AC_MSG_RESULT([$with_python])
 758
 759 if test "${with_python}" = no; then
 760   AC_MSG_WARN([python support disabled; some features may be unavailable.])
 761   have_libpython=no
 762 else
 763   case "${with_python}" in
 764   [[\\/]]* | ?:[[\\/]]*)
 765     if test -d ${with_python}; then
 766       # Assume the python binary is ${with_python}/bin/python.
 767       python_prog="${with_python}/bin/python"
 768       python_prefix=
 769       # If python does not exit ${with_python}/bin, then try in
 770       # ${with_python}.  On Windows/MinGW, this is where the Python
 771       # executable is.
 772       if test ! -x "${python_prog}"; then
 773         python_prog="${with_python}/python"
 774         python_prefix=
 775       fi
 776       if test ! -x "${python_prog}"; then
 777         # Fall back to gdb 7.0/7.1 behaviour.
 778         python_prog=missing
 779         python_prefix=${with_python}
 780       fi
 781     elif test -x "${with_python}"; then
 782       # While we can't run python compiled for $host (unless host == build),
 783       # the user could write a script that provides the needed information,
 784       # so we support that.
 785       python_prog=${with_python}
 786       python_prefix=
 787     else
 788       AC_ERROR(invalid value for --with-python)
 789     fi
 790     ;;
 791   */*)
 792     # Disallow --with-python=foo/bar.
 793     AC_ERROR(invalid value for --with-python)
 794     ;;
 795   *)
 796     # The user has either specified auto, yes, or the name of the python
 797     # program assumed to be in $PATH.
 798     python_prefix=
 799     case "${with_python}" in
 800     yes | auto)
 801       if test ${build} = ${host}; then
 802         AC_PATH_PROG(python_prog_path, python, missing)
 803         if test "${python_prog_path}" = missing; then
 804           python_prog=missing
 805         else
 806           python_prog=${python_prog_path}
 807         fi
 808       else
 809         # Not much we can do except assume the cross-compiler will find the
 810         # right files.
 811         python_prog=missing
 812       fi
 813       ;;
 814     *)
 815       # While we can't run python compiled for $host (unless host == build),
 816       # the user could write a script that provides the needed information,
 817       # so we support that.
 818       python_prog="${with_python}"
 819       AC_PATH_PROG(python_prog_path, ${python_prog}, missing)
 820       if test "${python_prog_path}" = missing; then
 821         AC_ERROR(unable to find python program ${python_prog})
 822       fi
 823       ;;
 824     esac
 825   esac
 826
 827   if test "${python_prog}" != missing; then
 828     # We have a python program to use, but it may be too old.
 829     # Don't flag an error for --with-python=auto (the default).
 830     have_python_config=yes
 831     python_includes=`${python_prog} ${srcdir}/python/python-config.py --includes`
 832     if test $? != 0; then
 833       have_python_config=failed
 834       if test "${with_python}" != auto; then
 835         AC_ERROR(failure running python-config --includes)
 836       fi
 837     fi
 838     python_libs=`${python_prog} ${srcdir}/python/python-config.py --ldflags`
 839     if test $? != 0; then
 840       have_python_config=failed
 841       if test "${with_python}" != auto; then
 842         AC_ERROR(failure running python-config --ldflags)
 843       fi
 844     fi
 845     python_prefix=`${python_prog} ${srcdir}/python/python-config.py --exec-prefix`
 846     if test $? != 0; then
 847       have_python_config=failed
 848       if test "${with_python}" != auto; then
 849         AC_ERROR(failure running python-config --exec-prefix)
 850       fi
 851     fi
 852   else
 853     # We do not have a python executable we can use to determine where
 854     # to find the Python headers and libs.  We cannot guess the include
 855     # path from the python_prefix either, because that include path
 856     # depends on the Python version.  So, there is nothing much we can
 857     # do except assume that the compiler will be able to find those files.
 858     python_includes=
 859     python_libs=
 860     have_python_config=no
 861   fi
 862
 863   # If we have python-config, only try the configuration it provides.
 864   # Otherwise fallback on the old way of trying different versions of
 865   # python in turn.
 866
 867   have_libpython=no
 868   if test "${have_python_config}" = yes; then
 869     # Determine the Python version by extracting "-lpython<version>"
 870     # part of the python_libs. <version> is usually X.Y with X and Y
 871     # being decimal numbers, but can also be XY (seen on Windows).
 872     #
 873     # The extraction is performed using sed with a regular expression.
 874     # Initially, the regexp used was using the '?' quantifier to make
 875     # the dot in the version number optional.  Unfortunately, this
 876     # does not work with non-GNU versions of sed because, because of
 877     # what looks like a limitation (the '?' quantifier does not work
 878     # with back-references).  We work around this limitation by using
 879     # the '*' quantifier instead.  It means that, in theory, we might
 880     # match unexpected version strings such as "-lpython2..7", but
 881     # this seems unlikely in practice.  And even if that happens,
 882     # an error will be triggered later on, when checking that version
 883     # number.
 884     python_version=`echo " ${python_libs} " \
 885                          | sed -e 's,^.* -l\(python[[0-9]]*[[.]]*[[0-9]]*\).*$,\1,'`
 886     case "${python_version}" in
 887     python*)
 888       AC_TRY_LIBPYTHON(${python_version}, have_libpython,
 889                        ${python_includes}, ${python_libs})
 890       ;;
 891     *)
 892       AC_MSG_ERROR([unable to determine python version from ${python_libs}])
 893       ;;
 894     esac
 895   elif test "${have_python_config}" != failed; then
 896     if test "${have_libpython}" = no; then
 897       AC_TRY_LIBPYTHON(python2.7, have_libpython,
 898                        ${python_includes}, "${python_libs} -lpython2.7")
 899     fi
 900     if test "${have_libpython}" = no; then
 901       AC_TRY_LIBPYTHON(python2.6, have_libpython,
 902                        ${python_includes}, "${python_libs} -lpython2.6")
 903     fi
 904     if test ${have_libpython} = no; then
 905       AC_TRY_LIBPYTHON(python2.5, have_libpython,
 906                        ${python_includes}, "${python_libs} -lpython2.5")
 907     fi
 908     if test ${have_libpython} = no; then
 909       AC_TRY_LIBPYTHON(python2.4, have_libpython,
 910                        ${python_includes}, "${python_libs} -lpython2.4")
 911     fi
 912   fi
 913   if test "${have_libpython}" = python2.7 -o "${have_libpython}" = python27; then
 914     AC_DEFINE(HAVE_LIBPYTHON2_7, 1, [Define if Python 2.7 is being used.])
 915   elif test "${have_libpython}" = python2.6 -o "${have_libpython}" = python26; then
 916     AC_DEFINE(HAVE_LIBPYTHON2_6, 1, [Define if Python 2.6 is being used.])
 917   elif test "${have_libpython}" = python2.5 -o "${have_libpython}" = python25; then
 918     AC_DEFINE(HAVE_LIBPYTHON2_5, 1, [Define if Python 2.5 is being used.])
 919   elif test "${have_libpython}" = python2.4 -o "${have_libpython}" = python24; then
 920     AC_DEFINE(HAVE_LIBPYTHON2_4, 1, [Define if Python 2.4 is being used.])
 921   fi
 922
 923   if test "${have_libpython}" = no; then
 924     case "${with_python}" in
 925     yes)
 926       AC_MSG_ERROR([python is missing or unusable])
 927       ;;
 928     auto)
 929       AC_MSG_WARN([python is missing or unusable; some features may be unavailable.])
 930       ;;
 931     *)
 932       AC_MSG_ERROR([no usable python found at ${with_python}])
 933       ;;
 934     esac
 935   else
 936     if test -n "${python_prefix}"; then
 937       AC_DEFINE_UNQUOTED(WITH_PYTHON_PATH, "${python_prefix}",
 938                          [Define if --with-python provides a path, either directly or via python-config.py --exec-prefix.])
 939       GDB_AC_DEFINE_RELOCATABLE(PYTHON_PATH, python, ${python_prefix})
 940     fi
 941   fi
 942 fi
 943
 944 if test "${have_libpython}" != no; then
 945   AC_DEFINE(HAVE_PYTHON, 1, [Define if Python interpreter is being linked in.])
 946   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_PYTHON_OBS)"
 947   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_PYTHON_DEPS)"
 948   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_PYTHON_SRCS)"
 949   CONFIG_INSTALL="$CONFIG_INSTALL install-python"
 950   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_PYTHON_CFLAGS)"
 951
 952   # Flags needed to compile Python code (taken from python-config --cflags).
 953   # We cannot call python-config directly because it will output whatever was
 954   # used when compiling the Python interpreter itself, including flags which
 955   # would make the python-related objects be compiled differently from the
 956   # rest of GDB (e.g., -O2 and -fPIC).
 957   if test "${GCC}" = yes; then
 958     tentative_python_cflags="-fno-strict-aliasing -DNDEBUG -fwrapv"
 959   fi
 960
 961   if test "x${tentative_python_cflags}" != x; then
 962     AC_MSG_CHECKING(compiler flags for python code)
 963     for flag in ${tentative_python_cflags}; do
 964       # Check that the compiler accepts it
 965       saved_CFLAGS="$CFLAGS"
 966       CFLAGS="$CFLAGS $flag"
 967       AC_TRY_COMPILE([],[],PYTHON_CFLAGS="${PYTHON_CFLAGS} $flag",)
 968       CFLAGS="$saved_CFLAGS"
 969     done
 970     AC_MSG_RESULT(${PYTHON_CFLAGS})
 971   fi
 972
 973   # On x64 Windows, Python's include headers, and pyconfig.h in
 974   # particular, rely on MS_WIN64 macro to detect that it's a 64bit
 975   # version of Windows.  Unfortunately, MS_WIN64 is only defined if
 976   # _MSC_VER, a Microsoft-specific macro, is defined.  So, when
 977   # building on x64 Windows with GCC, we define MS_WIN64 ourselves.
 978   # The issue was reported to the Python community, but still isn't
 979   # solved as of 2012-10-02 (http://bugs.python.org/issue4709).
 980
 981   case "$gdb_host" in
 982     mingw64)
 983            if test "${GCC}" = yes; then
 984              CPPFLAGS="$CPPFLAGS -DMS_WIN64"
 985            fi
 986            ;;
 987   esac
 988
 989   # Note that "python -m threading" cannot be used to check for
 990   # threading support due to a bug in Python 2.7.3
 991   # (http://bugs.python.org/issue15567).
 992   AC_MSG_CHECKING(whether python supports threads)
 993   saved_CPPFLAGS="${CPPFLAGS}"
 994   CPPFLAGS="${PYTHON_CPPFLAGS}"
 995   # Note that the test is reversed so that python_has_threads=yes on
 996   # unexpected failures.
 997   AC_PREPROC_IFELSE(AC_LANG_SOURCE([[
 998 #include <Python.h>
 999 #ifdef WITH_THREAD
1000 # error
1001 #endif
1002   ]]), [python_has_threads=no], [python_has_threads=yes])
1003   AC_MSG_RESULT(${python_has_threads})
1004   CPPFLAGS="${saved_CPPFLAGS}"
1005 else
1006   # Even if Python support is not compiled in, we need to have this file
1007   # included so that the "python" command, et.al., still exists.
1008   CONFIG_OBS="$CONFIG_OBS python.o"
1009   CONFIG_SRCS="$CONFIG_SRCS python/python.c"
1010 fi
1011
1012 # Work around Python http://bugs.python.org/issue10112.  See also
1013 # http://bugs.python.org/issue11410, otherwise -Wl,--dynamic-list has
1014 # no effect.  Note that the only test after this that uses Python is
1015 # the -rdynamic/-Wl,--dynamic-list test, and we do want that one to be
1016 # run without -export-dynamic too.
1017 PYTHON_LIBS=`echo $PYTHON_LIBS | sed -e 's/-Xlinker -export-dynamic//'`
1018
1019 AC_SUBST(PYTHON_CFLAGS)
1020 AC_SUBST(PYTHON_CPPFLAGS)
1021 AC_SUBST(PYTHON_LIBS)
1022 AM_CONDITIONAL(HAVE_PYTHON, test "${have_libpython}" != no)
1023
1024 # -------------------- #
1025 # Check for libguile.  #
1026 # -------------------- #
1027
1028 dnl Utility to simplify finding libguile.
1029 dnl $1 = pkg-config-program
1030 dnl $2 = space-separate list of guile versions to try
1031 dnl $3 = yes|no, indicating whether to flag errors or ignore them
1032 dnl $4 = the shell variable to assign the result to
1033 dnl      If libguile is found we store "yes" here.
1034
1035 AC_DEFUN([AC_TRY_LIBGUILE],
1036 [
1037   pkg_config=$1
1038   guile_version_list=$2
1039   flag_errors=$3
1040   define([have_libguile_var],$4)
1041   found_usable_guile=checking
1042   AC_MSG_CHECKING([for usable guile from ${pkg_config}])
1043   for guile_version in ${guile_version_list}; do
1044     ${pkg_config} --exists ${guile_version} 2>/dev/null
1045     if test $? != 0; then
1046       continue
1047     fi
1048     dnl pkg-config says the package exists, so if we get an error now,
1049     dnl that's bad.
1050     new_CPPFLAGS=`${pkg_config} --cflags ${guile_version}`
1051     if test $? != 0; then
1052       AC_MSG_ERROR([failure running pkg-config --cflags ${guile_version}])
1053     fi
1054     new_LIBS=`${pkg_config} --libs ${guile_version}`
1055     if test $? != 0; then
1056       AC_MSG_ERROR([failure running pkg-config --libs ${guile_version}])
1057     fi
1058     dnl If we get this far, great.
1059     found_usable_guile=${guile_version}
1060     break
1061   done
1062   if test "${found_usable_guile}" = "checking"; then
1063     if test "${flag_errors}" = "yes"; then
1064       AC_MSG_ERROR([unable to find usable guile version from "${guile_version_list}"])
1065     else
1066       found_usable_guile=no
1067     fi
1068   fi
1069   dnl One final sanity check.
1070   dnl The user could have said --with-guile=python-2.7.
1071   if test "${found_usable_guile}" != no; then
1072     save_CPPFLAGS=$CPPFLAGS
1073     save_LIBS=$LIBS
1074     CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
1075     LIBS="$LIBS $new_LIBS"
1076     AC_LINK_IFELSE(AC_LANG_PROGRAM([[#include "libguile.h"]],
1077                                    [[scm_init_guile ();]]),
1078                    [have_libguile_var=yes
1079                     GUILE_CPPFLAGS=$new_CPPFLAGS
1080                     GUILE_LIBS=$new_LIBS],
1081                    [found_usable_guile=no])
1082     dnl scm_set_automatic_finalization_enabled added in Guile 2.2.
1083     AC_CHECK_FUNC(scm_set_automatic_finalization_enabled,
1084       AC_DEFINE(HAVE_GUILE_MANUAL_FINALIZATION, 1,
1085                 [Define if Guile supports manual finalization.])
1086     )
1087     CPPFLAGS=$save_CPPFLAGS
1088     LIBS=$save_LIBS
1089     if test "${found_usable_guile}" = no; then
1090       if test "${flag_errors}" = yes; then
1091         AC_MSG_FAILURE([linking guile version ${guile_version} test program failed])
1092       fi
1093     fi
1094   fi
1095   AC_MSG_RESULT([${found_usable_guile}])
1096 ])
1097
1098 dnl There are several different values for --with-guile:
1099 dnl
1100 dnl no -   Don't include guile support.
1101 dnl yes -  Include guile support, error if it's missing.
1102 dnl        The pkg-config program must be in $PATH.
1103 dnl auto - Same as "yes", but if guile is missing from the system,
1104 dnl        fall back to "no".
1105 dnl guile-version [guile-version-choice-2 ...] -
1106 dnl        A space-separated list of guile package versions to try.
1107 dnl        These are passed to pkg-config as-is.
1108 dnl        E.g., guile-2.0 or guile-2.2-uninstalled
1109 dnl        This requires making sure PKG_CONFIG_PATH is set appropriately.
1110 dnl /path/to/pkg-config -
1111 dnl        Use this pkg-config program.
1112 dnl        NOTE: This needn't be the "real" pkg-config program.
1113 dnl        It could be a shell script.  It is invoked as:
1114 dnl        pkg-config --exists $version
1115 dnl        pkg-config --cflags $version
1116 dnl        pkg-config --libs $version
1117 dnl        pkg-config --variable guild $version
1118 dnl        The script will be called with $version having each value in
1119 dnl        $try_guile_versions until --exists indicates success.
1120
1121 AC_ARG_WITH(guile,
1122   AS_HELP_STRING([--with-guile@<:@=GUILE@:>@], [include guile support (auto/yes/no/<guile-version>/<pkg-config-program>)]),
1123   [], [with_guile=auto])
1124 AC_MSG_CHECKING([whether to use guile])
1125 AC_MSG_RESULT([$with_guile])
1126
1127 dnl We check guile with pkg-config.
1128 AC_PATH_PROG(pkg_config_prog_path, pkg-config, missing)
1129
1130 try_guile_versions="guile-2.2 guile-2.0"
1131 have_libguile=no
1132 case "${with_guile}" in
1133 no)
1134   AC_MSG_WARN([guile support disabled; some features will be unavailable.])
1135   ;;
1136 auto)
1137   if test "${pkg_config_prog_path}" = "missing"; then
1138     AC_MSG_WARN([pkg-config not found, guile support disabled])
1139   else
1140     AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${try_guile_versions}, no, have_libguile)
1141   fi
1142   ;;
1143 yes)
1144   if test "${pkg_config_prog_path}" = "missing"; then
1145     AC_MSG_ERROR([pkg-config not found])
1146   fi
1147   AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${try_guile_versions}, yes, have_libguile)
1148   ;;
1149 [[\\/]]* | ?:[[\\/]]*)
1150   if test -x "${with_guile}"; then
1151     AC_TRY_LIBGUILE(${with_guile}, ${try_guile_versions}, yes, have_libguile)
1152   else
1153     AC_MSG_ERROR([Guile config program not executable: ${with_guile}])
1154   fi
1155   ;;
1156 "" | */*)
1157   # Disallow --with=guile="" and --with-guile=foo/bar.
1158   AC_MSG_ERROR([invalid value for --with-guile])
1159   ;;
1160 *)
1161   # A space separate list of guile versions to try, in order.
1162   if test "${pkg_config_prog_path}" = "missing"; then
1163     AC_MSG_ERROR([pkg-config not found])
1164   fi
1165   AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${with_guile}, yes, have_libguile)
1166   ;;
1167 esac
1168
1169 if test "${have_libguile}" != no; then
1170   dnl Get the name of the 'guild' program.
1171   case "${with_guile}" in
1172   [[\\/]]* | ?:[[\\/]]*)
1173     GDB_GUILE_PROGRAM_NAMES(["${with_guile}"], ["${guile_version}"])
1174     ;;
1175   *)
1176     GDB_GUILE_PROGRAM_NAMES(["${pkg_config_prog_path}"], ["${guile_version}"])
1177     ;;
1178   esac
1179
1180   dnl Make sure guild can handle this host.
1181   GDB_TRY_GUILD([$srcdir/guile/lib/gdb/support.scm])
1182   dnl If not, disable guile support.
1183   if test "$ac_cv_guild_ok" = no; then
1184     have_libguile=no
1185     AC_MSG_WARN(disabling guile support, $GUILD fails compiling for $host)
1186   fi
1187 fi
1188
1189 if test "${have_libguile}" != no; then
1190   AC_DEFINE(HAVE_GUILE, 1, [Define if Guile interpreter is being linked in.])
1191   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_GUILE_OBS)"
1192   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_GUILE_DEPS)"
1193   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_GUILE_SRCS)"
1194   CONFIG_INSTALL="$CONFIG_INSTALL install-guile"
1195   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_GUILE_CFLAGS)"
1196
1197   dnl The 'scm_new_smob' function appeared in Guile 2.0.6.
1198   save_LIBS="$LIBS"
1199   save_CPPFLAGS="$CPPFLAGS"
1200   LIBS="$GUILE_LIBS"
1201   CPPFLAGS="$GUILE_CPPFLAGS"
1202   AC_CHECK_FUNCS([scm_new_smob])
1203   LIBS="$save_LIBS"
1204   CPPFLAGS="$save_CPPFLAGS"
1205 else
1206   # Even if Guile support is not compiled in, we need to have these files
1207   # included.
1208   CONFIG_OBS="$CONFIG_OBS guile.o"
1209   CONFIG_SRCS="$CONFIG_SRCS guile/guile.c"
1210 fi
1211 AC_SUBST(GUILE_CPPFLAGS)
1212 AC_SUBST(GUILE_LIBS)
1213 AM_CONDITIONAL(HAVE_GUILE, test "${have_libguile}" != no)
1214
1215 # --------------------- #
1216 # Check for libmcheck.  #
1217 # --------------------- #
1218
1219 # Enable -lmcheck by default (it provides cheap-enough memory mangling),
1220 # but turn it off if Python is enabled with threads, since -lmcheck is
1221 # not thread safe (http://sourceware.org/bugzilla/show_bug.cgi?id=9939),
1222 # and for releases.
1223 if test \( "${have_libpython}" = "no" -o "${python_has_threads}" = "no" \) \
1224    && $development; then
1225   libmcheck_default=yes
1226 else
1227   libmcheck_default=no
1228 fi
1229 GDB_AC_LIBMCHECK(${libmcheck_default})
1230
1231 if test "$ENABLE_LIBMCHECK" = "yes" \
1232         -a "${have_libpython}" != "no" \
1233         -a "${python_has_threads}" = "yes" ; then
1234   AC_MSG_WARN(--enable-libmcheck may lead to spurious crashes if threads are used in python)
1235 fi
1236
1237 AC_ARG_WITH(intel_pt,
1238   AS_HELP_STRING([--with-intel-pt], [include Intel Processor Trace support (auto/yes/no)]),
1239   [], [with_intel_pt=auto])
1240 AC_MSG_CHECKING([whether to use intel pt])
1241 AC_MSG_RESULT([$with_intel_pt])
1242
1243 if test "${with_intel_pt}" = no; then
1244   AC_MSG_WARN([Intel Processor Trace support disabled; some features may be unavailable.])
1245   HAVE_LIBIPT=no
1246 else
1247   AC_PREPROC_IFELSE(AC_LANG_SOURCE([[
1248 #include <linux/perf_event.h>
1249 #ifndef PERF_ATTR_SIZE_VER5
1250 # error
1251 #endif
1252   ]]), [perf_event=yes], [perf_event=no])
1253   if test "$perf_event" != yes; then
1254     if test "$with_intel_pt" = yes; then
1255       AC_MSG_ERROR([linux/perf_event.h missing or too old])
1256     else
1257       AC_MSG_WARN([linux/perf_event.h missing or too old; some features may be unavailable.])
1258     fi
1259   fi
1260
1261   AC_LIB_HAVE_LINKFLAGS([ipt], [], [#include "intel-pt.h"], [pt_insn_alloc_decoder (0);])
1262   if test "$HAVE_LIBIPT" != yes; then
1263     if test "$with_intel_pt" = yes; then
1264       AC_MSG_ERROR([libipt is missing or unusable])
1265     else
1266       AC_MSG_WARN([libipt is missing or unusable; some features may be unavailable.])
1267     fi
1268   else
1269     save_LIBS=$LIBS
1270     LIBS="$LIBS $LIBIPT"
1271     AC_CHECK_FUNCS(pt_insn_event)
1272     AC_CHECK_MEMBERS([struct pt_insn.enabled, struct pt_insn.resynced], [], [],
1273                      [#include <intel-pt.h>])
1274     LIBS=$save_LIBS
1275   fi
1276 fi
1277
1278 # ------------------------- #
1279 # Checks for header files.  #
1280 # ------------------------- #
1281
1282 AC_HEADER_STDC
1283 # elf_hp.h is for HP/UX 64-bit shared library support.
1284 AC_CHECK_HEADERS([nlist.h machine/reg.h poll.h sys/poll.h proc_service.h \
1285                   thread_db.h \
1286                   sys/fault.h \
1287                   sys/file.h sys/filio.h sys/ioctl.h sys/param.h \
1288                   sys/resource.h sys/procfs.h sys/ptrace.h ptrace.h \
1289                   sys/reg.h sys/debugreg.h sys/select.h sys/syscall.h \
1290                   termios.h termio.h \
1291                   sgtty.h elf_hp.h \
1292                   dlfcn.h])
1293 AC_CHECK_HEADERS(sys/proc.h, [], [],
1294 [#if HAVE_SYS_PARAM_H
1295 # include <sys/param.h>
1296 #endif
1297 ])
1298 AC_CHECK_HEADERS(sys/user.h, [], [],
1299 [#if HAVE_SYS_PARAM_H
1300 # include <sys/param.h>
1301 #endif
1302 ])
1303
1304 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncurses/ncurses.h ncurses/term.h)
1305 AC_CHECK_HEADERS(term.h, [], [],
1306 [#if HAVE_CURSES_H
1307 # include <curses.h>
1308 #endif
1309 ])
1310
1311 # ------------------------- #
1312 # Checks for declarations.  #
1313 # ------------------------- #
1314
1315 libiberty_INIT
1316
1317 AC_CHECK_DECLS([free, malloc, realloc, snprintf])
1318 AM_LC_MESSAGES
1319
1320 # ----------------------- #
1321 # Checks for structures.  #
1322 # ----------------------- #
1323
1324 AC_CHECK_MEMBERS([struct stat.st_blocks, struct stat.st_blksize])
1325
1326 # ------------------ #
1327 # Checks for types.  #
1328 # ------------------ #
1329
1330 AC_CHECK_TYPES(socklen_t, [], [],
1331 [#include <sys/types.h>
1332 #include <sys/socket.h>
1333 ])
1334
1335 # ------------------------------------- #
1336 # Checks for compiler characteristics.  #
1337 # ------------------------------------- #
1338
1339 AC_C_CONST
1340 AC_C_INLINE
1341 AC_C_BIGENDIAN
1342
1343 # ------------------------------ #
1344 # Checks for library functions.  #
1345 # ------------------------------ #
1346
1347 AC_FUNC_MMAP
1348 AC_FUNC_VFORK
1349 AC_CHECK_FUNCS([getauxval getrusage getuid getgid \
1350                 pipe poll pread pread64 pwrite resize_term \
1351                 sbrk setpgid setpgrp setsid \
1352                 sigaction sigprocmask sigsetmask socketpair \
1353                 ttrace wborder wresize setlocale iconvlist libiconvlist btowc \
1354                 setrlimit getrlimit posix_madvise waitpid \
1355                 ptrace64 sigaltstack mkdtemp setns])
1356 AM_LANGINFO_CODESET
1357 GDB_AC_COMMON
1358
1359 # Check the return and argument types of ptrace.
1360 GDB_AC_PTRACE
1361
1362 dnl AC_FUNC_SETPGRP does not work when cross compiling
1363 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
1364 if test "$cross_compiling" = no; then
1365   AC_FUNC_SETPGRP
1366 else
1367   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
1368     [AC_TRY_COMPILE([
1369 #include <unistd.h>
1370 ], [
1371   if (setpgrp(1,1) == -1)
1372     exit (0);
1373   else
1374     exit (1);
1375 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
1376 if test $ac_cv_func_setpgrp_void = yes; then
1377   AC_DEFINE(SETPGRP_VOID, 1)
1378 fi
1379 fi
1380
1381 # Assume we'll default to using the included libiberty regex.
1382 gdb_use_included_regex=yes
1383
1384 # However, if the system regex is GNU regex, then default to *not*
1385 # using the included regex.
1386 AC_CACHE_CHECK(
1387   [for GNU regex],
1388   [gdb_cv_have_gnu_regex],
1389   [AC_TRY_COMPILE(
1390     [#include <gnu-versions.h>],
1391     [#define REGEX_INTERFACE_VERSION 1
1392 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
1393 # error "Version mismatch"
1394 #endif],
1395     gdb_cv_have_gnu_regex=yes,
1396     gdb_cv_have_gnu_regex=no)])
1397 if test $gdb_cv_have_gnu_regex = yes; then
1398   gdb_use_included_regex=no
1399 fi
1400
1401 AC_ARG_WITH(included-regex,
1402   AS_HELP_STRING([--without-included-regex], [don't use included regex; this is the default on systems with version 2 of the GNU C library (use with caution on other system)]),
1403   gdb_with_regex=$withval,
1404   gdb_with_regex=$gdb_use_included_regex)
1405 if test "$gdb_with_regex" = yes; then
1406   AC_DEFINE(USE_INCLUDED_REGEX, 1,
1407     [Define to 1 if the regex included in libiberty should be used.])
1408 fi
1409
1410 # Check if <sys/proc.h> defines `struct thread' with a td_pcb member.
1411 AC_CHECK_MEMBERS([struct thread.td_pcb], [], [],
1412 [#include <sys/param.h>
1413 #include <sys/proc.h>
1414 ])
1415
1416 # See if <sys/lwp.h> defines `struct lwp`.
1417 AC_CACHE_CHECK([for struct lwp], gdb_cv_struct_lwp,
1418 [AC_TRY_COMPILE([#include <sys/param.h>
1419 #define _KMEMUSER
1420 #include <sys/lwp.h>], [struct lwp l;],
1421 gdb_cv_struct_lwp=yes, gdb_cv_struct_lwp=no)])
1422 if test $gdb_cv_struct_lwp = yes; then
1423   AC_DEFINE(HAVE_STRUCT_LWP, 1,
1424             [Define to 1 if your system has struct lwp.])
1425 fi
1426
1427 # See if <machine/reg.h> degines `struct reg'.
1428 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
1429 [AC_TRY_COMPILE([#include <sys/types.h>
1430 #include <machine/reg.h>], [struct reg r;],
1431 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
1432 if test $gdb_cv_struct_reg = yes; then
1433   AC_DEFINE(HAVE_STRUCT_REG, 1,
1434             [Define to 1 if your system has struct reg in <machine/reg.h>.])
1435 fi
1436
1437 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
1438 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
1439 AC_CHECK_MEMBERS([struct reg.r_fs, struct reg.r_gs], [], [],
1440                  [#include <sys/types.h>
1441 #include <machine/reg.h>])
1442
1443 # See if <sys/user.h> supports the %fs_base and %gs_bas amd64 segment registers.
1444 # Older amd64 Linux's don't have the fs_base and gs_base members of
1445 # `struct user_regs_struct'.
1446 AC_CHECK_MEMBERS([struct user_regs_struct.fs_base, struct user_regs_struct.gs_base],
1447                  [], [], [#include <sys/user.h>])
1448
1449 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
1450 AC_MSG_CHECKING(for PTRACE_GETREGS)
1451 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
1452 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1453                 [PTRACE_GETREGS;],
1454                 [gdb_cv_have_ptrace_getregs=yes],
1455                 [gdb_cv_have_ptrace_getregs=no])])
1456 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
1457 if test $gdb_cv_have_ptrace_getregs = yes; then
1458   AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
1459   [Define if sys/ptrace.h defines the PTRACE_GETREGS request.])
1460 fi
1461
1462 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
1463 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
1464 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
1465 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1466                 [PTRACE_GETFPXREGS;],
1467                 [gdb_cv_have_ptrace_getfpxregs=yes],
1468                 [gdb_cv_have_ptrace_getfpxregs=no])])
1469 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
1470 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
1471   AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
1472   [Define if sys/ptrace.h defines the PTRACE_GETFPXREGS request.])
1473 fi
1474
1475 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
1476 AC_MSG_CHECKING(for PT_GETDBREGS)
1477 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
1478 [AC_TRY_COMPILE([#include <sys/types.h>
1479 #include <sys/ptrace.h>],
1480                 [PT_GETDBREGS;],
1481                 [gdb_cv_have_pt_getdbregs=yes],
1482                 [gdb_cv_have_pt_getdbregs=no])])
1483 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
1484 if test $gdb_cv_have_pt_getdbregs = yes; then
1485   AC_DEFINE(HAVE_PT_GETDBREGS, 1,
1486   [Define if sys/ptrace.h defines the PT_GETDBREGS request.])
1487 fi
1488
1489 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
1490 AC_MSG_CHECKING(for PT_GETXMMREGS)
1491 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
1492 [AC_TRY_COMPILE([#include <sys/types.h>
1493 #include <sys/ptrace.h>],
1494                 [PT_GETXMMREGS;],
1495                 [gdb_cv_have_pt_getxmmregs=yes],
1496                 [gdb_cv_have_pt_getxmmregs=no])])
1497 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
1498 if test $gdb_cv_have_pt_getxmmregs = yes; then
1499   AC_DEFINE(HAVE_PT_GETXMMREGS, 1,
1500   [Define if sys/ptrace.h defines the PT_GETXMMREGS request.])
1501 fi
1502
1503 # See if <sys/ptrace.h> supports LWP names on FreeBSD
1504 # Older FreeBSD versions don't have the pl_tdname member of
1505 # `struct ptrace_lwpinfo'.
1506 AC_CHECK_MEMBERS([struct ptrace_lwpinfo.pl_tdname], [], [],
1507                  [#include <sys/ptrace.h>])
1508
1509 # See if <sys/ptrace.h> supports syscall fields on FreeBSD.  The
1510 # pl_syscall_code member of `struct ptrace_lwpinfo' was added in
1511 # FreeBSD 10.3.
1512 AC_CHECK_MEMBERS([struct ptrace_lwpinfo.pl_syscall_code], [], [],
1513                  [#include <sys/ptrace.h>])
1514
1515 # Detect which type of /proc is in use, such as for Solaris.
1516
1517 if test "${target}" = "${host}"; then
1518   case "${host}" in
1519   *-*-sysv4.2* | *-*-sysv5* )
1520       AC_DEFINE(NEW_PROC_API, 1,
1521       [Define if you want to use new multi-fd /proc interface.])
1522       ;;
1523   *-*-solaris2.[[6789]] | *-*-solaris2.1[[0-9]]*)
1524       AC_DEFINE(NEW_PROC_API, 1,
1525       [Define if you want to use new multi-fd /proc interface.])
1526       ;;
1527   esac
1528 fi
1529
1530 if test "$ac_cv_header_sys_procfs_h" = yes; then
1531   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
1532   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
1533   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
1534   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
1535   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
1536   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
1537   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
1538   BFD_HAVE_SYS_PROCFS_TYPE(prsysent_t)
1539   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigset_t)
1540   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigaction64_t)
1541   BFD_HAVE_SYS_PROCFS_TYPE(pr_siginfo64_t)
1542
1543
1544   dnl Check for broken prfpregset_t type
1545
1546   dnl For Linux/i386, glibc 2.1.3 was released with a bogus
1547   dnl prfpregset_t type (it's a typedef for the pointer to a struct
1548   dnl instead of the struct itself).  We detect this here, and work
1549   dnl around it in gdb_proc_service.h.
1550
1551   if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
1552     AC_MSG_CHECKING(whether prfpregset_t type is broken)
1553     AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
1554       [AC_TRY_RUN([#include <sys/procfs.h>
1555        int main ()
1556        {
1557          if (sizeof (prfpregset_t) == sizeof (void *))
1558            return 1;
1559          return 0;
1560        }],
1561        gdb_cv_prfpregset_t_broken=no,
1562        gdb_cv_prfpregset_t_broken=yes,
1563        gdb_cv_prfpregset_t_broken=yes)])
1564     AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
1565     if test $gdb_cv_prfpregset_t_broken = yes; then
1566       AC_DEFINE(PRFPREGSET_T_BROKEN, 1,
1567       [Define if the prfpregset_t type is broken.])
1568     fi
1569   fi
1570 fi
1571
1572 # Check if the compiler supports the `long long' type.
1573
1574 AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long,
1575                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1576 [[extern long long foo;]],
1577 [[switch (foo & 2) { case 0: return 1; }]])],
1578                                   gdb_cv_c_long_long=yes,
1579                                   gdb_cv_c_long_long=no)])
1580 if test $gdb_cv_c_long_long != yes; then
1581   # libdecnumber requires long long.
1582   AC_MSG_ERROR([Compiler must support long long for GDB.])
1583 fi
1584
1585 # Check if the compiler and runtime support printing long longs.
1586
1587 AC_CACHE_CHECK([for long long support in printf],
1588                gdb_cv_printf_has_long_long,
1589                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1590 [[char buf[32];
1591   long long l = 0;
1592   l = (l << 16) + 0x0123;
1593   l = (l << 16) + 0x4567;
1594   l = (l << 16) + 0x89ab;
1595   l = (l << 16) + 0xcdef;
1596   sprintf (buf, "0x%016llx", l);
1597   return (strcmp ("0x0123456789abcdef", buf));]])],
1598                               gdb_cv_printf_has_long_long=yes,
1599                               gdb_cv_printf_has_long_long=no,
1600                               gdb_cv_printf_has_long_long=no)])
1601 if test $gdb_cv_printf_has_long_long = yes; then
1602   AC_DEFINE(PRINTF_HAS_LONG_LONG, 1,
1603             [Define to 1 if the "%ll" format works to print long longs.])
1604 fi
1605
1606 # Check if the compiler and runtime support printing decfloats.
1607
1608 AC_CACHE_CHECK([for decfloat support in printf],
1609                gdb_cv_printf_has_decfloat,
1610                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1611 [[char buf[64];
1612   _Decimal32 d32 = 1.2345df;
1613   _Decimal64 d64 = 1.2345dd;
1614   _Decimal128 d128 = 1.2345dl;
1615   sprintf (buf, "Decimal32: %H\nDecimal64: %D\nDecimal128: %DD", d32, d64, d128);
1616   return (strcmp ("Decimal32: 1.2345\nDecimal64: 1.2345\nDecimal128: 1.2345", buf));]])],
1617                               gdb_cv_printf_has_decfloat=yes,
1618                               gdb_cv_printf_has_decfloat=no,
1619                               gdb_cv_printf_has_decfloat=no)])
1620 if test $gdb_cv_printf_has_decfloat = yes; then
1621   AC_DEFINE(PRINTF_HAS_DECFLOAT, 1,
1622             [Define to 1 if the "%H, %D and %DD" formats work to print decfloats.])
1623 fi
1624
1625 # Check if the compiler supports the `long double' type.  We can't use
1626 # AC_C_LONG_DOUBLE because that one does additional checks on the
1627 # constants defined in <float.h> that fail on some systems,
1628 # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6.
1629
1630 AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double,
1631                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])],
1632                                   gdb_cv_c_long_double=yes,
1633                                   gdb_cv_c_long_double=no)])
1634 if test $gdb_cv_c_long_double = yes; then
1635   AC_DEFINE(HAVE_LONG_DOUBLE, 1,
1636            [Define to 1 if the compiler supports long double.])
1637 fi
1638
1639 # Check if the compiler and runtime support printing long doubles.
1640
1641 AC_CACHE_CHECK([for long double support in printf],
1642                gdb_cv_printf_has_long_double,
1643                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1644 [[char buf[16];
1645   long double f = 3.141592653;
1646   sprintf (buf, "%Lg", f);
1647   return (strncmp ("3.14159", buf, 7));]])],
1648                               gdb_cv_printf_has_long_double=yes,
1649                               gdb_cv_printf_has_long_double=no,
1650                               gdb_cv_printf_has_long_double=no)])
1651 if test $gdb_cv_printf_has_long_double = yes; then
1652   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1,
1653             [Define to 1 if the "%Lg" format works to print long doubles.])
1654 fi
1655
1656 # Check if the compiler and runtime support scanning long doubles.
1657
1658 AC_CACHE_CHECK([for long double support in scanf],
1659                gdb_cv_scanf_has_long_double,
1660                [AC_RUN_IFELSE([AC_LANG_PROGRAM(
1661 [[#include <stdio.h>]],
1662 [[char *buf = "3.141592653";
1663   long double f = 0;
1664   sscanf (buf, "%Lg", &f);
1665   return !(f > 3.14159 && f < 3.14160);]])],
1666                               gdb_cv_scanf_has_long_double=yes,
1667                               gdb_cv_scanf_has_long_double=no,
1668                               gdb_cv_scanf_has_long_double=no)])
1669 if test $gdb_cv_scanf_has_long_double = yes; then
1670   AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1,
1671             [Define to 1 if the "%Lg" format works to scan long doubles.])
1672 fi
1673
1674 case ${host_os} in
1675 aix*)
1676   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1677     SAVE_LDFLAGS=$LDFLAGS
1678
1679     case $GCC in
1680     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1681     *) gdb_cv_bigtoc=-bbigtoc ;;
1682     esac
1683
1684     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1685     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1686     LDFLAGS="${SAVE_LDFLAGS}"
1687   ])
1688   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
1689   ;;
1690 esac
1691
1692 AC_MSG_CHECKING(for the dynamic export flag)
1693 dynamic_list=false
1694 if test "${gdb_native}" = yes; then
1695    # The dynamically loaded libthread_db needs access to symbols in the gdb
1696    # executable.  Older GNU ld supports --export-dynamic but --dynamic-list
1697    # may not be supported there.
1698    old_LDFLAGS="$LDFLAGS"
1699    # Older GNU ld supports --export-dynamic but --dynamic-list it does not.
1700    RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
1701    LDFLAGS="$LDFLAGS $RDYNAMIC"
1702    if test "${have_libpython}" = no; then
1703      AC_TRY_LINK([], [], [dynamic_list=true])
1704    else
1705      # Workaround http://bugs.python.org/issue4434 where static
1706      # libpythonX.Y.a would get its symbols required for
1707      # pythonX.Y/lib-dynload/*.so modules hidden by -Wl,--dynamic-list.
1708      # Problem does not happen for the recommended libpythonX.Y.so linkage.
1709
1710      # Note the workaround for Python
1711      # http://bugs.python.org/issue10112 earlier has removed
1712      # -export-dynamic from PYTHON_LIBS.  That's exactly what we want
1713      # here too, as otherwise it'd make this -Wl,--dynamic-list test
1714      # always pass.
1715      old_CFLAGS="$CFLAGS"
1716      CFLAGS="$CFLAGS $PYTHON_CFLAGS"
1717      old_LIBS="$LIBS"
1718      LIBS="$LIBS $PYTHON_LIBS"
1719      old_CPPFLAGS="$CPPFLAGS"
1720      CPPFLAGS="$CPPFLAGS $PYTHON_CPPFLAGS"
1721      AC_RUN_IFELSE(
1722        AC_LANG_PROGRAM(
1723          [#include "Python.h"],
1724          [int err;
1725           Py_Initialize ();
1726           err = PyRun_SimpleString ("import itertools\n");
1727           Py_Finalize ();
1728           return err == 0 ? 0 : 1;]),
1729        [dynamic_list=true], [], [true])
1730      LIBS="$old_LIBS"
1731      CFLAGS="$old_CFLAGS"
1732      CPPFLAGS="$old_CPPFLAGS"
1733    fi
1734    LDFLAGS="$old_LDFLAGS"
1735 fi
1736 if $dynamic_list; then
1737   found="-Wl,--dynamic-list"
1738   RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'
1739 else
1740   found="-rdynamic"
1741   RDYNAMIC="-rdynamic"
1742 fi
1743 AC_SUBST(RDYNAMIC)
1744 AC_MSG_RESULT($found)
1745
1746 dnl For certain native configurations, we need to check whether thread
1747 dnl support can be built in or not.
1748 dnl
1749 dnl Note that we only want this if we are both native (host == target),
1750 dnl and not doing a canadian cross build (build == host).
1751
1752 if test ${build} = ${host} -a ${host} = ${target} ; then
1753    case ${host_os} in
1754    aix*)
1755       AC_MSG_CHECKING(for AiX thread debugging library)
1756       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
1757                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
1758                                    [#ifndef PTHDB_VERSION_3
1759                                     #error
1760                                     #endif],
1761                                    gdb_cv_have_aix_thread_debug=yes,
1762                                    gdb_cv_have_aix_thread_debug=no)])
1763       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1764       if test $gdb_cv_have_aix_thread_debug = yes; then
1765          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1766          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1767          LIBS="$LIBS -lpthdebug"
1768
1769          # Older versions of AIX do not provide the declaration for
1770          # the getthrds function (it appears that it was introduced
1771          # with AIX 6.x).
1772          AC_CHECK_DECLS(getthrds, [], [], [[#include <procinfo.h>]])
1773       fi
1774       ;;
1775    esac
1776    AC_SUBST(CONFIG_LDFLAGS)
1777 fi
1778
1779 dnl See if we have a thread_db header file that has TD_NOTALLOC and
1780 dnl other error codes.
1781 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1782    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
1783                   gdb_cv_thread_db_h_has_td_notalloc,
1784      AC_TRY_COMPILE(
1785        [#include <thread_db.h>],
1786        [int i = TD_NOTALLOC;],
1787        gdb_cv_thread_db_h_has_td_notalloc=yes,
1788        gdb_cv_thread_db_h_has_td_notalloc=no
1789      )
1790    )
1791    AC_CACHE_CHECK([whether <thread_db.h> has TD_VERSION],
1792                   gdb_cv_thread_db_h_has_td_version,
1793      AC_TRY_COMPILE(
1794        [#include <thread_db.h>],
1795        [int i = TD_VERSION;],
1796        gdb_cv_thread_db_h_has_td_version=yes,
1797        gdb_cv_thread_db_h_has_td_version=no
1798      )
1799    )
1800    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTLS],
1801                   gdb_cv_thread_db_h_has_td_notls,
1802      AC_TRY_COMPILE(
1803        [#include <thread_db.h>],
1804        [int i = TD_NOTLS;],
1805        gdb_cv_thread_db_h_has_td_notls=yes,
1806        gdb_cv_thread_db_h_has_td_notls=no
1807      )
1808    )
1809 fi
1810 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1811   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1812             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1813 fi
1814 if test "x$gdb_cv_thread_db_h_has_td_version" = "xyes"; then
1815   AC_DEFINE(THREAD_DB_HAS_TD_VERSION, 1,
1816             [Define if <thread_db.h> has the TD_VERSION error code.])
1817 fi
1818 if test "x$gdb_cv_thread_db_h_has_td_notls" = "xyes"; then
1819   AC_DEFINE(THREAD_DB_HAS_TD_NOTLS, 1,
1820             [Define if <thread_db.h> has the TD_NOTLS error code.])
1821 fi
1822
1823 dnl Check if we can disable the virtual address space randomization.
1824 dnl The functionality of setarch -R.
1825 AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>])
1826 define([PERSONALITY_TEST], [AC_LANG_PROGRAM([#include <sys/personality.h>], [
1827 #      if !HAVE_DECL_ADDR_NO_RANDOMIZE
1828 #       define ADDR_NO_RANDOMIZE 0x0040000
1829 #      endif
1830        /* Test the flag could be set and stays set.  */
1831        personality (personality (0xffffffff) | ADDR_NO_RANDOMIZE);
1832        if (!(personality (personality (0xffffffff)) & ADDR_NO_RANDOMIZE))
1833            return 1])])
1834 AC_RUN_IFELSE([PERSONALITY_TEST],
1835               [have_personality=true],
1836               [have_personality=false],
1837               [AC_LINK_IFELSE([PERSONALITY_TEST],
1838                               [have_personality=true],
1839                               [have_personality=false])])
1840 if $have_personality
1841 then
1842     AC_DEFINE([HAVE_PERSONALITY], 1,
1843               [Define if you support the personality syscall.])
1844 fi
1845
1846 dnl Set the host's .gdbinit filename.
1847 case $host_os in
1848   go32* | *djgpp*)
1849     gdbinit=gdb.ini
1850     ;;
1851   *)
1852     gdbinit=.gdbinit
1853     ;;
1854 esac
1855 AC_DEFINE_UNQUOTED(GDBINIT,"$gdbinit",[The .gdbinit filename.])
1856
1857 dnl Handle optional features that can be enabled.
1858
1859 # Support for --with-sysroot is a copy of GDB_AC_WITH_DIR,
1860 # except that the argument to --with-sysroot is optional.
1861 # --with-sysroot (or --with-sysroot=yes) sets the default sysroot path.
1862 if test "x$with_sysroot" = xyes; then
1863   with_sysroot="${exec_prefix}/${target_alias}/sys-root"
1864 fi
1865 AC_ARG_WITH(sysroot,
1866   AS_HELP_STRING([--with-sysroot@<:@=DIR@:>@],
1867                  [search for usr/lib et al within DIR]),
1868   [TARGET_SYSTEM_ROOT=$withval], [TARGET_SYSTEM_ROOT=])
1869 AC_DEFINE_DIR(TARGET_SYSTEM_ROOT, TARGET_SYSTEM_ROOT,
1870               [search for usr/lib et al within DIR])
1871 AC_SUBST(TARGET_SYSTEM_ROOT)
1872 GDB_AC_DEFINE_RELOCATABLE(TARGET_SYSTEM_ROOT, sysroot, ${ac_define_dir})
1873
1874 GDB_AC_WITH_DIR(SYSTEM_GDBINIT, system-gdbinit,
1875     [automatically load a system-wide gdbinit file],
1876     [])
1877
1878 AM_GDB_WARNINGS
1879
1880 # In the Cygwin environment, we need some additional flags.
1881 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1882 [AC_EGREP_CPP(^lose$, [
1883 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1884 lose
1885 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1886
1887
1888 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1889 SER_HARDWIRE="ser-base.o ser-unix.o ser-pipe.o ser-tcp.o"
1890 case ${host} in
1891   *go32* ) SER_HARDWIRE=ser-go32.o ;;
1892   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
1893   *mingw32*) SER_HARDWIRE="ser-base.o ser-tcp.o ser-mingw.o" ;;
1894 esac
1895 AC_SUBST(SER_HARDWIRE)
1896
1897 # libreadline needs libuser32.a in a cygwin environment
1898 WIN32LIBS=
1899 if test x$gdb_cv_os_cygwin = xyes; then
1900     WIN32LIBS="-luser32"
1901     case "${target}" in
1902         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
1903         ;;
1904     esac
1905 fi
1906
1907 # The ser-tcp.c module requires sockets.
1908 case ${host} in
1909   *mingw32*)
1910     AC_DEFINE(USE_WIN32API, 1,
1911               [Define if we should use the Windows API, instead of the
1912                POSIX API.  On Windows, we use the Windows API when
1913                building for MinGW, but the POSIX API when building
1914                for Cygwin.])
1915     WIN32LIBS="$WIN32LIBS -lws2_32"
1916     ;;
1917 esac
1918 AC_SUBST(WIN32LIBS)
1919
1920 # Add ELF support to GDB, but only if BFD includes ELF support.
1921 GDB_AC_CHECK_BFD([for ELF support in BFD], gdb_cv_var_elf,
1922                  [bfd_get_elf_phdr_upper_bound (NULL)], elf-bfd.h)
1923 if test $gdb_cv_var_elf = yes; then
1924   CONFIG_OBS="$CONFIG_OBS elfread.o stap-probe.o dtrace-probe.o"
1925   AC_DEFINE(HAVE_ELF, 1,
1926             [Define if ELF support should be included.])
1927   # -ldl is provided by bfd/Makfile.am (LIBDL) <PLUGINS>.
1928   if test "$plugins" = "yes"; then
1929     AC_SEARCH_LIBS(dlopen, dl)
1930   fi
1931 fi
1932
1933 # Add macho support to GDB, but only if BFD includes it.
1934 GDB_AC_CHECK_BFD([for Mach-O support in BFD], gdb_cv_var_macho,
1935                  [bfd_mach_o_lookup_command (NULL, 0, NULL)], mach-o.h)
1936 if test $gdb_cv_var_macho = yes; then
1937   CONFIG_OBS="$CONFIG_OBS machoread.o"
1938 fi
1939
1940 # Add any host-specific objects to GDB.
1941 CONFIG_OBS="${CONFIG_OBS} ${gdb_host_obs}"
1942
1943 # If building on ELF, look for lzma support for embedded compressed debug info.
1944 if test $gdb_cv_var_elf = yes; then
1945   AC_ARG_WITH(lzma,
1946     AS_HELP_STRING([--with-lzma], [support lzma compression (auto/yes/no)]),
1947     [], [with_lzma=auto])
1948   AC_MSG_CHECKING([whether to use lzma])
1949   AC_MSG_RESULT([$with_lzma])
1950
1951   if test "${with_lzma}" != no; then
1952     AC_LIB_HAVE_LINKFLAGS([lzma], [], [#include "lzma.h"],
1953                           [lzma_index_iter iter;
1954                            lzma_index_iter_init (&iter, 0);
1955                            lzma_mf_is_supported (LZMA_MF_HC3);])
1956     if test "$HAVE_LIBLZMA" != yes; then
1957       if test "$with_lzma" = yes; then
1958         AC_MSG_ERROR([missing liblzma for --with-lzma])
1959       fi
1960     fi
1961   fi
1962 fi
1963
1964 LIBGUI="../libgui/src/libgui.a"
1965 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
1966 AC_SUBST(LIBGUI)
1967 AC_SUBST(GUI_CFLAGS_X)
1968
1969 WIN32LDAPP=
1970 AC_SUBST(WIN32LIBS)
1971 AC_SUBST(WIN32LDAPP)
1972
1973 case "${host}" in
1974 *-*-cygwin* | *-*-mingw* )
1975     configdir="win"
1976     ;;
1977 *)
1978     configdir="unix"
1979     ;;
1980 esac
1981
1982 GDBTKLIBS=
1983 if test "${enable_gdbtk}" = "yes"; then
1984
1985     # Gdbtk must have an absolute path to srcdir in order to run
1986     # properly when not installed.
1987     here=`pwd`
1988     cd ${srcdir}
1989     GDBTK_SRC_DIR=`pwd`
1990     cd $here
1991
1992     SC_PATH_TCLCONFIG
1993
1994     # If $no_tk is nonempty, then we can't do Tk, and there is no
1995     # point to doing Tcl.
1996     SC_PATH_TKCONFIG
1997
1998     if test -z "${no_tcl}" -a -z "${no_tk}"; then
1999         SC_LOAD_TCLCONFIG
2000
2001         # Check for in-tree tcl
2002         here=`pwd`
2003         cd ${srcdir}/..
2004         topdir=`pwd`
2005         cd ${here}
2006
2007         intree="no"
2008         if test "${TCL_SRC_DIR}" = "${topdir}/tcl"; then
2009           intree="yes"
2010         fi
2011
2012         # Find Tcl private headers
2013         if test x"${intree}" = xno; then
2014           CY_AC_TCL_PRIVATE_HEADERS
2015           TCL_INCLUDE="${TCL_INCLUDE_SPEC} ${TCL_PRIVATE_INCLUDE}"
2016           TCL_LIBRARY="${TCL_LIB_SPEC}"
2017           TCL_DEPS=""
2018         else
2019           # If building tcl in the same src tree, private headers
2020           # are not needed, but we need to be sure to use the right
2021           # headers library
2022           TCL_INCLUDE="-I${TCL_SRC_DIR}/generic"
2023           TCL_LIBRARY="${TCL_BUILD_LIB_SPEC}"
2024           TCL_DEPS="../tcl/${configdir}${TCL_LIB_FILE}"
2025         fi
2026         AC_SUBST(TCL_INCLUDE)
2027         AC_SUBST(TCL_LIBRARY)
2028         AC_SUBST(TCL_DEPS)
2029
2030         SC_LOAD_TKCONFIG
2031
2032         # Check for in-tree Tk
2033         intree="no"
2034         if test "${TK_SRC_DIR}" = "${topdir}/tk"; then
2035           intree="yes"
2036         fi
2037
2038         # Find Tk private headers
2039         if test x"${intree}" = xno; then
2040           CY_AC_TK_PRIVATE_HEADERS
2041           TK_INCLUDE="${TK_INCLUDE_SPEC} ${TK_PRIVATE_INCLUDE}"
2042           TK_LIBRARY=${TK_LIB_SPEC}
2043           TK_DEPS=""
2044         else
2045           TK_INCLUDE="-I${TK_SRC_DIR}/generic"
2046           TK_LIBRARY="${TK_BUILD_LIB_SPEC}"
2047           TK_DEPS="../tk/${configdir}/${TK_LIB_FILE}"
2048         fi
2049         AC_SUBST(TK_INCLUDE)
2050         AC_SUBST(TK_LIBRARY)
2051         AC_SUBST(TK_DEPS)
2052         AC_SUBST(TK_XINCLUDES)
2053
2054         ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
2055
2056         # Include some libraries that Tcl and Tk want.
2057         TCL_LIBS='$(LIBGUI) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
2058         # Yes, the ordering seems wrong here.  But it isn't.
2059         # TK_LIBS is the list of libraries that need to be linked
2060         # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
2061         # were in LIBS then any link tests after this point would
2062         # try to include things like `$(LIBGUI)', which wouldn't work.
2063         GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
2064
2065         CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
2066         CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
2067         CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
2068         CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
2069         CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
2070         CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
2071         CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
2072
2073         if test x$gdb_cv_os_cygwin = xyes; then
2074           WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
2075           WIN32LDAPP="-Wl,--subsystem,console"
2076           CONFIG_OBS="${CONFIG_OBS} gdbres.o"
2077         fi
2078
2079         AC_CONFIG_SUBDIRS(gdbtk)
2080     fi
2081 fi
2082
2083 AC_SUBST(X_CFLAGS)
2084 AC_SUBST(X_LDFLAGS)
2085 AC_SUBST(X_LIBS)
2086 AC_SUBST(GDBTKLIBS)
2087 AC_SUBST(GDBTK_CFLAGS)
2088 AC_SUBST(GDBTK_SRC_DIR)
2089
2090 AC_PATH_X
2091
2092 # Unlike the sim directory, whether a simulator is linked is controlled by
2093 # presence of a gdb_sim definition in the target configure.tgt entry.
2094 # This code just checks for a few cases where we'd like to ignore those
2095 # definitions, even when they're present in the '.mt' file.  These cases
2096 # are when --disable-sim is specified, or if the simulator directory is
2097 # not part of the source tree.
2098 #
2099 AC_ARG_ENABLE(sim,
2100 AS_HELP_STRING([--enable-sim], [link gdb with simulator]),
2101 [echo "enable_sim = $enable_sim";
2102  echo "enableval = ${enableval}";
2103  case "${enableval}" in
2104   yes) ignore_sim=false ;;
2105   no)  ignore_sim=true ;;
2106   *)   ignore_sim=false ;;
2107  esac],
2108 [ignore_sim=false])
2109
2110 if test ! -d "${srcdir}/../sim"; then
2111   ignore_sim=true
2112 fi
2113
2114 SIM=
2115 SIM_OBS=
2116 if test "${ignore_sim}" = "false"; then
2117   if test x"${gdb_sim}" != x ; then
2118     SIM="${gdb_sim}"
2119     SIM_OBS="remote-sim.o"
2120     AC_DEFINE(WITH_SIM, 1, [Define if the simulator is being linked in.])
2121
2122     # Some tdep code should only be compiled in when the ppc sim is
2123     # built.  PR sim/13418.
2124     case $target in
2125       powerpc*-*-*)
2126         AC_DEFINE(WITH_PPC_SIM, 1, [Define if the PPC simulator is being linked in.])
2127         ;;
2128     esac
2129   fi
2130 fi
2131 AC_SUBST(SIM)
2132 AC_SUBST(SIM_OBS)
2133
2134 AC_SUBST(ENABLE_CFLAGS)
2135 AC_SUBST(PROFILE_CFLAGS)
2136
2137 AC_SUBST(CONFIG_OBS)
2138 AC_SUBST(CONFIG_DEPS)
2139 AC_SUBST(CONFIG_SRCS)
2140 AC_SUBST(CONFIG_ALL)
2141 AC_SUBST(CONFIG_CLEAN)
2142 AC_SUBST(CONFIG_INSTALL)
2143 AC_SUBST(CONFIG_UNINSTALL)
2144
2145 # List of host floatformats.
2146 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
2147 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
2148 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
2149
2150 # target_subdir is used by the testsuite to find the target libraries.
2151 target_subdir=
2152 if test "${host}" != "${target}"; then
2153     target_subdir="${target_alias}/"
2154 fi
2155 AC_SUBST(target_subdir)
2156
2157 # Import nat definitions.
2158 nat_makefile_frag=/dev/null
2159 if test "${gdb_native}" = "yes"; then
2160   . ${srcdir}/configure.nat
2161   nativefile=$NAT_FILE
2162 fi
2163
2164 AC_SUBST(NAT_FILE)
2165 AC_SUBST(NATDEPFILES)
2166 AC_SUBST(NAT_CDEPS)
2167 AC_SUBST(LOADLIBES)
2168 AC_SUBST(MH_CFLAGS)
2169 AC_SUBST(XM_CLIBS)
2170 AC_SUBST(NAT_GENERATED_FILES)
2171 AC_SUBST(HAVE_NATIVE_GCORE_HOST)
2172 AC_SUBST_FILE(nat_makefile_frag)
2173
2174 if test x"${gdb_osabi}" != x ; then
2175     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
2176                        [Define to the default OS ABI for this configuration.])
2177 fi
2178
2179 # Enable multi-ice-gdb-server.
2180 AC_ARG_ENABLE(multi-ice,
2181 AS_HELP_STRING([--enable-multi-ice], [build the multi-ice-gdb-server]),
2182   [case $enableval in
2183     yes | no)
2184       ;;
2185     *) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;;
2186   esac])
2187 if test "x$enable_multi_ice" = xyes; then
2188    AC_CONFIG_SUBDIRS(multi-ice)
2189 fi
2190
2191 AC_ARG_ENABLE(gdbserver,
2192 AS_HELP_STRING([--enable-gdbserver],
2193                [automatically build gdbserver (yes/no/auto, default is auto)]),
2194 [case "${enableval}" in
2195   yes| no|auto) ;;
2196   *) AC_MSG_ERROR(bad value ${enableval} for --enable-gdbserver option) ;;
2197 esac],[enable_gdbserver=auto])
2198
2199 # We only build gdbserver automatically in a native configuration, and
2200 # only if the user did not explicitly disable its build.
2201 if test "$gdb_native" = "yes" -a "$enable_gdbserver" != "no"; then
2202   AC_MSG_CHECKING(whether gdbserver is supported on this host)
2203   if test "x$build_gdbserver" = xyes; then
2204     AC_MSG_RESULT(yes)
2205     AC_CONFIG_SUBDIRS(gdbserver)
2206     gdbserver_build_enabled=yes
2207   else
2208     AC_MSG_RESULT(no)
2209   fi
2210 fi
2211
2212 # If the user explicitly request the gdbserver to be built, verify that
2213 # we were in fact able to enable it.
2214 if test "$enable_gdbserver" = "yes" -a "$gdbserver_build_enabled" != "yes"; then
2215   AC_MSG_ERROR(Automatic gdbserver build is not supported for this configuration)
2216 fi
2217
2218 # Check for babeltrace and babeltrace-ctf
2219 AC_ARG_WITH(babeltrace,
2220   AC_HELP_STRING([--with-babeltrace], [include babeltrace support (auto/yes/no)]),
2221   [], [with_babeltrace=auto])
2222 AC_MSG_CHECKING([whether to use babeltrace])
2223 AC_MSG_RESULT([$with_babeltrace])
2224
2225 if test "x$with_babeltrace" = "xno"; then
2226   AC_MSG_WARN([babletrace support disabled; GDB is unable to read CTF data.])
2227 else
2228   # Append -Werror to CFLAGS so that configure can catch the warning
2229   # "assignment from incompatible pointer type", which is related to
2230   # the babeltrace change from 1.0.3 to 1.1.0.  Babeltrace 1.1.0 works
2231   # in GDB, while babeltrace 1.0.3 is broken.
2232   # AC_LIB_HAVE_LINKFLAGS may modify CPPFLAGS in it, so it should be
2233   # safe to save and restore CFLAGS here.
2234   saved_CFLAGS=$CFLAGS
2235   CFLAGS="$CFLAGS -Werror"
2236   AC_LIB_HAVE_LINKFLAGS([babeltrace], [babeltrace-ctf],
2237                         [#include <babeltrace/babeltrace.h>
2238                          #include <babeltrace/ctf/events.h>
2239                          #include <babeltrace/ctf/iterator.h>],
2240                         [struct bt_iter_pos *pos = bt_iter_get_pos (bt_ctf_get_iter (NULL));
2241                         struct bt_ctf_event *event = NULL;
2242                         const struct bt_definition *scope;
2243
2244                         pos->type = BT_SEEK_BEGIN;
2245                         bt_iter_set_pos (bt_ctf_get_iter (NULL), pos);
2246                         scope = bt_ctf_get_top_level_scope (event,
2247                                                            BT_STREAM_EVENT_HEADER);
2248                         bt_ctf_get_uint64 (bt_ctf_get_field (event, scope, "id"));
2249                         ])
2250   CFLAGS=$saved_CFLAGS
2251
2252   if test "$HAVE_LIBBABELTRACE" != yes; then
2253      if test "$with_babeltrace" = yes; then
2254        AC_MSG_ERROR([babeltrace is missing or unusable])
2255      else
2256        AC_MSG_WARN([babeltrace is missing or unusable; GDB is unable to read CTF data.])
2257      fi
2258   fi
2259 fi
2260
2261 # If nativefile (NAT_FILE) is not set in configure.nat, we link to an
2262 # empty version.
2263
2264 files=
2265 links=
2266
2267 rm -f nm.h
2268 if test "${nativefile}" != ""; then
2269     case "${nativefile}" in
2270       nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
2271       * ) GDB_NM_FILE="${nativefile}"
2272     esac
2273     files="${files} ${GDB_NM_FILE}"
2274     links="${links} nm.h"
2275     AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}", [nativefile])
2276 fi
2277 AC_SUBST(GDB_NM_FILE)
2278
2279 dnl Add dependency for xsltproc if building with maintainer-mode enabled.
2280 AC_PATH_PROGS(XSLTPROC, xsltproc, missing)
2281 if test "x$USE_MAINTAINER_MODE" = xyes; then
2282   if test "${XSLTPROC}" = missing; then
2283     AC_ERROR(unable to find xsltproc.  maintainer-mode requires xsltproc.)
2284   fi
2285 fi
2286 AC_SUBST(XSLTPROC)
2287
2288 AC_LINK_FILES($files, $links)
2289
2290 dnl Check for exe extension set on certain hosts (e.g. Win32)
2291 AC_EXEEXT
2292
2293 dnl  Detect the character set used by this host.
2294 dnl  At the moment, we just assume it's UTF-8.
2295 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "UTF-8",
2296           [Define to be a string naming the default host character set.])
2297
2298 if $development; then
2299   AC_DEFINE(GDB_SELF_TEST, 1,
2300             [Define if self-testing features should be enabled])
2301   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_UNITTESTS_OBS)"
2302   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_UNITTESTS_SRCS)"
2303 fi
2304
2305 GDB_AC_TRANSFORM([gdb], [GDB_TRANSFORM_NAME])
2306 GDB_AC_TRANSFORM([gcore], [GCORE_TRANSFORM_NAME])
2307 AC_CONFIG_FILES([gcore], [chmod +x gcore])
2308 AC_CONFIG_FILES([Makefile gdb-gdb.gdb doc/Makefile data-directory/Makefile],
2309 [
2310 case x$CONFIG_HEADERS in
2311 xconfig.h:config.in)
2312 echo > stamp-h ;;
2313 esac
2314 ])
2315
2316 AC_OUTPUT