gdb/configure.ac

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995-2012 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Process this file with autoconf to produce a configure script.
  20
  21 AC_PREREQ(2.59)dnl
  22 AC_INIT(main.c)
  23 AC_CONFIG_HEADER(config.h:config.in)
  24 AM_MAINTAINER_MODE
  25
  26 AC_PROG_CC
  27 AC_USE_SYSTEM_EXTENSIONS
  28 gl_EARLY
  29 ACX_LARGEFILE
  30 AM_PROG_CC_STDC
  31
  32 AC_CONFIG_AUX_DIR(..)
  33 AC_CANONICAL_SYSTEM
  34
  35 # Dependency checking.
  36 ZW_CREATE_DEPDIR
  37 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  38
  39 # Check for the 'make' the user wants to use.
  40 AC_CHECK_PROGS(MAKE, make)
  41 MAKE_IS_GNU=
  42 case "`$MAKE --version 2>&1 | sed 1q`" in
  43   *GNU*)
  44     MAKE_IS_GNU=yes
  45     ;;
  46 esac
  47 AM_CONDITIONAL(GMAKE, test "$MAKE_IS_GNU" = yes)
  48 AC_PROG_MAKE_SET
  49
  50 dnl List of object files and targets accumulated by configure.
  51
  52 CONFIG_OBS=
  53 CONFIG_DEPS=
  54 CONFIG_SRCS=
  55 ENABLE_CFLAGS=
  56
  57 CONFIG_ALL=
  58 CONFIG_CLEAN=
  59 CONFIG_INSTALL=
  60 CONFIG_UNINSTALL=
  61
  62 dnl Set up for gettext.
  63 ZW_GNU_GETTEXT_SISTER_DIR
  64
  65 localedir='${datadir}/locale'
  66 AC_SUBST(localedir)
  67
  68 if test x"$USE_NLS" = xyes; then
  69    CONFIG_ALL="$CONFIG_ALL all-po"
  70    CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
  71    CONFIG_INSTALL="$CONFIG_INSTALL install-po"
  72    CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
  73 fi
  74
  75 gl_INIT
  76
  77 # For Makefile dependencies.
  78 GNULIB_STDINT_H=
  79 if test x"$STDINT_H" != x; then
  80   GNULIB_STDINT_H=gnulib/$STDINT_H
  81 fi
  82 AC_SUBST(GNULIB_STDINT_H)
  83
  84 PACKAGE=gdb
  85 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
  86 AC_SUBST(PACKAGE)
  87
  88 # We never need to detect it in this sub-configure.
  89 # But preserve it for config.status --recheck.
  90 AC_ARG_VAR(MAKEINFO,
  91   [Parent configure detects if it is of sufficient version.])
  92 AC_ARG_VAR(MAKEINFOFLAGS,
  93   [Parameters for MAKEINFO.])
  94
  95 MAKEINFO_EXTRA_FLAGS=""
  96 AC_CACHE_CHECK([whether $MAKEINFO supports @click], gdb_cv_have_makeinfo_click,
  97   [echo '@clicksequence{a @click{} b}' >conftest.texinfo
  98   if eval "$MAKEINFO conftest.texinfo >&5 2>&5"; then
  99     gdb_cv_have_makeinfo_click=yes
 100   else
 101     gdb_cv_have_makeinfo_click=no
 102   fi])
 103 if test x"$gdb_cv_have_makeinfo_click" = xyes; then
 104   MAKEINFO_EXTRA_FLAGS="$MAKEINFO_EXTRA_FLAGS -DHAVE_MAKEINFO_CLICK"
 105 fi
 106 AC_SUBST(MAKEINFO_EXTRA_FLAGS)
 107
 108 # GDB does not use automake, but gnulib does.  This line lets us
 109 # generate its Makefile.in.
 110 AM_INIT_AUTOMAKE(gdb, UNUSED-VERSION, [no-define])
 111
 112 GDB_AC_WITH_DIR(DEBUGDIR, separate-debug-dir,
 113     [look for global separate debug info in this path @<:@LIBDIR/debug@:>@],
 114     [${libdir}/debug])
 115
 116 # We can't pass paths as command line arguments.
 117 # Mingw32 tries to be clever and will convert the paths for us.
 118 # For example -DBINDIR="/usr/local/bin" passed on the command line may get
 119 # converted to -DBINDIR="E:/msys/mingw32/msys/1.0/local/bin".
 120 # This breaks GDB's relocatable path conversions since paths passed in
 121 # config.h would not get so translated, the path prefixes no longer match.
 122 AC_DEFINE_DIR(BINDIR, bindir, [Directory of programs.])
 123
 124 # GDB's datadir relocation
 125
 126 GDB_AC_WITH_DIR(GDB_DATADIR, gdb-datadir,
 127     [look for global separate data files in this path @<:@DATADIR/gdb@:>@],
 128     [${datadir}/gdb])
 129
 130 AC_ARG_WITH(relocated-sources,
 131 AS_HELP_STRING([--with-relocated-sources=PATH], [automatically relocate this path for source files]),
 132 [reloc_srcdir="${withval}"
 133  AC_DEFINE_DIR(RELOC_SRCDIR, reloc_srcdir,
 134               [Relocated directory for source files. ])
 135 ])
 136
 137 AC_CONFIG_SUBDIRS(testsuite)
 138
 139 # Check whether to support alternative target configurations
 140 AC_ARG_ENABLE(targets,
 141 AS_HELP_STRING([--enable-targets=TARGETS], [alternative target configurations]),
 142 [case "${enableval}" in
 143   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
 144             ;;
 145   no)       enable_targets= ;;
 146   *)        enable_targets=$enableval ;;
 147 esac])
 148
 149 # Check whether to enable 64-bit support on 32-bit hosts
 150 AC_ARG_ENABLE(64-bit-bfd,
 151 AS_HELP_STRING([--enable-64-bit-bfd], [64-bit support (on hosts with narrower word sizes)]),
 152 [case "${enableval}" in
 153   yes)  want64=true  ;;
 154   no)   want64=false ;;
 155   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
 156 esac],[want64=false])dnl
 157
 158 # Provide defaults for some variables set by the per-host and per-target
 159 # configuration.
 160 gdb_host_obs=posix-hdep.o
 161
 162 if test "${target}" = "${host}"; then
 163   gdb_native=yes
 164 else
 165   gdb_native=no
 166 fi
 167
 168 . $srcdir/configure.host
 169
 170 # Accumulate some settings from configure.tgt over all enabled targets
 171
 172 TARGET_OBS=
 173 all_targets=
 174
 175 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 176 do
 177   if test "$targ_alias" = "all"; then
 178     all_targets=true
 179   else
 180     # Canonicalize the secondary target names.
 181     result=`$ac_config_sub $targ_alias 2>/dev/null`
 182     if test -n "$result"; then
 183         targ=$result
 184     else
 185         targ=$targ_alias
 186     fi
 187
 188     . ${srcdir}/configure.tgt
 189
 190     AS_IF([test -z "${gdb_target_obs}"],
 191       [AC_MSG_ERROR([configuration ${targ} is unsupported.])])
 192
 193     # Target-specific object files
 194     for i in ${gdb_target_obs}; do
 195         case " $TARGET_OBS " in
 196         *" ${i} "*) ;;
 197         *)
 198           TARGET_OBS="$TARGET_OBS ${i}"
 199           ;;
 200         esac
 201     done
 202
 203     # Check whether this target needs 64-bit CORE_ADDR
 204     if test x${want64} = xfalse; then
 205       . ${srcdir}/../bfd/config.bfd
 206     fi
 207   fi
 208 done
 209
 210 if test x${all_targets} = xtrue; then
 211
 212   # We want all 64-bit targets if we either:
 213   #  - run on a 64-bit host  or
 214   #  - already require 64-bit support for some other target  or
 215   #  - the --enable-64-bit-bfd option was supplied
 216   # Otherwise we only support all 32-bit targets.
 217   #
 218   # NOTE: This test must be in sync with the corresponding
 219   #       tests in BFD!
 220
 221   if test x${want64} = xfalse; then
 222     AC_CHECK_SIZEOF(long)
 223     if test "x${ac_cv_sizeof_long}" = "x8"; then
 224       want64=true
 225     fi
 226   fi
 227   if test x${want64} = xtrue; then
 228     TARGET_OBS='$(ALL_TARGET_OBS) $(ALL_64_TARGET_OBS)'
 229   else
 230     TARGET_OBS='$(ALL_TARGET_OBS)'
 231   fi
 232 fi
 233
 234 AC_SUBST(TARGET_OBS)
 235
 236 # For other settings, only the main target counts.
 237 gdb_sim=
 238 gdb_osabi=
 239 build_gdbserver=
 240 targ=$target; . ${srcdir}/configure.tgt
 241
 242 # Fetch the default architecture and default target vector from BFD.
 243 targ=$target; . $srcdir/../bfd/config.bfd
 244
 245 # We only want the first architecture, so strip off the others if
 246 # there is more than one.
 247 targ_archs=`echo $targ_archs | sed 's/ .*//'`
 248
 249 if test "x$targ_archs" != x; then
 250   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
 251     [Define to BFD's default architecture. ])
 252 fi
 253 if test "x$targ_defvec" != x; then
 254   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
 255     [Define to BFD's default target vector. ])
 256 fi
 257
 258 # The CLI cannot be disabled yet, but may be in the future.
 259
 260 # Enable CLI.
 261 AC_ARG_ENABLE(gdbcli,
 262 AS_HELP_STRING([--disable-gdbcli], [disable command-line interface (CLI)]),
 263   [case $enableval in
 264     yes)
 265       ;;
 266     no)
 267       AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;;
 268     *)
 269       AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;;
 270   esac],
 271   [enable_gdbcli=yes])
 272 if test x"$enable_gdbcli" = xyes; then
 273   if test -d $srcdir/cli; then
 274     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)"
 275     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)"
 276     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)"
 277     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)"
 278   fi
 279 fi
 280
 281 # Enable MI.
 282 AC_ARG_ENABLE(gdbmi,
 283 AS_HELP_STRING([--disable-gdbmi], [disable machine-interface (MI)]),
 284   [case $enableval in
 285     yes | no)
 286       ;;
 287     *)
 288       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 289   esac],
 290   [enable_gdbmi=yes])
 291 if test x"$enable_gdbmi" = xyes; then
 292   if test -d $srcdir/mi; then
 293     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 294     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 295     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 296     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 297   fi
 298 fi
 299
 300 # Enable TUI.
 301 AC_ARG_ENABLE(tui,
 302 AS_HELP_STRING([--enable-tui], [enable full-screen terminal user interface (TUI)]),
 303   [case $enableval in
 304     yes | no | auto)
 305       ;;
 306     *)
 307       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 308   esac],enable_tui=auto)
 309
 310 # Enable gdbtk.
 311 AC_ARG_ENABLE(gdbtk,
 312 AS_HELP_STRING([--enable-gdbtk], [enable gdbtk graphical user interface (GUI)]),
 313   [case $enableval in
 314     yes | no)
 315       ;;
 316     *)
 317       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 318   esac],
 319   [if test -d $srcdir/gdbtk; then
 320     enable_gdbtk=yes
 321   else
 322     enable_gdbtk=no
 323   fi])
 324 # We unconditionally disable gdbtk tests on selected platforms.
 325 case $host_os in
 326   go32* | windows*)
 327     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 328     enable_gdbtk=no ;;
 329 esac
 330
 331 # Libunwind support for ia64.
 332
 333 AC_ARG_WITH(libunwind-ia64,
 334 AS_HELP_STRING([--with-libunwind-ia64],
 335                [use libunwind frame unwinding for ia64 targets]),,
 336             [with_libunwind_ia64=auto])
 337
 338 # Backward compatibility option.
 339 if test "${with_libunwind+set}" = set; then
 340   if test x"$with_libunwind_ia64" != xauto; then
 341     AC_MSG_ERROR(
 342       [option --with-libunwind is deprecated, use --with-libunwind-ia64])
 343   fi
 344   AC_MSG_WARN([option --with-libunwind is deprecated, use --with-libunwind-ia64])
 345   with_libunwind_ia64="$with_libunwind"
 346 fi
 347
 348 case "$with_libunwind_ia64" in
 349   yes | no)
 350     ;;
 351   auto)
 352     AC_CHECK_HEADERS(libunwind-ia64.h)
 353     with_libunwind_ia64=$ac_cv_header_libunwind_ia64_h
 354     ;;
 355   *)
 356     AC_MSG_ERROR(
 357       [bad value $with_libunwind_ia64 for GDB --with-libunwind-ia64 option])
 358     ;;
 359 esac
 360
 361 if test x"$with_libunwind_ia64" = xyes; then
 362   AC_CHECK_HEADERS(libunwind-ia64.h)
 363   if test x"$ac_cv_header_libunwind_ia64_h" != xyes; then
 364     AC_MSG_ERROR([GDB option --with-libunwind-ia64 requires libunwind-ia64.h])
 365   fi
 366   CONFIG_OBS="$CONFIG_OBS ia64-libunwind-tdep.o"
 367   CONFIG_DEPS="$CONFIG_DEPS ia64-libunwind-tdep.o"
 368   CONFIG_SRCS="$CONFIG_SRCS ia64-libunwind-tdep.c"
 369 fi
 370
 371 opt_curses=no
 372 AC_ARG_WITH(curses, AS_HELP_STRING([--with-curses], [use the curses library instead of the termcap library]), opt_curses=$withval)
 373
 374 prefer_curses=no
 375 if test "$opt_curses" = "yes"; then
 376   prefer_curses=yes
 377 fi
 378
 379 # Profiling support.
 380 AC_ARG_ENABLE(profiling,
 381 AS_HELP_STRING([--enable-profiling], [enable profiling of GDB]),
 382   [case $enableval in
 383     yes | no)
 384       ;;
 385     *)
 386       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 387   esac],
 388  [enable_profiling=no])
 389
 390 AC_CHECK_FUNCS(monstartup _mcleanup)
 391 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 392 [AC_TRY_LINK(
 393 [#include <stdlib.h>
 394 extern char _etext;
 395 ],
 396 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 397 if test $ac_cv_var__etext = yes; then
 398   AC_DEFINE(HAVE__ETEXT, 1,
 399             [Define to 1 if your system has the _etext variable. ])
 400 fi
 401 AC_CACHE_CHECK([for etext], ac_cv_var_etext,
 402 [AC_TRY_LINK(
 403 [#include <stdlib.h>
 404 extern char etext;
 405 ],
 406 [free (&etext);], ac_cv_var_etext=yes, ac_cv_var_etext=no)])
 407 if test $ac_cv_var_etext = yes; then
 408   AC_DEFINE(HAVE_ETEXT, 1,
 409             [Define to 1 if your system has the etext variable. ])
 410 fi
 411 if test "$enable_profiling" = yes ; then
 412   if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
 413     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 414   fi
 415   PROFILE_CFLAGS=-pg
 416   OLD_CFLAGS="$CFLAGS"
 417   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 418
 419   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 420     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 421      ac_cv_cc_supports_pg=no)])
 422
 423   if test $ac_cv_cc_supports_pg = no; then
 424     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 425   fi
 426
 427   CFLAGS="$OLD_CFLAGS"
 428 fi
 429
 430 ACX_PKGVERSION([GDB])
 431 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 432 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 433 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 434
 435 # --------------------- #
 436 # Checks for programs.  #
 437 # --------------------- #
 438
 439 AC_PROG_AWK
 440 AC_PROG_INSTALL
 441 AC_PROG_LN_S
 442 AC_PROG_RANLIB
 443 AC_PROG_YACC
 444
 445 AC_CHECK_TOOL(AR, ar)
 446 AC_CHECK_TOOL(DLLTOOL, dlltool)
 447 AC_CHECK_TOOL(WINDRES, windres)
 448
 449 # Needed for GNU/Hurd.
 450 AC_CHECK_TOOL(MIG, mig)
 451
 452 # ---------------------- #
 453 # Checks for libraries.  #
 454 # ---------------------- #
 455
 456 # We might need to link with -lm; most simulators need it.
 457 AC_CHECK_LIB(m, main)
 458
 459 # We need to link with -lw to get `wctype' on Solaris before Solaris
 460 # 2.6.  Solaris 2.6 and beyond have this function in libc, and have a
 461 # libw that some versions of the GNU linker cannot hanle (GNU ld 2.9.1
 462 # is known to have this problem).  Therefore we avoid libw if we can.
 463 AC_CHECK_FUNC(wctype, [],
 464   [AC_CHECK_LIB(w, wctype)])
 465
 466 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 467 AC_SEARCH_LIBS(gethostbyname, nsl)
 468
 469 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 470 AC_SEARCH_LIBS(socketpair, socket)
 471
 472 # Link in zlib if we can.  This allows us to read compressed debug sections.
 473 AM_ZLIB
 474
 475 # On HP/UX we may need libxpdl for dlgetmodinfo (used by solib-pa64.c).
 476 AC_SEARCH_LIBS(dlgetmodinfo, [dl xpdl])
 477
 478 AM_ICONV
 479
 480 # GDB may fork/exec the iconv program to get the list of supported character
 481 # sets.  Allow the user to specify where to find it.
 482 # There are several factors affecting the choice of option name:
 483 # - There is already --with-libiconv-prefix but we can't use it, it specifies
 484 #   the build-time location of libiconv files.
 485 # - The program we need to find is iconv, which comes with glibc.  The user
 486 #   doesn't necessarily have libiconv installed.  Therefore naming this
 487 #   --with-libiconv-foo feels wrong.
 488 # - We want the path to be relocatable, but GDB_AC_DEFINE_RELOCATABLE is
 489 #   defined to work on directories not files (though it really doesn't know
 490 #   the difference).
 491 # - Calling this --with-iconv-prefix is perceived to cause too much confusion
 492 #   with --with-libiconv-prefix.
 493 # Putting these together is why the option name is --with-iconv-bin.
 494
 495 AC_ARG_WITH(iconv-bin,
 496 AS_HELP_STRING([--with-iconv-bin=PATH], [specify where to find the iconv program]),
 497 [iconv_bin="${withval}"
 498  AC_DEFINE_UNQUOTED([ICONV_BIN], ["${iconv_bin}"],
 499                     [Path of directory of iconv program.])
 500  GDB_AC_DEFINE_RELOCATABLE(ICONV_BIN, iconv, ${iconv_bin})
 501 ])
 502
 503 # On alpha-osf, it appears that libtermcap and libcurses are not compatible.
 504 # There is a very specific comment in /usr/include/curses.h explaining that
 505 # termcap routines built into libcurses must not be used.
 506 #
 507 # The symptoms we observed so far is GDB unexpectedly changing
 508 # the terminal settings when tgetent is called - this is particularly
 509 # visible as the output is missing carriage returns, and so rapidly
 510 # becomes very hard to read.
 511 #
 512 # The readline configure script has already decided that libtermcap
 513 # was enough for its purposes, and so decided to build readline using
 514 # libtermcap.  Since the TUI mode requires curses, building GDB with
 515 # TUI enabled results in both libraries to be used at the same time,
 516 # which is not allowed.  This basically means that GDB with TUI is
 517 # broken on alpha-osf.
 518
 519 case $host_os in
 520   osf* )
 521     if test x"$enable_tui" = xyes; then
 522       AC_MSG_ERROR([Building GDB with TUI mode is not supported on this host])
 523     fi
 524     if test x"$enable_tui" = xauto; then
 525       enable_tui=no
 526     fi
 527     ;;
 528 esac
 529
 530 # For the TUI, we need enhanced curses functionality.
 531 if test x"$enable_tui" != xno; then
 532   prefer_curses=yes
 533 fi
 534
 535 curses_found=no
 536 if test x"$prefer_curses" = xyes; then
 537   # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
 538   # curses library because the latter might not provide all the
 539   # functionality we need.  However, this leads to problems on systems
 540   # where the linker searches /usr/local/lib, but the compiler doesn't
 541   # search /usr/local/include, if ncurses is installed in /usr/local.  A
 542   # default installation of ncurses on alpha*-dec-osf* will lead to such
 543   # a situation.
 544   AC_SEARCH_LIBS(waddstr, [ncurses cursesX curses])
 545
 546   if test "$ac_cv_search_waddstr" != no; then
 547     curses_found=yes
 548   fi
 549 fi
 550
 551 # Check whether we should enable the TUI, but only do so if we really
 552 # can.
 553 if test x"$enable_tui" != xno; then
 554   if test -d $srcdir/tui; then
 555     if test "$curses_found" != no; then
 556       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
 557       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
 558       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
 559       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
 560     else
 561       if test x"$enable_tui" = xyes; then
 562         AC_MSG_ERROR([no enhanced curses library found; disable TUI])
 563       else
 564         AC_MSG_WARN([no enhanced curses library found; disabling TUI])
 565       fi
 566     fi
 567   fi
 568 fi
 569
 570 # Since GDB uses Readline, we need termcap functionality.  In many
 571 # cases this will be provided by the curses library, but some systems
 572 # have a seperate termcap library, or no curses library at all.
 573
 574 case $host_os in
 575   cygwin*)
 576     if test -d $srcdir/libtermcap; then
 577       LIBS="../libtermcap/libtermcap.a $LIBS"
 578       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 579     fi ;;
 580   go32* | *djgpp*)
 581     ac_cv_search_tgetent="none required"
 582     ;;
 583   *mingw32*)
 584     ac_cv_search_tgetent="none required"
 585     CONFIG_OBS="$CONFIG_OBS windows-termcap.o"
 586     ;;
 587 esac
 588
 589 # These are the libraries checked by Readline.
 590 AC_SEARCH_LIBS(tgetent, [termcap tinfo curses ncurses])
 591
 592 if test "$ac_cv_search_tgetent" = no; then
 593   AC_MSG_ERROR([no termcap library found])
 594 fi
 595
 596 AC_ARG_WITH([system-readline],
 597   [AS_HELP_STRING([--with-system-readline],
 598                   [use installed readline library])])
 599
 600 if test "$with_system_readline" = yes; then
 601   READLINE=-lreadline
 602   READLINE_DEPS=
 603   READLINE_CFLAGS=
 604   READLINE_TEXI_INCFLAG=
 605 else
 606   READLINE='$(READLINE_DIR)/libreadline.a'
 607   READLINE_DEPS='$(READLINE)'
 608   READLINE_CFLAGS='-I$(READLINE_SRC)/..'
 609   READLINE_TEXI_INCFLAG='-I $(READLINE_DIR)'
 610 fi
 611 AC_SUBST(READLINE)
 612 AC_SUBST(READLINE_DEPS)
 613 AC_SUBST(READLINE_CFLAGS)
 614 AC_SUBST(READLINE_TEXI_INCFLAG)
 615
 616 # Generate jit-reader.h
 617
 618 # This is typedeffed to GDB_CORE_ADDR in jit-reader.h
 619 TARGET_PTR=
 620
 621 AC_CHECK_SIZEOF(unsigned long long)
 622 AC_CHECK_SIZEOF(unsigned long)
 623 AC_CHECK_SIZEOF(unsigned __int128)
 624
 625 if test "x${ac_cv_sizeof_unsigned_long}" = "x8"; then
 626   TARGET_PTR="unsigned long"
 627 elif test "x${ac_cv_sizeof_unsigned_long_long}" = "x8"; then
 628   TARGET_PTR="unsigned long long"
 629 elif test "x${ac_cv_sizeof_unsigned___int128}" = "x16"; then
 630   TARGET_PTR="unsigned __int128"
 631 else
 632   TARGET_PTR="unsigned long"
 633 fi
 634
 635 AC_SUBST(TARGET_PTR)
 636 AC_CONFIG_FILES([jit-reader.h:jit-reader.in])
 637
 638 AC_SEARCH_LIBS(dlopen, dl)
 639
 640 GDB_AC_WITH_DIR([JIT_READER_DIR], [jit-reader-dir],
 641                 [directory to load the JIT readers from],
 642                 [${libdir}/gdb])
 643
 644 AC_ARG_WITH(expat,
 645   AS_HELP_STRING([--with-expat], [include expat support (auto/yes/no)]),
 646   [], [with_expat=auto])
 647 AC_MSG_CHECKING([whether to use expat])
 648 AC_MSG_RESULT([$with_expat])
 649
 650 if test "${with_expat}" = no; then
 651   AC_MSG_WARN([expat support disabled; some features may be unavailable.])
 652   HAVE_LIBEXPAT=no
 653 else
 654   AC_LIB_HAVE_LINKFLAGS([expat], [], [#include "expat.h"],
 655                         [XML_Parser p = XML_ParserCreate (0);])
 656   if test "$HAVE_LIBEXPAT" != yes; then
 657     if test "$with_expat" = yes; then
 658       AC_MSG_ERROR([expat is missing or unusable])
 659     else
 660       AC_MSG_WARN([expat is missing or unusable; some features may be unavailable.])
 661     fi
 662   else
 663     save_LIBS=$LIBS
 664     LIBS="$LIBS $LIBEXPAT"
 665     AC_CHECK_FUNCS(XML_StopParser)
 666     LIBS=$save_LIBS
 667   fi
 668 fi
 669
 670 dnl Utility to simplify finding libpython.
 671 dnl $1 = pythonX.Y
 672 dnl $2 = the shell variable to assign the result to
 673 dnl      If libpython is found we store $version here.
 674 dnl $3 = additional flags to add to CPPFLAGS
 675 dnl $4 = additional flags to add to LIBS
 676
 677 AC_DEFUN([AC_TRY_LIBPYTHON],
 678 [
 679   version=$1
 680   define([have_libpython_var],$2)
 681   new_CPPFLAGS=$3
 682   new_LIBS=$4
 683   AC_MSG_CHECKING([for ${version}])
 684   save_CPPFLAGS=$CPPFLAGS
 685   save_LIBS=$LIBS
 686   CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
 687   LIBS="$LIBS $new_LIBS"
 688   found_usable_python=no
 689   AC_LINK_IFELSE(AC_LANG_PROGRAM([[#include "Python.h"]],
 690                                  [[Py_Initialize ();]]),
 691                  [have_libpython_var=${version}
 692                   found_usable_python=yes
 693                   PYTHON_CPPFLAGS=$new_CPPFLAGS
 694                   PYTHON_LIBS=$new_LIBS])
 695   CPPFLAGS=$save_CPPFLAGS
 696   LIBS=$save_LIBS
 697   AC_MSG_RESULT([${found_usable_python}])
 698 ])
 699
 700 dnl There are several different values for --with-python:
 701 dnl
 702 dnl no -   Don't include python support.
 703 dnl yes -  Include python support, error if it's missing.
 704 dnl        If we find python in $PATH, use it to fetch configure options,
 705 dnl        otherwise assume the compiler can find it with no help from us.
 706 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 707 dnl auto - Same as "yes", but if python is missing from the system,
 708 dnl        fall back to "no".
 709 dnl /path/to/python/exec-prefix -
 710 dnl        Use the python located in this directory.
 711 dnl        If /path/to/python/exec-prefix/bin/python exists, use it to find
 712 dnl        the compilation parameters.  Otherwise use
 713 dnl        -I/path/to/python/exec-prefix/include,
 714 dnl        -L/path/to/python/exec-prefix/lib.
 715 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 716 dnl        NOTE: This case is historical.  It is what was done for 7.0/7.1
 717 dnl        but is deprecated.
 718 dnl /path/to/python/executable -
 719 dnl        Run python-config.py with this version of python to fetch the
 720 dnl        compilation parameters.
 721 dnl        NOTE: This needn't be the real python executable.
 722 dnl        In a cross-compilation scenario (build != host), this could be
 723 dnl        a shell script that provides what python-config.py provides for
 724 dnl        --ldflags, --includes, --exec-prefix.
 725 dnl python-executable -
 726 dnl        Find python-executable in $PATH, and then handle the same as
 727 dnl        /path/to/python/executable.
 728 dnl
 729 dnl If a python program is specified, it is used to run python-config.py and
 730 dnl is passed --ldflags, --includes, --exec-prefix.
 731
 732 AC_ARG_WITH(python,
 733   AS_HELP_STRING([--with-python@<:@=PYTHON@:>@], [include python support (auto/yes/no/<python-program>)]),
 734   [], [with_python=auto])
 735 AC_MSG_CHECKING([whether to use python])
 736 AC_MSG_RESULT([$with_python])
 737
 738 if test "${with_python}" = no; then
 739   AC_MSG_WARN([python support disabled; some features may be unavailable.])
 740   have_libpython=no
 741 else
 742   case "${with_python}" in
 743   [[\\/]]* | ?:[[\\/]]*)
 744     if test -d ${with_python}; then
 745       # Assume the python binary is ${with_python}/bin/python.
 746       python_prog="${with_python}/bin/python"
 747       python_prefix=
 748       # If python does not exit ${with_python}/bin, then try in
 749       # ${with_python}.  On Windows/MinGW, this is where the Python
 750       # executable is.
 751       if test ! -x "${python_prog}"; then
 752         python_prog="${with_python}/python"
 753         python_prefix=
 754       fi
 755       if test ! -x "${python_prog}"; then
 756         # Fall back to gdb 7.0/7.1 behaviour.
 757         python_prog=missing
 758         python_prefix=${with_python}
 759       fi
 760     elif test -x "${with_python}"; then
 761       # While we can't run python compiled for $host (unless host == build),
 762       # the user could write a script that provides the needed information,
 763       # so we support that.
 764       python_prog=${with_python}
 765       python_prefix=
 766     else
 767       AC_ERROR(invalid value for --with-python)
 768     fi
 769     ;;
 770   */*)
 771     # Disallow --with-python=foo/bar.
 772     AC_ERROR(invalid value for --with-python)
 773     ;;
 774   *)
 775     # The user has either specified auto, yes, or the name of the python
 776     # program assumed to be in $PATH.
 777     python_prefix=
 778     case "${with_python}" in
 779     yes | auto)
 780       if test ${build} = ${host}; then
 781         AC_PATH_PROG(python_prog_path, python, missing)
 782         if test "${python_prog_path}" = missing; then
 783           python_prog=missing
 784         else
 785           python_prog=${python_prog_path}
 786         fi
 787       else
 788         # Not much we can do except assume the cross-compiler will find the
 789         # right files.
 790         python_prog=missing
 791       fi
 792       ;;
 793     *)
 794       # While we can't run python compiled for $host (unless host == build),
 795       # the user could write a script that provides the needed information,
 796       # so we support that.
 797       python_prog="${with_python}"
 798       AC_PATH_PROG(python_prog_path, ${python_prog}, missing)
 799       if test "${python_prog_path}" = missing; then
 800         AC_ERROR(unable to find python program ${python_prog})
 801       fi
 802       ;;
 803     esac
 804   esac
 805
 806   if test "${python_prog}" != missing; then
 807     # We have a python program to use, but it may be too old.
 808     # Don't flag an error for --with-python=auto (the default).
 809     have_python_config=yes
 810     python_includes=`${python_prog} ${srcdir}/python/python-config.py --includes`
 811     if test $? != 0; then
 812       have_python_config=failed
 813       if test "${with_python}" != auto; then
 814         AC_ERROR(failure running python-config --includes)
 815       fi
 816     fi
 817     python_libs=`${python_prog} ${srcdir}/python/python-config.py --ldflags`
 818     if test $? != 0; then
 819       have_python_config=failed
 820       if test "${with_python}" != auto; then
 821         AC_ERROR(failure running python-config --ldflags)
 822       fi
 823     fi
 824     python_prefix=`${python_prog} ${srcdir}/python/python-config.py --exec-prefix`
 825     if test $? != 0; then
 826       have_python_config=failed
 827       if test "${with_python}" != auto; then
 828         AC_ERROR(failure running python-config --exec-prefix)
 829       fi
 830     fi
 831   else
 832     # We do not have a python executable we can use to determine where
 833     # to find the Python headers and libs.  We cannot guess the include
 834     # path from the python_prefix either, because that include path
 835     # depends on the Python version.  So, there is nothing much we can
 836     # do except assume that the compiler will be able to find those files.
 837     python_includes=
 838     python_libs=
 839     have_python_config=no
 840   fi
 841
 842   # If we have python-config, only try the configuration it provides.
 843   # Otherwise fallback on the old way of trying different versions of
 844   # python in turn.
 845
 846   have_libpython=no
 847   if test "${have_python_config}" = yes; then
 848     # Determine the Python version by extracting "-lpython<version>"
 849     # part of the python_libs. <version> is usually X.Y with X and Y
 850     # being decimal numbers, but can also be XY (seen on Windows).
 851     #
 852     # The extraction is performed using sed with a regular expression.
 853     # Initially, the regexp used was using the '?' quantifier to make
 854     # the dot in the version number optional.  Unfortunately, this
 855     # does not work with non-GNU versions of sed because, because of
 856     # what looks like a limitation (the '?' quantifier does not work
 857     # with back-references).  We work around this limitation by using
 858     # the '*' quantifier instead.  It means that, in theory, we might
 859     # match unexpected version strings such as "-lpython2..7", but
 860     # this seems unlikely in practice.  And even if that happens,
 861     # an error will be triggered later on, when checking that version
 862     # number.
 863     python_version=`echo " ${python_libs} " \
 864                          | sed -e 's,^.* -l\(python[[0-9]]*[[.]]*[[0-9]]*\).*$,\1,'`
 865     case "${python_version}" in
 866     python*)
 867       AC_TRY_LIBPYTHON(${python_version}, have_libpython,
 868                        ${python_includes}, ${python_libs})
 869       ;;
 870     *)
 871       AC_MSG_ERROR([unable to determine python version from ${python_libs}])
 872       ;;
 873     esac
 874   elif test "${have_python_config}" != failed; then
 875     if test "${have_libpython}" = no; then
 876       AC_TRY_LIBPYTHON(python2.7, have_libpython,
 877                        ${python_includes}, "${python_libs} -lpython2.7")
 878     fi
 879     if test "${have_libpython}" = no; then
 880       AC_TRY_LIBPYTHON(python2.6, have_libpython,
 881                        ${python_includes}, "${python_libs} -lpython2.6")
 882     fi
 883     if test ${have_libpython} = no; then
 884       AC_TRY_LIBPYTHON(python2.5, have_libpython,
 885                        ${python_includes}, "${python_libs} -lpython2.5")
 886     fi
 887     if test ${have_libpython} = no; then
 888       AC_TRY_LIBPYTHON(python2.4, have_libpython,
 889                        ${python_includes}, "${python_libs} -lpython2.4")
 890     fi
 891   fi
 892   if test "${have_libpython}" = python2.7 -o "${have_libpython}" = python27; then
 893     AC_DEFINE(HAVE_LIBPYTHON2_7, 1, [Define if Python 2.7 is being used.])
 894   elif test "${have_libpython}" = python2.6 -o "${have_libpython}" = python26; then
 895     AC_DEFINE(HAVE_LIBPYTHON2_6, 1, [Define if Python 2.6 is being used.])
 896   elif test "${have_libpython}" = python2.5 -o "${have_libpython}" = python25; then
 897     AC_DEFINE(HAVE_LIBPYTHON2_5, 1, [Define if Python 2.5 is being used.])
 898   elif test "${have_libpython}" = python2.4 -o "${have_libpython}" = python24; then
 899     AC_DEFINE(HAVE_LIBPYTHON2_4, 1, [Define if Python 2.4 is being used.])
 900   fi
 901
 902   if test "${have_libpython}" = no; then
 903     case "${with_python}" in
 904     yes)
 905       AC_MSG_ERROR([python is missing or unusable])
 906       ;;
 907     auto)
 908       AC_MSG_WARN([python is missing or unusable; some features may be unavailable.])
 909       ;;
 910     *)
 911       AC_MSG_ERROR([no usable python found at ${with_python}])
 912       ;;
 913     esac
 914   else
 915     if test -n "${python_prefix}"; then
 916       AC_DEFINE_UNQUOTED(WITH_PYTHON_PATH, "${python_prefix}",
 917                          [Define if --with-python provides a path, either directly or via python-config.py --exec-prefix.])
 918       GDB_AC_DEFINE_RELOCATABLE(PYTHON_PATH, python, ${python_prefix})
 919     fi
 920   fi
 921 fi
 922
 923 if test "${have_libpython}" != no; then
 924   AC_DEFINE(HAVE_PYTHON, 1, [Define if Python interpreter is being linked in.])
 925   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_PYTHON_OBS)"
 926   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_PYTHON_DEPS)"
 927   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_PYTHON_SRCS)"
 928   CONFIG_INSTALL="$CONFIG_INSTALL install-python"
 929   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_PYTHON_CFLAGS)"
 930
 931   # Flags needed to compile Python code (taken from python-config --cflags).
 932   # We cannot call python-config directly because it will output whatever was
 933   # used when compiling the Python interpreter itself, including flags which
 934   # would make the python-related objects be compiled differently from the
 935   # rest of GDB (e.g., -O2 and -fPIC).
 936   if test "${GCC}" = yes; then
 937     tentative_python_cflags="-fno-strict-aliasing -DNDEBUG -fwrapv"
 938   fi
 939
 940   if test "x${tentative_python_cflags}" != x; then
 941     AC_MSG_CHECKING(compiler flags for python code)
 942     for flag in ${tentative_python_cflags}; do
 943       # Check that the compiler accepts it
 944       saved_CFLAGS="$CFLAGS"
 945       CFLAGS="$CFLAGS $flag"
 946       AC_TRY_COMPILE([],[],PYTHON_CFLAGS="${PYTHON_CFLAGS} $flag",)
 947       CFLAGS="$saved_CFLAGS"
 948     done
 949     AC_MSG_RESULT(${PYTHON_CFLAGS})
 950   fi
 951
 952   # On IRIX, type siginfo is not defined.  Instead, sys/siginfo.h provides:
 953   #    #if _SGIAPI
 954   #    #define siginfo __siginfo
 955   #    #endif
 956   # The problem is that including Python causes some XOPEN macros to be
 957   # unilaterally defined, and that in turn causes _SGIAPI to evaluate
 958   # to false.  So, we work around this issue by defining siginfo ourself
 959   # though the command-line.
 960   case "$gdb_host" in
 961     irix*) if test "${GCC}" = yes; then
 962              CPPFLAGS="$CPPFLAGS -Dsiginfo=__siginfo"
 963            fi
 964            ;;
 965   esac
 966 else
 967   # Even if Python support is not compiled in, we need to have these files
 968   # included.
 969   CONFIG_OBS="$CONFIG_OBS python.o py-value.o py-prettyprint.o py-auto-load.o"
 970   CONFIG_SRCS="$CONFIG_SRCS python/python.c python/py-value.c \
 971         python/py-prettyprint.c python/py-auto-load.c"
 972 fi
 973 AC_SUBST(PYTHON_CFLAGS)
 974 AC_SUBST(PYTHON_CPPFLAGS)
 975 AC_SUBST(PYTHON_LIBS)
 976
 977 # ------------------------- #
 978 # Checks for header files.  #
 979 # ------------------------- #
 980
 981 AC_HEADER_DIRENT
 982 AC_HEADER_STAT
 983 AC_HEADER_STDC
 984 # elf_hp.h is for HP/UX 64-bit shared library support.
 985 # FIXME: kettenis/20030102: In most cases we include these (ctype.h, time.h)
 986 # unconditionally, so what's the point in checking these?
 987 AC_CHECK_HEADERS([nlist.h machine/reg.h poll.h sys/poll.h proc_service.h \
 988                   thread_db.h gnu/libc-version.h signal.h stddef.h \
 989                   stdlib.h string.h memory.h strings.h sys/fault.h \
 990                   sys/file.h sys/filio.h sys/ioctl.h sys/param.h \
 991                   sys/resource.h sys/procfs.h sys/ptrace.h ptrace.h \
 992                   sys/reg.h sys/debugreg.h sys/select.h sys/syscall.h \
 993                   sys/types.h sys/wait.h wait.h termios.h termio.h \
 994                   sgtty.h unistd.h elf_hp.h ctype.h time.h locale.h \
 995                   dlfcn.h sys/socket.h sys/un.h])
 996 AC_CHECK_HEADERS(link.h, [], [],
 997 [#if HAVE_SYS_TYPES_H
 998 # include <sys/types.h>
 999 #endif
1000 #if HAVE_NLIST_H
1001 # include <nlist.h>
1002 #endif
1003 ])
1004 AC_CHECK_HEADERS(sys/proc.h, [], [],
1005 [#if HAVE_SYS_PARAM_H
1006 # include <sys/param.h>
1007 #endif
1008 ])
1009 AC_CHECK_HEADERS(sys/user.h, [], [],
1010 [#if HAVE_SYS_PARAM_H
1011 # include <sys/param.h>
1012 #endif
1013 ])
1014
1015 # On Solaris 2.[789], we need to define _MSE_INT_H to avoid a clash
1016 # between <widec.h> and <wchar.h> that would cause AC_CHECK_HEADERS to
1017 # think that we don't have <curses.h> if we're using GCC.
1018 case $host_os in
1019   solaris2.[[789]])
1020     if test "$GCC" = yes; then
1021       AC_DEFINE(_MSE_INT_H, 1,
1022         [Define to 1 to avoid a clash between <widec.h> and <wchar.h> on
1023    Solaris 2.[789] when using GCC. ])
1024     fi ;;
1025 esac
1026 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncurses/ncurses.h ncurses/term.h)
1027 AC_CHECK_HEADERS(term.h, [], [],
1028 [#if HAVE_CURSES_H
1029 # include <curses.h>
1030 #endif
1031 ])
1032
1033 # ------------------------- #
1034 # Checks for declarations.  #
1035 # ------------------------- #
1036
1037 AC_CHECK_DECLS([free, malloc, realloc, strerror, strstr, getopt,
1038                 snprintf, vsnprintf])
1039 AM_LC_MESSAGES
1040
1041 # ----------------------- #
1042 # Checks for structures.  #
1043 # ----------------------- #
1044
1045 AC_CHECK_MEMBERS([struct stat.st_blocks, struct stat.st_blksize])
1046
1047 # ------------------ #
1048 # Checks for types.  #
1049 # ------------------ #
1050
1051 AC_TYPE_SIGNAL
1052 AC_CHECK_TYPES(socklen_t, [], [],
1053 [#include <sys/types.h>
1054 #include <sys/socket.h>
1055 ])
1056
1057 # ------------------------------------- #
1058 # Checks for compiler characteristics.  #
1059 # ------------------------------------- #
1060
1061 AC_C_CONST
1062 AC_C_INLINE
1063 AC_C_BIGENDIAN
1064
1065 # ------------------------------ #
1066 # Checks for library functions.  #
1067 # ------------------------------ #
1068
1069 AC_FUNC_ALLOCA
1070 AC_FUNC_MMAP
1071 AC_FUNC_VFORK
1072 AC_CHECK_FUNCS([canonicalize_file_name realpath getrusage getuid getgid \
1073                 pipe poll pread pread64 pwrite readlink resize_term \
1074                 sbrk setpgid setpgrp setsid \
1075                 sigaction sigprocmask sigsetmask socketpair syscall \
1076                 ttrace wborder wresize setlocale iconvlist libiconvlist btowc \
1077                 setrlimit getrlimit posix_madvise waitpid lstat])
1078 AM_LANGINFO_CODESET
1079
1080 # Check the return and argument types of ptrace.  No canned test for
1081 # this, so roll our own.
1082 gdb_ptrace_headers='
1083 #if HAVE_SYS_TYPES_H
1084 # include <sys/types.h>
1085 #endif
1086 #if HAVE_SYS_PTRACE_H
1087 # include <sys/ptrace.h>
1088 #endif
1089 #if HAVE_UNISTD_H
1090 # include <unistd.h>
1091 #endif
1092 '
1093 # There is no point in checking if we don't have a prototype.
1094 AC_CHECK_DECLS(ptrace, [], [
1095   : ${gdb_cv_func_ptrace_ret='int'}
1096   : ${gdb_cv_func_ptrace_args='int,int,long,long'}
1097 ], $gdb_ptrace_headers)
1098 # Check return type.  Varargs (used on GNU/Linux) conflict with the
1099 # empty argument list, so check for that explicitly.
1100 AC_CACHE_CHECK([return type of ptrace], gdb_cv_func_ptrace_ret,
1101   AC_TRY_COMPILE($gdb_ptrace_headers,
1102     [extern long ptrace (enum __ptrace_request, ...);],
1103     gdb_cv_func_ptrace_ret='long',
1104     AC_TRY_COMPILE($gdb_ptrace_headers,
1105       [extern int ptrace ();],
1106       gdb_cv_func_ptrace_ret='int',
1107       gdb_cv_func_ptrace_ret='long')))
1108 AC_DEFINE_UNQUOTED(PTRACE_TYPE_RET, $gdb_cv_func_ptrace_ret,
1109   [Define as the return type of ptrace.])
1110 # Check argument types.
1111 AC_CACHE_CHECK([types of arguments for ptrace], gdb_cv_func_ptrace_args, [
1112   AC_TRY_COMPILE($gdb_ptrace_headers,
1113     [extern long ptrace (enum __ptrace_request, ...);],
1114     [gdb_cv_func_ptrace_args='int,int,long,long'],[
1115 for gdb_arg1 in 'int' 'long'; do
1116  for gdb_arg2 in 'pid_t' 'int' 'long'; do
1117   for gdb_arg3 in 'int *' 'caddr_t' 'int' 'long' 'void *'; do
1118    for gdb_arg4 in 'int' 'long'; do
1119      AC_TRY_COMPILE($gdb_ptrace_headers, [
1120 extern $gdb_cv_func_ptrace_ret
1121   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4);
1122 ], [gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4";
1123     break 4;])
1124     for gdb_arg5 in 'int *' 'int' 'long'; do
1125      AC_TRY_COMPILE($gdb_ptrace_headers, [
1126 extern $gdb_cv_func_ptrace_ret
1127   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4, $gdb_arg5);
1128 ], [
1129 gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4,$gdb_arg5";
1130     break 5;])
1131     done
1132    done
1133   done
1134  done
1135 done
1136 # Provide a safe default value.
1137 : ${gdb_cv_func_ptrace_args='int,int,long,long'}
1138 ])])
1139 ac_save_IFS=$IFS; IFS=','
1140 set dummy `echo "$gdb_cv_func_ptrace_args" | sed 's/\*/\*/g'`
1141 IFS=$ac_save_IFS
1142 shift
1143 AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG3, $[3],
1144   [Define to the type of arg 3 for ptrace.])
1145 if test -n "$[5]"; then
1146   AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG5, $[5],
1147     [Define to the type of arg 5 for ptrace.])
1148 fi
1149
1150 dnl AC_FUNC_SETPGRP does not work when cross compiling
1151 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
1152 if test "$cross_compiling" = no; then
1153   AC_FUNC_SETPGRP
1154 else
1155   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
1156     [AC_TRY_COMPILE([
1157 #include <unistd.h>
1158 ], [
1159   if (setpgrp(1,1) == -1)
1160     exit (0);
1161   else
1162     exit (1);
1163 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
1164 if test $ac_cv_func_setpgrp_void = yes; then
1165   AC_DEFINE(SETPGRP_VOID, 1)
1166 fi
1167 fi
1168
1169 # Check if sigsetjmp is available.  Using AC_CHECK_FUNCS won't do
1170 # since sigsetjmp might only be defined as a macro.
1171 AC_CACHE_CHECK([for sigsetjmp], gdb_cv_func_sigsetjmp,
1172 [AC_TRY_COMPILE([
1173 #include <setjmp.h>
1174 ], [sigjmp_buf env; while (! sigsetjmp (env, 1)) siglongjmp (env, 1);],
1175 gdb_cv_func_sigsetjmp=yes, gdb_cv_func_sigsetjmp=no)])
1176 if test $gdb_cv_func_sigsetjmp = yes; then
1177   AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available. ])
1178 fi
1179
1180 # Assume we'll default to using the included libiberty regex.
1181 gdb_use_included_regex=yes
1182
1183 # However, if the system regex is GNU regex, then default to *not*
1184 # using the included regex.
1185 AC_CACHE_CHECK(
1186   [for GNU regex],
1187   [gdb_cv_have_gnu_regex],
1188   [AC_TRY_COMPILE(
1189     [#include <gnu-versions.h>],
1190     [#define REGEX_INTERFACE_VERSION 1
1191 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
1192 # error "Version mismatch"
1193 #endif],
1194     gdb_cv_have_gnu_regex=yes,
1195     gdb_cv_have_gnu_regex=no)])
1196 if test $gdb_cv_have_gnu_regex = yes; then
1197   gdb_use_included_regex=no
1198 fi
1199
1200 AC_ARG_WITH(included-regex,
1201   AS_HELP_STRING([--without-included-regex], [don't use included regex; this is the default on systems with version 2 of the GNU C library (use with caution on other system)]),
1202   gdb_with_regex=$withval,
1203   gdb_with_regex=$gdb_use_included_regex)
1204 if test "$gdb_with_regex" = yes; then
1205   AC_DEFINE(USE_INCLUDED_REGEX, 1,
1206     [Define to 1 if the regex included in libiberty should be used.])
1207 fi
1208
1209 # Check if <sys/proc.h> defines `struct thread' with a td_pcb member.
1210 AC_CHECK_MEMBERS([struct thread.td_pcb], [], [],
1211 [#include <sys/param.h>
1212 #include <sys/proc.h>
1213 ])
1214
1215 # See if <sys/lwp.h> defines `struct lwp`.
1216 AC_CACHE_CHECK([for struct lwp], gdb_cv_struct_lwp,
1217 [AC_TRY_COMPILE([#include <sys/param.h>
1218 #include <sys/lwp.h>], [struct lwp l;],
1219 gdb_cv_struct_lwp=yes, gdb_cv_struct_lwp=no)])
1220 if test $gdb_cv_struct_lwp = yes; then
1221   AC_DEFINE(HAVE_STRUCT_LWP, 1,
1222             [Define to 1 if your system has struct lwp.])
1223 fi
1224
1225 # See if <machine/reg.h> degines `struct reg'.
1226 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
1227 [AC_TRY_COMPILE([#include <sys/types.h>
1228 #include <machine/reg.h>], [struct reg r;],
1229 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
1230 if test $gdb_cv_struct_reg = yes; then
1231   AC_DEFINE(HAVE_STRUCT_REG, 1,
1232             [Define to 1 if your system has struct reg in <machine/reg.h>.])
1233 fi
1234
1235 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
1236 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
1237 AC_CHECK_MEMBERS([struct reg.r_fs, struct reg.r_gs], [], [],
1238                  [#include <machine/reg.h>])
1239
1240 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
1241 AC_MSG_CHECKING(for PTRACE_GETREGS)
1242 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
1243 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1244                 [PTRACE_GETREGS;],
1245                 [gdb_cv_have_ptrace_getregs=yes],
1246                 [gdb_cv_have_ptrace_getregs=no])])
1247 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
1248 if test $gdb_cv_have_ptrace_getregs = yes; then
1249   AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
1250   [Define if sys/ptrace.h defines the PTRACE_GETREGS request.])
1251 fi
1252
1253 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
1254 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
1255 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
1256 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1257                 [PTRACE_GETFPXREGS;],
1258                 [gdb_cv_have_ptrace_getfpxregs=yes],
1259                 [gdb_cv_have_ptrace_getfpxregs=no])])
1260 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
1261 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
1262   AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
1263   [Define if sys/ptrace.h defines the PTRACE_GETFPXREGS request.])
1264 fi
1265
1266 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
1267 AC_MSG_CHECKING(for PT_GETDBREGS)
1268 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
1269 [AC_TRY_COMPILE([#include <sys/types.h>
1270 #include <sys/ptrace.h>],
1271                 [PT_GETDBREGS;],
1272                 [gdb_cv_have_pt_getdbregs=yes],
1273                 [gdb_cv_have_pt_getdbregs=no])])
1274 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
1275 if test $gdb_cv_have_pt_getdbregs = yes; then
1276   AC_DEFINE(HAVE_PT_GETDBREGS, 1,
1277   [Define if sys/ptrace.h defines the PT_GETDBREGS request.])
1278 fi
1279
1280 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
1281 AC_MSG_CHECKING(for PT_GETXMMREGS)
1282 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
1283 [AC_TRY_COMPILE([#include <sys/types.h>
1284 #include <sys/ptrace.h>],
1285                 [PT_GETXMMREGS;],
1286                 [gdb_cv_have_pt_getxmmregs=yes],
1287                 [gdb_cv_have_pt_getxmmregs=no])])
1288 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
1289 if test $gdb_cv_have_pt_getxmmregs = yes; then
1290   AC_DEFINE(HAVE_PT_GETXMMREGS, 1,
1291   [Define if sys/ptrace.h defines the PT_GETXMMREGS request.])
1292 fi
1293
1294 # Detect which type of /proc is in use, such as for Unixware or Solaris.
1295
1296 if test "${target}" = "${host}"; then
1297   case "${host}" in
1298   *-*-unixware* | *-*-sysv4.2* | *-*-sysv5* | *-*-interix* )
1299       AC_DEFINE(NEW_PROC_API, 1,
1300       [Define if you want to use new multi-fd /proc interface
1301        (replaces HAVE_MULTIPLE_PROC_FDS as well as other macros).])
1302       ;;
1303   *-*-solaris2.[[6789]] | *-*-solaris2.1[[0-9]]*)
1304       AC_DEFINE(NEW_PROC_API, 1,
1305       [Define if you want to use new multi-fd /proc interface
1306        (replaces HAVE_MULTIPLE_PROC_FDS as well as other macros).])
1307       ;;
1308   mips-sgi-irix5*)
1309       # Work around <sys/proc.h> needing _KMEMUSER problem on IRIX 5.
1310       AC_DEFINE([_KMEMUSER], 1,
1311       [Define to 1 so <sys/proc.h> gets a definition of anon_hdl.  Works
1312        around a <sys/proc.h> problem on IRIX 5.])
1313       ;;
1314   esac
1315 fi
1316
1317 if test "$ac_cv_header_sys_procfs_h" = yes; then
1318   BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
1319   BFD_HAVE_SYS_PROCFS_TYPE(prrun_t)
1320   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
1321   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
1322   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
1323   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
1324   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
1325   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset32_t)
1326   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
1327   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
1328   BFD_HAVE_SYS_PROCFS_TYPE(prsysent_t)
1329   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigset_t)
1330   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigaction64_t)
1331   BFD_HAVE_SYS_PROCFS_TYPE(pr_siginfo64_t)
1332
1333
1334   dnl Check for broken prfpregset_t type
1335
1336   dnl For Linux/i386, glibc 2.1.3 was released with a bogus
1337   dnl prfpregset_t type (it's a typedef for the pointer to a struct
1338   dnl instead of the struct itself).  We detect this here, and work
1339   dnl around it in gdb_proc_service.h.
1340
1341   if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
1342     AC_MSG_CHECKING(whether prfpregset_t type is broken)
1343     AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
1344       [AC_TRY_RUN([#include <sys/procfs.h>
1345        int main ()
1346        {
1347          if (sizeof (prfpregset_t) == sizeof (void *))
1348            return 1;
1349          return 0;
1350        }],
1351        gdb_cv_prfpregset_t_broken=no,
1352        gdb_cv_prfpregset_t_broken=yes,
1353        gdb_cv_prfpregset_t_broken=yes)])
1354     AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
1355     if test $gdb_cv_prfpregset_t_broken = yes; then
1356       AC_DEFINE(PRFPREGSET_T_BROKEN, 1,
1357       [Define if the prfpregset_t type is broken.])
1358     fi
1359   fi
1360
1361   dnl Check for PIOCSET ioctl entry
1362
1363   AC_MSG_CHECKING(for PIOCSET ioctl entry in sys/procfs.h)
1364   AC_CACHE_VAL(gdb_cv_have_procfs_piocset,
1365   [AC_TRY_COMPILE([#include <unistd.h>
1366 #include <sys/types.h>
1367 #include <sys/procfs.h>
1368 ], [
1369     int dummy;;
1370     dummy = ioctl(0, PIOCSET, &dummy);
1371   ],
1372   gdb_cv_have_procfs_piocset=yes, gdb_cv_have_procfs_piocset=no)])
1373   AC_MSG_RESULT($gdb_cv_have_procfs_piocset)
1374   if test $gdb_cv_have_procfs_piocset = yes; then
1375     AC_DEFINE(HAVE_PROCFS_PIOCSET, 1,
1376     [Define if ioctl argument PIOCSET is available.])
1377   fi
1378 fi
1379
1380 dnl For native ports (host == target), check to see what kind of
1381 dnl legacy link.h support is needed.  (See solib-legacy.c.)
1382 if test ${host} = ${target} ; then
1383   dnl Check for struct link_map with l_ members which are indicative
1384   dnl of SVR4-like shared libraries
1385
1386   AC_MSG_CHECKING(for member l_addr in struct link_map)
1387   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_l_members,
1388     [AC_TRY_COMPILE([#include <link.h>],
1389                     [struct link_map lm; (void) lm.l_addr;],
1390                     gdb_cv_have_struct_link_map_with_l_members=yes,
1391                     gdb_cv_have_struct_link_map_with_l_members=no)])
1392   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_l_members)
1393   if test $gdb_cv_have_struct_link_map_with_l_members = yes; then
1394     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_L_MEMBERS,1,
1395     [Define if <link.h> exists and defines struct link_map which has
1396      members with an ``l_'' prefix.  (For Solaris, SVR4, and
1397      SVR4-like systems.)])
1398   fi
1399
1400   dnl Check for struct link_map with lm_ members which are indicative
1401   dnl of SunOS-like shared libraries
1402
1403   AC_MSG_CHECKING(for member lm_addr in struct link_map)
1404   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_lm_members,
1405     [AC_TRY_COMPILE([#include <sys/types.h>
1406 #include <link.h>],
1407                     [struct link_map lm; (void) lm.lm_addr;],
1408                     gdb_cv_have_struct_link_map_with_lm_members=yes,
1409                     gdb_cv_have_struct_link_map_with_lm_members=no)])
1410   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_lm_members)
1411   if test $gdb_cv_have_struct_link_map_with_lm_members = yes; then
1412     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_LM_MEMBERS, 1,
1413     [Define if <link.h> exists and defines struct link_map which has
1414      members with an ``lm_'' prefix.  (For SunOS.)])
1415   fi
1416
1417   dnl Check for struct so_map with som_ members which are found on
1418   dnl some *BSD systems.
1419
1420   AC_MSG_CHECKING(for member som_addr in struct so_map)
1421   AC_CACHE_VAL(gdb_cv_have_struct_so_map_with_som_members,
1422     [AC_TRY_COMPILE([#include <sys/types.h>
1423 #ifdef HAVE_NLIST_H
1424 #include <nlist.h>
1425 #endif
1426 #include <link.h>],
1427                     [struct so_map lm; (void) lm.som_addr;],
1428                     gdb_cv_have_struct_so_map_with_som_members=yes,
1429                     gdb_cv_have_struct_so_map_with_som_members=no)])
1430   AC_MSG_RESULT($gdb_cv_have_struct_so_map_with_som_members)
1431   if test $gdb_cv_have_struct_so_map_with_som_members = yes; then
1432     AC_DEFINE(HAVE_STRUCT_SO_MAP_WITH_SOM_MEMBERS, 1,
1433     [Define if <link.h> exists and defines a struct so_map which has
1434      members with an ``som_'' prefix.  (Found on older *BSD systems.)])
1435   fi
1436
1437   dnl Check for struct link_map32 type, which allows a 64-bit Solaris
1438   dnl debugger to debug a 32-bit Solaris app with 32-bit shared libraries.
1439
1440   AC_MSG_CHECKING(for struct link_map32 in sys/link.h)
1441   AC_CACHE_VAL(gdb_cv_have_struct_link_map32,
1442     [AC_TRY_COMPILE([#define _SYSCALL32
1443 #include <sys/link.h>], [struct link_map32 l;],
1444      gdb_cv_have_struct_link_map32=yes,
1445      gdb_cv_have_struct_link_map32=no)])
1446   AC_MSG_RESULT($gdb_cv_have_struct_link_map32)
1447   if test $gdb_cv_have_struct_link_map32 = yes; then
1448     AC_DEFINE(HAVE_STRUCT_LINK_MAP32, 1,
1449     [Define if <sys/link.h> has struct link_map32])
1450     AC_DEFINE(_SYSCALL32, 1,
1451     [Define if <sys/link.h> has link_map32 (solaris sparc-64 target)])
1452   fi
1453 fi
1454
1455 # Check if the compiler supports the `long long' type.
1456
1457 AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long,
1458                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1459 [[extern long long foo;]],
1460 [[switch (foo & 2) { case 0: return 1; }]])],
1461                                   gdb_cv_c_long_long=yes,
1462                                   gdb_cv_c_long_long=no)])
1463 if test $gdb_cv_c_long_long = yes; then
1464   AC_DEFINE(CC_HAS_LONG_LONG, 1,
1465             [Define to 1 if the compiler supports long long.])
1466 fi
1467
1468 # Check if the compiler and runtime support printing long longs.
1469
1470 AC_CACHE_CHECK([for long long support in printf],
1471                gdb_cv_printf_has_long_long,
1472                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1473 [[char buf[32];
1474   long long l = 0;
1475   l = (l << 16) + 0x0123;
1476   l = (l << 16) + 0x4567;
1477   l = (l << 16) + 0x89ab;
1478   l = (l << 16) + 0xcdef;
1479   sprintf (buf, "0x%016llx", l);
1480   return (strcmp ("0x0123456789abcdef", buf));]])],
1481                               gdb_cv_printf_has_long_long=yes,
1482                               gdb_cv_printf_has_long_long=no,
1483                               gdb_cv_printf_has_long_long=no)])
1484 if test $gdb_cv_printf_has_long_long = yes; then
1485   AC_DEFINE(PRINTF_HAS_LONG_LONG, 1,
1486             [Define to 1 if the "%ll" format works to print long longs.])
1487 fi
1488
1489 # Check if the compiler and runtime support printing decfloats.
1490
1491 AC_CACHE_CHECK([for decfloat support in printf],
1492                gdb_cv_printf_has_decfloat,
1493                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1494 [[char buf[64];
1495   _Decimal32 d32 = 1.2345df;
1496   _Decimal64 d64 = 1.2345dd;
1497   _Decimal128 d128 = 1.2345dl;
1498   sprintf (buf, "Decimal32: %H\nDecimal64: %D\nDecimal128: %DD", d32, d64, d128);
1499   return (strcmp ("Decimal32: 1.2345\nDecimal64: 1.2345\nDecimal128: 1.2345", buf));]])],
1500                               gdb_cv_printf_has_decfloat=yes,
1501                               gdb_cv_printf_has_decfloat=no,
1502                               gdb_cv_printf_has_decfloat=no)])
1503 if test $gdb_cv_printf_has_decfloat = yes; then
1504   AC_DEFINE(PRINTF_HAS_DECFLOAT, 1,
1505             [Define to 1 if the "%H, %D and %DD" formats work to print decfloats.])
1506 fi
1507
1508 # Check if the compiler supports the `long double' type.  We can't use
1509 # AC_C_LONG_DOUBLE because that one does additional checks on the
1510 # constants defined in <float.h> that fail on some systems,
1511 # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6.
1512
1513 AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double,
1514                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])],
1515                                   gdb_cv_c_long_double=yes,
1516                                   gdb_cv_c_long_double=no)])
1517 if test $gdb_cv_c_long_double = yes; then
1518   AC_DEFINE(HAVE_LONG_DOUBLE, 1,
1519            [Define to 1 if the compiler supports long double.])
1520 fi
1521
1522 # Check if the compiler and runtime support printing long doubles.
1523
1524 AC_CACHE_CHECK([for long double support in printf],
1525                gdb_cv_printf_has_long_double,
1526                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1527 [[char buf[16];
1528   long double f = 3.141592653;
1529   sprintf (buf, "%Lg", f);
1530   return (strncmp ("3.14159", buf, 7));]])],
1531                               gdb_cv_printf_has_long_double=yes,
1532                               gdb_cv_printf_has_long_double=no,
1533                               gdb_cv_printf_has_long_double=no)])
1534 if test $gdb_cv_printf_has_long_double = yes; then
1535   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1,
1536             [Define to 1 if the "%Lg" format works to print long doubles.])
1537 fi
1538
1539 # Check if the compiler and runtime support scanning long doubles.
1540
1541 AC_CACHE_CHECK([for long double support in scanf],
1542                gdb_cv_scanf_has_long_double,
1543                [AC_RUN_IFELSE([AC_LANG_PROGRAM(
1544 [[#include <stdio.h>]],
1545 [[char *buf = "3.141592653";
1546   long double f = 0;
1547   sscanf (buf, "%Lg", &f);
1548   return !(f > 3.14159 && f < 3.14160);]])],
1549                               gdb_cv_scanf_has_long_double=yes,
1550                               gdb_cv_scanf_has_long_double=no,
1551                               gdb_cv_scanf_has_long_double=no)])
1552 if test $gdb_cv_scanf_has_long_double = yes; then
1553   AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1,
1554             [Define to 1 if the "%Lg" format works to scan long doubles.])
1555 fi
1556
1557 case ${host_os} in
1558 aix*)
1559   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1560     SAVE_LDFLAGS=$LDFLAGS
1561
1562     case $GCC in
1563     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1564     *) gdb_cv_bigtoc=-bbigtoc ;;
1565     esac
1566
1567     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1568     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1569     LDFLAGS="${SAVE_LDFLAGS}"
1570   ])
1571   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
1572   ;;
1573 esac
1574
1575 AC_MSG_CHECKING(for the dynamic export flag)
1576 dynamic_list=false
1577 if test "${gdb_native}" = yes; then
1578    # The dynamically loaded libthread_db needs access to symbols in the gdb
1579    # executable.  Older GNU ld supports --export-dynamic but --dynamic-list
1580    # may not be supported there.
1581    old_LDFLAGS="$LDFLAGS"
1582    # Older GNU ld supports --export-dynamic but --dynamic-list it does not.
1583    RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
1584    LDFLAGS="$LDFLAGS $RDYNAMIC"
1585    if test "${have_libpython}" = no; then
1586      AC_TRY_LINK([], [], [dynamic_list=true])
1587    else
1588      # Workaround http://bugs.python.org/issue4434 where static
1589      # libpythonX.Y.a would get its symbols required for
1590      # pythonX.Y/lib-dynload/*.so modules hidden by -Wl,--dynamic-list.
1591      # Problem does not happen for the recommended libpythonX.Y.so linkage.
1592      old_CFLAGS="$CFLAGS"
1593      CFLAGS="$CFLAGS $PYTHON_CFLAGS"
1594      AC_RUN_IFELSE(
1595        AC_LANG_PROGRAM(
1596          [#include "]${have_libpython}[/Python.h"],
1597          [int err;
1598           Py_Initialize ();
1599           err = PyRun_SimpleString ("import itertools\n");
1600           Py_Finalize ();
1601           return err == 0 ? 0 : 1;]),
1602        [dynamic_list=true], [], [true])
1603      CFLAGS="$old_CFLAGS"
1604    fi
1605    LDFLAGS="$old_LDFLAGS"
1606 fi
1607 if $dynamic_list; then
1608   found="-Wl,--dynamic-list"
1609   RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'
1610 else
1611   found="-rdynamic"
1612   RDYNAMIC="-rdynamic"
1613 fi
1614 AC_SUBST(RDYNAMIC)
1615 AC_MSG_RESULT($found)
1616
1617 dnl For certain native configurations, we need to check whether thread
1618 dnl support can be built in or not.
1619 dnl
1620 dnl Note that we only want this if we are both native (host == target),
1621 dnl and not doing a canadian cross build (build == host).
1622
1623 if test ${build} = ${host} -a ${host} = ${target} ; then
1624    case ${host_os} in
1625    solaris*)
1626       # See if thread_db library is around for Solaris thread debugging.
1627       # Note that we must explicitly test for version 1 of the library
1628       # because version 0 (present on Solaris 2.4 or earlier) doesn't have
1629       # the same API.
1630       AC_MSG_CHECKING(for Solaris thread debugging library)
1631       if test -f /usr/lib/libthread_db.so.1 ; then
1632          AC_MSG_RESULT(yes)
1633          AC_DEFINE(HAVE_THREAD_DB_LIB, 1,
1634          [Define if using Solaris thread debugging.])
1635          CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
1636          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
1637          AC_CHECK_LIB(dl, dlopen)
1638          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} $RDYNAMIC"
1639          # Sun randomly tweaked the prototypes in <proc_service.h>
1640          # at one point.
1641          AC_MSG_CHECKING(if <proc_service.h> is old)
1642          AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
1643             AC_TRY_COMPILE([
1644                 #include <proc_service.h>
1645                 ps_err_e ps_pdwrite
1646                     (struct ps_prochandle*, psaddr_t, const void*, size_t);
1647             ],, gdb_cv_proc_service_is_old=no,
1648                 gdb_cv_proc_service_is_old=yes)
1649          ])
1650          AC_MSG_RESULT($gdb_cv_proc_service_is_old)
1651          if test $gdb_cv_proc_service_is_old = yes; then
1652             AC_DEFINE(PROC_SERVICE_IS_OLD, 1,
1653             [Define if <proc_service.h> on solaris uses int instead of
1654              size_t, and assorted other type changes.])
1655          fi
1656       else
1657          AC_MSG_RESULT(no)
1658       fi
1659       ;;
1660    aix*)
1661       AC_MSG_CHECKING(for AiX thread debugging library)
1662       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
1663                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
1664                                    [#ifndef PTHDB_VERSION_3
1665                                     #error
1666                                     #endif],
1667                                    gdb_cv_have_aix_thread_debug=yes,
1668                                    gdb_cv_have_aix_thread_debug=no)])
1669       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1670       if test $gdb_cv_have_aix_thread_debug = yes; then
1671          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1672          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1673          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -lpthdebug"
1674
1675          # Older versions of AIX do not provide the declaration for
1676          # the getthrds function (it appears that it was introduced
1677          # with AIX 6.x).
1678          AC_CHECK_DECLS(getthrds, [], [], [[#include <procinfo.h>]])
1679       fi
1680       ;;
1681    esac
1682    AC_SUBST(CONFIG_LDFLAGS)
1683 fi
1684
1685 dnl See if we have a thread_db header file that has TD_NOTALLOC and
1686 dnl other error codes.
1687 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1688    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
1689                   gdb_cv_thread_db_h_has_td_notalloc,
1690      AC_TRY_COMPILE(
1691        [#include <thread_db.h>],
1692        [int i = TD_NOTALLOC;],
1693        gdb_cv_thread_db_h_has_td_notalloc=yes,
1694        gdb_cv_thread_db_h_has_td_notalloc=no
1695      )
1696    )
1697    AC_CACHE_CHECK([whether <thread_db.h> has TD_VERSION],
1698                   gdb_cv_thread_db_h_has_td_version,
1699      AC_TRY_COMPILE(
1700        [#include <thread_db.h>],
1701        [int i = TD_VERSION;],
1702        gdb_cv_thread_db_h_has_td_version=yes,
1703        gdb_cv_thread_db_h_has_td_version=no
1704      )
1705    )
1706    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTLS],
1707                   gdb_cv_thread_db_h_has_td_notls,
1708      AC_TRY_COMPILE(
1709        [#include <thread_db.h>],
1710        [int i = TD_NOTLS;],
1711        gdb_cv_thread_db_h_has_td_notls=yes,
1712        gdb_cv_thread_db_h_has_td_notls=no
1713      )
1714    )
1715 fi
1716 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1717   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1718             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1719 fi
1720 if test "x$gdb_cv_thread_db_h_has_td_version" = "xyes"; then
1721   AC_DEFINE(THREAD_DB_HAS_TD_VERSION, 1,
1722             [Define if <thread_db.h> has the TD_VERSION error code.])
1723 fi
1724 if test "x$gdb_cv_thread_db_h_has_td_notls" = "xyes"; then
1725   AC_DEFINE(THREAD_DB_HAS_TD_NOTLS, 1,
1726             [Define if <thread_db.h> has the TD_NOTLS error code.])
1727 fi
1728
1729 dnl See if we have a sys/syscall header file that has __NR_tkill.
1730 if test "x$ac_cv_header_sys_syscall_h" = "xyes"; then
1731    AC_CACHE_CHECK([whether <sys/syscall.h> has __NR_tkill],
1732                   gdb_cv_sys_syscall_h_has_tkill,
1733      AC_TRY_COMPILE(
1734        [#include <sys/syscall.h>],
1735        [int i = __NR_tkill;],
1736        gdb_cv_sys_syscall_h_has_tkill=yes,
1737        gdb_cv_sys_syscall_h_has_tkill=no
1738      )
1739    )
1740 fi
1741 dnl See if we can issue tkill syscall.
1742 if test "x$gdb_cv_sys_syscall_h_has_tkill" = "xyes" && test "x$ac_cv_func_syscall" = "xyes"; then
1743   AC_DEFINE(HAVE_TKILL_SYSCALL, 1, [Define if you support the tkill syscall.])
1744 fi
1745
1746 dnl Check if we can disable the virtual address space randomization.
1747 dnl The functionality of setarch -R.
1748 AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>])
1749 define([PERSONALITY_TEST], [AC_LANG_PROGRAM([#include <sys/personality.h>], [
1750 #      if !HAVE_DECL_ADDR_NO_RANDOMIZE
1751 #       define ADDR_NO_RANDOMIZE 0x0040000
1752 #      endif
1753        /* Test the flag could be set and stays set.  */
1754        personality (personality (0xffffffff) | ADDR_NO_RANDOMIZE);
1755        if (!(personality (personality (0xffffffff)) & ADDR_NO_RANDOMIZE))
1756            return 1])])
1757 AC_RUN_IFELSE([PERSONALITY_TEST],
1758               [have_personality=true],
1759               [have_personality=false],
1760               [AC_LINK_IFELSE([PERSONALITY_TEST],
1761                               [have_personality=true],
1762                               [have_personality=false])])
1763 if $have_personality
1764 then
1765     AC_DEFINE([HAVE_PERSONALITY], 1,
1766               [Define if you support the personality syscall.])
1767 fi
1768
1769 dnl Handle optional features that can be enabled.
1770
1771 # Support for --with-sysroot is a copy of GDB_AC_WITH_DIR,
1772 # except that the argument to --with-sysroot is optional.
1773 # --with-sysroot (or --with-sysroot=yes) sets the default sysroot path.
1774 if test "x$with_sysroot" = xyes; then
1775   with_sysroot="${exec_prefix}/${target_alias}/sys-root"
1776 fi
1777 AC_ARG_WITH(sysroot,
1778   AS_HELP_STRING([--with-sysroot@<:@=DIR@:>@],
1779                  [search for usr/lib et al within DIR]),
1780   [TARGET_SYSTEM_ROOT=$withval], [TARGET_SYSTEM_ROOT=])
1781 AC_DEFINE_DIR(TARGET_SYSTEM_ROOT, TARGET_SYSTEM_ROOT,
1782               [search for usr/lib et al within DIR])
1783 AC_SUBST(TARGET_SYSTEM_ROOT)
1784 GDB_AC_DEFINE_RELOCATABLE(TARGET_SYSTEM_ROOT, sysroot, ${ac_define_dir})
1785
1786 GDB_AC_WITH_DIR(SYSTEM_GDBINIT, system-gdbinit,
1787     [automatically load a system-wide gdbinit file],
1788     [])
1789
1790 AC_ARG_ENABLE(werror,
1791   AS_HELP_STRING([--enable-werror], [treat compile warnings as errors]),
1792   [case "${enableval}" in
1793      yes | y) ERROR_ON_WARNING="yes" ;;
1794      no | n)  ERROR_ON_WARNING="no" ;;
1795      *) AC_MSG_ERROR(bad value ${enableval} for --enable-werror) ;;
1796    esac])
1797
1798 # Enable -Werror by default when using gcc
1799 if test "${GCC}" = yes -a -z "${ERROR_ON_WARNING}" ; then
1800     ERROR_ON_WARNING=yes
1801 fi
1802
1803 WERROR_CFLAGS=""
1804 if test "${ERROR_ON_WARNING}" = yes ; then
1805     WERROR_CFLAGS="-Werror"
1806 fi
1807
1808 # The entries after -Wno-pointer-sign are disabled warnings which may
1809 # be enabled in the future, which can not currently be used to build
1810 # GDB.
1811 # NOTE: If you change this list, remember to update
1812 # gdb/doc/gdbint.texinfo.
1813 build_warnings="-Wall -Wdeclaration-after-statement -Wpointer-arith \
1814 -Wformat-nonliteral -Wno-pointer-sign \
1815 -Wno-unused -Wunused-value -Wunused-function \
1816 -Wno-switch -Wno-char-subscripts -Wmissing-prototypes"
1817
1818 # Enable -Wno-format by default when using gcc on mingw since many
1819 # GCC versions complain about %I64.
1820 case "${host}" in
1821   *-*-mingw32*) build_warnings="$build_warnings -Wno-format" ;;
1822 esac
1823
1824 AC_ARG_ENABLE(build-warnings,
1825 AS_HELP_STRING([--enable-build-warnings], [enable build-time compiler warnings if gcc is used]),
1826 [case "${enableval}" in
1827   yes)  ;;
1828   no)   build_warnings="-w";;
1829   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1830         build_warnings="${build_warnings} ${t}";;
1831   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1832         build_warnings="${t} ${build_warnings}";;
1833   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1834 esac
1835 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1836   echo "Setting compiler warning flags = $build_warnings" 6>&1
1837 fi])dnl
1838 AC_ARG_ENABLE(gdb-build-warnings,
1839 AS_HELP_STRING([--enable-gdb-build-warnings], [enable GDB specific build-time compiler warnings if gcc is used]),
1840 [case "${enableval}" in
1841   yes)  ;;
1842   no)   build_warnings="-w";;
1843   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1844         build_warnings="${build_warnings} ${t}";;
1845   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1846         build_warnings="${t} ${build_warnings}";;
1847   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1848 esac
1849 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1850   echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1
1851 fi])dnl
1852 WARN_CFLAGS=""
1853 if test "x${build_warnings}" != x -a "x$GCC" = xyes
1854 then
1855     AC_MSG_CHECKING(compiler warning flags)
1856     # Separate out the -Werror flag as some files just cannot be
1857     # compiled with it enabled.
1858     for w in ${build_warnings}; do
1859         case $w in
1860         -Werr*) WERROR_CFLAGS=-Werror ;;
1861         *) # Check that GCC accepts it
1862             saved_CFLAGS="$CFLAGS"
1863             CFLAGS="$CFLAGS $w"
1864             AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
1865             CFLAGS="$saved_CFLAGS"
1866         esac
1867     done
1868     AC_MSG_RESULT(${WARN_CFLAGS} ${WERROR_CFLAGS})
1869 fi
1870 AC_SUBST(WARN_CFLAGS)
1871 AC_SUBST(WERROR_CFLAGS)
1872
1873 # In the Cygwin environment, we need some additional flags.
1874 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1875 [AC_EGREP_CPP(lose, [
1876 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1877 lose
1878 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1879
1880
1881 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1882 SER_HARDWIRE="ser-base.o ser-unix.o ser-pipe.o ser-tcp.o"
1883 case ${host} in
1884   *go32* ) SER_HARDWIRE=ser-go32.o ;;
1885   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
1886   *mingw32*) SER_HARDWIRE="ser-base.o ser-tcp.o ser-mingw.o" ;;
1887 esac
1888 AC_SUBST(SER_HARDWIRE)
1889
1890 # libreadline needs libuser32.a in a cygwin environment
1891 WIN32LIBS=
1892 if test x$gdb_cv_os_cygwin = xyes; then
1893     WIN32LIBS="-luser32"
1894     case "${target}" in
1895         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
1896         ;;
1897     esac
1898 fi
1899
1900 # The ser-tcp.c module requires sockets.
1901 case ${host} in
1902   *mingw32*)
1903     AC_DEFINE(USE_WIN32API, 1,
1904               [Define if we should use the Windows API, instead of the
1905                POSIX API.  On Windows, we use the Windows API when
1906                building for MinGW, but the POSIX API when building
1907                for Cygwin.])
1908     WIN32LIBS="$WIN32LIBS -lws2_32"
1909     ;;
1910 esac
1911 AC_SUBST(WIN32LIBS)
1912
1913 # Add ELF support to GDB, but only if BFD includes ELF support.
1914 OLD_CFLAGS=$CFLAGS
1915 OLD_LDFLAGS=$LDFLAGS
1916 OLD_LIBS=$LIBS
1917 # Put the old CFLAGS/LDFLAGS last, in case the user's (C|LD)FLAGS
1918 # points somewhere with bfd, with -I/foo/lib and -L/foo/lib.  We
1919 # always want our bfd.
1920 CFLAGS="-I${srcdir}/../include -I../bfd -I${srcdir}/../bfd $CFLAGS"
1921 LDFLAGS="-L../bfd -L../libiberty $LDFLAGS"
1922 intl=`echo $LIBINTL | sed 's,${top_builddir}/,,g'`
1923 # -ldl is provided by bfd/Makfile.am (LIBDL) <PLUGINS>.
1924 if test "$plugins" = "yes"; then
1925   LIBS="-ldl $LIBS"
1926 fi
1927 LIBS="-lbfd -liberty $intl $LIBS"
1928 AC_CACHE_CHECK([for ELF support in BFD], gdb_cv_var_elf,
1929 [AC_TRY_LINK(
1930 [#include <stdlib.h>
1931 #include "bfd.h"
1932 #include "elf-bfd.h"
1933 ],
1934 [bfd *abfd = NULL; bfd_get_elf_phdr_upper_bound (abfd); ],
1935 gdb_cv_var_elf=yes, gdb_cv_var_elf=no)])
1936 if test $gdb_cv_var_elf = yes; then
1937   CONFIG_OBS="$CONFIG_OBS elfread.o"
1938   AC_DEFINE(HAVE_ELF, 1,
1939             [Define if ELF support should be included.])
1940   # -ldl is provided by bfd/Makfile.am (LIBDL) <PLUGINS>.
1941   if test "$plugins" = "yes"; then
1942     OLD_LIBS="-ldl $OLD_LIBS"
1943   fi
1944 fi
1945 CFLAGS=$OLD_CFLAGS
1946 LDFLAGS=$OLD_LDFLAGS
1947 LIBS=$OLD_LIBS
1948
1949 # Add any host-specific objects to GDB.
1950 CONFIG_OBS="${CONFIG_OBS} ${gdb_host_obs}"
1951
1952 LIBGUI="../libgui/src/libgui.a"
1953 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
1954 AC_SUBST(LIBGUI)
1955 AC_SUBST(GUI_CFLAGS_X)
1956
1957 WIN32LDAPP=
1958 AC_SUBST(WIN32LIBS)
1959 AC_SUBST(WIN32LDAPP)
1960
1961 case "${host}" in
1962 *-*-cygwin* | *-*-mingw* )
1963     configdir="win"
1964     ;;
1965 *)
1966     configdir="unix"
1967     ;;
1968 esac
1969
1970 GDBTKLIBS=
1971 if test "${enable_gdbtk}" = "yes"; then
1972
1973     # Gdbtk must have an absolute path to srcdir in order to run
1974     # properly when not installed.
1975     here=`pwd`
1976     cd ${srcdir}
1977     GDBTK_SRC_DIR=`pwd`
1978     cd $here
1979
1980     SC_PATH_TCLCONFIG
1981
1982     # If $no_tk is nonempty, then we can't do Tk, and there is no
1983     # point to doing Tcl.
1984     SC_PATH_TKCONFIG
1985
1986     if test -z "${no_tcl}" -a -z "${no_tk}"; then
1987         SC_LOAD_TCLCONFIG
1988
1989         # Check for in-tree tcl
1990         here=`pwd`
1991         cd ${srcdir}/..
1992         topdir=`pwd`
1993         cd ${here}
1994
1995         intree="no"
1996         if test "${TCL_SRC_DIR}" = "${topdir}/tcl"; then
1997           intree="yes"
1998         fi
1999
2000         # Find Tcl private headers
2001         if test x"${intree}" = xno; then
2002           CY_AC_TCL_PRIVATE_HEADERS
2003           TCL_INCLUDE="${TCL_INCLUDE_SPEC} ${TCL_PRIVATE_INCLUDE}"
2004           TCL_LIBRARY="${TCL_LIB_SPEC}"
2005           TCL_DEPS=""
2006         else
2007           # If building tcl in the same src tree, private headers
2008           # are not needed, but we need to be sure to use the right
2009           # headers library
2010           TCL_INCLUDE="-I${TCL_SRC_DIR}/generic"
2011           TCL_LIBRARY="${TCL_BUILD_LIB_SPEC}"
2012           TCL_DEPS="../tcl/${configdir}${TCL_LIB_FILE}"
2013         fi
2014         AC_SUBST(TCL_INCLUDE)
2015         AC_SUBST(TCL_LIBRARY)
2016         AC_SUBST(TCL_DEPS)
2017
2018         SC_LOAD_TKCONFIG
2019
2020         # Check for in-tree Tk
2021         intree="no"
2022         if test "${TK_SRC_DIR}" = "${topdir}/tk"; then
2023           intree="yes"
2024         fi
2025
2026         # Find Tk private headers
2027         if test x"${intree}" = xno; then
2028           CY_AC_TK_PRIVATE_HEADERS
2029           TK_INCLUDE="${TK_INCLUDE_SPEC} ${TK_PRIVATE_INCLUDE}"
2030           TK_LIBRARY=${TK_LIB_SPEC}
2031           TK_DEPS=""
2032         else
2033           TK_INCLUDE="-I${TK_SRC_DIR}/generic"
2034           TK_LIBRARY="${TK_BUILD_LIB_SPEC}"
2035           TK_DEPS="../tk/${configdir}/${TK_LIB_FILE}"
2036         fi
2037         AC_SUBST(TK_INCLUDE)
2038         AC_SUBST(TK_LIBRARY)
2039         AC_SUBST(TK_DEPS)
2040         AC_SUBST(TK_XINCLUDES)
2041
2042         ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
2043
2044         # Include some libraries that Tcl and Tk want.
2045         TCL_LIBS='$(LIBGUI) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
2046         # Yes, the ordering seems wrong here.  But it isn't.
2047         # TK_LIBS is the list of libraries that need to be linked
2048         # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
2049         # were in LIBS then any link tests after this point would
2050         # try to include things like `$(LIBGUI)', which wouldn't work.
2051         GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
2052
2053         CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
2054         CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
2055         CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
2056         CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
2057         CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
2058         CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
2059         CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
2060
2061         if test x$gdb_cv_os_cygwin = xyes; then
2062           WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
2063           WIN32LDAPP="-Wl,--subsystem,console"
2064           CONFIG_OBS="${CONFIG_OBS} gdbres.o"
2065         fi
2066
2067         AC_CONFIG_SUBDIRS(gdbtk)
2068     fi
2069 fi
2070
2071 AC_SUBST(X_CFLAGS)
2072 AC_SUBST(X_LDFLAGS)
2073 AC_SUBST(X_LIBS)
2074 AC_SUBST(GDBTKLIBS)
2075 AC_SUBST(GDBTK_CFLAGS)
2076 AC_SUBST(GDBTK_SRC_DIR)
2077
2078 AC_PATH_X
2079
2080 # Unlike the sim directory, whether a simulator is linked is controlled by
2081 # presence of a gdb_sim definition in the target configure.tgt entry.
2082 # This code just checks for a few cases where we'd like to ignore those
2083 # definitions, even when they're present in the '.mt' file.  These cases
2084 # are when --disable-sim is specified, or if the simulator directory is
2085 # not part of the source tree.
2086 #
2087 AC_ARG_ENABLE(sim,
2088 AS_HELP_STRING([--enable-sim], [link gdb with simulator]),
2089 [echo "enable_sim = $enable_sim";
2090  echo "enableval = ${enableval}";
2091  case "${enableval}" in
2092   yes) ignore_sim=false ;;
2093   no)  ignore_sim=true ;;
2094   *)   ignore_sim=false ;;
2095  esac],
2096 [ignore_sim=false])
2097
2098 if test ! -d "${srcdir}/../sim"; then
2099   ignore_sim=true
2100 fi
2101
2102 SIM=
2103 SIM_OBS=
2104 if test "${ignore_sim}" = "false"; then
2105   if test x"${gdb_sim}" != x ; then
2106     SIM="${gdb_sim}"
2107     SIM_OBS="remote-sim.o"
2108     AC_DEFINE(WITH_SIM, 1, [Define if the simulator is being linked in.])
2109   fi
2110 fi
2111 AC_SUBST(SIM)
2112 AC_SUBST(SIM_OBS)
2113
2114 AC_SUBST(ENABLE_CFLAGS)
2115 AC_SUBST(PROFILE_CFLAGS)
2116
2117 AC_SUBST(CONFIG_OBS)
2118 AC_SUBST(CONFIG_DEPS)
2119 AC_SUBST(CONFIG_SRCS)
2120 AC_SUBST(CONFIG_ALL)
2121 AC_SUBST(CONFIG_CLEAN)
2122 AC_SUBST(CONFIG_INSTALL)
2123 AC_SUBST(CONFIG_UNINSTALL)
2124
2125 # List of host floatformats.
2126 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
2127 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
2128 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
2129
2130 # target_subdir is used by the testsuite to find the target libraries.
2131 target_subdir=
2132 if test "${host}" != "${target}"; then
2133     target_subdir="${target_alias}/"
2134 fi
2135 AC_SUBST(target_subdir)
2136
2137 frags=
2138 if test "${gdb_native}" = "yes"; then
2139   host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
2140   if test ! -f ${host_makefile_frag}; then
2141     AC_MSG_ERROR("*** Gdb does not support native target ${host}")
2142   fi
2143   frags="$frags $host_makefile_frag"
2144 else
2145   host_makefile_frag=/dev/null
2146 fi
2147
2148 AC_SUBST_FILE(host_makefile_frag)
2149 AC_SUBST(frags)
2150
2151 changequote(,)dnl
2152 if test "${gdb_native}" = "yes"; then
2153 # We pick this up from the host configuration file (.mh) because we
2154 # do not have a native configuration Makefile fragment.
2155 nativefile=`sed -n '
2156 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
2157 ' ${host_makefile_frag}`
2158 fi
2159 changequote([,])
2160
2161 if test x"${gdb_osabi}" != x ; then
2162     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
2163                        [Define to the default OS ABI for this configuration.])
2164 fi
2165
2166 # Enable multi-ice-gdb-server.
2167 AC_ARG_ENABLE(multi-ice,
2168 AS_HELP_STRING([--enable-multi-ice], [build the multi-ice-gdb-server]),
2169   [case $enableval in
2170     yes | no)
2171       ;;
2172     *) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;;
2173   esac])
2174 if test "x$enable_multi_ice" = xyes; then
2175    AC_CONFIG_SUBDIRS(multi-ice)
2176 fi
2177
2178 AC_ARG_ENABLE(gdbserver,
2179 AS_HELP_STRING([--enable-gdbserver],
2180                [automatically build gdbserver (yes/no/auto, default is auto)]),
2181 [case "${enableval}" in
2182   yes| no|auto) ;;
2183   *) AC_MSG_ERROR(bad value ${enableval} for --enable-gdbserver option) ;;
2184 esac],[enable_gdbserver=auto])
2185
2186 # We only build gdbserver automatically in a native configuration, and
2187 # only if the user did not explicitly disable its build.
2188 if test "$gdb_native" = "yes" -a "$enable_gdbserver" != "no"; then
2189   AC_MSG_CHECKING(whether gdbserver is supported on this host)
2190   if test "x$build_gdbserver" = xyes; then
2191     AC_MSG_RESULT(yes)
2192     AC_CONFIG_SUBDIRS(gdbserver)
2193     gdbserver_build_enabled=yes
2194   else
2195     AC_MSG_RESULT(no)
2196   fi
2197 fi
2198
2199 # If the user explicitly request the gdbserver to be built, verify that
2200 # we were in fact able to enable it.
2201 if test "$enable_gdbserver" = "yes" -a "$gdbserver_build_enabled" != "yes"; then
2202   AC_MSG_ERROR(Automatic gdbserver build is not supported for this configuration)
2203 fi
2204
2205 # If nativefile (NAT_FILE) is not set in config/*/*.m[ht] files, we link
2206 # to an empty version.
2207
2208 files=
2209 links=
2210
2211 rm -f nm.h
2212 if test "${nativefile}" != ""; then
2213     case "${nativefile}" in
2214       nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
2215       * ) GDB_NM_FILE="${nativefile}"
2216     esac
2217     files="${files} ${GDB_NM_FILE}"
2218     links="${links} nm.h"
2219     AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}", [nativefile])
2220 fi
2221 AC_SUBST(GDB_NM_FILE)
2222
2223 AC_LINK_FILES($files, $links)
2224
2225 dnl Check for exe extension set on certain hosts (e.g. Win32)
2226 AC_EXEEXT
2227
2228 dnl  Detect the character set used by this host.
2229 dnl  At the moment, we just assume it's UTF-8.
2230 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "UTF-8",
2231           [Define to be a string naming the default host character set.])
2232
2233 AC_OUTPUT(Makefile .gdbinit:gdbinit.in doc/Makefile gnulib/Makefile data-directory/Makefile,
2234 [
2235 case x$CONFIG_HEADERS in
2236 xconfig.h:config.in)
2237 echo > stamp-h ;;
2238 esac
2239 ])
2240
2241 exit 0