gdb/configure.ac

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995-2012 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Process this file with autoconf to produce a configure script.
  20
  21 AC_PREREQ(2.59)dnl
  22 AC_INIT(main.c)
  23 AC_CONFIG_HEADER(config.h:config.in)
  24 AM_MAINTAINER_MODE
  25
  26 # Provide more thorough testing by -lmcheck.
  27 # Set it to 'true' for development snapshots, 'false' for releases or
  28 # pre-releases.
  29 development=true
  30
  31 AC_PROG_CC
  32 AC_USE_SYSTEM_EXTENSIONS
  33 ACX_LARGEFILE
  34 AM_PROG_CC_STDC
  35
  36 AC_CONFIG_AUX_DIR(..)
  37 AC_CANONICAL_SYSTEM
  38 AC_ARG_PROGRAM
  39
  40 # Dependency checking.
  41 ZW_CREATE_DEPDIR
  42 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  43
  44 # Check for the 'make' the user wants to use.
  45 AC_CHECK_PROGS(MAKE, make)
  46 MAKE_IS_GNU=
  47 case "`$MAKE --version 2>&1 | sed 1q`" in
  48   *GNU*)
  49     MAKE_IS_GNU=yes
  50     ;;
  51 esac
  52 AM_CONDITIONAL(GMAKE, test "$MAKE_IS_GNU" = yes)
  53 AC_PROG_MAKE_SET
  54
  55 # Configure gnulib.  We need to build gnulib under some other
  56 # directory not "gnulib", to avoid the problem of both GDB and
  57 # GDBserver wanting to build it in the same directory, when building
  58 # in the source dir.
  59 ACX_CONFIGURE_DIR(["gnulib"], ["build-gnulib"])
  60
  61 dnl List of object files and targets accumulated by configure.
  62
  63 CONFIG_OBS=
  64 CONFIG_DEPS=
  65 CONFIG_SRCS=
  66 ENABLE_CFLAGS=
  67
  68 CONFIG_ALL=
  69 CONFIG_CLEAN=
  70 CONFIG_INSTALL=
  71 CONFIG_UNINSTALL=
  72
  73 dnl Set up for gettext.
  74 ZW_GNU_GETTEXT_SISTER_DIR
  75
  76 localedir='${datadir}/locale'
  77 AC_SUBST(localedir)
  78
  79 if test x"$USE_NLS" = xyes; then
  80    CONFIG_ALL="$CONFIG_ALL all-po"
  81    CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
  82    CONFIG_INSTALL="$CONFIG_INSTALL install-po"
  83    CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
  84 fi
  85
  86 GNULIB=build-gnulib/import
  87
  88 # For Makefile dependencies.
  89 GNULIB_STDINT_H=
  90 if test x"$STDINT_H" != x; then
  91   GNULIB_STDINT_H=$GNULIB/$STDINT_H
  92 fi
  93 AC_SUBST(GNULIB_STDINT_H)
  94
  95 PACKAGE=gdb
  96 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
  97 AC_SUBST(PACKAGE)
  98
  99 # We never need to detect it in this sub-configure.
 100 # But preserve it for config.status --recheck.
 101 AC_ARG_VAR(MAKEINFO,
 102   [Parent configure detects if it is of sufficient version.])
 103 AC_ARG_VAR(MAKEINFOFLAGS,
 104   [Parameters for MAKEINFO.])
 105
 106 MAKEINFO_EXTRA_FLAGS=""
 107 AC_CACHE_CHECK([whether $MAKEINFO supports @click], gdb_cv_have_makeinfo_click,
 108   [echo '@clicksequence{a @click{} b}' >conftest.texinfo
 109   if eval "$MAKEINFO conftest.texinfo >&5 2>&5"; then
 110     gdb_cv_have_makeinfo_click=yes
 111   else
 112     gdb_cv_have_makeinfo_click=no
 113   fi])
 114 if test x"$gdb_cv_have_makeinfo_click" = xyes; then
 115   MAKEINFO_EXTRA_FLAGS="$MAKEINFO_EXTRA_FLAGS -DHAVE_MAKEINFO_CLICK"
 116 fi
 117 AC_SUBST(MAKEINFO_EXTRA_FLAGS)
 118
 119 GDB_AC_WITH_DIR(DEBUGDIR, separate-debug-dir,
 120     [look for global separate debug info in this path @<:@LIBDIR/debug@:>@],
 121     [${libdir}/debug])
 122
 123 # We can't pass paths as command line arguments.
 124 # Mingw32 tries to be clever and will convert the paths for us.
 125 # For example -DBINDIR="/usr/local/bin" passed on the command line may get
 126 # converted to -DBINDIR="E:/msys/mingw32/msys/1.0/local/bin".
 127 # This breaks GDB's relocatable path conversions since paths passed in
 128 # config.h would not get so translated, the path prefixes no longer match.
 129 AC_DEFINE_DIR(BINDIR, bindir, [Directory of programs.])
 130
 131 # GDB's datadir relocation
 132
 133 GDB_AC_WITH_DIR(GDB_DATADIR, gdb-datadir,
 134     [look for global separate data files in this path @<:@DATADIR/gdb@:>@],
 135     [${datadir}/gdb])
 136
 137 AC_ARG_WITH(relocated-sources,
 138 AS_HELP_STRING([--with-relocated-sources=PATH], [automatically relocate this path for source files]),
 139 [reloc_srcdir="${withval}"
 140  AC_DEFINE_DIR(RELOC_SRCDIR, reloc_srcdir,
 141               [Relocated directory for source files. ])
 142 ])
 143
 144 AC_MSG_CHECKING([for default auto-load directory])
 145 AC_ARG_WITH(auto-load-dir,
 146 AS_HELP_STRING([--with-auto-load-dir=PATH],
 147   [directories from which to load auto-loaded scripts @<:@$debugdir:$datadir/auto-load@:>@]),,
 148   [with_auto_load_dir='$debugdir:$datadir/auto-load'])
 149 escape_dir=`echo $with_auto_load_dir | sed 's/[[$]]\(datadir\|debugdir\)\>/\\\\\\\\\\\\&/g'`
 150 AC_DEFINE_DIR(AUTO_LOAD_DIR, escape_dir,
 151               [Directories from which to load auto-loaded scripts.])
 152 AC_MSG_RESULT([$with_auto_load_dir])
 153
 154 AC_MSG_CHECKING([for default auto-load safe-path])
 155 AC_ARG_WITH(auto-load-safe-path,
 156 AS_HELP_STRING([--with-auto-load-safe-path=PATH],
 157   [directories safe to hold auto-loaded files @<:@--with-auto-load-dir@:>@])
 158 AS_HELP_STRING([--without-auto-load-safe-path],
 159                [do not restrict auto-loaded files locations]),
 160     [if test "$with_auto_load_safe_path" = "no"; then
 161      with_auto_load_safe_path="/"
 162      fi],
 163 [with_auto_load_safe_path="$with_auto_load_dir"])
 164 escape_dir=`echo $with_auto_load_safe_path | sed 's/[[$]]\(datadir\|debugdir\)\>/\\\\\\\\\\\\&/g'`
 165 AC_DEFINE_DIR(AUTO_LOAD_SAFE_PATH, escape_dir,
 166               [Directories safe to hold auto-loaded files.])
 167 AC_MSG_RESULT([$with_auto_load_safe_path])
 168
 169 AC_CONFIG_SUBDIRS(testsuite)
 170
 171 # Check whether to support alternative target configurations
 172 AC_ARG_ENABLE(targets,
 173 AS_HELP_STRING([--enable-targets=TARGETS], [alternative target configurations]),
 174 [case "${enableval}" in
 175   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
 176             ;;
 177   no)       enable_targets= ;;
 178   *)        enable_targets=$enableval ;;
 179 esac])
 180
 181 # Check whether to enable 64-bit support on 32-bit hosts
 182 AC_ARG_ENABLE(64-bit-bfd,
 183 AS_HELP_STRING([--enable-64-bit-bfd], [64-bit support (on hosts with narrower word sizes)]),
 184 [case "${enableval}" in
 185   yes)  want64=true  ;;
 186   no)   want64=false ;;
 187   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
 188 esac],[want64=false])dnl
 189
 190 # Provide defaults for some variables set by the per-host and per-target
 191 # configuration.
 192 gdb_host_obs=posix-hdep.o
 193
 194 if test "${target}" = "${host}"; then
 195   gdb_native=yes
 196 else
 197   gdb_native=no
 198 fi
 199
 200 . $srcdir/configure.host
 201
 202 # Accumulate some settings from configure.tgt over all enabled targets
 203
 204 TARGET_OBS=
 205 all_targets=
 206
 207 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 208 do
 209   if test "$targ_alias" = "all"; then
 210     all_targets=true
 211   else
 212     # Canonicalize the secondary target names.
 213     result=`$ac_config_sub $targ_alias 2>/dev/null`
 214     if test -n "$result"; then
 215         targ=$result
 216     else
 217         targ=$targ_alias
 218     fi
 219
 220     . ${srcdir}/configure.tgt
 221
 222     AS_IF([test -z "${gdb_target_obs}"],
 223       [AC_MSG_ERROR([configuration ${targ} is unsupported.])])
 224
 225     # Target-specific object files
 226     for i in ${gdb_target_obs}; do
 227         case " $TARGET_OBS " in
 228         *" ${i} "*) ;;
 229         *)
 230           TARGET_OBS="$TARGET_OBS ${i}"
 231           ;;
 232         esac
 233     done
 234
 235     # Check whether this target needs 64-bit CORE_ADDR
 236     if test x${want64} = xfalse; then
 237       . ${srcdir}/../bfd/config.bfd
 238     fi
 239   fi
 240 done
 241
 242 if test x${all_targets} = xtrue; then
 243
 244   # We want all 64-bit targets if we either:
 245   #  - run on a 64-bit host  or
 246   #  - already require 64-bit support for some other target  or
 247   #  - the --enable-64-bit-bfd option was supplied
 248   # Otherwise we only support all 32-bit targets.
 249   #
 250   # NOTE: This test must be in sync with the corresponding
 251   #       tests in BFD!
 252
 253   if test x${want64} = xfalse; then
 254     AC_CHECK_SIZEOF(long)
 255     if test "x${ac_cv_sizeof_long}" = "x8"; then
 256       want64=true
 257     fi
 258   fi
 259   if test x${want64} = xtrue; then
 260     TARGET_OBS='$(ALL_TARGET_OBS) $(ALL_64_TARGET_OBS)'
 261   else
 262     TARGET_OBS='$(ALL_TARGET_OBS)'
 263   fi
 264 fi
 265
 266 AC_SUBST(TARGET_OBS)
 267
 268 # For other settings, only the main target counts.
 269 gdb_sim=
 270 gdb_osabi=
 271 build_gdbserver=
 272 targ=$target; . ${srcdir}/configure.tgt
 273
 274 # Fetch the default architecture and default target vector from BFD.
 275 targ=$target; . $srcdir/../bfd/config.bfd
 276
 277 # We only want the first architecture, so strip off the others if
 278 # there is more than one.
 279 targ_archs=`echo $targ_archs | sed 's/ .*//'`
 280
 281 if test "x$targ_archs" != x; then
 282   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
 283     [Define to BFD's default architecture. ])
 284 fi
 285 if test "x$targ_defvec" != x; then
 286   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
 287     [Define to BFD's default target vector. ])
 288 fi
 289
 290 # The CLI cannot be disabled yet, but may be in the future.
 291
 292 # Enable CLI.
 293 AC_ARG_ENABLE(gdbcli,
 294 AS_HELP_STRING([--disable-gdbcli], [disable command-line interface (CLI)]),
 295   [case $enableval in
 296     yes)
 297       ;;
 298     no)
 299       AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;;
 300     *)
 301       AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;;
 302   esac],
 303   [enable_gdbcli=yes])
 304 if test x"$enable_gdbcli" = xyes; then
 305   if test -d $srcdir/cli; then
 306     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)"
 307     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)"
 308     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)"
 309     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)"
 310   fi
 311 fi
 312
 313 # Enable MI.
 314 AC_ARG_ENABLE(gdbmi,
 315 AS_HELP_STRING([--disable-gdbmi], [disable machine-interface (MI)]),
 316   [case $enableval in
 317     yes | no)
 318       ;;
 319     *)
 320       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 321   esac],
 322   [enable_gdbmi=yes])
 323 if test x"$enable_gdbmi" = xyes; then
 324   if test -d $srcdir/mi; then
 325     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 326     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 327     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 328     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 329   fi
 330 fi
 331
 332 # Enable TUI.
 333 AC_ARG_ENABLE(tui,
 334 AS_HELP_STRING([--enable-tui], [enable full-screen terminal user interface (TUI)]),
 335   [case $enableval in
 336     yes | no | auto)
 337       ;;
 338     *)
 339       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 340   esac],enable_tui=auto)
 341
 342 # Enable gdbtk.
 343 AC_ARG_ENABLE(gdbtk,
 344 AS_HELP_STRING([--enable-gdbtk], [enable gdbtk graphical user interface (GUI)]),
 345   [case $enableval in
 346     yes | no)
 347       ;;
 348     *)
 349       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 350   esac],
 351   [if test -d $srcdir/gdbtk; then
 352     enable_gdbtk=yes
 353   else
 354     enable_gdbtk=no
 355   fi])
 356 # We unconditionally disable gdbtk tests on selected platforms.
 357 case $host_os in
 358   go32* | windows*)
 359     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 360     enable_gdbtk=no ;;
 361 esac
 362
 363 # Libunwind support for ia64.
 364
 365 AC_ARG_WITH(libunwind-ia64,
 366 AS_HELP_STRING([--with-libunwind-ia64],
 367                [use libunwind frame unwinding for ia64 targets]),,
 368             [with_libunwind_ia64=auto])
 369
 370 # Backward compatibility option.
 371 if test "${with_libunwind+set}" = set; then
 372   if test x"$with_libunwind_ia64" != xauto; then
 373     AC_MSG_ERROR(
 374       [option --with-libunwind is deprecated, use --with-libunwind-ia64])
 375   fi
 376   AC_MSG_WARN([option --with-libunwind is deprecated, use --with-libunwind-ia64])
 377   with_libunwind_ia64="$with_libunwind"
 378 fi
 379
 380 case "$with_libunwind_ia64" in
 381   yes | no)
 382     ;;
 383   auto)
 384     AC_CHECK_HEADERS(libunwind-ia64.h)
 385     with_libunwind_ia64=$ac_cv_header_libunwind_ia64_h
 386     ;;
 387   *)
 388     AC_MSG_ERROR(
 389       [bad value $with_libunwind_ia64 for GDB --with-libunwind-ia64 option])
 390     ;;
 391 esac
 392
 393 if test x"$with_libunwind_ia64" = xyes; then
 394   AC_CHECK_HEADERS(libunwind-ia64.h)
 395   if test x"$ac_cv_header_libunwind_ia64_h" != xyes; then
 396     AC_MSG_ERROR([GDB option --with-libunwind-ia64 requires libunwind-ia64.h])
 397   fi
 398   CONFIG_OBS="$CONFIG_OBS ia64-libunwind-tdep.o"
 399   CONFIG_DEPS="$CONFIG_DEPS ia64-libunwind-tdep.o"
 400   CONFIG_SRCS="$CONFIG_SRCS ia64-libunwind-tdep.c"
 401 fi
 402
 403 opt_curses=no
 404 AC_ARG_WITH(curses, AS_HELP_STRING([--with-curses], [use the curses library instead of the termcap library]), opt_curses=$withval)
 405
 406 prefer_curses=no
 407 if test "$opt_curses" = "yes"; then
 408   prefer_curses=yes
 409 fi
 410
 411 # Profiling support.
 412 AC_ARG_ENABLE(profiling,
 413 AS_HELP_STRING([--enable-profiling], [enable profiling of GDB]),
 414   [case $enableval in
 415     yes | no)
 416       ;;
 417     *)
 418       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 419   esac],
 420  [enable_profiling=no])
 421
 422 AC_CHECK_FUNCS(monstartup _mcleanup)
 423 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 424 [AC_TRY_LINK(
 425 [#include <stdlib.h>
 426 extern char _etext;
 427 ],
 428 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 429 if test $ac_cv_var__etext = yes; then
 430   AC_DEFINE(HAVE__ETEXT, 1,
 431             [Define to 1 if your system has the _etext variable. ])
 432 fi
 433 AC_CACHE_CHECK([for etext], ac_cv_var_etext,
 434 [AC_TRY_LINK(
 435 [#include <stdlib.h>
 436 extern char etext;
 437 ],
 438 [free (&etext);], ac_cv_var_etext=yes, ac_cv_var_etext=no)])
 439 if test $ac_cv_var_etext = yes; then
 440   AC_DEFINE(HAVE_ETEXT, 1,
 441             [Define to 1 if your system has the etext variable. ])
 442 fi
 443 if test "$enable_profiling" = yes ; then
 444   if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
 445     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 446   fi
 447   PROFILE_CFLAGS=-pg
 448   OLD_CFLAGS="$CFLAGS"
 449   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 450
 451   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 452     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 453      ac_cv_cc_supports_pg=no)])
 454
 455   if test $ac_cv_cc_supports_pg = no; then
 456     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 457   fi
 458
 459   CFLAGS="$OLD_CFLAGS"
 460 fi
 461
 462 ACX_PKGVERSION([GDB])
 463 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 464 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 465 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 466
 467 # --------------------- #
 468 # Checks for programs.  #
 469 # --------------------- #
 470
 471 AC_PROG_AWK
 472 AC_PROG_INSTALL
 473 AC_PROG_LN_S
 474 AC_PROG_RANLIB
 475 AC_PROG_YACC
 476
 477 AC_CHECK_TOOL(AR, ar)
 478 AC_CHECK_TOOL(DLLTOOL, dlltool)
 479 AC_CHECK_TOOL(WINDRES, windres)
 480
 481 # Needed for GNU/Hurd.
 482 AC_CHECK_TOOL(MIG, mig)
 483
 484 # ---------------------- #
 485 # Checks for libraries.  #
 486 # ---------------------- #
 487
 488 # We might need to link with -lm; most simulators need it.
 489 AC_CHECK_LIB(m, main)
 490
 491 # We need to link with -lw to get `wctype' on Solaris before Solaris
 492 # 2.6.  Solaris 2.6 and beyond have this function in libc, and have a
 493 # libw that some versions of the GNU linker cannot hanle (GNU ld 2.9.1
 494 # is known to have this problem).  Therefore we avoid libw if we can.
 495 AC_CHECK_FUNC(wctype, [],
 496   [AC_CHECK_LIB(w, wctype)])
 497
 498 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 499 AC_SEARCH_LIBS(gethostbyname, nsl)
 500
 501 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 502 AC_SEARCH_LIBS(socketpair, socket)
 503
 504 # Link in zlib if we can.  This allows us to read compressed debug sections.
 505 AM_ZLIB
 506
 507 # On HP/UX we may need libxpdl for dlgetmodinfo (used by solib-pa64.c).
 508 AC_SEARCH_LIBS(dlgetmodinfo, [dl xpdl])
 509
 510 AM_ICONV
 511
 512 # GDB may fork/exec the iconv program to get the list of supported character
 513 # sets.  Allow the user to specify where to find it.
 514 # There are several factors affecting the choice of option name:
 515 # - There is already --with-libiconv-prefix but we can't use it, it specifies
 516 #   the build-time location of libiconv files.
 517 # - The program we need to find is iconv, which comes with glibc.  The user
 518 #   doesn't necessarily have libiconv installed.  Therefore naming this
 519 #   --with-libiconv-foo feels wrong.
 520 # - We want the path to be relocatable, but GDB_AC_DEFINE_RELOCATABLE is
 521 #   defined to work on directories not files (though it really doesn't know
 522 #   the difference).
 523 # - Calling this --with-iconv-prefix is perceived to cause too much confusion
 524 #   with --with-libiconv-prefix.
 525 # Putting these together is why the option name is --with-iconv-bin.
 526
 527 AC_ARG_WITH(iconv-bin,
 528 AS_HELP_STRING([--with-iconv-bin=PATH], [specify where to find the iconv program]),
 529 [iconv_bin="${withval}"
 530  AC_DEFINE_UNQUOTED([ICONV_BIN], ["${iconv_bin}"],
 531                     [Path of directory of iconv program.])
 532  GDB_AC_DEFINE_RELOCATABLE(ICONV_BIN, iconv, ${iconv_bin})
 533 ])
 534
 535 # On alpha-osf, it appears that libtermcap and libcurses are not compatible.
 536 # There is a very specific comment in /usr/include/curses.h explaining that
 537 # termcap routines built into libcurses must not be used.
 538 #
 539 # The symptoms we observed so far is GDB unexpectedly changing
 540 # the terminal settings when tgetent is called - this is particularly
 541 # visible as the output is missing carriage returns, and so rapidly
 542 # becomes very hard to read.
 543 #
 544 # The readline configure script has already decided that libtermcap
 545 # was enough for its purposes, and so decided to build readline using
 546 # libtermcap.  Since the TUI mode requires curses, building GDB with
 547 # TUI enabled results in both libraries to be used at the same time,
 548 # which is not allowed.  This basically means that GDB with TUI is
 549 # broken on alpha-osf.
 550
 551 case $host_os in
 552   osf* )
 553     if test x"$enable_tui" = xyes; then
 554       AC_MSG_ERROR([Building GDB with TUI mode is not supported on this host])
 555     fi
 556     if test x"$enable_tui" = xauto; then
 557       enable_tui=no
 558     fi
 559     ;;
 560 esac
 561
 562 # For the TUI, we need enhanced curses functionality.
 563 if test x"$enable_tui" != xno; then
 564   prefer_curses=yes
 565 fi
 566
 567 curses_found=no
 568 if test x"$prefer_curses" = xyes; then
 569   # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
 570   # curses library because the latter might not provide all the
 571   # functionality we need.  However, this leads to problems on systems
 572   # where the linker searches /usr/local/lib, but the compiler doesn't
 573   # search /usr/local/include, if ncurses is installed in /usr/local.  A
 574   # default installation of ncurses on alpha*-dec-osf* will lead to such
 575   # a situation.
 576   AC_SEARCH_LIBS(waddstr, [ncurses cursesX curses])
 577
 578   if test "$ac_cv_search_waddstr" != no; then
 579     curses_found=yes
 580   fi
 581 fi
 582
 583 # Check whether we should enable the TUI, but only do so if we really
 584 # can.
 585 if test x"$enable_tui" != xno; then
 586   if test -d $srcdir/tui; then
 587     if test "$curses_found" != no; then
 588       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
 589       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
 590       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
 591       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
 592     else
 593       if test x"$enable_tui" = xyes; then
 594         AC_MSG_ERROR([no enhanced curses library found; disable TUI])
 595       else
 596         AC_MSG_WARN([no enhanced curses library found; disabling TUI])
 597       fi
 598     fi
 599   fi
 600 fi
 601
 602 # Since GDB uses Readline, we need termcap functionality.  In many
 603 # cases this will be provided by the curses library, but some systems
 604 # have a seperate termcap library, or no curses library at all.
 605
 606 case $host_os in
 607   cygwin*)
 608     if test -d $srcdir/libtermcap; then
 609       LIBS="../libtermcap/libtermcap.a $LIBS"
 610       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 611     fi ;;
 612   go32* | *djgpp*)
 613     ac_cv_search_tgetent="none required"
 614     ;;
 615   *mingw32*)
 616     ac_cv_search_tgetent="none required"
 617     CONFIG_OBS="$CONFIG_OBS windows-termcap.o"
 618     ;;
 619 esac
 620
 621 # These are the libraries checked by Readline.
 622 AC_SEARCH_LIBS(tgetent, [termcap tinfo curses ncurses])
 623
 624 if test "$ac_cv_search_tgetent" = no; then
 625   AC_MSG_ERROR([no termcap library found])
 626 fi
 627
 628 AC_ARG_WITH([system-readline],
 629   [AS_HELP_STRING([--with-system-readline],
 630                   [use installed readline library])])
 631
 632 if test "$with_system_readline" = yes; then
 633   READLINE=-lreadline
 634   READLINE_DEPS=
 635   READLINE_CFLAGS=
 636   READLINE_TEXI_INCFLAG=
 637 else
 638   READLINE='$(READLINE_DIR)/libreadline.a'
 639   READLINE_DEPS='$(READLINE)'
 640   READLINE_CFLAGS='-I$(READLINE_SRC)/..'
 641   READLINE_TEXI_INCFLAG='-I $(READLINE_DIR)'
 642 fi
 643 AC_SUBST(READLINE)
 644 AC_SUBST(READLINE_DEPS)
 645 AC_SUBST(READLINE_CFLAGS)
 646 AC_SUBST(READLINE_TEXI_INCFLAG)
 647
 648 dnl -lmcheck provides cheap enough memory mangling for debugging purposes.
 649 if $development; then
 650   AC_CHECK_LIB(mcheck, main)
 651 fi
 652
 653 # Generate jit-reader.h
 654
 655 # This is typedeffed to GDB_CORE_ADDR in jit-reader.h
 656 TARGET_PTR=
 657
 658 AC_CHECK_SIZEOF(unsigned long long)
 659 AC_CHECK_SIZEOF(unsigned long)
 660 AC_CHECK_SIZEOF(unsigned __int128)
 661
 662 if test "x${ac_cv_sizeof_unsigned_long}" = "x8"; then
 663   TARGET_PTR="unsigned long"
 664 elif test "x${ac_cv_sizeof_unsigned_long_long}" = "x8"; then
 665   TARGET_PTR="unsigned long long"
 666 elif test "x${ac_cv_sizeof_unsigned___int128}" = "x16"; then
 667   TARGET_PTR="unsigned __int128"
 668 else
 669   TARGET_PTR="unsigned long"
 670 fi
 671
 672 AC_SUBST(TARGET_PTR)
 673 AC_CONFIG_FILES([jit-reader.h:jit-reader.in])
 674
 675 AC_SEARCH_LIBS(dlopen, dl)
 676
 677 GDB_AC_WITH_DIR([JIT_READER_DIR], [jit-reader-dir],
 678                 [directory to load the JIT readers from],
 679                 [${libdir}/gdb])
 680
 681 AC_ARG_WITH(expat,
 682   AS_HELP_STRING([--with-expat], [include expat support (auto/yes/no)]),
 683   [], [with_expat=auto])
 684 AC_MSG_CHECKING([whether to use expat])
 685 AC_MSG_RESULT([$with_expat])
 686
 687 if test "${with_expat}" = no; then
 688   AC_MSG_WARN([expat support disabled; some features may be unavailable.])
 689   HAVE_LIBEXPAT=no
 690 else
 691   AC_LIB_HAVE_LINKFLAGS([expat], [], [#include "expat.h"],
 692                         [XML_Parser p = XML_ParserCreate (0);])
 693   if test "$HAVE_LIBEXPAT" != yes; then
 694     if test "$with_expat" = yes; then
 695       AC_MSG_ERROR([expat is missing or unusable])
 696     else
 697       AC_MSG_WARN([expat is missing or unusable; some features may be unavailable.])
 698     fi
 699   else
 700     save_LIBS=$LIBS
 701     LIBS="$LIBS $LIBEXPAT"
 702     AC_CHECK_FUNCS(XML_StopParser)
 703     LIBS=$save_LIBS
 704   fi
 705 fi
 706
 707 dnl Utility to simplify finding libpython.
 708 dnl $1 = pythonX.Y
 709 dnl $2 = the shell variable to assign the result to
 710 dnl      If libpython is found we store $version here.
 711 dnl $3 = additional flags to add to CPPFLAGS
 712 dnl $4 = additional flags to add to LIBS
 713
 714 AC_DEFUN([AC_TRY_LIBPYTHON],
 715 [
 716   version=$1
 717   define([have_libpython_var],$2)
 718   new_CPPFLAGS=$3
 719   new_LIBS=$4
 720   AC_MSG_CHECKING([for ${version}])
 721   save_CPPFLAGS=$CPPFLAGS
 722   save_LIBS=$LIBS
 723   CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
 724   LIBS="$LIBS $new_LIBS"
 725   found_usable_python=no
 726   AC_LINK_IFELSE(AC_LANG_PROGRAM([[#include "Python.h"]],
 727                                  [[Py_Initialize ();]]),
 728                  [have_libpython_var=${version}
 729                   found_usable_python=yes
 730                   PYTHON_CPPFLAGS=$new_CPPFLAGS
 731                   PYTHON_LIBS=$new_LIBS])
 732   CPPFLAGS=$save_CPPFLAGS
 733   LIBS=$save_LIBS
 734   AC_MSG_RESULT([${found_usable_python}])
 735 ])
 736
 737 dnl There are several different values for --with-python:
 738 dnl
 739 dnl no -   Don't include python support.
 740 dnl yes -  Include python support, error if it's missing.
 741 dnl        If we find python in $PATH, use it to fetch configure options,
 742 dnl        otherwise assume the compiler can find it with no help from us.
 743 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 744 dnl auto - Same as "yes", but if python is missing from the system,
 745 dnl        fall back to "no".
 746 dnl /path/to/python/exec-prefix -
 747 dnl        Use the python located in this directory.
 748 dnl        If /path/to/python/exec-prefix/bin/python exists, use it to find
 749 dnl        the compilation parameters.  Otherwise use
 750 dnl        -I/path/to/python/exec-prefix/include,
 751 dnl        -L/path/to/python/exec-prefix/lib.
 752 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 753 dnl        NOTE: This case is historical.  It is what was done for 7.0/7.1
 754 dnl        but is deprecated.
 755 dnl /path/to/python/executable -
 756 dnl        Run python-config.py with this version of python to fetch the
 757 dnl        compilation parameters.
 758 dnl        NOTE: This needn't be the real python executable.
 759 dnl        In a cross-compilation scenario (build != host), this could be
 760 dnl        a shell script that provides what python-config.py provides for
 761 dnl        --ldflags, --includes, --exec-prefix.
 762 dnl python-executable -
 763 dnl        Find python-executable in $PATH, and then handle the same as
 764 dnl        /path/to/python/executable.
 765 dnl
 766 dnl If a python program is specified, it is used to run python-config.py and
 767 dnl is passed --ldflags, --includes, --exec-prefix.
 768
 769 AC_ARG_WITH(python,
 770   AS_HELP_STRING([--with-python@<:@=PYTHON@:>@], [include python support (auto/yes/no/<python-program>)]),
 771   [], [with_python=auto])
 772 AC_MSG_CHECKING([whether to use python])
 773 AC_MSG_RESULT([$with_python])
 774
 775 if test "${with_python}" = no; then
 776   AC_MSG_WARN([python support disabled; some features may be unavailable.])
 777   have_libpython=no
 778 else
 779   case "${with_python}" in
 780   [[\\/]]* | ?:[[\\/]]*)
 781     if test -d ${with_python}; then
 782       # Assume the python binary is ${with_python}/bin/python.
 783       python_prog="${with_python}/bin/python"
 784       python_prefix=
 785       # If python does not exit ${with_python}/bin, then try in
 786       # ${with_python}.  On Windows/MinGW, this is where the Python
 787       # executable is.
 788       if test ! -x "${python_prog}"; then
 789         python_prog="${with_python}/python"
 790         python_prefix=
 791       fi
 792       if test ! -x "${python_prog}"; then
 793         # Fall back to gdb 7.0/7.1 behaviour.
 794         python_prog=missing
 795         python_prefix=${with_python}
 796       fi
 797     elif test -x "${with_python}"; then
 798       # While we can't run python compiled for $host (unless host == build),
 799       # the user could write a script that provides the needed information,
 800       # so we support that.
 801       python_prog=${with_python}
 802       python_prefix=
 803     else
 804       AC_ERROR(invalid value for --with-python)
 805     fi
 806     ;;
 807   */*)
 808     # Disallow --with-python=foo/bar.
 809     AC_ERROR(invalid value for --with-python)
 810     ;;
 811   *)
 812     # The user has either specified auto, yes, or the name of the python
 813     # program assumed to be in $PATH.
 814     python_prefix=
 815     case "${with_python}" in
 816     yes | auto)
 817       if test ${build} = ${host}; then
 818         AC_PATH_PROG(python_prog_path, python, missing)
 819         if test "${python_prog_path}" = missing; then
 820           python_prog=missing
 821         else
 822           python_prog=${python_prog_path}
 823         fi
 824       else
 825         # Not much we can do except assume the cross-compiler will find the
 826         # right files.
 827         python_prog=missing
 828       fi
 829       ;;
 830     *)
 831       # While we can't run python compiled for $host (unless host == build),
 832       # the user could write a script that provides the needed information,
 833       # so we support that.
 834       python_prog="${with_python}"
 835       AC_PATH_PROG(python_prog_path, ${python_prog}, missing)
 836       if test "${python_prog_path}" = missing; then
 837         AC_ERROR(unable to find python program ${python_prog})
 838       fi
 839       ;;
 840     esac
 841   esac
 842
 843   if test "${python_prog}" != missing; then
 844     # We have a python program to use, but it may be too old.
 845     # Don't flag an error for --with-python=auto (the default).
 846     have_python_config=yes
 847     python_includes=`${python_prog} ${srcdir}/python/python-config.py --includes`
 848     if test $? != 0; then
 849       have_python_config=failed
 850       if test "${with_python}" != auto; then
 851         AC_ERROR(failure running python-config --includes)
 852       fi
 853     fi
 854     python_libs=`${python_prog} ${srcdir}/python/python-config.py --ldflags`
 855     if test $? != 0; then
 856       have_python_config=failed
 857       if test "${with_python}" != auto; then
 858         AC_ERROR(failure running python-config --ldflags)
 859       fi
 860     fi
 861     python_prefix=`${python_prog} ${srcdir}/python/python-config.py --exec-prefix`
 862     if test $? != 0; then
 863       have_python_config=failed
 864       if test "${with_python}" != auto; then
 865         AC_ERROR(failure running python-config --exec-prefix)
 866       fi
 867     fi
 868   else
 869     # We do not have a python executable we can use to determine where
 870     # to find the Python headers and libs.  We cannot guess the include
 871     # path from the python_prefix either, because that include path
 872     # depends on the Python version.  So, there is nothing much we can
 873     # do except assume that the compiler will be able to find those files.
 874     python_includes=
 875     python_libs=
 876     have_python_config=no
 877   fi
 878
 879   # If we have python-config, only try the configuration it provides.
 880   # Otherwise fallback on the old way of trying different versions of
 881   # python in turn.
 882
 883   have_libpython=no
 884   if test "${have_python_config}" = yes; then
 885     # Determine the Python version by extracting "-lpython<version>"
 886     # part of the python_libs. <version> is usually X.Y with X and Y
 887     # being decimal numbers, but can also be XY (seen on Windows).
 888     #
 889     # The extraction is performed using sed with a regular expression.
 890     # Initially, the regexp used was using the '?' quantifier to make
 891     # the dot in the version number optional.  Unfortunately, this
 892     # does not work with non-GNU versions of sed because, because of
 893     # what looks like a limitation (the '?' quantifier does not work
 894     # with back-references).  We work around this limitation by using
 895     # the '*' quantifier instead.  It means that, in theory, we might
 896     # match unexpected version strings such as "-lpython2..7", but
 897     # this seems unlikely in practice.  And even if that happens,
 898     # an error will be triggered later on, when checking that version
 899     # number.
 900     python_version=`echo " ${python_libs} " \
 901                          | sed -e 's,^.* -l\(python[[0-9]]*[[.]]*[[0-9]]*\).*$,\1,'`
 902     case "${python_version}" in
 903     python*)
 904       AC_TRY_LIBPYTHON(${python_version}, have_libpython,
 905                        ${python_includes}, ${python_libs})
 906       ;;
 907     *)
 908       AC_MSG_ERROR([unable to determine python version from ${python_libs}])
 909       ;;
 910     esac
 911   elif test "${have_python_config}" != failed; then
 912     if test "${have_libpython}" = no; then
 913       AC_TRY_LIBPYTHON(python2.7, have_libpython,
 914                        ${python_includes}, "${python_libs} -lpython2.7")
 915     fi
 916     if test "${have_libpython}" = no; then
 917       AC_TRY_LIBPYTHON(python2.6, have_libpython,
 918                        ${python_includes}, "${python_libs} -lpython2.6")
 919     fi
 920     if test ${have_libpython} = no; then
 921       AC_TRY_LIBPYTHON(python2.5, have_libpython,
 922                        ${python_includes}, "${python_libs} -lpython2.5")
 923     fi
 924     if test ${have_libpython} = no; then
 925       AC_TRY_LIBPYTHON(python2.4, have_libpython,
 926                        ${python_includes}, "${python_libs} -lpython2.4")
 927     fi
 928   fi
 929   if test "${have_libpython}" = python2.7 -o "${have_libpython}" = python27; then
 930     AC_DEFINE(HAVE_LIBPYTHON2_7, 1, [Define if Python 2.7 is being used.])
 931   elif test "${have_libpython}" = python2.6 -o "${have_libpython}" = python26; then
 932     AC_DEFINE(HAVE_LIBPYTHON2_6, 1, [Define if Python 2.6 is being used.])
 933   elif test "${have_libpython}" = python2.5 -o "${have_libpython}" = python25; then
 934     AC_DEFINE(HAVE_LIBPYTHON2_5, 1, [Define if Python 2.5 is being used.])
 935   elif test "${have_libpython}" = python2.4 -o "${have_libpython}" = python24; then
 936     AC_DEFINE(HAVE_LIBPYTHON2_4, 1, [Define if Python 2.4 is being used.])
 937   fi
 938
 939   if test "${have_libpython}" = no; then
 940     case "${with_python}" in
 941     yes)
 942       AC_MSG_ERROR([python is missing or unusable])
 943       ;;
 944     auto)
 945       AC_MSG_WARN([python is missing or unusable; some features may be unavailable.])
 946       ;;
 947     *)
 948       AC_MSG_ERROR([no usable python found at ${with_python}])
 949       ;;
 950     esac
 951   else
 952     if test -n "${python_prefix}"; then
 953       AC_DEFINE_UNQUOTED(WITH_PYTHON_PATH, "${python_prefix}",
 954                          [Define if --with-python provides a path, either directly or via python-config.py --exec-prefix.])
 955       GDB_AC_DEFINE_RELOCATABLE(PYTHON_PATH, python, ${python_prefix})
 956     fi
 957   fi
 958 fi
 959
 960 if test "${have_libpython}" != no; then
 961   AC_DEFINE(HAVE_PYTHON, 1, [Define if Python interpreter is being linked in.])
 962   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_PYTHON_OBS)"
 963   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_PYTHON_DEPS)"
 964   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_PYTHON_SRCS)"
 965   CONFIG_INSTALL="$CONFIG_INSTALL install-python"
 966   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_PYTHON_CFLAGS)"
 967
 968   # Flags needed to compile Python code (taken from python-config --cflags).
 969   # We cannot call python-config directly because it will output whatever was
 970   # used when compiling the Python interpreter itself, including flags which
 971   # would make the python-related objects be compiled differently from the
 972   # rest of GDB (e.g., -O2 and -fPIC).
 973   if test "${GCC}" = yes; then
 974     tentative_python_cflags="-fno-strict-aliasing -DNDEBUG -fwrapv"
 975   fi
 976
 977   if test "x${tentative_python_cflags}" != x; then
 978     AC_MSG_CHECKING(compiler flags for python code)
 979     for flag in ${tentative_python_cflags}; do
 980       # Check that the compiler accepts it
 981       saved_CFLAGS="$CFLAGS"
 982       CFLAGS="$CFLAGS $flag"
 983       AC_TRY_COMPILE([],[],PYTHON_CFLAGS="${PYTHON_CFLAGS} $flag",)
 984       CFLAGS="$saved_CFLAGS"
 985     done
 986     AC_MSG_RESULT(${PYTHON_CFLAGS})
 987   fi
 988
 989   # On IRIX, type siginfo is not defined.  Instead, sys/siginfo.h provides:
 990   #    #if _SGIAPI
 991   #    #define siginfo __siginfo
 992   #    #endif
 993   # The problem is that including Python causes some XOPEN macros to be
 994   # unilaterally defined, and that in turn causes _SGIAPI to evaluate
 995   # to false.  So, we work around this issue by defining siginfo ourself
 996   # though the command-line.
 997   case "$gdb_host" in
 998     irix*) if test "${GCC}" = yes; then
 999              CPPFLAGS="$CPPFLAGS -Dsiginfo=__siginfo"
1000            fi
1001            ;;
1002   esac
1003 else
1004   # Even if Python support is not compiled in, we need to have these files
1005   # included.
1006   CONFIG_OBS="$CONFIG_OBS python.o py-value.o py-prettyprint.o py-auto-load.o"
1007   CONFIG_SRCS="$CONFIG_SRCS python/python.c python/py-value.c \
1008         python/py-prettyprint.c python/py-auto-load.c"
1009 fi
1010 AC_SUBST(PYTHON_CFLAGS)
1011 AC_SUBST(PYTHON_CPPFLAGS)
1012 AC_SUBST(PYTHON_LIBS)
1013
1014 # ------------------------- #
1015 # Checks for header files.  #
1016 # ------------------------- #
1017
1018 AC_HEADER_DIRENT
1019 AC_HEADER_STAT
1020 AC_HEADER_STDC
1021 # elf_hp.h is for HP/UX 64-bit shared library support.
1022 # FIXME: kettenis/20030102: In most cases we include these (ctype.h, time.h)
1023 # unconditionally, so what's the point in checking these?
1024 AC_CHECK_HEADERS([nlist.h machine/reg.h poll.h sys/poll.h proc_service.h \
1025                   thread_db.h gnu/libc-version.h signal.h stddef.h \
1026                   stdlib.h string.h memory.h strings.h sys/fault.h \
1027                   sys/file.h sys/filio.h sys/ioctl.h sys/param.h \
1028                   sys/resource.h sys/procfs.h sys/ptrace.h ptrace.h \
1029                   sys/reg.h sys/debugreg.h sys/select.h sys/syscall.h \
1030                   sys/types.h sys/wait.h wait.h termios.h termio.h \
1031                   sgtty.h unistd.h elf_hp.h ctype.h time.h locale.h \
1032                   dlfcn.h sys/socket.h sys/un.h])
1033 AC_CHECK_HEADERS(link.h, [], [],
1034 [#if HAVE_SYS_TYPES_H
1035 # include <sys/types.h>
1036 #endif
1037 #if HAVE_NLIST_H
1038 # include <nlist.h>
1039 #endif
1040 ])
1041 AC_CHECK_HEADERS(sys/proc.h, [], [],
1042 [#if HAVE_SYS_PARAM_H
1043 # include <sys/param.h>
1044 #endif
1045 ])
1046 AC_CHECK_HEADERS(sys/user.h, [], [],
1047 [#if HAVE_SYS_PARAM_H
1048 # include <sys/param.h>
1049 #endif
1050 ])
1051
1052 # On Solaris 2.[789], we need to define _MSE_INT_H to avoid a clash
1053 # between <widec.h> and <wchar.h> that would cause AC_CHECK_HEADERS to
1054 # think that we don't have <curses.h> if we're using GCC.
1055 case $host_os in
1056   solaris2.[[789]])
1057     if test "$GCC" = yes; then
1058       AC_DEFINE(_MSE_INT_H, 1,
1059         [Define to 1 to avoid a clash between <widec.h> and <wchar.h> on
1060    Solaris 2.[789] when using GCC. ])
1061     fi ;;
1062 esac
1063 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncurses/ncurses.h ncurses/term.h)
1064 AC_CHECK_HEADERS(term.h, [], [],
1065 [#if HAVE_CURSES_H
1066 # include <curses.h>
1067 #endif
1068 ])
1069
1070 # ------------------------- #
1071 # Checks for declarations.  #
1072 # ------------------------- #
1073
1074 AC_CHECK_DECLS([free, malloc, realloc, strerror, strstr, getopt,
1075                 snprintf, vsnprintf])
1076 AM_LC_MESSAGES
1077
1078 # ----------------------- #
1079 # Checks for structures.  #
1080 # ----------------------- #
1081
1082 AC_CHECK_MEMBERS([struct stat.st_blocks, struct stat.st_blksize])
1083
1084 # ------------------ #
1085 # Checks for types.  #
1086 # ------------------ #
1087
1088 AC_TYPE_SIGNAL
1089 AC_CHECK_TYPES(socklen_t, [], [],
1090 [#include <sys/types.h>
1091 #include <sys/socket.h>
1092 ])
1093
1094 # ------------------------------------- #
1095 # Checks for compiler characteristics.  #
1096 # ------------------------------------- #
1097
1098 AC_C_CONST
1099 AC_C_INLINE
1100 AC_C_BIGENDIAN
1101
1102 # ------------------------------ #
1103 # Checks for library functions.  #
1104 # ------------------------------ #
1105
1106 AC_FUNC_ALLOCA
1107 AC_FUNC_MMAP
1108 AC_FUNC_VFORK
1109 AC_CHECK_FUNCS([canonicalize_file_name realpath getrusage getuid getgid \
1110                 pipe poll pread pread64 pwrite readlink resize_term \
1111                 sbrk setpgid setpgrp setsid \
1112                 sigaction sigprocmask sigsetmask socketpair syscall \
1113                 ttrace wborder wresize setlocale iconvlist libiconvlist btowc \
1114                 setrlimit getrlimit posix_madvise waitpid lstat])
1115 AM_LANGINFO_CODESET
1116
1117 # Check the return and argument types of ptrace.  No canned test for
1118 # this, so roll our own.
1119 gdb_ptrace_headers='
1120 #if HAVE_SYS_TYPES_H
1121 # include <sys/types.h>
1122 #endif
1123 #if HAVE_SYS_PTRACE_H
1124 # include <sys/ptrace.h>
1125 #endif
1126 #if HAVE_UNISTD_H
1127 # include <unistd.h>
1128 #endif
1129 '
1130 # There is no point in checking if we don't have a prototype.
1131 AC_CHECK_DECLS(ptrace, [], [
1132   : ${gdb_cv_func_ptrace_ret='int'}
1133   : ${gdb_cv_func_ptrace_args='int,int,long,long'}
1134 ], $gdb_ptrace_headers)
1135 # Check return type.  Varargs (used on GNU/Linux) conflict with the
1136 # empty argument list, so check for that explicitly.
1137 AC_CACHE_CHECK([return type of ptrace], gdb_cv_func_ptrace_ret,
1138   AC_TRY_COMPILE($gdb_ptrace_headers,
1139     [extern long ptrace (enum __ptrace_request, ...);],
1140     gdb_cv_func_ptrace_ret='long',
1141     AC_TRY_COMPILE($gdb_ptrace_headers,
1142       [extern int ptrace ();],
1143       gdb_cv_func_ptrace_ret='int',
1144       gdb_cv_func_ptrace_ret='long')))
1145 AC_DEFINE_UNQUOTED(PTRACE_TYPE_RET, $gdb_cv_func_ptrace_ret,
1146   [Define as the return type of ptrace.])
1147 # Check argument types.
1148 AC_CACHE_CHECK([types of arguments for ptrace], gdb_cv_func_ptrace_args, [
1149   AC_TRY_COMPILE($gdb_ptrace_headers,
1150     [extern long ptrace (enum __ptrace_request, ...);],
1151     [gdb_cv_func_ptrace_args='int,int,long,long'],[
1152 for gdb_arg1 in 'int' 'long'; do
1153  for gdb_arg2 in 'pid_t' 'int' 'long'; do
1154   for gdb_arg3 in 'int *' 'caddr_t' 'int' 'long' 'void *'; do
1155    for gdb_arg4 in 'int' 'long'; do
1156      AC_TRY_COMPILE($gdb_ptrace_headers, [
1157 extern $gdb_cv_func_ptrace_ret
1158   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4);
1159 ], [gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4";
1160     break 4;])
1161     for gdb_arg5 in 'int *' 'int' 'long'; do
1162      AC_TRY_COMPILE($gdb_ptrace_headers, [
1163 extern $gdb_cv_func_ptrace_ret
1164   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4, $gdb_arg5);
1165 ], [
1166 gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4,$gdb_arg5";
1167     break 5;])
1168     done
1169    done
1170   done
1171  done
1172 done
1173 # Provide a safe default value.
1174 : ${gdb_cv_func_ptrace_args='int,int,long,long'}
1175 ])])
1176 ac_save_IFS=$IFS; IFS=','
1177 set dummy `echo "$gdb_cv_func_ptrace_args" | sed 's/\*/\*/g'`
1178 IFS=$ac_save_IFS
1179 shift
1180 AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG3, $[3],
1181   [Define to the type of arg 3 for ptrace.])
1182 if test -n "$[5]"; then
1183   AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG5, $[5],
1184     [Define to the type of arg 5 for ptrace.])
1185 fi
1186
1187 dnl AC_FUNC_SETPGRP does not work when cross compiling
1188 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
1189 if test "$cross_compiling" = no; then
1190   AC_FUNC_SETPGRP
1191 else
1192   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
1193     [AC_TRY_COMPILE([
1194 #include <unistd.h>
1195 ], [
1196   if (setpgrp(1,1) == -1)
1197     exit (0);
1198   else
1199     exit (1);
1200 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
1201 if test $ac_cv_func_setpgrp_void = yes; then
1202   AC_DEFINE(SETPGRP_VOID, 1)
1203 fi
1204 fi
1205
1206 # Check if sigsetjmp is available.  Using AC_CHECK_FUNCS won't do
1207 # since sigsetjmp might only be defined as a macro.
1208 AC_CACHE_CHECK([for sigsetjmp], gdb_cv_func_sigsetjmp,
1209 [AC_TRY_COMPILE([
1210 #include <setjmp.h>
1211 ], [sigjmp_buf env; while (! sigsetjmp (env, 1)) siglongjmp (env, 1);],
1212 gdb_cv_func_sigsetjmp=yes, gdb_cv_func_sigsetjmp=no)])
1213 if test $gdb_cv_func_sigsetjmp = yes; then
1214   AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available. ])
1215 fi
1216
1217 # Assume we'll default to using the included libiberty regex.
1218 gdb_use_included_regex=yes
1219
1220 # However, if the system regex is GNU regex, then default to *not*
1221 # using the included regex.
1222 AC_CACHE_CHECK(
1223   [for GNU regex],
1224   [gdb_cv_have_gnu_regex],
1225   [AC_TRY_COMPILE(
1226     [#include <gnu-versions.h>],
1227     [#define REGEX_INTERFACE_VERSION 1
1228 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
1229 # error "Version mismatch"
1230 #endif],
1231     gdb_cv_have_gnu_regex=yes,
1232     gdb_cv_have_gnu_regex=no)])
1233 if test $gdb_cv_have_gnu_regex = yes; then
1234   gdb_use_included_regex=no
1235 fi
1236
1237 AC_ARG_WITH(included-regex,
1238   AS_HELP_STRING([--without-included-regex], [don't use included regex; this is the default on systems with version 2 of the GNU C library (use with caution on other system)]),
1239   gdb_with_regex=$withval,
1240   gdb_with_regex=$gdb_use_included_regex)
1241 if test "$gdb_with_regex" = yes; then
1242   AC_DEFINE(USE_INCLUDED_REGEX, 1,
1243     [Define to 1 if the regex included in libiberty should be used.])
1244 fi
1245
1246 # Check if <sys/proc.h> defines `struct thread' with a td_pcb member.
1247 AC_CHECK_MEMBERS([struct thread.td_pcb], [], [],
1248 [#include <sys/param.h>
1249 #include <sys/proc.h>
1250 ])
1251
1252 # See if <sys/lwp.h> defines `struct lwp`.
1253 AC_CACHE_CHECK([for struct lwp], gdb_cv_struct_lwp,
1254 [AC_TRY_COMPILE([#include <sys/param.h>
1255 #include <sys/lwp.h>], [struct lwp l;],
1256 gdb_cv_struct_lwp=yes, gdb_cv_struct_lwp=no)])
1257 if test $gdb_cv_struct_lwp = yes; then
1258   AC_DEFINE(HAVE_STRUCT_LWP, 1,
1259             [Define to 1 if your system has struct lwp.])
1260 fi
1261
1262 # See if <machine/reg.h> degines `struct reg'.
1263 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
1264 [AC_TRY_COMPILE([#include <sys/types.h>
1265 #include <machine/reg.h>], [struct reg r;],
1266 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
1267 if test $gdb_cv_struct_reg = yes; then
1268   AC_DEFINE(HAVE_STRUCT_REG, 1,
1269             [Define to 1 if your system has struct reg in <machine/reg.h>.])
1270 fi
1271
1272 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
1273 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
1274 AC_CHECK_MEMBERS([struct reg.r_fs, struct reg.r_gs], [], [],
1275                  [#include <machine/reg.h>])
1276
1277 # See if <sys/user.h> supports the %fs_base and %gs_bas amd64 segment registers.
1278 # Older amd64 Linux's don't have the fs_base and gs_base members of
1279 # `struct user_regs_struct'.
1280 AC_CHECK_MEMBERS([struct user_regs_struct.fs_base, struct user_regs_struct.gs_base],
1281                  [], [], [#include <sys/user.h>])
1282
1283 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
1284 AC_MSG_CHECKING(for PTRACE_GETREGS)
1285 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
1286 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1287                 [PTRACE_GETREGS;],
1288                 [gdb_cv_have_ptrace_getregs=yes],
1289                 [gdb_cv_have_ptrace_getregs=no])])
1290 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
1291 if test $gdb_cv_have_ptrace_getregs = yes; then
1292   AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
1293   [Define if sys/ptrace.h defines the PTRACE_GETREGS request.])
1294 fi
1295
1296 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
1297 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
1298 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
1299 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1300                 [PTRACE_GETFPXREGS;],
1301                 [gdb_cv_have_ptrace_getfpxregs=yes],
1302                 [gdb_cv_have_ptrace_getfpxregs=no])])
1303 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
1304 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
1305   AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
1306   [Define if sys/ptrace.h defines the PTRACE_GETFPXREGS request.])
1307 fi
1308
1309 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
1310 AC_MSG_CHECKING(for PT_GETDBREGS)
1311 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
1312 [AC_TRY_COMPILE([#include <sys/types.h>
1313 #include <sys/ptrace.h>],
1314                 [PT_GETDBREGS;],
1315                 [gdb_cv_have_pt_getdbregs=yes],
1316                 [gdb_cv_have_pt_getdbregs=no])])
1317 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
1318 if test $gdb_cv_have_pt_getdbregs = yes; then
1319   AC_DEFINE(HAVE_PT_GETDBREGS, 1,
1320   [Define if sys/ptrace.h defines the PT_GETDBREGS request.])
1321 fi
1322
1323 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
1324 AC_MSG_CHECKING(for PT_GETXMMREGS)
1325 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
1326 [AC_TRY_COMPILE([#include <sys/types.h>
1327 #include <sys/ptrace.h>],
1328                 [PT_GETXMMREGS;],
1329                 [gdb_cv_have_pt_getxmmregs=yes],
1330                 [gdb_cv_have_pt_getxmmregs=no])])
1331 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
1332 if test $gdb_cv_have_pt_getxmmregs = yes; then
1333   AC_DEFINE(HAVE_PT_GETXMMREGS, 1,
1334   [Define if sys/ptrace.h defines the PT_GETXMMREGS request.])
1335 fi
1336
1337 # Detect which type of /proc is in use, such as for Unixware or Solaris.
1338
1339 if test "${target}" = "${host}"; then
1340   case "${host}" in
1341   *-*-unixware* | *-*-sysv4.2* | *-*-sysv5* | *-*-interix* )
1342       AC_DEFINE(NEW_PROC_API, 1,
1343       [Define if you want to use new multi-fd /proc interface
1344        (replaces HAVE_MULTIPLE_PROC_FDS as well as other macros).])
1345       ;;
1346   *-*-solaris2.[[6789]] | *-*-solaris2.1[[0-9]]*)
1347       AC_DEFINE(NEW_PROC_API, 1,
1348       [Define if you want to use new multi-fd /proc interface
1349        (replaces HAVE_MULTIPLE_PROC_FDS as well as other macros).])
1350       ;;
1351   mips-sgi-irix5*)
1352       # Work around <sys/proc.h> needing _KMEMUSER problem on IRIX 5.
1353       AC_DEFINE([_KMEMUSER], 1,
1354       [Define to 1 so <sys/proc.h> gets a definition of anon_hdl.  Works
1355        around a <sys/proc.h> problem on IRIX 5.])
1356       ;;
1357   esac
1358 fi
1359
1360 if test "$ac_cv_header_sys_procfs_h" = yes; then
1361   BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
1362   BFD_HAVE_SYS_PROCFS_TYPE(prrun_t)
1363   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
1364   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
1365   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
1366   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
1367   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
1368   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset32_t)
1369   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
1370   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
1371   BFD_HAVE_SYS_PROCFS_TYPE(prsysent_t)
1372   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigset_t)
1373   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigaction64_t)
1374   BFD_HAVE_SYS_PROCFS_TYPE(pr_siginfo64_t)
1375
1376
1377   dnl Check for broken prfpregset_t type
1378
1379   dnl For Linux/i386, glibc 2.1.3 was released with a bogus
1380   dnl prfpregset_t type (it's a typedef for the pointer to a struct
1381   dnl instead of the struct itself).  We detect this here, and work
1382   dnl around it in gdb_proc_service.h.
1383
1384   if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
1385     AC_MSG_CHECKING(whether prfpregset_t type is broken)
1386     AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
1387       [AC_TRY_RUN([#include <sys/procfs.h>
1388        int main ()
1389        {
1390          if (sizeof (prfpregset_t) == sizeof (void *))
1391            return 1;
1392          return 0;
1393        }],
1394        gdb_cv_prfpregset_t_broken=no,
1395        gdb_cv_prfpregset_t_broken=yes,
1396        gdb_cv_prfpregset_t_broken=yes)])
1397     AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
1398     if test $gdb_cv_prfpregset_t_broken = yes; then
1399       AC_DEFINE(PRFPREGSET_T_BROKEN, 1,
1400       [Define if the prfpregset_t type is broken.])
1401     fi
1402   fi
1403
1404   dnl Check for PIOCSET ioctl entry
1405
1406   AC_MSG_CHECKING(for PIOCSET ioctl entry in sys/procfs.h)
1407   AC_CACHE_VAL(gdb_cv_have_procfs_piocset,
1408   [AC_TRY_COMPILE([#include <unistd.h>
1409 #include <sys/types.h>
1410 #include <sys/procfs.h>
1411 ], [
1412     int dummy;;
1413     dummy = ioctl(0, PIOCSET, &dummy);
1414   ],
1415   gdb_cv_have_procfs_piocset=yes, gdb_cv_have_procfs_piocset=no)])
1416   AC_MSG_RESULT($gdb_cv_have_procfs_piocset)
1417   if test $gdb_cv_have_procfs_piocset = yes; then
1418     AC_DEFINE(HAVE_PROCFS_PIOCSET, 1,
1419     [Define if ioctl argument PIOCSET is available.])
1420   fi
1421 fi
1422
1423 dnl For native ports (host == target), check to see what kind of
1424 dnl legacy link.h support is needed.  (See solib-legacy.c.)
1425 if test ${host} = ${target} ; then
1426   dnl Check for struct link_map with l_ members which are indicative
1427   dnl of SVR4-like shared libraries
1428
1429   AC_MSG_CHECKING(for member l_addr in struct link_map)
1430   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_l_members,
1431     [AC_TRY_COMPILE([#include <link.h>],
1432                     [struct link_map lm; (void) lm.l_addr;],
1433                     gdb_cv_have_struct_link_map_with_l_members=yes,
1434                     gdb_cv_have_struct_link_map_with_l_members=no)])
1435   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_l_members)
1436   if test $gdb_cv_have_struct_link_map_with_l_members = yes; then
1437     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_L_MEMBERS,1,
1438     [Define if <link.h> exists and defines struct link_map which has
1439      members with an ``l_'' prefix.  (For Solaris, SVR4, and
1440      SVR4-like systems.)])
1441   fi
1442
1443   dnl Check for struct link_map with lm_ members which are indicative
1444   dnl of SunOS-like shared libraries
1445
1446   AC_MSG_CHECKING(for member lm_addr in struct link_map)
1447   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_lm_members,
1448     [AC_TRY_COMPILE([#include <sys/types.h>
1449 #include <link.h>],
1450                     [struct link_map lm; (void) lm.lm_addr;],
1451                     gdb_cv_have_struct_link_map_with_lm_members=yes,
1452                     gdb_cv_have_struct_link_map_with_lm_members=no)])
1453   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_lm_members)
1454   if test $gdb_cv_have_struct_link_map_with_lm_members = yes; then
1455     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_LM_MEMBERS, 1,
1456     [Define if <link.h> exists and defines struct link_map which has
1457      members with an ``lm_'' prefix.  (For SunOS.)])
1458   fi
1459
1460   dnl Check for struct so_map with som_ members which are found on
1461   dnl some *BSD systems.
1462
1463   AC_MSG_CHECKING(for member som_addr in struct so_map)
1464   AC_CACHE_VAL(gdb_cv_have_struct_so_map_with_som_members,
1465     [AC_TRY_COMPILE([#include <sys/types.h>
1466 #ifdef HAVE_NLIST_H
1467 #include <nlist.h>
1468 #endif
1469 #include <link.h>],
1470                     [struct so_map lm; (void) lm.som_addr;],
1471                     gdb_cv_have_struct_so_map_with_som_members=yes,
1472                     gdb_cv_have_struct_so_map_with_som_members=no)])
1473   AC_MSG_RESULT($gdb_cv_have_struct_so_map_with_som_members)
1474   if test $gdb_cv_have_struct_so_map_with_som_members = yes; then
1475     AC_DEFINE(HAVE_STRUCT_SO_MAP_WITH_SOM_MEMBERS, 1,
1476     [Define if <link.h> exists and defines a struct so_map which has
1477      members with an ``som_'' prefix.  (Found on older *BSD systems.)])
1478   fi
1479
1480   dnl Check for struct link_map32 type, which allows a 64-bit Solaris
1481   dnl debugger to debug a 32-bit Solaris app with 32-bit shared libraries.
1482
1483   AC_MSG_CHECKING(for struct link_map32 in sys/link.h)
1484   AC_CACHE_VAL(gdb_cv_have_struct_link_map32,
1485     [AC_TRY_COMPILE([#define _SYSCALL32
1486 #include <sys/link.h>], [struct link_map32 l;],
1487      gdb_cv_have_struct_link_map32=yes,
1488      gdb_cv_have_struct_link_map32=no)])
1489   AC_MSG_RESULT($gdb_cv_have_struct_link_map32)
1490   if test $gdb_cv_have_struct_link_map32 = yes; then
1491     AC_DEFINE(HAVE_STRUCT_LINK_MAP32, 1,
1492     [Define if <sys/link.h> has struct link_map32])
1493     AC_DEFINE(_SYSCALL32, 1,
1494     [Define if <sys/link.h> has link_map32 (solaris sparc-64 target)])
1495   fi
1496 fi
1497
1498 # Check if the compiler supports the `long long' type.
1499
1500 AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long,
1501                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1502 [[extern long long foo;]],
1503 [[switch (foo & 2) { case 0: return 1; }]])],
1504                                   gdb_cv_c_long_long=yes,
1505                                   gdb_cv_c_long_long=no)])
1506 if test $gdb_cv_c_long_long = yes; then
1507   AC_DEFINE(CC_HAS_LONG_LONG, 1,
1508             [Define to 1 if the compiler supports long long.])
1509 fi
1510
1511 # Check if the compiler and runtime support printing long longs.
1512
1513 AC_CACHE_CHECK([for long long support in printf],
1514                gdb_cv_printf_has_long_long,
1515                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1516 [[char buf[32];
1517   long long l = 0;
1518   l = (l << 16) + 0x0123;
1519   l = (l << 16) + 0x4567;
1520   l = (l << 16) + 0x89ab;
1521   l = (l << 16) + 0xcdef;
1522   sprintf (buf, "0x%016llx", l);
1523   return (strcmp ("0x0123456789abcdef", buf));]])],
1524                               gdb_cv_printf_has_long_long=yes,
1525                               gdb_cv_printf_has_long_long=no,
1526                               gdb_cv_printf_has_long_long=no)])
1527 if test $gdb_cv_printf_has_long_long = yes; then
1528   AC_DEFINE(PRINTF_HAS_LONG_LONG, 1,
1529             [Define to 1 if the "%ll" format works to print long longs.])
1530 fi
1531
1532 # Check if the compiler and runtime support printing decfloats.
1533
1534 AC_CACHE_CHECK([for decfloat support in printf],
1535                gdb_cv_printf_has_decfloat,
1536                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1537 [[char buf[64];
1538   _Decimal32 d32 = 1.2345df;
1539   _Decimal64 d64 = 1.2345dd;
1540   _Decimal128 d128 = 1.2345dl;
1541   sprintf (buf, "Decimal32: %H\nDecimal64: %D\nDecimal128: %DD", d32, d64, d128);
1542   return (strcmp ("Decimal32: 1.2345\nDecimal64: 1.2345\nDecimal128: 1.2345", buf));]])],
1543                               gdb_cv_printf_has_decfloat=yes,
1544                               gdb_cv_printf_has_decfloat=no,
1545                               gdb_cv_printf_has_decfloat=no)])
1546 if test $gdb_cv_printf_has_decfloat = yes; then
1547   AC_DEFINE(PRINTF_HAS_DECFLOAT, 1,
1548             [Define to 1 if the "%H, %D and %DD" formats work to print decfloats.])
1549 fi
1550
1551 # Check if the compiler supports the `long double' type.  We can't use
1552 # AC_C_LONG_DOUBLE because that one does additional checks on the
1553 # constants defined in <float.h> that fail on some systems,
1554 # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6.
1555
1556 AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double,
1557                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])],
1558                                   gdb_cv_c_long_double=yes,
1559                                   gdb_cv_c_long_double=no)])
1560 if test $gdb_cv_c_long_double = yes; then
1561   AC_DEFINE(HAVE_LONG_DOUBLE, 1,
1562            [Define to 1 if the compiler supports long double.])
1563 fi
1564
1565 # Check if the compiler and runtime support printing long doubles.
1566
1567 AC_CACHE_CHECK([for long double support in printf],
1568                gdb_cv_printf_has_long_double,
1569                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1570 [[char buf[16];
1571   long double f = 3.141592653;
1572   sprintf (buf, "%Lg", f);
1573   return (strncmp ("3.14159", buf, 7));]])],
1574                               gdb_cv_printf_has_long_double=yes,
1575                               gdb_cv_printf_has_long_double=no,
1576                               gdb_cv_printf_has_long_double=no)])
1577 if test $gdb_cv_printf_has_long_double = yes; then
1578   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1,
1579             [Define to 1 if the "%Lg" format works to print long doubles.])
1580 fi
1581
1582 # Check if the compiler and runtime support scanning long doubles.
1583
1584 AC_CACHE_CHECK([for long double support in scanf],
1585                gdb_cv_scanf_has_long_double,
1586                [AC_RUN_IFELSE([AC_LANG_PROGRAM(
1587 [[#include <stdio.h>]],
1588 [[char *buf = "3.141592653";
1589   long double f = 0;
1590   sscanf (buf, "%Lg", &f);
1591   return !(f > 3.14159 && f < 3.14160);]])],
1592                               gdb_cv_scanf_has_long_double=yes,
1593                               gdb_cv_scanf_has_long_double=no,
1594                               gdb_cv_scanf_has_long_double=no)])
1595 if test $gdb_cv_scanf_has_long_double = yes; then
1596   AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1,
1597             [Define to 1 if the "%Lg" format works to scan long doubles.])
1598 fi
1599
1600 case ${host_os} in
1601 aix*)
1602   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1603     SAVE_LDFLAGS=$LDFLAGS
1604
1605     case $GCC in
1606     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1607     *) gdb_cv_bigtoc=-bbigtoc ;;
1608     esac
1609
1610     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1611     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1612     LDFLAGS="${SAVE_LDFLAGS}"
1613   ])
1614   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
1615   ;;
1616 esac
1617
1618 AC_MSG_CHECKING(for the dynamic export flag)
1619 dynamic_list=false
1620 if test "${gdb_native}" = yes; then
1621    # The dynamically loaded libthread_db needs access to symbols in the gdb
1622    # executable.  Older GNU ld supports --export-dynamic but --dynamic-list
1623    # may not be supported there.
1624    old_LDFLAGS="$LDFLAGS"
1625    # Older GNU ld supports --export-dynamic but --dynamic-list it does not.
1626    RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
1627    LDFLAGS="$LDFLAGS $RDYNAMIC"
1628    if test "${have_libpython}" = no; then
1629      AC_TRY_LINK([], [], [dynamic_list=true])
1630    else
1631      # Workaround http://bugs.python.org/issue4434 where static
1632      # libpythonX.Y.a would get its symbols required for
1633      # pythonX.Y/lib-dynload/*.so modules hidden by -Wl,--dynamic-list.
1634      # Problem does not happen for the recommended libpythonX.Y.so linkage.
1635      old_CFLAGS="$CFLAGS"
1636      CFLAGS="$CFLAGS $PYTHON_CFLAGS"
1637      AC_RUN_IFELSE(
1638        AC_LANG_PROGRAM(
1639          [#include "]${have_libpython}[/Python.h"],
1640          [int err;
1641           Py_Initialize ();
1642           err = PyRun_SimpleString ("import itertools\n");
1643           Py_Finalize ();
1644           return err == 0 ? 0 : 1;]),
1645        [dynamic_list=true], [], [true])
1646      CFLAGS="$old_CFLAGS"
1647    fi
1648    LDFLAGS="$old_LDFLAGS"
1649 fi
1650 if $dynamic_list; then
1651   found="-Wl,--dynamic-list"
1652   RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'
1653 else
1654   found="-rdynamic"
1655   RDYNAMIC="-rdynamic"
1656 fi
1657 AC_SUBST(RDYNAMIC)
1658 AC_MSG_RESULT($found)
1659
1660 dnl For certain native configurations, we need to check whether thread
1661 dnl support can be built in or not.
1662 dnl
1663 dnl Note that we only want this if we are both native (host == target),
1664 dnl and not doing a canadian cross build (build == host).
1665
1666 if test ${build} = ${host} -a ${host} = ${target} ; then
1667    case ${host_os} in
1668    solaris*)
1669       # See if thread_db library is around for Solaris thread debugging.
1670       # Note that we must explicitly test for version 1 of the library
1671       # because version 0 (present on Solaris 2.4 or earlier) doesn't have
1672       # the same API.
1673       AC_MSG_CHECKING(for Solaris thread debugging library)
1674       if test -f /usr/lib/libthread_db.so.1 ; then
1675          AC_MSG_RESULT(yes)
1676          AC_DEFINE(HAVE_THREAD_DB_LIB, 1,
1677          [Define if using Solaris thread debugging.])
1678          CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
1679          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
1680          AC_CHECK_LIB(dl, dlopen)
1681          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} $RDYNAMIC"
1682          # Sun randomly tweaked the prototypes in <proc_service.h>
1683          # at one point.
1684          AC_MSG_CHECKING(if <proc_service.h> is old)
1685          AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
1686             AC_TRY_COMPILE([
1687                 #include <proc_service.h>
1688                 ps_err_e ps_pdwrite
1689                     (struct ps_prochandle*, psaddr_t, const void*, size_t);
1690             ],, gdb_cv_proc_service_is_old=no,
1691                 gdb_cv_proc_service_is_old=yes)
1692          ])
1693          AC_MSG_RESULT($gdb_cv_proc_service_is_old)
1694          if test $gdb_cv_proc_service_is_old = yes; then
1695             AC_DEFINE(PROC_SERVICE_IS_OLD, 1,
1696             [Define if <proc_service.h> on solaris uses int instead of
1697              size_t, and assorted other type changes.])
1698          fi
1699       else
1700          AC_MSG_RESULT(no)
1701       fi
1702       ;;
1703    aix*)
1704       AC_MSG_CHECKING(for AiX thread debugging library)
1705       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
1706                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
1707                                    [#ifndef PTHDB_VERSION_3
1708                                     #error
1709                                     #endif],
1710                                    gdb_cv_have_aix_thread_debug=yes,
1711                                    gdb_cv_have_aix_thread_debug=no)])
1712       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1713       if test $gdb_cv_have_aix_thread_debug = yes; then
1714          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1715          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1716          LIBS="$LIBS -lpthdebug"
1717
1718          # Older versions of AIX do not provide the declaration for
1719          # the getthrds function (it appears that it was introduced
1720          # with AIX 6.x).
1721          AC_CHECK_DECLS(getthrds, [], [], [[#include <procinfo.h>]])
1722       fi
1723       ;;
1724    esac
1725    AC_SUBST(CONFIG_LDFLAGS)
1726 fi
1727
1728 dnl See if we have a thread_db header file that has TD_NOTALLOC and
1729 dnl other error codes.
1730 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1731    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
1732                   gdb_cv_thread_db_h_has_td_notalloc,
1733      AC_TRY_COMPILE(
1734        [#include <thread_db.h>],
1735        [int i = TD_NOTALLOC;],
1736        gdb_cv_thread_db_h_has_td_notalloc=yes,
1737        gdb_cv_thread_db_h_has_td_notalloc=no
1738      )
1739    )
1740    AC_CACHE_CHECK([whether <thread_db.h> has TD_VERSION],
1741                   gdb_cv_thread_db_h_has_td_version,
1742      AC_TRY_COMPILE(
1743        [#include <thread_db.h>],
1744        [int i = TD_VERSION;],
1745        gdb_cv_thread_db_h_has_td_version=yes,
1746        gdb_cv_thread_db_h_has_td_version=no
1747      )
1748    )
1749    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTLS],
1750                   gdb_cv_thread_db_h_has_td_notls,
1751      AC_TRY_COMPILE(
1752        [#include <thread_db.h>],
1753        [int i = TD_NOTLS;],
1754        gdb_cv_thread_db_h_has_td_notls=yes,
1755        gdb_cv_thread_db_h_has_td_notls=no
1756      )
1757    )
1758 fi
1759 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1760   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1761             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1762 fi
1763 if test "x$gdb_cv_thread_db_h_has_td_version" = "xyes"; then
1764   AC_DEFINE(THREAD_DB_HAS_TD_VERSION, 1,
1765             [Define if <thread_db.h> has the TD_VERSION error code.])
1766 fi
1767 if test "x$gdb_cv_thread_db_h_has_td_notls" = "xyes"; then
1768   AC_DEFINE(THREAD_DB_HAS_TD_NOTLS, 1,
1769             [Define if <thread_db.h> has the TD_NOTLS error code.])
1770 fi
1771
1772 dnl See if we have a sys/syscall header file that has __NR_tkill.
1773 if test "x$ac_cv_header_sys_syscall_h" = "xyes"; then
1774    AC_CACHE_CHECK([whether <sys/syscall.h> has __NR_tkill],
1775                   gdb_cv_sys_syscall_h_has_tkill,
1776      AC_TRY_COMPILE(
1777        [#include <sys/syscall.h>],
1778        [int i = __NR_tkill;],
1779        gdb_cv_sys_syscall_h_has_tkill=yes,
1780        gdb_cv_sys_syscall_h_has_tkill=no
1781      )
1782    )
1783 fi
1784 dnl See if we can issue tkill syscall.
1785 if test "x$gdb_cv_sys_syscall_h_has_tkill" = "xyes" && test "x$ac_cv_func_syscall" = "xyes"; then
1786   AC_DEFINE(HAVE_TKILL_SYSCALL, 1, [Define if you support the tkill syscall.])
1787 fi
1788
1789 dnl Check if we can disable the virtual address space randomization.
1790 dnl The functionality of setarch -R.
1791 AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>])
1792 define([PERSONALITY_TEST], [AC_LANG_PROGRAM([#include <sys/personality.h>], [
1793 #      if !HAVE_DECL_ADDR_NO_RANDOMIZE
1794 #       define ADDR_NO_RANDOMIZE 0x0040000
1795 #      endif
1796        /* Test the flag could be set and stays set.  */
1797        personality (personality (0xffffffff) | ADDR_NO_RANDOMIZE);
1798        if (!(personality (personality (0xffffffff)) & ADDR_NO_RANDOMIZE))
1799            return 1])])
1800 AC_RUN_IFELSE([PERSONALITY_TEST],
1801               [have_personality=true],
1802               [have_personality=false],
1803               [AC_LINK_IFELSE([PERSONALITY_TEST],
1804                               [have_personality=true],
1805                               [have_personality=false])])
1806 if $have_personality
1807 then
1808     AC_DEFINE([HAVE_PERSONALITY], 1,
1809               [Define if you support the personality syscall.])
1810 fi
1811
1812 dnl Handle optional features that can be enabled.
1813
1814 # Support for --with-sysroot is a copy of GDB_AC_WITH_DIR,
1815 # except that the argument to --with-sysroot is optional.
1816 # --with-sysroot (or --with-sysroot=yes) sets the default sysroot path.
1817 if test "x$with_sysroot" = xyes; then
1818   with_sysroot="${exec_prefix}/${target_alias}/sys-root"
1819 fi
1820 AC_ARG_WITH(sysroot,
1821   AS_HELP_STRING([--with-sysroot@<:@=DIR@:>@],
1822                  [search for usr/lib et al within DIR]),
1823   [TARGET_SYSTEM_ROOT=$withval], [TARGET_SYSTEM_ROOT=])
1824 AC_DEFINE_DIR(TARGET_SYSTEM_ROOT, TARGET_SYSTEM_ROOT,
1825               [search for usr/lib et al within DIR])
1826 AC_SUBST(TARGET_SYSTEM_ROOT)
1827 GDB_AC_DEFINE_RELOCATABLE(TARGET_SYSTEM_ROOT, sysroot, ${ac_define_dir})
1828
1829 GDB_AC_WITH_DIR(SYSTEM_GDBINIT, system-gdbinit,
1830     [automatically load a system-wide gdbinit file],
1831     [])
1832
1833 AC_ARG_ENABLE(werror,
1834   AS_HELP_STRING([--enable-werror], [treat compile warnings as errors]),
1835   [case "${enableval}" in
1836      yes | y) ERROR_ON_WARNING="yes" ;;
1837      no | n)  ERROR_ON_WARNING="no" ;;
1838      *) AC_MSG_ERROR(bad value ${enableval} for --enable-werror) ;;
1839    esac])
1840
1841 # Enable -Werror by default when using gcc.  Turn it off for releases.
1842 if test "${GCC}" = yes -a -z "${ERROR_ON_WARNING}" && $development; then
1843     ERROR_ON_WARNING=yes
1844 fi
1845
1846 WERROR_CFLAGS=""
1847 if test "${ERROR_ON_WARNING}" = yes ; then
1848     WERROR_CFLAGS="-Werror"
1849 fi
1850
1851 # The entries after -Wno-pointer-sign are disabled warnings which may
1852 # be enabled in the future, which can not currently be used to build
1853 # GDB.
1854 # NOTE: If you change this list, remember to update
1855 # gdb/doc/gdbint.texinfo.
1856 build_warnings="-Wall -Wdeclaration-after-statement -Wpointer-arith \
1857 -Wformat-nonliteral -Wno-pointer-sign \
1858 -Wno-unused -Wunused-value -Wunused-function \
1859 -Wno-switch -Wno-char-subscripts -Wmissing-prototypes \
1860 -Wdeclaration-after-statement"
1861
1862 # Enable -Wno-format by default when using gcc on mingw since many
1863 # GCC versions complain about %I64.
1864 case "${host}" in
1865   *-*-mingw32*) build_warnings="$build_warnings -Wno-format" ;;
1866 esac
1867
1868 AC_ARG_ENABLE(build-warnings,
1869 AS_HELP_STRING([--enable-build-warnings], [enable build-time compiler warnings if gcc is used]),
1870 [case "${enableval}" in
1871   yes)  ;;
1872   no)   build_warnings="-w";;
1873   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1874         build_warnings="${build_warnings} ${t}";;
1875   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1876         build_warnings="${t} ${build_warnings}";;
1877   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1878 esac
1879 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1880   echo "Setting compiler warning flags = $build_warnings" 6>&1
1881 fi])dnl
1882 AC_ARG_ENABLE(gdb-build-warnings,
1883 AS_HELP_STRING([--enable-gdb-build-warnings], [enable GDB specific build-time compiler warnings if gcc is used]),
1884 [case "${enableval}" in
1885   yes)  ;;
1886   no)   build_warnings="-w";;
1887   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1888         build_warnings="${build_warnings} ${t}";;
1889   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1890         build_warnings="${t} ${build_warnings}";;
1891   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1892 esac
1893 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1894   echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1
1895 fi])dnl
1896 WARN_CFLAGS=""
1897 if test "x${build_warnings}" != x -a "x$GCC" = xyes
1898 then
1899     AC_MSG_CHECKING(compiler warning flags)
1900     # Separate out the -Werror flag as some files just cannot be
1901     # compiled with it enabled.
1902     for w in ${build_warnings}; do
1903         case $w in
1904         -Werr*) WERROR_CFLAGS=-Werror ;;
1905         *) # Check that GCC accepts it
1906             saved_CFLAGS="$CFLAGS"
1907             CFLAGS="$CFLAGS $w"
1908             AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
1909             CFLAGS="$saved_CFLAGS"
1910         esac
1911     done
1912     AC_MSG_RESULT(${WARN_CFLAGS} ${WERROR_CFLAGS})
1913 fi
1914 AC_SUBST(WARN_CFLAGS)
1915 AC_SUBST(WERROR_CFLAGS)
1916
1917 # In the Cygwin environment, we need some additional flags.
1918 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1919 [AC_EGREP_CPP(lose, [
1920 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1921 lose
1922 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1923
1924
1925 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1926 SER_HARDWIRE="ser-base.o ser-unix.o ser-pipe.o ser-tcp.o"
1927 case ${host} in
1928   *go32* ) SER_HARDWIRE=ser-go32.o ;;
1929   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
1930   *mingw32*) SER_HARDWIRE="ser-base.o ser-tcp.o ser-mingw.o" ;;
1931 esac
1932 AC_SUBST(SER_HARDWIRE)
1933
1934 # libreadline needs libuser32.a in a cygwin environment
1935 WIN32LIBS=
1936 if test x$gdb_cv_os_cygwin = xyes; then
1937     WIN32LIBS="-luser32"
1938     case "${target}" in
1939         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
1940         ;;
1941     esac
1942 fi
1943
1944 # The ser-tcp.c module requires sockets.
1945 case ${host} in
1946   *mingw32*)
1947     AC_DEFINE(USE_WIN32API, 1,
1948               [Define if we should use the Windows API, instead of the
1949                POSIX API.  On Windows, we use the Windows API when
1950                building for MinGW, but the POSIX API when building
1951                for Cygwin.])
1952     WIN32LIBS="$WIN32LIBS -lws2_32"
1953     ;;
1954 esac
1955 AC_SUBST(WIN32LIBS)
1956
1957 # Add ELF support to GDB, but only if BFD includes ELF support.
1958 OLD_CFLAGS=$CFLAGS
1959 OLD_LDFLAGS=$LDFLAGS
1960 OLD_LIBS=$LIBS
1961 # Put the old CFLAGS/LDFLAGS last, in case the user's (C|LD)FLAGS
1962 # points somewhere with bfd, with -I/foo/lib and -L/foo/lib.  We
1963 # always want our bfd.
1964 CFLAGS="-I${srcdir}/../include -I../bfd -I${srcdir}/../bfd $CFLAGS"
1965 LDFLAGS="-L../bfd -L../libiberty $LDFLAGS"
1966 intl=`echo $LIBINTL | sed 's,${top_builddir}/,,g'`
1967 # -ldl is provided by bfd/Makfile.am (LIBDL) <PLUGINS>.
1968 if test "$plugins" = "yes"; then
1969   LIBS="-ldl $LIBS"
1970 fi
1971 LIBS="-lbfd -liberty $intl $LIBS"
1972 AC_CACHE_CHECK([for ELF support in BFD], gdb_cv_var_elf,
1973 [AC_TRY_LINK(
1974 [#include <stdlib.h>
1975 #include "bfd.h"
1976 #include "elf-bfd.h"
1977 ],
1978 [bfd *abfd = NULL; bfd_get_elf_phdr_upper_bound (abfd); ],
1979 gdb_cv_var_elf=yes, gdb_cv_var_elf=no)])
1980 if test $gdb_cv_var_elf = yes; then
1981   CONFIG_OBS="$CONFIG_OBS elfread.o stap-probe.o"
1982   AC_DEFINE(HAVE_ELF, 1,
1983             [Define if ELF support should be included.])
1984   # -ldl is provided by bfd/Makfile.am (LIBDL) <PLUGINS>.
1985   if test "$plugins" = "yes"; then
1986     OLD_LIBS="-ldl $OLD_LIBS"
1987   fi
1988 fi
1989 CFLAGS=$OLD_CFLAGS
1990 LDFLAGS=$OLD_LDFLAGS
1991 LIBS=$OLD_LIBS
1992
1993 # Add any host-specific objects to GDB.
1994 CONFIG_OBS="${CONFIG_OBS} ${gdb_host_obs}"
1995
1996 LIBGUI="../libgui/src/libgui.a"
1997 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
1998 AC_SUBST(LIBGUI)
1999 AC_SUBST(GUI_CFLAGS_X)
2000
2001 WIN32LDAPP=
2002 AC_SUBST(WIN32LIBS)
2003 AC_SUBST(WIN32LDAPP)
2004
2005 case "${host}" in
2006 *-*-cygwin* | *-*-mingw* )
2007     configdir="win"
2008     ;;
2009 *)
2010     configdir="unix"
2011     ;;
2012 esac
2013
2014 GDBTKLIBS=
2015 if test "${enable_gdbtk}" = "yes"; then
2016
2017     # Gdbtk must have an absolute path to srcdir in order to run
2018     # properly when not installed.
2019     here=`pwd`
2020     cd ${srcdir}
2021     GDBTK_SRC_DIR=`pwd`
2022     cd $here
2023
2024     SC_PATH_TCLCONFIG
2025
2026     # If $no_tk is nonempty, then we can't do Tk, and there is no
2027     # point to doing Tcl.
2028     SC_PATH_TKCONFIG
2029
2030     if test -z "${no_tcl}" -a -z "${no_tk}"; then
2031         SC_LOAD_TCLCONFIG
2032
2033         # Check for in-tree tcl
2034         here=`pwd`
2035         cd ${srcdir}/..
2036         topdir=`pwd`
2037         cd ${here}
2038
2039         intree="no"
2040         if test "${TCL_SRC_DIR}" = "${topdir}/tcl"; then
2041           intree="yes"
2042         fi
2043
2044         # Find Tcl private headers
2045         if test x"${intree}" = xno; then
2046           CY_AC_TCL_PRIVATE_HEADERS
2047           TCL_INCLUDE="${TCL_INCLUDE_SPEC} ${TCL_PRIVATE_INCLUDE}"
2048           TCL_LIBRARY="${TCL_LIB_SPEC}"
2049           TCL_DEPS=""
2050         else
2051           # If building tcl in the same src tree, private headers
2052           # are not needed, but we need to be sure to use the right
2053           # headers library
2054           TCL_INCLUDE="-I${TCL_SRC_DIR}/generic"
2055           TCL_LIBRARY="${TCL_BUILD_LIB_SPEC}"
2056           TCL_DEPS="../tcl/${configdir}${TCL_LIB_FILE}"
2057         fi
2058         AC_SUBST(TCL_INCLUDE)
2059         AC_SUBST(TCL_LIBRARY)
2060         AC_SUBST(TCL_DEPS)
2061
2062         SC_LOAD_TKCONFIG
2063
2064         # Check for in-tree Tk
2065         intree="no"
2066         if test "${TK_SRC_DIR}" = "${topdir}/tk"; then
2067           intree="yes"
2068         fi
2069
2070         # Find Tk private headers
2071         if test x"${intree}" = xno; then
2072           CY_AC_TK_PRIVATE_HEADERS
2073           TK_INCLUDE="${TK_INCLUDE_SPEC} ${TK_PRIVATE_INCLUDE}"
2074           TK_LIBRARY=${TK_LIB_SPEC}
2075           TK_DEPS=""
2076         else
2077           TK_INCLUDE="-I${TK_SRC_DIR}/generic"
2078           TK_LIBRARY="${TK_BUILD_LIB_SPEC}"
2079           TK_DEPS="../tk/${configdir}/${TK_LIB_FILE}"
2080         fi
2081         AC_SUBST(TK_INCLUDE)
2082         AC_SUBST(TK_LIBRARY)
2083         AC_SUBST(TK_DEPS)
2084         AC_SUBST(TK_XINCLUDES)
2085
2086         ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
2087
2088         # Include some libraries that Tcl and Tk want.
2089         TCL_LIBS='$(LIBGUI) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
2090         # Yes, the ordering seems wrong here.  But it isn't.
2091         # TK_LIBS is the list of libraries that need to be linked
2092         # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
2093         # were in LIBS then any link tests after this point would
2094         # try to include things like `$(LIBGUI)', which wouldn't work.
2095         GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
2096
2097         CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
2098         CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
2099         CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
2100         CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
2101         CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
2102         CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
2103         CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
2104
2105         if test x$gdb_cv_os_cygwin = xyes; then
2106           WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
2107           WIN32LDAPP="-Wl,--subsystem,console"
2108           CONFIG_OBS="${CONFIG_OBS} gdbres.o"
2109         fi
2110
2111         AC_CONFIG_SUBDIRS(gdbtk)
2112     fi
2113 fi
2114
2115 AC_SUBST(X_CFLAGS)
2116 AC_SUBST(X_LDFLAGS)
2117 AC_SUBST(X_LIBS)
2118 AC_SUBST(GDBTKLIBS)
2119 AC_SUBST(GDBTK_CFLAGS)
2120 AC_SUBST(GDBTK_SRC_DIR)
2121
2122 AC_PATH_X
2123
2124 # Unlike the sim directory, whether a simulator is linked is controlled by
2125 # presence of a gdb_sim definition in the target configure.tgt entry.
2126 # This code just checks for a few cases where we'd like to ignore those
2127 # definitions, even when they're present in the '.mt' file.  These cases
2128 # are when --disable-sim is specified, or if the simulator directory is
2129 # not part of the source tree.
2130 #
2131 AC_ARG_ENABLE(sim,
2132 AS_HELP_STRING([--enable-sim], [link gdb with simulator]),
2133 [echo "enable_sim = $enable_sim";
2134  echo "enableval = ${enableval}";
2135  case "${enableval}" in
2136   yes) ignore_sim=false ;;
2137   no)  ignore_sim=true ;;
2138   *)   ignore_sim=false ;;
2139  esac],
2140 [ignore_sim=false])
2141
2142 if test ! -d "${srcdir}/../sim"; then
2143   ignore_sim=true
2144 fi
2145
2146 SIM=
2147 SIM_OBS=
2148 if test "${ignore_sim}" = "false"; then
2149   if test x"${gdb_sim}" != x ; then
2150     SIM="${gdb_sim}"
2151     SIM_OBS="remote-sim.o"
2152     AC_DEFINE(WITH_SIM, 1, [Define if the simulator is being linked in.])
2153   fi
2154 fi
2155 AC_SUBST(SIM)
2156 AC_SUBST(SIM_OBS)
2157
2158 AC_SUBST(ENABLE_CFLAGS)
2159 AC_SUBST(PROFILE_CFLAGS)
2160
2161 AC_SUBST(CONFIG_OBS)
2162 AC_SUBST(CONFIG_DEPS)
2163 AC_SUBST(CONFIG_SRCS)
2164 AC_SUBST(CONFIG_ALL)
2165 AC_SUBST(CONFIG_CLEAN)
2166 AC_SUBST(CONFIG_INSTALL)
2167 AC_SUBST(CONFIG_UNINSTALL)
2168
2169 # List of host floatformats.
2170 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
2171 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
2172 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
2173
2174 # target_subdir is used by the testsuite to find the target libraries.
2175 target_subdir=
2176 if test "${host}" != "${target}"; then
2177     target_subdir="${target_alias}/"
2178 fi
2179 AC_SUBST(target_subdir)
2180
2181 frags=
2182 if test "${gdb_native}" = "yes"; then
2183   host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
2184   if test ! -f ${host_makefile_frag}; then
2185     AC_MSG_ERROR("*** Gdb does not support native target ${host}")
2186   fi
2187   frags="$frags $host_makefile_frag"
2188 else
2189   host_makefile_frag=/dev/null
2190 fi
2191
2192 AC_SUBST_FILE(host_makefile_frag)
2193 AC_SUBST(frags)
2194
2195 changequote(,)dnl
2196 if test "${gdb_native}" = "yes"; then
2197 # We pick this up from the host configuration file (.mh) because we
2198 # do not have a native configuration Makefile fragment.
2199 nativefile=`sed -n '
2200 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
2201 ' ${host_makefile_frag}`
2202 fi
2203 changequote([,])
2204
2205 if test x"${gdb_osabi}" != x ; then
2206     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
2207                        [Define to the default OS ABI for this configuration.])
2208 fi
2209
2210 # Enable multi-ice-gdb-server.
2211 AC_ARG_ENABLE(multi-ice,
2212 AS_HELP_STRING([--enable-multi-ice], [build the multi-ice-gdb-server]),
2213   [case $enableval in
2214     yes | no)
2215       ;;
2216     *) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;;
2217   esac])
2218 if test "x$enable_multi_ice" = xyes; then
2219    AC_CONFIG_SUBDIRS(multi-ice)
2220 fi
2221
2222 AC_ARG_ENABLE(gdbserver,
2223 AS_HELP_STRING([--enable-gdbserver],
2224                [automatically build gdbserver (yes/no/auto, default is auto)]),
2225 [case "${enableval}" in
2226   yes| no|auto) ;;
2227   *) AC_MSG_ERROR(bad value ${enableval} for --enable-gdbserver option) ;;
2228 esac],[enable_gdbserver=auto])
2229
2230 # We only build gdbserver automatically in a native configuration, and
2231 # only if the user did not explicitly disable its build.
2232 if test "$gdb_native" = "yes" -a "$enable_gdbserver" != "no"; then
2233   AC_MSG_CHECKING(whether gdbserver is supported on this host)
2234   if test "x$build_gdbserver" = xyes; then
2235     AC_MSG_RESULT(yes)
2236     AC_CONFIG_SUBDIRS(gdbserver)
2237     gdbserver_build_enabled=yes
2238   else
2239     AC_MSG_RESULT(no)
2240   fi
2241 fi
2242
2243 # If the user explicitly request the gdbserver to be built, verify that
2244 # we were in fact able to enable it.
2245 if test "$enable_gdbserver" = "yes" -a "$gdbserver_build_enabled" != "yes"; then
2246   AC_MSG_ERROR(Automatic gdbserver build is not supported for this configuration)
2247 fi
2248
2249 # If nativefile (NAT_FILE) is not set in config/*/*.m[ht] files, we link
2250 # to an empty version.
2251
2252 files=
2253 links=
2254
2255 rm -f nm.h
2256 if test "${nativefile}" != ""; then
2257     case "${nativefile}" in
2258       nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
2259       * ) GDB_NM_FILE="${nativefile}"
2260     esac
2261     files="${files} ${GDB_NM_FILE}"
2262     links="${links} nm.h"
2263     AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}", [nativefile])
2264 fi
2265 AC_SUBST(GDB_NM_FILE)
2266
2267 AC_LINK_FILES($files, $links)
2268
2269 dnl Check for exe extension set on certain hosts (e.g. Win32)
2270 AC_EXEEXT
2271
2272 dnl  Detect the character set used by this host.
2273 dnl  At the moment, we just assume it's UTF-8.
2274 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "UTF-8",
2275           [Define to be a string naming the default host character set.])
2276
2277 AC_OUTPUT(Makefile gdb-gdb.gdb doc/Makefile data-directory/Makefile,
2278 [
2279 case x$CONFIG_HEADERS in
2280 xconfig.h:config.in)
2281 echo > stamp-h ;;
2282 esac
2283 ])
2284
2285 exit 0