gdb/configure.ac

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995-2018 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Process this file with autoconf to produce a configure script.
  20
  21 AC_PREREQ(2.59)dnl
  22 AC_INIT(main.c)
  23 AC_CONFIG_HEADER(config.h:config.in)
  24 AM_MAINTAINER_MODE
  25
  26 # Set the 'development' global.
  27 . $srcdir/../bfd/development.sh
  28
  29 AC_PROG_CC
  30 AC_PROG_CXX
  31
  32 AC_USE_SYSTEM_EXTENSIONS
  33 ACX_LARGEFILE
  34 AM_PROG_CC_STDC
  35 AM_PROG_INSTALL_STRIP
  36
  37 AC_CONFIG_AUX_DIR(..)
  38 AC_CANONICAL_SYSTEM
  39 AC_ARG_PROGRAM
  40
  41 # We require a C++11 compiler.  Check if one is available, and if
  42 # necessary, set CXX_DIALECT to some -std=xxx switch.
  43 AX_CXX_COMPILE_STDCXX(11, , mandatory)
  44
  45 # Dependency checking.
  46 ZW_CREATE_DEPDIR
  47 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  48
  49 gnulib_extra_configure_args=
  50 # If large-file support is disabled, make sure gnulib does the same.
  51 if test "$enable_largefile" = no; then
  52 gnulib_extra_configure_args="$gnulib_extra_configure_args --disable-largefile"
  53 fi
  54
  55 # Configure gnulib.  We need to build gnulib under some other
  56 # directory not "gnulib", to avoid the problem of both GDB and
  57 # GDBserver wanting to build it in the same directory, when building
  58 # in the source dir.
  59 ACX_CONFIGURE_DIR(["gnulib"], ["build-gnulib"],
  60                   ["$gnulib_extra_configure_args"])
  61
  62 dnl List of object files and targets accumulated by configure.
  63
  64 CONFIG_OBS=
  65 CONFIG_DEPS=
  66 CONFIG_SRCS=
  67 ENABLE_CFLAGS=
  68
  69 CONFIG_ALL=
  70 CONFIG_CLEAN=
  71 CONFIG_INSTALL=
  72 CONFIG_UNINSTALL=
  73
  74 dnl Set up for gettext.
  75 ZW_GNU_GETTEXT_SISTER_DIR
  76
  77 localedir='${datadir}/locale'
  78 AC_SUBST(localedir)
  79
  80 if test x"$USE_NLS" = xyes; then
  81    CONFIG_ALL="$CONFIG_ALL all-po"
  82    CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
  83    CONFIG_INSTALL="$CONFIG_INSTALL install-po"
  84    CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
  85 fi
  86
  87 GNULIB=build-gnulib/import
  88
  89 # For Makefile dependencies.
  90 GNULIB_STDINT_H=
  91 if test x"$STDINT_H" != x; then
  92   GNULIB_STDINT_H=$GNULIB/$STDINT_H
  93 fi
  94 AC_SUBST(GNULIB_STDINT_H)
  95
  96 PACKAGE=gdb
  97 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
  98 AC_SUBST(PACKAGE)
  99
 100 # We never need to detect it in this sub-configure.
 101 # But preserve it for config.status --recheck.
 102 AC_ARG_VAR(MAKEINFO,
 103   [Parent configure detects if it is of sufficient version.])
 104 AC_ARG_VAR(MAKEINFOFLAGS,
 105   [Parameters for MAKEINFO.])
 106
 107 MAKEINFO_EXTRA_FLAGS=""
 108 AC_CACHE_CHECK([whether $MAKEINFO supports @click], gdb_cv_have_makeinfo_click,
 109   [echo '@clicksequence{a @click{} b}' >conftest.texinfo
 110   if eval "$MAKEINFO conftest.texinfo >&5 2>&5"; then
 111     gdb_cv_have_makeinfo_click=yes
 112   else
 113     gdb_cv_have_makeinfo_click=no
 114   fi])
 115 if test x"$gdb_cv_have_makeinfo_click" = xyes; then
 116   MAKEINFO_EXTRA_FLAGS="$MAKEINFO_EXTRA_FLAGS -DHAVE_MAKEINFO_CLICK"
 117 fi
 118 AC_SUBST(MAKEINFO_EXTRA_FLAGS)
 119
 120 GDB_AC_WITH_DIR(DEBUGDIR, separate-debug-dir,
 121     [look for global separate debug info in this path @<:@LIBDIR/debug@:>@],
 122     [${libdir}/debug])
 123
 124 # We can't pass paths as command line arguments.
 125 # Mingw32 tries to be clever and will convert the paths for us.
 126 # For example -DBINDIR="/usr/local/bin" passed on the command line may get
 127 # converted to -DBINDIR="E:/msys/mingw32/msys/1.0/local/bin".
 128 # This breaks GDB's relocatable path conversions since paths passed in
 129 # config.h would not get so translated, the path prefixes no longer match.
 130 AC_DEFINE_DIR(BINDIR, bindir, [Directory of programs.])
 131
 132 # GDB's datadir relocation
 133
 134 GDB_AC_WITH_DIR(GDB_DATADIR, gdb-datadir,
 135     [look for global separate data files in this path @<:@DATADIR/gdb@:>@],
 136     [${datadir}/gdb])
 137
 138 AC_ARG_WITH(relocated-sources,
 139 AS_HELP_STRING([--with-relocated-sources=PATH], [automatically relocate this path for source files]),
 140 [reloc_srcdir="${withval}"
 141  AC_DEFINE_DIR(RELOC_SRCDIR, reloc_srcdir,
 142               [Relocated directory for source files. ])
 143 ])
 144
 145 AC_MSG_CHECKING([for default auto-load directory])
 146 AC_ARG_WITH(auto-load-dir,
 147 AS_HELP_STRING([--with-auto-load-dir=PATH],
 148   [directories from which to load auto-loaded scripts @<:@$debugdir:$datadir/auto-load@:>@]),,
 149   [with_auto_load_dir='$debugdir:$datadir/auto-load'])
 150 escape_dir=`echo $with_auto_load_dir | sed 's/[[$]]\(datadir\|debugdir\)\>/\\\\\\\\\\\\&/g'`
 151 AC_DEFINE_DIR(AUTO_LOAD_DIR, escape_dir,
 152               [Directories from which to load auto-loaded scripts.])
 153 AC_MSG_RESULT([$with_auto_load_dir])
 154
 155 AC_MSG_CHECKING([for default auto-load safe-path])
 156 AC_ARG_WITH(auto-load-safe-path,
 157 AS_HELP_STRING([--with-auto-load-safe-path=PATH],
 158   [directories safe to hold auto-loaded files @<:@--with-auto-load-dir@:>@])
 159 AS_HELP_STRING([--without-auto-load-safe-path],
 160                [do not restrict auto-loaded files locations]),
 161     [if test "$with_auto_load_safe_path" = "no"; then
 162      with_auto_load_safe_path="/"
 163      fi],
 164 [with_auto_load_safe_path="$with_auto_load_dir"])
 165 escape_dir=`echo $with_auto_load_safe_path | sed 's/[[$]]\(datadir\|debugdir\)\>/\\\\\\\\\\\\&/g'`
 166 AC_DEFINE_DIR(AUTO_LOAD_SAFE_PATH, escape_dir,
 167               [Directories safe to hold auto-loaded files.])
 168 AC_MSG_RESULT([$with_auto_load_safe_path])
 169
 170 AC_CONFIG_SUBDIRS(testsuite)
 171
 172 # Check whether to support alternative target configurations
 173 AC_ARG_ENABLE(targets,
 174 AS_HELP_STRING([--enable-targets=TARGETS], [alternative target configurations]),
 175 [case "${enableval}" in
 176   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
 177             ;;
 178   no)       enable_targets= ;;
 179   *)        enable_targets=$enableval ;;
 180 esac])
 181
 182 # Check whether to enable 64-bit support on 32-bit hosts
 183 AC_ARG_ENABLE(64-bit-bfd,
 184 AS_HELP_STRING([--enable-64-bit-bfd], [64-bit support (on hosts with narrower word sizes)]),
 185 [case "${enableval}" in
 186   yes)  want64=true  ;;
 187   no)   want64=false ;;
 188   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
 189 esac],[want64=false])dnl
 190
 191 # Provide defaults for some variables set by the per-host and per-target
 192 # configuration.
 193 gdb_host_obs=posix-hdep.o
 194
 195 if test "${target}" = "${host}"; then
 196   gdb_native=yes
 197 else
 198   gdb_native=no
 199 fi
 200
 201 . $srcdir/configure.host
 202
 203 # Add in the common host objects.
 204 . $srcdir/common/common.host
 205 gdb_host_obs="$gdb_host_obs $common_host_obs"
 206
 207 # Accumulate some settings from configure.tgt over all enabled targets
 208
 209 TARGET_OBS=
 210 all_targets=
 211 HAVE_NATIVE_GCORE_TARGET=
 212
 213 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 214 do
 215   if test "$targ_alias" = "all"; then
 216     all_targets=true
 217   else
 218     # Canonicalize the secondary target names.
 219     result=`$ac_config_sub $targ_alias 2>/dev/null`
 220     if test -n "$result"; then
 221         targ=$result
 222     else
 223         targ=$targ_alias
 224     fi
 225
 226     . ${srcdir}/configure.tgt
 227
 228     AS_IF([test -z "${gdb_target_obs}"],
 229       [AC_MSG_ERROR([configuration ${targ} is unsupported.])])
 230
 231     # Target-specific object files
 232     for i in ${gdb_target_obs}; do
 233         case " $TARGET_OBS " in
 234         *" ${i} "*) ;;
 235         *)
 236           TARGET_OBS="$TARGET_OBS ${i}"
 237           ;;
 238         esac
 239     done
 240
 241     # Check whether this target needs 64-bit CORE_ADDR
 242     if test x${want64} = xfalse; then
 243       . ${srcdir}/../bfd/config.bfd
 244     fi
 245
 246     # Check whether this target is native and supports gcore.
 247     if test $gdb_native = yes -a "$targ_alias" = "$target_alias" \
 248        && $gdb_have_gcore; then
 249       HAVE_NATIVE_GCORE_TARGET=1
 250     fi
 251   fi
 252 done
 253
 254 if test x${all_targets} = xtrue; then
 255
 256   # We want all 64-bit targets if we either:
 257   #  - run on a 64-bit host  or
 258   #  - already require 64-bit support for some other target  or
 259   #  - the --enable-64-bit-bfd option was supplied
 260   # Otherwise we only support all 32-bit targets.
 261   #
 262   # NOTE: This test must be in sync with the corresponding
 263   #       tests in BFD!
 264
 265   if test x${want64} = xfalse; then
 266     AC_CHECK_SIZEOF(long)
 267     if test "x${ac_cv_sizeof_long}" = "x8"; then
 268       want64=true
 269     fi
 270   fi
 271   if test x${want64} = xtrue; then
 272     TARGET_OBS='$(ALL_TARGET_OBS) $(ALL_64_TARGET_OBS)'
 273   else
 274     TARGET_OBS='$(ALL_TARGET_OBS)'
 275   fi
 276 fi
 277
 278 AC_SUBST(TARGET_OBS)
 279 AC_SUBST(HAVE_NATIVE_GCORE_TARGET)
 280
 281 # For other settings, only the main target counts.
 282 gdb_sim=
 283 gdb_osabi=
 284 build_gdbserver=
 285 targ=$target; . ${srcdir}/configure.tgt
 286
 287 # Fetch the default architecture and default target vector from BFD.
 288 targ=$target; . $srcdir/../bfd/config.bfd
 289
 290 # We only want the first architecture, so strip off the others if
 291 # there is more than one.
 292 targ_archs=`echo $targ_archs | sed 's/ .*//'`
 293
 294 if test "x$targ_archs" != x; then
 295   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
 296     [Define to BFD's default architecture. ])
 297 fi
 298 if test "x$targ_defvec" != x; then
 299   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
 300     [Define to BFD's default target vector. ])
 301 fi
 302
 303 # The CLI cannot be disabled yet, but may be in the future.
 304
 305 # Enable CLI.
 306 AC_ARG_ENABLE(gdbcli,
 307 AS_HELP_STRING([--disable-gdbcli], [disable command-line interface (CLI)]),
 308   [case $enableval in
 309     yes)
 310       ;;
 311     no)
 312       AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;;
 313     *)
 314       AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;;
 315   esac],
 316   [enable_gdbcli=yes])
 317 if test x"$enable_gdbcli" = xyes; then
 318   if test -d $srcdir/cli; then
 319     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)"
 320     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)"
 321     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)"
 322     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)"
 323   fi
 324 fi
 325
 326 # Enable MI.
 327 AC_ARG_ENABLE(gdbmi,
 328 AS_HELP_STRING([--disable-gdbmi], [disable machine-interface (MI)]),
 329   [case $enableval in
 330     yes | no)
 331       ;;
 332     *)
 333       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 334   esac],
 335   [enable_gdbmi=yes])
 336 if test x"$enable_gdbmi" = xyes; then
 337   if test -d $srcdir/mi; then
 338     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 339     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 340     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 341     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 342   fi
 343 fi
 344
 345 # Enable TUI.
 346 AC_ARG_ENABLE(tui,
 347 AS_HELP_STRING([--enable-tui], [enable full-screen terminal user interface (TUI)]),
 348   [case $enableval in
 349     yes | no | auto)
 350       ;;
 351     *)
 352       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 353   esac],enable_tui=auto)
 354
 355 # Enable gdbtk.
 356 AC_ARG_ENABLE(gdbtk,
 357 AS_HELP_STRING([--enable-gdbtk], [enable gdbtk graphical user interface (GUI)]),
 358   [case $enableval in
 359     yes | no)
 360       ;;
 361     *)
 362       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 363   esac],
 364   [if test -d $srcdir/gdbtk; then
 365     enable_gdbtk=yes
 366   else
 367     enable_gdbtk=no
 368   fi])
 369 # We unconditionally disable gdbtk tests on selected platforms.
 370 case $host_os in
 371   go32* | windows*)
 372     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 373     enable_gdbtk=no ;;
 374 esac
 375
 376 # Libunwind support for ia64.
 377
 378 AC_ARG_WITH(libunwind-ia64,
 379 AS_HELP_STRING([--with-libunwind-ia64],
 380                [use libunwind frame unwinding for ia64 targets]),,
 381             [with_libunwind_ia64=auto])
 382
 383 # Backward compatibility option.
 384 if test "${with_libunwind+set}" = set; then
 385   if test x"$with_libunwind_ia64" != xauto; then
 386     AC_MSG_ERROR(
 387       [option --with-libunwind is deprecated, use --with-libunwind-ia64])
 388   fi
 389   AC_MSG_WARN([option --with-libunwind is deprecated, use --with-libunwind-ia64])
 390   with_libunwind_ia64="$with_libunwind"
 391 fi
 392
 393 case "$with_libunwind_ia64" in
 394   yes | no)
 395     ;;
 396   auto)
 397     AC_CHECK_HEADERS(libunwind-ia64.h)
 398     with_libunwind_ia64=$ac_cv_header_libunwind_ia64_h
 399     ;;
 400   *)
 401     AC_MSG_ERROR(
 402       [bad value $with_libunwind_ia64 for GDB --with-libunwind-ia64 option])
 403     ;;
 404 esac
 405
 406 if test x"$with_libunwind_ia64" = xyes; then
 407   AC_CHECK_HEADERS(libunwind-ia64.h)
 408   if test x"$ac_cv_header_libunwind_ia64_h" != xyes; then
 409     AC_MSG_ERROR([GDB option --with-libunwind-ia64 requires libunwind-ia64.h])
 410   fi
 411   CONFIG_OBS="$CONFIG_OBS ia64-libunwind-tdep.o"
 412   CONFIG_DEPS="$CONFIG_DEPS ia64-libunwind-tdep.o"
 413   CONFIG_SRCS="$CONFIG_SRCS ia64-libunwind-tdep.c"
 414 fi
 415
 416 opt_curses=no
 417 AC_ARG_WITH(curses, AS_HELP_STRING([--with-curses], [use the curses library instead of the termcap library]), opt_curses=$withval)
 418
 419 prefer_curses=no
 420 if test "$opt_curses" = "yes"; then
 421   prefer_curses=yes
 422 fi
 423
 424 # Profiling support.
 425 AC_ARG_ENABLE(profiling,
 426 AS_HELP_STRING([--enable-profiling], [enable profiling of GDB]),
 427   [case $enableval in
 428     yes | no)
 429       ;;
 430     *)
 431       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 432   esac],
 433  [enable_profiling=no])
 434
 435 AC_CHECK_FUNCS(monstartup _mcleanup)
 436 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 437 [AC_TRY_LINK(
 438 [#include <stdlib.h>
 439 extern char _etext;
 440 ],
 441 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 442 if test $ac_cv_var__etext = yes; then
 443   AC_DEFINE(HAVE__ETEXT, 1,
 444             [Define to 1 if your system has the _etext variable. ])
 445 fi
 446 AC_CACHE_CHECK([for etext], ac_cv_var_etext,
 447 [AC_TRY_LINK(
 448 [#include <stdlib.h>
 449 extern char etext;
 450 ],
 451 [free (&etext);], ac_cv_var_etext=yes, ac_cv_var_etext=no)])
 452 if test $ac_cv_var_etext = yes; then
 453   AC_DEFINE(HAVE_ETEXT, 1,
 454             [Define to 1 if your system has the etext variable. ])
 455 fi
 456 if test "$enable_profiling" = yes ; then
 457   if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
 458     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 459   fi
 460   PROFILE_CFLAGS=-pg
 461   OLD_CFLAGS="$CFLAGS"
 462   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 463
 464   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 465     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 466      ac_cv_cc_supports_pg=no)])
 467
 468   if test $ac_cv_cc_supports_pg = no; then
 469     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 470   fi
 471
 472   CFLAGS="$OLD_CFLAGS"
 473 fi
 474
 475 ACX_PKGVERSION([GDB])
 476 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 477 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 478 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 479
 480 # --------------------- #
 481 # Checks for programs.  #
 482 # --------------------- #
 483
 484 AC_PROG_AWK
 485 AC_PROG_INSTALL
 486 AC_PROG_LN_S
 487 AC_PROG_RANLIB
 488 AC_PROG_YACC
 489
 490 AC_CHECK_TOOL(AR, ar)
 491 AC_CHECK_TOOL(DLLTOOL, dlltool)
 492 AC_CHECK_TOOL(WINDRES, windres)
 493
 494 case $host_os in
 495   gnu*)
 496     # Needed for GNU Hurd hosts.
 497     AC_CHECK_TOOL(MIG, mig)
 498     if test x"$MIG" = x; then
 499       AC_MSG_ERROR([MIG not found but required for $host hosts])
 500     fi
 501     ;;
 502 esac
 503
 504 # ---------------------- #
 505 # Checks for libraries.  #
 506 # ---------------------- #
 507
 508 # We might need to link with -lm; most simulators need it.
 509 AC_CHECK_LIB(m, main)
 510
 511 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 512 AC_SEARCH_LIBS(gethostbyname, nsl)
 513
 514 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 515 AC_SEARCH_LIBS(socketpair, socket)
 516
 517 # Link in zlib if we can.  This allows us to read compressed debug sections.
 518 AM_ZLIB
 519
 520 # On FreeBSD we may need libutil for kinfo_getvmmap (used by fbsd-nat.c).
 521 # On GNU/kFreeBSD systems, FreeBSD libutil is renamed to libutil-freebsd.
 522 AC_SEARCH_LIBS(kinfo_getvmmap, util util-freebsd,
 523   [AC_DEFINE(HAVE_KINFO_GETVMMAP, 1,
 524             [Define to 1 if your system has the kinfo_getvmmap function. ])])
 525
 526 AM_ICONV
 527
 528 # GDB may fork/exec the iconv program to get the list of supported character
 529 # sets.  Allow the user to specify where to find it.
 530 # There are several factors affecting the choice of option name:
 531 # - There is already --with-libiconv-prefix but we can't use it, it specifies
 532 #   the build-time location of libiconv files.
 533 # - The program we need to find is iconv, which comes with glibc.  The user
 534 #   doesn't necessarily have libiconv installed.  Therefore naming this
 535 #   --with-libiconv-foo feels wrong.
 536 # - We want the path to be relocatable, but GDB_AC_DEFINE_RELOCATABLE is
 537 #   defined to work on directories not files (though it really doesn't know
 538 #   the difference).
 539 # - Calling this --with-iconv-prefix is perceived to cause too much confusion
 540 #   with --with-libiconv-prefix.
 541 # Putting these together is why the option name is --with-iconv-bin.
 542
 543 AC_ARG_WITH(iconv-bin,
 544 AS_HELP_STRING([--with-iconv-bin=PATH], [specify where to find the iconv program]),
 545 [iconv_bin="${withval}"
 546  AC_DEFINE_UNQUOTED([ICONV_BIN], ["${iconv_bin}"],
 547                     [Path of directory of iconv program.])
 548  GDB_AC_DEFINE_RELOCATABLE(ICONV_BIN, iconv, ${iconv_bin})
 549 ])
 550
 551 # For the TUI, we need enhanced curses functionality.
 552 if test x"$enable_tui" != xno; then
 553   prefer_curses=yes
 554 fi
 555
 556 curses_found=no
 557 if test x"$prefer_curses" = xyes; then
 558   # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
 559   # curses library because the latter might not provide all the
 560   # functionality we need.  However, this leads to problems on systems
 561   # where the linker searches /usr/local/lib, but the compiler doesn't
 562   # search /usr/local/include, if ncurses is installed in /usr/local.  A
 563   # default installation of ncurses on alpha*-dec-osf* will lead to such
 564   # a situation.
 565   AC_SEARCH_LIBS(waddstr, [ncursesw ncurses cursesX curses])
 566
 567   if test "$ac_cv_search_waddstr" != no; then
 568     curses_found=yes
 569   fi
 570 fi
 571
 572 # Check whether we should enable the TUI, but only do so if we really
 573 # can.
 574 if test x"$enable_tui" != xno; then
 575   if test -d $srcdir/tui; then
 576     if test "$curses_found" != no; then
 577       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
 578       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
 579       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
 580       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
 581     else
 582       if test x"$enable_tui" = xyes; then
 583         AC_MSG_ERROR([no enhanced curses library found; disable TUI])
 584       else
 585         AC_MSG_WARN([no enhanced curses library found; disabling TUI])
 586       fi
 587     fi
 588   fi
 589 fi
 590
 591 # Since GDB uses Readline, we need termcap functionality.  In many
 592 # cases this will be provided by the curses library, but some systems
 593 # have a separate termcap library, or no curses library at all.
 594
 595 case $host_os in
 596   cygwin*)
 597     if test -d $srcdir/libtermcap; then
 598       LIBS="../libtermcap/libtermcap.a $LIBS"
 599       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 600     fi ;;
 601   go32* | *djgpp*)
 602     ac_cv_search_tgetent="none required"
 603     ;;
 604 esac
 605
 606 # These are the libraries checked by Readline.
 607 AC_SEARCH_LIBS(tgetent, [termcap tinfo curses ncursesw ncurses])
 608
 609 if test "$ac_cv_search_tgetent" = no; then
 610   CONFIG_OBS="$CONFIG_OBS stub-termcap.o"
 611 fi
 612
 613 AC_ARG_WITH([system-readline],
 614   [AS_HELP_STRING([--with-system-readline],
 615                   [use installed readline library])])
 616
 617 if test "$with_system_readline" = yes; then
 618   READLINE=-lreadline
 619   READLINE_DEPS=
 620   READLINE_CFLAGS=
 621   READLINE_TEXI_INCFLAG=
 622 else
 623   READLINE='$(READLINE_DIR)/libreadline.a'
 624   READLINE_DEPS='$(READLINE)'
 625   READLINE_CFLAGS='-I$(READLINE_SRC)/..'
 626   READLINE_TEXI_INCFLAG='-I $(READLINE_DIR)'
 627 fi
 628 AC_SUBST(READLINE)
 629 AC_SUBST(READLINE_DEPS)
 630 AC_SUBST(READLINE_CFLAGS)
 631 AC_SUBST(READLINE_TEXI_INCFLAG)
 632
 633 # Generate jit-reader.h
 634
 635 # This is typedeffed to GDB_CORE_ADDR in jit-reader.h
 636 TARGET_PTR=
 637
 638 AC_CHECK_SIZEOF(unsigned long long)
 639 AC_CHECK_SIZEOF(unsigned long)
 640 AC_CHECK_SIZEOF(unsigned __int128)
 641
 642 if test "x${ac_cv_sizeof_unsigned_long}" = "x8"; then
 643   TARGET_PTR="unsigned long"
 644 elif test "x${ac_cv_sizeof_unsigned_long_long}" = "x8"; then
 645   TARGET_PTR="unsigned long long"
 646 elif test "x${ac_cv_sizeof_unsigned___int128}" = "x16"; then
 647   TARGET_PTR="unsigned __int128"
 648 else
 649   TARGET_PTR="unsigned long"
 650 fi
 651
 652 AC_SUBST(TARGET_PTR)
 653 AC_CONFIG_FILES([jit-reader.h:jit-reader.in])
 654
 655 AC_SEARCH_LIBS(dlopen, dl)
 656
 657 GDB_AC_WITH_DIR([JIT_READER_DIR], [jit-reader-dir],
 658                 [directory to load the JIT readers from],
 659                 [${libdir}/gdb])
 660
 661 AC_ARG_WITH(expat,
 662   AS_HELP_STRING([--with-expat], [include expat support (auto/yes/no)]),
 663   [], [with_expat=auto])
 664 AC_MSG_CHECKING([whether to use expat])
 665 AC_MSG_RESULT([$with_expat])
 666
 667 if test "${with_expat}" = no; then
 668   AC_MSG_WARN([expat support disabled; some features may be unavailable.])
 669   HAVE_LIBEXPAT=no
 670 else
 671   AC_LIB_HAVE_LINKFLAGS([expat], [], [#include "expat.h"],
 672                         [XML_Parser p = XML_ParserCreate (0);])
 673   if test "$HAVE_LIBEXPAT" != yes; then
 674     if test "$with_expat" = yes; then
 675       AC_MSG_ERROR([expat is missing or unusable])
 676     else
 677       AC_MSG_WARN([expat is missing or unusable; some features may be unavailable.])
 678     fi
 679   else
 680     save_LIBS=$LIBS
 681     LIBS="$LIBS $LIBEXPAT"
 682     AC_CHECK_FUNCS(XML_StopParser)
 683     LIBS=$save_LIBS
 684   fi
 685 fi
 686
 687 AC_ARG_WITH(mpfr,
 688   AS_HELP_STRING([--with-mpfr], [include MPFR support (auto/yes/no)]),
 689   [], [with_mpfr=auto])
 690 AC_MSG_CHECKING([whether to use MPFR])
 691 AC_MSG_RESULT([$with_mpfr])
 692
 693 if test "${with_mpfr}" = no; then
 694   AC_MSG_WARN([MPFR support disabled; some features may be unavailable.])
 695   HAVE_LIBMPFR=no
 696 else
 697   AC_LIB_HAVE_LINKFLAGS([mpfr], [], [#include <mpfr.h>],
 698                         [mpfr_exp_t exp; mpfr_t x;
 699                          mpfr_frexp (&exp, x, x, MPFR_RNDN);])
 700   if test "$HAVE_LIBMPFR" != yes; then
 701     if test "$with_mpfr" = yes; then
 702       AC_MSG_ERROR([MPFR is missing or unusable])
 703     else
 704       AC_MSG_WARN([MPFR is missing or unusable; some features may be unavailable.])
 705     fi
 706   fi
 707 fi
 708
 709 # --------------------- #
 710 # Check for libpython.  #
 711 # --------------------- #
 712
 713 dnl Utility to simplify finding libpython.
 714 dnl $1 = pythonX.Y
 715 dnl $2 = the shell variable to assign the result to
 716 dnl      If libpython is found we store $version here.
 717 dnl $3 = additional flags to add to CPPFLAGS
 718 dnl $4 = additional flags to add to LIBS
 719
 720 AC_DEFUN([AC_TRY_LIBPYTHON],
 721 [
 722   version=$1
 723   define([have_libpython_var],$2)
 724   new_CPPFLAGS=$3
 725   new_LIBS=$4
 726   AC_MSG_CHECKING([for ${version}])
 727   save_CPPFLAGS=$CPPFLAGS
 728   save_LIBS=$LIBS
 729   CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
 730   LIBS="$LIBS $new_LIBS"
 731   found_usable_python=no
 732   AC_LINK_IFELSE(AC_LANG_PROGRAM([[#include "Python.h"]],
 733                                  [[Py_Initialize ();]]),
 734                  [have_libpython_var=${version}
 735                   found_usable_python=yes
 736                   PYTHON_CPPFLAGS=$new_CPPFLAGS
 737                   PYTHON_LIBS=$new_LIBS])
 738   CPPFLAGS=$save_CPPFLAGS
 739   LIBS=$save_LIBS
 740   AC_MSG_RESULT([${found_usable_python}])
 741 ])
 742
 743 dnl There are several different values for --with-python:
 744 dnl
 745 dnl no -   Don't include python support.
 746 dnl yes -  Include python support, error if it's missing.
 747 dnl        If we find python in $PATH, use it to fetch configure options,
 748 dnl        otherwise assume the compiler can find it with no help from us.
 749 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 750 dnl auto - Same as "yes", but if python is missing from the system,
 751 dnl        fall back to "no".
 752 dnl /path/to/python/exec-prefix -
 753 dnl        Use the python located in this directory.
 754 dnl        If /path/to/python/exec-prefix/bin/python exists, use it to find
 755 dnl        the compilation parameters.  Otherwise use
 756 dnl        -I/path/to/python/exec-prefix/include,
 757 dnl        -L/path/to/python/exec-prefix/lib.
 758 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 759 dnl        NOTE: This case is historical.  It is what was done for 7.0/7.1
 760 dnl        but is deprecated.
 761 dnl /path/to/python/executable -
 762 dnl        Run python-config.py with this version of python to fetch the
 763 dnl        compilation parameters.
 764 dnl        NOTE: This needn't be the real python executable.
 765 dnl        In a cross-compilation scenario (build != host), this could be
 766 dnl        a shell script that provides what python-config.py provides for
 767 dnl        --ldflags, --includes, --exec-prefix.
 768 dnl python-executable -
 769 dnl        Find python-executable in $PATH, and then handle the same as
 770 dnl        /path/to/python/executable.
 771 dnl
 772 dnl If a python program is specified, it is used to run python-config.py and
 773 dnl is passed --ldflags, --includes, --exec-prefix.
 774
 775 AC_ARG_WITH(python,
 776   AS_HELP_STRING([--with-python@<:@=PYTHON@:>@], [include python support (auto/yes/no/<python-program>)]),
 777   [], [with_python=auto])
 778 AC_MSG_CHECKING([whether to use python])
 779 AC_MSG_RESULT([$with_python])
 780
 781 if test "${with_python}" = no; then
 782   AC_MSG_WARN([python support disabled; some features may be unavailable.])
 783   have_libpython=no
 784 else
 785   case "${with_python}" in
 786   [[\\/]]* | ?:[[\\/]]*)
 787     if test -d ${with_python}; then
 788       # Assume the python binary is ${with_python}/bin/python.
 789       python_prog="${with_python}/bin/python"
 790       python_prefix=
 791       # If python does not exit ${with_python}/bin, then try in
 792       # ${with_python}.  On Windows/MinGW, this is where the Python
 793       # executable is.
 794       if test ! -x "${python_prog}"; then
 795         python_prog="${with_python}/python"
 796         python_prefix=
 797       fi
 798       if test ! -x "${python_prog}"; then
 799         # Fall back to gdb 7.0/7.1 behaviour.
 800         python_prog=missing
 801         python_prefix=${with_python}
 802       fi
 803     elif test -x "${with_python}"; then
 804       # While we can't run python compiled for $host (unless host == build),
 805       # the user could write a script that provides the needed information,
 806       # so we support that.
 807       python_prog=${with_python}
 808       python_prefix=
 809     else
 810       AC_ERROR(invalid value for --with-python)
 811     fi
 812     ;;
 813   */*)
 814     # Disallow --with-python=foo/bar.
 815     AC_ERROR(invalid value for --with-python)
 816     ;;
 817   *)
 818     # The user has either specified auto, yes, or the name of the python
 819     # program assumed to be in $PATH.
 820     python_prefix=
 821     case "${with_python}" in
 822     yes | auto)
 823       if test ${build} = ${host}; then
 824         AC_PATH_PROG(python_prog_path, python, missing)
 825         if test "${python_prog_path}" = missing; then
 826           python_prog=missing
 827         else
 828           python_prog=${python_prog_path}
 829         fi
 830       else
 831         # Not much we can do except assume the cross-compiler will find the
 832         # right files.
 833         python_prog=missing
 834       fi
 835       ;;
 836     *)
 837       # While we can't run python compiled for $host (unless host == build),
 838       # the user could write a script that provides the needed information,
 839       # so we support that.
 840       python_prog="${with_python}"
 841       AC_PATH_PROG(python_prog_path, ${python_prog}, missing)
 842       if test "${python_prog_path}" = missing; then
 843         AC_ERROR(unable to find python program ${python_prog})
 844       fi
 845       ;;
 846     esac
 847   esac
 848
 849   if test "${python_prog}" != missing; then
 850     # We have a python program to use, but it may be too old.
 851     # Don't flag an error for --with-python=auto (the default).
 852     have_python_config=yes
 853     python_includes=`${python_prog} ${srcdir}/python/python-config.py --includes`
 854     if test $? != 0; then
 855       have_python_config=failed
 856       if test "${with_python}" != auto; then
 857         AC_ERROR(failure running python-config --includes)
 858       fi
 859     fi
 860     python_libs=`${python_prog} ${srcdir}/python/python-config.py --ldflags`
 861     if test $? != 0; then
 862       have_python_config=failed
 863       if test "${with_python}" != auto; then
 864         AC_ERROR(failure running python-config --ldflags)
 865       fi
 866     fi
 867     python_prefix=`${python_prog} ${srcdir}/python/python-config.py --exec-prefix`
 868     if test $? != 0; then
 869       have_python_config=failed
 870       if test "${with_python}" != auto; then
 871         AC_ERROR(failure running python-config --exec-prefix)
 872       fi
 873     fi
 874   else
 875     # We do not have a python executable we can use to determine where
 876     # to find the Python headers and libs.  We cannot guess the include
 877     # path from the python_prefix either, because that include path
 878     # depends on the Python version.  So, there is nothing much we can
 879     # do except assume that the compiler will be able to find those files.
 880     python_includes=
 881     python_libs=
 882     have_python_config=no
 883   fi
 884
 885   # If we have python-config, only try the configuration it provides.
 886   # Otherwise fallback on the old way of trying different versions of
 887   # python in turn.
 888
 889   have_libpython=no
 890   if test "${have_python_config}" = yes; then
 891     # Determine the Python version by extracting "-lpython<version>"
 892     # part of the python_libs. <version> is usually X.Y with X and Y
 893     # being decimal numbers, but can also be XY (seen on Windows).
 894     #
 895     # The extraction is performed using sed with a regular expression.
 896     # Initially, the regexp used was using the '?' quantifier to make
 897     # the dot in the version number optional.  Unfortunately, this
 898     # does not work with non-GNU versions of sed because, because of
 899     # what looks like a limitation (the '?' quantifier does not work
 900     # with back-references).  We work around this limitation by using
 901     # the '*' quantifier instead.  It means that, in theory, we might
 902     # match unexpected version strings such as "-lpython2..7", but
 903     # this seems unlikely in practice.  And even if that happens,
 904     # an error will be triggered later on, when checking that version
 905     # number.
 906     python_version=`echo " ${python_libs} " \
 907                          | sed -e 's,^.* -l\(python[[0-9]]*[[.]]*[[0-9]]*\).*$,\1,'`
 908     case "${python_version}" in
 909     python*)
 910       AC_TRY_LIBPYTHON(${python_version}, have_libpython,
 911                        ${python_includes}, ${python_libs})
 912       ;;
 913     *)
 914       AC_MSG_ERROR([unable to determine python version from ${python_libs}])
 915       ;;
 916     esac
 917   elif test "${have_python_config}" != failed; then
 918     if test "${have_libpython}" = no; then
 919       AC_TRY_LIBPYTHON(python2.7, have_libpython,
 920                        ${python_includes}, "${python_libs} -lpython2.7")
 921     fi
 922     if test "${have_libpython}" = no; then
 923       AC_TRY_LIBPYTHON(python2.6, have_libpython,
 924                        ${python_includes}, "${python_libs} -lpython2.6")
 925     fi
 926     if test ${have_libpython} = no; then
 927       AC_TRY_LIBPYTHON(python2.5, have_libpython,
 928                        ${python_includes}, "${python_libs} -lpython2.5")
 929     fi
 930     if test ${have_libpython} = no; then
 931       AC_TRY_LIBPYTHON(python2.4, have_libpython,
 932                        ${python_includes}, "${python_libs} -lpython2.4")
 933     fi
 934   fi
 935   if test "${have_libpython}" = python2.7 -o "${have_libpython}" = python27; then
 936     AC_DEFINE(HAVE_LIBPYTHON2_7, 1, [Define if Python 2.7 is being used.])
 937   elif test "${have_libpython}" = python2.6 -o "${have_libpython}" = python26; then
 938     AC_DEFINE(HAVE_LIBPYTHON2_6, 1, [Define if Python 2.6 is being used.])
 939   elif test "${have_libpython}" = python2.5 -o "${have_libpython}" = python25; then
 940     AC_DEFINE(HAVE_LIBPYTHON2_5, 1, [Define if Python 2.5 is being used.])
 941   elif test "${have_libpython}" = python2.4 -o "${have_libpython}" = python24; then
 942     AC_DEFINE(HAVE_LIBPYTHON2_4, 1, [Define if Python 2.4 is being used.])
 943   fi
 944
 945   if test "${have_libpython}" = no; then
 946     case "${with_python}" in
 947     yes)
 948       AC_MSG_ERROR([python is missing or unusable])
 949       ;;
 950     auto)
 951       AC_MSG_WARN([python is missing or unusable; some features may be unavailable.])
 952       ;;
 953     *)
 954       AC_MSG_ERROR([no usable python found at ${with_python}])
 955       ;;
 956     esac
 957   else
 958     if test -n "${python_prefix}"; then
 959       AC_DEFINE_UNQUOTED(WITH_PYTHON_PATH, "${python_prefix}",
 960                          [Define if --with-python provides a path, either directly or via python-config.py --exec-prefix.])
 961       GDB_AC_DEFINE_RELOCATABLE(PYTHON_PATH, python, ${python_prefix})
 962     fi
 963   fi
 964 fi
 965
 966 if test "${have_libpython}" != no; then
 967   AC_DEFINE(HAVE_PYTHON, 1, [Define if Python interpreter is being linked in.])
 968   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_PYTHON_OBS)"
 969   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_PYTHON_DEPS)"
 970   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_PYTHON_SRCS)"
 971   CONFIG_INSTALL="$CONFIG_INSTALL install-python"
 972   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_PYTHON_CFLAGS)"
 973
 974   # Flags needed to compile Python code (taken from python-config --cflags).
 975   # We cannot call python-config directly because it will output whatever was
 976   # used when compiling the Python interpreter itself, including flags which
 977   # would make the python-related objects be compiled differently from the
 978   # rest of GDB (e.g., -O2 and -fPIC).
 979   if test "${GCC}" = yes; then
 980     tentative_python_cflags="-fno-strict-aliasing -DNDEBUG -fwrapv"
 981   fi
 982
 983   if test "x${tentative_python_cflags}" != x; then
 984     AC_MSG_CHECKING(compiler flags for python code)
 985     for flag in ${tentative_python_cflags}; do
 986       # Check that the compiler accepts it
 987       saved_CFLAGS="$CFLAGS"
 988       CFLAGS="$CFLAGS $flag"
 989       AC_TRY_COMPILE([],[],PYTHON_CFLAGS="${PYTHON_CFLAGS} $flag",)
 990       CFLAGS="$saved_CFLAGS"
 991     done
 992     AC_MSG_RESULT(${PYTHON_CFLAGS})
 993   fi
 994
 995   # On x64 Windows, Python's include headers, and pyconfig.h in
 996   # particular, rely on MS_WIN64 macro to detect that it's a 64bit
 997   # version of Windows.  Unfortunately, MS_WIN64 is only defined if
 998   # _MSC_VER, a Microsoft-specific macro, is defined.  So, when
 999   # building on x64 Windows with GCC, we define MS_WIN64 ourselves.
1000   # The issue was reported to the Python community, but still isn't
1001   # solved as of 2012-10-02 (http://bugs.python.org/issue4709).
1002
1003   case "$gdb_host" in
1004     mingw64)
1005            if test "${GCC}" = yes; then
1006              CPPFLAGS="$CPPFLAGS -DMS_WIN64"
1007            fi
1008            ;;
1009   esac
1010
1011   # Note that "python -m threading" cannot be used to check for
1012   # threading support due to a bug in Python 2.7.3
1013   # (http://bugs.python.org/issue15567).
1014   AC_MSG_CHECKING(whether python supports threads)
1015   saved_CPPFLAGS="${CPPFLAGS}"
1016   CPPFLAGS="${PYTHON_CPPFLAGS}"
1017   # Note that the test is reversed so that python_has_threads=yes on
1018   # unexpected failures.
1019   AC_PREPROC_IFELSE(AC_LANG_SOURCE([[
1020 #include <Python.h>
1021 #ifdef WITH_THREAD
1022 # error
1023 #endif
1024   ]]), [python_has_threads=no], [python_has_threads=yes])
1025   AC_MSG_RESULT(${python_has_threads})
1026   CPPFLAGS="${saved_CPPFLAGS}"
1027 else
1028   # Even if Python support is not compiled in, we need to have this file
1029   # included so that the "python" command, et.al., still exists.
1030   CONFIG_OBS="$CONFIG_OBS python/python.o"
1031   CONFIG_SRCS="$CONFIG_SRCS python/python.c"
1032 fi
1033
1034 # Work around Python http://bugs.python.org/issue10112.  See also
1035 # http://bugs.python.org/issue11410, otherwise -Wl,--dynamic-list has
1036 # no effect.  Note that the only test after this that uses Python is
1037 # the -rdynamic/-Wl,--dynamic-list test, and we do want that one to be
1038 # run without -export-dynamic too.
1039 PYTHON_LIBS=`echo $PYTHON_LIBS | sed -e 's/-Xlinker -export-dynamic//'`
1040
1041 AC_SUBST(PYTHON_CFLAGS)
1042 AC_SUBST(PYTHON_CPPFLAGS)
1043 AC_SUBST(PYTHON_LIBS)
1044 AM_CONDITIONAL(HAVE_PYTHON, test "${have_libpython}" != no)
1045
1046 # -------------------- #
1047 # Check for libguile.  #
1048 # -------------------- #
1049
1050 dnl Utility to simplify finding libguile.
1051 dnl $1 = pkg-config-program
1052 dnl $2 = space-separate list of guile versions to try
1053 dnl $3 = yes|no, indicating whether to flag errors or ignore them
1054 dnl $4 = the shell variable to assign the result to
1055 dnl      If libguile is found we store "yes" here.
1056
1057 AC_DEFUN([AC_TRY_LIBGUILE],
1058 [
1059   pkg_config=$1
1060   guile_version_list=$2
1061   flag_errors=$3
1062   define([have_libguile_var],$4)
1063   found_usable_guile=checking
1064   AC_MSG_CHECKING([for usable guile from ${pkg_config}])
1065   for guile_version in ${guile_version_list}; do
1066     ${pkg_config} --exists ${guile_version} 2>/dev/null
1067     if test $? != 0; then
1068       continue
1069     fi
1070     dnl pkg-config says the package exists, so if we get an error now,
1071     dnl that's bad.
1072     new_CPPFLAGS=`${pkg_config} --cflags ${guile_version}`
1073     if test $? != 0; then
1074       AC_MSG_ERROR([failure running pkg-config --cflags ${guile_version}])
1075     fi
1076     new_LIBS=`${pkg_config} --libs ${guile_version}`
1077     if test $? != 0; then
1078       AC_MSG_ERROR([failure running pkg-config --libs ${guile_version}])
1079     fi
1080     dnl If we get this far, great.
1081     found_usable_guile=${guile_version}
1082     break
1083   done
1084   if test "${found_usable_guile}" = "checking"; then
1085     if test "${flag_errors}" = "yes"; then
1086       AC_MSG_ERROR([unable to find usable guile version from "${guile_version_list}"])
1087     else
1088       found_usable_guile=no
1089     fi
1090   fi
1091   dnl One final sanity check.
1092   dnl The user could have said --with-guile=python-2.7.
1093   if test "${found_usable_guile}" != no; then
1094     save_CPPFLAGS=$CPPFLAGS
1095     save_LIBS=$LIBS
1096     CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
1097     LIBS="$LIBS $new_LIBS"
1098     AC_LINK_IFELSE(AC_LANG_PROGRAM([[#include "libguile.h"]],
1099                                    [[scm_init_guile ();]]),
1100                    [have_libguile_var=yes
1101                     GUILE_CPPFLAGS=$new_CPPFLAGS
1102                     GUILE_LIBS=$new_LIBS],
1103                    [found_usable_guile=no])
1104     dnl scm_set_automatic_finalization_enabled added in Guile 2.2.
1105     AC_CHECK_FUNC(scm_set_automatic_finalization_enabled,
1106       AC_DEFINE(HAVE_GUILE_MANUAL_FINALIZATION, 1,
1107                 [Define if Guile supports manual finalization.])
1108     )
1109     CPPFLAGS=$save_CPPFLAGS
1110     LIBS=$save_LIBS
1111     if test "${found_usable_guile}" = no; then
1112       if test "${flag_errors}" = yes; then
1113         AC_MSG_FAILURE([linking guile version ${guile_version} test program failed])
1114       fi
1115     fi
1116   fi
1117   AC_MSG_RESULT([${found_usable_guile}])
1118 ])
1119
1120 dnl There are several different values for --with-guile:
1121 dnl
1122 dnl no -   Don't include guile support.
1123 dnl yes -  Include guile support, error if it's missing.
1124 dnl        The pkg-config program must be in $PATH.
1125 dnl auto - Same as "yes", but if guile is missing from the system,
1126 dnl        fall back to "no".
1127 dnl guile-version [guile-version-choice-2 ...] -
1128 dnl        A space-separated list of guile package versions to try.
1129 dnl        These are passed to pkg-config as-is.
1130 dnl        E.g., guile-2.0 or guile-2.2-uninstalled
1131 dnl        This requires making sure PKG_CONFIG_PATH is set appropriately.
1132 dnl /path/to/pkg-config -
1133 dnl        Use this pkg-config program.
1134 dnl        NOTE: This needn't be the "real" pkg-config program.
1135 dnl        It could be a shell script.  It is invoked as:
1136 dnl        pkg-config --exists $version
1137 dnl        pkg-config --cflags $version
1138 dnl        pkg-config --libs $version
1139 dnl        pkg-config --variable guild $version
1140 dnl        The script will be called with $version having each value in
1141 dnl        $try_guile_versions until --exists indicates success.
1142
1143 AC_ARG_WITH(guile,
1144   AS_HELP_STRING([--with-guile@<:@=GUILE@:>@], [include guile support (auto/yes/no/<guile-version>/<pkg-config-program>)]),
1145   [], [with_guile=auto])
1146 AC_MSG_CHECKING([whether to use guile])
1147 AC_MSG_RESULT([$with_guile])
1148
1149 dnl We check guile with pkg-config.
1150 AC_PATH_PROG(pkg_config_prog_path, pkg-config, missing)
1151
1152 try_guile_versions="guile-2.0"
1153 have_libguile=no
1154 case "${with_guile}" in
1155 no)
1156   AC_MSG_WARN([guile support disabled; some features will be unavailable.])
1157   ;;
1158 auto)
1159   if test "${pkg_config_prog_path}" = "missing"; then
1160     AC_MSG_WARN([pkg-config not found, guile support disabled])
1161   else
1162     AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${try_guile_versions}, no, have_libguile)
1163   fi
1164   ;;
1165 yes)
1166   if test "${pkg_config_prog_path}" = "missing"; then
1167     AC_MSG_ERROR([pkg-config not found])
1168   fi
1169   AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${try_guile_versions}, yes, have_libguile)
1170   ;;
1171 [[\\/]]* | ?:[[\\/]]*)
1172   if test -x "${with_guile}"; then
1173     AC_TRY_LIBGUILE(${with_guile}, ${try_guile_versions}, yes, have_libguile)
1174   else
1175     AC_MSG_ERROR([Guile config program not executable: ${with_guile}])
1176   fi
1177   ;;
1178 "" | */*)
1179   # Disallow --with=guile="" and --with-guile=foo/bar.
1180   AC_MSG_ERROR([invalid value for --with-guile])
1181   ;;
1182 *)
1183   # A space separate list of guile versions to try, in order.
1184   if test "${pkg_config_prog_path}" = "missing"; then
1185     AC_MSG_ERROR([pkg-config not found])
1186   fi
1187   AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${with_guile}, yes, have_libguile)
1188   ;;
1189 esac
1190
1191 if test "${have_libguile}" != no; then
1192   dnl Get the name of the 'guild' program.
1193   case "${with_guile}" in
1194   [[\\/]]* | ?:[[\\/]]*)
1195     GDB_GUILE_PROGRAM_NAMES(["${with_guile}"], ["${guile_version}"])
1196     ;;
1197   *)
1198     GDB_GUILE_PROGRAM_NAMES(["${pkg_config_prog_path}"], ["${guile_version}"])
1199     ;;
1200   esac
1201
1202   dnl Make sure guild can handle this host.
1203   GDB_TRY_GUILD([$srcdir/guile/lib/gdb/support.scm])
1204   dnl If not, disable guile support.
1205   if test "$ac_cv_guild_ok" = no; then
1206     have_libguile=no
1207     AC_MSG_WARN(disabling guile support, $GUILD fails compiling for $host)
1208   fi
1209 fi
1210
1211 if test "${have_libguile}" != no; then
1212   AC_DEFINE(HAVE_GUILE, 1, [Define if Guile interpreter is being linked in.])
1213   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_GUILE_OBS)"
1214   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_GUILE_DEPS)"
1215   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_GUILE_SRCS)"
1216   CONFIG_INSTALL="$CONFIG_INSTALL install-guile"
1217   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_GUILE_CFLAGS)"
1218
1219   dnl The 'scm_new_smob' function appeared in Guile 2.0.6.
1220   save_LIBS="$LIBS"
1221   save_CPPFLAGS="$CPPFLAGS"
1222   LIBS="$GUILE_LIBS"
1223   CPPFLAGS="$GUILE_CPPFLAGS"
1224   AC_CHECK_FUNCS([scm_new_smob])
1225   LIBS="$save_LIBS"
1226   CPPFLAGS="$save_CPPFLAGS"
1227 else
1228   # Even if Guile support is not compiled in, we need to have these files
1229   # included.
1230   CONFIG_OBS="$CONFIG_OBS guile/guile.o"
1231   CONFIG_SRCS="$CONFIG_SRCS guile/guile.c"
1232 fi
1233 AC_SUBST(GUILE_CPPFLAGS)
1234 AC_SUBST(GUILE_LIBS)
1235 AM_CONDITIONAL(HAVE_GUILE, test "${have_libguile}" != no)
1236
1237 # --------------------- #
1238 # Check for libmcheck.  #
1239 # --------------------- #
1240
1241 # Enable -lmcheck by default (it provides cheap-enough memory mangling),
1242 # but turn it off if Python is enabled with threads, since -lmcheck is
1243 # not thread safe (http://sourceware.org/bugzilla/show_bug.cgi?id=9939),
1244 # and for releases.
1245 if test \( "${have_libpython}" = "no" -o "${python_has_threads}" = "no" \) \
1246    && $development; then
1247   libmcheck_default=yes
1248 else
1249   libmcheck_default=no
1250 fi
1251 GDB_AC_LIBMCHECK(${libmcheck_default})
1252
1253 if test "$ENABLE_LIBMCHECK" = "yes" \
1254         -a "${have_libpython}" != "no" \
1255         -a "${python_has_threads}" = "yes" ; then
1256   AC_MSG_WARN(--enable-libmcheck may lead to spurious crashes if threads are used in python)
1257 fi
1258
1259 AC_ARG_WITH(intel_pt,
1260   AS_HELP_STRING([--with-intel-pt], [include Intel Processor Trace support (auto/yes/no)]),
1261   [], [with_intel_pt=auto])
1262 AC_MSG_CHECKING([whether to use intel pt])
1263 AC_MSG_RESULT([$with_intel_pt])
1264
1265 if test "${with_intel_pt}" = no; then
1266   AC_MSG_WARN([Intel Processor Trace support disabled; some features may be unavailable.])
1267   HAVE_LIBIPT=no
1268 else
1269   AC_PREPROC_IFELSE(AC_LANG_SOURCE([[
1270 #include <linux/perf_event.h>
1271 #ifndef PERF_ATTR_SIZE_VER5
1272 # error
1273 #endif
1274   ]]), [perf_event=yes], [perf_event=no])
1275   if test "$perf_event" != yes; then
1276     if test "$with_intel_pt" = yes; then
1277       AC_MSG_ERROR([linux/perf_event.h missing or too old])
1278     else
1279       AC_MSG_WARN([linux/perf_event.h missing or too old; some features may be unavailable.])
1280     fi
1281   fi
1282
1283   AC_LIB_HAVE_LINKFLAGS([ipt], [], [#include "intel-pt.h"], [pt_insn_alloc_decoder (0);])
1284   if test "$HAVE_LIBIPT" != yes; then
1285     if test "$with_intel_pt" = yes; then
1286       AC_MSG_ERROR([libipt is missing or unusable])
1287     else
1288       AC_MSG_WARN([libipt is missing or unusable; some features may be unavailable.])
1289     fi
1290   else
1291     save_LIBS=$LIBS
1292     LIBS="$LIBS $LIBIPT"
1293     AC_CHECK_FUNCS(pt_insn_event)
1294     AC_CHECK_MEMBERS([struct pt_insn.enabled, struct pt_insn.resynced], [], [],
1295                      [#include <intel-pt.h>])
1296     LIBS=$save_LIBS
1297   fi
1298 fi
1299
1300 # ------------------------- #
1301 # Checks for header files.  #
1302 # ------------------------- #
1303
1304 AC_HEADER_STDC
1305 # elf_hp.h is for HP/UX 64-bit shared library support.
1306 AC_CHECK_HEADERS([nlist.h machine/reg.h poll.h sys/poll.h proc_service.h \
1307                   thread_db.h \
1308                   sys/file.h sys/filio.h sys/ioctl.h sys/param.h \
1309                   sys/resource.h sys/procfs.h sys/ptrace.h ptrace.h \
1310                   sys/reg.h sys/debugreg.h sys/select.h \
1311                   termios.h elf_hp.h \
1312                   dlfcn.h])
1313 AC_CHECK_HEADERS(sys/user.h, [], [],
1314 [#if HAVE_SYS_PARAM_H
1315 # include <sys/param.h>
1316 #endif
1317 ])
1318
1319 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncursesw/ncurses.h ncurses/ncurses.h ncurses/term.h)
1320 AC_CHECK_HEADERS(term.h, [], [],
1321 [#if HAVE_CURSES_H
1322 # include <curses.h>
1323 #endif
1324 ])
1325
1326 # ------------------------- #
1327 # Checks for declarations.  #
1328 # ------------------------- #
1329
1330 libiberty_INIT
1331
1332 AC_CHECK_DECLS([free, malloc, realloc, snprintf])
1333 AM_LC_MESSAGES
1334
1335 # ----------------------- #
1336 # Checks for structures.  #
1337 # ----------------------- #
1338
1339 AC_CHECK_MEMBERS([struct stat.st_blocks, struct stat.st_blksize])
1340
1341 # ------------------ #
1342 # Checks for types.  #
1343 # ------------------ #
1344
1345 AC_CHECK_TYPES(socklen_t, [], [],
1346 [#include <sys/types.h>
1347 #include <sys/socket.h>
1348 ])
1349
1350 # ------------------------------------- #
1351 # Checks for compiler characteristics.  #
1352 # ------------------------------------- #
1353
1354 AC_C_CONST
1355 AC_C_INLINE
1356 AC_C_BIGENDIAN
1357
1358 # ------------------------------ #
1359 # Checks for library functions.  #
1360 # ------------------------------ #
1361
1362 AC_FUNC_MMAP
1363 AC_FUNC_VFORK
1364 AC_CHECK_FUNCS([getauxval getrusage getuid getgid \
1365                 pipe poll pread pread64 pwrite resize_term \
1366                 sbrk setpgid setpgrp setsid \
1367                 sigaction sigprocmask sigsetmask socketpair \
1368                 ttrace wborder wresize setlocale iconvlist libiconvlist btowc \
1369                 setrlimit getrlimit posix_madvise waitpid \
1370                 ptrace64 sigaltstack mkdtemp setns])
1371 AM_LANGINFO_CODESET
1372 GDB_AC_COMMON
1373
1374 # Check the return and argument types of ptrace.
1375 GDB_AC_PTRACE
1376
1377 dnl AC_FUNC_SETPGRP does not work when cross compiling
1378 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
1379 if test "$cross_compiling" = no; then
1380   AC_FUNC_SETPGRP
1381 else
1382   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
1383     [AC_TRY_COMPILE([
1384 #include <unistd.h>
1385 ], [
1386   if (setpgrp(1,1) == -1)
1387     exit (0);
1388   else
1389     exit (1);
1390 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
1391 if test $ac_cv_func_setpgrp_void = yes; then
1392   AC_DEFINE(SETPGRP_VOID, 1)
1393 fi
1394 fi
1395
1396 # Assume we'll default to using the included libiberty regex.
1397 gdb_use_included_regex=yes
1398
1399 # However, if the system regex is GNU regex, then default to *not*
1400 # using the included regex.
1401 AC_CACHE_CHECK(
1402   [for GNU regex],
1403   [gdb_cv_have_gnu_regex],
1404   [AC_TRY_COMPILE(
1405     [#include <gnu-versions.h>],
1406     [#define REGEX_INTERFACE_VERSION 1
1407 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
1408 # error "Version mismatch"
1409 #endif],
1410     gdb_cv_have_gnu_regex=yes,
1411     gdb_cv_have_gnu_regex=no)])
1412 if test $gdb_cv_have_gnu_regex = yes; then
1413   gdb_use_included_regex=no
1414 fi
1415
1416 AC_ARG_WITH(included-regex,
1417   AS_HELP_STRING([--without-included-regex], [don't use included regex; this is the default on systems with version 2 of the GNU C library (use with caution on other system)]),
1418   gdb_with_regex=$withval,
1419   gdb_with_regex=$gdb_use_included_regex)
1420 if test "$gdb_with_regex" = yes; then
1421   AC_DEFINE(USE_INCLUDED_REGEX, 1,
1422     [Define to 1 if the regex included in libiberty should be used.])
1423 fi
1424
1425 # Check if <sys/proc.h> defines `struct thread' with a td_pcb member.
1426 AC_CHECK_MEMBERS([struct thread.td_pcb], [], [],
1427 [#include <sys/param.h>
1428 #include <sys/proc.h>
1429 ])
1430
1431 # See if <sys/lwp.h> defines `struct lwp`.
1432 AC_CACHE_CHECK([for struct lwp], gdb_cv_struct_lwp,
1433 [AC_TRY_COMPILE([#include <sys/param.h>
1434 #define _KMEMUSER
1435 #include <sys/lwp.h>], [struct lwp l;],
1436 gdb_cv_struct_lwp=yes, gdb_cv_struct_lwp=no)])
1437 if test $gdb_cv_struct_lwp = yes; then
1438   AC_DEFINE(HAVE_STRUCT_LWP, 1,
1439             [Define to 1 if your system has struct lwp.])
1440 fi
1441
1442 # See if <machine/reg.h> degines `struct reg'.
1443 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
1444 [AC_TRY_COMPILE([#include <sys/types.h>
1445 #include <machine/reg.h>], [struct reg r;],
1446 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
1447 if test $gdb_cv_struct_reg = yes; then
1448   AC_DEFINE(HAVE_STRUCT_REG, 1,
1449             [Define to 1 if your system has struct reg in <machine/reg.h>.])
1450 fi
1451
1452 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
1453 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
1454 AC_CHECK_MEMBERS([struct reg.r_fs, struct reg.r_gs], [], [],
1455                  [#include <sys/types.h>
1456 #include <machine/reg.h>])
1457
1458 # See if <sys/user.h> supports the %fs_base and %gs_bas amd64 segment registers.
1459 # Older amd64 Linux's don't have the fs_base and gs_base members of
1460 # `struct user_regs_struct'.
1461 AC_CHECK_MEMBERS([struct user_regs_struct.fs_base, struct user_regs_struct.gs_base],
1462      [], [], [#include <sys/types.h>
1463 #include <sys/user.h>])
1464
1465 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
1466 AC_MSG_CHECKING(for PTRACE_GETREGS)
1467 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
1468 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1469                 [PTRACE_GETREGS;],
1470                 [gdb_cv_have_ptrace_getregs=yes],
1471                 [gdb_cv_have_ptrace_getregs=no])])
1472 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
1473 if test $gdb_cv_have_ptrace_getregs = yes; then
1474   AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
1475   [Define if sys/ptrace.h defines the PTRACE_GETREGS request.])
1476 fi
1477
1478 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
1479 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
1480 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
1481 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1482                 [PTRACE_GETFPXREGS;],
1483                 [gdb_cv_have_ptrace_getfpxregs=yes],
1484                 [gdb_cv_have_ptrace_getfpxregs=no])])
1485 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
1486 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
1487   AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
1488   [Define if sys/ptrace.h defines the PTRACE_GETFPXREGS request.])
1489 fi
1490
1491 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
1492 AC_MSG_CHECKING(for PT_GETDBREGS)
1493 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
1494 [AC_TRY_COMPILE([#include <sys/types.h>
1495 #include <sys/ptrace.h>],
1496                 [PT_GETDBREGS;],
1497                 [gdb_cv_have_pt_getdbregs=yes],
1498                 [gdb_cv_have_pt_getdbregs=no])])
1499 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
1500 if test $gdb_cv_have_pt_getdbregs = yes; then
1501   AC_DEFINE(HAVE_PT_GETDBREGS, 1,
1502   [Define if sys/ptrace.h defines the PT_GETDBREGS request.])
1503 fi
1504
1505 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
1506 AC_MSG_CHECKING(for PT_GETXMMREGS)
1507 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
1508 [AC_TRY_COMPILE([#include <sys/types.h>
1509 #include <sys/ptrace.h>],
1510                 [PT_GETXMMREGS;],
1511                 [gdb_cv_have_pt_getxmmregs=yes],
1512                 [gdb_cv_have_pt_getxmmregs=no])])
1513 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
1514 if test $gdb_cv_have_pt_getxmmregs = yes; then
1515   AC_DEFINE(HAVE_PT_GETXMMREGS, 1,
1516   [Define if sys/ptrace.h defines the PT_GETXMMREGS request.])
1517 fi
1518
1519 # See if <sys/ptrace.h> supports LWP names on FreeBSD
1520 # Older FreeBSD versions don't have the pl_tdname member of
1521 # `struct ptrace_lwpinfo'.
1522 AC_CHECK_MEMBERS([struct ptrace_lwpinfo.pl_tdname], [], [],
1523                  [#include <sys/ptrace.h>])
1524
1525 # See if <sys/ptrace.h> supports syscall fields on FreeBSD.  The
1526 # pl_syscall_code member of `struct ptrace_lwpinfo' was added in
1527 # FreeBSD 10.3.
1528 AC_CHECK_MEMBERS([struct ptrace_lwpinfo.pl_syscall_code], [], [],
1529                  [#include <sys/ptrace.h>])
1530
1531 if test "$ac_cv_header_sys_procfs_h" = yes; then
1532   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
1533   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
1534   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
1535   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
1536   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
1537   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
1538   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
1539
1540   dnl Check for broken prfpregset_t type
1541
1542   dnl For Linux/i386, glibc 2.1.3 was released with a bogus
1543   dnl prfpregset_t type (it's a typedef for the pointer to a struct
1544   dnl instead of the struct itself).  We detect this here, and work
1545   dnl around it in gdb_proc_service.h.
1546
1547   if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
1548     AC_MSG_CHECKING(whether prfpregset_t type is broken)
1549     AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
1550       [AC_TRY_RUN([#include <sys/procfs.h>
1551        int main ()
1552        {
1553          if (sizeof (prfpregset_t) == sizeof (void *))
1554            return 1;
1555          return 0;
1556        }],
1557        gdb_cv_prfpregset_t_broken=no,
1558        gdb_cv_prfpregset_t_broken=yes,
1559        gdb_cv_prfpregset_t_broken=yes)])
1560     AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
1561     if test $gdb_cv_prfpregset_t_broken = yes; then
1562       AC_DEFINE(PRFPREGSET_T_BROKEN, 1,
1563       [Define if the prfpregset_t type is broken.])
1564     fi
1565   fi
1566 fi
1567
1568 # Check if the compiler supports the `long long' type.
1569
1570 AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long,
1571                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1572 [[extern long long foo;]],
1573 [[switch (foo & 2) { case 0: return 1; }]])],
1574                                   gdb_cv_c_long_long=yes,
1575                                   gdb_cv_c_long_long=no)])
1576 if test $gdb_cv_c_long_long != yes; then
1577   # libdecnumber requires long long.
1578   AC_MSG_ERROR([Compiler must support long long for GDB.])
1579 fi
1580
1581 # Check if the compiler and runtime support printing long longs.
1582
1583 AC_CACHE_CHECK([for long long support in printf],
1584                gdb_cv_printf_has_long_long,
1585                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1586 [[char buf[32];
1587   long long l = 0;
1588   l = (l << 16) + 0x0123;
1589   l = (l << 16) + 0x4567;
1590   l = (l << 16) + 0x89ab;
1591   l = (l << 16) + 0xcdef;
1592   sprintf (buf, "0x%016llx", l);
1593   return (strcmp ("0x0123456789abcdef", buf));]])],
1594                               gdb_cv_printf_has_long_long=yes,
1595                               gdb_cv_printf_has_long_long=no,
1596                               gdb_cv_printf_has_long_long=no)])
1597 if test $gdb_cv_printf_has_long_long = yes; then
1598   AC_DEFINE(PRINTF_HAS_LONG_LONG, 1,
1599             [Define to 1 if the "%ll" format works to print long longs.])
1600 fi
1601
1602 # Check if the compiler and runtime support printing decfloats.
1603
1604 AC_CACHE_CHECK([for decfloat support in printf],
1605                gdb_cv_printf_has_decfloat,
1606                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1607 [[char buf[64];
1608   _Decimal32 d32 = 1.2345df;
1609   _Decimal64 d64 = 1.2345dd;
1610   _Decimal128 d128 = 1.2345dl;
1611   sprintf (buf, "Decimal32: %H\nDecimal64: %D\nDecimal128: %DD", d32, d64, d128);
1612   return (strcmp ("Decimal32: 1.2345\nDecimal64: 1.2345\nDecimal128: 1.2345", buf));]])],
1613                               gdb_cv_printf_has_decfloat=yes,
1614                               gdb_cv_printf_has_decfloat=no,
1615                               gdb_cv_printf_has_decfloat=no)])
1616 if test $gdb_cv_printf_has_decfloat = yes; then
1617   AC_DEFINE(PRINTF_HAS_DECFLOAT, 1,
1618             [Define to 1 if the "%H, %D and %DD" formats work to print decfloats.])
1619 fi
1620
1621 # Check if the compiler supports the `long double' type.  We can't use
1622 # AC_C_LONG_DOUBLE because that one does additional checks on the
1623 # constants defined in <float.h> that fail on some systems,
1624 # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6.
1625
1626 AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double,
1627                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])],
1628                                   gdb_cv_c_long_double=yes,
1629                                   gdb_cv_c_long_double=no)])
1630 if test $gdb_cv_c_long_double = yes; then
1631   AC_DEFINE(HAVE_LONG_DOUBLE, 1,
1632            [Define to 1 if the compiler supports long double.])
1633 fi
1634
1635 # Check if the compiler and runtime support printing long doubles.
1636
1637 AC_CACHE_CHECK([for long double support in printf],
1638                gdb_cv_printf_has_long_double,
1639                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1640 [[char buf[16];
1641   long double f = 3.141592653;
1642   sprintf (buf, "%Lg", f);
1643   return (strncmp ("3.14159", buf, 7));]])],
1644                               gdb_cv_printf_has_long_double=yes,
1645                               gdb_cv_printf_has_long_double=no,
1646                               gdb_cv_printf_has_long_double=no)])
1647 if test $gdb_cv_printf_has_long_double = yes; then
1648   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1,
1649             [Define to 1 if the "%Lg" format works to print long doubles.])
1650 fi
1651
1652 # Check if the compiler and runtime support scanning long doubles.
1653
1654 AC_CACHE_CHECK([for long double support in scanf],
1655                gdb_cv_scanf_has_long_double,
1656                [AC_RUN_IFELSE([AC_LANG_PROGRAM(
1657 [[#include <stdio.h>]],
1658 [[char *buf = "3.141592653";
1659   long double f = 0;
1660   sscanf (buf, "%Lg", &f);
1661   return !(f > 3.14159 && f < 3.14160);]])],
1662                               gdb_cv_scanf_has_long_double=yes,
1663                               gdb_cv_scanf_has_long_double=no,
1664                               gdb_cv_scanf_has_long_double=no)])
1665 if test $gdb_cv_scanf_has_long_double = yes; then
1666   AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1,
1667             [Define to 1 if the "%Lg" format works to scan long doubles.])
1668 fi
1669
1670 case ${host_os} in
1671 aix*)
1672   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1673     SAVE_LDFLAGS=$LDFLAGS
1674
1675     case $GCC in
1676     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1677     *) gdb_cv_bigtoc=-bbigtoc ;;
1678     esac
1679
1680     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1681     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1682     LDFLAGS="${SAVE_LDFLAGS}"
1683   ])
1684   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
1685   ;;
1686 esac
1687
1688 AC_MSG_CHECKING(for the dynamic export flag)
1689 dynamic_list=false
1690 if test "${gdb_native}" = yes; then
1691    # The dynamically loaded libthread_db needs access to symbols in the gdb
1692    # executable.  Older GNU ld supports --export-dynamic but --dynamic-list
1693    # may not be supported there.
1694    old_LDFLAGS="$LDFLAGS"
1695    # Older GNU ld supports --export-dynamic but --dynamic-list it does not.
1696    RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
1697    LDFLAGS="$LDFLAGS $RDYNAMIC"
1698    if test "${have_libpython}" = no; then
1699      AC_TRY_LINK([], [], [dynamic_list=true])
1700    else
1701      # Workaround http://bugs.python.org/issue4434 where static
1702      # libpythonX.Y.a would get its symbols required for
1703      # pythonX.Y/lib-dynload/*.so modules hidden by -Wl,--dynamic-list.
1704      # Problem does not happen for the recommended libpythonX.Y.so linkage.
1705
1706      # Note the workaround for Python
1707      # http://bugs.python.org/issue10112 earlier has removed
1708      # -export-dynamic from PYTHON_LIBS.  That's exactly what we want
1709      # here too, as otherwise it'd make this -Wl,--dynamic-list test
1710      # always pass.
1711      old_CFLAGS="$CFLAGS"
1712      CFLAGS="$CFLAGS $PYTHON_CFLAGS"
1713      old_LIBS="$LIBS"
1714      LIBS="$LIBS $PYTHON_LIBS"
1715      old_CPPFLAGS="$CPPFLAGS"
1716      CPPFLAGS="$CPPFLAGS $PYTHON_CPPFLAGS"
1717      AC_RUN_IFELSE(
1718        AC_LANG_PROGRAM(
1719          [#include "Python.h"],
1720          [int err;
1721           Py_Initialize ();
1722           err = PyRun_SimpleString ("import itertools\n");
1723           Py_Finalize ();
1724           return err == 0 ? 0 : 1;]),
1725        [dynamic_list=true], [], [true])
1726      LIBS="$old_LIBS"
1727      CFLAGS="$old_CFLAGS"
1728      CPPFLAGS="$old_CPPFLAGS"
1729    fi
1730    LDFLAGS="$old_LDFLAGS"
1731 fi
1732 if $dynamic_list; then
1733   found="-Wl,--dynamic-list"
1734   RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'
1735 else
1736   found="-rdynamic"
1737   RDYNAMIC="-rdynamic"
1738 fi
1739 AC_SUBST(RDYNAMIC)
1740 AC_MSG_RESULT($found)
1741
1742 dnl For certain native configurations, we need to check whether thread
1743 dnl support can be built in or not.
1744 dnl
1745 dnl Note that we only want this if we are both native (host == target),
1746 dnl and not doing a canadian cross build (build == host).
1747
1748 if test ${build} = ${host} -a ${host} = ${target} ; then
1749    case ${host_os} in
1750    aix*)
1751       AC_MSG_CHECKING(for AiX thread debugging library)
1752       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
1753                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
1754                                    [#ifndef PTHDB_VERSION_3
1755                                     #error
1756                                     #endif],
1757                                    gdb_cv_have_aix_thread_debug=yes,
1758                                    gdb_cv_have_aix_thread_debug=no)])
1759       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1760       if test $gdb_cv_have_aix_thread_debug = yes; then
1761          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1762          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1763          LIBS="$LIBS -lpthdebug"
1764
1765          # Older versions of AIX do not provide the declaration for
1766          # the getthrds function (it appears that it was introduced
1767          # with AIX 6.x).
1768          AC_CHECK_DECLS(getthrds, [], [], [[#include <procinfo.h>]])
1769       fi
1770       ;;
1771    esac
1772    AC_SUBST(CONFIG_LDFLAGS)
1773 fi
1774
1775 dnl See if we have a thread_db header file that has TD_NOTALLOC and
1776 dnl other error codes.
1777 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1778    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
1779                   gdb_cv_thread_db_h_has_td_notalloc,
1780      AC_TRY_COMPILE(
1781        [#include <thread_db.h>],
1782        [int i = TD_NOTALLOC;],
1783        gdb_cv_thread_db_h_has_td_notalloc=yes,
1784        gdb_cv_thread_db_h_has_td_notalloc=no
1785      )
1786    )
1787    AC_CACHE_CHECK([whether <thread_db.h> has TD_VERSION],
1788                   gdb_cv_thread_db_h_has_td_version,
1789      AC_TRY_COMPILE(
1790        [#include <thread_db.h>],
1791        [int i = TD_VERSION;],
1792        gdb_cv_thread_db_h_has_td_version=yes,
1793        gdb_cv_thread_db_h_has_td_version=no
1794      )
1795    )
1796    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTLS],
1797                   gdb_cv_thread_db_h_has_td_notls,
1798      AC_TRY_COMPILE(
1799        [#include <thread_db.h>],
1800        [int i = TD_NOTLS;],
1801        gdb_cv_thread_db_h_has_td_notls=yes,
1802        gdb_cv_thread_db_h_has_td_notls=no
1803      )
1804    )
1805 fi
1806 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1807   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1808             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1809 fi
1810 if test "x$gdb_cv_thread_db_h_has_td_version" = "xyes"; then
1811   AC_DEFINE(THREAD_DB_HAS_TD_VERSION, 1,
1812             [Define if <thread_db.h> has the TD_VERSION error code.])
1813 fi
1814 if test "x$gdb_cv_thread_db_h_has_td_notls" = "xyes"; then
1815   AC_DEFINE(THREAD_DB_HAS_TD_NOTLS, 1,
1816             [Define if <thread_db.h> has the TD_NOTLS error code.])
1817 fi
1818
1819 dnl Check if we can disable the virtual address space randomization.
1820 dnl The functionality of setarch -R.
1821 AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>])
1822 define([PERSONALITY_TEST], [AC_LANG_PROGRAM([#include <sys/personality.h>], [
1823 #      if !HAVE_DECL_ADDR_NO_RANDOMIZE
1824 #       define ADDR_NO_RANDOMIZE 0x0040000
1825 #      endif
1826        /* Test the flag could be set and stays set.  */
1827        personality (personality (0xffffffff) | ADDR_NO_RANDOMIZE);
1828        if (!(personality (personality (0xffffffff)) & ADDR_NO_RANDOMIZE))
1829            return 1])])
1830 AC_RUN_IFELSE([PERSONALITY_TEST],
1831               [have_personality=true],
1832               [have_personality=false],
1833               [AC_LINK_IFELSE([PERSONALITY_TEST],
1834                               [have_personality=true],
1835                               [have_personality=false])])
1836 if $have_personality
1837 then
1838     AC_DEFINE([HAVE_PERSONALITY], 1,
1839               [Define if you support the personality syscall.])
1840 fi
1841
1842 dnl Set the host's .gdbinit filename.
1843 case $host_os in
1844   go32* | *djgpp*)
1845     gdbinit=gdb.ini
1846     ;;
1847   *)
1848     gdbinit=.gdbinit
1849     ;;
1850 esac
1851 AC_DEFINE_UNQUOTED(GDBINIT,"$gdbinit",[The .gdbinit filename.])
1852
1853 dnl Handle optional features that can be enabled.
1854
1855 # Support for --with-sysroot is a copy of GDB_AC_WITH_DIR,
1856 # except that the argument to --with-sysroot is optional.
1857 # --with-sysroot (or --with-sysroot=yes) sets the default sysroot path.
1858 if test "x$with_sysroot" = xyes; then
1859   with_sysroot="${exec_prefix}/${target_alias}/sys-root"
1860 fi
1861 AC_ARG_WITH(sysroot,
1862   AS_HELP_STRING([--with-sysroot@<:@=DIR@:>@],
1863                  [search for usr/lib et al within DIR]),
1864   [TARGET_SYSTEM_ROOT=$withval], [TARGET_SYSTEM_ROOT=])
1865 AC_DEFINE_DIR(TARGET_SYSTEM_ROOT, TARGET_SYSTEM_ROOT,
1866               [search for usr/lib et al within DIR])
1867 AC_SUBST(TARGET_SYSTEM_ROOT)
1868 GDB_AC_DEFINE_RELOCATABLE(TARGET_SYSTEM_ROOT, sysroot, ${ac_define_dir})
1869
1870 GDB_AC_WITH_DIR(SYSTEM_GDBINIT, system-gdbinit,
1871     [automatically load a system-wide gdbinit file],
1872     [])
1873
1874 AM_GDB_WARNINGS
1875
1876 # In the Cygwin environment, we need some additional flags.
1877 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1878 [AC_EGREP_CPP(^lose$, [
1879 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1880 lose
1881 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1882
1883
1884 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1885 SER_HARDWIRE="ser-base.o ser-unix.o ser-pipe.o ser-tcp.o"
1886 case ${host} in
1887   *go32* ) SER_HARDWIRE=ser-go32.o ;;
1888   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
1889   *mingw32*) SER_HARDWIRE="ser-base.o ser-tcp.o ser-mingw.o" ;;
1890 esac
1891 AC_SUBST(SER_HARDWIRE)
1892
1893 # libreadline needs libuser32.a in a cygwin environment
1894 WIN32LIBS=
1895 if test x$gdb_cv_os_cygwin = xyes; then
1896     WIN32LIBS="-luser32"
1897     case "${target}" in
1898         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
1899         ;;
1900     esac
1901 fi
1902
1903 # The ser-tcp.c module requires sockets.
1904 case ${host} in
1905   *mingw32*)
1906     AC_DEFINE(USE_WIN32API, 1,
1907               [Define if we should use the Windows API, instead of the
1908                POSIX API.  On Windows, we use the Windows API when
1909                building for MinGW, but the POSIX API when building
1910                for Cygwin.])
1911     WIN32LIBS="$WIN32LIBS -lws2_32"
1912     ;;
1913 esac
1914 AC_SUBST(WIN32LIBS)
1915
1916 # Add ELF support to GDB, but only if BFD includes ELF support.
1917 GDB_AC_CHECK_BFD([for ELF support in BFD], gdb_cv_var_elf,
1918                  [bfd_get_elf_phdr_upper_bound (NULL)], elf-bfd.h)
1919 if test $gdb_cv_var_elf = yes; then
1920   CONFIG_OBS="$CONFIG_OBS elfread.o stap-probe.o dtrace-probe.o"
1921   AC_DEFINE(HAVE_ELF, 1,
1922             [Define if ELF support should be included.])
1923   # -ldl is provided by bfd/Makfile.am (LIBDL) <PLUGINS>.
1924   if test "$plugins" = "yes"; then
1925     AC_SEARCH_LIBS(dlopen, dl)
1926   fi
1927 fi
1928
1929 # Add macho support to GDB, but only if BFD includes it.
1930 GDB_AC_CHECK_BFD([for Mach-O support in BFD], gdb_cv_var_macho,
1931                  [bfd_mach_o_lookup_command (NULL, 0, NULL)], mach-o.h)
1932 if test $gdb_cv_var_macho = yes; then
1933   CONFIG_OBS="$CONFIG_OBS machoread.o"
1934 fi
1935
1936 # Add any host-specific objects to GDB.
1937 CONFIG_OBS="${CONFIG_OBS} ${gdb_host_obs}"
1938
1939 # If building on ELF, look for lzma support for embedded compressed debug info.
1940 if test $gdb_cv_var_elf = yes; then
1941   AC_ARG_WITH(lzma,
1942     AS_HELP_STRING([--with-lzma], [support lzma compression (auto/yes/no)]),
1943     [], [with_lzma=auto])
1944   AC_MSG_CHECKING([whether to use lzma])
1945   AC_MSG_RESULT([$with_lzma])
1946
1947   if test "${with_lzma}" != no; then
1948     AC_LIB_HAVE_LINKFLAGS([lzma], [], [#include "lzma.h"],
1949                           [lzma_index_iter iter;
1950                            lzma_index_iter_init (&iter, 0);
1951                            lzma_mf_is_supported (LZMA_MF_HC3);])
1952     if test "$HAVE_LIBLZMA" != yes; then
1953       if test "$with_lzma" = yes; then
1954         AC_MSG_ERROR([missing liblzma for --with-lzma])
1955       fi
1956     fi
1957   fi
1958 fi
1959
1960 LIBGUI="../libgui/src/libgui.a"
1961 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
1962 AC_SUBST(LIBGUI)
1963 AC_SUBST(GUI_CFLAGS_X)
1964
1965 WIN32LDAPP=
1966 AC_SUBST(WIN32LIBS)
1967 AC_SUBST(WIN32LDAPP)
1968
1969 case "${host}" in
1970 *-*-cygwin* | *-*-mingw* )
1971     configdir="win"
1972     ;;
1973 *)
1974     configdir="unix"
1975     ;;
1976 esac
1977
1978 GDBTKLIBS=
1979 if test "${enable_gdbtk}" = "yes"; then
1980
1981     # Gdbtk must have an absolute path to srcdir in order to run
1982     # properly when not installed.
1983     here=`pwd`
1984     cd ${srcdir}
1985     GDBTK_SRC_DIR=`pwd`
1986     cd $here
1987
1988     SC_PATH_TCLCONFIG
1989
1990     # If $no_tk is nonempty, then we can't do Tk, and there is no
1991     # point to doing Tcl.
1992     SC_PATH_TKCONFIG
1993
1994     if test -z "${no_tcl}" -a -z "${no_tk}"; then
1995         SC_LOAD_TCLCONFIG
1996
1997         # Check for in-tree tcl
1998         here=`pwd`
1999         cd ${srcdir}/..
2000         topdir=`pwd`
2001         cd ${here}
2002
2003         intree="no"
2004         if test "${TCL_SRC_DIR}" = "${topdir}/tcl"; then
2005           intree="yes"
2006         fi
2007
2008         # Find Tcl private headers
2009         if test x"${intree}" = xno; then
2010           CY_AC_TCL_PRIVATE_HEADERS
2011           TCL_INCLUDE="${TCL_INCLUDE_SPEC} ${TCL_PRIVATE_INCLUDE}"
2012           TCL_LIBRARY="${TCL_LIB_SPEC}"
2013           TCL_DEPS=""
2014         else
2015           # If building tcl in the same src tree, private headers
2016           # are not needed, but we need to be sure to use the right
2017           # headers library
2018           TCL_INCLUDE="-I${TCL_SRC_DIR}/generic"
2019           TCL_LIBRARY="${TCL_BUILD_LIB_SPEC}"
2020           TCL_DEPS="../tcl/${configdir}${TCL_LIB_FILE}"
2021         fi
2022         AC_SUBST(TCL_INCLUDE)
2023         AC_SUBST(TCL_LIBRARY)
2024         AC_SUBST(TCL_DEPS)
2025
2026         SC_LOAD_TKCONFIG
2027
2028         # Check for in-tree Tk
2029         intree="no"
2030         if test "${TK_SRC_DIR}" = "${topdir}/tk"; then
2031           intree="yes"
2032         fi
2033
2034         # Find Tk private headers
2035         if test x"${intree}" = xno; then
2036           CY_AC_TK_PRIVATE_HEADERS
2037           TK_INCLUDE="${TK_INCLUDE_SPEC} ${TK_PRIVATE_INCLUDE}"
2038           TK_LIBRARY=${TK_LIB_SPEC}
2039           TK_DEPS=""
2040         else
2041           TK_INCLUDE="-I${TK_SRC_DIR}/generic"
2042           TK_LIBRARY="${TK_BUILD_LIB_SPEC}"
2043           TK_DEPS="../tk/${configdir}/${TK_LIB_FILE}"
2044         fi
2045         AC_SUBST(TK_INCLUDE)
2046         AC_SUBST(TK_LIBRARY)
2047         AC_SUBST(TK_DEPS)
2048         AC_SUBST(TK_XINCLUDES)
2049
2050         ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
2051
2052         # Include some libraries that Tcl and Tk want.
2053         TCL_LIBS='$(LIBGUI) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
2054         # Yes, the ordering seems wrong here.  But it isn't.
2055         # TK_LIBS is the list of libraries that need to be linked
2056         # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
2057         # were in LIBS then any link tests after this point would
2058         # try to include things like `$(LIBGUI)', which wouldn't work.
2059         GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
2060
2061         CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
2062         CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
2063         CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
2064         CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
2065         CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
2066         CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
2067         CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
2068
2069         if test x$gdb_cv_os_cygwin = xyes; then
2070           WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
2071           WIN32LDAPP="-Wl,--subsystem,console"
2072           CONFIG_OBS="${CONFIG_OBS} gdbres.o"
2073         fi
2074
2075         AC_CONFIG_SUBDIRS(gdbtk)
2076     fi
2077 fi
2078
2079 AC_SUBST(X_CFLAGS)
2080 AC_SUBST(X_LDFLAGS)
2081 AC_SUBST(X_LIBS)
2082 AC_SUBST(GDBTKLIBS)
2083 AC_SUBST(GDBTK_CFLAGS)
2084 AC_SUBST(GDBTK_SRC_DIR)
2085
2086 AC_PATH_X
2087
2088 # Unlike the sim directory, whether a simulator is linked is controlled by
2089 # presence of a gdb_sim definition in the target configure.tgt entry.
2090 # This code just checks for a few cases where we'd like to ignore those
2091 # definitions, even when they're present in the '.mt' file.  These cases
2092 # are when --disable-sim is specified, or if the simulator directory is
2093 # not part of the source tree.
2094 #
2095 AC_ARG_ENABLE(sim,
2096 AS_HELP_STRING([--enable-sim], [link gdb with simulator]),
2097 [echo "enable_sim = $enable_sim";
2098  echo "enableval = ${enableval}";
2099  case "${enableval}" in
2100   yes) ignore_sim=false ;;
2101   no)  ignore_sim=true ;;
2102   *)   ignore_sim=false ;;
2103  esac],
2104 [ignore_sim=false])
2105
2106 if test ! -d "${srcdir}/../sim"; then
2107   ignore_sim=true
2108 fi
2109
2110 SIM=
2111 SIM_OBS=
2112 if test "${ignore_sim}" = "false"; then
2113   if test x"${gdb_sim}" != x ; then
2114     SIM="${gdb_sim}"
2115     SIM_OBS="remote-sim.o"
2116     AC_DEFINE(WITH_SIM, 1, [Define if the simulator is being linked in.])
2117
2118     # Some tdep code should only be compiled in when the ppc sim is
2119     # built.  PR sim/13418.
2120     case $target in
2121       powerpc*-*-*)
2122         AC_DEFINE(WITH_PPC_SIM, 1, [Define if the PPC simulator is being linked in.])
2123         ;;
2124     esac
2125   fi
2126 fi
2127 AC_SUBST(SIM)
2128 AC_SUBST(SIM_OBS)
2129
2130 AC_SUBST(ENABLE_CFLAGS)
2131 AC_SUBST(PROFILE_CFLAGS)
2132
2133 AC_SUBST(CONFIG_OBS)
2134 AC_SUBST(CONFIG_DEPS)
2135 AC_SUBST(CONFIG_SRCS)
2136 AC_SUBST(CONFIG_ALL)
2137 AC_SUBST(CONFIG_CLEAN)
2138 AC_SUBST(CONFIG_INSTALL)
2139 AC_SUBST(CONFIG_UNINSTALL)
2140
2141 # List of host floatformats.
2142 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
2143 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
2144 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
2145
2146 # target_subdir is used by the testsuite to find the target libraries.
2147 target_subdir=
2148 if test "${host}" != "${target}"; then
2149     target_subdir="${target_alias}/"
2150 fi
2151 AC_SUBST(target_subdir)
2152
2153 # Import nat definitions.
2154 nat_makefile_frag=/dev/null
2155 if test "${gdb_native}" = "yes"; then
2156   . ${srcdir}/configure.nat
2157   nativefile=$NAT_FILE
2158 fi
2159
2160 AC_SUBST(NAT_FILE)
2161 AC_SUBST(NATDEPFILES)
2162 AC_SUBST(NAT_CDEPS)
2163 AC_SUBST(LOADLIBES)
2164 AC_SUBST(MH_CFLAGS)
2165 AC_SUBST(XM_CLIBS)
2166 AC_SUBST(NAT_GENERATED_FILES)
2167 AC_SUBST(HAVE_NATIVE_GCORE_HOST)
2168 AC_SUBST_FILE(nat_makefile_frag)
2169
2170 if test x"${gdb_osabi}" != x ; then
2171     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
2172                        [Define to the default OS ABI for this configuration.])
2173 fi
2174
2175 # Enable multi-ice-gdb-server.
2176 AC_ARG_ENABLE(multi-ice,
2177 AS_HELP_STRING([--enable-multi-ice], [build the multi-ice-gdb-server]),
2178   [case $enableval in
2179     yes | no)
2180       ;;
2181     *) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;;
2182   esac])
2183 if test "x$enable_multi_ice" = xyes; then
2184    AC_CONFIG_SUBDIRS(multi-ice)
2185 fi
2186
2187 AC_ARG_ENABLE(gdbserver,
2188 AS_HELP_STRING([--enable-gdbserver],
2189                [automatically build gdbserver (yes/no/auto, default is auto)]),
2190 [case "${enableval}" in
2191   yes| no|auto) ;;
2192   *) AC_MSG_ERROR(bad value ${enableval} for --enable-gdbserver option) ;;
2193 esac],[enable_gdbserver=auto])
2194
2195 # We only build gdbserver automatically in a native configuration, and
2196 # only if the user did not explicitly disable its build.
2197 if test "$gdb_native" = "yes" -a "$enable_gdbserver" != "no"; then
2198   AC_MSG_CHECKING(whether gdbserver is supported on this host)
2199   if test "x$build_gdbserver" = xyes; then
2200     AC_MSG_RESULT(yes)
2201     AC_CONFIG_SUBDIRS(gdbserver)
2202     gdbserver_build_enabled=yes
2203   else
2204     AC_MSG_RESULT(no)
2205   fi
2206 fi
2207
2208 # If the user explicitly request the gdbserver to be built, verify that
2209 # we were in fact able to enable it.
2210 if test "$enable_gdbserver" = "yes" -a "$gdbserver_build_enabled" != "yes"; then
2211   AC_MSG_ERROR(Automatic gdbserver build is not supported for this configuration)
2212 fi
2213
2214 # Check for babeltrace and babeltrace-ctf
2215 AC_ARG_WITH(babeltrace,
2216   AC_HELP_STRING([--with-babeltrace], [include babeltrace support (auto/yes/no)]),
2217   [], [with_babeltrace=auto])
2218 AC_MSG_CHECKING([whether to use babeltrace])
2219 AC_MSG_RESULT([$with_babeltrace])
2220
2221 if test "x$with_babeltrace" = "xno"; then
2222   AC_MSG_WARN([babletrace support disabled; GDB is unable to read CTF data.])
2223 else
2224   # Append -Werror to CFLAGS so that configure can catch the warning
2225   # "assignment from incompatible pointer type", which is related to
2226   # the babeltrace change from 1.0.3 to 1.1.0.  Babeltrace 1.1.0 works
2227   # in GDB, while babeltrace 1.0.3 is broken.
2228   # AC_LIB_HAVE_LINKFLAGS may modify CPPFLAGS in it, so it should be
2229   # safe to save and restore CFLAGS here.
2230   saved_CFLAGS=$CFLAGS
2231   CFLAGS="$CFLAGS -Werror"
2232   AC_LIB_HAVE_LINKFLAGS([babeltrace], [babeltrace-ctf],
2233                         [#include <babeltrace/babeltrace.h>
2234                          #include <babeltrace/ctf/events.h>
2235                          #include <babeltrace/ctf/iterator.h>],
2236                         [struct bt_iter_pos *pos = bt_iter_get_pos (bt_ctf_get_iter (NULL));
2237                         struct bt_ctf_event *event = NULL;
2238                         const struct bt_definition *scope;
2239
2240                         pos->type = BT_SEEK_BEGIN;
2241                         bt_iter_set_pos (bt_ctf_get_iter (NULL), pos);
2242                         scope = bt_ctf_get_top_level_scope (event,
2243                                                            BT_STREAM_EVENT_HEADER);
2244                         bt_ctf_get_uint64 (bt_ctf_get_field (event, scope, "id"));
2245                         ])
2246   CFLAGS=$saved_CFLAGS
2247
2248   if test "$HAVE_LIBBABELTRACE" != yes; then
2249      if test "$with_babeltrace" = yes; then
2250        AC_MSG_ERROR([babeltrace is missing or unusable])
2251      else
2252        AC_MSG_WARN([babeltrace is missing or unusable; GDB is unable to read CTF data.])
2253      fi
2254   fi
2255 fi
2256
2257 # If nativefile (NAT_FILE) is not set in configure.nat, we link to an
2258 # empty version.
2259
2260 files=
2261 links=
2262
2263 rm -f nm.h
2264 if test "${nativefile}" != ""; then
2265     case "${nativefile}" in
2266       nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
2267       * ) GDB_NM_FILE="${nativefile}"
2268     esac
2269     files="${files} ${GDB_NM_FILE}"
2270     links="${links} nm.h"
2271     AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}", [nativefile])
2272 fi
2273 AC_SUBST(GDB_NM_FILE)
2274
2275 dnl Add dependency for xsltproc if building with maintainer-mode enabled.
2276 AC_PATH_PROGS(XSLTPROC, xsltproc, missing)
2277 if test "x$USE_MAINTAINER_MODE" = xyes; then
2278   if test "${XSLTPROC}" = missing; then
2279     AC_ERROR(unable to find xsltproc.  maintainer-mode requires xsltproc.)
2280   fi
2281 fi
2282 AC_SUBST(XSLTPROC)
2283
2284 AC_LINK_FILES($files, $links)
2285
2286 dnl Check for exe extension set on certain hosts (e.g. Win32)
2287 AC_EXEEXT
2288
2289 dnl  Detect the character set used by this host.
2290 dnl  At the moment, we just assume it's UTF-8.
2291 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "UTF-8",
2292           [Define to be a string naming the default host character set.])
2293
2294 if $development; then
2295   AC_DEFINE(GDB_SELF_TEST, 1,
2296             [Define if self-testing features should be enabled])
2297   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_UNITTESTS_OBS) selftest.o selftest-arch.o"
2298   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_UNITTESTS_SRCS) common/selftest.c selftest-arch.c"
2299 fi
2300
2301 GDB_AC_TRANSFORM([gdb], [GDB_TRANSFORM_NAME])
2302 GDB_AC_TRANSFORM([gcore], [GCORE_TRANSFORM_NAME])
2303 AC_CONFIG_FILES([gcore], [chmod +x gcore])
2304 AC_CONFIG_FILES([Makefile gdb-gdb.gdb doc/Makefile data-directory/Makefile],
2305 [
2306 case x$CONFIG_HEADERS in
2307 xconfig.h:config.in)
2308 echo > stamp-h ;;
2309 esac
2310 ])
2311
2312 AC_OUTPUT