gdb/configure.ac

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995-2016 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Process this file with autoconf to produce a configure script.
  20
  21 AC_PREREQ(2.59)dnl
  22 AC_INIT(main.c)
  23 AC_CONFIG_HEADER(config.h:config.in)
  24 AM_MAINTAINER_MODE
  25
  26 # Set the 'development' global.
  27 . $srcdir/../bfd/development.sh
  28
  29 AC_PROG_CC
  30 AC_PROG_CXX
  31
  32 AC_USE_SYSTEM_EXTENSIONS
  33 ACX_LARGEFILE
  34 AM_PROG_CC_STDC
  35 AM_PROG_INSTALL_STRIP
  36
  37 AC_CONFIG_AUX_DIR(..)
  38 AC_CANONICAL_SYSTEM
  39 AC_ARG_PROGRAM
  40
  41 # We require a C++11 compiler.  Check if one is available, and if
  42 # necessary, set CXX_DIALECT to some -std=xxx switch.
  43 AX_CXX_COMPILE_STDCXX(11, , mandatory)
  44
  45 # Dependency checking.
  46 ZW_CREATE_DEPDIR
  47 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  48
  49 # Check for the 'make' the user wants to use.
  50 AC_CHECK_PROGS(MAKE, make)
  51 MAKE_IS_GNU=
  52 case "`$MAKE --version 2>&1 | sed 1q`" in
  53   *GNU*)
  54     MAKE_IS_GNU=yes
  55     ;;
  56 esac
  57 AM_CONDITIONAL(GMAKE, test "$MAKE_IS_GNU" = yes)
  58 AC_PROG_MAKE_SET
  59
  60 gnulib_extra_configure_args=
  61 # If large-file support is disabled, make sure gnulib does the same.
  62 if test "$enable_largefile" = no; then
  63 gnulib_extra_configure_args="$gnulib_extra_configure_args --disable-largefile"
  64 fi
  65
  66 # Configure gnulib.  We need to build gnulib under some other
  67 # directory not "gnulib", to avoid the problem of both GDB and
  68 # GDBserver wanting to build it in the same directory, when building
  69 # in the source dir.
  70 ACX_CONFIGURE_DIR(["gnulib"], ["build-gnulib"],
  71                   ["$gnulib_extra_configure_args"])
  72
  73 dnl List of object files and targets accumulated by configure.
  74
  75 CONFIG_OBS=
  76 CONFIG_DEPS=
  77 CONFIG_SRCS=
  78 ENABLE_CFLAGS=
  79
  80 CONFIG_ALL=
  81 CONFIG_CLEAN=
  82 CONFIG_INSTALL=
  83 CONFIG_UNINSTALL=
  84
  85 dnl Set up for gettext.
  86 ZW_GNU_GETTEXT_SISTER_DIR
  87
  88 localedir='${datadir}/locale'
  89 AC_SUBST(localedir)
  90
  91 if test x"$USE_NLS" = xyes; then
  92    CONFIG_ALL="$CONFIG_ALL all-po"
  93    CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
  94    CONFIG_INSTALL="$CONFIG_INSTALL install-po"
  95    CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
  96 fi
  97
  98 GNULIB=build-gnulib/import
  99
 100 # For Makefile dependencies.
 101 GNULIB_STDINT_H=
 102 if test x"$STDINT_H" != x; then
 103   GNULIB_STDINT_H=$GNULIB/$STDINT_H
 104 fi
 105 AC_SUBST(GNULIB_STDINT_H)
 106
 107 PACKAGE=gdb
 108 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
 109 AC_SUBST(PACKAGE)
 110
 111 # We never need to detect it in this sub-configure.
 112 # But preserve it for config.status --recheck.
 113 AC_ARG_VAR(MAKEINFO,
 114   [Parent configure detects if it is of sufficient version.])
 115 AC_ARG_VAR(MAKEINFOFLAGS,
 116   [Parameters for MAKEINFO.])
 117
 118 MAKEINFO_EXTRA_FLAGS=""
 119 AC_CACHE_CHECK([whether $MAKEINFO supports @click], gdb_cv_have_makeinfo_click,
 120   [echo '@clicksequence{a @click{} b}' >conftest.texinfo
 121   if eval "$MAKEINFO conftest.texinfo >&5 2>&5"; then
 122     gdb_cv_have_makeinfo_click=yes
 123   else
 124     gdb_cv_have_makeinfo_click=no
 125   fi])
 126 if test x"$gdb_cv_have_makeinfo_click" = xyes; then
 127   MAKEINFO_EXTRA_FLAGS="$MAKEINFO_EXTRA_FLAGS -DHAVE_MAKEINFO_CLICK"
 128 fi
 129 AC_SUBST(MAKEINFO_EXTRA_FLAGS)
 130
 131 GDB_AC_WITH_DIR(DEBUGDIR, separate-debug-dir,
 132     [look for global separate debug info in this path @<:@LIBDIR/debug@:>@],
 133     [${libdir}/debug])
 134
 135 # We can't pass paths as command line arguments.
 136 # Mingw32 tries to be clever and will convert the paths for us.
 137 # For example -DBINDIR="/usr/local/bin" passed on the command line may get
 138 # converted to -DBINDIR="E:/msys/mingw32/msys/1.0/local/bin".
 139 # This breaks GDB's relocatable path conversions since paths passed in
 140 # config.h would not get so translated, the path prefixes no longer match.
 141 AC_DEFINE_DIR(BINDIR, bindir, [Directory of programs.])
 142
 143 # GDB's datadir relocation
 144
 145 GDB_AC_WITH_DIR(GDB_DATADIR, gdb-datadir,
 146     [look for global separate data files in this path @<:@DATADIR/gdb@:>@],
 147     [${datadir}/gdb])
 148
 149 AC_ARG_WITH(relocated-sources,
 150 AS_HELP_STRING([--with-relocated-sources=PATH], [automatically relocate this path for source files]),
 151 [reloc_srcdir="${withval}"
 152  AC_DEFINE_DIR(RELOC_SRCDIR, reloc_srcdir,
 153               [Relocated directory for source files. ])
 154 ])
 155
 156 AC_MSG_CHECKING([for default auto-load directory])
 157 AC_ARG_WITH(auto-load-dir,
 158 AS_HELP_STRING([--with-auto-load-dir=PATH],
 159   [directories from which to load auto-loaded scripts @<:@$debugdir:$datadir/auto-load@:>@]),,
 160   [with_auto_load_dir='$debugdir:$datadir/auto-load'])
 161 escape_dir=`echo $with_auto_load_dir | sed 's/[[$]]\(datadir\|debugdir\)\>/\\\\\\\\\\\\&/g'`
 162 AC_DEFINE_DIR(AUTO_LOAD_DIR, escape_dir,
 163               [Directories from which to load auto-loaded scripts.])
 164 AC_MSG_RESULT([$with_auto_load_dir])
 165
 166 AC_MSG_CHECKING([for default auto-load safe-path])
 167 AC_ARG_WITH(auto-load-safe-path,
 168 AS_HELP_STRING([--with-auto-load-safe-path=PATH],
 169   [directories safe to hold auto-loaded files @<:@--with-auto-load-dir@:>@])
 170 AS_HELP_STRING([--without-auto-load-safe-path],
 171                [do not restrict auto-loaded files locations]),
 172     [if test "$with_auto_load_safe_path" = "no"; then
 173      with_auto_load_safe_path="/"
 174      fi],
 175 [with_auto_load_safe_path="$with_auto_load_dir"])
 176 escape_dir=`echo $with_auto_load_safe_path | sed 's/[[$]]\(datadir\|debugdir\)\>/\\\\\\\\\\\\&/g'`
 177 AC_DEFINE_DIR(AUTO_LOAD_SAFE_PATH, escape_dir,
 178               [Directories safe to hold auto-loaded files.])
 179 AC_MSG_RESULT([$with_auto_load_safe_path])
 180
 181 AC_CONFIG_SUBDIRS(testsuite)
 182
 183 # Check whether to support alternative target configurations
 184 AC_ARG_ENABLE(targets,
 185 AS_HELP_STRING([--enable-targets=TARGETS], [alternative target configurations]),
 186 [case "${enableval}" in
 187   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
 188             ;;
 189   no)       enable_targets= ;;
 190   *)        enable_targets=$enableval ;;
 191 esac])
 192
 193 # Check whether to enable 64-bit support on 32-bit hosts
 194 AC_ARG_ENABLE(64-bit-bfd,
 195 AS_HELP_STRING([--enable-64-bit-bfd], [64-bit support (on hosts with narrower word sizes)]),
 196 [case "${enableval}" in
 197   yes)  want64=true  ;;
 198   no)   want64=false ;;
 199   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
 200 esac],[want64=false])dnl
 201
 202 # Provide defaults for some variables set by the per-host and per-target
 203 # configuration.
 204 gdb_host_obs=posix-hdep.o
 205
 206 if test "${target}" = "${host}"; then
 207   gdb_native=yes
 208 else
 209   gdb_native=no
 210 fi
 211
 212 . $srcdir/configure.host
 213
 214 # Add in the common host objects.
 215 . $srcdir/common/common.host
 216 gdb_host_obs="$gdb_host_obs $common_host_obs"
 217
 218 # Accumulate some settings from configure.tgt over all enabled targets
 219
 220 TARGET_OBS=
 221 all_targets=
 222 HAVE_NATIVE_GCORE_TARGET=
 223
 224 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 225 do
 226   if test "$targ_alias" = "all"; then
 227     all_targets=true
 228   else
 229     # Canonicalize the secondary target names.
 230     result=`$ac_config_sub $targ_alias 2>/dev/null`
 231     if test -n "$result"; then
 232         targ=$result
 233     else
 234         targ=$targ_alias
 235     fi
 236
 237     . ${srcdir}/configure.tgt
 238
 239     AS_IF([test -z "${gdb_target_obs}"],
 240       [AC_MSG_ERROR([configuration ${targ} is unsupported.])])
 241
 242     # Target-specific object files
 243     for i in ${gdb_target_obs}; do
 244         case " $TARGET_OBS " in
 245         *" ${i} "*) ;;
 246         *)
 247           TARGET_OBS="$TARGET_OBS ${i}"
 248           ;;
 249         esac
 250     done
 251
 252     # Check whether this target needs 64-bit CORE_ADDR
 253     if test x${want64} = xfalse; then
 254       . ${srcdir}/../bfd/config.bfd
 255     fi
 256
 257     # Check whether this target is native and supports gcore.
 258     if test $gdb_native = yes -a "$targ_alias" = "$target_alias" \
 259        && $gdb_have_gcore; then
 260       HAVE_NATIVE_GCORE_TARGET=1
 261     fi
 262   fi
 263 done
 264
 265 if test x${all_targets} = xtrue; then
 266
 267   # We want all 64-bit targets if we either:
 268   #  - run on a 64-bit host  or
 269   #  - already require 64-bit support for some other target  or
 270   #  - the --enable-64-bit-bfd option was supplied
 271   # Otherwise we only support all 32-bit targets.
 272   #
 273   # NOTE: This test must be in sync with the corresponding
 274   #       tests in BFD!
 275
 276   if test x${want64} = xfalse; then
 277     AC_CHECK_SIZEOF(long)
 278     if test "x${ac_cv_sizeof_long}" = "x8"; then
 279       want64=true
 280     fi
 281   fi
 282   if test x${want64} = xtrue; then
 283     TARGET_OBS='$(ALL_TARGET_OBS) $(ALL_64_TARGET_OBS)'
 284   else
 285     TARGET_OBS='$(ALL_TARGET_OBS)'
 286   fi
 287 fi
 288
 289 AC_SUBST(TARGET_OBS)
 290 AC_SUBST(HAVE_NATIVE_GCORE_TARGET)
 291
 292 # For other settings, only the main target counts.
 293 gdb_sim=
 294 gdb_osabi=
 295 build_gdbserver=
 296 targ=$target; . ${srcdir}/configure.tgt
 297
 298 # Fetch the default architecture and default target vector from BFD.
 299 targ=$target; . $srcdir/../bfd/config.bfd
 300
 301 # We only want the first architecture, so strip off the others if
 302 # there is more than one.
 303 targ_archs=`echo $targ_archs | sed 's/ .*//'`
 304
 305 if test "x$targ_archs" != x; then
 306   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
 307     [Define to BFD's default architecture. ])
 308 fi
 309 if test "x$targ_defvec" != x; then
 310   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
 311     [Define to BFD's default target vector. ])
 312 fi
 313
 314 # The CLI cannot be disabled yet, but may be in the future.
 315
 316 # Enable CLI.
 317 AC_ARG_ENABLE(gdbcli,
 318 AS_HELP_STRING([--disable-gdbcli], [disable command-line interface (CLI)]),
 319   [case $enableval in
 320     yes)
 321       ;;
 322     no)
 323       AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;;
 324     *)
 325       AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;;
 326   esac],
 327   [enable_gdbcli=yes])
 328 if test x"$enable_gdbcli" = xyes; then
 329   if test -d $srcdir/cli; then
 330     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)"
 331     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)"
 332     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)"
 333     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)"
 334   fi
 335 fi
 336
 337 # Enable MI.
 338 AC_ARG_ENABLE(gdbmi,
 339 AS_HELP_STRING([--disable-gdbmi], [disable machine-interface (MI)]),
 340   [case $enableval in
 341     yes | no)
 342       ;;
 343     *)
 344       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 345   esac],
 346   [enable_gdbmi=yes])
 347 if test x"$enable_gdbmi" = xyes; then
 348   if test -d $srcdir/mi; then
 349     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 350     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 351     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 352     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 353   fi
 354 fi
 355
 356 # Enable TUI.
 357 AC_ARG_ENABLE(tui,
 358 AS_HELP_STRING([--enable-tui], [enable full-screen terminal user interface (TUI)]),
 359   [case $enableval in
 360     yes | no | auto)
 361       ;;
 362     *)
 363       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 364   esac],enable_tui=auto)
 365
 366 # Enable gdbtk.
 367 AC_ARG_ENABLE(gdbtk,
 368 AS_HELP_STRING([--enable-gdbtk], [enable gdbtk graphical user interface (GUI)]),
 369   [case $enableval in
 370     yes | no)
 371       ;;
 372     *)
 373       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 374   esac],
 375   [if test -d $srcdir/gdbtk; then
 376     enable_gdbtk=yes
 377   else
 378     enable_gdbtk=no
 379   fi])
 380 # We unconditionally disable gdbtk tests on selected platforms.
 381 case $host_os in
 382   go32* | windows*)
 383     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 384     enable_gdbtk=no ;;
 385 esac
 386
 387 # Libunwind support for ia64.
 388
 389 AC_ARG_WITH(libunwind-ia64,
 390 AS_HELP_STRING([--with-libunwind-ia64],
 391                [use libunwind frame unwinding for ia64 targets]),,
 392             [with_libunwind_ia64=auto])
 393
 394 # Backward compatibility option.
 395 if test "${with_libunwind+set}" = set; then
 396   if test x"$with_libunwind_ia64" != xauto; then
 397     AC_MSG_ERROR(
 398       [option --with-libunwind is deprecated, use --with-libunwind-ia64])
 399   fi
 400   AC_MSG_WARN([option --with-libunwind is deprecated, use --with-libunwind-ia64])
 401   with_libunwind_ia64="$with_libunwind"
 402 fi
 403
 404 case "$with_libunwind_ia64" in
 405   yes | no)
 406     ;;
 407   auto)
 408     AC_CHECK_HEADERS(libunwind-ia64.h)
 409     with_libunwind_ia64=$ac_cv_header_libunwind_ia64_h
 410     ;;
 411   *)
 412     AC_MSG_ERROR(
 413       [bad value $with_libunwind_ia64 for GDB --with-libunwind-ia64 option])
 414     ;;
 415 esac
 416
 417 if test x"$with_libunwind_ia64" = xyes; then
 418   AC_CHECK_HEADERS(libunwind-ia64.h)
 419   if test x"$ac_cv_header_libunwind_ia64_h" != xyes; then
 420     AC_MSG_ERROR([GDB option --with-libunwind-ia64 requires libunwind-ia64.h])
 421   fi
 422   CONFIG_OBS="$CONFIG_OBS ia64-libunwind-tdep.o"
 423   CONFIG_DEPS="$CONFIG_DEPS ia64-libunwind-tdep.o"
 424   CONFIG_SRCS="$CONFIG_SRCS ia64-libunwind-tdep.c"
 425 fi
 426
 427 opt_curses=no
 428 AC_ARG_WITH(curses, AS_HELP_STRING([--with-curses], [use the curses library instead of the termcap library]), opt_curses=$withval)
 429
 430 prefer_curses=no
 431 if test "$opt_curses" = "yes"; then
 432   prefer_curses=yes
 433 fi
 434
 435 # Profiling support.
 436 AC_ARG_ENABLE(profiling,
 437 AS_HELP_STRING([--enable-profiling], [enable profiling of GDB]),
 438   [case $enableval in
 439     yes | no)
 440       ;;
 441     *)
 442       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 443   esac],
 444  [enable_profiling=no])
 445
 446 AC_CHECK_FUNCS(monstartup _mcleanup)
 447 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 448 [AC_TRY_LINK(
 449 [#include <stdlib.h>
 450 extern char _etext;
 451 ],
 452 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 453 if test $ac_cv_var__etext = yes; then
 454   AC_DEFINE(HAVE__ETEXT, 1,
 455             [Define to 1 if your system has the _etext variable. ])
 456 fi
 457 AC_CACHE_CHECK([for etext], ac_cv_var_etext,
 458 [AC_TRY_LINK(
 459 [#include <stdlib.h>
 460 extern char etext;
 461 ],
 462 [free (&etext);], ac_cv_var_etext=yes, ac_cv_var_etext=no)])
 463 if test $ac_cv_var_etext = yes; then
 464   AC_DEFINE(HAVE_ETEXT, 1,
 465             [Define to 1 if your system has the etext variable. ])
 466 fi
 467 if test "$enable_profiling" = yes ; then
 468   if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
 469     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 470   fi
 471   PROFILE_CFLAGS=-pg
 472   OLD_CFLAGS="$CFLAGS"
 473   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 474
 475   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 476     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 477      ac_cv_cc_supports_pg=no)])
 478
 479   if test $ac_cv_cc_supports_pg = no; then
 480     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 481   fi
 482
 483   CFLAGS="$OLD_CFLAGS"
 484 fi
 485
 486 ACX_PKGVERSION([GDB])
 487 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 488 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 489 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 490
 491 # --------------------- #
 492 # Checks for programs.  #
 493 # --------------------- #
 494
 495 AC_PROG_AWK
 496 AC_PROG_INSTALL
 497 AC_PROG_LN_S
 498 AC_PROG_RANLIB
 499 AC_PROG_YACC
 500
 501 AC_CHECK_TOOL(AR, ar)
 502 AC_CHECK_TOOL(DLLTOOL, dlltool)
 503 AC_CHECK_TOOL(WINDRES, windres)
 504
 505 case $host_os in
 506   gnu*)
 507     # Needed for GNU Hurd hosts.
 508     AC_CHECK_TOOL(MIG, mig)
 509     if test x"$MIG" = x; then
 510       AC_MSG_ERROR([MIG not found but required for $host hosts])
 511     fi
 512     ;;
 513 esac
 514
 515 # ---------------------- #
 516 # Checks for libraries.  #
 517 # ---------------------- #
 518
 519 # We might need to link with -lm; most simulators need it.
 520 AC_CHECK_LIB(m, main)
 521
 522 # We need to link with -lw to get `wctype' on Solaris before Solaris
 523 # 2.6.  Solaris 2.6 and beyond have this function in libc, and have a
 524 # libw that some versions of the GNU linker cannot hanle (GNU ld 2.9.1
 525 # is known to have this problem).  Therefore we avoid libw if we can.
 526 AC_CHECK_FUNC(wctype, [],
 527   [AC_CHECK_LIB(w, wctype)])
 528
 529 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 530 AC_SEARCH_LIBS(gethostbyname, nsl)
 531
 532 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 533 AC_SEARCH_LIBS(socketpair, socket)
 534
 535 # Link in zlib if we can.  This allows us to read compressed debug sections.
 536 AM_ZLIB
 537
 538 # On FreeBSD we may need libutil for kinfo_getvmmap (used by fbsd-nat.c).
 539 # On GNU/kFreeBSD systems, FreeBSD libutil is renamed to libutil-freebsd.
 540 AC_SEARCH_LIBS(kinfo_getvmmap, util util-freebsd,
 541   [AC_DEFINE(HAVE_KINFO_GETVMMAP, 1,
 542             [Define to 1 if your system has the kinfo_getvmmap function. ])])
 543
 544 AM_ICONV
 545
 546 # GDB may fork/exec the iconv program to get the list of supported character
 547 # sets.  Allow the user to specify where to find it.
 548 # There are several factors affecting the choice of option name:
 549 # - There is already --with-libiconv-prefix but we can't use it, it specifies
 550 #   the build-time location of libiconv files.
 551 # - The program we need to find is iconv, which comes with glibc.  The user
 552 #   doesn't necessarily have libiconv installed.  Therefore naming this
 553 #   --with-libiconv-foo feels wrong.
 554 # - We want the path to be relocatable, but GDB_AC_DEFINE_RELOCATABLE is
 555 #   defined to work on directories not files (though it really doesn't know
 556 #   the difference).
 557 # - Calling this --with-iconv-prefix is perceived to cause too much confusion
 558 #   with --with-libiconv-prefix.
 559 # Putting these together is why the option name is --with-iconv-bin.
 560
 561 AC_ARG_WITH(iconv-bin,
 562 AS_HELP_STRING([--with-iconv-bin=PATH], [specify where to find the iconv program]),
 563 [iconv_bin="${withval}"
 564  AC_DEFINE_UNQUOTED([ICONV_BIN], ["${iconv_bin}"],
 565                     [Path of directory of iconv program.])
 566  GDB_AC_DEFINE_RELOCATABLE(ICONV_BIN, iconv, ${iconv_bin})
 567 ])
 568
 569 # For the TUI, we need enhanced curses functionality.
 570 if test x"$enable_tui" != xno; then
 571   prefer_curses=yes
 572 fi
 573
 574 curses_found=no
 575 if test x"$prefer_curses" = xyes; then
 576   # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
 577   # curses library because the latter might not provide all the
 578   # functionality we need.  However, this leads to problems on systems
 579   # where the linker searches /usr/local/lib, but the compiler doesn't
 580   # search /usr/local/include, if ncurses is installed in /usr/local.  A
 581   # default installation of ncurses on alpha*-dec-osf* will lead to such
 582   # a situation.
 583   AC_SEARCH_LIBS(waddstr, [ncurses cursesX curses])
 584
 585   if test "$ac_cv_search_waddstr" != no; then
 586     curses_found=yes
 587   fi
 588 fi
 589
 590 # Check whether we should enable the TUI, but only do so if we really
 591 # can.
 592 if test x"$enable_tui" != xno; then
 593   if test -d $srcdir/tui; then
 594     if test "$curses_found" != no; then
 595       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
 596       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
 597       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
 598       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
 599     else
 600       if test x"$enable_tui" = xyes; then
 601         AC_MSG_ERROR([no enhanced curses library found; disable TUI])
 602       else
 603         AC_MSG_WARN([no enhanced curses library found; disabling TUI])
 604       fi
 605     fi
 606   fi
 607 fi
 608
 609 # Since GDB uses Readline, we need termcap functionality.  In many
 610 # cases this will be provided by the curses library, but some systems
 611 # have a seperate termcap library, or no curses library at all.
 612
 613 case $host_os in
 614   cygwin*)
 615     if test -d $srcdir/libtermcap; then
 616       LIBS="../libtermcap/libtermcap.a $LIBS"
 617       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 618     fi ;;
 619   go32* | *djgpp*)
 620     ac_cv_search_tgetent="none required"
 621     ;;
 622 esac
 623
 624 # These are the libraries checked by Readline.
 625 AC_SEARCH_LIBS(tgetent, [termcap tinfo curses ncurses])
 626
 627 if test "$ac_cv_search_tgetent" = no; then
 628   CONFIG_OBS="$CONFIG_OBS stub-termcap.o"
 629 fi
 630
 631 AC_ARG_WITH([system-readline],
 632   [AS_HELP_STRING([--with-system-readline],
 633                   [use installed readline library])])
 634
 635 if test "$with_system_readline" = yes; then
 636   READLINE=-lreadline
 637   READLINE_DEPS=
 638   READLINE_CFLAGS=
 639   READLINE_TEXI_INCFLAG=
 640 else
 641   READLINE='$(READLINE_DIR)/libreadline.a'
 642   READLINE_DEPS='$(READLINE)'
 643   READLINE_CFLAGS='-I$(READLINE_SRC)/..'
 644   READLINE_TEXI_INCFLAG='-I $(READLINE_DIR)'
 645 fi
 646 AC_SUBST(READLINE)
 647 AC_SUBST(READLINE_DEPS)
 648 AC_SUBST(READLINE_CFLAGS)
 649 AC_SUBST(READLINE_TEXI_INCFLAG)
 650
 651 # Generate jit-reader.h
 652
 653 # This is typedeffed to GDB_CORE_ADDR in jit-reader.h
 654 TARGET_PTR=
 655
 656 AC_CHECK_SIZEOF(unsigned long long)
 657 AC_CHECK_SIZEOF(unsigned long)
 658 AC_CHECK_SIZEOF(unsigned __int128)
 659
 660 if test "x${ac_cv_sizeof_unsigned_long}" = "x8"; then
 661   TARGET_PTR="unsigned long"
 662 elif test "x${ac_cv_sizeof_unsigned_long_long}" = "x8"; then
 663   TARGET_PTR="unsigned long long"
 664 elif test "x${ac_cv_sizeof_unsigned___int128}" = "x16"; then
 665   TARGET_PTR="unsigned __int128"
 666 else
 667   TARGET_PTR="unsigned long"
 668 fi
 669
 670 AC_SUBST(TARGET_PTR)
 671 AC_CONFIG_FILES([jit-reader.h:jit-reader.in])
 672
 673 AC_SEARCH_LIBS(dlopen, dl)
 674
 675 GDB_AC_WITH_DIR([JIT_READER_DIR], [jit-reader-dir],
 676                 [directory to load the JIT readers from],
 677                 [${libdir}/gdb])
 678
 679 AC_ARG_WITH(expat,
 680   AS_HELP_STRING([--with-expat], [include expat support (auto/yes/no)]),
 681   [], [with_expat=auto])
 682 AC_MSG_CHECKING([whether to use expat])
 683 AC_MSG_RESULT([$with_expat])
 684
 685 if test "${with_expat}" = no; then
 686   AC_MSG_WARN([expat support disabled; some features may be unavailable.])
 687   HAVE_LIBEXPAT=no
 688 else
 689   AC_LIB_HAVE_LINKFLAGS([expat], [], [#include "expat.h"],
 690                         [XML_Parser p = XML_ParserCreate (0);])
 691   if test "$HAVE_LIBEXPAT" != yes; then
 692     if test "$with_expat" = yes; then
 693       AC_MSG_ERROR([expat is missing or unusable])
 694     else
 695       AC_MSG_WARN([expat is missing or unusable; some features may be unavailable.])
 696     fi
 697   else
 698     save_LIBS=$LIBS
 699     LIBS="$LIBS $LIBEXPAT"
 700     AC_CHECK_FUNCS(XML_StopParser)
 701     LIBS=$save_LIBS
 702   fi
 703 fi
 704
 705 # --------------------- #
 706 # Check for libpython.  #
 707 # --------------------- #
 708
 709 dnl Utility to simplify finding libpython.
 710 dnl $1 = pythonX.Y
 711 dnl $2 = the shell variable to assign the result to
 712 dnl      If libpython is found we store $version here.
 713 dnl $3 = additional flags to add to CPPFLAGS
 714 dnl $4 = additional flags to add to LIBS
 715
 716 AC_DEFUN([AC_TRY_LIBPYTHON],
 717 [
 718   version=$1
 719   define([have_libpython_var],$2)
 720   new_CPPFLAGS=$3
 721   new_LIBS=$4
 722   AC_MSG_CHECKING([for ${version}])
 723   save_CPPFLAGS=$CPPFLAGS
 724   save_LIBS=$LIBS
 725   CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
 726   LIBS="$LIBS $new_LIBS"
 727   found_usable_python=no
 728   AC_LINK_IFELSE(AC_LANG_PROGRAM([[#include "Python.h"]],
 729                                  [[Py_Initialize ();]]),
 730                  [have_libpython_var=${version}
 731                   found_usable_python=yes
 732                   PYTHON_CPPFLAGS=$new_CPPFLAGS
 733                   PYTHON_LIBS=$new_LIBS])
 734   CPPFLAGS=$save_CPPFLAGS
 735   LIBS=$save_LIBS
 736   AC_MSG_RESULT([${found_usable_python}])
 737 ])
 738
 739 dnl There are several different values for --with-python:
 740 dnl
 741 dnl no -   Don't include python support.
 742 dnl yes -  Include python support, error if it's missing.
 743 dnl        If we find python in $PATH, use it to fetch configure options,
 744 dnl        otherwise assume the compiler can find it with no help from us.
 745 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 746 dnl auto - Same as "yes", but if python is missing from the system,
 747 dnl        fall back to "no".
 748 dnl /path/to/python/exec-prefix -
 749 dnl        Use the python located in this directory.
 750 dnl        If /path/to/python/exec-prefix/bin/python exists, use it to find
 751 dnl        the compilation parameters.  Otherwise use
 752 dnl        -I/path/to/python/exec-prefix/include,
 753 dnl        -L/path/to/python/exec-prefix/lib.
 754 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 755 dnl        NOTE: This case is historical.  It is what was done for 7.0/7.1
 756 dnl        but is deprecated.
 757 dnl /path/to/python/executable -
 758 dnl        Run python-config.py with this version of python to fetch the
 759 dnl        compilation parameters.
 760 dnl        NOTE: This needn't be the real python executable.
 761 dnl        In a cross-compilation scenario (build != host), this could be
 762 dnl        a shell script that provides what python-config.py provides for
 763 dnl        --ldflags, --includes, --exec-prefix.
 764 dnl python-executable -
 765 dnl        Find python-executable in $PATH, and then handle the same as
 766 dnl        /path/to/python/executable.
 767 dnl
 768 dnl If a python program is specified, it is used to run python-config.py and
 769 dnl is passed --ldflags, --includes, --exec-prefix.
 770
 771 AC_ARG_WITH(python,
 772   AS_HELP_STRING([--with-python@<:@=PYTHON@:>@], [include python support (auto/yes/no/<python-program>)]),
 773   [], [with_python=auto])
 774 AC_MSG_CHECKING([whether to use python])
 775 AC_MSG_RESULT([$with_python])
 776
 777 if test "${with_python}" = no; then
 778   AC_MSG_WARN([python support disabled; some features may be unavailable.])
 779   have_libpython=no
 780 else
 781   case "${with_python}" in
 782   [[\\/]]* | ?:[[\\/]]*)
 783     if test -d ${with_python}; then
 784       # Assume the python binary is ${with_python}/bin/python.
 785       python_prog="${with_python}/bin/python"
 786       python_prefix=
 787       # If python does not exit ${with_python}/bin, then try in
 788       # ${with_python}.  On Windows/MinGW, this is where the Python
 789       # executable is.
 790       if test ! -x "${python_prog}"; then
 791         python_prog="${with_python}/python"
 792         python_prefix=
 793       fi
 794       if test ! -x "${python_prog}"; then
 795         # Fall back to gdb 7.0/7.1 behaviour.
 796         python_prog=missing
 797         python_prefix=${with_python}
 798       fi
 799     elif test -x "${with_python}"; then
 800       # While we can't run python compiled for $host (unless host == build),
 801       # the user could write a script that provides the needed information,
 802       # so we support that.
 803       python_prog=${with_python}
 804       python_prefix=
 805     else
 806       AC_ERROR(invalid value for --with-python)
 807     fi
 808     ;;
 809   */*)
 810     # Disallow --with-python=foo/bar.
 811     AC_ERROR(invalid value for --with-python)
 812     ;;
 813   *)
 814     # The user has either specified auto, yes, or the name of the python
 815     # program assumed to be in $PATH.
 816     python_prefix=
 817     case "${with_python}" in
 818     yes | auto)
 819       if test ${build} = ${host}; then
 820         AC_PATH_PROG(python_prog_path, python, missing)
 821         if test "${python_prog_path}" = missing; then
 822           python_prog=missing
 823         else
 824           python_prog=${python_prog_path}
 825         fi
 826       else
 827         # Not much we can do except assume the cross-compiler will find the
 828         # right files.
 829         python_prog=missing
 830       fi
 831       ;;
 832     *)
 833       # While we can't run python compiled for $host (unless host == build),
 834       # the user could write a script that provides the needed information,
 835       # so we support that.
 836       python_prog="${with_python}"
 837       AC_PATH_PROG(python_prog_path, ${python_prog}, missing)
 838       if test "${python_prog_path}" = missing; then
 839         AC_ERROR(unable to find python program ${python_prog})
 840       fi
 841       ;;
 842     esac
 843   esac
 844
 845   if test "${python_prog}" != missing; then
 846     # We have a python program to use, but it may be too old.
 847     # Don't flag an error for --with-python=auto (the default).
 848     have_python_config=yes
 849     python_includes=`${python_prog} ${srcdir}/python/python-config.py --includes`
 850     if test $? != 0; then
 851       have_python_config=failed
 852       if test "${with_python}" != auto; then
 853         AC_ERROR(failure running python-config --includes)
 854       fi
 855     fi
 856     python_libs=`${python_prog} ${srcdir}/python/python-config.py --ldflags`
 857     if test $? != 0; then
 858       have_python_config=failed
 859       if test "${with_python}" != auto; then
 860         AC_ERROR(failure running python-config --ldflags)
 861       fi
 862     fi
 863     python_prefix=`${python_prog} ${srcdir}/python/python-config.py --exec-prefix`
 864     if test $? != 0; then
 865       have_python_config=failed
 866       if test "${with_python}" != auto; then
 867         AC_ERROR(failure running python-config --exec-prefix)
 868       fi
 869     fi
 870   else
 871     # We do not have a python executable we can use to determine where
 872     # to find the Python headers and libs.  We cannot guess the include
 873     # path from the python_prefix either, because that include path
 874     # depends on the Python version.  So, there is nothing much we can
 875     # do except assume that the compiler will be able to find those files.
 876     python_includes=
 877     python_libs=
 878     have_python_config=no
 879   fi
 880
 881   # If we have python-config, only try the configuration it provides.
 882   # Otherwise fallback on the old way of trying different versions of
 883   # python in turn.
 884
 885   have_libpython=no
 886   if test "${have_python_config}" = yes; then
 887     # Determine the Python version by extracting "-lpython<version>"
 888     # part of the python_libs. <version> is usually X.Y with X and Y
 889     # being decimal numbers, but can also be XY (seen on Windows).
 890     #
 891     # The extraction is performed using sed with a regular expression.
 892     # Initially, the regexp used was using the '?' quantifier to make
 893     # the dot in the version number optional.  Unfortunately, this
 894     # does not work with non-GNU versions of sed because, because of
 895     # what looks like a limitation (the '?' quantifier does not work
 896     # with back-references).  We work around this limitation by using
 897     # the '*' quantifier instead.  It means that, in theory, we might
 898     # match unexpected version strings such as "-lpython2..7", but
 899     # this seems unlikely in practice.  And even if that happens,
 900     # an error will be triggered later on, when checking that version
 901     # number.
 902     python_version=`echo " ${python_libs} " \
 903                          | sed -e 's,^.* -l\(python[[0-9]]*[[.]]*[[0-9]]*\).*$,\1,'`
 904     case "${python_version}" in
 905     python*)
 906       AC_TRY_LIBPYTHON(${python_version}, have_libpython,
 907                        ${python_includes}, ${python_libs})
 908       ;;
 909     *)
 910       AC_MSG_ERROR([unable to determine python version from ${python_libs}])
 911       ;;
 912     esac
 913   elif test "${have_python_config}" != failed; then
 914     if test "${have_libpython}" = no; then
 915       AC_TRY_LIBPYTHON(python2.7, have_libpython,
 916                        ${python_includes}, "${python_libs} -lpython2.7")
 917     fi
 918     if test "${have_libpython}" = no; then
 919       AC_TRY_LIBPYTHON(python2.6, have_libpython,
 920                        ${python_includes}, "${python_libs} -lpython2.6")
 921     fi
 922     if test ${have_libpython} = no; then
 923       AC_TRY_LIBPYTHON(python2.5, have_libpython,
 924                        ${python_includes}, "${python_libs} -lpython2.5")
 925     fi
 926     if test ${have_libpython} = no; then
 927       AC_TRY_LIBPYTHON(python2.4, have_libpython,
 928                        ${python_includes}, "${python_libs} -lpython2.4")
 929     fi
 930   fi
 931   if test "${have_libpython}" = python2.7 -o "${have_libpython}" = python27; then
 932     AC_DEFINE(HAVE_LIBPYTHON2_7, 1, [Define if Python 2.7 is being used.])
 933   elif test "${have_libpython}" = python2.6 -o "${have_libpython}" = python26; then
 934     AC_DEFINE(HAVE_LIBPYTHON2_6, 1, [Define if Python 2.6 is being used.])
 935   elif test "${have_libpython}" = python2.5 -o "${have_libpython}" = python25; then
 936     AC_DEFINE(HAVE_LIBPYTHON2_5, 1, [Define if Python 2.5 is being used.])
 937   elif test "${have_libpython}" = python2.4 -o "${have_libpython}" = python24; then
 938     AC_DEFINE(HAVE_LIBPYTHON2_4, 1, [Define if Python 2.4 is being used.])
 939   fi
 940
 941   if test "${have_libpython}" = no; then
 942     case "${with_python}" in
 943     yes)
 944       AC_MSG_ERROR([python is missing or unusable])
 945       ;;
 946     auto)
 947       AC_MSG_WARN([python is missing or unusable; some features may be unavailable.])
 948       ;;
 949     *)
 950       AC_MSG_ERROR([no usable python found at ${with_python}])
 951       ;;
 952     esac
 953   else
 954     if test -n "${python_prefix}"; then
 955       AC_DEFINE_UNQUOTED(WITH_PYTHON_PATH, "${python_prefix}",
 956                          [Define if --with-python provides a path, either directly or via python-config.py --exec-prefix.])
 957       GDB_AC_DEFINE_RELOCATABLE(PYTHON_PATH, python, ${python_prefix})
 958     fi
 959   fi
 960 fi
 961
 962 if test "${have_libpython}" != no; then
 963   AC_DEFINE(HAVE_PYTHON, 1, [Define if Python interpreter is being linked in.])
 964   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_PYTHON_OBS)"
 965   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_PYTHON_DEPS)"
 966   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_PYTHON_SRCS)"
 967   CONFIG_INSTALL="$CONFIG_INSTALL install-python"
 968   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_PYTHON_CFLAGS)"
 969
 970   # Flags needed to compile Python code (taken from python-config --cflags).
 971   # We cannot call python-config directly because it will output whatever was
 972   # used when compiling the Python interpreter itself, including flags which
 973   # would make the python-related objects be compiled differently from the
 974   # rest of GDB (e.g., -O2 and -fPIC).
 975   if test "${GCC}" = yes; then
 976     tentative_python_cflags="-fno-strict-aliasing -DNDEBUG -fwrapv"
 977   fi
 978
 979   if test "x${tentative_python_cflags}" != x; then
 980     AC_MSG_CHECKING(compiler flags for python code)
 981     for flag in ${tentative_python_cflags}; do
 982       # Check that the compiler accepts it
 983       saved_CFLAGS="$CFLAGS"
 984       CFLAGS="$CFLAGS $flag"
 985       AC_TRY_COMPILE([],[],PYTHON_CFLAGS="${PYTHON_CFLAGS} $flag",)
 986       CFLAGS="$saved_CFLAGS"
 987     done
 988     AC_MSG_RESULT(${PYTHON_CFLAGS})
 989   fi
 990
 991   # On x64 Windows, Python's include headers, and pyconfig.h in
 992   # particular, rely on MS_WIN64 macro to detect that it's a 64bit
 993   # version of Windows.  Unfortunately, MS_WIN64 is only defined if
 994   # _MSC_VER, a Microsoft-specific macro, is defined.  So, when
 995   # building on x64 Windows with GCC, we define MS_WIN64 ourselves.
 996   # The issue was reported to the Python community, but still isn't
 997   # solved as of 2012-10-02 (http://bugs.python.org/issue4709).
 998
 999   case "$gdb_host" in
1000     mingw64)
1001            if test "${GCC}" = yes; then
1002              CPPFLAGS="$CPPFLAGS -DMS_WIN64"
1003            fi
1004            ;;
1005   esac
1006
1007   # Note that "python -m threading" cannot be used to check for
1008   # threading support due to a bug in Python 2.7.3
1009   # (http://bugs.python.org/issue15567).
1010   AC_MSG_CHECKING(whether python supports threads)
1011   saved_CPPFLAGS="${CPPFLAGS}"
1012   CPPFLAGS="${PYTHON_CPPFLAGS}"
1013   # Note that the test is reversed so that python_has_threads=yes on
1014   # unexpected failures.
1015   AC_PREPROC_IFELSE(AC_LANG_SOURCE([[
1016 #include <Python.h>
1017 #ifdef WITH_THREAD
1018 # error
1019 #endif
1020   ]]), [python_has_threads=no], [python_has_threads=yes])
1021   AC_MSG_RESULT(${python_has_threads})
1022   CPPFLAGS="${saved_CPPFLAGS}"
1023 else
1024   # Even if Python support is not compiled in, we need to have this file
1025   # included so that the "python" command, et.al., still exists.
1026   CONFIG_OBS="$CONFIG_OBS python.o"
1027   CONFIG_SRCS="$CONFIG_SRCS python/python.c"
1028 fi
1029
1030 # Work around Python http://bugs.python.org/issue10112.  See also
1031 # http://bugs.python.org/issue11410, otherwise -Wl,--dynamic-list has
1032 # no effect.  Note that the only test after this that uses Python is
1033 # the -rdynamic/-Wl,--dynamic-list test, and we do want that one to be
1034 # run without -export-dynamic too.
1035 PYTHON_LIBS=`echo $PYTHON_LIBS | sed -e 's/-Xlinker -export-dynamic//'`
1036
1037 AC_SUBST(PYTHON_CFLAGS)
1038 AC_SUBST(PYTHON_CPPFLAGS)
1039 AC_SUBST(PYTHON_LIBS)
1040 AM_CONDITIONAL(HAVE_PYTHON, test "${have_libpython}" != no)
1041
1042 # -------------------- #
1043 # Check for libguile.  #
1044 # -------------------- #
1045
1046 dnl Utility to simplify finding libguile.
1047 dnl $1 = pkg-config-program
1048 dnl $2 = space-separate list of guile versions to try
1049 dnl $3 = yes|no, indicating whether to flag errors or ignore them
1050 dnl $4 = the shell variable to assign the result to
1051 dnl      If libguile is found we store "yes" here.
1052
1053 AC_DEFUN([AC_TRY_LIBGUILE],
1054 [
1055   pkg_config=$1
1056   guile_version_list=$2
1057   flag_errors=$3
1058   define([have_libguile_var],$4)
1059   found_usable_guile=checking
1060   AC_MSG_CHECKING([for usable guile from ${pkg_config}])
1061   for guile_version in ${guile_version_list}; do
1062     ${pkg_config} --exists ${guile_version} 2>/dev/null
1063     if test $? != 0; then
1064       continue
1065     fi
1066     dnl pkg-config says the package exists, so if we get an error now,
1067     dnl that's bad.
1068     new_CPPFLAGS=`${pkg_config} --cflags ${guile_version}`
1069     if test $? != 0; then
1070       AC_MSG_ERROR([failure running pkg-config --cflags ${guile_version}])
1071     fi
1072     new_LIBS=`${pkg_config} --libs ${guile_version}`
1073     if test $? != 0; then
1074       AC_MSG_ERROR([failure running pkg-config --libs ${guile_version}])
1075     fi
1076     dnl If we get this far, great.
1077     found_usable_guile=${guile_version}
1078     break
1079   done
1080   if test "${found_usable_guile}" = "checking"; then
1081     if test "${flag_errors}" = "yes"; then
1082       AC_MSG_ERROR([unable to find usable guile version from "${guile_version_list}"])
1083     else
1084       found_usable_guile=no
1085     fi
1086   fi
1087   dnl One final sanity check.
1088   dnl The user could have said --with-guile=python-2.7.
1089   if test "${found_usable_guile}" != no; then
1090     save_CPPFLAGS=$CPPFLAGS
1091     save_LIBS=$LIBS
1092     CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
1093     LIBS="$LIBS $new_LIBS"
1094     AC_LINK_IFELSE(AC_LANG_PROGRAM([[#include "libguile.h"]],
1095                                    [[scm_init_guile ();]]),
1096                    [have_libguile_var=yes
1097                     GUILE_CPPFLAGS=$new_CPPFLAGS
1098                     GUILE_LIBS=$new_LIBS],
1099                    [found_usable_guile=no])
1100     dnl scm_set_automatic_finalization_enabled added in Guile 2.2.
1101     AC_CHECK_FUNC(scm_set_automatic_finalization_enabled,
1102       AC_DEFINE(HAVE_GUILE_MANUAL_FINALIZATION, 1,
1103                 [Define if Guile supports manual finalization.])
1104     )
1105     CPPFLAGS=$save_CPPFLAGS
1106     LIBS=$save_LIBS
1107     if test "${found_usable_guile}" = no; then
1108       if test "${flag_errors}" = yes; then
1109         AC_MSG_FAILURE([linking guile version ${guile_version} test program failed])
1110       fi
1111     fi
1112   fi
1113   AC_MSG_RESULT([${found_usable_guile}])
1114 ])
1115
1116 dnl There are several different values for --with-guile:
1117 dnl
1118 dnl no -   Don't include guile support.
1119 dnl yes -  Include guile support, error if it's missing.
1120 dnl        The pkg-config program must be in $PATH.
1121 dnl auto - Same as "yes", but if guile is missing from the system,
1122 dnl        fall back to "no".
1123 dnl guile-version [guile-version-choice-2 ...] -
1124 dnl        A space-separated list of guile package versions to try.
1125 dnl        These are passed to pkg-config as-is.
1126 dnl        E.g., guile-2.0 or guile-2.2-uninstalled
1127 dnl        This requires making sure PKG_CONFIG_PATH is set appropriately.
1128 dnl /path/to/pkg-config -
1129 dnl        Use this pkg-config program.
1130 dnl        NOTE: This needn't be the "real" pkg-config program.
1131 dnl        It could be a shell script.  It is invoked as:
1132 dnl        pkg-config --exists $version
1133 dnl        pkg-config --cflags $version
1134 dnl        pkg-config --libs $version
1135 dnl        pkg-config --variable guild $version
1136 dnl        The script will be called with $version having each value in
1137 dnl        $try_guile_versions until --exists indicates success.
1138
1139 AC_ARG_WITH(guile,
1140   AS_HELP_STRING([--with-guile@<:@=GUILE@:>@], [include guile support (auto/yes/no/<guile-version>/<pkg-config-program>)]),
1141   [], [with_guile=auto])
1142 AC_MSG_CHECKING([whether to use guile])
1143 AC_MSG_RESULT([$with_guile])
1144
1145 dnl We check guile with pkg-config.
1146 AC_PATH_PROG(pkg_config_prog_path, pkg-config, missing)
1147
1148 try_guile_versions="guile-2.2 guile-2.0"
1149 have_libguile=no
1150 case "${with_guile}" in
1151 no)
1152   AC_MSG_WARN([guile support disabled; some features will be unavailable.])
1153   ;;
1154 auto)
1155   if test "${pkg_config_prog_path}" = "missing"; then
1156     AC_MSG_WARN([pkg-config not found, guile support disabled])
1157   else
1158     AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${try_guile_versions}, no, have_libguile)
1159   fi
1160   ;;
1161 yes)
1162   if test "${pkg_config_prog_path}" = "missing"; then
1163     AC_MSG_ERROR([pkg-config not found])
1164   fi
1165   AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${try_guile_versions}, yes, have_libguile)
1166   ;;
1167 [[\\/]]* | ?:[[\\/]]*)
1168   if test -x "${with_guile}"; then
1169     AC_TRY_LIBGUILE(${with_guile}, ${try_guile_versions}, yes, have_libguile)
1170   else
1171     AC_MSG_ERROR([Guile config program not executable: ${with_guile}])
1172   fi
1173   ;;
1174 "" | */*)
1175   # Disallow --with=guile="" and --with-guile=foo/bar.
1176   AC_MSG_ERROR([invalid value for --with-guile])
1177   ;;
1178 *)
1179   # A space separate list of guile versions to try, in order.
1180   if test "${pkg_config_prog_path}" = "missing"; then
1181     AC_MSG_ERROR([pkg-config not found])
1182   fi
1183   AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${with_guile}, yes, have_libguile)
1184   ;;
1185 esac
1186
1187 if test "${have_libguile}" != no; then
1188   dnl Get the name of the 'guild' program.
1189   case "${with_guile}" in
1190   [[\\/]]* | ?:[[\\/]]*)
1191     GDB_GUILE_PROGRAM_NAMES(["${with_guile}"], ["${guile_version}"])
1192     ;;
1193   *)
1194     GDB_GUILE_PROGRAM_NAMES(["${pkg_config_prog_path}"], ["${guile_version}"])
1195     ;;
1196   esac
1197
1198   dnl Make sure guild can handle this host.
1199   GDB_TRY_GUILD([$srcdir/guile/lib/gdb/support.scm])
1200   dnl If not, disable guile support.
1201   if test "$ac_cv_guild_ok" = no; then
1202     have_libguile=no
1203     AC_MSG_WARN(disabling guile support, $GUILD fails compiling for $host)
1204   fi
1205 fi
1206
1207 if test "${have_libguile}" != no; then
1208   AC_DEFINE(HAVE_GUILE, 1, [Define if Guile interpreter is being linked in.])
1209   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_GUILE_OBS)"
1210   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_GUILE_DEPS)"
1211   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_GUILE_SRCS)"
1212   CONFIG_INSTALL="$CONFIG_INSTALL install-guile"
1213   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_GUILE_CFLAGS)"
1214
1215   dnl The 'scm_new_smob' function appeared in Guile 2.0.6.
1216   save_LIBS="$LIBS"
1217   save_CPPFLAGS="$CPPFLAGS"
1218   LIBS="$GUILE_LIBS"
1219   CPPFLAGS="$GUILE_CPPFLAGS"
1220   AC_CHECK_FUNCS([scm_new_smob])
1221   LIBS="$save_LIBS"
1222   CPPFLAGS="$save_CPPFLAGS"
1223 else
1224   # Even if Guile support is not compiled in, we need to have these files
1225   # included.
1226   CONFIG_OBS="$CONFIG_OBS guile.o"
1227   CONFIG_SRCS="$CONFIG_SRCS guile/guile.c"
1228 fi
1229 AC_SUBST(GUILE_CPPFLAGS)
1230 AC_SUBST(GUILE_LIBS)
1231 AM_CONDITIONAL(HAVE_GUILE, test "${have_libguile}" != no)
1232
1233 # --------------------- #
1234 # Check for libmcheck.  #
1235 # --------------------- #
1236
1237 # Enable -lmcheck by default (it provides cheap-enough memory mangling),
1238 # but turn it off if Python is enabled with threads, since -lmcheck is
1239 # not thread safe (http://sourceware.org/bugzilla/show_bug.cgi?id=9939),
1240 # and for releases.
1241 if test \( "${have_libpython}" = "no" -o "${python_has_threads}" = "no" \) \
1242    && $development; then
1243   libmcheck_default=yes
1244 else
1245   libmcheck_default=no
1246 fi
1247 GDB_AC_LIBMCHECK(${libmcheck_default})
1248
1249 if test "$ENABLE_LIBMCHECK" = "yes" \
1250         -a "${have_libpython}" != "no" \
1251         -a "${python_has_threads}" = "yes" ; then
1252   AC_MSG_WARN(--enable-libmcheck may lead to spurious crashes if threads are used in python)
1253 fi
1254
1255 AC_ARG_WITH(intel_pt,
1256   AS_HELP_STRING([--with-intel-pt], [include Intel Processor Trace support (auto/yes/no)]),
1257   [], [with_intel_pt=auto])
1258 AC_MSG_CHECKING([whether to use intel pt])
1259 AC_MSG_RESULT([$with_intel_pt])
1260
1261 if test "${with_intel_pt}" = no; then
1262   AC_MSG_WARN([Intel Processor Trace support disabled; some features may be unavailable.])
1263   HAVE_LIBIPT=no
1264 else
1265   AC_PREPROC_IFELSE(AC_LANG_SOURCE([[
1266 #include <linux/perf_event.h>
1267 #ifndef PERF_ATTR_SIZE_VER5
1268 # error
1269 #endif
1270   ]]), [perf_event=yes], [perf_event=no])
1271   if test "$perf_event" != yes; then
1272     if test "$with_intel_pt" = yes; then
1273       AC_MSG_ERROR([linux/perf_event.h missing or too old])
1274     else
1275       AC_MSG_WARN([linux/perf_event.h missing or too old; some features may be unavailable.])
1276     fi
1277   fi
1278
1279   AC_LIB_HAVE_LINKFLAGS([ipt], [], [#include "intel-pt.h"], [pt_insn_alloc_decoder (0);])
1280   if test "$HAVE_LIBIPT" != yes; then
1281     if test "$with_intel_pt" = yes; then
1282       AC_MSG_ERROR([libipt is missing or unusable])
1283     else
1284       AC_MSG_WARN([libipt is missing or unusable; some features may be unavailable.])
1285     fi
1286   fi
1287 fi
1288
1289 # ------------------------- #
1290 # Checks for header files.  #
1291 # ------------------------- #
1292
1293 AC_HEADER_STDC
1294 # elf_hp.h is for HP/UX 64-bit shared library support.
1295 AC_CHECK_HEADERS([nlist.h machine/reg.h poll.h sys/poll.h proc_service.h \
1296                   thread_db.h \
1297                   sys/fault.h \
1298                   sys/file.h sys/filio.h sys/ioctl.h sys/param.h \
1299                   sys/resource.h sys/procfs.h sys/ptrace.h ptrace.h \
1300                   sys/reg.h sys/debugreg.h sys/select.h sys/syscall.h \
1301                   termios.h termio.h \
1302                   sgtty.h elf_hp.h \
1303                   dlfcn.h])
1304 AC_CHECK_HEADERS(sys/proc.h, [], [],
1305 [#if HAVE_SYS_PARAM_H
1306 # include <sys/param.h>
1307 #endif
1308 ])
1309 AC_CHECK_HEADERS(sys/user.h, [], [],
1310 [#if HAVE_SYS_PARAM_H
1311 # include <sys/param.h>
1312 #endif
1313 ])
1314
1315 # On Solaris 2.[789], we need to define _MSE_INT_H to avoid a clash
1316 # between <widec.h> and <wchar.h> that would cause AC_CHECK_HEADERS to
1317 # think that we don't have <curses.h> if we're using GCC.
1318 case $host_os in
1319   solaris2.[[789]])
1320     if test "$GCC" = yes; then
1321       AC_DEFINE(_MSE_INT_H, 1,
1322         [Define to 1 to avoid a clash between <widec.h> and <wchar.h> on
1323    Solaris 2.[789] when using GCC. ])
1324     fi ;;
1325 esac
1326 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncurses/ncurses.h ncurses/term.h)
1327 AC_CHECK_HEADERS(term.h, [], [],
1328 [#if HAVE_CURSES_H
1329 # include <curses.h>
1330 #endif
1331 ])
1332
1333 # ------------------------- #
1334 # Checks for declarations.  #
1335 # ------------------------- #
1336
1337 libiberty_INIT
1338
1339 AC_CHECK_DECLS([free, malloc, realloc, snprintf])
1340 AM_LC_MESSAGES
1341
1342 # ----------------------- #
1343 # Checks for structures.  #
1344 # ----------------------- #
1345
1346 AC_CHECK_MEMBERS([struct stat.st_blocks, struct stat.st_blksize])
1347
1348 # ------------------ #
1349 # Checks for types.  #
1350 # ------------------ #
1351
1352 AC_CHECK_TYPES(socklen_t, [], [],
1353 [#include <sys/types.h>
1354 #include <sys/socket.h>
1355 ])
1356
1357 # ------------------------------------- #
1358 # Checks for compiler characteristics.  #
1359 # ------------------------------------- #
1360
1361 AC_C_CONST
1362 AC_C_INLINE
1363 AC_C_BIGENDIAN
1364
1365 # ------------------------------ #
1366 # Checks for library functions.  #
1367 # ------------------------------ #
1368
1369 AC_FUNC_MMAP
1370 AC_FUNC_VFORK
1371 AC_CHECK_FUNCS([getauxval getrusage getuid getgid \
1372                 pipe poll pread pread64 pwrite resize_term \
1373                 sbrk setpgid setpgrp setsid \
1374                 sigaction sigprocmask sigsetmask socketpair \
1375                 ttrace wborder wresize setlocale iconvlist libiconvlist btowc \
1376                 setrlimit getrlimit posix_madvise waitpid \
1377                 ptrace64 sigaltstack mkdtemp setns])
1378 AM_LANGINFO_CODESET
1379 GDB_AC_COMMON
1380
1381 # Check the return and argument types of ptrace.
1382 GDB_AC_PTRACE
1383
1384 dnl AC_FUNC_SETPGRP does not work when cross compiling
1385 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
1386 if test "$cross_compiling" = no; then
1387   AC_FUNC_SETPGRP
1388 else
1389   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
1390     [AC_TRY_COMPILE([
1391 #include <unistd.h>
1392 ], [
1393   if (setpgrp(1,1) == -1)
1394     exit (0);
1395   else
1396     exit (1);
1397 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
1398 if test $ac_cv_func_setpgrp_void = yes; then
1399   AC_DEFINE(SETPGRP_VOID, 1)
1400 fi
1401 fi
1402
1403 # Assume we'll default to using the included libiberty regex.
1404 gdb_use_included_regex=yes
1405
1406 # However, if the system regex is GNU regex, then default to *not*
1407 # using the included regex.
1408 AC_CACHE_CHECK(
1409   [for GNU regex],
1410   [gdb_cv_have_gnu_regex],
1411   [AC_TRY_COMPILE(
1412     [#include <gnu-versions.h>],
1413     [#define REGEX_INTERFACE_VERSION 1
1414 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
1415 # error "Version mismatch"
1416 #endif],
1417     gdb_cv_have_gnu_regex=yes,
1418     gdb_cv_have_gnu_regex=no)])
1419 if test $gdb_cv_have_gnu_regex = yes; then
1420   gdb_use_included_regex=no
1421 fi
1422
1423 AC_ARG_WITH(included-regex,
1424   AS_HELP_STRING([--without-included-regex], [don't use included regex; this is the default on systems with version 2 of the GNU C library (use with caution on other system)]),
1425   gdb_with_regex=$withval,
1426   gdb_with_regex=$gdb_use_included_regex)
1427 if test "$gdb_with_regex" = yes; then
1428   AC_DEFINE(USE_INCLUDED_REGEX, 1,
1429     [Define to 1 if the regex included in libiberty should be used.])
1430 fi
1431
1432 # Check if <sys/proc.h> defines `struct thread' with a td_pcb member.
1433 AC_CHECK_MEMBERS([struct thread.td_pcb], [], [],
1434 [#include <sys/param.h>
1435 #include <sys/proc.h>
1436 ])
1437
1438 # See if <sys/lwp.h> defines `struct lwp`.
1439 AC_CACHE_CHECK([for struct lwp], gdb_cv_struct_lwp,
1440 [AC_TRY_COMPILE([#include <sys/param.h>
1441 #include <sys/lwp.h>], [struct lwp l;],
1442 gdb_cv_struct_lwp=yes, gdb_cv_struct_lwp=no)])
1443 if test $gdb_cv_struct_lwp = yes; then
1444   AC_DEFINE(HAVE_STRUCT_LWP, 1,
1445             [Define to 1 if your system has struct lwp.])
1446 fi
1447
1448 # See if <machine/reg.h> degines `struct reg'.
1449 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
1450 [AC_TRY_COMPILE([#include <sys/types.h>
1451 #include <machine/reg.h>], [struct reg r;],
1452 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
1453 if test $gdb_cv_struct_reg = yes; then
1454   AC_DEFINE(HAVE_STRUCT_REG, 1,
1455             [Define to 1 if your system has struct reg in <machine/reg.h>.])
1456 fi
1457
1458 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
1459 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
1460 AC_CHECK_MEMBERS([struct reg.r_fs, struct reg.r_gs], [], [],
1461                  [#include <sys/types.h>
1462 #include <machine/reg.h>])
1463
1464 # See if <sys/user.h> supports the %fs_base and %gs_bas amd64 segment registers.
1465 # Older amd64 Linux's don't have the fs_base and gs_base members of
1466 # `struct user_regs_struct'.
1467 AC_CHECK_MEMBERS([struct user_regs_struct.fs_base, struct user_regs_struct.gs_base],
1468                  [], [], [#include <sys/user.h>])
1469
1470 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
1471 AC_MSG_CHECKING(for PTRACE_GETREGS)
1472 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
1473 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1474                 [PTRACE_GETREGS;],
1475                 [gdb_cv_have_ptrace_getregs=yes],
1476                 [gdb_cv_have_ptrace_getregs=no])])
1477 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
1478 if test $gdb_cv_have_ptrace_getregs = yes; then
1479   AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
1480   [Define if sys/ptrace.h defines the PTRACE_GETREGS request.])
1481 fi
1482
1483 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
1484 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
1485 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
1486 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1487                 [PTRACE_GETFPXREGS;],
1488                 [gdb_cv_have_ptrace_getfpxregs=yes],
1489                 [gdb_cv_have_ptrace_getfpxregs=no])])
1490 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
1491 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
1492   AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
1493   [Define if sys/ptrace.h defines the PTRACE_GETFPXREGS request.])
1494 fi
1495
1496 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
1497 AC_MSG_CHECKING(for PT_GETDBREGS)
1498 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
1499 [AC_TRY_COMPILE([#include <sys/types.h>
1500 #include <sys/ptrace.h>],
1501                 [PT_GETDBREGS;],
1502                 [gdb_cv_have_pt_getdbregs=yes],
1503                 [gdb_cv_have_pt_getdbregs=no])])
1504 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
1505 if test $gdb_cv_have_pt_getdbregs = yes; then
1506   AC_DEFINE(HAVE_PT_GETDBREGS, 1,
1507   [Define if sys/ptrace.h defines the PT_GETDBREGS request.])
1508 fi
1509
1510 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
1511 AC_MSG_CHECKING(for PT_GETXMMREGS)
1512 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
1513 [AC_TRY_COMPILE([#include <sys/types.h>
1514 #include <sys/ptrace.h>],
1515                 [PT_GETXMMREGS;],
1516                 [gdb_cv_have_pt_getxmmregs=yes],
1517                 [gdb_cv_have_pt_getxmmregs=no])])
1518 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
1519 if test $gdb_cv_have_pt_getxmmregs = yes; then
1520   AC_DEFINE(HAVE_PT_GETXMMREGS, 1,
1521   [Define if sys/ptrace.h defines the PT_GETXMMREGS request.])
1522 fi
1523
1524 # See if <sys/ptrace.h> supports LWP names on FreeBSD
1525 # Older FreeBSD versions don't have the pl_tdname member of
1526 # `struct ptrace_lwpinfo'.
1527 AC_CHECK_MEMBERS([struct ptrace_lwpinfo.pl_tdname], [], [],
1528                  [#include <sys/ptrace.h>])
1529
1530 # See if <sys/ptrace.h> supports syscall fields on FreeBSD.  The
1531 # pl_syscall_code member of `struct ptrace_lwpinfo' was added in
1532 # FreeBSD 10.3.
1533 AC_CHECK_MEMBERS([struct ptrace_lwpinfo.pl_syscall_code], [], [],
1534                  [#include <sys/ptrace.h>])
1535
1536 # Detect which type of /proc is in use, such as for Solaris.
1537
1538 if test "${target}" = "${host}"; then
1539   case "${host}" in
1540   *-*-sysv4.2* | *-*-sysv5* )
1541       AC_DEFINE(NEW_PROC_API, 1,
1542       [Define if you want to use new multi-fd /proc interface.])
1543       ;;
1544   *-*-solaris2.[[6789]] | *-*-solaris2.1[[0-9]]*)
1545       AC_DEFINE(NEW_PROC_API, 1,
1546       [Define if you want to use new multi-fd /proc interface.])
1547       ;;
1548   mips-sgi-irix5*)
1549       # Work around <sys/proc.h> needing _KMEMUSER problem on IRIX 5.
1550       AC_DEFINE([_KMEMUSER], 1,
1551       [Define to 1 so <sys/proc.h> gets a definition of anon_hdl.  Works
1552        around a <sys/proc.h> problem on IRIX 5.])
1553       ;;
1554   esac
1555 fi
1556
1557 if test "$ac_cv_header_sys_procfs_h" = yes; then
1558   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
1559   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
1560   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
1561   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
1562   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
1563   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
1564   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
1565   BFD_HAVE_SYS_PROCFS_TYPE(prsysent_t)
1566   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigset_t)
1567   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigaction64_t)
1568   BFD_HAVE_SYS_PROCFS_TYPE(pr_siginfo64_t)
1569
1570
1571   dnl Check for broken prfpregset_t type
1572
1573   dnl For Linux/i386, glibc 2.1.3 was released with a bogus
1574   dnl prfpregset_t type (it's a typedef for the pointer to a struct
1575   dnl instead of the struct itself).  We detect this here, and work
1576   dnl around it in gdb_proc_service.h.
1577
1578   if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
1579     AC_MSG_CHECKING(whether prfpregset_t type is broken)
1580     AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
1581       [AC_TRY_RUN([#include <sys/procfs.h>
1582        int main ()
1583        {
1584          if (sizeof (prfpregset_t) == sizeof (void *))
1585            return 1;
1586          return 0;
1587        }],
1588        gdb_cv_prfpregset_t_broken=no,
1589        gdb_cv_prfpregset_t_broken=yes,
1590        gdb_cv_prfpregset_t_broken=yes)])
1591     AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
1592     if test $gdb_cv_prfpregset_t_broken = yes; then
1593       AC_DEFINE(PRFPREGSET_T_BROKEN, 1,
1594       [Define if the prfpregset_t type is broken.])
1595     fi
1596   fi
1597 fi
1598
1599 # Check if the compiler supports the `long long' type.
1600
1601 AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long,
1602                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1603 [[extern long long foo;]],
1604 [[switch (foo & 2) { case 0: return 1; }]])],
1605                                   gdb_cv_c_long_long=yes,
1606                                   gdb_cv_c_long_long=no)])
1607 if test $gdb_cv_c_long_long != yes; then
1608   # libdecnumber requires long long.
1609   AC_MSG_ERROR([Compiler must support long long for GDB.])
1610 fi
1611
1612 # Check if the compiler and runtime support printing long longs.
1613
1614 AC_CACHE_CHECK([for long long support in printf],
1615                gdb_cv_printf_has_long_long,
1616                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1617 [[char buf[32];
1618   long long l = 0;
1619   l = (l << 16) + 0x0123;
1620   l = (l << 16) + 0x4567;
1621   l = (l << 16) + 0x89ab;
1622   l = (l << 16) + 0xcdef;
1623   sprintf (buf, "0x%016llx", l);
1624   return (strcmp ("0x0123456789abcdef", buf));]])],
1625                               gdb_cv_printf_has_long_long=yes,
1626                               gdb_cv_printf_has_long_long=no,
1627                               gdb_cv_printf_has_long_long=no)])
1628 if test $gdb_cv_printf_has_long_long = yes; then
1629   AC_DEFINE(PRINTF_HAS_LONG_LONG, 1,
1630             [Define to 1 if the "%ll" format works to print long longs.])
1631 fi
1632
1633 # Check if the compiler and runtime support printing decfloats.
1634
1635 AC_CACHE_CHECK([for decfloat support in printf],
1636                gdb_cv_printf_has_decfloat,
1637                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1638 [[char buf[64];
1639   _Decimal32 d32 = 1.2345df;
1640   _Decimal64 d64 = 1.2345dd;
1641   _Decimal128 d128 = 1.2345dl;
1642   sprintf (buf, "Decimal32: %H\nDecimal64: %D\nDecimal128: %DD", d32, d64, d128);
1643   return (strcmp ("Decimal32: 1.2345\nDecimal64: 1.2345\nDecimal128: 1.2345", buf));]])],
1644                               gdb_cv_printf_has_decfloat=yes,
1645                               gdb_cv_printf_has_decfloat=no,
1646                               gdb_cv_printf_has_decfloat=no)])
1647 if test $gdb_cv_printf_has_decfloat = yes; then
1648   AC_DEFINE(PRINTF_HAS_DECFLOAT, 1,
1649             [Define to 1 if the "%H, %D and %DD" formats work to print decfloats.])
1650 fi
1651
1652 # Check if the compiler supports the `long double' type.  We can't use
1653 # AC_C_LONG_DOUBLE because that one does additional checks on the
1654 # constants defined in <float.h> that fail on some systems,
1655 # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6.
1656
1657 AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double,
1658                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])],
1659                                   gdb_cv_c_long_double=yes,
1660                                   gdb_cv_c_long_double=no)])
1661 if test $gdb_cv_c_long_double = yes; then
1662   AC_DEFINE(HAVE_LONG_DOUBLE, 1,
1663            [Define to 1 if the compiler supports long double.])
1664 fi
1665
1666 # Check if the compiler and runtime support printing long doubles.
1667
1668 AC_CACHE_CHECK([for long double support in printf],
1669                gdb_cv_printf_has_long_double,
1670                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1671 [[char buf[16];
1672   long double f = 3.141592653;
1673   sprintf (buf, "%Lg", f);
1674   return (strncmp ("3.14159", buf, 7));]])],
1675                               gdb_cv_printf_has_long_double=yes,
1676                               gdb_cv_printf_has_long_double=no,
1677                               gdb_cv_printf_has_long_double=no)])
1678 if test $gdb_cv_printf_has_long_double = yes; then
1679   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1,
1680             [Define to 1 if the "%Lg" format works to print long doubles.])
1681 fi
1682
1683 # Check if the compiler and runtime support scanning long doubles.
1684
1685 AC_CACHE_CHECK([for long double support in scanf],
1686                gdb_cv_scanf_has_long_double,
1687                [AC_RUN_IFELSE([AC_LANG_PROGRAM(
1688 [[#include <stdio.h>]],
1689 [[char *buf = "3.141592653";
1690   long double f = 0;
1691   sscanf (buf, "%Lg", &f);
1692   return !(f > 3.14159 && f < 3.14160);]])],
1693                               gdb_cv_scanf_has_long_double=yes,
1694                               gdb_cv_scanf_has_long_double=no,
1695                               gdb_cv_scanf_has_long_double=no)])
1696 if test $gdb_cv_scanf_has_long_double = yes; then
1697   AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1,
1698             [Define to 1 if the "%Lg" format works to scan long doubles.])
1699 fi
1700
1701 case ${host_os} in
1702 aix*)
1703   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1704     SAVE_LDFLAGS=$LDFLAGS
1705
1706     case $GCC in
1707     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1708     *) gdb_cv_bigtoc=-bbigtoc ;;
1709     esac
1710
1711     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1712     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1713     LDFLAGS="${SAVE_LDFLAGS}"
1714   ])
1715   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
1716   ;;
1717 esac
1718
1719 AC_MSG_CHECKING(for the dynamic export flag)
1720 dynamic_list=false
1721 if test "${gdb_native}" = yes; then
1722    # The dynamically loaded libthread_db needs access to symbols in the gdb
1723    # executable.  Older GNU ld supports --export-dynamic but --dynamic-list
1724    # may not be supported there.
1725    old_LDFLAGS="$LDFLAGS"
1726    # Older GNU ld supports --export-dynamic but --dynamic-list it does not.
1727    RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
1728    LDFLAGS="$LDFLAGS $RDYNAMIC"
1729    if test "${have_libpython}" = no; then
1730      AC_TRY_LINK([], [], [dynamic_list=true])
1731    else
1732      # Workaround http://bugs.python.org/issue4434 where static
1733      # libpythonX.Y.a would get its symbols required for
1734      # pythonX.Y/lib-dynload/*.so modules hidden by -Wl,--dynamic-list.
1735      # Problem does not happen for the recommended libpythonX.Y.so linkage.
1736
1737      # Note the workaround for Python
1738      # http://bugs.python.org/issue10112 earlier has removed
1739      # -export-dynamic from PYTHON_LIBS.  That's exactly what we want
1740      # here too, as otherwise it'd make this -Wl,--dynamic-list test
1741      # always pass.
1742      old_CFLAGS="$CFLAGS"
1743      CFLAGS="$CFLAGS $PYTHON_CFLAGS"
1744      old_LIBS="$LIBS"
1745      LIBS="$LIBS $PYTHON_LIBS"
1746      old_CPPFLAGS="$CPPFLAGS"
1747      CPPFLAGS="$CPPFLAGS $PYTHON_CPPFLAGS"
1748      AC_RUN_IFELSE(
1749        AC_LANG_PROGRAM(
1750          [#include "Python.h"],
1751          [int err;
1752           Py_Initialize ();
1753           err = PyRun_SimpleString ("import itertools\n");
1754           Py_Finalize ();
1755           return err == 0 ? 0 : 1;]),
1756        [dynamic_list=true], [], [true])
1757      LIBS="$old_LIBS"
1758      CFLAGS="$old_CFLAGS"
1759      CPPFLAGS="$old_CPPFLAGS"
1760    fi
1761    LDFLAGS="$old_LDFLAGS"
1762 fi
1763 if $dynamic_list; then
1764   found="-Wl,--dynamic-list"
1765   RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'
1766 else
1767   found="-rdynamic"
1768   RDYNAMIC="-rdynamic"
1769 fi
1770 AC_SUBST(RDYNAMIC)
1771 AC_MSG_RESULT($found)
1772
1773 dnl For certain native configurations, we need to check whether thread
1774 dnl support can be built in or not.
1775 dnl
1776 dnl Note that we only want this if we are both native (host == target),
1777 dnl and not doing a canadian cross build (build == host).
1778
1779 if test ${build} = ${host} -a ${host} = ${target} ; then
1780    case ${host_os} in
1781    solaris*)
1782       # See if thread_db library is around for Solaris thread debugging.
1783       # Note that we must explicitly test for version 1 of the library
1784       # because version 0 (present on Solaris 2.4 or earlier) doesn't have
1785       # the same API.
1786       AC_MSG_CHECKING(for Solaris thread debugging library)
1787       if test -f /usr/lib/libthread_db.so.1 ; then
1788          AC_MSG_RESULT(yes)
1789          AC_DEFINE(HAVE_THREAD_DB_LIB, 1,
1790          [Define if using Solaris thread debugging.])
1791          CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
1792          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
1793          AC_CHECK_LIB(dl, dlopen)
1794          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} $RDYNAMIC"
1795          # Sun randomly tweaked the prototypes in <proc_service.h>
1796          # at one point.
1797          AC_MSG_CHECKING(if <proc_service.h> is old)
1798          AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
1799             AC_TRY_COMPILE([
1800                 #include <proc_service.h>
1801                 ps_err_e ps_pdwrite
1802                     (struct ps_prochandle*, psaddr_t, const void*, size_t);
1803             ],, gdb_cv_proc_service_is_old=no,
1804                 gdb_cv_proc_service_is_old=yes)
1805          ])
1806          AC_MSG_RESULT($gdb_cv_proc_service_is_old)
1807          if test $gdb_cv_proc_service_is_old = yes; then
1808             AC_DEFINE(PROC_SERVICE_IS_OLD, 1,
1809             [Define if <proc_service.h> on solaris uses int instead of
1810              size_t, and assorted other type changes.])
1811          fi
1812       else
1813          AC_MSG_RESULT(no)
1814       fi
1815       ;;
1816    aix*)
1817       AC_MSG_CHECKING(for AiX thread debugging library)
1818       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
1819                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
1820                                    [#ifndef PTHDB_VERSION_3
1821                                     #error
1822                                     #endif],
1823                                    gdb_cv_have_aix_thread_debug=yes,
1824                                    gdb_cv_have_aix_thread_debug=no)])
1825       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1826       if test $gdb_cv_have_aix_thread_debug = yes; then
1827          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1828          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1829          LIBS="$LIBS -lpthdebug"
1830
1831          # Older versions of AIX do not provide the declaration for
1832          # the getthrds function (it appears that it was introduced
1833          # with AIX 6.x).
1834          AC_CHECK_DECLS(getthrds, [], [], [[#include <procinfo.h>]])
1835       fi
1836       ;;
1837    esac
1838    AC_SUBST(CONFIG_LDFLAGS)
1839 fi
1840
1841 dnl See if we have a thread_db header file that has TD_NOTALLOC and
1842 dnl other error codes.
1843 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1844    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
1845                   gdb_cv_thread_db_h_has_td_notalloc,
1846      AC_TRY_COMPILE(
1847        [#include <thread_db.h>],
1848        [int i = TD_NOTALLOC;],
1849        gdb_cv_thread_db_h_has_td_notalloc=yes,
1850        gdb_cv_thread_db_h_has_td_notalloc=no
1851      )
1852    )
1853    AC_CACHE_CHECK([whether <thread_db.h> has TD_VERSION],
1854                   gdb_cv_thread_db_h_has_td_version,
1855      AC_TRY_COMPILE(
1856        [#include <thread_db.h>],
1857        [int i = TD_VERSION;],
1858        gdb_cv_thread_db_h_has_td_version=yes,
1859        gdb_cv_thread_db_h_has_td_version=no
1860      )
1861    )
1862    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTLS],
1863                   gdb_cv_thread_db_h_has_td_notls,
1864      AC_TRY_COMPILE(
1865        [#include <thread_db.h>],
1866        [int i = TD_NOTLS;],
1867        gdb_cv_thread_db_h_has_td_notls=yes,
1868        gdb_cv_thread_db_h_has_td_notls=no
1869      )
1870    )
1871 fi
1872 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1873   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1874             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1875 fi
1876 if test "x$gdb_cv_thread_db_h_has_td_version" = "xyes"; then
1877   AC_DEFINE(THREAD_DB_HAS_TD_VERSION, 1,
1878             [Define if <thread_db.h> has the TD_VERSION error code.])
1879 fi
1880 if test "x$gdb_cv_thread_db_h_has_td_notls" = "xyes"; then
1881   AC_DEFINE(THREAD_DB_HAS_TD_NOTLS, 1,
1882             [Define if <thread_db.h> has the TD_NOTLS error code.])
1883 fi
1884
1885 dnl Check if we can disable the virtual address space randomization.
1886 dnl The functionality of setarch -R.
1887 AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>])
1888 define([PERSONALITY_TEST], [AC_LANG_PROGRAM([#include <sys/personality.h>], [
1889 #      if !HAVE_DECL_ADDR_NO_RANDOMIZE
1890 #       define ADDR_NO_RANDOMIZE 0x0040000
1891 #      endif
1892        /* Test the flag could be set and stays set.  */
1893        personality (personality (0xffffffff) | ADDR_NO_RANDOMIZE);
1894        if (!(personality (personality (0xffffffff)) & ADDR_NO_RANDOMIZE))
1895            return 1])])
1896 AC_RUN_IFELSE([PERSONALITY_TEST],
1897               [have_personality=true],
1898               [have_personality=false],
1899               [AC_LINK_IFELSE([PERSONALITY_TEST],
1900                               [have_personality=true],
1901                               [have_personality=false])])
1902 if $have_personality
1903 then
1904     AC_DEFINE([HAVE_PERSONALITY], 1,
1905               [Define if you support the personality syscall.])
1906 fi
1907
1908 dnl Set the host's .gdbinit filename.
1909 case $host_os in
1910   go32* | *djgpp*)
1911     gdbinit=gdb.ini
1912     ;;
1913   *)
1914     gdbinit=.gdbinit
1915     ;;
1916 esac
1917 AC_DEFINE_UNQUOTED(GDBINIT,"$gdbinit",[The .gdbinit filename.])
1918
1919 dnl Handle optional features that can be enabled.
1920
1921 # Support for --with-sysroot is a copy of GDB_AC_WITH_DIR,
1922 # except that the argument to --with-sysroot is optional.
1923 # --with-sysroot (or --with-sysroot=yes) sets the default sysroot path.
1924 if test "x$with_sysroot" = xyes; then
1925   with_sysroot="${exec_prefix}/${target_alias}/sys-root"
1926 fi
1927 AC_ARG_WITH(sysroot,
1928   AS_HELP_STRING([--with-sysroot@<:@=DIR@:>@],
1929                  [search for usr/lib et al within DIR]),
1930   [TARGET_SYSTEM_ROOT=$withval], [TARGET_SYSTEM_ROOT=])
1931 AC_DEFINE_DIR(TARGET_SYSTEM_ROOT, TARGET_SYSTEM_ROOT,
1932               [search for usr/lib et al within DIR])
1933 AC_SUBST(TARGET_SYSTEM_ROOT)
1934 GDB_AC_DEFINE_RELOCATABLE(TARGET_SYSTEM_ROOT, sysroot, ${ac_define_dir})
1935
1936 GDB_AC_WITH_DIR(SYSTEM_GDBINIT, system-gdbinit,
1937     [automatically load a system-wide gdbinit file],
1938     [])
1939
1940 AM_GDB_WARNINGS
1941
1942 # In the Cygwin environment, we need some additional flags.
1943 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1944 [AC_EGREP_CPP(^lose$, [
1945 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1946 lose
1947 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1948
1949
1950 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1951 SER_HARDWIRE="ser-base.o ser-unix.o ser-pipe.o ser-tcp.o"
1952 case ${host} in
1953   *go32* ) SER_HARDWIRE=ser-go32.o ;;
1954   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
1955   *mingw32*) SER_HARDWIRE="ser-base.o ser-tcp.o ser-mingw.o" ;;
1956 esac
1957 AC_SUBST(SER_HARDWIRE)
1958
1959 # libreadline needs libuser32.a in a cygwin environment
1960 WIN32LIBS=
1961 if test x$gdb_cv_os_cygwin = xyes; then
1962     WIN32LIBS="-luser32"
1963     case "${target}" in
1964         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
1965         ;;
1966     esac
1967 fi
1968
1969 # The ser-tcp.c module requires sockets.
1970 case ${host} in
1971   *mingw32*)
1972     AC_DEFINE(USE_WIN32API, 1,
1973               [Define if we should use the Windows API, instead of the
1974                POSIX API.  On Windows, we use the Windows API when
1975                building for MinGW, but the POSIX API when building
1976                for Cygwin.])
1977     WIN32LIBS="$WIN32LIBS -lws2_32"
1978     ;;
1979 esac
1980 AC_SUBST(WIN32LIBS)
1981
1982 # Add ELF support to GDB, but only if BFD includes ELF support.
1983 GDB_AC_CHECK_BFD([for ELF support in BFD], gdb_cv_var_elf,
1984                  [bfd_get_elf_phdr_upper_bound (NULL)], elf-bfd.h)
1985 if test $gdb_cv_var_elf = yes; then
1986   CONFIG_OBS="$CONFIG_OBS elfread.o stap-probe.o dtrace-probe.o"
1987   AC_DEFINE(HAVE_ELF, 1,
1988             [Define if ELF support should be included.])
1989   # -ldl is provided by bfd/Makfile.am (LIBDL) <PLUGINS>.
1990   if test "$plugins" = "yes"; then
1991     AC_SEARCH_LIBS(dlopen, dl)
1992   fi
1993 fi
1994
1995 # Add macho support to GDB, but only if BFD includes it.
1996 GDB_AC_CHECK_BFD([for Mach-O support in BFD], gdb_cv_var_macho,
1997                  [bfd_mach_o_lookup_command (NULL, 0, NULL)], mach-o.h)
1998 if test $gdb_cv_var_macho = yes; then
1999   CONFIG_OBS="$CONFIG_OBS machoread.o"
2000 fi
2001
2002 # Add any host-specific objects to GDB.
2003 CONFIG_OBS="${CONFIG_OBS} ${gdb_host_obs}"
2004
2005 # If building on ELF, look for lzma support for embedded compressed debug info.
2006 if test $gdb_cv_var_elf = yes; then
2007   AC_ARG_WITH(lzma,
2008     AS_HELP_STRING([--with-lzma], [support lzma compression (auto/yes/no)]),
2009     [], [with_lzma=auto])
2010   AC_MSG_CHECKING([whether to use lzma])
2011   AC_MSG_RESULT([$with_lzma])
2012
2013   if test "${with_lzma}" != no; then
2014     AC_LIB_HAVE_LINKFLAGS([lzma], [], [#include "lzma.h"],
2015                           [lzma_index_iter iter;
2016                            lzma_index_iter_init (&iter, 0);
2017                            lzma_mf_is_supported (LZMA_MF_HC3);])
2018     if test "$HAVE_LIBLZMA" != yes; then
2019       if test "$with_lzma" = yes; then
2020         AC_MSG_ERROR([missing liblzma for --with-lzma])
2021       fi
2022     fi
2023   fi
2024 fi
2025
2026 LIBGUI="../libgui/src/libgui.a"
2027 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
2028 AC_SUBST(LIBGUI)
2029 AC_SUBST(GUI_CFLAGS_X)
2030
2031 WIN32LDAPP=
2032 AC_SUBST(WIN32LIBS)
2033 AC_SUBST(WIN32LDAPP)
2034
2035 case "${host}" in
2036 *-*-cygwin* | *-*-mingw* )
2037     configdir="win"
2038     ;;
2039 *)
2040     configdir="unix"
2041     ;;
2042 esac
2043
2044 GDBTKLIBS=
2045 if test "${enable_gdbtk}" = "yes"; then
2046
2047     # Gdbtk must have an absolute path to srcdir in order to run
2048     # properly when not installed.
2049     here=`pwd`
2050     cd ${srcdir}
2051     GDBTK_SRC_DIR=`pwd`
2052     cd $here
2053
2054     SC_PATH_TCLCONFIG
2055
2056     # If $no_tk is nonempty, then we can't do Tk, and there is no
2057     # point to doing Tcl.
2058     SC_PATH_TKCONFIG
2059
2060     if test -z "${no_tcl}" -a -z "${no_tk}"; then
2061         SC_LOAD_TCLCONFIG
2062
2063         # Check for in-tree tcl
2064         here=`pwd`
2065         cd ${srcdir}/..
2066         topdir=`pwd`
2067         cd ${here}
2068
2069         intree="no"
2070         if test "${TCL_SRC_DIR}" = "${topdir}/tcl"; then
2071           intree="yes"
2072         fi
2073
2074         # Find Tcl private headers
2075         if test x"${intree}" = xno; then
2076           CY_AC_TCL_PRIVATE_HEADERS
2077           TCL_INCLUDE="${TCL_INCLUDE_SPEC} ${TCL_PRIVATE_INCLUDE}"
2078           TCL_LIBRARY="${TCL_LIB_SPEC}"
2079           TCL_DEPS=""
2080         else
2081           # If building tcl in the same src tree, private headers
2082           # are not needed, but we need to be sure to use the right
2083           # headers library
2084           TCL_INCLUDE="-I${TCL_SRC_DIR}/generic"
2085           TCL_LIBRARY="${TCL_BUILD_LIB_SPEC}"
2086           TCL_DEPS="../tcl/${configdir}${TCL_LIB_FILE}"
2087         fi
2088         AC_SUBST(TCL_INCLUDE)
2089         AC_SUBST(TCL_LIBRARY)
2090         AC_SUBST(TCL_DEPS)
2091
2092         SC_LOAD_TKCONFIG
2093
2094         # Check for in-tree Tk
2095         intree="no"
2096         if test "${TK_SRC_DIR}" = "${topdir}/tk"; then
2097           intree="yes"
2098         fi
2099
2100         # Find Tk private headers
2101         if test x"${intree}" = xno; then
2102           CY_AC_TK_PRIVATE_HEADERS
2103           TK_INCLUDE="${TK_INCLUDE_SPEC} ${TK_PRIVATE_INCLUDE}"
2104           TK_LIBRARY=${TK_LIB_SPEC}
2105           TK_DEPS=""
2106         else
2107           TK_INCLUDE="-I${TK_SRC_DIR}/generic"
2108           TK_LIBRARY="${TK_BUILD_LIB_SPEC}"
2109           TK_DEPS="../tk/${configdir}/${TK_LIB_FILE}"
2110         fi
2111         AC_SUBST(TK_INCLUDE)
2112         AC_SUBST(TK_LIBRARY)
2113         AC_SUBST(TK_DEPS)
2114         AC_SUBST(TK_XINCLUDES)
2115
2116         ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
2117
2118         # Include some libraries that Tcl and Tk want.
2119         TCL_LIBS='$(LIBGUI) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
2120         # Yes, the ordering seems wrong here.  But it isn't.
2121         # TK_LIBS is the list of libraries that need to be linked
2122         # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
2123         # were in LIBS then any link tests after this point would
2124         # try to include things like `$(LIBGUI)', which wouldn't work.
2125         GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
2126
2127         CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
2128         CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
2129         CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
2130         CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
2131         CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
2132         CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
2133         CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
2134
2135         if test x$gdb_cv_os_cygwin = xyes; then
2136           WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
2137           WIN32LDAPP="-Wl,--subsystem,console"
2138           CONFIG_OBS="${CONFIG_OBS} gdbres.o"
2139         fi
2140
2141         AC_CONFIG_SUBDIRS(gdbtk)
2142     fi
2143 fi
2144
2145 AC_SUBST(X_CFLAGS)
2146 AC_SUBST(X_LDFLAGS)
2147 AC_SUBST(X_LIBS)
2148 AC_SUBST(GDBTKLIBS)
2149 AC_SUBST(GDBTK_CFLAGS)
2150 AC_SUBST(GDBTK_SRC_DIR)
2151
2152 AC_PATH_X
2153
2154 # Unlike the sim directory, whether a simulator is linked is controlled by
2155 # presence of a gdb_sim definition in the target configure.tgt entry.
2156 # This code just checks for a few cases where we'd like to ignore those
2157 # definitions, even when they're present in the '.mt' file.  These cases
2158 # are when --disable-sim is specified, or if the simulator directory is
2159 # not part of the source tree.
2160 #
2161 AC_ARG_ENABLE(sim,
2162 AS_HELP_STRING([--enable-sim], [link gdb with simulator]),
2163 [echo "enable_sim = $enable_sim";
2164  echo "enableval = ${enableval}";
2165  case "${enableval}" in
2166   yes) ignore_sim=false ;;
2167   no)  ignore_sim=true ;;
2168   *)   ignore_sim=false ;;
2169  esac],
2170 [ignore_sim=false])
2171
2172 if test ! -d "${srcdir}/../sim"; then
2173   ignore_sim=true
2174 fi
2175
2176 SIM=
2177 SIM_OBS=
2178 if test "${ignore_sim}" = "false"; then
2179   if test x"${gdb_sim}" != x ; then
2180     SIM="${gdb_sim}"
2181     SIM_OBS="remote-sim.o"
2182     AC_DEFINE(WITH_SIM, 1, [Define if the simulator is being linked in.])
2183
2184     # Some tdep code should only be compiled in when the ppc sim is
2185     # built.  PR sim/13418.
2186     case $target in
2187       powerpc*-*-*)
2188         AC_DEFINE(WITH_PPC_SIM, 1, [Define if the PPC simulator is being linked in.])
2189         ;;
2190     esac
2191   fi
2192 fi
2193 AC_SUBST(SIM)
2194 AC_SUBST(SIM_OBS)
2195
2196 AC_SUBST(ENABLE_CFLAGS)
2197 AC_SUBST(PROFILE_CFLAGS)
2198
2199 AC_SUBST(CONFIG_OBS)
2200 AC_SUBST(CONFIG_DEPS)
2201 AC_SUBST(CONFIG_SRCS)
2202 AC_SUBST(CONFIG_ALL)
2203 AC_SUBST(CONFIG_CLEAN)
2204 AC_SUBST(CONFIG_INSTALL)
2205 AC_SUBST(CONFIG_UNINSTALL)
2206
2207 # List of host floatformats.
2208 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
2209 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
2210 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
2211
2212 # target_subdir is used by the testsuite to find the target libraries.
2213 target_subdir=
2214 if test "${host}" != "${target}"; then
2215     target_subdir="${target_alias}/"
2216 fi
2217 AC_SUBST(target_subdir)
2218
2219 frags=
2220 if test "${gdb_native}" = "yes"; then
2221   host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
2222   if test ! -f ${host_makefile_frag}; then
2223     AC_MSG_ERROR("*** Gdb does not support native target ${host}")
2224   fi
2225   frags="$frags $host_makefile_frag"
2226 else
2227   host_makefile_frag=/dev/null
2228 fi
2229
2230 AC_SUBST_FILE(host_makefile_frag)
2231 AC_SUBST(frags)
2232
2233 changequote(,)dnl
2234 if test "${gdb_native}" = "yes"; then
2235 # We pick this up from the host configuration file (.mh) because we
2236 # do not have a native configuration Makefile fragment.
2237 nativefile=`sed -n '
2238 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
2239 ' ${host_makefile_frag}`
2240 fi
2241 changequote([,])
2242
2243 if test x"${gdb_osabi}" != x ; then
2244     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
2245                        [Define to the default OS ABI for this configuration.])
2246 fi
2247
2248 # Enable multi-ice-gdb-server.
2249 AC_ARG_ENABLE(multi-ice,
2250 AS_HELP_STRING([--enable-multi-ice], [build the multi-ice-gdb-server]),
2251   [case $enableval in
2252     yes | no)
2253       ;;
2254     *) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;;
2255   esac])
2256 if test "x$enable_multi_ice" = xyes; then
2257    AC_CONFIG_SUBDIRS(multi-ice)
2258 fi
2259
2260 AC_ARG_ENABLE(gdbserver,
2261 AS_HELP_STRING([--enable-gdbserver],
2262                [automatically build gdbserver (yes/no/auto, default is auto)]),
2263 [case "${enableval}" in
2264   yes| no|auto) ;;
2265   *) AC_MSG_ERROR(bad value ${enableval} for --enable-gdbserver option) ;;
2266 esac],[enable_gdbserver=auto])
2267
2268 # We only build gdbserver automatically in a native configuration, and
2269 # only if the user did not explicitly disable its build.
2270 if test "$gdb_native" = "yes" -a "$enable_gdbserver" != "no"; then
2271   AC_MSG_CHECKING(whether gdbserver is supported on this host)
2272   if test "x$build_gdbserver" = xyes; then
2273     AC_MSG_RESULT(yes)
2274     AC_CONFIG_SUBDIRS(gdbserver)
2275     gdbserver_build_enabled=yes
2276   else
2277     AC_MSG_RESULT(no)
2278   fi
2279 fi
2280
2281 # If the user explicitly request the gdbserver to be built, verify that
2282 # we were in fact able to enable it.
2283 if test "$enable_gdbserver" = "yes" -a "$gdbserver_build_enabled" != "yes"; then
2284   AC_MSG_ERROR(Automatic gdbserver build is not supported for this configuration)
2285 fi
2286
2287 # Check for babeltrace and babeltrace-ctf
2288 AC_ARG_WITH(babeltrace,
2289   AC_HELP_STRING([--with-babeltrace], [include babeltrace support (auto/yes/no)]),
2290   [], [with_babeltrace=auto])
2291 AC_MSG_CHECKING([whether to use babeltrace])
2292 AC_MSG_RESULT([$with_babeltrace])
2293
2294 if test "x$with_babeltrace" = "xno"; then
2295   AC_MSG_WARN([babletrace support disabled; GDB is unable to read CTF data.])
2296 else
2297   # Append -Werror to CFLAGS so that configure can catch the warning
2298   # "assignment from incompatible pointer type", which is related to
2299   # the babeltrace change from 1.0.3 to 1.1.0.  Babeltrace 1.1.0 works
2300   # in GDB, while babeltrace 1.0.3 is broken.
2301   # AC_LIB_HAVE_LINKFLAGS may modify CPPFLAGS in it, so it should be
2302   # safe to save and restore CFLAGS here.
2303   saved_CFLAGS=$CFLAGS
2304   CFLAGS="$CFLAGS -Werror"
2305   AC_LIB_HAVE_LINKFLAGS([babeltrace], [babeltrace-ctf],
2306                         [#include <babeltrace/babeltrace.h>
2307                          #include <babeltrace/ctf/events.h>
2308                          #include <babeltrace/ctf/iterator.h>],
2309                         [struct bt_iter_pos *pos = bt_iter_get_pos (bt_ctf_get_iter (NULL));
2310                         struct bt_ctf_event *event = NULL;
2311                         const struct bt_definition *scope;
2312
2313                         pos->type = BT_SEEK_BEGIN;
2314                         bt_iter_set_pos (bt_ctf_get_iter (NULL), pos);
2315                         scope = bt_ctf_get_top_level_scope (event,
2316                                                            BT_STREAM_EVENT_HEADER);
2317                         bt_ctf_get_uint64 (bt_ctf_get_field (event, scope, "id"));
2318                         ])
2319   CFLAGS=$saved_CFLAGS
2320
2321   if test "$HAVE_LIBBABELTRACE" != yes; then
2322      if test "$with_babeltrace" = yes; then
2323        AC_MSG_ERROR([babeltrace is missing or unusable])
2324      else
2325        AC_MSG_WARN([babeltrace is missing or unusable; GDB is unable to read CTF data.])
2326      fi
2327   fi
2328 fi
2329
2330 # If nativefile (NAT_FILE) is not set in config/*/*.m[ht] files, we link
2331 # to an empty version.
2332
2333 files=
2334 links=
2335
2336 rm -f nm.h
2337 if test "${nativefile}" != ""; then
2338     case "${nativefile}" in
2339       nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
2340       * ) GDB_NM_FILE="${nativefile}"
2341     esac
2342     files="${files} ${GDB_NM_FILE}"
2343     links="${links} nm.h"
2344     AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}", [nativefile])
2345 fi
2346 AC_SUBST(GDB_NM_FILE)
2347
2348 dnl Add dependency for xsltproc if building with maintainer-mode enabled.
2349 AC_PATH_PROGS(XSLTPROC, xsltproc, missing)
2350 if test "x$USE_MAINTAINER_MODE" = xyes; then
2351   if test "${XSLTPROC}" = missing; then
2352     AC_ERROR(unable to find xsltproc.  maintainer-mode requires xsltproc.)
2353   fi
2354 fi
2355 AC_SUBST(XSLTPROC)
2356
2357 AC_LINK_FILES($files, $links)
2358
2359 dnl Check for exe extension set on certain hosts (e.g. Win32)
2360 AC_EXEEXT
2361
2362 dnl  Detect the character set used by this host.
2363 dnl  At the moment, we just assume it's UTF-8.
2364 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "UTF-8",
2365           [Define to be a string naming the default host character set.])
2366
2367 if $development; then
2368   AC_DEFINE(GDB_SELF_TEST, 1,
2369             [Define if self-testing features should be enabled])
2370 fi
2371
2372 GDB_AC_TRANSFORM([gdb], [GDB_TRANSFORM_NAME])
2373 GDB_AC_TRANSFORM([gcore], [GCORE_TRANSFORM_NAME])
2374 AC_CONFIG_FILES([gcore], [chmod +x gcore])
2375 AC_CONFIG_FILES([Makefile gdb-gdb.gdb doc/Makefile data-directory/Makefile],
2376 [
2377 case x$CONFIG_HEADERS in
2378 xconfig.h:config.in)
2379 echo > stamp-h ;;
2380 esac
2381 ])
2382
2383 AC_OUTPUT