gdb/configure.ac

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995-2018 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Process this file with autoconf to produce a configure script.
  20
  21 AC_INIT(main.c)
  22 AC_CONFIG_HEADER(config.h:config.in)
  23 AM_MAINTAINER_MODE
  24
  25 # Set the 'development' global.
  26 . $srcdir/../bfd/development.sh
  27
  28 AC_PROG_CC
  29 AC_PROG_CXX
  30
  31 AC_USE_SYSTEM_EXTENSIONS
  32 ACX_LARGEFILE
  33 AM_PROG_CC_STDC
  34 AM_PROG_INSTALL_STRIP
  35
  36 AC_CONFIG_AUX_DIR(..)
  37 AC_CANONICAL_SYSTEM
  38 AC_ARG_PROGRAM
  39
  40 # We require a C++11 compiler.  Check if one is available, and if
  41 # necessary, set CXX_DIALECT to some -std=xxx switch.
  42 AX_CXX_COMPILE_STDCXX(11, , mandatory)
  43
  44 # Dependency checking.
  45 ZW_CREATE_DEPDIR
  46 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  47
  48 gnulib_extra_configure_args=
  49 # If large-file support is disabled, make sure gnulib does the same.
  50 if test "$enable_largefile" = no; then
  51 gnulib_extra_configure_args="$gnulib_extra_configure_args --disable-largefile"
  52 fi
  53
  54 # Configure gnulib.  We need to build gnulib under some other
  55 # directory not "gnulib", to avoid the problem of both GDB and
  56 # GDBserver wanting to build it in the same directory, when building
  57 # in the source dir.
  58 ACX_CONFIGURE_DIR(["gnulib"], ["build-gnulib"],
  59                   ["$gnulib_extra_configure_args"])
  60
  61 dnl List of object files and targets accumulated by configure.
  62
  63 CONFIG_OBS=
  64 CONFIG_DEPS=
  65 CONFIG_SRCS=
  66 ENABLE_CFLAGS=
  67
  68 CONFIG_ALL=
  69 CONFIG_CLEAN=
  70 CONFIG_INSTALL=
  71 CONFIG_UNINSTALL=
  72
  73 dnl Set up for gettext.
  74 ZW_GNU_GETTEXT_SISTER_DIR
  75
  76 localedir='${datadir}/locale'
  77 AC_SUBST(localedir)
  78
  79 if test x"$USE_NLS" = xyes; then
  80    CONFIG_ALL="$CONFIG_ALL all-po"
  81    CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
  82    CONFIG_INSTALL="$CONFIG_INSTALL install-po"
  83    CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
  84 fi
  85
  86 GNULIB=build-gnulib/import
  87
  88 # For Makefile dependencies.
  89 GNULIB_STDINT_H=
  90 if test x"$STDINT_H" != x; then
  91   GNULIB_STDINT_H=$GNULIB/$STDINT_H
  92 fi
  93 AC_SUBST(GNULIB_STDINT_H)
  94
  95 PACKAGE=gdb
  96 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
  97 AC_SUBST(PACKAGE)
  98
  99 # We never need to detect it in this sub-configure.
 100 # But preserve it for config.status --recheck.
 101 AC_ARG_VAR(MAKEINFO,
 102   [Parent configure detects if it is of sufficient version.])
 103 AC_ARG_VAR(MAKEINFOFLAGS,
 104   [Parameters for MAKEINFO.])
 105
 106 MAKEINFO_EXTRA_FLAGS=""
 107 AC_CACHE_CHECK([whether $MAKEINFO supports @click], gdb_cv_have_makeinfo_click,
 108   [echo '@clicksequence{a @click{} b}' >conftest.texinfo
 109   if eval "$MAKEINFO conftest.texinfo >&5 2>&5"; then
 110     gdb_cv_have_makeinfo_click=yes
 111   else
 112     gdb_cv_have_makeinfo_click=no
 113   fi])
 114 if test x"$gdb_cv_have_makeinfo_click" = xyes; then
 115   MAKEINFO_EXTRA_FLAGS="$MAKEINFO_EXTRA_FLAGS -DHAVE_MAKEINFO_CLICK"
 116 fi
 117 AC_SUBST(MAKEINFO_EXTRA_FLAGS)
 118
 119 GDB_AC_WITH_DIR(DEBUGDIR, separate-debug-dir,
 120     [look for global separate debug info in this path @<:@LIBDIR/debug@:>@],
 121     [${libdir}/debug])
 122
 123 # We can't pass paths as command line arguments.
 124 # Mingw32 tries to be clever and will convert the paths for us.
 125 # For example -DBINDIR="/usr/local/bin" passed on the command line may get
 126 # converted to -DBINDIR="E:/msys/mingw32/msys/1.0/local/bin".
 127 # This breaks GDB's relocatable path conversions since paths passed in
 128 # config.h would not get so translated, the path prefixes no longer match.
 129 AC_DEFINE_DIR(BINDIR, bindir, [Directory of programs.])
 130
 131 # GDB's datadir relocation
 132
 133 GDB_AC_WITH_DIR(GDB_DATADIR, gdb-datadir,
 134     [look for global separate data files in this path @<:@DATADIR/gdb@:>@],
 135     [${datadir}/gdb])
 136
 137 AC_ARG_WITH(relocated-sources,
 138 AS_HELP_STRING([--with-relocated-sources=PATH], [automatically relocate this path for source files]),
 139 [reloc_srcdir="${withval}"
 140  AC_DEFINE_DIR(RELOC_SRCDIR, reloc_srcdir,
 141               [Relocated directory for source files. ])
 142 ])
 143
 144 AC_MSG_CHECKING([for default auto-load directory])
 145 AC_ARG_WITH(auto-load-dir,
 146 AS_HELP_STRING([--with-auto-load-dir=PATH],
 147   [directories from which to load auto-loaded scripts @<:@$debugdir:$datadir/auto-load@:>@]),,
 148   [with_auto_load_dir='$debugdir:$datadir/auto-load'])
 149 escape_dir=`echo $with_auto_load_dir | sed 's/[[$]]\(datadir\|debugdir\)\>/\\\\\\\\\\\\&/g'`
 150 AC_DEFINE_DIR(AUTO_LOAD_DIR, escape_dir,
 151               [Directories from which to load auto-loaded scripts.])
 152 AC_MSG_RESULT([$with_auto_load_dir])
 153
 154 AC_MSG_CHECKING([for default auto-load safe-path])
 155 AC_ARG_WITH(auto-load-safe-path,
 156 AS_HELP_STRING([--with-auto-load-safe-path=PATH],
 157   [directories safe to hold auto-loaded files @<:@--with-auto-load-dir@:>@])
 158 AS_HELP_STRING([--without-auto-load-safe-path],
 159                [do not restrict auto-loaded files locations]),
 160     [if test "$with_auto_load_safe_path" = "no"; then
 161      with_auto_load_safe_path="/"
 162      fi],
 163 [with_auto_load_safe_path="$with_auto_load_dir"])
 164 escape_dir=`echo $with_auto_load_safe_path | sed 's/[[$]]\(datadir\|debugdir\)\>/\\\\\\\\\\\\&/g'`
 165 AC_DEFINE_DIR(AUTO_LOAD_SAFE_PATH, escape_dir,
 166               [Directories safe to hold auto-loaded files.])
 167 AC_MSG_RESULT([$with_auto_load_safe_path])
 168
 169 AC_CONFIG_SUBDIRS(testsuite)
 170
 171 # Check whether to support alternative target configurations
 172 AC_ARG_ENABLE(targets,
 173 AS_HELP_STRING([--enable-targets=TARGETS], [alternative target configurations]),
 174 [case "${enableval}" in
 175   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
 176             ;;
 177   no)       enable_targets= ;;
 178   *)        enable_targets=$enableval ;;
 179 esac])
 180
 181 # Check whether to enable 64-bit support on 32-bit hosts
 182 AC_ARG_ENABLE(64-bit-bfd,
 183 AS_HELP_STRING([--enable-64-bit-bfd], [64-bit support (on hosts with narrower word sizes)]),
 184 [case "${enableval}" in
 185   yes)  want64=true  ;;
 186   no)   want64=false ;;
 187   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
 188 esac],[want64=false])dnl
 189
 190 # Provide defaults for some variables set by the per-host and per-target
 191 # configuration.
 192 gdb_host_obs=posix-hdep.o
 193
 194 if test "${target}" = "${host}"; then
 195   gdb_native=yes
 196 else
 197   gdb_native=no
 198 fi
 199
 200 . $srcdir/configure.host
 201
 202 # Add in the common host objects.
 203 . $srcdir/common/common.host
 204 gdb_host_obs="$gdb_host_obs $common_host_obs"
 205
 206 # Accumulate some settings from configure.tgt over all enabled targets
 207
 208 TARGET_OBS=
 209 all_targets=
 210 HAVE_NATIVE_GCORE_TARGET=
 211
 212 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 213 do
 214   if test "$targ_alias" = "all"; then
 215     all_targets=true
 216   else
 217     # Canonicalize the secondary target names.
 218     result=`$ac_config_sub $targ_alias 2>/dev/null`
 219     if test -n "$result"; then
 220         targ=$result
 221     else
 222         targ=$targ_alias
 223     fi
 224
 225     . ${srcdir}/configure.tgt
 226
 227     AS_IF([test -z "${gdb_target_obs}"],
 228       [AC_MSG_ERROR([configuration ${targ} is unsupported.])])
 229
 230     # Target-specific object files
 231     for i in ${gdb_target_obs}; do
 232         case " $TARGET_OBS " in
 233         *" ${i} "*) ;;
 234         *)
 235           TARGET_OBS="$TARGET_OBS ${i}"
 236           ;;
 237         esac
 238     done
 239
 240     # Check whether this target needs 64-bit CORE_ADDR
 241     if test x${want64} = xfalse; then
 242       . ${srcdir}/../bfd/config.bfd
 243     fi
 244
 245     # Check whether this target is native and supports gcore.
 246     if test $gdb_native = yes -a "$targ_alias" = "$target_alias" \
 247        && $gdb_have_gcore; then
 248       HAVE_NATIVE_GCORE_TARGET=1
 249     fi
 250   fi
 251 done
 252
 253 if test x${all_targets} = xtrue; then
 254
 255   # We want all 64-bit targets if we either:
 256   #  - run on a 64-bit host  or
 257   #  - already require 64-bit support for some other target  or
 258   #  - the --enable-64-bit-bfd option was supplied
 259   # Otherwise we only support all 32-bit targets.
 260   #
 261   # NOTE: This test must be in sync with the corresponding
 262   #       tests in BFD!
 263
 264   if test x${want64} = xfalse; then
 265     AC_CHECK_SIZEOF(long)
 266     if test "x${ac_cv_sizeof_long}" = "x8"; then
 267       want64=true
 268     fi
 269   fi
 270   if test x${want64} = xtrue; then
 271     TARGET_OBS='$(ALL_TARGET_OBS) $(ALL_64_TARGET_OBS)'
 272   else
 273     TARGET_OBS='$(ALL_TARGET_OBS)'
 274   fi
 275 fi
 276
 277 AC_SUBST(TARGET_OBS)
 278 AC_SUBST(HAVE_NATIVE_GCORE_TARGET)
 279
 280 # For other settings, only the main target counts.
 281 gdb_sim=
 282 gdb_osabi=
 283 build_gdbserver=
 284 targ=$target; . ${srcdir}/configure.tgt
 285
 286 # Fetch the default architecture and default target vector from BFD.
 287 targ=$target; . $srcdir/../bfd/config.bfd
 288
 289 # We only want the first architecture, so strip off the others if
 290 # there is more than one.
 291 targ_archs=`echo $targ_archs | sed 's/ .*//'`
 292
 293 if test "x$targ_archs" != x; then
 294   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
 295     [Define to BFD's default architecture. ])
 296 fi
 297 if test "x$targ_defvec" != x; then
 298   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
 299     [Define to BFD's default target vector. ])
 300 fi
 301
 302 # Enable MI.
 303 AC_ARG_ENABLE(gdbmi,
 304 AS_HELP_STRING([--disable-gdbmi], [disable machine-interface (MI)]),
 305   [case $enableval in
 306     yes | no)
 307       ;;
 308     *)
 309       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 310   esac],
 311   [enable_gdbmi=yes])
 312 if test x"$enable_gdbmi" = xyes; then
 313   if test -d $srcdir/mi; then
 314     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 315     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 316     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 317     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 318   fi
 319 fi
 320
 321 # Enable TUI.
 322 AC_ARG_ENABLE(tui,
 323 AS_HELP_STRING([--enable-tui], [enable full-screen terminal user interface (TUI)]),
 324   [case $enableval in
 325     yes | no | auto)
 326       ;;
 327     *)
 328       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 329   esac],enable_tui=auto)
 330
 331 # Enable gdbtk.
 332 AC_ARG_ENABLE(gdbtk,
 333 AS_HELP_STRING([--enable-gdbtk], [enable gdbtk graphical user interface (GUI)]),
 334   [case $enableval in
 335     yes | no)
 336       ;;
 337     *)
 338       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 339   esac],
 340   [if test -d $srcdir/gdbtk; then
 341     enable_gdbtk=yes
 342   else
 343     enable_gdbtk=no
 344   fi])
 345 # We unconditionally disable gdbtk tests on selected platforms.
 346 case $host_os in
 347   go32* | windows*)
 348     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 349     enable_gdbtk=no ;;
 350 esac
 351
 352 # Libunwind support for ia64.
 353
 354 AC_ARG_WITH(libunwind-ia64,
 355 AS_HELP_STRING([--with-libunwind-ia64],
 356                [use libunwind frame unwinding for ia64 targets]),,
 357             [with_libunwind_ia64=auto])
 358
 359 # Backward compatibility option.
 360 if test "${with_libunwind+set}" = set; then
 361   if test x"$with_libunwind_ia64" != xauto; then
 362     AC_MSG_ERROR(
 363       [option --with-libunwind is deprecated, use --with-libunwind-ia64])
 364   fi
 365   AC_MSG_WARN([option --with-libunwind is deprecated, use --with-libunwind-ia64])
 366   with_libunwind_ia64="$with_libunwind"
 367 fi
 368
 369 case "$with_libunwind_ia64" in
 370   yes | no)
 371     ;;
 372   auto)
 373     AC_CHECK_HEADERS(libunwind-ia64.h)
 374     with_libunwind_ia64=$ac_cv_header_libunwind_ia64_h
 375     ;;
 376   *)
 377     AC_MSG_ERROR(
 378       [bad value $with_libunwind_ia64 for GDB --with-libunwind-ia64 option])
 379     ;;
 380 esac
 381
 382 if test x"$with_libunwind_ia64" = xyes; then
 383   AC_CHECK_HEADERS(libunwind-ia64.h)
 384   if test x"$ac_cv_header_libunwind_ia64_h" != xyes; then
 385     AC_MSG_ERROR([GDB option --with-libunwind-ia64 requires libunwind-ia64.h])
 386   fi
 387   CONFIG_OBS="$CONFIG_OBS ia64-libunwind-tdep.o"
 388   CONFIG_DEPS="$CONFIG_DEPS ia64-libunwind-tdep.o"
 389   CONFIG_SRCS="$CONFIG_SRCS ia64-libunwind-tdep.c"
 390 fi
 391
 392 opt_curses=no
 393 AC_ARG_WITH(curses, AS_HELP_STRING([--with-curses], [use the curses library instead of the termcap library]), opt_curses=$withval)
 394
 395 prefer_curses=no
 396 if test "$opt_curses" = "yes"; then
 397   prefer_curses=yes
 398 fi
 399
 400 # Profiling support.
 401 AC_ARG_ENABLE(profiling,
 402 AS_HELP_STRING([--enable-profiling], [enable profiling of GDB]),
 403   [case $enableval in
 404     yes | no)
 405       ;;
 406     *)
 407       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 408   esac],
 409  [enable_profiling=no])
 410
 411 AC_CHECK_FUNCS(monstartup _mcleanup)
 412 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 413 [AC_TRY_LINK(
 414 [#include <stdlib.h>
 415 extern char _etext;
 416 ],
 417 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 418 if test $ac_cv_var__etext = yes; then
 419   AC_DEFINE(HAVE__ETEXT, 1,
 420             [Define to 1 if your system has the _etext variable. ])
 421 fi
 422 AC_CACHE_CHECK([for etext], ac_cv_var_etext,
 423 [AC_TRY_LINK(
 424 [#include <stdlib.h>
 425 extern char etext;
 426 ],
 427 [free (&etext);], ac_cv_var_etext=yes, ac_cv_var_etext=no)])
 428 if test $ac_cv_var_etext = yes; then
 429   AC_DEFINE(HAVE_ETEXT, 1,
 430             [Define to 1 if your system has the etext variable. ])
 431 fi
 432 if test "$enable_profiling" = yes ; then
 433   if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
 434     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 435   fi
 436   PROFILE_CFLAGS=-pg
 437   OLD_CFLAGS="$CFLAGS"
 438   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 439
 440   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 441     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 442      ac_cv_cc_supports_pg=no)])
 443
 444   if test $ac_cv_cc_supports_pg = no; then
 445     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 446   fi
 447
 448   CFLAGS="$OLD_CFLAGS"
 449 fi
 450
 451 CODESIGN_CERT=
 452 AC_ARG_ENABLE([codesign],
 453   AS_HELP_STRING([--enable-codesign=CERT],
 454                  [sign gdb with 'codesign -s CERT']),
 455   [CODESIGN_CERT=$enableval])
 456 AC_SUBST([CODESIGN_CERT])
 457
 458 ACX_PKGVERSION([GDB])
 459 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 460 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 461 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 462
 463 # --------------------- #
 464 # Checks for programs.  #
 465 # --------------------- #
 466
 467 AC_PROG_AWK
 468 AC_PROG_INSTALL
 469 AC_PROG_LN_S
 470 AC_PROG_RANLIB
 471 AC_PROG_YACC
 472
 473 AC_CHECK_TOOL(AR, ar)
 474 AC_CHECK_TOOL(DLLTOOL, dlltool)
 475 AC_CHECK_TOOL(WINDRES, windres)
 476
 477 case $host_os in
 478   gnu*)
 479     # Needed for GNU Hurd hosts.
 480     AC_CHECK_TOOL(MIG, mig)
 481     if test x"$MIG" = x; then
 482       AC_MSG_ERROR([MIG not found but required for $host hosts])
 483     fi
 484     ;;
 485 esac
 486
 487 # ---------------------- #
 488 # Checks for libraries.  #
 489 # ---------------------- #
 490
 491 # We might need to link with -lm; most simulators need it.
 492 AC_CHECK_LIB(m, main)
 493
 494 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 495 AC_SEARCH_LIBS(gethostbyname, nsl)
 496
 497 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 498 AC_SEARCH_LIBS(socketpair, socket)
 499
 500 # Link in zlib if we can.  This allows us to read compressed debug sections.
 501 AM_ZLIB
 502
 503 # On FreeBSD we may need libutil for kinfo_getvmmap (used by fbsd-nat.c).
 504 # On GNU/kFreeBSD systems, FreeBSD libutil is renamed to libutil-freebsd.
 505 AC_SEARCH_LIBS(kinfo_getvmmap, util util-freebsd,
 506   [AC_DEFINE(HAVE_KINFO_GETVMMAP, 1,
 507             [Define to 1 if your system has the kinfo_getvmmap function. ])])
 508
 509 # fbsd-nat.c can also use kinfo_getfile.
 510 AC_SEARCH_LIBS(kinfo_getfile, util util-freebsd,
 511   [AC_DEFINE(HAVE_KINFO_GETFILE, 1,
 512             [Define to 1 if your system has the kinfo_getfile function. ])])
 513
 514 AM_ICONV
 515
 516 # GDB may fork/exec the iconv program to get the list of supported character
 517 # sets.  Allow the user to specify where to find it.
 518 # There are several factors affecting the choice of option name:
 519 # - There is already --with-libiconv-prefix but we can't use it, it specifies
 520 #   the build-time location of libiconv files.
 521 # - The program we need to find is iconv, which comes with glibc.  The user
 522 #   doesn't necessarily have libiconv installed.  Therefore naming this
 523 #   --with-libiconv-foo feels wrong.
 524 # - We want the path to be relocatable, but GDB_AC_DEFINE_RELOCATABLE is
 525 #   defined to work on directories not files (though it really doesn't know
 526 #   the difference).
 527 # - Calling this --with-iconv-prefix is perceived to cause too much confusion
 528 #   with --with-libiconv-prefix.
 529 # Putting these together is why the option name is --with-iconv-bin.
 530
 531 AC_ARG_WITH(iconv-bin,
 532 AS_HELP_STRING([--with-iconv-bin=PATH], [specify where to find the iconv program]),
 533 [iconv_bin="${withval}"
 534  AC_DEFINE_UNQUOTED([ICONV_BIN], ["${iconv_bin}"],
 535                     [Path of directory of iconv program.])
 536  GDB_AC_DEFINE_RELOCATABLE(ICONV_BIN, iconv, ${iconv_bin})
 537 ])
 538
 539 # For the TUI, we need enhanced curses functionality.
 540 if test x"$enable_tui" != xno; then
 541   prefer_curses=yes
 542 fi
 543
 544 curses_found=no
 545 if test x"$prefer_curses" = xyes; then
 546   # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
 547   # curses library because the latter might not provide all the
 548   # functionality we need.  However, this leads to problems on systems
 549   # where the linker searches /usr/local/lib, but the compiler doesn't
 550   # search /usr/local/include, if ncurses is installed in /usr/local.  A
 551   # default installation of ncurses on alpha*-dec-osf* will lead to such
 552   # a situation.
 553   AC_SEARCH_LIBS(waddstr, [ncursesw ncurses cursesX curses])
 554
 555   if test "$ac_cv_search_waddstr" != no; then
 556     curses_found=yes
 557   fi
 558 fi
 559
 560 # Check whether we should enable the TUI, but only do so if we really
 561 # can.
 562 if test x"$enable_tui" != xno; then
 563   if test -d $srcdir/tui; then
 564     if test "$curses_found" != no; then
 565       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
 566       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
 567       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
 568       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
 569     else
 570       if test x"$enable_tui" = xyes; then
 571         AC_MSG_ERROR([no enhanced curses library found; disable TUI])
 572       else
 573         AC_MSG_WARN([no enhanced curses library found; disabling TUI])
 574       fi
 575     fi
 576   fi
 577 fi
 578
 579 # Since GDB uses Readline, we need termcap functionality.  In many
 580 # cases this will be provided by the curses library, but some systems
 581 # have a separate termcap library, or no curses library at all.
 582
 583 case $host_os in
 584   cygwin*)
 585     if test -d $srcdir/libtermcap; then
 586       LIBS="../libtermcap/libtermcap.a $LIBS"
 587       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 588     fi ;;
 589   go32* | *djgpp*)
 590     ac_cv_search_tgetent="none required"
 591     ;;
 592 esac
 593
 594 # These are the libraries checked by Readline.
 595 AC_SEARCH_LIBS(tgetent, [termcap tinfo curses ncursesw ncurses])
 596
 597 if test "$ac_cv_search_tgetent" = no; then
 598   CONFIG_OBS="$CONFIG_OBS stub-termcap.o"
 599 fi
 600
 601 AC_ARG_WITH([system-readline],
 602   [AS_HELP_STRING([--with-system-readline],
 603                   [use installed readline library])])
 604
 605 if test "$with_system_readline" = yes; then
 606   READLINE=-lreadline
 607   READLINE_DEPS=
 608   READLINE_CFLAGS=
 609   READLINE_TEXI_INCFLAG=
 610 else
 611   READLINE='$(READLINE_DIR)/libreadline.a'
 612   READLINE_DEPS='$(READLINE)'
 613   READLINE_CFLAGS='-I$(READLINE_SRC)/..'
 614   READLINE_TEXI_INCFLAG='-I $(READLINE_DIR)'
 615 fi
 616 AC_SUBST(READLINE)
 617 AC_SUBST(READLINE_DEPS)
 618 AC_SUBST(READLINE_CFLAGS)
 619 AC_SUBST(READLINE_TEXI_INCFLAG)
 620
 621 # Generate jit-reader.h
 622
 623 # This is typedeffed to GDB_CORE_ADDR in jit-reader.h
 624 TARGET_PTR=
 625
 626 AC_CHECK_SIZEOF(unsigned long long)
 627 AC_CHECK_SIZEOF(unsigned long)
 628 AC_CHECK_SIZEOF(unsigned __int128)
 629
 630 if test "x${ac_cv_sizeof_unsigned_long}" = "x8"; then
 631   TARGET_PTR="unsigned long"
 632 elif test "x${ac_cv_sizeof_unsigned_long_long}" = "x8"; then
 633   TARGET_PTR="unsigned long long"
 634 elif test "x${ac_cv_sizeof_unsigned___int128}" = "x16"; then
 635   TARGET_PTR="unsigned __int128"
 636 else
 637   TARGET_PTR="unsigned long"
 638 fi
 639
 640 AC_SUBST(TARGET_PTR)
 641 AC_CONFIG_FILES([jit-reader.h:jit-reader.in])
 642
 643 AC_SEARCH_LIBS(dlopen, dl)
 644
 645 GDB_AC_WITH_DIR([JIT_READER_DIR], [jit-reader-dir],
 646                 [directory to load the JIT readers from],
 647                 [${libdir}/gdb])
 648
 649 AC_ARG_WITH(expat,
 650   AS_HELP_STRING([--with-expat], [include expat support (auto/yes/no)]),
 651   [], [with_expat=auto])
 652 AC_MSG_CHECKING([whether to use expat])
 653 AC_MSG_RESULT([$with_expat])
 654
 655 if test "${with_expat}" = no; then
 656   AC_MSG_WARN([expat support disabled; some features may be unavailable.])
 657   HAVE_LIBEXPAT=no
 658 else
 659   AC_LIB_HAVE_LINKFLAGS([expat], [], [#include "expat.h"],
 660                         [XML_Parser p = XML_ParserCreate (0);])
 661   if test "$HAVE_LIBEXPAT" != yes; then
 662     if test "$with_expat" = yes; then
 663       AC_MSG_ERROR([expat is missing or unusable])
 664     else
 665       AC_MSG_WARN([expat is missing or unusable; some features may be unavailable.])
 666     fi
 667   else
 668     save_LIBS=$LIBS
 669     LIBS="$LIBS $LIBEXPAT"
 670     AC_CHECK_FUNCS(XML_StopParser)
 671     LIBS=$save_LIBS
 672   fi
 673 fi
 674
 675 AC_ARG_WITH(mpfr,
 676   AS_HELP_STRING([--with-mpfr], [include MPFR support (auto/yes/no)]),
 677   [], [with_mpfr=auto])
 678 AC_MSG_CHECKING([whether to use MPFR])
 679 AC_MSG_RESULT([$with_mpfr])
 680
 681 if test "${with_mpfr}" = no; then
 682   AC_MSG_WARN([MPFR support disabled; some features may be unavailable.])
 683   HAVE_LIBMPFR=no
 684 else
 685   AC_LIB_HAVE_LINKFLAGS([mpfr], [gmp], [#include <mpfr.h>],
 686                         [mpfr_exp_t exp; mpfr_t x;
 687                          mpfr_frexp (&exp, x, x, MPFR_RNDN);])
 688   if test "$HAVE_LIBMPFR" != yes; then
 689     if test "$with_mpfr" = yes; then
 690       AC_MSG_ERROR([MPFR is missing or unusable])
 691     else
 692       AC_MSG_WARN([MPFR is missing or unusable; some features may be unavailable.])
 693     fi
 694   fi
 695 fi
 696
 697 # --------------------- #
 698 # Check for libpython.  #
 699 # --------------------- #
 700
 701 dnl Utility to simplify finding libpython.
 702 dnl $1 = pythonX.Y
 703 dnl $2 = the shell variable to assign the result to
 704 dnl      If libpython is found we store $version here.
 705 dnl $3 = additional flags to add to CPPFLAGS
 706 dnl $4 = additional flags to add to LIBS
 707
 708 AC_DEFUN([AC_TRY_LIBPYTHON],
 709 [
 710   version=$1
 711   define([have_libpython_var],$2)
 712   new_CPPFLAGS=$3
 713   new_LIBS=$4
 714   AC_MSG_CHECKING([for ${version}])
 715   save_CPPFLAGS=$CPPFLAGS
 716   save_LIBS=$LIBS
 717   CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
 718   LIBS="$new_LIBS $LIBS"
 719   found_usable_python=no
 720   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "Python.h"]],
 721                                  [[Py_Initialize ();]])],
 722                  [have_libpython_var=${version}
 723                   found_usable_python=yes
 724                   PYTHON_CPPFLAGS=$new_CPPFLAGS
 725                   PYTHON_LIBS=$new_LIBS])
 726   CPPFLAGS=$save_CPPFLAGS
 727   LIBS=$save_LIBS
 728   AC_MSG_RESULT([${found_usable_python}])
 729 ])
 730
 731 dnl There are several different values for --with-python:
 732 dnl
 733 dnl no -   Don't include python support.
 734 dnl yes -  Include python support, error if it's missing.
 735 dnl        If we find python in $PATH, use it to fetch configure options,
 736 dnl        otherwise assume the compiler can find it with no help from us.
 737 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 738 dnl auto - Same as "yes", but if python is missing from the system,
 739 dnl        fall back to "no".
 740 dnl /path/to/python/exec-prefix -
 741 dnl        Use the python located in this directory.
 742 dnl        If /path/to/python/exec-prefix/bin/python exists, use it to find
 743 dnl        the compilation parameters.  Otherwise use
 744 dnl        -I/path/to/python/exec-prefix/include,
 745 dnl        -L/path/to/python/exec-prefix/lib.
 746 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 747 dnl        NOTE: This case is historical.  It is what was done for 7.0/7.1
 748 dnl        but is deprecated.
 749 dnl /path/to/python/executable -
 750 dnl        Run python-config.py with this version of python to fetch the
 751 dnl        compilation parameters.
 752 dnl        NOTE: This needn't be the real python executable.
 753 dnl        In a cross-compilation scenario (build != host), this could be
 754 dnl        a shell script that provides what python-config.py provides for
 755 dnl        --ldflags, --includes, --exec-prefix.
 756 dnl python-executable -
 757 dnl        Find python-executable in $PATH, and then handle the same as
 758 dnl        /path/to/python/executable.
 759 dnl
 760 dnl If a python program is specified, it is used to run python-config.py and
 761 dnl is passed --ldflags, --includes, --exec-prefix.
 762
 763 AC_ARG_WITH(python,
 764   AS_HELP_STRING([--with-python@<:@=PYTHON@:>@], [include python support (auto/yes/no/<python-program>)]),
 765   [], [with_python=auto])
 766 AC_MSG_CHECKING([whether to use python])
 767 AC_MSG_RESULT([$with_python])
 768
 769 if test "${with_python}" = no; then
 770   AC_MSG_WARN([python support disabled; some features may be unavailable.])
 771   have_libpython=no
 772 else
 773   case "${with_python}" in
 774   [[\\/]]* | ?:[[\\/]]*)
 775     if test -d ${with_python}; then
 776       # Assume the python binary is ${with_python}/bin/python.
 777       python_prog="${with_python}/bin/python"
 778       python_prefix=
 779       # If python does not exit ${with_python}/bin, then try in
 780       # ${with_python}.  On Windows/MinGW, this is where the Python
 781       # executable is.
 782       if test ! -x "${python_prog}"; then
 783         python_prog="${with_python}/python"
 784         python_prefix=
 785       fi
 786       if test ! -x "${python_prog}"; then
 787         # Fall back to gdb 7.0/7.1 behaviour.
 788         python_prog=missing
 789         python_prefix=${with_python}
 790       fi
 791     elif test -x "${with_python}"; then
 792       # While we can't run python compiled for $host (unless host == build),
 793       # the user could write a script that provides the needed information,
 794       # so we support that.
 795       python_prog=${with_python}
 796       python_prefix=
 797     else
 798       AC_ERROR(invalid value for --with-python)
 799     fi
 800     ;;
 801   */*)
 802     # Disallow --with-python=foo/bar.
 803     AC_ERROR(invalid value for --with-python)
 804     ;;
 805   *)
 806     # The user has either specified auto, yes, or the name of the python
 807     # program assumed to be in $PATH.
 808     python_prefix=
 809     case "${with_python}" in
 810     yes | auto)
 811       if test ${build} = ${host}; then
 812         AC_PATH_PROG(python_prog_path, python, missing)
 813         if test "${python_prog_path}" = missing; then
 814           python_prog=missing
 815         else
 816           python_prog=${python_prog_path}
 817         fi
 818       else
 819         # Not much we can do except assume the cross-compiler will find the
 820         # right files.
 821         python_prog=missing
 822       fi
 823       ;;
 824     *)
 825       # While we can't run python compiled for $host (unless host == build),
 826       # the user could write a script that provides the needed information,
 827       # so we support that.
 828       python_prog="${with_python}"
 829       AC_PATH_PROG(python_prog_path, ${python_prog}, missing)
 830       if test "${python_prog_path}" = missing; then
 831         AC_ERROR(unable to find python program ${python_prog})
 832       fi
 833       ;;
 834     esac
 835   esac
 836
 837   if test "${python_prog}" != missing; then
 838     # We have a python program to use, but it may be too old.
 839     # Don't flag an error for --with-python=auto (the default).
 840     have_python_config=yes
 841     python_includes=`${python_prog} ${srcdir}/python/python-config.py --includes`
 842     if test $? != 0; then
 843       have_python_config=failed
 844       if test "${with_python}" != auto; then
 845         AC_ERROR(failure running python-config --includes)
 846       fi
 847     fi
 848     python_libs=`${python_prog} ${srcdir}/python/python-config.py --ldflags`
 849     if test $? != 0; then
 850       have_python_config=failed
 851       if test "${with_python}" != auto; then
 852         AC_ERROR(failure running python-config --ldflags)
 853       fi
 854     fi
 855     python_prefix=`${python_prog} ${srcdir}/python/python-config.py --exec-prefix`
 856     if test $? != 0; then
 857       have_python_config=failed
 858       if test "${with_python}" != auto; then
 859         AC_ERROR(failure running python-config --exec-prefix)
 860       fi
 861     fi
 862   else
 863     # We do not have a python executable we can use to determine where
 864     # to find the Python headers and libs.  We cannot guess the include
 865     # path from the python_prefix either, because that include path
 866     # depends on the Python version.  So, there is nothing much we can
 867     # do except assume that the compiler will be able to find those files.
 868     python_includes=
 869     python_libs=
 870     have_python_config=no
 871   fi
 872
 873   # If we have python-config, only try the configuration it provides.
 874   # Otherwise fallback on the old way of trying different versions of
 875   # python in turn.
 876
 877   have_libpython=no
 878   if test "${have_python_config}" = yes; then
 879     # Determine the Python version by extracting "-lpython<version>"
 880     # part of the python_libs. <version> is usually X.Y with X and Y
 881     # being decimal numbers, but can also be XY (seen on Windows).
 882     #
 883     # The extraction is performed using sed with a regular expression.
 884     # Initially, the regexp used was using the '?' quantifier to make
 885     # the dot in the version number optional.  Unfortunately, this
 886     # does not work with non-GNU versions of sed because, because of
 887     # what looks like a limitation (the '?' quantifier does not work
 888     # with back-references).  We work around this limitation by using
 889     # the '*' quantifier instead.  It means that, in theory, we might
 890     # match unexpected version strings such as "-lpython2..7", but
 891     # this seems unlikely in practice.  And even if that happens,
 892     # an error will be triggered later on, when checking that version
 893     # number.
 894     python_version=`echo " ${python_libs} " \
 895                          | sed -e 's,^.* -l\(python[[0-9]]*[[.]]*[[0-9]]*\).*$,\1,'`
 896     case "${python_version}" in
 897     python*)
 898       AC_TRY_LIBPYTHON(${python_version}, have_libpython,
 899                        ${python_includes}, ${python_libs})
 900       ;;
 901     *)
 902       AC_MSG_ERROR([unable to determine python version from ${python_libs}])
 903       ;;
 904     esac
 905   elif test "${have_python_config}" != failed; then
 906     if test "${have_libpython}" = no; then
 907       AC_TRY_LIBPYTHON(python2.7, have_libpython,
 908                        ${python_includes}, "-lpython2.7 ${python_libs}")
 909     fi
 910     if test "${have_libpython}" = no; then
 911       AC_TRY_LIBPYTHON(python2.6, have_libpython,
 912                        ${python_includes}, "-lpython2.6 ${python_libs}")
 913     fi
 914     if test ${have_libpython} = no; then
 915       AC_TRY_LIBPYTHON(python2.5, have_libpython,
 916                        ${python_includes}, "-lpython2.5 ${python_libs}")
 917     fi
 918     if test ${have_libpython} = no; then
 919       AC_TRY_LIBPYTHON(python2.4, have_libpython,
 920                        ${python_includes}, "-lpython2.4 ${python_libs}")
 921     fi
 922   fi
 923   if test "${have_libpython}" = python2.7 -o "${have_libpython}" = python27; then
 924     AC_DEFINE(HAVE_LIBPYTHON2_7, 1, [Define if Python 2.7 is being used.])
 925   elif test "${have_libpython}" = python2.6 -o "${have_libpython}" = python26; then
 926     AC_DEFINE(HAVE_LIBPYTHON2_6, 1, [Define if Python 2.6 is being used.])
 927   elif test "${have_libpython}" = python2.5 -o "${have_libpython}" = python25; then
 928     AC_DEFINE(HAVE_LIBPYTHON2_5, 1, [Define if Python 2.5 is being used.])
 929   elif test "${have_libpython}" = python2.4 -o "${have_libpython}" = python24; then
 930     AC_DEFINE(HAVE_LIBPYTHON2_4, 1, [Define if Python 2.4 is being used.])
 931   fi
 932
 933   if test "${have_libpython}" = no; then
 934     case "${with_python}" in
 935     yes)
 936       AC_MSG_ERROR([python is missing or unusable])
 937       ;;
 938     auto)
 939       AC_MSG_WARN([python is missing or unusable; some features may be unavailable.])
 940       ;;
 941     *)
 942       AC_MSG_ERROR([no usable python found at ${with_python}])
 943       ;;
 944     esac
 945   else
 946     if test -n "${python_prefix}"; then
 947       AC_DEFINE_UNQUOTED(WITH_PYTHON_PATH, "${python_prefix}",
 948                          [Define if --with-python provides a path, either directly or via python-config.py --exec-prefix.])
 949       GDB_AC_DEFINE_RELOCATABLE(PYTHON_PATH, python, ${python_prefix})
 950     fi
 951   fi
 952 fi
 953
 954 if test "${have_libpython}" != no; then
 955   AC_DEFINE(HAVE_PYTHON, 1, [Define if Python interpreter is being linked in.])
 956   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_PYTHON_OBS)"
 957   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_PYTHON_DEPS)"
 958   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_PYTHON_SRCS)"
 959   CONFIG_INSTALL="$CONFIG_INSTALL install-python"
 960   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_PYTHON_CFLAGS)"
 961
 962   # Flags needed to compile Python code (taken from python-config --cflags).
 963   # We cannot call python-config directly because it will output whatever was
 964   # used when compiling the Python interpreter itself, including flags which
 965   # would make the python-related objects be compiled differently from the
 966   # rest of GDB (e.g., -O2 and -fPIC).
 967   if test "${GCC}" = yes; then
 968     tentative_python_cflags="-fno-strict-aliasing -DNDEBUG -fwrapv"
 969   fi
 970
 971   if test "x${tentative_python_cflags}" != x; then
 972     AC_MSG_CHECKING(compiler flags for python code)
 973     for flag in ${tentative_python_cflags}; do
 974       # Check that the compiler accepts it
 975       saved_CFLAGS="$CFLAGS"
 976       CFLAGS="$CFLAGS $flag"
 977       AC_TRY_COMPILE([],[],PYTHON_CFLAGS="${PYTHON_CFLAGS} $flag",)
 978       CFLAGS="$saved_CFLAGS"
 979     done
 980     AC_MSG_RESULT(${PYTHON_CFLAGS})
 981   fi
 982
 983   # On x64 Windows, Python's include headers, and pyconfig.h in
 984   # particular, rely on MS_WIN64 macro to detect that it's a 64bit
 985   # version of Windows.  Unfortunately, MS_WIN64 is only defined if
 986   # _MSC_VER, a Microsoft-specific macro, is defined.  So, when
 987   # building on x64 Windows with GCC, we define MS_WIN64 ourselves.
 988   # The issue was reported to the Python community, but still isn't
 989   # solved as of 2012-10-02 (http://bugs.python.org/issue4709).
 990
 991   case "$gdb_host" in
 992     mingw64)
 993            if test "${GCC}" = yes; then
 994              CPPFLAGS="$CPPFLAGS -DMS_WIN64"
 995            fi
 996            ;;
 997   esac
 998
 999   # Note that "python -m threading" cannot be used to check for
1000   # threading support due to a bug in Python 2.7.3
1001   # (http://bugs.python.org/issue15567).
1002   AC_MSG_CHECKING(whether python supports threads)
1003   saved_CPPFLAGS="${CPPFLAGS}"
1004   CPPFLAGS="${PYTHON_CPPFLAGS}"
1005   # Note that the test is reversed so that python_has_threads=yes on
1006   # unexpected failures.
1007   AC_PREPROC_IFELSE([AC_LANG_SOURCE([[
1008 #include <Python.h>
1009 #ifdef WITH_THREAD
1010 # error
1011 #endif
1012   ]])], [python_has_threads=no], [python_has_threads=yes])
1013   AC_MSG_RESULT(${python_has_threads})
1014   CPPFLAGS="${saved_CPPFLAGS}"
1015 else
1016   # Even if Python support is not compiled in, we need to have this file
1017   # included so that the "python" command, et.al., still exists.
1018   CONFIG_OBS="$CONFIG_OBS python/python.o"
1019   CONFIG_SRCS="$CONFIG_SRCS python/python.c"
1020 fi
1021
1022 # Work around Python http://bugs.python.org/issue10112.  See also
1023 # http://bugs.python.org/issue11410, otherwise -Wl,--dynamic-list has
1024 # no effect.  Note that the only test after this that uses Python is
1025 # the -rdynamic/-Wl,--dynamic-list test, and we do want that one to be
1026 # run without -export-dynamic too.
1027 PYTHON_LIBS=`echo $PYTHON_LIBS | sed -e 's/-Xlinker -export-dynamic//'`
1028
1029 AC_SUBST(PYTHON_CFLAGS)
1030 AC_SUBST(PYTHON_CPPFLAGS)
1031 AC_SUBST(PYTHON_LIBS)
1032 AM_CONDITIONAL(HAVE_PYTHON, test "${have_libpython}" != no)
1033
1034 # -------------------- #
1035 # Check for libguile.  #
1036 # -------------------- #
1037
1038 dnl Utility to simplify finding libguile.
1039 dnl $1 = pkg-config-program
1040 dnl $2 = space-separate list of guile versions to try
1041 dnl $3 = yes|no, indicating whether to flag errors or ignore them
1042 dnl $4 = the shell variable to assign the result to
1043 dnl      If libguile is found we store "yes" here.
1044
1045 AC_DEFUN([AC_TRY_LIBGUILE],
1046 [
1047   pkg_config=$1
1048   guile_version_list=$2
1049   flag_errors=$3
1050   define([have_libguile_var],$4)
1051   found_usable_guile=checking
1052   AC_MSG_CHECKING([for usable guile from ${pkg_config}])
1053   for guile_version in ${guile_version_list}; do
1054     ${pkg_config} --exists ${guile_version} 2>/dev/null
1055     if test $? != 0; then
1056       continue
1057     fi
1058     dnl pkg-config says the package exists, so if we get an error now,
1059     dnl that's bad.
1060     new_CPPFLAGS=`${pkg_config} --cflags ${guile_version}`
1061     if test $? != 0; then
1062       AC_MSG_ERROR([failure running pkg-config --cflags ${guile_version}])
1063     fi
1064     new_LIBS=`${pkg_config} --libs ${guile_version}`
1065     if test $? != 0; then
1066       AC_MSG_ERROR([failure running pkg-config --libs ${guile_version}])
1067     fi
1068     dnl If we get this far, great.
1069     found_usable_guile=${guile_version}
1070     break
1071   done
1072   if test "${found_usable_guile}" = "checking"; then
1073     if test "${flag_errors}" = "yes"; then
1074       AC_MSG_ERROR([unable to find usable guile version from "${guile_version_list}"])
1075     else
1076       found_usable_guile=no
1077     fi
1078   fi
1079   dnl One final sanity check.
1080   dnl The user could have said --with-guile=python-2.7.
1081   if test "${found_usable_guile}" != no; then
1082     save_CPPFLAGS=$CPPFLAGS
1083     save_LIBS=$LIBS
1084     CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
1085     LIBS="$LIBS $new_LIBS"
1086     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "libguile.h"]],
1087                                    [[scm_init_guile ();]])],
1088                    [have_libguile_var=yes
1089                     GUILE_CPPFLAGS=$new_CPPFLAGS
1090                     GUILE_LIBS=$new_LIBS],
1091                    [found_usable_guile=no])
1092     dnl scm_set_automatic_finalization_enabled added in Guile 2.2.
1093     AC_CHECK_FUNC(scm_set_automatic_finalization_enabled,
1094       AC_DEFINE(HAVE_GUILE_MANUAL_FINALIZATION, 1,
1095                 [Define if Guile supports manual finalization.])
1096     )
1097     CPPFLAGS=$save_CPPFLAGS
1098     LIBS=$save_LIBS
1099     if test "${found_usable_guile}" = no; then
1100       if test "${flag_errors}" = yes; then
1101         AC_MSG_FAILURE([linking guile version ${guile_version} test program failed])
1102       fi
1103     fi
1104   fi
1105   AC_MSG_RESULT([${found_usable_guile}])
1106 ])
1107
1108 dnl There are several different values for --with-guile:
1109 dnl
1110 dnl no -   Don't include guile support.
1111 dnl yes -  Include guile support, error if it's missing.
1112 dnl        The pkg-config program must be in $PATH.
1113 dnl auto - Same as "yes", but if guile is missing from the system,
1114 dnl        fall back to "no".
1115 dnl guile-version [guile-version-choice-2 ...] -
1116 dnl        A space-separated list of guile package versions to try.
1117 dnl        These are passed to pkg-config as-is.
1118 dnl        E.g., guile-2.0 or guile-2.2-uninstalled
1119 dnl        This requires making sure PKG_CONFIG_PATH is set appropriately.
1120 dnl /path/to/pkg-config -
1121 dnl        Use this pkg-config program.
1122 dnl        NOTE: This needn't be the "real" pkg-config program.
1123 dnl        It could be a shell script.  It is invoked as:
1124 dnl        pkg-config --exists $version
1125 dnl        pkg-config --cflags $version
1126 dnl        pkg-config --libs $version
1127 dnl        pkg-config --variable guild $version
1128 dnl        The script will be called with $version having each value in
1129 dnl        $try_guile_versions until --exists indicates success.
1130
1131 AC_ARG_WITH(guile,
1132   AS_HELP_STRING([--with-guile@<:@=GUILE@:>@], [include guile support (auto/yes/no/<guile-version>/<pkg-config-program>)]),
1133   [], [with_guile=auto])
1134 AC_MSG_CHECKING([whether to use guile])
1135 AC_MSG_RESULT([$with_guile])
1136
1137 dnl We check guile with pkg-config.
1138 AC_PATH_PROG(pkg_config_prog_path, pkg-config, missing)
1139
1140 try_guile_versions="guile-2.0"
1141 have_libguile=no
1142 case "${with_guile}" in
1143 no)
1144   AC_MSG_WARN([guile support disabled; some features will be unavailable.])
1145   ;;
1146 auto)
1147   if test "${pkg_config_prog_path}" = "missing"; then
1148     AC_MSG_WARN([pkg-config not found, guile support disabled])
1149   else
1150     AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${try_guile_versions}, no, have_libguile)
1151   fi
1152   ;;
1153 yes)
1154   if test "${pkg_config_prog_path}" = "missing"; then
1155     AC_MSG_ERROR([pkg-config not found])
1156   fi
1157   AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${try_guile_versions}, yes, have_libguile)
1158   ;;
1159 [[\\/]]* | ?:[[\\/]]*)
1160   if test -x "${with_guile}"; then
1161     AC_TRY_LIBGUILE(${with_guile}, ${try_guile_versions}, yes, have_libguile)
1162   else
1163     AC_MSG_ERROR([Guile config program not executable: ${with_guile}])
1164   fi
1165   ;;
1166 "" | */*)
1167   # Disallow --with=guile="" and --with-guile=foo/bar.
1168   AC_MSG_ERROR([invalid value for --with-guile])
1169   ;;
1170 *)
1171   # A space separate list of guile versions to try, in order.
1172   if test "${pkg_config_prog_path}" = "missing"; then
1173     AC_MSG_ERROR([pkg-config not found])
1174   fi
1175   AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${with_guile}, yes, have_libguile)
1176   ;;
1177 esac
1178
1179 if test "${have_libguile}" != no; then
1180   dnl Get the name of the 'guild' program.
1181   case "${with_guile}" in
1182   [[\\/]]* | ?:[[\\/]]*)
1183     GDB_GUILE_PROGRAM_NAMES(["${with_guile}"], ["${guile_version}"])
1184     ;;
1185   *)
1186     GDB_GUILE_PROGRAM_NAMES(["${pkg_config_prog_path}"], ["${guile_version}"])
1187     ;;
1188   esac
1189
1190   dnl Make sure guild can handle this host.
1191   GDB_TRY_GUILD([$srcdir/guile/lib/gdb/support.scm])
1192   dnl If not, disable guile support.
1193   if test "$ac_cv_guild_ok" = no; then
1194     have_libguile=no
1195     AC_MSG_WARN(disabling guile support, $GUILD fails compiling for $host)
1196   fi
1197 fi
1198
1199 if test "${have_libguile}" != no; then
1200   AC_DEFINE(HAVE_GUILE, 1, [Define if Guile interpreter is being linked in.])
1201   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_GUILE_OBS)"
1202   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_GUILE_DEPS)"
1203   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_GUILE_SRCS)"
1204   CONFIG_INSTALL="$CONFIG_INSTALL install-guile"
1205   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_GUILE_CFLAGS)"
1206
1207   dnl The 'scm_new_smob' function appeared in Guile 2.0.6.
1208   save_LIBS="$LIBS"
1209   save_CPPFLAGS="$CPPFLAGS"
1210   LIBS="$GUILE_LIBS"
1211   CPPFLAGS="$GUILE_CPPFLAGS"
1212   AC_CHECK_FUNCS([scm_new_smob])
1213   LIBS="$save_LIBS"
1214   CPPFLAGS="$save_CPPFLAGS"
1215 else
1216   # Even if Guile support is not compiled in, we need to have these files
1217   # included.
1218   CONFIG_OBS="$CONFIG_OBS guile/guile.o"
1219   CONFIG_SRCS="$CONFIG_SRCS guile/guile.c"
1220 fi
1221 AC_SUBST(GUILE_CPPFLAGS)
1222 AC_SUBST(GUILE_LIBS)
1223 AM_CONDITIONAL(HAVE_GUILE, test "${have_libguile}" != no)
1224
1225 # --------------------- #
1226 # Check for libmcheck.  #
1227 # --------------------- #
1228
1229 # Enable -lmcheck by default (it provides cheap-enough memory mangling),
1230 # but turn it off if Python is enabled with threads, since -lmcheck is
1231 # not thread safe (http://sourceware.org/bugzilla/show_bug.cgi?id=9939),
1232 # and for releases.
1233 if test \( "${have_libpython}" = "no" -o "${python_has_threads}" = "no" \) \
1234    && $development; then
1235   libmcheck_default=yes
1236 else
1237   libmcheck_default=no
1238 fi
1239 GDB_AC_LIBMCHECK(${libmcheck_default})
1240
1241 if test "$ENABLE_LIBMCHECK" = "yes" \
1242         -a "${have_libpython}" != "no" \
1243         -a "${python_has_threads}" = "yes" ; then
1244   AC_MSG_WARN(--enable-libmcheck may lead to spurious crashes if threads are used in python)
1245 fi
1246
1247 AC_ARG_WITH(intel_pt,
1248   AS_HELP_STRING([--with-intel-pt], [include Intel Processor Trace support (auto/yes/no)]),
1249   [], [with_intel_pt=auto])
1250 AC_MSG_CHECKING([whether to use intel pt])
1251 AC_MSG_RESULT([$with_intel_pt])
1252
1253 if test "${with_intel_pt}" = no; then
1254   AC_MSG_WARN([Intel Processor Trace support disabled; some features may be unavailable.])
1255   HAVE_LIBIPT=no
1256 else
1257   AC_PREPROC_IFELSE([AC_LANG_SOURCE([[
1258 #include <linux/perf_event.h>
1259 #ifndef PERF_ATTR_SIZE_VER5
1260 # error
1261 #endif
1262   ]])], [perf_event=yes], [perf_event=no])
1263   if test "$perf_event" != yes; then
1264     if test "$with_intel_pt" = yes; then
1265       AC_MSG_ERROR([linux/perf_event.h missing or too old])
1266     else
1267       AC_MSG_WARN([linux/perf_event.h missing or too old; some features may be unavailable.])
1268     fi
1269   fi
1270
1271   AC_LIB_HAVE_LINKFLAGS([ipt], [], [#include "intel-pt.h"], [pt_insn_alloc_decoder (0);])
1272   if test "$HAVE_LIBIPT" != yes; then
1273     if test "$with_intel_pt" = yes; then
1274       AC_MSG_ERROR([libipt is missing or unusable])
1275     else
1276       AC_MSG_WARN([libipt is missing or unusable; some features may be unavailable.])
1277     fi
1278   else
1279     save_LIBS=$LIBS
1280     LIBS="$LIBS $LIBIPT"
1281     AC_CHECK_FUNCS(pt_insn_event)
1282     AC_CHECK_MEMBERS([struct pt_insn.enabled, struct pt_insn.resynced], [], [],
1283                      [#include <intel-pt.h>])
1284     LIBS=$save_LIBS
1285   fi
1286 fi
1287
1288 # ------------------------- #
1289 # Checks for header files.  #
1290 # ------------------------- #
1291
1292 AC_HEADER_STDC
1293 # elf_hp.h is for HP/UX 64-bit shared library support.
1294 AC_CHECK_HEADERS([nlist.h machine/reg.h poll.h sys/poll.h proc_service.h \
1295                   thread_db.h \
1296                   sys/file.h sys/filio.h sys/ioctl.h sys/param.h \
1297                   sys/resource.h sys/procfs.h sys/ptrace.h ptrace.h \
1298                   sys/reg.h sys/debugreg.h sys/select.h \
1299                   termios.h elf_hp.h \
1300                   dlfcn.h])
1301 AC_CHECK_HEADERS(sys/user.h, [], [],
1302 [#if HAVE_SYS_PARAM_H
1303 # include <sys/param.h>
1304 #endif
1305 ])
1306
1307 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncursesw/ncurses.h ncurses/ncurses.h ncurses/term.h)
1308 AC_CHECK_HEADERS(term.h, [], [],
1309 [#if HAVE_CURSES_H
1310 # include <curses.h>
1311 #endif
1312 ])
1313
1314 # ------------------------- #
1315 # Checks for declarations.  #
1316 # ------------------------- #
1317
1318 libiberty_INIT
1319
1320 AC_CHECK_DECLS([snprintf])
1321 AM_LC_MESSAGES
1322
1323 # ----------------------- #
1324 # Checks for structures.  #
1325 # ----------------------- #
1326
1327 AC_CHECK_MEMBERS([struct stat.st_blocks, struct stat.st_blksize])
1328
1329 # ------------------ #
1330 # Checks for types.  #
1331 # ------------------ #
1332
1333 AC_CHECK_TYPES(socklen_t, [], [],
1334 [#include <sys/types.h>
1335 #include <sys/socket.h>
1336 ])
1337
1338 # ------------------------------------- #
1339 # Checks for compiler characteristics.  #
1340 # ------------------------------------- #
1341
1342 AC_C_CONST
1343 AC_C_INLINE
1344 AC_C_BIGENDIAN
1345
1346 # ------------------------------ #
1347 # Checks for library functions.  #
1348 # ------------------------------ #
1349
1350 AC_FUNC_MMAP
1351 AC_FUNC_VFORK
1352 AC_CHECK_FUNCS([getauxval getrusage getuid getgid \
1353                 pipe poll pread pread64 pwrite resize_term \
1354                 sbrk getpgid setpgid setpgrp setsid \
1355                 sigaction sigprocmask sigsetmask socketpair \
1356                 ttrace wborder wresize setlocale iconvlist libiconvlist btowc \
1357                 setrlimit getrlimit posix_madvise waitpid \
1358                 ptrace64 sigaltstack mkdtemp setns])
1359 AM_LANGINFO_CODESET
1360 GDB_AC_COMMON
1361
1362 # Check the return and argument types of ptrace.
1363 GDB_AC_PTRACE
1364
1365 dnl AC_FUNC_SETPGRP does not work when cross compiling
1366 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
1367 if test "$cross_compiling" = no; then
1368   AC_FUNC_SETPGRP
1369 else
1370   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
1371     [AC_TRY_COMPILE([
1372 #include <unistd.h>
1373 ], [
1374   if (setpgrp(1,1) == -1)
1375     exit (0);
1376   else
1377     exit (1);
1378 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
1379 if test $ac_cv_func_setpgrp_void = yes; then
1380   AC_DEFINE(SETPGRP_VOID, 1)
1381 fi
1382 fi
1383
1384 # Assume we'll default to using the included libiberty regex.
1385 gdb_use_included_regex=yes
1386
1387 # However, if the system regex is GNU regex, then default to *not*
1388 # using the included regex.
1389 AC_CACHE_CHECK(
1390   [for GNU regex],
1391   [gdb_cv_have_gnu_regex],
1392   [AC_TRY_COMPILE(
1393     [#include <gnu-versions.h>],
1394     [#define REGEX_INTERFACE_VERSION 1
1395 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
1396 # error "Version mismatch"
1397 #endif],
1398     gdb_cv_have_gnu_regex=yes,
1399     gdb_cv_have_gnu_regex=no)])
1400 if test $gdb_cv_have_gnu_regex = yes; then
1401   gdb_use_included_regex=no
1402 fi
1403
1404 AC_ARG_WITH(included-regex,
1405   AS_HELP_STRING([--without-included-regex], [don't use included regex; this is the default on systems with version 2 of the GNU C library (use with caution on other system)]),
1406   gdb_with_regex=$withval,
1407   gdb_with_regex=$gdb_use_included_regex)
1408 if test "$gdb_with_regex" = yes; then
1409   AC_DEFINE(USE_INCLUDED_REGEX, 1,
1410     [Define to 1 if the regex included in libiberty should be used.])
1411 fi
1412
1413 # Check if <sys/proc.h> defines `struct thread' with a td_pcb member.
1414 AC_CHECK_MEMBERS([struct thread.td_pcb], [], [],
1415 [#include <sys/param.h>
1416 #include <sys/proc.h>
1417 ])
1418
1419 # See if <sys/lwp.h> defines `struct lwp`.
1420 AC_CACHE_CHECK([for struct lwp], gdb_cv_struct_lwp,
1421 [AC_TRY_COMPILE([#include <sys/param.h>
1422 #define _KMEMUSER
1423 #include <sys/lwp.h>], [struct lwp l;],
1424 gdb_cv_struct_lwp=yes, gdb_cv_struct_lwp=no)])
1425 if test $gdb_cv_struct_lwp = yes; then
1426   AC_DEFINE(HAVE_STRUCT_LWP, 1,
1427             [Define to 1 if your system has struct lwp.])
1428 fi
1429
1430 # See if <machine/reg.h> degines `struct reg'.
1431 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
1432 [AC_TRY_COMPILE([#include <sys/types.h>
1433 #include <machine/reg.h>], [struct reg r;],
1434 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
1435 if test $gdb_cv_struct_reg = yes; then
1436   AC_DEFINE(HAVE_STRUCT_REG, 1,
1437             [Define to 1 if your system has struct reg in <machine/reg.h>.])
1438 fi
1439
1440 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
1441 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
1442 AC_CHECK_MEMBERS([struct reg.r_fs, struct reg.r_gs], [], [],
1443                  [#include <sys/types.h>
1444 #include <machine/reg.h>])
1445
1446 # See if <sys/user.h> supports the %fs_base and %gs_bas amd64 segment registers.
1447 # Older amd64 Linux's don't have the fs_base and gs_base members of
1448 # `struct user_regs_struct'.
1449 AC_CHECK_MEMBERS([struct user_regs_struct.fs_base, struct user_regs_struct.gs_base],
1450      [], [], [#include <sys/types.h>
1451 #include <sys/user.h>])
1452
1453 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
1454 AC_MSG_CHECKING(for PTRACE_GETREGS)
1455 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
1456 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1457                 [PTRACE_GETREGS;],
1458                 [gdb_cv_have_ptrace_getregs=yes],
1459                 [gdb_cv_have_ptrace_getregs=no])])
1460 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
1461 if test $gdb_cv_have_ptrace_getregs = yes; then
1462   AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
1463   [Define if sys/ptrace.h defines the PTRACE_GETREGS request.])
1464 fi
1465
1466 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
1467 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
1468 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
1469 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1470                 [PTRACE_GETFPXREGS;],
1471                 [gdb_cv_have_ptrace_getfpxregs=yes],
1472                 [gdb_cv_have_ptrace_getfpxregs=no])])
1473 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
1474 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
1475   AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
1476   [Define if sys/ptrace.h defines the PTRACE_GETFPXREGS request.])
1477 fi
1478
1479 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
1480 AC_MSG_CHECKING(for PT_GETDBREGS)
1481 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
1482 [AC_TRY_COMPILE([#include <sys/types.h>
1483 #include <sys/ptrace.h>],
1484                 [PT_GETDBREGS;],
1485                 [gdb_cv_have_pt_getdbregs=yes],
1486                 [gdb_cv_have_pt_getdbregs=no])])
1487 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
1488 if test $gdb_cv_have_pt_getdbregs = yes; then
1489   AC_DEFINE(HAVE_PT_GETDBREGS, 1,
1490   [Define if sys/ptrace.h defines the PT_GETDBREGS request.])
1491 fi
1492
1493 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
1494 AC_MSG_CHECKING(for PT_GETXMMREGS)
1495 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
1496 [AC_TRY_COMPILE([#include <sys/types.h>
1497 #include <sys/ptrace.h>],
1498                 [PT_GETXMMREGS;],
1499                 [gdb_cv_have_pt_getxmmregs=yes],
1500                 [gdb_cv_have_pt_getxmmregs=no])])
1501 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
1502 if test $gdb_cv_have_pt_getxmmregs = yes; then
1503   AC_DEFINE(HAVE_PT_GETXMMREGS, 1,
1504   [Define if sys/ptrace.h defines the PT_GETXMMREGS request.])
1505 fi
1506
1507 # See if <sys/ptrace.h> supports LWP names on FreeBSD
1508 # Older FreeBSD versions don't have the pl_tdname member of
1509 # `struct ptrace_lwpinfo'.
1510 AC_CHECK_MEMBERS([struct ptrace_lwpinfo.pl_tdname], [], [],
1511                  [#include <sys/ptrace.h>])
1512
1513 # See if <sys/ptrace.h> supports syscall fields on FreeBSD.  The
1514 # pl_syscall_code member of `struct ptrace_lwpinfo' was added in
1515 # FreeBSD 10.3.
1516 AC_CHECK_MEMBERS([struct ptrace_lwpinfo.pl_syscall_code], [], [],
1517                  [#include <sys/ptrace.h>])
1518
1519 if test "$ac_cv_header_sys_procfs_h" = yes; then
1520   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
1521   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
1522   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
1523   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
1524   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
1525   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
1526   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
1527
1528   dnl Check for broken prfpregset_t type
1529
1530   dnl For Linux/i386, glibc 2.1.3 was released with a bogus
1531   dnl prfpregset_t type (it's a typedef for the pointer to a struct
1532   dnl instead of the struct itself).  We detect this here, and work
1533   dnl around it in gdb_proc_service.h.
1534
1535   if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
1536     AC_MSG_CHECKING(whether prfpregset_t type is broken)
1537     AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
1538       [AC_TRY_RUN([#include <sys/procfs.h>
1539        int main ()
1540        {
1541          if (sizeof (prfpregset_t) == sizeof (void *))
1542            return 1;
1543          return 0;
1544        }],
1545        gdb_cv_prfpregset_t_broken=no,
1546        gdb_cv_prfpregset_t_broken=yes,
1547        gdb_cv_prfpregset_t_broken=yes)])
1548     AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
1549     if test $gdb_cv_prfpregset_t_broken = yes; then
1550       AC_DEFINE(PRFPREGSET_T_BROKEN, 1,
1551       [Define if the prfpregset_t type is broken.])
1552     fi
1553   fi
1554 fi
1555
1556 # Check if the compiler supports the `long long' type.
1557
1558 AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long,
1559                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1560 [[extern long long foo;]],
1561 [[switch (foo & 2) { case 0: return 1; }]])],
1562                                   gdb_cv_c_long_long=yes,
1563                                   gdb_cv_c_long_long=no)])
1564 if test $gdb_cv_c_long_long != yes; then
1565   # libdecnumber requires long long.
1566   AC_MSG_ERROR([Compiler must support long long for GDB.])
1567 fi
1568
1569 # Check if the compiler and runtime support printing long longs.
1570
1571 AC_CACHE_CHECK([for long long support in printf],
1572                gdb_cv_printf_has_long_long,
1573                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1574 [[char buf[32];
1575   long long l = 0;
1576   l = (l << 16) + 0x0123;
1577   l = (l << 16) + 0x4567;
1578   l = (l << 16) + 0x89ab;
1579   l = (l << 16) + 0xcdef;
1580   sprintf (buf, "0x%016llx", l);
1581   return (strcmp ("0x0123456789abcdef", buf));]])],
1582                               gdb_cv_printf_has_long_long=yes,
1583                               gdb_cv_printf_has_long_long=no,
1584                               gdb_cv_printf_has_long_long=no)])
1585 if test $gdb_cv_printf_has_long_long = yes; then
1586   AC_DEFINE(PRINTF_HAS_LONG_LONG, 1,
1587             [Define to 1 if the "%ll" format works to print long longs.])
1588 fi
1589
1590 # Check if the compiler and runtime support printing decfloats.
1591
1592 AC_CACHE_CHECK([for decfloat support in printf],
1593                gdb_cv_printf_has_decfloat,
1594                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1595 [[char buf[64];
1596   _Decimal32 d32 = 1.2345df;
1597   _Decimal64 d64 = 1.2345dd;
1598   _Decimal128 d128 = 1.2345dl;
1599   sprintf (buf, "Decimal32: %H\nDecimal64: %D\nDecimal128: %DD", d32, d64, d128);
1600   return (strcmp ("Decimal32: 1.2345\nDecimal64: 1.2345\nDecimal128: 1.2345", buf));]])],
1601                               gdb_cv_printf_has_decfloat=yes,
1602                               gdb_cv_printf_has_decfloat=no,
1603                               gdb_cv_printf_has_decfloat=no)])
1604 if test $gdb_cv_printf_has_decfloat = yes; then
1605   AC_DEFINE(PRINTF_HAS_DECFLOAT, 1,
1606             [Define to 1 if the "%H, %D and %DD" formats work to print decfloats.])
1607 fi
1608
1609 # Check if the compiler supports the `long double' type.  We can't use
1610 # AC_C_LONG_DOUBLE because that one does additional checks on the
1611 # constants defined in <float.h> that fail on some systems,
1612 # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6.
1613
1614 AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double,
1615                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])],
1616                                   gdb_cv_c_long_double=yes,
1617                                   gdb_cv_c_long_double=no)])
1618 if test $gdb_cv_c_long_double = yes; then
1619   AC_DEFINE(HAVE_LONG_DOUBLE, 1,
1620            [Define to 1 if the compiler supports long double.])
1621 fi
1622
1623 # Check if the compiler and runtime support printing long doubles.
1624
1625 AC_CACHE_CHECK([for long double support in printf],
1626                gdb_cv_printf_has_long_double,
1627                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1628 [[char buf[16];
1629   long double f = 3.141592653;
1630   sprintf (buf, "%Lg", f);
1631   return (strncmp ("3.14159", buf, 7));]])],
1632                               gdb_cv_printf_has_long_double=yes,
1633                               gdb_cv_printf_has_long_double=no,
1634                               gdb_cv_printf_has_long_double=no)])
1635 if test $gdb_cv_printf_has_long_double = yes; then
1636   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1,
1637             [Define to 1 if the "%Lg" format works to print long doubles.])
1638 fi
1639
1640 # Check if the compiler and runtime support scanning long doubles.
1641
1642 AC_CACHE_CHECK([for long double support in scanf],
1643                gdb_cv_scanf_has_long_double,
1644                [AC_RUN_IFELSE([AC_LANG_PROGRAM(
1645 [[#include <stdio.h>]],
1646 [[char *buf = "3.141592653";
1647   long double f = 0;
1648   sscanf (buf, "%Lg", &f);
1649   return !(f > 3.14159 && f < 3.14160);]])],
1650                               gdb_cv_scanf_has_long_double=yes,
1651                               gdb_cv_scanf_has_long_double=no,
1652                               gdb_cv_scanf_has_long_double=no)])
1653 if test $gdb_cv_scanf_has_long_double = yes; then
1654   AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1,
1655             [Define to 1 if the "%Lg" format works to scan long doubles.])
1656 fi
1657
1658 case ${host_os} in
1659 aix*)
1660   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1661     SAVE_LDFLAGS=$LDFLAGS
1662
1663     case $GCC in
1664     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1665     *) gdb_cv_bigtoc=-bbigtoc ;;
1666     esac
1667
1668     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1669     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1670     LDFLAGS="${SAVE_LDFLAGS}"
1671   ])
1672   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
1673   ;;
1674 esac
1675
1676 AC_MSG_CHECKING(for the dynamic export flag)
1677 dynamic_list=false
1678 if test "${gdb_native}" = yes; then
1679    # The dynamically loaded libthread_db needs access to symbols in the gdb
1680    # executable.  Older GNU ld supports --export-dynamic but --dynamic-list
1681    # may not be supported there.
1682    old_LDFLAGS="$LDFLAGS"
1683    # Older GNU ld supports --export-dynamic but --dynamic-list it does not.
1684    RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
1685    LDFLAGS="$LDFLAGS $RDYNAMIC"
1686    if test "${have_libpython}" = no; then
1687      AC_TRY_LINK([], [], [dynamic_list=true])
1688    else
1689      # Workaround http://bugs.python.org/issue4434 where static
1690      # libpythonX.Y.a would get its symbols required for
1691      # pythonX.Y/lib-dynload/*.so modules hidden by -Wl,--dynamic-list.
1692      # Problem does not happen for the recommended libpythonX.Y.so linkage.
1693
1694      # Note the workaround for Python
1695      # http://bugs.python.org/issue10112 earlier has removed
1696      # -export-dynamic from PYTHON_LIBS.  That's exactly what we want
1697      # here too, as otherwise it'd make this -Wl,--dynamic-list test
1698      # always pass.
1699      old_CFLAGS="$CFLAGS"
1700      CFLAGS="$CFLAGS $PYTHON_CFLAGS"
1701      old_LIBS="$LIBS"
1702      LIBS="$LIBS $PYTHON_LIBS"
1703      old_CPPFLAGS="$CPPFLAGS"
1704      CPPFLAGS="$CPPFLAGS $PYTHON_CPPFLAGS"
1705      AC_RUN_IFELSE(
1706        [AC_LANG_PROGRAM(
1707          [#include "Python.h"],
1708          [int err;
1709           Py_Initialize ();
1710           err = PyRun_SimpleString ("import itertools\n");
1711           Py_Finalize ();
1712           return err == 0 ? 0 : 1;])],
1713        [dynamic_list=true], [], [true])
1714      LIBS="$old_LIBS"
1715      CFLAGS="$old_CFLAGS"
1716      CPPFLAGS="$old_CPPFLAGS"
1717    fi
1718    LDFLAGS="$old_LDFLAGS"
1719 fi
1720 if $dynamic_list; then
1721   found="-Wl,--dynamic-list"
1722   RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'
1723 else
1724   found="-rdynamic"
1725   RDYNAMIC="-rdynamic"
1726 fi
1727 AC_SUBST(RDYNAMIC)
1728 AC_MSG_RESULT($found)
1729
1730 dnl For certain native configurations, we need to check whether thread
1731 dnl support can be built in or not.
1732 dnl
1733 dnl Note that we only want this if we are both native (host == target),
1734 dnl and not doing a canadian cross build (build == host).
1735
1736 if test ${build} = ${host} -a ${host} = ${target} ; then
1737    case ${host_os} in
1738    aix*)
1739       AC_MSG_CHECKING(for AiX thread debugging library)
1740       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
1741                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
1742                                    [#ifndef PTHDB_VERSION_3
1743                                     #error
1744                                     #endif],
1745                                    gdb_cv_have_aix_thread_debug=yes,
1746                                    gdb_cv_have_aix_thread_debug=no)])
1747       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1748       if test $gdb_cv_have_aix_thread_debug = yes; then
1749          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1750          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1751          LIBS="$LIBS -lpthdebug"
1752
1753          # Older versions of AIX do not provide the declaration for
1754          # the getthrds function (it appears that it was introduced
1755          # with AIX 6.x).
1756          AC_CHECK_DECLS(getthrds, [], [], [[#include <procinfo.h>]])
1757       fi
1758       ;;
1759    esac
1760    AC_SUBST(CONFIG_LDFLAGS)
1761 fi
1762
1763 dnl See if we have a thread_db header file that has TD_NOTALLOC and
1764 dnl other error codes.
1765 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1766    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
1767                   gdb_cv_thread_db_h_has_td_notalloc,
1768      AC_TRY_COMPILE(
1769        [#include <thread_db.h>],
1770        [int i = TD_NOTALLOC;],
1771        gdb_cv_thread_db_h_has_td_notalloc=yes,
1772        gdb_cv_thread_db_h_has_td_notalloc=no
1773      )
1774    )
1775    AC_CACHE_CHECK([whether <thread_db.h> has TD_VERSION],
1776                   gdb_cv_thread_db_h_has_td_version,
1777      AC_TRY_COMPILE(
1778        [#include <thread_db.h>],
1779        [int i = TD_VERSION;],
1780        gdb_cv_thread_db_h_has_td_version=yes,
1781        gdb_cv_thread_db_h_has_td_version=no
1782      )
1783    )
1784    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTLS],
1785                   gdb_cv_thread_db_h_has_td_notls,
1786      AC_TRY_COMPILE(
1787        [#include <thread_db.h>],
1788        [int i = TD_NOTLS;],
1789        gdb_cv_thread_db_h_has_td_notls=yes,
1790        gdb_cv_thread_db_h_has_td_notls=no
1791      )
1792    )
1793 fi
1794 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1795   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1796             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1797 fi
1798 if test "x$gdb_cv_thread_db_h_has_td_version" = "xyes"; then
1799   AC_DEFINE(THREAD_DB_HAS_TD_VERSION, 1,
1800             [Define if <thread_db.h> has the TD_VERSION error code.])
1801 fi
1802 if test "x$gdb_cv_thread_db_h_has_td_notls" = "xyes"; then
1803   AC_DEFINE(THREAD_DB_HAS_TD_NOTLS, 1,
1804             [Define if <thread_db.h> has the TD_NOTLS error code.])
1805 fi
1806
1807 dnl Check if we can disable the virtual address space randomization.
1808 dnl The functionality of setarch -R.
1809 AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>])
1810 define([PERSONALITY_TEST], [AC_LANG_PROGRAM([#include <sys/personality.h>], [
1811 #      if !HAVE_DECL_ADDR_NO_RANDOMIZE
1812 #       define ADDR_NO_RANDOMIZE 0x0040000
1813 #      endif
1814        /* Test the flag could be set and stays set.  */
1815        personality (personality (0xffffffff) | ADDR_NO_RANDOMIZE);
1816        if (!(personality (personality (0xffffffff)) & ADDR_NO_RANDOMIZE))
1817            return 1])])
1818 AC_RUN_IFELSE([PERSONALITY_TEST],
1819               [have_personality=true],
1820               [have_personality=false],
1821               [AC_LINK_IFELSE([PERSONALITY_TEST],
1822                               [have_personality=true],
1823                               [have_personality=false])])
1824 if $have_personality
1825 then
1826     AC_DEFINE([HAVE_PERSONALITY], 1,
1827               [Define if you support the personality syscall.])
1828 fi
1829
1830 dnl Set the host's .gdbinit filename.
1831 case $host_os in
1832   go32* | *djgpp*)
1833     gdbinit=gdb.ini
1834     ;;
1835   *)
1836     gdbinit=.gdbinit
1837     ;;
1838 esac
1839 AC_DEFINE_UNQUOTED(GDBINIT,"$gdbinit",[The .gdbinit filename.])
1840
1841 dnl Handle optional features that can be enabled.
1842
1843 # Support for --with-sysroot is a copy of GDB_AC_WITH_DIR,
1844 # except that the argument to --with-sysroot is optional.
1845 # --with-sysroot (or --with-sysroot=yes) sets the default sysroot path.
1846 if test "x$with_sysroot" = xyes; then
1847   with_sysroot="${exec_prefix}/${target_alias}/sys-root"
1848 fi
1849 AC_ARG_WITH(sysroot,
1850   AS_HELP_STRING([--with-sysroot@<:@=DIR@:>@],
1851                  [search for usr/lib et al within DIR]),
1852   [TARGET_SYSTEM_ROOT=$withval], [TARGET_SYSTEM_ROOT=])
1853 AC_DEFINE_DIR(TARGET_SYSTEM_ROOT, TARGET_SYSTEM_ROOT,
1854               [search for usr/lib et al within DIR])
1855 AC_SUBST(TARGET_SYSTEM_ROOT)
1856 GDB_AC_DEFINE_RELOCATABLE(TARGET_SYSTEM_ROOT, sysroot, ${ac_define_dir})
1857
1858 GDB_AC_WITH_DIR(SYSTEM_GDBINIT, system-gdbinit,
1859     [automatically load a system-wide gdbinit file],
1860     [])
1861
1862 AM_GDB_WARNINGS
1863
1864 # In the Cygwin environment, we need some additional flags.
1865 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1866 [AC_EGREP_CPP(^lose$, [
1867 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1868 lose
1869 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1870
1871
1872 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1873 SER_HARDWIRE="ser-base.o ser-unix.o ser-pipe.o ser-tcp.o"
1874 case ${host} in
1875   *go32* ) SER_HARDWIRE=ser-go32.o ;;
1876   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
1877   *mingw32*) SER_HARDWIRE="ser-base.o ser-tcp.o ser-mingw.o" ;;
1878 esac
1879 AC_SUBST(SER_HARDWIRE)
1880
1881 # libreadline needs libuser32.a in a cygwin environment
1882 WIN32LIBS=
1883 if test x$gdb_cv_os_cygwin = xyes; then
1884     WIN32LIBS="-luser32"
1885     case "${target}" in
1886         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
1887         ;;
1888     esac
1889 fi
1890
1891 # The ser-tcp.c module requires sockets.
1892 case ${host} in
1893   *mingw32*)
1894     AC_DEFINE(USE_WIN32API, 1,
1895               [Define if we should use the Windows API, instead of the
1896                POSIX API.  On Windows, we use the Windows API when
1897                building for MinGW, but the POSIX API when building
1898                for Cygwin.])
1899     WIN32LIBS="$WIN32LIBS -lws2_32"
1900     ;;
1901 esac
1902 AC_SUBST(WIN32LIBS)
1903
1904 # Add ELF support to GDB, but only if BFD includes ELF support.
1905 GDB_AC_CHECK_BFD([for ELF support in BFD], gdb_cv_var_elf,
1906                  [bfd_get_elf_phdr_upper_bound (NULL)], elf-bfd.h)
1907 if test $gdb_cv_var_elf = yes; then
1908   CONFIG_OBS="$CONFIG_OBS elfread.o stap-probe.o dtrace-probe.o"
1909   AC_DEFINE(HAVE_ELF, 1,
1910             [Define if ELF support should be included.])
1911   # -ldl is provided by bfd/Makfile.am (LIBDL) <PLUGINS>.
1912   if test "$plugins" = "yes"; then
1913     AC_SEARCH_LIBS(dlopen, dl)
1914   fi
1915 fi
1916
1917 # Add macho support to GDB, but only if BFD includes it.
1918 GDB_AC_CHECK_BFD([for Mach-O support in BFD], gdb_cv_var_macho,
1919                  [bfd_mach_o_lookup_command (NULL, 0, NULL)], mach-o.h)
1920 if test $gdb_cv_var_macho = yes; then
1921   CONFIG_OBS="$CONFIG_OBS machoread.o"
1922 fi
1923
1924 # Add any host-specific objects to GDB.
1925 CONFIG_OBS="${CONFIG_OBS} ${gdb_host_obs}"
1926
1927 # If building on ELF, look for lzma support for embedded compressed debug info.
1928 if test $gdb_cv_var_elf = yes; then
1929   AC_ARG_WITH(lzma,
1930     AS_HELP_STRING([--with-lzma], [support lzma compression (auto/yes/no)]),
1931     [], [with_lzma=auto])
1932   AC_MSG_CHECKING([whether to use lzma])
1933   AC_MSG_RESULT([$with_lzma])
1934
1935   if test "${with_lzma}" != no; then
1936     AC_LIB_HAVE_LINKFLAGS([lzma], [], [#include "lzma.h"],
1937                           [lzma_index_iter iter;
1938                            lzma_index_iter_init (&iter, 0);
1939                            lzma_mf_is_supported (LZMA_MF_HC3);])
1940     if test "$HAVE_LIBLZMA" != yes; then
1941       if test "$with_lzma" = yes; then
1942         AC_MSG_ERROR([missing liblzma for --with-lzma])
1943       fi
1944     fi
1945   fi
1946 fi
1947
1948 LIBGUI="../libgui/src/libgui.a"
1949 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
1950 AC_SUBST(LIBGUI)
1951 AC_SUBST(GUI_CFLAGS_X)
1952
1953 WIN32LDAPP=
1954 AC_SUBST(WIN32LIBS)
1955 AC_SUBST(WIN32LDAPP)
1956
1957 case "${host}" in
1958 *-*-cygwin* | *-*-mingw* )
1959     configdir="win"
1960     ;;
1961 *)
1962     configdir="unix"
1963     ;;
1964 esac
1965
1966 GDBTKLIBS=
1967 if test "${enable_gdbtk}" = "yes"; then
1968
1969     # Gdbtk must have an absolute path to srcdir in order to run
1970     # properly when not installed.
1971     here=`pwd`
1972     cd ${srcdir}
1973     GDBTK_SRC_DIR=`pwd`
1974     cd $here
1975
1976     SC_PATH_TCLCONFIG
1977
1978     # If $no_tk is nonempty, then we can't do Tk, and there is no
1979     # point to doing Tcl.
1980     SC_PATH_TKCONFIG
1981
1982     if test -z "${no_tcl}" -a -z "${no_tk}"; then
1983         SC_LOAD_TCLCONFIG
1984
1985         # Check for in-tree tcl
1986         here=`pwd`
1987         cd ${srcdir}/..
1988         topdir=`pwd`
1989         cd ${here}
1990
1991         intree="no"
1992         if test "${TCL_SRC_DIR}" = "${topdir}/tcl"; then
1993           intree="yes"
1994         fi
1995
1996         # Find Tcl private headers
1997         if test x"${intree}" = xno; then
1998           CY_AC_TCL_PRIVATE_HEADERS
1999           TCL_INCLUDE="${TCL_INCLUDE_SPEC} ${TCL_PRIVATE_INCLUDE}"
2000           TCL_LIBRARY="${TCL_LIB_SPEC}"
2001           TCL_DEPS=""
2002         else
2003           # If building tcl in the same src tree, private headers
2004           # are not needed, but we need to be sure to use the right
2005           # headers library
2006           TCL_INCLUDE="-I${TCL_SRC_DIR}/generic"
2007           TCL_LIBRARY="${TCL_BUILD_LIB_SPEC}"
2008           TCL_DEPS="../tcl/${configdir}${TCL_LIB_FILE}"
2009         fi
2010         AC_SUBST(TCL_INCLUDE)
2011         AC_SUBST(TCL_LIBRARY)
2012         AC_SUBST(TCL_DEPS)
2013
2014         SC_LOAD_TKCONFIG
2015
2016         # Check for in-tree Tk
2017         intree="no"
2018         if test "${TK_SRC_DIR}" = "${topdir}/tk"; then
2019           intree="yes"
2020         fi
2021
2022         # Find Tk private headers
2023         if test x"${intree}" = xno; then
2024           CY_AC_TK_PRIVATE_HEADERS
2025           TK_INCLUDE="${TK_INCLUDE_SPEC} ${TK_PRIVATE_INCLUDE}"
2026           TK_LIBRARY=${TK_LIB_SPEC}
2027           TK_DEPS=""
2028         else
2029           TK_INCLUDE="-I${TK_SRC_DIR}/generic"
2030           TK_LIBRARY="${TK_BUILD_LIB_SPEC}"
2031           TK_DEPS="../tk/${configdir}/${TK_LIB_FILE}"
2032         fi
2033         AC_SUBST(TK_INCLUDE)
2034         AC_SUBST(TK_LIBRARY)
2035         AC_SUBST(TK_DEPS)
2036         AC_SUBST(TK_XINCLUDES)
2037
2038         ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
2039
2040         # Include some libraries that Tcl and Tk want.
2041         TCL_LIBS='$(LIBGUI) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
2042         # Yes, the ordering seems wrong here.  But it isn't.
2043         # TK_LIBS is the list of libraries that need to be linked
2044         # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
2045         # were in LIBS then any link tests after this point would
2046         # try to include things like `$(LIBGUI)', which wouldn't work.
2047         GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
2048
2049         CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
2050         CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
2051         CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
2052         CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
2053         CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
2054         CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
2055         CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
2056
2057         if test x$gdb_cv_os_cygwin = xyes; then
2058           WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
2059           WIN32LDAPP="-Wl,--subsystem,console"
2060           CONFIG_OBS="${CONFIG_OBS} gdbres.o"
2061         fi
2062
2063         AC_CONFIG_SUBDIRS(gdbtk)
2064     fi
2065 fi
2066
2067 AC_SUBST(X_CFLAGS)
2068 AC_SUBST(X_LDFLAGS)
2069 AC_SUBST(X_LIBS)
2070 AC_SUBST(GDBTKLIBS)
2071 AC_SUBST(GDBTK_CFLAGS)
2072 AC_SUBST(GDBTK_SRC_DIR)
2073
2074 AC_PATH_X
2075
2076 # Unlike the sim directory, whether a simulator is linked is controlled by
2077 # presence of a gdb_sim definition in the target configure.tgt entry.
2078 # This code just checks for a few cases where we'd like to ignore those
2079 # definitions, even when they're present in the '.mt' file.  These cases
2080 # are when --disable-sim is specified, or if the simulator directory is
2081 # not part of the source tree.
2082 #
2083 AC_ARG_ENABLE(sim,
2084 AS_HELP_STRING([--enable-sim], [link gdb with simulator]),
2085 [echo "enable_sim = $enable_sim";
2086  echo "enableval = ${enableval}";
2087  case "${enableval}" in
2088   yes) ignore_sim=false ;;
2089   no)  ignore_sim=true ;;
2090   *)   ignore_sim=false ;;
2091  esac],
2092 [ignore_sim=false])
2093
2094 if test ! -d "${srcdir}/../sim"; then
2095   ignore_sim=true
2096 fi
2097
2098 SIM=
2099 SIM_OBS=
2100 if test "${ignore_sim}" = "false"; then
2101   if test x"${gdb_sim}" != x ; then
2102     SIM="${gdb_sim}"
2103     SIM_OBS="remote-sim.o"
2104     AC_DEFINE(WITH_SIM, 1, [Define if the simulator is being linked in.])
2105
2106     # Some tdep code should only be compiled in when the ppc sim is
2107     # built.  PR sim/13418.
2108     case $target in
2109       powerpc*-*-*)
2110         AC_DEFINE(WITH_PPC_SIM, 1, [Define if the PPC simulator is being linked in.])
2111         ;;
2112     esac
2113   fi
2114 fi
2115 AC_SUBST(SIM)
2116 AC_SUBST(SIM_OBS)
2117
2118 AC_SUBST(ENABLE_CFLAGS)
2119 AC_SUBST(PROFILE_CFLAGS)
2120
2121 AC_SUBST(CONFIG_OBS)
2122 AC_SUBST(CONFIG_DEPS)
2123 AC_SUBST(CONFIG_SRCS)
2124 AC_SUBST(CONFIG_ALL)
2125 AC_SUBST(CONFIG_CLEAN)
2126 AC_SUBST(CONFIG_INSTALL)
2127 AC_SUBST(CONFIG_UNINSTALL)
2128
2129 # List of host floatformats.
2130 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
2131 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
2132 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
2133
2134 # target_subdir is used by the testsuite to find the target libraries.
2135 target_subdir=
2136 if test "${host}" != "${target}"; then
2137     target_subdir="${target_alias}/"
2138 fi
2139 AC_SUBST(target_subdir)
2140
2141 # Import nat definitions.
2142 nat_makefile_frag=/dev/null
2143 if test "${gdb_native}" = "yes"; then
2144   . ${srcdir}/configure.nat
2145   nativefile=$NAT_FILE
2146 fi
2147
2148 AC_SUBST(NAT_FILE)
2149 AC_SUBST(NATDEPFILES)
2150 AC_SUBST(NAT_CDEPS)
2151 AC_SUBST(LOADLIBES)
2152 AC_SUBST(MH_CFLAGS)
2153 AC_SUBST(XM_CLIBS)
2154 AC_SUBST(NAT_GENERATED_FILES)
2155 AC_SUBST(HAVE_NATIVE_GCORE_HOST)
2156 AC_SUBST_FILE(nat_makefile_frag)
2157
2158 if test x"${gdb_osabi}" != x ; then
2159     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
2160                        [Define to the default OS ABI for this configuration.])
2161 fi
2162
2163 AC_ARG_ENABLE(gdbserver,
2164 AS_HELP_STRING([--enable-gdbserver],
2165                [automatically build gdbserver (yes/no/auto, default is auto)]),
2166 [case "${enableval}" in
2167   yes| no|auto) ;;
2168   *) AC_MSG_ERROR(bad value ${enableval} for --enable-gdbserver option) ;;
2169 esac],[enable_gdbserver=auto])
2170
2171 # We only build gdbserver automatically in a native configuration, and
2172 # only if the user did not explicitly disable its build.
2173 if test "$gdb_native" = "yes" -a "$enable_gdbserver" != "no"; then
2174   AC_MSG_CHECKING(whether gdbserver is supported on this host)
2175   if test "x$build_gdbserver" = xyes; then
2176     AC_MSG_RESULT(yes)
2177     AC_CONFIG_SUBDIRS(gdbserver)
2178     gdbserver_build_enabled=yes
2179   else
2180     AC_MSG_RESULT(no)
2181   fi
2182 fi
2183
2184 # If the user explicitly request the gdbserver to be built, verify that
2185 # we were in fact able to enable it.
2186 if test "$enable_gdbserver" = "yes" -a "$gdbserver_build_enabled" != "yes"; then
2187   AC_MSG_ERROR(Automatic gdbserver build is not supported for this configuration)
2188 fi
2189
2190 # Check for babeltrace and babeltrace-ctf
2191 AC_ARG_WITH(babeltrace,
2192   AC_HELP_STRING([--with-babeltrace], [include babeltrace support (auto/yes/no)]),
2193   [], [with_babeltrace=auto])
2194 AC_MSG_CHECKING([whether to use babeltrace])
2195 AC_MSG_RESULT([$with_babeltrace])
2196
2197 if test "x$with_babeltrace" = "xno"; then
2198   AC_MSG_WARN([babletrace support disabled; GDB is unable to read CTF data.])
2199 else
2200   # Append -Werror to CFLAGS so that configure can catch the warning
2201   # "assignment from incompatible pointer type", which is related to
2202   # the babeltrace change from 1.0.3 to 1.1.0.  Babeltrace 1.1.0 works
2203   # in GDB, while babeltrace 1.0.3 is broken.
2204   # AC_LIB_HAVE_LINKFLAGS may modify CPPFLAGS in it, so it should be
2205   # safe to save and restore CFLAGS here.
2206   saved_CFLAGS=$CFLAGS
2207   CFLAGS="$CFLAGS -Werror"
2208   AC_LIB_HAVE_LINKFLAGS([babeltrace], [babeltrace-ctf],
2209                         [#include <babeltrace/babeltrace.h>
2210                          #include <babeltrace/ctf/events.h>
2211                          #include <babeltrace/ctf/iterator.h>],
2212                         [struct bt_iter_pos *pos = bt_iter_get_pos (bt_ctf_get_iter (NULL));
2213                         struct bt_ctf_event *event = NULL;
2214                         const struct bt_definition *scope;
2215
2216                         pos->type = BT_SEEK_BEGIN;
2217                         bt_iter_set_pos (bt_ctf_get_iter (NULL), pos);
2218                         scope = bt_ctf_get_top_level_scope (event,
2219                                                            BT_STREAM_EVENT_HEADER);
2220                         bt_ctf_get_uint64 (bt_ctf_get_field (event, scope, "id"));
2221                         ])
2222   CFLAGS=$saved_CFLAGS
2223
2224   if test "$HAVE_LIBBABELTRACE" != yes; then
2225      if test "$with_babeltrace" = yes; then
2226        AC_MSG_ERROR([babeltrace is missing or unusable])
2227      else
2228        AC_MSG_WARN([babeltrace is missing or unusable; GDB is unable to read CTF data.])
2229      fi
2230   fi
2231 fi
2232
2233 # If nativefile (NAT_FILE) is not set in configure.nat, we link to an
2234 # empty version.
2235
2236 files=
2237 links=
2238
2239 rm -f nm.h
2240 if test "${nativefile}" != ""; then
2241     case "${nativefile}" in
2242       nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
2243       * ) GDB_NM_FILE="${nativefile}"
2244     esac
2245     files="${files} ${GDB_NM_FILE}"
2246     links="${links} nm.h"
2247     AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}", [nativefile])
2248 fi
2249 AC_SUBST(GDB_NM_FILE)
2250
2251 dnl Add dependency for xsltproc if building with maintainer-mode enabled.
2252 AC_PATH_PROGS(XSLTPROC, xsltproc, missing)
2253 if test "x$USE_MAINTAINER_MODE" = xyes; then
2254   if test "${XSLTPROC}" = missing; then
2255     AC_ERROR(unable to find xsltproc.  maintainer-mode requires xsltproc.)
2256   fi
2257 fi
2258 AC_SUBST(XSLTPROC)
2259
2260 AC_LINK_FILES($files, $links)
2261
2262 dnl Check for exe extension set on certain hosts (e.g. Win32)
2263 AC_EXEEXT
2264
2265 dnl  Detect the character set used by this host.
2266 dnl  At the moment, we just assume it's UTF-8.
2267 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "UTF-8",
2268           [Define to be a string naming the default host character set.])
2269
2270 if $development; then
2271   AC_DEFINE(GDB_SELF_TEST, 1,
2272             [Define if self-testing features should be enabled])
2273   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_UNITTESTS_OBS) common/selftest.o selftest-arch.o"
2274   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_UNITTESTS_SRCS) common/selftest.c selftest-arch.c"
2275 fi
2276
2277 GDB_AC_TRANSFORM([gdb], [GDB_TRANSFORM_NAME])
2278 GDB_AC_TRANSFORM([gcore], [GCORE_TRANSFORM_NAME])
2279 AC_CONFIG_FILES([gcore], [chmod +x gcore])
2280 AC_CONFIG_FILES([Makefile gdb-gdb.gdb gdb-gdb.py doc/Makefile data-directory/Makefile],
2281 [
2282 case x$CONFIG_HEADERS in
2283 xconfig.h:config.in)
2284 echo > stamp-h ;;
2285 esac
2286 ])
2287
2288 AC_OUTPUT