gdb/configure.ac

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003,
   3 dnl 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011
   4 dnl Free Software Foundation, Inc.
   5 dnl
   6 dnl This file is part of GDB.
   7 dnl
   8 dnl This program is free software; you can redistribute it and/or modify
   9 dnl it under the terms of the GNU General Public License as published by
  10 dnl the Free Software Foundation; either version 3 of the License, or
  11 dnl (at your option) any later version.
  12 dnl
  13 dnl This program is distributed in the hope that it will be useful,
  14 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 dnl GNU General Public License for more details.
  17 dnl
  18 dnl You should have received a copy of the GNU General Public License
  19 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 dnl Process this file with autoconf to produce a configure script.
  22
  23 AC_PREREQ(2.59)dnl
  24 AC_INIT(main.c)
  25 AC_CONFIG_HEADER(config.h:config.in)
  26 AM_MAINTAINER_MODE
  27
  28 AC_PROG_CC
  29 AC_USE_SYSTEM_EXTENSIONS
  30 gl_EARLY
  31 ACX_LARGEFILE
  32 AM_PROG_CC_STDC
  33
  34 AC_CONFIG_AUX_DIR(..)
  35 AC_CANONICAL_SYSTEM
  36
  37 # Dependency checking.
  38 ZW_CREATE_DEPDIR
  39 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  40
  41 # Check for the 'make' the user wants to use.
  42 AC_CHECK_PROGS(MAKE, make)
  43 MAKE_IS_GNU=
  44 case "`$MAKE --version 2>&1 | sed 1q`" in
  45   *GNU*)
  46     MAKE_IS_GNU=yes
  47     ;;
  48 esac
  49 AM_CONDITIONAL(GMAKE, test "$MAKE_IS_GNU" = yes)
  50 AC_PROG_MAKE_SET
  51
  52 dnl List of object files and targets accumulated by configure.
  53
  54 CONFIG_OBS=
  55 CONFIG_DEPS=
  56 CONFIG_SRCS=
  57 ENABLE_CFLAGS=
  58
  59 CONFIG_ALL=
  60 CONFIG_CLEAN=
  61 CONFIG_INSTALL=
  62 CONFIG_UNINSTALL=
  63
  64 dnl Set up for gettext.
  65 ZW_GNU_GETTEXT_SISTER_DIR
  66
  67 localedir='${datadir}/locale'
  68 AC_SUBST(localedir)
  69
  70 if test x"$USE_NLS" = xyes; then
  71    CONFIG_ALL="$CONFIG_ALL all-po"
  72    CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
  73    CONFIG_INSTALL="$CONFIG_INSTALL install-po"
  74    CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
  75 fi
  76
  77 gl_INIT
  78
  79 # For Makefile dependencies.
  80 GNULIB_STDINT_H=
  81 if test x"$STDINT_H" != x; then
  82   GNULIB_STDINT_H=gnulib/$STDINT_H
  83 fi
  84 AC_SUBST(GNULIB_STDINT_H)
  85
  86 PACKAGE=gdb
  87 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
  88 AC_SUBST(PACKAGE)
  89
  90 # GDB does not use automake, but gnulib does.  This line lets us
  91 # generate its Makefile.in.
  92 AM_INIT_AUTOMAKE(gdb, UNUSED-VERSION, [no-define])
  93
  94 GDB_AC_WITH_DIR(DEBUGDIR, separate-debug-dir,
  95     [look for global separate debug info in this path @<:@LIBDIR/debug@:>@],
  96     [${libdir}/debug])
  97
  98 # GDB's datadir relocation
  99
 100 GDB_AC_WITH_DIR(GDB_DATADIR, gdb-datadir,
 101     [look for global separate data files in this path @<:@DATADIR/gdb@:>@],
 102     [${datadir}/gdb])
 103
 104 AC_ARG_WITH(relocated-sources,
 105 AS_HELP_STRING([--with-relocated-sources=PATH], [automatically relocate this path for source files]),
 106 [reloc_srcdir="${withval}"
 107  AC_DEFINE_DIR(RELOC_SRCDIR, reloc_srcdir,
 108               [Relocated directory for source files. ])
 109 ])
 110
 111 AC_CONFIG_SUBDIRS(testsuite)
 112
 113 # Check whether to support alternative target configurations
 114 AC_ARG_ENABLE(targets,
 115 AS_HELP_STRING([--enable-targets=TARGETS], [alternative target configurations]),
 116 [case "${enableval}" in
 117   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
 118             ;;
 119   no)       enable_targets= ;;
 120   *)        enable_targets=$enableval ;;
 121 esac])
 122
 123 # Check whether to enable 64-bit support on 32-bit hosts
 124 AC_ARG_ENABLE(64-bit-bfd,
 125 AS_HELP_STRING([--enable-64-bit-bfd], [64-bit support (on hosts with narrower word sizes)]),
 126 [case "${enableval}" in
 127   yes)  want64=true  ;;
 128   no)   want64=false ;;
 129   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
 130 esac],[want64=false])dnl
 131
 132 # Provide defaults for some variables set by the per-host and per-target
 133 # configuration.
 134 gdb_host_obs=posix-hdep.o
 135
 136 if test "${target}" = "${host}"; then
 137   gdb_native=yes
 138 else
 139   gdb_native=no
 140 fi
 141
 142 . $srcdir/configure.host
 143
 144 # Accumulate some settings from configure.tgt over all enabled targets
 145
 146 TARGET_OBS=
 147 all_targets=
 148
 149 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 150 do
 151   if test "$targ_alias" = "all"; then
 152     all_targets=true
 153   else
 154     # Canonicalize the secondary target names.
 155     result=`$ac_config_sub $targ_alias 2>/dev/null`
 156     if test -n "$result"; then
 157         targ=$result
 158     else
 159         targ=$targ_alias
 160     fi
 161
 162     . ${srcdir}/configure.tgt
 163
 164     AS_IF([test -z "${gdb_target_obs}"],
 165       [AC_MSG_ERROR([configuration ${targ} is unsupported.])])
 166
 167     # Target-specific object files
 168     for i in ${gdb_target_obs}; do
 169         case " $TARGET_OBS " in
 170         *" ${i} "*) ;;
 171         *)
 172           TARGET_OBS="$TARGET_OBS ${i}"
 173           ;;
 174         esac
 175     done
 176
 177     # Check whether this target needs 64-bit CORE_ADDR
 178     if test x${want64} = xfalse; then
 179       . ${srcdir}/../bfd/config.bfd
 180     fi
 181   fi
 182 done
 183
 184 if test x${all_targets} = xtrue; then
 185
 186   # We want all 64-bit targets if we either:
 187   #  - run on a 64-bit host  or
 188   #  - already require 64-bit support for some other target  or
 189   #  - the --enable-64-bit-bfd option was supplied
 190   # Otherwise we only support all 32-bit targets.
 191   #
 192   # NOTE: This test must be in sync with the corresponding
 193   #       tests in BFD!
 194
 195   if test x${want64} = xfalse; then
 196     AC_CHECK_SIZEOF(long)
 197     if test "x${ac_cv_sizeof_long}" = "x8"; then
 198       want64=true
 199     fi
 200   fi
 201   if test x${want64} = xtrue; then
 202     TARGET_OBS='$(ALL_TARGET_OBS) $(ALL_64_TARGET_OBS)'
 203   else
 204     TARGET_OBS='$(ALL_TARGET_OBS)'
 205   fi
 206 fi
 207
 208 AC_SUBST(TARGET_OBS)
 209
 210 # For other settings, only the main target counts.
 211 gdb_sim=
 212 gdb_osabi=
 213 build_gdbserver=
 214 targ=$target; . ${srcdir}/configure.tgt
 215
 216 # Fetch the default architecture and default target vector from BFD.
 217 targ=$target; . $srcdir/../bfd/config.bfd
 218
 219 # We only want the first architecture, so strip off the others if
 220 # there is more than one.
 221 targ_archs=`echo $targ_archs | sed 's/ .*//'`
 222
 223 if test "x$targ_archs" != x; then
 224   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
 225     [Define to BFD's default architecture. ])
 226 fi
 227 if test "x$targ_defvec" != x; then
 228   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
 229     [Define to BFD's default target vector. ])
 230 fi
 231
 232 # The CLI cannot be disabled yet, but may be in the future.
 233
 234 # Enable CLI.
 235 AC_ARG_ENABLE(gdbcli,
 236 AS_HELP_STRING([--disable-gdbcli], [disable command-line interface (CLI)]),
 237   [case $enableval in
 238     yes)
 239       ;;
 240     no)
 241       AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;;
 242     *)
 243       AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;;
 244   esac],
 245   [enable_gdbcli=yes])
 246 if test x"$enable_gdbcli" = xyes; then
 247   if test -d $srcdir/cli; then
 248     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)"
 249     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)"
 250     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)"
 251     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)"
 252   fi
 253 fi
 254
 255 # Enable MI.
 256 AC_ARG_ENABLE(gdbmi,
 257 AS_HELP_STRING([--disable-gdbmi], [disable machine-interface (MI)]),
 258   [case $enableval in
 259     yes | no)
 260       ;;
 261     *)
 262       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 263   esac],
 264   [enable_gdbmi=yes])
 265 if test x"$enable_gdbmi" = xyes; then
 266   if test -d $srcdir/mi; then
 267     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 268     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 269     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 270     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 271   fi
 272 fi
 273
 274 # Enable TUI.
 275 AC_ARG_ENABLE(tui,
 276 AS_HELP_STRING([--enable-tui], [enable full-screen terminal user interface (TUI)]),
 277   [case $enableval in
 278     yes | no | auto)
 279       ;;
 280     *)
 281       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 282   esac],enable_tui=auto)
 283
 284 # Enable gdbtk.
 285 AC_ARG_ENABLE(gdbtk,
 286 AS_HELP_STRING([--enable-gdbtk], [enable gdbtk graphical user interface (GUI)]),
 287   [case $enableval in
 288     yes | no)
 289       ;;
 290     *)
 291       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 292   esac],
 293   [if test -d $srcdir/gdbtk; then
 294     enable_gdbtk=yes
 295   else
 296     enable_gdbtk=no
 297   fi])
 298 # We unconditionally disable gdbtk tests on selected platforms.
 299 case $host_os in
 300   go32* | windows*)
 301     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 302     enable_gdbtk=no ;;
 303 esac
 304
 305 # Libunwind support.
 306 AC_ARG_WITH(libunwind,
 307 AS_HELP_STRING([--with-libunwind], [use libunwind frame unwinding support]),
 308 [case "${withval}" in
 309   yes)  enable_libunwind=yes ;;
 310   no)   enable_libunwind=no ;;
 311   *)    AC_MSG_ERROR(bad value ${withval} for GDB with-libunwind option) ;;
 312 esac],[
 313   AC_CHECK_HEADERS(libunwind.h libunwind-ia64.h)
 314   if test x"$ac_cv_header_libunwind_h" = xyes -a x"$ac_cv_header_libunwind_ia64_h" = xyes; then
 315     enable_libunwind=yes;
 316   fi
 317 ])
 318
 319 if test x"$enable_libunwind" = xyes; then
 320   AC_CHECK_HEADERS(libunwind.h libunwind-ia64.h)
 321   AC_DEFINE(HAVE_LIBUNWIND, 1, [Define if libunwind library is being used.])
 322   CONFIG_OBS="$CONFIG_OBS libunwind-frame.o"
 323   CONFIG_DEPS="$CONFIG_DEPS libunwind-frame.o"
 324   CONFIG_SRCS="$CONFIG_SRCS libunwind-frame.c"
 325 fi
 326
 327 opt_curses=no
 328 AC_ARG_WITH(curses, AS_HELP_STRING([--with-curses], [use the curses library instead of the termcap library]), opt_curses=$withval)
 329
 330 prefer_curses=no
 331 if test "$opt_curses" = "yes"; then
 332   prefer_curses=yes
 333 fi
 334
 335 # Profiling support.
 336 AC_ARG_ENABLE(profiling,
 337 AS_HELP_STRING([--enable-profiling], [enable profiling of GDB]),
 338   [case $enableval in
 339     yes | no)
 340       ;;
 341     *)
 342       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 343   esac],
 344  [enable_profiling=no])
 345
 346 AC_CHECK_FUNCS(monstartup _mcleanup)
 347 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 348 [AC_TRY_LINK(
 349 [#include <stdlib.h>
 350 extern char _etext;
 351 ],
 352 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 353 if test $ac_cv_var__etext = yes; then
 354   AC_DEFINE(HAVE__ETEXT, 1,
 355             [Define to 1 if your system has the _etext variable. ])
 356 fi
 357 AC_CACHE_CHECK([for etext], ac_cv_var_etext,
 358 [AC_TRY_LINK(
 359 [#include <stdlib.h>
 360 extern char etext;
 361 ],
 362 [free (&etext);], ac_cv_var_etext=yes, ac_cv_var_etext=no)])
 363 if test $ac_cv_var_etext = yes; then
 364   AC_DEFINE(HAVE_ETEXT, 1,
 365             [Define to 1 if your system has the etext variable. ])
 366 fi
 367 if test "$enable_profiling" = yes ; then
 368   if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
 369     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 370   fi
 371   PROFILE_CFLAGS=-pg
 372   OLD_CFLAGS="$CFLAGS"
 373   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 374
 375   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 376     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 377      ac_cv_cc_supports_pg=no)])
 378
 379   if test $ac_cv_cc_supports_pg = no; then
 380     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 381   fi
 382
 383   CFLAGS="$OLD_CFLAGS"
 384 fi
 385
 386 ACX_PKGVERSION([GDB])
 387 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 388 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 389 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 390
 391 # --------------------- #
 392 # Checks for programs.  #
 393 # --------------------- #
 394
 395 AC_PROG_AWK
 396 AC_PROG_INSTALL
 397 AC_PROG_LN_S
 398 AC_PROG_RANLIB
 399 AC_PROG_YACC
 400
 401 AC_CHECK_TOOL(AR, ar)
 402 AC_CHECK_TOOL(DLLTOOL, dlltool)
 403 AC_CHECK_TOOL(WINDRES, windres)
 404
 405 # Needed for GNU/Hurd.
 406 AC_CHECK_TOOL(MIG, mig)
 407
 408 # ---------------------- #
 409 # Checks for libraries.  #
 410 # ---------------------- #
 411
 412 # We might need to link with -lm; most simulators need it.
 413 AC_CHECK_LIB(m, main)
 414
 415 # We need to link with -lw to get `wctype' on Solaris before Solaris
 416 # 2.6.  Solaris 2.6 and beyond have this function in libc, and have a
 417 # libw that some versions of the GNU linker cannot hanle (GNU ld 2.9.1
 418 # is known to have this problem).  Therefore we avoid libw if we can.
 419 AC_CHECK_FUNC(wctype, [],
 420   [AC_CHECK_LIB(w, wctype)])
 421
 422 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 423 AC_SEARCH_LIBS(gethostbyname, nsl)
 424
 425 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 426 AC_SEARCH_LIBS(socketpair, socket)
 427
 428 # Link in zlib if we can.  This allows us to read compressed debug sections.
 429 AM_ZLIB
 430
 431 # On HP/UX we may need libxpdl for dlgetmodinfo (used by solib-pa64.c).
 432 AC_SEARCH_LIBS(dlgetmodinfo, [dl xpdl])
 433
 434 AM_ICONV
 435
 436 # On alpha-osf, it appears that libtermcap and libcurses are not compatible.
 437 # There is a very specific comment in /usr/include/curses.h explaining that
 438 # termcap routines built into libcurses must not be used.
 439 #
 440 # The symptoms we observed so far is GDB unexpectedly changing
 441 # the terminal settings when tgetent is called - this is particularly
 442 # visible as the output is missing carriage returns, and so rapidly
 443 # becomes very hard to read.
 444 #
 445 # The readline configure script has already decided that libtermcap
 446 # was enough for its purposes, and so decided to build readline using
 447 # libtermcap.  Since the TUI mode requires curses, building GDB with
 448 # TUI enabled results in both libraries to be used at the same time,
 449 # which is not allowed.  This basically means that GDB with TUI is
 450 # broken on alpha-osf.
 451
 452 case $host_os in
 453   osf* )
 454     if test x"$enable_tui" = xyes; then
 455       AC_MSG_ERROR([Building GDB with TUI mode is not supported on this host])
 456     fi
 457     if test x"$enable_tui" = xauto; then
 458       enable_tui=no
 459     fi
 460     ;;
 461 esac
 462
 463 # For the TUI, we need enhanced curses functionality.
 464 if test x"$enable_tui" != xno; then
 465   prefer_curses=yes
 466 fi
 467
 468 curses_found=no
 469 if test x"$prefer_curses" = xyes; then
 470   # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
 471   # curses library because the latter might not provide all the
 472   # functionality we need.  However, this leads to problems on systems
 473   # where the linker searches /usr/local/lib, but the compiler doesn't
 474   # search /usr/local/include, if ncurses is installed in /usr/local.  A
 475   # default installation of ncurses on alpha*-dec-osf* will lead to such
 476   # a situation.
 477   AC_SEARCH_LIBS(waddstr, [ncurses cursesX curses])
 478
 479   if test "$ac_cv_search_waddstr" != no; then
 480     curses_found=yes
 481   fi
 482 fi
 483
 484 # Check whether we should enable the TUI, but only do so if we really
 485 # can.
 486 if test x"$enable_tui" != xno; then
 487   if test -d $srcdir/tui; then
 488     if test "$curses_found" != no; then
 489       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
 490       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
 491       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
 492       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
 493       CONFIG_ALL="${CONFIG_ALL} all-tui"
 494       CONFIG_CLEAN="${CONFIG_CLEAN} clean-tui"
 495       CONFIG_INSTALL="${CONFIG_INSTALL} install-tui"
 496       CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-tui"
 497     else
 498       if test x"$enable_tui" = xyes; then
 499         AC_MSG_ERROR([no enhanced curses library found; disable TUI])
 500       else
 501         AC_MSG_WARN([no enhanced curses library found; disabling TUI])
 502       fi
 503     fi
 504   fi
 505 fi
 506
 507 # Since GDB uses Readline, we need termcap functionality.  In many
 508 # cases this will be provided by the curses library, but some systems
 509 # have a seperate termcap library, or no curses library at all.
 510
 511 case $host_os in
 512   cygwin*)
 513     if test -d $srcdir/libtermcap; then
 514       LIBS="../libtermcap/libtermcap.a $LIBS"
 515       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 516     fi ;;
 517   go32* | *djgpp*)
 518     ac_cv_search_tgetent="none required"
 519     ;;
 520   *mingw32*)
 521     ac_cv_search_tgetent="none required"
 522     CONFIG_OBS="$CONFIG_OBS windows-termcap.o"
 523     ;;
 524 esac
 525
 526 # These are the libraries checked by Readline.
 527 AC_SEARCH_LIBS(tgetent, [termcap tinfo curses ncurses])
 528
 529 if test "$ac_cv_search_tgetent" = no; then
 530   AC_MSG_ERROR([no termcap library found])
 531 fi
 532
 533 AC_ARG_WITH([system-readline],
 534   [AS_HELP_STRING([--with-system-readline],
 535                   [use installed readline library])])
 536
 537 if test "$with_system_readline" = yes; then
 538   READLINE=-lreadline
 539   READLINE_DEPS=
 540   READLINE_CFLAGS=
 541   READLINE_TEXI_INCFLAG=
 542
 543   # readline-6.0 started to use the name `_rl_echoing_p'.
 544   # `$(READLINE_DIR)/' of bundled readline would not resolve in configure.
 545
 546   AC_MSG_CHECKING([for readline_echoing_p])
 547   save_LIBS=$LIBS
 548   LIBS="$LIBS $READLINE"
 549   AC_LINK_IFELSE(AC_LANG_PROGRAM(,[[extern int readline_echoing_p;
 550                                     return readline_echoing_p;]]),
 551                  [READLINE_ECHOING_P=yes],
 552                  [READLINE_ECHOING_P=no
 553                   AC_DEFINE([readline_echoing_p], [_rl_echoing_p],
 554                             [readline-6.0 started to use different name.])])
 555   LIBS="$save_LIBS"
 556   AC_MSG_RESULT([$READLINE_ECHOING_P])
 557 else
 558   READLINE='$(READLINE_DIR)/libreadline.a'
 559   READLINE_DEPS='$(READLINE)'
 560   READLINE_CFLAGS='-I$(READLINE_SRC)/..'
 561   READLINE_TEXI_INCFLAG='-I $(READLINE_DIR)'
 562 fi
 563 AC_SUBST(READLINE)
 564 AC_SUBST(READLINE_DEPS)
 565 AC_SUBST(READLINE_CFLAGS)
 566 AC_SUBST(READLINE_TEXI_INCFLAG)
 567
 568 AC_ARG_WITH(expat,
 569   AS_HELP_STRING([--with-expat], [include expat support (auto/yes/no)]),
 570   [], [with_expat=auto])
 571 AC_MSG_CHECKING([whether to use expat])
 572 AC_MSG_RESULT([$with_expat])
 573
 574 if test "${with_expat}" = no; then
 575   AC_MSG_WARN([expat support disabled; some features may be unavailable.])
 576   HAVE_LIBEXPAT=no
 577 else
 578   AC_LIB_HAVE_LINKFLAGS([expat], [], [#include "expat.h"],
 579                         [XML_Parser p = XML_ParserCreate (0);])
 580   if test "$HAVE_LIBEXPAT" != yes; then
 581     if test "$with_expat" = yes; then
 582       AC_MSG_ERROR([expat is missing or unusable])
 583     else
 584       AC_MSG_WARN([expat is missing or unusable; some features may be unavailable.])
 585     fi
 586   else
 587     save_LIBS=$LIBS
 588     LIBS="$LIBS $LIBEXPAT"
 589     AC_CHECK_FUNCS(XML_StopParser)
 590     LIBS=$save_LIBS
 591   fi
 592 fi
 593
 594 dnl Utility to simplify finding libpython.
 595 dnl $1 = pythonX.Y
 596 dnl $2 = the shell variable to assign the result to
 597 dnl      If libpython is found we store $version here.
 598 dnl $3 = additional flags to add to CPPFLAGS
 599 dnl $4 = additional flags to add to LIBS
 600
 601 AC_DEFUN([AC_TRY_LIBPYTHON],
 602 [
 603   version=$1
 604   define([have_libpython_var],$2)
 605   new_CPPFLAGS=$3
 606   new_LIBS=$4
 607   AC_MSG_CHECKING([for ${version}])
 608   save_CPPFLAGS=$CPPFLAGS
 609   save_LIBS=$LIBS
 610   CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
 611   LIBS="$LIBS $new_LIBS"
 612   found_usable_python=no
 613   AC_LINK_IFELSE(AC_LANG_PROGRAM([[#include "Python.h"]],
 614                                  [[Py_Initialize ();]]),
 615                  [have_libpython_var=${version}
 616                   found_usable_python=yes
 617                   PYTHON_CPPFLAGS=$new_CPPFLAGS
 618                   PYTHON_LIBS=$new_LIBS])
 619   CPPFLAGS=$save_CPPFLAGS
 620   LIBS=$save_LIBS
 621   AC_MSG_RESULT([${found_usable_python}])
 622 ])
 623
 624 dnl There are several different values for --with-python:
 625 dnl
 626 dnl no -   Don't include python support.
 627 dnl yes -  Include python support, error if it's missing.
 628 dnl        If we find python in $PATH, use it to fetch configure options,
 629 dnl        otherwise assume the compiler can find it with no help from us.
 630 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 631 dnl auto - Same as "yes", but if python is missing from the system,
 632 dnl        fall back to "no".
 633 dnl /path/to/python/exec-prefix -
 634 dnl        Use the python located in this directory.
 635 dnl        If /path/to/python/exec-prefix/bin/python exists, use it to find
 636 dnl        the compilation parameters.  Otherwise use
 637 dnl        -I/path/to/python/exec-prefix/include,
 638 dnl        -L/path/to/python/exec-prefix/lib.
 639 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 640 dnl        NOTE: This case is historical.  It is what was done for 7.0/7.1
 641 dnl        but is deprecated.
 642 dnl /path/to/python/executable -
 643 dnl        Run python-config.py with this version of python to fetch the
 644 dnl        compilation parameters.
 645 dnl        NOTE: This needn't be the real python executable.
 646 dnl        In a cross-compilation scenario (build != host), this could be
 647 dnl        a shell script that provides what python-config.py provides for
 648 dnl        --ldflags, --includes, --exec-prefix.
 649 dnl python-executable -
 650 dnl        Find python-executable in $PATH, and then handle the same as
 651 dnl        /path/to/python/executable.
 652 dnl
 653 dnl If a python program is specified, it is used to run python-config.py and
 654 dnl is passed --ldflags, --includes, --exec-prefix.
 655
 656 AC_ARG_WITH(python,
 657   AS_HELP_STRING([--with-python@<:@=PYTHON@:>@], [include python support (auto/yes/no/<python-program>)]),
 658   [], [with_python=auto])
 659 AC_MSG_CHECKING([whether to use python])
 660 AC_MSG_RESULT([$with_python])
 661
 662 if test "${with_python}" = no; then
 663   AC_MSG_WARN([python support disabled; some features may be unavailable.])
 664   have_libpython=no
 665 else
 666   case "${with_python}" in
 667   /*)
 668     if test -d ${with_python}; then
 669       # Assume the python binary is ${with_python}/bin/python.
 670       python_prog="${with_python}/bin/python"
 671       python_prefix=
 672       # If python does not exit ${with_python}/bin, then try in
 673       # ${with_python}.  On Windows/MinGW, this is where the Python
 674       # executable is.
 675       if test ! -x "${python_prog}"; then
 676         python_prog="${with_python}/python"
 677         python_prefix=
 678       fi
 679       if test ! -x "${python_prog}"; then
 680         # Fall back to gdb 7.0/7.1 behaviour.
 681         python_prog=missing
 682         python_prefix=${with_python}
 683       fi
 684     elif test -x "${with_python}"; then
 685       # While we can't run python compiled for $host (unless host == build),
 686       # the user could write a script that provides the needed information,
 687       # so we support that.
 688       python_prog=${with_python}
 689       python_prefix=
 690     else
 691       AC_ERROR(invalid value for --with-python)
 692     fi
 693     ;;
 694   */*)
 695     # Disallow --with-python=foo/bar.
 696     AC_ERROR(invalid value for --with-python)
 697     ;;
 698   *)
 699     # The user has either specified auto, yes, or the name of the python
 700     # program assumed to be in $PATH.
 701     python_prefix=
 702     case "${with_python}" in
 703     yes | auto)
 704       if test ${build} = ${host}; then
 705         AC_PATH_PROG(python_prog_path, python, missing)
 706         if test "${python_prog_path}" = missing; then
 707           python_prog=missing
 708         else
 709           python_prog=${python_prog_path}
 710         fi
 711       else
 712         # Not much we can do except assume the cross-compiler will find the
 713         # right files.
 714         python_prog=missing
 715       fi
 716       ;;
 717     *)
 718       # While we can't run python compiled for $host (unless host == build),
 719       # the user could write a script that provides the needed information,
 720       # so we support that.
 721       python_prog="${with_python}"
 722       AC_PATH_PROG(python_prog_path, ${python_prog}, missing)
 723       if test "${python_prog_path}" = missing; then
 724         AC_ERROR(unable to find python program ${python_prog})
 725       fi
 726       ;;
 727     esac
 728   esac
 729
 730   if test "${python_prog}" != missing; then
 731     # We have a python program to use, but it may be too old.
 732     # Don't flag an error for --with-python=auto (the default).
 733     have_python_config=yes
 734     python_includes=`${python_prog} ${srcdir}/python/python-config.py --includes`
 735     if test $? != 0; then
 736       have_python_config=failed
 737       if test "${with_python}" != auto; then
 738         AC_ERROR(failure running python-config --includes)
 739       fi
 740     fi
 741     python_libs=`${python_prog} ${srcdir}/python/python-config.py --ldflags`
 742     if test $? != 0; then
 743       have_python_config=failed
 744       if test "${with_python}" != auto; then
 745         AC_ERROR(failure running python-config --ldflags)
 746       fi
 747     fi
 748     python_prefix=`${python_prog} ${srcdir}/python/python-config.py --exec-prefix`
 749     if test $? != 0; then
 750       have_python_config=failed
 751       if test "${with_python}" != auto; then
 752         AC_ERROR(failure running python-config --exec-prefix)
 753       fi
 754     fi
 755   else
 756     # We do not have a python executable we can use to determine where
 757     # to find the Python headers and libs.  We cannot guess the include
 758     # path from the python_prefix either, because that include path
 759     # depends on the Python version.  So, there is nothing much we can
 760     # do except assume that the compiler will be able to find those files.
 761     python_includes=
 762     python_libs=
 763     have_python_config=no
 764   fi
 765
 766   # If we have python-config, only try the configuration it provides.
 767   # Otherwise fallback on the old way of trying different versions of
 768   # python in turn.
 769
 770   have_libpython=no
 771   if test "${have_python_config}" = yes; then
 772     # Determine the Python version by extracting "-lpython<version>"
 773     # part of the python_libs. <version> is usually X.Y with X and Y
 774     # being decimal numbers, but can also be XY (seen on Windows).
 775     #
 776     # The extraction is performed using sed with a regular expression.
 777     # Initially, the regexp used was using the '?' quantifier to make
 778     # the dot in the version number optional.  Unfortunately, this
 779     # does not work with non-GNU versions of sed because, because of
 780     # what looks like a limitation (the '?' quantifier does not work
 781     # with back-references).  We work around this limitation by using
 782     # the '*' quantifier instead.  It means that, in theory, we might
 783     # match unexpected version strings such as "-lpython2..7", but
 784     # this seems unlikely in practice.  And even if that happens,
 785     # an error will be triggered later on, when checking that version
 786     # number.
 787     python_version=`echo " ${python_libs} " \
 788                          | sed -e 's,^.* -l\(python[[0-9]]*[[.]]*[[0-9]]*\).*$,\1,'`
 789     case "${python_version}" in
 790     python*)
 791       AC_TRY_LIBPYTHON(${python_version}, have_libpython,
 792                        ${python_includes}, ${python_libs})
 793       ;;
 794     *)
 795       AC_MSG_ERROR([unable to determine python version from ${python_libs}])
 796       ;;
 797     esac
 798   elif test "${have_python_config}" != failed; then
 799     if test "${have_libpython}" = no; then
 800       AC_TRY_LIBPYTHON(python2.7, have_libpython,
 801                        ${python_includes}, "${python_libs} -lpython2.7")
 802     fi
 803     if test "${have_libpython}" = no; then
 804       AC_TRY_LIBPYTHON(python2.6, have_libpython,
 805                        ${python_includes}, "${python_libs} -lpython2.6")
 806     fi
 807     if test ${have_libpython} = no; then
 808       AC_TRY_LIBPYTHON(python2.5, have_libpython,
 809                        ${python_includes}, "${python_libs} -lpython2.5")
 810     fi
 811     if test ${have_libpython} = no; then
 812       AC_TRY_LIBPYTHON(python2.4, have_libpython,
 813                        ${python_includes}, "${python_libs} -lpython2.4")
 814     fi
 815   fi
 816   if test "${have_libpython}" = python2.7 -o "${have_libpython}" = python27; then
 817     AC_DEFINE(HAVE_LIBPYTHON2_7, 1, [Define if Python 2.7 is being used.])
 818   elif test "${have_libpython}" = python2.6 -o "${have_libpython}" = python26; then
 819     AC_DEFINE(HAVE_LIBPYTHON2_6, 1, [Define if Python 2.6 is being used.])
 820   elif test "${have_libpython}" = python2.5 -o "${have_libpython}" = python25; then
 821     AC_DEFINE(HAVE_LIBPYTHON2_5, 1, [Define if Python 2.5 is being used.])
 822   elif test "${have_libpython}" = python2.4 -o "${have_libpython}" = python24; then
 823     AC_DEFINE(HAVE_LIBPYTHON2_4, 1, [Define if Python 2.4 is being used.])
 824   fi
 825
 826   if test "${have_libpython}" = no; then
 827     case "${with_python}" in
 828     yes)
 829       AC_MSG_ERROR([python is missing or unusable])
 830       ;;
 831     auto)
 832       AC_MSG_WARN([python is missing or unusable; some features may be unavailable.])
 833       ;;
 834     *)
 835       AC_MSG_ERROR([no usable python found at ${with_python}])
 836       ;;
 837     esac
 838   else
 839     if test -n "${python_prefix}"; then
 840       AC_DEFINE_UNQUOTED(WITH_PYTHON_PATH, "${python_prefix}",
 841                          [Define if --with-python provides a path, either directly or via python-config.py --exec-prefix.])
 842       GDB_AC_DEFINE_RELOCATABLE(PYTHON_PATH, python, ${python_prefix})
 843     fi
 844   fi
 845 fi
 846
 847 if test "${have_libpython}" != no; then
 848   AC_DEFINE(HAVE_PYTHON, 1, [Define if Python interpreter is being linked in.])
 849   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_PYTHON_OBS)"
 850   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_PYTHON_DEPS)"
 851   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_PYTHON_SRCS)"
 852   CONFIG_INSTALL="$CONFIG_INSTALL install-python"
 853   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_PYTHON_CFLAGS)"
 854
 855   # Flags needed to compile Python code (taken from python-config --cflags).
 856   # We cannot call python-config directly because it will output whatever was
 857   # used when compiling the Python interpreter itself, including flags which
 858   # would make the python-related objects be compiled differently from the
 859   # rest of GDB (e.g., -O2 and -fPIC).
 860   if test "${GCC}" = yes; then
 861     tentative_python_cflags="-fno-strict-aliasing -DNDEBUG -fwrapv"
 862   fi
 863
 864   if test "x${tentative_python_cflags}" != x; then
 865     AC_MSG_CHECKING(compiler flags for python code)
 866     for flag in ${tentative_python_cflags}; do
 867       # Check that the compiler accepts it
 868       saved_CFLAGS="$CFLAGS"
 869       CFLAGS="$CFLAGS $flag"
 870       AC_TRY_COMPILE([],[],PYTHON_CFLAGS="${PYTHON_CFLAGS} $flag",)
 871       CFLAGS="$saved_CFLAGS"
 872     done
 873     AC_MSG_RESULT(${PYTHON_CFLAGS})
 874   fi
 875
 876   # On IRIX, type siginfo is not defined.  Instead, sys/siginfo.h provides:
 877   #    #if _SGIAPI
 878   #    #define siginfo __siginfo
 879   #    #endif
 880   # The problem is that including Python causes some XOPEN macros to be
 881   # unilaterally defined, and that in turn causes _SGIAPI to evaluate
 882   # to false.  So, we work around this issue by defining siginfo ourself
 883   # though the command-line.
 884   case "$gdb_host" in
 885     irix*) if test "${GCC}" = yes; then
 886              CPPFLAGS="$CPPFLAGS -Dsiginfo=__siginfo"
 887            fi
 888            ;;
 889   esac
 890 else
 891   # Even if Python support is not compiled in, we need to have these files
 892   # included.
 893   CONFIG_OBS="$CONFIG_OBS python.o py-value.o py-prettyprint.o py-auto-load.o"
 894   CONFIG_SRCS="$CONFIG_SRCS python/python.c python/py-value.c \
 895         python/py-prettyprint.c python/py-auto-load.c"
 896 fi
 897 AC_SUBST(PYTHON_CFLAGS)
 898 AC_SUBST(PYTHON_CPPFLAGS)
 899 AC_SUBST(PYTHON_LIBS)
 900
 901 # ------------------------- #
 902 # Checks for header files.  #
 903 # ------------------------- #
 904
 905 AC_HEADER_DIRENT
 906 AC_HEADER_STAT
 907 AC_HEADER_STDC
 908 # elf_hp.h is for HP/UX 64-bit shared library support.
 909 # FIXME: kettenis/20030102: In most cases we include these (ctype.h, time.h)
 910 # unconditionally, so what's the point in checking these?
 911 AC_CHECK_HEADERS([nlist.h machine/reg.h poll.h sys/poll.h proc_service.h \
 912                   thread_db.h gnu/libc-version.h signal.h stddef.h \
 913                   stdlib.h string.h memory.h strings.h sys/fault.h \
 914                   sys/file.h sys/filio.h sys/ioctl.h sys/param.h \
 915                   sys/resource.h sys/procfs.h sys/ptrace.h ptrace.h \
 916                   sys/reg.h sys/debugreg.h sys/select.h sys/syscall.h \
 917                   sys/types.h sys/wait.h wait.h termios.h termio.h \
 918                   sgtty.h unistd.h elf_hp.h ctype.h time.h locale.h])
 919 AC_CHECK_HEADERS(link.h, [], [],
 920 [#if HAVE_SYS_TYPES_H
 921 # include <sys/types.h>
 922 #endif
 923 #if HAVE_NLIST_H
 924 # include <nlist.h>
 925 #endif
 926 ])
 927 AC_CHECK_HEADERS(sys/proc.h, [], [],
 928 [#if HAVE_SYS_PARAM_H
 929 # include <sys/param.h>
 930 #endif
 931 ])
 932 AC_CHECK_HEADERS(sys/user.h, [], [],
 933 [#if HAVE_SYS_PARAM_H
 934 # include <sys/param.h>
 935 #endif
 936 ])
 937
 938 # On Solaris 2.[789], we need to define _MSE_INT_H to avoid a clash
 939 # between <widec.h> and <wchar.h> that would cause AC_CHECK_HEADERS to
 940 # think that we don't have <curses.h> if we're using GCC.
 941 case $host_os in
 942   solaris2.[[789]])
 943     if test "$GCC" = yes; then
 944       AC_DEFINE(_MSE_INT_H, 1,
 945         [Define to 1 to avoid a clash between <widec.h> and <wchar.h> on
 946    Solaris 2.[789] when using GCC. ])
 947     fi ;;
 948 esac
 949 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncurses/ncurses.h ncurses/term.h)
 950 AC_CHECK_HEADERS(term.h, [], [],
 951 [#if HAVE_CURSES_H
 952 # include <curses.h>
 953 #endif
 954 ])
 955
 956 # ------------------------- #
 957 # Checks for declarations.  #
 958 # ------------------------- #
 959
 960 AC_CHECK_DECLS([free, malloc, realloc, strerror, strstr, getopt,
 961                 snprintf, vsnprintf])
 962 AM_LC_MESSAGES
 963
 964 # ----------------------- #
 965 # Checks for structures.  #
 966 # ----------------------- #
 967
 968 AC_CHECK_MEMBERS([struct stat.st_blocks, struct stat.st_blksize])
 969
 970 # ------------------ #
 971 # Checks for types.  #
 972 # ------------------ #
 973
 974 AC_TYPE_SIGNAL
 975 AC_CHECK_TYPES(socklen_t, [], [],
 976 [#include <sys/types.h>
 977 #include <sys/socket.h>
 978 ])
 979
 980 # ------------------------------------- #
 981 # Checks for compiler characteristics.  #
 982 # ------------------------------------- #
 983
 984 AC_C_CONST
 985 AC_C_INLINE
 986 AC_C_BIGENDIAN
 987
 988 # ------------------------------ #
 989 # Checks for library functions.  #
 990 # ------------------------------ #
 991
 992 AC_FUNC_ALLOCA
 993 AC_FUNC_MMAP
 994 AC_FUNC_VFORK
 995 AC_CHECK_FUNCS([canonicalize_file_name realpath getrusage getuid \
 996                 getgid pipe poll pread64 resize_term sbrk setpgid setpgrp setsid \
 997                 sigaction sigprocmask sigsetmask socketpair syscall \
 998                 ttrace wborder wresize setlocale iconvlist libiconvlist btowc \
 999                 setrlimit getrlimit posix_madvise waitpid])
