gdb/configure.ac

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995-2015 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Process this file with autoconf to produce a configure script.
  20
  21 AC_PREREQ(2.59)dnl
  22 AC_INIT(main.c)
  23 AC_CONFIG_HEADER(config.h:config.in)
  24 AM_MAINTAINER_MODE
  25
  26 # Set the 'development' global.
  27 . $srcdir/../bfd/development.sh
  28
  29 AC_PROG_CC
  30 AC_PROG_CXX
  31
  32 AC_USE_SYSTEM_EXTENSIONS
  33 ACX_LARGEFILE
  34 AM_PROG_CC_STDC
  35 AM_PROG_INSTALL_STRIP
  36
  37 AC_CONFIG_AUX_DIR(..)
  38 AC_CANONICAL_SYSTEM
  39 AC_ARG_PROGRAM
  40
  41 # See if we are building with C++, and substitute COMPILER.
  42 GDB_AC_BUILD_WITH_CXX
  43
  44 # Dependency checking.
  45 ZW_CREATE_DEPDIR
  46 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  47
  48 # Check for the 'make' the user wants to use.
  49 AC_CHECK_PROGS(MAKE, make)
  50 MAKE_IS_GNU=
  51 case "`$MAKE --version 2>&1 | sed 1q`" in
  52   *GNU*)
  53     MAKE_IS_GNU=yes
  54     ;;
  55 esac
  56 AM_CONDITIONAL(GMAKE, test "$MAKE_IS_GNU" = yes)
  57 AC_PROG_MAKE_SET
  58
  59 gnulib_extra_configure_args=
  60 # If large-file support is disabled, make sure gnulib does the same.
  61 if test "$enable_largefile" = no; then
  62 gnulib_extra_configure_args="$gnulib_extra_configure_args --disable-largefile"
  63 fi
  64
  65 # Configure gnulib.  We need to build gnulib under some other
  66 # directory not "gnulib", to avoid the problem of both GDB and
  67 # GDBserver wanting to build it in the same directory, when building
  68 # in the source dir.
  69 ACX_CONFIGURE_DIR(["gnulib"], ["build-gnulib"],
  70                   ["$gnulib_extra_configure_args"])
  71
  72 dnl List of object files and targets accumulated by configure.
  73
  74 CONFIG_OBS=
  75 CONFIG_DEPS=
  76 CONFIG_SRCS=
  77 ENABLE_CFLAGS=
  78
  79 CONFIG_ALL=
  80 CONFIG_CLEAN=
  81 CONFIG_INSTALL=
  82 CONFIG_UNINSTALL=
  83
  84 dnl Set up for gettext.
  85 ZW_GNU_GETTEXT_SISTER_DIR
  86
  87 localedir='${datadir}/locale'
  88 AC_SUBST(localedir)
  89
  90 if test x"$USE_NLS" = xyes; then
  91    CONFIG_ALL="$CONFIG_ALL all-po"
  92    CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
  93    CONFIG_INSTALL="$CONFIG_INSTALL install-po"
  94    CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
  95 fi
  96
  97 GNULIB=build-gnulib/import
  98
  99 # For Makefile dependencies.
 100 GNULIB_STDINT_H=
 101 if test x"$STDINT_H" != x; then
 102   GNULIB_STDINT_H=$GNULIB/$STDINT_H
 103 fi
 104 AC_SUBST(GNULIB_STDINT_H)
 105
 106 PACKAGE=gdb
 107 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
 108 AC_SUBST(PACKAGE)
 109
 110 # We never need to detect it in this sub-configure.
 111 # But preserve it for config.status --recheck.
 112 AC_ARG_VAR(MAKEINFO,
 113   [Parent configure detects if it is of sufficient version.])
 114 AC_ARG_VAR(MAKEINFOFLAGS,
 115   [Parameters for MAKEINFO.])
 116
 117 MAKEINFO_EXTRA_FLAGS=""
 118 AC_CACHE_CHECK([whether $MAKEINFO supports @click], gdb_cv_have_makeinfo_click,
 119   [echo '@clicksequence{a @click{} b}' >conftest.texinfo
 120   if eval "$MAKEINFO conftest.texinfo >&5 2>&5"; then
 121     gdb_cv_have_makeinfo_click=yes
 122   else
 123     gdb_cv_have_makeinfo_click=no
 124   fi])
 125 if test x"$gdb_cv_have_makeinfo_click" = xyes; then
 126   MAKEINFO_EXTRA_FLAGS="$MAKEINFO_EXTRA_FLAGS -DHAVE_MAKEINFO_CLICK"
 127 fi
 128 AC_SUBST(MAKEINFO_EXTRA_FLAGS)
 129
 130 GDB_AC_WITH_DIR(DEBUGDIR, separate-debug-dir,
 131     [look for global separate debug info in this path @<:@LIBDIR/debug@:>@],
 132     [${libdir}/debug])
 133
 134 # We can't pass paths as command line arguments.
 135 # Mingw32 tries to be clever and will convert the paths for us.
 136 # For example -DBINDIR="/usr/local/bin" passed on the command line may get
 137 # converted to -DBINDIR="E:/msys/mingw32/msys/1.0/local/bin".
 138 # This breaks GDB's relocatable path conversions since paths passed in
 139 # config.h would not get so translated, the path prefixes no longer match.
 140 AC_DEFINE_DIR(BINDIR, bindir, [Directory of programs.])
 141
 142 # GDB's datadir relocation
 143
 144 GDB_AC_WITH_DIR(GDB_DATADIR, gdb-datadir,
 145     [look for global separate data files in this path @<:@DATADIR/gdb@:>@],
 146     [${datadir}/gdb])
 147
 148 AC_ARG_WITH(relocated-sources,
 149 AS_HELP_STRING([--with-relocated-sources=PATH], [automatically relocate this path for source files]),
 150 [reloc_srcdir="${withval}"
 151  AC_DEFINE_DIR(RELOC_SRCDIR, reloc_srcdir,
 152               [Relocated directory for source files. ])
 153 ])
 154
 155 AC_MSG_CHECKING([for default auto-load directory])
 156 AC_ARG_WITH(auto-load-dir,
 157 AS_HELP_STRING([--with-auto-load-dir=PATH],
 158   [directories from which to load auto-loaded scripts @<:@$debugdir:$datadir/auto-load@:>@]),,
 159   [with_auto_load_dir='$debugdir:$datadir/auto-load'])
 160 escape_dir=`echo $with_auto_load_dir | sed 's/[[$]]\(datadir\|debugdir\)\>/\\\\\\\\\\\\&/g'`
 161 AC_DEFINE_DIR(AUTO_LOAD_DIR, escape_dir,
 162               [Directories from which to load auto-loaded scripts.])
 163 AC_MSG_RESULT([$with_auto_load_dir])
 164
 165 AC_MSG_CHECKING([for default auto-load safe-path])
 166 AC_ARG_WITH(auto-load-safe-path,
 167 AS_HELP_STRING([--with-auto-load-safe-path=PATH],
 168   [directories safe to hold auto-loaded files @<:@--with-auto-load-dir@:>@])
 169 AS_HELP_STRING([--without-auto-load-safe-path],
 170                [do not restrict auto-loaded files locations]),
 171     [if test "$with_auto_load_safe_path" = "no"; then
 172      with_auto_load_safe_path="/"
 173      fi],
 174 [with_auto_load_safe_path="$with_auto_load_dir"])
 175 escape_dir=`echo $with_auto_load_safe_path | sed 's/[[$]]\(datadir\|debugdir\)\>/\\\\\\\\\\\\&/g'`
 176 AC_DEFINE_DIR(AUTO_LOAD_SAFE_PATH, escape_dir,
 177               [Directories safe to hold auto-loaded files.])
 178 AC_MSG_RESULT([$with_auto_load_safe_path])
 179
 180 AC_CONFIG_SUBDIRS(testsuite)
 181
 182 # Check whether to support alternative target configurations
 183 AC_ARG_ENABLE(targets,
 184 AS_HELP_STRING([--enable-targets=TARGETS], [alternative target configurations]),
 185 [case "${enableval}" in
 186   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
 187             ;;
 188   no)       enable_targets= ;;
 189   *)        enable_targets=$enableval ;;
 190 esac])
 191
 192 # Check whether to enable 64-bit support on 32-bit hosts
 193 AC_ARG_ENABLE(64-bit-bfd,
 194 AS_HELP_STRING([--enable-64-bit-bfd], [64-bit support (on hosts with narrower word sizes)]),
 195 [case "${enableval}" in
 196   yes)  want64=true  ;;
 197   no)   want64=false ;;
 198   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
 199 esac],[want64=false])dnl
 200
 201 # Provide defaults for some variables set by the per-host and per-target
 202 # configuration.
 203 gdb_host_obs=posix-hdep.o
 204
 205 if test "${target}" = "${host}"; then
 206   gdb_native=yes
 207 else
 208   gdb_native=no
 209 fi
 210
 211 . $srcdir/configure.host
 212
 213 # Add in the common host objects.
 214 . $srcdir/common/common.host
 215 gdb_host_obs="$gdb_host_obs $common_host_obs"
 216
 217 # Accumulate some settings from configure.tgt over all enabled targets
 218
 219 TARGET_OBS=
 220 all_targets=
 221 HAVE_NATIVE_GCORE_TARGET=
 222
 223 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 224 do
 225   if test "$targ_alias" = "all"; then
 226     all_targets=true
 227   else
 228     # Canonicalize the secondary target names.
 229     result=`$ac_config_sub $targ_alias 2>/dev/null`
 230     if test -n "$result"; then
 231         targ=$result
 232     else
 233         targ=$targ_alias
 234     fi
 235
 236     . ${srcdir}/configure.tgt
 237
 238     AS_IF([test -z "${gdb_target_obs}"],
 239       [AC_MSG_ERROR([configuration ${targ} is unsupported.])])
 240
 241     # Target-specific object files
 242     for i in ${gdb_target_obs}; do
 243         case " $TARGET_OBS " in
 244         *" ${i} "*) ;;
 245         *)
 246           TARGET_OBS="$TARGET_OBS ${i}"
 247           ;;
 248         esac
 249     done
 250
 251     # Check whether this target needs 64-bit CORE_ADDR
 252     if test x${want64} = xfalse; then
 253       . ${srcdir}/../bfd/config.bfd
 254     fi
 255
 256     # Check whether this target is native and supports gcore.
 257     if test $gdb_native = yes -a "$targ_alias" = "$target_alias" \
 258        && $gdb_have_gcore; then
 259       HAVE_NATIVE_GCORE_TARGET=1
 260     fi
 261   fi
 262 done
 263
 264 if test x${all_targets} = xtrue; then
 265
 266   # We want all 64-bit targets if we either:
 267   #  - run on a 64-bit host  or
 268   #  - already require 64-bit support for some other target  or
 269   #  - the --enable-64-bit-bfd option was supplied
 270   # Otherwise we only support all 32-bit targets.
 271   #
 272   # NOTE: This test must be in sync with the corresponding
 273   #       tests in BFD!
 274
 275   if test x${want64} = xfalse; then
 276     AC_CHECK_SIZEOF(long)
 277     if test "x${ac_cv_sizeof_long}" = "x8"; then
 278       want64=true
 279     fi
 280   fi
 281   if test x${want64} = xtrue; then
 282     TARGET_OBS='$(ALL_TARGET_OBS) $(ALL_64_TARGET_OBS)'
 283   else
 284     TARGET_OBS='$(ALL_TARGET_OBS)'
 285   fi
 286 fi
 287
 288 AC_SUBST(TARGET_OBS)
 289 AC_SUBST(HAVE_NATIVE_GCORE_TARGET)
 290
 291 # For other settings, only the main target counts.
 292 gdb_sim=
 293 gdb_osabi=
 294 build_gdbserver=
 295 targ=$target; . ${srcdir}/configure.tgt
 296
 297 # Fetch the default architecture and default target vector from BFD.
 298 targ=$target; . $srcdir/../bfd/config.bfd
 299
 300 # We only want the first architecture, so strip off the others if
 301 # there is more than one.
 302 targ_archs=`echo $targ_archs | sed 's/ .*//'`
 303
 304 if test "x$targ_archs" != x; then
 305   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
 306     [Define to BFD's default architecture. ])
 307 fi
 308 if test "x$targ_defvec" != x; then
 309   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
 310     [Define to BFD's default target vector. ])
 311 fi
 312
 313 # The CLI cannot be disabled yet, but may be in the future.
 314
 315 # Enable CLI.
 316 AC_ARG_ENABLE(gdbcli,
 317 AS_HELP_STRING([--disable-gdbcli], [disable command-line interface (CLI)]),
 318   [case $enableval in
 319     yes)
 320       ;;
 321     no)
 322       AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;;
 323     *)
 324       AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;;
 325   esac],
 326   [enable_gdbcli=yes])
 327 if test x"$enable_gdbcli" = xyes; then
 328   if test -d $srcdir/cli; then
 329     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)"
 330     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)"
 331     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)"
 332     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)"
 333   fi
 334 fi
 335
 336 # Enable MI.
 337 AC_ARG_ENABLE(gdbmi,
 338 AS_HELP_STRING([--disable-gdbmi], [disable machine-interface (MI)]),
 339   [case $enableval in
 340     yes | no)
 341       ;;
 342     *)
 343       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 344   esac],
 345   [enable_gdbmi=yes])
 346 if test x"$enable_gdbmi" = xyes; then
 347   if test -d $srcdir/mi; then
 348     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 349     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 350     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 351     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 352   fi
 353 fi
 354
 355 # Enable TUI.
 356 AC_ARG_ENABLE(tui,
 357 AS_HELP_STRING([--enable-tui], [enable full-screen terminal user interface (TUI)]),
 358   [case $enableval in
 359     yes | no | auto)
 360       ;;
 361     *)
 362       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 363   esac],enable_tui=auto)
 364
 365 # Enable gdbtk.
 366 AC_ARG_ENABLE(gdbtk,
 367 AS_HELP_STRING([--enable-gdbtk], [enable gdbtk graphical user interface (GUI)]),
 368   [case $enableval in
 369     yes | no)
 370       ;;
 371     *)
 372       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 373   esac],
 374   [if test -d $srcdir/gdbtk; then
 375     enable_gdbtk=yes
 376   else
 377     enable_gdbtk=no
 378   fi])
 379 # We unconditionally disable gdbtk tests on selected platforms.
 380 case $host_os in
 381   go32* | windows*)
 382     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 383     enable_gdbtk=no ;;
 384 esac
 385
 386 # Libunwind support for ia64.
 387
 388 AC_ARG_WITH(libunwind-ia64,
 389 AS_HELP_STRING([--with-libunwind-ia64],
 390                [use libunwind frame unwinding for ia64 targets]),,
 391             [with_libunwind_ia64=auto])
 392
 393 # Backward compatibility option.
 394 if test "${with_libunwind+set}" = set; then
 395   if test x"$with_libunwind_ia64" != xauto; then
 396     AC_MSG_ERROR(
 397       [option --with-libunwind is deprecated, use --with-libunwind-ia64])
 398   fi
 399   AC_MSG_WARN([option --with-libunwind is deprecated, use --with-libunwind-ia64])
 400   with_libunwind_ia64="$with_libunwind"
 401 fi
 402
 403 case "$with_libunwind_ia64" in
 404   yes | no)
 405     ;;
 406   auto)
 407     AC_CHECK_HEADERS(libunwind-ia64.h)
 408     with_libunwind_ia64=$ac_cv_header_libunwind_ia64_h
 409     ;;
 410   *)
 411     AC_MSG_ERROR(
 412       [bad value $with_libunwind_ia64 for GDB --with-libunwind-ia64 option])
 413     ;;
 414 esac
 415
 416 if test x"$with_libunwind_ia64" = xyes; then
 417   AC_CHECK_HEADERS(libunwind-ia64.h)
 418   if test x"$ac_cv_header_libunwind_ia64_h" != xyes; then
 419     AC_MSG_ERROR([GDB option --with-libunwind-ia64 requires libunwind-ia64.h])
 420   fi
 421   CONFIG_OBS="$CONFIG_OBS ia64-libunwind-tdep.o"
 422   CONFIG_DEPS="$CONFIG_DEPS ia64-libunwind-tdep.o"
 423   CONFIG_SRCS="$CONFIG_SRCS ia64-libunwind-tdep.c"
 424 fi
 425
 426 opt_curses=no
 427 AC_ARG_WITH(curses, AS_HELP_STRING([--with-curses], [use the curses library instead of the termcap library]), opt_curses=$withval)
 428
 429 prefer_curses=no
 430 if test "$opt_curses" = "yes"; then
 431   prefer_curses=yes
 432 fi
 433
 434 # Profiling support.
 435 AC_ARG_ENABLE(profiling,
 436 AS_HELP_STRING([--enable-profiling], [enable profiling of GDB]),
 437   [case $enableval in
 438     yes | no)
 439       ;;
 440     *)
 441       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 442   esac],
 443  [enable_profiling=no])
 444
 445 AC_CHECK_FUNCS(monstartup _mcleanup)
 446 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 447 [AC_TRY_LINK(
 448 [#include <stdlib.h>
 449 extern char _etext;
 450 ],
 451 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 452 if test $ac_cv_var__etext = yes; then
 453   AC_DEFINE(HAVE__ETEXT, 1,
 454             [Define to 1 if your system has the _etext variable. ])
 455 fi
 456 AC_CACHE_CHECK([for etext], ac_cv_var_etext,
 457 [AC_TRY_LINK(
 458 [#include <stdlib.h>
 459 extern char etext;
 460 ],
 461 [free (&etext);], ac_cv_var_etext=yes, ac_cv_var_etext=no)])
 462 if test $ac_cv_var_etext = yes; then
 463   AC_DEFINE(HAVE_ETEXT, 1,
 464             [Define to 1 if your system has the etext variable. ])
 465 fi
 466 if test "$enable_profiling" = yes ; then
 467   if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
 468     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 469   fi
 470   PROFILE_CFLAGS=-pg
 471   OLD_CFLAGS="$CFLAGS"
 472   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 473
 474   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 475     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 476      ac_cv_cc_supports_pg=no)])
 477
 478   if test $ac_cv_cc_supports_pg = no; then
 479     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 480   fi
 481
 482   CFLAGS="$OLD_CFLAGS"
 483 fi
 484
 485 ACX_PKGVERSION([GDB])
 486 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 487 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 488 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 489
 490 # --------------------- #
 491 # Checks for programs.  #
 492 # --------------------- #
 493
 494 AC_PROG_AWK
 495 AC_PROG_INSTALL
 496 AC_PROG_LN_S
 497 AC_PROG_RANLIB
 498 AC_PROG_YACC
 499
 500 AC_CHECK_TOOL(AR, ar)
 501 AC_CHECK_TOOL(DLLTOOL, dlltool)
 502 AC_CHECK_TOOL(WINDRES, windres)
 503
 504 case $host_os in
 505   gnu*)
 506     # Needed for GNU Hurd hosts.
 507     AC_CHECK_TOOL(MIG, mig)
 508     if test x"$MIG" = x; then
 509       AC_MSG_ERROR([MIG not found but required for $host hosts])
 510     fi
 511     ;;
 512 esac
 513
 514 # ---------------------- #
 515 # Checks for libraries.  #
 516 # ---------------------- #
 517
 518 # We might need to link with -lm; most simulators need it.
 519 AC_CHECK_LIB(m, main)
 520
 521 # We need to link with -lw to get `wctype' on Solaris before Solaris
 522 # 2.6.  Solaris 2.6 and beyond have this function in libc, and have a
 523 # libw that some versions of the GNU linker cannot hanle (GNU ld 2.9.1
 524 # is known to have this problem).  Therefore we avoid libw if we can.
 525 AC_CHECK_FUNC(wctype, [],
 526   [AC_CHECK_LIB(w, wctype)])
 527
 528 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 529 AC_SEARCH_LIBS(gethostbyname, nsl)
 530
 531 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 532 AC_SEARCH_LIBS(socketpair, socket)
 533
 534 # Link in zlib if we can.  This allows us to read compressed debug sections.
 535 AM_ZLIB
 536
 537 # On FreeBSD we may need libutil for kinfo_getvmmap (used by fbsd-nat.c).
 538 AC_SEARCH_LIBS(kinfo_getvmmap, util,
 539   [AC_DEFINE(HAVE_KINFO_GETVMMAP, 1,
 540             [Define to 1 if your system has the kinfo_getvmmap function. ])])
 541
 542 AM_ICONV
 543
 544 # GDB may fork/exec the iconv program to get the list of supported character
 545 # sets.  Allow the user to specify where to find it.
 546 # There are several factors affecting the choice of option name:
 547 # - There is already --with-libiconv-prefix but we can't use it, it specifies
 548 #   the build-time location of libiconv files.
 549 # - The program we need to find is iconv, which comes with glibc.  The user
 550 #   doesn't necessarily have libiconv installed.  Therefore naming this
 551 #   --with-libiconv-foo feels wrong.
 552 # - We want the path to be relocatable, but GDB_AC_DEFINE_RELOCATABLE is
 553 #   defined to work on directories not files (though it really doesn't know
 554 #   the difference).
 555 # - Calling this --with-iconv-prefix is perceived to cause too much confusion
 556 #   with --with-libiconv-prefix.
 557 # Putting these together is why the option name is --with-iconv-bin.
 558
 559 AC_ARG_WITH(iconv-bin,
 560 AS_HELP_STRING([--with-iconv-bin=PATH], [specify where to find the iconv program]),
 561 [iconv_bin="${withval}"
 562  AC_DEFINE_UNQUOTED([ICONV_BIN], ["${iconv_bin}"],
 563                     [Path of directory of iconv program.])
 564  GDB_AC_DEFINE_RELOCATABLE(ICONV_BIN, iconv, ${iconv_bin})
 565 ])
 566
 567 # For the TUI, we need enhanced curses functionality.
 568 if test x"$enable_tui" != xno; then
 569   prefer_curses=yes
 570 fi
 571
 572 curses_found=no
 573 if test x"$prefer_curses" = xyes; then
 574   # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
 575   # curses library because the latter might not provide all the
 576   # functionality we need.  However, this leads to problems on systems
 577   # where the linker searches /usr/local/lib, but the compiler doesn't
 578   # search /usr/local/include, if ncurses is installed in /usr/local.  A
 579   # default installation of ncurses on alpha*-dec-osf* will lead to such
 580   # a situation.
 581   AC_SEARCH_LIBS(waddstr, [ncurses cursesX curses])
 582
 583   if test "$ac_cv_search_waddstr" != no; then
 584     curses_found=yes
 585   fi
 586 fi
 587
 588 # Check whether we should enable the TUI, but only do so if we really
 589 # can.
 590 if test x"$enable_tui" != xno; then
 591   if test -d $srcdir/tui; then
 592     if test "$curses_found" != no; then
 593       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
 594       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
 595       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
 596       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
 597     else
 598       if test x"$enable_tui" = xyes; then
 599         AC_MSG_ERROR([no enhanced curses library found; disable TUI])
 600       else
 601         AC_MSG_WARN([no enhanced curses library found; disabling TUI])
 602       fi
 603     fi
 604   fi
 605 fi
 606
 607 # Since GDB uses Readline, we need termcap functionality.  In many
 608 # cases this will be provided by the curses library, but some systems
 609 # have a seperate termcap library, or no curses library at all.
 610
 611 case $host_os in
 612   cygwin*)
 613     if test -d $srcdir/libtermcap; then
 614       LIBS="../libtermcap/libtermcap.a $LIBS"
 615       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 616     fi ;;
 617   go32* | *djgpp*)
 618     ac_cv_search_tgetent="none required"
 619     ;;
 620 esac
 621
 622 # These are the libraries checked by Readline.
 623 AC_SEARCH_LIBS(tgetent, [termcap tinfo curses ncurses])
 624
 625 if test "$ac_cv_search_tgetent" = no; then
 626   CONFIG_OBS="$CONFIG_OBS stub-termcap.o"
 627 fi
 628
 629 AC_ARG_WITH([system-readline],
 630   [AS_HELP_STRING([--with-system-readline],
 631                   [use installed readline library])])
 632
 633 if test "$with_system_readline" = yes; then
 634   READLINE=-lreadline
 635   READLINE_DEPS=
 636   READLINE_CFLAGS=
 637   READLINE_TEXI_INCFLAG=
 638 else
 639   READLINE='$(READLINE_DIR)/libreadline.a'
 640   READLINE_DEPS='$(READLINE)'
 641   READLINE_CFLAGS='-I$(READLINE_SRC)/..'
 642   READLINE_TEXI_INCFLAG='-I $(READLINE_DIR)'
 643 fi
 644 AC_SUBST(READLINE)
 645 AC_SUBST(READLINE_DEPS)
 646 AC_SUBST(READLINE_CFLAGS)
 647 AC_SUBST(READLINE_TEXI_INCFLAG)
 648
 649 # Generate jit-reader.h
 650
 651 # This is typedeffed to GDB_CORE_ADDR in jit-reader.h
 652 TARGET_PTR=
 653
 654 AC_CHECK_SIZEOF(unsigned long long)
 655 AC_CHECK_SIZEOF(unsigned long)
 656 AC_CHECK_SIZEOF(unsigned __int128)
 657
 658 if test "x${ac_cv_sizeof_unsigned_long}" = "x8"; then
 659   TARGET_PTR="unsigned long"
 660 elif test "x${ac_cv_sizeof_unsigned_long_long}" = "x8"; then
 661   TARGET_PTR="unsigned long long"
 662 elif test "x${ac_cv_sizeof_unsigned___int128}" = "x16"; then
 663   TARGET_PTR="unsigned __int128"
 664 else
 665   TARGET_PTR="unsigned long"
 666 fi
 667
 668 AC_SUBST(TARGET_PTR)
 669 AC_CONFIG_FILES([jit-reader.h:jit-reader.in])
 670
 671 AC_SEARCH_LIBS(dlopen, dl)
 672
 673 GDB_AC_WITH_DIR([JIT_READER_DIR], [jit-reader-dir],
 674                 [directory to load the JIT readers from],
 675                 [${libdir}/gdb])
 676
 677 AC_ARG_WITH(expat,
 678   AS_HELP_STRING([--with-expat], [include expat support (auto/yes/no)]),
 679   [], [with_expat=auto])
 680 AC_MSG_CHECKING([whether to use expat])
 681 AC_MSG_RESULT([$with_expat])
 682
 683 if test "${with_expat}" = no; then
 684   AC_MSG_WARN([expat support disabled; some features may be unavailable.])
 685   HAVE_LIBEXPAT=no
 686 else
 687   AC_LIB_HAVE_LINKFLAGS([expat], [], [#include "expat.h"],
 688                         [XML_Parser p = XML_ParserCreate (0);])
 689   if test "$HAVE_LIBEXPAT" != yes; then
 690     if test "$with_expat" = yes; then
 691       AC_MSG_ERROR([expat is missing or unusable])
 692     else
 693       AC_MSG_WARN([expat is missing or unusable; some features may be unavailable.])
 694     fi
 695   else
 696     save_LIBS=$LIBS
 697     LIBS="$LIBS $LIBEXPAT"
 698     AC_CHECK_FUNCS(XML_StopParser)
 699     LIBS=$save_LIBS
 700   fi
 701 fi
 702
 703 # --------------------- #
 704 # Check for libpython.  #
 705 # --------------------- #
 706
 707 dnl Utility to simplify finding libpython.
 708 dnl $1 = pythonX.Y
 709 dnl $2 = the shell variable to assign the result to
 710 dnl      If libpython is found we store $version here.
 711 dnl $3 = additional flags to add to CPPFLAGS
 712 dnl $4 = additional flags to add to LIBS
 713
 714 AC_DEFUN([AC_TRY_LIBPYTHON],
 715 [
 716   version=$1
 717   define([have_libpython_var],$2)
 718   new_CPPFLAGS=$3
 719   new_LIBS=$4
 720   AC_MSG_CHECKING([for ${version}])
 721   save_CPPFLAGS=$CPPFLAGS
 722   save_LIBS=$LIBS
 723   CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
 724   LIBS="$LIBS $new_LIBS"
 725   found_usable_python=no
 726   AC_LINK_IFELSE(AC_LANG_PROGRAM([[#include "Python.h"]],
 727                                  [[Py_Initialize ();]]),
 728                  [have_libpython_var=${version}
 729                   found_usable_python=yes
 730                   PYTHON_CPPFLAGS=$new_CPPFLAGS
 731                   PYTHON_LIBS=$new_LIBS])
 732   CPPFLAGS=$save_CPPFLAGS
 733   LIBS=$save_LIBS
 734   AC_MSG_RESULT([${found_usable_python}])
 735 ])
 736
 737 dnl There are several different values for --with-python:
 738 dnl
 739 dnl no -   Don't include python support.
 740 dnl yes -  Include python support, error if it's missing.
 741 dnl        If we find python in $PATH, use it to fetch configure options,
 742 dnl        otherwise assume the compiler can find it with no help from us.
 743 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 744 dnl auto - Same as "yes", but if python is missing from the system,
 745 dnl        fall back to "no".
 746 dnl /path/to/python/exec-prefix -
 747 dnl        Use the python located in this directory.
 748 dnl        If /path/to/python/exec-prefix/bin/python exists, use it to find
 749 dnl        the compilation parameters.  Otherwise use
 750 dnl        -I/path/to/python/exec-prefix/include,
 751 dnl        -L/path/to/python/exec-prefix/lib.
 752 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 753 dnl        NOTE: This case is historical.  It is what was done for 7.0/7.1
 754 dnl        but is deprecated.
 755 dnl /path/to/python/executable -
 756 dnl        Run python-config.py with this version of python to fetch the
 757 dnl        compilation parameters.
 758 dnl        NOTE: This needn't be the real python executable.
 759 dnl        In a cross-compilation scenario (build != host), this could be
 760 dnl        a shell script that provides what python-config.py provides for
 761 dnl        --ldflags, --includes, --exec-prefix.
 762 dnl python-executable -
 763 dnl        Find python-executable in $PATH, and then handle the same as
 764 dnl        /path/to/python/executable.
 765 dnl
 766 dnl If a python program is specified, it is used to run python-config.py and
 767 dnl is passed --ldflags, --includes, --exec-prefix.
 768
 769 AC_ARG_WITH(python,
 770   AS_HELP_STRING([--with-python@<:@=PYTHON@:>@], [include python support (auto/yes/no/<python-program>)]),
 771   [], [with_python=auto])
 772 AC_MSG_CHECKING([whether to use python])
 773 AC_MSG_RESULT([$with_python])
 774
 775 if test "${with_python}" = no; then
 776   AC_MSG_WARN([python support disabled; some features may be unavailable.])
 777   have_libpython=no
 778 else
 779   case "${with_python}" in
 780   [[\\/]]* | ?:[[\\/]]*)
 781     if test -d ${with_python}; then
 782       # Assume the python binary is ${with_python}/bin/python.
 783       python_prog="${with_python}/bin/python"
 784       python_prefix=
 785       # If python does not exit ${with_python}/bin, then try in
 786       # ${with_python}.  On Windows/MinGW, this is where the Python
 787       # executable is.
 788       if test ! -x "${python_prog}"; then
 789         python_prog="${with_python}/python"
 790         python_prefix=
 791       fi
 792       if test ! -x "${python_prog}"; then
 793         # Fall back to gdb 7.0/7.1 behaviour.
 794         python_prog=missing
 795         python_prefix=${with_python}
 796       fi
 797     elif test -x "${with_python}"; then
 798       # While we can't run python compiled for $host (unless host == build),
 799       # the user could write a script that provides the needed information,
 800       # so we support that.
 801       python_prog=${with_python}
 802       python_prefix=
 803     else
 804       AC_ERROR(invalid value for --with-python)
 805     fi
 806     ;;
 807   */*)
 808     # Disallow --with-python=foo/bar.
 809     AC_ERROR(invalid value for --with-python)
 810     ;;
 811   *)
 812     # The user has either specified auto, yes, or the name of the python
 813     # program assumed to be in $PATH.
 814     python_prefix=
 815     case "${with_python}" in
 816     yes | auto)
 817       if test ${build} = ${host}; then
 818         AC_PATH_PROG(python_prog_path, python, missing)
 819         if test "${python_prog_path}" = missing; then
 820           python_prog=missing
 821         else
 822           python_prog=${python_prog_path}
 823         fi
 824       else
 825         # Not much we can do except assume the cross-compiler will find the
 826         # right files.
 827         python_prog=missing
 828       fi
 829       ;;
 830     *)
 831       # While we can't run python compiled for $host (unless host == build),
 832       # the user could write a script that provides the needed information,
 833       # so we support that.
 834       python_prog="${with_python}"
 835       AC_PATH_PROG(python_prog_path, ${python_prog}, missing)
 836       if test "${python_prog_path}" = missing; then
 837         AC_ERROR(unable to find python program ${python_prog})
 838       fi
 839       ;;
 840     esac
 841   esac
 842
 843   if test "${python_prog}" != missing; then
 844     # We have a python program to use, but it may be too old.
 845     # Don't flag an error for --with-python=auto (the default).
 846     have_python_config=yes
 847     python_includes=`${python_prog} ${srcdir}/python/python-config.py --includes`
 848     if test $? != 0; then
 849       have_python_config=failed
 850       if test "${with_python}" != auto; then
 851         AC_ERROR(failure running python-config --includes)
 852       fi
 853     fi
 854     python_libs=`${python_prog} ${srcdir}/python/python-config.py --ldflags`
 855     if test $? != 0; then
 856       have_python_config=failed
 857       if test "${with_python}" != auto; then
 858         AC_ERROR(failure running python-config --ldflags)
 859       fi
 860     fi
 861     python_prefix=`${python_prog} ${srcdir}/python/python-config.py --exec-prefix`
 862     if test $? != 0; then
 863       have_python_config=failed
 864       if test "${with_python}" != auto; then
 865         AC_ERROR(failure running python-config --exec-prefix)
 866       fi
 867     fi
 868   else
 869     # We do not have a python executable we can use to determine where
 870     # to find the Python headers and libs.  We cannot guess the include
 871     # path from the python_prefix either, because that include path
 872     # depends on the Python version.  So, there is nothing much we can
 873     # do except assume that the compiler will be able to find those files.
 874     python_includes=
 875     python_libs=
 876     have_python_config=no
 877   fi
 878
 879   # If we have python-config, only try the configuration it provides.
 880   # Otherwise fallback on the old way of trying different versions of
 881   # python in turn.
 882
 883   have_libpython=no
 884   if test "${have_python_config}" = yes; then
 885     # Determine the Python version by extracting "-lpython<version>"
 886     # part of the python_libs. <version> is usually X.Y with X and Y
 887     # being decimal numbers, but can also be XY (seen on Windows).
 888     #
 889     # The extraction is performed using sed with a regular expression.
 890     # Initially, the regexp used was using the '?' quantifier to make
 891     # the dot in the version number optional.  Unfortunately, this
 892     # does not work with non-GNU versions of sed because, because of
 893     # what looks like a limitation (the '?' quantifier does not work
 894     # with back-references).  We work around this limitation by using
 895     # the '*' quantifier instead.  It means that, in theory, we might
 896     # match unexpected version strings such as "-lpython2..7", but
 897     # this seems unlikely in practice.  And even if that happens,
 898     # an error will be triggered later on, when checking that version
 899     # number.
 900     python_version=`echo " ${python_libs} " \
 901                          | sed -e 's,^.* -l\(python[[0-9]]*[[.]]*[[0-9]]*\).*$,\1,'`
 902     case "${python_version}" in
 903     python*)
 904       AC_TRY_LIBPYTHON(${python_version}, have_libpython,
 905                        ${python_includes}, ${python_libs})
 906       ;;
 907     *)
 908       AC_MSG_ERROR([unable to determine python version from ${python_libs}])
 909       ;;
 910     esac
 911   elif test "${have_python_config}" != failed; then
 912     if test "${have_libpython}" = no; then
 913       AC_TRY_LIBPYTHON(python2.7, have_libpython,
 914                        ${python_includes}, "${python_libs} -lpython2.7")
 915     fi
 916     if test "${have_libpython}" = no; then
 917       AC_TRY_LIBPYTHON(python2.6, have_libpython,
 918                        ${python_includes}, "${python_libs} -lpython2.6")
 919     fi
 920     if test ${have_libpython} = no; then
 921       AC_TRY_LIBPYTHON(python2.5, have_libpython,
 922                        ${python_includes}, "${python_libs} -lpython2.5")
 923     fi
 924     if test ${have_libpython} = no; then
 925       AC_TRY_LIBPYTHON(python2.4, have_libpython,
 926                        ${python_includes}, "${python_libs} -lpython2.4")
 927     fi
 928   fi
 929   if test "${have_libpython}" = python2.7 -o "${have_libpython}" = python27; then
 930     AC_DEFINE(HAVE_LIBPYTHON2_7, 1, [Define if Python 2.7 is being used.])
 931   elif test "${have_libpython}" = python2.6 -o "${have_libpython}" = python26; then
 932     AC_DEFINE(HAVE_LIBPYTHON2_6, 1, [Define if Python 2.6 is being used.])
 933   elif test "${have_libpython}" = python2.5 -o "${have_libpython}" = python25; then
 934     AC_DEFINE(HAVE_LIBPYTHON2_5, 1, [Define if Python 2.5 is being used.])
 935   elif test "${have_libpython}" = python2.4 -o "${have_libpython}" = python24; then
 936     AC_DEFINE(HAVE_LIBPYTHON2_4, 1, [Define if Python 2.4 is being used.])
 937   fi
 938
 939   if test "${have_libpython}" = no; then
 940     case "${with_python}" in
 941     yes)
 942       AC_MSG_ERROR([python is missing or unusable])
 943       ;;
 944     auto)
 945       AC_MSG_WARN([python is missing or unusable; some features may be unavailable.])
 946       ;;
 947     *)
 948       AC_MSG_ERROR([no usable python found at ${with_python}])
 949       ;;
 950     esac
 951   else
 952     if test -n "${python_prefix}"; then
 953       AC_DEFINE_UNQUOTED(WITH_PYTHON_PATH, "${python_prefix}",
 954                          [Define if --with-python provides a path, either directly or via python-config.py --exec-prefix.])
 955       GDB_AC_DEFINE_RELOCATABLE(PYTHON_PATH, python, ${python_prefix})
 956     fi
 957   fi
 958 fi
 959
 960 if test "${have_libpython}" != no; then
 961   AC_DEFINE(HAVE_PYTHON, 1, [Define if Python interpreter is being linked in.])
 962   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_PYTHON_OBS)"
 963   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_PYTHON_DEPS)"
 964   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_PYTHON_SRCS)"
 965   CONFIG_INSTALL="$CONFIG_INSTALL install-python"
 966   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_PYTHON_CFLAGS)"
 967
 968   # Flags needed to compile Python code (taken from python-config --cflags).
 969   # We cannot call python-config directly because it will output whatever was
 970   # used when compiling the Python interpreter itself, including flags which
 971   # would make the python-related objects be compiled differently from the
 972   # rest of GDB (e.g., -O2 and -fPIC).
 973   if test "${GCC}" = yes; then
 974     tentative_python_cflags="-fno-strict-aliasing -DNDEBUG -fwrapv"
 975   fi
 976
 977   if test "x${tentative_python_cflags}" != x; then
 978     AC_MSG_CHECKING(compiler flags for python code)
 979     for flag in ${tentative_python_cflags}; do
 980       # Check that the compiler accepts it
 981       saved_CFLAGS="$CFLAGS"
 982       CFLAGS="$CFLAGS $flag"
 983       AC_TRY_COMPILE([],[],PYTHON_CFLAGS="${PYTHON_CFLAGS} $flag",)
 984       CFLAGS="$saved_CFLAGS"
 985     done
 986     AC_MSG_RESULT(${PYTHON_CFLAGS})
 987   fi
 988
 989   # On x64 Windows, Python's include headers, and pyconfig.h in
 990   # particular, rely on MS_WIN64 macro to detect that it's a 64bit
 991   # version of Windows.  Unfortunately, MS_WIN64 is only defined if
 992   # _MSC_VER, a Microsoft-specific macro, is defined.  So, when
 993   # building on x64 Windows with GCC, we define MS_WIN64 ourselves.
 994   # The issue was reported to the Python community, but still isn't
 995   # solved as of 2012-10-02 (http://bugs.python.org/issue4709).
 996
 997   case "$gdb_host" in
 998     mingw64)
 999            if test "${GCC}" = yes; then
1000              CPPFLAGS="$CPPFLAGS -DMS_WIN64"
1001            fi
1002            ;;
1003   esac
1004
1005   # Note that "python -m threading" cannot be used to check for
1006   # threading support due to a bug in Python 2.7.3
1007   # (http://bugs.python.org/issue15567).
1008   AC_MSG_CHECKING(whether python supports threads)
1009   saved_CPPFLAGS="${CPPFLAGS}"
1010   CPPFLAGS="${PYTHON_CPPFLAGS}"
1011   # Note that the test is reversed so that python_has_threads=yes on
1012   # unexpected failures.
1013   AC_PREPROC_IFELSE(AC_LANG_SOURCE([[
1014 #include <Python.h>
1015 #ifdef WITH_THREAD
1016 # error
1017 #endif
1018   ]]), [python_has_threads=no], [python_has_threads=yes])
1019   AC_MSG_RESULT(${python_has_threads})
1020   CPPFLAGS="${saved_CPPFLAGS}"
1021 else
1022   # Even if Python support is not compiled in, we need to have this file
1023   # included so that the "python" command, et.al., still exists.
1024   CONFIG_OBS="$CONFIG_OBS python.o"
1025   CONFIG_SRCS="$CONFIG_SRCS python/python.c"
1026 fi
1027 AC_SUBST(PYTHON_CFLAGS)
1028 AC_SUBST(PYTHON_CPPFLAGS)
1029 AC_SUBST(PYTHON_LIBS)
1030 AM_CONDITIONAL(HAVE_PYTHON, test "${have_libpython}" != no)
1031
1032 # -------------------- #
1033 # Check for libguile.  #
1034 # -------------------- #
1035
1036 dnl Utility to simplify finding libguile.
1037 dnl $1 = pkg-config-program
1038 dnl $2 = space-separate list of guile versions to try
1039 dnl $3 = yes|no, indicating whether to flag errors or ignore them
1040 dnl $4 = the shell variable to assign the result to
1041 dnl      If libguile is found we store "yes" here.
1042
1043 AC_DEFUN([AC_TRY_LIBGUILE],
1044 [
1045   pkg_config=$1
1046   guile_version_list=$2
1047   flag_errors=$3
1048   define([have_libguile_var],$4)
1049   found_usable_guile=checking
1050   AC_MSG_CHECKING([for usable guile from ${pkg_config}])
1051   for guile_version in ${guile_version_list}; do
1052     ${pkg_config} --exists ${guile_version} 2>/dev/null
1053     if test $? != 0; then
1054       continue
1055     fi
1056     dnl pkg-config says the package exists, so if we get an error now,
1057     dnl that's bad.
1058     new_CPPFLAGS=`${pkg_config} --cflags ${guile_version}`
1059     if test $? != 0; then
1060       AC_MSG_ERROR([failure running pkg-config --cflags ${guile_version}])
1061     fi
1062     new_LIBS=`${pkg_config} --libs ${guile_version}`
1063     if test $? != 0; then
1064       AC_MSG_ERROR([failure running pkg-config --libs ${guile_version}])
1065     fi
1066     dnl If we get this far, great.
1067     found_usable_guile=${guile_version}
1068     break
1069   done
1070   if test "${found_usable_guile}" = "checking"; then
1071     if test "${flag_errors}" = "yes"; then
1072       AC_MSG_ERROR([unable to find usable guile version from "${guile_version_list}"])
1073     else
1074       found_usable_guile=no
1075     fi
1076   fi
1077   dnl One final sanity check.
1078   dnl The user could have said --with-guile=python-2.7.
1079   if test "${found_usable_guile}" != no; then
1080     save_CPPFLAGS=$CPPFLAGS
1081     save_LIBS=$LIBS
1082     CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
1083     LIBS="$LIBS $new_LIBS"
1084     AC_LINK_IFELSE(AC_LANG_PROGRAM([[#include "libguile.h"]],
1085                                    [[scm_init_guile ();]]),
1086                    [have_libguile_var=yes
1087                     GUILE_CPPFLAGS=$new_CPPFLAGS
1088                     GUILE_LIBS=$new_LIBS],
1089                    [found_usable_guile=no])
1090     dnl scm_set_automatic_finalization_enabled added in Guile 2.2.
1091     AC_CHECK_FUNC(scm_set_automatic_finalization_enabled,
1092       AC_DEFINE(HAVE_GUILE_MANUAL_FINALIZATION, 1,
1093                 [Define if Guile supports manual finalization.])
1094     )
1095     CPPFLAGS=$save_CPPFLAGS
1096     LIBS=$save_LIBS
1097     if test "${found_usable_guile}" = no; then
1098       if test "${flag_errors}" = yes; then
1099         AC_MSG_FAILURE([linking guile version ${guile_version} test program failed])
1100       fi
1101     fi
1102   fi
1103   AC_MSG_RESULT([${found_usable_guile}])
1104 ])
1105
1106 dnl There are several different values for --with-guile:
1107 dnl
1108 dnl no -   Don't include guile support.
1109 dnl yes -  Include guile support, error if it's missing.
1110 dnl        The pkg-config program must be in $PATH.
1111 dnl auto - Same as "yes", but if guile is missing from the system,
1112 dnl        fall back to "no".
1113 dnl guile-version [guile-version-choice-2 ...] -
1114 dnl        A space-separated list of guile package versions to try.
1115 dnl        These are passed to pkg-config as-is.
1116 dnl        E.g., guile-2.0 or guile-2.2-uninstalled
1117 dnl        This requires making sure PKG_CONFIG_PATH is set appropriately.
1118 dnl /path/to/pkg-config -
1119 dnl        Use this pkg-config program.
1120 dnl        NOTE: This needn't be the "real" pkg-config program.
1121 dnl        It could be a shell script.  It is invoked as:
1122 dnl        pkg-config --exists $version
1123 dnl        pkg-config --cflags $version
1124 dnl        pkg-config --libs $version
1125 dnl        pkg-config --variable guild $version
1126 dnl        The script will be called with $version having each value in
1127 dnl        $try_guile_versions until --exists indicates success.
1128
1129 AC_ARG_WITH(guile,
1130   AS_HELP_STRING([--with-guile@<:@=GUILE@:>@], [include guile support (auto/yes/no/<guile-version>/<pkg-config-program>)]),
1131   [], [with_guile=auto])
1132 AC_MSG_CHECKING([whether to use guile])
1133 AC_MSG_RESULT([$with_guile])
1134
1135 dnl We check guile with pkg-config.
1136 AC_PATH_PROG(pkg_config_prog_path, pkg-config, missing)
1137
1138 try_guile_versions="guile-2.2 guile-2.0"
1139 have_libguile=no
1140 case "${with_guile}" in
1141 no)
1142   AC_MSG_WARN([guile support disabled; some features will be unavailable.])
1143   ;;
1144 auto)
1145   if test "${pkg_config_prog_path}" = "missing"; then
1146     AC_MSG_WARN([pkg-config not found, guile support disabled])
1147   else
1148     AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${try_guile_versions}, no, have_libguile)
1149   fi
1150   ;;
1151 yes)
1152   if test "${pkg_config_prog_path}" = "missing"; then
1153     AC_MSG_ERROR([pkg-config not found])
1154   fi
1155   AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${try_guile_versions}, yes, have_libguile)
1156   ;;
1157 [[\\/]]* | ?:[[\\/]]*)
1158   if test -x "${with_guile}"; then
1159     AC_TRY_LIBGUILE(${with_guile}, ${try_guile_versions}, yes, have_libguile)
1160   else
1161     AC_MSG_ERROR([Guile config program not executable: ${with_guile}])
1162   fi
1163   ;;
1164 "" | */*)
1165   # Disallow --with=guile="" and --with-guile=foo/bar.
1166   AC_MSG_ERROR([invalid value for --with-guile])
1167   ;;
1168 *)
1169   # A space separate list of guile versions to try, in order.
1170   if test "${pkg_config_prog_path}" = "missing"; then
1171     AC_MSG_ERROR([pkg-config not found])
1172   fi
1173   AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${with_guile}, yes, have_libguile)
1174   ;;
1175 esac
1176
1177 if test "${have_libguile}" != no; then
1178   dnl Get the name of the 'guild' program.
1179   case "${with_guile}" in
1180   [[\\/]]* | ?:[[\\/]]*)
1181     GDB_GUILE_PROGRAM_NAMES(["${with_guile}"], ["${guile_version}"])
1182     ;;
1183   *)
1184     GDB_GUILE_PROGRAM_NAMES(["${pkg_config_prog_path}"], ["${guile_version}"])
1185     ;;
1186   esac
1187
1188   dnl Make sure guild can handle this host.
1189   GDB_TRY_GUILD([$srcdir/guile/lib/gdb/support.scm])
1190   dnl If not, disable guile support.
1191   if test "$ac_cv_guild_ok" = no; then
1192     have_libguile=no
1193     AC_MSG_WARN(disabling guile support, $GUILD fails compiling for $host)
1194   fi
1195 fi
1196
1197 if test "${have_libguile}" != no; then
1198   AC_DEFINE(HAVE_GUILE, 1, [Define if Guile interpreter is being linked in.])
1199   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_GUILE_OBS)"
1200   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_GUILE_DEPS)"
1201   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_GUILE_SRCS)"
1202   CONFIG_INSTALL="$CONFIG_INSTALL install-guile"
1203   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_GUILE_CFLAGS)"
1204
1205   dnl The 'scm_new_smob' function appeared in Guile 2.0.6.
1206   save_LIBS="$LIBS"
1207   save_CPPFLAGS="$CPPFLAGS"
1208   LIBS="$GUILE_LIBS"
1209   CPPFLAGS="$GUILE_CPPFLAGS"
1210   AC_CHECK_FUNCS([scm_new_smob])
1211   LIBS="$save_LIBS"
1212   CPPFLAGS="$save_CPPFLAGS"
1213 else
1214   # Even if Guile support is not compiled in, we need to have these files
1215   # included.
1216   CONFIG_OBS="$CONFIG_OBS guile.o"
1217   CONFIG_SRCS="$CONFIG_SRCS guile/guile.c"
1218 fi
1219 AC_SUBST(GUILE_CPPFLAGS)
1220 AC_SUBST(GUILE_LIBS)
1221 AM_CONDITIONAL(HAVE_GUILE, test "${have_libguile}" != no)
1222
1223 # --------------------- #
1224 # Check for libmcheck.  #
1225 # --------------------- #
1226
1227 # Enable -lmcheck by default (it provides cheap-enough memory mangling),
1228 # but turn it off if Python is enabled with threads, since -lmcheck is
1229 # not thread safe (http://sourceware.org/bugzilla/show_bug.cgi?id=9939),
1230 # and for releases.
1231 if test \( "${have_libpython}" = "no" -o "${python_has_threads}" = "no" \) \
1232    && $development; then
1233   libmcheck_default=yes
1234 else
1235   libmcheck_default=no
1236 fi
1237 GDB_AC_LIBMCHECK(${libmcheck_default})
1238
1239 if test "$ENABLE_LIBMCHECK" = "yes" \
1240         -a "${have_libpython}" != "no" \
1241         -a "${python_has_threads}" = "yes" ; then
1242   AC_MSG_WARN(--enable-libmcheck may lead to spurious crashes if threads are used in python)
1243 fi
1244
1245 AC_ARG_WITH(intel_pt,
1246   AS_HELP_STRING([--with-intel-pt], [include Intel(R) Processor Trace support (auto/yes/no)]),
1247   [], [with_intel_pt=auto])
1248 AC_MSG_CHECKING([whether to use intel pt])
1249 AC_MSG_RESULT([$with_intel_pt])
1250
1251 if test "${with_intel_pt}" = no; then
1252   AC_MSG_WARN([Intel(R) Processor Trace support disabled; some features may be unavailable.])
1253   HAVE_LIBIPT=no
1254 else
1255   AC_PREPROC_IFELSE(AC_LANG_SOURCE([[
1256 #include <linux/perf_event.h>
1257 #ifndef PERF_ATTR_SIZE_VER5
1258 # error
1259 #endif
1260   ]]), [perf_event=yes], [perf_event=no])
1261   if test "$perf_event" != yes; then
1262     if test "$with_intel_pt" = yes; then
1263       AC_MSG_ERROR([linux/perf_event.h missing or too old])
1264     else
1265       AC_MSG_WARN([linux/perf_event.h missing or too old; some features may be unavailable.])
1266     fi
1267   fi
1268
1269   AC_LIB_HAVE_LINKFLAGS([ipt], [], [#include "intel-pt.h"], [pt_insn_alloc_decoder (0);])
1270   if test "$HAVE_LIBIPT" != yes; then
1271     if test "$with_intel_pt" = yes; then
1272       AC_MSG_ERROR([libipt is missing or unusable])
1273     else
1274       AC_MSG_WARN([libipt is missing or unusable; some features may be unavailable.])
1275     fi
1276   fi
1277 fi
1278
1279 # ------------------------- #
1280 # Checks for header files.  #
1281 # ------------------------- #
1282
1283 AC_HEADER_STDC
1284 # elf_hp.h is for HP/UX 64-bit shared library support.
1285 AC_CHECK_HEADERS([nlist.h machine/reg.h poll.h sys/poll.h proc_service.h \
1286                   thread_db.h \
1287                   sys/fault.h \
1288                   sys/file.h sys/filio.h sys/ioctl.h sys/param.h \
1289                   sys/resource.h sys/procfs.h sys/ptrace.h ptrace.h \
1290                   sys/reg.h sys/debugreg.h sys/select.h sys/syscall.h \
1291                   termios.h termio.h \
1292                   sgtty.h elf_hp.h \
1293                   dlfcn.h])
1294 AC_CHECK_HEADERS(sys/proc.h, [], [],
1295 [#if HAVE_SYS_PARAM_H
1296 # include <sys/param.h>
1297 #endif
1298 ])
1299 AC_CHECK_HEADERS(sys/user.h, [], [],
1300 [#if HAVE_SYS_PARAM_H
1301 # include <sys/param.h>
1302 #endif
1303 ])
1304
1305 # On Solaris 2.[789], we need to define _MSE_INT_H to avoid a clash
1306 # between <widec.h> and <wchar.h> that would cause AC_CHECK_HEADERS to
1307 # think that we don't have <curses.h> if we're using GCC.
1308 case $host_os in
1309   solaris2.[[789]])
1310     if test "$GCC" = yes; then
1311       AC_DEFINE(_MSE_INT_H, 1,
1312         [Define to 1 to avoid a clash between <widec.h> and <wchar.h> on
1313    Solaris 2.[789] when using GCC. ])
1314     fi ;;
1315 esac
1316 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncurses/ncurses.h ncurses/term.h)
1317 AC_CHECK_HEADERS(term.h, [], [],
1318 [#if HAVE_CURSES_H
1319 # include <curses.h>
1320 #endif
1321 ])
1322
1323 # ------------------------- #
1324 # Checks for declarations.  #
1325 # ------------------------- #
1326
1327 libiberty_INIT
1328
1329 AC_CHECK_DECLS([free, malloc, realloc, snprintf])
1330 AM_LC_MESSAGES
1331
1332 # ----------------------- #
1333 # Checks for structures.  #
1334 # ----------------------- #
1335
1336 AC_CHECK_MEMBERS([struct stat.st_blocks, struct stat.st_blksize])
1337
1338 # ------------------ #
1339 # Checks for types.  #
1340 # ------------------ #
1341
1342 AC_CHECK_TYPES(socklen_t, [], [],
1343 [#include <sys/types.h>
1344 #include <sys/socket.h>
1345 ])
1346
1347 # ------------------------------------- #
1348 # Checks for compiler characteristics.  #
1349 # ------------------------------------- #
1350
1351 AC_C_CONST
1352 AC_C_INLINE
1353 AC_C_BIGENDIAN
1354
1355 # ------------------------------ #
1356 # Checks for library functions.  #
1357 # ------------------------------ #
1358
1359 AC_FUNC_MMAP
1360 AC_FUNC_VFORK
1361 AC_CHECK_FUNCS([getauxval getrusage getuid getgid \
1362                 pipe poll pread pread64 pwrite resize_term \
1363                 sbrk setpgid setpgrp setsid \
1364                 sigaction sigprocmask sigsetmask socketpair \
1365                 ttrace wborder wresize setlocale iconvlist libiconvlist btowc \
1366                 setrlimit getrlimit posix_madvise waitpid \
1367                 ptrace64 sigaltstack mkdtemp setns])
1368 AM_LANGINFO_CODESET
1369 GDB_AC_COMMON
1370
1371 # Check the return and argument types of ptrace.
1372 GDB_AC_PTRACE
1373
1374 dnl AC_FUNC_SETPGRP does not work when cross compiling
1375 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
1376 if test "$cross_compiling" = no; then
1377   AC_FUNC_SETPGRP
1378 else
1379   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
1380     [AC_TRY_COMPILE([
1381 #include <unistd.h>
1382 ], [
1383   if (setpgrp(1,1) == -1)
1384     exit (0);
1385   else
1386     exit (1);
1387 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
1388 if test $ac_cv_func_setpgrp_void = yes; then
1389   AC_DEFINE(SETPGRP_VOID, 1)
1390 fi
1391 fi
1392
1393 # Assume we'll default to using the included libiberty regex.
1394 gdb_use_included_regex=yes
1395
1396 # However, if the system regex is GNU regex, then default to *not*
1397 # using the included regex.
1398 AC_CACHE_CHECK(
1399   [for GNU regex],
1400   [gdb_cv_have_gnu_regex],
1401   [AC_TRY_COMPILE(
1402     [#include <gnu-versions.h>],
1403     [#define REGEX_INTERFACE_VERSION 1
1404 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
1405 # error "Version mismatch"
1406 #endif],
1407     gdb_cv_have_gnu_regex=yes,
1408     gdb_cv_have_gnu_regex=no)])
1409 if test $gdb_cv_have_gnu_regex = yes; then
1410   gdb_use_included_regex=no
1411 fi
1412
1413 AC_ARG_WITH(included-regex,
1414   AS_HELP_STRING([--without-included-regex], [don't use included regex; this is the default on systems with version 2 of the GNU C library (use with caution on other system)]),
1415   gdb_with_regex=$withval,
1416   gdb_with_regex=$gdb_use_included_regex)
1417 if test "$gdb_with_regex" = yes; then
1418   AC_DEFINE(USE_INCLUDED_REGEX, 1,
1419     [Define to 1 if the regex included in libiberty should be used.])
1420 fi
1421
1422 # Check if <sys/proc.h> defines `struct thread' with a td_pcb member.
1423 AC_CHECK_MEMBERS([struct thread.td_pcb], [], [],
1424 [#include <sys/param.h>
1425 #include <sys/proc.h>
1426 ])
1427
1428 # See if <sys/lwp.h> defines `struct lwp`.
1429 AC_CACHE_CHECK([for struct lwp], gdb_cv_struct_lwp,
1430 [AC_TRY_COMPILE([#include <sys/param.h>
1431 #include <sys/lwp.h>], [struct lwp l;],
1432 gdb_cv_struct_lwp=yes, gdb_cv_struct_lwp=no)])
1433 if test $gdb_cv_struct_lwp = yes; then
1434   AC_DEFINE(HAVE_STRUCT_LWP, 1,
1435             [Define to 1 if your system has struct lwp.])
1436 fi
1437
1438 # See if <machine/reg.h> degines `struct reg'.
1439 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
1440 [AC_TRY_COMPILE([#include <sys/types.h>
1441 #include <machine/reg.h>], [struct reg r;],
1442 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
1443 if test $gdb_cv_struct_reg = yes; then
1444   AC_DEFINE(HAVE_STRUCT_REG, 1,
1445             [Define to 1 if your system has struct reg in <machine/reg.h>.])
1446 fi
1447
1448 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
1449 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
1450 AC_CHECK_MEMBERS([struct reg.r_fs, struct reg.r_gs], [], [],
1451                  [#include <machine/reg.h>])
1452
1453 # See if <sys/user.h> supports the %fs_base and %gs_bas amd64 segment registers.
1454 # Older amd64 Linux's don't have the fs_base and gs_base members of
1455 # `struct user_regs_struct'.
1456 AC_CHECK_MEMBERS([struct user_regs_struct.fs_base, struct user_regs_struct.gs_base],
1457                  [], [], [#include <sys/user.h>])
1458
1459 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
1460 AC_MSG_CHECKING(for PTRACE_GETREGS)
1461 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
1462 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1463                 [PTRACE_GETREGS;],
1464                 [gdb_cv_have_ptrace_getregs=yes],
1465                 [gdb_cv_have_ptrace_getregs=no])])
1466 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
1467 if test $gdb_cv_have_ptrace_getregs = yes; then
1468   AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
1469   [Define if sys/ptrace.h defines the PTRACE_GETREGS request.])
1470 fi
1471
1472 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
1473 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
1474 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
1475 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1476                 [PTRACE_GETFPXREGS;],
1477                 [gdb_cv_have_ptrace_getfpxregs=yes],
1478                 [gdb_cv_have_ptrace_getfpxregs=no])])
1479 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
1480 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
1481   AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
1482   [Define if sys/ptrace.h defines the PTRACE_GETFPXREGS request.])
1483 fi
1484
1485 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
1486 AC_MSG_CHECKING(for PT_GETDBREGS)
1487 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
1488 [AC_TRY_COMPILE([#include <sys/types.h>
1489 #include <sys/ptrace.h>],
1490                 [PT_GETDBREGS;],
1491                 [gdb_cv_have_pt_getdbregs=yes],
1492                 [gdb_cv_have_pt_getdbregs=no])])
1493 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
1494 if test $gdb_cv_have_pt_getdbregs = yes; then
1495   AC_DEFINE(HAVE_PT_GETDBREGS, 1,
1496   [Define if sys/ptrace.h defines the PT_GETDBREGS request.])
1497 fi
1498
1499 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
1500 AC_MSG_CHECKING(for PT_GETXMMREGS)
1501 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
1502 [AC_TRY_COMPILE([#include <sys/types.h>
1503 #include <sys/ptrace.h>],
1504                 [PT_GETXMMREGS;],
1505                 [gdb_cv_have_pt_getxmmregs=yes],
1506                 [gdb_cv_have_pt_getxmmregs=no])])
1507 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
1508 if test $gdb_cv_have_pt_getxmmregs = yes; then
1509   AC_DEFINE(HAVE_PT_GETXMMREGS, 1,
1510   [Define if sys/ptrace.h defines the PT_GETXMMREGS request.])
1511 fi
1512
1513 # Detect which type of /proc is in use, such as for Solaris.
1514
1515 if test "${target}" = "${host}"; then
1516   case "${host}" in
1517   *-*-sysv4.2* | *-*-sysv5* )
1518       AC_DEFINE(NEW_PROC_API, 1,
1519       [Define if you want to use new multi-fd /proc interface.])
1520       ;;
1521   *-*-solaris2.[[6789]] | *-*-solaris2.1[[0-9]]*)
1522       AC_DEFINE(NEW_PROC_API, 1,
1523       [Define if you want to use new multi-fd /proc interface.])
1524       ;;
1525   mips-sgi-irix5*)
1526       # Work around <sys/proc.h> needing _KMEMUSER problem on IRIX 5.
1527       AC_DEFINE([_KMEMUSER], 1,
1528       [Define to 1 so <sys/proc.h> gets a definition of anon_hdl.  Works
1529        around a <sys/proc.h> problem on IRIX 5.])
1530       ;;
1531   esac
1532 fi
1533
1534 if test "$ac_cv_header_sys_procfs_h" = yes; then
1535   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
1536   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
1537   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
1538   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
1539   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
1540   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
1541   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
1542   BFD_HAVE_SYS_PROCFS_TYPE(prsysent_t)
1543   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigset_t)
1544   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigaction64_t)
1545   BFD_HAVE_SYS_PROCFS_TYPE(pr_siginfo64_t)
1546
1547
1548   dnl Check for broken prfpregset_t type
1549
1550   dnl For Linux/i386, glibc 2.1.3 was released with a bogus
1551   dnl prfpregset_t type (it's a typedef for the pointer to a struct
1552   dnl instead of the struct itself).  We detect this here, and work
1553   dnl around it in gdb_proc_service.h.
1554
1555   if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
1556     AC_MSG_CHECKING(whether prfpregset_t type is broken)
1557     AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
1558       [AC_TRY_RUN([#include <sys/procfs.h>
1559        int main ()
1560        {
1561          if (sizeof (prfpregset_t) == sizeof (void *))
1562            return 1;
1563          return 0;
1564        }],
1565        gdb_cv_prfpregset_t_broken=no,
1566        gdb_cv_prfpregset_t_broken=yes,
1567        gdb_cv_prfpregset_t_broken=yes)])
1568     AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
1569     if test $gdb_cv_prfpregset_t_broken = yes; then
1570       AC_DEFINE(PRFPREGSET_T_BROKEN, 1,
1571       [Define if the prfpregset_t type is broken.])
1572     fi
1573   fi
1574 fi
1575
1576 # Check if the compiler supports the `long long' type.
1577
1578 AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long,
1579                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1580 [[extern long long foo;]],
1581 [[switch (foo & 2) { case 0: return 1; }]])],
1582                                   gdb_cv_c_long_long=yes,
1583                                   gdb_cv_c_long_long=no)])
1584 if test $gdb_cv_c_long_long != yes; then
1585   # libdecnumber requires long long.
1586   AC_MSG_ERROR([Compiler must support long long for GDB.])
1587 fi
1588
1589 # Check if the compiler and runtime support printing long longs.
1590
1591 AC_CACHE_CHECK([for long long support in printf],
1592                gdb_cv_printf_has_long_long,
1593                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1594 [[char buf[32];
1595   long long l = 0;
1596   l = (l << 16) + 0x0123;
1597   l = (l << 16) + 0x4567;
1598   l = (l << 16) + 0x89ab;
1599   l = (l << 16) + 0xcdef;
1600   sprintf (buf, "0x%016llx", l);
1601   return (strcmp ("0x0123456789abcdef", buf));]])],
1602                               gdb_cv_printf_has_long_long=yes,
1603                               gdb_cv_printf_has_long_long=no,
1604                               gdb_cv_printf_has_long_long=no)])
1605 if test $gdb_cv_printf_has_long_long = yes; then
1606   AC_DEFINE(PRINTF_HAS_LONG_LONG, 1,
1607             [Define to 1 if the "%ll" format works to print long longs.])
1608 fi
1609
1610 # Check if the compiler and runtime support printing decfloats.
1611
1612 AC_CACHE_CHECK([for decfloat support in printf],
1613                gdb_cv_printf_has_decfloat,
1614                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1615 [[char buf[64];
1616   _Decimal32 d32 = 1.2345df;
1617   _Decimal64 d64 = 1.2345dd;
1618   _Decimal128 d128 = 1.2345dl;
1619   sprintf (buf, "Decimal32: %H\nDecimal64: %D\nDecimal128: %DD", d32, d64, d128);
1620   return (strcmp ("Decimal32: 1.2345\nDecimal64: 1.2345\nDecimal128: 1.2345", buf));]])],
1621                               gdb_cv_printf_has_decfloat=yes,
1622                               gdb_cv_printf_has_decfloat=no,
1623                               gdb_cv_printf_has_decfloat=no)])
1624 if test $gdb_cv_printf_has_decfloat = yes; then
1625   AC_DEFINE(PRINTF_HAS_DECFLOAT, 1,
1626             [Define to 1 if the "%H, %D and %DD" formats work to print decfloats.])
1627 fi
1628
1629 # Check if the compiler supports the `long double' type.  We can't use
1630 # AC_C_LONG_DOUBLE because that one does additional checks on the
1631 # constants defined in <float.h> that fail on some systems,
1632 # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6.
1633
1634 AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double,
1635                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])],
1636                                   gdb_cv_c_long_double=yes,
1637                                   gdb_cv_c_long_double=no)])
1638 if test $gdb_cv_c_long_double = yes; then
1639   AC_DEFINE(HAVE_LONG_DOUBLE, 1,
1640            [Define to 1 if the compiler supports long double.])
1641 fi
1642
1643 # Check if the compiler and runtime support printing long doubles.
1644
1645 AC_CACHE_CHECK([for long double support in printf],
1646                gdb_cv_printf_has_long_double,
1647                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1648 [[char buf[16];
1649   long double f = 3.141592653;
1650   sprintf (buf, "%Lg", f);
1651   return (strncmp ("3.14159", buf, 7));]])],
1652                               gdb_cv_printf_has_long_double=yes,
1653                               gdb_cv_printf_has_long_double=no,
1654                               gdb_cv_printf_has_long_double=no)])
1655 if test $gdb_cv_printf_has_long_double = yes; then
1656   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1,
1657             [Define to 1 if the "%Lg" format works to print long doubles.])
1658 fi
1659
1660 # Check if the compiler and runtime support scanning long doubles.
1661
1662 AC_CACHE_CHECK([for long double support in scanf],
1663                gdb_cv_scanf_has_long_double,
1664                [AC_RUN_IFELSE([AC_LANG_PROGRAM(
1665 [[#include <stdio.h>]],
1666 [[char *buf = "3.141592653";
1667   long double f = 0;
1668   sscanf (buf, "%Lg", &f);
1669   return !(f > 3.14159 && f < 3.14160);]])],
1670                               gdb_cv_scanf_has_long_double=yes,
1671                               gdb_cv_scanf_has_long_double=no,
1672                               gdb_cv_scanf_has_long_double=no)])
1673 if test $gdb_cv_scanf_has_long_double = yes; then
1674   AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1,
1675             [Define to 1 if the "%Lg" format works to scan long doubles.])
1676 fi
1677
1678 case ${host_os} in
1679 aix*)
1680   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1681     SAVE_LDFLAGS=$LDFLAGS
1682
1683     case $GCC in
1684     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1685     *) gdb_cv_bigtoc=-bbigtoc ;;
1686     esac
1687
1688     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1689     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1690     LDFLAGS="${SAVE_LDFLAGS}"
1691   ])
1692   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
1693   ;;
1694 esac
1695
1696 AC_MSG_CHECKING(for the dynamic export flag)
1697 dynamic_list=false
1698 if test "${gdb_native}" = yes; then
1699    # The dynamically loaded libthread_db needs access to symbols in the gdb
1700    # executable.  Older GNU ld supports --export-dynamic but --dynamic-list
1701    # may not be supported there.
1702    old_LDFLAGS="$LDFLAGS"
1703    # Older GNU ld supports --export-dynamic but --dynamic-list it does not.
1704    RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
1705    LDFLAGS="$LDFLAGS $RDYNAMIC"
1706    if test "${have_libpython}" = no; then
1707      AC_TRY_LINK([], [], [dynamic_list=true])
1708    else
1709      # Workaround http://bugs.python.org/issue4434 where static
1710      # libpythonX.Y.a would get its symbols required for
1711      # pythonX.Y/lib-dynload/*.so modules hidden by -Wl,--dynamic-list.
1712      # Problem does not happen for the recommended libpythonX.Y.so linkage.
1713      old_CFLAGS="$CFLAGS"
1714      CFLAGS="$CFLAGS $PYTHON_CFLAGS"
1715      old_LIBS="$LIBS"
1716      LIBS="$LIBS $PYTHON_LIBS"
1717      AC_RUN_IFELSE(
1718        AC_LANG_PROGRAM(
1719          [#include "]${have_libpython}[/Python.h"],
1720          [int err;
1721           Py_Initialize ();
1722           err = PyRun_SimpleString ("import itertools\n");
1723           Py_Finalize ();
1724           return err == 0 ? 0 : 1;]),
1725        [dynamic_list=true], [], [true])
1726      LIBS="$old_LIBS"
1727      CFLAGS="$old_CFLAGS"
1728    fi
1729    LDFLAGS="$old_LDFLAGS"
1730 fi
1731 if $dynamic_list; then
1732   found="-Wl,--dynamic-list"
1733   RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'
1734 else
1735   found="-rdynamic"
1736   RDYNAMIC="-rdynamic"
1737 fi
1738 AC_SUBST(RDYNAMIC)
1739 AC_MSG_RESULT($found)
1740
1741 dnl For certain native configurations, we need to check whether thread
1742 dnl support can be built in or not.
1743 dnl
1744 dnl Note that we only want this if we are both native (host == target),
1745 dnl and not doing a canadian cross build (build == host).
1746
1747 if test ${build} = ${host} -a ${host} = ${target} ; then
1748    case ${host_os} in
1749    solaris*)
1750       # See if thread_db library is around for Solaris thread debugging.
1751       # Note that we must explicitly test for version 1 of the library
1752       # because version 0 (present on Solaris 2.4 or earlier) doesn't have
1753       # the same API.
1754       AC_MSG_CHECKING(for Solaris thread debugging library)
1755       if test -f /usr/lib/libthread_db.so.1 ; then
1756          AC_MSG_RESULT(yes)
1757          AC_DEFINE(HAVE_THREAD_DB_LIB, 1,
1758          [Define if using Solaris thread debugging.])
1759          CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
1760          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
1761          AC_CHECK_LIB(dl, dlopen)
1762          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} $RDYNAMIC"
1763          # Sun randomly tweaked the prototypes in <proc_service.h>
1764          # at one point.
1765          AC_MSG_CHECKING(if <proc_service.h> is old)
1766          AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
1767             AC_TRY_COMPILE([
1768                 #include <proc_service.h>
1769                 ps_err_e ps_pdwrite
1770                     (struct ps_prochandle*, psaddr_t, const void*, size_t);
1771             ],, gdb_cv_proc_service_is_old=no,
1772                 gdb_cv_proc_service_is_old=yes)
1773          ])
1774          AC_MSG_RESULT($gdb_cv_proc_service_is_old)
1775          if test $gdb_cv_proc_service_is_old = yes; then
1776             AC_DEFINE(PROC_SERVICE_IS_OLD, 1,
1777             [Define if <proc_service.h> on solaris uses int instead of
1778              size_t, and assorted other type changes.])
1779          fi
1780       else
1781          AC_MSG_RESULT(no)
1782       fi
1783       ;;
1784    aix*)
1785       AC_MSG_CHECKING(for AiX thread debugging library)
1786       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
1787                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
1788                                    [#ifndef PTHDB_VERSION_3
1789                                     #error
1790                                     #endif],
1791                                    gdb_cv_have_aix_thread_debug=yes,
1792                                    gdb_cv_have_aix_thread_debug=no)])
1793       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1794       if test $gdb_cv_have_aix_thread_debug = yes; then
1795          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1796          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1797          LIBS="$LIBS -lpthdebug"
1798
1799          # Older versions of AIX do not provide the declaration for
1800          # the getthrds function (it appears that it was introduced
1801          # with AIX 6.x).
1802          AC_CHECK_DECLS(getthrds, [], [], [[#include <procinfo.h>]])
1803       fi
1804       ;;
1805    esac
1806    AC_SUBST(CONFIG_LDFLAGS)
1807 fi
1808
1809 dnl See if we have a thread_db header file that has TD_NOTALLOC and
1810 dnl other error codes.
1811 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1812    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
1813                   gdb_cv_thread_db_h_has_td_notalloc,
1814      AC_TRY_COMPILE(
1815        [#include <thread_db.h>],
1816        [int i = TD_NOTALLOC;],
1817        gdb_cv_thread_db_h_has_td_notalloc=yes,
1818        gdb_cv_thread_db_h_has_td_notalloc=no
1819      )
1820    )
1821    AC_CACHE_CHECK([whether <thread_db.h> has TD_VERSION],
1822                   gdb_cv_thread_db_h_has_td_version,
1823      AC_TRY_COMPILE(
1824        [#include <thread_db.h>],
1825        [int i = TD_VERSION;],
1826        gdb_cv_thread_db_h_has_td_version=yes,
1827        gdb_cv_thread_db_h_has_td_version=no
1828      )
1829    )
1830    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTLS],
1831                   gdb_cv_thread_db_h_has_td_notls,
1832      AC_TRY_COMPILE(
1833        [#include <thread_db.h>],
1834        [int i = TD_NOTLS;],
1835        gdb_cv_thread_db_h_has_td_notls=yes,
1836        gdb_cv_thread_db_h_has_td_notls=no
1837      )
1838    )
1839 fi
1840 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1841   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1842             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1843 fi
1844 if test "x$gdb_cv_thread_db_h_has_td_version" = "xyes"; then
1845   AC_DEFINE(THREAD_DB_HAS_TD_VERSION, 1,
1846             [Define if <thread_db.h> has the TD_VERSION error code.])
1847 fi
1848 if test "x$gdb_cv_thread_db_h_has_td_notls" = "xyes"; then
1849   AC_DEFINE(THREAD_DB_HAS_TD_NOTLS, 1,
1850             [Define if <thread_db.h> has the TD_NOTLS error code.])
1851 fi
1852
1853 dnl See if we have a sys/syscall header file that has __NR_tkill.
1854 if test "x$ac_cv_header_sys_syscall_h" = "xyes"; then
1855    AC_CACHE_CHECK([whether <sys/syscall.h> has __NR_tkill],
1856                   gdb_cv_sys_syscall_h_has_tkill,
1857      AC_TRY_COMPILE(
1858        [#include <sys/syscall.h>],
1859        [int i = __NR_tkill;],
1860        gdb_cv_sys_syscall_h_has_tkill=yes,
1861        gdb_cv_sys_syscall_h_has_tkill=no
1862      )
1863    )
1864 fi
1865 dnl See if we can issue tkill syscall.
1866 if test "x$gdb_cv_sys_syscall_h_has_tkill" = "xyes"; then
1867   AC_CHECK_FUNC(syscall,
1868     AC_DEFINE(HAVE_TKILL_SYSCALL, 1, [Define if you support the tkill syscall.])
1869   )
1870 fi
1871
1872 dnl Check if we can disable the virtual address space randomization.
1873 dnl The functionality of setarch -R.
1874 AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>])
1875 define([PERSONALITY_TEST], [AC_LANG_PROGRAM([#include <sys/personality.h>], [
1876 #      if !HAVE_DECL_ADDR_NO_RANDOMIZE
1877 #       define ADDR_NO_RANDOMIZE 0x0040000
1878 #      endif
1879        /* Test the flag could be set and stays set.  */
1880        personality (personality (0xffffffff) | ADDR_NO_RANDOMIZE);
1881        if (!(personality (personality (0xffffffff)) & ADDR_NO_RANDOMIZE))
1882            return 1])])
1883 AC_RUN_IFELSE([PERSONALITY_TEST],
1884               [have_personality=true],
1885               [have_personality=false],
1886               [AC_LINK_IFELSE([PERSONALITY_TEST],
1887                               [have_personality=true],
1888                               [have_personality=false])])
1889 if $have_personality
1890 then
1891     AC_DEFINE([HAVE_PERSONALITY], 1,
1892               [Define if you support the personality syscall.])
1893 fi
1894
1895 dnl Set the host's .gdbinit filename.
1896 case $host_os in
1897   go32* | *djgpp*)
1898     gdbinit=gdb.ini
1899     ;;
1900   *)
1901     gdbinit=.gdbinit
1902     ;;
1903 esac
1904 AC_DEFINE_UNQUOTED(GDBINIT,"$gdbinit",[The .gdbinit filename.])
1905
1906 dnl Handle optional features that can be enabled.
1907
1908 # Support for --with-sysroot is a copy of GDB_AC_WITH_DIR,
1909 # except that the argument to --with-sysroot is optional.
1910 # --with-sysroot (or --with-sysroot=yes) sets the default sysroot path.
1911 if test "x$with_sysroot" = xyes; then
1912   with_sysroot="${exec_prefix}/${target_alias}/sys-root"
1913 fi
1914 AC_ARG_WITH(sysroot,
1915   AS_HELP_STRING([--with-sysroot@<:@=DIR@:>@],
1916                  [search for usr/lib et al within DIR]),
1917   [TARGET_SYSTEM_ROOT=$withval], [TARGET_SYSTEM_ROOT=])
1918 AC_DEFINE_DIR(TARGET_SYSTEM_ROOT, TARGET_SYSTEM_ROOT,
1919               [search for usr/lib et al within DIR])
1920 AC_SUBST(TARGET_SYSTEM_ROOT)
1921 GDB_AC_DEFINE_RELOCATABLE(TARGET_SYSTEM_ROOT, sysroot, ${ac_define_dir})
1922
1923 GDB_AC_WITH_DIR(SYSTEM_GDBINIT, system-gdbinit,
1924     [automatically load a system-wide gdbinit file],
1925     [])
1926
1927 AC_ARG_ENABLE(werror,
1928   AS_HELP_STRING([--enable-werror], [treat compile warnings as errors]),
1929   [case "${enableval}" in
1930      yes | y) ERROR_ON_WARNING="yes" ;;
1931      no | n)  ERROR_ON_WARNING="no" ;;
1932      *) AC_MSG_ERROR(bad value ${enableval} for --enable-werror) ;;
1933    esac])
1934
1935 # Enable -Werror by default when using gcc in C mode.  Leave it off
1936 # for C++ until we're warning clean.  Turn it off for releases.
1937 if test "${GCC}" = yes -a -z "${ERROR_ON_WARNING}" \
1938    && test x"$enable_build_with_cxx" != x"yes" \
1939    && $development; then
1940     ERROR_ON_WARNING=yes
1941 fi
1942
1943 WERROR_CFLAGS=""
1944 if test "${ERROR_ON_WARNING}" = yes ; then
1945     WERROR_CFLAGS="-Werror"
1946 fi
1947
1948 # These options work in either C or C++ modes.
1949 build_warnings="-Wall -Wpointer-arith \
1950 -Wno-unused -Wunused-value -Wunused-function \
1951 -Wno-switch -Wno-char-subscripts \
1952 -Wempty-body"
1953
1954 # Now add in C and C++ specific options, depending on mode.
1955 if test "$enable_build_with_cxx" = "yes"; then
1956    build_warnings="$build_warnings -Wno-sign-compare -Wno-write-strings \
1957 -Wno-narrowing"
1958 else
1959    build_warnings="$build_warnings -Wpointer-sign -Wmissing-prototypes \
1960 -Wdeclaration-after-statement -Wmissing-parameter-type \
1961 -Wold-style-declaration -Wold-style-definition"
1962 fi
1963
1964 # Enable -Wno-format by default when using gcc on mingw since many
1965 # GCC versions complain about %I64.
1966 case "${host}" in
1967   *-*-mingw32*) build_warnings="$build_warnings -Wno-format" ;;
1968   *) build_warnings="$build_warnings -Wformat-nonliteral" ;;
1969 esac
1970
1971 AC_ARG_ENABLE(build-warnings,
1972 AS_HELP_STRING([--enable-build-warnings], [enable build-time compiler warnings if gcc is used]),
1973 [case "${enableval}" in
1974   yes)  ;;
1975   no)   build_warnings="-w";;
1976   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1977         build_warnings="${build_warnings} ${t}";;
1978   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1979         build_warnings="${t} ${build_warnings}";;
1980   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1981 esac
1982 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1983   echo "Setting compiler warning flags = $build_warnings" 6>&1
1984 fi])dnl
1985 AC_ARG_ENABLE(gdb-build-warnings,
1986 AS_HELP_STRING([--enable-gdb-build-warnings], [enable GDB specific build-time compiler warnings if gcc is used]),
1987 [case "${enableval}" in
1988   yes)  ;;
1989   no)   build_warnings="-w";;
1990   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1991         build_warnings="${build_warnings} ${t}";;
1992   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1993         build_warnings="${t} ${build_warnings}";;
1994   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1995 esac
1996 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1997   echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1
1998 fi])dnl
1999
2000 # The set of warnings supported by a C++ compiler is not the same as
2001 # of the C compiler.
2002 if test "$enable_build_with_cxx" = "yes"; then
2003     AC_LANG_PUSH([C++])
2004 fi
2005
2006 WARN_CFLAGS=""
2007 if test "x${build_warnings}" != x -a "x$GCC" = xyes
2008 then
2009     AC_MSG_CHECKING(compiler warning flags)
2010     # Separate out the -Werror flag as some files just cannot be
2011     # compiled with it enabled.
2012     for w in ${build_warnings}; do
2013         case $w in
2014         -Werr*) WERROR_CFLAGS=-Werror ;;
2015         *)
2016             # Check whether GCC accepts it.
2017             saved_CFLAGS="$CFLAGS"
2018             CFLAGS="$CFLAGS $w"
2019             saved_CXXFLAGS="$CXXFLAGS"
2020             CXXFLAGS="$CXXFLAGS $w"
2021             AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
2022             CFLAGS="$saved_CFLAGS"
2023             CXXFLAGS="$saved_CXXFLAGS"
2024         esac
2025     done
2026     AC_MSG_RESULT(${WARN_CFLAGS} ${WERROR_CFLAGS})
2027 fi
2028 AC_SUBST(WARN_CFLAGS)
2029 AC_SUBST(WERROR_CFLAGS)
2030
2031 if test "$enable_build_with_cxx" = "yes"; then
2032    AC_LANG_POP([C++])
2033 fi
2034
2035 # In the Cygwin environment, we need some additional flags.
2036 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
2037 [AC_EGREP_CPP(^lose$, [
2038 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
2039 lose
2040 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
2041
2042
2043 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
2044 SER_HARDWIRE="ser-base.o ser-unix.o ser-pipe.o ser-tcp.o"
2045 case ${host} in
2046   *go32* ) SER_HARDWIRE=ser-go32.o ;;
2047   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
2048   *mingw32*) SER_HARDWIRE="ser-base.o ser-tcp.o ser-mingw.o" ;;
2049 esac
2050 AC_SUBST(SER_HARDWIRE)
2051
2052 # libreadline needs libuser32.a in a cygwin environment
2053 WIN32LIBS=
2054 if test x$gdb_cv_os_cygwin = xyes; then
2055     WIN32LIBS="-luser32"
2056     case "${target}" in
2057         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
2058         ;;
2059     esac
2060 fi
2061
2062 # The ser-tcp.c module requires sockets.
2063 case ${host} in
2064   *mingw32*)
2065     AC_DEFINE(USE_WIN32API, 1,
2066               [Define if we should use the Windows API, instead of the
2067                POSIX API.  On Windows, we use the Windows API when
2068                building for MinGW, but the POSIX API when building
2069                for Cygwin.])
2070     WIN32LIBS="$WIN32LIBS -lws2_32"
2071     ;;
2072 esac
2073 AC_SUBST(WIN32LIBS)
2074
2075 # Add ELF support to GDB, but only if BFD includes ELF support.
2076 GDB_AC_CHECK_BFD([for ELF support in BFD], gdb_cv_var_elf,
2077                  [bfd_get_elf_phdr_upper_bound (NULL)], elf-bfd.h)
2078 if test $gdb_cv_var_elf = yes; then
2079   CONFIG_OBS="$CONFIG_OBS elfread.o stap-probe.o dtrace-probe.o"
2080   AC_DEFINE(HAVE_ELF, 1,
2081             [Define if ELF support should be included.])
2082   # -ldl is provided by bfd/Makfile.am (LIBDL) <PLUGINS>.
2083   if test "$plugins" = "yes"; then
2084     AC_SEARCH_LIBS(dlopen, dl)
2085   fi
2086 fi
2087
2088 # Add macho support to GDB, but only if BFD includes it.
2089 GDB_AC_CHECK_BFD([for Mach-O support in BFD], gdb_cv_var_macho,
2090                  [bfd_mach_o_lookup_command (NULL, 0, NULL)], mach-o.h)
2091 if test $gdb_cv_var_macho = yes; then
2092   CONFIG_OBS="$CONFIG_OBS machoread.o"
2093 fi
2094
2095 # Add any host-specific objects to GDB.
2096 CONFIG_OBS="${CONFIG_OBS} ${gdb_host_obs}"
2097
2098 # If building on ELF, look for lzma support for embedded compressed debug info.
2099 if test $gdb_cv_var_elf = yes; then
2100   AC_ARG_WITH(lzma,
2101     AS_HELP_STRING([--with-lzma], [support lzma compression (auto/yes/no)]),
2102     [], [with_lzma=auto])
2103   AC_MSG_CHECKING([whether to use lzma])
2104   AC_MSG_RESULT([$with_lzma])
2105
2106   if test "${with_lzma}" != no; then
2107     AC_LIB_HAVE_LINKFLAGS([lzma], [], [#include "lzma.h"],
2108                           [lzma_index_iter iter;
2109                            lzma_index_iter_init (&iter, 0);
2110                            lzma_mf_is_supported (LZMA_MF_HC3);])
2111     if test "$HAVE_LIBLZMA" != yes; then
2112       if test "$with_lzma" = yes; then
2113         AC_MSG_ERROR([missing liblzma for --with-lzma])
2114       fi
2115     fi
2116   fi
2117 fi
2118
2119 LIBGUI="../libgui/src/libgui.a"
2120 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
2121 AC_SUBST(LIBGUI)
2122 AC_SUBST(GUI_CFLAGS_X)
2123
2124 WIN32LDAPP=
2125 AC_SUBST(WIN32LIBS)
2126 AC_SUBST(WIN32LDAPP)
2127
2128 case "${host}" in
2129 *-*-cygwin* | *-*-mingw* )
2130     configdir="win"
2131     ;;
2132 *)
2133     configdir="unix"
2134     ;;
2135 esac
2136
2137 GDBTKLIBS=
2138 if test "${enable_gdbtk}" = "yes"; then
2139
2140     # Gdbtk must have an absolute path to srcdir in order to run
2141     # properly when not installed.
2142     here=`pwd`
2143     cd ${srcdir}
2144     GDBTK_SRC_DIR=`pwd`
2145     cd $here
2146
2147     SC_PATH_TCLCONFIG
2148
2149     # If $no_tk is nonempty, then we can't do Tk, and there is no
2150     # point to doing Tcl.
2151     SC_PATH_TKCONFIG
2152
2153     if test -z "${no_tcl}" -a -z "${no_tk}"; then
2154         SC_LOAD_TCLCONFIG
2155
2156         # Check for in-tree tcl
2157         here=`pwd`
2158         cd ${srcdir}/..
2159         topdir=`pwd`
2160         cd ${here}
2161
2162         intree="no"
2163         if test "${TCL_SRC_DIR}" = "${topdir}/tcl"; then
2164           intree="yes"
2165         fi
2166
2167         # Find Tcl private headers
2168         if test x"${intree}" = xno; then
2169           CY_AC_TCL_PRIVATE_HEADERS
2170           TCL_INCLUDE="${TCL_INCLUDE_SPEC} ${TCL_PRIVATE_INCLUDE}"
2171           TCL_LIBRARY="${TCL_LIB_SPEC}"
2172           TCL_DEPS=""
2173         else
2174           # If building tcl in the same src tree, private headers
2175           # are not needed, but we need to be sure to use the right
2176           # headers library
2177           TCL_INCLUDE="-I${TCL_SRC_DIR}/generic"
2178           TCL_LIBRARY="${TCL_BUILD_LIB_SPEC}"
2179           TCL_DEPS="../tcl/${configdir}${TCL_LIB_FILE}"
2180         fi
2181         AC_SUBST(TCL_INCLUDE)
2182         AC_SUBST(TCL_LIBRARY)
2183         AC_SUBST(TCL_DEPS)
2184
2185         SC_LOAD_TKCONFIG
2186
2187         # Check for in-tree Tk
2188         intree="no"
2189         if test "${TK_SRC_DIR}" = "${topdir}/tk"; then
2190           intree="yes"
2191         fi
2192
2193         # Find Tk private headers
2194         if test x"${intree}" = xno; then
2195           CY_AC_TK_PRIVATE_HEADERS
2196           TK_INCLUDE="${TK_INCLUDE_SPEC} ${TK_PRIVATE_INCLUDE}"
2197           TK_LIBRARY=${TK_LIB_SPEC}
2198           TK_DEPS=""
2199         else
2200           TK_INCLUDE="-I${TK_SRC_DIR}/generic"
2201           TK_LIBRARY="${TK_BUILD_LIB_SPEC}"
2202           TK_DEPS="../tk/${configdir}/${TK_LIB_FILE}"
2203         fi
2204         AC_SUBST(TK_INCLUDE)
2205         AC_SUBST(TK_LIBRARY)
2206         AC_SUBST(TK_DEPS)
2207         AC_SUBST(TK_XINCLUDES)
2208
2209         ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
2210
2211         # Include some libraries that Tcl and Tk want.
2212         TCL_LIBS='$(LIBGUI) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
2213         # Yes, the ordering seems wrong here.  But it isn't.
2214         # TK_LIBS is the list of libraries that need to be linked
2215         # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
2216         # were in LIBS then any link tests after this point would
2217         # try to include things like `$(LIBGUI)', which wouldn't work.
2218         GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
2219
2220         CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
2221         CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
2222         CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
2223         CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
2224         CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
2225         CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
2226         CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
2227
2228         if test x$gdb_cv_os_cygwin = xyes; then
2229           WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
2230           WIN32LDAPP="-Wl,--subsystem,console"
2231           CONFIG_OBS="${CONFIG_OBS} gdbres.o"
2232         fi
2233
2234         AC_CONFIG_SUBDIRS(gdbtk)
2235     fi
2236 fi
2237
2238 AC_SUBST(X_CFLAGS)
2239 AC_SUBST(X_LDFLAGS)
2240 AC_SUBST(X_LIBS)
2241 AC_SUBST(GDBTKLIBS)
2242 AC_SUBST(GDBTK_CFLAGS)
2243 AC_SUBST(GDBTK_SRC_DIR)
2244
2245 AC_PATH_X
2246
2247 # Unlike the sim directory, whether a simulator is linked is controlled by
2248 # presence of a gdb_sim definition in the target configure.tgt entry.
2249 # This code just checks for a few cases where we'd like to ignore those
2250 # definitions, even when they're present in the '.mt' file.  These cases
2251 # are when --disable-sim is specified, or if the simulator directory is
2252 # not part of the source tree.
2253 #
2254 AC_ARG_ENABLE(sim,
2255 AS_HELP_STRING([--enable-sim], [link gdb with simulator]),
2256 [echo "enable_sim = $enable_sim";
2257  echo "enableval = ${enableval}";
2258  case "${enableval}" in
2259   yes) ignore_sim=false ;;
2260   no)  ignore_sim=true ;;
2261   *)   ignore_sim=false ;;
2262  esac],
2263 [ignore_sim=false])
2264
2265 if test ! -d "${srcdir}/../sim"; then
2266   ignore_sim=true
2267 fi
2268
2269 SIM=
2270 SIM_OBS=
2271 if test "${ignore_sim}" = "false"; then
2272   if test x"${gdb_sim}" != x ; then
2273     SIM="${gdb_sim}"
2274     SIM_OBS="remote-sim.o"
2275     AC_DEFINE(WITH_SIM, 1, [Define if the simulator is being linked in.])
2276   fi
2277 fi
2278 AC_SUBST(SIM)
2279 AC_SUBST(SIM_OBS)
2280
2281 AC_SUBST(ENABLE_CFLAGS)
2282 AC_SUBST(PROFILE_CFLAGS)
2283
2284 AC_SUBST(CONFIG_OBS)
2285 AC_SUBST(CONFIG_DEPS)
2286 AC_SUBST(CONFIG_SRCS)
2287 AC_SUBST(CONFIG_ALL)
2288 AC_SUBST(CONFIG_CLEAN)
2289 AC_SUBST(CONFIG_INSTALL)
2290 AC_SUBST(CONFIG_UNINSTALL)
2291
2292 # List of host floatformats.
2293 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
2294 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
2295 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
2296
2297 # target_subdir is used by the testsuite to find the target libraries.
2298 target_subdir=
2299 if test "${host}" != "${target}"; then
2300     target_subdir="${target_alias}/"
2301 fi
2302 AC_SUBST(target_subdir)
2303
2304 frags=
2305 if test "${gdb_native}" = "yes"; then
2306   host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
2307   if test ! -f ${host_makefile_frag}; then
2308     AC_MSG_ERROR("*** Gdb does not support native target ${host}")
2309   fi
2310   frags="$frags $host_makefile_frag"
2311 else
2312   host_makefile_frag=/dev/null
2313 fi
2314
2315 AC_SUBST_FILE(host_makefile_frag)
2316 AC_SUBST(frags)
2317
2318 changequote(,)dnl
2319 if test "${gdb_native}" = "yes"; then
2320 # We pick this up from the host configuration file (.mh) because we
2321 # do not have a native configuration Makefile fragment.
2322 nativefile=`sed -n '
2323 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
2324 ' ${host_makefile_frag}`
2325 fi
2326 changequote([,])
2327
2328 if test x"${gdb_osabi}" != x ; then
2329     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
2330                        [Define to the default OS ABI for this configuration.])
2331 fi
2332
2333 # Enable multi-ice-gdb-server.
2334 AC_ARG_ENABLE(multi-ice,
2335 AS_HELP_STRING([--enable-multi-ice], [build the multi-ice-gdb-server]),
2336   [case $enableval in
2337     yes | no)
2338       ;;
2339     *) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;;
2340   esac])
2341 if test "x$enable_multi_ice" = xyes; then
2342    AC_CONFIG_SUBDIRS(multi-ice)
2343 fi
2344
2345 AC_ARG_ENABLE(gdbserver,
2346 AS_HELP_STRING([--enable-gdbserver],
2347                [automatically build gdbserver (yes/no/auto, default is auto)]),
2348 [case "${enableval}" in
2349   yes| no|auto) ;;
2350   *) AC_MSG_ERROR(bad value ${enableval} for --enable-gdbserver option) ;;
2351 esac],[enable_gdbserver=auto])
2352
2353 # We only build gdbserver automatically in a native configuration, and
2354 # only if the user did not explicitly disable its build.
2355 if test "$gdb_native" = "yes" -a "$enable_gdbserver" != "no"; then
2356   AC_MSG_CHECKING(whether gdbserver is supported on this host)
2357   if test "x$build_gdbserver" = xyes; then
2358     AC_MSG_RESULT(yes)
2359     AC_CONFIG_SUBDIRS(gdbserver)
2360     gdbserver_build_enabled=yes
2361   else
2362     AC_MSG_RESULT(no)
2363   fi
2364 fi
2365
2366 # If the user explicitly request the gdbserver to be built, verify that
2367 # we were in fact able to enable it.
2368 if test "$enable_gdbserver" = "yes" -a "$gdbserver_build_enabled" != "yes"; then
2369   AC_MSG_ERROR(Automatic gdbserver build is not supported for this configuration)
2370 fi
2371
2372 # Check for babeltrace and babeltrace-ctf
2373 AC_ARG_WITH(babeltrace,
2374   AC_HELP_STRING([--with-babeltrace], [include babeltrace support (auto/yes/no)]),
2375   [], [with_babeltrace=auto])
2376 AC_MSG_CHECKING([whether to use babeltrace])
2377 AC_MSG_RESULT([$with_babeltrace])
2378
2379 if test "x$with_babeltrace" = "xno"; then
2380   AC_MSG_WARN([babletrace support disabled; GDB is unable to read CTF data.])
2381 else
2382   # Append -Werror to CFLAGS so that configure can catch the warning
2383   # "assignment from incompatible pointer type", which is related to
2384   # the babeltrace change from 1.0.3 to 1.1.0.  Babeltrace 1.1.0 works
2385   # in GDB, while babeltrace 1.0.3 is broken.
2386   # AC_LIB_HAVE_LINKFLAGS may modify CPPFLAGS in it, so it should be
2387   # safe to save and restore CFLAGS here.
2388   saved_CFLAGS=$CFLAGS
2389   CFLAGS="$CFLAGS -Werror"
2390   AC_LIB_HAVE_LINKFLAGS([babeltrace], [babeltrace-ctf],
2391                         [#include <babeltrace/babeltrace.h>
2392                          #include <babeltrace/ctf/events.h>
2393                          #include <babeltrace/ctf/iterator.h>],
2394                         [struct bt_iter_pos *pos = bt_iter_get_pos (bt_ctf_get_iter (NULL));
2395                         struct bt_ctf_event *event = NULL;
2396                         const struct bt_definition *scope;
2397
2398                         bt_iter_set_pos (bt_ctf_get_iter (NULL), pos);
2399                         scope = bt_ctf_get_top_level_scope (event,
2400                                                            BT_STREAM_EVENT_HEADER);
2401                         bt_ctf_get_uint64 (bt_ctf_get_field (event, scope, "id"));
2402                         ])
2403   CFLAGS=$saved_CFLAGS
2404
2405   if test "$HAVE_LIBBABELTRACE" != yes; then
2406      if test "$with_babeltrace" = yes; then
2407        AC_MSG_ERROR([babeltrace is missing or unusable])
2408      else
2409        AC_MSG_WARN([babeltrace is missing or unusable; GDB is unable to read CTF data.])
2410      fi
2411   fi
2412 fi
2413
2414 # If nativefile (NAT_FILE) is not set in config/*/*.m[ht] files, we link
2415 # to an empty version.
2416
2417 files=
2418 links=
2419
2420 rm -f nm.h
2421 if test "${nativefile}" != ""; then
2422     case "${nativefile}" in
2423       nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
2424       * ) GDB_NM_FILE="${nativefile}"
2425     esac
2426     files="${files} ${GDB_NM_FILE}"
2427     links="${links} nm.h"
2428     AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}", [nativefile])
2429 fi
2430 AC_SUBST(GDB_NM_FILE)
2431
2432 AC_LINK_FILES($files, $links)
2433
2434 dnl Check for exe extension set on certain hosts (e.g. Win32)
2435 AC_EXEEXT
2436
2437 dnl  Detect the character set used by this host.
2438 dnl  At the moment, we just assume it's UTF-8.
2439 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "UTF-8",
2440           [Define to be a string naming the default host character set.])
2441
2442 GDB_AC_TRANSFORM([gdb], [GDB_TRANSFORM_NAME])
2443 GDB_AC_TRANSFORM([gcore], [GCORE_TRANSFORM_NAME])
2444 AC_CONFIG_FILES([gcore], [chmod +x gcore])
2445
2446 AC_OUTPUT(Makefile gdb-gdb.gdb doc/Makefile data-directory/Makefile,
2447 [
2448 case x$CONFIG_HEADERS in
2449 xconfig.h:config.in)
2450 echo > stamp-h ;;
2451 esac
2452 ])
2453
2454 exit 0