1000 AM_LANGINFO_CODESET
1001
1002 # Check the return and argument types of ptrace.  No canned test for
1003 # this, so roll our own.
1004 gdb_ptrace_headers='
1005 #if HAVE_SYS_TYPES_H
1006 # include <sys/types.h>
1007 #endif
1008 #if HAVE_SYS_PTRACE_H
1009 # include <sys/ptrace.h>
1010 #endif
1011 #if HAVE_UNISTD_H
1012 # include <unistd.h>
1013 #endif
1014 '
1015 # There is no point in checking if we don't have a prototype.
1016 AC_CHECK_DECLS(ptrace, [], [
1017   : ${gdb_cv_func_ptrace_ret='int'}
1018   : ${gdb_cv_func_ptrace_args='int,int,long,long'}
1019 ], $gdb_ptrace_headers)
1020 # Check return type.  Varargs (used on GNU/Linux) conflict with the
1021 # empty argument list, so check for that explicitly.
1022 AC_CACHE_CHECK([return type of ptrace], gdb_cv_func_ptrace_ret,
1023   AC_TRY_COMPILE($gdb_ptrace_headers,
1024     [extern long ptrace (enum __ptrace_request, ...);],
1025     gdb_cv_func_ptrace_ret='long',
1026     AC_TRY_COMPILE($gdb_ptrace_headers,
1027       [extern int ptrace ();],
1028       gdb_cv_func_ptrace_ret='int',
1029       gdb_cv_func_ptrace_ret='long')))
1030 AC_DEFINE_UNQUOTED(PTRACE_TYPE_RET, $gdb_cv_func_ptrace_ret,
1031   [Define as the return type of ptrace.])
1032 # Check argument types.
1033 AC_CACHE_CHECK([types of arguments for ptrace], gdb_cv_func_ptrace_args, [
1034   AC_TRY_COMPILE($gdb_ptrace_headers,
1035     [extern long ptrace (enum __ptrace_request, ...);],
1036     [gdb_cv_func_ptrace_args='int,int,long,long'],[
1037 for gdb_arg1 in 'int' 'long'; do
1038  for gdb_arg2 in 'pid_t' 'int' 'long'; do
1039   for gdb_arg3 in 'int *' 'caddr_t' 'int' 'long' 'void *'; do
1040    for gdb_arg4 in 'int' 'long'; do
1041      AC_TRY_COMPILE($gdb_ptrace_headers, [
1042 extern $gdb_cv_func_ptrace_ret
1043   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4);
1044 ], [gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4";
1045     break 4;])
1046     for gdb_arg5 in 'int *' 'int' 'long'; do
1047      AC_TRY_COMPILE($gdb_ptrace_headers, [
1048 extern $gdb_cv_func_ptrace_ret
1049   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4, $gdb_arg5);
1050 ], [
1051 gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4,$gdb_arg5";
1052     break 5;])
1053     done
1054    done
1055   done
1056  done
1057 done
1058 # Provide a safe default value.
1059 : ${gdb_cv_func_ptrace_args='int,int,long,long'}
1060 ])])
1061 ac_save_IFS=$IFS; IFS=','
1062 set dummy `echo "$gdb_cv_func_ptrace_args" | sed 's/\*/\*/g'`
1063 IFS=$ac_save_IFS
1064 shift
1065 AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG3, $[3],
1066   [Define to the type of arg 3 for ptrace.])
1067 if test -n "$[5]"; then
1068   AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG5, $[5],
1069     [Define to the type of arg 5 for ptrace.])
1070 fi
1071
1072 dnl AC_FUNC_SETPGRP does not work when cross compiling
1073 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
1074 if test "$cross_compiling" = no; then
1075   AC_FUNC_SETPGRP
1076 else
1077   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
1078     [AC_TRY_COMPILE([
1079 #include <unistd.h>
1080 ], [
1081   if (setpgrp(1,1) == -1)
1082     exit (0);
1083   else
1084     exit (1);
1085 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
1086 if test $ac_cv_func_setpgrp_void = yes; then
1087   AC_DEFINE(SETPGRP_VOID, 1)
1088 fi
1089 fi
1090
1091 # Check if sigsetjmp is available.  Using AC_CHECK_FUNCS won't do
1092 # since sigsetjmp might only be defined as a macro.
1093 AC_CACHE_CHECK([for sigsetjmp], gdb_cv_func_sigsetjmp,
1094 [AC_TRY_COMPILE([
1095 #include <setjmp.h>
1096 ], [sigjmp_buf env; while (! sigsetjmp (env, 1)) siglongjmp (env, 1);],
1097 gdb_cv_func_sigsetjmp=yes, gdb_cv_func_sigsetjmp=no)])
1098 if test $gdb_cv_func_sigsetjmp = yes; then
1099   AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available. ])
1100 fi
1101
1102 # Assume we'll default to using the included libiberty regex.
1103 gdb_use_included_regex=yes
1104
1105 # However, if the system regex is GNU regex, then default to *not*
1106 # using the included regex.
1107 AC_CACHE_CHECK(
1108   [for GNU regex],
1109   [gdb_cv_have_gnu_regex],
1110   [AC_TRY_COMPILE(
1111     [#include <gnu-versions.h>],
1112     [#define REGEX_INTERFACE_VERSION 1
1113 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
1114 # error "Version mismatch"
1115 #endif],
1116     gdb_cv_have_gnu_regex=yes,
1117     gdb_cv_have_gnu_regex=no)])
1118 if test $gdb_cv_have_gnu_regex = yes; then
1119   gdb_use_included_regex=no
1120 fi
1121
1122 AC_ARG_WITH(included-regex,
1123   AS_HELP_STRING([--without-included-regex], [don't use included regex; this is the default on systems with version 2 of the GNU C library (use with caution on other system)]),
1124   gdb_with_regex=$withval,
1125   gdb_with_regex=$gdb_use_included_regex)
1126 if test "$gdb_with_regex" = yes; then
1127   AC_DEFINE(USE_INCLUDED_REGEX, 1,
1128     [Define to 1 if the regex included in libiberty should be used.])
1129 fi
1130
1131 # Check if <sys/proc.h> defines `struct thread' with a td_pcb member.
1132 AC_CHECK_MEMBERS([struct thread.td_pcb], [], [],
1133 [#include <sys/param.h>
1134 #include <sys/proc.h>
1135 ])
1136
1137 # See if <sys/lwp.h> defines `struct lwp`.
1138 AC_CACHE_CHECK([for struct lwp], gdb_cv_struct_lwp,
1139 [AC_TRY_COMPILE([#include <sys/param.h>
1140 #include <sys/lwp.h>], [struct lwp l;],
1141 gdb_cv_struct_lwp=yes, gdb_cv_struct_lwp=no)])
1142 if test $gdb_cv_struct_lwp = yes; then
1143   AC_DEFINE(HAVE_STRUCT_LWP, 1,
1144             [Define to 1 if your system has struct lwp.])
1145 fi
1146
1147 # See if <machine/reg.h> degines `struct reg'.
1148 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
1149 [AC_TRY_COMPILE([#include <sys/types.h>
1150 #include <machine/reg.h>], [struct reg r;],
1151 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
1152 if test $gdb_cv_struct_reg = yes; then
1153   AC_DEFINE(HAVE_STRUCT_REG, 1,
1154             [Define to 1 if your system has struct reg in <machine/reg.h>.])
1155 fi
1156
1157 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
1158 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
1159 AC_CHECK_MEMBERS([struct reg.r_fs, struct reg.r_gs], [], [],
1160                  [#include <machine/reg.h>])
1161
1162 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
1163 AC_MSG_CHECKING(for PTRACE_GETREGS)
1164 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
1165 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1166                 [PTRACE_GETREGS;],
1167                 [gdb_cv_have_ptrace_getregs=yes],
1168                 [gdb_cv_have_ptrace_getregs=no])])
1169 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
1170 if test $gdb_cv_have_ptrace_getregs = yes; then
1171   AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
1172   [Define if sys/ptrace.h defines the PTRACE_GETREGS request.])
1173 fi
1174
1175 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
1176 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
1177 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
1178 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1179                 [PTRACE_GETFPXREGS;],
1180                 [gdb_cv_have_ptrace_getfpxregs=yes],
1181                 [gdb_cv_have_ptrace_getfpxregs=no])])
1182 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
1183 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
1184   AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
1185   [Define if sys/ptrace.h defines the PTRACE_GETFPXREGS request.])
1186 fi
1187
1188 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
1189 AC_MSG_CHECKING(for PT_GETDBREGS)
1190 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
1191 [AC_TRY_COMPILE([#include <sys/types.h>
1192 #include <sys/ptrace.h>],
1193                 [PT_GETDBREGS;],
1194                 [gdb_cv_have_pt_getdbregs=yes],
1195                 [gdb_cv_have_pt_getdbregs=no])])
1196 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
1197 if test $gdb_cv_have_pt_getdbregs = yes; then
1198   AC_DEFINE(HAVE_PT_GETDBREGS, 1,
1199   [Define if sys/ptrace.h defines the PT_GETDBREGS request.])
1200 fi
1201
1202 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
1203 AC_MSG_CHECKING(for PT_GETXMMREGS)
1204 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
1205 [AC_TRY_COMPILE([#include <sys/types.h>
1206 #include <sys/ptrace.h>],
1207                 [PT_GETXMMREGS;],
1208                 [gdb_cv_have_pt_getxmmregs=yes],
1209                 [gdb_cv_have_pt_getxmmregs=no])])
1210 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
1211 if test $gdb_cv_have_pt_getxmmregs = yes; then
1212   AC_DEFINE(HAVE_PT_GETXMMREGS, 1,
1213   [Define if sys/ptrace.h defines the PT_GETXMMREGS request.])
1214 fi
1215
1216 # Detect which type of /proc is in use, such as for Unixware or Solaris.
1217
1218 if test "${target}" = "${host}"; then
1219   case "${host}" in
1220   *-*-unixware* | *-*-sysv4.2* | *-*-sysv5* | *-*-interix* )
1221       AC_DEFINE(NEW_PROC_API, 1,
1222       [Define if you want to use new multi-fd /proc interface
1223        (replaces HAVE_MULTIPLE_PROC_FDS as well as other macros).])
1224       ;;
1225   *-*-solaris2.[[6789]] | *-*-solaris2.1[[0-9]]*)
1226       AC_DEFINE(NEW_PROC_API, 1,
1227       [Define if you want to use new multi-fd /proc interface
1228        (replaces HAVE_MULTIPLE_PROC_FDS as well as other macros).])
1229       ;;
1230   mips-sgi-irix5*)
1231       # Work around <sys/proc.h> needing _KMEMUSER problem on IRIX 5.
1232       AC_DEFINE([_KMEMUSER], 1,
1233       [Define to 1 so <sys/proc.h> gets a definition of anon_hdl.  Works
1234        around a <sys/proc.h> problem on IRIX 5.])
1235       ;;
1236   esac
1237 fi
1238
1239 if test "$ac_cv_header_sys_procfs_h" = yes; then
1240   BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
1241   BFD_HAVE_SYS_PROCFS_TYPE(prrun_t)
1242   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
1243   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
1244   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
1245   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
1246   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
1247   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset32_t)
1248   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
1249   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
1250   BFD_HAVE_SYS_PROCFS_TYPE(prsysent_t)
1251   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigset_t)
1252   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigaction64_t)
1253   BFD_HAVE_SYS_PROCFS_TYPE(pr_siginfo64_t)
1254
1255
1256   dnl Check for broken prfpregset_t type
1257
1258   dnl For Linux/i386, glibc 2.1.3 was released with a bogus
1259   dnl prfpregset_t type (it's a typedef for the pointer to a struct
1260   dnl instead of the struct itself).  We detect this here, and work
1261   dnl around it in gdb_proc_service.h.
1262
1263   if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
1264     AC_MSG_CHECKING(whether prfpregset_t type is broken)
1265     AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
1266       [AC_TRY_RUN([#include <sys/procfs.h>
1267        int main ()
1268        {
1269          if (sizeof (prfpregset_t) == sizeof (void *))
1270            return 1;
1271          return 0;
1272        }],
1273        gdb_cv_prfpregset_t_broken=no,
1274        gdb_cv_prfpregset_t_broken=yes,
1275        gdb_cv_prfpregset_t_broken=yes)])
1276     AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
1277     if test $gdb_cv_prfpregset_t_broken = yes; then
1278       AC_DEFINE(PRFPREGSET_T_BROKEN, 1,
1279       [Define if the prfpregset_t type is broken.])
1280     fi
1281   fi
1282
1283   dnl Check for PIOCSET ioctl entry
1284
1285   AC_MSG_CHECKING(for PIOCSET ioctl entry in sys/procfs.h)
1286   AC_CACHE_VAL(gdb_cv_have_procfs_piocset,
1287   [AC_TRY_COMPILE([#include <unistd.h>
1288 #include <sys/types.h>
1289 #include <sys/procfs.h>
1290 ], [
1291     int dummy;;
1292     dummy = ioctl(0, PIOCSET, &dummy);
1293   ],
1294   gdb_cv_have_procfs_piocset=yes, gdb_cv_have_procfs_piocset=no)])
1295   AC_MSG_RESULT($gdb_cv_have_procfs_piocset)
1296   if test $gdb_cv_have_procfs_piocset = yes; then
1297     AC_DEFINE(HAVE_PROCFS_PIOCSET, 1,
1298     [Define if ioctl argument PIOCSET is available.])
1299   fi
1300 fi
1301
1302 dnl For native ports (host == target), check to see what kind of
1303 dnl legacy link.h support is needed.  (See solib-legacy.c.)
1304 if test ${host} = ${target} ; then
1305   dnl Check for struct link_map with l_ members which are indicative
1306   dnl of SVR4-like shared libraries
1307
1308   AC_MSG_CHECKING(for member l_addr in struct link_map)
1309   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_l_members,
1310     [AC_TRY_COMPILE([#include <link.h>],
1311                     [struct link_map lm; (void) lm.l_addr;],
1312                     gdb_cv_have_struct_link_map_with_l_members=yes,
1313                     gdb_cv_have_struct_link_map_with_l_members=no)])
1314   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_l_members)
1315   if test $gdb_cv_have_struct_link_map_with_l_members = yes; then
1316     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_L_MEMBERS,1,
1317     [Define if <link.h> exists and defines struct link_map which has
1318      members with an ``l_'' prefix.  (For Solaris, SVR4, and
1319      SVR4-like systems.)])
1320   fi
1321
1322   dnl Check for struct link_map with lm_ members which are indicative
1323   dnl of SunOS-like shared libraries
1324
1325   AC_MSG_CHECKING(for member lm_addr in struct link_map)
1326   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_lm_members,
1327     [AC_TRY_COMPILE([#include <sys/types.h>
1328 #include <link.h>],
1329                     [struct link_map lm; (void) lm.lm_addr;],
1330                     gdb_cv_have_struct_link_map_with_lm_members=yes,
1331                     gdb_cv_have_struct_link_map_with_lm_members=no)])
1332   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_lm_members)
1333   if test $gdb_cv_have_struct_link_map_with_lm_members = yes; then
1334     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_LM_MEMBERS, 1,
1335     [Define if <link.h> exists and defines struct link_map which has
1336      members with an ``lm_'' prefix.  (For SunOS.)])
1337   fi
1338
1339   dnl Check for struct so_map with som_ members which are found on
1340   dnl some *BSD systems.
1341
1342   AC_MSG_CHECKING(for member som_addr in struct so_map)
1343   AC_CACHE_VAL(gdb_cv_have_struct_so_map_with_som_members,
1344     [AC_TRY_COMPILE([#include <sys/types.h>
1345 #ifdef HAVE_NLIST_H
1346 #include <nlist.h>
1347 #endif
1348 #include <link.h>],
1349                     [struct so_map lm; (void) lm.som_addr;],
1350                     gdb_cv_have_struct_so_map_with_som_members=yes,
1351                     gdb_cv_have_struct_so_map_with_som_members=no)])
1352   AC_MSG_RESULT($gdb_cv_have_struct_so_map_with_som_members)
1353   if test $gdb_cv_have_struct_so_map_with_som_members = yes; then
1354     AC_DEFINE(HAVE_STRUCT_SO_MAP_WITH_SOM_MEMBERS, 1,
1355     [Define if <link.h> exists and defines a struct so_map which has
1356      members with an ``som_'' prefix.  (Found on older *BSD systems.)])
1357   fi
1358
1359   dnl Check for struct link_map32 type, which allows a 64-bit Solaris
1360   dnl debugger to debug a 32-bit Solaris app with 32-bit shared libraries.
1361
1362   AC_MSG_CHECKING(for struct link_map32 in sys/link.h)
1363   AC_CACHE_VAL(gdb_cv_have_struct_link_map32,
1364     [AC_TRY_COMPILE([#define _SYSCALL32
1365 #include <sys/link.h>], [struct link_map32 l;],
1366      gdb_cv_have_struct_link_map32=yes,
1367      gdb_cv_have_struct_link_map32=no)])
1368   AC_MSG_RESULT($gdb_cv_have_struct_link_map32)
1369   if test $gdb_cv_have_struct_link_map32 = yes; then
1370     AC_DEFINE(HAVE_STRUCT_LINK_MAP32, 1,
1371     [Define if <sys/link.h> has struct link_map32])
1372     AC_DEFINE(_SYSCALL32, 1,
1373     [Define if <sys/link.h> has link_map32 (solaris sparc-64 target)])
1374   fi
1375 fi
1376
1377 # Check if the compiler supports the `long long' type.
1378
1379 AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long,
1380                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1381 [[extern long long foo;]],
1382 [[switch (foo & 2) { case 0: return 1; }]])],
1383                                   gdb_cv_c_long_long=yes,
1384                                   gdb_cv_c_long_long=no)])
1385 if test $gdb_cv_c_long_long = yes; then
1386   AC_DEFINE(CC_HAS_LONG_LONG, 1,
1387             [Define to 1 if the compiler supports long long.])
1388 fi
1389
1390 # Check if the compiler and runtime support printing long longs.
1391
1392 AC_CACHE_CHECK([for long long support in printf],
1393                gdb_cv_printf_has_long_long,
1394                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1395 [[char buf[32];
1396   long long l = 0;
1397   l = (l << 16) + 0x0123;
1398   l = (l << 16) + 0x4567;
1399   l = (l << 16) + 0x89ab;
1400   l = (l << 16) + 0xcdef;
1401   sprintf (buf, "0x%016llx", l);
1402   return (strcmp ("0x0123456789abcdef", buf));]])],
1403                               gdb_cv_printf_has_long_long=yes,
1404                               gdb_cv_printf_has_long_long=no,
1405                               gdb_cv_printf_has_long_long=no)])
1406 if test $gdb_cv_printf_has_long_long = yes; then
1407   AC_DEFINE(PRINTF_HAS_LONG_LONG, 1,
1408             [Define to 1 if the "%ll" format works to print long longs.])
1409 fi
1410
1411 # Check if the compiler and runtime support printing decfloats.
1412
1413 AC_CACHE_CHECK([for decfloat support in printf],
1414                gdb_cv_printf_has_decfloat,
1415                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1416 [[char buf[64];
1417   _Decimal32 d32 = 1.2345df;
1418   _Decimal64 d64 = 1.2345dd;
1419   _Decimal128 d128 = 1.2345dl;
1420   sprintf (buf, "Decimal32: %H\nDecimal64: %D\nDecimal128: %DD", d32, d64, d128);
1421   return (strcmp ("Decimal32: 1.2345\nDecimal64: 1.2345\nDecimal128: 1.2345", buf));]])],
1422                               gdb_cv_printf_has_decfloat=yes,
1423                               gdb_cv_printf_has_decfloat=no,
1424                               gdb_cv_printf_has_decfloat=no)])
1425 if test $gdb_cv_printf_has_decfloat = yes; then
1426   AC_DEFINE(PRINTF_HAS_DECFLOAT, 1,
1427             [Define to 1 if the "%H, %D and %DD" formats work to print decfloats.])
1428 fi
1429
1430 # Check if the compiler supports the `long double' type.  We can't use
1431 # AC_C_LONG_DOUBLE because that one does additional checks on the
1432 # constants defined in <float.h> that fail on some systems,
1433 # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6.
1434
1435 AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double,
1436                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])],
1437                                   gdb_cv_c_long_double=yes,
1438                                   gdb_cv_c_long_double=no)])
1439 if test $gdb_cv_c_long_double = yes; then
1440   AC_DEFINE(HAVE_LONG_DOUBLE, 1,
1441            [Define to 1 if the compiler supports long double.])
1442 fi
1443
1444 # Check if the compiler and runtime support printing long doubles.
1445
1446 AC_CACHE_CHECK([for long double support in printf],
1447                gdb_cv_printf_has_long_double,
1448                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1449 [[char buf[16];
1450   long double f = 3.141592653;
1451   sprintf (buf, "%Lg", f);
1452   return (strncmp ("3.14159", buf, 7));]])],
1453                               gdb_cv_printf_has_long_double=yes,
1454                               gdb_cv_printf_has_long_double=no,
1455                               gdb_cv_printf_has_long_double=no)])
1456 if test $gdb_cv_printf_has_long_double = yes; then
1457   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1,
1458             [Define to 1 if the "%Lg" format works to print long doubles.])
1459 fi
1460
1461 # Check if the compiler and runtime support scanning long doubles.
1462
1463 AC_CACHE_CHECK([for long double support in scanf],
1464                gdb_cv_scanf_has_long_double,
1465                [AC_RUN_IFELSE([AC_LANG_PROGRAM(
1466 [[#include <stdio.h>]],
1467 [[char *buf = "3.141592653";
1468   long double f = 0;
1469   sscanf (buf, "%Lg", &f);
1470   return !(f > 3.14159 && f < 3.14160);]])],
1471                               gdb_cv_scanf_has_long_double=yes,
1472                               gdb_cv_scanf_has_long_double=no,
1473                               gdb_cv_scanf_has_long_double=no)])
1474 if test $gdb_cv_scanf_has_long_double = yes; then
1475   AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1,
1476             [Define to 1 if the "%Lg" format works to scan long doubles.])
1477 fi
1478
1479 case ${host_os} in
1480 aix*)
1481   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1482     SAVE_LDFLAGS=$LDFLAGS
1483
1484     case $GCC in
1485     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1486     *) gdb_cv_bigtoc=-bbigtoc ;;
1487     esac
1488
1489     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1490     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1491     LDFLAGS="${SAVE_LDFLAGS}"
1492   ])
1493   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
1494   ;;
1495 esac
1496
1497 AC_MSG_CHECKING(for the dynamic export flag)
1498 dynamic_list=false
1499 if test "${gdb_native}" = yes; then
1500    # The dynamically loaded libthread_db needs access to symbols in the gdb
1501    # executable.  Older GNU ld supports --export-dynamic but --dynamic-list
1502    # may not be supported there.
1503    old_LDFLAGS="$LDFLAGS"
1504    # Older GNU ld supports --export-dynamic but --dynamic-list it does not.
1505    RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
1506    LDFLAGS="$LDFLAGS $RDYNAMIC"
1507    if test "${have_libpython}" = no; then
1508      AC_TRY_LINK([], [], [dynamic_list=true])
1509    else
1510      # Workaround http://bugs.python.org/issue4434 where static
1511      # libpythonX.Y.a would get its symbols required for
1512      # pythonX.Y/lib-dynload/*.so modules hidden by -Wl,--dynamic-list.
1513      # Problem does not happen for the recommended libpythonX.Y.so linkage.
1514      old_CFLAGS="$CFLAGS"
1515      CFLAGS="$CFLAGS $PYTHON_CFLAGS"
1516      AC_RUN_IFELSE(
1517        AC_LANG_PROGRAM(
1518          [#include "]${have_libpython}[/Python.h"],
1519          [int err;
1520           Py_Initialize ();
1521           err = PyRun_SimpleString ("import itertools\n");
1522           Py_Finalize ();
1523           return err == 0 ? 0 : 1;]),
1524        [dynamic_list=true], [], [true])
1525      CFLAGS="$old_CFLAGS"
1526    fi
1527    LDFLAGS="$old_LDFLAGS"
1528 fi
1529 if $dynamic_list; then
1530   found="-Wl,--dynamic-list"
1531   RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'
1532 else
1533   found="-rdynamic"
1534   RDYNAMIC="-rdynamic"
1535 fi
1536 AC_SUBST(RDYNAMIC)
1537 AC_MSG_RESULT($found)
1538
1539 dnl For certain native configurations, we need to check whether thread
1540 dnl support can be built in or not.
1541 dnl
1542 dnl Note that we only want this if we are both native (host == target),
1543 dnl and not doing a canadian cross build (build == host).
1544
1545 if test ${build} = ${host} -a ${host} = ${target} ; then
1546    case ${host_os} in
1547    solaris*)
1548       # See if thread_db library is around for Solaris thread debugging.
1549       # Note that we must explicitly test for version 1 of the library
1550       # because version 0 (present on Solaris 2.4 or earlier) doesn't have
1551       # the same API.
1552       AC_MSG_CHECKING(for Solaris thread debugging library)
1553       if test -f /usr/lib/libthread_db.so.1 ; then
1554          AC_MSG_RESULT(yes)
1555          AC_DEFINE(HAVE_THREAD_DB_LIB, 1,
1556          [Define if using Solaris thread debugging.])
1557          CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
1558          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
1559          AC_CHECK_LIB(dl, dlopen)
1560          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} $RDYNAMIC"
1561          # Sun randomly tweaked the prototypes in <proc_service.h>
1562          # at one point.
1563          AC_MSG_CHECKING(if <proc_service.h> is old)
1564          AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
1565             AC_TRY_COMPILE([
1566                 #include <proc_service.h>
1567                 ps_err_e ps_pdwrite
1568                     (struct ps_prochandle*, psaddr_t, const void*, size_t);
1569             ],, gdb_cv_proc_service_is_old=no,
1570                 gdb_cv_proc_service_is_old=yes)
1571          ])
1572          AC_MSG_RESULT($gdb_cv_proc_service_is_old)
1573          if test $gdb_cv_proc_service_is_old = yes; then
1574             AC_DEFINE(PROC_SERVICE_IS_OLD, 1,
1575             [Define if <proc_service.h> on solaris uses int instead of
1576              size_t, and assorted other type changes.])
1577          fi
1578       else
1579          AC_MSG_RESULT(no)
1580       fi
1581       ;;
1582    aix*)
1583       AC_MSG_CHECKING(for AiX thread debugging library)
1584       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
1585                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
1586                                    [#ifndef PTHDB_VERSION_3
1587                                     #error
1588                                     #endif],
1589                                    gdb_cv_have_aix_thread_debug=yes,
1590                                    gdb_cv_have_aix_thread_debug=no)])
1591       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1592       if test $gdb_cv_have_aix_thread_debug = yes; then
1593          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1594          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1595          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -lpthdebug"
1596
1597          # Older versions of AIX do not provide the declaration for
1598          # the getthrds function (it appears that it was introduced
1599          # with AIX 6.x).
1600          AC_CHECK_DECLS(getthrds, [], [], [[#include <procinfo.h>]])
1601       fi
1602       ;;
1603    esac
1604    AC_SUBST(CONFIG_LDFLAGS)
1605 fi
1606
1607 dnl See if we have a thread_db header file that has TD_NOTALLOC and
1608 dnl other error codes.
1609 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1610    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
1611                   gdb_cv_thread_db_h_has_td_notalloc,
1612      AC_TRY_COMPILE(
1613        [#include <thread_db.h>],
1614        [int i = TD_NOTALLOC;],
1615        gdb_cv_thread_db_h_has_td_notalloc=yes,
1616        gdb_cv_thread_db_h_has_td_notalloc=no
1617      )
1618    )
1619    AC_CACHE_CHECK([whether <thread_db.h> has TD_VERSION],
1620                   gdb_cv_thread_db_h_has_td_version,
1621      AC_TRY_COMPILE(
1622        [#include <thread_db.h>],
1623        [int i = TD_VERSION;],
1624        gdb_cv_thread_db_h_has_td_version=yes,
1625        gdb_cv_thread_db_h_has_td_version=no
1626      )
1627    )
1628    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTLS],
1629                   gdb_cv_thread_db_h_has_td_notls,
1630      AC_TRY_COMPILE(
1631        [#include <thread_db.h>],
1632        [int i = TD_NOTLS;],
1633        gdb_cv_thread_db_h_has_td_notls=yes,
1634        gdb_cv_thread_db_h_has_td_notls=no
1635      )
1636    )
1637 fi
1638 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1639   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1640             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1641 fi
1642 if test "x$gdb_cv_thread_db_h_has_td_version" = "xyes"; then
1643   AC_DEFINE(THREAD_DB_HAS_TD_VERSION, 1,
1644             [Define if <thread_db.h> has the TD_VERSION error code.])
1645 fi
1646 if test "x$gdb_cv_thread_db_h_has_td_notls" = "xyes"; then
1647   AC_DEFINE(THREAD_DB_HAS_TD_NOTLS, 1,
1648             [Define if <thread_db.h> has the TD_NOTLS error code.])
1649 fi
1650
1651 dnl See if we have a sys/syscall header file that has __NR_tkill.
1652 if test "x$ac_cv_header_sys_syscall_h" = "xyes"; then
1653    AC_CACHE_CHECK([whether <sys/syscall.h> has __NR_tkill],
1654                   gdb_cv_sys_syscall_h_has_tkill,
1655      AC_TRY_COMPILE(
1656        [#include <sys/syscall.h>],
1657        [int i = __NR_tkill;],
1658        gdb_cv_sys_syscall_h_has_tkill=yes,
1659        gdb_cv_sys_syscall_h_has_tkill=no
1660      )
1661    )
1662 fi
1663 dnl See if we can issue tkill syscall.
1664 if test "x$gdb_cv_sys_syscall_h_has_tkill" = "xyes" && test "x$ac_cv_func_syscall" = "xyes"; then
1665   AC_DEFINE(HAVE_TKILL_SYSCALL, 1, [Define if you support the tkill syscall.])
1666 fi
1667
1668 dnl Check if we can disable the virtual address space randomization.
1669 dnl The functionality of setarch -R.
1670 AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>])
1671 define([PERSONALITY_TEST], [AC_LANG_PROGRAM([#include <sys/personality.h>], [
1672 #      if !HAVE_DECL_ADDR_NO_RANDOMIZE
1673 #       define ADDR_NO_RANDOMIZE 0x0040000
1674 #      endif
1675        /* Test the flag could be set and stays set.  */
1676        personality (personality (0xffffffff) | ADDR_NO_RANDOMIZE);
1677        if (!(personality (personality (0xffffffff)) & ADDR_NO_RANDOMIZE))
1678            return 1])])
1679 AC_RUN_IFELSE([PERSONALITY_TEST],
1680               [have_personality=true],
1681               [have_personality=false],
1682               [AC_LINK_IFELSE([PERSONALITY_TEST],
1683                               [have_personality=true],
1684                               [have_personality=false])])
1685 if $have_personality
1686 then
1687     AC_DEFINE([HAVE_PERSONALITY], 1,
1688               [Define if you support the personality syscall.])
1689 fi
1690
1691 dnl Handle optional features that can be enabled.
1692
1693 target_sysroot_reloc=0
1694 AC_ARG_WITH(sysroot,
1695 AS_HELP_STRING([--with-sysroot@<:@=DIR@:>@], [search for usr/lib et al within DIR]),
1696 [
1697  case ${with_sysroot} in
1698  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
1699  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
1700  esac
1701
1702  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
1703
1704  if test "x$prefix" = xNONE; then
1705   test_prefix=/usr/local
1706  else
1707   test_prefix=$prefix
1708  fi
1709  if test "x$exec_prefix" = xNONE || test "x$exec_prefix" = 'x${prefix}'; then
1710   test_exec_prefix=$test_prefix
1711  else
1712   test_exec_prefix=$exec_prefix
1713  fi
1714  case ${TARGET_SYSTEM_ROOT} in
1715  "${test_prefix}"|"${test_prefix}/"*|\
1716  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
1717  '${prefix}'|'${prefix}/'*|\
1718  '${exec_prefix}'|'${exec_prefix}/'*)
1719    target_sysroot_reloc=1
1720    ;;
1721  esac
1722 ], [
1723  TARGET_SYSTEM_ROOT=
1724  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"'
1725 ])
1726 TARGET_SYSTEM_ROOT_DEFINE="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE=$target_sysroot_reloc"
1727 AC_SUBST(TARGET_SYSTEM_ROOT)
1728 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
1729
1730 GDB_AC_WITH_DIR(SYSTEM_GDBINIT, system-gdbinit,
1731     [automatically load a system-wide gdbinit file],
1732     [])
1733
1734 AC_ARG_ENABLE(werror,
1735   AS_HELP_STRING([--enable-werror], [treat compile warnings as errors]),
1736   [case "${enableval}" in
1737      yes | y) ERROR_ON_WARNING="yes" ;;
1738      no | n)  ERROR_ON_WARNING="no" ;;
1739      *) AC_MSG_ERROR(bad value ${enableval} for --enable-werror) ;;
1740    esac])
1741
1742 # Enable -Werror by default when using gcc
1743 if test "${GCC}" = yes -a -z "${ERROR_ON_WARNING}" ; then
1744     ERROR_ON_WARNING=yes
1745 fi
1746
1747 WERROR_CFLAGS=""
1748 if test "${ERROR_ON_WARNING}" = yes ; then
1749     WERROR_CFLAGS="-Werror"
1750 fi
1751
1752 # The entries after -Wno-pointer-sign are disabled warnings which may
1753 # be enabled in the future, which can not currently be used to build
1754 # GDB.
1755 # NOTE: If you change this list, remember to update
1756 # gdb/doc/gdbint.texinfo.
1757 build_warnings="-Wall -Wdeclaration-after-statement -Wpointer-arith \
1758 -Wformat-nonliteral -Wno-pointer-sign \
1759 -Wno-unused -Wunused-value -Wunused-function \
1760 -Wno-switch -Wno-char-subscripts"
1761
1762 # Enable -Wno-format by default when using gcc on mingw since many
1763 # GCC versions complain about %I64.
1764 case "${host}" in
1765   *-*-mingw32*) build_warnings="$build_warnings -Wno-format" ;;
1766 esac
1767
1768 AC_ARG_ENABLE(build-warnings,
1769 AS_HELP_STRING([--enable-build-warnings], [enable build-time compiler warnings if gcc is used]),
1770 [case "${enableval}" in
1771   yes)  ;;
1772   no)   build_warnings="-w";;
1773   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1774         build_warnings="${build_warnings} ${t}";;
1775   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1776         build_warnings="${t} ${build_warnings}";;
1777   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1778 esac
1779 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1780   echo "Setting compiler warning flags = $build_warnings" 6>&1
1781 fi])dnl
1782 AC_ARG_ENABLE(gdb-build-warnings,
1783 AS_HELP_STRING([--enable-gdb-build-warnings], [enable GDB specific build-time compiler warnings if gcc is used]),
1784 [case "${enableval}" in
1785   yes)  ;;
1786   no)   build_warnings="-w";;
1787   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1788         build_warnings="${build_warnings} ${t}";;
1789   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1790         build_warnings="${t} ${build_warnings}";;
1791   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1792 esac
1793 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1794   echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1
1795 fi])dnl
1796 WARN_CFLAGS=""
1797 if test "x${build_warnings}" != x -a "x$GCC" = xyes
1798 then
1799     AC_MSG_CHECKING(compiler warning flags)
1800     # Separate out the -Werror flag as some files just cannot be
1801     # compiled with it enabled.
1802     for w in ${build_warnings}; do
1803         case $w in
1804         -Werr*) WERROR_CFLAGS=-Werror ;;
1805         *) # Check that GCC accepts it
1806             saved_CFLAGS="$CFLAGS"
1807             CFLAGS="$CFLAGS $w"
1808             AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
1809             CFLAGS="$saved_CFLAGS"
1810         esac
1811     done
1812     AC_MSG_RESULT(${WARN_CFLAGS} ${WERROR_CFLAGS})
1813 fi
1814 AC_SUBST(WARN_CFLAGS)
1815 AC_SUBST(WERROR_CFLAGS)
1816
1817 # In the Cygwin environment, we need some additional flags.
1818 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1819 [AC_EGREP_CPP(lose, [
1820 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1821 lose
1822 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1823
1824
1825 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1826 SER_HARDWIRE="ser-base.o ser-unix.o ser-pipe.o ser-tcp.o"
1827 case ${host} in
1828   *go32* ) SER_HARDWIRE=ser-go32.o ;;
1829   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
1830   *mingw32*) SER_HARDWIRE="ser-base.o ser-tcp.o ser-mingw.o" ;;
1831 esac
1832 AC_SUBST(SER_HARDWIRE)
1833
1834 # libreadline needs libuser32.a in a cygwin environment
1835 WIN32LIBS=
1836 if test x$gdb_cv_os_cygwin = xyes; then
1837     WIN32LIBS="-luser32"
1838     case "${target}" in
1839         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
1840         ;;
1841     esac
1842 fi
1843
1844 # The ser-tcp.c module requires sockets.
1845 case ${host} in
1846   *mingw32*)
1847     AC_DEFINE(USE_WIN32API, 1,
1848               [Define if we should use the Windows API, instead of the
1849                POSIX API.  On Windows, we use the Windows API when
1850                building for MinGW, but the POSIX API when building
1851                for Cygwin.])
1852     WIN32LIBS="$WIN32LIBS -lws2_32"
1853     ;;
1854 esac
1855 AC_SUBST(WIN32LIBS)
1856
1857 # Add ELF support to GDB, but only if BFD includes ELF support.
1858 OLD_CFLAGS=$CFLAGS
1859 OLD_LDFLAGS=$LDFLAGS
1860 OLD_LIBS=$LIBS
1861 CFLAGS="$CFLAGS -I${srcdir}/../include -I../bfd -I${srcdir}/../bfd"
1862 LDFLAGS="$LDFLAGS -L../bfd -L../libiberty"
1863 intl=`echo $LIBINTL | sed 's,${top_builddir}/,,g'`
1864 # -ldl is provided by bfd/Makfile.am (LIBDL) <PLUGINS>.
1865 if test "$plugins" = "yes"; then
1866   LIBS="-ldl $LIBS"
1867 fi
1868 LIBS="-lbfd -liberty $intl $LIBS"
1869 AC_CACHE_CHECK([for ELF support in BFD], gdb_cv_var_elf,
1870 [AC_TRY_LINK(
1871 [#include <stdlib.h>
1872 #include "bfd.h"
1873 #include "elf-bfd.h"
1874 ],
1875 [bfd *abfd = NULL; bfd_get_elf_phdr_upper_bound (abfd); ],
1876 gdb_cv_var_elf=yes, gdb_cv_var_elf=no)])
1877 if test $gdb_cv_var_elf = yes; then
1878   CONFIG_OBS="$CONFIG_OBS elfread.o"
1879   AC_DEFINE(HAVE_ELF, 1,
1880             [Define if ELF support should be included.])
1881   # -ldl is provided by bfd/Makfile.am (LIBDL) <PLUGINS>.
1882   if test "$plugins" = "yes"; then
1883     OLD_LIBS="-ldl $OLD_LIBS"
1884   fi
1885 fi
1886 CFLAGS=$OLD_CFLAGS
1887 LDFLAGS=$OLD_LDFLAGS
1888 LIBS=$OLD_LIBS
1889
1890 # Add any host-specific objects to GDB.
1891 CONFIG_OBS="${CONFIG_OBS} ${gdb_host_obs}"
1892
1893 LIBGUI="../libgui/src/libgui.a"
1894 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
1895 AC_SUBST(LIBGUI)
1896 AC_SUBST(GUI_CFLAGS_X)
1897
1898 WIN32LDAPP=
1899 AC_SUBST(WIN32LIBS)
1900 AC_SUBST(WIN32LDAPP)
1901
1902 case "${host}" in
1903 *-*-cygwin* | *-*-mingw* )
1904     configdir="win"
1905     ;;
1906 *)
1907     configdir="unix"
1908     ;;
1909 esac
1910
1911 GDBTKLIBS=
1912 if test "${enable_gdbtk}" = "yes"; then
1913
1914     # Gdbtk must have an absolute path to srcdir in order to run
1915     # properly when not installed.
1916     here=`pwd`
1917     cd ${srcdir}
1918     GDBTK_SRC_DIR=`pwd`
1919     cd $here
1920
1921     SC_PATH_TCLCONFIG
1922
1923     # If $no_tk is nonempty, then we can't do Tk, and there is no
1924     # point to doing Tcl.
1925     SC_PATH_TKCONFIG
1926
1927     if test -z "${no_tcl}" -a -z "${no_tk}"; then
1928         SC_LOAD_TCLCONFIG
1929
1930         # Check for in-tree tcl
1931         here=`pwd`
1932         cd ${srcdir}/..
1933         topdir=`pwd`
1934         cd ${here}
1935
1936         intree="no"
1937         if test "${TCL_SRC_DIR}" = "${topdir}/tcl"; then
1938           intree="yes"
1939         fi
1940
1941         # Find Tcl private headers
1942         if test x"${intree}" = xno; then
1943           CY_AC_TCL_PRIVATE_HEADERS
1944           TCL_INCLUDE="${TCL_INCLUDE_SPEC} ${TCL_PRIVATE_INCLUDE}"
1945           TCL_LIBRARY="${TCL_LIB_SPEC}"
1946           TCL_DEPS=""
1947         else
1948           # If building tcl in the same src tree, private headers
1949           # are not needed, but we need to be sure to use the right
1950           # headers library
1951           TCL_INCLUDE="-I${TCL_SRC_DIR}/generic"
1952           TCL_LIBRARY="${TCL_BUILD_LIB_SPEC}"
1953           TCL_DEPS="../tcl/${configdir}${TCL_LIB_FILE}"
1954         fi
1955         AC_SUBST(TCL_INCLUDE)
1956         AC_SUBST(TCL_LIBRARY)
1957         AC_SUBST(TCL_DEPS)
1958
1959         SC_LOAD_TKCONFIG
1960
1961         # Check for in-tree Tk
1962         intree="no"
1963         if test "${TK_SRC_DIR}" = "${topdir}/tk"; then
1964           intree="yes"
1965         fi
1966
1967         # Find Tk private headers
1968         if test x"${intree}" = xno; then
1969           CY_AC_TK_PRIVATE_HEADERS
1970           TK_INCLUDE="${TK_INCLUDE_SPEC} ${TK_PRIVATE_INCLUDE}"
1971           TK_LIBRARY=${TK_LIB_SPEC}
1972           TK_DEPS=""
1973         else
1974           TK_INCLUDE="-I${TK_SRC_DIR}/generic"
1975           TK_LIBRARY="${TK_BUILD_LIB_SPEC}"
1976           TK_DEPS="../tk/${configdir}/${TK_LIB_FILE}"
1977         fi
1978         AC_SUBST(TK_INCLUDE)
1979         AC_SUBST(TK_LIBRARY)
1980         AC_SUBST(TK_DEPS)
1981         AC_SUBST(TK_XINCLUDES)
1982
1983         ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
1984
1985         # Include some libraries that Tcl and Tk want.
1986         TCL_LIBS='$(LIBGUI) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
1987         # Yes, the ordering seems wrong here.  But it isn't.
1988         # TK_LIBS is the list of libraries that need to be linked
1989         # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
1990         # were in LIBS then any link tests after this point would
1991         # try to include things like `$(LIBGUI)', which wouldn't work.
1992         GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
1993
1994         CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
1995         CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
1996         CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
1997         CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
1998         CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
1999         CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
2000         CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
2001
2002         if test x$gdb_cv_os_cygwin = xyes; then
2003           WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
2004           WIN32LDAPP="-Wl,--subsystem,console"
2005           CONFIG_OBS="${CONFIG_OBS} gdbres.o"
2006         fi
2007
2008         AC_CONFIG_SUBDIRS(gdbtk)
2009     fi
2010 fi
2011
2012 AC_SUBST(X_CFLAGS)
2013 AC_SUBST(X_LDFLAGS)
2014 AC_SUBST(X_LIBS)
2015 AC_SUBST(GDBTKLIBS)
2016 AC_SUBST(GDBTK_CFLAGS)
2017 AC_SUBST(GDBTK_SRC_DIR)
2018
2019 AC_PATH_X
2020
2021 # Unlike the sim directory, whether a simulator is linked is controlled by
2022 # presence of a gdb_sim definition in the target configure.tgt entry.
2023 # This code just checks for a few cases where we'd like to ignore those
2024 # definitions, even when they're present in the '.mt' file.  These cases
2025 # are when --disable-sim is specified, or if the simulator directory is
2026 # not part of the source tree.
2027 #
2028 AC_ARG_ENABLE(sim,
2029 AS_HELP_STRING([--enable-sim], [link gdb with simulator]),
2030 [echo "enable_sim = $enable_sim";
2031  echo "enableval = ${enableval}";
2032  case "${enableval}" in
2033   yes) ignore_sim=false ;;
2034   no)  ignore_sim=true ;;
2035   *)   ignore_sim=false ;;
2036  esac],
2037 [ignore_sim=false])
2038
2039 if test ! -d "${srcdir}/../sim"; then
2040   ignore_sim=true
2041 fi
2042
2043 SIM=
2044 SIM_OBS=
2045 if test "${ignore_sim}" = "false"; then
2046   if test x"${gdb_sim}" != x ; then
2047     SIM="${gdb_sim}"
2048     SIM_OBS="remote-sim.o"
2049     AC_DEFINE(WITH_SIM, 1, [Define if the simulator is being linked in.])
2050   fi
2051 fi
2052 AC_SUBST(SIM)
2053 AC_SUBST(SIM_OBS)
2054
2055 AC_SUBST(ENABLE_CFLAGS)
2056 AC_SUBST(PROFILE_CFLAGS)
2057
2058 AC_SUBST(CONFIG_OBS)
2059 AC_SUBST(CONFIG_DEPS)
2060 AC_SUBST(CONFIG_SRCS)
2061 AC_SUBST(CONFIG_ALL)
2062 AC_SUBST(CONFIG_CLEAN)
2063 AC_SUBST(CONFIG_INSTALL)
2064 AC_SUBST(CONFIG_UNINSTALL)
2065
2066 # List of host floatformats.
2067 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
2068 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
2069 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
2070
2071 # target_subdir is used by the testsuite to find the target libraries.
2072 target_subdir=
2073 if test "${host}" != "${target}"; then
2074     target_subdir="${target_alias}/"
2075 fi
2076 AC_SUBST(target_subdir)
2077
2078 frags=
2079 if test "${gdb_native}" = "yes"; then
2080   host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
2081   if test ! -f ${host_makefile_frag}; then
2082     AC_MSG_ERROR("*** Gdb does not support native target ${host}")
2083   fi
2084   frags="$frags $host_makefile_frag"
2085 else
2086   host_makefile_frag=/dev/null
2087 fi
2088
2089 AC_SUBST_FILE(host_makefile_frag)
2090 AC_SUBST(frags)
2091
2092 changequote(,)dnl
2093 if test "${gdb_native}" = "yes"; then
2094 # We pick this up from the host configuration file (.mh) because we
2095 # do not have a native configuration Makefile fragment.
2096 nativefile=`sed -n '
2097 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
2098 ' ${host_makefile_frag}`
2099 fi
2100 changequote([,])
2101
2102 if test x"${gdb_osabi}" != x ; then
2103     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
2104                        [Define to the default OS ABI for this configuration.])
2105 fi
2106
2107 # Enable multi-ice-gdb-server.
2108 AC_ARG_ENABLE(multi-ice,
2109 AS_HELP_STRING([--enable-multi-ice], [build the multi-ice-gdb-server]),
2110   [case $enableval in
2111     yes | no)
2112       ;;
2113     *) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;;
2114   esac])
2115 if test "x$enable_multi_ice" = xyes; then
2116    AC_CONFIG_SUBDIRS(multi-ice)
2117 fi
2118
2119 AC_ARG_ENABLE(gdbserver,
2120 AS_HELP_STRING([--enable-gdbserver],
2121                [automatically build gdbserver (yes/no/auto, default is auto)]),
2122 [case "${enableval}" in
2123   yes| no|auto) ;;
2124   *) AC_MSG_ERROR(bad value ${enableval} for --enable-gdbserver option) ;;
2125 esac],[enable_gdbserver=auto])
2126
2127 # We only build gdbserver automatically in a native configuration, and
2128 # only if the user did not explicitly disable its build.
2129 if test "$gdb_native" = "yes" -a "$enable_gdbserver" != "no"; then
2130   AC_MSG_CHECKING(whether gdbserver is supported on this host)
2131   if test "x$build_gdbserver" = xyes; then
2132     AC_MSG_RESULT(yes)
2133     AC_CONFIG_SUBDIRS(gdbserver)
2134     gdbserver_build_enabled=yes
2135   else
2136     AC_MSG_RESULT(no)
2137   fi
2138 fi
2139
2140 # If the user explicitly request the gdbserver to be built, verify that
2141 # we were in fact able to enable it.
2142 if test "$enable_gdbserver" = "yes" -a "$gdbserver_build_enabled" != "yes"; then
2143   AC_MSG_ERROR(Automatic gdbserver build is not supported for this configuration)
2144 fi
2145
2146 # If nativefile (NAT_FILE) is not set in config/*/*.m[ht] files, we link
2147 # to an empty version.
2148
2149 files=
2150 links=
2151
2152 rm -f nm.h
2153 if test "${nativefile}" != ""; then
2154     case "${nativefile}" in
2155       nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
2156       * ) GDB_NM_FILE="${nativefile}"
2157     esac
2158     files="${files} ${GDB_NM_FILE}"
2159     links="${links} nm.h"
2160     AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}", [nativefile])
2161 fi
2162 AC_SUBST(GDB_NM_FILE)
2163
2164 AC_LINK_FILES($files, $links)
2165
2166 dnl Check for exe extension set on certain hosts (e.g. Win32)
2167 AC_EXEEXT
2168
2169 dnl  Detect the character set used by this host.
2170 dnl  At the moment, we just assume it's UTF-8.
2171 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "UTF-8",
2172           [Define to be a string naming the default host character set.])
2173
2174 AC_OUTPUT(Makefile .gdbinit:gdbinit.in doc/Makefile gnulib/Makefile data-directory/Makefile,
2175 [
2176 case x$CONFIG_HEADERS in
2177 xconfig.h:config.in)
2178 echo > stamp-h ;;
2179 esac
2180 ])
2181
2182 exit 0